src/HOL/Multivariate_Analysis/Topology_Euclidean_Space.thy
author huffman
Wed Aug 31 08:11:47 2011 -0700 (2011-08-31)
changeset 44628 bd17b7543af1
parent 44584 08ad27488983
child 44632 076a45f65e12
permissions -rw-r--r--
move lemmas from Topology_Euclidean_Space to Euclidean_Space
     1 (*  title:      HOL/Library/Topology_Euclidian_Space.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3     Author:     Robert Himmelmann, TU Muenchen
     4     Author:     Brian Huffman, Portland State University
     5 *)
     6 
     7 header {* Elementary topology in Euclidean space. *}
     8 
     9 theory Topology_Euclidean_Space
    10 imports SEQ Linear_Algebra "~~/src/HOL/Library/Glbs" Norm_Arith
    11 begin
    12 
    13 subsection {* General notion of a topology as a value *}
    14 
    15 definition "istopology L \<longleftrightarrow> L {} \<and> (\<forall>S T. L S \<longrightarrow> L T \<longrightarrow> L (S \<inter> T)) \<and> (\<forall>K. Ball K L \<longrightarrow> L (\<Union> K))"
    16 typedef (open) 'a topology = "{L::('a set) \<Rightarrow> bool. istopology L}"
    17   morphisms "openin" "topology"
    18   unfolding istopology_def by blast
    19 
    20 lemma istopology_open_in[intro]: "istopology(openin U)"
    21   using openin[of U] by blast
    22 
    23 lemma topology_inverse': "istopology U \<Longrightarrow> openin (topology U) = U"
    24   using topology_inverse[unfolded mem_Collect_eq] .
    25 
    26 lemma topology_inverse_iff: "istopology U \<longleftrightarrow> openin (topology U) = U"
    27   using topology_inverse[of U] istopology_open_in[of "topology U"] by auto
    28 
    29 lemma topology_eq: "T1 = T2 \<longleftrightarrow> (\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S)"
    30 proof-
    31   {assume "T1=T2" hence "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S" by simp}
    32   moreover
    33   {assume H: "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S"
    34     hence "openin T1 = openin T2" by (simp add: fun_eq_iff)
    35     hence "topology (openin T1) = topology (openin T2)" by simp
    36     hence "T1 = T2" unfolding openin_inverse .}
    37   ultimately show ?thesis by blast
    38 qed
    39 
    40 text{* Infer the "universe" from union of all sets in the topology. *}
    41 
    42 definition "topspace T =  \<Union>{S. openin T S}"
    43 
    44 subsubsection {* Main properties of open sets *}
    45 
    46 lemma openin_clauses:
    47   fixes U :: "'a topology"
    48   shows "openin U {}"
    49   "\<And>S T. openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S\<inter>T)"
    50   "\<And>K. (\<forall>S \<in> K. openin U S) \<Longrightarrow> openin U (\<Union>K)"
    51   using openin[of U] unfolding istopology_def mem_Collect_eq
    52   by fast+
    53 
    54 lemma openin_subset[intro]: "openin U S \<Longrightarrow> S \<subseteq> topspace U"
    55   unfolding topspace_def by blast
    56 lemma openin_empty[simp]: "openin U {}" by (simp add: openin_clauses)
    57 
    58 lemma openin_Int[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<inter> T)"
    59   using openin_clauses by simp
    60 
    61 lemma openin_Union[intro]: "(\<forall>S \<in>K. openin U S) \<Longrightarrow> openin U (\<Union> K)"
    62   using openin_clauses by simp
    63 
    64 lemma openin_Un[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<union> T)"
    65   using openin_Union[of "{S,T}" U] by auto
    66 
    67 lemma openin_topspace[intro, simp]: "openin U (topspace U)" by (simp add: openin_Union topspace_def)
    68 
    69 lemma openin_subopen: "openin U S \<longleftrightarrow> (\<forall>x \<in> S. \<exists>T. openin U T \<and> x \<in> T \<and> T \<subseteq> S)" (is "?lhs \<longleftrightarrow> ?rhs")
    70 proof
    71   assume ?lhs then show ?rhs by auto
    72 next
    73   assume H: ?rhs
    74   let ?t = "\<Union>{T. openin U T \<and> T \<subseteq> S}"
    75   have "openin U ?t" by (simp add: openin_Union)
    76   also have "?t = S" using H by auto
    77   finally show "openin U S" .
    78 qed
    79 
    80 subsubsection {* Closed sets *}
    81 
    82 definition "closedin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> openin U (topspace U - S)"
    83 
    84 lemma closedin_subset: "closedin U S \<Longrightarrow> S \<subseteq> topspace U" by (metis closedin_def)
    85 lemma closedin_empty[simp]: "closedin U {}" by (simp add: closedin_def)
    86 lemma closedin_topspace[intro,simp]:
    87   "closedin U (topspace U)" by (simp add: closedin_def)
    88 lemma closedin_Un[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<union> T)"
    89   by (auto simp add: Diff_Un closedin_def)
    90 
    91 lemma Diff_Inter[intro]: "A - \<Inter>S = \<Union> {A - s|s. s\<in>S}" by auto
    92 lemma closedin_Inter[intro]: assumes Ke: "K \<noteq> {}" and Kc: "\<forall>S \<in>K. closedin U S"
    93   shows "closedin U (\<Inter> K)"  using Ke Kc unfolding closedin_def Diff_Inter by auto
    94 
    95 lemma closedin_Int[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<inter> T)"
    96   using closedin_Inter[of "{S,T}" U] by auto
    97 
    98 lemma Diff_Diff_Int: "A - (A - B) = A \<inter> B" by blast
    99 lemma openin_closedin_eq: "openin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> closedin U (topspace U - S)"
   100   apply (auto simp add: closedin_def Diff_Diff_Int inf_absorb2)
   101   apply (metis openin_subset subset_eq)
   102   done
   103 
   104 lemma openin_closedin:  "S \<subseteq> topspace U \<Longrightarrow> (openin U S \<longleftrightarrow> closedin U (topspace U - S))"
   105   by (simp add: openin_closedin_eq)
   106 
   107 lemma openin_diff[intro]: assumes oS: "openin U S" and cT: "closedin U T" shows "openin U (S - T)"
   108 proof-
   109   have "S - T = S \<inter> (topspace U - T)" using openin_subset[of U S]  oS cT
   110     by (auto simp add: topspace_def openin_subset)
   111   then show ?thesis using oS cT by (auto simp add: closedin_def)
   112 qed
   113 
   114 lemma closedin_diff[intro]: assumes oS: "closedin U S" and cT: "openin U T" shows "closedin U (S - T)"
   115 proof-
   116   have "S - T = S \<inter> (topspace U - T)" using closedin_subset[of U S]  oS cT
   117     by (auto simp add: topspace_def )
   118   then show ?thesis using oS cT by (auto simp add: openin_closedin_eq)
   119 qed
   120 
   121 subsubsection {* Subspace topology *}
   122 
   123 definition "subtopology U V = topology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   124 
   125 lemma istopology_subtopology: "istopology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   126   (is "istopology ?L")
   127 proof-
   128   have "?L {}" by blast
   129   {fix A B assume A: "?L A" and B: "?L B"
   130     from A B obtain Sa and Sb where Sa: "openin U Sa" "A = Sa \<inter> V" and Sb: "openin U Sb" "B = Sb \<inter> V" by blast
   131     have "A\<inter>B = (Sa \<inter> Sb) \<inter> V" "openin U (Sa \<inter> Sb)"  using Sa Sb by blast+
   132     then have "?L (A \<inter> B)" by blast}
   133   moreover
   134   {fix K assume K: "K \<subseteq> Collect ?L"
   135     have th0: "Collect ?L = (\<lambda>S. S \<inter> V) ` Collect (openin U)"
   136       apply (rule set_eqI)
   137       apply (simp add: Ball_def image_iff)
   138       by metis
   139     from K[unfolded th0 subset_image_iff]
   140     obtain Sk where Sk: "Sk \<subseteq> Collect (openin U)" "K = (\<lambda>S. S \<inter> V) ` Sk" by blast
   141     have "\<Union>K = (\<Union>Sk) \<inter> V" using Sk by auto
   142     moreover have "openin U (\<Union> Sk)" using Sk by (auto simp add: subset_eq)
   143     ultimately have "?L (\<Union>K)" by blast}
   144   ultimately show ?thesis
   145     unfolding subset_eq mem_Collect_eq istopology_def by blast
   146 qed
   147 
   148 lemma openin_subtopology:
   149   "openin (subtopology U V) S \<longleftrightarrow> (\<exists> T. (openin U T) \<and> (S = T \<inter> V))"
   150   unfolding subtopology_def topology_inverse'[OF istopology_subtopology]
   151   by auto
   152 
   153 lemma topspace_subtopology: "topspace(subtopology U V) = topspace U \<inter> V"
   154   by (auto simp add: topspace_def openin_subtopology)
   155 
   156 lemma closedin_subtopology:
   157   "closedin (subtopology U V) S \<longleftrightarrow> (\<exists>T. closedin U T \<and> S = T \<inter> V)"
   158   unfolding closedin_def topspace_subtopology
   159   apply (simp add: openin_subtopology)
   160   apply (rule iffI)
   161   apply clarify
   162   apply (rule_tac x="topspace U - T" in exI)
   163   by auto
   164 
   165 lemma openin_subtopology_refl: "openin (subtopology U V) V \<longleftrightarrow> V \<subseteq> topspace U"
   166   unfolding openin_subtopology
   167   apply (rule iffI, clarify)
   168   apply (frule openin_subset[of U])  apply blast
   169   apply (rule exI[where x="topspace U"])
   170   by auto
   171 
   172 lemma subtopology_superset: assumes UV: "topspace U \<subseteq> V"
   173   shows "subtopology U V = U"
   174 proof-
   175   {fix S
   176     {fix T assume T: "openin U T" "S = T \<inter> V"
   177       from T openin_subset[OF T(1)] UV have eq: "S = T" by blast
   178       have "openin U S" unfolding eq using T by blast}
   179     moreover
   180     {assume S: "openin U S"
   181       hence "\<exists>T. openin U T \<and> S = T \<inter> V"
   182         using openin_subset[OF S] UV by auto}
   183     ultimately have "(\<exists>T. openin U T \<and> S = T \<inter> V) \<longleftrightarrow> openin U S" by blast}
   184   then show ?thesis unfolding topology_eq openin_subtopology by blast
   185 qed
   186 
   187 lemma subtopology_topspace[simp]: "subtopology U (topspace U) = U"
   188   by (simp add: subtopology_superset)
   189 
   190 lemma subtopology_UNIV[simp]: "subtopology U UNIV = U"
   191   by (simp add: subtopology_superset)
   192 
   193 subsubsection {* The standard Euclidean topology *}
   194 
   195 definition
   196   euclidean :: "'a::topological_space topology" where
   197   "euclidean = topology open"
   198 
   199 lemma open_openin: "open S \<longleftrightarrow> openin euclidean S"
   200   unfolding euclidean_def
   201   apply (rule cong[where x=S and y=S])
   202   apply (rule topology_inverse[symmetric])
   203   apply (auto simp add: istopology_def)
   204   done
   205 
   206 lemma topspace_euclidean: "topspace euclidean = UNIV"
   207   apply (simp add: topspace_def)
   208   apply (rule set_eqI)
   209   by (auto simp add: open_openin[symmetric])
   210 
   211 lemma topspace_euclidean_subtopology[simp]: "topspace (subtopology euclidean S) = S"
   212   by (simp add: topspace_euclidean topspace_subtopology)
   213 
   214 lemma closed_closedin: "closed S \<longleftrightarrow> closedin euclidean S"
   215   by (simp add: closed_def closedin_def topspace_euclidean open_openin Compl_eq_Diff_UNIV)
   216 
   217 lemma open_subopen: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S)"
   218   by (simp add: open_openin openin_subopen[symmetric])
   219 
   220 text {* Basic "localization" results are handy for connectedness. *}
   221 
   222 lemma openin_open: "openin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. open T \<and> (S = U \<inter> T))"
   223   by (auto simp add: openin_subtopology open_openin[symmetric])
   224 
   225 lemma openin_open_Int[intro]: "open S \<Longrightarrow> openin (subtopology euclidean U) (U \<inter> S)"
   226   by (auto simp add: openin_open)
   227 
   228 lemma open_openin_trans[trans]:
   229  "open S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> openin (subtopology euclidean S) T"
   230   by (metis Int_absorb1  openin_open_Int)
   231 
   232 lemma open_subset:  "S \<subseteq> T \<Longrightarrow> open S \<Longrightarrow> openin (subtopology euclidean T) S"
   233   by (auto simp add: openin_open)
   234 
   235 lemma closedin_closed: "closedin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. closed T \<and> S = U \<inter> T)"
   236   by (simp add: closedin_subtopology closed_closedin Int_ac)
   237 
   238 lemma closedin_closed_Int: "closed S ==> closedin (subtopology euclidean U) (U \<inter> S)"
   239   by (metis closedin_closed)
   240 
   241 lemma closed_closedin_trans: "closed S \<Longrightarrow> closed T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> closedin (subtopology euclidean S) T"
   242   apply (subgoal_tac "S \<inter> T = T" )
   243   apply auto
   244   apply (frule closedin_closed_Int[of T S])
   245   by simp
   246 
   247 lemma closed_subset: "S \<subseteq> T \<Longrightarrow> closed S \<Longrightarrow> closedin (subtopology euclidean T) S"
   248   by (auto simp add: closedin_closed)
   249 
   250 lemma openin_euclidean_subtopology_iff:
   251   fixes S U :: "'a::metric_space set"
   252   shows "openin (subtopology euclidean U) S
   253   \<longleftrightarrow> S \<subseteq> U \<and> (\<forall>x\<in>S. \<exists>e>0. \<forall>x'\<in>U. dist x' x < e \<longrightarrow> x'\<in> S)" (is "?lhs \<longleftrightarrow> ?rhs")
   254 proof
   255   assume ?lhs thus ?rhs unfolding openin_open open_dist by blast
   256 next
   257   def T \<equiv> "{x. \<exists>a\<in>S. \<exists>d>0. (\<forall>y\<in>U. dist y a < d \<longrightarrow> y \<in> S) \<and> dist x a < d}"
   258   have 1: "\<forall>x\<in>T. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> T"
   259     unfolding T_def
   260     apply clarsimp
   261     apply (rule_tac x="d - dist x a" in exI)
   262     apply (clarsimp simp add: less_diff_eq)
   263     apply (erule rev_bexI)
   264     apply (rule_tac x=d in exI, clarify)
   265     apply (erule le_less_trans [OF dist_triangle])
   266     done
   267   assume ?rhs hence 2: "S = U \<inter> T"
   268     unfolding T_def
   269     apply auto
   270     apply (drule (1) bspec, erule rev_bexI)
   271     apply auto
   272     done
   273   from 1 2 show ?lhs
   274     unfolding openin_open open_dist by fast
   275 qed
   276 
   277 text {* These "transitivity" results are handy too *}
   278 
   279 lemma openin_trans[trans]: "openin (subtopology euclidean T) S \<Longrightarrow> openin (subtopology euclidean U) T
   280   \<Longrightarrow> openin (subtopology euclidean U) S"
   281   unfolding open_openin openin_open by blast
   282 
   283 lemma openin_open_trans: "openin (subtopology euclidean T) S \<Longrightarrow> open T \<Longrightarrow> open S"
   284   by (auto simp add: openin_open intro: openin_trans)
   285 
   286 lemma closedin_trans[trans]:
   287  "closedin (subtopology euclidean T) S \<Longrightarrow>
   288            closedin (subtopology euclidean U) T
   289            ==> closedin (subtopology euclidean U) S"
   290   by (auto simp add: closedin_closed closed_closedin closed_Inter Int_assoc)
   291 
   292 lemma closedin_closed_trans: "closedin (subtopology euclidean T) S \<Longrightarrow> closed T \<Longrightarrow> closed S"
   293   by (auto simp add: closedin_closed intro: closedin_trans)
   294 
   295 
   296 subsection {* Open and closed balls *}
   297 
   298 definition
   299   ball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set" where
   300   "ball x e = {y. dist x y < e}"
   301 
   302 definition
   303   cball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set" where
   304   "cball x e = {y. dist x y \<le> e}"
   305 
   306 lemma mem_ball[simp]: "y \<in> ball x e \<longleftrightarrow> dist x y < e" by (simp add: ball_def)
   307 lemma mem_cball[simp]: "y \<in> cball x e \<longleftrightarrow> dist x y \<le> e" by (simp add: cball_def)
   308 
   309 lemma mem_ball_0 [simp]:
   310   fixes x :: "'a::real_normed_vector"
   311   shows "x \<in> ball 0 e \<longleftrightarrow> norm x < e"
   312   by (simp add: dist_norm)
   313 
   314 lemma mem_cball_0 [simp]:
   315   fixes x :: "'a::real_normed_vector"
   316   shows "x \<in> cball 0 e \<longleftrightarrow> norm x \<le> e"
   317   by (simp add: dist_norm)
   318 
   319 lemma centre_in_cball[simp]: "x \<in> cball x e \<longleftrightarrow> 0\<le> e"  by simp
   320 lemma ball_subset_cball[simp,intro]: "ball x e \<subseteq> cball x e" by (simp add: subset_eq)
   321 lemma subset_ball[intro]: "d <= e ==> ball x d \<subseteq> ball x e" by (simp add: subset_eq)
   322 lemma subset_cball[intro]: "d <= e ==> cball x d \<subseteq> cball x e" by (simp add: subset_eq)
   323 lemma ball_max_Un: "ball a (max r s) = ball a r \<union> ball a s"
   324   by (simp add: set_eq_iff) arith
   325 
   326 lemma ball_min_Int: "ball a (min r s) = ball a r \<inter> ball a s"
   327   by (simp add: set_eq_iff)
   328 
   329 lemma diff_less_iff: "(a::real) - b > 0 \<longleftrightarrow> a > b"
   330   "(a::real) - b < 0 \<longleftrightarrow> a < b"
   331   "a - b < c \<longleftrightarrow> a < c +b" "a - b > c \<longleftrightarrow> a > c +b" by arith+
   332 lemma diff_le_iff: "(a::real) - b \<ge> 0 \<longleftrightarrow> a \<ge> b" "(a::real) - b \<le> 0 \<longleftrightarrow> a \<le> b"
   333   "a - b \<le> c \<longleftrightarrow> a \<le> c +b" "a - b \<ge> c \<longleftrightarrow> a \<ge> c +b"  by arith+
   334 
   335 lemma open_ball[intro, simp]: "open (ball x e)"
   336   unfolding open_dist ball_def mem_Collect_eq Ball_def
   337   unfolding dist_commute
   338   apply clarify
   339   apply (rule_tac x="e - dist xa x" in exI)
   340   using dist_triangle_alt[where z=x]
   341   apply (clarsimp simp add: diff_less_iff)
   342   apply atomize
   343   apply (erule_tac x="y" in allE)
   344   apply (erule_tac x="xa" in allE)
   345   by arith
   346 
   347 lemma centre_in_ball[simp]: "x \<in> ball x e \<longleftrightarrow> e > 0" by (metis mem_ball dist_self)
   348 lemma open_contains_ball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. ball x e \<subseteq> S)"
   349   unfolding open_dist subset_eq mem_ball Ball_def dist_commute ..
   350 
   351 lemma openE[elim?]:
   352   assumes "open S" "x\<in>S" 
   353   obtains e where "e>0" "ball x e \<subseteq> S"
   354   using assms unfolding open_contains_ball by auto
   355 
   356 lemma open_contains_ball_eq: "open S \<Longrightarrow> \<forall>x. x\<in>S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
   357   by (metis open_contains_ball subset_eq centre_in_ball)
   358 
   359 lemma ball_eq_empty[simp]: "ball x e = {} \<longleftrightarrow> e \<le> 0"
   360   unfolding mem_ball set_eq_iff
   361   apply (simp add: not_less)
   362   by (metis zero_le_dist order_trans dist_self)
   363 
   364 lemma ball_empty[intro]: "e \<le> 0 ==> ball x e = {}" by simp
   365 
   366 
   367 subsection{* Connectedness *}
   368 
   369 definition "connected S \<longleftrightarrow>
   370   ~(\<exists>e1 e2. open e1 \<and> open e2 \<and> S \<subseteq> (e1 \<union> e2) \<and> (e1 \<inter> e2 \<inter> S = {})
   371   \<and> ~(e1 \<inter> S = {}) \<and> ~(e2 \<inter> S = {}))"
   372 
   373 lemma connected_local:
   374  "connected S \<longleftrightarrow> ~(\<exists>e1 e2.
   375                  openin (subtopology euclidean S) e1 \<and>
   376                  openin (subtopology euclidean S) e2 \<and>
   377                  S \<subseteq> e1 \<union> e2 \<and>
   378                  e1 \<inter> e2 = {} \<and>
   379                  ~(e1 = {}) \<and>
   380                  ~(e2 = {}))"
   381 unfolding connected_def openin_open by (safe, blast+)
   382 
   383 lemma exists_diff:
   384   fixes P :: "'a set \<Rightarrow> bool"
   385   shows "(\<exists>S. P(- S)) \<longleftrightarrow> (\<exists>S. P S)" (is "?lhs \<longleftrightarrow> ?rhs")
   386 proof-
   387   {assume "?lhs" hence ?rhs by blast }
   388   moreover
   389   {fix S assume H: "P S"
   390     have "S = - (- S)" by auto
   391     with H have "P (- (- S))" by metis }
   392   ultimately show ?thesis by metis
   393 qed
   394 
   395 lemma connected_clopen: "connected S \<longleftrightarrow>
   396         (\<forall>T. openin (subtopology euclidean S) T \<and>
   397             closedin (subtopology euclidean S) T \<longrightarrow> T = {} \<or> T = S)" (is "?lhs \<longleftrightarrow> ?rhs")
   398 proof-
   399   have " \<not> connected S \<longleftrightarrow> (\<exists>e1 e2. open e1 \<and> open (- e2) \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   400     unfolding connected_def openin_open closedin_closed
   401     apply (subst exists_diff) by blast
   402   hence th0: "connected S \<longleftrightarrow> \<not> (\<exists>e2 e1. closed e2 \<and> open e1 \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   403     (is " _ \<longleftrightarrow> \<not> (\<exists>e2 e1. ?P e2 e1)") apply (simp add: closed_def) by metis
   404 
   405   have th1: "?rhs \<longleftrightarrow> \<not> (\<exists>t' t. closed t'\<and>t = S\<inter>t' \<and> t\<noteq>{} \<and> t\<noteq>S \<and> (\<exists>t'. open t' \<and> t = S \<inter> t'))"
   406     (is "_ \<longleftrightarrow> \<not> (\<exists>t' t. ?Q t' t)")
   407     unfolding connected_def openin_open closedin_closed by auto
   408   {fix e2
   409     {fix e1 have "?P e2 e1 \<longleftrightarrow> (\<exists>t.  closed e2 \<and> t = S\<inter>e2 \<and> open e1 \<and> t = S\<inter>e1 \<and> t\<noteq>{} \<and> t\<noteq>S)"
   410         by auto}
   411     then have "(\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)" by metis}
   412   then have "\<forall>e2. (\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)" by blast
   413   then show ?thesis unfolding th0 th1 by simp
   414 qed
   415 
   416 lemma connected_empty[simp, intro]: "connected {}"
   417   by (simp add: connected_def)
   418 
   419 
   420 subsection{* Limit points *}
   421 
   422 definition (in topological_space)
   423   islimpt:: "'a \<Rightarrow> 'a set \<Rightarrow> bool" (infixr "islimpt" 60) where
   424   "x islimpt S \<longleftrightarrow> (\<forall>T. x\<in>T \<longrightarrow> open T \<longrightarrow> (\<exists>y\<in>S. y\<in>T \<and> y\<noteq>x))"
   425 
   426 lemma islimptI:
   427   assumes "\<And>T. x \<in> T \<Longrightarrow> open T \<Longrightarrow> \<exists>y\<in>S. y \<in> T \<and> y \<noteq> x"
   428   shows "x islimpt S"
   429   using assms unfolding islimpt_def by auto
   430 
   431 lemma islimptE:
   432   assumes "x islimpt S" and "x \<in> T" and "open T"
   433   obtains y where "y \<in> S" and "y \<in> T" and "y \<noteq> x"
   434   using assms unfolding islimpt_def by auto
   435 
   436 lemma islimpt_iff_eventually: "x islimpt S \<longleftrightarrow> \<not> eventually (\<lambda>y. y \<notin> S) (at x)"
   437   unfolding islimpt_def eventually_at_topological by auto
   438 
   439 lemma islimpt_subset: "\<lbrakk>x islimpt S; S \<subseteq> T\<rbrakk> \<Longrightarrow> x islimpt T"
   440   unfolding islimpt_def by fast
   441 
   442 lemma islimpt_approachable:
   443   fixes x :: "'a::metric_space"
   444   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e)"
   445   unfolding islimpt_iff_eventually eventually_at by fast
   446 
   447 lemma islimpt_approachable_le:
   448   fixes x :: "'a::metric_space"
   449   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in> S. x' \<noteq> x \<and> dist x' x <= e)"
   450   unfolding islimpt_approachable
   451   using approachable_lt_le [where f="\<lambda>y. dist y x" and P="\<lambda>y. y \<notin> S \<or> y = x",
   452     THEN arg_cong [where f=Not]]
   453   by (simp add: Bex_def conj_commute conj_left_commute)
   454 
   455 lemma islimpt_UNIV_iff: "x islimpt UNIV \<longleftrightarrow> \<not> open {x}"
   456   unfolding islimpt_def by (safe, fast, case_tac "T = {x}", fast, fast)
   457 
   458 text {* A perfect space has no isolated points. *}
   459 
   460 lemma islimpt_UNIV [simp, intro]: "(x::'a::perfect_space) islimpt UNIV"
   461   unfolding islimpt_UNIV_iff by (rule not_open_singleton)
   462 
   463 lemma perfect_choose_dist:
   464   fixes x :: "'a::{perfect_space, metric_space}"
   465   shows "0 < r \<Longrightarrow> \<exists>a. a \<noteq> x \<and> dist a x < r"
   466 using islimpt_UNIV [of x]
   467 by (simp add: islimpt_approachable)
   468 
   469 lemma closed_limpt: "closed S \<longleftrightarrow> (\<forall>x. x islimpt S \<longrightarrow> x \<in> S)"
   470   unfolding closed_def
   471   apply (subst open_subopen)
   472   apply (simp add: islimpt_def subset_eq)
   473   by (metis ComplE ComplI)
   474 
   475 lemma islimpt_EMPTY[simp]: "\<not> x islimpt {}"
   476   unfolding islimpt_def by auto
   477 
   478 lemma finite_set_avoid:
   479   fixes a :: "'a::metric_space"
   480   assumes fS: "finite S" shows  "\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<longrightarrow> d <= dist a x"
   481 proof(induct rule: finite_induct[OF fS])
   482   case 1 thus ?case by (auto intro: zero_less_one)
   483 next
   484   case (2 x F)
   485   from 2 obtain d where d: "d >0" "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> d \<le> dist a x" by blast
   486   {assume "x = a" hence ?case using d by auto  }
   487   moreover
   488   {assume xa: "x\<noteq>a"
   489     let ?d = "min d (dist a x)"
   490     have dp: "?d > 0" using xa d(1) using dist_nz by auto
   491     from d have d': "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> ?d \<le> dist a x" by auto
   492     with dp xa have ?case by(auto intro!: exI[where x="?d"]) }
   493   ultimately show ?case by blast
   494 qed
   495 
   496 lemma islimpt_finite:
   497   fixes S :: "'a::metric_space set"
   498   assumes fS: "finite S" shows "\<not> a islimpt S"
   499   unfolding islimpt_approachable
   500   using finite_set_avoid[OF fS, of a] by (metis dist_commute  not_le)
   501 
   502 lemma islimpt_Un: "x islimpt (S \<union> T) \<longleftrightarrow> x islimpt S \<or> x islimpt T"
   503   apply (rule iffI)
   504   defer
   505   apply (metis Un_upper1 Un_upper2 islimpt_subset)
   506   unfolding islimpt_def
   507   apply (rule ccontr, clarsimp, rename_tac A B)
   508   apply (drule_tac x="A \<inter> B" in spec)
   509   apply (auto simp add: open_Int)
   510   done
   511 
   512 lemma discrete_imp_closed:
   513   fixes S :: "'a::metric_space set"
   514   assumes e: "0 < e" and d: "\<forall>x \<in> S. \<forall>y \<in> S. dist y x < e \<longrightarrow> y = x"
   515   shows "closed S"
   516 proof-
   517   {fix x assume C: "\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e"
   518     from e have e2: "e/2 > 0" by arith
   519     from C[rule_format, OF e2] obtain y where y: "y \<in> S" "y\<noteq>x" "dist y x < e/2" by blast
   520     let ?m = "min (e/2) (dist x y) "
   521     from e2 y(2) have mp: "?m > 0" by (simp add: dist_nz[THEN sym])
   522     from C[rule_format, OF mp] obtain z where z: "z \<in> S" "z\<noteq>x" "dist z x < ?m" by blast
   523     have th: "dist z y < e" using z y
   524       by (intro dist_triangle_lt [where z=x], simp)
   525     from d[rule_format, OF y(1) z(1) th] y z
   526     have False by (auto simp add: dist_commute)}
   527   then show ?thesis by (metis islimpt_approachable closed_limpt [where 'a='a])
   528 qed
   529 
   530 
   531 subsection {* Interior of a Set *}
   532 
   533 definition "interior S = \<Union>{T. open T \<and> T \<subseteq> S}"
   534 
   535 lemma interiorI [intro?]:
   536   assumes "open T" and "x \<in> T" and "T \<subseteq> S"
   537   shows "x \<in> interior S"
   538   using assms unfolding interior_def by fast
   539 
   540 lemma interiorE [elim?]:
   541   assumes "x \<in> interior S"
   542   obtains T where "open T" and "x \<in> T" and "T \<subseteq> S"
   543   using assms unfolding interior_def by fast
   544 
   545 lemma open_interior [simp, intro]: "open (interior S)"
   546   by (simp add: interior_def open_Union)
   547 
   548 lemma interior_subset: "interior S \<subseteq> S"
   549   by (auto simp add: interior_def)
   550 
   551 lemma interior_maximal: "T \<subseteq> S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> interior S"
   552   by (auto simp add: interior_def)
   553 
   554 lemma interior_open: "open S \<Longrightarrow> interior S = S"
   555   by (intro equalityI interior_subset interior_maximal subset_refl)
   556 
   557 lemma interior_eq: "interior S = S \<longleftrightarrow> open S"
   558   by (metis open_interior interior_open)
   559 
   560 lemma open_subset_interior: "open S \<Longrightarrow> S \<subseteq> interior T \<longleftrightarrow> S \<subseteq> T"
   561   by (metis interior_maximal interior_subset subset_trans)
   562 
   563 lemma interior_empty [simp]: "interior {} = {}"
   564   using open_empty by (rule interior_open)
   565 
   566 lemma interior_UNIV [simp]: "interior UNIV = UNIV"
   567   using open_UNIV by (rule interior_open)
   568 
   569 lemma interior_interior [simp]: "interior (interior S) = interior S"
   570   using open_interior by (rule interior_open)
   571 
   572 lemma interior_mono: "S \<subseteq> T \<Longrightarrow> interior S \<subseteq> interior T"
   573   by (auto simp add: interior_def)
   574 
   575 lemma interior_unique:
   576   assumes "T \<subseteq> S" and "open T"
   577   assumes "\<And>T'. T' \<subseteq> S \<Longrightarrow> open T' \<Longrightarrow> T' \<subseteq> T"
   578   shows "interior S = T"
   579   by (intro equalityI assms interior_subset open_interior interior_maximal)
   580 
   581 lemma interior_inter [simp]: "interior (S \<inter> T) = interior S \<inter> interior T"
   582   by (intro equalityI Int_mono Int_greatest interior_mono Int_lower1
   583     Int_lower2 interior_maximal interior_subset open_Int open_interior)
   584 
   585 lemma mem_interior: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
   586   using open_contains_ball_eq [where S="interior S"]
   587   by (simp add: open_subset_interior)
   588 
   589 lemma interior_limit_point [intro]:
   590   fixes x :: "'a::perfect_space"
   591   assumes x: "x \<in> interior S" shows "x islimpt S"
   592   using x islimpt_UNIV [of x]
   593   unfolding interior_def islimpt_def
   594   apply (clarsimp, rename_tac T T')
   595   apply (drule_tac x="T \<inter> T'" in spec)
   596   apply (auto simp add: open_Int)
   597   done
   598 
   599 lemma interior_closed_Un_empty_interior:
   600   assumes cS: "closed S" and iT: "interior T = {}"
   601   shows "interior (S \<union> T) = interior S"
   602 proof
   603   show "interior S \<subseteq> interior (S \<union> T)"
   604     by (rule interior_mono, rule Un_upper1)
   605 next
   606   show "interior (S \<union> T) \<subseteq> interior S"
   607   proof
   608     fix x assume "x \<in> interior (S \<union> T)"
   609     then obtain R where "open R" "x \<in> R" "R \<subseteq> S \<union> T" ..
   610     show "x \<in> interior S"
   611     proof (rule ccontr)
   612       assume "x \<notin> interior S"
   613       with `x \<in> R` `open R` obtain y where "y \<in> R - S"
   614         unfolding interior_def by fast
   615       from `open R` `closed S` have "open (R - S)" by (rule open_Diff)
   616       from `R \<subseteq> S \<union> T` have "R - S \<subseteq> T" by fast
   617       from `y \<in> R - S` `open (R - S)` `R - S \<subseteq> T` `interior T = {}`
   618       show "False" unfolding interior_def by fast
   619     qed
   620   qed
   621 qed
   622 
   623 lemma interior_Times: "interior (A \<times> B) = interior A \<times> interior B"
   624 proof (rule interior_unique)
   625   show "interior A \<times> interior B \<subseteq> A \<times> B"
   626     by (intro Sigma_mono interior_subset)
   627   show "open (interior A \<times> interior B)"
   628     by (intro open_Times open_interior)
   629   fix T assume "T \<subseteq> A \<times> B" and "open T" thus "T \<subseteq> interior A \<times> interior B"
   630   proof (safe)
   631     fix x y assume "(x, y) \<in> T"
   632     then obtain C D where "open C" "open D" "C \<times> D \<subseteq> T" "x \<in> C" "y \<in> D"
   633       using `open T` unfolding open_prod_def by fast
   634     hence "open C" "open D" "C \<subseteq> A" "D \<subseteq> B" "x \<in> C" "y \<in> D"
   635       using `T \<subseteq> A \<times> B` by auto
   636     thus "x \<in> interior A" and "y \<in> interior B"
   637       by (auto intro: interiorI)
   638   qed
   639 qed
   640 
   641 
   642 subsection {* Closure of a Set *}
   643 
   644 definition "closure S = S \<union> {x | x. x islimpt S}"
   645 
   646 lemma interior_closure: "interior S = - (closure (- S))"
   647   unfolding interior_def closure_def islimpt_def by auto
   648 
   649 lemma closure_interior: "closure S = - interior (- S)"
   650   unfolding interior_closure by simp
   651 
   652 lemma closed_closure[simp, intro]: "closed (closure S)"
   653   unfolding closure_interior by (simp add: closed_Compl)
   654 
   655 lemma closure_subset: "S \<subseteq> closure S"
   656   unfolding closure_def by simp
   657 
   658 lemma closure_hull: "closure S = closed hull S"
   659   unfolding hull_def closure_interior interior_def by auto
   660 
   661 lemma closure_eq: "closure S = S \<longleftrightarrow> closed S"
   662   unfolding closure_hull using closed_Inter by (rule hull_eq)
   663 
   664 lemma closure_closed [simp]: "closed S \<Longrightarrow> closure S = S"
   665   unfolding closure_eq .
   666 
   667 lemma closure_closure [simp]: "closure (closure S) = closure S"
   668   unfolding closure_hull by (rule hull_hull)
   669 
   670 lemma closure_mono: "S \<subseteq> T \<Longrightarrow> closure S \<subseteq> closure T"
   671   unfolding closure_hull by (rule hull_mono)
   672 
   673 lemma closure_minimal: "S \<subseteq> T \<Longrightarrow> closed T \<Longrightarrow> closure S \<subseteq> T"
   674   unfolding closure_hull by (rule hull_minimal)
   675 
   676 lemma closure_unique:
   677   assumes "S \<subseteq> T" and "closed T"
   678   assumes "\<And>T'. S \<subseteq> T' \<Longrightarrow> closed T' \<Longrightarrow> T \<subseteq> T'"
   679   shows "closure S = T"
   680   using assms unfolding closure_hull by (rule hull_unique)
   681 
   682 lemma closure_empty [simp]: "closure {} = {}"
   683   using closed_empty by (rule closure_closed)
   684 
   685 lemma closure_UNIV [simp]: "closure UNIV = UNIV"
   686   using closed_UNIV by (rule closure_closed)
   687 
   688 lemma closure_union [simp]: "closure (S \<union> T) = closure S \<union> closure T"
   689   unfolding closure_interior by simp
   690 
   691 lemma closure_eq_empty: "closure S = {} \<longleftrightarrow> S = {}"
   692   using closure_empty closure_subset[of S]
   693   by blast
   694 
   695 lemma closure_subset_eq: "closure S \<subseteq> S \<longleftrightarrow> closed S"
   696   using closure_eq[of S] closure_subset[of S]
   697   by simp
   698 
   699 lemma open_inter_closure_eq_empty:
   700   "open S \<Longrightarrow> (S \<inter> closure T) = {} \<longleftrightarrow> S \<inter> T = {}"
   701   using open_subset_interior[of S "- T"]
   702   using interior_subset[of "- T"]
   703   unfolding closure_interior
   704   by auto
   705 
   706 lemma open_inter_closure_subset:
   707   "open S \<Longrightarrow> (S \<inter> (closure T)) \<subseteq> closure(S \<inter> T)"
   708 proof
   709   fix x
   710   assume as: "open S" "x \<in> S \<inter> closure T"
   711   { assume *:"x islimpt T"
   712     have "x islimpt (S \<inter> T)"
   713     proof (rule islimptI)
   714       fix A
   715       assume "x \<in> A" "open A"
   716       with as have "x \<in> A \<inter> S" "open (A \<inter> S)"
   717         by (simp_all add: open_Int)
   718       with * obtain y where "y \<in> T" "y \<in> A \<inter> S" "y \<noteq> x"
   719         by (rule islimptE)
   720       hence "y \<in> S \<inter> T" "y \<in> A \<and> y \<noteq> x"
   721         by simp_all
   722       thus "\<exists>y\<in>(S \<inter> T). y \<in> A \<and> y \<noteq> x" ..
   723     qed
   724   }
   725   then show "x \<in> closure (S \<inter> T)" using as
   726     unfolding closure_def
   727     by blast
   728 qed
   729 
   730 lemma closure_complement: "closure (- S) = - interior S"
   731   unfolding closure_interior by simp
   732 
   733 lemma interior_complement: "interior (- S) = - closure S"
   734   unfolding closure_interior by simp
   735 
   736 lemma closure_Times: "closure (A \<times> B) = closure A \<times> closure B"
   737 proof (rule closure_unique)
   738   show "A \<times> B \<subseteq> closure A \<times> closure B"
   739     by (intro Sigma_mono closure_subset)
   740   show "closed (closure A \<times> closure B)"
   741     by (intro closed_Times closed_closure)
   742   fix T assume "A \<times> B \<subseteq> T" and "closed T" thus "closure A \<times> closure B \<subseteq> T"
   743     apply (simp add: closed_def open_prod_def, clarify)
   744     apply (rule ccontr)
   745     apply (drule_tac x="(a, b)" in bspec, simp, clarify, rename_tac C D)
   746     apply (simp add: closure_interior interior_def)
   747     apply (drule_tac x=C in spec)
   748     apply (drule_tac x=D in spec)
   749     apply auto
   750     done
   751 qed
   752 
   753 
   754 subsection {* Frontier (aka boundary) *}
   755 
   756 definition "frontier S = closure S - interior S"
   757 
   758 lemma frontier_closed: "closed(frontier S)"
   759   by (simp add: frontier_def closed_Diff)
   760 
   761 lemma frontier_closures: "frontier S = (closure S) \<inter> (closure(- S))"
   762   by (auto simp add: frontier_def interior_closure)
   763 
   764 lemma frontier_straddle:
   765   fixes a :: "'a::metric_space"
   766   shows "a \<in> frontier S \<longleftrightarrow> (\<forall>e>0. (\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e))" (is "?lhs \<longleftrightarrow> ?rhs")
   767 proof
   768   assume "?lhs"
   769   { fix e::real
   770     assume "e > 0"
   771     let ?rhse = "(\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e)"
   772     { assume "a\<in>S"
   773       have "\<exists>x\<in>S. dist a x < e" using `e>0` `a\<in>S` by(rule_tac x=a in bexI) auto
   774       moreover have "\<exists>x. x \<notin> S \<and> dist a x < e" using `?lhs` `a\<in>S`
   775         unfolding frontier_closures closure_def islimpt_def using `e>0`
   776         by (auto, erule_tac x="ball a e" in allE, auto)
   777       ultimately have ?rhse by auto
   778     }
   779     moreover
   780     { assume "a\<notin>S"
   781       hence ?rhse using `?lhs`
   782         unfolding frontier_closures closure_def islimpt_def
   783         using open_ball[of a e] `e > 0`
   784           by simp (metis centre_in_ball mem_ball open_ball) 
   785     }
   786     ultimately have ?rhse by auto
   787   }
   788   thus ?rhs by auto
   789 next
   790   assume ?rhs
   791   moreover
   792   { fix T assume "a\<notin>S" and
   793     as:"\<forall>e>0. (\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e)" "a \<notin> S" "a \<in> T" "open T"
   794     from `open T` `a \<in> T` have "\<exists>e>0. ball a e \<subseteq> T" unfolding open_contains_ball[of T] by auto
   795     then obtain e where "e>0" "ball a e \<subseteq> T" by auto
   796     then obtain y where y:"y\<in>S" "dist a y < e"  using as(1) by auto
   797     have "\<exists>y\<in>S. y \<in> T \<and> y \<noteq> a"
   798       using `dist a y < e` `ball a e \<subseteq> T` unfolding ball_def using `y\<in>S` `a\<notin>S` by auto
   799   }
   800   hence "a \<in> closure S" unfolding closure_def islimpt_def using `?rhs` by auto
   801   moreover
   802   { fix T assume "a \<in> T"  "open T" "a\<in>S"
   803     then obtain e where "e>0" and balle: "ball a e \<subseteq> T" unfolding open_contains_ball using `?rhs` by auto
   804     obtain x where "x \<notin> S" "dist a x < e" using `?rhs` using `e>0` by auto
   805     hence "\<exists>y\<in>- S. y \<in> T \<and> y \<noteq> a" using balle `a\<in>S` unfolding ball_def by (rule_tac x=x in bexI)auto
   806   }
   807   hence "a islimpt (- S) \<or> a\<notin>S" unfolding islimpt_def by auto
   808   ultimately show ?lhs unfolding frontier_closures using closure_def[of "- S"] by auto
   809 qed
   810 
   811 lemma frontier_subset_closed: "closed S \<Longrightarrow> frontier S \<subseteq> S"
   812   by (metis frontier_def closure_closed Diff_subset)
   813 
   814 lemma frontier_empty[simp]: "frontier {} = {}"
   815   by (simp add: frontier_def)
   816 
   817 lemma frontier_subset_eq: "frontier S \<subseteq> S \<longleftrightarrow> closed S"
   818 proof-
   819   { assume "frontier S \<subseteq> S"
   820     hence "closure S \<subseteq> S" using interior_subset unfolding frontier_def by auto
   821     hence "closed S" using closure_subset_eq by auto
   822   }
   823   thus ?thesis using frontier_subset_closed[of S] ..
   824 qed
   825 
   826 lemma frontier_complement: "frontier(- S) = frontier S"
   827   by (auto simp add: frontier_def closure_complement interior_complement)
   828 
   829 lemma frontier_disjoint_eq: "frontier S \<inter> S = {} \<longleftrightarrow> open S"
   830   using frontier_complement frontier_subset_eq[of "- S"]
   831   unfolding open_closed by auto
   832 
   833 
   834 subsection {* Filters and the ``eventually true'' quantifier *}
   835 
   836 definition
   837   at_infinity :: "'a::real_normed_vector filter" where
   838   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
   839 
   840 definition
   841   indirection :: "'a::real_normed_vector \<Rightarrow> 'a \<Rightarrow> 'a filter"
   842     (infixr "indirection" 70) where
   843   "a indirection v = (at a) within {b. \<exists>c\<ge>0. b - a = scaleR c v}"
   844 
   845 text{* Prove That They are all filters. *}
   846 
   847 lemma eventually_at_infinity:
   848   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. norm x >= b \<longrightarrow> P x)"
   849 unfolding at_infinity_def
   850 proof (rule eventually_Abs_filter, rule is_filter.intro)
   851   fix P Q :: "'a \<Rightarrow> bool"
   852   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
   853   then obtain r s where
   854     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
   855   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
   856   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
   857 qed auto
   858 
   859 text {* Identify Trivial limits, where we can't approach arbitrarily closely. *}
   860 
   861 lemma trivial_limit_within:
   862   shows "trivial_limit (at a within S) \<longleftrightarrow> \<not> a islimpt S"
   863 proof
   864   assume "trivial_limit (at a within S)"
   865   thus "\<not> a islimpt S"
   866     unfolding trivial_limit_def
   867     unfolding eventually_within eventually_at_topological
   868     unfolding islimpt_def
   869     apply (clarsimp simp add: set_eq_iff)
   870     apply (rename_tac T, rule_tac x=T in exI)
   871     apply (clarsimp, drule_tac x=y in bspec, simp_all)
   872     done
   873 next
   874   assume "\<not> a islimpt S"
   875   thus "trivial_limit (at a within S)"
   876     unfolding trivial_limit_def
   877     unfolding eventually_within eventually_at_topological
   878     unfolding islimpt_def
   879     apply clarsimp
   880     apply (rule_tac x=T in exI)
   881     apply auto
   882     done
   883 qed
   884 
   885 lemma trivial_limit_at_iff: "trivial_limit (at a) \<longleftrightarrow> \<not> a islimpt UNIV"
   886   using trivial_limit_within [of a UNIV]
   887   by (simp add: within_UNIV)
   888 
   889 lemma trivial_limit_at:
   890   fixes a :: "'a::perfect_space"
   891   shows "\<not> trivial_limit (at a)"
   892   by (rule at_neq_bot)
   893 
   894 lemma trivial_limit_at_infinity:
   895   "\<not> trivial_limit (at_infinity :: ('a::{real_normed_vector,perfect_space}) filter)"
   896   unfolding trivial_limit_def eventually_at_infinity
   897   apply clarsimp
   898   apply (subgoal_tac "\<exists>x::'a. x \<noteq> 0", clarify)
   899    apply (rule_tac x="scaleR (b / norm x) x" in exI, simp)
   900   apply (cut_tac islimpt_UNIV [of "0::'a", unfolded islimpt_def])
   901   apply (drule_tac x=UNIV in spec, simp)
   902   done
   903 
   904 text {* Some property holds "sufficiently close" to the limit point. *}
   905 
   906 lemma eventually_at: (* FIXME: this replaces Limits.eventually_at *)
   907   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
   908 unfolding eventually_at dist_nz by auto
   909 
   910 lemma eventually_within: "eventually P (at a within S) \<longleftrightarrow>
   911         (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
   912 unfolding eventually_within eventually_at dist_nz by auto
   913 
   914 lemma eventually_within_le: "eventually P (at a within S) \<longleftrightarrow>
   915         (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a <= d \<longrightarrow> P x)" (is "?lhs = ?rhs")
   916 unfolding eventually_within
   917 by auto (metis Rats_dense_in_nn_real order_le_less_trans order_refl) 
   918 
   919 lemma eventually_happens: "eventually P net ==> trivial_limit net \<or> (\<exists>x. P x)"
   920   unfolding trivial_limit_def
   921   by (auto elim: eventually_rev_mp)
   922 
   923 lemma trivial_limit_eventually: "trivial_limit net \<Longrightarrow> eventually P net"
   924   unfolding trivial_limit_def by (auto elim: eventually_rev_mp)
   925 
   926 lemma trivial_limit_eq: "trivial_limit net \<longleftrightarrow> (\<forall>P. eventually P net)"
   927   by (simp add: filter_eq_iff)
   928 
   929 text{* Combining theorems for "eventually" *}
   930 
   931 lemma eventually_rev_mono:
   932   "eventually P net \<Longrightarrow> (\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually Q net"
   933 using eventually_mono [of P Q] by fast
   934 
   935 lemma not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> ~(trivial_limit net) ==> ~(eventually (\<lambda>x. P x) net)"
   936   by (simp add: eventually_False)
   937 
   938 
   939 subsection {* Limits *}
   940 
   941 text{* Notation Lim to avoid collition with lim defined in analysis *}
   942 
   943 definition Lim :: "'a filter \<Rightarrow> ('a \<Rightarrow> 'b::t2_space) \<Rightarrow> 'b"
   944   where "Lim A f = (THE l. (f ---> l) A)"
   945 
   946 lemma Lim:
   947  "(f ---> l) net \<longleftrightarrow>
   948         trivial_limit net \<or>
   949         (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
   950   unfolding tendsto_iff trivial_limit_eq by auto
   951 
   952 text{* Show that they yield usual definitions in the various cases. *}
   953 
   954 lemma Lim_within_le: "(f ---> l)(at a within S) \<longleftrightarrow>
   955            (\<forall>e>0. \<exists>d>0. \<forall>x\<in>S. 0 < dist x a  \<and> dist x a  <= d \<longrightarrow> dist (f x) l < e)"
   956   by (auto simp add: tendsto_iff eventually_within_le)
   957 
   958 lemma Lim_within: "(f ---> l) (at a within S) \<longleftrightarrow>
   959         (\<forall>e >0. \<exists>d>0. \<forall>x \<in> S. 0 < dist x a  \<and> dist x a  < d  \<longrightarrow> dist (f x) l < e)"
   960   by (auto simp add: tendsto_iff eventually_within)
   961 
   962 lemma Lim_at: "(f ---> l) (at a) \<longleftrightarrow>
   963         (\<forall>e >0. \<exists>d>0. \<forall>x. 0 < dist x a  \<and> dist x a  < d  \<longrightarrow> dist (f x) l < e)"
   964   by (auto simp add: tendsto_iff eventually_at)
   965 
   966 lemma Lim_at_iff_LIM: "(f ---> l) (at a) \<longleftrightarrow> f -- a --> l"
   967   unfolding Lim_at LIM_def by (simp only: zero_less_dist_iff)
   968 
   969 lemma Lim_at_infinity:
   970   "(f ---> l) at_infinity \<longleftrightarrow> (\<forall>e>0. \<exists>b. \<forall>x. norm x >= b \<longrightarrow> dist (f x) l < e)"
   971   by (auto simp add: tendsto_iff eventually_at_infinity)
   972 
   973 lemma Lim_sequentially:
   974  "(S ---> l) sequentially \<longleftrightarrow>
   975           (\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (S n) l < e)"
   976   by (rule LIMSEQ_def) (* FIXME: redundant *)
   977 
   978 lemma Lim_eventually: "eventually (\<lambda>x. f x = l) net \<Longrightarrow> (f ---> l) net"
   979   by (rule topological_tendstoI, auto elim: eventually_rev_mono)
   980 
   981 text{* The expected monotonicity property. *}
   982 
   983 lemma Lim_within_empty: "(f ---> l) (net within {})"
   984   unfolding tendsto_def Limits.eventually_within by simp
   985 
   986 lemma Lim_within_subset: "(f ---> l) (net within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (net within T)"
   987   unfolding tendsto_def Limits.eventually_within
   988   by (auto elim!: eventually_elim1)
   989 
   990 lemma Lim_Un: assumes "(f ---> l) (net within S)" "(f ---> l) (net within T)"
   991   shows "(f ---> l) (net within (S \<union> T))"
   992   using assms unfolding tendsto_def Limits.eventually_within
   993   apply clarify
   994   apply (drule spec, drule (1) mp, drule (1) mp)
   995   apply (drule spec, drule (1) mp, drule (1) mp)
   996   apply (auto elim: eventually_elim2)
   997   done
   998 
   999 lemma Lim_Un_univ:
  1000  "(f ---> l) (net within S) \<Longrightarrow> (f ---> l) (net within T) \<Longrightarrow>  S \<union> T = UNIV
  1001         ==> (f ---> l) net"
  1002   by (metis Lim_Un within_UNIV)
  1003 
  1004 text{* Interrelations between restricted and unrestricted limits. *}
  1005 
  1006 lemma Lim_at_within: "(f ---> l) net ==> (f ---> l)(net within S)"
  1007   (* FIXME: rename *)
  1008   unfolding tendsto_def Limits.eventually_within
  1009   apply (clarify, drule spec, drule (1) mp, drule (1) mp)
  1010   by (auto elim!: eventually_elim1)
  1011 
  1012 lemma eventually_within_interior:
  1013   assumes "x \<in> interior S"
  1014   shows "eventually P (at x within S) \<longleftrightarrow> eventually P (at x)" (is "?lhs = ?rhs")
  1015 proof-
  1016   from assms obtain T where T: "open T" "x \<in> T" "T \<subseteq> S" ..
  1017   { assume "?lhs"
  1018     then obtain A where "open A" "x \<in> A" "\<forall>y\<in>A. y \<noteq> x \<longrightarrow> y \<in> S \<longrightarrow> P y"
  1019       unfolding Limits.eventually_within Limits.eventually_at_topological
  1020       by auto
  1021     with T have "open (A \<inter> T)" "x \<in> A \<inter> T" "\<forall>y\<in>(A \<inter> T). y \<noteq> x \<longrightarrow> P y"
  1022       by auto
  1023     then have "?rhs"
  1024       unfolding Limits.eventually_at_topological by auto
  1025   } moreover
  1026   { assume "?rhs" hence "?lhs"
  1027       unfolding Limits.eventually_within
  1028       by (auto elim: eventually_elim1)
  1029   } ultimately
  1030   show "?thesis" ..
  1031 qed
  1032 
  1033 lemma at_within_interior:
  1034   "x \<in> interior S \<Longrightarrow> at x within S = at x"
  1035   by (simp add: filter_eq_iff eventually_within_interior)
  1036 
  1037 lemma at_within_open:
  1038   "\<lbrakk>x \<in> S; open S\<rbrakk> \<Longrightarrow> at x within S = at x"
  1039   by (simp only: at_within_interior interior_open)
  1040 
  1041 lemma Lim_within_open:
  1042   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1043   assumes"a \<in> S" "open S"
  1044   shows "(f ---> l)(at a within S) \<longleftrightarrow> (f ---> l)(at a)"
  1045   using assms by (simp only: at_within_open)
  1046 
  1047 lemma Lim_within_LIMSEQ:
  1048   fixes a :: "'a::metric_space"
  1049   assumes "\<forall>S. (\<forall>n. S n \<noteq> a \<and> S n \<in> T) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
  1050   shows "(X ---> L) (at a within T)"
  1051   using assms unfolding tendsto_def [where l=L]
  1052   by (simp add: sequentially_imp_eventually_within)
  1053 
  1054 lemma Lim_right_bound:
  1055   fixes f :: "real \<Rightarrow> real"
  1056   assumes mono: "\<And>a b. a \<in> I \<Longrightarrow> b \<in> I \<Longrightarrow> x < a \<Longrightarrow> a \<le> b \<Longrightarrow> f a \<le> f b"
  1057   assumes bnd: "\<And>a. a \<in> I \<Longrightarrow> x < a \<Longrightarrow> K \<le> f a"
  1058   shows "(f ---> Inf (f ` ({x<..} \<inter> I))) (at x within ({x<..} \<inter> I))"
  1059 proof cases
  1060   assume "{x<..} \<inter> I = {}" then show ?thesis by (simp add: Lim_within_empty)
  1061 next
  1062   assume [simp]: "{x<..} \<inter> I \<noteq> {}"
  1063   show ?thesis
  1064   proof (rule Lim_within_LIMSEQ, safe)
  1065     fix S assume S: "\<forall>n. S n \<noteq> x \<and> S n \<in> {x <..} \<inter> I" "S ----> x"
  1066     
  1067     show "(\<lambda>n. f (S n)) ----> Inf (f ` ({x<..} \<inter> I))"
  1068     proof (rule LIMSEQ_I, rule ccontr)
  1069       fix r :: real assume "0 < r"
  1070       with Inf_close[of "f ` ({x<..} \<inter> I)" r]
  1071       obtain y where y: "x < y" "y \<in> I" "f y < Inf (f ` ({x <..} \<inter> I)) + r" by auto
  1072       from `x < y` have "0 < y - x" by auto
  1073       from S(2)[THEN LIMSEQ_D, OF this]
  1074       obtain N where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>S n - x\<bar> < y - x" by auto
  1075       
  1076       assume "\<not> (\<exists>N. \<forall>n\<ge>N. norm (f (S n) - Inf (f ` ({x<..} \<inter> I))) < r)"
  1077       moreover have "\<And>n. Inf (f ` ({x<..} \<inter> I)) \<le> f (S n)"
  1078         using S bnd by (intro Inf_lower[where z=K]) auto
  1079       ultimately obtain n where n: "N \<le> n" "r + Inf (f ` ({x<..} \<inter> I)) \<le> f (S n)"
  1080         by (auto simp: not_less field_simps)
  1081       with N[OF n(1)] mono[OF _ `y \<in> I`, of "S n"] S(1)[THEN spec, of n] y
  1082       show False by auto
  1083     qed
  1084   qed
  1085 qed
  1086 
  1087 text{* Another limit point characterization. *}
  1088 
  1089 lemma islimpt_sequential:
  1090   fixes x :: "'a::metric_space"
  1091   shows "x islimpt S \<longleftrightarrow> (\<exists>f. (\<forall>n::nat. f n \<in> S -{x}) \<and> (f ---> x) sequentially)"
  1092     (is "?lhs = ?rhs")
  1093 proof
  1094   assume ?lhs
  1095   then obtain f where f:"\<forall>y. y>0 \<longrightarrow> f y \<in> S \<and> f y \<noteq> x \<and> dist (f y) x < y"
  1096     unfolding islimpt_approachable
  1097     using choice[of "\<lambda>e y. e>0 \<longrightarrow> y\<in>S \<and> y\<noteq>x \<and> dist y x < e"] by auto
  1098   let ?I = "\<lambda>n. inverse (real (Suc n))"
  1099   have "\<forall>n. f (?I n) \<in> S - {x}" using f by simp
  1100   moreover have "(\<lambda>n. f (?I n)) ----> x"
  1101   proof (rule metric_tendsto_imp_tendsto)
  1102     show "?I ----> 0"
  1103       by (rule LIMSEQ_inverse_real_of_nat)
  1104     show "eventually (\<lambda>n. dist (f (?I n)) x \<le> dist (?I n) 0) sequentially"
  1105       by (simp add: norm_conv_dist [symmetric] less_imp_le f)
  1106   qed
  1107   ultimately show ?rhs by fast
  1108 next
  1109   assume ?rhs
  1110   then obtain f::"nat\<Rightarrow>'a"  where f:"(\<forall>n. f n \<in> S - {x})" "(\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f n) x < e)" unfolding Lim_sequentially by auto
  1111   { fix e::real assume "e>0"
  1112     then obtain N where "dist (f N) x < e" using f(2) by auto
  1113     moreover have "f N\<in>S" "f N \<noteq> x" using f(1) by auto
  1114     ultimately have "\<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e" by auto
  1115   }
  1116   thus ?lhs unfolding islimpt_approachable by auto
  1117 qed
  1118 
  1119 lemma Lim_inv: (* TODO: delete *)
  1120   fixes f :: "'a \<Rightarrow> real" and A :: "'a filter"
  1121   assumes "(f ---> l) A" and "l \<noteq> 0"
  1122   shows "((inverse o f) ---> inverse l) A"
  1123   unfolding o_def using assms by (rule tendsto_inverse)
  1124 
  1125 lemma Lim_null:
  1126   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1127   shows "(f ---> l) net \<longleftrightarrow> ((\<lambda>x. f(x) - l) ---> 0) net"
  1128   by (simp add: Lim dist_norm)
  1129 
  1130 lemma Lim_null_comparison:
  1131   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1132   assumes "eventually (\<lambda>x. norm (f x) \<le> g x) net" "(g ---> 0) net"
  1133   shows "(f ---> 0) net"
  1134 proof (rule metric_tendsto_imp_tendsto)
  1135   show "(g ---> 0) net" by fact
  1136   show "eventually (\<lambda>x. dist (f x) 0 \<le> dist (g x) 0) net"
  1137     using assms(1) by (rule eventually_elim1, simp add: dist_norm)
  1138 qed
  1139 
  1140 lemma Lim_transform_bound:
  1141   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1142   fixes g :: "'a \<Rightarrow> 'c::real_normed_vector"
  1143   assumes "eventually (\<lambda>n. norm(f n) <= norm(g n)) net"  "(g ---> 0) net"
  1144   shows "(f ---> 0) net"
  1145   using assms(1) tendsto_norm_zero [OF assms(2)]
  1146   by (rule Lim_null_comparison)
  1147 
  1148 text{* Deducing things about the limit from the elements. *}
  1149 
  1150 lemma Lim_in_closed_set:
  1151   assumes "closed S" "eventually (\<lambda>x. f(x) \<in> S) net" "\<not>(trivial_limit net)" "(f ---> l) net"
  1152   shows "l \<in> S"
  1153 proof (rule ccontr)
  1154   assume "l \<notin> S"
  1155   with `closed S` have "open (- S)" "l \<in> - S"
  1156     by (simp_all add: open_Compl)
  1157   with assms(4) have "eventually (\<lambda>x. f x \<in> - S) net"
  1158     by (rule topological_tendstoD)
  1159   with assms(2) have "eventually (\<lambda>x. False) net"
  1160     by (rule eventually_elim2) simp
  1161   with assms(3) show "False"
  1162     by (simp add: eventually_False)
  1163 qed
  1164 
  1165 text{* Need to prove closed(cball(x,e)) before deducing this as a corollary. *}
  1166 
  1167 lemma Lim_dist_ubound:
  1168   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. dist a (f x) <= e) net"
  1169   shows "dist a l <= e"
  1170 proof-
  1171   have "dist a l \<in> {..e}"
  1172   proof (rule Lim_in_closed_set)
  1173     show "closed {..e}" by simp
  1174     show "eventually (\<lambda>x. dist a (f x) \<in> {..e}) net" by (simp add: assms)
  1175     show "\<not> trivial_limit net" by fact
  1176     show "((\<lambda>x. dist a (f x)) ---> dist a l) net" by (intro tendsto_intros assms)
  1177   qed
  1178   thus ?thesis by simp
  1179 qed
  1180 
  1181 lemma Lim_norm_ubound:
  1182   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1183   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. norm(f x) <= e) net"
  1184   shows "norm(l) <= e"
  1185 proof-
  1186   have "norm l \<in> {..e}"
  1187   proof (rule Lim_in_closed_set)
  1188     show "closed {..e}" by simp
  1189     show "eventually (\<lambda>x. norm (f x) \<in> {..e}) net" by (simp add: assms)
  1190     show "\<not> trivial_limit net" by fact
  1191     show "((\<lambda>x. norm (f x)) ---> norm l) net" by (intro tendsto_intros assms)
  1192   qed
  1193   thus ?thesis by simp
  1194 qed
  1195 
  1196 lemma Lim_norm_lbound:
  1197   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1198   assumes "\<not> (trivial_limit net)"  "(f ---> l) net"  "eventually (\<lambda>x. e <= norm(f x)) net"
  1199   shows "e \<le> norm l"
  1200 proof-
  1201   have "norm l \<in> {e..}"
  1202   proof (rule Lim_in_closed_set)
  1203     show "closed {e..}" by simp
  1204     show "eventually (\<lambda>x. norm (f x) \<in> {e..}) net" by (simp add: assms)
  1205     show "\<not> trivial_limit net" by fact
  1206     show "((\<lambda>x. norm (f x)) ---> norm l) net" by (intro tendsto_intros assms)
  1207   qed
  1208   thus ?thesis by simp
  1209 qed
  1210 
  1211 text{* Uniqueness of the limit, when nontrivial. *}
  1212 
  1213 lemma tendsto_Lim:
  1214   fixes f :: "'a \<Rightarrow> 'b::t2_space"
  1215   shows "~(trivial_limit net) \<Longrightarrow> (f ---> l) net ==> Lim net f = l"
  1216   unfolding Lim_def using tendsto_unique[of net f] by auto
  1217 
  1218 text{* Limit under bilinear function *}
  1219 
  1220 lemma Lim_bilinear:
  1221   assumes "(f ---> l) net" and "(g ---> m) net" and "bounded_bilinear h"
  1222   shows "((\<lambda>x. h (f x) (g x)) ---> (h l m)) net"
  1223 using `bounded_bilinear h` `(f ---> l) net` `(g ---> m) net`
  1224 by (rule bounded_bilinear.tendsto)
  1225 
  1226 text{* These are special for limits out of the same vector space. *}
  1227 
  1228 lemma Lim_within_id: "(id ---> a) (at a within s)"
  1229   unfolding tendsto_def Limits.eventually_within eventually_at_topological
  1230   by auto
  1231 
  1232 lemma Lim_at_id: "(id ---> a) (at a)"
  1233 apply (subst within_UNIV[symmetric]) by (simp add: Lim_within_id)
  1234 
  1235 lemma Lim_at_zero:
  1236   fixes a :: "'a::real_normed_vector"
  1237   fixes l :: "'b::topological_space"
  1238   shows "(f ---> l) (at a) \<longleftrightarrow> ((\<lambda>x. f(a + x)) ---> l) (at 0)" (is "?lhs = ?rhs")
  1239   using LIM_offset_zero LIM_offset_zero_cancel ..
  1240 
  1241 text{* It's also sometimes useful to extract the limit point from the filter. *}
  1242 
  1243 definition
  1244   netlimit :: "'a::t2_space filter \<Rightarrow> 'a" where
  1245   "netlimit net = (SOME a. ((\<lambda>x. x) ---> a) net)"
  1246 
  1247 lemma netlimit_within:
  1248   assumes "\<not> trivial_limit (at a within S)"
  1249   shows "netlimit (at a within S) = a"
  1250 unfolding netlimit_def
  1251 apply (rule some_equality)
  1252 apply (rule Lim_at_within)
  1253 apply (rule tendsto_ident_at)
  1254 apply (erule tendsto_unique [OF assms])
  1255 apply (rule Lim_at_within)
  1256 apply (rule tendsto_ident_at)
  1257 done
  1258 
  1259 lemma netlimit_at:
  1260   fixes a :: "'a::{perfect_space,t2_space}"
  1261   shows "netlimit (at a) = a"
  1262   apply (subst within_UNIV[symmetric])
  1263   using netlimit_within[of a UNIV]
  1264   by (simp add: within_UNIV)
  1265 
  1266 lemma lim_within_interior:
  1267   "x \<in> interior S \<Longrightarrow> (f ---> l) (at x within S) \<longleftrightarrow> (f ---> l) (at x)"
  1268   by (simp add: at_within_interior)
  1269 
  1270 lemma netlimit_within_interior:
  1271   fixes x :: "'a::{t2_space,perfect_space}"
  1272   assumes "x \<in> interior S"
  1273   shows "netlimit (at x within S) = x"
  1274 using assms by (simp add: at_within_interior netlimit_at)
  1275 
  1276 text{* Transformation of limit. *}
  1277 
  1278 lemma Lim_transform:
  1279   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
  1280   assumes "((\<lambda>x. f x - g x) ---> 0) net" "(f ---> l) net"
  1281   shows "(g ---> l) net"
  1282   using tendsto_diff [OF assms(2) assms(1)] by simp
  1283 
  1284 lemma Lim_transform_eventually:
  1285   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f ---> l) net \<Longrightarrow> (g ---> l) net"
  1286   apply (rule topological_tendstoI)
  1287   apply (drule (2) topological_tendstoD)
  1288   apply (erule (1) eventually_elim2, simp)
  1289   done
  1290 
  1291 lemma Lim_transform_within:
  1292   assumes "0 < d" and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1293   and "(f ---> l) (at x within S)"
  1294   shows "(g ---> l) (at x within S)"
  1295 proof (rule Lim_transform_eventually)
  1296   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1297     unfolding eventually_within
  1298     using assms(1,2) by auto
  1299   show "(f ---> l) (at x within S)" by fact
  1300 qed
  1301 
  1302 lemma Lim_transform_at:
  1303   assumes "0 < d" and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1304   and "(f ---> l) (at x)"
  1305   shows "(g ---> l) (at x)"
  1306 proof (rule Lim_transform_eventually)
  1307   show "eventually (\<lambda>x. f x = g x) (at x)"
  1308     unfolding eventually_at
  1309     using assms(1,2) by auto
  1310   show "(f ---> l) (at x)" by fact
  1311 qed
  1312 
  1313 text{* Common case assuming being away from some crucial point like 0. *}
  1314 
  1315 lemma Lim_transform_away_within:
  1316   fixes a b :: "'a::t1_space"
  1317   assumes "a \<noteq> b" and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1318   and "(f ---> l) (at a within S)"
  1319   shows "(g ---> l) (at a within S)"
  1320 proof (rule Lim_transform_eventually)
  1321   show "(f ---> l) (at a within S)" by fact
  1322   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1323     unfolding Limits.eventually_within eventually_at_topological
  1324     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1325 qed
  1326 
  1327 lemma Lim_transform_away_at:
  1328   fixes a b :: "'a::t1_space"
  1329   assumes ab: "a\<noteq>b" and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1330   and fl: "(f ---> l) (at a)"
  1331   shows "(g ---> l) (at a)"
  1332   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl
  1333   by (auto simp add: within_UNIV)
  1334 
  1335 text{* Alternatively, within an open set. *}
  1336 
  1337 lemma Lim_transform_within_open:
  1338   assumes "open S" and "a \<in> S" and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  1339   and "(f ---> l) (at a)"
  1340   shows "(g ---> l) (at a)"
  1341 proof (rule Lim_transform_eventually)
  1342   show "eventually (\<lambda>x. f x = g x) (at a)"
  1343     unfolding eventually_at_topological
  1344     using assms(1,2,3) by auto
  1345   show "(f ---> l) (at a)" by fact
  1346 qed
  1347 
  1348 text{* A congruence rule allowing us to transform limits assuming not at point. *}
  1349 
  1350 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1351 
  1352 lemma Lim_cong_within(*[cong add]*):
  1353   assumes "a = b" "x = y" "S = T"
  1354   assumes "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1355   shows "(f ---> x) (at a within S) \<longleftrightarrow> (g ---> y) (at b within T)"
  1356   unfolding tendsto_def Limits.eventually_within eventually_at_topological
  1357   using assms by simp
  1358 
  1359 lemma Lim_cong_at(*[cong add]*):
  1360   assumes "a = b" "x = y"
  1361   assumes "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1362   shows "((\<lambda>x. f x) ---> x) (at a) \<longleftrightarrow> ((g ---> y) (at a))"
  1363   unfolding tendsto_def eventually_at_topological
  1364   using assms by simp
  1365 
  1366 text{* Useful lemmas on closure and set of possible sequential limits.*}
  1367 
  1368 lemma closure_sequential:
  1369   fixes l :: "'a::metric_space"
  1370   shows "l \<in> closure S \<longleftrightarrow> (\<exists>x. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially)" (is "?lhs = ?rhs")
  1371 proof
  1372   assume "?lhs" moreover
  1373   { assume "l \<in> S"
  1374     hence "?rhs" using tendsto_const[of l sequentially] by auto
  1375   } moreover
  1376   { assume "l islimpt S"
  1377     hence "?rhs" unfolding islimpt_sequential by auto
  1378   } ultimately
  1379   show "?rhs" unfolding closure_def by auto
  1380 next
  1381   assume "?rhs"
  1382   thus "?lhs" unfolding closure_def unfolding islimpt_sequential by auto
  1383 qed
  1384 
  1385 lemma closed_sequential_limits:
  1386   fixes S :: "'a::metric_space set"
  1387   shows "closed S \<longleftrightarrow> (\<forall>x l. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially \<longrightarrow> l \<in> S)"
  1388   unfolding closed_limpt
  1389   using closure_sequential [where 'a='a] closure_closed [where 'a='a] closed_limpt [where 'a='a] islimpt_sequential [where 'a='a] mem_delete [where 'a='a]
  1390   by metis
  1391 
  1392 lemma closure_approachable:
  1393   fixes S :: "'a::metric_space set"
  1394   shows "x \<in> closure S \<longleftrightarrow> (\<forall>e>0. \<exists>y\<in>S. dist y x < e)"
  1395   apply (auto simp add: closure_def islimpt_approachable)
  1396   by (metis dist_self)
  1397 
  1398 lemma closed_approachable:
  1399   fixes S :: "'a::metric_space set"
  1400   shows "closed S ==> (\<forall>e>0. \<exists>y\<in>S. dist y x < e) \<longleftrightarrow> x \<in> S"
  1401   by (metis closure_closed closure_approachable)
  1402 
  1403 text{* Some other lemmas about sequences. *}
  1404 
  1405 lemma sequentially_offset:
  1406   assumes "eventually (\<lambda>i. P i) sequentially"
  1407   shows "eventually (\<lambda>i. P (i + k)) sequentially"
  1408   using assms unfolding eventually_sequentially by (metis trans_le_add1)
  1409 
  1410 lemma seq_offset:
  1411   assumes "(f ---> l) sequentially"
  1412   shows "((\<lambda>i. f (i + k)) ---> l) sequentially"
  1413   using assms by (rule LIMSEQ_ignore_initial_segment) (* FIXME: redundant *)
  1414 
  1415 lemma seq_offset_neg:
  1416   "(f ---> l) sequentially ==> ((\<lambda>i. f(i - k)) ---> l) sequentially"
  1417   apply (rule topological_tendstoI)
  1418   apply (drule (2) topological_tendstoD)
  1419   apply (simp only: eventually_sequentially)
  1420   apply (subgoal_tac "\<And>N k (n::nat). N + k <= n ==> N <= n - k")
  1421   apply metis
  1422   by arith
  1423 
  1424 lemma seq_offset_rev:
  1425   "((\<lambda>i. f(i + k)) ---> l) sequentially ==> (f ---> l) sequentially"
  1426   by (rule LIMSEQ_offset) (* FIXME: redundant *)
  1427 
  1428 lemma seq_harmonic: "((\<lambda>n. inverse (real n)) ---> 0) sequentially"
  1429   using LIMSEQ_inverse_real_of_nat by (rule LIMSEQ_imp_Suc)
  1430 
  1431 subsection {* More properties of closed balls *}
  1432 
  1433 lemma closed_cball: "closed (cball x e)"
  1434 unfolding cball_def closed_def
  1435 unfolding Collect_neg_eq [symmetric] not_le
  1436 apply (clarsimp simp add: open_dist, rename_tac y)
  1437 apply (rule_tac x="dist x y - e" in exI, clarsimp)
  1438 apply (rename_tac x')
  1439 apply (cut_tac x=x and y=x' and z=y in dist_triangle)
  1440 apply simp
  1441 done
  1442 
  1443 lemma open_contains_cball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0.  cball x e \<subseteq> S)"
  1444 proof-
  1445   { fix x and e::real assume "x\<in>S" "e>0" "ball x e \<subseteq> S"
  1446     hence "\<exists>d>0. cball x d \<subseteq> S" unfolding subset_eq by (rule_tac x="e/2" in exI, auto)
  1447   } moreover
  1448   { fix x and e::real assume "x\<in>S" "e>0" "cball x e \<subseteq> S"
  1449     hence "\<exists>d>0. ball x d \<subseteq> S" unfolding subset_eq apply(rule_tac x="e/2" in exI) by auto
  1450   } ultimately
  1451   show ?thesis unfolding open_contains_ball by auto
  1452 qed
  1453 
  1454 lemma open_contains_cball_eq: "open S ==> (\<forall>x. x \<in> S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S))"
  1455   by (metis open_contains_cball subset_eq order_less_imp_le centre_in_cball)
  1456 
  1457 lemma mem_interior_cball: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S)"
  1458   apply (simp add: interior_def, safe)
  1459   apply (force simp add: open_contains_cball)
  1460   apply (rule_tac x="ball x e" in exI)
  1461   apply (simp add: subset_trans [OF ball_subset_cball])
  1462   done
  1463 
  1464 lemma islimpt_ball:
  1465   fixes x y :: "'a::{real_normed_vector,perfect_space}"
  1466   shows "y islimpt ball x e \<longleftrightarrow> 0 < e \<and> y \<in> cball x e" (is "?lhs = ?rhs")
  1467 proof
  1468   assume "?lhs"
  1469   { assume "e \<le> 0"
  1470     hence *:"ball x e = {}" using ball_eq_empty[of x e] by auto
  1471     have False using `?lhs` unfolding * using islimpt_EMPTY[of y] by auto
  1472   }
  1473   hence "e > 0" by (metis not_less)
  1474   moreover
  1475   have "y \<in> cball x e" using closed_cball[of x e] islimpt_subset[of y "ball x e" "cball x e"] ball_subset_cball[of x e] `?lhs` unfolding closed_limpt by auto
  1476   ultimately show "?rhs" by auto
  1477 next
  1478   assume "?rhs" hence "e>0"  by auto
  1479   { fix d::real assume "d>0"
  1480     have "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1481     proof(cases "d \<le> dist x y")
  1482       case True thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1483       proof(cases "x=y")
  1484         case True hence False using `d \<le> dist x y` `d>0` by auto
  1485         thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d" by auto
  1486       next
  1487         case False
  1488 
  1489         have "dist x (y - (d / (2 * dist y x)) *\<^sub>R (y - x))
  1490               = norm (x - y + (d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  1491           unfolding mem_cball mem_ball dist_norm diff_diff_eq2 diff_add_eq[THEN sym] by auto
  1492         also have "\<dots> = \<bar>- 1 + d / (2 * norm (x - y))\<bar> * norm (x - y)"
  1493           using scaleR_left_distrib[of "- 1" "d / (2 * norm (y - x))", THEN sym, of "y - x"]
  1494           unfolding scaleR_minus_left scaleR_one
  1495           by (auto simp add: norm_minus_commute)
  1496         also have "\<dots> = \<bar>- norm (x - y) + d / 2\<bar>"
  1497           unfolding abs_mult_pos[of "norm (x - y)", OF norm_ge_zero[of "x - y"]]
  1498           unfolding left_distrib using `x\<noteq>y`[unfolded dist_nz, unfolded dist_norm] by auto
  1499         also have "\<dots> \<le> e - d/2" using `d \<le> dist x y` and `d>0` and `?rhs` by(auto simp add: dist_norm)
  1500         finally have "y - (d / (2 * dist y x)) *\<^sub>R (y - x) \<in> ball x e" using `d>0` by auto
  1501 
  1502         moreover
  1503 
  1504         have "(d / (2*dist y x)) *\<^sub>R (y - x) \<noteq> 0"
  1505           using `x\<noteq>y`[unfolded dist_nz] `d>0` unfolding scaleR_eq_0_iff by (auto simp add: dist_commute)
  1506         moreover
  1507         have "dist (y - (d / (2 * dist y x)) *\<^sub>R (y - x)) y < d" unfolding dist_norm apply simp unfolding norm_minus_cancel
  1508           using `d>0` `x\<noteq>y`[unfolded dist_nz] dist_commute[of x y]
  1509           unfolding dist_norm by auto
  1510         ultimately show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d" by (rule_tac  x="y - (d / (2*dist y x)) *\<^sub>R (y - x)" in bexI) auto
  1511       qed
  1512     next
  1513       case False hence "d > dist x y" by auto
  1514       show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1515       proof(cases "x=y")
  1516         case True
  1517         obtain z where **: "z \<noteq> y" "dist z y < min e d"
  1518           using perfect_choose_dist[of "min e d" y]
  1519           using `d > 0` `e>0` by auto
  1520         show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1521           unfolding `x = y`
  1522           using `z \<noteq> y` **
  1523           by (rule_tac x=z in bexI, auto simp add: dist_commute)
  1524       next
  1525         case False thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1526           using `d>0` `d > dist x y` `?rhs` by(rule_tac x=x in bexI, auto)
  1527       qed
  1528     qed  }
  1529   thus "?lhs" unfolding mem_cball islimpt_approachable mem_ball by auto
  1530 qed
  1531 
  1532 lemma closure_ball_lemma:
  1533   fixes x y :: "'a::real_normed_vector"
  1534   assumes "x \<noteq> y" shows "y islimpt ball x (dist x y)"
  1535 proof (rule islimptI)
  1536   fix T assume "y \<in> T" "open T"
  1537   then obtain r where "0 < r" "\<forall>z. dist z y < r \<longrightarrow> z \<in> T"
  1538     unfolding open_dist by fast
  1539   (* choose point between x and y, within distance r of y. *)
  1540   def k \<equiv> "min 1 (r / (2 * dist x y))"
  1541   def z \<equiv> "y + scaleR k (x - y)"
  1542   have z_def2: "z = x + scaleR (1 - k) (y - x)"
  1543     unfolding z_def by (simp add: algebra_simps)
  1544   have "dist z y < r"
  1545     unfolding z_def k_def using `0 < r`
  1546     by (simp add: dist_norm min_def)
  1547   hence "z \<in> T" using `\<forall>z. dist z y < r \<longrightarrow> z \<in> T` by simp
  1548   have "dist x z < dist x y"
  1549     unfolding z_def2 dist_norm
  1550     apply (simp add: norm_minus_commute)
  1551     apply (simp only: dist_norm [symmetric])
  1552     apply (subgoal_tac "\<bar>1 - k\<bar> * dist x y < 1 * dist x y", simp)
  1553     apply (rule mult_strict_right_mono)
  1554     apply (simp add: k_def divide_pos_pos zero_less_dist_iff `0 < r` `x \<noteq> y`)
  1555     apply (simp add: zero_less_dist_iff `x \<noteq> y`)
  1556     done
  1557   hence "z \<in> ball x (dist x y)" by simp
  1558   have "z \<noteq> y"
  1559     unfolding z_def k_def using `x \<noteq> y` `0 < r`
  1560     by (simp add: min_def)
  1561   show "\<exists>z\<in>ball x (dist x y). z \<in> T \<and> z \<noteq> y"
  1562     using `z \<in> ball x (dist x y)` `z \<in> T` `z \<noteq> y`
  1563     by fast
  1564 qed
  1565 
  1566 lemma closure_ball:
  1567   fixes x :: "'a::real_normed_vector"
  1568   shows "0 < e \<Longrightarrow> closure (ball x e) = cball x e"
  1569 apply (rule equalityI)
  1570 apply (rule closure_minimal)
  1571 apply (rule ball_subset_cball)
  1572 apply (rule closed_cball)
  1573 apply (rule subsetI, rename_tac y)
  1574 apply (simp add: le_less [where 'a=real])
  1575 apply (erule disjE)
  1576 apply (rule subsetD [OF closure_subset], simp)
  1577 apply (simp add: closure_def)
  1578 apply clarify
  1579 apply (rule closure_ball_lemma)
  1580 apply (simp add: zero_less_dist_iff)
  1581 done
  1582 
  1583 (* In a trivial vector space, this fails for e = 0. *)
  1584 lemma interior_cball:
  1585   fixes x :: "'a::{real_normed_vector, perfect_space}"
  1586   shows "interior (cball x e) = ball x e"
  1587 proof(cases "e\<ge>0")
  1588   case False note cs = this
  1589   from cs have "ball x e = {}" using ball_empty[of e x] by auto moreover
  1590   { fix y assume "y \<in> cball x e"
  1591     hence False unfolding mem_cball using dist_nz[of x y] cs by auto  }
  1592   hence "cball x e = {}" by auto
  1593   hence "interior (cball x e) = {}" using interior_empty by auto
  1594   ultimately show ?thesis by blast
  1595 next
  1596   case True note cs = this
  1597   have "ball x e \<subseteq> cball x e" using ball_subset_cball by auto moreover
  1598   { fix S y assume as: "S \<subseteq> cball x e" "open S" "y\<in>S"
  1599     then obtain d where "d>0" and d:"\<forall>x'. dist x' y < d \<longrightarrow> x' \<in> S" unfolding open_dist by blast
  1600 
  1601     then obtain xa where xa_y: "xa \<noteq> y" and xa: "dist xa y < d"
  1602       using perfect_choose_dist [of d] by auto
  1603     have "xa\<in>S" using d[THEN spec[where x=xa]] using xa by(auto simp add: dist_commute)
  1604     hence xa_cball:"xa \<in> cball x e" using as(1) by auto
  1605 
  1606     hence "y \<in> ball x e" proof(cases "x = y")
  1607       case True
  1608       hence "e>0" using xa_y[unfolded dist_nz] xa_cball[unfolded mem_cball] by (auto simp add: dist_commute)
  1609       thus "y \<in> ball x e" using `x = y ` by simp
  1610     next
  1611       case False
  1612       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) y < d" unfolding dist_norm
  1613         using `d>0` norm_ge_zero[of "y - x"] `x \<noteq> y` by auto
  1614       hence *:"y + (d / 2 / dist y x) *\<^sub>R (y - x) \<in> cball x e" using d as(1)[unfolded subset_eq] by blast
  1615       have "y - x \<noteq> 0" using `x \<noteq> y` by auto
  1616       hence **:"d / (2 * norm (y - x)) > 0" unfolding zero_less_norm_iff[THEN sym]
  1617         using `d>0` divide_pos_pos[of d "2*norm (y - x)"] by auto
  1618 
  1619       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) x = norm (y + (d / (2 * norm (y - x))) *\<^sub>R y - (d / (2 * norm (y - x))) *\<^sub>R x - x)"
  1620         by (auto simp add: dist_norm algebra_simps)
  1621       also have "\<dots> = norm ((1 + d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  1622         by (auto simp add: algebra_simps)
  1623       also have "\<dots> = \<bar>1 + d / (2 * norm (y - x))\<bar> * norm (y - x)"
  1624         using ** by auto
  1625       also have "\<dots> = (dist y x) + d/2"using ** by (auto simp add: left_distrib dist_norm)
  1626       finally have "e \<ge> dist x y +d/2" using *[unfolded mem_cball] by (auto simp add: dist_commute)
  1627       thus "y \<in> ball x e" unfolding mem_ball using `d>0` by auto
  1628     qed  }
  1629   hence "\<forall>S \<subseteq> cball x e. open S \<longrightarrow> S \<subseteq> ball x e" by auto
  1630   ultimately show ?thesis using interior_unique[of "ball x e" "cball x e"] using open_ball[of x e] by auto
  1631 qed
  1632 
  1633 lemma frontier_ball:
  1634   fixes a :: "'a::real_normed_vector"
  1635   shows "0 < e ==> frontier(ball a e) = {x. dist a x = e}"
  1636   apply (simp add: frontier_def closure_ball interior_open order_less_imp_le)
  1637   apply (simp add: set_eq_iff)
  1638   by arith
  1639 
  1640 lemma frontier_cball:
  1641   fixes a :: "'a::{real_normed_vector, perfect_space}"
  1642   shows "frontier(cball a e) = {x. dist a x = e}"
  1643   apply (simp add: frontier_def interior_cball closed_cball order_less_imp_le)
  1644   apply (simp add: set_eq_iff)
  1645   by arith
  1646 
  1647 lemma cball_eq_empty: "(cball x e = {}) \<longleftrightarrow> e < 0"
  1648   apply (simp add: set_eq_iff not_le)
  1649   by (metis zero_le_dist dist_self order_less_le_trans)
  1650 lemma cball_empty: "e < 0 ==> cball x e = {}" by (simp add: cball_eq_empty)
  1651 
  1652 lemma cball_eq_sing:
  1653   fixes x :: "'a::{metric_space,perfect_space}"
  1654   shows "(cball x e = {x}) \<longleftrightarrow> e = 0"
  1655 proof (rule linorder_cases)
  1656   assume e: "0 < e"
  1657   obtain a where "a \<noteq> x" "dist a x < e"
  1658     using perfect_choose_dist [OF e] by auto
  1659   hence "a \<noteq> x" "dist x a \<le> e" by (auto simp add: dist_commute)
  1660   with e show ?thesis by (auto simp add: set_eq_iff)
  1661 qed auto
  1662 
  1663 lemma cball_sing:
  1664   fixes x :: "'a::metric_space"
  1665   shows "e = 0 ==> cball x e = {x}"
  1666   by (auto simp add: set_eq_iff)
  1667 
  1668 
  1669 subsection {* Boundedness *}
  1670 
  1671   (* FIXME: This has to be unified with BSEQ!! *)
  1672 definition (in metric_space)
  1673   bounded :: "'a set \<Rightarrow> bool" where
  1674   "bounded S \<longleftrightarrow> (\<exists>x e. \<forall>y\<in>S. dist x y \<le> e)"
  1675 
  1676 lemma bounded_any_center: "bounded S \<longleftrightarrow> (\<exists>e. \<forall>y\<in>S. dist a y \<le> e)"
  1677 unfolding bounded_def
  1678 apply safe
  1679 apply (rule_tac x="dist a x + e" in exI, clarify)
  1680 apply (drule (1) bspec)
  1681 apply (erule order_trans [OF dist_triangle add_left_mono])
  1682 apply auto
  1683 done
  1684 
  1685 lemma bounded_iff: "bounded S \<longleftrightarrow> (\<exists>a. \<forall>x\<in>S. norm x \<le> a)"
  1686 unfolding bounded_any_center [where a=0]
  1687 by (simp add: dist_norm)
  1688 
  1689 lemma bounded_empty[simp]: "bounded {}" by (simp add: bounded_def)
  1690 lemma bounded_subset: "bounded T \<Longrightarrow> S \<subseteq> T ==> bounded S"
  1691   by (metis bounded_def subset_eq)
  1692 
  1693 lemma bounded_interior[intro]: "bounded S ==> bounded(interior S)"
  1694   by (metis bounded_subset interior_subset)
  1695 
  1696 lemma bounded_closure[intro]: assumes "bounded S" shows "bounded(closure S)"
  1697 proof-
  1698   from assms obtain x and a where a: "\<forall>y\<in>S. dist x y \<le> a" unfolding bounded_def by auto
  1699   { fix y assume "y \<in> closure S"
  1700     then obtain f where f: "\<forall>n. f n \<in> S"  "(f ---> y) sequentially"
  1701       unfolding closure_sequential by auto
  1702     have "\<forall>n. f n \<in> S \<longrightarrow> dist x (f n) \<le> a" using a by simp
  1703     hence "eventually (\<lambda>n. dist x (f n) \<le> a) sequentially"
  1704       by (rule eventually_mono, simp add: f(1))
  1705     have "dist x y \<le> a"
  1706       apply (rule Lim_dist_ubound [of sequentially f])
  1707       apply (rule trivial_limit_sequentially)
  1708       apply (rule f(2))
  1709       apply fact
  1710       done
  1711   }
  1712   thus ?thesis unfolding bounded_def by auto
  1713 qed
  1714 
  1715 lemma bounded_cball[simp,intro]: "bounded (cball x e)"
  1716   apply (simp add: bounded_def)
  1717   apply (rule_tac x=x in exI)
  1718   apply (rule_tac x=e in exI)
  1719   apply auto
  1720   done
  1721 
  1722 lemma bounded_ball[simp,intro]: "bounded(ball x e)"
  1723   by (metis ball_subset_cball bounded_cball bounded_subset)
  1724 
  1725 lemma finite_imp_bounded[intro]:
  1726   fixes S :: "'a::metric_space set" assumes "finite S" shows "bounded S"
  1727 proof-
  1728   { fix a and F :: "'a set" assume as:"bounded F"
  1729     then obtain x e where "\<forall>y\<in>F. dist x y \<le> e" unfolding bounded_def by auto
  1730     hence "\<forall>y\<in>(insert a F). dist x y \<le> max e (dist x a)" by auto
  1731     hence "bounded (insert a F)" unfolding bounded_def by (intro exI)
  1732   }
  1733   thus ?thesis using finite_induct[of S bounded]  using bounded_empty assms by auto
  1734 qed
  1735 
  1736 lemma bounded_Un[simp]: "bounded (S \<union> T) \<longleftrightarrow> bounded S \<and> bounded T"
  1737   apply (auto simp add: bounded_def)
  1738   apply (rename_tac x y r s)
  1739   apply (rule_tac x=x in exI)
  1740   apply (rule_tac x="max r (dist x y + s)" in exI)
  1741   apply (rule ballI, rename_tac z, safe)
  1742   apply (drule (1) bspec, simp)
  1743   apply (drule (1) bspec)
  1744   apply (rule min_max.le_supI2)
  1745   apply (erule order_trans [OF dist_triangle add_left_mono])
  1746   done
  1747 
  1748 lemma bounded_Union[intro]: "finite F \<Longrightarrow> (\<forall>S\<in>F. bounded S) \<Longrightarrow> bounded(\<Union>F)"
  1749   by (induct rule: finite_induct[of F], auto)
  1750 
  1751 lemma bounded_pos: "bounded S \<longleftrightarrow> (\<exists>b>0. \<forall>x\<in> S. norm x <= b)"
  1752   apply (simp add: bounded_iff)
  1753   apply (subgoal_tac "\<And>x (y::real). 0 < 1 + abs y \<and> (x <= y \<longrightarrow> x <= 1 + abs y)")
  1754   by metis arith
  1755 
  1756 lemma bounded_Int[intro]: "bounded S \<or> bounded T \<Longrightarrow> bounded (S \<inter> T)"
  1757   by (metis Int_lower1 Int_lower2 bounded_subset)
  1758 
  1759 lemma bounded_diff[intro]: "bounded S ==> bounded (S - T)"
  1760 apply (metis Diff_subset bounded_subset)
  1761 done
  1762 
  1763 lemma bounded_insert[intro]:"bounded(insert x S) \<longleftrightarrow> bounded S"
  1764   by (metis Diff_cancel Un_empty_right Un_insert_right bounded_Un bounded_subset finite.emptyI finite_imp_bounded infinite_remove subset_insertI)
  1765 
  1766 lemma not_bounded_UNIV[simp, intro]:
  1767   "\<not> bounded (UNIV :: 'a::{real_normed_vector, perfect_space} set)"
  1768 proof(auto simp add: bounded_pos not_le)
  1769   obtain x :: 'a where "x \<noteq> 0"
  1770     using perfect_choose_dist [OF zero_less_one] by fast
  1771   fix b::real  assume b: "b >0"
  1772   have b1: "b +1 \<ge> 0" using b by simp
  1773   with `x \<noteq> 0` have "b < norm (scaleR (b + 1) (sgn x))"
  1774     by (simp add: norm_sgn)
  1775   then show "\<exists>x::'a. b < norm x" ..
  1776 qed
  1777 
  1778 lemma bounded_linear_image:
  1779   assumes "bounded S" "bounded_linear f"
  1780   shows "bounded(f ` S)"
  1781 proof-
  1782   from assms(1) obtain b where b:"b>0" "\<forall>x\<in>S. norm x \<le> b" unfolding bounded_pos by auto
  1783   from assms(2) obtain B where B:"B>0" "\<forall>x. norm (f x) \<le> B * norm x" using bounded_linear.pos_bounded by (auto simp add: mult_ac)
  1784   { fix x assume "x\<in>S"
  1785     hence "norm x \<le> b" using b by auto
  1786     hence "norm (f x) \<le> B * b" using B(2) apply(erule_tac x=x in allE)
  1787       by (metis B(1) B(2) order_trans mult_le_cancel_left_pos)
  1788   }
  1789   thus ?thesis unfolding bounded_pos apply(rule_tac x="b*B" in exI)
  1790     using b B mult_pos_pos [of b B] by (auto simp add: mult_commute)
  1791 qed
  1792 
  1793 lemma bounded_scaling:
  1794   fixes S :: "'a::real_normed_vector set"
  1795   shows "bounded S \<Longrightarrow> bounded ((\<lambda>x. c *\<^sub>R x) ` S)"
  1796   apply (rule bounded_linear_image, assumption)
  1797   apply (rule bounded_linear_scaleR_right)
  1798   done
  1799 
  1800 lemma bounded_translation:
  1801   fixes S :: "'a::real_normed_vector set"
  1802   assumes "bounded S" shows "bounded ((\<lambda>x. a + x) ` S)"
  1803 proof-
  1804   from assms obtain b where b:"b>0" "\<forall>x\<in>S. norm x \<le> b" unfolding bounded_pos by auto
  1805   { fix x assume "x\<in>S"
  1806     hence "norm (a + x) \<le> b + norm a" using norm_triangle_ineq[of a x] b by auto
  1807   }
  1808   thus ?thesis unfolding bounded_pos using norm_ge_zero[of a] b(1) using add_strict_increasing[of b 0 "norm a"]
  1809     by (auto intro!: add exI[of _ "b + norm a"])
  1810 qed
  1811 
  1812 
  1813 text{* Some theorems on sups and infs using the notion "bounded". *}
  1814 
  1815 lemma bounded_real:
  1816   fixes S :: "real set"
  1817   shows "bounded S \<longleftrightarrow>  (\<exists>a. \<forall>x\<in>S. abs x <= a)"
  1818   by (simp add: bounded_iff)
  1819 
  1820 lemma bounded_has_Sup:
  1821   fixes S :: "real set"
  1822   assumes "bounded S" "S \<noteq> {}"
  1823   shows "\<forall>x\<in>S. x <= Sup S" and "\<forall>b. (\<forall>x\<in>S. x <= b) \<longrightarrow> Sup S <= b"
  1824 proof
  1825   fix x assume "x\<in>S"
  1826   thus "x \<le> Sup S"
  1827     by (metis SupInf.Sup_upper abs_le_D1 assms(1) bounded_real)
  1828 next
  1829   show "\<forall>b. (\<forall>x\<in>S. x \<le> b) \<longrightarrow> Sup S \<le> b" using assms
  1830     by (metis SupInf.Sup_least)
  1831 qed
  1832 
  1833 lemma Sup_insert:
  1834   fixes S :: "real set"
  1835   shows "bounded S ==> Sup(insert x S) = (if S = {} then x else max x (Sup S))" 
  1836 by auto (metis Int_absorb Sup_insert_nonempty assms bounded_has_Sup(1) disjoint_iff_not_equal) 
  1837 
  1838 lemma Sup_insert_finite:
  1839   fixes S :: "real set"
  1840   shows "finite S \<Longrightarrow> Sup(insert x S) = (if S = {} then x else max x (Sup S))"
  1841   apply (rule Sup_insert)
  1842   apply (rule finite_imp_bounded)
  1843   by simp
  1844 
  1845 lemma bounded_has_Inf:
  1846   fixes S :: "real set"
  1847   assumes "bounded S"  "S \<noteq> {}"
  1848   shows "\<forall>x\<in>S. x >= Inf S" and "\<forall>b. (\<forall>x\<in>S. x >= b) \<longrightarrow> Inf S >= b"
  1849 proof
  1850   fix x assume "x\<in>S"
  1851   from assms(1) obtain a where a:"\<forall>x\<in>S. \<bar>x\<bar> \<le> a" unfolding bounded_real by auto
  1852   thus "x \<ge> Inf S" using `x\<in>S`
  1853     by (metis Inf_lower_EX abs_le_D2 minus_le_iff)
  1854 next
  1855   show "\<forall>b. (\<forall>x\<in>S. x >= b) \<longrightarrow> Inf S \<ge> b" using assms
  1856     by (metis SupInf.Inf_greatest)
  1857 qed
  1858 
  1859 lemma Inf_insert:
  1860   fixes S :: "real set"
  1861   shows "bounded S ==> Inf(insert x S) = (if S = {} then x else min x (Inf S))" 
  1862 by auto (metis Int_absorb Inf_insert_nonempty bounded_has_Inf(1) disjoint_iff_not_equal) 
  1863 lemma Inf_insert_finite:
  1864   fixes S :: "real set"
  1865   shows "finite S ==> Inf(insert x S) = (if S = {} then x else min x (Inf S))"
  1866   by (rule Inf_insert, rule finite_imp_bounded, simp)
  1867 
  1868 (* TODO: Move this to RComplete.thy -- would need to include Glb into RComplete *)
  1869 lemma real_isGlb_unique: "[| isGlb R S x; isGlb R S y |] ==> x = (y::real)"
  1870   apply (frule isGlb_isLb)
  1871   apply (frule_tac x = y in isGlb_isLb)
  1872   apply (blast intro!: order_antisym dest!: isGlb_le_isLb)
  1873   done
  1874 
  1875 
  1876 subsection {* Equivalent versions of compactness *}
  1877 
  1878 subsubsection{* Sequential compactness *}
  1879 
  1880 definition
  1881   compact :: "'a::metric_space set \<Rightarrow> bool" where (* TODO: generalize *)
  1882   "compact S \<longleftrightarrow>
  1883    (\<forall>f. (\<forall>n. f n \<in> S) \<longrightarrow>
  1884        (\<exists>l\<in>S. \<exists>r. subseq r \<and> ((f o r) ---> l) sequentially))"
  1885 
  1886 lemma compactI:
  1887   assumes "\<And>f. \<forall>n. f n \<in> S \<Longrightarrow> \<exists>l\<in>S. \<exists>r. subseq r \<and> ((f o r) ---> l) sequentially"
  1888   shows "compact S"
  1889   unfolding compact_def using assms by fast
  1890 
  1891 lemma compactE:
  1892   assumes "compact S" "\<forall>n. f n \<in> S"
  1893   obtains l r where "l \<in> S" "subseq r" "((f \<circ> r) ---> l) sequentially"
  1894   using assms unfolding compact_def by fast
  1895 
  1896 text {*
  1897   A metric space (or topological vector space) is said to have the
  1898   Heine-Borel property if every closed and bounded subset is compact.
  1899 *}
  1900 
  1901 class heine_borel = metric_space +
  1902   assumes bounded_imp_convergent_subsequence:
  1903     "bounded s \<Longrightarrow> \<forall>n. f n \<in> s
  1904       \<Longrightarrow> \<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  1905 
  1906 lemma bounded_closed_imp_compact:
  1907   fixes s::"'a::heine_borel set"
  1908   assumes "bounded s" and "closed s" shows "compact s"
  1909 proof (unfold compact_def, clarify)
  1910   fix f :: "nat \<Rightarrow> 'a" assume f: "\<forall>n. f n \<in> s"
  1911   obtain l r where r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  1912     using bounded_imp_convergent_subsequence [OF `bounded s` `\<forall>n. f n \<in> s`] by auto
  1913   from f have fr: "\<forall>n. (f \<circ> r) n \<in> s" by simp
  1914   have "l \<in> s" using `closed s` fr l
  1915     unfolding closed_sequential_limits by blast
  1916   show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  1917     using `l \<in> s` r l by blast
  1918 qed
  1919 
  1920 lemma subseq_bigger: assumes "subseq r" shows "n \<le> r n"
  1921 proof(induct n)
  1922   show "0 \<le> r 0" by auto
  1923 next
  1924   fix n assume "n \<le> r n"
  1925   moreover have "r n < r (Suc n)"
  1926     using assms [unfolded subseq_def] by auto
  1927   ultimately show "Suc n \<le> r (Suc n)" by auto
  1928 qed
  1929 
  1930 lemma eventually_subseq:
  1931   assumes r: "subseq r"
  1932   shows "eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1933 unfolding eventually_sequentially
  1934 by (metis subseq_bigger [OF r] le_trans)
  1935 
  1936 lemma lim_subseq:
  1937   "subseq r \<Longrightarrow> (s ---> l) sequentially \<Longrightarrow> ((s o r) ---> l) sequentially"
  1938 unfolding tendsto_def eventually_sequentially o_def
  1939 by (metis subseq_bigger le_trans)
  1940 
  1941 lemma num_Axiom: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
  1942   unfolding Ex1_def
  1943   apply (rule_tac x="nat_rec e f" in exI)
  1944   apply (rule conjI)+
  1945 apply (rule def_nat_rec_0, simp)
  1946 apply (rule allI, rule def_nat_rec_Suc, simp)
  1947 apply (rule allI, rule impI, rule ext)
  1948 apply (erule conjE)
  1949 apply (induct_tac x)
  1950 apply simp
  1951 apply (erule_tac x="n" in allE)
  1952 apply (simp)
  1953 done
  1954 
  1955 lemma convergent_bounded_increasing: fixes s ::"nat\<Rightarrow>real"
  1956   assumes "incseq s" and "\<forall>n. abs(s n) \<le> b"
  1957   shows "\<exists> l. \<forall>e::real>0. \<exists> N. \<forall>n \<ge> N.  abs(s n - l) < e"
  1958 proof-
  1959   have "isUb UNIV (range s) b" using assms(2) and abs_le_D1 unfolding isUb_def and setle_def by auto
  1960   then obtain t where t:"isLub UNIV (range s) t" using reals_complete[of "range s" ] by auto
  1961   { fix e::real assume "e>0" and as:"\<forall>N. \<exists>n\<ge>N. \<not> \<bar>s n - t\<bar> < e"
  1962     { fix n::nat
  1963       obtain N where "N\<ge>n" and n:"\<bar>s N - t\<bar> \<ge> e" using as[THEN spec[where x=n]] by auto
  1964       have "t \<ge> s N" using isLub_isUb[OF t, unfolded isUb_def setle_def] by auto
  1965       with n have "s N \<le> t - e" using `e>0` by auto
  1966       hence "s n \<le> t - e" using assms(1)[unfolded incseq_def, THEN spec[where x=n], THEN spec[where x=N]] using `n\<le>N` by auto  }
  1967     hence "isUb UNIV (range s) (t - e)" unfolding isUb_def and setle_def by auto
  1968     hence False using isLub_le_isUb[OF t, of "t - e"] and `e>0` by auto  }
  1969   thus ?thesis by blast
  1970 qed
  1971 
  1972 lemma convergent_bounded_monotone: fixes s::"nat \<Rightarrow> real"
  1973   assumes "\<forall>n. abs(s n) \<le> b" and "monoseq s"
  1974   shows "\<exists>l. \<forall>e::real>0. \<exists>N. \<forall>n\<ge>N. abs(s n - l) < e"
  1975   using convergent_bounded_increasing[of s b] assms using convergent_bounded_increasing[of "\<lambda>n. - s n" b]
  1976   unfolding monoseq_def incseq_def
  1977   apply auto unfolding minus_add_distrib[THEN sym, unfolded diff_minus[THEN sym]]
  1978   unfolding abs_minus_cancel by(rule_tac x="-l" in exI)auto
  1979 
  1980 (* TODO: merge this lemma with the ones above *)
  1981 lemma bounded_increasing_convergent: fixes s::"nat \<Rightarrow> real"
  1982   assumes "bounded {s n| n::nat. True}"  "\<forall>n. (s n) \<le>(s(Suc n))"
  1983   shows "\<exists>l. (s ---> l) sequentially"
  1984 proof-
  1985   obtain a where a:"\<forall>n. \<bar> (s n)\<bar> \<le>  a" using assms(1)[unfolded bounded_iff] by auto
  1986   { fix m::nat
  1987     have "\<And> n. n\<ge>m \<longrightarrow>  (s m) \<le> (s n)"
  1988       apply(induct_tac n) apply simp using assms(2) apply(erule_tac x="na" in allE)
  1989       apply(case_tac "m \<le> na") unfolding not_less_eq_eq by(auto simp add: not_less_eq_eq)  }
  1990   hence "\<forall>m n. m \<le> n \<longrightarrow> (s m) \<le> (s n)" by auto
  1991   then obtain l where "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<bar> (s n) - l\<bar> < e" using convergent_bounded_monotone[OF a]
  1992     unfolding monoseq_def by auto
  1993   thus ?thesis unfolding Lim_sequentially apply(rule_tac x="l" in exI)
  1994     unfolding dist_norm  by auto
  1995 qed
  1996 
  1997 lemma compact_real_lemma:
  1998   assumes "\<forall>n::nat. abs(s n) \<le> b"
  1999   shows "\<exists>(l::real) r. subseq r \<and> ((s \<circ> r) ---> l) sequentially"
  2000 proof-
  2001   obtain r where r:"subseq r" "monoseq (\<lambda>n. s (r n))"
  2002     using seq_monosub[of s] by auto
  2003   thus ?thesis using convergent_bounded_monotone[of "\<lambda>n. s (r n)" b] and assms
  2004     unfolding tendsto_iff dist_norm eventually_sequentially by auto
  2005 qed
  2006 
  2007 instance real :: heine_borel
  2008 proof
  2009   fix s :: "real set" and f :: "nat \<Rightarrow> real"
  2010   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2011   then obtain b where b: "\<forall>n. abs (f n) \<le> b"
  2012     unfolding bounded_iff by auto
  2013   obtain l :: real and r :: "nat \<Rightarrow> nat" where
  2014     r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  2015     using compact_real_lemma [OF b] by auto
  2016   thus "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2017     by auto
  2018 qed
  2019 
  2020 lemma bounded_component: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $$ i) ` s)"
  2021   apply (erule bounded_linear_image)
  2022   apply (rule bounded_linear_euclidean_component)
  2023   done
  2024 
  2025 lemma compact_lemma:
  2026   fixes f :: "nat \<Rightarrow> 'a::euclidean_space"
  2027   assumes "bounded s" and "\<forall>n. f n \<in> s"
  2028   shows "\<forall>d. \<exists>l::'a. \<exists> r. subseq r \<and>
  2029         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2030 proof
  2031   fix d'::"nat set" def d \<equiv> "d' \<inter> {..<DIM('a)}"
  2032   have "finite d" "d\<subseteq>{..<DIM('a)}" unfolding d_def by auto
  2033   hence "\<exists>l::'a. \<exists>r. subseq r \<and>
  2034       (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2035   proof(induct d) case empty thus ?case unfolding subseq_def by auto
  2036   next case (insert k d) have k[intro]:"k<DIM('a)" using insert by auto
  2037     have s': "bounded ((\<lambda>x. x $$ k) ` s)" using `bounded s` by (rule bounded_component)
  2038     obtain l1::"'a" and r1 where r1:"subseq r1" and
  2039       lr1:"\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $$ i) (l1 $$ i) < e) sequentially"
  2040       using insert(3) using insert(4) by auto
  2041     have f': "\<forall>n. f (r1 n) $$ k \<in> (\<lambda>x. x $$ k) ` s" using `\<forall>n. f n \<in> s` by simp
  2042     obtain l2 r2 where r2:"subseq r2" and lr2:"((\<lambda>i. f (r1 (r2 i)) $$ k) ---> l2) sequentially"
  2043       using bounded_imp_convergent_subsequence[OF s' f'] unfolding o_def by auto
  2044     def r \<equiv> "r1 \<circ> r2" have r:"subseq r"
  2045       using r1 and r2 unfolding r_def o_def subseq_def by auto
  2046     moreover
  2047     def l \<equiv> "(\<chi>\<chi> i. if i = k then l2 else l1$$i)::'a"
  2048     { fix e::real assume "e>0"
  2049       from lr1 `e>0` have N1:"eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $$ i) (l1 $$ i) < e) sequentially" by blast
  2050       from lr2 `e>0` have N2:"eventually (\<lambda>n. dist (f (r1 (r2 n)) $$ k) l2 < e) sequentially" by (rule tendstoD)
  2051       from r2 N1 have N1': "eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 (r2 n)) $$ i) (l1 $$ i) < e) sequentially"
  2052         by (rule eventually_subseq)
  2053       have "eventually (\<lambda>n. \<forall>i\<in>(insert k d). dist (f (r n) $$ i) (l $$ i) < e) sequentially"
  2054         using N1' N2 apply(rule eventually_elim2) unfolding l_def r_def o_def
  2055         using insert.prems by auto
  2056     }
  2057     ultimately show ?case by auto
  2058   qed
  2059   thus "\<exists>l::'a. \<exists>r. subseq r \<and>
  2060       (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d'. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2061     apply safe apply(rule_tac x=l in exI,rule_tac x=r in exI) apply safe
  2062     apply(erule_tac x=e in allE) unfolding d_def eventually_sequentially apply safe 
  2063     apply(rule_tac x=N in exI) apply safe apply(erule_tac x=n in allE,safe)
  2064     apply(erule_tac x=i in ballE) 
  2065   proof- fix i and r::"nat=>nat" and n::nat and e::real and l::'a
  2066     assume "i\<in>d'" "i \<notin> d' \<inter> {..<DIM('a)}" and e:"e>0"
  2067     hence *:"i\<ge>DIM('a)" by auto
  2068     thus "dist (f (r n) $$ i) (l $$ i) < e" using e by auto
  2069   qed
  2070 qed
  2071 
  2072 instance euclidean_space \<subseteq> heine_borel
  2073 proof
  2074   fix s :: "'a set" and f :: "nat \<Rightarrow> 'a"
  2075   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2076   then obtain l::'a and r where r: "subseq r"
  2077     and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $$ i) (l $$ i) < e) sequentially"
  2078     using compact_lemma [OF s f] by blast
  2079   let ?d = "{..<DIM('a)}"
  2080   { fix e::real assume "e>0"
  2081     hence "0 < e / (real_of_nat (card ?d))"
  2082       using DIM_positive using divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
  2083     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $$ i) (l $$ i) < e / (real_of_nat (card ?d))) sequentially"
  2084       by simp
  2085     moreover
  2086     { fix n assume n: "\<forall>i. dist (f (r n) $$ i) (l $$ i) < e / (real_of_nat (card ?d))"
  2087       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $$ i) (l $$ i))"
  2088         apply(subst euclidean_dist_l2) using zero_le_dist by (rule setL2_le_setsum)
  2089       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
  2090         apply(rule setsum_strict_mono) using n by auto
  2091       finally have "dist (f (r n)) l < e" unfolding setsum_constant
  2092         using DIM_positive[where 'a='a] by auto
  2093     }
  2094     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  2095       by (rule eventually_elim1)
  2096   }
  2097   hence *:"((f \<circ> r) ---> l) sequentially" unfolding o_def tendsto_iff by simp
  2098   with r show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" by auto
  2099 qed
  2100 
  2101 lemma bounded_fst: "bounded s \<Longrightarrow> bounded (fst ` s)"
  2102 unfolding bounded_def
  2103 apply clarify
  2104 apply (rule_tac x="a" in exI)
  2105 apply (rule_tac x="e" in exI)
  2106 apply clarsimp
  2107 apply (drule (1) bspec)
  2108 apply (simp add: dist_Pair_Pair)
  2109 apply (erule order_trans [OF real_sqrt_sum_squares_ge1])
  2110 done
  2111 
  2112 lemma bounded_snd: "bounded s \<Longrightarrow> bounded (snd ` s)"
  2113 unfolding bounded_def
  2114 apply clarify
  2115 apply (rule_tac x="b" in exI)
  2116 apply (rule_tac x="e" in exI)
  2117 apply clarsimp
  2118 apply (drule (1) bspec)
  2119 apply (simp add: dist_Pair_Pair)
  2120 apply (erule order_trans [OF real_sqrt_sum_squares_ge2])
  2121 done
  2122 
  2123 instance prod :: (heine_borel, heine_borel) heine_borel
  2124 proof
  2125   fix s :: "('a * 'b) set" and f :: "nat \<Rightarrow> 'a * 'b"
  2126   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2127   from s have s1: "bounded (fst ` s)" by (rule bounded_fst)
  2128   from f have f1: "\<forall>n. fst (f n) \<in> fst ` s" by simp
  2129   obtain l1 r1 where r1: "subseq r1"
  2130     and l1: "((\<lambda>n. fst (f (r1 n))) ---> l1) sequentially"
  2131     using bounded_imp_convergent_subsequence [OF s1 f1]
  2132     unfolding o_def by fast
  2133   from s have s2: "bounded (snd ` s)" by (rule bounded_snd)
  2134   from f have f2: "\<forall>n. snd (f (r1 n)) \<in> snd ` s" by simp
  2135   obtain l2 r2 where r2: "subseq r2"
  2136     and l2: "((\<lambda>n. snd (f (r1 (r2 n)))) ---> l2) sequentially"
  2137     using bounded_imp_convergent_subsequence [OF s2 f2]
  2138     unfolding o_def by fast
  2139   have l1': "((\<lambda>n. fst (f (r1 (r2 n)))) ---> l1) sequentially"
  2140     using lim_subseq [OF r2 l1] unfolding o_def .
  2141   have l: "((f \<circ> (r1 \<circ> r2)) ---> (l1, l2)) sequentially"
  2142     using tendsto_Pair [OF l1' l2] unfolding o_def by simp
  2143   have r: "subseq (r1 \<circ> r2)"
  2144     using r1 r2 unfolding subseq_def by simp
  2145   show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2146     using l r by fast
  2147 qed
  2148 
  2149 subsubsection{* Completeness *}
  2150 
  2151 lemma cauchy_def:
  2152   "Cauchy s \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m n. m \<ge> N \<and> n \<ge> N --> dist(s m)(s n) < e)"
  2153 unfolding Cauchy_def by blast
  2154 
  2155 definition
  2156   complete :: "'a::metric_space set \<Rightarrow> bool" where
  2157   "complete s \<longleftrightarrow> (\<forall>f. (\<forall>n. f n \<in> s) \<and> Cauchy f
  2158                       --> (\<exists>l \<in> s. (f ---> l) sequentially))"
  2159 
  2160 lemma cauchy: "Cauchy s \<longleftrightarrow> (\<forall>e>0.\<exists> N::nat. \<forall>n\<ge>N. dist(s n)(s N) < e)" (is "?lhs = ?rhs")
  2161 proof-
  2162   { assume ?rhs
  2163     { fix e::real
  2164       assume "e>0"
  2165       with `?rhs` obtain N where N:"\<forall>n\<ge>N. dist (s n) (s N) < e/2"
  2166         by (erule_tac x="e/2" in allE) auto
  2167       { fix n m
  2168         assume nm:"N \<le> m \<and> N \<le> n"
  2169         hence "dist (s m) (s n) < e" using N
  2170           using dist_triangle_half_l[of "s m" "s N" "e" "s n"]
  2171           by blast
  2172       }
  2173       hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"
  2174         by blast
  2175     }
  2176     hence ?lhs
  2177       unfolding cauchy_def
  2178       by blast
  2179   }
  2180   thus ?thesis
  2181     unfolding cauchy_def
  2182     using dist_triangle_half_l
  2183     by blast
  2184 qed
  2185 
  2186 lemma convergent_imp_cauchy:
  2187  "(s ---> l) sequentially ==> Cauchy s"
  2188 proof(simp only: cauchy_def, rule, rule)
  2189   fix e::real assume "e>0" "(s ---> l) sequentially"
  2190   then obtain N::nat where N:"\<forall>n\<ge>N. dist (s n) l < e/2" unfolding Lim_sequentially by(erule_tac x="e/2" in allE) auto
  2191   thus "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"  using dist_triangle_half_l[of _ l e _] by (rule_tac x=N in exI) auto
  2192 qed
  2193 
  2194 lemma cauchy_imp_bounded: assumes "Cauchy s" shows "bounded (range s)"
  2195 proof-
  2196   from assms obtain N::nat where "\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < 1" unfolding cauchy_def apply(erule_tac x= 1 in allE) by auto
  2197   hence N:"\<forall>n. N \<le> n \<longrightarrow> dist (s N) (s n) < 1" by auto
  2198   moreover
  2199   have "bounded (s ` {0..N})" using finite_imp_bounded[of "s ` {1..N}"] by auto
  2200   then obtain a where a:"\<forall>x\<in>s ` {0..N}. dist (s N) x \<le> a"
  2201     unfolding bounded_any_center [where a="s N"] by auto
  2202   ultimately show "?thesis"
  2203     unfolding bounded_any_center [where a="s N"]
  2204     apply(rule_tac x="max a 1" in exI) apply auto
  2205     apply(erule_tac x=y in allE) apply(erule_tac x=y in ballE) by auto
  2206 qed
  2207 
  2208 lemma compact_imp_complete: assumes "compact s" shows "complete s"
  2209 proof-
  2210   { fix f assume as: "(\<forall>n::nat. f n \<in> s)" "Cauchy f"
  2211     from as(1) obtain l r where lr: "l\<in>s" "subseq r" "((f \<circ> r) ---> l) sequentially" using assms unfolding compact_def by blast
  2212 
  2213     note lr' = subseq_bigger [OF lr(2)]
  2214 
  2215     { fix e::real assume "e>0"
  2216       from as(2) obtain N where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (f m) (f n) < e/2" unfolding cauchy_def using `e>0` apply (erule_tac x="e/2" in allE) by auto
  2217       from lr(3)[unfolded Lim_sequentially, THEN spec[where x="e/2"]] obtain M where M:"\<forall>n\<ge>M. dist ((f \<circ> r) n) l < e/2" using `e>0` by auto
  2218       { fix n::nat assume n:"n \<ge> max N M"
  2219         have "dist ((f \<circ> r) n) l < e/2" using n M by auto
  2220         moreover have "r n \<ge> N" using lr'[of n] n by auto
  2221         hence "dist (f n) ((f \<circ> r) n) < e / 2" using N using n by auto
  2222         ultimately have "dist (f n) l < e" using dist_triangle_half_r[of "f (r n)" "f n" e l] by (auto simp add: dist_commute)  }
  2223       hence "\<exists>N. \<forall>n\<ge>N. dist (f n) l < e" by blast  }
  2224     hence "\<exists>l\<in>s. (f ---> l) sequentially" using `l\<in>s` unfolding Lim_sequentially by auto  }
  2225   thus ?thesis unfolding complete_def by auto
  2226 qed
  2227 
  2228 instance heine_borel < complete_space
  2229 proof
  2230   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  2231   hence "bounded (range f)"
  2232     by (rule cauchy_imp_bounded)
  2233   hence "compact (closure (range f))"
  2234     using bounded_closed_imp_compact [of "closure (range f)"] by auto
  2235   hence "complete (closure (range f))"
  2236     by (rule compact_imp_complete)
  2237   moreover have "\<forall>n. f n \<in> closure (range f)"
  2238     using closure_subset [of "range f"] by auto
  2239   ultimately have "\<exists>l\<in>closure (range f). (f ---> l) sequentially"
  2240     using `Cauchy f` unfolding complete_def by auto
  2241   then show "convergent f"
  2242     unfolding convergent_def by auto
  2243 qed
  2244 
  2245 lemma complete_univ: "complete (UNIV :: 'a::complete_space set)"
  2246 proof(simp add: complete_def, rule, rule)
  2247   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  2248   hence "convergent f" by (rule Cauchy_convergent)
  2249   thus "\<exists>l. f ----> l" unfolding convergent_def .  
  2250 qed
  2251 
  2252 lemma complete_imp_closed: assumes "complete s" shows "closed s"
  2253 proof -
  2254   { fix x assume "x islimpt s"
  2255     then obtain f where f: "\<forall>n. f n \<in> s - {x}" "(f ---> x) sequentially"
  2256       unfolding islimpt_sequential by auto
  2257     then obtain l where l: "l\<in>s" "(f ---> l) sequentially"
  2258       using `complete s`[unfolded complete_def] using convergent_imp_cauchy[of f x] by auto
  2259     hence "x \<in> s"  using tendsto_unique[of sequentially f l x] trivial_limit_sequentially f(2) by auto
  2260   }
  2261   thus "closed s" unfolding closed_limpt by auto
  2262 qed
  2263 
  2264 lemma complete_eq_closed:
  2265   fixes s :: "'a::complete_space set"
  2266   shows "complete s \<longleftrightarrow> closed s" (is "?lhs = ?rhs")
  2267 proof
  2268   assume ?lhs thus ?rhs by (rule complete_imp_closed)
  2269 next
  2270   assume ?rhs
  2271   { fix f assume as:"\<forall>n::nat. f n \<in> s" "Cauchy f"
  2272     then obtain l where "(f ---> l) sequentially" using complete_univ[unfolded complete_def, THEN spec[where x=f]] by auto
  2273     hence "\<exists>l\<in>s. (f ---> l) sequentially" using `?rhs`[unfolded closed_sequential_limits, THEN spec[where x=f], THEN spec[where x=l]] using as(1) by auto  }
  2274   thus ?lhs unfolding complete_def by auto
  2275 qed
  2276 
  2277 lemma convergent_eq_cauchy:
  2278   fixes s :: "nat \<Rightarrow> 'a::complete_space"
  2279   shows "(\<exists>l. (s ---> l) sequentially) \<longleftrightarrow> Cauchy s" (is "?lhs = ?rhs")
  2280 proof
  2281   assume ?lhs then obtain l where "(s ---> l) sequentially" by auto
  2282   thus ?rhs using convergent_imp_cauchy by auto
  2283 next
  2284   assume ?rhs thus ?lhs using complete_univ[unfolded complete_def, THEN spec[where x=s]] by auto
  2285 qed
  2286 
  2287 lemma convergent_imp_bounded:
  2288   fixes s :: "nat \<Rightarrow> 'a::metric_space"
  2289   shows "(s ---> l) sequentially ==> bounded (s ` (UNIV::(nat set)))"
  2290   using convergent_imp_cauchy[of s]
  2291   using cauchy_imp_bounded[of s]
  2292   unfolding image_def
  2293   by auto
  2294 
  2295 subsubsection{* Total boundedness *}
  2296 
  2297 fun helper_1::"('a::metric_space set) \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> 'a" where
  2298   "helper_1 s e n = (SOME y::'a. y \<in> s \<and> (\<forall>m<n. \<not> (dist (helper_1 s e m) y < e)))"
  2299 declare helper_1.simps[simp del]
  2300 
  2301 lemma compact_imp_totally_bounded:
  2302   assumes "compact s"
  2303   shows "\<forall>e>0. \<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> (\<Union>((\<lambda>x. ball x e) ` k))"
  2304 proof(rule, rule, rule ccontr)
  2305   fix e::real assume "e>0" and assm:"\<not> (\<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k)"
  2306   def x \<equiv> "helper_1 s e"
  2307   { fix n
  2308     have "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)"
  2309     proof(induct_tac rule:nat_less_induct)
  2310       fix n  def Q \<equiv> "(\<lambda>y. y \<in> s \<and> (\<forall>m<n. \<not> dist (x m) y < e))"
  2311       assume as:"\<forall>m<n. x m \<in> s \<and> (\<forall>ma<m. \<not> dist (x ma) (x m) < e)"
  2312       have "\<not> s \<subseteq> (\<Union>x\<in>x ` {0..<n}. ball x e)" using assm apply simp apply(erule_tac x="x ` {0 ..< n}" in allE) using as by auto
  2313       then obtain z where z:"z\<in>s" "z \<notin> (\<Union>x\<in>x ` {0..<n}. ball x e)" unfolding subset_eq by auto
  2314       have "Q (x n)" unfolding x_def and helper_1.simps[of s e n]
  2315         apply(rule someI2[where a=z]) unfolding x_def[symmetric] and Q_def using z by auto
  2316       thus "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)" unfolding Q_def by auto
  2317     qed }
  2318   hence "\<forall>n::nat. x n \<in> s" and x:"\<forall>n. \<forall>m < n. \<not> (dist (x m) (x n) < e)" by blast+
  2319   then obtain l r where "l\<in>s" and r:"subseq r" and "((x \<circ> r) ---> l) sequentially" using assms(1)[unfolded compact_def, THEN spec[where x=x]] by auto
  2320   from this(3) have "Cauchy (x \<circ> r)" using convergent_imp_cauchy by auto
  2321   then obtain N::nat where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist ((x \<circ> r) m) ((x \<circ> r) n) < e" unfolding cauchy_def using `e>0` by auto
  2322   show False
  2323     using N[THEN spec[where x=N], THEN spec[where x="N+1"]]
  2324     using r[unfolded subseq_def, THEN spec[where x=N], THEN spec[where x="N+1"]]
  2325     using x[THEN spec[where x="r (N+1)"], THEN spec[where x="r (N)"]] by auto
  2326 qed
  2327 
  2328 subsubsection{* Heine-Borel theorem *}
  2329 
  2330 text {* Following Burkill \& Burkill vol. 2. *}
  2331 
  2332 lemma heine_borel_lemma: fixes s::"'a::metric_space set"
  2333   assumes "compact s"  "s \<subseteq> (\<Union> t)"  "\<forall>b \<in> t. open b"
  2334   shows "\<exists>e>0. \<forall>x \<in> s. \<exists>b \<in> t. ball x e \<subseteq> b"
  2335 proof(rule ccontr)
  2336   assume "\<not> (\<exists>e>0. \<forall>x\<in>s. \<exists>b\<in>t. ball x e \<subseteq> b)"
  2337   hence cont:"\<forall>e>0. \<exists>x\<in>s. \<forall>xa\<in>t. \<not> (ball x e \<subseteq> xa)" by auto
  2338   { fix n::nat
  2339     have "1 / real (n + 1) > 0" by auto
  2340     hence "\<exists>x. x\<in>s \<and> (\<forall>xa\<in>t. \<not> (ball x (inverse (real (n+1))) \<subseteq> xa))" using cont unfolding Bex_def by auto }
  2341   hence "\<forall>n::nat. \<exists>x. x \<in> s \<and> (\<forall>xa\<in>t. \<not> ball x (inverse (real (n + 1))) \<subseteq> xa)" by auto
  2342   then obtain f where f:"\<forall>n::nat. f n \<in> s \<and> (\<forall>xa\<in>t. \<not> ball (f n) (inverse (real (n + 1))) \<subseteq> xa)"
  2343     using choice[of "\<lambda>n::nat. \<lambda>x. x\<in>s \<and> (\<forall>xa\<in>t. \<not> ball x (inverse (real (n + 1))) \<subseteq> xa)"] by auto
  2344 
  2345   then obtain l r where l:"l\<in>s" and r:"subseq r" and lr:"((f \<circ> r) ---> l) sequentially"
  2346     using assms(1)[unfolded compact_def, THEN spec[where x=f]] by auto
  2347 
  2348   obtain b where "l\<in>b" "b\<in>t" using assms(2) and l by auto
  2349   then obtain e where "e>0" and e:"\<forall>z. dist z l < e \<longrightarrow> z\<in>b"
  2350     using assms(3)[THEN bspec[where x=b]] unfolding open_dist by auto
  2351 
  2352   then obtain N1 where N1:"\<forall>n\<ge>N1. dist ((f \<circ> r) n) l < e / 2"
  2353     using lr[unfolded Lim_sequentially, THEN spec[where x="e/2"]] by auto
  2354 
  2355   obtain N2::nat where N2:"N2>0" "inverse (real N2) < e /2" using real_arch_inv[of "e/2"] and `e>0` by auto
  2356   have N2':"inverse (real (r (N1 + N2) +1 )) < e/2"
  2357     apply(rule order_less_trans) apply(rule less_imp_inverse_less) using N2
  2358     using subseq_bigger[OF r, of "N1 + N2"] by auto
  2359 
  2360   def x \<equiv> "(f (r (N1 + N2)))"
  2361   have x:"\<not> ball x (inverse (real (r (N1 + N2) + 1))) \<subseteq> b" unfolding x_def
  2362     using f[THEN spec[where x="r (N1 + N2)"]] using `b\<in>t` by auto
  2363   have "\<exists>y\<in>ball x (inverse (real (r (N1 + N2) + 1))). y\<notin>b" apply(rule ccontr) using x by auto
  2364   then obtain y where y:"y \<in> ball x (inverse (real (r (N1 + N2) + 1)))" "y \<notin> b" by auto
  2365 
  2366   have "dist x l < e/2" using N1 unfolding x_def o_def by auto
  2367   hence "dist y l < e" using y N2' using dist_triangle[of y l x]by (auto simp add:dist_commute)
  2368 
  2369   thus False using e and `y\<notin>b` by auto
  2370 qed
  2371 
  2372 lemma compact_imp_heine_borel: "compact s ==> (\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f)
  2373                \<longrightarrow> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f')))"
  2374 proof clarify
  2375   fix f assume "compact s" " \<forall>t\<in>f. open t" "s \<subseteq> \<Union>f"
  2376   then obtain e::real where "e>0" and "\<forall>x\<in>s. \<exists>b\<in>f. ball x e \<subseteq> b" using heine_borel_lemma[of s f] by auto
  2377   hence "\<forall>x\<in>s. \<exists>b. b\<in>f \<and> ball x e \<subseteq> b" by auto
  2378   hence "\<exists>bb. \<forall>x\<in>s. bb x \<in>f \<and> ball x e \<subseteq> bb x" using bchoice[of s "\<lambda>x b. b\<in>f \<and> ball x e \<subseteq> b"] by auto
  2379   then obtain  bb where bb:"\<forall>x\<in>s. (bb x) \<in> f \<and> ball x e \<subseteq> (bb x)" by blast
  2380 
  2381   from `compact s` have  "\<exists> k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k" using compact_imp_totally_bounded[of s] `e>0` by auto
  2382   then obtain k where k:"finite k" "k \<subseteq> s" "s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k" by auto
  2383 
  2384   have "finite (bb ` k)" using k(1) by auto
  2385   moreover
  2386   { fix x assume "x\<in>s"
  2387     hence "x\<in>\<Union>(\<lambda>x. ball x e) ` k" using k(3)  unfolding subset_eq by auto
  2388     hence "\<exists>X\<in>bb ` k. x \<in> X" using bb k(2) by blast
  2389     hence "x \<in> \<Union>(bb ` k)" using  Union_iff[of x "bb ` k"] by auto
  2390   }
  2391   ultimately show "\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f'" using bb k(2) by (rule_tac x="bb ` k" in exI) auto
  2392 qed
  2393 
  2394 subsubsection {* Bolzano-Weierstrass property *}
  2395 
  2396 lemma heine_borel_imp_bolzano_weierstrass:
  2397   assumes "\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f) --> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f'))"
  2398           "infinite t"  "t \<subseteq> s"
  2399   shows "\<exists>x \<in> s. x islimpt t"
  2400 proof(rule ccontr)
  2401   assume "\<not> (\<exists>x \<in> s. x islimpt t)"
  2402   then obtain f where f:"\<forall>x\<in>s. x \<in> f x \<and> open (f x) \<and> (\<forall>y\<in>t. y \<in> f x \<longrightarrow> y = x)" unfolding islimpt_def
  2403     using bchoice[of s "\<lambda> x T. x \<in> T \<and> open T \<and> (\<forall>y\<in>t. y \<in> T \<longrightarrow> y = x)"] by auto
  2404   obtain g where g:"g\<subseteq>{t. \<exists>x. x \<in> s \<and> t = f x}" "finite g" "s \<subseteq> \<Union>g"
  2405     using assms(1)[THEN spec[where x="{t. \<exists>x. x\<in>s \<and> t = f x}"]] using f by auto
  2406   from g(1,3) have g':"\<forall>x\<in>g. \<exists>xa \<in> s. x = f xa" by auto
  2407   { fix x y assume "x\<in>t" "y\<in>t" "f x = f y"
  2408     hence "x \<in> f x"  "y \<in> f x \<longrightarrow> y = x" using f[THEN bspec[where x=x]] and `t\<subseteq>s` by auto
  2409     hence "x = y" using `f x = f y` and f[THEN bspec[where x=y]] and `y\<in>t` and `t\<subseteq>s` by auto  }
  2410   hence "inj_on f t" unfolding inj_on_def by simp
  2411   hence "infinite (f ` t)" using assms(2) using finite_imageD by auto
  2412   moreover
  2413   { fix x assume "x\<in>t" "f x \<notin> g"
  2414     from g(3) assms(3) `x\<in>t` obtain h where "h\<in>g" and "x\<in>h" by auto
  2415     then obtain y where "y\<in>s" "h = f y" using g'[THEN bspec[where x=h]] by auto
  2416     hence "y = x" using f[THEN bspec[where x=y]] and `x\<in>t` and `x\<in>h`[unfolded `h = f y`] by auto
  2417     hence False using `f x \<notin> g` `h\<in>g` unfolding `h = f y` by auto  }
  2418   hence "f ` t \<subseteq> g" by auto
  2419   ultimately show False using g(2) using finite_subset by auto
  2420 qed
  2421 
  2422 subsubsection {* Complete the chain of compactness variants *}
  2423 
  2424 lemma islimpt_range_imp_convergent_subsequence:
  2425   fixes f :: "nat \<Rightarrow> 'a::metric_space"
  2426   assumes "l islimpt (range f)"
  2427   shows "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2428 proof (intro exI conjI)
  2429   have *: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. 0 < dist (f n) l \<and> dist (f n) l < e"
  2430     using assms unfolding islimpt_def
  2431     by (drule_tac x="ball l e" in spec)
  2432        (auto simp add: zero_less_dist_iff dist_commute)
  2433 
  2434   def t \<equiv> "\<lambda>e. LEAST n. 0 < dist (f n) l \<and> dist (f n) l < e"
  2435   have f_t_neq: "\<And>e. 0 < e \<Longrightarrow> 0 < dist (f (t e)) l"
  2436     unfolding t_def by (rule LeastI2_ex [OF * conjunct1])
  2437   have f_t_closer: "\<And>e. 0 < e \<Longrightarrow> dist (f (t e)) l < e"
  2438     unfolding t_def by (rule LeastI2_ex [OF * conjunct2])
  2439   have t_le: "\<And>n e. 0 < dist (f n) l \<Longrightarrow> dist (f n) l < e \<Longrightarrow> t e \<le> n"
  2440     unfolding t_def by (simp add: Least_le)
  2441   have less_tD: "\<And>n e. n < t e \<Longrightarrow> 0 < dist (f n) l \<Longrightarrow> e \<le> dist (f n) l"
  2442     unfolding t_def by (drule not_less_Least) simp
  2443   have t_antimono: "\<And>e e'. 0 < e \<Longrightarrow> e \<le> e' \<Longrightarrow> t e' \<le> t e"
  2444     apply (rule t_le)
  2445     apply (erule f_t_neq)
  2446     apply (erule (1) less_le_trans [OF f_t_closer])
  2447     done
  2448   have t_dist_f_neq: "\<And>n. 0 < dist (f n) l \<Longrightarrow> t (dist (f n) l) \<noteq> n"
  2449     by (drule f_t_closer) auto
  2450   have t_less: "\<And>e. 0 < e \<Longrightarrow> t e < t (dist (f (t e)) l)"
  2451     apply (subst less_le)
  2452     apply (rule conjI)
  2453     apply (rule t_antimono)
  2454     apply (erule f_t_neq)
  2455     apply (erule f_t_closer [THEN less_imp_le])
  2456     apply (rule t_dist_f_neq [symmetric])
  2457     apply (erule f_t_neq)
  2458     done
  2459   have dist_f_t_less':
  2460     "\<And>e e'. 0 < e \<Longrightarrow> 0 < e' \<Longrightarrow> t e \<le> t e' \<Longrightarrow> dist (f (t e')) l < e"
  2461     apply (simp add: le_less)
  2462     apply (erule disjE)
  2463     apply (rule less_trans)
  2464     apply (erule f_t_closer)
  2465     apply (rule le_less_trans)
  2466     apply (erule less_tD)
  2467     apply (erule f_t_neq)
  2468     apply (erule f_t_closer)
  2469     apply (erule subst)
  2470     apply (erule f_t_closer)
  2471     done
  2472 
  2473   def r \<equiv> "nat_rec (t 1) (\<lambda>_ x. t (dist (f x) l))"
  2474   have r_simps: "r 0 = t 1" "\<And>n. r (Suc n) = t (dist (f (r n)) l)"
  2475     unfolding r_def by simp_all
  2476   have f_r_neq: "\<And>n. 0 < dist (f (r n)) l"
  2477     by (induct_tac n) (simp_all add: r_simps f_t_neq)
  2478 
  2479   show "subseq r"
  2480     unfolding subseq_Suc_iff
  2481     apply (rule allI)
  2482     apply (case_tac n)
  2483     apply (simp_all add: r_simps)
  2484     apply (rule t_less, rule zero_less_one)
  2485     apply (rule t_less, rule f_r_neq)
  2486     done
  2487   show "((f \<circ> r) ---> l) sequentially"
  2488     unfolding Lim_sequentially o_def
  2489     apply (clarify, rule_tac x="t e" in exI, clarify)
  2490     apply (drule le_trans, rule seq_suble [OF `subseq r`])
  2491     apply (case_tac n, simp_all add: r_simps dist_f_t_less' f_r_neq)
  2492     done
  2493 qed
  2494 
  2495 lemma finite_range_imp_infinite_repeats:
  2496   fixes f :: "nat \<Rightarrow> 'a"
  2497   assumes "finite (range f)"
  2498   shows "\<exists>k. infinite {n. f n = k}"
  2499 proof -
  2500   { fix A :: "'a set" assume "finite A"
  2501     hence "\<And>f. infinite {n. f n \<in> A} \<Longrightarrow> \<exists>k. infinite {n. f n = k}"
  2502     proof (induct)
  2503       case empty thus ?case by simp
  2504     next
  2505       case (insert x A)
  2506      show ?case
  2507       proof (cases "finite {n. f n = x}")
  2508         case True
  2509         with `infinite {n. f n \<in> insert x A}`
  2510         have "infinite {n. f n \<in> A}" by simp
  2511         thus "\<exists>k. infinite {n. f n = k}" by (rule insert)
  2512       next
  2513         case False thus "\<exists>k. infinite {n. f n = k}" ..
  2514       qed
  2515     qed
  2516   } note H = this
  2517   from assms show "\<exists>k. infinite {n. f n = k}"
  2518     by (rule H) simp
  2519 qed
  2520 
  2521 lemma bolzano_weierstrass_imp_compact:
  2522   fixes s :: "'a::metric_space set"
  2523   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2524   shows "compact s"
  2525 proof -
  2526   { fix f :: "nat \<Rightarrow> 'a" assume f: "\<forall>n. f n \<in> s"
  2527     have "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2528     proof (cases "finite (range f)")
  2529       case True
  2530       hence "\<exists>l. infinite {n. f n = l}"
  2531         by (rule finite_range_imp_infinite_repeats)
  2532       then obtain l where "infinite {n. f n = l}" ..
  2533       hence "\<exists>r. subseq r \<and> (\<forall>n. r n \<in> {n. f n = l})"
  2534         by (rule infinite_enumerate)
  2535       then obtain r where "subseq r" and fr: "\<forall>n. f (r n) = l" by auto
  2536       hence "subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2537         unfolding o_def by (simp add: fr tendsto_const)
  2538       hence "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2539         by - (rule exI)
  2540       from f have "\<forall>n. f (r n) \<in> s" by simp
  2541       hence "l \<in> s" by (simp add: fr)
  2542       thus "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2543         by (rule rev_bexI) fact
  2544     next
  2545       case False
  2546       with f assms have "\<exists>x\<in>s. x islimpt (range f)" by auto
  2547       then obtain l where "l \<in> s" "l islimpt (range f)" ..
  2548       have "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2549         using `l islimpt (range f)`
  2550         by (rule islimpt_range_imp_convergent_subsequence)
  2551       with `l \<in> s` show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" ..
  2552     qed
  2553   }
  2554   thus ?thesis unfolding compact_def by auto
  2555 qed
  2556 
  2557 primrec helper_2::"(real \<Rightarrow> 'a::metric_space) \<Rightarrow> nat \<Rightarrow> 'a" where
  2558   "helper_2 beyond 0 = beyond 0" |
  2559   "helper_2 beyond (Suc n) = beyond (dist undefined (helper_2 beyond n) + 1 )"
  2560 
  2561 lemma bolzano_weierstrass_imp_bounded: fixes s::"'a::metric_space set"
  2562   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2563   shows "bounded s"
  2564 proof(rule ccontr)
  2565   assume "\<not> bounded s"
  2566   then obtain beyond where "\<forall>a. beyond a \<in>s \<and> \<not> dist undefined (beyond a) \<le> a"
  2567     unfolding bounded_any_center [where a=undefined]
  2568     apply simp using choice[of "\<lambda>a x. x\<in>s \<and> \<not> dist undefined x \<le> a"] by auto
  2569   hence beyond:"\<And>a. beyond a \<in>s" "\<And>a. dist undefined (beyond a) > a"
  2570     unfolding linorder_not_le by auto
  2571   def x \<equiv> "helper_2 beyond"
  2572 
  2573   { fix m n ::nat assume "m<n"
  2574     hence "dist undefined (x m) + 1 < dist undefined (x n)"
  2575     proof(induct n)
  2576       case 0 thus ?case by auto
  2577     next
  2578       case (Suc n)
  2579       have *:"dist undefined (x n) + 1 < dist undefined (x (Suc n))"
  2580         unfolding x_def and helper_2.simps
  2581         using beyond(2)[of "dist undefined (helper_2 beyond n) + 1"] by auto
  2582       thus ?case proof(cases "m < n")
  2583         case True thus ?thesis using Suc and * by auto
  2584       next
  2585         case False hence "m = n" using Suc(2) by auto
  2586         thus ?thesis using * by auto
  2587       qed
  2588     qed  } note * = this
  2589   { fix m n ::nat assume "m\<noteq>n"
  2590     have "1 < dist (x m) (x n)"
  2591     proof(cases "m<n")
  2592       case True
  2593       hence "1 < dist undefined (x n) - dist undefined (x m)" using *[of m n] by auto
  2594       thus ?thesis using dist_triangle [of undefined "x n" "x m"] by arith
  2595     next
  2596       case False hence "n<m" using `m\<noteq>n` by auto
  2597       hence "1 < dist undefined (x m) - dist undefined (x n)" using *[of n m] by auto
  2598       thus ?thesis using dist_triangle2 [of undefined "x m" "x n"] by arith
  2599     qed  } note ** = this
  2600   { fix a b assume "x a = x b" "a \<noteq> b"
  2601     hence False using **[of a b] by auto  }
  2602   hence "inj x" unfolding inj_on_def by auto
  2603   moreover
  2604   { fix n::nat
  2605     have "x n \<in> s"
  2606     proof(cases "n = 0")
  2607       case True thus ?thesis unfolding x_def using beyond by auto
  2608     next
  2609       case False then obtain z where "n = Suc z" using not0_implies_Suc by auto
  2610       thus ?thesis unfolding x_def using beyond by auto
  2611     qed  }
  2612   ultimately have "infinite (range x) \<and> range x \<subseteq> s" unfolding x_def using range_inj_infinite[of "helper_2 beyond"] using beyond(1) by auto
  2613 
  2614   then obtain l where "l\<in>s" and l:"l islimpt range x" using assms[THEN spec[where x="range x"]] by auto
  2615   then obtain y where "x y \<noteq> l" and y:"dist (x y) l < 1/2" unfolding islimpt_approachable apply(erule_tac x="1/2" in allE) by auto
  2616   then obtain z where "x z \<noteq> l" and z:"dist (x z) l < dist (x y) l" using l[unfolded islimpt_approachable, THEN spec[where x="dist (x y) l"]]
  2617     unfolding dist_nz by auto
  2618   show False using y and z and dist_triangle_half_l[of "x y" l 1 "x z"] and **[of y z] by auto
  2619 qed
  2620 
  2621 lemma sequence_infinite_lemma:
  2622   fixes f :: "nat \<Rightarrow> 'a::t1_space"
  2623   assumes "\<forall>n. f n \<noteq> l" and "(f ---> l) sequentially"
  2624   shows "infinite (range f)"
  2625 proof
  2626   assume "finite (range f)"
  2627   hence "closed (range f)" by (rule finite_imp_closed)
  2628   hence "open (- range f)" by (rule open_Compl)
  2629   from assms(1) have "l \<in> - range f" by auto
  2630   from assms(2) have "eventually (\<lambda>n. f n \<in> - range f) sequentially"
  2631     using `open (- range f)` `l \<in> - range f` by (rule topological_tendstoD)
  2632   thus False unfolding eventually_sequentially by auto
  2633 qed
  2634 
  2635 lemma closure_insert:
  2636   fixes x :: "'a::t1_space"
  2637   shows "closure (insert x s) = insert x (closure s)"
  2638 apply (rule closure_unique)
  2639 apply (rule insert_mono [OF closure_subset])
  2640 apply (rule closed_insert [OF closed_closure])
  2641 apply (simp add: closure_minimal)
  2642 done
  2643 
  2644 lemma islimpt_insert:
  2645   fixes x :: "'a::t1_space"
  2646   shows "x islimpt (insert a s) \<longleftrightarrow> x islimpt s"
  2647 proof
  2648   assume *: "x islimpt (insert a s)"
  2649   show "x islimpt s"
  2650   proof (rule islimptI)
  2651     fix t assume t: "x \<in> t" "open t"
  2652     show "\<exists>y\<in>s. y \<in> t \<and> y \<noteq> x"
  2653     proof (cases "x = a")
  2654       case True
  2655       obtain y where "y \<in> insert a s" "y \<in> t" "y \<noteq> x"
  2656         using * t by (rule islimptE)
  2657       with `x = a` show ?thesis by auto
  2658     next
  2659       case False
  2660       with t have t': "x \<in> t - {a}" "open (t - {a})"
  2661         by (simp_all add: open_Diff)
  2662       obtain y where "y \<in> insert a s" "y \<in> t - {a}" "y \<noteq> x"
  2663         using * t' by (rule islimptE)
  2664       thus ?thesis by auto
  2665     qed
  2666   qed
  2667 next
  2668   assume "x islimpt s" thus "x islimpt (insert a s)"
  2669     by (rule islimpt_subset) auto
  2670 qed
  2671 
  2672 lemma islimpt_union_finite:
  2673   fixes x :: "'a::t1_space"
  2674   shows "finite s \<Longrightarrow> x islimpt (s \<union> t) \<longleftrightarrow> x islimpt t"
  2675 by (induct set: finite, simp_all add: islimpt_insert)
  2676  
  2677 lemma sequence_unique_limpt:
  2678   fixes f :: "nat \<Rightarrow> 'a::t2_space"
  2679   assumes "(f ---> l) sequentially" and "l' islimpt (range f)"
  2680   shows "l' = l"
  2681 proof (rule ccontr)
  2682   assume "l' \<noteq> l"
  2683   obtain s t where "open s" "open t" "l' \<in> s" "l \<in> t" "s \<inter> t = {}"
  2684     using hausdorff [OF `l' \<noteq> l`] by auto
  2685   have "eventually (\<lambda>n. f n \<in> t) sequentially"
  2686     using assms(1) `open t` `l \<in> t` by (rule topological_tendstoD)
  2687   then obtain N where "\<forall>n\<ge>N. f n \<in> t"
  2688     unfolding eventually_sequentially by auto
  2689 
  2690   have "UNIV = {..<N} \<union> {N..}" by auto
  2691   hence "l' islimpt (f ` ({..<N} \<union> {N..}))" using assms(2) by simp
  2692   hence "l' islimpt (f ` {..<N} \<union> f ` {N..})" by (simp add: image_Un)
  2693   hence "l' islimpt (f ` {N..})" by (simp add: islimpt_union_finite)
  2694   then obtain y where "y \<in> f ` {N..}" "y \<in> s" "y \<noteq> l'"
  2695     using `l' \<in> s` `open s` by (rule islimptE)
  2696   then obtain n where "N \<le> n" "f n \<in> s" "f n \<noteq> l'" by auto
  2697   with `\<forall>n\<ge>N. f n \<in> t` have "f n \<in> s \<inter> t" by simp
  2698   with `s \<inter> t = {}` show False by simp
  2699 qed
  2700 
  2701 lemma bolzano_weierstrass_imp_closed:
  2702   fixes s :: "'a::metric_space set" (* TODO: can this be generalized? *)
  2703   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2704   shows "closed s"
  2705 proof-
  2706   { fix x l assume as: "\<forall>n::nat. x n \<in> s" "(x ---> l) sequentially"
  2707     hence "l \<in> s"
  2708     proof(cases "\<forall>n. x n \<noteq> l")
  2709       case False thus "l\<in>s" using as(1) by auto
  2710     next
  2711       case True note cas = this
  2712       with as(2) have "infinite (range x)" using sequence_infinite_lemma[of x l] by auto
  2713       then obtain l' where "l'\<in>s" "l' islimpt (range x)" using assms[THEN spec[where x="range x"]] as(1) by auto
  2714       thus "l\<in>s" using sequence_unique_limpt[of x l l'] using as cas by auto
  2715     qed  }
  2716   thus ?thesis unfolding closed_sequential_limits by fast
  2717 qed
  2718 
  2719 text {* Hence express everything as an equivalence. *}
  2720 
  2721 lemma compact_eq_heine_borel:
  2722   fixes s :: "'a::metric_space set"
  2723   shows "compact s \<longleftrightarrow>
  2724            (\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f)
  2725                --> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f')))" (is "?lhs = ?rhs")
  2726 proof
  2727   assume ?lhs thus ?rhs by (rule compact_imp_heine_borel)
  2728 next
  2729   assume ?rhs
  2730   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x\<in>s. x islimpt t)"
  2731     by (blast intro: heine_borel_imp_bolzano_weierstrass[of s])
  2732   thus ?lhs by (rule bolzano_weierstrass_imp_compact)
  2733 qed
  2734 
  2735 lemma compact_eq_bolzano_weierstrass:
  2736   fixes s :: "'a::metric_space set"
  2737   shows "compact s \<longleftrightarrow> (\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t))" (is "?lhs = ?rhs")
  2738 proof
  2739   assume ?lhs thus ?rhs unfolding compact_eq_heine_borel using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2740 next
  2741   assume ?rhs thus ?lhs by (rule bolzano_weierstrass_imp_compact)
  2742 qed
  2743 
  2744 lemma compact_eq_bounded_closed:
  2745   fixes s :: "'a::heine_borel set"
  2746   shows "compact s \<longleftrightarrow> bounded s \<and> closed s"  (is "?lhs = ?rhs")
  2747 proof
  2748   assume ?lhs thus ?rhs unfolding compact_eq_bolzano_weierstrass using bolzano_weierstrass_imp_bounded bolzano_weierstrass_imp_closed by auto
  2749 next
  2750   assume ?rhs thus ?lhs using bounded_closed_imp_compact by auto
  2751 qed
  2752 
  2753 lemma compact_imp_bounded:
  2754   fixes s :: "'a::metric_space set"
  2755   shows "compact s ==> bounded s"
  2756 proof -
  2757   assume "compact s"
  2758   hence "\<forall>f. (\<forall>t\<in>f. open t) \<and> s \<subseteq> \<Union>f \<longrightarrow> (\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f')"
  2759     by (rule compact_imp_heine_borel)
  2760   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t)"
  2761     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2762   thus "bounded s"
  2763     by (rule bolzano_weierstrass_imp_bounded)
  2764 qed
  2765 
  2766 lemma compact_imp_closed:
  2767   fixes s :: "'a::metric_space set"
  2768   shows "compact s ==> closed s"
  2769 proof -
  2770   assume "compact s"
  2771   hence "\<forall>f. (\<forall>t\<in>f. open t) \<and> s \<subseteq> \<Union>f \<longrightarrow> (\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f')"
  2772     by (rule compact_imp_heine_borel)
  2773   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t)"
  2774     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2775   thus "closed s"
  2776     by (rule bolzano_weierstrass_imp_closed)
  2777 qed
  2778 
  2779 text{* In particular, some common special cases. *}
  2780 
  2781 lemma compact_empty[simp]:
  2782  "compact {}"
  2783   unfolding compact_def
  2784   by simp
  2785 
  2786 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  2787   unfolding subseq_def by simp (* TODO: move somewhere else *)
  2788 
  2789 lemma compact_union [intro]:
  2790   assumes "compact s" and "compact t"
  2791   shows "compact (s \<union> t)"
  2792 proof (rule compactI)
  2793   fix f :: "nat \<Rightarrow> 'a"
  2794   assume "\<forall>n. f n \<in> s \<union> t"
  2795   hence "infinite {n. f n \<in> s \<union> t}" by simp
  2796   hence "infinite {n. f n \<in> s} \<or> infinite {n. f n \<in> t}" by simp
  2797   thus "\<exists>l\<in>s \<union> t. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2798   proof
  2799     assume "infinite {n. f n \<in> s}"
  2800     from infinite_enumerate [OF this]
  2801     obtain q where "subseq q" "\<forall>n. (f \<circ> q) n \<in> s" by auto
  2802     obtain r l where "l \<in> s" "subseq r" "((f \<circ> q \<circ> r) ---> l) sequentially"
  2803       using `compact s` `\<forall>n. (f \<circ> q) n \<in> s` by (rule compactE)
  2804     hence "l \<in> s \<union> t" "subseq (q \<circ> r)" "((f \<circ> (q \<circ> r)) ---> l) sequentially"
  2805       using `subseq q` by (simp_all add: subseq_o o_assoc)
  2806     thus ?thesis by auto
  2807   next
  2808     assume "infinite {n. f n \<in> t}"
  2809     from infinite_enumerate [OF this]
  2810     obtain q where "subseq q" "\<forall>n. (f \<circ> q) n \<in> t" by auto
  2811     obtain r l where "l \<in> t" "subseq r" "((f \<circ> q \<circ> r) ---> l) sequentially"
  2812       using `compact t` `\<forall>n. (f \<circ> q) n \<in> t` by (rule compactE)
  2813     hence "l \<in> s \<union> t" "subseq (q \<circ> r)" "((f \<circ> (q \<circ> r)) ---> l) sequentially"
  2814       using `subseq q` by (simp_all add: subseq_o o_assoc)
  2815     thus ?thesis by auto
  2816   qed
  2817 qed
  2818 
  2819 lemma compact_inter_closed [intro]:
  2820   assumes "compact s" and "closed t"
  2821   shows "compact (s \<inter> t)"
  2822 proof (rule compactI)
  2823   fix f :: "nat \<Rightarrow> 'a"
  2824   assume "\<forall>n. f n \<in> s \<inter> t"
  2825   hence "\<forall>n. f n \<in> s" and "\<forall>n. f n \<in> t" by simp_all
  2826   obtain l r where "l \<in> s" "subseq r" "((f \<circ> r) ---> l) sequentially"
  2827     using `compact s` `\<forall>n. f n \<in> s` by (rule compactE)
  2828   moreover
  2829   from `closed t` `\<forall>n. f n \<in> t` `((f \<circ> r) ---> l) sequentially` have "l \<in> t"
  2830     unfolding closed_sequential_limits o_def by fast
  2831   ultimately show "\<exists>l\<in>s \<inter> t. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2832     by auto
  2833 qed
  2834 
  2835 lemma closed_inter_compact [intro]:
  2836   assumes "closed s" and "compact t"
  2837   shows "compact (s \<inter> t)"
  2838   using compact_inter_closed [of t s] assms
  2839   by (simp add: Int_commute)
  2840 
  2841 lemma compact_inter [intro]:
  2842   assumes "compact s" and "compact t"
  2843   shows "compact (s \<inter> t)"
  2844   using assms by (intro compact_inter_closed compact_imp_closed)
  2845 
  2846 lemma compact_sing [simp]: "compact {a}"
  2847   unfolding compact_def o_def subseq_def
  2848   by (auto simp add: tendsto_const)
  2849 
  2850 lemma compact_insert [simp]:
  2851   assumes "compact s" shows "compact (insert x s)"
  2852 proof -
  2853   have "compact ({x} \<union> s)"
  2854     using compact_sing assms by (rule compact_union)
  2855   thus ?thesis by simp
  2856 qed
  2857 
  2858 lemma finite_imp_compact:
  2859   shows "finite s \<Longrightarrow> compact s"
  2860   by (induct set: finite) simp_all
  2861 
  2862 lemma compact_cball[simp]:
  2863   fixes x :: "'a::heine_borel"
  2864   shows "compact(cball x e)"
  2865   using compact_eq_bounded_closed bounded_cball closed_cball
  2866   by blast
  2867 
  2868 lemma compact_frontier_bounded[intro]:
  2869   fixes s :: "'a::heine_borel set"
  2870   shows "bounded s ==> compact(frontier s)"
  2871   unfolding frontier_def
  2872   using compact_eq_bounded_closed
  2873   by blast
  2874 
  2875 lemma compact_frontier[intro]:
  2876   fixes s :: "'a::heine_borel set"
  2877   shows "compact s ==> compact (frontier s)"
  2878   using compact_eq_bounded_closed compact_frontier_bounded
  2879   by blast
  2880 
  2881 lemma frontier_subset_compact:
  2882   fixes s :: "'a::heine_borel set"
  2883   shows "compact s ==> frontier s \<subseteq> s"
  2884   using frontier_subset_closed compact_eq_bounded_closed
  2885   by blast
  2886 
  2887 lemma open_delete:
  2888   fixes s :: "'a::t1_space set"
  2889   shows "open s \<Longrightarrow> open (s - {x})"
  2890   by (simp add: open_Diff)
  2891 
  2892 text{* Finite intersection property. I could make it an equivalence in fact. *}
  2893 
  2894 lemma compact_imp_fip:
  2895   assumes "compact s"  "\<forall>t \<in> f. closed t"
  2896         "\<forall>f'. finite f' \<and> f' \<subseteq> f --> (s \<inter> (\<Inter> f') \<noteq> {})"
  2897   shows "s \<inter> (\<Inter> f) \<noteq> {}"
  2898 proof
  2899   assume as:"s \<inter> (\<Inter> f) = {}"
  2900   hence "s \<subseteq> \<Union> uminus ` f" by auto
  2901   moreover have "Ball (uminus ` f) open" using open_Diff closed_Diff using assms(2) by auto
  2902   ultimately obtain f' where f':"f' \<subseteq> uminus ` f"  "finite f'"  "s \<subseteq> \<Union>f'" using assms(1)[unfolded compact_eq_heine_borel, THEN spec[where x="(\<lambda>t. - t) ` f"]] by auto
  2903   hence "finite (uminus ` f') \<and> uminus ` f' \<subseteq> f" by(auto simp add: Diff_Diff_Int)
  2904   hence "s \<inter> \<Inter>uminus ` f' \<noteq> {}" using assms(3)[THEN spec[where x="uminus ` f'"]] by auto
  2905   thus False using f'(3) unfolding subset_eq and Union_iff by blast
  2906 qed
  2907 
  2908 
  2909 subsection {* Bounded closed nest property (proof does not use Heine-Borel) *}
  2910 
  2911 lemma bounded_closed_nest:
  2912   assumes "\<forall>n. closed(s n)" "\<forall>n. (s n \<noteq> {})"
  2913   "(\<forall>m n. m \<le> n --> s n \<subseteq> s m)"  "bounded(s 0)"
  2914   shows "\<exists>a::'a::heine_borel. \<forall>n::nat. a \<in> s(n)"
  2915 proof-
  2916   from assms(2) obtain x where x:"\<forall>n::nat. x n \<in> s n" using choice[of "\<lambda>n x. x\<in> s n"] by auto
  2917   from assms(4,1) have *:"compact (s 0)" using bounded_closed_imp_compact[of "s 0"] by auto
  2918 
  2919   then obtain l r where lr:"l\<in>s 0" "subseq r" "((x \<circ> r) ---> l) sequentially"
  2920     unfolding compact_def apply(erule_tac x=x in allE)  using x using assms(3) by blast
  2921 
  2922   { fix n::nat
  2923     { fix e::real assume "e>0"
  2924       with lr(3) obtain N where N:"\<forall>m\<ge>N. dist ((x \<circ> r) m) l < e" unfolding Lim_sequentially by auto
  2925       hence "dist ((x \<circ> r) (max N n)) l < e" by auto
  2926       moreover
  2927       have "r (max N n) \<ge> n" using lr(2) using subseq_bigger[of r "max N n"] by auto
  2928       hence "(x \<circ> r) (max N n) \<in> s n"
  2929         using x apply(erule_tac x=n in allE)
  2930         using x apply(erule_tac x="r (max N n)" in allE)
  2931         using assms(3) apply(erule_tac x=n in allE)apply( erule_tac x="r (max N n)" in allE) by auto
  2932       ultimately have "\<exists>y\<in>s n. dist y l < e" by auto
  2933     }
  2934     hence "l \<in> s n" using closed_approachable[of "s n" l] assms(1) by blast
  2935   }
  2936   thus ?thesis by auto
  2937 qed
  2938 
  2939 text {* Decreasing case does not even need compactness, just completeness. *}
  2940 
  2941 lemma decreasing_closed_nest:
  2942   assumes "\<forall>n. closed(s n)"
  2943           "\<forall>n. (s n \<noteq> {})"
  2944           "\<forall>m n. m \<le> n --> s n \<subseteq> s m"
  2945           "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y \<in> (s n). dist x y < e"
  2946   shows "\<exists>a::'a::heine_borel. \<forall>n::nat. a \<in> s n"
  2947 proof-
  2948   have "\<forall>n. \<exists> x. x\<in>s n" using assms(2) by auto
  2949   hence "\<exists>t. \<forall>n. t n \<in> s n" using choice[of "\<lambda> n x. x \<in> s n"] by auto
  2950   then obtain t where t: "\<forall>n. t n \<in> s n" by auto
  2951   { fix e::real assume "e>0"
  2952     then obtain N where N:"\<forall>x\<in>s N. \<forall>y\<in>s N. dist x y < e" using assms(4) by auto
  2953     { fix m n ::nat assume "N \<le> m \<and> N \<le> n"
  2954       hence "t m \<in> s N" "t n \<in> s N" using assms(3) t unfolding  subset_eq t by blast+
  2955       hence "dist (t m) (t n) < e" using N by auto
  2956     }
  2957     hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (t m) (t n) < e" by auto
  2958   }
  2959   hence  "Cauchy t" unfolding cauchy_def by auto
  2960   then obtain l where l:"(t ---> l) sequentially" using complete_univ unfolding complete_def by auto
  2961   { fix n::nat
  2962     { fix e::real assume "e>0"
  2963       then obtain N::nat where N:"\<forall>n\<ge>N. dist (t n) l < e" using l[unfolded Lim_sequentially] by auto
  2964       have "t (max n N) \<in> s n" using assms(3) unfolding subset_eq apply(erule_tac x=n in allE) apply (erule_tac x="max n N" in allE) using t by auto
  2965       hence "\<exists>y\<in>s n. dist y l < e" apply(rule_tac x="t (max n N)" in bexI) using N by auto
  2966     }
  2967     hence "l \<in> s n" using closed_approachable[of "s n" l] assms(1) by auto
  2968   }
  2969   then show ?thesis by auto
  2970 qed
  2971 
  2972 text {* Strengthen it to the intersection actually being a singleton. *}
  2973 
  2974 lemma decreasing_closed_nest_sing:
  2975   fixes s :: "nat \<Rightarrow> 'a::heine_borel set"
  2976   assumes "\<forall>n. closed(s n)"
  2977           "\<forall>n. s n \<noteq> {}"
  2978           "\<forall>m n. m \<le> n --> s n \<subseteq> s m"
  2979           "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y\<in>(s n). dist x y < e"
  2980   shows "\<exists>a. \<Inter>(range s) = {a}"
  2981 proof-
  2982   obtain a where a:"\<forall>n. a \<in> s n" using decreasing_closed_nest[of s] using assms by auto
  2983   { fix b assume b:"b \<in> \<Inter>(range s)"
  2984     { fix e::real assume "e>0"
  2985       hence "dist a b < e" using assms(4 )using b using a by blast
  2986     }
  2987     hence "dist a b = 0" by (metis dist_eq_0_iff dist_nz less_le)
  2988   }
  2989   with a have "\<Inter>(range s) = {a}" unfolding image_def by auto
  2990   thus ?thesis ..
  2991 qed
  2992 
  2993 text{* Cauchy-type criteria for uniform convergence. *}
  2994 
  2995 lemma uniformly_convergent_eq_cauchy: fixes s::"nat \<Rightarrow> 'b \<Rightarrow> 'a::heine_borel" shows
  2996  "(\<exists>l. \<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x --> dist(s n x)(l x) < e) \<longleftrightarrow>
  2997   (\<forall>e>0. \<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e)" (is "?lhs = ?rhs")
  2998 proof(rule)
  2999   assume ?lhs
  3000   then obtain l where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e" by auto
  3001   { fix e::real assume "e>0"
  3002     then obtain N::nat where N:"\<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e / 2" using l[THEN spec[where x="e/2"]] by auto
  3003     { fix n m::nat and x::"'b" assume "N \<le> m \<and> N \<le> n \<and> P x"
  3004       hence "dist (s m x) (s n x) < e"
  3005         using N[THEN spec[where x=m], THEN spec[where x=x]]
  3006         using N[THEN spec[where x=n], THEN spec[where x=x]]
  3007         using dist_triangle_half_l[of "s m x" "l x" e "s n x"] by auto  }
  3008     hence "\<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e"  by auto  }
  3009   thus ?rhs by auto
  3010 next
  3011   assume ?rhs
  3012   hence "\<forall>x. P x \<longrightarrow> Cauchy (\<lambda>n. s n x)" unfolding cauchy_def apply auto by (erule_tac x=e in allE)auto
  3013   then obtain l where l:"\<forall>x. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l x) sequentially" unfolding convergent_eq_cauchy[THEN sym]
  3014     using choice[of "\<lambda>x l. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l) sequentially"] by auto
  3015   { fix e::real assume "e>0"
  3016     then obtain N where N:"\<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x \<longrightarrow> dist (s m x) (s n x) < e/2"
  3017       using `?rhs`[THEN spec[where x="e/2"]] by auto
  3018     { fix x assume "P x"
  3019       then obtain M where M:"\<forall>n\<ge>M. dist (s n x) (l x) < e/2"
  3020         using l[THEN spec[where x=x], unfolded Lim_sequentially] using `e>0` by(auto elim!: allE[where x="e/2"])
  3021       fix n::nat assume "n\<ge>N"
  3022       hence "dist(s n x)(l x) < e"  using `P x`and N[THEN spec[where x=n], THEN spec[where x="N+M"], THEN spec[where x=x]]
  3023         using M[THEN spec[where x="N+M"]] and dist_triangle_half_l[of "s n x" "s (N+M) x" e "l x"] by (auto simp add: dist_commute)  }
  3024     hence "\<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e" by auto }
  3025   thus ?lhs by auto
  3026 qed
  3027 
  3028 lemma uniformly_cauchy_imp_uniformly_convergent:
  3029   fixes s :: "nat \<Rightarrow> 'a \<Rightarrow> 'b::heine_borel"
  3030   assumes "\<forall>e>0.\<exists>N. \<forall>m (n::nat) x. N \<le> m \<and> N \<le> n \<and> P x --> dist(s m x)(s n x) < e"
  3031           "\<forall>x. P x --> (\<forall>e>0. \<exists>N. \<forall>n. N \<le> n --> dist(s n x)(l x) < e)"
  3032   shows "\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x --> dist(s n x)(l x) < e"
  3033 proof-
  3034   obtain l' where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l' x) < e"
  3035     using assms(1) unfolding uniformly_convergent_eq_cauchy[THEN sym] by auto
  3036   moreover
  3037   { fix x assume "P x"
  3038     hence "l x = l' x" using tendsto_unique[OF trivial_limit_sequentially, of "\<lambda>n. s n x" "l x" "l' x"]
  3039       using l and assms(2) unfolding Lim_sequentially by blast  }
  3040   ultimately show ?thesis by auto
  3041 qed
  3042 
  3043 
  3044 subsection {* Continuity *}
  3045 
  3046 text {* Define continuity over a net to take in restrictions of the set. *}
  3047 
  3048 definition
  3049   continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  3050   where "continuous net f \<longleftrightarrow> (f ---> f(netlimit net)) net"
  3051 
  3052 lemma continuous_trivial_limit:
  3053  "trivial_limit net ==> continuous net f"
  3054   unfolding continuous_def tendsto_def trivial_limit_eq by auto
  3055 
  3056 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f(x)) (at x within s)"
  3057   unfolding continuous_def
  3058   unfolding tendsto_def
  3059   using netlimit_within[of x s]
  3060   by (cases "trivial_limit (at x within s)") (auto simp add: trivial_limit_eventually)
  3061 
  3062 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> (f ---> f(x)) (at x)"
  3063   using continuous_within [of x UNIV f] by (simp add: within_UNIV)
  3064 
  3065 lemma continuous_at_within:
  3066   assumes "continuous (at x) f"  shows "continuous (at x within s) f"
  3067   using assms unfolding continuous_at continuous_within
  3068   by (rule Lim_at_within)
  3069 
  3070 text{* Derive the epsilon-delta forms, which we often use as "definitions" *}
  3071 
  3072 lemma continuous_within_eps_delta:
  3073   "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. \<forall>x'\<in> s.  dist x' x < d --> dist (f x') (f x) < e)"
  3074   unfolding continuous_within and Lim_within
  3075   apply auto unfolding dist_nz[THEN sym] apply(auto del: allE elim!:allE) apply(rule_tac x=d in exI) by auto
  3076 
  3077 lemma continuous_at_eps_delta: "continuous (at x) f \<longleftrightarrow>  (\<forall>e>0. \<exists>d>0.
  3078                            \<forall>x'. dist x' x < d --> dist(f x')(f x) < e)"
  3079   using continuous_within_eps_delta[of x UNIV f]
  3080   unfolding within_UNIV by blast
  3081 
  3082 text{* Versions in terms of open balls. *}
  3083 
  3084 lemma continuous_within_ball:
  3085  "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0.
  3086                             f ` (ball x d \<inter> s) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  3087 proof
  3088   assume ?lhs
  3089   { fix e::real assume "e>0"
  3090     then obtain d where d: "d>0" "\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < e"
  3091       using `?lhs`[unfolded continuous_within Lim_within] by auto
  3092     { fix y assume "y\<in>f ` (ball x d \<inter> s)"
  3093       hence "y \<in> ball (f x) e" using d(2) unfolding dist_nz[THEN sym]
  3094         apply (auto simp add: dist_commute) apply(erule_tac x=xa in ballE) apply auto using `e>0` by auto
  3095     }
  3096     hence "\<exists>d>0. f ` (ball x d \<inter> s) \<subseteq> ball (f x) e" using `d>0` unfolding subset_eq ball_def by (auto simp add: dist_commute)  }
  3097   thus ?rhs by auto
  3098 next
  3099   assume ?rhs thus ?lhs unfolding continuous_within Lim_within ball_def subset_eq
  3100     apply (auto simp add: dist_commute) apply(erule_tac x=e in allE) by auto
  3101 qed
  3102 
  3103 lemma continuous_at_ball:
  3104   "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. f ` (ball x d) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  3105 proof
  3106   assume ?lhs thus ?rhs unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  3107     apply auto apply(erule_tac x=e in allE) apply auto apply(rule_tac x=d in exI) apply auto apply(erule_tac x=xa in allE) apply (auto simp add: dist_commute dist_nz)
  3108     unfolding dist_nz[THEN sym] by auto
  3109 next
  3110   assume ?rhs thus ?lhs unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  3111     apply auto apply(erule_tac x=e in allE) apply auto apply(rule_tac x=d in exI) apply auto apply(erule_tac x="f xa" in allE) by (auto simp add: dist_commute dist_nz)
  3112 qed
  3113 
  3114 text{* Define setwise continuity in terms of limits within the set. *}
  3115 
  3116 definition
  3117   continuous_on ::
  3118     "'a set \<Rightarrow> ('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  3119 where
  3120   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  3121 
  3122 lemma continuous_on_topological:
  3123   "continuous_on s f \<longleftrightarrow>
  3124     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow>
  3125       (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  3126 unfolding continuous_on_def tendsto_def
  3127 unfolding Limits.eventually_within eventually_at_topological
  3128 by (intro ball_cong [OF refl] all_cong imp_cong ex_cong conj_cong refl) auto
  3129 
  3130 lemma continuous_on_iff:
  3131   "continuous_on s f \<longleftrightarrow>
  3132     (\<forall>x\<in>s. \<forall>e>0. \<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  3133 unfolding continuous_on_def Lim_within
  3134 apply (intro ball_cong [OF refl] all_cong ex_cong)
  3135 apply (rename_tac y, case_tac "y = x", simp)
  3136 apply (simp add: dist_nz)
  3137 done
  3138 
  3139 definition
  3140   uniformly_continuous_on ::
  3141     "'a set \<Rightarrow> ('a::metric_space \<Rightarrow> 'b::metric_space) \<Rightarrow> bool"
  3142 where
  3143   "uniformly_continuous_on s f \<longleftrightarrow>
  3144     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  3145 
  3146 text{* Some simple consequential lemmas. *}
  3147 
  3148 lemma uniformly_continuous_imp_continuous:
  3149  " uniformly_continuous_on s f ==> continuous_on s f"
  3150   unfolding uniformly_continuous_on_def continuous_on_iff by blast
  3151 
  3152 lemma continuous_at_imp_continuous_within:
  3153  "continuous (at x) f ==> continuous (at x within s) f"
  3154   unfolding continuous_within continuous_at using Lim_at_within by auto
  3155 
  3156 lemma Lim_trivial_limit: "trivial_limit net \<Longrightarrow> (f ---> l) net"
  3157 unfolding tendsto_def by (simp add: trivial_limit_eq)
  3158 
  3159 lemma continuous_at_imp_continuous_on:
  3160   assumes "\<forall>x\<in>s. continuous (at x) f"
  3161   shows "continuous_on s f"
  3162 unfolding continuous_on_def
  3163 proof
  3164   fix x assume "x \<in> s"
  3165   with assms have *: "(f ---> f (netlimit (at x))) (at x)"
  3166     unfolding continuous_def by simp
  3167   have "(f ---> f x) (at x)"
  3168   proof (cases "trivial_limit (at x)")
  3169     case True thus ?thesis
  3170       by (rule Lim_trivial_limit)
  3171   next
  3172     case False
  3173     hence 1: "netlimit (at x) = x"
  3174       using netlimit_within [of x UNIV]
  3175       by (simp add: within_UNIV)
  3176     with * show ?thesis by simp
  3177   qed
  3178   thus "(f ---> f x) (at x within s)"
  3179     by (rule Lim_at_within)
  3180 qed
  3181 
  3182 lemma continuous_on_eq_continuous_within:
  3183   "continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. continuous (at x within s) f)"
  3184 unfolding continuous_on_def continuous_def
  3185 apply (rule ball_cong [OF refl])
  3186 apply (case_tac "trivial_limit (at x within s)")
  3187 apply (simp add: Lim_trivial_limit)
  3188 apply (simp add: netlimit_within)
  3189 done
  3190 
  3191 lemmas continuous_on = continuous_on_def -- "legacy theorem name"
  3192 
  3193 lemma continuous_on_eq_continuous_at:
  3194   shows "open s ==> (continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. continuous (at x) f))"
  3195   by (auto simp add: continuous_on continuous_at Lim_within_open)
  3196 
  3197 lemma continuous_within_subset:
  3198  "continuous (at x within s) f \<Longrightarrow> t \<subseteq> s
  3199              ==> continuous (at x within t) f"
  3200   unfolding continuous_within by(metis Lim_within_subset)
  3201 
  3202 lemma continuous_on_subset:
  3203   shows "continuous_on s f \<Longrightarrow> t \<subseteq> s ==> continuous_on t f"
  3204   unfolding continuous_on by (metis subset_eq Lim_within_subset)
  3205 
  3206 lemma continuous_on_interior:
  3207   shows "continuous_on s f \<Longrightarrow> x \<in> interior s \<Longrightarrow> continuous (at x) f"
  3208   by (erule interiorE, drule (1) continuous_on_subset,
  3209     simp add: continuous_on_eq_continuous_at)
  3210 
  3211 lemma continuous_on_eq:
  3212   "(\<forall>x \<in> s. f x = g x) \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on s g"
  3213   unfolding continuous_on_def tendsto_def Limits.eventually_within
  3214   by simp
  3215 
  3216 text {* Characterization of various kinds of continuity in terms of sequences. *}
  3217 
  3218 lemma continuous_within_sequentially:
  3219   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3220   shows "continuous (at a within s) f \<longleftrightarrow>
  3221                 (\<forall>x. (\<forall>n::nat. x n \<in> s) \<and> (x ---> a) sequentially
  3222                      --> ((f o x) ---> f a) sequentially)" (is "?lhs = ?rhs")
  3223 proof
  3224   assume ?lhs
  3225   { fix x::"nat \<Rightarrow> 'a" assume x:"\<forall>n. x n \<in> s" "\<forall>e>0. eventually (\<lambda>n. dist (x n) a < e) sequentially"
  3226     fix T::"'b set" assume "open T" and "f a \<in> T"
  3227     with `?lhs` obtain d where "d>0" and d:"\<forall>x\<in>s. 0 < dist x a \<and> dist x a < d \<longrightarrow> f x \<in> T"
  3228       unfolding continuous_within tendsto_def eventually_within by auto
  3229     have "eventually (\<lambda>n. dist (x n) a < d) sequentially"
  3230       using x(2) `d>0` by simp
  3231     hence "eventually (\<lambda>n. (f \<circ> x) n \<in> T) sequentially"
  3232     proof (rule eventually_elim1)
  3233       fix n assume "dist (x n) a < d" thus "(f \<circ> x) n \<in> T"
  3234         using d x(1) `f a \<in> T` unfolding dist_nz[THEN sym] by auto
  3235     qed
  3236   }
  3237   thus ?rhs unfolding tendsto_iff unfolding tendsto_def by simp
  3238 next
  3239   assume ?rhs thus ?lhs
  3240     unfolding continuous_within tendsto_def [where l="f a"]
  3241     by (simp add: sequentially_imp_eventually_within)
  3242 qed
  3243 
  3244 lemma continuous_at_sequentially:
  3245   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3246   shows "continuous (at a) f \<longleftrightarrow> (\<forall>x. (x ---> a) sequentially
  3247                   --> ((f o x) ---> f a) sequentially)"
  3248   using continuous_within_sequentially[of a UNIV f]
  3249   unfolding within_UNIV by auto
  3250 
  3251 lemma continuous_on_sequentially:
  3252   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3253   shows "continuous_on s f \<longleftrightarrow>
  3254     (\<forall>x. \<forall>a \<in> s. (\<forall>n. x(n) \<in> s) \<and> (x ---> a) sequentially
  3255                     --> ((f o x) ---> f(a)) sequentially)" (is "?lhs = ?rhs")
  3256 proof
  3257   assume ?rhs thus ?lhs using continuous_within_sequentially[of _ s f] unfolding continuous_on_eq_continuous_within by auto
  3258 next
  3259   assume ?lhs thus ?rhs unfolding continuous_on_eq_continuous_within using continuous_within_sequentially[of _ s f] by auto
  3260 qed
  3261 
  3262 lemma uniformly_continuous_on_sequentially':
  3263   "uniformly_continuous_on s f \<longleftrightarrow> (\<forall>x y. (\<forall>n. x n \<in> s) \<and> (\<forall>n. y n \<in> s) \<and>
  3264                     ((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially
  3265                     \<longrightarrow> ((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially)" (is "?lhs = ?rhs")
  3266 proof
  3267   assume ?lhs
  3268   { fix x y assume x:"\<forall>n. x n \<in> s" and y:"\<forall>n. y n \<in> s" and xy:"((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially"
  3269     { fix e::real assume "e>0"
  3270       then obtain d where "d>0" and d:"\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e"
  3271         using `?lhs`[unfolded uniformly_continuous_on_def, THEN spec[where x=e]] by auto
  3272       obtain N where N:"\<forall>n\<ge>N. dist (x n) (y n) < d" using xy[unfolded Lim_sequentially dist_norm] and `d>0` by auto
  3273       { fix n assume "n\<ge>N"
  3274         hence "dist (f (x n)) (f (y n)) < e"
  3275           using N[THEN spec[where x=n]] using d[THEN bspec[where x="x n"], THEN bspec[where x="y n"]] using x and y
  3276           unfolding dist_commute by simp  }
  3277       hence "\<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e"  by auto  }
  3278     hence "((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially" unfolding Lim_sequentially and dist_real_def by auto  }
  3279   thus ?rhs by auto
  3280 next
  3281   assume ?rhs
  3282   { assume "\<not> ?lhs"
  3283     then obtain e where "e>0" "\<forall>d>0. \<exists>x\<in>s. \<exists>x'\<in>s. dist x' x < d \<and> \<not> dist (f x') (f x) < e" unfolding uniformly_continuous_on_def by auto
  3284     then obtain fa where fa:"\<forall>x.  0 < x \<longrightarrow> fst (fa x) \<in> s \<and> snd (fa x) \<in> s \<and> dist (fst (fa x)) (snd (fa x)) < x \<and> \<not> dist (f (fst (fa x))) (f (snd (fa x))) < e"
  3285       using choice[of "\<lambda>d x. d>0 \<longrightarrow> fst x \<in> s \<and> snd x \<in> s \<and> dist (snd x) (fst x) < d \<and> \<not> dist (f (snd x)) (f (fst x)) < e"] unfolding Bex_def
  3286       by (auto simp add: dist_commute)
  3287     def x \<equiv> "\<lambda>n::nat. fst (fa (inverse (real n + 1)))"
  3288     def y \<equiv> "\<lambda>n::nat. snd (fa (inverse (real n + 1)))"
  3289     have xyn:"\<forall>n. x n \<in> s \<and> y n \<in> s" and xy0:"\<forall>n. dist (x n) (y n) < inverse (real n + 1)" and fxy:"\<forall>n. \<not> dist (f (x n)) (f (y n)) < e"
  3290       unfolding x_def and y_def using fa by auto
  3291     { fix e::real assume "e>0"
  3292       then obtain N::nat where "N \<noteq> 0" and N:"0 < inverse (real N) \<and> inverse (real N) < e" unfolding real_arch_inv[of e]   by auto
  3293       { fix n::nat assume "n\<ge>N"
  3294         hence "inverse (real n + 1) < inverse (real N)" using real_of_nat_ge_zero and `N\<noteq>0` by auto
  3295         also have "\<dots> < e" using N by auto
  3296         finally have "inverse (real n + 1) < e" by auto
  3297         hence "dist (x n) (y n) < e" using xy0[THEN spec[where x=n]] by auto  }
  3298       hence "\<exists>N. \<forall>n\<ge>N. dist (x n) (y n) < e" by auto  }
  3299     hence "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e" using `?rhs`[THEN spec[where x=x], THEN spec[where x=y]] and xyn unfolding Lim_sequentially dist_real_def by auto
  3300     hence False using fxy and `e>0` by auto  }
  3301   thus ?lhs unfolding uniformly_continuous_on_def by blast
  3302 qed
  3303 
  3304 lemma uniformly_continuous_on_sequentially:
  3305   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
  3306   shows "uniformly_continuous_on s f \<longleftrightarrow> (\<forall>x y. (\<forall>n. x n \<in> s) \<and> (\<forall>n. y n \<in> s) \<and>
  3307                     ((\<lambda>n. x n - y n) ---> 0) sequentially
  3308                     \<longrightarrow> ((\<lambda>n. f(x n) - f(y n)) ---> 0) sequentially)" (is "?lhs = ?rhs")
  3309 (* BH: maybe the previous lemma should replace this one? *)
  3310 unfolding uniformly_continuous_on_sequentially'
  3311 unfolding dist_norm tendsto_norm_zero_iff ..
  3312 
  3313 text{* The usual transformation theorems. *}
  3314 
  3315 lemma continuous_transform_within:
  3316   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3317   assumes "0 < d" "x \<in> s" "\<forall>x' \<in> s. dist x' x < d --> f x' = g x'"
  3318           "continuous (at x within s) f"
  3319   shows "continuous (at x within s) g"
  3320 unfolding continuous_within
  3321 proof (rule Lim_transform_within)
  3322   show "0 < d" by fact
  3323   show "\<forall>x'\<in>s. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  3324     using assms(3) by auto
  3325   have "f x = g x"
  3326     using assms(1,2,3) by auto
  3327   thus "(f ---> g x) (at x within s)"
  3328     using assms(4) unfolding continuous_within by simp
  3329 qed
  3330 
  3331 lemma continuous_transform_at:
  3332   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3333   assumes "0 < d" "\<forall>x'. dist x' x < d --> f x' = g x'"
  3334           "continuous (at x) f"
  3335   shows "continuous (at x) g"
  3336   using continuous_transform_within [of d x UNIV f g] assms
  3337   by (simp add: within_UNIV)
  3338 
  3339 text{* Combination results for pointwise continuity. *}
  3340 
  3341 lemma continuous_const: "continuous net (\<lambda>x. c)"
  3342   by (auto simp add: continuous_def tendsto_const)
  3343 
  3344 lemma continuous_cmul:
  3345   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3346   shows "continuous net f ==> continuous net (\<lambda>x. c *\<^sub>R f x)"
  3347   by (auto simp add: continuous_def intro: tendsto_intros)
  3348 
  3349 lemma continuous_neg:
  3350   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3351   shows "continuous net f ==> continuous net (\<lambda>x. -(f x))"
  3352   by (auto simp add: continuous_def tendsto_minus)
  3353 
  3354 lemma continuous_add:
  3355   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3356   shows "continuous net f \<Longrightarrow> continuous net g \<Longrightarrow> continuous net (\<lambda>x. f x + g x)"
  3357   by (auto simp add: continuous_def tendsto_add)
  3358 
  3359 lemma continuous_sub:
  3360   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3361   shows "continuous net f \<Longrightarrow> continuous net g \<Longrightarrow> continuous net (\<lambda>x. f x - g x)"
  3362   by (auto simp add: continuous_def tendsto_diff)
  3363 
  3364 
  3365 text{* Same thing for setwise continuity. *}
  3366 
  3367 lemma continuous_on_const: "continuous_on s (\<lambda>x. c)"
  3368   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3369 
  3370 lemma continuous_on_minus:
  3371   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3372   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
  3373   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3374 
  3375 lemma continuous_on_add:
  3376   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3377   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  3378            \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
  3379   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3380 
  3381 lemma continuous_on_diff:
  3382   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3383   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  3384            \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
  3385   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3386 
  3387 lemma (in bounded_linear) continuous_on:
  3388   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
  3389   unfolding continuous_on_def by (fast intro: tendsto)
  3390 
  3391 lemma (in bounded_bilinear) continuous_on:
  3392   "\<lbrakk>continuous_on s f; continuous_on s g\<rbrakk> \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
  3393   unfolding continuous_on_def by (fast intro: tendsto)
  3394 
  3395 lemma continuous_on_scaleR:
  3396   fixes g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3397   assumes "continuous_on s f" and "continuous_on s g"
  3398   shows "continuous_on s (\<lambda>x. f x *\<^sub>R g x)"
  3399   using bounded_bilinear_scaleR assms
  3400   by (rule bounded_bilinear.continuous_on)
  3401 
  3402 lemma continuous_on_mult:
  3403   fixes g :: "'a::topological_space \<Rightarrow> 'b::real_normed_algebra"
  3404   assumes "continuous_on s f" and "continuous_on s g"
  3405   shows "continuous_on s (\<lambda>x. f x * g x)"
  3406   using bounded_bilinear_mult assms
  3407   by (rule bounded_bilinear.continuous_on)
  3408 
  3409 lemma continuous_on_inner:
  3410   fixes g :: "'a::topological_space \<Rightarrow> 'b::real_inner"
  3411   assumes "continuous_on s f" and "continuous_on s g"
  3412   shows "continuous_on s (\<lambda>x. inner (f x) (g x))"
  3413   using bounded_bilinear_inner assms
  3414   by (rule bounded_bilinear.continuous_on)
  3415 
  3416 lemma continuous_on_euclidean_component:
  3417   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x $$ i)"
  3418   using bounded_linear_euclidean_component
  3419   by (rule bounded_linear.continuous_on)
  3420 
  3421 text{* Same thing for uniform continuity, using sequential formulations. *}
  3422 
  3423 lemma uniformly_continuous_on_const:
  3424  "uniformly_continuous_on s (\<lambda>x. c)"
  3425   unfolding uniformly_continuous_on_def by simp
  3426 
  3427 lemma uniformly_continuous_on_cmul:
  3428   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3429   assumes "uniformly_continuous_on s f"
  3430   shows "uniformly_continuous_on s (\<lambda>x. c *\<^sub>R f(x))"
  3431 proof-
  3432   { fix x y assume "((\<lambda>n. f (x n) - f (y n)) ---> 0) sequentially"
  3433     hence "((\<lambda>n. c *\<^sub>R f (x n) - c *\<^sub>R f (y n)) ---> 0) sequentially"
  3434       using tendsto_scaleR [OF tendsto_const, of "(\<lambda>n. f (x n) - f (y n))" 0 sequentially c]
  3435       unfolding scaleR_zero_right scaleR_right_diff_distrib by auto
  3436   }
  3437   thus ?thesis using assms unfolding uniformly_continuous_on_sequentially'
  3438     unfolding dist_norm tendsto_norm_zero_iff by auto
  3439 qed
  3440 
  3441 lemma dist_minus:
  3442   fixes x y :: "'a::real_normed_vector"
  3443   shows "dist (- x) (- y) = dist x y"
  3444   unfolding dist_norm minus_diff_minus norm_minus_cancel ..
  3445 
  3446 lemma uniformly_continuous_on_neg:
  3447   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3448   shows "uniformly_continuous_on s f
  3449          ==> uniformly_continuous_on s (\<lambda>x. -(f x))"
  3450   unfolding uniformly_continuous_on_def dist_minus .
  3451 
  3452 lemma uniformly_continuous_on_add:
  3453   fixes f g :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3454   assumes "uniformly_continuous_on s f" "uniformly_continuous_on s g"
  3455   shows "uniformly_continuous_on s (\<lambda>x. f x + g x)"
  3456 proof-
  3457   {  fix x y assume "((\<lambda>n. f (x n) - f (y n)) ---> 0) sequentially"
  3458                     "((\<lambda>n. g (x n) - g (y n)) ---> 0) sequentially"
  3459     hence "((\<lambda>xa. f (x xa) - f (y xa) + (g (x xa) - g (y xa))) ---> 0 + 0) sequentially"
  3460       using tendsto_add[of "\<lambda> n. f (x n) - f (y n)" 0  sequentially "\<lambda> n. g (x n) - g (y n)" 0] by auto
  3461     hence "((\<lambda>n. f (x n) + g (x n) - (f (y n) + g (y n))) ---> 0) sequentially" unfolding Lim_sequentially and add_diff_add [symmetric] by auto  }
  3462   thus ?thesis using assms unfolding uniformly_continuous_on_sequentially'
  3463     unfolding dist_norm tendsto_norm_zero_iff by auto
  3464 qed
  3465 
  3466 lemma uniformly_continuous_on_sub:
  3467   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3468   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s g
  3469            ==> uniformly_continuous_on s  (\<lambda>x. f x - g x)"
  3470   unfolding ab_diff_minus
  3471   using uniformly_continuous_on_add[of s f "\<lambda>x. - g x"]
  3472   using uniformly_continuous_on_neg[of s g] by auto
  3473 
  3474 text{* Identity function is continuous in every sense. *}
  3475 
  3476 lemma continuous_within_id:
  3477  "continuous (at a within s) (\<lambda>x. x)"
  3478   unfolding continuous_within by (rule Lim_at_within [OF tendsto_ident_at])
  3479 
  3480 lemma continuous_at_id:
  3481  "continuous (at a) (\<lambda>x. x)"
  3482   unfolding continuous_at by (rule tendsto_ident_at)
  3483 
  3484 lemma continuous_on_id:
  3485  "continuous_on s (\<lambda>x. x)"
  3486   unfolding continuous_on_def by (auto intro: tendsto_ident_at_within)
  3487 
  3488 lemma uniformly_continuous_on_id:
  3489  "uniformly_continuous_on s (\<lambda>x. x)"
  3490   unfolding uniformly_continuous_on_def by auto
  3491 
  3492 text{* Continuity of all kinds is preserved under composition. *}
  3493 
  3494 lemma continuous_within_topological:
  3495   "continuous (at x within s) f \<longleftrightarrow>
  3496     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow>
  3497       (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  3498 unfolding continuous_within
  3499 unfolding tendsto_def Limits.eventually_within eventually_at_topological
  3500 by (intro ball_cong [OF refl] all_cong imp_cong ex_cong conj_cong refl) auto
  3501 
  3502 lemma continuous_within_compose:
  3503   assumes "continuous (at x within s) f"
  3504   assumes "continuous (at (f x) within f ` s) g"
  3505   shows "continuous (at x within s) (g o f)"
  3506 using assms unfolding continuous_within_topological by simp metis
  3507 
  3508 lemma continuous_at_compose:
  3509   assumes "continuous (at x) f"  "continuous (at (f x)) g"
  3510   shows "continuous (at x) (g o f)"
  3511 proof-
  3512   have " continuous (at (f x) within range f) g" using assms(2) using continuous_within_subset[of "f x" UNIV g "range f", unfolded within_UNIV] by auto
  3513   thus ?thesis using assms(1) using continuous_within_compose[of x UNIV f g, unfolded within_UNIV] by auto
  3514 qed
  3515 
  3516 lemma continuous_on_compose:
  3517   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  3518   unfolding continuous_on_topological by simp metis
  3519 
  3520 lemma uniformly_continuous_on_compose:
  3521   assumes "uniformly_continuous_on s f"  "uniformly_continuous_on (f ` s) g"
  3522   shows "uniformly_continuous_on s (g o f)"
  3523 proof-
  3524   { fix e::real assume "e>0"
  3525     then obtain d where "d>0" and d:"\<forall>x\<in>f ` s. \<forall>x'\<in>f ` s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e" using assms(2) unfolding uniformly_continuous_on_def by auto
  3526     obtain d' where "d'>0" "\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d' \<longrightarrow> dist (f x') (f x) < d" using `d>0` using assms(1) unfolding uniformly_continuous_on_def by auto
  3527     hence "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist ((g \<circ> f) x') ((g \<circ> f) x) < e" using `d>0` using d by auto  }
  3528   thus ?thesis using assms unfolding uniformly_continuous_on_def by auto
  3529 qed
  3530 
  3531 text{* Continuity in terms of open preimages. *}
  3532 
  3533 lemma continuous_at_open:
  3534   shows "continuous (at x) f \<longleftrightarrow> (\<forall>t. open t \<and> f x \<in> t --> (\<exists>s. open s \<and> x \<in> s \<and> (\<forall>x' \<in> s. (f x') \<in> t)))"
  3535 unfolding continuous_within_topological [of x UNIV f, unfolded within_UNIV]
  3536 unfolding imp_conjL by (intro all_cong imp_cong ex_cong conj_cong refl) auto
  3537 
  3538 lemma continuous_on_open:
  3539   shows "continuous_on s f \<longleftrightarrow>
  3540         (\<forall>t. openin (subtopology euclidean (f ` s)) t
  3541             --> openin (subtopology euclidean s) {x \<in> s. f x \<in> t})" (is "?lhs = ?rhs")
  3542 proof (safe)
  3543   fix t :: "'b set"
  3544   assume 1: "continuous_on s f"
  3545   assume 2: "openin (subtopology euclidean (f ` s)) t"
  3546   from 2 obtain B where B: "open B" and t: "t = f ` s \<inter> B"
  3547     unfolding openin_open by auto
  3548   def U == "\<Union>{A. open A \<and> (\<forall>x\<in>s. x \<in> A \<longrightarrow> f x \<in> B)}"
  3549   have "open U" unfolding U_def by (simp add: open_Union)
  3550   moreover have "\<forall>x\<in>s. x \<in> U \<longleftrightarrow> f x \<in> t"
  3551   proof (intro ballI iffI)
  3552     fix x assume "x \<in> s" and "x \<in> U" thus "f x \<in> t"
  3553       unfolding U_def t by auto
  3554   next
  3555     fix x assume "x \<in> s" and "f x \<in> t"
  3556     hence "x \<in> s" and "f x \<in> B"
  3557       unfolding t by auto
  3558     with 1 B obtain A where "open A" "x \<in> A" "\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B"
  3559       unfolding t continuous_on_topological by metis
  3560     then show "x \<in> U"
  3561       unfolding U_def by auto
  3562   qed
  3563   ultimately have "open U \<and> {x \<in> s. f x \<in> t} = s \<inter> U" by auto
  3564   then show "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3565     unfolding openin_open by fast
  3566 next
  3567   assume "?rhs" show "continuous_on s f"
  3568   unfolding continuous_on_topological
  3569   proof (clarify)
  3570     fix x and B assume "x \<in> s" and "open B" and "f x \<in> B"
  3571     have "openin (subtopology euclidean (f ` s)) (f ` s \<inter> B)"
  3572       unfolding openin_open using `open B` by auto
  3573     then have "openin (subtopology euclidean s) {x \<in> s. f x \<in> f ` s \<inter> B}"
  3574       using `?rhs` by fast
  3575     then show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  3576       unfolding openin_open using `x \<in> s` and `f x \<in> B` by auto
  3577   qed
  3578 qed
  3579 
  3580 text {* Similarly in terms of closed sets. *}
  3581 
  3582 lemma continuous_on_closed:
  3583   shows "continuous_on s f \<longleftrightarrow>  (\<forall>t. closedin (subtopology euclidean (f ` s)) t  --> closedin (subtopology euclidean s) {x \<in> s. f x \<in> t})" (is "?lhs = ?rhs")
  3584 proof
  3585   assume ?lhs
  3586   { fix t
  3587     have *:"s - {x \<in> s. f x \<in> f ` s - t} = {x \<in> s. f x \<in> t}" by auto
  3588     have **:"f ` s - (f ` s - (f ` s - t)) = f ` s - t" by auto
  3589     assume as:"closedin (subtopology euclidean (f ` s)) t"
  3590     hence "closedin (subtopology euclidean (f ` s)) (f ` s - (f ` s - t))" unfolding closedin_def topspace_euclidean_subtopology unfolding ** by auto
  3591     hence "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}" using `?lhs`[unfolded continuous_on_open, THEN spec[where x="(f ` s) - t"]]
  3592       unfolding openin_closedin_eq topspace_euclidean_subtopology unfolding * by auto  }
  3593   thus ?rhs by auto
  3594 next
  3595   assume ?rhs
  3596   { fix t
  3597     have *:"s - {x \<in> s. f x \<in> f ` s - t} = {x \<in> s. f x \<in> t}" by auto
  3598     assume as:"openin (subtopology euclidean (f ` s)) t"
  3599     hence "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}" using `?rhs`[THEN spec[where x="(f ` s) - t"]]
  3600       unfolding openin_closedin_eq topspace_euclidean_subtopology *[THEN sym] closedin_subtopology by auto }
  3601   thus ?lhs unfolding continuous_on_open by auto
  3602 qed
  3603 
  3604 text {* Half-global and completely global cases. *}
  3605 
  3606 lemma continuous_open_in_preimage:
  3607   assumes "continuous_on s f"  "open t"
  3608   shows "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3609 proof-
  3610   have *:"\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)" by auto
  3611   have "openin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  3612     using openin_open_Int[of t "f ` s", OF assms(2)] unfolding openin_open by auto
  3613   thus ?thesis using assms(1)[unfolded continuous_on_open, THEN spec[where x="t \<inter> f ` s"]] using * by auto
  3614 qed
  3615 
  3616 lemma continuous_closed_in_preimage:
  3617   assumes "continuous_on s f"  "closed t"
  3618   shows "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3619 proof-
  3620   have *:"\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)" by auto
  3621   have "closedin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  3622     using closedin_closed_Int[of t "f ` s", OF assms(2)] unfolding Int_commute by auto
  3623   thus ?thesis
  3624     using assms(1)[unfolded continuous_on_closed, THEN spec[where x="t \<inter> f ` s"]] using * by auto
  3625 qed
  3626 
  3627 lemma continuous_open_preimage:
  3628   assumes "continuous_on s f" "open s" "open t"
  3629   shows "open {x \<in> s. f x \<in> t}"
  3630 proof-
  3631   obtain T where T: "open T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  3632     using continuous_open_in_preimage[OF assms(1,3)] unfolding openin_open by auto
  3633   thus ?thesis using open_Int[of s T, OF assms(2)] by auto
  3634 qed
  3635 
  3636 lemma continuous_closed_preimage:
  3637   assumes "continuous_on s f" "closed s" "closed t"
  3638   shows "closed {x \<in> s. f x \<in> t}"
  3639 proof-
  3640   obtain T where T: "closed T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  3641     using continuous_closed_in_preimage[OF assms(1,3)] unfolding closedin_closed by auto
  3642   thus ?thesis using closed_Int[of s T, OF assms(2)] by auto
  3643 qed
  3644 
  3645 lemma continuous_open_preimage_univ:
  3646   shows "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open {x. f x \<in> s}"
  3647   using continuous_open_preimage[of UNIV f s] open_UNIV continuous_at_imp_continuous_on by auto
  3648 
  3649 lemma continuous_closed_preimage_univ:
  3650   shows "(\<forall>x. continuous (at x) f) \<Longrightarrow> closed s ==> closed {x. f x \<in> s}"
  3651   using continuous_closed_preimage[of UNIV f s] closed_UNIV continuous_at_imp_continuous_on by auto
  3652 
  3653 lemma continuous_open_vimage:
  3654   shows "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open (f -` s)"
  3655   unfolding vimage_def by (rule continuous_open_preimage_univ)
  3656 
  3657 lemma continuous_closed_vimage:
  3658   shows "\<forall>x. continuous (at x) f \<Longrightarrow> closed s \<Longrightarrow> closed (f -` s)"
  3659   unfolding vimage_def by (rule continuous_closed_preimage_univ)
  3660 
  3661 lemma interior_image_subset:
  3662   assumes "\<forall>x. continuous (at x) f" "inj f"
  3663   shows "interior (f ` s) \<subseteq> f ` (interior s)"
  3664 proof
  3665   fix x assume "x \<in> interior (f ` s)"
  3666   then obtain T where as: "open T" "x \<in> T" "T \<subseteq> f ` s" ..
  3667   hence "x \<in> f ` s" by auto
  3668   then obtain y where y: "y \<in> s" "x = f y" by auto
  3669   have "open (vimage f T)"
  3670     using assms(1) `open T` by (rule continuous_open_vimage)
  3671   moreover have "y \<in> vimage f T"
  3672     using `x = f y` `x \<in> T` by simp
  3673   moreover have "vimage f T \<subseteq> s"
  3674     using `T \<subseteq> image f s` `inj f` unfolding inj_on_def subset_eq by auto
  3675   ultimately have "y \<in> interior s" ..
  3676   with `x = f y` show "x \<in> f ` interior s" ..
  3677 qed
  3678 
  3679 text {* Equality of continuous functions on closure and related results. *}
  3680 
  3681 lemma continuous_closed_in_preimage_constant:
  3682   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3683   shows "continuous_on s f ==> closedin (subtopology euclidean s) {x \<in> s. f x = a}"
  3684   using continuous_closed_in_preimage[of s f "{a}"] by auto
  3685 
  3686 lemma continuous_closed_preimage_constant:
  3687   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3688   shows "continuous_on s f \<Longrightarrow> closed s ==> closed {x \<in> s. f x = a}"
  3689   using continuous_closed_preimage[of s f "{a}"] by auto
  3690 
  3691 lemma continuous_constant_on_closure:
  3692   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3693   assumes "continuous_on (closure s) f"
  3694           "\<forall>x \<in> s. f x = a"
  3695   shows "\<forall>x \<in> (closure s). f x = a"
  3696     using continuous_closed_preimage_constant[of "closure s" f a]
  3697     assms closure_minimal[of s "{x \<in> closure s. f x = a}"] closure_subset unfolding subset_eq by auto
  3698 
  3699 lemma image_closure_subset:
  3700   assumes "continuous_on (closure s) f"  "closed t"  "(f ` s) \<subseteq> t"
  3701   shows "f ` (closure s) \<subseteq> t"
  3702 proof-
  3703   have "s \<subseteq> {x \<in> closure s. f x \<in> t}" using assms(3) closure_subset by auto
  3704   moreover have "closed {x \<in> closure s. f x \<in> t}"
  3705     using continuous_closed_preimage[OF assms(1)] and assms(2) by auto
  3706   ultimately have "closure s = {x \<in> closure s . f x \<in> t}"
  3707     using closure_minimal[of s "{x \<in> closure s. f x \<in> t}"] by auto
  3708   thus ?thesis by auto
  3709 qed
  3710 
  3711 lemma continuous_on_closure_norm_le:
  3712   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3713   assumes "continuous_on (closure s) f"  "\<forall>y \<in> s. norm(f y) \<le> b"  "x \<in> (closure s)"
  3714   shows "norm(f x) \<le> b"
  3715 proof-
  3716   have *:"f ` s \<subseteq> cball 0 b" using assms(2)[unfolded mem_cball_0[THEN sym]] by auto
  3717   show ?thesis
  3718     using image_closure_subset[OF assms(1) closed_cball[of 0 b] *] assms(3)
  3719     unfolding subset_eq apply(erule_tac x="f x" in ballE) by (auto simp add: dist_norm)
  3720 qed
  3721 
  3722 text {* Making a continuous function avoid some value in a neighbourhood. *}
  3723 
  3724 lemma continuous_within_avoid:
  3725   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* FIXME: generalize *)
  3726   assumes "continuous (at x within s) f"  "x \<in> s"  "f x \<noteq> a"
  3727   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e --> f y \<noteq> a"
  3728 proof-
  3729   obtain d where "d>0" and d:"\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < dist (f x) a"
  3730     using assms(1)[unfolded continuous_within Lim_within, THEN spec[where x="dist (f x) a"]] assms(3)[unfolded dist_nz] by auto
  3731   { fix y assume " y\<in>s"  "dist x y < d"
  3732     hence "f y \<noteq> a" using d[THEN bspec[where x=y]] assms(3)[unfolded dist_nz]
  3733       apply auto unfolding dist_nz[THEN sym] by (auto simp add: dist_commute) }
  3734   thus ?thesis using `d>0` by auto
  3735 qed
  3736 
  3737 lemma continuous_at_avoid:
  3738   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* FIXME: generalize *)
  3739   assumes "continuous (at x) f"  "f x \<noteq> a"
  3740   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  3741 using assms using continuous_within_avoid[of x UNIV f a, unfolded within_UNIV] by auto
  3742 
  3743 lemma continuous_on_avoid:
  3744   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* TODO: generalize *)
  3745   assumes "continuous_on s f"  "x \<in> s"  "f x \<noteq> a"
  3746   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e \<longrightarrow> f y \<noteq> a"
  3747 using assms(1)[unfolded continuous_on_eq_continuous_within, THEN bspec[where x=x], OF assms(2)]  continuous_within_avoid[of x s f a]  assms(2,3) by auto
  3748 
  3749 lemma continuous_on_open_avoid:
  3750   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* TODO: generalize *)
  3751   assumes "continuous_on s f"  "open s"  "x \<in> s"  "f x \<noteq> a"
  3752   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  3753 using assms(1)[unfolded continuous_on_eq_continuous_at[OF assms(2)], THEN bspec[where x=x], OF assms(3)]  continuous_at_avoid[of x f a]  assms(3,4) by auto
  3754 
  3755 text {* Proving a function is constant by proving open-ness of level set. *}
  3756 
  3757 lemma continuous_levelset_open_in_cases:
  3758   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3759   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  3760         openin (subtopology euclidean s) {x \<in> s. f x = a}
  3761         ==> (\<forall>x \<in> s. f x \<noteq> a) \<or> (\<forall>x \<in> s. f x = a)"
  3762 unfolding connected_clopen using continuous_closed_in_preimage_constant by auto
  3763 
  3764 lemma continuous_levelset_open_in:
  3765   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3766   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  3767         openin (subtopology euclidean s) {x \<in> s. f x = a} \<Longrightarrow>
  3768         (\<exists>x \<in> s. f x = a)  ==> (\<forall>x \<in> s. f x = a)"
  3769 using continuous_levelset_open_in_cases[of s f ]
  3770 by meson
  3771 
  3772 lemma continuous_levelset_open:
  3773   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3774   assumes "connected s"  "continuous_on s f"  "open {x \<in> s. f x = a}"  "\<exists>x \<in> s.  f x = a"
  3775   shows "\<forall>x \<in> s. f x = a"
  3776 using continuous_levelset_open_in[OF assms(1,2), of a, unfolded openin_open] using assms (3,4) by fast
  3777 
  3778 text {* Some arithmetical combinations (more to prove). *}
  3779 
  3780 lemma open_scaling[intro]:
  3781   fixes s :: "'a::real_normed_vector set"
  3782   assumes "c \<noteq> 0"  "open s"
  3783   shows "open((\<lambda>x. c *\<^sub>R x) ` s)"
  3784 proof-
  3785   { fix x assume "x \<in> s"
  3786     then obtain e where "e>0" and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> s" using assms(2)[unfolded open_dist, THEN bspec[where x=x]] by auto
  3787     have "e * abs c > 0" using assms(1)[unfolded zero_less_abs_iff[THEN sym]] using mult_pos_pos[OF `e>0`] by auto
  3788     moreover
  3789     { fix y assume "dist y (c *\<^sub>R x) < e * \<bar>c\<bar>"
  3790       hence "norm ((1 / c) *\<^sub>R y - x) < e" unfolding dist_norm
  3791         using norm_scaleR[of c "(1 / c) *\<^sub>R y - x", unfolded scaleR_right_diff_distrib, unfolded scaleR_scaleR] assms(1)
  3792           assms(1)[unfolded zero_less_abs_iff[THEN sym]] by (simp del:zero_less_abs_iff)
  3793       hence "y \<in> op *\<^sub>R c ` s" using rev_image_eqI[of "(1 / c) *\<^sub>R y" s y "op *\<^sub>R c"]  e[THEN spec[where x="(1 / c) *\<^sub>R y"]]  assms(1) unfolding dist_norm scaleR_scaleR by auto  }
  3794     ultimately have "\<exists>e>0. \<forall>x'. dist x' (c *\<^sub>R x) < e \<longrightarrow> x' \<in> op *\<^sub>R c ` s" apply(rule_tac x="e * abs c" in exI) by auto  }
  3795   thus ?thesis unfolding open_dist by auto
  3796 qed
  3797 
  3798 lemma minus_image_eq_vimage:
  3799   fixes A :: "'a::ab_group_add set"
  3800   shows "(\<lambda>x. - x) ` A = (\<lambda>x. - x) -` A"
  3801   by (auto intro!: image_eqI [where f="\<lambda>x. - x"])
  3802 
  3803 lemma open_negations:
  3804   fixes s :: "'a::real_normed_vector set"
  3805   shows "open s ==> open ((\<lambda> x. -x) ` s)"
  3806   unfolding scaleR_minus1_left [symmetric]
  3807   by (rule open_scaling, auto)
  3808 
  3809 lemma open_translation:
  3810   fixes s :: "'a::real_normed_vector set"
  3811   assumes "open s"  shows "open((\<lambda>x. a + x) ` s)"
  3812 proof-
  3813   { fix x have "continuous (at x) (\<lambda>x. x - a)" using continuous_sub[of "at x" "\<lambda>x. x" "\<lambda>x. a"] continuous_at_id[of x] continuous_const[of "at x" a] by auto  }
  3814   moreover have "{x. x - a \<in> s}  = op + a ` s" apply auto unfolding image_iff apply(rule_tac x="x - a" in bexI) by auto
  3815   ultimately show ?thesis using continuous_open_preimage_univ[of "\<lambda>x. x - a" s] using assms by auto
  3816 qed
  3817 
  3818 lemma open_affinity:
  3819   fixes s :: "'a::real_normed_vector set"
  3820   assumes "open s"  "c \<noteq> 0"
  3821   shows "open ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  3822 proof-
  3823   have *:"(\<lambda>x. a + c *\<^sub>R x) = (\<lambda>x. a + x) \<circ> (\<lambda>x. c *\<^sub>R x)" unfolding o_def ..
  3824   have "op + a ` op *\<^sub>R c ` s = (op + a \<circ> op *\<^sub>R c) ` s" by auto
  3825   thus ?thesis using assms open_translation[of "op *\<^sub>R c ` s" a] unfolding * by auto
  3826 qed
  3827 
  3828 lemma interior_translation:
  3829   fixes s :: "'a::real_normed_vector set"
  3830   shows "interior ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (interior s)"
  3831 proof (rule set_eqI, rule)
  3832   fix x assume "x \<in> interior (op + a ` s)"
  3833   then obtain e where "e>0" and e:"ball x e \<subseteq> op + a ` s" unfolding mem_interior by auto
  3834   hence "ball (x - a) e \<subseteq> s" unfolding subset_eq Ball_def mem_ball dist_norm apply auto apply(erule_tac x="a + xa" in allE) unfolding ab_group_add_class.diff_diff_eq[THEN sym] by auto
  3835   thus "x \<in> op + a ` interior s" unfolding image_iff apply(rule_tac x="x - a" in bexI) unfolding mem_interior using `e > 0` by auto
  3836 next
  3837   fix x assume "x \<in> op + a ` interior s"
  3838   then obtain y e where "e>0" and e:"ball y e \<subseteq> s" and y:"x = a + y" unfolding image_iff Bex_def mem_interior by auto
  3839   { fix z have *:"a + y - z = y + a - z" by auto
  3840     assume "z\<in>ball x e"
  3841     hence "z - a \<in> s" using e[unfolded subset_eq, THEN bspec[where x="z - a"]] unfolding mem_ball dist_norm y ab_group_add_class.diff_diff_eq2 * by auto
  3842     hence "z \<in> op + a ` s" unfolding image_iff by(auto intro!: bexI[where x="z - a"])  }
  3843   hence "ball x e \<subseteq> op + a ` s" unfolding subset_eq by auto
  3844   thus "x \<in> interior (op + a ` s)" unfolding mem_interior using `e>0` by auto
  3845 qed
  3846 
  3847 text {* We can now extend limit compositions to consider the scalar multiplier. *}
  3848 
  3849 lemma continuous_vmul:
  3850   fixes c :: "'a::metric_space \<Rightarrow> real" and v :: "'b::real_normed_vector"
  3851   shows "continuous net c ==> continuous net (\<lambda>x. c(x) *\<^sub>R v)"
  3852   unfolding continuous_def by (intro tendsto_intros)
  3853 
  3854 lemma continuous_mul:
  3855   fixes c :: "'a::metric_space \<Rightarrow> real"
  3856   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3857   shows "continuous net c \<Longrightarrow> continuous net f
  3858              ==> continuous net (\<lambda>x. c(x) *\<^sub>R f x) "
  3859   unfolding continuous_def by (intro tendsto_intros)
  3860 
  3861 lemmas continuous_intros = continuous_add continuous_vmul continuous_cmul
  3862   continuous_const continuous_sub continuous_at_id continuous_within_id continuous_mul
  3863 
  3864 lemmas continuous_on_intros = continuous_on_add continuous_on_const
  3865   continuous_on_id continuous_on_compose continuous_on_minus
  3866   continuous_on_diff continuous_on_scaleR continuous_on_mult
  3867   continuous_on_inner continuous_on_euclidean_component
  3868   uniformly_continuous_on_add uniformly_continuous_on_const
  3869   uniformly_continuous_on_id uniformly_continuous_on_compose
  3870   uniformly_continuous_on_cmul uniformly_continuous_on_neg
  3871   uniformly_continuous_on_sub
  3872 
  3873 text {* And so we have continuity of inverse. *}
  3874 
  3875 lemma continuous_inv:
  3876   fixes f :: "'a::metric_space \<Rightarrow> real"
  3877   shows "continuous net f \<Longrightarrow> f(netlimit net) \<noteq> 0
  3878            ==> continuous net (inverse o f)"
  3879   unfolding continuous_def using Lim_inv by auto
  3880 
  3881 lemma continuous_at_within_inv:
  3882   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_field"
  3883   assumes "continuous (at a within s) f" "f a \<noteq> 0"
  3884   shows "continuous (at a within s) (inverse o f)"
  3885   using assms unfolding continuous_within o_def
  3886   by (intro tendsto_intros)
  3887 
  3888 lemma continuous_at_inv:
  3889   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_field"
  3890   shows "continuous (at a) f \<Longrightarrow> f a \<noteq> 0
  3891          ==> continuous (at a) (inverse o f) "
  3892   using within_UNIV[THEN sym, of "at a"] using continuous_at_within_inv[of a UNIV] by auto
  3893 
  3894 text {* Topological properties of linear functions. *}
  3895 
  3896 lemma linear_lim_0:
  3897   assumes "bounded_linear f" shows "(f ---> 0) (at (0))"
  3898 proof-
  3899   interpret f: bounded_linear f by fact
  3900   have "(f ---> f 0) (at 0)"
  3901     using tendsto_ident_at by (rule f.tendsto)
  3902   thus ?thesis unfolding f.zero .
  3903 qed
  3904 
  3905 lemma linear_continuous_at:
  3906   assumes "bounded_linear f"  shows "continuous (at a) f"
  3907   unfolding continuous_at using assms
  3908   apply (rule bounded_linear.tendsto)
  3909   apply (rule tendsto_ident_at)
  3910   done
  3911 
  3912 lemma linear_continuous_within:
  3913   shows "bounded_linear f ==> continuous (at x within s) f"
  3914   using continuous_at_imp_continuous_within[of x f s] using linear_continuous_at[of f] by auto
  3915 
  3916 lemma linear_continuous_on:
  3917   shows "bounded_linear f ==> continuous_on s f"
  3918   using continuous_at_imp_continuous_on[of s f] using linear_continuous_at[of f] by auto
  3919 
  3920 text {* Also bilinear functions, in composition form. *}
  3921 
  3922 lemma bilinear_continuous_at_compose:
  3923   shows "continuous (at x) f \<Longrightarrow> continuous (at x) g \<Longrightarrow> bounded_bilinear h
  3924         ==> continuous (at x) (\<lambda>x. h (f x) (g x))"
  3925   unfolding continuous_at using Lim_bilinear[of f "f x" "(at x)" g "g x" h] by auto
  3926 
  3927 lemma bilinear_continuous_within_compose:
  3928   shows "continuous (at x within s) f \<Longrightarrow> continuous (at x within s) g \<Longrightarrow> bounded_bilinear h
  3929         ==> continuous (at x within s) (\<lambda>x. h (f x) (g x))"
  3930   unfolding continuous_within using Lim_bilinear[of f "f x"] by auto
  3931 
  3932 lemma bilinear_continuous_on_compose:
  3933   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> bounded_bilinear h
  3934              ==> continuous_on s (\<lambda>x. h (f x) (g x))"
  3935   unfolding continuous_on_def
  3936   by (fast elim: bounded_bilinear.tendsto)
  3937 
  3938 text {* Preservation of compactness and connectedness under continuous function. *}
  3939 
  3940 lemma compact_continuous_image:
  3941   assumes "continuous_on s f"  "compact s"
  3942   shows "compact(f ` s)"
  3943 proof-
  3944   { fix x assume x:"\<forall>n::nat. x n \<in> f ` s"
  3945     then obtain y where y:"\<forall>n. y n \<in> s \<and> x n = f (y n)" unfolding image_iff Bex_def using choice[of "\<lambda>n xa. xa \<in> s \<and> x n = f xa"] by auto
  3946     then obtain l r where "l\<in>s" and r:"subseq r" and lr:"((y \<circ> r) ---> l) sequentially" using assms(2)[unfolded compact_def, THEN spec[where x=y]] by auto
  3947     { fix e::real assume "e>0"
  3948       then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' l < d \<longrightarrow> dist (f x') (f l) < e" using assms(1)[unfolded continuous_on_iff, THEN bspec[where x=l], OF `l\<in>s`] by auto
  3949       then obtain N::nat where N:"\<forall>n\<ge>N. dist ((y \<circ> r) n) l < d" using lr[unfolded Lim_sequentially, THEN spec[where x=d]] by auto
  3950       { fix n::nat assume "n\<ge>N" hence "dist ((x \<circ> r) n) (f l) < e" using N[THEN spec[where x=n]] d[THEN bspec[where x="y (r n)"]] y[THEN spec[where x="r n"]] by auto  }
  3951       hence "\<exists>N. \<forall>n\<ge>N. dist ((x \<circ> r) n) (f l) < e" by auto  }
  3952     hence "\<exists>l\<in>f ` s. \<exists>r. subseq r \<and> ((x \<circ> r) ---> l) sequentially" unfolding Lim_sequentially using r lr `l\<in>s` by auto  }
  3953   thus ?thesis unfolding compact_def by auto
  3954 qed
  3955 
  3956 lemma connected_continuous_image:
  3957   assumes "continuous_on s f"  "connected s"
  3958   shows "connected(f ` s)"
  3959 proof-
  3960   { fix T assume as: "T \<noteq> {}"  "T \<noteq> f ` s"  "openin (subtopology euclidean (f ` s)) T"  "closedin (subtopology euclidean (f ` s)) T"
  3961     have "{x \<in> s. f x \<in> T} = {} \<or> {x \<in> s. f x \<in> T} = s"
  3962       using assms(1)[unfolded continuous_on_open, THEN spec[where x=T]]
  3963       using assms(1)[unfolded continuous_on_closed, THEN spec[where x=T]]
  3964       using assms(2)[unfolded connected_clopen, THEN spec[where x="{x \<in> s. f x \<in> T}"]] as(3,4) by auto
  3965     hence False using as(1,2)
  3966       using as(4)[unfolded closedin_def topspace_euclidean_subtopology] by auto }
  3967   thus ?thesis unfolding connected_clopen by auto
  3968 qed
  3969 
  3970 text {* Continuity implies uniform continuity on a compact domain. *}
  3971 
  3972 lemma compact_uniformly_continuous:
  3973   assumes "continuous_on s f"  "compact s"
  3974   shows "uniformly_continuous_on s f"
  3975 proof-
  3976     { fix x assume x:"x\<in>s"
  3977       hence "\<forall>xa. \<exists>y. 0 < xa \<longrightarrow> (y > 0 \<and> (\<forall>x'\<in>s. dist x' x < y \<longrightarrow> dist (f x') (f x) < xa))" using assms(1)[unfolded continuous_on_iff, THEN bspec[where x=x]] by auto
  3978       hence "\<exists>fa. \<forall>xa>0. \<forall>x'\<in>s. fa xa > 0 \<and> (dist x' x < fa xa \<longrightarrow> dist (f x') (f x) < xa)" using choice[of "\<lambda>e d. e>0 \<longrightarrow> d>0 \<and>(\<forall>x'\<in>s. (dist x' x < d \<longrightarrow> dist (f x') (f x) < e))"] by auto  }
  3979     then have "\<forall>x\<in>s. \<exists>y. \<forall>xa. 0 < xa \<longrightarrow> (\<forall>x'\<in>s. y xa > 0 \<and> (dist x' x < y xa \<longrightarrow> dist (f x') (f x) < xa))" by auto
  3980     then obtain d where d:"\<forall>e>0. \<forall>x\<in>s. \<forall>x'\<in>s. d x e > 0 \<and> (dist x' x < d x e \<longrightarrow> dist (f x') (f x) < e)"
  3981       using bchoice[of s "\<lambda>x fa. \<forall>xa>0. \<forall>x'\<in>s. fa xa > 0 \<and> (dist x' x < fa xa \<longrightarrow> dist (f x') (f x) < xa)"] by blast
  3982 
  3983   { fix e::real assume "e>0"
  3984 
  3985     { fix x assume "x\<in>s" hence "x \<in> ball x (d x (e / 2))" unfolding centre_in_ball using d[THEN spec[where x="e/2"]] using `e>0` by auto  }
  3986     hence "s \<subseteq> \<Union>{ball x (d x (e / 2)) |x. x \<in> s}" unfolding subset_eq by auto
  3987     moreover
  3988     { fix b assume "b\<in>{ball x (d x (e / 2)) |x. x \<in> s}" hence "open b" by auto  }
  3989     ultimately obtain ea where "ea>0" and ea:"\<forall>x\<in>s. \<exists>b\<in>{ball x (d x (e / 2)) |x. x \<in> s}. ball x ea \<subseteq> b" using heine_borel_lemma[OF assms(2), of "{ball x (d x (e / 2)) | x. x\<in>s }"] by auto
  3990 
  3991     { fix x y assume "x\<in>s" "y\<in>s" and as:"dist y x < ea"
  3992       obtain z where "z\<in>s" and z:"ball x ea \<subseteq> ball z (d z (e / 2))" using ea[THEN bspec[where x=x]] and `x\<in>s` by auto
  3993       hence "x\<in>ball z (d z (e / 2))" using `ea>0` unfolding subset_eq by auto
  3994       hence "dist (f z) (f x) < e / 2" using d[THEN spec[where x="e/2"]] and `e>0` and `x\<in>s` and `z\<in>s`
  3995         by (auto  simp add: dist_commute)
  3996       moreover have "y\<in>ball z (d z (e / 2))" using as and `ea>0` and z[unfolded subset_eq]
  3997         by (auto simp add: dist_commute)
  3998       hence "dist (f z) (f y) < e / 2" using d[THEN spec[where x="e/2"]] and `e>0` and `y\<in>s` and `z\<in>s`
  3999         by (auto  simp add: dist_commute)
  4000       ultimately have "dist (f y) (f x) < e" using dist_triangle_half_r[of "f z" "f x" e "f y"]
  4001         by (auto simp add: dist_commute)  }
  4002     then have "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e" using `ea>0` by auto  }
  4003   thus ?thesis unfolding uniformly_continuous_on_def by auto
  4004 qed
  4005 
  4006 text{* Continuity of inverse function on compact domain. *}
  4007 
  4008 lemma continuous_on_inverse:
  4009   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  4010     (* TODO: can this be generalized more? *)
  4011   assumes "continuous_on s f"  "compact s"  "\<forall>x \<in> s. g (f x) = x"
  4012   shows "continuous_on (f ` s) g"
  4013 proof-
  4014   have *:"g ` f ` s = s" using assms(3) by (auto simp add: image_iff)
  4015   { fix t assume t:"closedin (subtopology euclidean (g ` f ` s)) t"
  4016     then obtain T where T: "closed T" "t = s \<inter> T" unfolding closedin_closed unfolding * by auto
  4017     have "continuous_on (s \<inter> T) f" using continuous_on_subset[OF assms(1), of "s \<inter> t"]
  4018       unfolding T(2) and Int_left_absorb by auto
  4019     moreover have "compact (s \<inter> T)"
  4020       using assms(2) unfolding compact_eq_bounded_closed
  4021       using bounded_subset[of s "s \<inter> T"] and T(1) by auto
  4022     ultimately have "closed (f ` t)" using T(1) unfolding T(2)
  4023       using compact_continuous_image [of "s \<inter> T" f] unfolding compact_eq_bounded_closed by auto
  4024     moreover have "{x \<in> f ` s. g x \<in> t} = f ` s \<inter> f ` t" using assms(3) unfolding T(2) by auto
  4025     ultimately have "closedin (subtopology euclidean (f ` s)) {x \<in> f ` s. g x \<in> t}"
  4026       unfolding closedin_closed by auto  }
  4027   thus ?thesis unfolding continuous_on_closed by auto
  4028 qed
  4029 
  4030 text {* A uniformly convergent limit of continuous functions is continuous. *}
  4031 
  4032 lemma continuous_uniform_limit:
  4033   fixes f :: "'a \<Rightarrow> 'b::metric_space \<Rightarrow> 'c::metric_space"
  4034   assumes "\<not> trivial_limit F"
  4035   assumes "eventually (\<lambda>n. continuous_on s (f n)) F"
  4036   assumes "\<forall>e>0. eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e) F"
  4037   shows "continuous_on s g"
  4038 proof-
  4039   { fix x and e::real assume "x\<in>s" "e>0"
  4040     have "eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e / 3) F"
  4041       using `e>0` assms(3)[THEN spec[where x="e/3"]] by auto
  4042     from eventually_happens [OF eventually_conj [OF this assms(2)]]
  4043     obtain n where n:"\<forall>x\<in>s. dist (f n x) (g x) < e / 3"  "continuous_on s (f n)"
  4044       using assms(1) by blast
  4045     have "e / 3 > 0" using `e>0` by auto
  4046     then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f n x') (f n x) < e / 3"
  4047       using n(2)[unfolded continuous_on_iff, THEN bspec[where x=x], OF `x\<in>s`, THEN spec[where x="e/3"]] by blast
  4048     { fix y assume "y \<in> s" and "dist y x < d"
  4049       hence "dist (f n y) (f n x) < e / 3"
  4050         by (rule d [rule_format])
  4051       hence "dist (f n y) (g x) < 2 * e / 3"
  4052         using dist_triangle [of "f n y" "g x" "f n x"]
  4053         using n(1)[THEN bspec[where x=x], OF `x\<in>s`]
  4054         by auto
  4055       hence "dist (g y) (g x) < e"
  4056         using n(1)[THEN bspec[where x=y], OF `y\<in>s`]
  4057         using dist_triangle3 [of "g y" "g x" "f n y"]
  4058         by auto }
  4059     hence "\<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e"
  4060       using `d>0` by auto }
  4061   thus ?thesis unfolding continuous_on_iff by auto
  4062 qed
  4063 
  4064 
  4065 subsection {* Topological stuff lifted from and dropped to R *}
  4066 
  4067 lemma open_real:
  4068   fixes s :: "real set" shows
  4069  "open s \<longleftrightarrow>
  4070         (\<forall>x \<in> s. \<exists>e>0. \<forall>x'. abs(x' - x) < e --> x' \<in> s)" (is "?lhs = ?rhs")
  4071   unfolding open_dist dist_norm by simp
  4072 
  4073 lemma islimpt_approachable_real:
  4074   fixes s :: "real set"
  4075   shows "x islimpt s \<longleftrightarrow> (\<forall>e>0.  \<exists>x'\<in> s. x' \<noteq> x \<and> abs(x' - x) < e)"
  4076   unfolding islimpt_approachable dist_norm by simp
  4077 
  4078 lemma closed_real:
  4079   fixes s :: "real set"
  4080   shows "closed s \<longleftrightarrow>
  4081         (\<forall>x. (\<forall>e>0.  \<exists>x' \<in> s. x' \<noteq> x \<and> abs(x' - x) < e)
  4082             --> x \<in> s)"
  4083   unfolding closed_limpt islimpt_approachable dist_norm by simp
  4084 
  4085 lemma continuous_at_real_range:
  4086   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  4087   shows "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0.
  4088         \<forall>x'. norm(x' - x) < d --> abs(f x' - f x) < e)"
  4089   unfolding continuous_at unfolding Lim_at
  4090   unfolding dist_nz[THEN sym] unfolding dist_norm apply auto
  4091   apply(erule_tac x=e in allE) apply auto apply (rule_tac x=d in exI) apply auto apply (erule_tac x=x' in allE) apply auto
  4092   apply(erule_tac x=e in allE) by auto
  4093 
  4094 lemma continuous_on_real_range:
  4095   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  4096   shows "continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. \<forall>e>0. \<exists>d>0. (\<forall>x' \<in> s. norm(x' - x) < d --> abs(f x' - f x) < e))"
  4097   unfolding continuous_on_iff dist_norm by simp
  4098 
  4099 lemma continuous_at_norm: "continuous (at x) norm"
  4100   unfolding continuous_at by (intro tendsto_intros)
  4101 
  4102 lemma continuous_on_norm: "continuous_on s norm"
  4103 unfolding continuous_on by (intro ballI tendsto_intros)
  4104 
  4105 lemma continuous_at_infnorm: "continuous (at x) infnorm"
  4106   unfolding continuous_at Lim_at o_def unfolding dist_norm
  4107   apply auto apply (rule_tac x=e in exI) apply auto
  4108   using order_trans[OF real_abs_sub_infnorm infnorm_le_norm, of _ x] by (metis xt1(7))
  4109 
  4110 text {* Hence some handy theorems on distance, diameter etc. of/from a set. *}
  4111 
  4112 lemma compact_attains_sup:
  4113   fixes s :: "real set"
  4114   assumes "compact s"  "s \<noteq> {}"
  4115   shows "\<exists>x \<in> s. \<forall>y \<in> s. y \<le> x"
  4116 proof-
  4117   from assms(1) have a:"bounded s" "closed s" unfolding compact_eq_bounded_closed by auto
  4118   { fix e::real assume as: "\<forall>x\<in>s. x \<le> Sup s" "Sup s \<notin> s"  "0 < e" "\<forall>x'\<in>s. x' = Sup s \<or> \<not> Sup s - x' < e"
  4119     have "isLub UNIV s (Sup s)" using Sup[OF assms(2)] unfolding setle_def using as(1) by auto
  4120     moreover have "isUb UNIV s (Sup s - e)" unfolding isUb_def unfolding setle_def using as(4,2) by auto
  4121     ultimately have False using isLub_le_isUb[of UNIV s "Sup s" "Sup s - e"] using `e>0` by auto  }
  4122   thus ?thesis using bounded_has_Sup(1)[OF a(1) assms(2)] using a(2)[unfolded closed_real, THEN spec[where x="Sup s"]]
  4123     apply(rule_tac x="Sup s" in bexI) by auto
  4124 qed
  4125 
  4126 lemma Inf:
  4127   fixes S :: "real set"
  4128   shows "S \<noteq> {} ==> (\<exists>b. b <=* S) ==> isGlb UNIV S (Inf S)"
  4129 by (auto simp add: isLb_def setle_def setge_def isGlb_def greatestP_def) 
  4130 
  4131 lemma compact_attains_inf:
  4132   fixes s :: "real set"
  4133   assumes "compact s" "s \<noteq> {}"  shows "\<exists>x \<in> s. \<forall>y \<in> s. x \<le> y"
  4134 proof-
  4135   from assms(1) have a:"bounded s" "closed s" unfolding compact_eq_bounded_closed by auto
  4136   { fix e::real assume as: "\<forall>x\<in>s. x \<ge> Inf s"  "Inf s \<notin> s"  "0 < e"
  4137       "\<forall>x'\<in>s. x' = Inf s \<or> \<not> abs (x' - Inf s) < e"
  4138     have "isGlb UNIV s (Inf s)" using Inf[OF assms(2)] unfolding setge_def using as(1) by auto
  4139     moreover
  4140     { fix x assume "x \<in> s"
  4141       hence *:"abs (x - Inf s) = x - Inf s" using as(1)[THEN bspec[where x=x]] by auto
  4142       have "Inf s + e \<le> x" using as(4)[THEN bspec[where x=x]] using as(2) `x\<in>s` unfolding * by auto }
  4143     hence "isLb UNIV s (Inf s + e)" unfolding isLb_def and setge_def by auto
  4144     ultimately have False using isGlb_le_isLb[of UNIV s "Inf s" "Inf s + e"] using `e>0` by auto  }
  4145   thus ?thesis using bounded_has_Inf(1)[OF a(1) assms(2)] using a(2)[unfolded closed_real, THEN spec[where x="Inf s"]]
  4146     apply(rule_tac x="Inf s" in bexI) by auto
  4147 qed
  4148 
  4149 lemma continuous_attains_sup:
  4150   fixes f :: "'a::metric_space \<Rightarrow> real"
  4151   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f
  4152         ==> (\<exists>x \<in> s. \<forall>y \<in> s.  f y \<le> f x)"
  4153   using compact_attains_sup[of "f ` s"]
  4154   using compact_continuous_image[of s f] by auto
  4155 
  4156 lemma continuous_attains_inf:
  4157   fixes f :: "'a::metric_space \<Rightarrow> real"
  4158   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f
  4159         \<Longrightarrow> (\<exists>x \<in> s. \<forall>y \<in> s. f x \<le> f y)"
  4160   using compact_attains_inf[of "f ` s"]
  4161   using compact_continuous_image[of s f] by auto
  4162 
  4163 lemma distance_attains_sup:
  4164   assumes "compact s" "s \<noteq> {}"
  4165   shows "\<exists>x \<in> s. \<forall>y \<in> s. dist a y \<le> dist a x"
  4166 proof (rule continuous_attains_sup [OF assms])
  4167   { fix x assume "x\<in>s"
  4168     have "(dist a ---> dist a x) (at x within s)"
  4169       by (intro tendsto_dist tendsto_const Lim_at_within tendsto_ident_at)
  4170   }
  4171   thus "continuous_on s (dist a)"
  4172     unfolding continuous_on ..
  4173 qed
  4174 
  4175 text {* For \emph{minimal} distance, we only need closure, not compactness. *}
  4176 
  4177 lemma distance_attains_inf:
  4178   fixes a :: "'a::heine_borel"
  4179   assumes "closed s"  "s \<noteq> {}"
  4180   shows "\<exists>x \<in> s. \<forall>y \<in> s. dist a x \<le> dist a y"
  4181 proof-
  4182   from assms(2) obtain b where "b\<in>s" by auto
  4183   let ?B = "cball a (dist b a) \<inter> s"
  4184   have "b \<in> ?B" using `b\<in>s` by (simp add: dist_commute)
  4185   hence "?B \<noteq> {}" by auto
  4186   moreover
  4187   { fix x assume "x\<in>?B"
  4188     fix e::real assume "e>0"
  4189     { fix x' assume "x'\<in>?B" and as:"dist x' x < e"
  4190       from as have "\<bar>dist a x' - dist a x\<bar> < e"
  4191         unfolding abs_less_iff minus_diff_eq
  4192         using dist_triangle2 [of a x' x]
  4193         using dist_triangle [of a x x']
  4194         by arith
  4195     }
  4196     hence "\<exists>d>0. \<forall>x'\<in>?B. dist x' x < d \<longrightarrow> \<bar>dist a x' - dist a x\<bar> < e"
  4197       using `e>0` by auto
  4198   }
  4199   hence "continuous_on (cball a (dist b a) \<inter> s) (dist a)"
  4200     unfolding continuous_on Lim_within dist_norm real_norm_def
  4201     by fast
  4202   moreover have "compact ?B"
  4203     using compact_cball[of a "dist b a"]
  4204     unfolding compact_eq_bounded_closed
  4205     using bounded_Int and closed_Int and assms(1) by auto
  4206   ultimately obtain x where "x\<in>cball a (dist b a) \<inter> s" "\<forall>y\<in>cball a (dist b a) \<inter> s. dist a x \<le> dist a y"
  4207     using continuous_attains_inf[of ?B "dist a"] by fastsimp
  4208   thus ?thesis by fastsimp
  4209 qed
  4210 
  4211 
  4212 subsection {* Pasted sets *}
  4213 
  4214 lemma bounded_Times:
  4215   assumes "bounded s" "bounded t" shows "bounded (s \<times> t)"
  4216 proof-
  4217   obtain x y a b where "\<forall>z\<in>s. dist x z \<le> a" "\<forall>z\<in>t. dist y z \<le> b"
  4218     using assms [unfolded bounded_def] by auto
  4219   then have "\<forall>z\<in>s \<times> t. dist (x, y) z \<le> sqrt (a\<twosuperior> + b\<twosuperior>)"
  4220     by (auto simp add: dist_Pair_Pair real_sqrt_le_mono add_mono power_mono)
  4221   thus ?thesis unfolding bounded_any_center [where a="(x, y)"] by auto
  4222 qed
  4223 
  4224 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
  4225 by (induct x) simp
  4226 
  4227 lemma compact_Times: "compact s \<Longrightarrow> compact t \<Longrightarrow> compact (s \<times> t)"
  4228 unfolding compact_def
  4229 apply clarify
  4230 apply (drule_tac x="fst \<circ> f" in spec)
  4231 apply (drule mp, simp add: mem_Times_iff)
  4232 apply (clarify, rename_tac l1 r1)
  4233 apply (drule_tac x="snd \<circ> f \<circ> r1" in spec)
  4234 apply (drule mp, simp add: mem_Times_iff)
  4235 apply (clarify, rename_tac l2 r2)
  4236 apply (rule_tac x="(l1, l2)" in rev_bexI, simp)
  4237 apply (rule_tac x="r1 \<circ> r2" in exI)
  4238 apply (rule conjI, simp add: subseq_def)
  4239 apply (drule_tac r=r2 in lim_subseq [COMP swap_prems_rl], assumption)
  4240 apply (drule (1) tendsto_Pair) back
  4241 apply (simp add: o_def)
  4242 done
  4243 
  4244 text{* Hence some useful properties follow quite easily. *}
  4245 
  4246 lemma compact_scaling:
  4247   fixes s :: "'a::real_normed_vector set"
  4248   assumes "compact s"  shows "compact ((\<lambda>x. c *\<^sub>R x) ` s)"
  4249 proof-
  4250   let ?f = "\<lambda>x. scaleR c x"
  4251   have *:"bounded_linear ?f" by (rule bounded_linear_scaleR_right)
  4252   show ?thesis using compact_continuous_image[of s ?f] continuous_at_imp_continuous_on[of s ?f]
  4253     using linear_continuous_at[OF *] assms by auto
  4254 qed
  4255 
  4256 lemma compact_negations:
  4257   fixes s :: "'a::real_normed_vector set"
  4258   assumes "compact s"  shows "compact ((\<lambda>x. -x) ` s)"
  4259   using compact_scaling [OF assms, of "- 1"] by auto
  4260 
  4261 lemma compact_sums:
  4262   fixes s t :: "'a::real_normed_vector set"
  4263   assumes "compact s"  "compact t"  shows "compact {x + y | x y. x \<in> s \<and> y \<in> t}"
  4264 proof-
  4265   have *:"{x + y | x y. x \<in> s \<and> y \<in> t} = (\<lambda>z. fst z + snd z) ` (s \<times> t)"
  4266     apply auto unfolding image_iff apply(rule_tac x="(xa, y)" in bexI) by auto
  4267   have "continuous_on (s \<times> t) (\<lambda>z. fst z + snd z)"
  4268     unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  4269   thus ?thesis unfolding * using compact_continuous_image compact_Times [OF assms] by auto
  4270 qed
  4271 
  4272 lemma compact_differences:
  4273   fixes s t :: "'a::real_normed_vector set"
  4274   assumes "compact s" "compact t"  shows "compact {x - y | x y. x \<in> s \<and> y \<in> t}"
  4275 proof-
  4276   have "{x - y | x y. x\<in>s \<and> y \<in> t} =  {x + y | x y. x \<in> s \<and> y \<in> (uminus ` t)}"
  4277     apply auto apply(rule_tac x= xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4278   thus ?thesis using compact_sums[OF assms(1) compact_negations[OF assms(2)]] by auto
  4279 qed
  4280 
  4281 lemma compact_translation:
  4282   fixes s :: "'a::real_normed_vector set"
  4283   assumes "compact s"  shows "compact ((\<lambda>x. a + x) ` s)"
  4284 proof-
  4285   have "{x + y |x y. x \<in> s \<and> y \<in> {a}} = (\<lambda>x. a + x) ` s" by auto
  4286   thus ?thesis using compact_sums[OF assms compact_sing[of a]] by auto
  4287 qed
  4288 
  4289 lemma compact_affinity:
  4290   fixes s :: "'a::real_normed_vector set"
  4291   assumes "compact s"  shows "compact ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  4292 proof-
  4293   have "op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s" by auto
  4294   thus ?thesis using compact_translation[OF compact_scaling[OF assms], of a c] by auto
  4295 qed
  4296 
  4297 text {* Hence we get the following. *}
  4298 
  4299 lemma compact_sup_maxdistance:
  4300   fixes s :: "'a::real_normed_vector set"
  4301   assumes "compact s"  "s \<noteq> {}"
  4302   shows "\<exists>x\<in>s. \<exists>y\<in>s. \<forall>u\<in>s. \<forall>v\<in>s. norm(u - v) \<le> norm(x - y)"
  4303 proof-
  4304   have "{x - y | x y . x\<in>s \<and> y\<in>s} \<noteq> {}" using `s \<noteq> {}` by auto
  4305   then obtain x where x:"x\<in>{x - y |x y. x \<in> s \<and> y \<in> s}"  "\<forall>y\<in>{x - y |x y. x \<in> s \<and> y \<in> s}. norm y \<le> norm x"
  4306     using compact_differences[OF assms(1) assms(1)]
  4307     using distance_attains_sup[where 'a="'a", unfolded dist_norm, of "{x - y | x y . x\<in>s \<and> y\<in>s}" 0] by auto
  4308   from x(1) obtain a b where "a\<in>s" "b\<in>s" "x = a - b" by auto
  4309   thus ?thesis using x(2)[unfolded `x = a - b`] by blast
  4310 qed
  4311 
  4312 text {* We can state this in terms of diameter of a set. *}
  4313 
  4314 definition "diameter s = (if s = {} then 0::real else Sup {norm(x - y) | x y. x \<in> s \<and> y \<in> s})"
  4315   (* TODO: generalize to class metric_space *)
  4316 
  4317 lemma diameter_bounded:
  4318   assumes "bounded s"
  4319   shows "\<forall>x\<in>s. \<forall>y\<in>s. norm(x - y) \<le> diameter s"
  4320         "\<forall>d>0. d < diameter s --> (\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d)"
  4321 proof-
  4322   let ?D = "{norm (x - y) |x y. x \<in> s \<and> y \<in> s}"
  4323   obtain a where a:"\<forall>x\<in>s. norm x \<le> a" using assms[unfolded bounded_iff] by auto
  4324   { fix x y assume "x \<in> s" "y \<in> s"
  4325     hence "norm (x - y) \<le> 2 * a" using norm_triangle_ineq[of x "-y", unfolded norm_minus_cancel] a[THEN bspec[where x=x]] a[THEN bspec[where x=y]] by (auto simp add: field_simps)  }
  4326   note * = this
  4327   { fix x y assume "x\<in>s" "y\<in>s"  hence "s \<noteq> {}" by auto
  4328     have "norm(x - y) \<le> diameter s" unfolding diameter_def using `s\<noteq>{}` *[OF `x\<in>s` `y\<in>s`] `x\<in>s` `y\<in>s`
  4329       by simp (blast del: Sup_upper intro!: * Sup_upper) }
  4330   moreover
  4331   { fix d::real assume "d>0" "d < diameter s"
  4332     hence "s\<noteq>{}" unfolding diameter_def by auto
  4333     have "\<exists>d' \<in> ?D. d' > d"
  4334     proof(rule ccontr)
  4335       assume "\<not> (\<exists>d'\<in>{norm (x - y) |x y. x \<in> s \<and> y \<in> s}. d < d')"
  4336       hence "\<forall>d'\<in>?D. d' \<le> d" by auto (metis not_leE) 
  4337       thus False using `d < diameter s` `s\<noteq>{}` 
  4338         apply (auto simp add: diameter_def) 
  4339         apply (drule Sup_real_iff [THEN [2] rev_iffD2])
  4340         apply (auto, force) 
  4341         done
  4342     qed
  4343     hence "\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d" by auto  }
  4344   ultimately show "\<forall>x\<in>s. \<forall>y\<in>s. norm(x - y) \<le> diameter s"
  4345         "\<forall>d>0. d < diameter s --> (\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d)" by auto
  4346 qed
  4347 
  4348 lemma diameter_bounded_bound:
  4349  "bounded s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s ==> norm(x - y) \<le> diameter s"
  4350   using diameter_bounded by blast
  4351 
  4352 lemma diameter_compact_attained:
  4353   fixes s :: "'a::real_normed_vector set"
  4354   assumes "compact s"  "s \<noteq> {}"
  4355   shows "\<exists>x\<in>s. \<exists>y\<in>s. (norm(x - y) = diameter s)"
  4356 proof-
  4357   have b:"bounded s" using assms(1) by (rule compact_imp_bounded)
  4358   then obtain x y where xys:"x\<in>s" "y\<in>s" and xy:"\<forall>u\<in>s. \<forall>v\<in>s. norm (u - v) \<le> norm (x - y)" using compact_sup_maxdistance[OF assms] by auto
  4359   hence "diameter s \<le> norm (x - y)"
  4360     unfolding diameter_def by clarsimp (rule Sup_least, fast+)
  4361   thus ?thesis
  4362     by (metis b diameter_bounded_bound order_antisym xys)
  4363 qed
  4364 
  4365 text {* Related results with closure as the conclusion. *}
  4366 
  4367 lemma closed_scaling:
  4368   fixes s :: "'a::real_normed_vector set"
  4369   assumes "closed s" shows "closed ((\<lambda>x. c *\<^sub>R x) ` s)"
  4370 proof(cases "s={}")
  4371   case True thus ?thesis by auto
  4372 next
  4373   case False
  4374   show ?thesis
  4375   proof(cases "c=0")
  4376     have *:"(\<lambda>x. 0) ` s = {0}" using `s\<noteq>{}` by auto
  4377     case True thus ?thesis apply auto unfolding * by auto
  4378   next
  4379     case False
  4380     { fix x l assume as:"\<forall>n::nat. x n \<in> scaleR c ` s"  "(x ---> l) sequentially"
  4381       { fix n::nat have "scaleR (1 / c) (x n) \<in> s"
  4382           using as(1)[THEN spec[where x=n]]
  4383           using `c\<noteq>0` by auto
  4384       }
  4385       moreover
  4386       { fix e::real assume "e>0"
  4387         hence "0 < e *\<bar>c\<bar>"  using `c\<noteq>0` mult_pos_pos[of e "abs c"] by auto
  4388         then obtain N where "\<forall>n\<ge>N. dist (x n) l < e * \<bar>c\<bar>"
  4389           using as(2)[unfolded Lim_sequentially, THEN spec[where x="e * abs c"]] by auto
  4390         hence "\<exists>N. \<forall>n\<ge>N. dist (scaleR (1 / c) (x n)) (scaleR (1 / c) l) < e"
  4391           unfolding dist_norm unfolding scaleR_right_diff_distrib[THEN sym]
  4392           using mult_imp_div_pos_less[of "abs c" _ e] `c\<noteq>0` by auto  }
  4393       hence "((\<lambda>n. scaleR (1 / c) (x n)) ---> scaleR (1 / c) l) sequentially" unfolding Lim_sequentially by auto
  4394       ultimately have "l \<in> scaleR c ` s"
  4395         using assms[unfolded closed_sequential_limits, THEN spec[where x="\<lambda>n. scaleR (1/c) (x n)"], THEN spec[where x="scaleR (1/c) l"]]
  4396         unfolding image_iff using `c\<noteq>0` apply(rule_tac x="scaleR (1 / c) l" in bexI) by auto  }
  4397     thus ?thesis unfolding closed_sequential_limits by fast
  4398   qed
  4399 qed
  4400 
  4401 lemma closed_negations:
  4402   fixes s :: "'a::real_normed_vector set"
  4403   assumes "closed s"  shows "closed ((\<lambda>x. -x) ` s)"
  4404   using closed_scaling[OF assms, of "- 1"] by simp
  4405 
  4406 lemma compact_closed_sums:
  4407   fixes s :: "'a::real_normed_vector set"
  4408   assumes "compact s"  "closed t"  shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  4409 proof-
  4410   let ?S = "{x + y |x y. x \<in> s \<and> y \<in> t}"
  4411   { fix x l assume as:"\<forall>n. x n \<in> ?S"  "(x ---> l) sequentially"
  4412     from as(1) obtain f where f:"\<forall>n. x n = fst (f n) + snd (f n)"  "\<forall>n. fst (f n) \<in> s"  "\<forall>n. snd (f n) \<in> t"
  4413       using choice[of "\<lambda>n y. x n = (fst y) + (snd y) \<and> fst y \<in> s \<and> snd y \<in> t"] by auto
  4414     obtain l' r where "l'\<in>s" and r:"subseq r" and lr:"(((\<lambda>n. fst (f n)) \<circ> r) ---> l') sequentially"
  4415       using assms(1)[unfolded compact_def, THEN spec[where x="\<lambda> n. fst (f n)"]] using f(2) by auto
  4416     have "((\<lambda>n. snd (f (r n))) ---> l - l') sequentially"
  4417       using tendsto_diff[OF lim_subseq[OF r as(2)] lr] and f(1) unfolding o_def by auto
  4418     hence "l - l' \<in> t"
  4419       using assms(2)[unfolded closed_sequential_limits, THEN spec[where x="\<lambda> n. snd (f (r n))"], THEN spec[where x="l - l'"]]
  4420       using f(3) by auto
  4421     hence "l \<in> ?S" using `l' \<in> s` apply auto apply(rule_tac x=l' in exI) apply(rule_tac x="l - l'" in exI) by auto
  4422   }
  4423   thus ?thesis unfolding closed_sequential_limits by fast
  4424 qed
  4425 
  4426 lemma closed_compact_sums:
  4427   fixes s t :: "'a::real_normed_vector set"
  4428   assumes "closed s"  "compact t"
  4429   shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  4430 proof-
  4431   have "{x + y |x y. x \<in> t \<and> y \<in> s} = {x + y |x y. x \<in> s \<and> y \<in> t}" apply auto
  4432     apply(rule_tac x=y in exI) apply auto apply(rule_tac x=y in exI) by auto
  4433   thus ?thesis using compact_closed_sums[OF assms(2,1)] by simp
  4434 qed
  4435 
  4436 lemma compact_closed_differences:
  4437   fixes s t :: "'a::real_normed_vector set"
  4438   assumes "compact s"  "closed t"
  4439   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  4440 proof-
  4441   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} =  {x - y |x y. x \<in> s \<and> y \<in> t}"
  4442     apply auto apply(rule_tac x=xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4443   thus ?thesis using compact_closed_sums[OF assms(1) closed_negations[OF assms(2)]] by auto
  4444 qed
  4445 
  4446 lemma closed_compact_differences:
  4447   fixes s t :: "'a::real_normed_vector set"
  4448   assumes "closed s" "compact t"
  4449   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  4450 proof-
  4451   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} = {x - y |x y. x \<in> s \<and> y \<in> t}"
  4452     apply auto apply(rule_tac x=xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4453  thus ?thesis using closed_compact_sums[OF assms(1) compact_negations[OF assms(2)]] by simp
  4454 qed
  4455 
  4456 lemma closed_translation:
  4457   fixes a :: "'a::real_normed_vector"
  4458   assumes "closed s"  shows "closed ((\<lambda>x. a + x) ` s)"
  4459 proof-
  4460   have "{a + y |y. y \<in> s} = (op + a ` s)" by auto
  4461   thus ?thesis using compact_closed_sums[OF compact_sing[of a] assms] by auto
  4462 qed
  4463 
  4464 lemma translation_Compl:
  4465   fixes a :: "'a::ab_group_add"
  4466   shows "(\<lambda>x. a + x) ` (- t) = - ((\<lambda>x. a + x) ` t)"
  4467   apply (auto simp add: image_iff) apply(rule_tac x="x - a" in bexI) by auto
  4468 
  4469 lemma translation_UNIV:
  4470   fixes a :: "'a::ab_group_add" shows "range (\<lambda>x. a + x) = UNIV"
  4471   apply (auto simp add: image_iff) apply(rule_tac x="x - a" in exI) by auto
  4472 
  4473 lemma translation_diff:
  4474   fixes a :: "'a::ab_group_add"
  4475   shows "(\<lambda>x. a + x) ` (s - t) = ((\<lambda>x. a + x) ` s) - ((\<lambda>x. a + x) ` t)"
  4476   by auto
  4477 
  4478 lemma closure_translation:
  4479   fixes a :: "'a::real_normed_vector"
  4480   shows "closure ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (closure s)"
  4481 proof-
  4482   have *:"op + a ` (- s) = - op + a ` s"
  4483     apply auto unfolding image_iff apply(rule_tac x="x - a" in bexI) by auto
  4484   show ?thesis unfolding closure_interior translation_Compl
  4485     using interior_translation[of a "- s"] unfolding * by auto
  4486 qed
  4487 
  4488 lemma frontier_translation:
  4489   fixes a :: "'a::real_normed_vector"
  4490   shows "frontier((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (frontier s)"
  4491   unfolding frontier_def translation_diff interior_translation closure_translation by auto
  4492 
  4493 
  4494 subsection {* Separation between points and sets *}
  4495 
  4496 lemma separate_point_closed:
  4497   fixes s :: "'a::heine_borel set"
  4498   shows "closed s \<Longrightarrow> a \<notin> s  ==> (\<exists>d>0. \<forall>x\<in>s. d \<le> dist a x)"
  4499 proof(cases "s = {}")
  4500   case True
  4501   thus ?thesis by(auto intro!: exI[where x=1])
  4502 next
  4503   case False
  4504   assume "closed s" "a \<notin> s"
  4505   then obtain x where "x\<in>s" "\<forall>y\<in>s. dist a x \<le> dist a y" using `s \<noteq> {}` distance_attains_inf [of s a] by blast
  4506   with `x\<in>s` show ?thesis using dist_pos_lt[of a x] and`a \<notin> s` by blast
  4507 qed
  4508 
  4509 lemma separate_compact_closed:
  4510   fixes s t :: "'a::{heine_borel, real_normed_vector} set"
  4511     (* TODO: does this generalize to heine_borel? *)
  4512   assumes "compact s" and "closed t" and "s \<inter> t = {}"
  4513   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  4514 proof-
  4515   have "0 \<notin> {x - y |x y. x \<in> s \<and> y \<in> t}" using assms(3) by auto
  4516   then obtain d where "d>0" and d:"\<forall>x\<in>{x - y |x y. x \<in> s \<and> y \<in> t}. d \<le> dist 0 x"
  4517     using separate_point_closed[OF compact_closed_differences[OF assms(1,2)], of 0] by auto
  4518   { fix x y assume "x\<in>s" "y\<in>t"
  4519     hence "x - y \<in> {x - y |x y. x \<in> s \<and> y \<in> t}" by auto
  4520     hence "d \<le> dist (x - y) 0" using d[THEN bspec[where x="x - y"]] using dist_commute
  4521       by (auto  simp add: dist_commute)
  4522     hence "d \<le> dist x y" unfolding dist_norm by auto  }
  4523   thus ?thesis using `d>0` by auto
  4524 qed
  4525 
  4526 lemma separate_closed_compact:
  4527   fixes s t :: "'a::{heine_borel, real_normed_vector} set"
  4528   assumes "closed s" and "compact t" and "s \<inter> t = {}"
  4529   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  4530 proof-
  4531   have *:"t \<inter> s = {}" using assms(3) by auto
  4532   show ?thesis using separate_compact_closed[OF assms(2,1) *]
  4533     apply auto apply(rule_tac x=d in exI) apply auto apply (erule_tac x=y in ballE)
  4534     by (auto simp add: dist_commute)
  4535 qed
  4536 
  4537 
  4538 subsection {* Intervals *}
  4539   
  4540 lemma interval: fixes a :: "'a::ordered_euclidean_space" shows
  4541   "{a <..< b} = {x::'a. \<forall>i<DIM('a). a$$i < x$$i \<and> x$$i < b$$i}" and
  4542   "{a .. b} = {x::'a. \<forall>i<DIM('a). a$$i \<le> x$$i \<and> x$$i \<le> b$$i}"
  4543   by(auto simp add:set_eq_iff eucl_le[where 'a='a] eucl_less[where 'a='a])
  4544 
  4545 lemma mem_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4546   "x \<in> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i < x$$i \<and> x$$i < b$$i)"
  4547   "x \<in> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i \<le> x$$i \<and> x$$i \<le> b$$i)"
  4548   using interval[of a b] by(auto simp add: set_eq_iff eucl_le[where 'a='a] eucl_less[where 'a='a])
  4549 
  4550 lemma interval_eq_empty: fixes a :: "'a::ordered_euclidean_space" shows
  4551  "({a <..< b} = {} \<longleftrightarrow> (\<exists>i<DIM('a). b$$i \<le> a$$i))" (is ?th1) and
  4552  "({a  ..  b} = {} \<longleftrightarrow> (\<exists>i<DIM('a). b$$i < a$$i))" (is ?th2)
  4553 proof-
  4554   { fix i x assume i:"i<DIM('a)" and as:"b$$i \<le> a$$i" and x:"x\<in>{a <..< b}"
  4555     hence "a $$ i < x $$ i \<and> x $$ i < b $$ i" unfolding mem_interval by auto
  4556     hence "a$$i < b$$i" by auto
  4557     hence False using as by auto  }
  4558   moreover
  4559   { assume as:"\<forall>i<DIM('a). \<not> (b$$i \<le> a$$i)"
  4560     let ?x = "(1/2) *\<^sub>R (a + b)"
  4561     { fix i assume i:"i<DIM('a)" 
  4562       have "a$$i < b$$i" using as[THEN spec[where x=i]] using i by auto
  4563       hence "a$$i < ((1/2) *\<^sub>R (a+b)) $$ i" "((1/2) *\<^sub>R (a+b)) $$ i < b$$i"
  4564         unfolding euclidean_simps by auto }
  4565     hence "{a <..< b} \<noteq> {}" using mem_interval(1)[of "?x" a b] by auto  }
  4566   ultimately show ?th1 by blast
  4567 
  4568   { fix i x assume i:"i<DIM('a)" and as:"b$$i < a$$i" and x:"x\<in>{a .. b}"
  4569     hence "a $$ i \<le> x $$ i \<and> x $$ i \<le> b $$ i" unfolding mem_interval by auto
  4570     hence "a$$i \<le> b$$i" by auto
  4571     hence False using as by auto  }
  4572   moreover
  4573   { assume as:"\<forall>i<DIM('a). \<not> (b$$i < a$$i)"
  4574     let ?x = "(1/2) *\<^sub>R (a + b)"
  4575     { fix i assume i:"i<DIM('a)"
  4576       have "a$$i \<le> b$$i" using as[THEN spec[where x=i]] by auto
  4577       hence "a$$i \<le> ((1/2) *\<^sub>R (a+b)) $$ i" "((1/2) *\<^sub>R (a+b)) $$ i \<le> b$$i"
  4578         unfolding euclidean_simps by auto }
  4579     hence "{a .. b} \<noteq> {}" using mem_interval(2)[of "?x" a b] by auto  }
  4580   ultimately show ?th2 by blast
  4581 qed
  4582 
  4583 lemma interval_ne_empty: fixes a :: "'a::ordered_euclidean_space" shows
  4584   "{a  ..  b} \<noteq> {} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i \<le> b$$i)" and
  4585   "{a <..< b} \<noteq> {} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i < b$$i)"
  4586   unfolding interval_eq_empty[of a b] by fastsimp+
  4587 
  4588 lemma interval_sing:
  4589   fixes a :: "'a::ordered_euclidean_space"
  4590   shows "{a .. a} = {a}" and "{a<..<a} = {}"
  4591   unfolding set_eq_iff mem_interval eq_iff [symmetric]
  4592   by (auto simp add: euclidean_eq[where 'a='a] eq_commute
  4593     eucl_less[where 'a='a] eucl_le[where 'a='a])
  4594 
  4595 lemma subset_interval_imp: fixes a :: "'a::ordered_euclidean_space" shows
  4596  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c .. d} \<subseteq> {a .. b}" and
  4597  "(\<forall>i<DIM('a). a$$i < c$$i \<and> d$$i < b$$i) \<Longrightarrow> {c .. d} \<subseteq> {a<..<b}" and
  4598  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c<..<d} \<subseteq> {a .. b}" and
  4599  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c<..<d} \<subseteq> {a<..<b}"
  4600   unfolding subset_eq[unfolded Ball_def] unfolding mem_interval
  4601   by (best intro: order_trans less_le_trans le_less_trans less_imp_le)+
  4602 
  4603 lemma interval_open_subset_closed:
  4604   fixes a :: "'a::ordered_euclidean_space"
  4605   shows "{a<..<b} \<subseteq> {a .. b}"
  4606   unfolding subset_eq [unfolded Ball_def] mem_interval
  4607   by (fast intro: less_imp_le)
  4608 
  4609 lemma subset_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4610  "{c .. d} \<subseteq> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i \<le> d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th1) and
  4611  "{c .. d} \<subseteq> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i \<le> d$$i) --> (\<forall>i<DIM('a). a$$i < c$$i \<and> d$$i < b$$i)" (is ?th2) and
  4612  "{c<..<d} \<subseteq> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i < d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th3) and
  4613  "{c<..<d} \<subseteq> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i < d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th4)
  4614 proof-
  4615   show ?th1 unfolding subset_eq and Ball_def and mem_interval by (auto intro: order_trans)
  4616   show ?th2 unfolding subset_eq and Ball_def and mem_interval by (auto intro: le_less_trans less_le_trans order_trans less_imp_le)
  4617   { assume as: "{c<..<d} \<subseteq> {a .. b}" "\<forall>i<DIM('a). c$$i < d$$i"
  4618     hence "{c<..<d} \<noteq> {}" unfolding interval_eq_empty by auto
  4619     fix i assume i:"i<DIM('a)"
  4620     (** TODO combine the following two parts as done in the HOL_light version. **)
  4621     { let ?x = "(\<chi>\<chi> j. (if j=i then ((min (a$$j) (d$$j))+c$$j)/2 else (c$$j+d$$j)/2))::'a"
  4622       assume as2: "a$$i > c$$i"
  4623       { fix j assume j:"j<DIM('a)"
  4624         hence "c $$ j < ?x $$ j \<and> ?x $$ j < d $$ j"
  4625           apply(cases "j=i") using as(2)[THEN spec[where x=j]] i
  4626           by (auto simp add: as2)  }
  4627       hence "?x\<in>{c<..<d}" using i unfolding mem_interval by auto
  4628       moreover
  4629       have "?x\<notin>{a .. b}"
  4630         unfolding mem_interval apply auto apply(rule_tac x=i in exI)
  4631         using as(2)[THEN spec[where x=i]] and as2 i
  4632         by auto
  4633       ultimately have False using as by auto  }
  4634     hence "a$$i \<le> c$$i" by(rule ccontr)auto
  4635     moreover
  4636     { let ?x = "(\<chi>\<chi> j. (if j=i then ((max (b$$j) (c$$j))+d$$j)/2 else (c$$j+d$$j)/2))::'a"
  4637       assume as2: "b$$i < d$$i"
  4638       { fix j assume "j<DIM('a)"
  4639         hence "d $$ j > ?x $$ j \<and> ?x $$ j > c $$ j" 
  4640           apply(cases "j=i") using as(2)[THEN spec[where x=j]]
  4641           by (auto simp add: as2)  }
  4642       hence "?x\<in>{c<..<d}" unfolding mem_interval by auto
  4643       moreover
  4644       have "?x\<notin>{a .. b}"
  4645         unfolding mem_interval apply auto apply(rule_tac x=i in exI)
  4646         using as(2)[THEN spec[where x=i]] and as2 using i
  4647         by auto
  4648       ultimately have False using as by auto  }
  4649     hence "b$$i \<ge> d$$i" by(rule ccontr)auto
  4650     ultimately
  4651     have "a$$i \<le> c$$i \<and> d$$i \<le> b$$i" by auto
  4652   } note part1 = this
  4653   show ?th3 unfolding subset_eq and Ball_def and mem_interval 
  4654     apply(rule,rule,rule,rule) apply(rule part1) unfolding subset_eq and Ball_def and mem_interval
  4655     prefer 4 apply auto by(erule_tac x=i in allE,erule_tac x=i in allE,fastsimp)+ 
  4656   { assume as:"{c<..<d} \<subseteq> {a<..<b}" "\<forall>i<DIM('a). c$$i < d$$i"
  4657     fix i assume i:"i<DIM('a)"
  4658     from as(1) have "{c<..<d} \<subseteq> {a..b}" using interval_open_subset_closed[of a b] by auto
  4659     hence "a$$i \<le> c$$i \<and> d$$i \<le> b$$i" using part1 and as(2) using i by auto  } note * = this
  4660   show ?th4 unfolding subset_eq and Ball_def and mem_interval 
  4661     apply(rule,rule,rule,rule) apply(rule *) unfolding subset_eq and Ball_def and mem_interval prefer 4
  4662     apply auto by(erule_tac x=i in allE, simp)+ 
  4663 qed
  4664 
  4665 lemma disjoint_interval: fixes a::"'a::ordered_euclidean_space" shows
  4666   "{a .. b} \<inter> {c .. d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i < a$$i \<or> d$$i < c$$i \<or> b$$i < c$$i \<or> d$$i < a$$i))" (is ?th1) and
  4667   "{a .. b} \<inter> {c<..<d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i < a$$i \<or> d$$i \<le> c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th2) and
  4668   "{a<..<b} \<inter> {c .. d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i \<le> a$$i \<or> d$$i < c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th3) and
  4669   "{a<..<b} \<inter> {c<..<d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i \<le> a$$i \<or> d$$i \<le> c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th4)
  4670 proof-
  4671   let ?z = "(\<chi>\<chi> i. ((max (a$$i) (c$$i)) + (min (b$$i) (d$$i))) / 2)::'a"
  4672   note * = set_eq_iff Int_iff empty_iff mem_interval all_conj_distrib[THEN sym] eq_False
  4673   show ?th1 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4674     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4675   show ?th2 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4676     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4677   show ?th3 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4678     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4679   show ?th4 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4680     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4681 qed
  4682 
  4683 lemma inter_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4684  "{a .. b} \<inter> {c .. d} =  {(\<chi>\<chi> i. max (a$$i) (c$$i)) .. (\<chi>\<chi> i. min (b$$i) (d$$i))}"
  4685   unfolding set_eq_iff and Int_iff and mem_interval
  4686   by auto
  4687 
  4688 (* Moved interval_open_subset_closed a bit upwards *)
  4689 
  4690 lemma open_interval[intro]:
  4691   fixes a b :: "'a::ordered_euclidean_space" shows "open {a<..<b}"
  4692 proof-
  4693   have "open (\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i<..<b$$i})"
  4694     by (intro open_INT finite_lessThan ballI continuous_open_vimage allI
  4695       linear_continuous_at bounded_linear_euclidean_component
  4696       open_real_greaterThanLessThan)
  4697   also have "(\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i<..<b$$i}) = {a<..<b}"
  4698     by (auto simp add: eucl_less [where 'a='a])
  4699   finally show "open {a<..<b}" .
  4700 qed
  4701 
  4702 lemma closed_interval[intro]:
  4703   fixes a b :: "'a::ordered_euclidean_space" shows "closed {a .. b}"
  4704 proof-
  4705   have "closed (\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i .. b$$i})"
  4706     by (intro closed_INT ballI continuous_closed_vimage allI
  4707       linear_continuous_at bounded_linear_euclidean_component
  4708       closed_real_atLeastAtMost)
  4709   also have "(\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i .. b$$i}) = {a .. b}"
  4710     by (auto simp add: eucl_le [where 'a='a])
  4711   finally show "closed {a .. b}" .
  4712 qed
  4713 
  4714 lemma interior_closed_interval [intro]:
  4715   fixes a b :: "'a::ordered_euclidean_space"
  4716   shows "interior {a..b} = {a<..<b}" (is "?L = ?R")
  4717 proof(rule subset_antisym)
  4718   show "?R \<subseteq> ?L" using interval_open_subset_closed open_interval
  4719     by (rule interior_maximal)
  4720 next
  4721   { fix x assume "x \<in> interior {a..b}"
  4722     then obtain s where s:"open s" "x \<in> s" "s \<subseteq> {a..b}" ..
  4723     then obtain e where "e>0" and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> {a..b}" unfolding open_dist and subset_eq by auto
  4724     { fix i assume i:"i<DIM('a)"
  4725       have "dist (x - (e / 2) *\<^sub>R basis i) x < e"
  4726            "dist (x + (e / 2) *\<^sub>R basis i) x < e"
  4727         unfolding dist_norm apply auto
  4728         unfolding norm_minus_cancel using norm_basis and `e>0` by auto
  4729       hence "a $$ i \<le> (x - (e / 2) *\<^sub>R basis i) $$ i"
  4730                      "(x + (e / 2) *\<^sub>R basis i) $$ i \<le> b $$ i"
  4731         using e[THEN spec[where x="x - (e/2) *\<^sub>R basis i"]]
  4732         and   e[THEN spec[where x="x + (e/2) *\<^sub>R basis i"]]
  4733         unfolding mem_interval using i by blast+
  4734       hence "a $$ i < x $$ i" and "x $$ i < b $$ i" unfolding euclidean_simps
  4735         unfolding basis_component using `e>0` i by auto  }
  4736     hence "x \<in> {a<..<b}" unfolding mem_interval by auto  }
  4737   thus "?L \<subseteq> ?R" ..
  4738 qed
  4739 
  4740 lemma bounded_closed_interval: fixes a :: "'a::ordered_euclidean_space" shows "bounded {a .. b}"
  4741 proof-
  4742   let ?b = "\<Sum>i<DIM('a). \<bar>a$$i\<bar> + \<bar>b$$i\<bar>"
  4743   { fix x::"'a" assume x:"\<forall>i<DIM('a). a $$ i \<le> x $$ i \<and> x $$ i \<le> b $$ i"
  4744     { fix i assume "i<DIM('a)"
  4745       hence "\<bar>x$$i\<bar> \<le> \<bar>a$$i\<bar> + \<bar>b$$i\<bar>" using x[THEN spec[where x=i]] by auto  }
  4746     hence "(\<Sum>i<DIM('a). \<bar>x $$ i\<bar>) \<le> ?b" apply-apply(rule setsum_mono) by auto
  4747     hence "norm x \<le> ?b" using norm_le_l1[of x] by auto  }
  4748   thus ?thesis unfolding interval and bounded_iff by auto
  4749 qed
  4750 
  4751 lemma bounded_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4752  "bounded {a .. b} \<and> bounded {a<..<b}"
  4753   using bounded_closed_interval[of a b]
  4754   using interval_open_subset_closed[of a b]
  4755   using bounded_subset[of "{a..b}" "{a<..<b}"]
  4756   by simp
  4757 
  4758 lemma not_interval_univ: fixes a :: "'a::ordered_euclidean_space" shows
  4759  "({a .. b} \<noteq> UNIV) \<and> ({a<..<b} \<noteq> UNIV)"
  4760   using bounded_interval[of a b] by auto
  4761 
  4762 lemma compact_interval: fixes a :: "'a::ordered_euclidean_space" shows "compact {a .. b}"
  4763   using bounded_closed_imp_compact[of "{a..b}"] using bounded_interval[of a b]
  4764   by auto
  4765 
  4766 lemma open_interval_midpoint: fixes a :: "'a::ordered_euclidean_space"
  4767   assumes "{a<..<b} \<noteq> {}" shows "((1/2) *\<^sub>R (a + b)) \<in> {a<..<b}"
  4768 proof-
  4769   { fix i assume "i<DIM('a)"
  4770     hence "a $$ i < ((1 / 2) *\<^sub>R (a + b)) $$ i \<and> ((1 / 2) *\<^sub>R (a + b)) $$ i < b $$ i"
  4771       using assms[unfolded interval_ne_empty, THEN spec[where x=i]]
  4772       unfolding euclidean_simps by auto  }
  4773   thus ?thesis unfolding mem_interval by auto
  4774 qed
  4775 
  4776 lemma open_closed_interval_convex: fixes x :: "'a::ordered_euclidean_space"
  4777   assumes x:"x \<in> {a<..<b}" and y:"y \<in> {a .. b}" and e:"0 < e" "e \<le> 1"
  4778   shows "(e *\<^sub>R x + (1 - e) *\<^sub>R y) \<in> {a<..<b}"
  4779 proof-
  4780   { fix i assume i:"i<DIM('a)"
  4781     have "a $$ i = e * a$$i + (1 - e) * a$$i" unfolding left_diff_distrib by simp
  4782     also have "\<dots> < e * x $$ i + (1 - e) * y $$ i" apply(rule add_less_le_mono)
  4783       using e unfolding mult_less_cancel_left and mult_le_cancel_left apply simp_all
  4784       using x unfolding mem_interval using i apply simp
  4785       using y unfolding mem_interval using i apply simp
  4786       done
  4787     finally have "a $$ i < (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i" unfolding euclidean_simps by auto
  4788     moreover {
  4789     have "b $$ i = e * b$$i + (1 - e) * b$$i" unfolding left_diff_distrib by simp
  4790     also have "\<dots> > e * x $$ i + (1 - e) * y $$ i" apply(rule add_less_le_mono)
  4791       using e unfolding mult_less_cancel_left and mult_le_cancel_left apply simp_all
  4792       using x unfolding mem_interval using i apply simp
  4793       using y unfolding mem_interval using i apply simp
  4794       done
  4795     finally have "(e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i < b $$ i" unfolding euclidean_simps by auto
  4796     } ultimately have "a $$ i < (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i \<and> (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i < b $$ i" by auto }
  4797   thus ?thesis unfolding mem_interval by auto
  4798 qed
  4799 
  4800 lemma closure_open_interval: fixes a :: "'a::ordered_euclidean_space"
  4801   assumes "{a<..<b} \<noteq> {}"
  4802   shows "closure {a<..<b} = {a .. b}"
  4803 proof-
  4804   have ab:"a < b" using assms[unfolded interval_ne_empty] apply(subst eucl_less) by auto
  4805   let ?c = "(1 / 2) *\<^sub>R (a + b)"
  4806   { fix x assume as:"x \<in> {a .. b}"
  4807     def f == "\<lambda>n::nat. x + (inverse (real n + 1)) *\<^sub>R (?c - x)"
  4808     { fix n assume fn:"f n < b \<longrightarrow> a < f n \<longrightarrow> f n = x" and xc:"x \<noteq> ?c"
  4809       have *:"0 < inverse (real n + 1)" "inverse (real n + 1) \<le> 1" unfolding inverse_le_1_iff by auto
  4810       have "(inverse (real n + 1)) *\<^sub>R ((1 / 2) *\<^sub>R (a + b)) + (1 - inverse (real n + 1)) *\<^sub>R x =
  4811         x + (inverse (real n + 1)) *\<^sub>R (((1 / 2) *\<^sub>R (a + b)) - x)"
  4812         by (auto simp add: algebra_simps)
  4813       hence "f n < b" and "a < f n" using open_closed_interval_convex[OF open_interval_midpoint[OF assms] as *] unfolding f_def by auto
  4814       hence False using fn unfolding f_def using xc by auto  }
  4815     moreover
  4816     { assume "\<not> (f ---> x) sequentially"
  4817       { fix e::real assume "e>0"
  4818         hence "\<exists>N::nat. inverse (real (N + 1)) < e" using real_arch_inv[of e] apply (auto simp add: Suc_pred') apply(rule_tac x="n - 1" in exI) by auto
  4819         then obtain N::nat where "inverse (real (N + 1)) < e" by auto
  4820         hence "\<forall>n\<ge>N. inverse (real n + 1) < e" by (auto, metis Suc_le_mono le_SucE less_imp_inverse_less nat_le_real_less order_less_trans real_of_nat_Suc real_of_nat_Suc_gt_zero)
  4821         hence "\<exists>N::nat. \<forall>n\<ge>N. inverse (real n + 1) < e" by auto  }
  4822       hence "((\<lambda>n. inverse (real n + 1)) ---> 0) sequentially"
  4823         unfolding Lim_sequentially by(auto simp add: dist_norm)
  4824       hence "(f ---> x) sequentially" unfolding f_def
  4825         using tendsto_add[OF tendsto_const, of "\<lambda>n::nat. (inverse (real n + 1)) *\<^sub>R ((1 / 2) *\<^sub>R (a + b) - x)" 0 sequentially x]
  4826         using tendsto_scaleR [OF _ tendsto_const, of "\<lambda>n::nat. inverse (real n + 1)" 0 sequentially "((1 / 2) *\<^sub>R (a + b) - x)"] by auto  }
  4827     ultimately have "x \<in> closure {a<..<b}"
  4828       using as and open_interval_midpoint[OF assms] unfolding closure_def unfolding islimpt_sequential by(cases "x=?c")auto  }
  4829   thus ?thesis using closure_minimal[OF interval_open_subset_closed closed_interval, of a b] by blast
  4830 qed
  4831 
  4832 lemma bounded_subset_open_interval_symmetric: fixes s::"('a::ordered_euclidean_space) set"
  4833   assumes "bounded s"  shows "\<exists>a. s \<subseteq> {-a<..<a}"
  4834 proof-
  4835   obtain b where "b>0" and b:"\<forall>x\<in>s. norm x \<le> b" using assms[unfolded bounded_pos] by auto
  4836   def a \<equiv> "(\<chi>\<chi> i. b+1)::'a"
  4837   { fix x assume "x\<in>s"
  4838     fix i assume i:"i<DIM('a)"
  4839     hence "(-a)$$i < x$$i" and "x$$i < a$$i" using b[THEN bspec[where x=x], OF `x\<in>s`]
  4840       and component_le_norm[of x i] unfolding euclidean_simps and a_def by auto  }
  4841   thus ?thesis by(auto intro: exI[where x=a] simp add: eucl_less[where 'a='a])
  4842 qed
  4843 
  4844 lemma bounded_subset_open_interval:
  4845   fixes s :: "('a::ordered_euclidean_space) set"
  4846   shows "bounded s ==> (\<exists>a b. s \<subseteq> {a<..<b})"
  4847   by (auto dest!: bounded_subset_open_interval_symmetric)
  4848 
  4849 lemma bounded_subset_closed_interval_symmetric:
  4850   fixes s :: "('a::ordered_euclidean_space) set"
  4851   assumes "bounded s" shows "\<exists>a. s \<subseteq> {-a .. a}"
  4852 proof-
  4853   obtain a where "s \<subseteq> {- a<..<a}" using bounded_subset_open_interval_symmetric[OF assms] by auto
  4854   thus ?thesis using interval_open_subset_closed[of "-a" a] by auto
  4855 qed
  4856 
  4857 lemma bounded_subset_closed_interval:
  4858   fixes s :: "('a::ordered_euclidean_space) set"
  4859   shows "bounded s ==> (\<exists>a b. s \<subseteq> {a .. b})"
  4860   using bounded_subset_closed_interval_symmetric[of s] by auto
  4861 
  4862 lemma frontier_closed_interval:
  4863   fixes a b :: "'a::ordered_euclidean_space"
  4864   shows "frontier {a .. b} = {a .. b} - {a<..<b}"
  4865   unfolding frontier_def unfolding interior_closed_interval and closure_closed[OF closed_interval] ..
  4866 
  4867 lemma frontier_open_interval:
  4868   fixes a b :: "'a::ordered_euclidean_space"
  4869   shows "frontier {a<..<b} = (if {a<..<b} = {} then {} else {a .. b} - {a<..<b})"
  4870 proof(cases "{a<..<b} = {}")
  4871   case True thus ?thesis using frontier_empty by auto
  4872 next
  4873   case False thus ?thesis unfolding frontier_def and closure_open_interval[OF False] and interior_open[OF open_interval] by auto
  4874 qed
  4875 
  4876 lemma inter_interval_mixed_eq_empty: fixes a :: "'a::ordered_euclidean_space"
  4877   assumes "{c<..<d} \<noteq> {}"  shows "{a<..<b} \<inter> {c .. d} = {} \<longleftrightarrow> {a<..<b} \<inter> {c<..<d} = {}"
  4878   unfolding closure_open_interval[OF assms, THEN sym] unfolding open_inter_closure_eq_empty[OF open_interval] ..
  4879 
  4880 
  4881 (* Some stuff for half-infinite intervals too; FIXME: notation?  *)
  4882 
  4883 lemma closed_interval_left: fixes b::"'a::euclidean_space"
  4884   shows "closed {x::'a. \<forall>i<DIM('a). x$$i \<le> b$$i}"
  4885 proof-
  4886   { fix i assume i:"i<DIM('a)"
  4887     fix x::"'a" assume x:"\<forall>e>0. \<exists>x'\<in>{x. \<forall>i<DIM('a). x $$ i \<le> b $$ i}. x' \<noteq> x \<and> dist x' x < e"
  4888     { assume "x$$i > b$$i"
  4889       then obtain y where "y $$ i \<le> b $$ i"  "y \<noteq> x"  "dist y x < x$$i - b$$i"
  4890         using x[THEN spec[where x="x$$i - b$$i"]] using i by auto
  4891       hence False using component_le_norm[of "y - x" i] unfolding dist_norm euclidean_simps using i 
  4892         by auto   }
  4893     hence "x$$i \<le> b$$i" by(rule ccontr)auto  }
  4894   thus ?thesis unfolding closed_limpt unfolding islimpt_approachable by blast
  4895 qed
  4896 
  4897 lemma closed_interval_right: fixes a::"'a::euclidean_space"
  4898   shows "closed {x::'a. \<forall>i<DIM('a). a$$i \<le> x$$i}"
  4899 proof-
  4900   { fix i assume i:"i<DIM('a)"
  4901     fix x::"'a" assume x:"\<forall>e>0. \<exists>x'\<in>{x. \<forall>i<DIM('a). a $$ i \<le> x $$ i}. x' \<noteq> x \<and> dist x' x < e"
  4902     { assume "a$$i > x$$i"
  4903       then obtain y where "a $$ i \<le> y $$ i"  "y \<noteq> x"  "dist y x < a$$i - x$$i"
  4904         using x[THEN spec[where x="a$$i - x$$i"]] i by auto
  4905       hence False using component_le_norm[of "y - x" i] unfolding dist_norm and euclidean_simps by auto   }
  4906     hence "a$$i \<le> x$$i" by(rule ccontr)auto  }
  4907   thus ?thesis unfolding closed_limpt unfolding islimpt_approachable by blast
  4908 qed
  4909 
  4910 text {* Intervals in general, including infinite and mixtures of open and closed. *}
  4911 
  4912 definition "is_interval (s::('a::euclidean_space) set) \<longleftrightarrow>
  4913   (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i<DIM('a). ((a$$i \<le> x$$i \<and> x$$i \<le> b$$i) \<or> (b$$i \<le> x$$i \<and> x$$i \<le> a$$i))) \<longrightarrow> x \<in> s)"
  4914 
  4915 lemma is_interval_interval: "is_interval {a .. b::'a::ordered_euclidean_space}" (is ?th1)
  4916   "is_interval {a<..<b}" (is ?th2) proof -
  4917   show ?th1 ?th2  unfolding is_interval_def mem_interval Ball_def atLeastAtMost_iff
  4918     by(meson order_trans le_less_trans less_le_trans less_trans)+ qed
  4919 
  4920 lemma is_interval_empty:
  4921  "is_interval {}"
  4922   unfolding is_interval_def
  4923   by simp
  4924 
  4925 lemma is_interval_univ:
  4926  "is_interval UNIV"
  4927   unfolding is_interval_def
  4928   by simp
  4929 
  4930 
  4931 subsection {* Closure of halfspaces and hyperplanes *}
  4932 
  4933 lemma isCont_open_vimage:
  4934   assumes "\<And>x. isCont f x" and "open s" shows "open (f -` s)"
  4935 proof -
  4936   from assms(1) have "continuous_on UNIV f"
  4937     unfolding isCont_def continuous_on_def within_UNIV by simp
  4938   hence "open {x \<in> UNIV. f x \<in> s}"
  4939     using open_UNIV `open s` by (rule continuous_open_preimage)
  4940   thus "open (f -` s)"
  4941     by (simp add: vimage_def)
  4942 qed
  4943 
  4944 lemma isCont_closed_vimage:
  4945   assumes "\<And>x. isCont f x" and "closed s" shows "closed (f -` s)"
  4946   using assms unfolding closed_def vimage_Compl [symmetric]
  4947   by (rule isCont_open_vimage)
  4948 
  4949 lemma open_Collect_less:
  4950   fixes f g :: "'a::topological_space \<Rightarrow> real"
  4951   assumes f: "\<And>x. isCont f x"
  4952   assumes g: "\<And>x. isCont g x"
  4953   shows "open {x. f x < g x}"
  4954 proof -
  4955   have "open ((\<lambda>x. g x - f x) -` {0<..})"
  4956     using isCont_diff [OF g f] open_real_greaterThan
  4957     by (rule isCont_open_vimage)
  4958   also have "((\<lambda>x. g x - f x) -` {0<..}) = {x. f x < g x}"
  4959     by auto
  4960   finally show ?thesis .
  4961 qed
  4962 
  4963 lemma closed_Collect_le:
  4964   fixes f g :: "'a::topological_space \<Rightarrow> real"
  4965   assumes f: "\<And>x. isCont f x"
  4966   assumes g: "\<And>x. isCont g x"
  4967   shows "closed {x. f x \<le> g x}"
  4968 proof -
  4969   have "closed ((\<lambda>x. g x - f x) -` {0..})"
  4970     using isCont_diff [OF g f] closed_real_atLeast
  4971     by (rule isCont_closed_vimage)
  4972   also have "((\<lambda>x. g x - f x) -` {0..}) = {x. f x \<le> g x}"
  4973     by auto
  4974   finally show ?thesis .
  4975 qed
  4976 
  4977 lemma closed_Collect_eq:
  4978   fixes f g :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  4979   assumes f: "\<And>x. isCont f x"
  4980   assumes g: "\<And>x. isCont g x"
  4981   shows "closed {x. f x = g x}"
  4982 proof -
  4983   have "open {(x::'b, y::'b). x \<noteq> y}"
  4984     unfolding open_prod_def by (auto dest!: hausdorff)
  4985   hence "closed {(x::'b, y::'b). x = y}"
  4986     unfolding closed_def split_def Collect_neg_eq .
  4987   with isCont_Pair [OF f g]
  4988   have "closed ((\<lambda>x. (f x, g x)) -` {(x, y). x = y})"
  4989     by (rule isCont_closed_vimage)
  4990   also have "\<dots> = {x. f x = g x}" by auto
  4991   finally show ?thesis .
  4992 qed
  4993 
  4994 lemma continuous_at_inner: "continuous (at x) (inner a)"
  4995   unfolding continuous_at by (intro tendsto_intros)
  4996 
  4997 lemma continuous_at_euclidean_component[intro!, simp]: "continuous (at x) (\<lambda>x. x $$ i)"
  4998   unfolding euclidean_component_def by (rule continuous_at_inner)
  4999 
  5000 lemma closed_halfspace_le: "closed {x. inner a x \<le> b}"
  5001   by (simp add: closed_Collect_le)
  5002 
  5003 lemma closed_halfspace_ge: "closed {x. inner a x \<ge> b}"
  5004   by (simp add: closed_Collect_le)
  5005 
  5006 lemma closed_hyperplane: "closed {x. inner a x = b}"
  5007   by (simp add: closed_Collect_eq)
  5008 
  5009 lemma closed_halfspace_component_le:
  5010   shows "closed {x::'a::euclidean_space. x$$i \<le> a}"
  5011   by (simp add: closed_Collect_le)
  5012 
  5013 lemma closed_halfspace_component_ge:
  5014   shows "closed {x::'a::euclidean_space. x$$i \<ge> a}"
  5015   by (simp add: closed_Collect_le)
  5016 
  5017 text {* Openness of halfspaces. *}
  5018 
  5019 lemma open_halfspace_lt: "open {x. inner a x < b}"
  5020   by (simp add: open_Collect_less)
  5021 
  5022 lemma open_halfspace_gt: "open {x. inner a x > b}"
  5023   by (simp add: open_Collect_less)
  5024 
  5025 lemma open_halfspace_component_lt:
  5026   shows "open {x::'a::euclidean_space. x$$i < a}"
  5027   by (simp add: open_Collect_less)
  5028 
  5029 lemma open_halfspace_component_gt:
  5030   shows "open {x::'a::euclidean_space. x$$i > a}"
  5031   by (simp add: open_Collect_less)
  5032 
  5033 text{* Instantiation for intervals on @{text ordered_euclidean_space} *}
  5034 
  5035 lemma eucl_lessThan_eq_halfspaces:
  5036   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5037   shows "{..<a} = (\<Inter>i<DIM('a). {x. x $$ i < a $$ i})"
  5038  by (auto simp: eucl_less[where 'a='a])
  5039 
  5040 lemma eucl_greaterThan_eq_halfspaces:
  5041   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5042   shows "{a<..} = (\<Inter>i<DIM('a). {x. a $$ i < x $$ i})"
  5043  by (auto simp: eucl_less[where 'a='a])
  5044 
  5045 lemma eucl_atMost_eq_halfspaces:
  5046   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5047   shows "{.. a} = (\<Inter>i<DIM('a). {x. x $$ i \<le> a $$ i})"
  5048  by (auto simp: eucl_le[where 'a='a])
  5049 
  5050 lemma eucl_atLeast_eq_halfspaces:
  5051   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5052   shows "{a ..} = (\<Inter>i<DIM('a). {x. a $$ i \<le> x $$ i})"
  5053  by (auto simp: eucl_le[where 'a='a])
  5054 
  5055 lemma open_eucl_lessThan[simp, intro]:
  5056   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5057   shows "open {..< a}"
  5058   by (auto simp: eucl_lessThan_eq_halfspaces open_halfspace_component_lt)
  5059 
  5060 lemma open_eucl_greaterThan[simp, intro]:
  5061   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5062   shows "open {a <..}"
  5063   by (auto simp: eucl_greaterThan_eq_halfspaces open_halfspace_component_gt)
  5064 
  5065 lemma closed_eucl_atMost[simp, intro]:
  5066   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5067   shows "closed {.. a}"
  5068   unfolding eucl_atMost_eq_halfspaces
  5069   by (simp add: closed_INT closed_Collect_le)
  5070 
  5071 lemma closed_eucl_atLeast[simp, intro]:
  5072   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5073   shows "closed {a ..}"
  5074   unfolding eucl_atLeast_eq_halfspaces
  5075   by (simp add: closed_INT closed_Collect_le)
  5076 
  5077 lemma open_vimage_euclidean_component: "open S \<Longrightarrow> open ((\<lambda>x. x $$ i) -` S)"
  5078   by (auto intro!: continuous_open_vimage)
  5079 
  5080 text {* This gives a simple derivation of limit component bounds. *}
  5081 
  5082 lemma Lim_component_le: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5083   assumes "(f ---> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f(x)$$i \<le> b) net"
  5084   shows "l$$i \<le> b"
  5085 proof-
  5086   { fix x have "x \<in> {x::'b. inner (basis i) x \<le> b} \<longleftrightarrow> x$$i \<le> b"
  5087       unfolding euclidean_component_def by auto  } note * = this
  5088   show ?thesis using Lim_in_closed_set[of "{x. inner (basis i) x \<le> b}" f net l] unfolding *
  5089     using closed_halfspace_le[of "(basis i)::'b" b] and assms(1,2,3) by auto
  5090 qed
  5091 
  5092 lemma Lim_component_ge: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5093   assumes "(f ---> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$$i) net"
  5094   shows "b \<le> l$$i"
  5095 proof-
  5096   { fix x have "x \<in> {x::'b. inner (basis i) x \<ge> b} \<longleftrightarrow> x$$i \<ge> b"
  5097       unfolding euclidean_component_def by auto  } note * = this
  5098   show ?thesis using Lim_in_closed_set[of "{x. inner (basis i) x \<ge> b}" f net l] unfolding *
  5099     using closed_halfspace_ge[of b "(basis i)"] and assms(1,2,3) by auto
  5100 qed
  5101 
  5102 lemma Lim_component_eq: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5103   assumes net:"(f ---> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$$i = b) net"
  5104   shows "l$$i = b"
  5105   using ev[unfolded order_eq_iff eventually_conj_iff] using Lim_component_ge[OF net, of b i] and Lim_component_le[OF net, of i b] by auto
  5106 text{* Limits relative to a union.                                               *}
  5107 
  5108 lemma eventually_within_Un:
  5109   "eventually P (net within (s \<union> t)) \<longleftrightarrow>
  5110     eventually P (net within s) \<and> eventually P (net within t)"
  5111   unfolding Limits.eventually_within
  5112   by (auto elim!: eventually_rev_mp)
  5113 
  5114 lemma Lim_within_union:
  5115  "(f ---> l) (net within (s \<union> t)) \<longleftrightarrow>
  5116   (f ---> l) (net within s) \<and> (f ---> l) (net within t)"
  5117   unfolding tendsto_def
  5118   by (auto simp add: eventually_within_Un)
  5119 
  5120 lemma Lim_topological:
  5121  "(f ---> l) net \<longleftrightarrow>
  5122         trivial_limit net \<or>
  5123         (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net)"
  5124   unfolding tendsto_def trivial_limit_eq by auto
  5125 
  5126 lemma continuous_on_union:
  5127   assumes "closed s" "closed t" "continuous_on s f" "continuous_on t f"
  5128   shows "continuous_on (s \<union> t) f"
  5129   using assms unfolding continuous_on Lim_within_union
  5130   unfolding Lim_topological trivial_limit_within closed_limpt by auto
  5131 
  5132 lemma continuous_on_cases:
  5133   assumes "closed s" "closed t" "continuous_on s f" "continuous_on t g"
  5134           "\<forall>x. (x\<in>s \<and> \<not> P x) \<or> (x \<in> t \<and> P x) \<longrightarrow> f x = g x"
  5135   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)"
  5136 proof-
  5137   let ?h = "(\<lambda>x. if P x then f x else g x)"
  5138   have "\<forall>x\<in>s. f x = (if P x then f x else g x)" using assms(5) by auto
  5139   hence "continuous_on s ?h" using continuous_on_eq[of s f ?h] using assms(3) by auto
  5140   moreover
  5141   have "\<forall>x\<in>t. g x = (if P x then f x else g x)" using assms(5) by auto
  5142   hence "continuous_on t ?h" using continuous_on_eq[of t g ?h] using assms(4) by auto
  5143   ultimately show ?thesis using continuous_on_union[OF assms(1,2), of ?h] by auto
  5144 qed
  5145 
  5146 
  5147 text{* Some more convenient intermediate-value theorem formulations.             *}
  5148 
  5149 lemma connected_ivt_hyperplane:
  5150   assumes "connected s" "x \<in> s" "y \<in> s" "inner a x \<le> b" "b \<le> inner a y"
  5151   shows "\<exists>z \<in> s. inner a z = b"
  5152 proof(rule ccontr)
  5153   assume as:"\<not> (\<exists>z\<in>s. inner a z = b)"
  5154   let ?A = "{x. inner a x < b}"
  5155   let ?B = "{x. inner a x > b}"
  5156   have "open ?A" "open ?B" using open_halfspace_lt and open_halfspace_gt by auto
  5157   moreover have "?A \<inter> ?B = {}" by auto
  5158   moreover have "s \<subseteq> ?A \<union> ?B" using as by auto
  5159   ultimately show False using assms(1)[unfolded connected_def not_ex, THEN spec[where x="?A"], THEN spec[where x="?B"]] and assms(2-5) by auto
  5160 qed
  5161 
  5162 lemma connected_ivt_component: fixes x::"'a::euclidean_space" shows
  5163  "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$$k \<le> a \<Longrightarrow> a \<le> y$$k \<Longrightarrow> (\<exists>z\<in>s.  z$$k = a)"
  5164   using connected_ivt_hyperplane[of s x y "(basis k)::'a" a]
  5165   unfolding euclidean_component_def by auto
  5166 
  5167 
  5168 subsection {* Homeomorphisms *}
  5169 
  5170 definition "homeomorphism s t f g \<equiv>
  5171      (\<forall>x\<in>s. (g(f x) = x)) \<and> (f ` s = t) \<and> continuous_on s f \<and>
  5172      (\<forall>y\<in>t. (f(g y) = y)) \<and> (g ` t = s) \<and> continuous_on t g"
  5173 
  5174 definition
  5175   homeomorphic :: "'a::metric_space set \<Rightarrow> 'b::metric_space set \<Rightarrow> bool"
  5176     (infixr "homeomorphic" 60) where
  5177   homeomorphic_def: "s homeomorphic t \<equiv> (\<exists>f g. homeomorphism s t f g)"
  5178 
  5179 lemma homeomorphic_refl: "s homeomorphic s"
  5180   unfolding homeomorphic_def
  5181   unfolding homeomorphism_def
  5182   using continuous_on_id
  5183   apply(rule_tac x = "(\<lambda>x. x)" in exI)
  5184   apply(rule_tac x = "(\<lambda>x. x)" in exI)
  5185   by blast
  5186 
  5187 lemma homeomorphic_sym:
  5188  "s homeomorphic t \<longleftrightarrow> t homeomorphic s"
  5189 unfolding homeomorphic_def
  5190 unfolding homeomorphism_def
  5191 by blast 
  5192 
  5193 lemma homeomorphic_trans:
  5194   assumes "s homeomorphic t" "t homeomorphic u" shows "s homeomorphic u"
  5195 proof-
  5196   obtain f1 g1 where fg1:"\<forall>x\<in>s. g1 (f1 x) = x"  "f1 ` s = t" "continuous_on s f1" "\<forall>y\<in>t. f1 (g1 y) = y" "g1 ` t = s" "continuous_on t g1"
  5197     using assms(1) unfolding homeomorphic_def homeomorphism_def by auto
  5198   obtain f2 g2 where fg2:"\<forall>x\<in>t. g2 (f2 x) = x"  "f2 ` t = u" "continuous_on t f2" "\<forall>y\<in>u. f2 (g2 y) = y" "g2 ` u = t" "continuous_on u g2"
  5199     using assms(2) unfolding homeomorphic_def homeomorphism_def by auto
  5200 
  5201   { fix x assume "x\<in>s" hence "(g1 \<circ> g2) ((f2 \<circ> f1) x) = x" using fg1(1)[THEN bspec[where x=x]] and fg2(1)[THEN bspec[where x="f1 x"]] and fg1(2) by auto }
  5202   moreover have "(f2 \<circ> f1) ` s = u" using fg1(2) fg2(2) by auto
  5203   moreover have "continuous_on s (f2 \<circ> f1)" using continuous_on_compose[OF fg1(3)] and fg2(3) unfolding fg1(2) by auto
  5204   moreover { fix y assume "y\<in>u" hence "(f2 \<circ> f1) ((g1 \<circ> g2) y) = y" using fg2(4)[THEN bspec[where x=y]] and fg1(4)[THEN bspec[where x="g2 y"]] and fg2(5) by auto }
  5205   moreover have "(g1 \<circ> g2) ` u = s" using fg1(5) fg2(5) by auto
  5206   moreover have "continuous_on u (g1 \<circ> g2)" using continuous_on_compose[OF fg2(6)] and fg1(6)  unfolding fg2(5) by auto
  5207   ultimately show ?thesis unfolding homeomorphic_def homeomorphism_def apply(rule_tac x="f2 \<circ> f1" in exI) apply(rule_tac x="g1 \<circ> g2" in exI) by auto
  5208 qed
  5209 
  5210 lemma homeomorphic_minimal:
  5211  "s homeomorphic t \<longleftrightarrow>
  5212     (\<exists>f g. (\<forall>x\<in>s. f(x) \<in> t \<and> (g(f(x)) = x)) \<and>
  5213            (\<forall>y\<in>t. g(y) \<in> s \<and> (f(g(y)) = y)) \<and>
  5214            continuous_on s f \<and> continuous_on t g)"
  5215 unfolding homeomorphic_def homeomorphism_def
  5216 apply auto apply (rule_tac x=f in exI) apply (rule_tac x=g in exI)
  5217 apply auto apply (rule_tac x=f in exI) apply (rule_tac x=g in exI) apply auto
  5218 unfolding image_iff
  5219 apply(erule_tac x="g x" in ballE) apply(erule_tac x="x" in ballE)
  5220 apply auto apply(rule_tac x="g x" in bexI) apply auto
  5221 apply(erule_tac x="f x" in ballE) apply(erule_tac x="x" in ballE)
  5222 apply auto apply(rule_tac x="f x" in bexI) by auto
  5223 
  5224 text {* Relatively weak hypotheses if a set is compact. *}
  5225 
  5226 lemma homeomorphism_compact:
  5227   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  5228     (* class constraint due to continuous_on_inverse *)
  5229   assumes "compact s" "continuous_on s f"  "f ` s = t"  "inj_on f s"
  5230   shows "\<exists>g. homeomorphism s t f g"
  5231 proof-
  5232   def g \<equiv> "\<lambda>x. SOME y. y\<in>s \<and> f y = x"
  5233   have g:"\<forall>x\<in>s. g (f x) = x" using assms(3) assms(4)[unfolded inj_on_def] unfolding g_def by auto
  5234   { fix y assume "y\<in>t"
  5235     then obtain x where x:"f x = y" "x\<in>s" using assms(3) by auto
  5236     hence "g (f x) = x" using g by auto
  5237     hence "f (g y) = y" unfolding x(1)[THEN sym] by auto  }
  5238   hence g':"\<forall>x\<in>t. f (g x) = x" by auto
  5239   moreover
  5240   { fix x
  5241     have "x\<in>s \<Longrightarrow> x \<in> g ` t" using g[THEN bspec[where x=x]] unfolding image_iff using assms(3) by(auto intro!: bexI[where x="f x"])
  5242     moreover
  5243     { assume "x\<in>g ` t"
  5244       then obtain y where y:"y\<in>t" "g y = x" by auto
  5245       then obtain x' where x':"x'\<in>s" "f x' = y" using assms(3) by auto
  5246       hence "x \<in> s" unfolding g_def using someI2[of "\<lambda>b. b\<in>s \<and> f b = y" x' "\<lambda>x. x\<in>s"] unfolding y(2)[THEN sym] and g_def by auto }
  5247     ultimately have "x\<in>s \<longleftrightarrow> x \<in> g ` t" ..  }
  5248   hence "g ` t = s" by auto
  5249   ultimately
  5250   show ?thesis unfolding homeomorphism_def homeomorphic_def
  5251     apply(rule_tac x=g in exI) using g and assms(3) and continuous_on_inverse[OF assms(2,1), of g, unfolded assms(3)] and assms(2) by auto
  5252 qed
  5253 
  5254 lemma homeomorphic_compact:
  5255   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  5256     (* class constraint due to continuous_on_inverse *)
  5257   shows "compact s \<Longrightarrow> continuous_on s f \<Longrightarrow> (f ` s = t) \<Longrightarrow> inj_on f s
  5258           \<Longrightarrow> s homeomorphic t"
  5259   unfolding homeomorphic_def by (metis homeomorphism_compact)
  5260 
  5261 text{* Preservation of topological properties.                                   *}
  5262 
  5263 lemma homeomorphic_compactness:
  5264  "s homeomorphic t ==> (compact s \<longleftrightarrow> compact t)"
  5265 unfolding homeomorphic_def homeomorphism_def
  5266 by (metis compact_continuous_image)
  5267 
  5268 text{* Results on translation, scaling etc.                                      *}
  5269 
  5270 lemma homeomorphic_scaling:
  5271   fixes s :: "'a::real_normed_vector set"
  5272   assumes "c \<noteq> 0"  shows "s homeomorphic ((\<lambda>x. c *\<^sub>R x) ` s)"
  5273   unfolding homeomorphic_minimal
  5274   apply(rule_tac x="\<lambda>x. c *\<^sub>R x" in exI)
  5275   apply(rule_tac x="\<lambda>x. (1 / c) *\<^sub>R x" in exI)
  5276   using assms by (auto simp add: continuous_on_intros)
  5277 
  5278 lemma homeomorphic_translation:
  5279   fixes s :: "'a::real_normed_vector set"
  5280   shows "s homeomorphic ((\<lambda>x. a + x) ` s)"
  5281   unfolding homeomorphic_minimal
  5282   apply(rule_tac x="\<lambda>x. a + x" in exI)
  5283   apply(rule_tac x="\<lambda>x. -a + x" in exI)
  5284   using continuous_on_add[OF continuous_on_const continuous_on_id] by auto
  5285 
  5286 lemma homeomorphic_affinity:
  5287   fixes s :: "'a::real_normed_vector set"
  5288   assumes "c \<noteq> 0"  shows "s homeomorphic ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  5289 proof-
  5290   have *:"op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s" by auto
  5291   show ?thesis
  5292     using homeomorphic_trans
  5293     using homeomorphic_scaling[OF assms, of s]
  5294     using homeomorphic_translation[of "(\<lambda>x. c *\<^sub>R x) ` s" a] unfolding * by auto
  5295 qed
  5296 
  5297 lemma homeomorphic_balls:
  5298   fixes a b ::"'a::real_normed_vector" (* FIXME: generalize to metric_space *)
  5299   assumes "0 < d"  "0 < e"
  5300   shows "(ball a d) homeomorphic  (ball b e)" (is ?th)
  5301         "(cball a d) homeomorphic (cball b e)" (is ?cth)
  5302 proof-
  5303   have *:"\<bar>e / d\<bar> > 0" "\<bar>d / e\<bar> >0" using assms using divide_pos_pos by auto
  5304   show ?th unfolding homeomorphic_minimal
  5305     apply(rule_tac x="\<lambda>x. b + (e/d) *\<^sub>R (x - a)" in exI)
  5306     apply(rule_tac x="\<lambda>x. a + (d/e) *\<^sub>R (x - b)" in exI)
  5307     using assms apply (auto simp add: dist_commute)
  5308     unfolding dist_norm
  5309     apply (auto simp add: pos_divide_less_eq mult_strict_left_mono)
  5310     unfolding continuous_on
  5311     by (intro ballI tendsto_intros, simp)+
  5312 next
  5313   have *:"\<bar>e / d\<bar> > 0" "\<bar>d / e\<bar> >0" using assms using divide_pos_pos by auto
  5314   show ?cth unfolding homeomorphic_minimal
  5315     apply(rule_tac x="\<lambda>x. b + (e/d) *\<^sub>R (x - a)" in exI)
  5316     apply(rule_tac x="\<lambda>x. a + (d/e) *\<^sub>R (x - b)" in exI)
  5317     using assms apply (auto simp add: dist_commute)
  5318     unfolding dist_norm
  5319     apply (auto simp add: pos_divide_le_eq)
  5320     unfolding continuous_on
  5321     by (intro ballI tendsto_intros, simp)+
  5322 qed
  5323 
  5324 text{* "Isometry" (up to constant bounds) of injective linear map etc.           *}
  5325 
  5326 lemma cauchy_isometric:
  5327   fixes x :: "nat \<Rightarrow> 'a::euclidean_space"
  5328   assumes e:"0 < e" and s:"subspace s" and f:"bounded_linear f" and normf:"\<forall>x\<in>s. norm(f x) \<ge> e * norm(x)" and xs:"\<forall>n::nat. x n \<in> s" and cf:"Cauchy(f o x)"
  5329   shows "Cauchy x"
  5330 proof-
  5331   interpret f: bounded_linear f by fact
  5332   { fix d::real assume "d>0"
  5333     then obtain N where N:"\<forall>n\<ge>N. norm (f (x n) - f (x N)) < e * d"
  5334       using cf[unfolded cauchy o_def dist_norm, THEN spec[where x="e*d"]] and e and mult_pos_pos[of e d] by auto
  5335     { fix n assume "n\<ge>N"
  5336       hence "norm (f (x n - x N)) < e * d" using N[THEN spec[where x=n]] unfolding f.diff[THEN sym] by auto
  5337       moreover have "e * norm (x n - x N) \<le> norm (f (x n - x N))"
  5338         using subspace_sub[OF s, of "x n" "x N"] using xs[THEN spec[where x=N]] and xs[THEN spec[where x=n]]
  5339         using normf[THEN bspec[where x="x n - x N"]] by auto
  5340       ultimately have "norm (x n - x N) < d" using `e>0`
  5341         using mult_left_less_imp_less[of e "norm (x n - x N)" d] by auto   }
  5342     hence "\<exists>N. \<forall>n\<ge>N. norm (x n - x N) < d" by auto }
  5343   thus ?thesis unfolding cauchy and dist_norm by auto
  5344 qed
  5345 
  5346 lemma complete_isometric_image:
  5347   fixes f :: "'a::euclidean_space => 'b::euclidean_space"
  5348   assumes "0 < e" and s:"subspace s" and f:"bounded_linear f" and normf:"\<forall>x\<in>s. norm(f x) \<ge> e * norm(x)" and cs:"complete s"
  5349   shows "complete(f ` s)"
  5350 proof-
  5351   { fix g assume as:"\<forall>n::nat. g n \<in> f ` s" and cfg:"Cauchy g"
  5352     then obtain x where "\<forall>n. x n \<in> s \<and> g n = f (x n)" 
  5353       using choice[of "\<lambda> n xa. xa \<in> s \<and> g n = f xa"] by auto
  5354     hence x:"\<forall>n. x n \<in> s"  "\<forall>n. g n = f (x n)" by auto
  5355     hence "f \<circ> x = g" unfolding fun_eq_iff by auto
  5356     then obtain l where "l\<in>s" and l:"(x ---> l) sequentially"
  5357       using cs[unfolded complete_def, THEN spec[where x="x"]]
  5358       using cauchy_isometric[OF `0<e` s f normf] and cfg and x(1) by auto
  5359     hence "\<exists>l\<in>f ` s. (g ---> l) sequentially"
  5360       using linear_continuous_at[OF f, unfolded continuous_at_sequentially, THEN spec[where x=x], of l]
  5361       unfolding `f \<circ> x = g` by auto  }
  5362   thus ?thesis unfolding complete_def by auto
  5363 qed
  5364 
  5365 lemma dist_0_norm:
  5366   fixes x :: "'a::real_normed_vector"
  5367   shows "dist 0 x = norm x"
  5368 unfolding dist_norm by simp
  5369 
  5370 lemma injective_imp_isometric: fixes f::"'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  5371   assumes s:"closed s"  "subspace s"  and f:"bounded_linear f" "\<forall>x\<in>s. (f x = 0) \<longrightarrow> (x = 0)"
  5372   shows "\<exists>e>0. \<forall>x\<in>s. norm (f x) \<ge> e * norm(x)"
  5373 proof(cases "s \<subseteq> {0::'a}")
  5374   case True
  5375   { fix x assume "x \<in> s"
  5376     hence "x = 0" using True by auto
  5377     hence "norm x \<le> norm (f x)" by auto  }
  5378   thus ?thesis by(auto intro!: exI[where x=1])
  5379 next
  5380   interpret f: bounded_linear f by fact
  5381   case False
  5382   then obtain a where a:"a\<noteq>0" "a\<in>s" by auto
  5383   from False have "s \<noteq> {}" by auto
  5384   let ?S = "{f x| x. (x \<in> s \<and> norm x = norm a)}"
  5385   let ?S' = "{x::'a. x\<in>s \<and> norm x = norm a}"
  5386   let ?S'' = "{x::'a. norm x = norm a}"
  5387 
  5388   have "?S'' = frontier(cball 0 (norm a))" unfolding frontier_cball and dist_norm by auto
  5389   hence "compact ?S''" using compact_frontier[OF compact_cball, of 0 "norm a"] by auto
  5390   moreover have "?S' = s \<inter> ?S''" by auto
  5391   ultimately have "compact ?S'" using closed_inter_compact[of s ?S''] using s(1) by auto
  5392   moreover have *:"f ` ?S' = ?S" by auto
  5393   ultimately have "compact ?S" using compact_continuous_image[OF linear_continuous_on[OF f(1)], of ?S'] by auto
  5394   hence "closed ?S" using compact_imp_closed by auto
  5395   moreover have "?S \<noteq> {}" using a by auto
  5396   ultimately obtain b' where "b'\<in>?S" "\<forall>y\<in>?S. norm b' \<le> norm y" using distance_attains_inf[of ?S 0] unfolding dist_0_norm by auto
  5397   then obtain b where "b\<in>s" and ba:"norm b = norm a" and b:"\<forall>x\<in>{x \<in> s. norm x = norm a}. norm (f b) \<le> norm (f x)" unfolding *[THEN sym] unfolding image_iff by auto
  5398 
  5399   let ?e = "norm (f b) / norm b"
  5400   have "norm b > 0" using ba and a and norm_ge_zero by auto
  5401   moreover have "norm (f b) > 0" using f(2)[THEN bspec[where x=b], OF `b\<in>s`] using `norm b >0` unfolding zero_less_norm_iff by auto
  5402   ultimately have "0 < norm (f b) / norm b" by(simp only: divide_pos_pos)
  5403   moreover
  5404   { fix x assume "x\<in>s"
  5405     hence "norm (f b) / norm b * norm x \<le> norm (f x)"
  5406     proof(cases "x=0")
  5407       case True thus "norm (f b) / norm b * norm x \<le> norm (f x)" by auto
  5408     next
  5409       case False
  5410       hence *:"0 < norm a / norm x" using `a\<noteq>0` unfolding zero_less_norm_iff[THEN sym] by(simp only: divide_pos_pos)
  5411       have "\<forall>c. \<forall>x\<in>s. c *\<^sub>R x \<in> s" using s[unfolded subspace_def] by auto
  5412       hence "(norm a / norm x) *\<^sub>R x \<in> {x \<in> s. norm x = norm a}" using `x\<in>s` and `x\<noteq>0` by auto
  5413       thus "norm (f b) / norm b * norm x \<le> norm (f x)" using b[THEN bspec[where x="(norm a / norm x) *\<^sub>R x"]]
  5414         unfolding f.scaleR and ba using `x\<noteq>0` `a\<noteq>0`
  5415         by (auto simp add: mult_commute pos_le_divide_eq pos_divide_le_eq)
  5416     qed }
  5417   ultimately
  5418   show ?thesis by auto
  5419 qed
  5420 
  5421 lemma closed_injective_image_subspace:
  5422   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  5423   assumes "subspace s" "bounded_linear f" "\<forall>x\<in>s. f x = 0 --> x = 0" "closed s"
  5424   shows "closed(f ` s)"
  5425 proof-
  5426   obtain e where "e>0" and e:"\<forall>x\<in>s. e * norm x \<le> norm (f x)" using injective_imp_isometric[OF assms(4,1,2,3)] by auto
  5427   show ?thesis using complete_isometric_image[OF `e>0` assms(1,2) e] and assms(4)
  5428     unfolding complete_eq_closed[THEN sym] by auto
  5429 qed
  5430 
  5431 
  5432 subsection {* Some properties of a canonical subspace *}
  5433 
  5434 lemma subspace_substandard:
  5435   "subspace {x::'a::euclidean_space. (\<forall>i<DIM('a). P i \<longrightarrow> x$$i = 0)}"
  5436   unfolding subspace_def by auto
  5437 
  5438 lemma closed_substandard:
  5439  "closed {x::'a::euclidean_space. \<forall>i<DIM('a). P i --> x$$i = 0}" (is "closed ?A")
  5440 proof-
  5441   let ?D = "{i. P i} \<inter> {..<DIM('a)}"
  5442   have "closed (\<Inter>i\<in>?D. {x::'a. x$$i = 0})"
  5443     by (simp add: closed_INT closed_Collect_eq)
  5444   also have "(\<Inter>i\<in>?D. {x::'a. x$$i = 0}) = ?A"
  5445     by auto
  5446   finally show "closed ?A" .
  5447 qed
  5448 
  5449 lemma dim_substandard: assumes "d\<subseteq>{..<DIM('a::euclidean_space)}"
  5450   shows "dim {x::'a::euclidean_space. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x$$i = 0} = card d" (is "dim ?A = _")
  5451 proof-
  5452   let ?D = "{..<DIM('a)}"
  5453   let ?B = "(basis::nat => 'a) ` d"
  5454   let ?bas = "basis::nat \<Rightarrow> 'a"
  5455   have "?B \<subseteq> ?A" by auto
  5456   moreover
  5457   { fix x::"'a" assume "x\<in>?A"
  5458     hence "finite d" "x\<in>?A" using assms by(auto intro:finite_subset)
  5459     hence "x\<in> span ?B"
  5460     proof(induct d arbitrary: x)
  5461       case empty hence "x=0" apply(subst euclidean_eq) by auto
  5462       thus ?case using subspace_0[OF subspace_span[of "{}"]] by auto
  5463     next
  5464       case (insert k F)
  5465       hence *:"\<forall>i<DIM('a). i \<notin> insert k F \<longrightarrow> x $$ i = 0" by auto
  5466       have **:"F \<subseteq> insert k F" by auto
  5467       def y \<equiv> "x - x$$k *\<^sub>R basis k"
  5468       have y:"x = y + (x$$k) *\<^sub>R basis k" unfolding y_def by auto
  5469       { fix i assume i':"i \<notin> F"
  5470         hence "y $$ i = 0" unfolding y_def 
  5471           using *[THEN spec[where x=i]] by auto }
  5472       hence "y \<in> span (basis ` F)" using insert(3) by auto
  5473       hence "y \<in> span (basis ` (insert k F))"
  5474         using span_mono[of "?bas ` F" "?bas ` (insert k F)"]
  5475         using image_mono[OF **, of basis] using assms by auto
  5476       moreover
  5477       have "basis k \<in> span (?bas ` (insert k F))" by(rule span_superset, auto)
  5478       hence "x$$k *\<^sub>R basis k \<in> span (?bas ` (insert k F))"
  5479         using span_mul by auto
  5480       ultimately
  5481       have "y + x$$k *\<^sub>R basis k \<in> span (?bas ` (insert k F))"
  5482         using span_add by auto
  5483       thus ?case using y by auto
  5484     qed
  5485   }
  5486   hence "?A \<subseteq> span ?B" by auto
  5487   moreover
  5488   { fix x assume "x \<in> ?B"
  5489     hence "x\<in>{(basis i)::'a |i. i \<in> ?D}" using assms by auto  }
  5490   hence "independent ?B" using independent_mono[OF independent_basis, of ?B] and assms by auto
  5491   moreover
  5492   have "d \<subseteq> ?D" unfolding subset_eq using assms by auto
  5493   hence *:"inj_on (basis::nat\<Rightarrow>'a) d" using subset_inj_on[OF basis_inj, of "d"] by auto
  5494   have "card ?B = card d" unfolding card_image[OF *] by auto
  5495   ultimately show ?thesis using dim_unique[of "basis ` d" ?A] by auto
  5496 qed
  5497 
  5498 text{* Hence closure and completeness of all subspaces.                          *}
  5499 
  5500 lemma closed_subspace_lemma: "n \<le> card (UNIV::'n::finite set) \<Longrightarrow> \<exists>A::'n set. card A = n"
  5501 apply (induct n)
  5502 apply (rule_tac x="{}" in exI, simp)
  5503 apply clarsimp
  5504 apply (subgoal_tac "\<exists>x. x \<notin> A")
  5505 apply (erule exE)
  5506 apply (rule_tac x="insert x A" in exI, simp)
  5507 apply (subgoal_tac "A \<noteq> UNIV", auto)
  5508 done
  5509 
  5510 lemma closed_subspace: fixes s::"('a::euclidean_space) set"
  5511   assumes "subspace s" shows "closed s"
  5512 proof-
  5513   have *:"dim s \<le> DIM('a)" using dim_subset_UNIV by auto
  5514   def d \<equiv> "{..<dim s}" have t:"card d = dim s" unfolding d_def by auto
  5515   let ?t = "{x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x$$i = 0}"
  5516   have "\<exists>f. linear f \<and> f ` {x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x $$ i = 0} = s \<and>
  5517       inj_on f {x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x $$ i = 0}"
  5518     apply(rule subspace_isomorphism[OF subspace_substandard[of "\<lambda>i. i \<notin> d"]])
  5519     using dim_substandard[of d,where 'a='a] and t unfolding d_def using * assms by auto
  5520   then guess f apply-by(erule exE conjE)+ note f = this
  5521   interpret f: bounded_linear f using f unfolding linear_conv_bounded_linear by auto
  5522   have "\<forall>x\<in>?t. f x = 0 \<longrightarrow> x = 0" using f.zero using f(3)[unfolded inj_on_def]
  5523     by(erule_tac x=0 in ballE) auto
  5524   moreover have "closed ?t" using closed_substandard .
  5525   moreover have "subspace ?t" using subspace_substandard .
  5526   ultimately show ?thesis using closed_injective_image_subspace[of ?t f]
  5527     unfolding f(2) using f(1) unfolding linear_conv_bounded_linear by auto
  5528 qed
  5529 
  5530 lemma complete_subspace:
  5531   fixes s :: "('a::euclidean_space) set" shows "subspace s ==> complete s"
  5532   using complete_eq_closed closed_subspace
  5533   by auto
  5534 
  5535 lemma dim_closure:
  5536   fixes s :: "('a::euclidean_space) set"
  5537   shows "dim(closure s) = dim s" (is "?dc = ?d")
  5538 proof-
  5539   have "?dc \<le> ?d" using closure_minimal[OF span_inc, of s]
  5540     using closed_subspace[OF subspace_span, of s]
  5541     using dim_subset[of "closure s" "span s"] unfolding dim_span by auto
  5542   thus ?thesis using dim_subset[OF closure_subset, of s] by auto
  5543 qed
  5544 
  5545 
  5546 subsection {* Affine transformations of intervals *}
  5547 
  5548 lemma real_affinity_le:
  5549  "0 < (m::'a::linordered_field) ==> (m * x + c \<le> y \<longleftrightarrow> x \<le> inverse(m) * y + -(c / m))"
  5550   by (simp add: field_simps inverse_eq_divide)
  5551 
  5552 lemma real_le_affinity:
  5553  "0 < (m::'a::linordered_field) ==> (y \<le> m * x + c \<longleftrightarrow> inverse(m) * y + -(c / m) \<le> x)"
  5554   by (simp add: field_simps inverse_eq_divide)
  5555 
  5556 lemma real_affinity_lt:
  5557  "0 < (m::'a::linordered_field) ==> (m * x + c < y \<longleftrightarrow> x < inverse(m) * y + -(c / m))"
  5558   by (simp add: field_simps inverse_eq_divide)
  5559 
  5560 lemma real_lt_affinity:
  5561  "0 < (m::'a::linordered_field) ==> (y < m * x + c \<longleftrightarrow> inverse(m) * y + -(c / m) < x)"
  5562   by (simp add: field_simps inverse_eq_divide)
  5563 
  5564 lemma real_affinity_eq:
  5565  "(m::'a::linordered_field) \<noteq> 0 ==> (m * x + c = y \<longleftrightarrow> x = inverse(m) * y + -(c / m))"
  5566   by (simp add: field_simps inverse_eq_divide)
  5567 
  5568 lemma real_eq_affinity:
  5569  "(m::'a::linordered_field) \<noteq> 0 ==> (y = m * x + c  \<longleftrightarrow> inverse(m) * y + -(c / m) = x)"
  5570   by (simp add: field_simps inverse_eq_divide)
  5571 
  5572 lemma image_affinity_interval: fixes m::real
  5573   fixes a b c :: "'a::ordered_euclidean_space"
  5574   shows "(\<lambda>x. m *\<^sub>R x + c) ` {a .. b} =
  5575             (if {a .. b} = {} then {}
  5576             else (if 0 \<le> m then {m *\<^sub>R a + c .. m *\<^sub>R b + c}
  5577             else {m *\<^sub>R b + c .. m *\<^sub>R a + c}))"
  5578 proof(cases "m=0")  
  5579   { fix x assume "x \<le> c" "c \<le> x"
  5580     hence "x=c" unfolding eucl_le[where 'a='a] apply-
  5581       apply(subst euclidean_eq) by (auto intro: order_antisym) }
  5582   moreover case True
  5583   moreover have "c \<in> {m *\<^sub>R a + c..m *\<^sub>R b + c}" unfolding True by(auto simp add: eucl_le[where 'a='a])
  5584   ultimately show ?thesis by auto
  5585 next
  5586   case False
  5587   { fix y assume "a \<le> y" "y \<le> b" "m > 0"
  5588     hence "m *\<^sub>R a + c \<le> m *\<^sub>R y + c"  "m *\<^sub>R y + c \<le> m *\<^sub>R b + c"
  5589       unfolding eucl_le[where 'a='a] by auto
  5590   } moreover
  5591   { fix y assume "a \<le> y" "y \<le> b" "m < 0"
  5592     hence "m *\<^sub>R b + c \<le> m *\<^sub>R y + c"  "m *\<^sub>R y + c \<le> m *\<^sub>R a + c"
  5593       unfolding eucl_le[where 'a='a] by(auto simp add: mult_left_mono_neg)
  5594   } moreover
  5595   { fix y assume "m > 0"  "m *\<^sub>R a + c \<le> y"  "y \<le> m *\<^sub>R b + c"
  5596     hence "y \<in> (\<lambda>x. m *\<^sub>R x + c) ` {a..b}"
  5597       unfolding image_iff Bex_def mem_interval eucl_le[where 'a='a]
  5598       apply (intro exI[where x="(1 / m) *\<^sub>R (y - c)"])
  5599       by(auto simp add: pos_le_divide_eq pos_divide_le_eq mult_commute diff_le_iff)
  5600   } moreover
  5601   { fix y assume "m *\<^sub>R b + c \<le> y" "y \<le> m *\<^sub>R a + c" "m < 0"
  5602     hence "y \<in> (\<lambda>x. m *\<^sub>R x + c) ` {a..b}"
  5603       unfolding image_iff Bex_def mem_interval eucl_le[where 'a='a]
  5604       apply (intro exI[where x="(1 / m) *\<^sub>R (y - c)"])
  5605       by(auto simp add: neg_le_divide_eq neg_divide_le_eq mult_commute diff_le_iff)
  5606   }
  5607   ultimately show ?thesis using False by auto
  5608 qed
  5609 
  5610 lemma image_smult_interval:"(\<lambda>x. m *\<^sub>R (x::_::ordered_euclidean_space)) ` {a..b} =
  5611   (if {a..b} = {} then {} else if 0 \<le> m then {m *\<^sub>R a..m *\<^sub>R b} else {m *\<^sub>R b..m *\<^sub>R a})"
  5612   using image_affinity_interval[of m 0 a b] by auto
  5613 
  5614 
  5615 subsection {* Banach fixed point theorem (not really topological...) *}
  5616 
  5617 lemma banach_fix:
  5618   assumes s:"complete s" "s \<noteq> {}" and c:"0 \<le> c" "c < 1" and f:"(f ` s) \<subseteq> s" and
  5619           lipschitz:"\<forall>x\<in>s. \<forall>y\<in>s. dist (f x) (f y) \<le> c * dist x y"
  5620   shows "\<exists>! x\<in>s. (f x = x)"
  5621 proof-
  5622   have "1 - c > 0" using c by auto
  5623 
  5624   from s(2) obtain z0 where "z0 \<in> s" by auto
  5625   def z \<equiv> "\<lambda>n. (f ^^ n) z0"
  5626   { fix n::nat
  5627     have "z n \<in> s" unfolding z_def
  5628     proof(induct n) case 0 thus ?case using `z0 \<in>s` by auto
  5629     next case Suc thus ?case using f by auto qed }
  5630   note z_in_s = this
  5631 
  5632   def d \<equiv> "dist (z 0) (z 1)"
  5633 
  5634   have fzn:"\<And>n. f (z n) = z (Suc n)" unfolding z_def by auto
  5635   { fix n::nat
  5636     have "dist (z n) (z (Suc n)) \<le> (c ^ n) * d"
  5637     proof(induct n)
  5638       case 0 thus ?case unfolding d_def by auto
  5639     next
  5640       case (Suc m)
  5641       hence "c * dist (z m) (z (Suc m)) \<le> c ^ Suc m * d"
  5642         using `0 \<le> c` using mult_left_mono[of "dist (z m) (z (Suc m))" "c ^ m * d" c] by auto
  5643       thus ?case using lipschitz[THEN bspec[where x="z m"], OF z_in_s, THEN bspec[where x="z (Suc m)"], OF z_in_s]
  5644         unfolding fzn and mult_le_cancel_left by auto
  5645     qed
  5646   } note cf_z = this
  5647 
  5648   { fix n m::nat
  5649     have "(1 - c) * dist (z m) (z (m+n)) \<le> (c ^ m) * d * (1 - c ^ n)"
  5650     proof(induct n)
  5651       case 0 show ?case by auto
  5652     next
  5653       case (Suc k)
  5654       have "(1 - c) * dist (z m) (z (m + Suc k)) \<le> (1 - c) * (dist (z m) (z (m + k)) + dist (z (m + k)) (z (Suc (m + k))))"
  5655         using dist_triangle and c by(auto simp add: dist_triangle)
  5656       also have "\<dots> \<le> (1 - c) * (dist (z m) (z (m + k)) + c ^ (m + k) * d)"
  5657         using cf_z[of "m + k"] and c by auto
  5658       also have "\<dots> \<le> c ^ m * d * (1 - c ^ k) + (1 - c) * c ^ (m + k) * d"
  5659         using Suc by (auto simp add: field_simps)
  5660       also have "\<dots> = (c ^ m) * (d * (1 - c ^ k) + (1 - c) * c ^ k * d)"
  5661         unfolding power_add by (auto simp add: field_simps)
  5662       also have "\<dots> \<le> (c ^ m) * d * (1 - c ^ Suc k)"
  5663         using c by (auto simp add: field_simps)
  5664       finally show ?case by auto
  5665     qed
  5666   } note cf_z2 = this
  5667   { fix e::real assume "e>0"
  5668     hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (z m) (z n) < e"
  5669     proof(cases "d = 0")
  5670       case True
  5671       have *: "\<And>x. ((1 - c) * x \<le> 0) = (x \<le> 0)" using `1 - c > 0`
  5672         by (metis mult_zero_left real_mult_commute real_mult_le_cancel_iff1)
  5673       from True have "\<And>n. z n = z0" using cf_z2[of 0] and c unfolding z_def
  5674         by (simp add: *)
  5675       thus ?thesis using `e>0` by auto
  5676     next
  5677       case False hence "d>0" unfolding d_def using zero_le_dist[of "z 0" "z 1"]
  5678         by (metis False d_def less_le)
  5679       hence "0 < e * (1 - c) / d" using `e>0` and `1-c>0`
  5680         using divide_pos_pos[of "e * (1 - c)" d] and mult_pos_pos[of e "1 - c"] by auto
  5681       then obtain N where N:"c ^ N < e * (1 - c) / d" using real_arch_pow_inv[of "e * (1 - c) / d" c] and c by auto
  5682       { fix m n::nat assume "m>n" and as:"m\<ge>N" "n\<ge>N"
  5683         have *:"c ^ n \<le> c ^ N" using `n\<ge>N` and c using power_decreasing[OF `n\<ge>N`, of c] by auto
  5684         have "1 - c ^ (m - n) > 0" using c and power_strict_mono[of c 1 "m - n"] using `m>n` by auto
  5685         hence **:"d * (1 - c ^ (m - n)) / (1 - c) > 0"
  5686           using mult_pos_pos[OF `d>0`, of "1 - c ^ (m - n)"]
  5687           using divide_pos_pos[of "d * (1 - c ^ (m - n))" "1 - c"]
  5688           using `0 < 1 - c` by auto
  5689 
  5690         have "dist (z m) (z n) \<le> c ^ n * d * (1 - c ^ (m - n)) / (1 - c)"
  5691           using cf_z2[of n "m - n"] and `m>n` unfolding pos_le_divide_eq[OF `1-c>0`]
  5692           by (auto simp add: mult_commute dist_commute)
  5693         also have "\<dots> \<le> c ^ N * d * (1 - c ^ (m - n)) / (1 - c)"
  5694           using mult_right_mono[OF * order_less_imp_le[OF **]]
  5695           unfolding mult_assoc by auto
  5696         also have "\<dots> < (e * (1 - c) / d) * d * (1 - c ^ (m - n)) / (1 - c)"
  5697           using mult_strict_right_mono[OF N **] unfolding mult_assoc by auto
  5698         also have "\<dots> = e * (1 - c ^ (m - n))" using c and `d>0` and `1 - c > 0` by auto
  5699         also have "\<dots> \<le> e" using c and `1 - c ^ (m - n) > 0` and `e>0` using mult_right_le_one_le[of e "1 - c ^ (m - n)"] by auto
  5700         finally have  "dist (z m) (z n) < e" by auto
  5701       } note * = this
  5702       { fix m n::nat assume as:"N\<le>m" "N\<le>n"
  5703         hence "dist (z n) (z m) < e"
  5704         proof(cases "n = m")
  5705           case True thus ?thesis using `e>0` by auto
  5706         next
  5707           case False thus ?thesis using as and *[of n m] *[of m n] unfolding nat_neq_iff by (auto simp add: dist_commute)
  5708         qed }
  5709       thus ?thesis by auto
  5710     qed
  5711   }
  5712   hence "Cauchy z" unfolding cauchy_def by auto
  5713   then obtain x where "x\<in>s" and x:"(z ---> x) sequentially" using s(1)[unfolded compact_def complete_def, THEN spec[where x=z]] and z_in_s by auto
  5714 
  5715   def e \<equiv> "dist (f x) x"
  5716   have "e = 0" proof(rule ccontr)
  5717     assume "e \<noteq> 0" hence "e>0" unfolding e_def using zero_le_dist[of "f x" x]
  5718       by (metis dist_eq_0_iff dist_nz e_def)
  5719     then obtain N where N:"\<forall>n\<ge>N. dist (z n) x < e / 2"
  5720       using x[unfolded Lim_sequentially, THEN spec[where x="e/2"]] by auto
  5721     hence N':"dist (z N) x < e / 2" by auto
  5722 
  5723     have *:"c * dist (z N) x \<le> dist (z N) x" unfolding mult_le_cancel_right2
  5724       using zero_le_dist[of "z N" x] and c
  5725       by (metis dist_eq_0_iff dist_nz order_less_asym less_le)
  5726     have "dist (f (z N)) (f x) \<le> c * dist (z N) x" using lipschitz[THEN bspec[where x="z N"], THEN bspec[where x=x]]
  5727       using z_in_s[of N] `x\<in>s` using c by auto
  5728     also have "\<dots> < e / 2" using N' and c using * by auto
  5729     finally show False unfolding fzn
  5730       using N[THEN spec[where x="Suc N"]] and dist_triangle_half_r[of "z (Suc N)" "f x" e x]
  5731       unfolding e_def by auto
  5732   qed
  5733   hence "f x = x" unfolding e_def by auto
  5734   moreover
  5735   { fix y assume "f y = y" "y\<in>s"
  5736     hence "dist x y \<le> c * dist x y" using lipschitz[THEN bspec[where x=x], THEN bspec[where x=y]]
  5737       using `x\<in>s` and `f x = x` by auto