src/HOL/Analysis/Cartesian_Euclidean_Space.thy
author immler
Thu Feb 22 15:17:25 2018 +0100 (18 months ago)
changeset 67685 bdff8bf0a75b
parent 67673 c8caefb20564
child 67686 2c58505bf151
permissions -rw-r--r--
moved theorems from AFP/Affine_Arithmetic and AFP/Ordinary_Differential_Equations
     1 section \<open>Instantiates the finite Cartesian product of Euclidean spaces as a Euclidean space.\<close>
     2 
     3 theory Cartesian_Euclidean_Space
     4 imports Finite_Cartesian_Product Derivative
     5 begin
     6 
     7 lemma subspace_special_hyperplane: "subspace {x. x $ k = 0}"
     8   by (simp add: subspace_def)
     9 
    10 lemma delta_mult_idempotent:
    11   "(if k=a then 1 else (0::'a::semiring_1)) * (if k=a then 1 else 0) = (if k=a then 1 else 0)"
    12   by simp
    13 
    14 (*move up?*)
    15 lemma sum_UNIV_sum:
    16   fixes g :: "'a::finite + 'b::finite \<Rightarrow> _"
    17   shows "(\<Sum>x\<in>UNIV. g x) = (\<Sum>x\<in>UNIV. g (Inl x)) + (\<Sum>x\<in>UNIV. g (Inr x))"
    18   apply (subst UNIV_Plus_UNIV [symmetric])
    19   apply (subst sum.Plus)
    20   apply simp_all
    21   done
    22 
    23 lemma sum_mult_product:
    24   "sum h {..<A * B :: nat} = (\<Sum>i\<in>{..<A}. \<Sum>j\<in>{..<B}. h (j + i * B))"
    25   unfolding sum_nat_group[of h B A, unfolded atLeast0LessThan, symmetric]
    26 proof (rule sum.cong, simp, rule sum.reindex_cong)
    27   fix i
    28   show "inj_on (\<lambda>j. j + i * B) {..<B}" by (auto intro!: inj_onI)
    29   show "{i * B..<i * B + B} = (\<lambda>j. j + i * B) ` {..<B}"
    30   proof safe
    31     fix j assume "j \<in> {i * B..<i * B + B}"
    32     then show "j \<in> (\<lambda>j. j + i * B) ` {..<B}"
    33       by (auto intro!: image_eqI[of _ _ "j - i * B"])
    34   qed simp
    35 qed simp
    36 
    37 subsection\<open>Basic componentwise operations on vectors.\<close>
    38 
    39 instantiation vec :: (times, finite) times
    40 begin
    41 
    42 definition "( * ) \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) * (y$i)))"
    43 instance ..
    44 
    45 end
    46 
    47 instantiation vec :: (one, finite) one
    48 begin
    49 
    50 definition "1 \<equiv> (\<chi> i. 1)"
    51 instance ..
    52 
    53 end
    54 
    55 instantiation vec :: (ord, finite) ord
    56 begin
    57 
    58 definition "x \<le> y \<longleftrightarrow> (\<forall>i. x$i \<le> y$i)"
    59 definition "x < (y::'a^'b) \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
    60 instance ..
    61 
    62 end
    63 
    64 text\<open>The ordering on one-dimensional vectors is linear.\<close>
    65 
    66 class cart_one =
    67   assumes UNIV_one: "card (UNIV :: 'a set) = Suc 0"
    68 begin
    69 
    70 subclass finite
    71 proof
    72   from UNIV_one show "finite (UNIV :: 'a set)"
    73     by (auto intro!: card_ge_0_finite)
    74 qed
    75 
    76 end
    77 
    78 instance vec:: (order, finite) order
    79   by standard (auto simp: less_eq_vec_def less_vec_def vec_eq_iff
    80       intro: order.trans order.antisym order.strict_implies_order)
    81 
    82 instance vec :: (linorder, cart_one) linorder
    83 proof
    84   obtain a :: 'b where all: "\<And>P. (\<forall>i. P i) \<longleftrightarrow> P a"
    85   proof -
    86     have "card (UNIV :: 'b set) = Suc 0" by (rule UNIV_one)
    87     then obtain b :: 'b where "UNIV = {b}" by (auto iff: card_Suc_eq)
    88     then have "\<And>P. (\<forall>i\<in>UNIV. P i) \<longleftrightarrow> P b" by auto
    89     then show thesis by (auto intro: that)
    90   qed
    91   fix x y :: "'a^'b::cart_one"
    92   note [simp] = less_eq_vec_def less_vec_def all vec_eq_iff field_simps
    93   show "x \<le> y \<or> y \<le> x" by auto
    94 qed
    95 
    96 text\<open>Constant Vectors\<close>
    97 
    98 definition "vec x = (\<chi> i. x)"
    99 
   100 lemma interval_cbox_cart: "{a::real^'n..b} = cbox a b"
   101   by (auto simp add: less_eq_vec_def mem_box Basis_vec_def inner_axis)
   102 
   103 text\<open>Also the scalar-vector multiplication.\<close>
   104 
   105 definition vector_scalar_mult:: "'a::times \<Rightarrow> 'a ^ 'n \<Rightarrow> 'a ^ 'n" (infixl "*s" 70)
   106   where "c *s x = (\<chi> i. c * (x$i))"
   107 
   108 
   109 subsection \<open>A naive proof procedure to lift really trivial arithmetic stuff from the basis of the vector space.\<close>
   110 
   111 lemma sum_cong_aux:
   112   "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> sum f A = sum g A"
   113   by (auto intro: sum.cong)
   114 
   115 hide_fact (open) sum_cong_aux
   116 
   117 method_setup vector = \<open>
   118 let
   119   val ss1 =
   120     simpset_of (put_simpset HOL_basic_ss @{context}
   121       addsimps [@{thm sum.distrib} RS sym,
   122       @{thm sum_subtractf} RS sym, @{thm sum_distrib_left},
   123       @{thm sum_distrib_right}, @{thm sum_negf} RS sym])
   124   val ss2 =
   125     simpset_of (@{context} addsimps
   126              [@{thm plus_vec_def}, @{thm times_vec_def},
   127               @{thm minus_vec_def}, @{thm uminus_vec_def},
   128               @{thm one_vec_def}, @{thm zero_vec_def}, @{thm vec_def},
   129               @{thm scaleR_vec_def},
   130               @{thm vec_lambda_beta}, @{thm vector_scalar_mult_def}])
   131   fun vector_arith_tac ctxt ths =
   132     simp_tac (put_simpset ss1 ctxt)
   133     THEN' (fn i => resolve_tac ctxt @{thms Cartesian_Euclidean_Space.sum_cong_aux} i
   134          ORELSE resolve_tac ctxt @{thms sum.neutral} i
   135          ORELSE simp_tac (put_simpset HOL_basic_ss ctxt addsimps [@{thm vec_eq_iff}]) i)
   136     (* THEN' TRY o clarify_tac HOL_cs  THEN' (TRY o rtac @{thm iffI}) *)
   137     THEN' asm_full_simp_tac (put_simpset ss2 ctxt addsimps ths)
   138 in
   139   Attrib.thms >> (fn ths => fn ctxt => SIMPLE_METHOD' (vector_arith_tac ctxt ths))
   140 end
   141 \<close> "lift trivial vector statements to real arith statements"
   142 
   143 lemma vec_0[simp]: "vec 0 = 0" by vector
   144 lemma vec_1[simp]: "vec 1 = 1" by vector
   145 
   146 lemma vec_inj[simp]: "vec x = vec y \<longleftrightarrow> x = y" by vector
   147 
   148 lemma vec_in_image_vec: "vec x \<in> (vec ` S) \<longleftrightarrow> x \<in> S" by auto
   149 
   150 lemma vec_add: "vec(x + y) = vec x + vec y"  by vector
   151 lemma vec_sub: "vec(x - y) = vec x - vec y" by vector
   152 lemma vec_cmul: "vec(c * x) = c *s vec x " by vector
   153 lemma vec_neg: "vec(- x) = - vec x " by vector
   154 
   155 lemma vec_sum:
   156   assumes "finite S"
   157   shows "vec(sum f S) = sum (vec \<circ> f) S"
   158   using assms
   159 proof induct
   160   case empty
   161   then show ?case by simp
   162 next
   163   case insert
   164   then show ?case by (auto simp add: vec_add)
   165 qed
   166 
   167 text\<open>Obvious "component-pushing".\<close>
   168 
   169 lemma vec_component [simp]: "vec x $ i = x"
   170   by vector
   171 
   172 lemma vector_mult_component [simp]: "(x * y)$i = x$i * y$i"
   173   by vector
   174 
   175 lemma vector_smult_component [simp]: "(c *s y)$i = c * (y$i)"
   176   by vector
   177 
   178 lemma cond_component: "(if b then x else y)$i = (if b then x$i else y$i)" by vector
   179 
   180 lemmas vector_component =
   181   vec_component vector_add_component vector_mult_component
   182   vector_smult_component vector_minus_component vector_uminus_component
   183   vector_scaleR_component cond_component
   184 
   185 
   186 subsection \<open>Some frequently useful arithmetic lemmas over vectors.\<close>
   187 
   188 instance vec :: (semigroup_mult, finite) semigroup_mult
   189   by standard (vector mult.assoc)
   190 
   191 instance vec :: (monoid_mult, finite) monoid_mult
   192   by standard vector+
   193 
   194 instance vec :: (ab_semigroup_mult, finite) ab_semigroup_mult
   195   by standard (vector mult.commute)
   196 
   197 instance vec :: (comm_monoid_mult, finite) comm_monoid_mult
   198   by standard vector
   199 
   200 instance vec :: (semiring, finite) semiring
   201   by standard (vector field_simps)+
   202 
   203 instance vec :: (semiring_0, finite) semiring_0
   204   by standard (vector field_simps)+
   205 instance vec :: (semiring_1, finite) semiring_1
   206   by standard vector
   207 instance vec :: (comm_semiring, finite) comm_semiring
   208   by standard (vector field_simps)+
   209 
   210 instance vec :: (comm_semiring_0, finite) comm_semiring_0 ..
   211 instance vec :: (cancel_comm_monoid_add, finite) cancel_comm_monoid_add ..
   212 instance vec :: (semiring_0_cancel, finite) semiring_0_cancel ..
   213 instance vec :: (comm_semiring_0_cancel, finite) comm_semiring_0_cancel ..
   214 instance vec :: (ring, finite) ring ..
   215 instance vec :: (semiring_1_cancel, finite) semiring_1_cancel ..
   216 instance vec :: (comm_semiring_1, finite) comm_semiring_1 ..
   217 
   218 instance vec :: (ring_1, finite) ring_1 ..
   219 
   220 instance vec :: (real_algebra, finite) real_algebra
   221   by standard (simp_all add: vec_eq_iff)
   222 
   223 instance vec :: (real_algebra_1, finite) real_algebra_1 ..
   224 
   225 lemma of_nat_index: "(of_nat n :: 'a::semiring_1 ^'n)$i = of_nat n"
   226 proof (induct n)
   227   case 0
   228   then show ?case by vector
   229 next
   230   case Suc
   231   then show ?case by vector
   232 qed
   233 
   234 lemma one_index [simp]: "(1 :: 'a :: one ^ 'n) $ i = 1"
   235   by vector
   236 
   237 lemma neg_one_index [simp]: "(- 1 :: 'a :: {one, uminus} ^ 'n) $ i = - 1"
   238   by vector
   239 
   240 instance vec :: (semiring_char_0, finite) semiring_char_0
   241 proof
   242   fix m n :: nat
   243   show "inj (of_nat :: nat \<Rightarrow> 'a ^ 'b)"
   244     by (auto intro!: injI simp add: vec_eq_iff of_nat_index)
   245 qed
   246 
   247 instance vec :: (numeral, finite) numeral ..
   248 instance vec :: (semiring_numeral, finite) semiring_numeral ..
   249 
   250 lemma numeral_index [simp]: "numeral w $ i = numeral w"
   251   by (induct w) (simp_all only: numeral.simps vector_add_component one_index)
   252 
   253 lemma neg_numeral_index [simp]: "- numeral w $ i = - numeral w"
   254   by (simp only: vector_uminus_component numeral_index)
   255 
   256 instance vec :: (comm_ring_1, finite) comm_ring_1 ..
   257 instance vec :: (ring_char_0, finite) ring_char_0 ..
   258 
   259 lemma vector_smult_assoc: "a *s (b *s x) = ((a::'a::semigroup_mult) * b) *s x"
   260   by (vector mult.assoc)
   261 lemma vector_sadd_rdistrib: "((a::'a::semiring) + b) *s x = a *s x + b *s x"
   262   by (vector field_simps)
   263 lemma vector_add_ldistrib: "(c::'a::semiring) *s (x + y) = c *s x + c *s y"
   264   by (vector field_simps)
   265 lemma vector_smult_lzero[simp]: "(0::'a::mult_zero) *s x = 0" by vector
   266 lemma vector_smult_lid[simp]: "(1::'a::monoid_mult) *s x = x" by vector
   267 lemma vector_ssub_ldistrib: "(c::'a::ring) *s (x - y) = c *s x - c *s y"
   268   by (vector field_simps)
   269 lemma vector_smult_rneg: "(c::'a::ring) *s -x = -(c *s x)" by vector
   270 lemma vector_smult_lneg: "- (c::'a::ring) *s x = -(c *s x)" by vector
   271 lemma vector_sneg_minus1: "-x = (-1::'a::ring_1) *s x" by vector
   272 lemma vector_smult_rzero[simp]: "c *s 0 = (0::'a::mult_zero ^ 'n)" by vector
   273 lemma vector_sub_rdistrib: "((a::'a::ring) - b) *s x = a *s x - b *s x"
   274   by (vector field_simps)
   275 
   276 lemma vec_eq[simp]: "(vec m = vec n) \<longleftrightarrow> (m = n)"
   277   by (simp add: vec_eq_iff)
   278 
   279 lemma norm_eq_0_imp: "norm x = 0 ==> x = (0::real ^'n)" by (metis norm_eq_zero)
   280 lemma vector_mul_eq_0[simp]: "(a *s x = 0) \<longleftrightarrow> a = (0::'a::idom) \<or> x = 0"
   281   by vector
   282 lemma vector_mul_lcancel[simp]: "a *s x = a *s y \<longleftrightarrow> a = (0::real) \<or> x = y"
   283   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_ssub_ldistrib)
   284 lemma vector_mul_rcancel[simp]: "a *s x = b *s x \<longleftrightarrow> (a::real) = b \<or> x = 0"
   285   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_sub_rdistrib)
   286 lemma vector_mul_lcancel_imp: "a \<noteq> (0::real) ==>  a *s x = a *s y ==> (x = y)"
   287   by (metis vector_mul_lcancel)
   288 lemma vector_mul_rcancel_imp: "x \<noteq> 0 \<Longrightarrow> (a::real) *s x = b *s x ==> a = b"
   289   by (metis vector_mul_rcancel)
   290 
   291 lemma component_le_norm_cart: "\<bar>x$i\<bar> <= norm x"
   292   apply (simp add: norm_vec_def)
   293   apply (rule member_le_L2_set, simp_all)
   294   done
   295 
   296 lemma norm_bound_component_le_cart: "norm x <= e ==> \<bar>x$i\<bar> <= e"
   297   by (metis component_le_norm_cart order_trans)
   298 
   299 lemma norm_bound_component_lt_cart: "norm x < e ==> \<bar>x$i\<bar> < e"
   300   by (metis component_le_norm_cart le_less_trans)
   301 
   302 lemma norm_le_l1_cart: "norm x <= sum(\<lambda>i. \<bar>x$i\<bar>) UNIV"
   303   by (simp add: norm_vec_def L2_set_le_sum)
   304 
   305 lemma scalar_mult_eq_scaleR: "c *s x = c *\<^sub>R x"
   306   unfolding scaleR_vec_def vector_scalar_mult_def by simp
   307 
   308 lemma dist_mul[simp]: "dist (c *s x) (c *s y) = \<bar>c\<bar> * dist x y"
   309   unfolding dist_norm scalar_mult_eq_scaleR
   310   unfolding scaleR_right_diff_distrib[symmetric] by simp
   311 
   312 lemma sum_component [simp]:
   313   fixes f:: " 'a \<Rightarrow> ('b::comm_monoid_add) ^'n"
   314   shows "(sum f S)$i = sum (\<lambda>x. (f x)$i) S"
   315 proof (cases "finite S")
   316   case True
   317   then show ?thesis by induct simp_all
   318 next
   319   case False
   320   then show ?thesis by simp
   321 qed
   322 
   323 lemma sum_eq: "sum f S = (\<chi> i. sum (\<lambda>x. (f x)$i ) S)"
   324   by (simp add: vec_eq_iff)
   325 
   326 lemma sum_cmul:
   327   fixes f:: "'c \<Rightarrow> ('a::semiring_1)^'n"
   328   shows "sum (\<lambda>x. c *s f x) S = c *s sum f S"
   329   by (simp add: vec_eq_iff sum_distrib_left)
   330 
   331 lemma sum_norm_allsubsets_bound_cart:
   332   fixes f:: "'a \<Rightarrow> real ^'n"
   333   assumes fP: "finite P" and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (sum f Q) \<le> e"
   334   shows "sum (\<lambda>x. norm (f x)) P \<le> 2 * real CARD('n) *  e"
   335   using sum_norm_allsubsets_bound[OF assms]
   336   by simp
   337 
   338 subsection\<open>Closures and interiors of halfspaces\<close>
   339 
   340 lemma interior_halfspace_le [simp]:
   341   assumes "a \<noteq> 0"
   342     shows "interior {x. a \<bullet> x \<le> b} = {x. a \<bullet> x < b}"
   343 proof -
   344   have *: "a \<bullet> x < b" if x: "x \<in> S" and S: "S \<subseteq> {x. a \<bullet> x \<le> b}" and "open S" for S x
   345   proof -
   346     obtain e where "e>0" and e: "cball x e \<subseteq> S"
   347       using \<open>open S\<close> open_contains_cball x by blast
   348     then have "x + (e / norm a) *\<^sub>R a \<in> cball x e"
   349       by (simp add: dist_norm)
   350     then have "x + (e / norm a) *\<^sub>R a \<in> S"
   351       using e by blast
   352     then have "x + (e / norm a) *\<^sub>R a \<in> {x. a \<bullet> x \<le> b}"
   353       using S by blast
   354     moreover have "e * (a \<bullet> a) / norm a > 0"
   355       by (simp add: \<open>0 < e\<close> assms)
   356     ultimately show ?thesis
   357       by (simp add: algebra_simps)
   358   qed
   359   show ?thesis
   360     by (rule interior_unique) (auto simp: open_halfspace_lt *)
   361 qed
   362 
   363 lemma interior_halfspace_ge [simp]:
   364    "a \<noteq> 0 \<Longrightarrow> interior {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x > b}"
   365 using interior_halfspace_le [of "-a" "-b"] by simp
   366 
   367 lemma interior_halfspace_component_le [simp]:
   368      "interior {x. x$k \<le> a} = {x :: (real,'n::finite) vec. x$k < a}" (is "?LE")
   369   and interior_halfspace_component_ge [simp]:
   370      "interior {x. x$k \<ge> a} = {x :: (real,'n::finite) vec. x$k > a}" (is "?GE")
   371 proof -
   372   have "axis k (1::real) \<noteq> 0"
   373     by (simp add: axis_def vec_eq_iff)
   374   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   375     by (simp add: cart_eq_inner_axis inner_commute)
   376   ultimately show ?LE ?GE
   377     using interior_halfspace_le [of "axis k (1::real)" a]
   378           interior_halfspace_ge [of "axis k (1::real)" a] by auto
   379 qed
   380 
   381 lemma closure_halfspace_lt [simp]:
   382   assumes "a \<noteq> 0"
   383     shows "closure {x. a \<bullet> x < b} = {x. a \<bullet> x \<le> b}"
   384 proof -
   385   have [simp]: "-{x. a \<bullet> x < b} = {x. a \<bullet> x \<ge> b}"
   386     by (force simp:)
   387   then show ?thesis
   388     using interior_halfspace_ge [of a b] assms
   389     by (force simp: closure_interior)
   390 qed
   391 
   392 lemma closure_halfspace_gt [simp]:
   393    "a \<noteq> 0 \<Longrightarrow> closure {x. a \<bullet> x > b} = {x. a \<bullet> x \<ge> b}"
   394 using closure_halfspace_lt [of "-a" "-b"] by simp
   395 
   396 lemma closure_halfspace_component_lt [simp]:
   397      "closure {x. x$k < a} = {x :: (real,'n::finite) vec. x$k \<le> a}" (is "?LE")
   398   and closure_halfspace_component_gt [simp]:
   399      "closure {x. x$k > a} = {x :: (real,'n::finite) vec. x$k \<ge> a}" (is "?GE")
   400 proof -
   401   have "axis k (1::real) \<noteq> 0"
   402     by (simp add: axis_def vec_eq_iff)
   403   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   404     by (simp add: cart_eq_inner_axis inner_commute)
   405   ultimately show ?LE ?GE
   406     using closure_halfspace_lt [of "axis k (1::real)" a]
   407           closure_halfspace_gt [of "axis k (1::real)" a] by auto
   408 qed
   409 
   410 lemma interior_hyperplane [simp]:
   411   assumes "a \<noteq> 0"
   412     shows "interior {x. a \<bullet> x = b} = {}"
   413 proof -
   414   have [simp]: "{x. a \<bullet> x = b} = {x. a \<bullet> x \<le> b} \<inter> {x. a \<bullet> x \<ge> b}"
   415     by (force simp:)
   416   then show ?thesis
   417     by (auto simp: assms)
   418 qed
   419 
   420 lemma frontier_halfspace_le:
   421   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   422     shows "frontier {x. a \<bullet> x \<le> b} = {x. a \<bullet> x = b}"
   423 proof (cases "a = 0")
   424   case True with assms show ?thesis by simp
   425 next
   426   case False then show ?thesis
   427     by (force simp: frontier_def closed_halfspace_le)
   428 qed
   429 
   430 lemma frontier_halfspace_ge:
   431   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   432     shows "frontier {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x = b}"
   433 proof (cases "a = 0")
   434   case True with assms show ?thesis by simp
   435 next
   436   case False then show ?thesis
   437     by (force simp: frontier_def closed_halfspace_ge)
   438 qed
   439 
   440 lemma frontier_halfspace_lt:
   441   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   442     shows "frontier {x. a \<bullet> x < b} = {x. a \<bullet> x = b}"
   443 proof (cases "a = 0")
   444   case True with assms show ?thesis by simp
   445 next
   446   case False then show ?thesis
   447     by (force simp: frontier_def interior_open open_halfspace_lt)
   448 qed
   449 
   450 lemma frontier_halfspace_gt:
   451   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   452     shows "frontier {x. a \<bullet> x > b} = {x. a \<bullet> x = b}"
   453 proof (cases "a = 0")
   454   case True with assms show ?thesis by simp
   455 next
   456   case False then show ?thesis
   457     by (force simp: frontier_def interior_open open_halfspace_gt)
   458 qed
   459 
   460 lemma interior_standard_hyperplane:
   461    "interior {x :: (real,'n::finite) vec. x$k = a} = {}"
   462 proof -
   463   have "axis k (1::real) \<noteq> 0"
   464     by (simp add: axis_def vec_eq_iff)
   465   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   466     by (simp add: cart_eq_inner_axis inner_commute)
   467   ultimately show ?thesis
   468     using interior_hyperplane [of "axis k (1::real)" a]
   469     by force
   470 qed
   471 
   472 subsection \<open>Matrix operations\<close>
   473 
   474 text\<open>Matrix notation. NB: an MxN matrix is of type @{typ "'a^'n^'m"}, not @{typ "'a^'m^'n"}\<close>
   475 
   476 definition matrix_matrix_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'p^'n \<Rightarrow> 'a ^ 'p ^'m"
   477     (infixl "**" 70)
   478   where "m ** m' == (\<chi> i j. sum (\<lambda>k. ((m$i)$k) * ((m'$k)$j)) (UNIV :: 'n set)) ::'a ^ 'p ^'m"
   479 
   480 definition matrix_vector_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n \<Rightarrow> 'a ^ 'm"
   481     (infixl "*v" 70)
   482   where "m *v x \<equiv> (\<chi> i. sum (\<lambda>j. ((m$i)$j) * (x$j)) (UNIV ::'n set)) :: 'a^'m"
   483 
   484 definition vector_matrix_mult :: "'a ^ 'm \<Rightarrow> ('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n "
   485     (infixl "v*" 70)
   486   where "v v* m == (\<chi> j. sum (\<lambda>i. ((m$i)$j) * (v$i)) (UNIV :: 'm set)) :: 'a^'n"
   487 
   488 definition "(mat::'a::zero => 'a ^'n^'n) k = (\<chi> i j. if i = j then k else 0)"
   489 definition transpose where
   490   "(transpose::'a^'n^'m \<Rightarrow> 'a^'m^'n) A = (\<chi> i j. ((A$j)$i))"
   491 definition "(row::'m => 'a ^'n^'m \<Rightarrow> 'a ^'n) i A = (\<chi> j. ((A$i)$j))"
   492 definition "(column::'n =>'a^'n^'m =>'a^'m) j A = (\<chi> i. ((A$i)$j))"
   493 definition "rows(A::'a^'n^'m) = { row i A | i. i \<in> (UNIV :: 'm set)}"
   494 definition "columns(A::'a^'n^'m) = { column i A | i. i \<in> (UNIV :: 'n set)}"
   495 
   496 lemma mat_0[simp]: "mat 0 = 0" by (vector mat_def)
   497 lemma matrix_add_ldistrib: "(A ** (B + C)) = (A ** B) + (A ** C)"
   498   by (vector matrix_matrix_mult_def sum.distrib[symmetric] field_simps)
   499 
   500 lemma matrix_mul_lid [simp]:
   501   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   502   shows "mat 1 ** A = A"
   503   apply (simp add: matrix_matrix_mult_def mat_def)
   504   apply vector
   505   apply (auto simp only: if_distrib cond_application_beta sum.delta'[OF finite]
   506     mult_1_left mult_zero_left if_True UNIV_I)
   507   done
   508 
   509 
   510 lemma matrix_mul_rid [simp]:
   511   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   512   shows "A ** mat 1 = A"
   513   apply (simp add: matrix_matrix_mult_def mat_def)
   514   apply vector
   515   apply (auto simp only: if_distrib cond_application_beta sum.delta[OF finite]
   516     mult_1_right mult_zero_right if_True UNIV_I cong: if_cong)
   517   done
   518 
   519 lemma matrix_mul_assoc: "A ** (B ** C) = (A ** B) ** C"
   520   apply (vector matrix_matrix_mult_def sum_distrib_left sum_distrib_right mult.assoc)
   521   apply (subst sum.swap)
   522   apply simp
   523   done
   524 
   525 lemma matrix_vector_mul_assoc: "A *v (B *v x) = (A ** B) *v x"
   526   apply (vector matrix_matrix_mult_def matrix_vector_mult_def
   527     sum_distrib_left sum_distrib_right mult.assoc)
   528   apply (subst sum.swap)
   529   apply simp
   530   done
   531 
   532 lemma matrix_vector_mul_lid [simp]: "mat 1 *v x = (x::'a::semiring_1 ^ 'n)"
   533   apply (vector matrix_vector_mult_def mat_def)
   534   apply (simp add: if_distrib cond_application_beta sum.delta' cong del: if_weak_cong)
   535   done
   536 
   537 lemma matrix_transpose_mul:
   538     "transpose(A ** B) = transpose B ** transpose (A::'a::comm_semiring_1^_^_)"
   539   by (simp add: matrix_matrix_mult_def transpose_def vec_eq_iff mult.commute)
   540 
   541 lemma matrix_eq:
   542   fixes A B :: "'a::semiring_1 ^ 'n ^ 'm"
   543   shows "A = B \<longleftrightarrow>  (\<forall>x. A *v x = B *v x)" (is "?lhs \<longleftrightarrow> ?rhs")
   544   apply auto
   545   apply (subst vec_eq_iff)
   546   apply clarify
   547   apply (clarsimp simp add: matrix_vector_mult_def if_distrib cond_application_beta vec_eq_iff cong del: if_weak_cong)
   548   apply (erule_tac x="axis ia 1" in allE)
   549   apply (erule_tac x="i" in allE)
   550   apply (auto simp add: if_distrib cond_application_beta axis_def
   551     sum.delta[OF finite] cong del: if_weak_cong)
   552   done
   553 
   554 lemma matrix_vector_mul_component: "((A::real^_^_) *v x)$k = (A$k) \<bullet> x"
   555   by (simp add: matrix_vector_mult_def inner_vec_def)
   556 
   557 lemma dot_lmul_matrix: "((x::real ^_) v* A) \<bullet> y = x \<bullet> (A *v y)"
   558   apply (simp add: inner_vec_def matrix_vector_mult_def vector_matrix_mult_def sum_distrib_right sum_distrib_left ac_simps)
   559   apply (subst sum.swap)
   560   apply simp
   561   done
   562 
   563 lemma transpose_mat [simp]: "transpose (mat n) = mat n"
   564   by (vector transpose_def mat_def)
   565 
   566 lemma transpose_transpose: "transpose(transpose A) = A"
   567   by (vector transpose_def)
   568 
   569 lemma row_transpose [simp]:
   570   fixes A:: "'a::semiring_1^_^_"
   571   shows "row i (transpose A) = column i A"
   572   by (simp add: row_def column_def transpose_def vec_eq_iff)
   573 
   574 lemma column_transpose [simp]:
   575   fixes A:: "'a::semiring_1^_^_"
   576   shows "column i (transpose A) = row i A"
   577   by (simp add: row_def column_def transpose_def vec_eq_iff)
   578 
   579 lemma rows_transpose: "rows(transpose (A::'a::semiring_1^_^_)) = columns A"
   580   by (auto simp add: rows_def columns_def row_transpose intro: set_eqI)
   581 
   582 lemma columns_transpose: "columns(transpose (A::'a::semiring_1^_^_)) = rows A"
   583   by (metis transpose_transpose rows_transpose)
   584 
   585 lemma matrix_mult_transpose_dot_column:
   586   fixes A :: "real^'n^'n"
   587   shows "transpose A ** A = (\<chi> i j. (column i A) \<bullet> (column j A))"
   588   by (simp add: matrix_matrix_mult_def vec_eq_iff transpose_def column_def inner_vec_def)
   589 
   590 lemma matrix_mult_transpose_dot_row:
   591   fixes A :: "real^'n^'n"
   592   shows "A ** transpose A = (\<chi> i j. (row i A) \<bullet> (row j A))"
   593   by (simp add: matrix_matrix_mult_def vec_eq_iff transpose_def row_def inner_vec_def)
   594 
   595 text\<open>Two sometimes fruitful ways of looking at matrix-vector multiplication.\<close>
   596 
   597 lemma matrix_mult_dot: "A *v x = (\<chi> i. A$i \<bullet> x)"
   598   by (simp add: matrix_vector_mult_def inner_vec_def)
   599 
   600 lemma matrix_mult_sum:
   601   "(A::'a::comm_semiring_1^'n^'m) *v x = sum (\<lambda>i. (x$i) *s column i A) (UNIV:: 'n set)"
   602   by (simp add: matrix_vector_mult_def vec_eq_iff column_def mult.commute)
   603 
   604 lemma vector_componentwise:
   605   "(x::'a::ring_1^'n) = (\<chi> j. \<Sum>i\<in>UNIV. (x$i) * (axis i 1 :: 'a^'n) $ j)"
   606   by (simp add: axis_def if_distrib sum.If_cases vec_eq_iff)
   607 
   608 lemma basis_expansion: "sum (\<lambda>i. (x$i) *s axis i 1) UNIV = (x::('a::ring_1) ^'n)"
   609   by (auto simp add: axis_def vec_eq_iff if_distrib sum.If_cases cong del: if_weak_cong)
   610 
   611 lemma linear_componentwise_expansion:
   612   fixes f:: "real ^'m \<Rightarrow> real ^ _"
   613   assumes lf: "linear f"
   614   shows "(f x)$j = sum (\<lambda>i. (x$i) * (f (axis i 1)$j)) (UNIV :: 'm set)" (is "?lhs = ?rhs")
   615 proof -
   616   let ?M = "(UNIV :: 'm set)"
   617   let ?N = "(UNIV :: 'n set)"
   618   have "?rhs = (sum (\<lambda>i.(x$i) *\<^sub>R f (axis i 1) ) ?M)$j"
   619     unfolding sum_component by simp
   620   then show ?thesis
   621     unfolding linear_sum_mul[OF lf, symmetric]
   622     unfolding scalar_mult_eq_scaleR[symmetric]
   623     unfolding basis_expansion
   624     by simp
   625 qed
   626 
   627 text\<open>Inverse matrices  (not necessarily square)\<close>
   628 
   629 definition
   630   "invertible(A::'a::semiring_1^'n^'m) \<longleftrightarrow> (\<exists>A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   631 
   632 definition
   633   "matrix_inv(A:: 'a::semiring_1^'n^'m) =
   634     (SOME A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   635 
   636 text\<open>Correspondence between matrices and linear operators.\<close>
   637 
   638 definition matrix :: "('a::{plus,times, one, zero}^'m \<Rightarrow> 'a ^ 'n) \<Rightarrow> 'a^'m^'n"
   639   where "matrix f = (\<chi> i j. (f(axis j 1))$i)"
   640 
   641 lemma matrix_vector_mul_linear: "linear(\<lambda>x. A *v (x::real ^ _))"
   642   by (simp add: linear_iff matrix_vector_mult_def vec_eq_iff
   643       field_simps sum_distrib_left sum.distrib)
   644 
   645 lemma matrix_vector_mult_add_distrib [algebra_simps]:
   646   fixes A :: "real^'n^'m"
   647   shows "A *v (x + y) = A *v x + A *v y"
   648   using matrix_vector_mul_linear [of A]  by (simp add: linear_add)
   649 
   650 lemma matrix_vector_mult_diff_distrib [algebra_simps]:
   651   fixes A :: "real^'n^'m"
   652   shows "A *v (x - y) = A *v x - A *v y"
   653   using matrix_vector_mul_linear [of A]  by (simp add: linear_diff)
   654 
   655 lemma matrix_vector_mult_scaleR[algebra_simps]:
   656   fixes A :: "real^'n^'m"
   657   shows "A *v (c *\<^sub>R x) = c *\<^sub>R (A *v x)"
   658   using linear_iff matrix_vector_mul_linear by blast
   659 
   660 lemma matrix_vector_mult_0_right [simp]: "A *v 0 = 0"
   661   by (simp add: matrix_vector_mult_def vec_eq_iff)
   662 
   663 lemma matrix_vector_mult_0 [simp]: "0 *v w = 0"
   664   by (simp add: matrix_vector_mult_def vec_eq_iff)
   665 
   666 lemma matrix_vector_mult_add_rdistrib [algebra_simps]:
   667   fixes A :: "real^'n^'m"
   668   shows "(A + B) *v x = (A *v x) + (B *v x)"
   669   by (simp add: vec_eq_iff inner_add_left matrix_vector_mul_component)
   670 
   671 lemma matrix_vector_mult_diff_rdistrib [algebra_simps]:
   672   fixes A :: "real^'n^'m"
   673   shows "(A - B) *v x = (A *v x) - (B *v x)"
   674   by (simp add: vec_eq_iff inner_diff_left matrix_vector_mul_component)
   675 
   676 lemma matrix_works:
   677   assumes lf: "linear f"
   678   shows "matrix f *v x = f (x::real ^ 'n)"
   679   apply (simp add: matrix_def matrix_vector_mult_def vec_eq_iff mult.commute)
   680   by (simp add: linear_componentwise_expansion lf)
   681 
   682 lemma matrix_vector_mul: "linear f ==> f = (\<lambda>x. matrix f *v (x::real ^ 'n))"
   683   by (simp add: ext matrix_works)
   684 
   685 lemma matrix_of_matrix_vector_mul [simp]: "matrix(\<lambda>x. A *v (x :: real ^ 'n)) = A"
   686   by (simp add: matrix_eq matrix_vector_mul_linear matrix_works)
   687 
   688 lemma matrix_compose:
   689   assumes lf: "linear (f::real^'n \<Rightarrow> real^'m)"
   690     and lg: "linear (g::real^'m \<Rightarrow> real^_)"
   691   shows "matrix (g \<circ> f) = matrix g ** matrix f"
   692   using lf lg linear_compose[OF lf lg] matrix_works[OF linear_compose[OF lf lg]]
   693   by (simp add: matrix_eq matrix_works matrix_vector_mul_assoc[symmetric] o_def)
   694 
   695 lemma matrix_vector_column:
   696   "(A::'a::comm_semiring_1^'n^_) *v x = sum (\<lambda>i. (x$i) *s ((transpose A)$i)) (UNIV:: 'n set)"
   697   by (simp add: matrix_vector_mult_def transpose_def vec_eq_iff mult.commute)
   698 
   699 lemma adjoint_matrix: "adjoint(\<lambda>x. (A::real^'n^'m) *v x) = (\<lambda>x. transpose A *v x)"
   700   apply (rule adjoint_unique)
   701   apply (simp add: transpose_def inner_vec_def matrix_vector_mult_def
   702     sum_distrib_right sum_distrib_left)
   703   apply (subst sum.swap)
   704   apply (auto simp add: ac_simps)
   705   done
   706 
   707 lemma matrix_adjoint: assumes lf: "linear (f :: real^'n \<Rightarrow> real ^'m)"
   708   shows "matrix(adjoint f) = transpose(matrix f)"
   709   apply (subst matrix_vector_mul[OF lf])
   710   unfolding adjoint_matrix matrix_of_matrix_vector_mul
   711   apply rule
   712   done
   713 
   714 
   715 subsection \<open>lambda skolemization on cartesian products\<close>
   716 
   717 (* FIXME: rename do choice_cart *)
   718 
   719 lemma lambda_skolem: "(\<forall>i. \<exists>x. P i x) \<longleftrightarrow>
   720    (\<exists>x::'a ^ 'n. \<forall>i. P i (x $ i))" (is "?lhs \<longleftrightarrow> ?rhs")
   721 proof -
   722   let ?S = "(UNIV :: 'n set)"
   723   { assume H: "?rhs"
   724     then have ?lhs by auto }
   725   moreover
   726   { assume H: "?lhs"
   727     then obtain f where f:"\<forall>i. P i (f i)" unfolding choice_iff by metis
   728     let ?x = "(\<chi> i. (f i)) :: 'a ^ 'n"
   729     { fix i
   730       from f have "P i (f i)" by metis
   731       then have "P i (?x $ i)" by auto
   732     }
   733     hence "\<forall>i. P i (?x$i)" by metis
   734     hence ?rhs by metis }
   735   ultimately show ?thesis by metis
   736 qed
   737 
   738 lemma vector_sub_project_orthogonal_cart: "(b::real^'n) \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *s b) = 0"
   739   unfolding inner_simps scalar_mult_eq_scaleR by auto
   740 
   741 lemma left_invertible_transpose:
   742   "(\<exists>(B). B ** transpose (A) = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). A ** B = mat 1)"
   743   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   744 
   745 lemma right_invertible_transpose:
   746   "(\<exists>(B). transpose (A) ** B = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). B ** A = mat 1)"
   747   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   748 
   749 lemma matrix_left_invertible_injective:
   750   "(\<exists>B. (B::real^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x y. A *v x = A *v y \<longrightarrow> x = y)"
   751 proof -
   752   { fix B:: "real^'m^'n" and x y assume B: "B ** A = mat 1" and xy: "A *v x = A*v y"
   753     from xy have "B*v (A *v x) = B *v (A*v y)" by simp
   754     hence "x = y"
   755       unfolding matrix_vector_mul_assoc B matrix_vector_mul_lid . }
   756   moreover
   757   { assume A: "\<forall>x y. A *v x = A *v y \<longrightarrow> x = y"
   758     hence i: "inj (( *v) A)" unfolding inj_on_def by auto
   759     from linear_injective_left_inverse[OF matrix_vector_mul_linear i]
   760     obtain g where g: "linear g" "g \<circ> ( *v) A = id" by blast
   761     have "matrix g ** A = mat 1"
   762       unfolding matrix_eq matrix_vector_mul_lid matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   763       using g(2) by (simp add: fun_eq_iff)
   764     then have "\<exists>B. (B::real ^'m^'n) ** A = mat 1" by blast }
   765   ultimately show ?thesis by blast
   766 qed
   767 
   768 lemma matrix_left_invertible_ker:
   769   "(\<exists>B. (B::real ^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x. A *v x = 0 \<longrightarrow> x = 0)"
   770   unfolding matrix_left_invertible_injective
   771   using linear_injective_0[OF matrix_vector_mul_linear, of A]
   772   by (simp add: inj_on_def)
   773 
   774 lemma matrix_right_invertible_surjective:
   775   "(\<exists>B. (A::real^'n^'m) ** (B::real^'m^'n) = mat 1) \<longleftrightarrow> surj (\<lambda>x. A *v x)"
   776 proof -
   777   { fix B :: "real ^'m^'n"
   778     assume AB: "A ** B = mat 1"
   779     { fix x :: "real ^ 'm"
   780       have "A *v (B *v x) = x"
   781         by (simp add: matrix_vector_mul_lid matrix_vector_mul_assoc AB) }
   782     hence "surj (( *v) A)" unfolding surj_def by metis }
   783   moreover
   784   { assume sf: "surj (( *v) A)"
   785     from linear_surjective_right_inverse[OF matrix_vector_mul_linear sf]
   786     obtain g:: "real ^'m \<Rightarrow> real ^'n" where g: "linear g" "( *v) A \<circ> g = id"
   787       by blast
   788 
   789     have "A ** (matrix g) = mat 1"
   790       unfolding matrix_eq  matrix_vector_mul_lid
   791         matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   792       using g(2) unfolding o_def fun_eq_iff id_def
   793       .
   794     hence "\<exists>B. A ** (B::real^'m^'n) = mat 1" by blast
   795   }
   796   ultimately show ?thesis unfolding surj_def by blast
   797 qed
   798 
   799 lemma matrix_left_invertible_independent_columns:
   800   fixes A :: "real^'n^'m"
   801   shows "(\<exists>(B::real ^'m^'n). B ** A = mat 1) \<longleftrightarrow>
   802       (\<forall>c. sum (\<lambda>i. c i *s column i A) (UNIV :: 'n set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   803     (is "?lhs \<longleftrightarrow> ?rhs")
   804 proof -
   805   let ?U = "UNIV :: 'n set"
   806   { assume k: "\<forall>x. A *v x = 0 \<longrightarrow> x = 0"
   807     { fix c i
   808       assume c: "sum (\<lambda>i. c i *s column i A) ?U = 0" and i: "i \<in> ?U"
   809       let ?x = "\<chi> i. c i"
   810       have th0:"A *v ?x = 0"
   811         using c
   812         unfolding matrix_mult_sum vec_eq_iff
   813         by auto
   814       from k[rule_format, OF th0] i
   815       have "c i = 0" by (vector vec_eq_iff)}
   816     hence ?rhs by blast }
   817   moreover
   818   { assume H: ?rhs
   819     { fix x assume x: "A *v x = 0"
   820       let ?c = "\<lambda>i. ((x$i ):: real)"
   821       from H[rule_format, of ?c, unfolded matrix_mult_sum[symmetric], OF x]
   822       have "x = 0" by vector }
   823   }
   824   ultimately show ?thesis unfolding matrix_left_invertible_ker by blast
   825 qed
   826 
   827 lemma matrix_right_invertible_independent_rows:
   828   fixes A :: "real^'n^'m"
   829   shows "(\<exists>(B::real^'m^'n). A ** B = mat 1) \<longleftrightarrow>
   830     (\<forall>c. sum (\<lambda>i. c i *s row i A) (UNIV :: 'm set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   831   unfolding left_invertible_transpose[symmetric]
   832     matrix_left_invertible_independent_columns
   833   by (simp add: column_transpose)
   834 
   835 lemma matrix_right_invertible_span_columns:
   836   "(\<exists>(B::real ^'n^'m). (A::real ^'m^'n) ** B = mat 1) \<longleftrightarrow>
   837     span (columns A) = UNIV" (is "?lhs = ?rhs")
   838 proof -
   839   let ?U = "UNIV :: 'm set"
   840   have fU: "finite ?U" by simp
   841   have lhseq: "?lhs \<longleftrightarrow> (\<forall>y. \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y)"
   842     unfolding matrix_right_invertible_surjective matrix_mult_sum surj_def
   843     apply (subst eq_commute)
   844     apply rule
   845     done
   846   have rhseq: "?rhs \<longleftrightarrow> (\<forall>x. x \<in> span (columns A))" by blast
   847   { assume h: ?lhs
   848     { fix x:: "real ^'n"
   849       from h[unfolded lhseq, rule_format, of x] obtain y :: "real ^'m"
   850         where y: "sum (\<lambda>i. (y$i) *s column i A) ?U = x" by blast
   851       have "x \<in> span (columns A)"
   852         unfolding y[symmetric]
   853         apply (rule span_sum)
   854         unfolding scalar_mult_eq_scaleR
   855         apply (rule span_mul)
   856         apply (rule span_superset)
   857         unfolding columns_def
   858         apply blast
   859         done
   860     }
   861     then have ?rhs unfolding rhseq by blast }
   862   moreover
   863   { assume h:?rhs
   864     let ?P = "\<lambda>(y::real ^'n). \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y"
   865     { fix y
   866       have "?P y"
   867       proof (rule span_induct_alt[of ?P "columns A", folded scalar_mult_eq_scaleR])
   868         show "\<exists>x::real ^ 'm. sum (\<lambda>i. (x$i) *s column i A) ?U = 0"
   869           by (rule exI[where x=0], simp)
   870       next
   871         fix c y1 y2
   872         assume y1: "y1 \<in> columns A" and y2: "?P y2"
   873         from y1 obtain i where i: "i \<in> ?U" "y1 = column i A"
   874           unfolding columns_def by blast
   875         from y2 obtain x:: "real ^'m" where
   876           x: "sum (\<lambda>i. (x$i) *s column i A) ?U = y2" by blast
   877         let ?x = "(\<chi> j. if j = i then c + (x$i) else (x$j))::real^'m"
   878         show "?P (c*s y1 + y2)"
   879         proof (rule exI[where x= "?x"], vector, auto simp add: i x[symmetric] if_distrib distrib_left cond_application_beta cong del: if_weak_cong)
   880           fix j
   881           have th: "\<forall>xa \<in> ?U. (if xa = i then (c + (x$i)) * ((column xa A)$j)
   882               else (x$xa) * ((column xa A$j))) = (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))"
   883             using i(1) by (simp add: field_simps)
   884           have "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
   885               else (x$xa) * ((column xa A$j))) ?U = sum (\<lambda>xa. (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))) ?U"
   886             apply (rule sum.cong[OF refl])
   887             using th apply blast
   888             done
   889           also have "\<dots> = sum (\<lambda>xa. if xa = i then c * ((column i A)$j) else 0) ?U + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
   890             by (simp add: sum.distrib)
   891           also have "\<dots> = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
   892             unfolding sum.delta[OF fU]
   893             using i(1) by simp
   894           finally show "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
   895             else (x$xa) * ((column xa A$j))) ?U = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U" .
   896         qed
   897       next
   898         show "y \<in> span (columns A)"
   899           unfolding h by blast
   900       qed
   901     }
   902     then have ?lhs unfolding lhseq ..
   903   }
   904   ultimately show ?thesis by blast
   905 qed
   906 
   907 lemma matrix_left_invertible_span_rows:
   908   "(\<exists>(B::real^'m^'n). B ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> span (rows A) = UNIV"
   909   unfolding right_invertible_transpose[symmetric]
   910   unfolding columns_transpose[symmetric]
   911   unfolding matrix_right_invertible_span_columns
   912   ..
   913 
   914 text \<open>The same result in terms of square matrices.\<close>
   915 
   916 lemma matrix_left_right_inverse:
   917   fixes A A' :: "real ^'n^'n"
   918   shows "A ** A' = mat 1 \<longleftrightarrow> A' ** A = mat 1"
   919 proof -
   920   { fix A A' :: "real ^'n^'n"
   921     assume AA': "A ** A' = mat 1"
   922     have sA: "surj (( *v) A)"
   923       unfolding surj_def
   924       apply clarify
   925       apply (rule_tac x="(A' *v y)" in exI)
   926       apply (simp add: matrix_vector_mul_assoc AA' matrix_vector_mul_lid)
   927       done
   928     from linear_surjective_isomorphism[OF matrix_vector_mul_linear sA]
   929     obtain f' :: "real ^'n \<Rightarrow> real ^'n"
   930       where f': "linear f'" "\<forall>x. f' (A *v x) = x" "\<forall>x. A *v f' x = x" by blast
   931     have th: "matrix f' ** A = mat 1"
   932       by (simp add: matrix_eq matrix_works[OF f'(1)]
   933           matrix_vector_mul_assoc[symmetric] matrix_vector_mul_lid f'(2)[rule_format])
   934     hence "(matrix f' ** A) ** A' = mat 1 ** A'" by simp
   935     hence "matrix f' = A'"
   936       by (simp add: matrix_mul_assoc[symmetric] AA' matrix_mul_rid matrix_mul_lid)
   937     hence "matrix f' ** A = A' ** A" by simp
   938     hence "A' ** A = mat 1" by (simp add: th)
   939   }
   940   then show ?thesis by blast
   941 qed
   942 
   943 text \<open>Considering an n-element vector as an n-by-1 or 1-by-n matrix.\<close>
   944 
   945 definition "rowvector v = (\<chi> i j. (v$j))"
   946 
   947 definition "columnvector v = (\<chi> i j. (v$i))"
   948 
   949 lemma transpose_columnvector: "transpose(columnvector v) = rowvector v"
   950   by (simp add: transpose_def rowvector_def columnvector_def vec_eq_iff)
   951 
   952 lemma transpose_rowvector: "transpose(rowvector v) = columnvector v"
   953   by (simp add: transpose_def columnvector_def rowvector_def vec_eq_iff)
   954 
   955 lemma dot_rowvector_columnvector: "columnvector (A *v v) = A ** columnvector v"
   956   by (vector columnvector_def matrix_matrix_mult_def matrix_vector_mult_def)
   957 
   958 lemma dot_matrix_product:
   959   "(x::real^'n) \<bullet> y = (((rowvector x ::real^'n^1) ** (columnvector y :: real^1^'n))$1)$1"
   960   by (vector matrix_matrix_mult_def rowvector_def columnvector_def inner_vec_def)
   961 
   962 lemma dot_matrix_vector_mul:
   963   fixes A B :: "real ^'n ^'n" and x y :: "real ^'n"
   964   shows "(A *v x) \<bullet> (B *v y) =
   965       (((rowvector x :: real^'n^1) ** ((transpose A ** B) ** (columnvector y :: real ^1^'n)))$1)$1"
   966   unfolding dot_matrix_product transpose_columnvector[symmetric]
   967     dot_rowvector_columnvector matrix_transpose_mul matrix_mul_assoc ..
   968 
   969 lemma infnorm_cart:"infnorm (x::real^'n) = Sup {\<bar>x$i\<bar> |i. i\<in>UNIV}"
   970   by (simp add: infnorm_def inner_axis Basis_vec_def) (metis (lifting) inner_axis real_inner_1_right)
   971 
   972 lemma component_le_infnorm_cart: "\<bar>x$i\<bar> \<le> infnorm (x::real^'n)"
   973   using Basis_le_infnorm[of "axis i 1" x]
   974   by (simp add: Basis_vec_def axis_eq_axis inner_axis)
   975 
   976 lemma continuous_component[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x $ i)"
   977   unfolding continuous_def by (rule tendsto_vec_nth)
   978 
   979 lemma continuous_on_component[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x $ i)"
   980   unfolding continuous_on_def by (fast intro: tendsto_vec_nth)
   981 
   982 lemma continuous_on_vec_lambda[continuous_intros]:
   983   "(\<And>i. continuous_on S (f i)) \<Longrightarrow> continuous_on S (\<lambda>x. \<chi> i. f i x)"
   984   unfolding continuous_on_def by (auto intro: tendsto_vec_lambda)
   985 
   986 lemma closed_positive_orthant: "closed {x::real^'n. \<forall>i. 0 \<le>x$i}"
   987   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
   988 
   989 lemma bounded_component_cart: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $ i) ` s)"
   990   unfolding bounded_def
   991   apply clarify
   992   apply (rule_tac x="x $ i" in exI)
   993   apply (rule_tac x="e" in exI)
   994   apply clarify
   995   apply (rule order_trans [OF dist_vec_nth_le], simp)
   996   done
   997 
   998 lemma compact_lemma_cart:
   999   fixes f :: "nat \<Rightarrow> 'a::heine_borel ^ 'n"
  1000   assumes f: "bounded (range f)"
  1001   shows "\<exists>l r. strict_mono r \<and>
  1002         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $ i) (l $ i) < e) sequentially)"
  1003     (is "?th d")
  1004 proof -
  1005   have "\<forall>d' \<subseteq> d. ?th d'"
  1006     by (rule compact_lemma_general[where unproj=vec_lambda])
  1007       (auto intro!: f bounded_component_cart simp: vec_lambda_eta)
  1008   then show "?th d" by simp
  1009 qed
  1010 
  1011 instance vec :: (heine_borel, finite) heine_borel
  1012 proof
  1013   fix f :: "nat \<Rightarrow> 'a ^ 'b"
  1014   assume f: "bounded (range f)"
  1015   then obtain l r where r: "strict_mono r"
  1016       and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $ i) (l $ i) < e) sequentially"
  1017     using compact_lemma_cart [OF f] by blast
  1018   let ?d = "UNIV::'b set"
  1019   { fix e::real assume "e>0"
  1020     hence "0 < e / (real_of_nat (card ?d))"
  1021       using zero_less_card_finite divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
  1022     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))) sequentially"
  1023       by simp
  1024     moreover
  1025     { fix n
  1026       assume n: "\<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))"
  1027       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $ i) (l $ i))"
  1028         unfolding dist_vec_def using zero_le_dist by (rule L2_set_le_sum)
  1029       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
  1030         by (rule sum_strict_mono) (simp_all add: n)
  1031       finally have "dist (f (r n)) l < e" by simp
  1032     }
  1033     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  1034       by (rule eventually_mono)
  1035   }
  1036   hence "((f \<circ> r) \<longlongrightarrow> l) sequentially" unfolding o_def tendsto_iff by simp
  1037   with r show "\<exists>l r. strict_mono r \<and> ((f \<circ> r) \<longlongrightarrow> l) sequentially" by auto
  1038 qed
  1039 
  1040 lemma interval_cart:
  1041   fixes a :: "real^'n"
  1042   shows "box a b = {x::real^'n. \<forall>i. a$i < x$i \<and> x$i < b$i}"
  1043     and "cbox a b = {x::real^'n. \<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i}"
  1044   by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def mem_box Basis_vec_def inner_axis)
  1045 
  1046 lemma mem_box_cart:
  1047   fixes a :: "real^'n"
  1048   shows "x \<in> box a b \<longleftrightarrow> (\<forall>i. a$i < x$i \<and> x$i < b$i)"
  1049     and "x \<in> cbox a b \<longleftrightarrow> (\<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i)"
  1050   using interval_cart[of a b] by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def)
  1051 
  1052 lemma interval_eq_empty_cart:
  1053   fixes a :: "real^'n"
  1054   shows "(box a b = {} \<longleftrightarrow> (\<exists>i. b$i \<le> a$i))" (is ?th1)
  1055     and "(cbox a b = {} \<longleftrightarrow> (\<exists>i. b$i < a$i))" (is ?th2)
  1056 proof -
  1057   { fix i x assume as:"b$i \<le> a$i" and x:"x\<in>box a b"
  1058     hence "a $ i < x $ i \<and> x $ i < b $ i" unfolding mem_box_cart by auto
  1059     hence "a$i < b$i" by auto
  1060     hence False using as by auto }
  1061   moreover
  1062   { assume as:"\<forall>i. \<not> (b$i \<le> a$i)"
  1063     let ?x = "(1/2) *\<^sub>R (a + b)"
  1064     { fix i
  1065       have "a$i < b$i" using as[THEN spec[where x=i]] by auto
  1066       hence "a$i < ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i < b$i"
  1067         unfolding vector_smult_component and vector_add_component
  1068         by auto }
  1069     hence "box a b \<noteq> {}" using mem_box_cart(1)[of "?x" a b] by auto }
  1070   ultimately show ?th1 by blast
  1071 
  1072   { fix i x assume as:"b$i < a$i" and x:"x\<in>cbox a b"
  1073     hence "a $ i \<le> x $ i \<and> x $ i \<le> b $ i" unfolding mem_box_cart by auto
  1074     hence "a$i \<le> b$i" by auto
  1075     hence False using as by auto }
  1076   moreover
  1077   { assume as:"\<forall>i. \<not> (b$i < a$i)"
  1078     let ?x = "(1/2) *\<^sub>R (a + b)"
  1079     { fix i
  1080       have "a$i \<le> b$i" using as[THEN spec[where x=i]] by auto
  1081       hence "a$i \<le> ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i \<le> b$i"
  1082         unfolding vector_smult_component and vector_add_component
  1083         by auto }
  1084     hence "cbox a b \<noteq> {}" using mem_box_cart(2)[of "?x" a b] by auto  }
  1085   ultimately show ?th2 by blast
  1086 qed
  1087 
  1088 lemma interval_ne_empty_cart:
  1089   fixes a :: "real^'n"
  1090   shows "cbox a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i \<le> b$i)"
  1091     and "box a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i < b$i)"
  1092   unfolding interval_eq_empty_cart[of a b] by (auto simp add: not_less not_le)
  1093     (* BH: Why doesn't just "auto" work here? *)
  1094 
  1095 lemma subset_interval_imp_cart:
  1096   fixes a :: "real^'n"
  1097   shows "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> cbox c d \<subseteq> cbox a b"
  1098     and "(\<forall>i. a$i < c$i \<and> d$i < b$i) \<Longrightarrow> cbox c d \<subseteq> box a b"
  1099     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> cbox a b"
  1100     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> box a b"
  1101   unfolding subset_eq[unfolded Ball_def] unfolding mem_box_cart
  1102   by (auto intro: order_trans less_le_trans le_less_trans less_imp_le) (* BH: Why doesn't just "auto" work here? *)
  1103 
  1104 lemma interval_sing:
  1105   fixes a :: "'a::linorder^'n"
  1106   shows "{a .. a} = {a} \<and> {a<..<a} = {}"
  1107   apply (auto simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
  1108   done
  1109 
  1110 lemma subset_interval_cart:
  1111   fixes a :: "real^'n"
  1112   shows "cbox c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th1)
  1113     and "cbox c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i < c$i \<and> d$i < b$i)" (is ?th2)
  1114     and "box c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th3)
  1115     and "box c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th4)
  1116   using subset_box[of c d a b] by (simp_all add: Basis_vec_def inner_axis)
  1117 
  1118 lemma disjoint_interval_cart:
  1119   fixes a::"real^'n"
  1120   shows "cbox a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i < c$i \<or> b$i < c$i \<or> d$i < a$i))" (is ?th1)
  1121     and "cbox a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th2)
  1122     and "box a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i < c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th3)
  1123     and "box a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th4)
  1124   using disjoint_interval[of a b c d] by (simp_all add: Basis_vec_def inner_axis)
  1125 
  1126 lemma inter_interval_cart:
  1127   fixes a :: "real^'n"
  1128   shows "cbox a b \<inter> cbox c d =  {(\<chi> i. max (a$i) (c$i)) .. (\<chi> i. min (b$i) (d$i))}"
  1129   unfolding Int_interval
  1130   by (auto simp: mem_box less_eq_vec_def)
  1131     (auto simp: Basis_vec_def inner_axis)
  1132 
  1133 lemma closed_interval_left_cart:
  1134   fixes b :: "real^'n"
  1135   shows "closed {x::real^'n. \<forall>i. x$i \<le> b$i}"
  1136   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1137 
  1138 lemma closed_interval_right_cart:
  1139   fixes a::"real^'n"
  1140   shows "closed {x::real^'n. \<forall>i. a$i \<le> x$i}"
  1141   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1142 
  1143 lemma is_interval_cart:
  1144   "is_interval (s::(real^'n) set) \<longleftrightarrow>
  1145     (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i. ((a$i \<le> x$i \<and> x$i \<le> b$i) \<or> (b$i \<le> x$i \<and> x$i \<le> a$i))) \<longrightarrow> x \<in> s)"
  1146   by (simp add: is_interval_def Ball_def Basis_vec_def inner_axis imp_ex)
  1147 
  1148 lemma closed_halfspace_component_le_cart: "closed {x::real^'n. x$i \<le> a}"
  1149   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1150 
  1151 lemma closed_halfspace_component_ge_cart: "closed {x::real^'n. x$i \<ge> a}"
  1152   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1153 
  1154 lemma open_halfspace_component_lt_cart: "open {x::real^'n. x$i < a}"
  1155   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1156 
  1157 lemma open_halfspace_component_gt_cart: "open {x::real^'n. x$i  > a}"
  1158   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1159 
  1160 lemma Lim_component_le_cart:
  1161   fixes f :: "'a \<Rightarrow> real^'n"
  1162   assumes "(f \<longlongrightarrow> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f x $i \<le> b) net"
  1163   shows "l$i \<le> b"
  1164   by (rule tendsto_le[OF assms(2) tendsto_const tendsto_vec_nth, OF assms(1, 3)])
  1165 
  1166 lemma Lim_component_ge_cart:
  1167   fixes f :: "'a \<Rightarrow> real^'n"
  1168   assumes "(f \<longlongrightarrow> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$i) net"
  1169   shows "b \<le> l$i"
  1170   by (rule tendsto_le[OF assms(2) tendsto_vec_nth tendsto_const, OF assms(1, 3)])
  1171 
  1172 lemma Lim_component_eq_cart:
  1173   fixes f :: "'a \<Rightarrow> real^'n"
  1174   assumes net: "(f \<longlongrightarrow> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$i = b) net"
  1175   shows "l$i = b"
  1176   using ev[unfolded order_eq_iff eventually_conj_iff] and
  1177     Lim_component_ge_cart[OF net, of b i] and
  1178     Lim_component_le_cart[OF net, of i b] by auto
  1179 
  1180 lemma connected_ivt_component_cart:
  1181   fixes x :: "real^'n"
  1182   shows "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$k \<le> a \<Longrightarrow> a \<le> y$k \<Longrightarrow> (\<exists>z\<in>s.  z$k = a)"
  1183   using connected_ivt_hyperplane[of s x y "axis k 1" a]
  1184   by (auto simp add: inner_axis inner_commute)
  1185 
  1186 lemma subspace_substandard_cart: "subspace {x::real^_. (\<forall>i. P i \<longrightarrow> x$i = 0)}"
  1187   unfolding subspace_def by auto
  1188 
  1189 lemma closed_substandard_cart:
  1190   "closed {x::'a::real_normed_vector ^ 'n. \<forall>i. P i \<longrightarrow> x$i = 0}"
  1191 proof -
  1192   { fix i::'n
  1193     have "closed {x::'a ^ 'n. P i \<longrightarrow> x$i = 0}"
  1194       by (cases "P i") (simp_all add: closed_Collect_eq continuous_on_const continuous_on_id continuous_on_component) }
  1195   thus ?thesis
  1196     unfolding Collect_all_eq by (simp add: closed_INT)
  1197 qed
  1198 
  1199 lemma dim_substandard_cart: "dim {x::real^'n. \<forall>i. i \<notin> d \<longrightarrow> x$i = 0} = card d"
  1200   (is "dim ?A = _")
  1201 proof -
  1202   let ?a = "\<lambda>x. axis x 1 :: real^'n"
  1203   have *: "{x. \<forall>i\<in>Basis. i \<notin> ?a ` d \<longrightarrow> x \<bullet> i = 0} = ?A"
  1204     by (auto simp: image_iff Basis_vec_def axis_eq_axis inner_axis)
  1205   have "?a ` d \<subseteq> Basis"
  1206     by (auto simp: Basis_vec_def)
  1207   thus ?thesis
  1208     using dim_substandard[of "?a ` d"] card_image[of ?a d]
  1209     by (auto simp: axis_eq_axis inj_on_def *)
  1210 qed
  1211 
  1212 lemma affinity_inverses:
  1213   assumes m0: "m \<noteq> (0::'a::field)"
  1214   shows "(\<lambda>x. m *s x + c) \<circ> (\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) = id"
  1215   "(\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) \<circ> (\<lambda>x. m *s x + c) = id"
  1216   using m0
  1217   apply (auto simp add: fun_eq_iff vector_add_ldistrib diff_conv_add_uminus simp del: add_uminus_conv_diff)
  1218   apply (simp_all add: vector_smult_lneg[symmetric] vector_smult_assoc vector_sneg_minus1 [symmetric])
  1219   done
  1220 
  1221 lemma vector_affinity_eq:
  1222   assumes m0: "(m::'a::field) \<noteq> 0"
  1223   shows "m *s x + c = y \<longleftrightarrow> x = inverse m *s y + -(inverse m *s c)"
  1224 proof
  1225   assume h: "m *s x + c = y"
  1226   hence "m *s x = y - c" by (simp add: field_simps)
  1227   hence "inverse m *s (m *s x) = inverse m *s (y - c)" by simp
  1228   then show "x = inverse m *s y + - (inverse m *s c)"
  1229     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1230 next
  1231   assume h: "x = inverse m *s y + - (inverse m *s c)"
  1232   show "m *s x + c = y" unfolding h
  1233     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1234 qed
  1235 
  1236 lemma vector_eq_affinity:
  1237     "(m::'a::field) \<noteq> 0 ==> (y = m *s x + c \<longleftrightarrow> inverse(m) *s y + -(inverse(m) *s c) = x)"
  1238   using vector_affinity_eq[where m=m and x=x and y=y and c=c]
  1239   by metis
  1240 
  1241 lemma vector_cart:
  1242   fixes f :: "real^'n \<Rightarrow> real"
  1243   shows "(\<chi> i. f (axis i 1)) = (\<Sum>i\<in>Basis. f i *\<^sub>R i)"
  1244   unfolding euclidean_eq_iff[where 'a="real^'n"]
  1245   by simp (simp add: Basis_vec_def inner_axis)
  1246 
  1247 lemma const_vector_cart:"((\<chi> i. d)::real^'n) = (\<Sum>i\<in>Basis. d *\<^sub>R i)"
  1248   by (rule vector_cart)
  1249 
  1250 subsection "Convex Euclidean Space"
  1251 
  1252 lemma Cart_1:"(1::real^'n) = \<Sum>Basis"
  1253   using const_vector_cart[of 1] by (simp add: one_vec_def)
  1254 
  1255 declare vector_add_ldistrib[simp] vector_ssub_ldistrib[simp] vector_smult_assoc[simp] vector_smult_rneg[simp]
  1256 declare vector_sadd_rdistrib[simp] vector_sub_rdistrib[simp]
  1257 
  1258 lemmas vector_component_simps = vector_minus_component vector_smult_component vector_add_component less_eq_vec_def vec_lambda_beta vector_uminus_component
  1259 
  1260 lemma convex_box_cart:
  1261   assumes "\<And>i. convex {x. P i x}"
  1262   shows "convex {x. \<forall>i. P i (x$i)}"
  1263   using assms unfolding convex_def by auto
  1264 
  1265 lemma convex_positive_orthant_cart: "convex {x::real^'n. (\<forall>i. 0 \<le> x$i)}"
  1266   by (rule convex_box_cart) (simp add: atLeast_def[symmetric])
  1267 
  1268 lemma unit_interval_convex_hull_cart:
  1269   "cbox (0::real^'n) 1 = convex hull {x. \<forall>i. (x$i = 0) \<or> (x$i = 1)}"
  1270   unfolding Cart_1 unit_interval_convex_hull[where 'a="real^'n"] box_real[symmetric]
  1271   by (rule arg_cong[where f="\<lambda>x. convex hull x"]) (simp add: Basis_vec_def inner_axis)
  1272 
  1273 lemma cube_convex_hull_cart:
  1274   assumes "0 < d"
  1275   obtains s::"(real^'n) set"
  1276     where "finite s" "cbox (x - (\<chi> i. d)) (x + (\<chi> i. d)) = convex hull s"
  1277 proof -
  1278   from assms obtain s where "finite s"
  1279     and "cbox (x - sum (( *\<^sub>R) d) Basis) (x + sum (( *\<^sub>R) d) Basis) = convex hull s"
  1280     by (rule cube_convex_hull)
  1281   with that[of s] show thesis
  1282     by (simp add: const_vector_cart)
  1283 qed
  1284 
  1285 
  1286 subsection "Derivative"
  1287 
  1288 definition "jacobian f net = matrix(frechet_derivative f net)"
  1289 
  1290 lemma jacobian_works:
  1291   "(f::(real^'a) \<Rightarrow> (real^'b)) differentiable net \<longleftrightarrow>
  1292     (f has_derivative (\<lambda>h. (jacobian f net) *v h)) net"
  1293   apply rule
  1294   unfolding jacobian_def
  1295   apply (simp only: matrix_works[OF linear_frechet_derivative]) defer
  1296   apply (rule differentiableI)
  1297   apply assumption
  1298   unfolding frechet_derivative_works
  1299   apply assumption
  1300   done
  1301 
  1302 
  1303 subsection \<open>Component of the differential must be zero if it exists at a local
  1304   maximum or minimum for that corresponding component.\<close>
  1305 
  1306 lemma differential_zero_maxmin_cart:
  1307   fixes f::"real^'a \<Rightarrow> real^'b"
  1308   assumes "0 < e" "((\<forall>y \<in> ball x e. (f y)$k \<le> (f x)$k) \<or> (\<forall>y\<in>ball x e. (f x)$k \<le> (f y)$k))"
  1309     "f differentiable (at x)"
  1310   shows "jacobian f (at x) $ k = 0"
  1311   using differential_zero_maxmin_component[of "axis k 1" e x f] assms
  1312     vector_cart[of "\<lambda>j. frechet_derivative f (at x) j $ k"]
  1313   by (simp add: Basis_vec_def axis_eq_axis inner_axis jacobian_def matrix_def)
  1314 
  1315 subsection \<open>Lemmas for working on @{typ "real^1"}\<close>
  1316 
  1317 lemma forall_1[simp]: "(\<forall>i::1. P i) \<longleftrightarrow> P 1"
  1318   by (metis (full_types) num1_eq_iff)
  1319 
  1320 lemma ex_1[simp]: "(\<exists>x::1. P x) \<longleftrightarrow> P 1"
  1321   by auto (metis (full_types) num1_eq_iff)
  1322 
  1323 lemma exhaust_2:
  1324   fixes x :: 2
  1325   shows "x = 1 \<or> x = 2"
  1326 proof (induct x)
  1327   case (of_int z)
  1328   then have "0 <= z" and "z < 2" by simp_all
  1329   then have "z = 0 | z = 1" by arith
  1330   then show ?case by auto
  1331 qed
  1332 
  1333 lemma forall_2: "(\<forall>i::2. P i) \<longleftrightarrow> P 1 \<and> P 2"
  1334   by (metis exhaust_2)
  1335 
  1336 lemma exhaust_3:
  1337   fixes x :: 3
  1338   shows "x = 1 \<or> x = 2 \<or> x = 3"
  1339 proof (induct x)
  1340   case (of_int z)
  1341   then have "0 <= z" and "z < 3" by simp_all
  1342   then have "z = 0 \<or> z = 1 \<or> z = 2" by arith
  1343   then show ?case by auto
  1344 qed
  1345 
  1346 lemma forall_3: "(\<forall>i::3. P i) \<longleftrightarrow> P 1 \<and> P 2 \<and> P 3"
  1347   by (metis exhaust_3)
  1348 
  1349 lemma UNIV_1 [simp]: "UNIV = {1::1}"
  1350   by (auto simp add: num1_eq_iff)
  1351 
  1352 lemma UNIV_2: "UNIV = {1::2, 2::2}"
  1353   using exhaust_2 by auto
  1354 
  1355 lemma UNIV_3: "UNIV = {1::3, 2::3, 3::3}"
  1356   using exhaust_3 by auto
  1357 
  1358 lemma sum_1: "sum f (UNIV::1 set) = f 1"
  1359   unfolding UNIV_1 by simp
  1360 
  1361 lemma sum_2: "sum f (UNIV::2 set) = f 1 + f 2"
  1362   unfolding UNIV_2 by simp
  1363 
  1364 lemma sum_3: "sum f (UNIV::3 set) = f 1 + f 2 + f 3"
  1365   unfolding UNIV_3 by (simp add: ac_simps)
  1366 
  1367 instantiation num1 :: cart_one
  1368 begin
  1369 
  1370 instance
  1371 proof
  1372   show "CARD(1) = Suc 0" by auto
  1373 qed
  1374 
  1375 end
  1376 
  1377 subsection\<open>The collapse of the general concepts to dimension one.\<close>
  1378 
  1379 lemma vector_one: "(x::'a ^1) = (\<chi> i. (x$1))"
  1380   by (simp add: vec_eq_iff)
  1381 
  1382 lemma forall_one: "(\<forall>(x::'a ^1). P x) \<longleftrightarrow> (\<forall>x. P(\<chi> i. x))"
  1383   apply auto
  1384   apply (erule_tac x= "x$1" in allE)
  1385   apply (simp only: vector_one[symmetric])
  1386   done
  1387 
  1388 lemma norm_vector_1: "norm (x :: _^1) = norm (x$1)"
  1389   by (simp add: norm_vec_def)
  1390 
  1391 lemma norm_real: "norm(x::real ^ 1) = \<bar>x$1\<bar>"
  1392   by (simp add: norm_vector_1)
  1393 
  1394 lemma dist_real: "dist(x::real ^ 1) y = \<bar>(x$1) - (y$1)\<bar>"
  1395   by (auto simp add: norm_real dist_norm)
  1396 
  1397 
  1398 subsection\<open>Explicit vector construction from lists.\<close>
  1399 
  1400 definition "vector l = (\<chi> i. foldr (\<lambda>x f n. fun_upd (f (n+1)) n x) l (\<lambda>n x. 0) 1 i)"
  1401 
  1402 lemma vector_1: "(vector[x]) $1 = x"
  1403   unfolding vector_def by simp
  1404 
  1405 lemma vector_2:
  1406  "(vector[x,y]) $1 = x"
  1407  "(vector[x,y] :: 'a^2)$2 = (y::'a::zero)"
  1408   unfolding vector_def by simp_all
  1409 
  1410 lemma vector_3:
  1411  "(vector [x,y,z] ::('a::zero)^3)$1 = x"
  1412  "(vector [x,y,z] ::('a::zero)^3)$2 = y"
  1413  "(vector [x,y,z] ::('a::zero)^3)$3 = z"
  1414   unfolding vector_def by simp_all
  1415 
  1416 lemma forall_vector_1: "(\<forall>v::'a::zero^1. P v) \<longleftrightarrow> (\<forall>x. P(vector[x]))"
  1417   apply auto
  1418   apply (erule_tac x="v$1" in allE)
  1419   apply (subgoal_tac "vector [v$1] = v")
  1420   apply simp
  1421   apply (vector vector_def)
  1422   apply simp
  1423   done
  1424 
  1425 lemma forall_vector_2: "(\<forall>v::'a::zero^2. P v) \<longleftrightarrow> (\<forall>x y. P(vector[x, y]))"
  1426   apply auto
  1427   apply (erule_tac x="v$1" in allE)
  1428   apply (erule_tac x="v$2" in allE)
  1429   apply (subgoal_tac "vector [v$1, v$2] = v")
  1430   apply simp
  1431   apply (vector vector_def)
  1432   apply (simp add: forall_2)
  1433   done
  1434 
  1435 lemma forall_vector_3: "(\<forall>v::'a::zero^3. P v) \<longleftrightarrow> (\<forall>x y z. P(vector[x, y, z]))"
  1436   apply auto
  1437   apply (erule_tac x="v$1" in allE)
  1438   apply (erule_tac x="v$2" in allE)
  1439   apply (erule_tac x="v$3" in allE)
  1440   apply (subgoal_tac "vector [v$1, v$2, v$3] = v")
  1441   apply simp
  1442   apply (vector vector_def)
  1443   apply (simp add: forall_3)
  1444   done
  1445 
  1446 lemma bounded_linear_component_cart[intro]: "bounded_linear (\<lambda>x::real^'n. x $ k)"
  1447   apply (rule bounded_linearI[where K=1])
  1448   using component_le_norm_cart[of _ k] unfolding real_norm_def by auto
  1449 
  1450 lemma interval_split_cart:
  1451   "{a..b::real^'n} \<inter> {x. x$k \<le> c} = {a .. (\<chi> i. if i = k then min (b$k) c else b$i)}"
  1452   "cbox a b \<inter> {x. x$k \<ge> c} = {(\<chi> i. if i = k then max (a$k) c else a$i) .. b}"
  1453   apply (rule_tac[!] set_eqI)
  1454   unfolding Int_iff mem_box_cart mem_Collect_eq interval_cbox_cart
  1455   unfolding vec_lambda_beta
  1456   by auto
  1457 
  1458 lemmas cartesian_euclidean_space_uniform_limit_intros[uniform_limit_intros] =
  1459   bounded_linear.uniform_limit[OF blinfun.bounded_linear_right]
  1460   bounded_linear.uniform_limit[OF bounded_linear_vec_nth]
  1461   bounded_linear.uniform_limit[OF bounded_linear_component_cart]
  1462 
  1463 end