src/HOL/Library/Float.thy
author Andreas Lochbihler
Wed Feb 27 10:33:30 2013 +0100 (2013-02-27)
changeset 51288 be7e9a675ec9
parent 49834 b27bbb021df1
child 51375 d9e62d9c98de
permissions -rw-r--r--
add wellorder instance for Numeral_Type (suggested by Jesus Aransay)
     1 (*  Title:      HOL/Library/Float.thy
     2     Author:     Johannes Hölzl, Fabian Immler
     3     Copyright   2012  TU München
     4 *)
     5 
     6 header {* Floating-Point Numbers *}
     7 
     8 theory Float
     9 imports Complex_Main "~~/src/HOL/Library/Lattice_Algebras"
    10 begin
    11 
    12 definition "float = {m * 2 powr e | (m :: int) (e :: int). True}"
    13 
    14 typedef float = float
    15   morphisms real_of_float float_of
    16   unfolding float_def by auto
    17 
    18 defs (overloaded)
    19   real_of_float_def[code_unfold]: "real \<equiv> real_of_float"
    20 
    21 lemma type_definition_float': "type_definition real float_of float"
    22   using type_definition_float unfolding real_of_float_def .
    23 
    24 setup_lifting (no_code) type_definition_float'
    25 
    26 lemmas float_of_inject[simp]
    27 
    28 declare [[coercion "real :: float \<Rightarrow> real"]]
    29 
    30 lemma real_of_float_eq:
    31   fixes f1 f2 :: float shows "f1 = f2 \<longleftrightarrow> real f1 = real f2"
    32   unfolding real_of_float_def real_of_float_inject ..
    33 
    34 lemma float_of_real[simp]: "float_of (real x) = x"
    35   unfolding real_of_float_def by (rule real_of_float_inverse)
    36 
    37 lemma real_float[simp]: "x \<in> float \<Longrightarrow> real (float_of x) = x"
    38   unfolding real_of_float_def by (rule float_of_inverse)
    39 
    40 subsection {* Real operations preserving the representation as floating point number *}
    41 
    42 lemma floatI: fixes m e :: int shows "m * 2 powr e = x \<Longrightarrow> x \<in> float"
    43   by (auto simp: float_def)
    44 
    45 lemma zero_float[simp]: "0 \<in> float" by (auto simp: float_def)
    46 lemma one_float[simp]: "1 \<in> float" by (intro floatI[of 1 0]) simp
    47 lemma numeral_float[simp]: "numeral i \<in> float" by (intro floatI[of "numeral i" 0]) simp  
    48 lemma neg_numeral_float[simp]: "neg_numeral i \<in> float" by (intro floatI[of "neg_numeral i" 0]) simp
    49 lemma real_of_int_float[simp]: "real (x :: int) \<in> float" by (intro floatI[of x 0]) simp
    50 lemma real_of_nat_float[simp]: "real (x :: nat) \<in> float" by (intro floatI[of x 0]) simp
    51 lemma two_powr_int_float[simp]: "2 powr (real (i::int)) \<in> float" by (intro floatI[of 1 i]) simp
    52 lemma two_powr_nat_float[simp]: "2 powr (real (i::nat)) \<in> float" by (intro floatI[of 1 i]) simp
    53 lemma two_powr_minus_int_float[simp]: "2 powr - (real (i::int)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    54 lemma two_powr_minus_nat_float[simp]: "2 powr - (real (i::nat)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    55 lemma two_powr_numeral_float[simp]: "2 powr numeral i \<in> float" by (intro floatI[of 1 "numeral i"]) simp
    56 lemma two_powr_neg_numeral_float[simp]: "2 powr neg_numeral i \<in> float" by (intro floatI[of 1 "neg_numeral i"]) simp
    57 lemma two_pow_float[simp]: "2 ^ n \<in> float" by (intro floatI[of 1 "n"]) (simp add: powr_realpow)
    58 lemma real_of_float_float[simp]: "real (f::float) \<in> float" by (cases f) simp
    59 
    60 lemma plus_float[simp]: "r \<in> float \<Longrightarrow> p \<in> float \<Longrightarrow> r + p \<in> float"
    61   unfolding float_def
    62 proof (safe, simp)
    63   fix e1 m1 e2 m2 :: int
    64   { fix e1 m1 e2 m2 :: int assume "e1 \<le> e2"
    65     then have "m1 * 2 powr e1 + m2 * 2 powr e2 = (m1 + m2 * 2 ^ nat (e2 - e1)) * 2 powr e1"
    66       by (simp add: powr_realpow[symmetric] powr_divide2[symmetric] field_simps)
    67     then have "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    68       by blast }
    69   note * = this
    70   show "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    71   proof (cases e1 e2 rule: linorder_le_cases)
    72     assume "e2 \<le> e1" from *[OF this, of m2 m1] show ?thesis by (simp add: ac_simps)
    73   qed (rule *)
    74 qed
    75 
    76 lemma uminus_float[simp]: "x \<in> float \<Longrightarrow> -x \<in> float"
    77   apply (auto simp: float_def)
    78   apply (rule_tac x="-x" in exI)
    79   apply (rule_tac x="xa" in exI)
    80   apply (simp add: field_simps)
    81   done
    82 
    83 lemma times_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x * y \<in> float"
    84   apply (auto simp: float_def)
    85   apply (rule_tac x="x * xa" in exI)
    86   apply (rule_tac x="xb + xc" in exI)
    87   apply (simp add: powr_add)
    88   done
    89 
    90 lemma minus_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x - y \<in> float"
    91   unfolding ab_diff_minus by (intro uminus_float plus_float)
    92 
    93 lemma abs_float[simp]: "x \<in> float \<Longrightarrow> abs x \<in> float"
    94   by (cases x rule: linorder_cases[of 0]) auto
    95 
    96 lemma sgn_of_float[simp]: "x \<in> float \<Longrightarrow> sgn x \<in> float"
    97   by (cases x rule: linorder_cases[of 0]) (auto intro!: uminus_float)
    98 
    99 lemma div_power_2_float[simp]: "x \<in> float \<Longrightarrow> x / 2^d \<in> float"
   100   apply (auto simp add: float_def)
   101   apply (rule_tac x="x" in exI)
   102   apply (rule_tac x="xa - d" in exI)
   103   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   104   done
   105 
   106 lemma div_power_2_int_float[simp]: "x \<in> float \<Longrightarrow> x / (2::int)^d \<in> float"
   107   apply (auto simp add: float_def)
   108   apply (rule_tac x="x" in exI)
   109   apply (rule_tac x="xa - d" in exI)
   110   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   111   done
   112 
   113 lemma div_numeral_Bit0_float[simp]:
   114   assumes x: "x / numeral n \<in> float" shows "x / (numeral (Num.Bit0 n)) \<in> float"
   115 proof -
   116   have "(x / numeral n) / 2^1 \<in> float"
   117     by (intro x div_power_2_float)
   118   also have "(x / numeral n) / 2^1 = x / (numeral (Num.Bit0 n))"
   119     by (induct n) auto
   120   finally show ?thesis .
   121 qed
   122 
   123 lemma div_neg_numeral_Bit0_float[simp]:
   124   assumes x: "x / numeral n \<in> float" shows "x / (neg_numeral (Num.Bit0 n)) \<in> float"
   125 proof -
   126   have "- (x / numeral (Num.Bit0 n)) \<in> float" using x by simp
   127   also have "- (x / numeral (Num.Bit0 n)) = x / neg_numeral (Num.Bit0 n)"
   128     unfolding neg_numeral_def by (simp del: minus_numeral)
   129   finally show ?thesis .
   130 qed
   131 
   132 lift_definition Float :: "int \<Rightarrow> int \<Rightarrow> float" is "\<lambda>(m::int) (e::int). m * 2 powr e" by simp
   133 declare Float.rep_eq[simp]
   134 
   135 lemma compute_real_of_float[code]:
   136   "real_of_float (Float m e) = (if e \<ge> 0 then m * 2 ^ nat e else m / 2 ^ (nat (-e)))"
   137 by (simp add: real_of_float_def[symmetric] powr_int)
   138 
   139 code_datatype Float
   140 
   141 subsection {* Arithmetic operations on floating point numbers *}
   142 
   143 instantiation float :: "{ring_1, linorder, linordered_ring, linordered_idom, numeral, equal}"
   144 begin
   145 
   146 lift_definition zero_float :: float is 0 by simp
   147 declare zero_float.rep_eq[simp]
   148 lift_definition one_float :: float is 1 by simp
   149 declare one_float.rep_eq[simp]
   150 lift_definition plus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op +" by simp
   151 declare plus_float.rep_eq[simp]
   152 lift_definition times_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op *" by simp
   153 declare times_float.rep_eq[simp]
   154 lift_definition minus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op -" by simp
   155 declare minus_float.rep_eq[simp]
   156 lift_definition uminus_float :: "float \<Rightarrow> float" is "uminus" by simp
   157 declare uminus_float.rep_eq[simp]
   158 
   159 lift_definition abs_float :: "float \<Rightarrow> float" is abs by simp
   160 declare abs_float.rep_eq[simp]
   161 lift_definition sgn_float :: "float \<Rightarrow> float" is sgn by simp
   162 declare sgn_float.rep_eq[simp]
   163 
   164 lift_definition equal_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op = :: real \<Rightarrow> real \<Rightarrow> bool" ..
   165 
   166 lift_definition less_eq_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op \<le>" ..
   167 declare less_eq_float.rep_eq[simp]
   168 lift_definition less_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op <" ..
   169 declare less_float.rep_eq[simp]
   170 
   171 instance
   172   proof qed (transfer, fastforce simp add: field_simps intro: mult_left_mono mult_right_mono)+
   173 end
   174 
   175 lemma real_of_float_power[simp]: fixes f::float shows "real (f^n) = real f^n"
   176   by (induct n) simp_all
   177 
   178 lemma fixes x y::float 
   179   shows real_of_float_min: "real (min x y) = min (real x) (real y)"
   180     and real_of_float_max: "real (max x y) = max (real x) (real y)"
   181   by (simp_all add: min_def max_def)
   182 
   183 instance float :: dense_linorder
   184 proof
   185   fix a b :: float
   186   show "\<exists>c. a < c"
   187     apply (intro exI[of _ "a + 1"])
   188     apply transfer
   189     apply simp
   190     done
   191   show "\<exists>c. c < a"
   192     apply (intro exI[of _ "a - 1"])
   193     apply transfer
   194     apply simp
   195     done
   196   assume "a < b"
   197   then show "\<exists>c. a < c \<and> c < b"
   198     apply (intro exI[of _ "(a + b) * Float 1 -1"])
   199     apply transfer
   200     apply (simp add: powr_neg_numeral) 
   201     done
   202 qed
   203 
   204 instantiation float :: lattice_ab_group_add
   205 begin
   206 
   207 definition inf_float::"float\<Rightarrow>float\<Rightarrow>float"
   208 where "inf_float a b = min a b"
   209 
   210 definition sup_float::"float\<Rightarrow>float\<Rightarrow>float"
   211 where "sup_float a b = max a b"
   212 
   213 instance
   214   by default
   215      (transfer, simp_all add: inf_float_def sup_float_def real_of_float_min real_of_float_max)+
   216 end
   217 
   218 lemma float_numeral[simp]: "real (numeral x :: float) = numeral x"
   219   apply (induct x)
   220   apply simp
   221   apply (simp_all only: numeral_Bit0 numeral_Bit1 real_of_float_eq real_float
   222                   plus_float.rep_eq one_float.rep_eq plus_float numeral_float one_float)
   223   done
   224 
   225 lemma transfer_numeral [transfer_rule]: 
   226   "fun_rel (op =) cr_float (numeral :: _ \<Rightarrow> real) (numeral :: _ \<Rightarrow> float)"
   227   unfolding fun_rel_def cr_float_def by simp
   228 
   229 lemma float_neg_numeral[simp]: "real (neg_numeral x :: float) = neg_numeral x"
   230   by (simp add: minus_numeral[symmetric] del: minus_numeral)
   231 
   232 lemma transfer_neg_numeral [transfer_rule]: 
   233   "fun_rel (op =) cr_float (neg_numeral :: _ \<Rightarrow> real) (neg_numeral :: _ \<Rightarrow> float)"
   234   unfolding fun_rel_def cr_float_def by simp
   235 
   236 lemma
   237   shows float_of_numeral[simp]: "numeral k = float_of (numeral k)"
   238     and float_of_neg_numeral[simp]: "neg_numeral k = float_of (neg_numeral k)"
   239   unfolding real_of_float_eq by simp_all
   240 
   241 subsection {* Represent floats as unique mantissa and exponent *}
   242 
   243 lemma int_induct_abs[case_names less]:
   244   fixes j :: int
   245   assumes H: "\<And>n. (\<And>i. \<bar>i\<bar> < \<bar>n\<bar> \<Longrightarrow> P i) \<Longrightarrow> P n"
   246   shows "P j"
   247 proof (induct "nat \<bar>j\<bar>" arbitrary: j rule: less_induct)
   248   case less show ?case by (rule H[OF less]) simp
   249 qed
   250 
   251 lemma int_cancel_factors:
   252   fixes n :: int assumes "1 < r" shows "n = 0 \<or> (\<exists>k i. n = k * r ^ i \<and> \<not> r dvd k)"
   253 proof (induct n rule: int_induct_abs)
   254   case (less n)
   255   { fix m assume n: "n \<noteq> 0" "n = m * r"
   256     then have "\<bar>m \<bar> < \<bar>n\<bar>"
   257       by (metis abs_dvd_iff abs_ge_self assms comm_semiring_1_class.normalizing_semiring_rules(7)
   258                 dvd_imp_le_int dvd_refl dvd_triv_right linorder_neq_iff linorder_not_le
   259                 mult_eq_0_iff zdvd_mult_cancel1)
   260     from less[OF this] n have "\<exists>k i. n = k * r ^ Suc i \<and> \<not> r dvd k" by auto }
   261   then show ?case
   262     by (metis comm_semiring_1_class.normalizing_semiring_rules(12,7) dvdE power_0)
   263 qed
   264 
   265 lemma mult_powr_eq_mult_powr_iff_asym:
   266   fixes m1 m2 e1 e2 :: int
   267   assumes m1: "\<not> 2 dvd m1" and "e1 \<le> e2"
   268   shows "m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   269 proof
   270   have "m1 \<noteq> 0" using m1 unfolding dvd_def by auto
   271   assume eq: "m1 * 2 powr e1 = m2 * 2 powr e2"
   272   with `e1 \<le> e2` have "m1 = m2 * 2 powr nat (e2 - e1)"
   273     by (simp add: powr_divide2[symmetric] field_simps)
   274   also have "\<dots> = m2 * 2^nat (e2 - e1)"
   275     by (simp add: powr_realpow)
   276   finally have m1_eq: "m1 = m2 * 2^nat (e2 - e1)"
   277     unfolding real_of_int_inject .
   278   with m1 have "m1 = m2"
   279     by (cases "nat (e2 - e1)") (auto simp add: dvd_def)
   280   then show "m1 = m2 \<and> e1 = e2"
   281     using eq `m1 \<noteq> 0` by (simp add: powr_inj)
   282 qed simp
   283 
   284 lemma mult_powr_eq_mult_powr_iff:
   285   fixes m1 m2 e1 e2 :: int
   286   shows "\<not> 2 dvd m1 \<Longrightarrow> \<not> 2 dvd m2 \<Longrightarrow> m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   287   using mult_powr_eq_mult_powr_iff_asym[of m1 e1 e2 m2]
   288   using mult_powr_eq_mult_powr_iff_asym[of m2 e2 e1 m1]
   289   by (cases e1 e2 rule: linorder_le_cases) auto
   290 
   291 lemma floatE_normed:
   292   assumes x: "x \<in> float"
   293   obtains (zero) "x = 0"
   294    | (powr) m e :: int where "x = m * 2 powr e" "\<not> 2 dvd m" "x \<noteq> 0"
   295 proof atomize_elim
   296   { assume "x \<noteq> 0"
   297     from x obtain m e :: int where x: "x = m * 2 powr e" by (auto simp: float_def)
   298     with `x \<noteq> 0` int_cancel_factors[of 2 m] obtain k i where "m = k * 2 ^ i" "\<not> 2 dvd k"
   299       by auto
   300     with `\<not> 2 dvd k` x have "\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m"
   301       by (rule_tac exI[of _ "k"], rule_tac exI[of _ "e + int i"])
   302          (simp add: powr_add powr_realpow) }
   303   then show "x = 0 \<or> (\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m \<and> x \<noteq> 0)"
   304     by blast
   305 qed
   306 
   307 lemma float_normed_cases:
   308   fixes f :: float
   309   obtains (zero) "f = 0"
   310    | (powr) m e :: int where "real f = m * 2 powr e" "\<not> 2 dvd m" "f \<noteq> 0"
   311 proof (atomize_elim, induct f)
   312   case (float_of y) then show ?case
   313     by (cases rule: floatE_normed) (auto simp: zero_float_def)
   314 qed
   315 
   316 definition mantissa :: "float \<Rightarrow> int" where
   317   "mantissa f = fst (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   318    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   319 
   320 definition exponent :: "float \<Rightarrow> int" where
   321   "exponent f = snd (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   322    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   323 
   324 lemma 
   325   shows exponent_0[simp]: "exponent (float_of 0) = 0" (is ?E)
   326     and mantissa_0[simp]: "mantissa (float_of 0) = 0" (is ?M)
   327 proof -
   328   have "\<And>p::int \<times> int. fst p = 0 \<and> snd p = 0 \<longleftrightarrow> p = (0, 0)" by auto
   329   then show ?E ?M
   330     by (auto simp add: mantissa_def exponent_def zero_float_def)
   331 qed
   332 
   333 lemma
   334   shows mantissa_exponent: "real f = mantissa f * 2 powr exponent f" (is ?E)
   335     and mantissa_not_dvd: "f \<noteq> (float_of 0) \<Longrightarrow> \<not> 2 dvd mantissa f" (is "_ \<Longrightarrow> ?D")
   336 proof cases
   337   assume [simp]: "f \<noteq> (float_of 0)"
   338   have "f = mantissa f * 2 powr exponent f \<and> \<not> 2 dvd mantissa f"
   339   proof (cases f rule: float_normed_cases)
   340     case (powr m e)
   341     then have "\<exists>p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   342      \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p)"
   343       by auto
   344     then show ?thesis
   345       unfolding exponent_def mantissa_def
   346       by (rule someI2_ex) (simp add: zero_float_def)
   347   qed (simp add: zero_float_def)
   348   then show ?E ?D by auto
   349 qed simp
   350 
   351 lemma mantissa_noteq_0: "f \<noteq> float_of 0 \<Longrightarrow> mantissa f \<noteq> 0"
   352   using mantissa_not_dvd[of f] by auto
   353 
   354 lemma 
   355   fixes m e :: int
   356   defines "f \<equiv> float_of (m * 2 powr e)"
   357   assumes dvd: "\<not> 2 dvd m"
   358   shows mantissa_float: "mantissa f = m" (is "?M")
   359     and exponent_float: "m \<noteq> 0 \<Longrightarrow> exponent f = e" (is "_ \<Longrightarrow> ?E")
   360 proof cases
   361   assume "m = 0" with dvd show "mantissa f = m" by auto
   362 next
   363   assume "m \<noteq> 0"
   364   then have f_not_0: "f \<noteq> float_of 0" by (simp add: f_def)
   365   from mantissa_exponent[of f]
   366   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   367     by (auto simp add: f_def)
   368   then show "?M" "?E"
   369     using mantissa_not_dvd[OF f_not_0] dvd
   370     by (auto simp: mult_powr_eq_mult_powr_iff)
   371 qed
   372 
   373 subsection {* Compute arithmetic operations *}
   374 
   375 lemma Float_mantissa_exponent: "Float (mantissa f) (exponent f) = f"
   376   unfolding real_of_float_eq mantissa_exponent[of f] by simp
   377 
   378 lemma Float_cases[case_names Float, cases type: float]:
   379   fixes f :: float
   380   obtains (Float) m e :: int where "f = Float m e"
   381   using Float_mantissa_exponent[symmetric]
   382   by (atomize_elim) auto
   383 
   384 lemma denormalize_shift:
   385   assumes f_def: "f \<equiv> Float m e" and not_0: "f \<noteq> float_of 0"
   386   obtains i where "m = mantissa f * 2 ^ i" "e = exponent f - i"
   387 proof
   388   from mantissa_exponent[of f] f_def
   389   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   390     by simp
   391   then have eq: "m = mantissa f * 2 powr (exponent f - e)"
   392     by (simp add: powr_divide2[symmetric] field_simps)
   393   moreover
   394   have "e \<le> exponent f"
   395   proof (rule ccontr)
   396     assume "\<not> e \<le> exponent f"
   397     then have pos: "exponent f < e" by simp
   398     then have "2 powr (exponent f - e) = 2 powr - real (e - exponent f)"
   399       by simp
   400     also have "\<dots> = 1 / 2^nat (e - exponent f)"
   401       using pos by (simp add: powr_realpow[symmetric] powr_divide2[symmetric])
   402     finally have "m * 2^nat (e - exponent f) = real (mantissa f)"
   403       using eq by simp
   404     then have "mantissa f = m * 2^nat (e - exponent f)"
   405       unfolding real_of_int_inject by simp
   406     with `exponent f < e` have "2 dvd mantissa f"
   407       apply (intro dvdI[where k="m * 2^(nat (e-exponent f)) div 2"])
   408       apply (cases "nat (e - exponent f)")
   409       apply auto
   410       done
   411     then show False using mantissa_not_dvd[OF not_0] by simp
   412   qed
   413   ultimately have "real m = mantissa f * 2^nat (exponent f - e)"
   414     by (simp add: powr_realpow[symmetric])
   415   with `e \<le> exponent f`
   416   show "m = mantissa f * 2 ^ nat (exponent f - e)" "e = exponent f - nat (exponent f - e)"
   417     unfolding real_of_int_inject by auto
   418 qed
   419 
   420 lemma compute_float_zero[code_unfold, code]: "0 = Float 0 0"
   421   by transfer simp
   422 hide_fact (open) compute_float_zero
   423 
   424 lemma compute_float_one[code_unfold, code]: "1 = Float 1 0"
   425   by transfer simp
   426 hide_fact (open) compute_float_one
   427 
   428 definition normfloat :: "float \<Rightarrow> float" where
   429   [simp]: "normfloat x = x"
   430 
   431 lemma compute_normfloat[code]: "normfloat (Float m e) =
   432   (if m mod 2 = 0 \<and> m \<noteq> 0 then normfloat (Float (m div 2) (e + 1))
   433                            else if m = 0 then 0 else Float m e)"
   434   unfolding normfloat_def
   435   by transfer (auto simp add: powr_add zmod_eq_0_iff)
   436 hide_fact (open) compute_normfloat
   437 
   438 lemma compute_float_numeral[code_abbrev]: "Float (numeral k) 0 = numeral k"
   439   by transfer simp
   440 hide_fact (open) compute_float_numeral
   441 
   442 lemma compute_float_neg_numeral[code_abbrev]: "Float (neg_numeral k) 0 = neg_numeral k"
   443   by transfer simp
   444 hide_fact (open) compute_float_neg_numeral
   445 
   446 lemma compute_float_uminus[code]: "- Float m1 e1 = Float (- m1) e1"
   447   by transfer simp
   448 hide_fact (open) compute_float_uminus
   449 
   450 lemma compute_float_times[code]: "Float m1 e1 * Float m2 e2 = Float (m1 * m2) (e1 + e2)"
   451   by transfer (simp add: field_simps powr_add)
   452 hide_fact (open) compute_float_times
   453 
   454 lemma compute_float_plus[code]: "Float m1 e1 + Float m2 e2 =
   455   (if e1 \<le> e2 then Float (m1 + m2 * 2^nat (e2 - e1)) e1
   456               else Float (m2 + m1 * 2^nat (e1 - e2)) e2)"
   457   by transfer (simp add: field_simps powr_realpow[symmetric] powr_divide2[symmetric])
   458 hide_fact (open) compute_float_plus
   459 
   460 lemma compute_float_minus[code]: fixes f g::float shows "f - g = f + (-g)"
   461   by simp
   462 hide_fact (open) compute_float_minus
   463 
   464 lemma compute_float_sgn[code]: "sgn (Float m1 e1) = (if 0 < m1 then 1 else if m1 < 0 then -1 else 0)"
   465   by transfer (simp add: sgn_times)
   466 hide_fact (open) compute_float_sgn
   467 
   468 lift_definition is_float_pos :: "float \<Rightarrow> bool" is "op < 0 :: real \<Rightarrow> bool" ..
   469 
   470 lemma compute_is_float_pos[code]: "is_float_pos (Float m e) \<longleftrightarrow> 0 < m"
   471   by transfer (auto simp add: zero_less_mult_iff not_le[symmetric, of _ 0])
   472 hide_fact (open) compute_is_float_pos
   473 
   474 lemma compute_float_less[code]: "a < b \<longleftrightarrow> is_float_pos (b - a)"
   475   by transfer (simp add: field_simps)
   476 hide_fact (open) compute_float_less
   477 
   478 lift_definition is_float_nonneg :: "float \<Rightarrow> bool" is "op \<le> 0 :: real \<Rightarrow> bool" ..
   479 
   480 lemma compute_is_float_nonneg[code]: "is_float_nonneg (Float m e) \<longleftrightarrow> 0 \<le> m"
   481   by transfer (auto simp add: zero_le_mult_iff not_less[symmetric, of _ 0])
   482 hide_fact (open) compute_is_float_nonneg
   483 
   484 lemma compute_float_le[code]: "a \<le> b \<longleftrightarrow> is_float_nonneg (b - a)"
   485   by transfer (simp add: field_simps)
   486 hide_fact (open) compute_float_le
   487 
   488 lift_definition is_float_zero :: "float \<Rightarrow> bool"  is "op = 0 :: real \<Rightarrow> bool" by simp
   489 
   490 lemma compute_is_float_zero[code]: "is_float_zero (Float m e) \<longleftrightarrow> 0 = m"
   491   by transfer (auto simp add: is_float_zero_def)
   492 hide_fact (open) compute_is_float_zero
   493 
   494 lemma compute_float_abs[code]: "abs (Float m e) = Float (abs m) e"
   495   by transfer (simp add: abs_mult)
   496 hide_fact (open) compute_float_abs
   497 
   498 lemma compute_float_eq[code]: "equal_class.equal f g = is_float_zero (f - g)"
   499   by transfer simp
   500 hide_fact (open) compute_float_eq
   501 
   502 subsection {* Rounding Real numbers *}
   503 
   504 definition round_down :: "int \<Rightarrow> real \<Rightarrow> real" where
   505   "round_down prec x = floor (x * 2 powr prec) * 2 powr -prec"
   506 
   507 definition round_up :: "int \<Rightarrow> real \<Rightarrow> real" where
   508   "round_up prec x = ceiling (x * 2 powr prec) * 2 powr -prec"
   509 
   510 lemma round_down_float[simp]: "round_down prec x \<in> float"
   511   unfolding round_down_def
   512   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   513 
   514 lemma round_up_float[simp]: "round_up prec x \<in> float"
   515   unfolding round_up_def
   516   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   517 
   518 lemma round_up: "x \<le> round_up prec x"
   519   by (simp add: powr_minus_divide le_divide_eq round_up_def)
   520 
   521 lemma round_down: "round_down prec x \<le> x"
   522   by (simp add: powr_minus_divide divide_le_eq round_down_def)
   523 
   524 lemma round_up_0[simp]: "round_up p 0 = 0"
   525   unfolding round_up_def by simp
   526 
   527 lemma round_down_0[simp]: "round_down p 0 = 0"
   528   unfolding round_down_def by simp
   529 
   530 lemma round_up_diff_round_down:
   531   "round_up prec x - round_down prec x \<le> 2 powr -prec"
   532 proof -
   533   have "round_up prec x - round_down prec x =
   534     (ceiling (x * 2 powr prec) - floor (x * 2 powr prec)) * 2 powr -prec"
   535     by (simp add: round_up_def round_down_def field_simps)
   536   also have "\<dots> \<le> 1 * 2 powr -prec"
   537     by (rule mult_mono)
   538        (auto simp del: real_of_int_diff
   539              simp: real_of_int_diff[symmetric] real_of_int_le_one_cancel_iff ceiling_diff_floor_le_1)
   540   finally show ?thesis by simp
   541 qed
   542 
   543 lemma round_down_shift: "round_down p (x * 2 powr k) = 2 powr k * round_down (p + k) x"
   544   unfolding round_down_def
   545   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   546     (simp add: powr_add[symmetric])
   547 
   548 lemma round_up_shift: "round_up p (x * 2 powr k) = 2 powr k * round_up (p + k) x"
   549   unfolding round_up_def
   550   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   551     (simp add: powr_add[symmetric])
   552 
   553 subsection {* Rounding Floats *}
   554 
   555 lift_definition float_up :: "int \<Rightarrow> float \<Rightarrow> float" is round_up by simp
   556 declare float_up.rep_eq[simp]
   557 
   558 lemma float_up_correct:
   559   shows "real (float_up e f) - real f \<in> {0..2 powr -e}"
   560 unfolding atLeastAtMost_iff
   561 proof
   562   have "round_up e f - f \<le> round_up e f - round_down e f" using round_down by simp
   563   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   564   finally show "real (float_up e f) - real f \<le> 2 powr real (- e)"
   565     by simp
   566 qed (simp add: algebra_simps round_up)
   567 
   568 lift_definition float_down :: "int \<Rightarrow> float \<Rightarrow> float" is round_down by simp
   569 declare float_down.rep_eq[simp]
   570 
   571 lemma float_down_correct:
   572   shows "real f - real (float_down e f) \<in> {0..2 powr -e}"
   573 unfolding atLeastAtMost_iff
   574 proof
   575   have "f - round_down e f \<le> round_up e f - round_down e f" using round_up by simp
   576   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   577   finally show "real f - real (float_down e f) \<le> 2 powr real (- e)"
   578     by simp
   579 qed (simp add: algebra_simps round_down)
   580 
   581 lemma compute_float_down[code]:
   582   "float_down p (Float m e) =
   583     (if p + e < 0 then Float (m div 2^nat (-(p + e))) (-p) else Float m e)"
   584 proof cases
   585   assume "p + e < 0"
   586   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   587     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   588   also have "... = 1 / 2 powr p / 2 powr e"
   589     unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   590   finally show ?thesis
   591     using `p + e < 0`
   592     by transfer (simp add: ac_simps round_down_def floor_divide_eq_div[symmetric])
   593 next
   594   assume "\<not> p + e < 0"
   595   then have r: "real e + real p = real (nat (e + p))" by simp
   596   have r: "\<lfloor>(m * 2 powr e) * 2 powr real p\<rfloor> = (m * 2 powr e) * 2 powr real p"
   597     by (auto intro: exI[where x="m*2^nat (e+p)"]
   598              simp add: ac_simps powr_add[symmetric] r powr_realpow)
   599   with `\<not> p + e < 0` show ?thesis
   600     by transfer
   601        (auto simp add: round_down_def field_simps powr_add powr_minus inverse_eq_divide)
   602 qed
   603 hide_fact (open) compute_float_down
   604 
   605 lemma ceil_divide_floor_conv:
   606 assumes "b \<noteq> 0"
   607 shows "\<lceil>real a / real b\<rceil> = (if b dvd a then a div b else \<lfloor>real a / real b\<rfloor> + 1)"
   608 proof cases
   609   assume "\<not> b dvd a"
   610   hence "a mod b \<noteq> 0" by auto
   611   hence ne: "real (a mod b) / real b \<noteq> 0" using `b \<noteq> 0` by auto
   612   have "\<lceil>real a / real b\<rceil> = \<lfloor>real a / real b\<rfloor> + 1"
   613   apply (rule ceiling_eq) apply (auto simp: floor_divide_eq_div[symmetric])
   614   proof -
   615     have "real \<lfloor>real a / real b\<rfloor> \<le> real a / real b" by simp
   616     moreover have "real \<lfloor>real a / real b\<rfloor> \<noteq> real a / real b"
   617     apply (subst (2) real_of_int_div_aux) unfolding floor_divide_eq_div using ne `b \<noteq> 0` by auto
   618     ultimately show "real \<lfloor>real a / real b\<rfloor> < real a / real b" by arith
   619   qed
   620   thus ?thesis using `\<not> b dvd a` by simp
   621 qed (simp add: ceiling_def real_of_int_minus[symmetric] divide_minus_left[symmetric]
   622   floor_divide_eq_div dvd_neg_div del: divide_minus_left real_of_int_minus)
   623 
   624 lemma compute_float_up[code]:
   625   "float_up p (Float m e) =
   626     (let P = 2^nat (-(p + e)); r = m mod P in
   627       if p + e < 0 then Float (m div P + (if r = 0 then 0 else 1)) (-p) else Float m e)"
   628 proof cases
   629   assume "p + e < 0"
   630   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   631     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   632   also have "... = 1 / 2 powr p / 2 powr e"
   633   unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   634   finally have twopow_rewrite:
   635     "real ((2::int) ^ nat (- (p + e))) = 1 / 2 powr real p / 2 powr real e" .
   636   with `p + e < 0` have powr_rewrite:
   637     "2 powr real e * 2 powr real p = 1 / real ((2::int) ^ nat (- (p + e)))"
   638     unfolding powr_divide2 by simp
   639   show ?thesis
   640   proof cases
   641     assume "2^nat (-(p + e)) dvd m"
   642     with `p + e < 0` twopow_rewrite show ?thesis
   643       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div dvd_eq_mod_eq_0)
   644   next
   645     assume ndvd: "\<not> 2 ^ nat (- (p + e)) dvd m"
   646     have one_div: "real m * (1 / real ((2::int) ^ nat (- (p + e)))) =
   647       real m / real ((2::int) ^ nat (- (p + e)))"
   648       by (simp add: field_simps)
   649     have "real \<lceil>real m * (2 powr real e * 2 powr real p)\<rceil> =
   650       real \<lfloor>real m * (2 powr real e * 2 powr real p)\<rfloor> + 1"
   651       using ndvd unfolding powr_rewrite one_div
   652       by (subst ceil_divide_floor_conv) (auto simp: field_simps)
   653     thus ?thesis using `p + e < 0` twopow_rewrite
   654       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div[symmetric])
   655   qed
   656 next
   657   assume "\<not> p + e < 0"
   658   then have r1: "real e + real p = real (nat (e + p))" by simp
   659   have r: "\<lceil>(m * 2 powr e) * 2 powr real p\<rceil> = (m * 2 powr e) * 2 powr real p"
   660     by (auto simp add: ac_simps powr_add[symmetric] r1 powr_realpow
   661       intro: exI[where x="m*2^nat (e+p)"])
   662   then show ?thesis using `\<not> p + e < 0`
   663     by transfer
   664        (simp add: round_up_def floor_divide_eq_div field_simps powr_add powr_minus inverse_eq_divide)
   665 qed
   666 hide_fact (open) compute_float_up
   667 
   668 lemmas real_of_ints =
   669   real_of_int_zero
   670   real_of_one
   671   real_of_int_add
   672   real_of_int_minus
   673   real_of_int_diff
   674   real_of_int_mult
   675   real_of_int_power
   676   real_numeral
   677 lemmas real_of_nats =
   678   real_of_nat_zero
   679   real_of_nat_one
   680   real_of_nat_1
   681   real_of_nat_add
   682   real_of_nat_mult
   683   real_of_nat_power
   684 
   685 lemmas int_of_reals = real_of_ints[symmetric]
   686 lemmas nat_of_reals = real_of_nats[symmetric]
   687 
   688 lemma two_real_int: "(2::real) = real (2::int)" by simp
   689 lemma two_real_nat: "(2::real) = real (2::nat)" by simp
   690 
   691 lemma mult_cong: "a = c ==> b = d ==> a*b = c*d" by simp
   692 
   693 subsection {* Compute bitlen of integers *}
   694 
   695 definition bitlen :: "int \<Rightarrow> int" where
   696   "bitlen a = (if a > 0 then \<lfloor>log 2 a\<rfloor> + 1 else 0)"
   697 
   698 lemma bitlen_nonneg: "0 \<le> bitlen x"
   699 proof -
   700   {
   701     assume "0 > x"
   702     have "-1 = log 2 (inverse 2)" by (subst log_inverse) simp_all
   703     also have "... < log 2 (-x)" using `0 > x` by auto
   704     finally have "-1 < log 2 (-x)" .
   705   } thus "0 \<le> bitlen x" unfolding bitlen_def by (auto intro!: add_nonneg_nonneg)
   706 qed
   707 
   708 lemma bitlen_bounds:
   709   assumes "x > 0"
   710   shows "2 ^ nat (bitlen x - 1) \<le> x \<and> x < 2 ^ nat (bitlen x)"
   711 proof
   712   have "(2::real) ^ nat \<lfloor>log 2 (real x)\<rfloor> = 2 powr real (floor (log 2 (real x)))"
   713     using powr_realpow[symmetric, of 2 "nat \<lfloor>log 2 (real x)\<rfloor>"] `x > 0`
   714     using real_nat_eq_real[of "floor (log 2 (real x))"]
   715     by simp
   716   also have "... \<le> 2 powr log 2 (real x)"
   717     by simp
   718   also have "... = real x"
   719     using `0 < x` by simp
   720   finally have "2 ^ nat \<lfloor>log 2 (real x)\<rfloor> \<le> real x" by simp
   721   thus "2 ^ nat (bitlen x - 1) \<le> x" using `x > 0`
   722     by (simp add: bitlen_def)
   723 next
   724   have "x \<le> 2 powr (log 2 x)" using `x > 0` by simp
   725   also have "... < 2 ^ nat (\<lfloor>log 2 (real x)\<rfloor> + 1)"
   726     apply (simp add: powr_realpow[symmetric])
   727     using `x > 0` by simp
   728   finally show "x < 2 ^ nat (bitlen x)" using `x > 0`
   729     by (simp add: bitlen_def ac_simps int_of_reals del: real_of_ints)
   730 qed
   731 
   732 lemma bitlen_pow2[simp]:
   733   assumes "b > 0"
   734   shows "bitlen (b * 2 ^ c) = bitlen b + c"
   735 proof -
   736   from assms have "b * 2 ^ c > 0" by (auto intro: mult_pos_pos)
   737   thus ?thesis
   738     using floor_add[of "log 2 b" c] assms
   739     by (auto simp add: log_mult log_nat_power bitlen_def)
   740 qed
   741 
   742 lemma bitlen_Float:
   743 fixes m e
   744 defines "f \<equiv> Float m e"
   745 shows "bitlen (\<bar>mantissa f\<bar>) + exponent f = (if m = 0 then 0 else bitlen \<bar>m\<bar> + e)"
   746 proof cases
   747   assume "m \<noteq> 0"
   748   hence "f \<noteq> float_of 0"
   749     unfolding real_of_float_eq by (simp add: f_def)
   750   hence "mantissa f \<noteq> 0"
   751     by (simp add: mantissa_noteq_0)
   752   moreover
   753   from f_def[THEN denormalize_shift, OF `f \<noteq> float_of 0`] guess i .
   754   ultimately show ?thesis by (simp add: abs_mult)
   755 qed (simp add: f_def bitlen_def Float_def)
   756 
   757 lemma compute_bitlen[code]:
   758   shows "bitlen x = (if x > 0 then bitlen (x div 2) + 1 else 0)"
   759 proof -
   760   { assume "2 \<le> x"
   761     then have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 (x - x mod 2)\<rfloor>"
   762       by (simp add: log_mult zmod_zdiv_equality')
   763     also have "\<dots> = \<lfloor>log 2 (real x)\<rfloor>"
   764     proof cases
   765       assume "x mod 2 = 0" then show ?thesis by simp
   766     next
   767       def n \<equiv> "\<lfloor>log 2 (real x)\<rfloor>"
   768       then have "0 \<le> n"
   769         using `2 \<le> x` by simp
   770       assume "x mod 2 \<noteq> 0"
   771       with `2 \<le> x` have "x mod 2 = 1" "\<not> 2 dvd x" by (auto simp add: dvd_eq_mod_eq_0)
   772       with `2 \<le> x` have "x \<noteq> 2^nat n" by (cases "nat n") auto
   773       moreover
   774       { have "real (2^nat n :: int) = 2 powr (nat n)"
   775           by (simp add: powr_realpow)
   776         also have "\<dots> \<le> 2 powr (log 2 x)"
   777           using `2 \<le> x` by (simp add: n_def del: powr_log_cancel)
   778         finally have "2^nat n \<le> x" using `2 \<le> x` by simp }
   779       ultimately have "2^nat n \<le> x - 1" by simp
   780       then have "2^nat n \<le> real (x - 1)"
   781         unfolding real_of_int_le_iff[symmetric] by simp
   782       { have "n = \<lfloor>log 2 (2^nat n)\<rfloor>"
   783           using `0 \<le> n` by (simp add: log_nat_power)
   784         also have "\<dots> \<le> \<lfloor>log 2 (x - 1)\<rfloor>"
   785           using `2^nat n \<le> real (x - 1)` `0 \<le> n` `2 \<le> x` by (auto intro: floor_mono)
   786         finally have "n \<le> \<lfloor>log 2 (x - 1)\<rfloor>" . }
   787       moreover have "\<lfloor>log 2 (x - 1)\<rfloor> \<le> n"
   788         using `2 \<le> x` by (auto simp add: n_def intro!: floor_mono)
   789       ultimately show "\<lfloor>log 2 (x - x mod 2)\<rfloor> = \<lfloor>log 2 x\<rfloor>"
   790         unfolding n_def `x mod 2 = 1` by auto
   791     qed
   792     finally have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 x\<rfloor>" . }
   793   moreover
   794   { assume "x < 2" "0 < x"
   795     then have "x = 1" by simp
   796     then have "\<lfloor>log 2 (real x)\<rfloor> = 0" by simp }
   797   ultimately show ?thesis
   798     unfolding bitlen_def
   799     by (auto simp: pos_imp_zdiv_pos_iff not_le)
   800 qed
   801 hide_fact (open) compute_bitlen
   802 
   803 lemma float_gt1_scale: assumes "1 \<le> Float m e"
   804   shows "0 \<le> e + (bitlen m - 1)"
   805 proof -
   806   have "0 < Float m e" using assms by auto
   807   hence "0 < m" using powr_gt_zero[of 2 e]
   808     by (auto simp: zero_less_mult_iff)
   809   hence "m \<noteq> 0" by auto
   810   show ?thesis
   811   proof (cases "0 \<le> e")
   812     case True thus ?thesis using `0 < m`  by (simp add: bitlen_def)
   813   next
   814     have "(1::int) < 2" by simp
   815     case False let ?S = "2^(nat (-e))"
   816     have "inverse (2 ^ nat (- e)) = 2 powr e" using assms False powr_realpow[of 2 "nat (-e)"]
   817       by (auto simp: powr_minus field_simps inverse_eq_divide)
   818     hence "1 \<le> real m * inverse ?S" using assms False powr_realpow[of 2 "nat (-e)"]
   819       by (auto simp: powr_minus)
   820     hence "1 * ?S \<le> real m * inverse ?S * ?S" by (rule mult_right_mono, auto)
   821     hence "?S \<le> real m" unfolding mult_assoc by auto
   822     hence "?S \<le> m" unfolding real_of_int_le_iff[symmetric] by auto
   823     from this bitlen_bounds[OF `0 < m`, THEN conjunct2]
   824     have "nat (-e) < (nat (bitlen m))" unfolding power_strict_increasing_iff[OF `1 < 2`, symmetric] by (rule order_le_less_trans)
   825     hence "-e < bitlen m" using False by auto
   826     thus ?thesis by auto
   827   qed
   828 qed
   829 
   830 lemma bitlen_div: assumes "0 < m" shows "1 \<le> real m / 2^nat (bitlen m - 1)" and "real m / 2^nat (bitlen m - 1) < 2"
   831 proof -
   832   let ?B = "2^nat(bitlen m - 1)"
   833 
   834   have "?B \<le> m" using bitlen_bounds[OF `0 <m`] ..
   835   hence "1 * ?B \<le> real m" unfolding real_of_int_le_iff[symmetric] by auto
   836   thus "1 \<le> real m / ?B" by auto
   837 
   838   have "m \<noteq> 0" using assms by auto
   839   have "0 \<le> bitlen m - 1" using `0 < m` by (auto simp: bitlen_def)
   840 
   841   have "m < 2^nat(bitlen m)" using bitlen_bounds[OF `0 <m`] ..
   842   also have "\<dots> = 2^nat(bitlen m - 1 + 1)" using `0 < m` by (auto simp: bitlen_def)
   843   also have "\<dots> = ?B * 2" unfolding nat_add_distrib[OF `0 \<le> bitlen m - 1` zero_le_one] by auto
   844   finally have "real m < 2 * ?B" unfolding real_of_int_less_iff[symmetric] by auto
   845   hence "real m / ?B < 2 * ?B / ?B" by (rule divide_strict_right_mono, auto)
   846   thus "real m / ?B < 2" by auto
   847 qed
   848 
   849 subsection {* Approximation of positive rationals *}
   850 
   851 lemma zdiv_zmult_twopow_eq: fixes a b::int shows "a div b div (2 ^ n) = a div (b * 2 ^ n)"
   852 by (simp add: zdiv_zmult2_eq)
   853 
   854 lemma div_mult_twopow_eq: fixes a b::nat shows "a div ((2::nat) ^ n) div b = a div (b * 2 ^ n)"
   855   by (cases "b=0") (simp_all add: div_mult2_eq[symmetric] ac_simps)
   856 
   857 lemma real_div_nat_eq_floor_of_divide:
   858   fixes a b::nat
   859   shows "a div b = real (floor (a/b))"
   860 by (metis floor_divide_eq_div real_of_int_of_nat_eq zdiv_int)
   861 
   862 definition "rat_precision prec x y = int prec - (bitlen x - bitlen y)"
   863 
   864 lift_definition lapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   865   is "\<lambda>prec (x::nat) (y::nat). round_down (rat_precision prec x y) (x / y)" by simp
   866 
   867 lemma compute_lapprox_posrat[code]:
   868   fixes prec x y 
   869   shows "lapprox_posrat prec x y = 
   870    (let 
   871        l = rat_precision prec x y;
   872        d = if 0 \<le> l then x * 2^nat l div y else x div 2^nat (- l) div y
   873     in normfloat (Float d (- l)))"
   874     unfolding div_mult_twopow_eq normfloat_def
   875     by transfer
   876        (simp add: round_down_def powr_int real_div_nat_eq_floor_of_divide field_simps Let_def
   877              del: two_powr_minus_int_float)
   878 hide_fact (open) compute_lapprox_posrat
   879 
   880 lift_definition rapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   881   is "\<lambda>prec (x::nat) (y::nat). round_up (rat_precision prec x y) (x / y)" by simp
   882 
   883 (* TODO: optimize using zmod_zmult2_eq, pdivmod ? *)
   884 lemma compute_rapprox_posrat[code]:
   885   fixes prec x y
   886   defines "l \<equiv> rat_precision prec x y"
   887   shows "rapprox_posrat prec x y = (let
   888      l = l ;
   889      X = if 0 \<le> l then (x * 2^nat l, y) else (x, y * 2^nat(-l)) ;
   890      d = fst X div snd X ;
   891      m = fst X mod snd X
   892    in normfloat (Float (d + (if m = 0 \<or> y = 0 then 0 else 1)) (- l)))"
   893 proof (cases "y = 0")
   894   assume "y = 0" thus ?thesis unfolding normfloat_def by transfer simp
   895 next
   896   assume "y \<noteq> 0"
   897   show ?thesis
   898   proof (cases "0 \<le> l")
   899     assume "0 \<le> l"
   900     def x' == "x * 2 ^ nat l"
   901     have "int x * 2 ^ nat l = x'" by (simp add: x'_def int_mult int_power)
   902     moreover have "real x * 2 powr real l = real x'"
   903       by (simp add: powr_realpow[symmetric] `0 \<le> l` x'_def)
   904     ultimately show ?thesis
   905       unfolding normfloat_def
   906       using ceil_divide_floor_conv[of y x'] powr_realpow[of 2 "nat l"] `0 \<le> l` `y \<noteq> 0`
   907         l_def[symmetric, THEN meta_eq_to_obj_eq]
   908       by transfer
   909          (simp add: floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0 round_up_def)
   910    next
   911     assume "\<not> 0 \<le> l"
   912     def y' == "y * 2 ^ nat (- l)"
   913     from `y \<noteq> 0` have "y' \<noteq> 0" by (simp add: y'_def)
   914     have "int y * 2 ^ nat (- l) = y'" by (simp add: y'_def int_mult int_power)
   915     moreover have "real x * real (2::int) powr real l / real y = x / real y'"
   916       using `\<not> 0 \<le> l`
   917       by (simp add: powr_realpow[symmetric] powr_minus y'_def field_simps inverse_eq_divide)
   918     ultimately show ?thesis
   919       unfolding normfloat_def
   920       using ceil_divide_floor_conv[of y' x] `\<not> 0 \<le> l` `y' \<noteq> 0` `y \<noteq> 0`
   921         l_def[symmetric, THEN meta_eq_to_obj_eq]
   922       by transfer
   923          (simp add: round_up_def ceil_divide_floor_conv floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0)
   924   qed
   925 qed
   926 hide_fact (open) compute_rapprox_posrat
   927 
   928 lemma rat_precision_pos:
   929   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   930   shows "rat_precision n (int x) (int y) > 0"
   931 proof -
   932   { assume "0 < x" hence "log 2 x + 1 = log 2 (2 * x)" by (simp add: log_mult) }
   933   hence "bitlen (int x) < bitlen (int y)" using assms
   934     by (simp add: bitlen_def del: floor_add_one)
   935       (auto intro!: floor_mono simp add: floor_add_one[symmetric] simp del: floor_add floor_add_one)
   936   thus ?thesis
   937     using assms by (auto intro!: pos_add_strict simp add: field_simps rat_precision_def)
   938 qed
   939 
   940 lemma power_aux: assumes "x > 0" shows "(2::int) ^ nat (x - 1) \<le> 2 ^ nat x - 1"
   941 proof -
   942   def y \<equiv> "nat (x - 1)" moreover
   943   have "(2::int) ^ y \<le> (2 ^ (y + 1)) - 1" by simp
   944   ultimately show ?thesis using assms by simp
   945 qed
   946 
   947 lemma rapprox_posrat_less1:
   948   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   949   shows "real (rapprox_posrat n x y) < 1"
   950 proof -
   951   have powr1: "2 powr real (rat_precision n (int x) (int y)) = 
   952     2 ^ nat (rat_precision n (int x) (int y))" using rat_precision_pos[of x y n] assms
   953     by (simp add: powr_realpow[symmetric])
   954   have "x * 2 powr real (rat_precision n (int x) (int y)) / y = (x / y) *
   955      2 powr real (rat_precision n (int x) (int y))" by simp
   956   also have "... < (1 / 2) * 2 powr real (rat_precision n (int x) (int y))"
   957     apply (rule mult_strict_right_mono) by (insert assms) auto
   958   also have "\<dots> = 2 powr real (rat_precision n (int x) (int y) - 1)"
   959     by (simp add: powr_add diff_def powr_neg_numeral)
   960   also have "\<dots> = 2 ^ nat (rat_precision n (int x) (int y) - 1)"
   961     using rat_precision_pos[of x y n] assms by (simp add: powr_realpow[symmetric])
   962   also have "\<dots> \<le> 2 ^ nat (rat_precision n (int x) (int y)) - 1"
   963     unfolding int_of_reals real_of_int_le_iff
   964     using rat_precision_pos[OF assms] by (rule power_aux)
   965   finally show ?thesis
   966     apply (transfer fixing: n x y)
   967     apply (simp add: round_up_def field_simps powr_minus inverse_eq_divide powr1)
   968     unfolding int_of_reals real_of_int_less_iff
   969     apply (simp add: ceiling_less_eq)
   970     done
   971 qed
   972 
   973 lift_definition lapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
   974   "\<lambda>prec (x::int) (y::int). round_down (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
   975 
   976 lemma compute_lapprox_rat[code]:
   977   "lapprox_rat prec x y =
   978     (if y = 0 then 0
   979     else if 0 \<le> x then
   980       (if 0 < y then lapprox_posrat prec (nat x) (nat y)
   981       else - (rapprox_posrat prec (nat x) (nat (-y)))) 
   982       else (if 0 < y
   983         then - (rapprox_posrat prec (nat (-x)) (nat y))
   984         else lapprox_posrat prec (nat (-x)) (nat (-y))))"
   985   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
   986 hide_fact (open) compute_lapprox_rat
   987 
   988 lift_definition rapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
   989   "\<lambda>prec (x::int) (y::int). round_up (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
   990 
   991 lemma compute_rapprox_rat[code]:
   992   "rapprox_rat prec x y =
   993     (if y = 0 then 0
   994     else if 0 \<le> x then
   995       (if 0 < y then rapprox_posrat prec (nat x) (nat y)
   996       else - (lapprox_posrat prec (nat x) (nat (-y)))) 
   997       else (if 0 < y
   998         then - (lapprox_posrat prec (nat (-x)) (nat y))
   999         else rapprox_posrat prec (nat (-x)) (nat (-y))))"
  1000   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
  1001 hide_fact (open) compute_rapprox_rat
  1002 
  1003 subsection {* Division *}
  1004 
  1005 lift_definition float_divl :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is
  1006   "\<lambda>(prec::nat) a b. round_down (prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)" by simp
  1007 
  1008 lemma compute_float_divl[code]:
  1009   "float_divl prec (Float m1 s1) (Float m2 s2) = lapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1010 proof cases
  1011   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1012   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1013   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1014   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1015     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1016   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1017     by (simp add: field_simps powr_divide2[symmetric])
  1018 
  1019   show ?thesis
  1020     using not_0 
  1021     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_down_shift, simp add: field_simps)
  1022 qed (transfer, auto)
  1023 hide_fact (open) compute_float_divl
  1024 
  1025 lift_definition float_divr :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is
  1026   "\<lambda>(prec::nat) a b. round_up (prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)" by simp
  1027 
  1028 lemma compute_float_divr[code]:
  1029   "float_divr prec (Float m1 s1) (Float m2 s2) = rapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1030 proof cases
  1031   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1032   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1033   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1034   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1035     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1036   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1037     by (simp add: field_simps powr_divide2[symmetric])
  1038 
  1039   show ?thesis
  1040     using not_0 
  1041     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_up_shift, simp add: field_simps)
  1042 qed (transfer, auto)
  1043 hide_fact (open) compute_float_divr
  1044 
  1045 subsection {* Lemmas needed by Approximate *}
  1046 
  1047 lemma Float_num[simp]: shows
  1048    "real (Float 1 0) = 1" and "real (Float 1 1) = 2" and "real (Float 1 2) = 4" and
  1049    "real (Float 1 -1) = 1/2" and "real (Float 1 -2) = 1/4" and "real (Float 1 -3) = 1/8" and
  1050    "real (Float -1 0) = -1" and "real (Float (number_of n) 0) = number_of n"
  1051 using two_powr_int_float[of 2] two_powr_int_float[of "-1"] two_powr_int_float[of "-2"] two_powr_int_float[of "-3"]
  1052 using powr_realpow[of 2 2] powr_realpow[of 2 3]
  1053 using powr_minus[of 2 1] powr_minus[of 2 2] powr_minus[of 2 3]
  1054 by auto
  1055 
  1056 lemma real_of_Float_int[simp]: "real (Float n 0) = real n" by simp
  1057 
  1058 lemma float_zero[simp]: "real (Float 0 e) = 0" by simp
  1059 
  1060 lemma abs_div_2_less: "a \<noteq> 0 \<Longrightarrow> a \<noteq> -1 \<Longrightarrow> abs((a::int) div 2) < abs a"
  1061 by arith
  1062 
  1063 lemma lapprox_rat:
  1064   shows "real (lapprox_rat prec x y) \<le> real x / real y"
  1065   using round_down by (simp add: lapprox_rat_def)
  1066 
  1067 lemma mult_div_le: fixes a b:: int assumes "b > 0" shows "a \<ge> b * (a div b)"
  1068 proof -
  1069   from zmod_zdiv_equality'[of a b]
  1070   have "a = b * (a div b) + a mod b" by simp
  1071   also have "... \<ge> b * (a div b) + 0" apply (rule add_left_mono) apply (rule pos_mod_sign)
  1072   using assms by simp
  1073   finally show ?thesis by simp
  1074 qed
  1075 
  1076 lemma lapprox_rat_nonneg:
  1077   fixes n x y
  1078   defines "p == int n - ((bitlen \<bar>x\<bar>) - (bitlen \<bar>y\<bar>))"
  1079   assumes "0 \<le> x" "0 < y"
  1080   shows "0 \<le> real (lapprox_rat n x y)"
  1081 using assms unfolding lapprox_rat_def p_def[symmetric] round_down_def real_of_int_minus[symmetric]
  1082    powr_int[of 2, simplified]
  1083   by (auto simp add: inverse_eq_divide intro!: mult_nonneg_nonneg divide_nonneg_pos mult_pos_pos)
  1084 
  1085 lemma rapprox_rat: "real x / real y \<le> real (rapprox_rat prec x y)"
  1086   using round_up by (simp add: rapprox_rat_def)
  1087 
  1088 lemma rapprox_rat_le1:
  1089   fixes n x y
  1090   assumes xy: "0 \<le> x" "0 < y" "x \<le> y"
  1091   shows "real (rapprox_rat n x y) \<le> 1"
  1092 proof -
  1093   have "bitlen \<bar>x\<bar> \<le> bitlen \<bar>y\<bar>"
  1094     using xy unfolding bitlen_def by (auto intro!: floor_mono)
  1095   then have "0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>" by (simp add: rat_precision_def)
  1096   have "real \<lceil>real x / real y * 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>
  1097       \<le> real \<lceil>2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>"
  1098     using xy by (auto intro!: ceiling_mono simp: field_simps)
  1099   also have "\<dots> = 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"
  1100     using `0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>`
  1101     by (auto intro!: exI[of _ "2^nat (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"] simp: powr_int)
  1102   finally show ?thesis
  1103     by (simp add: rapprox_rat_def round_up_def)
  1104        (simp add: powr_minus inverse_eq_divide)
  1105 qed
  1106 
  1107 lemma rapprox_rat_nonneg_neg: 
  1108   "0 \<le> x \<Longrightarrow> y < 0 \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1109   unfolding rapprox_rat_def round_up_def
  1110   by (auto simp: field_simps mult_le_0_iff zero_le_mult_iff)
  1111 
  1112 lemma rapprox_rat_neg:
  1113   "x < 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1114   unfolding rapprox_rat_def round_up_def
  1115   by (auto simp: field_simps mult_le_0_iff)
  1116 
  1117 lemma rapprox_rat_nonpos_pos:
  1118   "x \<le> 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1119   unfolding rapprox_rat_def round_up_def
  1120   by (auto simp: field_simps mult_le_0_iff)
  1121 
  1122 lemma float_divl: "real (float_divl prec x y) \<le> real x / real y"
  1123   by transfer (simp add: round_down)
  1124 
  1125 lemma float_divl_lower_bound:
  1126   "0 \<le> x \<Longrightarrow> 0 < y \<Longrightarrow> 0 \<le> real (float_divl prec x y)"
  1127   by transfer (simp add: round_down_def zero_le_mult_iff zero_le_divide_iff)
  1128 
  1129 lemma exponent_1: "exponent 1 = 0"
  1130   using exponent_float[of 1 0] by (simp add: one_float_def)
  1131 
  1132 lemma mantissa_1: "mantissa 1 = 1"
  1133   using mantissa_float[of 1 0] by (simp add: one_float_def)
  1134 
  1135 lemma bitlen_1: "bitlen 1 = 1"
  1136   by (simp add: bitlen_def)
  1137 
  1138 lemma mantissa_eq_zero_iff: "mantissa x = 0 \<longleftrightarrow> x = 0"
  1139 proof
  1140   assume "mantissa x = 0" hence z: "0 = real x" using mantissa_exponent by simp
  1141   show "x = 0" by (simp add: zero_float_def z)
  1142 qed (simp add: zero_float_def)
  1143 
  1144 lemma float_upper_bound: "x \<le> 2 powr (bitlen \<bar>mantissa x\<bar> + exponent x)"
  1145 proof (cases "x = 0", simp)
  1146   assume "x \<noteq> 0" hence "mantissa x \<noteq> 0" using mantissa_eq_zero_iff by auto
  1147   have "x = mantissa x * 2 powr (exponent x)" by (rule mantissa_exponent)
  1148   also have "mantissa x \<le> \<bar>mantissa x\<bar>" by simp
  1149   also have "... \<le> 2 powr (bitlen \<bar>mantissa x\<bar>)"
  1150     using bitlen_bounds[of "\<bar>mantissa x\<bar>"] bitlen_nonneg `mantissa x \<noteq> 0`
  1151     by (simp add: powr_int) (simp only: two_real_int int_of_reals real_of_int_abs[symmetric]
  1152       real_of_int_le_iff less_imp_le)
  1153   finally show ?thesis by (simp add: powr_add)
  1154 qed
  1155 
  1156 lemma float_divl_pos_less1_bound:
  1157   "0 < real x \<Longrightarrow> real x < 1 \<Longrightarrow> prec \<ge> 1 \<Longrightarrow> 1 \<le> real (float_divl prec 1 x)"
  1158 proof transfer
  1159   fix prec :: nat and x :: real assume x: "0 < x" "x < 1" "x \<in> float" and prec: "1 \<le> prec"
  1160   def p \<equiv> "int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor>" 
  1161   show "1 \<le> round_down (int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - \<lfloor>log 2 \<bar>1\<bar>\<rfloor>) (1 / x) "
  1162   proof cases
  1163     assume nonneg: "0 \<le> p"
  1164     hence "2 powr real (p) = floor (real ((2::int) ^ nat p)) * floor (1::real)"
  1165       by (simp add: powr_int del: real_of_int_power) simp
  1166     also have "floor (1::real) \<le> floor (1 / x)" using x prec by simp
  1167     also have "floor (real ((2::int) ^ nat p)) * floor (1 / x) \<le>
  1168       floor (real ((2::int) ^ nat p) * (1 / x))"
  1169       by (rule le_mult_floor) (auto simp: x prec less_imp_le)
  1170     finally have "2 powr real p \<le> floor (2 powr nat p / x)" by (simp add: powr_realpow)
  1171     thus ?thesis unfolding p_def[symmetric]
  1172       using x prec nonneg by (simp add: powr_minus inverse_eq_divide round_down_def)
  1173   next
  1174     assume neg: "\<not> 0 \<le> p"
  1175 
  1176     have "x = 2 powr (log 2 x)"
  1177       using x by simp
  1178     also have "2 powr (log 2 x) \<le> 2 powr p"
  1179     proof (rule powr_mono)
  1180       have "log 2 x \<le> \<lceil>log 2 x\<rceil>"
  1181         by simp
  1182       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + 1"
  1183         using ceiling_diff_floor_le_1[of "log 2 x"] by simp
  1184       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + prec"
  1185         using prec by simp
  1186       finally show "log 2 x \<le> real p"
  1187         using x by (simp add: p_def)
  1188     qed simp
  1189     finally have x_le: "x \<le> 2 powr p" .
  1190 
  1191     from neg have "2 powr real p \<le> 2 powr 0"
  1192       by (intro powr_mono) auto
  1193     also have "\<dots> \<le> \<lfloor>2 powr 0\<rfloor>" by simp
  1194     also have "\<dots> \<le> \<lfloor>2 powr real p / x\<rfloor>" unfolding real_of_int_le_iff
  1195       using x x_le by (intro floor_mono) (simp add:  pos_le_divide_eq mult_pos_pos)
  1196     finally show ?thesis
  1197       using prec x unfolding p_def[symmetric]
  1198       by (simp add: round_down_def powr_minus_divide pos_le_divide_eq mult_pos_pos)
  1199   qed
  1200 qed
  1201 
  1202 lemma float_divr: "real x / real y \<le> real (float_divr prec x y)"
  1203   using round_up by transfer simp
  1204 
  1205 lemma float_divr_pos_less1_lower_bound: assumes "0 < x" and "x < 1" shows "1 \<le> float_divr prec 1 x"
  1206 proof -
  1207   have "1 \<le> 1 / real x" using `0 < x` and `x < 1` by auto
  1208   also have "\<dots> \<le> real (float_divr prec 1 x)" using float_divr[where x=1 and y=x] by auto
  1209   finally show ?thesis by auto
  1210 qed
  1211 
  1212 lemma float_divr_nonpos_pos_upper_bound:
  1213   "real x \<le> 0 \<Longrightarrow> 0 < real y \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1214   by transfer (auto simp: field_simps mult_le_0_iff divide_le_0_iff round_up_def)
  1215 
  1216 lemma float_divr_nonneg_neg_upper_bound:
  1217   "0 \<le> real x \<Longrightarrow> real y < 0 \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1218   by transfer (auto simp: field_simps mult_le_0_iff zero_le_mult_iff divide_le_0_iff round_up_def)
  1219 
  1220 lift_definition float_round_up :: "nat \<Rightarrow> float \<Rightarrow> float" is
  1221   "\<lambda>(prec::nat) x. round_up (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x" by simp
  1222 
  1223 lemma float_round_up: "real x \<le> real (float_round_up prec x)"
  1224   using round_up by transfer simp
  1225 
  1226 lift_definition float_round_down :: "nat \<Rightarrow> float \<Rightarrow> float" is
  1227   "\<lambda>(prec::nat) x. round_down (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x" by simp
  1228 
  1229 lemma float_round_down: "real (float_round_down prec x) \<le> real x"
  1230   using round_down by transfer simp
  1231 
  1232 lemma floor_add2[simp]: "\<lfloor> real i + x \<rfloor> = i + \<lfloor> x \<rfloor>"
  1233   using floor_add[of x i] by (simp del: floor_add add: ac_simps)
  1234 
  1235 lemma compute_float_round_down[code]:
  1236   "float_round_down prec (Float m e) = (let d = bitlen (abs m) - int prec in
  1237     if 0 < d then let P = 2^nat d ; n = m div P in Float n (e + d)
  1238              else Float m e)"
  1239   using Float.compute_float_down[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1240   by transfer (simp add: field_simps abs_mult log_mult bitlen_def cong del: if_weak_cong)
  1241 hide_fact (open) compute_float_round_down
  1242 
  1243 lemma compute_float_round_up[code]:
  1244   "float_round_up prec (Float m e) = (let d = (bitlen (abs m) - int prec) in
  1245      if 0 < d then let P = 2^nat d ; n = m div P ; r = m mod P
  1246                    in Float (n + (if r = 0 then 0 else 1)) (e + d)
  1247               else Float m e)"
  1248   using Float.compute_float_up[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1249   unfolding Let_def
  1250   by transfer (simp add: field_simps abs_mult log_mult bitlen_def cong del: if_weak_cong)
  1251 hide_fact (open) compute_float_round_up
  1252 
  1253 lemma Float_le_zero_iff: "Float a b \<le> 0 \<longleftrightarrow> a \<le> 0"
  1254  apply (auto simp: zero_float_def mult_le_0_iff)
  1255  using powr_gt_zero[of 2 b] by simp
  1256 
  1257 lemma real_of_float_pprt[simp]: fixes a::float shows "real (pprt a) = pprt (real a)"
  1258   unfolding pprt_def sup_float_def max_def sup_real_def by auto
  1259 
  1260 lemma real_of_float_nprt[simp]: fixes a::float shows "real (nprt a) = nprt (real a)"
  1261   unfolding nprt_def inf_float_def min_def inf_real_def by auto
  1262 
  1263 lift_definition int_floor_fl :: "float \<Rightarrow> int" is floor by simp
  1264 
  1265 lemma compute_int_floor_fl[code]:
  1266   "int_floor_fl (Float m e) = (if 0 \<le> e then m * 2 ^ nat e else m div (2 ^ (nat (-e))))"
  1267   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1268 hide_fact (open) compute_int_floor_fl
  1269 
  1270 lift_definition floor_fl :: "float \<Rightarrow> float" is "\<lambda>x. real (floor x)" by simp
  1271 
  1272 lemma compute_floor_fl[code]:
  1273   "floor_fl (Float m e) = (if 0 \<le> e then Float m e else Float (m div (2 ^ (nat (-e)))) 0)"
  1274   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1275 hide_fact (open) compute_floor_fl
  1276 
  1277 lemma floor_fl: "real (floor_fl x) \<le> real x" by transfer simp
  1278 
  1279 lemma int_floor_fl: "real (int_floor_fl x) \<le> real x" by transfer simp
  1280 
  1281 lemma floor_pos_exp: "exponent (floor_fl x) \<ge> 0"
  1282 proof cases
  1283   assume nzero: "floor_fl x \<noteq> float_of 0"
  1284   have "floor_fl x = Float \<lfloor>real x\<rfloor> 0" by transfer simp
  1285   from denormalize_shift[OF this[THEN eq_reflection] nzero] guess i . note i = this
  1286   thus ?thesis by simp
  1287 qed (simp add: floor_fl_def)
  1288 
  1289 end
  1290