src/HOL/Enum.thy
author haftmann
Sat Oct 20 10:00:21 2012 +0200 (2012-10-20)
changeset 49949 be3dd2e602e8
parent 49948 744934b818c7
child 49950 cd882d53ba6b
permissions -rw-r--r--
refined internal structure of Enum.thy
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Finite types as explicit enumerations *}
     4 
     5 theory Enum
     6 imports Map String
     7 begin
     8 
     9 subsection {* Class @{text enum} *}
    10 
    11 class enum =
    12   fixes enum :: "'a list"
    13   fixes enum_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    14   fixes enum_ex  :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    15   assumes UNIV_enum: "UNIV = set enum"
    16     and enum_distinct: "distinct enum"
    17   assumes enum_all : "enum_all P = (\<forall> x. P x)"
    18   assumes enum_ex  : "enum_ex P = (\<exists> x. P x)" 
    19 begin
    20 
    21 subclass finite proof
    22 qed (simp add: UNIV_enum)
    23 
    24 lemma enum_UNIV: "set enum = UNIV" unfolding UNIV_enum ..
    25 
    26 lemma in_enum: "x \<in> set enum"
    27   unfolding enum_UNIV by auto
    28 
    29 lemma enum_eq_I:
    30   assumes "\<And>x. x \<in> set xs"
    31   shows "set enum = set xs"
    32 proof -
    33   from assms UNIV_eq_I have "UNIV = set xs" by auto
    34   with enum_UNIV show ?thesis by simp
    35 qed
    36 
    37 end
    38 
    39 
    40 subsection {* Implementations using @{class enum} *}
    41 
    42 subsubsection {* Unbounded operations and quantifiers *}
    43 
    44 lemma Collect_code [code]:
    45   "Collect P = set (filter P enum)"
    46   by (auto simp add: enum_UNIV)
    47 
    48 definition card_UNIV :: "'a itself \<Rightarrow> nat"
    49 where
    50   [code del]: "card_UNIV TYPE('a) = card (UNIV :: 'a set)"
    51 
    52 lemma [code]:
    53   "card_UNIV TYPE('a :: enum) = card (set (Enum.enum :: 'a list))"
    54   by (simp only: card_UNIV_def enum_UNIV)
    55 
    56 lemma all_code [code]: "(\<forall>x. P x) \<longleftrightarrow> enum_all P"
    57   by (simp add: enum_all)
    58 
    59 lemma exists_code [code]: "(\<exists>x. P x) \<longleftrightarrow> enum_ex P"
    60   by (simp add: enum_ex)
    61 
    62 lemma exists1_code [code]: "(\<exists>!x. P x) \<longleftrightarrow> list_ex1 P enum"
    63   by (auto simp add: enum_UNIV list_ex1_iff)
    64 
    65 
    66 subsubsection {* An executable choice operator *}
    67 
    68 definition
    69   [code del]: "enum_the = The"
    70 
    71 lemma [code]:
    72   "The P = (case filter P enum of [x] => x | _ => enum_the P)"
    73 proof -
    74   {
    75     fix a
    76     assume filter_enum: "filter P enum = [a]"
    77     have "The P = a"
    78     proof (rule the_equality)
    79       fix x
    80       assume "P x"
    81       show "x = a"
    82       proof (rule ccontr)
    83         assume "x \<noteq> a"
    84         from filter_enum obtain us vs
    85           where enum_eq: "enum = us @ [a] @ vs"
    86           and "\<forall> x \<in> set us. \<not> P x"
    87           and "\<forall> x \<in> set vs. \<not> P x"
    88           and "P a"
    89           by (auto simp add: filter_eq_Cons_iff) (simp only: filter_empty_conv[symmetric])
    90         with `P x` in_enum[of x, unfolded enum_eq] `x \<noteq> a` show "False" by auto
    91       qed
    92     next
    93       from filter_enum show "P a" by (auto simp add: filter_eq_Cons_iff)
    94     qed
    95   }
    96   from this show ?thesis
    97     unfolding enum_the_def by (auto split: list.split)
    98 qed
    99 
   100 code_abort enum_the
   101 code_const enum_the (Eval "(fn p => raise Match)")
   102 
   103 
   104 subsubsection {* Equality and order on functions *}
   105 
   106 instantiation "fun" :: (enum, equal) equal
   107 begin
   108 
   109 definition
   110   "HOL.equal f g \<longleftrightarrow> (\<forall>x \<in> set enum. f x = g x)"
   111 
   112 instance proof
   113 qed (simp_all add: equal_fun_def enum_UNIV fun_eq_iff)
   114 
   115 end
   116 
   117 lemma [code]:
   118   "HOL.equal f g \<longleftrightarrow> enum_all (%x. f x = g x)"
   119 by (auto simp add: equal enum_all fun_eq_iff)
   120 
   121 lemma [code nbe]:
   122   "HOL.equal (f :: _ \<Rightarrow> _) f \<longleftrightarrow> True"
   123   by (fact equal_refl)
   124 
   125 lemma order_fun [code]:
   126   fixes f g :: "'a\<Colon>enum \<Rightarrow> 'b\<Colon>order"
   127   shows "f \<le> g \<longleftrightarrow> enum_all (\<lambda>x. f x \<le> g x)"
   128     and "f < g \<longleftrightarrow> f \<le> g \<and> enum_ex (\<lambda>x. f x \<noteq> g x)"
   129   by (simp_all add: enum_all enum_ex fun_eq_iff le_fun_def order_less_le)
   130 
   131 
   132 subsubsection {* Operations on relations *}
   133 
   134 lemma [code]:
   135   "Id = image (\<lambda>x. (x, x)) (set Enum.enum)"
   136   by (auto intro: imageI in_enum)
   137 
   138 lemma tranclp_unfold [code, no_atp]:
   139   "tranclp r a b \<longleftrightarrow> (a, b) \<in> trancl {(x, y). r x y}"
   140   by (simp add: trancl_def)
   141 
   142 lemma rtranclp_rtrancl_eq [code, no_atp]:
   143   "rtranclp r x y \<longleftrightarrow> (x, y) \<in> rtrancl {(x, y). r x y}"
   144   by (simp add: rtrancl_def)
   145 
   146 lemma max_ext_eq [code]:
   147   "max_ext R = {(X, Y). finite X \<and> finite Y \<and> Y \<noteq> {} \<and> (\<forall>x. x \<in> X \<longrightarrow> (\<exists>xa \<in> Y. (x, xa) \<in> R))}"
   148   by (auto simp add: max_ext.simps)
   149 
   150 lemma max_extp_eq [code]:
   151   "max_extp r x y \<longleftrightarrow> (x, y) \<in> max_ext {(x, y). r x y}"
   152   by (simp add: max_ext_def)
   153 
   154 lemma mlex_eq [code]:
   155   "f <*mlex*> R = {(x, y). f x < f y \<or> (f x \<le> f y \<and> (x, y) \<in> R)}"
   156   by (auto simp add: mlex_prod_def)
   157 
   158 lemma [code]:
   159   fixes xs :: "('a::finite \<times> 'a) list"
   160   shows "acc (set xs) = bacc (set xs) (card_UNIV TYPE('a))"
   161   by (simp add: card_UNIV_def acc_bacc_eq)
   162 
   163 lemma [code]:
   164   "accp r = (\<lambda>x. x \<in> acc {(x, y). r x y})"
   165   by (simp add: acc_def)
   166 
   167 
   168 subsection {* Default instances for @{class enum} *}
   169 
   170 lemma map_of_zip_enum_is_Some:
   171   assumes "length ys = length (enum \<Colon> 'a\<Colon>enum list)"
   172   shows "\<exists>y. map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x = Some y"
   173 proof -
   174   from assms have "x \<in> set (enum \<Colon> 'a\<Colon>enum list) \<longleftrightarrow>
   175     (\<exists>y. map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x = Some y)"
   176     by (auto intro!: map_of_zip_is_Some)
   177   then show ?thesis using enum_UNIV by auto
   178 qed
   179 
   180 lemma map_of_zip_enum_inject:
   181   fixes xs ys :: "'b\<Colon>enum list"
   182   assumes length: "length xs = length (enum \<Colon> 'a\<Colon>enum list)"
   183       "length ys = length (enum \<Colon> 'a\<Colon>enum list)"
   184     and map_of: "the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys)"
   185   shows "xs = ys"
   186 proof -
   187   have "map_of (zip (enum \<Colon> 'a list) xs) = map_of (zip (enum \<Colon> 'a list) ys)"
   188   proof
   189     fix x :: 'a
   190     from length map_of_zip_enum_is_Some obtain y1 y2
   191       where "map_of (zip (enum \<Colon> 'a list) xs) x = Some y1"
   192         and "map_of (zip (enum \<Colon> 'a list) ys) x = Some y2" by blast
   193     moreover from map_of
   194       have "the (map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) x) = the (map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x)"
   195       by (auto dest: fun_cong)
   196     ultimately show "map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) x = map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x"
   197       by simp
   198   qed
   199   with length enum_distinct show "xs = ys" by (rule map_of_zip_inject)
   200 qed
   201 
   202 definition
   203   all_n_lists :: "(('a :: enum) list \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> bool"
   204 where
   205   "all_n_lists P n = (\<forall>xs \<in> set (List.n_lists n enum). P xs)"
   206 
   207 lemma [code]:
   208   "all_n_lists P n = (if n = 0 then P [] else enum_all (%x. all_n_lists (%xs. P (x # xs)) (n - 1)))"
   209 unfolding all_n_lists_def enum_all
   210 by (cases n) (auto simp add: enum_UNIV)
   211 
   212 definition
   213   ex_n_lists :: "(('a :: enum) list \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> bool"
   214 where
   215   "ex_n_lists P n = (\<exists>xs \<in> set (List.n_lists n enum). P xs)"
   216 
   217 lemma [code]:
   218   "ex_n_lists P n = (if n = 0 then P [] else enum_ex (%x. ex_n_lists (%xs. P (x # xs)) (n - 1)))"
   219 unfolding ex_n_lists_def enum_ex
   220 by (cases n) (auto simp add: enum_UNIV)
   221 
   222 
   223 instantiation "fun" :: (enum, enum) enum
   224 begin
   225 
   226 definition
   227   "enum = map (\<lambda>ys. the o map_of (zip (enum\<Colon>'a list) ys)) (List.n_lists (length (enum\<Colon>'a\<Colon>enum list)) enum)"
   228 
   229 definition
   230   "enum_all P = all_n_lists (\<lambda>bs. P (the o map_of (zip enum bs))) (length (enum :: 'a list))"
   231 
   232 definition
   233   "enum_ex P = ex_n_lists (\<lambda>bs. P (the o map_of (zip enum bs))) (length (enum :: 'a list))"
   234 
   235 
   236 instance proof
   237   show "UNIV = set (enum \<Colon> ('a \<Rightarrow> 'b) list)"
   238   proof (rule UNIV_eq_I)
   239     fix f :: "'a \<Rightarrow> 'b"
   240     have "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   241       by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
   242     then show "f \<in> set enum"
   243       by (auto simp add: enum_fun_def set_n_lists intro: in_enum)
   244   qed
   245 next
   246   from map_of_zip_enum_inject
   247   show "distinct (enum \<Colon> ('a \<Rightarrow> 'b) list)"
   248     by (auto intro!: inj_onI simp add: enum_fun_def
   249       distinct_map distinct_n_lists enum_distinct set_n_lists enum_all)
   250 next
   251   fix P
   252   show "enum_all (P :: ('a \<Rightarrow> 'b) \<Rightarrow> bool) = (\<forall>x. P x)"
   253   proof
   254     assume "enum_all P"
   255     show "\<forall>x. P x"
   256     proof
   257       fix f :: "'a \<Rightarrow> 'b"
   258       have f: "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   259         by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
   260       from `enum_all P` have "P (the \<circ> map_of (zip enum (map f enum)))"
   261         unfolding enum_all_fun_def all_n_lists_def
   262         apply (simp add: set_n_lists)
   263         apply (erule_tac x="map f enum" in allE)
   264         apply (auto intro!: in_enum)
   265         done
   266       from this f show "P f" by auto
   267     qed
   268   next
   269     assume "\<forall>x. P x"
   270     from this show "enum_all P"
   271       unfolding enum_all_fun_def all_n_lists_def by auto
   272   qed
   273 next
   274   fix P
   275   show "enum_ex (P :: ('a \<Rightarrow> 'b) \<Rightarrow> bool) = (\<exists>x. P x)"
   276   proof
   277     assume "enum_ex P"
   278     from this show "\<exists>x. P x"
   279       unfolding enum_ex_fun_def ex_n_lists_def by auto
   280   next
   281     assume "\<exists>x. P x"
   282     from this obtain f where "P f" ..
   283     have f: "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   284       by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum) 
   285     from `P f` this have "P (the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum)))"
   286       by auto
   287     from  this show "enum_ex P"
   288       unfolding enum_ex_fun_def ex_n_lists_def
   289       apply (auto simp add: set_n_lists)
   290       apply (rule_tac x="map f enum" in exI)
   291       apply (auto intro!: in_enum)
   292       done
   293   qed
   294 qed
   295 
   296 end
   297 
   298 lemma enum_fun_code [code]: "enum = (let enum_a = (enum \<Colon> 'a\<Colon>{enum, equal} list)
   299   in map (\<lambda>ys. the o map_of (zip enum_a ys)) (List.n_lists (length enum_a) enum))"
   300   by (simp add: enum_fun_def Let_def)
   301 
   302 lemma enum_all_fun_code [code]:
   303   "enum_all P = (let enum_a = (enum :: 'a::{enum, equal} list)
   304    in all_n_lists (\<lambda>bs. P (the o map_of (zip enum_a bs))) (length enum_a))"
   305   by (simp add: enum_all_fun_def Let_def)
   306 
   307 lemma enum_ex_fun_code [code]:
   308   "enum_ex P = (let enum_a = (enum :: 'a::{enum, equal} list)
   309    in ex_n_lists (\<lambda>bs. P (the o map_of (zip enum_a bs))) (length enum_a))"
   310   by (simp add: enum_ex_fun_def Let_def)
   311 
   312 instantiation unit :: enum
   313 begin
   314 
   315 definition
   316   "enum = [()]"
   317 
   318 definition
   319   "enum_all P = P ()"
   320 
   321 definition
   322   "enum_ex P = P ()"
   323 
   324 instance proof
   325 qed (auto simp add: enum_unit_def UNIV_unit enum_all_unit_def enum_ex_unit_def intro: unit.exhaust)
   326 
   327 end
   328 
   329 instantiation bool :: enum
   330 begin
   331 
   332 definition
   333   "enum = [False, True]"
   334 
   335 definition
   336   "enum_all P = (P False \<and> P True)"
   337 
   338 definition
   339   "enum_ex P = (P False \<or> P True)"
   340 
   341 instance proof
   342   fix P
   343   show "enum_all (P :: bool \<Rightarrow> bool) = (\<forall>x. P x)"
   344     unfolding enum_all_bool_def by (auto, case_tac x) auto
   345 next
   346   fix P
   347   show "enum_ex (P :: bool \<Rightarrow> bool) = (\<exists>x. P x)"
   348     unfolding enum_ex_bool_def by (auto, case_tac x) auto
   349 qed (auto simp add: enum_bool_def UNIV_bool)
   350 
   351 end
   352 
   353 instantiation prod :: (enum, enum) enum
   354 begin
   355 
   356 definition
   357   "enum = List.product enum enum"
   358 
   359 definition
   360   "enum_all P = enum_all (%x. enum_all (%y. P (x, y)))"
   361 
   362 definition
   363   "enum_ex P = enum_ex (%x. enum_ex (%y. P (x, y)))"
   364 
   365  
   366 instance by default
   367   (simp_all add: enum_prod_def product_list_set distinct_product
   368     enum_UNIV enum_distinct enum_all_prod_def enum_all enum_ex_prod_def enum_ex)
   369 
   370 end
   371 
   372 instantiation sum :: (enum, enum) enum
   373 begin
   374 
   375 definition
   376   "enum = map Inl enum @ map Inr enum"
   377 
   378 definition
   379   "enum_all P = (enum_all (%x. P (Inl x)) \<and> enum_all (%x. P (Inr x)))"
   380 
   381 definition
   382   "enum_ex P = (enum_ex (%x. P (Inl x)) \<or> enum_ex (%x. P (Inr x)))"
   383 
   384 instance proof
   385   fix P
   386   show "enum_all (P :: ('a + 'b) \<Rightarrow> bool) = (\<forall>x. P x)"
   387     unfolding enum_all_sum_def enum_all
   388     by (auto, case_tac x) auto
   389 next
   390   fix P
   391   show "enum_ex (P :: ('a + 'b) \<Rightarrow> bool) = (\<exists>x. P x)"
   392     unfolding enum_ex_sum_def enum_ex
   393     by (auto, case_tac x) auto
   394 qed (auto simp add: enum_UNIV enum_sum_def, case_tac x, auto intro: inj_onI simp add: distinct_map enum_distinct)
   395 
   396 end
   397 
   398 instantiation nibble :: enum
   399 begin
   400 
   401 definition
   402   "enum = [Nibble0, Nibble1, Nibble2, Nibble3, Nibble4, Nibble5, Nibble6, Nibble7,
   403     Nibble8, Nibble9, NibbleA, NibbleB, NibbleC, NibbleD, NibbleE, NibbleF]"
   404 
   405 definition
   406   "enum_all P = (P Nibble0 \<and> P Nibble1 \<and> P Nibble2 \<and> P Nibble3 \<and> P Nibble4 \<and> P Nibble5 \<and> P Nibble6 \<and> P Nibble7
   407      \<and> P Nibble8 \<and> P Nibble9 \<and> P NibbleA \<and> P NibbleB \<and> P NibbleC \<and> P NibbleD \<and> P NibbleE \<and> P NibbleF)"
   408 
   409 definition
   410   "enum_ex P = (P Nibble0 \<or> P Nibble1 \<or> P Nibble2 \<or> P Nibble3 \<or> P Nibble4 \<or> P Nibble5 \<or> P Nibble6 \<or> P Nibble7
   411      \<or> P Nibble8 \<or> P Nibble9 \<or> P NibbleA \<or> P NibbleB \<or> P NibbleC \<or> P NibbleD \<or> P NibbleE \<or> P NibbleF)"
   412 
   413 instance proof
   414   fix P
   415   show "enum_all (P :: nibble \<Rightarrow> bool) = (\<forall>x. P x)"
   416     unfolding enum_all_nibble_def
   417     by (auto, case_tac x) auto
   418 next
   419   fix P
   420   show "enum_ex (P :: nibble \<Rightarrow> bool) = (\<exists>x. P x)"
   421     unfolding enum_ex_nibble_def
   422     by (auto, case_tac x) auto
   423 qed (simp_all add: enum_nibble_def UNIV_nibble)
   424 
   425 end
   426 
   427 instantiation char :: enum
   428 begin
   429 
   430 definition
   431   "enum = map (split Char) (List.product enum enum)"
   432 
   433 lemma enum_chars [code]:
   434   "enum = chars"
   435   unfolding enum_char_def chars_def enum_nibble_def by simp
   436 
   437 definition
   438   "enum_all P = list_all P chars"
   439 
   440 definition
   441   "enum_ex P = list_ex P chars"
   442 
   443 lemma set_enum_char: "set (enum :: char list) = UNIV"
   444     by (auto intro: char.exhaust simp add: enum_char_def product_list_set enum_UNIV full_SetCompr_eq [symmetric])
   445 
   446 instance proof
   447   fix P
   448   show "enum_all (P :: char \<Rightarrow> bool) = (\<forall>x. P x)"
   449     unfolding enum_all_char_def enum_chars[symmetric]
   450     by (auto simp add: list_all_iff set_enum_char)
   451 next
   452   fix P
   453   show "enum_ex (P :: char \<Rightarrow> bool) = (\<exists>x. P x)"
   454     unfolding enum_ex_char_def enum_chars[symmetric]
   455     by (auto simp add: list_ex_iff set_enum_char)
   456 next
   457   show "distinct (enum :: char list)"
   458     by (auto intro: inj_onI simp add: enum_char_def product_list_set distinct_map distinct_product enum_distinct)
   459 qed (auto simp add: set_enum_char)
   460 
   461 end
   462 
   463 instantiation option :: (enum) enum
   464 begin
   465 
   466 definition
   467   "enum = None # map Some enum"
   468 
   469 definition
   470   "enum_all P = (P None \<and> enum_all (%x. P (Some x)))"
   471 
   472 definition
   473   "enum_ex P = (P None \<or> enum_ex (%x. P (Some x)))"
   474 
   475 instance proof
   476   fix P
   477   show "enum_all (P :: 'a option \<Rightarrow> bool) = (\<forall>x. P x)"
   478     unfolding enum_all_option_def enum_all
   479     by (auto, case_tac x) auto
   480 next
   481   fix P
   482   show "enum_ex (P :: 'a option \<Rightarrow> bool) = (\<exists>x. P x)"
   483     unfolding enum_ex_option_def enum_ex
   484     by (auto, case_tac x) auto
   485 qed (auto simp add: enum_UNIV enum_option_def, rule option.exhaust, auto intro: simp add: distinct_map enum_distinct)
   486 end
   487 
   488 instantiation set :: (enum) enum
   489 begin
   490 
   491 definition
   492   "enum = map set (sublists enum)"
   493 
   494 definition
   495   "enum_all P \<longleftrightarrow> (\<forall>A\<in>set enum. P (A::'a set))"
   496 
   497 definition
   498   "enum_ex P \<longleftrightarrow> (\<exists>A\<in>set enum. P (A::'a set))"
   499 
   500 instance proof
   501 qed (simp_all add: enum_set_def enum_all_set_def enum_ex_set_def sublists_powset distinct_set_sublists
   502   enum_distinct enum_UNIV)
   503 
   504 end
   505 
   506 
   507 subsection {* Small finite types *}
   508 
   509 text {* We define small finite types for the use in Quickcheck *}
   510 
   511 datatype finite_1 = a\<^isub>1
   512 
   513 notation (output) a\<^isub>1  ("a\<^isub>1")
   514 
   515 instantiation finite_1 :: enum
   516 begin
   517 
   518 definition
   519   "enum = [a\<^isub>1]"
   520 
   521 definition
   522   "enum_all P = P a\<^isub>1"
   523 
   524 definition
   525   "enum_ex P = P a\<^isub>1"
   526 
   527 instance proof
   528   fix P
   529   show "enum_all (P :: finite_1 \<Rightarrow> bool) = (\<forall>x. P x)"
   530     unfolding enum_all_finite_1_def
   531     by (auto, case_tac x) auto
   532 next
   533   fix P
   534   show "enum_ex (P :: finite_1 \<Rightarrow> bool) = (\<exists>x. P x)"
   535     unfolding enum_ex_finite_1_def
   536     by (auto, case_tac x) auto
   537 qed (auto simp add: enum_finite_1_def intro: finite_1.exhaust)
   538 
   539 end
   540 
   541 instantiation finite_1 :: linorder
   542 begin
   543 
   544 definition less_eq_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
   545 where
   546   "less_eq_finite_1 x y = True"
   547 
   548 definition less_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
   549 where
   550   "less_finite_1 x y = False"
   551 
   552 instance
   553 apply (intro_classes)
   554 apply (auto simp add: less_finite_1_def less_eq_finite_1_def)
   555 apply (metis finite_1.exhaust)
   556 done
   557 
   558 end
   559 
   560 hide_const (open) a\<^isub>1
   561 
   562 datatype finite_2 = a\<^isub>1 | a\<^isub>2
   563 
   564 notation (output) a\<^isub>1  ("a\<^isub>1")
   565 notation (output) a\<^isub>2  ("a\<^isub>2")
   566 
   567 instantiation finite_2 :: enum
   568 begin
   569 
   570 definition
   571   "enum = [a\<^isub>1, a\<^isub>2]"
   572 
   573 definition
   574   "enum_all P = (P a\<^isub>1 \<and> P a\<^isub>2)"
   575 
   576 definition
   577   "enum_ex P = (P a\<^isub>1 \<or> P a\<^isub>2)"
   578 
   579 instance proof
   580   fix P
   581   show "enum_all (P :: finite_2 \<Rightarrow> bool) = (\<forall>x. P x)"
   582     unfolding enum_all_finite_2_def
   583     by (auto, case_tac x) auto
   584 next
   585   fix P
   586   show "enum_ex (P :: finite_2 \<Rightarrow> bool) = (\<exists>x. P x)"
   587     unfolding enum_ex_finite_2_def
   588     by (auto, case_tac x) auto
   589 qed (auto simp add: enum_finite_2_def intro: finite_2.exhaust)
   590 
   591 end
   592 
   593 instantiation finite_2 :: linorder
   594 begin
   595 
   596 definition less_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
   597 where
   598   "less_finite_2 x y = ((x = a\<^isub>1) & (y = a\<^isub>2))"
   599 
   600 definition less_eq_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
   601 where
   602   "less_eq_finite_2 x y = ((x = y) \<or> (x < y))"
   603 
   604 
   605 instance
   606 apply (intro_classes)
   607 apply (auto simp add: less_finite_2_def less_eq_finite_2_def)
   608 apply (metis finite_2.distinct finite_2.nchotomy)+
   609 done
   610 
   611 end
   612 
   613 hide_const (open) a\<^isub>1 a\<^isub>2
   614 
   615 
   616 datatype finite_3 = a\<^isub>1 | a\<^isub>2 | a\<^isub>3
   617 
   618 notation (output) a\<^isub>1  ("a\<^isub>1")
   619 notation (output) a\<^isub>2  ("a\<^isub>2")
   620 notation (output) a\<^isub>3  ("a\<^isub>3")
   621 
   622 instantiation finite_3 :: enum
   623 begin
   624 
   625 definition
   626   "enum = [a\<^isub>1, a\<^isub>2, a\<^isub>3]"
   627 
   628 definition
   629   "enum_all P = (P a\<^isub>1 \<and> P a\<^isub>2 \<and> P a\<^isub>3)"
   630 
   631 definition
   632   "enum_ex P = (P a\<^isub>1 \<or> P a\<^isub>2 \<or> P a\<^isub>3)"
   633 
   634 instance proof
   635   fix P
   636   show "enum_all (P :: finite_3 \<Rightarrow> bool) = (\<forall>x. P x)"
   637     unfolding enum_all_finite_3_def
   638     by (auto, case_tac x) auto
   639 next
   640   fix P
   641   show "enum_ex (P :: finite_3 \<Rightarrow> bool) = (\<exists>x. P x)"
   642     unfolding enum_ex_finite_3_def
   643     by (auto, case_tac x) auto
   644 qed (auto simp add: enum_finite_3_def intro: finite_3.exhaust)
   645 
   646 end
   647 
   648 instantiation finite_3 :: linorder
   649 begin
   650 
   651 definition less_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
   652 where
   653   "less_finite_3 x y = (case x of a\<^isub>1 => (y \<noteq> a\<^isub>1)
   654      | a\<^isub>2 => (y = a\<^isub>3)| a\<^isub>3 => False)"
   655 
   656 definition less_eq_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
   657 where
   658   "less_eq_finite_3 x y = ((x = y) \<or> (x < y))"
   659 
   660 
   661 instance proof (intro_classes)
   662 qed (auto simp add: less_finite_3_def less_eq_finite_3_def split: finite_3.split_asm)
   663 
   664 end
   665 
   666 hide_const (open) a\<^isub>1 a\<^isub>2 a\<^isub>3
   667 
   668 
   669 datatype finite_4 = a\<^isub>1 | a\<^isub>2 | a\<^isub>3 | a\<^isub>4
   670 
   671 notation (output) a\<^isub>1  ("a\<^isub>1")
   672 notation (output) a\<^isub>2  ("a\<^isub>2")
   673 notation (output) a\<^isub>3  ("a\<^isub>3")
   674 notation (output) a\<^isub>4  ("a\<^isub>4")
   675 
   676 instantiation finite_4 :: enum
   677 begin
   678 
   679 definition
   680   "enum = [a\<^isub>1, a\<^isub>2, a\<^isub>3, a\<^isub>4]"
   681 
   682 definition
   683   "enum_all P = (P a\<^isub>1 \<and> P a\<^isub>2 \<and> P a\<^isub>3 \<and> P a\<^isub>4)"
   684 
   685 definition
   686   "enum_ex P = (P a\<^isub>1 \<or> P a\<^isub>2 \<or> P a\<^isub>3 \<or> P a\<^isub>4)"
   687 
   688 instance proof
   689   fix P
   690   show "enum_all (P :: finite_4 \<Rightarrow> bool) = (\<forall>x. P x)"
   691     unfolding enum_all_finite_4_def
   692     by (auto, case_tac x) auto
   693 next
   694   fix P
   695   show "enum_ex (P :: finite_4 \<Rightarrow> bool) = (\<exists>x. P x)"
   696     unfolding enum_ex_finite_4_def
   697     by (auto, case_tac x) auto
   698 qed (auto simp add: enum_finite_4_def intro: finite_4.exhaust)
   699 
   700 end
   701 
   702 hide_const (open) a\<^isub>1 a\<^isub>2 a\<^isub>3 a\<^isub>4
   703 
   704 
   705 datatype finite_5 = a\<^isub>1 | a\<^isub>2 | a\<^isub>3 | a\<^isub>4 | a\<^isub>5
   706 
   707 notation (output) a\<^isub>1  ("a\<^isub>1")
   708 notation (output) a\<^isub>2  ("a\<^isub>2")
   709 notation (output) a\<^isub>3  ("a\<^isub>3")
   710 notation (output) a\<^isub>4  ("a\<^isub>4")
   711 notation (output) a\<^isub>5  ("a\<^isub>5")
   712 
   713 instantiation finite_5 :: enum
   714 begin
   715 
   716 definition
   717   "enum = [a\<^isub>1, a\<^isub>2, a\<^isub>3, a\<^isub>4, a\<^isub>5]"
   718 
   719 definition
   720   "enum_all P = (P a\<^isub>1 \<and> P a\<^isub>2 \<and> P a\<^isub>3 \<and> P a\<^isub>4 \<and> P a\<^isub>5)"
   721 
   722 definition
   723   "enum_ex P = (P a\<^isub>1 \<or> P a\<^isub>2 \<or> P a\<^isub>3 \<or> P a\<^isub>4 \<or> P a\<^isub>5)"
   724 
   725 instance proof
   726   fix P
   727   show "enum_all (P :: finite_5 \<Rightarrow> bool) = (\<forall>x. P x)"
   728     unfolding enum_all_finite_5_def
   729     by (auto, case_tac x) auto
   730 next
   731   fix P
   732   show "enum_ex (P :: finite_5 \<Rightarrow> bool) = (\<exists>x. P x)"
   733     unfolding enum_ex_finite_5_def
   734     by (auto, case_tac x) auto
   735 qed (auto simp add: enum_finite_5_def intro: finite_5.exhaust)
   736 
   737 end
   738 
   739 hide_const (open) a\<^isub>1 a\<^isub>2 a\<^isub>3 a\<^isub>4 a\<^isub>5
   740 
   741 
   742 subsection {* Closing up *}
   743 
   744 hide_type (open) finite_1 finite_2 finite_3 finite_4 finite_5
   745 hide_const (open) enum enum_all enum_ex all_n_lists ex_n_lists ntrancl
   746 
   747 end
   748