src/HOL/Nat.thy
author haftmann
Sat Jul 05 11:01:53 2014 +0200 (2014-07-05)
changeset 57514 bdc2c6b40bf2
parent 57512 cc97b347b301
child 57952 1a9a6dfc255f
permissions -rw-r--r--
prefer ac_simps collections over separate name bindings for add and mult
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 begin
    13 
    14 ML_file "~~/src/Tools/rat.ML"
    15 ML_file "Tools/arith_data.ML"
    16 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    17 
    18 
    19 subsection {* Type @{text ind} *}
    20 
    21 typedecl ind
    22 
    23 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    24   -- {* the axiom of infinity in 2 parts *}
    25   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    26   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    27 
    28 subsection {* Type nat *}
    29 
    30 text {* Type definition *}
    31 
    32 inductive Nat :: "ind \<Rightarrow> bool" where
    33   Zero_RepI: "Nat Zero_Rep"
    34 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    35 
    36 typedef nat = "{n. Nat n}"
    37   morphisms Rep_Nat Abs_Nat
    38   using Nat.Zero_RepI by auto
    39 
    40 lemma Nat_Rep_Nat:
    41   "Nat (Rep_Nat n)"
    42   using Rep_Nat by simp
    43 
    44 lemma Nat_Abs_Nat_inverse:
    45   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    46   using Abs_Nat_inverse by simp
    47 
    48 lemma Nat_Abs_Nat_inject:
    49   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    50   using Abs_Nat_inject by simp
    51 
    52 instantiation nat :: zero
    53 begin
    54 
    55 definition Zero_nat_def:
    56   "0 = Abs_Nat Zero_Rep"
    57 
    58 instance ..
    59 
    60 end
    61 
    62 definition Suc :: "nat \<Rightarrow> nat" where
    63   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    67 
    68 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    69   by (rule not_sym, rule Suc_not_Zero not_sym)
    70 
    71 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    72   by (rule iffI, rule Suc_Rep_inject) simp_all
    73 
    74 lemma nat_induct0:
    75   fixes n
    76   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    77   shows "P n"
    78 using assms
    79 apply (unfold Zero_nat_def Suc_def)
    80 apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    81 apply (erule Nat_Rep_Nat [THEN Nat.induct])
    82 apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    83 done
    84 
    85 free_constructors case_nat for
    86     "0 \<Colon> nat"
    87   | Suc pred
    88 where
    89   "pred (0 \<Colon> nat) = (0 \<Colon> nat)"
    90   apply atomize_elim
    91   apply (rename_tac n, induct_tac n rule: nat_induct0, auto)
    92  apply (simp add: Suc_def Nat_Abs_Nat_inject Nat_Rep_Nat Suc_RepI
    93    Suc_Rep_inject' Rep_Nat_inject)
    94 apply (simp only: Suc_not_Zero)
    95 done
    96 
    97 -- {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    98 setup {* Sign.mandatory_path "old" *}
    99 
   100 rep_datatype "0 \<Colon> nat" Suc
   101   apply (erule nat_induct0, assumption)
   102  apply (rule nat.inject)
   103 apply (rule nat.distinct(1))
   104 done
   105 
   106 setup {* Sign.parent_path *}
   107 
   108 -- {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   109 setup {* Sign.mandatory_path "nat" *}
   110 
   111 declare
   112   old.nat.inject[iff del]
   113   old.nat.distinct(1)[simp del, induct_simp del]
   114 
   115 lemmas induct = old.nat.induct
   116 lemmas inducts = old.nat.inducts
   117 lemmas rec = old.nat.rec
   118 lemmas simps = nat.inject nat.distinct nat.case nat.rec
   119 
   120 setup {* Sign.parent_path *}
   121 
   122 abbreviation rec_nat :: "'a \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a" where
   123   "rec_nat \<equiv> old.rec_nat"
   124 
   125 declare nat.sel[code del]
   126 
   127 hide_const (open) Nat.pred -- {* hide everything related to the selector *}
   128 hide_fact
   129   nat.case_eq_if
   130   nat.collapse
   131   nat.expand
   132   nat.sel
   133   nat.sel_exhaust
   134   nat.sel_split
   135   nat.sel_split_asm
   136 
   137 lemma nat_exhaust [case_names 0 Suc, cases type: nat]:
   138   -- {* for backward compatibility -- names of variables differ *}
   139   "(y = 0 \<Longrightarrow> P) \<Longrightarrow> (\<And>nat. y = Suc nat \<Longrightarrow> P) \<Longrightarrow> P"
   140 by (rule old.nat.exhaust)
   141 
   142 lemma nat_induct [case_names 0 Suc, induct type: nat]:
   143   -- {* for backward compatibility -- names of variables differ *}
   144   fixes n
   145   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
   146   shows "P n"
   147 using assms by (rule nat.induct)
   148 
   149 hide_fact
   150   nat_exhaust
   151   nat_induct0
   152 
   153 text {* Injectiveness and distinctness lemmas *}
   154 
   155 lemma inj_Suc[simp]: "inj_on Suc N"
   156   by (simp add: inj_on_def)
   157 
   158 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   159 by (rule notE, rule Suc_not_Zero)
   160 
   161 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   162 by (rule Suc_neq_Zero, erule sym)
   163 
   164 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   165 by (rule inj_Suc [THEN injD])
   166 
   167 lemma n_not_Suc_n: "n \<noteq> Suc n"
   168 by (induct n) simp_all
   169 
   170 lemma Suc_n_not_n: "Suc n \<noteq> n"
   171 by (rule not_sym, rule n_not_Suc_n)
   172 
   173 text {* A special form of induction for reasoning
   174   about @{term "m < n"} and @{term "m - n"} *}
   175 
   176 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   177     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   178   apply (rule_tac x = m in spec)
   179   apply (induct n)
   180   prefer 2
   181   apply (rule allI)
   182   apply (induct_tac x, iprover+)
   183   done
   184 
   185 
   186 subsection {* Arithmetic operators *}
   187 
   188 instantiation nat :: comm_monoid_diff
   189 begin
   190 
   191 primrec plus_nat where
   192   add_0:      "0 + n = (n\<Colon>nat)"
   193 | add_Suc:  "Suc m + n = Suc (m + n)"
   194 
   195 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   196   by (induct m) simp_all
   197 
   198 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   199   by (induct m) simp_all
   200 
   201 declare add_0 [code]
   202 
   203 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   204   by simp
   205 
   206 primrec minus_nat where
   207   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   208 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   209 
   210 declare diff_Suc [simp del]
   211 
   212 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   213   by (induct n) (simp_all add: diff_Suc)
   214 
   215 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   216   by (induct n) (simp_all add: diff_Suc)
   217 
   218 instance proof
   219   fix n m q :: nat
   220   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   221   show "n + m = m + n" by (induct n) simp_all
   222   show "0 + n = n" by simp
   223   show "n - 0 = n" by simp
   224   show "0 - n = 0" by simp
   225   show "(q + n) - (q + m) = n - m" by (induct q) simp_all
   226   show "n - m - q = n - (m + q)" by (induct q) (simp_all add: diff_Suc)
   227 qed
   228 
   229 end
   230 
   231 hide_fact (open) add_0 add_0_right diff_0
   232 
   233 instantiation nat :: comm_semiring_1_cancel
   234 begin
   235 
   236 definition
   237   One_nat_def [simp]: "1 = Suc 0"
   238 
   239 primrec times_nat where
   240   mult_0:     "0 * n = (0\<Colon>nat)"
   241 | mult_Suc: "Suc m * n = n + (m * n)"
   242 
   243 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   244   by (induct m) simp_all
   245 
   246 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   247   by (induct m) (simp_all add: add.left_commute)
   248 
   249 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   250   by (induct m) (simp_all add: add.assoc)
   251 
   252 instance proof
   253   fix n m q :: nat
   254   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   255   show "1 * n = n" unfolding One_nat_def by simp
   256   show "n * m = m * n" by (induct n) simp_all
   257   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   258   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   259   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   260 qed
   261 
   262 end
   263 
   264 subsubsection {* Addition *}
   265 
   266 lemma nat_add_left_cancel:
   267   fixes k m n :: nat
   268   shows "k + m = k + n \<longleftrightarrow> m = n"
   269   by (fact add_left_cancel)
   270 
   271 lemma nat_add_right_cancel:
   272   fixes k m n :: nat
   273   shows "m + k = n + k \<longleftrightarrow> m = n"
   274   by (fact add_right_cancel)
   275 
   276 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   277 
   278 lemma add_is_0 [iff]:
   279   fixes m n :: nat
   280   shows "(m + n = 0) = (m = 0 & n = 0)"
   281   by (cases m) simp_all
   282 
   283 lemma add_is_1:
   284   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   285   by (cases m) simp_all
   286 
   287 lemma one_is_add:
   288   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   289   by (rule trans, rule eq_commute, rule add_is_1)
   290 
   291 lemma add_eq_self_zero:
   292   fixes m n :: nat
   293   shows "m + n = m \<Longrightarrow> n = 0"
   294   by (induct m) simp_all
   295 
   296 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   297   apply (induct k)
   298    apply simp
   299   apply(drule comp_inj_on[OF _ inj_Suc])
   300   apply (simp add:o_def)
   301   done
   302 
   303 lemma Suc_eq_plus1: "Suc n = n + 1"
   304   unfolding One_nat_def by simp
   305 
   306 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   307   unfolding One_nat_def by simp
   308 
   309 
   310 subsubsection {* Difference *}
   311 
   312 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   313   by (fact diff_cancel)
   314 
   315 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   316   by (fact diff_diff_add)
   317 
   318 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   319   by (simp add: diff_diff_left)
   320 
   321 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   322   by (fact diff_right_commute)
   323 
   324 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   325   by (fact add_diff_cancel_left')
   326 
   327 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   328   by (fact add_diff_cancel_right')
   329 
   330 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   331   by (fact comm_monoid_diff_class.add_diff_cancel_left)
   332 
   333 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   334   by (fact add_diff_cancel_right)
   335 
   336 lemma diff_add_0: "n - (n + m) = (0::nat)"
   337   by (fact diff_add_zero)
   338 
   339 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   340   unfolding One_nat_def by simp
   341 
   342 text {* Difference distributes over multiplication *}
   343 
   344 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   345 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   346 
   347 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   348 by (simp add: diff_mult_distrib mult.commute [of k])
   349   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   350 
   351 
   352 subsubsection {* Multiplication *}
   353 
   354 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   355   by (fact distrib_left)
   356 
   357 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   358   by (induct m) auto
   359 
   360 lemmas nat_distrib =
   361   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   362 
   363 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   364   apply (induct m)
   365    apply simp
   366   apply (induct n)
   367    apply auto
   368   done
   369 
   370 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   371   apply (rule trans)
   372   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   373   done
   374 
   375 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   376   unfolding One_nat_def by (rule mult_eq_1_iff)
   377 
   378 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   379   unfolding One_nat_def by (rule one_eq_mult_iff)
   380 
   381 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   382 proof -
   383   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   384   proof (induct n arbitrary: m)
   385     case 0 then show "m = 0" by simp
   386   next
   387     case (Suc n) then show "m = Suc n"
   388       by (cases m) (simp_all add: eq_commute [of "0"])
   389   qed
   390   then show ?thesis by auto
   391 qed
   392 
   393 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   394   by (simp add: mult.commute)
   395 
   396 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   397   by (subst mult_cancel1) simp
   398 
   399 
   400 subsection {* Orders on @{typ nat} *}
   401 
   402 subsubsection {* Operation definition *}
   403 
   404 instantiation nat :: linorder
   405 begin
   406 
   407 primrec less_eq_nat where
   408   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   409 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   410 
   411 declare less_eq_nat.simps [simp del]
   412 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   413 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by simp
   414 
   415 definition less_nat where
   416   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   417 
   418 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   419   by (simp add: less_eq_nat.simps(2))
   420 
   421 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   422   unfolding less_eq_Suc_le ..
   423 
   424 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   425   by (induct n) (simp_all add: less_eq_nat.simps(2))
   426 
   427 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   428   by (simp add: less_eq_Suc_le)
   429 
   430 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   431   by simp
   432 
   433 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   434   by (simp add: less_eq_Suc_le)
   435 
   436 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   437   by (simp add: less_eq_Suc_le)
   438 
   439 lemma Suc_less_eq2: "Suc n < m \<longleftrightarrow> (\<exists>m'. m = Suc m' \<and> n < m')"
   440   by (cases m) auto
   441 
   442 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   443   by (induct m arbitrary: n)
   444     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   445 
   446 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   447   by (cases n) (auto intro: le_SucI)
   448 
   449 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   450   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   451 
   452 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   453   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   454 
   455 instance
   456 proof
   457   fix n m :: nat
   458   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   459   proof (induct n arbitrary: m)
   460     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   461   next
   462     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   463   qed
   464 next
   465   fix n :: nat show "n \<le> n" by (induct n) simp_all
   466 next
   467   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   468   then show "n = m"
   469     by (induct n arbitrary: m)
   470       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   471 next
   472   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   473   then show "n \<le> q"
   474   proof (induct n arbitrary: m q)
   475     case 0 show ?case by simp
   476   next
   477     case (Suc n) then show ?case
   478       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   479         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   480         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   481   qed
   482 next
   483   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   484     by (induct n arbitrary: m)
   485       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   486 qed
   487 
   488 end
   489 
   490 instantiation nat :: order_bot
   491 begin
   492 
   493 definition bot_nat :: nat where
   494   "bot_nat = 0"
   495 
   496 instance proof
   497 qed (simp add: bot_nat_def)
   498 
   499 end
   500 
   501 instance nat :: no_top
   502   by default (auto intro: less_Suc_eq_le [THEN iffD2])
   503 
   504 
   505 subsubsection {* Introduction properties *}
   506 
   507 lemma lessI [iff]: "n < Suc n"
   508   by (simp add: less_Suc_eq_le)
   509 
   510 lemma zero_less_Suc [iff]: "0 < Suc n"
   511   by (simp add: less_Suc_eq_le)
   512 
   513 
   514 subsubsection {* Elimination properties *}
   515 
   516 lemma less_not_refl: "~ n < (n::nat)"
   517   by (rule order_less_irrefl)
   518 
   519 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   520   by (rule not_sym) (rule less_imp_neq) 
   521 
   522 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   523   by (rule less_imp_neq)
   524 
   525 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   526   by (rule notE, rule less_not_refl)
   527 
   528 lemma less_zeroE: "(n::nat) < 0 ==> R"
   529   by (rule notE) (rule not_less0)
   530 
   531 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   532   unfolding less_Suc_eq_le le_less ..
   533 
   534 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   535   by (simp add: less_Suc_eq)
   536 
   537 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   538   unfolding One_nat_def by (rule less_Suc0)
   539 
   540 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   541   by simp
   542 
   543 text {* "Less than" is antisymmetric, sort of *}
   544 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   545   unfolding not_less less_Suc_eq_le by (rule antisym)
   546 
   547 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   548   by (rule linorder_neq_iff)
   549 
   550 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   551   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   552   shows "P n m"
   553   apply (rule less_linear [THEN disjE])
   554   apply (erule_tac [2] disjE)
   555   apply (erule lessCase)
   556   apply (erule sym [THEN eqCase])
   557   apply (erule major)
   558   done
   559 
   560 
   561 subsubsection {* Inductive (?) properties *}
   562 
   563 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   564   unfolding less_eq_Suc_le [of m] le_less by simp 
   565 
   566 lemma lessE:
   567   assumes major: "i < k"
   568   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   569   shows P
   570 proof -
   571   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   572     unfolding less_eq_Suc_le by (induct k) simp_all
   573   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   574     by (clarsimp simp add: less_le)
   575   with p1 p2 show P by auto
   576 qed
   577 
   578 lemma less_SucE: assumes major: "m < Suc n"
   579   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   580   apply (rule major [THEN lessE])
   581   apply (rule eq, blast)
   582   apply (rule less, blast)
   583   done
   584 
   585 lemma Suc_lessE: assumes major: "Suc i < k"
   586   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   587   apply (rule major [THEN lessE])
   588   apply (erule lessI [THEN minor])
   589   apply (erule Suc_lessD [THEN minor], assumption)
   590   done
   591 
   592 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   593   by simp
   594 
   595 lemma less_trans_Suc:
   596   assumes le: "i < j" shows "j < k ==> Suc i < k"
   597   apply (induct k, simp_all)
   598   apply (insert le)
   599   apply (simp add: less_Suc_eq)
   600   apply (blast dest: Suc_lessD)
   601   done
   602 
   603 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   604 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   605   unfolding not_less less_Suc_eq_le ..
   606 
   607 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   608   unfolding not_le Suc_le_eq ..
   609 
   610 text {* Properties of "less than or equal" *}
   611 
   612 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   613   unfolding less_Suc_eq_le .
   614 
   615 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   616   unfolding not_le less_Suc_eq_le ..
   617 
   618 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   619   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   620 
   621 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   622   by (drule le_Suc_eq [THEN iffD1], iprover+)
   623 
   624 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   625   unfolding Suc_le_eq .
   626 
   627 text {* Stronger version of @{text Suc_leD} *}
   628 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   629   unfolding Suc_le_eq .
   630 
   631 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   632   unfolding less_eq_Suc_le by (rule Suc_leD)
   633 
   634 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   635 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   636 
   637 
   638 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   639 
   640 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   641   unfolding le_less .
   642 
   643 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   644   by (rule le_less)
   645 
   646 text {* Useful with @{text blast}. *}
   647 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   648   by auto
   649 
   650 lemma le_refl: "n \<le> (n::nat)"
   651   by simp
   652 
   653 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   654   by (rule order_trans)
   655 
   656 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   657   by (rule antisym)
   658 
   659 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   660   by (rule less_le)
   661 
   662 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   663   unfolding less_le ..
   664 
   665 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   666   by (rule linear)
   667 
   668 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   669 
   670 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   671   unfolding less_Suc_eq_le by auto
   672 
   673 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   674   unfolding not_less by (rule le_less_Suc_eq)
   675 
   676 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   677 
   678 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   679 by (cases n) simp_all
   680 
   681 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   682 by (cases n) simp_all
   683 
   684 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   685 by (cases n) simp_all
   686 
   687 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   688 by (cases n) simp_all
   689 
   690 text {* This theorem is useful with @{text blast} *}
   691 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   692 by (rule neq0_conv[THEN iffD1], iprover)
   693 
   694 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   695 by (fast intro: not0_implies_Suc)
   696 
   697 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   698 using neq0_conv by blast
   699 
   700 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   701 by (induct m') simp_all
   702 
   703 text {* Useful in certain inductive arguments *}
   704 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   705 by (cases m) simp_all
   706 
   707 
   708 subsubsection {* Monotonicity of Addition *}
   709 
   710 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   711 by (simp add: diff_Suc split: nat.split)
   712 
   713 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   714 unfolding One_nat_def by (rule Suc_pred)
   715 
   716 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   717 by (induct k) simp_all
   718 
   719 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   720 by (induct k) simp_all
   721 
   722 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   723 by(auto dest:gr0_implies_Suc)
   724 
   725 text {* strict, in 1st argument *}
   726 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   727 by (induct k) simp_all
   728 
   729 text {* strict, in both arguments *}
   730 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   731   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   732   apply (induct j, simp_all)
   733   done
   734 
   735 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   736 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   737   apply (induct n)
   738   apply (simp_all add: order_le_less)
   739   apply (blast elim!: less_SucE
   740                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   741   done
   742 
   743 lemma le_Suc_ex: "(k::nat) \<le> l \<Longrightarrow> (\<exists>n. l = k + n)"
   744   by (auto simp: less_Suc_eq_le[symmetric] dest: less_imp_Suc_add)
   745 
   746 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   747 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   748 apply(auto simp: gr0_conv_Suc)
   749 apply (induct_tac m)
   750 apply (simp_all add: add_less_mono)
   751 done
   752 
   753 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   754 instance nat :: linordered_semidom
   755 proof
   756   show "0 < (1::nat)" by simp
   757   show "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q + m \<le> q + n" by simp
   758   show "\<And>m n q :: nat. m < n \<Longrightarrow> 0 < q \<Longrightarrow> q * m < q * n" by (simp add: mult_less_mono2)
   759 qed
   760 
   761 instance nat :: no_zero_divisors
   762 proof
   763   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   764 qed
   765 
   766 
   767 subsubsection {* @{term min} and @{term max} *}
   768 
   769 lemma mono_Suc: "mono Suc"
   770 by (rule monoI) simp
   771 
   772 lemma min_0L [simp]: "min 0 n = (0::nat)"
   773 by (rule min_absorb1) simp
   774 
   775 lemma min_0R [simp]: "min n 0 = (0::nat)"
   776 by (rule min_absorb2) simp
   777 
   778 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   779 by (simp add: mono_Suc min_of_mono)
   780 
   781 lemma min_Suc1:
   782    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   783 by (simp split: nat.split)
   784 
   785 lemma min_Suc2:
   786    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   787 by (simp split: nat.split)
   788 
   789 lemma max_0L [simp]: "max 0 n = (n::nat)"
   790 by (rule max_absorb2) simp
   791 
   792 lemma max_0R [simp]: "max n 0 = (n::nat)"
   793 by (rule max_absorb1) simp
   794 
   795 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   796 by (simp add: mono_Suc max_of_mono)
   797 
   798 lemma max_Suc1:
   799    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   800 by (simp split: nat.split)
   801 
   802 lemma max_Suc2:
   803    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   804 by (simp split: nat.split)
   805 
   806 lemma nat_mult_min_left:
   807   fixes m n q :: nat
   808   shows "min m n * q = min (m * q) (n * q)"
   809   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   810 
   811 lemma nat_mult_min_right:
   812   fixes m n q :: nat
   813   shows "m * min n q = min (m * n) (m * q)"
   814   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   815 
   816 lemma nat_add_max_left:
   817   fixes m n q :: nat
   818   shows "max m n + q = max (m + q) (n + q)"
   819   by (simp add: max_def)
   820 
   821 lemma nat_add_max_right:
   822   fixes m n q :: nat
   823   shows "m + max n q = max (m + n) (m + q)"
   824   by (simp add: max_def)
   825 
   826 lemma nat_mult_max_left:
   827   fixes m n q :: nat
   828   shows "max m n * q = max (m * q) (n * q)"
   829   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   830 
   831 lemma nat_mult_max_right:
   832   fixes m n q :: nat
   833   shows "m * max n q = max (m * n) (m * q)"
   834   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   835 
   836 
   837 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   838 
   839 text {* Complete induction, aka course-of-values induction *}
   840 
   841 instance nat :: wellorder proof
   842   fix P and n :: nat
   843   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   844   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   845   proof (induct n)
   846     case (0 n)
   847     have "P 0" by (rule step) auto
   848     thus ?case using 0 by auto
   849   next
   850     case (Suc m n)
   851     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   852     thus ?case
   853     proof
   854       assume "n \<le> m" thus "P n" by (rule Suc(1))
   855     next
   856       assume n: "n = Suc m"
   857       show "P n"
   858         by (rule step) (rule Suc(1), simp add: n le_simps)
   859     qed
   860   qed
   861   then show "P n" by auto
   862 qed
   863 
   864 
   865 lemma Least_eq_0[simp]: "P(0::nat) \<Longrightarrow> Least P = 0"
   866 by (rule Least_equality[OF _ le0])
   867 
   868 lemma Least_Suc:
   869      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   870   apply (cases n, auto)
   871   apply (frule LeastI)
   872   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   873   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   874   apply (erule_tac [2] Least_le)
   875   apply (cases "LEAST x. P x", auto)
   876   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   877   apply (blast intro: order_antisym)
   878   done
   879 
   880 lemma Least_Suc2:
   881    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   882   apply (erule (1) Least_Suc [THEN ssubst])
   883   apply simp
   884   done
   885 
   886 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   887   apply (cases n)
   888    apply blast
   889   apply (rule_tac x="LEAST k. P(k)" in exI)
   890   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   891   done
   892 
   893 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   894   unfolding One_nat_def
   895   apply (cases n)
   896    apply blast
   897   apply (frule (1) ex_least_nat_le)
   898   apply (erule exE)
   899   apply (case_tac k)
   900    apply simp
   901   apply (rename_tac k1)
   902   apply (rule_tac x=k1 in exI)
   903   apply (auto simp add: less_eq_Suc_le)
   904   done
   905 
   906 lemma nat_less_induct:
   907   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   908   using assms less_induct by blast
   909 
   910 lemma measure_induct_rule [case_names less]:
   911   fixes f :: "'a \<Rightarrow> nat"
   912   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   913   shows "P a"
   914 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   915 
   916 text {* old style induction rules: *}
   917 lemma measure_induct:
   918   fixes f :: "'a \<Rightarrow> nat"
   919   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   920   by (rule measure_induct_rule [of f P a]) iprover
   921 
   922 lemma full_nat_induct:
   923   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   924   shows "P n"
   925   by (rule less_induct) (auto intro: step simp:le_simps)
   926 
   927 text{*An induction rule for estabilishing binary relations*}
   928 lemma less_Suc_induct:
   929   assumes less:  "i < j"
   930      and  step:  "!!i. P i (Suc i)"
   931      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   932   shows "P i j"
   933 proof -
   934   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   935   have "P i (Suc (i + k))"
   936   proof (induct k)
   937     case 0
   938     show ?case by (simp add: step)
   939   next
   940     case (Suc k)
   941     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   942     hence "i < Suc (i + k)" by (simp add: add.commute)
   943     from trans[OF this lessI Suc step]
   944     show ?case by simp
   945   qed
   946   thus "P i j" by (simp add: j)
   947 qed
   948 
   949 text {* The method of infinite descent, frequently used in number theory.
   950 Provided by Roelof Oosterhuis.
   951 $P(n)$ is true for all $n\in\mathbb{N}$ if
   952 \begin{itemize}
   953   \item case ``0'': given $n=0$ prove $P(n)$,
   954   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   955         a smaller integer $m$ such that $\neg P(m)$.
   956 \end{itemize} *}
   957 
   958 text{* A compact version without explicit base case: *}
   959 lemma infinite_descent:
   960   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   961 by (induct n rule: less_induct) auto
   962 
   963 lemma infinite_descent0[case_names 0 smaller]: 
   964   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   965 by (rule infinite_descent) (case_tac "n>0", auto)
   966 
   967 text {*
   968 Infinite descent using a mapping to $\mathbb{N}$:
   969 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   970 \begin{itemize}
   971 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   972 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   973 \end{itemize}
   974 NB: the proof also shows how to use the previous lemma. *}
   975 
   976 corollary infinite_descent0_measure [case_names 0 smaller]:
   977   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   978     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   979   shows "P x"
   980 proof -
   981   obtain n where "n = V x" by auto
   982   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   983   proof (induct n rule: infinite_descent0)
   984     case 0 -- "i.e. $V(x) = 0$"
   985     with A0 show "P x" by auto
   986   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   987     case (smaller n)
   988     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   989     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   990     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   991     then show ?case by auto
   992   qed
   993   ultimately show "P x" by auto
   994 qed
   995 
   996 text{* Again, without explicit base case: *}
   997 lemma infinite_descent_measure:
   998 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   999 proof -
  1000   from assms obtain n where "n = V x" by auto
  1001   moreover have "!!x. V x = n \<Longrightarrow> P x"
  1002   proof (induct n rule: infinite_descent, auto)
  1003     fix x assume "\<not> P x"
  1004     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
  1005   qed
  1006   ultimately show "P x" by auto
  1007 qed
  1008 
  1009 text {* A [clumsy] way of lifting @{text "<"}
  1010   monotonicity to @{text "\<le>"} monotonicity *}
  1011 lemma less_mono_imp_le_mono:
  1012   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
  1013 by (simp add: order_le_less) (blast)
  1014 
  1015 
  1016 text {* non-strict, in 1st argument *}
  1017 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
  1018 by (rule add_right_mono)
  1019 
  1020 text {* non-strict, in both arguments *}
  1021 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
  1022 by (rule add_mono)
  1023 
  1024 lemma le_add2: "n \<le> ((m + n)::nat)"
  1025 by (insert add_right_mono [of 0 m n], simp)
  1026 
  1027 lemma le_add1: "n \<le> ((n + m)::nat)"
  1028 by (simp add: add.commute, rule le_add2)
  1029 
  1030 lemma less_add_Suc1: "i < Suc (i + m)"
  1031 by (rule le_less_trans, rule le_add1, rule lessI)
  1032 
  1033 lemma less_add_Suc2: "i < Suc (m + i)"
  1034 by (rule le_less_trans, rule le_add2, rule lessI)
  1035 
  1036 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
  1037 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
  1038 
  1039 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
  1040 by (rule le_trans, assumption, rule le_add1)
  1041 
  1042 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
  1043 by (rule le_trans, assumption, rule le_add2)
  1044 
  1045 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
  1046 by (rule less_le_trans, assumption, rule le_add1)
  1047 
  1048 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1049 by (rule less_le_trans, assumption, rule le_add2)
  1050 
  1051 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1052 apply (rule le_less_trans [of _ "i+j"])
  1053 apply (simp_all add: le_add1)
  1054 done
  1055 
  1056 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1057 apply (rule notI)
  1058 apply (drule add_lessD1)
  1059 apply (erule less_irrefl [THEN notE])
  1060 done
  1061 
  1062 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1063 by (simp add: add.commute)
  1064 
  1065 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1066 apply (rule order_trans [of _ "m+k"])
  1067 apply (simp_all add: le_add1)
  1068 done
  1069 
  1070 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1071 apply (simp add: add.commute)
  1072 apply (erule add_leD1)
  1073 done
  1074 
  1075 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1076 by (blast dest: add_leD1 add_leD2)
  1077 
  1078 text {* needs @{text "!!k"} for @{text ac_simps} to work *}
  1079 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1080 by (force simp del: add_Suc_right
  1081     simp add: less_iff_Suc_add add_Suc_right [symmetric] ac_simps)
  1082 
  1083 
  1084 subsubsection {* More results about difference *}
  1085 
  1086 text {* Addition is the inverse of subtraction:
  1087   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1088 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1089 by (induct m n rule: diff_induct) simp_all
  1090 
  1091 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1092 by (simp add: add_diff_inverse linorder_not_less)
  1093 
  1094 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1095 by (simp add: add.commute)
  1096 
  1097 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1098 by (induct m n rule: diff_induct) simp_all
  1099 
  1100 lemma diff_less_Suc: "m - n < Suc m"
  1101 apply (induct m n rule: diff_induct)
  1102 apply (erule_tac [3] less_SucE)
  1103 apply (simp_all add: less_Suc_eq)
  1104 done
  1105 
  1106 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1107 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1108 
  1109 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1110   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1111 
  1112 instance nat :: ordered_cancel_comm_monoid_diff
  1113 proof
  1114   show "\<And>m n :: nat. m \<le> n \<longleftrightarrow> (\<exists>q. n = m + q)" by (fact le_iff_add)
  1115 qed
  1116 
  1117 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1118 by (rule le_less_trans, rule diff_le_self)
  1119 
  1120 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1121 by (cases n) (auto simp add: le_simps)
  1122 
  1123 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1124 by (induct j k rule: diff_induct) simp_all
  1125 
  1126 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1127 by (simp add: add.commute diff_add_assoc)
  1128 
  1129 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1130 by (auto simp add: diff_add_inverse2)
  1131 
  1132 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1133 by (induct m n rule: diff_induct) simp_all
  1134 
  1135 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1136 by (rule iffD2, rule diff_is_0_eq)
  1137 
  1138 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1139 by (induct m n rule: diff_induct) simp_all
  1140 
  1141 lemma less_imp_add_positive:
  1142   assumes "i < j"
  1143   shows "\<exists>k::nat. 0 < k & i + k = j"
  1144 proof
  1145   from assms show "0 < j - i & i + (j - i) = j"
  1146     by (simp add: order_less_imp_le)
  1147 qed
  1148 
  1149 text {* a nice rewrite for bounded subtraction *}
  1150 lemma nat_minus_add_max:
  1151   fixes n m :: nat
  1152   shows "n - m + m = max n m"
  1153     by (simp add: max_def not_le order_less_imp_le)
  1154 
  1155 lemma nat_diff_split:
  1156   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1157     -- {* elimination of @{text -} on @{text nat} *}
  1158 by (cases "a < b")
  1159   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1160     not_less le_less dest!: add_eq_self_zero add_eq_self_zero[OF sym])
  1161 
  1162 lemma nat_diff_split_asm:
  1163   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1164     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1165 by (auto split: nat_diff_split)
  1166 
  1167 lemma Suc_pred': "0 < n ==> n = Suc(n - 1)"
  1168   by simp
  1169 
  1170 lemma add_eq_if: "(m::nat) + n = (if m=0 then n else Suc ((m - 1) + n))"
  1171   unfolding One_nat_def by (cases m) simp_all
  1172 
  1173 lemma mult_eq_if: "(m::nat) * n = (if m=0 then 0 else n + ((m - 1) * n))"
  1174   unfolding One_nat_def by (cases m) simp_all
  1175 
  1176 lemma Suc_diff_eq_diff_pred: "0 < n ==> Suc m - n = m - (n - 1)"
  1177   unfolding One_nat_def by (cases n) simp_all
  1178 
  1179 lemma diff_Suc_eq_diff_pred: "m - Suc n = (m - 1) - n"
  1180   unfolding One_nat_def by (cases m) simp_all
  1181 
  1182 lemma Let_Suc [simp]: "Let (Suc n) f == f (Suc n)"
  1183   by (fact Let_def)
  1184 
  1185 
  1186 subsubsection {* Monotonicity of Multiplication *}
  1187 
  1188 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1189 by (simp add: mult_right_mono)
  1190 
  1191 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1192 by (simp add: mult_left_mono)
  1193 
  1194 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1195 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1196 by (simp add: mult_mono)
  1197 
  1198 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1199 by (simp add: mult_strict_right_mono)
  1200 
  1201 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1202       there are no negative numbers.*}
  1203 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1204   apply (induct m)
  1205    apply simp
  1206   apply (case_tac n)
  1207    apply simp_all
  1208   done
  1209 
  1210 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1211   apply (induct m)
  1212    apply simp
  1213   apply (case_tac n)
  1214    apply simp_all
  1215   done
  1216 
  1217 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1218   apply (safe intro!: mult_less_mono1)
  1219   apply (cases k, auto)
  1220   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1221   apply (blast intro: mult_le_mono1)
  1222   done
  1223 
  1224 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1225 by (simp add: mult.commute [of k])
  1226 
  1227 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1228 by (simp add: linorder_not_less [symmetric], auto)
  1229 
  1230 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1231 by (simp add: linorder_not_less [symmetric], auto)
  1232 
  1233 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1234 by (subst mult_less_cancel1) simp
  1235 
  1236 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1237 by (subst mult_le_cancel1) simp
  1238 
  1239 lemma le_square: "m \<le> m * (m::nat)"
  1240   by (cases m) (auto intro: le_add1)
  1241 
  1242 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1243   by (cases m) (auto intro: le_add1)
  1244 
  1245 text {* Lemma for @{text gcd} *}
  1246 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1247   apply (drule sym)
  1248   apply (rule disjCI)
  1249   apply (rule nat_less_cases, erule_tac [2] _)
  1250    apply (drule_tac [2] mult_less_mono2)
  1251     apply (auto)
  1252   done
  1253 
  1254 lemma mono_times_nat:
  1255   fixes n :: nat
  1256   assumes "n > 0"
  1257   shows "mono (times n)"
  1258 proof
  1259   fix m q :: nat
  1260   assume "m \<le> q"
  1261   with assms show "n * m \<le> n * q" by simp
  1262 qed
  1263 
  1264 text {* the lattice order on @{typ nat} *}
  1265 
  1266 instantiation nat :: distrib_lattice
  1267 begin
  1268 
  1269 definition
  1270   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1271 
  1272 definition
  1273   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1274 
  1275 instance by intro_classes
  1276   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1277     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1278 
  1279 end
  1280 
  1281 
  1282 subsection {* Natural operation of natural numbers on functions *}
  1283 
  1284 text {*
  1285   We use the same logical constant for the power operations on
  1286   functions and relations, in order to share the same syntax.
  1287 *}
  1288 
  1289 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1290 
  1291 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1292   "f ^^ n \<equiv> compow n f"
  1293 
  1294 notation (latex output)
  1295   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1296 
  1297 notation (HTML output)
  1298   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1299 
  1300 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1301 
  1302 overloading
  1303   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1304 begin
  1305 
  1306 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1307   "funpow 0 f = id"
  1308 | "funpow (Suc n) f = f o funpow n f"
  1309 
  1310 end
  1311 
  1312 lemma funpow_Suc_right:
  1313   "f ^^ Suc n = f ^^ n \<circ> f"
  1314 proof (induct n)
  1315   case 0 then show ?case by simp
  1316 next
  1317   fix n
  1318   assume "f ^^ Suc n = f ^^ n \<circ> f"
  1319   then show "f ^^ Suc (Suc n) = f ^^ Suc n \<circ> f"
  1320     by (simp add: o_assoc)
  1321 qed
  1322 
  1323 lemmas funpow_simps_right = funpow.simps(1) funpow_Suc_right
  1324 
  1325 text {* for code generation *}
  1326 
  1327 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1328   funpow_code_def [code_abbrev]: "funpow = compow"
  1329 
  1330 lemma [code]:
  1331   "funpow (Suc n) f = f o funpow n f"
  1332   "funpow 0 f = id"
  1333   by (simp_all add: funpow_code_def)
  1334 
  1335 hide_const (open) funpow
  1336 
  1337 lemma funpow_add:
  1338   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1339   by (induct m) simp_all
  1340 
  1341 lemma funpow_mult:
  1342   fixes f :: "'a \<Rightarrow> 'a"
  1343   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1344   by (induct n) (simp_all add: funpow_add)
  1345 
  1346 lemma funpow_swap1:
  1347   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1348 proof -
  1349   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1350   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1351   also have "\<dots> = (f ^^ n) (f x)" by simp
  1352   finally show ?thesis .
  1353 qed
  1354 
  1355 lemma comp_funpow:
  1356   fixes f :: "'a \<Rightarrow> 'a"
  1357   shows "comp f ^^ n = comp (f ^^ n)"
  1358   by (induct n) simp_all
  1359 
  1360 lemma Suc_funpow[simp]: "Suc ^^ n = (op + n)"
  1361   by (induct n) simp_all
  1362 
  1363 lemma id_funpow[simp]: "id ^^ n = id"
  1364   by (induct n) simp_all
  1365 
  1366 subsection {* Kleene iteration *}
  1367 
  1368 lemma Kleene_iter_lpfp:
  1369 assumes "mono f" and "f p \<le> p" shows "(f^^k) (bot::'a::order_bot) \<le> p"
  1370 proof(induction k)
  1371   case 0 show ?case by simp
  1372 next
  1373   case Suc
  1374   from monoD[OF assms(1) Suc] assms(2)
  1375   show ?case by simp
  1376 qed
  1377 
  1378 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1379 shows "lfp f = (f^^k) bot"
  1380 proof(rule antisym)
  1381   show "lfp f \<le> (f^^k) bot"
  1382   proof(rule lfp_lowerbound)
  1383     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1384   qed
  1385 next
  1386   show "(f^^k) bot \<le> lfp f"
  1387     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1388 qed
  1389 
  1390 
  1391 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1392 
  1393 context semiring_1
  1394 begin
  1395 
  1396 definition of_nat :: "nat \<Rightarrow> 'a" where
  1397   "of_nat n = (plus 1 ^^ n) 0"
  1398 
  1399 lemma of_nat_simps [simp]:
  1400   shows of_nat_0: "of_nat 0 = 0"
  1401     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1402   by (simp_all add: of_nat_def)
  1403 
  1404 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1405   by (simp add: of_nat_def)
  1406 
  1407 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1408   by (induct m) (simp_all add: ac_simps)
  1409 
  1410 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1411   by (induct m) (simp_all add: ac_simps distrib_right)
  1412 
  1413 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1414   "of_nat_aux inc 0 i = i"
  1415 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1416 
  1417 lemma of_nat_code:
  1418   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1419 proof (induct n)
  1420   case 0 then show ?case by simp
  1421 next
  1422   case (Suc n)
  1423   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1424     by (induct n) simp_all
  1425   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1426     by simp
  1427   with Suc show ?case by (simp add: add.commute)
  1428 qed
  1429 
  1430 end
  1431 
  1432 declare of_nat_code [code]
  1433 
  1434 text{*Class for unital semirings with characteristic zero.
  1435  Includes non-ordered rings like the complex numbers.*}
  1436 
  1437 class semiring_char_0 = semiring_1 +
  1438   assumes inj_of_nat: "inj of_nat"
  1439 begin
  1440 
  1441 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1442   by (auto intro: inj_of_nat injD)
  1443 
  1444 text{*Special cases where either operand is zero*}
  1445 
  1446 lemma of_nat_0_eq_iff [simp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1447   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1448 
  1449 lemma of_nat_eq_0_iff [simp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1450   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1451 
  1452 end
  1453 
  1454 context linordered_semidom
  1455 begin
  1456 
  1457 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1458   by (induct n) simp_all
  1459 
  1460 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1461   by (simp add: not_less)
  1462 
  1463 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1464   by (induct m n rule: diff_induct, simp_all add: add_pos_nonneg)
  1465 
  1466 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1467   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1468 
  1469 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1470   by simp
  1471 
  1472 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1473   by simp
  1474 
  1475 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1476 
  1477 subclass semiring_char_0 proof
  1478 qed (auto intro!: injI simp add: eq_iff)
  1479 
  1480 text{*Special cases where either operand is zero*}
  1481 
  1482 lemma of_nat_le_0_iff [simp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1483   by (rule of_nat_le_iff [of _ 0, simplified])
  1484 
  1485 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1486   by (rule of_nat_less_iff [of 0, simplified])
  1487 
  1488 end
  1489 
  1490 context ring_1
  1491 begin
  1492 
  1493 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1494 by (simp add: algebra_simps of_nat_add [symmetric])
  1495 
  1496 end
  1497 
  1498 context linordered_idom
  1499 begin
  1500 
  1501 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1502   unfolding abs_if by auto
  1503 
  1504 end
  1505 
  1506 lemma of_nat_id [simp]: "of_nat n = n"
  1507   by (induct n) simp_all
  1508 
  1509 lemma of_nat_eq_id [simp]: "of_nat = id"
  1510   by (auto simp add: fun_eq_iff)
  1511 
  1512 
  1513 subsection {* The Set of Natural Numbers *}
  1514 
  1515 context semiring_1
  1516 begin
  1517 
  1518 definition Nats  :: "'a set" where
  1519   "Nats = range of_nat"
  1520 
  1521 notation (xsymbols)
  1522   Nats  ("\<nat>")
  1523 
  1524 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1525   by (simp add: Nats_def)
  1526 
  1527 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1528 apply (simp add: Nats_def)
  1529 apply (rule range_eqI)
  1530 apply (rule of_nat_0 [symmetric])
  1531 done
  1532 
  1533 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1534 apply (simp add: Nats_def)
  1535 apply (rule range_eqI)
  1536 apply (rule of_nat_1 [symmetric])
  1537 done
  1538 
  1539 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1540 apply (auto simp add: Nats_def)
  1541 apply (rule range_eqI)
  1542 apply (rule of_nat_add [symmetric])
  1543 done
  1544 
  1545 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1546 apply (auto simp add: Nats_def)
  1547 apply (rule range_eqI)
  1548 apply (rule of_nat_mult [symmetric])
  1549 done
  1550 
  1551 lemma Nats_cases [cases set: Nats]:
  1552   assumes "x \<in> \<nat>"
  1553   obtains (of_nat) n where "x = of_nat n"
  1554   unfolding Nats_def
  1555 proof -
  1556   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1557   then obtain n where "x = of_nat n" ..
  1558   then show thesis ..
  1559 qed
  1560 
  1561 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1562   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1563   by (rule Nats_cases) auto
  1564 
  1565 end
  1566 
  1567 
  1568 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1569 
  1570 lemma subst_equals:
  1571   assumes 1: "t = s" and 2: "u = t"
  1572   shows "u = s"
  1573   using 2 1 by (rule trans)
  1574 
  1575 setup Arith_Data.setup
  1576 
  1577 ML_file "Tools/nat_arith.ML"
  1578 
  1579 simproc_setup nateq_cancel_sums
  1580   ("(l::nat) + m = n" | "(l::nat) = m + n" | "Suc m = n" | "m = Suc n") =
  1581   {* fn phi => try o Nat_Arith.cancel_eq_conv *}
  1582 
  1583 simproc_setup natless_cancel_sums
  1584   ("(l::nat) + m < n" | "(l::nat) < m + n" | "Suc m < n" | "m < Suc n") =
  1585   {* fn phi => try o Nat_Arith.cancel_less_conv *}
  1586 
  1587 simproc_setup natle_cancel_sums
  1588   ("(l::nat) + m \<le> n" | "(l::nat) \<le> m + n" | "Suc m \<le> n" | "m \<le> Suc n") =
  1589   {* fn phi => try o Nat_Arith.cancel_le_conv *}
  1590 
  1591 simproc_setup natdiff_cancel_sums
  1592   ("(l::nat) + m - n" | "(l::nat) - (m + n)" | "Suc m - n" | "m - Suc n") =
  1593   {* fn phi => try o Nat_Arith.cancel_diff_conv *}
  1594 
  1595 ML_file "Tools/lin_arith.ML"
  1596 setup {* Lin_Arith.global_setup *}
  1597 declaration {* K Lin_Arith.setup *}
  1598 
  1599 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1600   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1601 (* Because of this simproc, the arithmetic solver is really only
  1602 useful to detect inconsistencies among the premises for subgoals which are
  1603 *not* themselves (in)equalities, because the latter activate
  1604 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1605 solver all the time rather than add the additional check. *)
  1606 
  1607 
  1608 lemmas [arith_split] = nat_diff_split split_min split_max
  1609 
  1610 context order
  1611 begin
  1612 
  1613 lemma lift_Suc_mono_le:
  1614   assumes mono: "\<And>n. f n \<le> f (Suc n)" and "n \<le> n'"
  1615   shows "f n \<le> f n'"
  1616 proof (cases "n < n'")
  1617   case True
  1618   then show ?thesis
  1619     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1620 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1621 
  1622 lemma lift_Suc_antimono_le:
  1623   assumes mono: "\<And>n. f n \<ge> f (Suc n)" and "n \<le> n'"
  1624   shows "f n \<ge> f n'"
  1625 proof (cases "n < n'")
  1626   case True
  1627   then show ?thesis
  1628     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1629 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1630 
  1631 lemma lift_Suc_mono_less:
  1632   assumes mono: "\<And>n. f n < f (Suc n)" and "n < n'"
  1633   shows "f n < f n'"
  1634 using `n < n'`
  1635 by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1636 
  1637 lemma lift_Suc_mono_less_iff:
  1638   "(\<And>n. f n < f (Suc n)) \<Longrightarrow> f n < f m \<longleftrightarrow> n < m"
  1639   by (blast intro: less_asym' lift_Suc_mono_less [of f]
  1640     dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq [THEN iffD1])
  1641 
  1642 end
  1643 
  1644 lemma mono_iff_le_Suc:
  1645   "mono f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1646   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1647 
  1648 lemma antimono_iff_le_Suc:
  1649   "antimono f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1650   unfolding antimono_def by (auto intro: lift_Suc_antimono_le [of f])
  1651 
  1652 lemma mono_nat_linear_lb:
  1653   fixes f :: "nat \<Rightarrow> nat"
  1654   assumes "\<And>m n. m < n \<Longrightarrow> f m < f n"
  1655   shows "f m + k \<le> f (m + k)"
  1656 proof (induct k)
  1657   case 0 then show ?case by simp
  1658 next
  1659   case (Suc k)
  1660   then have "Suc (f m + k) \<le> Suc (f (m + k))" by simp
  1661   also from assms [of "m + k" "Suc (m + k)"] have "Suc (f (m + k)) \<le> f (Suc (m + k))"
  1662     by (simp add: Suc_le_eq)
  1663   finally show ?case by simp
  1664 qed
  1665 
  1666 
  1667 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1668 
  1669 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1670 by arith
  1671 
  1672 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1673 by arith
  1674 
  1675 lemma less_diff_conv2:
  1676   fixes j k i :: nat
  1677   assumes "k \<le> j"
  1678   shows "j - k < i \<longleftrightarrow> j < i + k"
  1679   using assms by arith
  1680 
  1681 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1682 by arith
  1683 
  1684 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1685   by (fact le_diff_conv2) -- {* FIXME delete *}
  1686 
  1687 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1688 by arith
  1689 
  1690 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1691   by (fact le_add_diff) -- {* FIXME delete *}
  1692 
  1693 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1694   second premise n\<le>m*)
  1695 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1696 by arith
  1697 
  1698 text {* Simplification of relational expressions involving subtraction *}
  1699 
  1700 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1701 by (simp split add: nat_diff_split)
  1702 
  1703 hide_fact (open) diff_diff_eq
  1704 
  1705 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1706 by (auto split add: nat_diff_split)
  1707 
  1708 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1709 by (auto split add: nat_diff_split)
  1710 
  1711 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1712 by (auto split add: nat_diff_split)
  1713 
  1714 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1715 
  1716 (* Monotonicity of subtraction in first argument *)
  1717 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1718 by (simp split add: nat_diff_split)
  1719 
  1720 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1721 by (simp split add: nat_diff_split)
  1722 
  1723 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1724 by (simp split add: nat_diff_split)
  1725 
  1726 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1727 by (simp split add: nat_diff_split)
  1728 
  1729 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1730 by auto
  1731 
  1732 lemma inj_on_diff_nat: 
  1733   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1734   shows "inj_on (\<lambda>n. n - k) N"
  1735 proof (rule inj_onI)
  1736   fix x y
  1737   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1738   with k_le_n have "x - k + k = y - k + k" by auto
  1739   with a k_le_n show "x = y" by auto
  1740 qed
  1741 
  1742 text{*Rewriting to pull differences out*}
  1743 
  1744 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1745 by arith
  1746 
  1747 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1748 by arith
  1749 
  1750 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1751 by arith
  1752 
  1753 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1754 by simp
  1755 
  1756 (*The others are
  1757       i - j - k = i - (j + k),
  1758       k \<le> j ==> j - k + i = j + i - k,
  1759       k \<le> j ==> i + (j - k) = i + j - k *)
  1760 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1761 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1762 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1763 
  1764 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1765 Least_Suc}, since there appears to be no need.*}
  1766 
  1767 text{*Lemmas for ex/Factorization*}
  1768 
  1769 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1770 by (cases m) auto
  1771 
  1772 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1773 by (cases m) auto
  1774 
  1775 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1776 by (cases m) auto
  1777 
  1778 text {* Specialized induction principles that work "backwards": *}
  1779 
  1780 lemma inc_induct[consumes 1, case_names base step]:
  1781   assumes less: "i \<le> j"
  1782   assumes base: "P j"
  1783   assumes step: "\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P (Suc n) \<Longrightarrow> P n"
  1784   shows "P i"
  1785   using less step
  1786 proof (induct d\<equiv>"j - i" arbitrary: i)
  1787   case (0 i)
  1788   hence "i = j" by simp
  1789   with base show ?case by simp
  1790 next
  1791   case (Suc d n)
  1792   hence "n \<le> n" "n < j" "P (Suc n)"
  1793     by simp_all
  1794   then show "P n" by fact
  1795 qed
  1796 
  1797 lemma strict_inc_induct[consumes 1, case_names base step]:
  1798   assumes less: "i < j"
  1799   assumes base: "!!i. j = Suc i ==> P i"
  1800   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1801   shows "P i"
  1802   using less
  1803 proof (induct d=="j - i - 1" arbitrary: i)
  1804   case (0 i)
  1805   with `i < j` have "j = Suc i" by simp
  1806   with base show ?case by simp
  1807 next
  1808   case (Suc d i)
  1809   hence "i < j" "P (Suc i)"
  1810     by simp_all
  1811   thus "P i" by (rule step)
  1812 qed
  1813 
  1814 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1815   using inc_induct[of "k - i" k P, simplified] by blast
  1816 
  1817 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1818   using inc_induct[of 0 k P] by blast
  1819 
  1820 text {* Further induction rule similar to @{thm inc_induct} *}
  1821 
  1822 lemma dec_induct[consumes 1, case_names base step]:
  1823   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1824   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1825  
  1826 subsection {* The divides relation on @{typ nat} *}
  1827 
  1828 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1829 unfolding dvd_def by simp
  1830 
  1831 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1832 by (simp add: dvd_def)
  1833 
  1834 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1835 by (simp add: dvd_def)
  1836 
  1837 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1838   unfolding dvd_def
  1839   by (force dest: mult_eq_self_implies_10 simp add: mult.assoc)
  1840 
  1841 text {* @{term "op dvd"} is a partial order *}
  1842 
  1843 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1844   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1845 
  1846 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1847 unfolding dvd_def
  1848 by (blast intro: diff_mult_distrib2 [symmetric])
  1849 
  1850 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1851   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1852   apply (blast intro: dvd_add)
  1853   done
  1854 
  1855 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1856 by (drule_tac m = m in dvd_diff_nat, auto)
  1857 
  1858 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1859   apply (rule iffI)
  1860    apply (erule_tac [2] dvd_add)
  1861    apply (rule_tac [2] dvd_refl)
  1862   apply (subgoal_tac "n = (n+k) -k")
  1863    prefer 2 apply simp
  1864   apply (erule ssubst)
  1865   apply (erule dvd_diff_nat)
  1866   apply (rule dvd_refl)
  1867   done
  1868 
  1869 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1870   unfolding dvd_def
  1871   apply (erule exE)
  1872   apply (simp add: ac_simps)
  1873   done
  1874 
  1875 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1876   apply auto
  1877    apply (subgoal_tac "m*n dvd m*1")
  1878    apply (drule dvd_mult_cancel, auto)
  1879   done
  1880 
  1881 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1882   apply (subst mult.commute)
  1883   apply (erule dvd_mult_cancel1)
  1884   done
  1885 
  1886 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1887 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1888 
  1889 lemma nat_dvd_not_less:
  1890   fixes m n :: nat
  1891   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1892 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1893 
  1894 lemma dvd_plusE:
  1895   fixes m n q :: nat
  1896   assumes "m dvd n + q" "m dvd n"
  1897   obtains "m dvd q"
  1898 proof (cases "m = 0")
  1899   case True with assms that show thesis by simp
  1900 next
  1901   case False then have "m > 0" by simp
  1902   from assms obtain r s where "n = m * r" and "n + q = m * s" by (blast elim: dvdE)
  1903   then have *: "m * r + q = m * s" by simp
  1904   show thesis proof (cases "r \<le> s")
  1905     case False then have "s < r" by (simp add: not_le)
  1906     with * have "m * r + q - m * s = m * s - m * s" by simp
  1907     then have "m * r + q - m * s = 0" by simp
  1908     with `m > 0` `s < r` have "m * r - m * s + q = 0" by (unfold less_le_not_le) auto
  1909     then have "m * (r - s) + q = 0" by auto
  1910     then have "m * (r - s) = 0" by simp
  1911     then have "m = 0 \<or> r - s = 0" by simp
  1912     with `s < r` have "m = 0" by (simp add: less_le_not_le)
  1913     with `m > 0` show thesis by auto
  1914   next
  1915     case True with * have "m * r + q - m * r = m * s - m * r" by simp
  1916     with `m > 0` `r \<le> s` have "m * r - m * r + q = m * s - m * r" by simp
  1917     then have "q = m * (s - r)" by (simp add: diff_mult_distrib2)
  1918     with assms that show thesis by (auto intro: dvdI)
  1919   qed
  1920 qed
  1921 
  1922 lemma dvd_plus_eq_right:
  1923   fixes m n q :: nat
  1924   assumes "m dvd n"
  1925   shows "m dvd n + q \<longleftrightarrow> m dvd q"
  1926   using assms by (auto elim: dvd_plusE)
  1927 
  1928 lemma dvd_plus_eq_left:
  1929   fixes m n q :: nat
  1930   assumes "m dvd q"
  1931   shows "m dvd n + q \<longleftrightarrow> m dvd n"
  1932   using assms by (simp add: dvd_plus_eq_right add.commute [of n])
  1933 
  1934 lemma less_eq_dvd_minus:
  1935   fixes m n :: nat
  1936   assumes "m \<le> n"
  1937   shows "m dvd n \<longleftrightarrow> m dvd n - m"
  1938 proof -
  1939   from assms have "n = m + (n - m)" by simp
  1940   then obtain q where "n = m + q" ..
  1941   then show ?thesis by (simp add: dvd_reduce add.commute [of m])
  1942 qed
  1943 
  1944 lemma dvd_minus_self:
  1945   fixes m n :: nat
  1946   shows "m dvd n - m \<longleftrightarrow> n < m \<or> m dvd n"
  1947   by (cases "n < m") (auto elim!: dvdE simp add: not_less le_imp_diff_is_add)
  1948 
  1949 lemma dvd_minus_add:
  1950   fixes m n q r :: nat
  1951   assumes "q \<le> n" "q \<le> r * m"
  1952   shows "m dvd n - q \<longleftrightarrow> m dvd n + (r * m - q)"
  1953 proof -
  1954   have "m dvd n - q \<longleftrightarrow> m dvd r * m + (n - q)"
  1955     by (auto elim: dvd_plusE)
  1956   also from assms have "\<dots> \<longleftrightarrow> m dvd r * m + n - q" by simp
  1957   also from assms have "\<dots> \<longleftrightarrow> m dvd (r * m - q) + n" by simp
  1958   also have "\<dots> \<longleftrightarrow> m dvd n + (r * m - q)" by (simp add: add.commute)
  1959   finally show ?thesis .
  1960 qed
  1961 
  1962 
  1963 subsection {* aliases *}
  1964 
  1965 lemma nat_mult_1: "(1::nat) * n = n"
  1966   by (rule mult_1_left)
  1967  
  1968 lemma nat_mult_1_right: "n * (1::nat) = n"
  1969   by (rule mult_1_right)
  1970 
  1971 
  1972 subsection {* size of a datatype value *}
  1973 
  1974 class size =
  1975   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1976 
  1977 
  1978 subsection {* code module namespace *}
  1979 
  1980 code_identifier
  1981   code_module Nat \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1982 
  1983 hide_const (open) of_nat_aux
  1984 
  1985 end