src/Pure/Thy/export_theory.ML
author wenzelm
Tue Mar 26 22:13:36 2019 +0100 (6 months ago)
changeset 69992 bd3c10813cc4
parent 69988 6fa51a36b7f7
child 69996 8f2d3a27aff0
permissions -rw-r--r--
more informative Spec_Rules.Equational, notably primrec argument types;
     1 (*  Title:      Pure/Thy/export_theory.ML
     2     Author:     Makarius
     3 
     4 Export foundational theory content and locale/class structure.
     5 *)
     6 
     7 signature EXPORT_THEORY =
     8 sig
     9   val setup_presentation: (Thy_Info.presentation_context -> theory -> unit) -> unit
    10   val export_body: theory -> string -> XML.body -> unit
    11 end;
    12 
    13 structure Export_Theory: EXPORT_THEORY =
    14 struct
    15 
    16 (* approximative syntax *)
    17 
    18 val get_syntax = Syntax.get_approx o Proof_Context.syn_of;
    19 fun get_syntax_type ctxt = get_syntax ctxt o Lexicon.mark_type;
    20 fun get_syntax_const ctxt = get_syntax ctxt o Lexicon.mark_const;
    21 fun get_syntax_fixed ctxt = get_syntax ctxt o Lexicon.mark_fixed;
    22 
    23 fun get_syntax_param ctxt loc x =
    24   let val thy = Proof_Context.theory_of ctxt in
    25     if Class.is_class thy loc then
    26       (case AList.lookup (op =) (Class.these_params thy [loc]) x of
    27         NONE => NONE
    28       | SOME (_, (c, _)) => get_syntax_const ctxt c)
    29     else get_syntax_fixed ctxt x
    30   end;
    31 
    32 val encode_syntax =
    33   XML.Encode.variant
    34    [fn NONE => ([], []),
    35     fn SOME (Syntax.Prefix delim) => ([delim], []),
    36     fn SOME (Syntax.Infix {assoc, delim, pri}) =>
    37       let
    38         val ass =
    39           (case assoc of
    40             Printer.No_Assoc => 0
    41           | Printer.Left_Assoc => 1
    42           | Printer.Right_Assoc => 2);
    43         open XML.Encode Term_XML.Encode;
    44       in ([], triple int string int (ass, delim, pri)) end];
    45 
    46 
    47 (* standardization of variables: only frees and named bounds *)
    48 
    49 local
    50 
    51 fun declare_names (Abs (_, _, b)) = declare_names b
    52   | declare_names (t $ u) = declare_names t #> declare_names u
    53   | declare_names (Const (c, _)) = Name.declare (Long_Name.base_name c)
    54   | declare_names (Free (x, _)) = Name.declare x
    55   | declare_names _ = I;
    56 
    57 fun variant_abs bs (Abs (x, T, t)) =
    58       let
    59         val names = fold Name.declare bs (declare_names t Name.context);
    60         val x' = #1 (Name.variant x names);
    61         val t' = variant_abs (x' :: bs) t;
    62       in Abs (x', T, t') end
    63   | variant_abs bs (t $ u) = variant_abs bs t $ variant_abs bs u
    64   | variant_abs _ t = t;
    65 
    66 in
    67 
    68 fun standard_vars used =
    69   let
    70     fun zero_var_indexes tm =
    71       Term_Subst.instantiate (Term_Subst.zero_var_indexes_inst used [tm]) tm;
    72 
    73     fun unvarifyT ty = ty |> Term.map_atyps
    74       (fn TVar ((a, _), S) => TFree (a, S)
    75         | T as TFree (a, _) =>
    76             if Name.is_declared used a then T
    77             else raise TYPE (Logic.bad_fixed a, [ty], []));
    78 
    79     fun unvarify tm = tm |> Term.map_aterms
    80       (fn Var ((x, _), T) => Free (x, T)
    81         | t as Free (x, _) =>
    82             if Name.is_declared used x then t
    83             else raise TERM (Logic.bad_fixed x, [tm])
    84         | t => t);
    85 
    86   in zero_var_indexes #> map_types unvarifyT #> unvarify #> variant_abs [] end;
    87 
    88 val standard_vars_global = standard_vars Name.context;
    89 
    90 end;
    91 
    92 
    93 (* free variables: not declared in the context *)
    94 
    95 val is_free = not oo Name.is_declared;
    96 
    97 fun add_frees used =
    98   fold_aterms (fn Free (x, T) => is_free used x ? insert (op =) (x, T) | _ => I);
    99 
   100 fun add_tfrees used =
   101   (fold_types o fold_atyps) (fn TFree (a, S) => is_free used a ? insert (op =) (a, S) | _ => I);
   102 
   103 
   104 (* spec rules *)
   105 
   106 fun primrec_types ctxt const =
   107   Spec_Rules.retrieve ctxt (Const const)
   108   |> get_first (fn (Spec_Rules.Equational (Spec_Rules.Primrec types), _) => SOME types | _ => NONE)
   109   |> the_default [];
   110 
   111 
   112 (* locales content *)
   113 
   114 fun locale_content thy loc =
   115   let
   116     val ctxt = Locale.init loc thy;
   117     val args =
   118       Locale.params_of thy loc
   119       |> map (fn ((x, T), _) => ((x, T), get_syntax_param ctxt loc x));
   120     val axioms =
   121       let
   122         val (asm, defs) = Locale.specification_of thy loc;
   123         val cprops = map (Thm.cterm_of ctxt) (the_list asm @ defs);
   124         val (intro1, intro2) = Locale.intros_of thy loc;
   125         val intros_tac = Method.try_intros_tac ctxt (the_list intro1 @ the_list intro2) [];
   126         val res =
   127           Goal.init (Conjunction.mk_conjunction_balanced cprops)
   128           |> (ALLGOALS Goal.conjunction_tac THEN intros_tac)
   129           |> try Seq.hd;
   130       in
   131         (case res of
   132           SOME goal => Thm.prems_of goal
   133         | NONE => raise Fail ("Cannot unfold locale " ^ quote loc))
   134       end;
   135     val typargs = rev (fold Term.add_tfrees (map (Free o #1) args @ axioms) []);
   136   in {typargs = typargs, args = args, axioms = axioms} end;
   137 
   138 fun get_locales thy =
   139   Locale.get_locales thy |> map_filter (fn loc =>
   140     if Experiment.is_experiment thy loc then NONE else SOME (loc, ()));
   141 
   142 fun get_dependencies prev_thys thy =
   143   Locale.dest_dependencies prev_thys thy |> map_filter (fn dep =>
   144     if Experiment.is_experiment thy (#source dep) orelse
   145       Experiment.is_experiment thy (#target dep) then NONE
   146     else
   147       let
   148         val (type_params, params) = Locale.parameters_of thy (#source dep);
   149         val typargs = fold (Term.add_tfreesT o #2 o #1) params type_params;
   150         val substT =
   151           typargs |> map_filter (fn v =>
   152             let
   153               val T = TFree v;
   154               val T' = Morphism.typ (#morphism dep) T;
   155             in if T = T' then NONE else SOME (v, T') end);
   156         val subst =
   157           params |> map_filter (fn (v, _) =>
   158             let
   159               val t = Free v;
   160               val t' = Morphism.term (#morphism dep) t;
   161             in if t aconv t' then NONE else SOME (v, t') end);
   162       in SOME (dep, (substT, subst)) end);
   163 
   164 
   165 (* general setup *)
   166 
   167 fun setup_presentation f =
   168   Theory.setup (Thy_Info.add_presentation (fn context => fn thy =>
   169     if Options.bool (#options context) "export_theory" then f context thy else ()));
   170 
   171 fun export_body thy name body =
   172   Export.export thy (Path.make ["theory", name])
   173     (Buffer.chunks (YXML.buffer_body body Buffer.empty));
   174 
   175 
   176 (* presentation *)
   177 
   178 val _ = setup_presentation (fn {adjust_pos, ...} => fn thy =>
   179   let
   180     val parents = Theory.parents_of thy;
   181     val rep_tsig = Type.rep_tsig (Sign.tsig_of thy);
   182 
   183     val thy_ctxt = Proof_Context.init_global thy;
   184 
   185 
   186     (* entities *)
   187 
   188     fun make_entity_markup name xname pos serial =
   189       let
   190         val props =
   191           Position.offset_properties_of (adjust_pos pos) @
   192           Position.id_properties_of pos @
   193           Markup.serial_properties serial;
   194       in (Markup.entityN, (Markup.nameN, name) :: (Markup.xnameN, xname) :: props) end;
   195 
   196     fun entity_markup space name =
   197       let
   198         val xname = Name_Space.extern_shortest thy_ctxt space name;
   199         val {serial, pos, ...} = Name_Space.the_entry space name;
   200       in make_entity_markup name xname pos serial end;
   201 
   202     fun export_entities export_name export get_space decls =
   203       let val elems =
   204         let
   205           val parent_spaces = map get_space parents;
   206           val space = get_space thy;
   207         in
   208           (decls, []) |-> fold (fn (name, decl) =>
   209             if exists (fn space => Name_Space.declared space name) parent_spaces then I
   210             else
   211               (case export name decl of
   212                 NONE => I
   213               | SOME body =>
   214                   cons (#serial (Name_Space.the_entry space name),
   215                     XML.Elem (entity_markup space name, body))))
   216           |> sort (int_ord o apply2 #1) |> map #2
   217         end;
   218       in if null elems then () else export_body thy export_name elems end;
   219 
   220 
   221     (* types *)
   222 
   223     val encode_type =
   224       let open XML.Encode Term_XML.Encode
   225       in triple encode_syntax (list string) (option typ) end;
   226 
   227     fun export_type c (Type.LogicalType n) =
   228           SOME (encode_type (get_syntax_type thy_ctxt c, Name.invent Name.context Name.aT n, NONE))
   229       | export_type c (Type.Abbreviation (args, U, false)) =
   230           SOME (encode_type (get_syntax_type thy_ctxt c, args, SOME U))
   231       | export_type _ _ = NONE;
   232 
   233     val _ =
   234       export_entities "types" export_type Sign.type_space
   235         (Name_Space.dest_table (#types rep_tsig));
   236 
   237 
   238     (* consts *)
   239 
   240     val encode_const =
   241       let open XML.Encode Term_XML.Encode in
   242         pair encode_syntax
   243           (pair (list string) (pair typ (pair (option term) (pair bool (list string)))))
   244       end;
   245 
   246     fun export_const c (T, abbrev) =
   247       let
   248         val syntax = get_syntax_const thy_ctxt c;
   249         val U = Logic.unvarifyT_global T;
   250         val U0 = Type.strip_sorts U;
   251         val primrec_types = primrec_types thy_ctxt (c, U);
   252         val abbrev' = abbrev |> Option.map (standard_vars_global #> map_types Type.strip_sorts);
   253         val args = map (#1 o dest_TFree) (Consts.typargs (Sign.consts_of thy) (c, U0));
   254         val propositional = Object_Logic.is_propositional thy_ctxt (Term.body_type U0);
   255       in encode_const (syntax, (args, (U0, (abbrev', (propositional, primrec_types))))) end;
   256 
   257     val _ =
   258       export_entities "consts" (SOME oo export_const) Sign.const_space
   259         (#constants (Consts.dest (Sign.consts_of thy)));
   260 
   261 
   262     (* axioms and facts *)
   263 
   264     fun prop_of raw_thm =
   265       let
   266         val thm = raw_thm
   267           |> Thm.transfer thy
   268           |> Thm.check_hyps (Context.Theory thy)
   269           |> Thm.strip_shyps;
   270         val prop = thm
   271           |> Thm.full_prop_of;
   272       in (Thm.extra_shyps thm, prop) end;
   273 
   274     fun encode_prop used (Ss, raw_prop) =
   275       let
   276         val prop = standard_vars used raw_prop;
   277         val args = rev (add_frees used prop []);
   278         val typargs = rev (add_tfrees used prop []);
   279         val used' = fold (Name.declare o #1) typargs used;
   280         val sorts = Name.invent used' Name.aT (length Ss) ~~ Ss;
   281       in
   282         (sorts @ typargs, args, prop) |>
   283           let open XML.Encode Term_XML.Encode
   284           in triple (list (pair string sort)) (list (pair string typ)) term end
   285       end;
   286 
   287     fun encode_axiom used t = encode_prop used ([], t);
   288 
   289     val encode_fact_single = encode_prop Name.context o prop_of;
   290     val encode_fact_multi = XML.Encode.list (encode_prop Name.context) o map prop_of;
   291 
   292     val _ =
   293       export_entities "axioms" (fn _ => fn t => SOME (encode_axiom Name.context t))
   294         Theory.axiom_space (Theory.axioms_of thy);
   295     val _ =
   296       export_entities "facts" (K (SOME o encode_fact_multi))
   297         (Facts.space_of o Global_Theory.facts_of)
   298         (Facts.dest_static true [] (Global_Theory.facts_of thy));
   299 
   300 
   301     (* type classes *)
   302 
   303     val encode_class =
   304       let open XML.Encode Term_XML.Encode
   305       in pair (list (pair string typ)) (list encode_fact_single) end;
   306 
   307     fun export_class name =
   308       (case try (Axclass.get_info thy) name of
   309         NONE => ([], [])
   310       | SOME {params, axioms, ...} => (params, axioms))
   311       |> encode_class |> SOME;
   312 
   313     val _ =
   314       export_entities "classes" (fn name => fn () => export_class name)
   315         Sign.class_space (map (rpair ()) (Graph.keys (Sorts.classes_of (#2 (#classes rep_tsig)))));
   316 
   317 
   318     (* sort algebra *)
   319 
   320     val {classrel, arities} =
   321       Sorts.dest_algebra (map (#2 o #classes o Type.rep_tsig o Sign.tsig_of) parents)
   322         (#2 (#classes rep_tsig));
   323 
   324     val encode_classrel =
   325       let open XML.Encode
   326       in list (pair string (list string)) end;
   327 
   328     val encode_arities =
   329       let open XML.Encode Term_XML.Encode
   330       in list (triple string (list sort) string) end;
   331 
   332     val _ = if null classrel then () else export_body thy "classrel" (encode_classrel classrel);
   333     val _ = if null arities then () else export_body thy "arities" (encode_arities arities);
   334 
   335 
   336     (* locales *)
   337 
   338     fun encode_locale used =
   339       let open XML.Encode Term_XML.Encode in
   340         triple (list (pair string sort)) (list (pair (pair string typ) encode_syntax))
   341           (list (encode_axiom used))
   342       end;
   343 
   344     fun export_locale loc =
   345       let
   346         val {typargs, args, axioms} = locale_content thy loc;
   347         val used = fold Name.declare (map #1 typargs @ map (#1 o #1) args) Name.context;
   348       in encode_locale used (typargs, args, axioms) end
   349       handle ERROR msg =>
   350         cat_error msg ("The error(s) above occurred in locale " ^
   351           quote (Locale.markup_name thy_ctxt loc));
   352 
   353     val _ =
   354       export_entities "locales" (fn loc => fn () => SOME (export_locale loc))
   355         Locale.locale_space (get_locales thy);
   356 
   357 
   358     (* locale dependencies *)
   359 
   360     fun encode_locale_dependency (dep: Locale.locale_dependency, subst) =
   361       (#source dep, (#target dep, (#prefix dep, subst))) |>
   362         let
   363           open XML.Encode Term_XML.Encode;
   364           val encode_subst =
   365             pair (list (pair (pair string sort) typ)) (list (pair (pair string typ) term));
   366         in pair string (pair string (pair (list (pair string bool)) encode_subst)) end;
   367 
   368     val _ =
   369       (case get_dependencies parents thy of
   370         [] => ()
   371       | deps =>
   372           deps |> map_index (fn (i, dep) =>
   373             let
   374               val xname = string_of_int (i + 1);
   375               val name = Long_Name.implode [Context.theory_name thy, xname];
   376               val markup = make_entity_markup name xname (#pos (#1 dep)) (#serial (#1 dep));
   377               val body = encode_locale_dependency dep;
   378             in XML.Elem (markup, body) end)
   379           |> export_body thy "locale_dependencies");
   380 
   381 
   382     (* parents *)
   383 
   384     val _ =
   385       export_body thy "parents"
   386         (XML.Encode.string (cat_lines (map Context.theory_long_name parents)));
   387 
   388   in () end);
   389 
   390 end;