src/HOL/Transfer.thy
author wenzelm
Tue Sep 01 22:32:58 2015 +0200 (2015-09-01)
changeset 61076 bdc1e2f0a86a
parent 60758 d8d85a8172b5
child 61630 608520e0e8e2
permissions -rw-r--r--
eliminated \<Colon>;
     1 (*  Title:      HOL/Transfer.thy
     2     Author:     Brian Huffman, TU Muenchen
     3     Author:     Ondrej Kuncar, TU Muenchen
     4 *)
     5 
     6 section \<open>Generic theorem transfer using relations\<close>
     7 
     8 theory Transfer
     9 imports Basic_BNF_LFPs Hilbert_Choice Metis
    10 begin
    11 
    12 subsection \<open>Relator for function space\<close>
    13 
    14 locale lifting_syntax
    15 begin
    16   notation rel_fun (infixr "===>" 55)
    17   notation map_fun (infixr "--->" 55)
    18 end
    19 
    20 context
    21 begin
    22 interpretation lifting_syntax .
    23 
    24 lemma rel_funD2:
    25   assumes "rel_fun A B f g" and "A x x"
    26   shows "B (f x) (g x)"
    27   using assms by (rule rel_funD)
    28 
    29 lemma rel_funE:
    30   assumes "rel_fun A B f g" and "A x y"
    31   obtains "B (f x) (g y)"
    32   using assms by (simp add: rel_fun_def)
    33 
    34 lemmas rel_fun_eq = fun.rel_eq
    35 
    36 lemma rel_fun_eq_rel:
    37 shows "rel_fun (op =) R = (\<lambda>f g. \<forall>x. R (f x) (g x))"
    38   by (simp add: rel_fun_def)
    39 
    40 
    41 subsection \<open>Transfer method\<close>
    42 
    43 text \<open>Explicit tag for relation membership allows for
    44   backward proof methods.\<close>
    45 
    46 definition Rel :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
    47   where "Rel r \<equiv> r"
    48 
    49 text \<open>Handling of equality relations\<close>
    50 
    51 definition is_equality :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
    52   where "is_equality R \<longleftrightarrow> R = (op =)"
    53 
    54 lemma is_equality_eq: "is_equality (op =)"
    55   unfolding is_equality_def by simp
    56 
    57 text \<open>Reverse implication for monotonicity rules\<close>
    58 
    59 definition rev_implies where
    60   "rev_implies x y \<longleftrightarrow> (y \<longrightarrow> x)"
    61 
    62 text \<open>Handling of meta-logic connectives\<close>
    63 
    64 definition transfer_forall where
    65   "transfer_forall \<equiv> All"
    66 
    67 definition transfer_implies where
    68   "transfer_implies \<equiv> op \<longrightarrow>"
    69 
    70 definition transfer_bforall :: "('a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool"
    71   where "transfer_bforall \<equiv> (\<lambda>P Q. \<forall>x. P x \<longrightarrow> Q x)"
    72 
    73 lemma transfer_forall_eq: "(\<And>x. P x) \<equiv> Trueprop (transfer_forall (\<lambda>x. P x))"
    74   unfolding atomize_all transfer_forall_def ..
    75 
    76 lemma transfer_implies_eq: "(A \<Longrightarrow> B) \<equiv> Trueprop (transfer_implies A B)"
    77   unfolding atomize_imp transfer_implies_def ..
    78 
    79 lemma transfer_bforall_unfold:
    80   "Trueprop (transfer_bforall P (\<lambda>x. Q x)) \<equiv> (\<And>x. P x \<Longrightarrow> Q x)"
    81   unfolding transfer_bforall_def atomize_imp atomize_all ..
    82 
    83 lemma transfer_start: "\<lbrakk>P; Rel (op =) P Q\<rbrakk> \<Longrightarrow> Q"
    84   unfolding Rel_def by simp
    85 
    86 lemma transfer_start': "\<lbrakk>P; Rel (op \<longrightarrow>) P Q\<rbrakk> \<Longrightarrow> Q"
    87   unfolding Rel_def by simp
    88 
    89 lemma transfer_prover_start: "\<lbrakk>x = x'; Rel R x' y\<rbrakk> \<Longrightarrow> Rel R x y"
    90   by simp
    91 
    92 lemma untransfer_start: "\<lbrakk>Q; Rel (op =) P Q\<rbrakk> \<Longrightarrow> P"
    93   unfolding Rel_def by simp
    94 
    95 lemma Rel_eq_refl: "Rel (op =) x x"
    96   unfolding Rel_def ..
    97 
    98 lemma Rel_app:
    99   assumes "Rel (A ===> B) f g" and "Rel A x y"
   100   shows "Rel B (f x) (g y)"
   101   using assms unfolding Rel_def rel_fun_def by fast
   102 
   103 lemma Rel_abs:
   104   assumes "\<And>x y. Rel A x y \<Longrightarrow> Rel B (f x) (g y)"
   105   shows "Rel (A ===> B) (\<lambda>x. f x) (\<lambda>y. g y)"
   106   using assms unfolding Rel_def rel_fun_def by fast
   107 
   108 subsection \<open>Predicates on relations, i.e. ``class constraints''\<close>
   109 
   110 definition left_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   111   where "left_total R \<longleftrightarrow> (\<forall>x. \<exists>y. R x y)"
   112 
   113 definition left_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   114   where "left_unique R \<longleftrightarrow> (\<forall>x y z. R x z \<longrightarrow> R y z \<longrightarrow> x = y)"
   115 
   116 definition right_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   117   where "right_total R \<longleftrightarrow> (\<forall>y. \<exists>x. R x y)"
   118 
   119 definition right_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   120   where "right_unique R \<longleftrightarrow> (\<forall>x y z. R x y \<longrightarrow> R x z \<longrightarrow> y = z)"
   121 
   122 definition bi_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   123   where "bi_total R \<longleftrightarrow> (\<forall>x. \<exists>y. R x y) \<and> (\<forall>y. \<exists>x. R x y)"
   124 
   125 definition bi_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   126   where "bi_unique R \<longleftrightarrow>
   127     (\<forall>x y z. R x y \<longrightarrow> R x z \<longrightarrow> y = z) \<and>
   128     (\<forall>x y z. R x z \<longrightarrow> R y z \<longrightarrow> x = y)"
   129 
   130 lemma left_uniqueI: "(\<And>x y z. \<lbrakk> A x z; A y z \<rbrakk> \<Longrightarrow> x = y) \<Longrightarrow> left_unique A"
   131 unfolding left_unique_def by blast
   132 
   133 lemma left_uniqueD: "\<lbrakk> left_unique A; A x z; A y z \<rbrakk> \<Longrightarrow> x = y"
   134 unfolding left_unique_def by blast
   135 
   136 lemma left_totalI:
   137   "(\<And>x. \<exists>y. R x y) \<Longrightarrow> left_total R"
   138 unfolding left_total_def by blast
   139 
   140 lemma left_totalE:
   141   assumes "left_total R"
   142   obtains "(\<And>x. \<exists>y. R x y)"
   143 using assms unfolding left_total_def by blast
   144 
   145 lemma bi_uniqueDr: "\<lbrakk> bi_unique A; A x y; A x z \<rbrakk> \<Longrightarrow> y = z"
   146 by(simp add: bi_unique_def)
   147 
   148 lemma bi_uniqueDl: "\<lbrakk> bi_unique A; A x y; A z y \<rbrakk> \<Longrightarrow> x = z"
   149 by(simp add: bi_unique_def)
   150 
   151 lemma right_uniqueI: "(\<And>x y z. \<lbrakk> A x y; A x z \<rbrakk> \<Longrightarrow> y = z) \<Longrightarrow> right_unique A"
   152 unfolding right_unique_def by fast
   153 
   154 lemma right_uniqueD: "\<lbrakk> right_unique A; A x y; A x z \<rbrakk> \<Longrightarrow> y = z"
   155 unfolding right_unique_def by fast
   156 
   157 lemma right_totalI: "(\<And>y. \<exists>x. A x y) \<Longrightarrow> right_total A"
   158 by(simp add: right_total_def)
   159 
   160 lemma right_totalE:
   161   assumes "right_total A"
   162   obtains x where "A x y"
   163 using assms by(auto simp add: right_total_def)
   164 
   165 lemma right_total_alt_def2:
   166   "right_total R \<longleftrightarrow> ((R ===> op \<longrightarrow>) ===> op \<longrightarrow>) All All"
   167   unfolding right_total_def rel_fun_def
   168   apply (rule iffI, fast)
   169   apply (rule allI)
   170   apply (drule_tac x="\<lambda>x. True" in spec)
   171   apply (drule_tac x="\<lambda>y. \<exists>x. R x y" in spec)
   172   apply fast
   173   done
   174 
   175 lemma right_unique_alt_def2:
   176   "right_unique R \<longleftrightarrow> (R ===> R ===> op \<longrightarrow>) (op =) (op =)"
   177   unfolding right_unique_def rel_fun_def by auto
   178 
   179 lemma bi_total_alt_def2:
   180   "bi_total R \<longleftrightarrow> ((R ===> op =) ===> op =) All All"
   181   unfolding bi_total_def rel_fun_def
   182   apply (rule iffI, fast)
   183   apply safe
   184   apply (drule_tac x="\<lambda>x. \<exists>y. R x y" in spec)
   185   apply (drule_tac x="\<lambda>y. True" in spec)
   186   apply fast
   187   apply (drule_tac x="\<lambda>x. True" in spec)
   188   apply (drule_tac x="\<lambda>y. \<exists>x. R x y" in spec)
   189   apply fast
   190   done
   191 
   192 lemma bi_unique_alt_def2:
   193   "bi_unique R \<longleftrightarrow> (R ===> R ===> op =) (op =) (op =)"
   194   unfolding bi_unique_def rel_fun_def by auto
   195 
   196 lemma [simp]:
   197   shows left_unique_conversep: "left_unique A\<inverse>\<inverse> \<longleftrightarrow> right_unique A"
   198   and right_unique_conversep: "right_unique A\<inverse>\<inverse> \<longleftrightarrow> left_unique A"
   199 by(auto simp add: left_unique_def right_unique_def)
   200 
   201 lemma [simp]:
   202   shows left_total_conversep: "left_total A\<inverse>\<inverse> \<longleftrightarrow> right_total A"
   203   and right_total_conversep: "right_total A\<inverse>\<inverse> \<longleftrightarrow> left_total A"
   204 by(simp_all add: left_total_def right_total_def)
   205 
   206 lemma bi_unique_conversep [simp]: "bi_unique R\<inverse>\<inverse> = bi_unique R"
   207 by(auto simp add: bi_unique_def)
   208 
   209 lemma bi_total_conversep [simp]: "bi_total R\<inverse>\<inverse> = bi_total R"
   210 by(auto simp add: bi_total_def)
   211 
   212 lemma right_unique_alt_def: "right_unique R = (conversep R OO R \<le> op=)" unfolding right_unique_def by blast
   213 lemma left_unique_alt_def: "left_unique R = (R OO (conversep R) \<le> op=)" unfolding left_unique_def by blast
   214 
   215 lemma right_total_alt_def: "right_total R = (conversep R OO R \<ge> op=)" unfolding right_total_def by blast
   216 lemma left_total_alt_def: "left_total R = (R OO conversep R \<ge> op=)" unfolding left_total_def by blast
   217 
   218 lemma bi_total_alt_def: "bi_total A = (left_total A \<and> right_total A)"
   219 unfolding left_total_def right_total_def bi_total_def by blast
   220 
   221 lemma bi_unique_alt_def: "bi_unique A = (left_unique A \<and> right_unique A)"
   222 unfolding left_unique_def right_unique_def bi_unique_def by blast
   223 
   224 lemma bi_totalI: "left_total R \<Longrightarrow> right_total R \<Longrightarrow> bi_total R"
   225 unfolding bi_total_alt_def ..
   226 
   227 lemma bi_uniqueI: "left_unique R \<Longrightarrow> right_unique R \<Longrightarrow> bi_unique R"
   228 unfolding bi_unique_alt_def ..
   229 
   230 end
   231 
   232 subsection \<open>Equality restricted by a predicate\<close>
   233 
   234 definition eq_onp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
   235   where "eq_onp R = (\<lambda>x y. R x \<and> x = y)"
   236 
   237 lemma eq_onp_Grp: "eq_onp P = BNF_Def.Grp (Collect P) id"
   238 unfolding eq_onp_def Grp_def by auto
   239 
   240 lemma eq_onp_to_eq:
   241   assumes "eq_onp P x y"
   242   shows "x = y"
   243 using assms by (simp add: eq_onp_def)
   244 
   245 lemma eq_onp_top_eq_eq: "eq_onp top = op="
   246 by (simp add: eq_onp_def)
   247 
   248 lemma eq_onp_same_args:
   249   shows "eq_onp P x x = P x"
   250 using assms by (auto simp add: eq_onp_def)
   251 
   252 lemma Ball_Collect: "Ball A P = (A \<subseteq> (Collect P))"
   253 by auto
   254 
   255 ML_file "Tools/Transfer/transfer.ML"
   256 declare refl [transfer_rule]
   257 
   258 hide_const (open) Rel
   259 
   260 context
   261 begin
   262 interpretation lifting_syntax .
   263 
   264 text \<open>Handling of domains\<close>
   265 
   266 lemma Domainp_iff: "Domainp T x \<longleftrightarrow> (\<exists>y. T x y)"
   267   by auto
   268 
   269 lemma Domainp_refl[transfer_domain_rule]:
   270   "Domainp T = Domainp T" ..
   271 
   272 lemma Domain_eq_top: "Domainp op= = top" by auto
   273 
   274 lemma Domainp_prod_fun_eq[relator_domain]:
   275   "Domainp (op= ===> T) = (\<lambda>f. \<forall>x. (Domainp T) (f x))"
   276 by (auto intro: choice simp: Domainp_iff rel_fun_def fun_eq_iff)
   277 
   278 text \<open>Properties are preserved by relation composition.\<close>
   279 
   280 lemma OO_def: "R OO S = (\<lambda>x z. \<exists>y. R x y \<and> S y z)"
   281   by auto
   282 
   283 lemma bi_total_OO: "\<lbrakk>bi_total A; bi_total B\<rbrakk> \<Longrightarrow> bi_total (A OO B)"
   284   unfolding bi_total_def OO_def by fast
   285 
   286 lemma bi_unique_OO: "\<lbrakk>bi_unique A; bi_unique B\<rbrakk> \<Longrightarrow> bi_unique (A OO B)"
   287   unfolding bi_unique_def OO_def by blast
   288 
   289 lemma right_total_OO:
   290   "\<lbrakk>right_total A; right_total B\<rbrakk> \<Longrightarrow> right_total (A OO B)"
   291   unfolding right_total_def OO_def by fast
   292 
   293 lemma right_unique_OO:
   294   "\<lbrakk>right_unique A; right_unique B\<rbrakk> \<Longrightarrow> right_unique (A OO B)"
   295   unfolding right_unique_def OO_def by fast
   296 
   297 lemma left_total_OO: "left_total R \<Longrightarrow> left_total S \<Longrightarrow> left_total (R OO S)"
   298 unfolding left_total_def OO_def by fast
   299 
   300 lemma left_unique_OO: "left_unique R \<Longrightarrow> left_unique S \<Longrightarrow> left_unique (R OO S)"
   301 unfolding left_unique_def OO_def by blast
   302 
   303 
   304 subsection \<open>Properties of relators\<close>
   305 
   306 lemma left_total_eq[transfer_rule]: "left_total op="
   307   unfolding left_total_def by blast
   308 
   309 lemma left_unique_eq[transfer_rule]: "left_unique op="
   310   unfolding left_unique_def by blast
   311 
   312 lemma right_total_eq [transfer_rule]: "right_total op="
   313   unfolding right_total_def by simp
   314 
   315 lemma right_unique_eq [transfer_rule]: "right_unique op="
   316   unfolding right_unique_def by simp
   317 
   318 lemma bi_total_eq[transfer_rule]: "bi_total (op =)"
   319   unfolding bi_total_def by simp
   320 
   321 lemma bi_unique_eq[transfer_rule]: "bi_unique (op =)"
   322   unfolding bi_unique_def by simp
   323 
   324 lemma left_total_fun[transfer_rule]:
   325   "\<lbrakk>left_unique A; left_total B\<rbrakk> \<Longrightarrow> left_total (A ===> B)"
   326   unfolding left_total_def rel_fun_def
   327   apply (rule allI, rename_tac f)
   328   apply (rule_tac x="\<lambda>y. SOME z. B (f (THE x. A x y)) z" in exI)
   329   apply clarify
   330   apply (subgoal_tac "(THE x. A x y) = x", simp)
   331   apply (rule someI_ex)
   332   apply (simp)
   333   apply (rule the_equality)
   334   apply assumption
   335   apply (simp add: left_unique_def)
   336   done
   337 
   338 lemma left_unique_fun[transfer_rule]:
   339   "\<lbrakk>left_total A; left_unique B\<rbrakk> \<Longrightarrow> left_unique (A ===> B)"
   340   unfolding left_total_def left_unique_def rel_fun_def
   341   by (clarify, rule ext, fast)
   342 
   343 lemma right_total_fun [transfer_rule]:
   344   "\<lbrakk>right_unique A; right_total B\<rbrakk> \<Longrightarrow> right_total (A ===> B)"
   345   unfolding right_total_def rel_fun_def
   346   apply (rule allI, rename_tac g)
   347   apply (rule_tac x="\<lambda>x. SOME z. B z (g (THE y. A x y))" in exI)
   348   apply clarify
   349   apply (subgoal_tac "(THE y. A x y) = y", simp)
   350   apply (rule someI_ex)
   351   apply (simp)
   352   apply (rule the_equality)
   353   apply assumption
   354   apply (simp add: right_unique_def)
   355   done
   356 
   357 lemma right_unique_fun [transfer_rule]:
   358   "\<lbrakk>right_total A; right_unique B\<rbrakk> \<Longrightarrow> right_unique (A ===> B)"
   359   unfolding right_total_def right_unique_def rel_fun_def
   360   by (clarify, rule ext, fast)
   361 
   362 lemma bi_total_fun[transfer_rule]:
   363   "\<lbrakk>bi_unique A; bi_total B\<rbrakk> \<Longrightarrow> bi_total (A ===> B)"
   364   unfolding bi_unique_alt_def bi_total_alt_def
   365   by (blast intro: right_total_fun left_total_fun)
   366 
   367 lemma bi_unique_fun[transfer_rule]:
   368   "\<lbrakk>bi_total A; bi_unique B\<rbrakk> \<Longrightarrow> bi_unique (A ===> B)"
   369   unfolding bi_unique_alt_def bi_total_alt_def
   370   by (blast intro: right_unique_fun left_unique_fun)
   371 
   372 end
   373 
   374 lemma if_conn:
   375   "(if P \<and> Q then t else e) = (if P then if Q then t else e else e)"
   376   "(if P \<or> Q then t else e) = (if P then t else if Q then t else e)"
   377   "(if P \<longrightarrow> Q then t else e) = (if P then if Q then t else e else t)"
   378   "(if \<not> P then t else e) = (if P then e else t)"
   379 by auto
   380 
   381 ML_file "Tools/Transfer/transfer_bnf.ML"
   382 ML_file "Tools/BNF/bnf_fp_rec_sugar_transfer.ML"
   383 
   384 declare pred_fun_def [simp]
   385 declare rel_fun_eq [relator_eq]
   386 
   387 subsection \<open>Transfer rules\<close>
   388 
   389 context
   390 begin
   391 interpretation lifting_syntax .
   392 
   393 lemma Domainp_forall_transfer [transfer_rule]:
   394   assumes "right_total A"
   395   shows "((A ===> op =) ===> op =)
   396     (transfer_bforall (Domainp A)) transfer_forall"
   397   using assms unfolding right_total_def
   398   unfolding transfer_forall_def transfer_bforall_def rel_fun_def Domainp_iff
   399   by fast
   400 
   401 text \<open>Transfer rules using implication instead of equality on booleans.\<close>
   402 
   403 lemma transfer_forall_transfer [transfer_rule]:
   404   "bi_total A \<Longrightarrow> ((A ===> op =) ===> op =) transfer_forall transfer_forall"
   405   "right_total A \<Longrightarrow> ((A ===> op =) ===> implies) transfer_forall transfer_forall"
   406   "right_total A \<Longrightarrow> ((A ===> implies) ===> implies) transfer_forall transfer_forall"
   407   "bi_total A \<Longrightarrow> ((A ===> op =) ===> rev_implies) transfer_forall transfer_forall"
   408   "bi_total A \<Longrightarrow> ((A ===> rev_implies) ===> rev_implies) transfer_forall transfer_forall"
   409   unfolding transfer_forall_def rev_implies_def rel_fun_def right_total_def bi_total_def
   410   by fast+
   411 
   412 lemma transfer_implies_transfer [transfer_rule]:
   413   "(op =        ===> op =        ===> op =       ) transfer_implies transfer_implies"
   414   "(rev_implies ===> implies     ===> implies    ) transfer_implies transfer_implies"
   415   "(rev_implies ===> op =        ===> implies    ) transfer_implies transfer_implies"
   416   "(op =        ===> implies     ===> implies    ) transfer_implies transfer_implies"
   417   "(op =        ===> op =        ===> implies    ) transfer_implies transfer_implies"
   418   "(implies     ===> rev_implies ===> rev_implies) transfer_implies transfer_implies"
   419   "(implies     ===> op =        ===> rev_implies) transfer_implies transfer_implies"
   420   "(op =        ===> rev_implies ===> rev_implies) transfer_implies transfer_implies"
   421   "(op =        ===> op =        ===> rev_implies) transfer_implies transfer_implies"
   422   unfolding transfer_implies_def rev_implies_def rel_fun_def by auto
   423 
   424 lemma eq_imp_transfer [transfer_rule]:
   425   "right_unique A \<Longrightarrow> (A ===> A ===> op \<longrightarrow>) (op =) (op =)"
   426   unfolding right_unique_alt_def2 .
   427 
   428 text \<open>Transfer rules using equality.\<close>
   429 
   430 lemma left_unique_transfer [transfer_rule]:
   431   assumes "right_total A"
   432   assumes "right_total B"
   433   assumes "bi_unique A"
   434   shows "((A ===> B ===> op=) ===> implies) left_unique left_unique"
   435 using assms unfolding left_unique_def[abs_def] right_total_def bi_unique_def rel_fun_def
   436 by metis
   437 
   438 lemma eq_transfer [transfer_rule]:
   439   assumes "bi_unique A"
   440   shows "(A ===> A ===> op =) (op =) (op =)"
   441   using assms unfolding bi_unique_def rel_fun_def by auto
   442 
   443 lemma right_total_Ex_transfer[transfer_rule]:
   444   assumes "right_total A"
   445   shows "((A ===> op=) ===> op=) (Bex (Collect (Domainp A))) Ex"
   446 using assms unfolding right_total_def Bex_def rel_fun_def Domainp_iff[abs_def]
   447 by fast
   448 
   449 lemma right_total_All_transfer[transfer_rule]:
   450   assumes "right_total A"
   451   shows "((A ===> op =) ===> op =) (Ball (Collect (Domainp A))) All"
   452 using assms unfolding right_total_def Ball_def rel_fun_def Domainp_iff[abs_def]
   453 by fast
   454 
   455 lemma All_transfer [transfer_rule]:
   456   assumes "bi_total A"
   457   shows "((A ===> op =) ===> op =) All All"
   458   using assms unfolding bi_total_def rel_fun_def by fast
   459 
   460 lemma Ex_transfer [transfer_rule]:
   461   assumes "bi_total A"
   462   shows "((A ===> op =) ===> op =) Ex Ex"
   463   using assms unfolding bi_total_def rel_fun_def by fast
   464 
   465 lemma Ex1_parametric [transfer_rule]:
   466   assumes [transfer_rule]: "bi_unique A" "bi_total A"
   467   shows "((A ===> op =) ===> op =) Ex1 Ex1"
   468 unfolding Ex1_def[abs_def] by transfer_prover
   469 
   470 declare If_transfer [transfer_rule]
   471 
   472 lemma Let_transfer [transfer_rule]: "(A ===> (A ===> B) ===> B) Let Let"
   473   unfolding rel_fun_def by simp
   474 
   475 declare id_transfer [transfer_rule]
   476 
   477 declare comp_transfer [transfer_rule]
   478 
   479 lemma curry_transfer [transfer_rule]:
   480   "((rel_prod A B ===> C) ===> A ===> B ===> C) curry curry"
   481   unfolding curry_def by transfer_prover
   482 
   483 lemma fun_upd_transfer [transfer_rule]:
   484   assumes [transfer_rule]: "bi_unique A"
   485   shows "((A ===> B) ===> A ===> B ===> A ===> B) fun_upd fun_upd"
   486   unfolding fun_upd_def [abs_def] by transfer_prover
   487 
   488 lemma case_nat_transfer [transfer_rule]:
   489   "(A ===> (op = ===> A) ===> op = ===> A) case_nat case_nat"
   490   unfolding rel_fun_def by (simp split: nat.split)
   491 
   492 lemma rec_nat_transfer [transfer_rule]:
   493   "(A ===> (op = ===> A ===> A) ===> op = ===> A) rec_nat rec_nat"
   494   unfolding rel_fun_def by (clarsimp, rename_tac n, induct_tac n, simp_all)
   495 
   496 lemma funpow_transfer [transfer_rule]:
   497   "(op = ===> (A ===> A) ===> (A ===> A)) compow compow"
   498   unfolding funpow_def by transfer_prover
   499 
   500 lemma mono_transfer[transfer_rule]:
   501   assumes [transfer_rule]: "bi_total A"
   502   assumes [transfer_rule]: "(A ===> A ===> op=) op\<le> op\<le>"
   503   assumes [transfer_rule]: "(B ===> B ===> op=) op\<le> op\<le>"
   504   shows "((A ===> B) ===> op=) mono mono"
   505 unfolding mono_def[abs_def] by transfer_prover
   506 
   507 lemma right_total_relcompp_transfer[transfer_rule]:
   508   assumes [transfer_rule]: "right_total B"
   509   shows "((A ===> B ===> op=) ===> (B ===> C ===> op=) ===> A ===> C ===> op=)
   510     (\<lambda>R S x z. \<exists>y\<in>Collect (Domainp B). R x y \<and> S y z) op OO"
   511 unfolding OO_def[abs_def] by transfer_prover
   512 
   513 lemma relcompp_transfer[transfer_rule]:
   514   assumes [transfer_rule]: "bi_total B"
   515   shows "((A ===> B ===> op=) ===> (B ===> C ===> op=) ===> A ===> C ===> op=) op OO op OO"
   516 unfolding OO_def[abs_def] by transfer_prover
   517 
   518 lemma right_total_Domainp_transfer[transfer_rule]:
   519   assumes [transfer_rule]: "right_total B"
   520   shows "((A ===> B ===> op=) ===> A ===> op=) (\<lambda>T x. \<exists>y\<in>Collect(Domainp B). T x y) Domainp"
   521 apply(subst(2) Domainp_iff[abs_def]) by transfer_prover
   522 
   523 lemma Domainp_transfer[transfer_rule]:
   524   assumes [transfer_rule]: "bi_total B"
   525   shows "((A ===> B ===> op=) ===> A ===> op=) Domainp Domainp"
   526 unfolding Domainp_iff[abs_def] by transfer_prover
   527 
   528 lemma reflp_transfer[transfer_rule]:
   529   "bi_total A \<Longrightarrow> ((A ===> A ===> op=) ===> op=) reflp reflp"
   530   "right_total A \<Longrightarrow> ((A ===> A ===> implies) ===> implies) reflp reflp"
   531   "right_total A \<Longrightarrow> ((A ===> A ===> op=) ===> implies) reflp reflp"
   532   "bi_total A \<Longrightarrow> ((A ===> A ===> rev_implies) ===> rev_implies) reflp reflp"
   533   "bi_total A \<Longrightarrow> ((A ===> A ===> op=) ===> rev_implies) reflp reflp"
   534 using assms unfolding reflp_def[abs_def] rev_implies_def bi_total_def right_total_def rel_fun_def
   535 by fast+
   536 
   537 lemma right_unique_transfer [transfer_rule]:
   538   "\<lbrakk> right_total A; right_total B; bi_unique B \<rbrakk>
   539   \<Longrightarrow> ((A ===> B ===> op=) ===> implies) right_unique right_unique"
   540 unfolding right_unique_def[abs_def] right_total_def bi_unique_def rel_fun_def
   541 by metis
   542 
   543 lemma left_total_parametric [transfer_rule]:
   544   assumes [transfer_rule]: "bi_total A" "bi_total B"
   545   shows "((A ===> B ===> op =) ===> op =) left_total left_total"
   546 unfolding left_total_def[abs_def] by transfer_prover
   547 
   548 lemma right_total_parametric [transfer_rule]:
   549   assumes [transfer_rule]: "bi_total A" "bi_total B"
   550   shows "((A ===> B ===> op =) ===> op =) right_total right_total"
   551 unfolding right_total_def[abs_def] by transfer_prover
   552 
   553 lemma left_unique_parametric [transfer_rule]:
   554   assumes [transfer_rule]: "bi_unique A" "bi_total A" "bi_total B"
   555   shows "((A ===> B ===> op =) ===> op =) left_unique left_unique"
   556 unfolding left_unique_def[abs_def] by transfer_prover
   557 
   558 lemma prod_pred_parametric [transfer_rule]:
   559   "((A ===> op =) ===> (B ===> op =) ===> rel_prod A B ===> op =) pred_prod pred_prod"
   560 unfolding pred_prod_def[abs_def] Basic_BNFs.fsts_def Basic_BNFs.snds_def fstsp.simps sndsp.simps 
   561 by simp transfer_prover
   562 
   563 lemma apfst_parametric [transfer_rule]:
   564   "((A ===> B) ===> rel_prod A C ===> rel_prod B C) apfst apfst"
   565 unfolding apfst_def[abs_def] by transfer_prover
   566 
   567 lemma rel_fun_eq_eq_onp: "(op= ===> eq_onp P) = eq_onp (\<lambda>f. \<forall>x. P(f x))"
   568 unfolding eq_onp_def rel_fun_def by auto
   569 
   570 lemma rel_fun_eq_onp_rel:
   571   shows "((eq_onp R) ===> S) = (\<lambda>f g. \<forall>x. R x \<longrightarrow> S (f x) (g x))"
   572 by (auto simp add: eq_onp_def rel_fun_def)
   573 
   574 lemma eq_onp_transfer [transfer_rule]:
   575   assumes [transfer_rule]: "bi_unique A"
   576   shows "((A ===> op=) ===> A ===> A ===> op=) eq_onp eq_onp"
   577 unfolding eq_onp_def[abs_def] by transfer_prover
   578 
   579 lemma rtranclp_parametric [transfer_rule]:
   580   assumes "bi_unique A" "bi_total A"
   581   shows "((A ===> A ===> op =) ===> A ===> A ===> op =) rtranclp rtranclp"
   582 proof(rule rel_funI iffI)+
   583   fix R :: "'a \<Rightarrow> 'a \<Rightarrow> bool" and R' x y x' y'
   584   assume R: "(A ===> A ===> op =) R R'" and "A x x'"
   585   {
   586     assume "R\<^sup>*\<^sup>* x y" "A y y'"
   587     thus "R'\<^sup>*\<^sup>* x' y'"
   588     proof(induction arbitrary: y')
   589       case base
   590       with \<open>bi_unique A\<close> \<open>A x x'\<close> have "x' = y'" by(rule bi_uniqueDr)
   591       thus ?case by simp
   592     next
   593       case (step y z z')
   594       from \<open>bi_total A\<close> obtain y' where "A y y'" unfolding bi_total_def by blast
   595       hence "R'\<^sup>*\<^sup>* x' y'" by(rule step.IH)
   596       moreover from R \<open>A y y'\<close> \<open>A z z'\<close> \<open>R y z\<close>
   597       have "R' y' z'" by(auto dest: rel_funD)
   598       ultimately show ?case ..
   599     qed
   600   next
   601     assume "R'\<^sup>*\<^sup>* x' y'" "A y y'"
   602     thus "R\<^sup>*\<^sup>* x y"
   603     proof(induction arbitrary: y)
   604       case base
   605       with \<open>bi_unique A\<close> \<open>A x x'\<close> have "x = y" by(rule bi_uniqueDl)
   606       thus ?case by simp
   607     next
   608       case (step y' z' z)
   609       from \<open>bi_total A\<close> obtain y where "A y y'" unfolding bi_total_def by blast
   610       hence "R\<^sup>*\<^sup>* x y" by(rule step.IH)
   611       moreover from R \<open>A y y'\<close> \<open>A z z'\<close> \<open>R' y' z'\<close>
   612       have "R y z" by(auto dest: rel_funD)
   613       ultimately show ?case ..
   614     qed
   615   }
   616 qed
   617 
   618 lemma right_unique_parametric [transfer_rule]:
   619   assumes [transfer_rule]: "bi_total A" "bi_unique B" "bi_total B"
   620   shows "((A ===> B ===> op =) ===> op =) right_unique right_unique"
   621 unfolding right_unique_def[abs_def] by transfer_prover
   622 
   623 end
   624 
   625 end