src/HOL/Library/Float.thy
author immler
Wed Nov 12 17:37:43 2014 +0100 (2014-11-12)
changeset 58985 bf498e0af9e3
parent 58982 27e7e3f9e665
child 58987 119680ebf37c
permissions -rw-r--r--
truncate intermediate results in horner to improve performance of approximate;
more efficient truncated addition float_plus_up/float_plus_down
     1 (*  Title:      HOL/Library/Float.thy
     2     Author:     Johannes Hölzl, Fabian Immler
     3     Copyright   2012  TU München
     4 *)
     5 
     6 section {* Floating-Point Numbers *}
     7 
     8 theory Float
     9 imports Complex_Main Lattice_Algebras
    10 begin
    11 
    12 definition "float = {m * 2 powr e | (m :: int) (e :: int). True}"
    13 
    14 typedef float = float
    15   morphisms real_of_float float_of
    16   unfolding float_def by auto
    17 
    18 instantiation float :: real_of
    19 begin
    20 
    21 definition real_float :: "float \<Rightarrow> real" where
    22   real_of_float_def[code_unfold]: "real \<equiv> real_of_float"
    23 
    24 instance ..
    25 end
    26 
    27 lemma type_definition_float': "type_definition real float_of float"
    28   using type_definition_float unfolding real_of_float_def .
    29 
    30 setup_lifting (no_code) type_definition_float'
    31 
    32 lemmas float_of_inject[simp]
    33 
    34 declare [[coercion "real :: float \<Rightarrow> real"]]
    35 
    36 lemma real_of_float_eq:
    37   fixes f1 f2 :: float shows "f1 = f2 \<longleftrightarrow> real f1 = real f2"
    38   unfolding real_of_float_def real_of_float_inject ..
    39 
    40 lemma float_of_real[simp]: "float_of (real x) = x"
    41   unfolding real_of_float_def by (rule real_of_float_inverse)
    42 
    43 lemma real_float[simp]: "x \<in> float \<Longrightarrow> real (float_of x) = x"
    44   unfolding real_of_float_def by (rule float_of_inverse)
    45 
    46 subsection {* Real operations preserving the representation as floating point number *}
    47 
    48 lemma floatI: fixes m e :: int shows "m * 2 powr e = x \<Longrightarrow> x \<in> float"
    49   by (auto simp: float_def)
    50 
    51 lemma zero_float[simp]: "0 \<in> float" by (auto simp: float_def)
    52 lemma one_float[simp]: "1 \<in> float" by (intro floatI[of 1 0]) simp
    53 lemma numeral_float[simp]: "numeral i \<in> float" by (intro floatI[of "numeral i" 0]) simp
    54 lemma neg_numeral_float[simp]: "- numeral i \<in> float" by (intro floatI[of "- numeral i" 0]) simp
    55 lemma real_of_int_float[simp]: "real (x :: int) \<in> float" by (intro floatI[of x 0]) simp
    56 lemma real_of_nat_float[simp]: "real (x :: nat) \<in> float" by (intro floatI[of x 0]) simp
    57 lemma two_powr_int_float[simp]: "2 powr (real (i::int)) \<in> float" by (intro floatI[of 1 i]) simp
    58 lemma two_powr_nat_float[simp]: "2 powr (real (i::nat)) \<in> float" by (intro floatI[of 1 i]) simp
    59 lemma two_powr_minus_int_float[simp]: "2 powr - (real (i::int)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    60 lemma two_powr_minus_nat_float[simp]: "2 powr - (real (i::nat)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    61 lemma two_powr_numeral_float[simp]: "2 powr numeral i \<in> float" by (intro floatI[of 1 "numeral i"]) simp
    62 lemma two_powr_neg_numeral_float[simp]: "2 powr - numeral i \<in> float" by (intro floatI[of 1 "- numeral i"]) simp
    63 lemma two_pow_float[simp]: "2 ^ n \<in> float" by (intro floatI[of 1 "n"]) (simp add: powr_realpow)
    64 lemma real_of_float_float[simp]: "real (f::float) \<in> float" by (cases f) simp
    65 
    66 lemma plus_float[simp]: "r \<in> float \<Longrightarrow> p \<in> float \<Longrightarrow> r + p \<in> float"
    67   unfolding float_def
    68 proof (safe, simp)
    69   fix e1 m1 e2 m2 :: int
    70   { fix e1 m1 e2 m2 :: int assume "e1 \<le> e2"
    71     then have "m1 * 2 powr e1 + m2 * 2 powr e2 = (m1 + m2 * 2 ^ nat (e2 - e1)) * 2 powr e1"
    72       by (simp add: powr_realpow[symmetric] powr_divide2[symmetric] field_simps)
    73     then have "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    74       by blast }
    75   note * = this
    76   show "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    77   proof (cases e1 e2 rule: linorder_le_cases)
    78     assume "e2 \<le> e1" from *[OF this, of m2 m1] show ?thesis by (simp add: ac_simps)
    79   qed (rule *)
    80 qed
    81 
    82 lemma uminus_float[simp]: "x \<in> float \<Longrightarrow> -x \<in> float"
    83   apply (auto simp: float_def)
    84   apply hypsubst_thin
    85   apply (rule_tac x="-x" in exI)
    86   apply (rule_tac x="xa" in exI)
    87   apply (simp add: field_simps)
    88   done
    89 
    90 lemma times_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x * y \<in> float"
    91   apply (auto simp: float_def)
    92   apply hypsubst_thin
    93   apply (rule_tac x="x * xa" in exI)
    94   apply (rule_tac x="xb + xc" in exI)
    95   apply (simp add: powr_add)
    96   done
    97 
    98 lemma minus_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x - y \<in> float"
    99   using plus_float [of x "- y"] by simp
   100 
   101 lemma abs_float[simp]: "x \<in> float \<Longrightarrow> abs x \<in> float"
   102   by (cases x rule: linorder_cases[of 0]) auto
   103 
   104 lemma sgn_of_float[simp]: "x \<in> float \<Longrightarrow> sgn x \<in> float"
   105   by (cases x rule: linorder_cases[of 0]) (auto intro!: uminus_float)
   106 
   107 lemma div_power_2_float[simp]: "x \<in> float \<Longrightarrow> x / 2^d \<in> float"
   108   apply (auto simp add: float_def)
   109   apply hypsubst_thin
   110   apply (rule_tac x="x" in exI)
   111   apply (rule_tac x="xa - d" in exI)
   112   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   113   done
   114 
   115 lemma div_power_2_int_float[simp]: "x \<in> float \<Longrightarrow> x / (2::int)^d \<in> float"
   116   apply (auto simp add: float_def)
   117   apply hypsubst_thin
   118   apply (rule_tac x="x" in exI)
   119   apply (rule_tac x="xa - d" in exI)
   120   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   121   done
   122 
   123 lemma div_numeral_Bit0_float[simp]:
   124   assumes x: "x / numeral n \<in> float" shows "x / (numeral (Num.Bit0 n)) \<in> float"
   125 proof -
   126   have "(x / numeral n) / 2^1 \<in> float"
   127     by (intro x div_power_2_float)
   128   also have "(x / numeral n) / 2^1 = x / (numeral (Num.Bit0 n))"
   129     by (induct n) auto
   130   finally show ?thesis .
   131 qed
   132 
   133 lemma div_neg_numeral_Bit0_float[simp]:
   134   assumes x: "x / numeral n \<in> float" shows "x / (- numeral (Num.Bit0 n)) \<in> float"
   135 proof -
   136   have "- (x / numeral (Num.Bit0 n)) \<in> float" using x by simp
   137   also have "- (x / numeral (Num.Bit0 n)) = x / - numeral (Num.Bit0 n)"
   138     by simp
   139   finally show ?thesis .
   140 qed
   141 
   142 lemma power_float[simp]: assumes "a \<in> float" shows "a ^ b \<in> float"
   143 proof -
   144   from assms obtain m e::int where "a = m * 2 powr e"
   145     by (auto simp: float_def)
   146   thus ?thesis
   147     by (auto intro!: floatI[where m="m^b" and e = "e*b"]
   148       simp: power_mult_distrib powr_realpow[symmetric] powr_powr)
   149 qed
   150 
   151 lift_definition Float :: "int \<Rightarrow> int \<Rightarrow> float" is "\<lambda>(m::int) (e::int). m * 2 powr e" by simp
   152 declare Float.rep_eq[simp]
   153 
   154 lemma compute_real_of_float[code]:
   155   "real_of_float (Float m e) = (if e \<ge> 0 then m * 2 ^ nat e else m / 2 ^ (nat (-e)))"
   156 by (simp add: real_of_float_def[symmetric] powr_int)
   157 
   158 code_datatype Float
   159 
   160 subsection {* Arithmetic operations on floating point numbers *}
   161 
   162 instantiation float :: "{ring_1, linorder, linordered_ring, linordered_idom, numeral, equal}"
   163 begin
   164 
   165 lift_definition zero_float :: float is 0 by simp
   166 declare zero_float.rep_eq[simp]
   167 lift_definition one_float :: float is 1 by simp
   168 declare one_float.rep_eq[simp]
   169 lift_definition plus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op +" by simp
   170 declare plus_float.rep_eq[simp]
   171 lift_definition times_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op *" by simp
   172 declare times_float.rep_eq[simp]
   173 lift_definition minus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op -" by simp
   174 declare minus_float.rep_eq[simp]
   175 lift_definition uminus_float :: "float \<Rightarrow> float" is "uminus" by simp
   176 declare uminus_float.rep_eq[simp]
   177 
   178 lift_definition abs_float :: "float \<Rightarrow> float" is abs by simp
   179 declare abs_float.rep_eq[simp]
   180 lift_definition sgn_float :: "float \<Rightarrow> float" is sgn by simp
   181 declare sgn_float.rep_eq[simp]
   182 
   183 lift_definition equal_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op = :: real \<Rightarrow> real \<Rightarrow> bool" .
   184 
   185 lift_definition less_eq_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op \<le>" .
   186 declare less_eq_float.rep_eq[simp]
   187 lift_definition less_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op <" .
   188 declare less_float.rep_eq[simp]
   189 
   190 instance
   191   proof qed (transfer, fastforce simp add: field_simps intro: mult_left_mono mult_right_mono)+
   192 end
   193 
   194 lemma Float_0_eq_0[simp]: "Float 0 e = 0"
   195   by transfer simp
   196 
   197 lemma real_of_float_power[simp]: fixes f::float shows "real (f^n) = real f^n"
   198   by (induct n) simp_all
   199 
   200 lemma fixes x y::float
   201   shows real_of_float_min: "real (min x y) = min (real x) (real y)"
   202     and real_of_float_max: "real (max x y) = max (real x) (real y)"
   203   by (simp_all add: min_def max_def)
   204 
   205 instance float :: unbounded_dense_linorder
   206 proof
   207   fix a b :: float
   208   show "\<exists>c. a < c"
   209     apply (intro exI[of _ "a + 1"])
   210     apply transfer
   211     apply simp
   212     done
   213   show "\<exists>c. c < a"
   214     apply (intro exI[of _ "a - 1"])
   215     apply transfer
   216     apply simp
   217     done
   218   assume "a < b"
   219   then show "\<exists>c. a < c \<and> c < b"
   220     apply (intro exI[of _ "(a + b) * Float 1 (- 1)"])
   221     apply transfer
   222     apply (simp add: powr_minus)
   223     done
   224 qed
   225 
   226 instantiation float :: lattice_ab_group_add
   227 begin
   228 
   229 definition inf_float::"float\<Rightarrow>float\<Rightarrow>float"
   230 where "inf_float a b = min a b"
   231 
   232 definition sup_float::"float\<Rightarrow>float\<Rightarrow>float"
   233 where "sup_float a b = max a b"
   234 
   235 instance
   236   by default
   237      (transfer, simp_all add: inf_float_def sup_float_def real_of_float_min real_of_float_max)+
   238 end
   239 
   240 lemma float_numeral[simp]: "real (numeral x :: float) = numeral x"
   241   apply (induct x)
   242   apply simp
   243   apply (simp_all only: numeral_Bit0 numeral_Bit1 real_of_float_eq real_float
   244                   plus_float.rep_eq one_float.rep_eq plus_float numeral_float one_float)
   245   done
   246 
   247 lemma transfer_numeral [transfer_rule]:
   248   "rel_fun (op =) pcr_float (numeral :: _ \<Rightarrow> real) (numeral :: _ \<Rightarrow> float)"
   249   unfolding rel_fun_def float.pcr_cr_eq  cr_float_def by simp
   250 
   251 lemma float_neg_numeral[simp]: "real (- numeral x :: float) = - numeral x"
   252   by simp
   253 
   254 lemma transfer_neg_numeral [transfer_rule]:
   255   "rel_fun (op =) pcr_float (- numeral :: _ \<Rightarrow> real) (- numeral :: _ \<Rightarrow> float)"
   256   unfolding rel_fun_def float.pcr_cr_eq cr_float_def by simp
   257 
   258 lemma
   259   shows float_of_numeral[simp]: "numeral k = float_of (numeral k)"
   260     and float_of_neg_numeral[simp]: "- numeral k = float_of (- numeral k)"
   261   unfolding real_of_float_eq by simp_all
   262 
   263 subsection {* Represent floats as unique mantissa and exponent *}
   264 
   265 lemma int_induct_abs[case_names less]:
   266   fixes j :: int
   267   assumes H: "\<And>n. (\<And>i. \<bar>i\<bar> < \<bar>n\<bar> \<Longrightarrow> P i) \<Longrightarrow> P n"
   268   shows "P j"
   269 proof (induct "nat \<bar>j\<bar>" arbitrary: j rule: less_induct)
   270   case less show ?case by (rule H[OF less]) simp
   271 qed
   272 
   273 lemma int_cancel_factors:
   274   fixes n :: int assumes "1 < r" shows "n = 0 \<or> (\<exists>k i. n = k * r ^ i \<and> \<not> r dvd k)"
   275 proof (induct n rule: int_induct_abs)
   276   case (less n)
   277   { fix m assume n: "n \<noteq> 0" "n = m * r"
   278     then have "\<bar>m \<bar> < \<bar>n\<bar>"
   279       by (metis abs_dvd_iff abs_ge_self assms comm_semiring_1_class.normalizing_semiring_rules(7)
   280                 dvd_imp_le_int dvd_refl dvd_triv_right linorder_neq_iff linorder_not_le
   281                 mult_eq_0_iff zdvd_mult_cancel1)
   282     from less[OF this] n have "\<exists>k i. n = k * r ^ Suc i \<and> \<not> r dvd k" by auto }
   283   then show ?case
   284     by (metis comm_semiring_1_class.normalizing_semiring_rules(12,7) dvdE power_0)
   285 qed
   286 
   287 lemma mult_powr_eq_mult_powr_iff_asym:
   288   fixes m1 m2 e1 e2 :: int
   289   assumes m1: "\<not> 2 dvd m1" and "e1 \<le> e2"
   290   shows "m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   291 proof
   292   have "m1 \<noteq> 0" using m1 unfolding dvd_def by auto
   293   assume eq: "m1 * 2 powr e1 = m2 * 2 powr e2"
   294   with `e1 \<le> e2` have "m1 = m2 * 2 powr nat (e2 - e1)"
   295     by (simp add: powr_divide2[symmetric] field_simps)
   296   also have "\<dots> = m2 * 2^nat (e2 - e1)"
   297     by (simp add: powr_realpow)
   298   finally have m1_eq: "m1 = m2 * 2^nat (e2 - e1)"
   299     unfolding real_of_int_inject .
   300   with m1 have "m1 = m2"
   301     by (cases "nat (e2 - e1)") (auto simp add: dvd_def)
   302   then show "m1 = m2 \<and> e1 = e2"
   303     using eq `m1 \<noteq> 0` by (simp add: powr_inj)
   304 qed simp
   305 
   306 lemma mult_powr_eq_mult_powr_iff:
   307   fixes m1 m2 e1 e2 :: int
   308   shows "\<not> 2 dvd m1 \<Longrightarrow> \<not> 2 dvd m2 \<Longrightarrow> m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   309   using mult_powr_eq_mult_powr_iff_asym[of m1 e1 e2 m2]
   310   using mult_powr_eq_mult_powr_iff_asym[of m2 e2 e1 m1]
   311   by (cases e1 e2 rule: linorder_le_cases) auto
   312 
   313 lemma floatE_normed:
   314   assumes x: "x \<in> float"
   315   obtains (zero) "x = 0"
   316    | (powr) m e :: int where "x = m * 2 powr e" "\<not> 2 dvd m" "x \<noteq> 0"
   317 proof atomize_elim
   318   { assume "x \<noteq> 0"
   319     from x obtain m e :: int where x: "x = m * 2 powr e" by (auto simp: float_def)
   320     with `x \<noteq> 0` int_cancel_factors[of 2 m] obtain k i where "m = k * 2 ^ i" "\<not> 2 dvd k"
   321       by auto
   322     with `\<not> 2 dvd k` x have "\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m"
   323       by (rule_tac exI[of _ "k"], rule_tac exI[of _ "e + int i"])
   324          (simp add: powr_add powr_realpow) }
   325   then show "x = 0 \<or> (\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m \<and> x \<noteq> 0)"
   326     by blast
   327 qed
   328 
   329 lemma float_normed_cases:
   330   fixes f :: float
   331   obtains (zero) "f = 0"
   332    | (powr) m e :: int where "real f = m * 2 powr e" "\<not> 2 dvd m" "f \<noteq> 0"
   333 proof (atomize_elim, induct f)
   334   case (float_of y) then show ?case
   335     by (cases rule: floatE_normed) (auto simp: zero_float_def)
   336 qed
   337 
   338 definition mantissa :: "float \<Rightarrow> int" where
   339   "mantissa f = fst (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   340    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   341 
   342 definition exponent :: "float \<Rightarrow> int" where
   343   "exponent f = snd (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   344    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   345 
   346 lemma
   347   shows exponent_0[simp]: "exponent (float_of 0) = 0" (is ?E)
   348     and mantissa_0[simp]: "mantissa (float_of 0) = 0" (is ?M)
   349 proof -
   350   have "\<And>p::int \<times> int. fst p = 0 \<and> snd p = 0 \<longleftrightarrow> p = (0, 0)" by auto
   351   then show ?E ?M
   352     by (auto simp add: mantissa_def exponent_def zero_float_def)
   353 qed
   354 
   355 lemma
   356   shows mantissa_exponent: "real f = mantissa f * 2 powr exponent f" (is ?E)
   357     and mantissa_not_dvd: "f \<noteq> (float_of 0) \<Longrightarrow> \<not> 2 dvd mantissa f" (is "_ \<Longrightarrow> ?D")
   358 proof cases
   359   assume [simp]: "f \<noteq> (float_of 0)"
   360   have "f = mantissa f * 2 powr exponent f \<and> \<not> 2 dvd mantissa f"
   361   proof (cases f rule: float_normed_cases)
   362     case (powr m e)
   363     then have "\<exists>p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   364      \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p)"
   365       by auto
   366     then show ?thesis
   367       unfolding exponent_def mantissa_def
   368       by (rule someI2_ex) (simp add: zero_float_def)
   369   qed (simp add: zero_float_def)
   370   then show ?E ?D by auto
   371 qed simp
   372 
   373 lemma mantissa_noteq_0: "f \<noteq> float_of 0 \<Longrightarrow> mantissa f \<noteq> 0"
   374   using mantissa_not_dvd[of f] by auto
   375 
   376 lemma
   377   fixes m e :: int
   378   defines "f \<equiv> float_of (m * 2 powr e)"
   379   assumes dvd: "\<not> 2 dvd m"
   380   shows mantissa_float: "mantissa f = m" (is "?M")
   381     and exponent_float: "m \<noteq> 0 \<Longrightarrow> exponent f = e" (is "_ \<Longrightarrow> ?E")
   382 proof cases
   383   assume "m = 0" with dvd show "mantissa f = m" by auto
   384 next
   385   assume "m \<noteq> 0"
   386   then have f_not_0: "f \<noteq> float_of 0" by (simp add: f_def)
   387   from mantissa_exponent[of f]
   388   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   389     by (auto simp add: f_def)
   390   then show "?M" "?E"
   391     using mantissa_not_dvd[OF f_not_0] dvd
   392     by (auto simp: mult_powr_eq_mult_powr_iff)
   393 qed
   394 
   395 subsection {* Compute arithmetic operations *}
   396 
   397 lemma Float_mantissa_exponent: "Float (mantissa f) (exponent f) = f"
   398   unfolding real_of_float_eq mantissa_exponent[of f] by simp
   399 
   400 lemma Float_cases[case_names Float, cases type: float]:
   401   fixes f :: float
   402   obtains (Float) m e :: int where "f = Float m e"
   403   using Float_mantissa_exponent[symmetric]
   404   by (atomize_elim) auto
   405 
   406 lemma denormalize_shift:
   407   assumes f_def: "f \<equiv> Float m e" and not_0: "f \<noteq> float_of 0"
   408   obtains i where "m = mantissa f * 2 ^ i" "e = exponent f - i"
   409 proof
   410   from mantissa_exponent[of f] f_def
   411   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   412     by simp
   413   then have eq: "m = mantissa f * 2 powr (exponent f - e)"
   414     by (simp add: powr_divide2[symmetric] field_simps)
   415   moreover
   416   have "e \<le> exponent f"
   417   proof (rule ccontr)
   418     assume "\<not> e \<le> exponent f"
   419     then have pos: "exponent f < e" by simp
   420     then have "2 powr (exponent f - e) = 2 powr - real (e - exponent f)"
   421       by simp
   422     also have "\<dots> = 1 / 2^nat (e - exponent f)"
   423       using pos by (simp add: powr_realpow[symmetric] powr_divide2[symmetric])
   424     finally have "m * 2^nat (e - exponent f) = real (mantissa f)"
   425       using eq by simp
   426     then have "mantissa f = m * 2^nat (e - exponent f)"
   427       unfolding real_of_int_inject by simp
   428     with `exponent f < e` have "2 dvd mantissa f"
   429       apply (intro dvdI[where k="m * 2^(nat (e-exponent f)) div 2"])
   430       apply (cases "nat (e - exponent f)")
   431       apply auto
   432       done
   433     then show False using mantissa_not_dvd[OF not_0] by simp
   434   qed
   435   ultimately have "real m = mantissa f * 2^nat (exponent f - e)"
   436     by (simp add: powr_realpow[symmetric])
   437   with `e \<le> exponent f`
   438   show "m = mantissa f * 2 ^ nat (exponent f - e)" "e = exponent f - nat (exponent f - e)"
   439     unfolding real_of_int_inject by auto
   440 qed
   441 
   442 lemma compute_float_zero[code_unfold, code]: "0 = Float 0 0"
   443   by transfer simp
   444 hide_fact (open) compute_float_zero
   445 
   446 lemma compute_float_one[code_unfold, code]: "1 = Float 1 0"
   447   by transfer simp
   448 hide_fact (open) compute_float_one
   449 
   450 lift_definition normfloat :: "float \<Rightarrow> float" is "\<lambda>x. x" .
   451 lemma normloat_id[simp]: "normfloat x = x" by transfer rule
   452 
   453 lemma compute_normfloat[code]: "normfloat (Float m e) =
   454   (if m mod 2 = 0 \<and> m \<noteq> 0 then normfloat (Float (m div 2) (e + 1))
   455                            else if m = 0 then 0 else Float m e)"
   456   by transfer (auto simp add: powr_add zmod_eq_0_iff)
   457 hide_fact (open) compute_normfloat
   458 
   459 lemma compute_float_numeral[code_abbrev]: "Float (numeral k) 0 = numeral k"
   460   by transfer simp
   461 hide_fact (open) compute_float_numeral
   462 
   463 lemma compute_float_neg_numeral[code_abbrev]: "Float (- numeral k) 0 = - numeral k"
   464   by transfer simp
   465 hide_fact (open) compute_float_neg_numeral
   466 
   467 lemma compute_float_uminus[code]: "- Float m1 e1 = Float (- m1) e1"
   468   by transfer simp
   469 hide_fact (open) compute_float_uminus
   470 
   471 lemma compute_float_times[code]: "Float m1 e1 * Float m2 e2 = Float (m1 * m2) (e1 + e2)"
   472   by transfer (simp add: field_simps powr_add)
   473 hide_fact (open) compute_float_times
   474 
   475 lemma compute_float_plus[code]: "Float m1 e1 + Float m2 e2 =
   476   (if m1 = 0 then Float m2 e2 else if m2 = 0 then Float m1 e1 else
   477   if e1 \<le> e2 then Float (m1 + m2 * 2^nat (e2 - e1)) e1
   478               else Float (m2 + m1 * 2^nat (e1 - e2)) e2)"
   479   by transfer (simp add: field_simps powr_realpow[symmetric] powr_divide2[symmetric])
   480 hide_fact (open) compute_float_plus
   481 
   482 lemma compute_float_minus[code]: fixes f g::float shows "f - g = f + (-g)"
   483   by simp
   484 hide_fact (open) compute_float_minus
   485 
   486 lemma compute_float_sgn[code]: "sgn (Float m1 e1) = (if 0 < m1 then 1 else if m1 < 0 then -1 else 0)"
   487   by transfer (simp add: sgn_times)
   488 hide_fact (open) compute_float_sgn
   489 
   490 lift_definition is_float_pos :: "float \<Rightarrow> bool" is "op < 0 :: real \<Rightarrow> bool" .
   491 
   492 lemma compute_is_float_pos[code]: "is_float_pos (Float m e) \<longleftrightarrow> 0 < m"
   493   by transfer (auto simp add: zero_less_mult_iff not_le[symmetric, of _ 0])
   494 hide_fact (open) compute_is_float_pos
   495 
   496 lemma compute_float_less[code]: "a < b \<longleftrightarrow> is_float_pos (b - a)"
   497   by transfer (simp add: field_simps)
   498 hide_fact (open) compute_float_less
   499 
   500 lift_definition is_float_nonneg :: "float \<Rightarrow> bool" is "op \<le> 0 :: real \<Rightarrow> bool" .
   501 
   502 lemma compute_is_float_nonneg[code]: "is_float_nonneg (Float m e) \<longleftrightarrow> 0 \<le> m"
   503   by transfer (auto simp add: zero_le_mult_iff not_less[symmetric, of _ 0])
   504 hide_fact (open) compute_is_float_nonneg
   505 
   506 lemma compute_float_le[code]: "a \<le> b \<longleftrightarrow> is_float_nonneg (b - a)"
   507   by transfer (simp add: field_simps)
   508 hide_fact (open) compute_float_le
   509 
   510 lift_definition is_float_zero :: "float \<Rightarrow> bool"  is "op = 0 :: real \<Rightarrow> bool" .
   511 
   512 lemma compute_is_float_zero[code]: "is_float_zero (Float m e) \<longleftrightarrow> 0 = m"
   513   by transfer (auto simp add: is_float_zero_def)
   514 hide_fact (open) compute_is_float_zero
   515 
   516 lemma compute_float_abs[code]: "abs (Float m e) = Float (abs m) e"
   517   by transfer (simp add: abs_mult)
   518 hide_fact (open) compute_float_abs
   519 
   520 lemma compute_float_eq[code]: "equal_class.equal f g = is_float_zero (f - g)"
   521   by transfer simp
   522 hide_fact (open) compute_float_eq
   523 
   524 
   525 subsection {* Lemmas for types @{typ real}, @{typ nat}, @{typ int}*}
   526 
   527 lemmas real_of_ints =
   528   real_of_int_zero
   529   real_of_one
   530   real_of_int_add
   531   real_of_int_minus
   532   real_of_int_diff
   533   real_of_int_mult
   534   real_of_int_power
   535   real_numeral
   536 lemmas real_of_nats =
   537   real_of_nat_zero
   538   real_of_nat_one
   539   real_of_nat_1
   540   real_of_nat_add
   541   real_of_nat_mult
   542   real_of_nat_power
   543 
   544 lemmas int_of_reals = real_of_ints[symmetric]
   545 lemmas nat_of_reals = real_of_nats[symmetric]
   546 
   547 lemma two_real_int: "(2::real) = real (2::int)" by simp
   548 lemma two_real_nat: "(2::real) = real (2::nat)" by simp
   549 
   550 
   551 subsection {* Rounding Real Numbers *}
   552 
   553 definition round_down :: "int \<Rightarrow> real \<Rightarrow> real" where
   554   "round_down prec x = floor (x * 2 powr prec) * 2 powr -prec"
   555 
   556 definition round_up :: "int \<Rightarrow> real \<Rightarrow> real" where
   557   "round_up prec x = ceiling (x * 2 powr prec) * 2 powr -prec"
   558 
   559 lemma round_down_float[simp]: "round_down prec x \<in> float"
   560   unfolding round_down_def
   561   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   562 
   563 lemma round_up_float[simp]: "round_up prec x \<in> float"
   564   unfolding round_up_def
   565   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   566 
   567 lemma round_up: "x \<le> round_up prec x"
   568   by (simp add: powr_minus_divide le_divide_eq round_up_def)
   569 
   570 lemma round_down: "round_down prec x \<le> x"
   571   by (simp add: powr_minus_divide divide_le_eq round_down_def)
   572 
   573 lemma round_up_0[simp]: "round_up p 0 = 0"
   574   unfolding round_up_def by simp
   575 
   576 lemma round_down_0[simp]: "round_down p 0 = 0"
   577   unfolding round_down_def by simp
   578 
   579 lemma round_up_diff_round_down:
   580   "round_up prec x - round_down prec x \<le> 2 powr -prec"
   581 proof -
   582   have "round_up prec x - round_down prec x =
   583     (ceiling (x * 2 powr prec) - floor (x * 2 powr prec)) * 2 powr -prec"
   584     by (simp add: round_up_def round_down_def field_simps)
   585   also have "\<dots> \<le> 1 * 2 powr -prec"
   586     by (rule mult_mono)
   587        (auto simp del: real_of_int_diff
   588              simp: real_of_int_diff[symmetric] real_of_int_le_one_cancel_iff ceiling_diff_floor_le_1)
   589   finally show ?thesis by simp
   590 qed
   591 
   592 lemma round_down_shift: "round_down p (x * 2 powr k) = 2 powr k * round_down (p + k) x"
   593   unfolding round_down_def
   594   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   595     (simp add: powr_add[symmetric])
   596 
   597 lemma round_up_shift: "round_up p (x * 2 powr k) = 2 powr k * round_up (p + k) x"
   598   unfolding round_up_def
   599   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   600     (simp add: powr_add[symmetric])
   601 
   602 lemma round_up_uminus_eq: "round_up p (-x) = - round_down p x"
   603   and round_down_uminus_eq: "round_down p (-x) = - round_up p x"
   604   by (auto simp: round_up_def round_down_def ceiling_def)
   605 
   606 lemma round_up_mono: "x \<le> y \<Longrightarrow> round_up p x \<le> round_up p y"
   607   by (auto intro!: ceiling_mono simp: round_up_def)
   608 
   609 lemma round_up_le1:
   610   assumes "x \<le> 1" "prec \<ge> 0"
   611   shows "round_up prec x \<le> 1"
   612 proof -
   613   have "real \<lceil>x * 2 powr prec\<rceil> \<le> real \<lceil>2 powr real prec\<rceil>"
   614     using assms by (auto intro!: ceiling_mono)
   615   also have "\<dots> = 2 powr prec" using assms by (auto simp: powr_int intro!: exI[where x="2^nat prec"])
   616   finally show ?thesis
   617     by (simp add: round_up_def) (simp add: powr_minus inverse_eq_divide)
   618 qed
   619 
   620 lemma round_up_less1:
   621   assumes "x < 1 / 2" "p > 0"
   622   shows "round_up p x < 1"
   623 proof -
   624   have powr1: "2 powr p = 2 ^ nat p"
   625     using `p > 0` by (simp add: powr_realpow[symmetric])
   626   have "x * 2 powr p < 1 / 2 * 2 powr p"
   627     using assms by simp
   628   also have "\<dots> = 2 powr (p - 1)"
   629     by (simp add: algebra_simps powr_mult_base)
   630   also have "\<dots> = 2 ^ nat (p - 1)"
   631     using `p > 0` by (simp add: powr_realpow[symmetric])
   632   also have "\<dots> \<le> 2 ^ nat p - 1"
   633     using `p > 0`
   634     unfolding int_of_reals real_of_int_le_iff
   635     by simp
   636   finally show ?thesis
   637     apply (simp add: round_up_def field_simps powr_minus powr1)
   638     unfolding int_of_reals real_of_int_less_iff
   639     apply (simp add: ceiling_less_eq)
   640     done
   641 qed
   642 
   643 lemma round_down_ge1:
   644   assumes x: "x \<ge> 1"
   645   assumes prec: "p \<ge> - log 2 x"
   646   shows "1 \<le> round_down p x"
   647 proof cases
   648   assume nonneg: "0 \<le> p"
   649   have "2 powr p = real \<lfloor>2 powr real p\<rfloor>"
   650     using nonneg by (auto simp: powr_int)
   651   also have "\<dots> \<le> real \<lfloor>x * 2 powr p\<rfloor>"
   652     using assms by (auto intro!: floor_mono)
   653   finally show ?thesis
   654     by (simp add: round_down_def) (simp add: powr_minus inverse_eq_divide)
   655 next
   656   assume neg: "\<not> 0 \<le> p"
   657   have "x = 2 powr (log 2 x)"
   658     using x by simp
   659   also have "2 powr (log 2 x) \<ge> 2 powr - p"
   660     using prec by auto
   661   finally have x_le: "x \<ge> 2 powr -p" .
   662 
   663   from neg have "2 powr real p \<le> 2 powr 0"
   664     by (intro powr_mono) auto
   665   also have "\<dots> \<le> \<lfloor>2 powr 0\<rfloor>" by simp
   666   also have "\<dots> \<le> \<lfloor>x * 2 powr real p\<rfloor>" unfolding real_of_int_le_iff
   667     using x x_le by (intro floor_mono) (simp add: powr_minus_divide field_simps)
   668   finally show ?thesis
   669     using prec x
   670     by (simp add: round_down_def powr_minus_divide pos_le_divide_eq)
   671 qed
   672 
   673 lemma round_up_le0: "x \<le> 0 \<Longrightarrow> round_up p x \<le> 0"
   674   unfolding round_up_def
   675   by (auto simp: field_simps mult_le_0_iff zero_le_mult_iff)
   676 
   677 
   678 subsection {* Rounding Floats *}
   679 
   680 definition div_twopow::"int \<Rightarrow> nat \<Rightarrow> int" where [simp]: "div_twopow x n = x div (2 ^ n)"
   681 
   682 definition mod_twopow::"int \<Rightarrow> nat \<Rightarrow> int" where [simp]: "mod_twopow x n = x mod (2 ^ n)"
   683 
   684 lemma compute_div_twopow[code]:
   685   "div_twopow x n = (if x = 0 \<or> x = -1 \<or> n = 0 then x else div_twopow (x div 2) (n - 1))"
   686   by (cases n) (auto simp: zdiv_zmult2_eq div_eq_minus1)
   687 
   688 lemma compute_mod_twopow[code]:
   689   "mod_twopow x n = (if n = 0 then 0 else x mod 2 + 2 * mod_twopow (x div 2) (n - 1))"
   690   by (cases n) (auto simp: zmod_zmult2_eq)
   691 
   692 lift_definition float_up :: "int \<Rightarrow> float \<Rightarrow> float" is round_up by simp
   693 declare float_up.rep_eq[simp]
   694 
   695 lemma round_up_correct:
   696   shows "round_up e f - f \<in> {0..2 powr -e}"
   697 unfolding atLeastAtMost_iff
   698 proof
   699   have "round_up e f - f \<le> round_up e f - round_down e f" using round_down by simp
   700   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   701   finally show "round_up e f - f \<le> 2 powr real (- e)"
   702     by simp
   703 qed (simp add: algebra_simps round_up)
   704 
   705 lemma float_up_correct:
   706   shows "real (float_up e f) - real f \<in> {0..2 powr -e}"
   707   by transfer (rule round_up_correct)
   708 
   709 lift_definition float_down :: "int \<Rightarrow> float \<Rightarrow> float" is round_down by simp
   710 declare float_down.rep_eq[simp]
   711 
   712 lemma round_down_correct:
   713   shows "f - (round_down e f) \<in> {0..2 powr -e}"
   714 unfolding atLeastAtMost_iff
   715 proof
   716   have "f - round_down e f \<le> round_up e f - round_down e f" using round_up by simp
   717   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   718   finally show "f - round_down e f \<le> 2 powr real (- e)"
   719     by simp
   720 qed (simp add: algebra_simps round_down)
   721 
   722 lemma float_down_correct:
   723   shows "real f - real (float_down e f) \<in> {0..2 powr -e}"
   724   by transfer (rule round_down_correct)
   725 
   726 lemma compute_float_down[code]:
   727   "float_down p (Float m e) =
   728     (if p + e < 0 then Float (div_twopow m (nat (-(p + e)))) (-p) else Float m e)"
   729 proof cases
   730   assume "p + e < 0"
   731   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   732     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   733   also have "... = 1 / 2 powr p / 2 powr e"
   734     unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   735   finally show ?thesis
   736     using `p + e < 0`
   737     by transfer (simp add: ac_simps round_down_def floor_divide_eq_div[symmetric])
   738 next
   739   assume "\<not> p + e < 0"
   740   then have r: "real e + real p = real (nat (e + p))" by simp
   741   have r: "\<lfloor>(m * 2 powr e) * 2 powr real p\<rfloor> = (m * 2 powr e) * 2 powr real p"
   742     by (auto intro: exI[where x="m*2^nat (e+p)"]
   743              simp add: ac_simps powr_add[symmetric] r powr_realpow)
   744   with `\<not> p + e < 0` show ?thesis
   745     by transfer (auto simp add: round_down_def field_simps powr_add powr_minus)
   746 qed
   747 hide_fact (open) compute_float_down
   748 
   749 lemma abs_round_down_le: "\<bar>f - (round_down e f)\<bar> \<le> 2 powr -e"
   750   using round_down_correct[of f e] by simp
   751 
   752 lemma abs_round_up_le: "\<bar>f - (round_up e f)\<bar> \<le> 2 powr -e"
   753   using round_up_correct[of e f] by simp
   754 
   755 lemma round_down_nonneg: "0 \<le> s \<Longrightarrow> 0 \<le> round_down p s"
   756   by (auto simp: round_down_def)
   757 
   758 lemma ceil_divide_floor_conv:
   759 assumes "b \<noteq> 0"
   760 shows "\<lceil>real a / real b\<rceil> = (if b dvd a then a div b else \<lfloor>real a / real b\<rfloor> + 1)"
   761 proof cases
   762   assume "\<not> b dvd a"
   763   hence "a mod b \<noteq> 0" by auto
   764   hence ne: "real (a mod b) / real b \<noteq> 0" using `b \<noteq> 0` by auto
   765   have "\<lceil>real a / real b\<rceil> = \<lfloor>real a / real b\<rfloor> + 1"
   766   apply (rule ceiling_eq) apply (auto simp: floor_divide_eq_div[symmetric])
   767   proof -
   768     have "real \<lfloor>real a / real b\<rfloor> \<le> real a / real b" by simp
   769     moreover have "real \<lfloor>real a / real b\<rfloor> \<noteq> real a / real b"
   770     apply (subst (2) real_of_int_div_aux) unfolding floor_divide_eq_div using ne `b \<noteq> 0` by auto
   771     ultimately show "real \<lfloor>real a / real b\<rfloor> < real a / real b" by arith
   772   qed
   773   thus ?thesis using `\<not> b dvd a` by simp
   774 qed (simp add: ceiling_def real_of_int_minus[symmetric] divide_minus_left[symmetric]
   775   floor_divide_eq_div dvd_neg_div del: divide_minus_left real_of_int_minus)
   776 
   777 lemma compute_float_up[code]:
   778   "float_up p x = - float_down p (-x)"
   779   by transfer (simp add: round_down_uminus_eq)
   780 hide_fact (open) compute_float_up
   781 
   782 
   783 subsection {* Compute bitlen of integers *}
   784 
   785 definition bitlen :: "int \<Rightarrow> int" where
   786   "bitlen a = (if a > 0 then \<lfloor>log 2 a\<rfloor> + 1 else 0)"
   787 
   788 lemma bitlen_nonneg: "0 \<le> bitlen x"
   789 proof -
   790   {
   791     assume "0 > x"
   792     have "-1 = log 2 (inverse 2)" by (subst log_inverse) simp_all
   793     also have "... < log 2 (-x)" using `0 > x` by auto
   794     finally have "-1 < log 2 (-x)" .
   795   } thus "0 \<le> bitlen x" unfolding bitlen_def by (auto intro!: add_nonneg_nonneg)
   796 qed
   797 
   798 lemma bitlen_bounds:
   799   assumes "x > 0"
   800   shows "2 ^ nat (bitlen x - 1) \<le> x \<and> x < 2 ^ nat (bitlen x)"
   801 proof
   802   have "(2::real) ^ nat \<lfloor>log 2 (real x)\<rfloor> = 2 powr real (floor (log 2 (real x)))"
   803     using powr_realpow[symmetric, of 2 "nat \<lfloor>log 2 (real x)\<rfloor>"] `x > 0`
   804     using real_nat_eq_real[of "floor (log 2 (real x))"]
   805     by simp
   806   also have "... \<le> 2 powr log 2 (real x)"
   807     by simp
   808   also have "... = real x"
   809     using `0 < x` by simp
   810   finally have "2 ^ nat \<lfloor>log 2 (real x)\<rfloor> \<le> real x" by simp
   811   thus "2 ^ nat (bitlen x - 1) \<le> x" using `x > 0`
   812     by (simp add: bitlen_def)
   813 next
   814   have "x \<le> 2 powr (log 2 x)" using `x > 0` by simp
   815   also have "... < 2 ^ nat (\<lfloor>log 2 (real x)\<rfloor> + 1)"
   816     apply (simp add: powr_realpow[symmetric])
   817     using `x > 0` by simp
   818   finally show "x < 2 ^ nat (bitlen x)" using `x > 0`
   819     by (simp add: bitlen_def ac_simps int_of_reals del: real_of_ints)
   820 qed
   821 
   822 lemma bitlen_pow2[simp]:
   823   assumes "b > 0"
   824   shows "bitlen (b * 2 ^ c) = bitlen b + c"
   825 proof -
   826   from assms have "b * 2 ^ c > 0" by auto
   827   thus ?thesis
   828     using floor_add[of "log 2 b" c] assms
   829     by (auto simp add: log_mult log_nat_power bitlen_def)
   830 qed
   831 
   832 lemma bitlen_Float:
   833   fixes m e
   834   defines "f \<equiv> Float m e"
   835   shows "bitlen (\<bar>mantissa f\<bar>) + exponent f = (if m = 0 then 0 else bitlen \<bar>m\<bar> + e)"
   836 proof (cases "m = 0")
   837   case True
   838   then show ?thesis by (simp add: f_def bitlen_def Float_def)
   839 next
   840   case False
   841   hence "f \<noteq> float_of 0"
   842     unfolding real_of_float_eq by (simp add: f_def)
   843   hence "mantissa f \<noteq> 0"
   844     by (simp add: mantissa_noteq_0)
   845   moreover
   846   obtain i where "m = mantissa f * 2 ^ i" "e = exponent f - int i"
   847     by (rule f_def[THEN denormalize_shift, OF `f \<noteq> float_of 0`])
   848   ultimately show ?thesis by (simp add: abs_mult)
   849 qed
   850 
   851 lemma compute_bitlen[code]:
   852   shows "bitlen x = (if x > 0 then bitlen (x div 2) + 1 else 0)"
   853 proof -
   854   { assume "2 \<le> x"
   855     then have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 (x - x mod 2)\<rfloor>"
   856       by (simp add: log_mult zmod_zdiv_equality')
   857     also have "\<dots> = \<lfloor>log 2 (real x)\<rfloor>"
   858     proof cases
   859       assume "x mod 2 = 0" then show ?thesis by simp
   860     next
   861       def n \<equiv> "\<lfloor>log 2 (real x)\<rfloor>"
   862       then have "0 \<le> n"
   863         using `2 \<le> x` by simp
   864       assume "x mod 2 \<noteq> 0"
   865       with `2 \<le> x` have "x mod 2 = 1" "\<not> 2 dvd x" by (auto simp add: dvd_eq_mod_eq_0)
   866       with `2 \<le> x` have "x \<noteq> 2^nat n" by (cases "nat n") auto
   867       moreover
   868       { have "real (2^nat n :: int) = 2 powr (nat n)"
   869           by (simp add: powr_realpow)
   870         also have "\<dots> \<le> 2 powr (log 2 x)"
   871           using `2 \<le> x` by (simp add: n_def del: powr_log_cancel)
   872         finally have "2^nat n \<le> x" using `2 \<le> x` by simp }
   873       ultimately have "2^nat n \<le> x - 1" by simp
   874       then have "2^nat n \<le> real (x - 1)"
   875         unfolding real_of_int_le_iff[symmetric] by simp
   876       { have "n = \<lfloor>log 2 (2^nat n)\<rfloor>"
   877           using `0 \<le> n` by (simp add: log_nat_power)
   878         also have "\<dots> \<le> \<lfloor>log 2 (x - 1)\<rfloor>"
   879           using `2^nat n \<le> real (x - 1)` `0 \<le> n` `2 \<le> x` by (auto intro: floor_mono)
   880         finally have "n \<le> \<lfloor>log 2 (x - 1)\<rfloor>" . }
   881       moreover have "\<lfloor>log 2 (x - 1)\<rfloor> \<le> n"
   882         using `2 \<le> x` by (auto simp add: n_def intro!: floor_mono)
   883       ultimately show "\<lfloor>log 2 (x - x mod 2)\<rfloor> = \<lfloor>log 2 x\<rfloor>"
   884         unfolding n_def `x mod 2 = 1` by auto
   885     qed
   886     finally have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 x\<rfloor>" . }
   887   moreover
   888   { assume "x < 2" "0 < x"
   889     then have "x = 1" by simp
   890     then have "\<lfloor>log 2 (real x)\<rfloor> = 0" by simp }
   891   ultimately show ?thesis
   892     unfolding bitlen_def
   893     by (auto simp: pos_imp_zdiv_pos_iff not_le)
   894 qed
   895 hide_fact (open) compute_bitlen
   896 
   897 lemma float_gt1_scale: assumes "1 \<le> Float m e"
   898   shows "0 \<le> e + (bitlen m - 1)"
   899 proof -
   900   have "0 < Float m e" using assms by auto
   901   hence "0 < m" using powr_gt_zero[of 2 e]
   902     by (auto simp: zero_less_mult_iff)
   903   hence "m \<noteq> 0" by auto
   904   show ?thesis
   905   proof (cases "0 \<le> e")
   906     case True thus ?thesis using `0 < m`  by (simp add: bitlen_def)
   907   next
   908     have "(1::int) < 2" by simp
   909     case False let ?S = "2^(nat (-e))"
   910     have "inverse (2 ^ nat (- e)) = 2 powr e" using assms False powr_realpow[of 2 "nat (-e)"]
   911       by (auto simp: powr_minus field_simps)
   912     hence "1 \<le> real m * inverse ?S" using assms False powr_realpow[of 2 "nat (-e)"]
   913       by (auto simp: powr_minus)
   914     hence "1 * ?S \<le> real m * inverse ?S * ?S" by (rule mult_right_mono, auto)
   915     hence "?S \<le> real m" unfolding mult.assoc by auto
   916     hence "?S \<le> m" unfolding real_of_int_le_iff[symmetric] by auto
   917     from this bitlen_bounds[OF `0 < m`, THEN conjunct2]
   918     have "nat (-e) < (nat (bitlen m))" unfolding power_strict_increasing_iff[OF `1 < 2`, symmetric]
   919       by (rule order_le_less_trans)
   920     hence "-e < bitlen m" using False by auto
   921     thus ?thesis by auto
   922   qed
   923 qed
   924 
   925 lemma bitlen_div:
   926   assumes "0 < m"
   927   shows "1 \<le> real m / 2^nat (bitlen m - 1)" and "real m / 2^nat (bitlen m - 1) < 2"
   928 proof -
   929   let ?B = "2^nat(bitlen m - 1)"
   930 
   931   have "?B \<le> m" using bitlen_bounds[OF `0 <m`] ..
   932   hence "1 * ?B \<le> real m" unfolding real_of_int_le_iff[symmetric] by auto
   933   thus "1 \<le> real m / ?B" by auto
   934 
   935   have "m \<noteq> 0" using assms by auto
   936   have "0 \<le> bitlen m - 1" using `0 < m` by (auto simp: bitlen_def)
   937 
   938   have "m < 2^nat(bitlen m)" using bitlen_bounds[OF `0 <m`] ..
   939   also have "\<dots> = 2^nat(bitlen m - 1 + 1)" using `0 < m` by (auto simp: bitlen_def)
   940   also have "\<dots> = ?B * 2" unfolding nat_add_distrib[OF `0 \<le> bitlen m - 1` zero_le_one] by auto
   941   finally have "real m < 2 * ?B" unfolding real_of_int_less_iff[symmetric] by auto
   942   hence "real m / ?B < 2 * ?B / ?B" by (rule divide_strict_right_mono, auto)
   943   thus "real m / ?B < 2" by auto
   944 qed
   945 
   946 subsection {* Truncating Real Numbers*}
   947 
   948 definition truncate_down::"nat \<Rightarrow> real \<Rightarrow> real" where
   949   "truncate_down prec x = round_down (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x"
   950 
   951 lemma truncate_down: "truncate_down prec x \<le> x"
   952   using round_down by (simp add: truncate_down_def)
   953 
   954 lemma truncate_down_le: "x \<le> y \<Longrightarrow> truncate_down prec x \<le> y"
   955   by (rule order_trans[OF truncate_down])
   956 
   957 lemma truncate_down_zero[simp]: "truncate_down prec 0 = 0"
   958   by (simp add: truncate_down_def)
   959 
   960 lemma truncate_down_float[simp]: "truncate_down p x \<in> float"
   961   by (auto simp: truncate_down_def)
   962 
   963 definition truncate_up::"nat \<Rightarrow> real \<Rightarrow> real" where
   964   "truncate_up prec x = round_up (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x"
   965 
   966 lemma truncate_up: "x \<le> truncate_up prec x"
   967   using round_up by (simp add: truncate_up_def)
   968 
   969 lemma truncate_up_le: "x \<le> y \<Longrightarrow> x \<le> truncate_up prec y"
   970   by (rule order_trans[OF _ truncate_up])
   971 
   972 lemma truncate_up_zero[simp]: "truncate_up prec 0 = 0"
   973   by (simp add: truncate_up_def)
   974 
   975 lemma truncate_up_uminus_eq: "truncate_up prec (-x) = - truncate_down prec x"
   976   and truncate_down_uminus_eq: "truncate_down prec (-x) = - truncate_up prec x"
   977   by (auto simp: truncate_up_def round_up_def truncate_down_def round_down_def ceiling_def)
   978 
   979 lemma truncate_up_float[simp]: "truncate_up p x \<in> float"
   980   by (auto simp: truncate_up_def)
   981 
   982 lemma mult_powr_eq: "0 < b \<Longrightarrow> b \<noteq> 1 \<Longrightarrow> 0 < x \<Longrightarrow> x * b powr y = b powr (y + log b x)"
   983   by (simp_all add: powr_add)
   984 
   985 lemma truncate_down_pos:
   986   assumes "x > 0" "p > 0"
   987   shows "truncate_down p x > 0"
   988 proof -
   989   have "0 \<le> log 2 x - real \<lfloor>log 2 x\<rfloor>"
   990     by (simp add: algebra_simps)
   991   from this assms
   992   show ?thesis
   993     by (auto simp: truncate_down_def round_down_def mult_powr_eq
   994       intro!: ge_one_powr_ge_zero mult_pos_pos)
   995 qed
   996 
   997 lemma truncate_down_nonneg: "0 \<le> y \<Longrightarrow> 0 \<le> truncate_down prec y"
   998   by (auto simp: truncate_down_def round_down_def)
   999 
  1000 lemma truncate_down_ge1: "1 \<le> x \<Longrightarrow> 1 \<le> p \<Longrightarrow> 1 \<le> truncate_down p x"
  1001   by (auto simp: truncate_down_def algebra_simps intro!: round_down_ge1 add_mono)
  1002 
  1003 lemma truncate_up_nonpos: "x \<le> 0 \<Longrightarrow> truncate_up prec x \<le> 0"
  1004   by (auto simp: truncate_up_def round_up_def intro!: mult_nonpos_nonneg)
  1005 
  1006 lemma truncate_up_le1:
  1007   assumes "x \<le> 1" "1 \<le> p" shows "truncate_up p x \<le> 1"
  1008 proof -
  1009   {
  1010     assume "x \<le> 0"
  1011     with truncate_up_nonpos[OF this, of p] have ?thesis by simp
  1012   } moreover {
  1013     assume "x > 0"
  1014     hence le: "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> \<le> 0"
  1015       using assms by (auto simp: log_less_iff)
  1016     from assms have "1 \<le> int p" by simp
  1017     from add_mono[OF this le]
  1018     have ?thesis using assms
  1019       by (simp add: truncate_up_def round_up_le1 add_mono)
  1020   } ultimately show ?thesis by arith
  1021 qed
  1022 
  1023 subsection {* Truncating Floats*}
  1024 
  1025 lift_definition float_round_up :: "nat \<Rightarrow> float \<Rightarrow> float" is truncate_up
  1026   by (simp add: truncate_up_def)
  1027 
  1028 lemma float_round_up: "real x \<le> real (float_round_up prec x)"
  1029   using truncate_up by transfer simp
  1030 
  1031 lemma float_round_up_zero[simp]: "float_round_up prec 0 = 0"
  1032   by transfer simp
  1033 
  1034 lift_definition float_round_down :: "nat \<Rightarrow> float \<Rightarrow> float" is truncate_down
  1035   by (simp add: truncate_down_def)
  1036 
  1037 lemma float_round_down: "real (float_round_down prec x) \<le> real x"
  1038   using truncate_down by transfer simp
  1039 
  1040 lemma float_round_down_zero[simp]: "float_round_down prec 0 = 0"
  1041   by transfer simp
  1042 
  1043 lemmas float_round_up_le = order_trans[OF _ float_round_up]
  1044   and float_round_down_le = order_trans[OF float_round_down]
  1045 
  1046 lemma minus_float_round_up_eq: "- float_round_up prec x = float_round_down prec (- x)"
  1047   and minus_float_round_down_eq: "- float_round_down prec x = float_round_up prec (- x)"
  1048   by (transfer, simp add: truncate_down_uminus_eq truncate_up_uminus_eq)+
  1049 
  1050 lemma compute_float_round_down[code]:
  1051   "float_round_down prec (Float m e) = (let d = bitlen (abs m) - int prec in
  1052     if 0 < d then Float (div_twopow m (nat d)) (e + d)
  1053              else Float m e)"
  1054   using Float.compute_float_down[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1055   by transfer (simp add: field_simps abs_mult log_mult bitlen_def truncate_down_def
  1056     cong del: if_weak_cong)
  1057 hide_fact (open) compute_float_round_down
  1058 
  1059 lemma compute_float_round_up[code]:
  1060   "float_round_up prec x = - float_round_down prec (-x)"
  1061   by transfer (simp add: truncate_down_uminus_eq)
  1062 hide_fact (open) compute_float_round_up
  1063 
  1064 
  1065 subsection {* Approximation of positive rationals *}
  1066 
  1067 lemma div_mult_twopow_eq: fixes a b::nat shows "a div ((2::nat) ^ n) div b = a div (b * 2 ^ n)"
  1068   by (cases "b=0") (simp_all add: div_mult2_eq[symmetric] ac_simps)
  1069 
  1070 lemma real_div_nat_eq_floor_of_divide:
  1071   fixes a b::nat
  1072   shows "a div b = real (floor (a/b))"
  1073 by (metis floor_divide_eq_div real_of_int_of_nat_eq zdiv_int)
  1074 
  1075 definition "rat_precision prec x y = int prec - (bitlen x - bitlen y)"
  1076 
  1077 lift_definition lapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
  1078   is "\<lambda>prec (x::nat) (y::nat). round_down (rat_precision prec x y) (x / y)" by simp
  1079 
  1080 lemma compute_lapprox_posrat[code]:
  1081   fixes prec x y
  1082   shows "lapprox_posrat prec x y =
  1083    (let
  1084        l = rat_precision prec x y;
  1085        d = if 0 \<le> l then x * 2^nat l div y else x div 2^nat (- l) div y
  1086     in normfloat (Float d (- l)))"
  1087     unfolding div_mult_twopow_eq
  1088     by transfer
  1089        (simp add: round_down_def powr_int real_div_nat_eq_floor_of_divide field_simps Let_def
  1090              del: two_powr_minus_int_float)
  1091 hide_fact (open) compute_lapprox_posrat
  1092 
  1093 lift_definition rapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
  1094   is "\<lambda>prec (x::nat) (y::nat). round_up (rat_precision prec x y) (x / y)" by simp
  1095 
  1096 lemma compute_rapprox_posrat[code]:
  1097   fixes prec x y
  1098   notes divmod_int_mod_div[simp]
  1099   defines "l \<equiv> rat_precision prec x y"
  1100   shows "rapprox_posrat prec x y = (let
  1101      l = l ;
  1102      X = if 0 \<le> l then (x * 2^nat l, y) else (x, y * 2^nat(-l)) ;
  1103      (d, m) = divmod_int (fst X) (snd X)
  1104    in normfloat (Float (d + (if m = 0 \<or> y = 0 then 0 else 1)) (- l)))"
  1105 proof (cases "y = 0")
  1106   assume "y = 0" thus ?thesis by transfer simp
  1107 next
  1108   assume "y \<noteq> 0"
  1109   show ?thesis
  1110   proof (cases "0 \<le> l")
  1111     assume "0 \<le> l"
  1112     def x' \<equiv> "x * 2 ^ nat l"
  1113     have "int x * 2 ^ nat l = x'" by (simp add: x'_def int_mult int_power)
  1114     moreover have "real x * 2 powr real l = real x'"
  1115       by (simp add: powr_realpow[symmetric] `0 \<le> l` x'_def)
  1116     ultimately show ?thesis
  1117       using ceil_divide_floor_conv[of y x'] powr_realpow[of 2 "nat l"] `0 \<le> l` `y \<noteq> 0`
  1118         l_def[symmetric, THEN meta_eq_to_obj_eq]
  1119       by transfer (auto simp add: floor_divide_eq_div [symmetric] round_up_def)
  1120    next
  1121     assume "\<not> 0 \<le> l"
  1122     def y' \<equiv> "y * 2 ^ nat (- l)"
  1123     from `y \<noteq> 0` have "y' \<noteq> 0" by (simp add: y'_def)
  1124     have "int y * 2 ^ nat (- l) = y'" by (simp add: y'_def int_mult int_power)
  1125     moreover have "real x * real (2::int) powr real l / real y = x / real y'"
  1126       using `\<not> 0 \<le> l`
  1127       by (simp add: powr_realpow[symmetric] powr_minus y'_def field_simps)
  1128     ultimately show ?thesis
  1129       using ceil_divide_floor_conv[of y' x] `\<not> 0 \<le> l` `y' \<noteq> 0` `y \<noteq> 0`
  1130         l_def[symmetric, THEN meta_eq_to_obj_eq]
  1131       by transfer
  1132          (auto simp add: round_up_def ceil_divide_floor_conv floor_divide_eq_div [symmetric])
  1133   qed
  1134 qed
  1135 hide_fact (open) compute_rapprox_posrat
  1136 
  1137 lemma rat_precision_pos:
  1138   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
  1139   shows "rat_precision n (int x) (int y) > 0"
  1140 proof -
  1141   { assume "0 < x" hence "log 2 x + 1 = log 2 (2 * x)" by (simp add: log_mult) }
  1142   hence "bitlen (int x) < bitlen (int y)" using assms
  1143     by (simp add: bitlen_def del: floor_add_one)
  1144       (auto intro!: floor_mono simp add: floor_add_one[symmetric] simp del: floor_add floor_add_one)
  1145   thus ?thesis
  1146     using assms by (auto intro!: pos_add_strict simp add: field_simps rat_precision_def)
  1147 qed
  1148 
  1149 lemma rapprox_posrat_less1:
  1150   shows "0 \<le> x \<Longrightarrow> 0 < y \<Longrightarrow> 2 * x < y \<Longrightarrow> 0 < n \<Longrightarrow> real (rapprox_posrat n x y) < 1"
  1151   by transfer (simp add: rat_precision_pos round_up_less1)
  1152 
  1153 lift_definition lapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
  1154   "\<lambda>prec (x::int) (y::int). round_down (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
  1155 
  1156 lemma compute_lapprox_rat[code]:
  1157   "lapprox_rat prec x y =
  1158     (if y = 0 then 0
  1159     else if 0 \<le> x then
  1160       (if 0 < y then lapprox_posrat prec (nat x) (nat y)
  1161       else - (rapprox_posrat prec (nat x) (nat (-y))))
  1162       else (if 0 < y
  1163         then - (rapprox_posrat prec (nat (-x)) (nat y))
  1164         else lapprox_posrat prec (nat (-x)) (nat (-y))))"
  1165   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
  1166 hide_fact (open) compute_lapprox_rat
  1167 
  1168 lift_definition rapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
  1169   "\<lambda>prec (x::int) (y::int). round_up (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
  1170 
  1171 lemma "rapprox_rat = rapprox_posrat"
  1172   by transfer auto
  1173 
  1174 lemma "lapprox_rat = lapprox_posrat"
  1175   by transfer auto
  1176 
  1177 lemma compute_rapprox_rat[code]:
  1178   "rapprox_rat prec x y = - lapprox_rat prec (-x) y"
  1179   by transfer (simp add: round_down_uminus_eq)
  1180 hide_fact (open) compute_rapprox_rat
  1181 
  1182 subsection {* Division *}
  1183 
  1184 definition "real_divl prec a b = round_down (int prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)"
  1185 
  1186 definition "real_divr prec a b = round_up (int prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)"
  1187 
  1188 lift_definition float_divl :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is real_divl
  1189   by (simp add: real_divl_def)
  1190 
  1191 lemma compute_float_divl[code]:
  1192   "float_divl prec (Float m1 s1) (Float m2 s2) = lapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1193 proof cases
  1194   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1195   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1196   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1197   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1198     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1199   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1200     by (simp add: field_simps powr_divide2[symmetric])
  1201 
  1202   show ?thesis
  1203     using not_0
  1204     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_down_shift real_divl_def,
  1205       simp add: field_simps)
  1206 qed (transfer, auto simp: real_divl_def)
  1207 hide_fact (open) compute_float_divl
  1208 
  1209 lift_definition float_divr :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is real_divr
  1210   by (simp add: real_divr_def)
  1211 
  1212 lemma compute_float_divr[code]:
  1213   "float_divr prec x y = - float_divl prec (-x) y"
  1214   by transfer (simp add: real_divr_def real_divl_def round_down_uminus_eq)
  1215 hide_fact (open) compute_float_divr
  1216 
  1217 
  1218 subsection {* Approximate Power *}
  1219 
  1220 lemma div2_less_self[termination_simp]: fixes n::nat shows "odd n \<Longrightarrow> n div 2 < n"
  1221   by (simp add: odd_pos)
  1222 
  1223 fun power_down :: "nat \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> real" where
  1224   "power_down p x 0 = 1"
  1225 | "power_down p x (Suc n) =
  1226     (if odd n then truncate_down (Suc p) ((power_down p x (Suc n div 2))\<^sup>2) else truncate_down (Suc p) (x * power_down p x n))"
  1227 
  1228 fun power_up :: "nat \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> real" where
  1229   "power_up p x 0 = 1"
  1230 | "power_up p x (Suc n) =
  1231     (if odd n then truncate_up p ((power_up p x (Suc n div 2))\<^sup>2) else truncate_up p (x * power_up p x n))"
  1232 
  1233 lift_definition power_up_fl :: "nat \<Rightarrow> float \<Rightarrow> nat \<Rightarrow> float" is power_up
  1234   by (induct_tac rule: power_up.induct) simp_all
  1235 
  1236 lift_definition power_down_fl :: "nat \<Rightarrow> float \<Rightarrow> nat \<Rightarrow> float" is power_down
  1237   by (induct_tac rule: power_down.induct) simp_all
  1238 
  1239 lemma power_float_transfer[transfer_rule]:
  1240   "(rel_fun pcr_float (rel_fun op = pcr_float)) op ^ op ^"
  1241   unfolding power_def
  1242   by transfer_prover
  1243 
  1244 lemma compute_power_up_fl[code]:
  1245   "power_up_fl p x 0 = 1"
  1246   "power_up_fl p x (Suc n) =
  1247     (if odd n then float_round_up p ((power_up_fl p x (Suc n div 2))\<^sup>2) else float_round_up p (x * power_up_fl p x n))"
  1248   and compute_power_down_fl[code]:
  1249   "power_down_fl p x 0 = 1"
  1250   "power_down_fl p x (Suc n) =
  1251     (if odd n then float_round_down (Suc p) ((power_down_fl p x (Suc n div 2))\<^sup>2) else float_round_down (Suc p) (x * power_down_fl p x n))"
  1252   unfolding atomize_conj
  1253   by transfer simp
  1254 
  1255 lemma power_down_pos: "0 < x \<Longrightarrow> 0 < power_down p x n"
  1256   by (induct p x n rule: power_down.induct)
  1257     (auto simp del: odd_Suc_div_two intro!: truncate_down_pos)
  1258 
  1259 lemma power_down_nonneg: "0 \<le> x \<Longrightarrow> 0 \<le> power_down p x n"
  1260   by (induct p x n rule: power_down.induct)
  1261     (auto simp del: odd_Suc_div_two intro!: truncate_down_nonneg mult_nonneg_nonneg)
  1262 
  1263 lemma power_down: "0 \<le> x \<Longrightarrow> power_down p x n \<le> x ^ n"
  1264 proof (induct p x n rule: power_down.induct)
  1265   case (2 p x n)
  1266   {
  1267     assume "odd n"
  1268     hence "(power_down p x (Suc n div 2)) ^ 2 \<le> (x ^ (Suc n div 2)) ^ 2"
  1269       using 2
  1270       by (auto intro: power_mono power_down_nonneg simp del: odd_Suc_div_two)
  1271     also have "\<dots> = x ^ (Suc n div 2 * 2)"
  1272       by (simp add: power_mult[symmetric])
  1273     also have "Suc n div 2 * 2 = Suc n"
  1274       using `odd n` by presburger
  1275     finally have ?case
  1276       using `odd n`
  1277       by (auto intro!: truncate_down_le simp del: odd_Suc_div_two)
  1278   } thus ?case
  1279     by (auto intro!: truncate_down_le mult_left_mono 2 mult_nonneg_nonneg power_down_nonneg)
  1280 qed simp
  1281 
  1282 lemma power_up: "0 \<le> x \<Longrightarrow> x ^ n \<le> power_up p x n"
  1283 proof (induct p x n rule: power_up.induct)
  1284   case (2 p x n)
  1285   {
  1286     assume "odd n"
  1287     hence "Suc n = Suc n div 2 * 2"
  1288       using `odd n` even_Suc by presburger
  1289     hence "x ^ Suc n \<le> (x ^ (Suc n div 2))\<^sup>2"
  1290       by (simp add: power_mult[symmetric])
  1291     also have "\<dots> \<le> (power_up p x (Suc n div 2))\<^sup>2"
  1292       using 2 `odd n`
  1293       by (auto intro: power_mono simp del: odd_Suc_div_two )
  1294     finally have ?case
  1295       using `odd n`
  1296       by (auto intro!: truncate_up_le simp del: odd_Suc_div_two )
  1297   } thus ?case
  1298     by (auto intro!: truncate_up_le mult_left_mono 2)
  1299 qed simp
  1300 
  1301 lemmas power_up_le = order_trans[OF _ power_up]
  1302   and power_up_less = less_le_trans[OF _ power_up]
  1303   and power_down_le = order_trans[OF power_down]
  1304 
  1305 lemma power_down_fl: "0 \<le> x \<Longrightarrow> power_down_fl p x n \<le> x ^ n"
  1306   by transfer (rule power_down)
  1307 
  1308 lemma power_up_fl: "0 \<le> x \<Longrightarrow> x ^ n \<le> power_up_fl p x n"
  1309   by transfer (rule power_up)
  1310 
  1311 lemma real_power_up_fl: "real (power_up_fl p x n) = power_up p x n"
  1312   by transfer simp
  1313 
  1314 lemma real_power_down_fl: "real (power_down_fl p x n) = power_down p x n"
  1315   by transfer simp
  1316 
  1317 
  1318 subsection {* Approximate Addition *}
  1319 
  1320 definition "plus_down prec x y = truncate_down prec (x + y)"
  1321 
  1322 definition "plus_up prec x y = truncate_up prec (x + y)"
  1323 
  1324 lemma float_plus_down_float[intro, simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> plus_down p x y \<in> float"
  1325   by (simp add: plus_down_def)
  1326 
  1327 lemma float_plus_up_float[intro, simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> plus_up p x y \<in> float"
  1328   by (simp add: plus_up_def)
  1329 
  1330 lift_definition float_plus_down::"nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is plus_down ..
  1331 
  1332 lift_definition float_plus_up::"nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is plus_up ..
  1333 
  1334 lemma plus_down: "plus_down prec x y \<le> x + y"
  1335   and plus_up: "x + y \<le> plus_up prec x y"
  1336   by (auto simp: plus_down_def truncate_down plus_up_def truncate_up)
  1337 
  1338 lemma float_plus_down: "real (float_plus_down prec x y) \<le> x + y"
  1339   and float_plus_up: "x + y \<le> real (float_plus_up prec x y)"
  1340   by (transfer, rule plus_down plus_up)+
  1341 
  1342 lemmas plus_down_le = order_trans[OF plus_down]
  1343   and plus_up_le = order_trans[OF _ plus_up]
  1344   and float_plus_down_le = order_trans[OF float_plus_down]
  1345   and float_plus_up_le = order_trans[OF _ float_plus_up]
  1346 
  1347 lemma compute_plus_up[code]: "plus_up p x y = - plus_down p (-x) (-y)"
  1348   using truncate_down_uminus_eq[of p "x + y"]
  1349   by (auto simp: plus_down_def plus_up_def)
  1350 
  1351 lemma
  1352   truncate_down_log2_eqI:
  1353   assumes "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> = \<lfloor>log 2 \<bar>y\<bar>\<rfloor>"
  1354   assumes "\<lfloor>x * 2 powr (p - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1)\<rfloor> = \<lfloor>y * 2 powr (p - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1)\<rfloor>"
  1355   shows "truncate_down p x = truncate_down p y"
  1356   using assms by (auto simp: truncate_down_def round_down_def)
  1357 
  1358 lemma bitlen_eq_zero_iff: "bitlen x = 0 \<longleftrightarrow> x \<le> 0"
  1359   by (clarsimp simp add: bitlen_def)
  1360     (metis Float.compute_bitlen add.commute bitlen_def bitlen_nonneg less_add_same_cancel2 not_less
  1361       zero_less_one)
  1362 
  1363 lemma
  1364   sum_neq_zeroI:
  1365   fixes a k::real
  1366   shows "abs a \<ge> k \<Longrightarrow> abs b < k \<Longrightarrow> a + b \<noteq> 0"
  1367     and "abs a > k \<Longrightarrow> abs b \<le> k \<Longrightarrow> a + b \<noteq> 0"
  1368   by auto
  1369 
  1370 lemma
  1371   abs_real_le_2_powr_bitlen[simp]:
  1372   "\<bar>real m2\<bar> < 2 powr real (bitlen \<bar>m2\<bar>)"
  1373 proof cases
  1374   assume "m2 \<noteq> 0"
  1375   hence "\<bar>m2\<bar> < 2 ^ nat (bitlen \<bar>m2\<bar>)"
  1376     using bitlen_bounds[of "\<bar>m2\<bar>"]
  1377     by (auto simp: powr_add bitlen_nonneg)
  1378   thus ?thesis
  1379     by (simp add: powr_int bitlen_nonneg real_of_int_less_iff[symmetric])
  1380 qed simp
  1381 
  1382 lemma floor_sum_times_2_powr_sgn_eq:
  1383   fixes ai p q::int
  1384   and a b::real
  1385   assumes "a * 2 powr p = ai"
  1386   assumes b_le_1: "abs (b * 2 powr (p + 1)) \<le> 1"
  1387   assumes leqp: "q \<le> p"
  1388   shows "\<lfloor>(a + b) * 2 powr q\<rfloor> = \<lfloor>(2 * ai + sgn b) * 2 powr (q - p - 1)\<rfloor>"
  1389 proof -
  1390   {
  1391     assume "b = 0"
  1392     hence ?thesis
  1393       by (simp add: assms(1)[symmetric] powr_add[symmetric] algebra_simps powr_mult_base)
  1394   } moreover {
  1395     assume "b > 0"
  1396     hence "b * 2 powr p < abs (b * 2 powr (p + 1))" by simp
  1397     also note b_le_1
  1398     finally have b_less_1: "b * 2 powr real p < 1" .
  1399 
  1400     from b_less_1 `b > 0` have floor_eq: "\<lfloor>b * 2 powr real p\<rfloor> = 0" "\<lfloor>sgn b / 2\<rfloor> = 0"
  1401       by (simp_all add: floor_eq_iff)
  1402 
  1403     have "\<lfloor>(a + b) * 2 powr q\<rfloor> = \<lfloor>(a + b) * 2 powr p * 2 powr (q - p)\<rfloor>"
  1404       by (simp add: algebra_simps powr_realpow[symmetric] powr_add[symmetric])
  1405     also have "\<dots> = \<lfloor>(ai + b * 2 powr p) * 2 powr (q - p)\<rfloor>"
  1406       by (simp add: assms algebra_simps)
  1407     also have "\<dots> = \<lfloor>(ai + b * 2 powr p) / real ((2::int) ^ nat (p - q))\<rfloor>"
  1408       using assms
  1409       by (simp add: algebra_simps powr_realpow[symmetric] divide_powr_uminus powr_add[symmetric])
  1410     also have "\<dots> = \<lfloor>ai / real ((2::int) ^ nat (p - q))\<rfloor>"
  1411       by (simp del: real_of_int_power add: floor_divide_real_eq_div floor_eq)
  1412     finally have "\<lfloor>(a + b) * 2 powr real q\<rfloor> = \<lfloor>real ai / real ((2::int) ^ nat (p - q))\<rfloor>" .
  1413     moreover
  1414     {
  1415       have "\<lfloor>(2 * ai + sgn b) * 2 powr (real (q - p) - 1)\<rfloor> = \<lfloor>(ai + sgn b / 2) * 2 powr (q - p)\<rfloor>"
  1416         by (subst powr_divide2[symmetric]) (simp add: field_simps)
  1417       also have "\<dots> = \<lfloor>(ai + sgn b / 2) / real ((2::int) ^ nat (p - q))\<rfloor>"
  1418         using leqp by (simp add: powr_realpow[symmetric] powr_divide2[symmetric])
  1419       also have "\<dots> = \<lfloor>ai / real ((2::int) ^ nat (p - q))\<rfloor>"
  1420         by (simp del: real_of_int_power add: floor_divide_real_eq_div floor_eq)
  1421       finally
  1422       have "\<lfloor>(2 * ai + (sgn b)) * 2 powr (real (q - p) - 1)\<rfloor> =
  1423           \<lfloor>real ai / real ((2::int) ^ nat (p - q))\<rfloor>"
  1424         .
  1425     } ultimately have ?thesis by simp
  1426   } moreover {
  1427     assume "\<not> 0 \<le> b"
  1428     hence "0 > b" by simp
  1429     hence floor_eq: "\<lfloor>b * 2 powr (real p + 1)\<rfloor> = -1"
  1430       using b_le_1
  1431       by (auto simp: floor_eq_iff algebra_simps pos_divide_le_eq[symmetric] abs_if divide_powr_uminus
  1432         intro!: mult_neg_pos split: split_if_asm)
  1433     have "\<lfloor>(a + b) * 2 powr q\<rfloor> = \<lfloor>(2*a + 2*b) * 2 powr p * 2 powr (q - p - 1)\<rfloor>"
  1434       by (simp add: algebra_simps powr_realpow[symmetric] powr_add[symmetric] powr_mult_base)
  1435     also have "\<dots> = \<lfloor>(2 * (a * 2 powr p) + 2 * b * 2 powr p) * 2 powr (q - p - 1)\<rfloor>"
  1436       by (simp add: algebra_simps)
  1437     also have "\<dots> = \<lfloor>(2 * ai + b * 2 powr (p + 1)) / 2 powr (1 - q + p)\<rfloor>"
  1438       using assms by (simp add: algebra_simps powr_mult_base divide_powr_uminus)
  1439     also have "\<dots> = \<lfloor>(2 * ai + b * 2 powr (p + 1)) / real ((2::int) ^ nat (p - q + 1))\<rfloor>"
  1440       using assms by (simp add: algebra_simps powr_realpow[symmetric])
  1441     also have "\<dots> = \<lfloor>(2 * ai - 1) / real ((2::int) ^ nat (p - q + 1))\<rfloor>"
  1442       using `b < 0` assms
  1443       by (simp add: floor_divide_eq_div floor_eq floor_divide_real_eq_div
  1444         del: real_of_int_mult real_of_int_power real_of_int_diff)
  1445     also have "\<dots> = \<lfloor>(2 * ai - 1) * 2 powr (q - p - 1)\<rfloor>"
  1446       using assms by (simp add: algebra_simps divide_powr_uminus powr_realpow[symmetric])
  1447     finally have ?thesis using `b < 0` by simp
  1448   } ultimately show ?thesis by arith
  1449 qed
  1450 
  1451 lemma
  1452   log2_abs_int_add_less_half_sgn_eq:
  1453   fixes ai::int and b::real
  1454   assumes "abs b \<le> 1/2" "ai \<noteq> 0"
  1455   shows "\<lfloor>log 2 \<bar>real ai + b\<bar>\<rfloor> = \<lfloor>log 2 \<bar>ai + sgn b / 2\<bar>\<rfloor>"
  1456 proof cases
  1457   assume "b = 0" thus ?thesis by simp
  1458 next
  1459   assume "b \<noteq> 0"
  1460   def k \<equiv> "\<lfloor>log 2 \<bar>ai\<bar>\<rfloor>"
  1461   hence "\<lfloor>log 2 \<bar>ai\<bar>\<rfloor> = k" by simp
  1462   hence k: "2 powr k \<le> \<bar>ai\<bar>" "\<bar>ai\<bar> < 2 powr (k + 1)"
  1463     by (simp_all add: floor_log_eq_powr_iff `ai \<noteq> 0`)
  1464   have "k \<ge> 0"
  1465     using assms by (auto simp: k_def)
  1466   def r \<equiv> "\<bar>ai\<bar> - 2 ^ nat k"
  1467   have r: "0 \<le> r" "r < 2 powr k"
  1468     using `k \<ge> 0` k
  1469     by (auto simp: r_def k_def algebra_simps powr_add abs_if powr_int)
  1470   hence "r \<le> (2::int) ^ nat k - 1"
  1471     using `k \<ge> 0` by (auto simp: powr_int)
  1472   from this[simplified real_of_int_le_iff[symmetric]] `0 \<le> k`
  1473   have r_le: "r \<le> 2 powr k - 1"
  1474     by (auto simp: algebra_simps powr_int simp del: real_of_int_le_iff)
  1475 
  1476   have "\<bar>ai\<bar> = 2 powr k + r"
  1477     using `k \<ge> 0` by (auto simp: k_def r_def powr_realpow[symmetric])
  1478 
  1479   have pos: "\<And>b::real. abs b < 1 \<Longrightarrow> 0 < 2 powr k + (r + b)"
  1480     using `0 \<le> k` `ai \<noteq> 0`
  1481     by (auto simp add: r_def powr_realpow[symmetric] abs_if sgn_if algebra_simps
  1482       split: split_if_asm)
  1483   have less: "\<bar>sgn ai * b\<bar> < 1"
  1484     and less': "\<bar>sgn (sgn ai * b) / 2\<bar> < 1"
  1485     using `abs b \<le> _` by (auto simp: abs_if sgn_if split: split_if_asm)
  1486 
  1487   have floor_eq: "\<And>b::real. abs b \<le> 1 / 2 \<Longrightarrow>
  1488       \<lfloor>log 2 (1 + (r + b) / 2 powr k)\<rfloor> = (if r = 0 \<and> b < 0 then -1 else 0)"
  1489     using `k \<ge> 0` r r_le
  1490     by (auto simp: floor_log_eq_powr_iff powr_minus_divide field_simps sgn_if)
  1491 
  1492   from `real \<bar>ai\<bar> = _` have "\<bar>ai + b\<bar> = 2 powr k + (r + sgn ai * b)"
  1493     using `abs b <= _` `0 \<le> k` r
  1494     by (auto simp add: sgn_if abs_if)
  1495   also have "\<lfloor>log 2 \<dots>\<rfloor> = \<lfloor>log 2 (2 powr k + r + sgn (sgn ai * b) / 2)\<rfloor>"
  1496   proof -
  1497     have "2 powr k + (r + (sgn ai) * b) = 2 powr k * (1 + (r + sgn ai * b) / 2 powr k)"
  1498       by (simp add: field_simps)
  1499     also have "\<lfloor>log 2 \<dots>\<rfloor> = k + \<lfloor>log 2 (1 + (r + sgn ai * b) / 2 powr k)\<rfloor>"
  1500       using pos[OF less]
  1501       by (subst log_mult) (simp_all add: log_mult powr_mult field_simps)
  1502     also
  1503     let ?if = "if r = 0 \<and> sgn ai * b < 0 then -1 else 0"
  1504     have "\<lfloor>log 2 (1 + (r + sgn ai * b) / 2 powr k)\<rfloor> = ?if"
  1505       using `abs b <= _`
  1506       by (intro floor_eq) (auto simp: abs_mult sgn_if)
  1507     also
  1508     have "\<dots> = \<lfloor>log 2 (1 + (r + sgn (sgn ai * b) / 2) / 2 powr k)\<rfloor>"
  1509       by (subst floor_eq) (auto simp: sgn_if)
  1510     also have "k + \<dots> = \<lfloor>log 2 (2 powr k * (1 + (r + sgn (sgn ai * b) / 2) / 2 powr k))\<rfloor>"
  1511       unfolding floor_add2[symmetric]
  1512       using pos[OF less'] `abs b \<le> _`
  1513       by (simp add: field_simps add_log_eq_powr)
  1514     also have "2 powr k * (1 + (r + sgn (sgn ai * b) / 2) / 2 powr k) =
  1515         2 powr k + r + sgn (sgn ai * b) / 2"
  1516       by (simp add: sgn_if field_simps)
  1517     finally show ?thesis .
  1518   qed
  1519   also have "2 powr k + r + sgn (sgn ai * b) / 2 = \<bar>ai + sgn b / 2\<bar>"
  1520     unfolding `real \<bar>ai\<bar> = _`[symmetric] using `ai \<noteq> 0`
  1521     by (auto simp: abs_if sgn_if algebra_simps)
  1522   finally show ?thesis .
  1523 qed
  1524 
  1525 lemma compute_far_float_plus_down:
  1526   fixes m1 e1 m2 e2::int and p::nat
  1527   defines "k1 \<equiv> p - nat (bitlen \<bar>m1\<bar>)"
  1528   assumes H: "bitlen \<bar>m2\<bar> \<le> e1 - e2 - k1 - 2" "m1 \<noteq> 0" "m2 \<noteq> 0" "e1 \<ge> e2"
  1529   shows "float_plus_down p (Float m1 e1) (Float m2 e2) =
  1530     float_round_down p (Float (m1 * 2 ^ (Suc (Suc k1)) + sgn m2) (e1 - int k1 - 2))"
  1531 proof -
  1532   let ?a = "real (Float m1 e1)"
  1533   let ?b = "real (Float m2 e2)"
  1534   let ?sum = "?a + ?b"
  1535   let ?shift = "real e2 - real e1 + real k1 + 1"
  1536   let ?m1 = "m1 * 2 ^ Suc k1"
  1537   let ?m2 = "m2 * 2 powr ?shift"
  1538   let ?m2' = "sgn m2 / 2"
  1539   let ?e = "e1 - int k1 - 1"
  1540 
  1541   have sum_eq: "?sum = (?m1 + ?m2) * 2 powr ?e"
  1542     by (auto simp: powr_add[symmetric] powr_mult[symmetric] algebra_simps
  1543       powr_realpow[symmetric] powr_mult_base)
  1544 
  1545   have "\<bar>?m2\<bar> * 2 < 2 powr (bitlen \<bar>m2\<bar> + ?shift + 1)"
  1546     by (auto simp: field_simps powr_add powr_mult_base powr_numeral powr_divide2[symmetric] abs_mult)
  1547   also have "\<dots> \<le> 2 powr 0"
  1548     using H by (intro powr_mono) auto
  1549   finally have abs_m2_less_half: "\<bar>?m2\<bar> < 1 / 2"
  1550     by simp
  1551 
  1552   hence "\<bar>real m2\<bar> < 2 powr -(?shift + 1)"
  1553     unfolding powr_minus_divide by (auto simp: bitlen_def field_simps powr_mult_base abs_mult)
  1554   also have "\<dots> \<le> 2 powr real (e1 - e2 - 2)"
  1555     by simp
  1556   finally have b_less_quarter: "\<bar>?b\<bar> < 1/4 * 2 powr real e1"
  1557     by (simp add: powr_add field_simps powr_divide2[symmetric] powr_numeral abs_mult)
  1558   also have "1/4 < \<bar>real m1\<bar> / 2" using `m1 \<noteq> 0` by simp
  1559   finally have b_less_half_a: "\<bar>?b\<bar> < 1/2 * \<bar>?a\<bar>"
  1560     by (simp add: algebra_simps powr_mult_base abs_mult)
  1561   hence a_half_less_sum: "\<bar>?a\<bar> / 2 < \<bar>?sum\<bar>"
  1562     by (auto simp: field_simps abs_if split: split_if_asm)
  1563 
  1564   from b_less_half_a have "\<bar>?b\<bar> < \<bar>?a\<bar>" "\<bar>?b\<bar> \<le> \<bar>?a\<bar>"
  1565     by simp_all
  1566 
  1567   have "\<bar>real (Float m1 e1)\<bar> \<ge> 1/4 * 2 powr real e1"
  1568     using `m1 \<noteq> 0`
  1569     by (auto simp: powr_add powr_int bitlen_nonneg divide_right_mono abs_mult)
  1570   hence "?sum \<noteq> 0" using b_less_quarter
  1571     by (rule sum_neq_zeroI)
  1572   hence "?m1 + ?m2 \<noteq> 0"
  1573     unfolding sum_eq by (simp add: abs_mult zero_less_mult_iff)
  1574 
  1575   have "\<bar>real ?m1\<bar> \<ge> 2 ^ Suc k1" "\<bar>?m2'\<bar> < 2 ^ Suc k1"
  1576     using `m1 \<noteq> 0` `m2 \<noteq> 0` by (auto simp: sgn_if less_1_mult abs_mult simp del: power.simps)
  1577   hence sum'_nz: "?m1 + ?m2' \<noteq> 0"
  1578     by (intro sum_neq_zeroI)
  1579 
  1580   have "\<lfloor>log 2 \<bar>real (Float m1 e1) + real (Float m2 e2)\<bar>\<rfloor> = \<lfloor>log 2 \<bar>?m1 + ?m2\<bar>\<rfloor> + ?e"
  1581     using `?m1 + ?m2 \<noteq> 0`
  1582     unfolding floor_add[symmetric] sum_eq
  1583     by (simp add: abs_mult log_mult)
  1584   also have "\<lfloor>log 2 \<bar>?m1 + ?m2\<bar>\<rfloor> = \<lfloor>log 2 \<bar>?m1 + sgn (real m2 * 2 powr ?shift) / 2\<bar>\<rfloor>"
  1585     using abs_m2_less_half `m1 \<noteq> 0`
  1586     by (intro log2_abs_int_add_less_half_sgn_eq) (auto simp: abs_mult)
  1587   also have "sgn (real m2 * 2 powr ?shift) = sgn m2"
  1588     by (auto simp: sgn_if zero_less_mult_iff less_not_sym)
  1589   also
  1590   have "\<bar>?m1 + ?m2'\<bar> * 2 powr ?e = \<bar>?m1 * 2 + sgn m2\<bar> * 2 powr (?e - 1)"
  1591     by (auto simp: field_simps powr_minus[symmetric] powr_divide2[symmetric] powr_mult_base)
  1592   hence "\<lfloor>log 2 \<bar>?m1 + ?m2'\<bar>\<rfloor> + ?e = \<lfloor>log 2 \<bar>real (Float (?m1 * 2 + sgn m2) (?e - 1))\<bar>\<rfloor>"
  1593     using `?m1 + ?m2' \<noteq> 0`
  1594     unfolding floor_add[symmetric]
  1595     by (simp add: log_add_eq_powr abs_mult_pos)
  1596   finally
  1597   have "\<lfloor>log 2 \<bar>?sum\<bar>\<rfloor> = \<lfloor>log 2 \<bar>real (Float (?m1*2 + sgn m2) (?e - 1))\<bar>\<rfloor>" .
  1598   hence "plus_down p (Float m1 e1) (Float m2 e2) =
  1599       truncate_down p (Float (?m1*2 + sgn m2) (?e - 1))"
  1600     unfolding plus_down_def
  1601   proof (rule truncate_down_log2_eqI)
  1602     let ?f = "(int p - \<lfloor>log 2 \<bar>real (Float m1 e1) + real (Float m2 e2)\<bar>\<rfloor> - 1)"
  1603     let ?ai = "m1 * 2 ^ (Suc k1)"
  1604     have "\<lfloor>(?a + ?b) * 2 powr real ?f\<rfloor> = \<lfloor>(real (2 * ?ai) + sgn ?b) * 2 powr real (?f - - ?e - 1)\<rfloor>"
  1605     proof (rule floor_sum_times_2_powr_sgn_eq)
  1606       show "?a * 2 powr real (-?e) = real ?ai"
  1607         by (simp add: powr_add powr_realpow[symmetric] powr_divide2[symmetric])
  1608       show "\<bar>?b * 2 powr real (-?e + 1)\<bar> \<le> 1"
  1609         using abs_m2_less_half
  1610         by (simp add: abs_mult powr_add[symmetric] algebra_simps powr_mult_base)
  1611     next
  1612       have "e1 + \<lfloor>log 2 \<bar>real m1\<bar>\<rfloor> - 1 = \<lfloor>log 2 \<bar>?a\<bar>\<rfloor> - 1"
  1613         using `m1 \<noteq> 0`
  1614         by (simp add: floor_add2[symmetric] algebra_simps log_mult abs_mult del: floor_add2)
  1615       also have "\<dots> \<le> \<lfloor>log 2 \<bar>?a + ?b\<bar>\<rfloor>"
  1616         using a_half_less_sum `m1 \<noteq> 0` `?sum \<noteq> 0`
  1617         unfolding floor_subtract[symmetric]
  1618         by (auto simp add: log_minus_eq_powr powr_minus_divide
  1619           intro!: floor_mono)
  1620       finally
  1621       have "int p - \<lfloor>log 2 \<bar>?a + ?b\<bar>\<rfloor> \<le> p - (bitlen \<bar>m1\<bar>) - e1 + 2"
  1622         by (auto simp: algebra_simps bitlen_def `m1 \<noteq> 0`)
  1623       also have "\<dots> \<le> 1 - ?e"
  1624         using bitlen_nonneg[of "\<bar>m1\<bar>"] by (simp add: k1_def)
  1625       finally show "?f \<le> - ?e" by simp
  1626     qed
  1627     also have "sgn ?b = sgn m2"
  1628       using powr_gt_zero[of 2 e2]
  1629       by (auto simp add: sgn_if zero_less_mult_iff simp del: powr_gt_zero)
  1630     also have "\<lfloor>(real (2 * ?m1) + real (sgn m2)) * 2 powr real (?f - - ?e - 1)\<rfloor> =
  1631         \<lfloor>Float (?m1 * 2 + sgn m2) (?e - 1) * 2 powr ?f\<rfloor>"
  1632       by (simp add: powr_add[symmetric] algebra_simps powr_realpow[symmetric])
  1633     finally
  1634     show "\<lfloor>(?a + ?b) * 2 powr ?f\<rfloor> = \<lfloor>real (Float (?m1 * 2 + sgn m2) (?e - 1)) * 2 powr ?f\<rfloor>" .
  1635   qed
  1636   thus ?thesis
  1637     by transfer (simp add: plus_down_def ac_simps Let_def)
  1638 qed
  1639 
  1640 lemma compute_float_plus_down_naive[code]: "float_plus_down p x y = float_round_down p (x + y)"
  1641   by transfer (auto simp: plus_down_def)
  1642 
  1643 lemma compute_float_plus_down[code]:
  1644   fixes p::nat and m1 e1 m2 e2::int
  1645   shows "float_plus_down p (Float m1 e1) (Float m2 e2) =
  1646     (if m1 = 0 then float_round_down p (Float m2 e2)
  1647     else if m2 = 0 then float_round_down p (Float m1 e1)
  1648     else (if e1 \<ge> e2 then
  1649       (let
  1650         k1 = p - nat (bitlen \<bar>m1\<bar>)
  1651       in
  1652         if bitlen \<bar>m2\<bar> > e1 - e2 - k1 - 2 then float_round_down p ((Float m1 e1) + (Float m2 e2))
  1653         else float_round_down p (Float (m1 * 2 ^ (Suc (Suc k1)) + sgn m2) (e1 - int k1 - 2)))
  1654     else float_plus_down p (Float m2 e2) (Float m1 e1)))"
  1655 proof -
  1656   {
  1657     assume H: "bitlen \<bar>m2\<bar> \<le> e1 - e2 - (p - nat (bitlen \<bar>m1\<bar>)) - 2" "m1 \<noteq> 0" "m2 \<noteq> 0" "e1 \<ge> e2"
  1658     note compute_far_float_plus_down[OF H]
  1659   }
  1660   thus ?thesis
  1661     by transfer (simp add: Let_def plus_down_def ac_simps)
  1662 qed
  1663 hide_fact (open) compute_far_float_plus_down
  1664 hide_fact (open) compute_float_plus_down
  1665 
  1666 lemma compute_float_plus_up[code]: "float_plus_up p x y = - float_plus_down p (-x) (-y)"
  1667   using truncate_down_uminus_eq[of p "x + y"]
  1668   by transfer (simp add: plus_down_def plus_up_def ac_simps)
  1669 hide_fact (open) compute_float_plus_up
  1670 
  1671 lemma mantissa_zero[simp]: "mantissa 0 = 0"
  1672 by (metis mantissa_0 zero_float.abs_eq)
  1673 
  1674 
  1675 subsection {* Lemmas needed by Approximate *}
  1676 
  1677 lemma Float_num[simp]: shows
  1678    "real (Float 1 0) = 1" and "real (Float 1 1) = 2" and "real (Float 1 2) = 4" and
  1679    "real (Float 1 (- 1)) = 1/2" and "real (Float 1 (- 2)) = 1/4" and "real (Float 1 (- 3)) = 1/8" and
  1680    "real (Float (- 1) 0) = -1" and "real (Float (number_of n) 0) = number_of n"
  1681 using two_powr_int_float[of 2] two_powr_int_float[of "-1"] two_powr_int_float[of "-2"] two_powr_int_float[of "-3"]
  1682 using powr_realpow[of 2 2] powr_realpow[of 2 3]
  1683 using powr_minus[of 2 1] powr_minus[of 2 2] powr_minus[of 2 3]
  1684 by auto
  1685 
  1686 lemma real_of_Float_int[simp]: "real (Float n 0) = real n" by simp
  1687 
  1688 lemma float_zero[simp]: "real (Float 0 e) = 0" by simp
  1689 
  1690 lemma abs_div_2_less: "a \<noteq> 0 \<Longrightarrow> a \<noteq> -1 \<Longrightarrow> abs((a::int) div 2) < abs a"
  1691 by arith
  1692 
  1693 lemma lapprox_rat:
  1694   shows "real (lapprox_rat prec x y) \<le> real x / real y"
  1695   using round_down by (simp add: lapprox_rat_def)
  1696 
  1697 lemma mult_div_le: fixes a b:: int assumes "b > 0" shows "a \<ge> b * (a div b)"
  1698 proof -
  1699   from zmod_zdiv_equality'[of a b]
  1700   have "a = b * (a div b) + a mod b" by simp
  1701   also have "... \<ge> b * (a div b) + 0" apply (rule add_left_mono) apply (rule pos_mod_sign)
  1702   using assms by simp
  1703   finally show ?thesis by simp
  1704 qed
  1705 
  1706 lemma lapprox_rat_nonneg:
  1707   fixes n x y
  1708   assumes "0 \<le> x" and "0 \<le> y"
  1709   shows "0 \<le> real (lapprox_rat n x y)"
  1710   using assms by (auto simp: lapprox_rat_def simp: round_down_nonneg)
  1711 
  1712 lemma rapprox_rat: "real x / real y \<le> real (rapprox_rat prec x y)"
  1713   using round_up by (simp add: rapprox_rat_def)
  1714 
  1715 lemma rapprox_rat_le1:
  1716   fixes n x y
  1717   assumes xy: "0 \<le> x" "0 < y" "x \<le> y"
  1718   shows "real (rapprox_rat n x y) \<le> 1"
  1719 proof -
  1720   have "bitlen \<bar>x\<bar> \<le> bitlen \<bar>y\<bar>"
  1721     using xy unfolding bitlen_def by (auto intro!: floor_mono)
  1722   from this assms show ?thesis
  1723     by transfer (auto intro!: round_up_le1 simp: rat_precision_def)
  1724 qed
  1725 
  1726 lemma rapprox_rat_nonneg_nonpos:
  1727   "0 \<le> x \<Longrightarrow> y \<le> 0 \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1728   by transfer (simp add: round_up_le0 divide_nonneg_nonpos)
  1729 
  1730 lemma rapprox_rat_nonpos_nonneg:
  1731   "x \<le> 0 \<Longrightarrow> 0 \<le> y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1732   by transfer (simp add: round_up_le0 divide_nonpos_nonneg)
  1733 
  1734 lemma real_divl: "real_divl prec x y \<le> x / y"
  1735   by (simp add: real_divl_def round_down)
  1736 
  1737 lemma real_divr: "x / y \<le> real_divr prec x y"
  1738   using round_up by (simp add: real_divr_def)
  1739 
  1740 lemma float_divl: "real (float_divl prec x y) \<le> real x / real y"
  1741   by transfer (rule real_divl)
  1742 
  1743 lemma real_divl_lower_bound:
  1744   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> 0 \<le> real_divl prec x y"
  1745   by (simp add: real_divl_def round_down_nonneg)
  1746 
  1747 lemma float_divl_lower_bound:
  1748   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> 0 \<le> real (float_divl prec x y)"
  1749   by transfer (rule real_divl_lower_bound)
  1750 
  1751 lemma exponent_1: "exponent 1 = 0"
  1752   using exponent_float[of 1 0] by (simp add: one_float_def)
  1753 
  1754 lemma mantissa_1: "mantissa 1 = 1"
  1755   using mantissa_float[of 1 0] by (simp add: one_float_def)
  1756 
  1757 lemma bitlen_1: "bitlen 1 = 1"
  1758   by (simp add: bitlen_def)
  1759 
  1760 lemma mantissa_eq_zero_iff: "mantissa x = 0 \<longleftrightarrow> x = 0"
  1761 proof
  1762   assume "mantissa x = 0" hence z: "0 = real x" using mantissa_exponent by simp
  1763   show "x = 0" by (simp add: zero_float_def z)
  1764 qed (simp add: zero_float_def)
  1765 
  1766 lemma float_upper_bound: "x \<le> 2 powr (bitlen \<bar>mantissa x\<bar> + exponent x)"
  1767 proof (cases "x = 0", simp)
  1768   assume "x \<noteq> 0" hence "mantissa x \<noteq> 0" using mantissa_eq_zero_iff by auto
  1769   have "x = mantissa x * 2 powr (exponent x)" by (rule mantissa_exponent)
  1770   also have "mantissa x \<le> \<bar>mantissa x\<bar>" by simp
  1771   also have "... \<le> 2 powr (bitlen \<bar>mantissa x\<bar>)"
  1772     using bitlen_bounds[of "\<bar>mantissa x\<bar>"] bitlen_nonneg `mantissa x \<noteq> 0`
  1773     by (simp add: powr_int) (simp only: two_real_int int_of_reals real_of_int_abs[symmetric]
  1774       real_of_int_le_iff less_imp_le)
  1775   finally show ?thesis by (simp add: powr_add)
  1776 qed
  1777 
  1778 lemma real_divl_pos_less1_bound:
  1779   assumes "0 < x" "x \<le> 1" "prec \<ge> 1"
  1780   shows "1 \<le> real_divl prec 1 x"
  1781 proof -
  1782   have "log 2 x \<le> real prec + real \<lfloor>log 2 x\<rfloor>" using `prec \<ge> 1` by arith
  1783   from this assms show ?thesis
  1784     by (simp add: real_divl_def log_divide round_down_ge1)
  1785 qed
  1786 
  1787 lemma float_divl_pos_less1_bound:
  1788   "0 < real x \<Longrightarrow> real x \<le> 1 \<Longrightarrow> prec \<ge> 1 \<Longrightarrow> 1 \<le> real (float_divl prec 1 x)"
  1789   by (transfer, rule real_divl_pos_less1_bound)
  1790 
  1791 lemma float_divr: "real x / real y \<le> real (float_divr prec x y)"
  1792   by transfer (rule real_divr)
  1793 
  1794 lemma real_divr_pos_less1_lower_bound: assumes "0 < x" and "x \<le> 1" shows "1 \<le> real_divr prec 1 x"
  1795 proof -
  1796   have "1 \<le> 1 / x" using `0 < x` and `x <= 1` by auto
  1797   also have "\<dots> \<le> real_divr prec 1 x" using real_divr[where x=1 and y=x] by auto
  1798   finally show ?thesis by auto
  1799 qed
  1800 
  1801 lemma float_divr_pos_less1_lower_bound: "0 < x \<Longrightarrow> x \<le> 1 \<Longrightarrow> 1 \<le> float_divr prec 1 x"
  1802   by transfer (rule real_divr_pos_less1_lower_bound)
  1803 
  1804 lemma real_divr_nonpos_pos_upper_bound:
  1805   "x \<le> 0 \<Longrightarrow> 0 \<le> y \<Longrightarrow> real_divr prec x y \<le> 0"
  1806   by (simp add: real_divr_def round_up_le0 divide_le_0_iff)
  1807 
  1808 lemma float_divr_nonpos_pos_upper_bound:
  1809   "real x \<le> 0 \<Longrightarrow> 0 \<le> real y \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1810   by transfer (rule real_divr_nonpos_pos_upper_bound)
  1811 
  1812 lemma real_divr_nonneg_neg_upper_bound:
  1813   "0 \<le> x \<Longrightarrow> y \<le> 0 \<Longrightarrow> real_divr prec x y \<le> 0"
  1814   by (simp add: real_divr_def round_up_le0 divide_le_0_iff)
  1815 
  1816 lemma float_divr_nonneg_neg_upper_bound:
  1817   "0 \<le> real x \<Longrightarrow> real y \<le> 0 \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1818   by transfer (rule real_divr_nonneg_neg_upper_bound)
  1819 
  1820 lemma truncate_up_nonneg_mono:
  1821   assumes "0 \<le> x" "x \<le> y"
  1822   shows "truncate_up prec x \<le> truncate_up prec y"
  1823 proof -
  1824   {
  1825     assume "\<lfloor>log 2 x\<rfloor> = \<lfloor>log 2 y\<rfloor>"
  1826     hence ?thesis
  1827       using assms
  1828       by (auto simp: truncate_up_def round_up_def intro!: ceiling_mono)
  1829   } moreover {
  1830     assume "0 < x"
  1831     hence "log 2 x \<le> log 2 y" using assms by auto
  1832     moreover
  1833     assume "\<lfloor>log 2 x\<rfloor> \<noteq> \<lfloor>log 2 y\<rfloor>"
  1834     ultimately have logless: "log 2 x < log 2 y" and flogless: "\<lfloor>log 2 x\<rfloor> < \<lfloor>log 2 y\<rfloor>"
  1835       unfolding atomize_conj
  1836       by (metis floor_less_cancel linorder_cases not_le)
  1837     have "truncate_up prec x =
  1838       real \<lceil>x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1)\<rceil> * 2 powr - real (int prec - \<lfloor>log 2 x\<rfloor> - 1)"
  1839       using assms by (simp add: truncate_up_def round_up_def)
  1840     also have "\<lceil>x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1)\<rceil> \<le> (2 ^ prec)"
  1841     proof (unfold ceiling_le_eq)
  1842       have "x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1) \<le> x * (2 powr real prec / (2 powr log 2 x))"
  1843         using real_of_int_floor_add_one_ge[of "log 2 x"] assms
  1844         by (auto simp add: algebra_simps powr_divide2 intro!: mult_left_mono)
  1845       thus "x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1) \<le> real ((2::int) ^ prec)"
  1846         using `0 < x` by (simp add: powr_realpow)
  1847     qed
  1848     hence "real \<lceil>x * 2 powr real (int prec - \<lfloor>log 2 x\<rfloor> - 1)\<rceil> \<le> 2 powr int prec"
  1849       by (auto simp: powr_realpow)
  1850     also
  1851     have "2 powr - real (int prec - \<lfloor>log 2 x\<rfloor> - 1) \<le> 2 powr - real (int prec - \<lfloor>log 2 y\<rfloor>)"
  1852       using logless flogless by (auto intro!: floor_mono)
  1853     also have "2 powr real (int prec) \<le> 2 powr (log 2 y + real (int prec - \<lfloor>log 2 y\<rfloor>))"
  1854       using assms `0 < x`
  1855       by (auto simp: algebra_simps)
  1856     finally have "truncate_up prec x \<le> 2 powr (log 2 y + real (int prec - \<lfloor>log 2 y\<rfloor>)) * 2 powr - real (int prec - \<lfloor>log 2 y\<rfloor>)"
  1857       by simp
  1858     also have "\<dots> = 2 powr (log 2 y + real (int prec - \<lfloor>log 2 y\<rfloor>) - real (int prec - \<lfloor>log 2 y\<rfloor>))"
  1859       by (subst powr_add[symmetric]) simp
  1860     also have "\<dots> = y"
  1861       using `0 < x` assms
  1862       by (simp add: powr_add)
  1863     also have "\<dots> \<le> truncate_up prec y"
  1864       by (rule truncate_up)
  1865     finally have ?thesis .
  1866   } moreover {
  1867     assume "~ 0 < x"
  1868     hence ?thesis
  1869       using assms
  1870       by (auto intro!: truncate_up_le)
  1871   } ultimately show ?thesis
  1872     by blast
  1873 qed
  1874 
  1875 lemma truncate_up_switch_sign_mono:
  1876   assumes "x \<le> 0" "0 \<le> y"
  1877   shows "truncate_up prec x \<le> truncate_up prec y"
  1878 proof -
  1879   note truncate_up_nonpos[OF `x \<le> 0`]
  1880   also note truncate_up_le[OF `0 \<le> y`]
  1881   finally show ?thesis .
  1882 qed
  1883 
  1884 lemma truncate_down_zeroprec_mono:
  1885   assumes "0 < x" "x \<le> y"
  1886   shows "truncate_down 0 x \<le> truncate_down 0 y"
  1887 proof -
  1888   have "x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1) = x * inverse (2 powr ((real \<lfloor>log 2 x\<rfloor> + 1)))"
  1889     by (simp add: powr_divide2[symmetric] powr_add powr_minus inverse_eq_divide)
  1890   also have "\<dots> = 2 powr (log 2 x - (real \<lfloor>log 2 x\<rfloor>) - 1)"
  1891     using `0 < x`
  1892     by (auto simp: field_simps powr_add powr_divide2[symmetric])
  1893   also have "\<dots> < 2 powr 0"
  1894     using real_of_int_floor_add_one_gt
  1895     unfolding neg_less_iff_less
  1896     by (intro powr_less_mono) (auto simp: algebra_simps)
  1897   finally have "\<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor> < 1"
  1898     unfolding less_ceiling_eq real_of_int_minus real_of_one
  1899     by simp
  1900   moreover
  1901   have "0 \<le> \<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor>"
  1902     using `x > 0` by auto
  1903   ultimately have "\<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor> \<in> {0 ..< 1}"
  1904     by simp
  1905   also have "\<dots> \<subseteq> {0}" by auto
  1906   finally have "\<lfloor>x * 2 powr (- real \<lfloor>log 2 x\<rfloor> - 1)\<rfloor> = 0" by simp
  1907   with assms show ?thesis
  1908     by (auto simp: truncate_down_def round_down_def)
  1909 qed
  1910 
  1911 lemma truncate_down_switch_sign_mono:
  1912   assumes "x \<le> 0" "0 \<le> y"
  1913   assumes "x \<le> y"
  1914   shows "truncate_down prec x \<le> truncate_down prec y"
  1915 proof -
  1916   note truncate_down_le[OF `x \<le> 0`]
  1917   also note truncate_down_nonneg[OF `0 \<le> y`]
  1918   finally show ?thesis .
  1919 qed
  1920 
  1921 lemma truncate_down_nonneg_mono:
  1922   assumes "0 \<le> x" "x \<le> y"
  1923   shows "truncate_down prec x \<le> truncate_down prec y"
  1924 proof -
  1925   {
  1926     assume "0 < x" "prec = 0"
  1927     with assms have ?thesis
  1928       by (simp add: truncate_down_zeroprec_mono)
  1929   } moreover {
  1930     assume "~ 0 < x"
  1931     with assms have "x = 0" "0 \<le> y" by simp_all
  1932     hence ?thesis
  1933       by (auto intro!: truncate_down_nonneg)
  1934   } moreover {
  1935     assume "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> = \<lfloor>log 2 \<bar>y\<bar>\<rfloor>"
  1936     hence ?thesis
  1937       using assms
  1938       by (auto simp: truncate_down_def round_down_def intro!: floor_mono)
  1939   } moreover {
  1940     assume "0 < x"
  1941     hence "log 2 x \<le> log 2 y" "0 < y" "0 \<le> y" using assms by auto
  1942     moreover
  1943     assume "\<lfloor>log 2 \<bar>x\<bar>\<rfloor> \<noteq> \<lfloor>log 2 \<bar>y\<bar>\<rfloor>"
  1944     ultimately have logless: "log 2 x < log 2 y" and flogless: "\<lfloor>log 2 x\<rfloor> < \<lfloor>log 2 y\<rfloor>"
  1945       unfolding atomize_conj abs_of_pos[OF `0 < x`] abs_of_pos[OF `0 < y`]
  1946       by (metis floor_less_cancel linorder_cases not_le)
  1947     assume "prec \<noteq> 0" hence [simp]: "prec \<ge> Suc 0" by auto
  1948     have "2 powr (prec - 1) \<le> y * 2 powr real (prec - 1) / (2 powr log 2 y)"
  1949       using `0 < y`
  1950       by simp
  1951     also have "\<dots> \<le> y * 2 powr real prec / (2 powr (real \<lfloor>log 2 y\<rfloor> + 1))"
  1952       using `0 \<le> y` `0 \<le> x` assms(2)
  1953       by (auto intro!: powr_mono divide_left_mono
  1954         simp: real_of_nat_diff powr_add
  1955         powr_divide2[symmetric])
  1956     also have "\<dots> = y * 2 powr real prec / (2 powr real \<lfloor>log 2 y\<rfloor> * 2)"
  1957       by (auto simp: powr_add)
  1958     finally have "(2 ^ (prec - 1)) \<le> \<lfloor>y * 2 powr real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor> - 1)\<rfloor>"
  1959       using `0 \<le> y`
  1960       by (auto simp: powr_divide2[symmetric] le_floor_eq powr_realpow)
  1961     hence "(2 ^ (prec - 1)) * 2 powr - real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor> - 1) \<le> truncate_down prec y"
  1962       by (auto simp: truncate_down_def round_down_def)
  1963     moreover
  1964     {
  1965       have "x = 2 powr (log 2 \<bar>x\<bar>)" using `0 < x` by simp
  1966       also have "\<dots> \<le> (2 ^ (prec )) * 2 powr - real (int prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1)"
  1967         using real_of_int_floor_add_one_ge[of "log 2 \<bar>x\<bar>"]
  1968         by (auto simp: powr_realpow[symmetric] powr_add[symmetric] algebra_simps)
  1969       also
  1970       have "2 powr - real (int prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) \<le> 2 powr - real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor>)"
  1971         using logless flogless `x > 0` `y > 0`
  1972         by (auto intro!: floor_mono)
  1973       finally have "x \<le> (2 ^ (prec - 1)) * 2 powr - real (int prec - \<lfloor>log 2 \<bar>y\<bar>\<rfloor> - 1)"
  1974         by (auto simp: powr_realpow[symmetric] powr_divide2[symmetric] assms real_of_nat_diff)
  1975     } ultimately have ?thesis
  1976       by (metis dual_order.trans truncate_down)
  1977   } ultimately show ?thesis by blast
  1978 qed
  1979 
  1980 lemma truncate_down_eq_truncate_up: "truncate_down p x = - truncate_up p (-x)"
  1981   and truncate_up_eq_truncate_down: "truncate_up p x = - truncate_down p (-x)"
  1982   by (auto simp: truncate_up_uminus_eq truncate_down_uminus_eq)
  1983 
  1984 lemma truncate_down_mono: "x \<le> y \<Longrightarrow> truncate_down p x \<le> truncate_down p y"
  1985   apply (cases "0 \<le> x")
  1986   apply (rule truncate_down_nonneg_mono, assumption+)
  1987   apply (simp add: truncate_down_eq_truncate_up)
  1988   apply (cases "0 \<le> y")
  1989   apply (auto intro: truncate_up_nonneg_mono truncate_up_switch_sign_mono)
  1990   done
  1991 
  1992 lemma truncate_up_mono: "x \<le> y \<Longrightarrow> truncate_up p x \<le> truncate_up p y"
  1993   by (simp add: truncate_up_eq_truncate_down truncate_down_mono)
  1994 
  1995 lemma Float_le_zero_iff: "Float a b \<le> 0 \<longleftrightarrow> a \<le> 0"
  1996  apply (auto simp: zero_float_def mult_le_0_iff)
  1997  using powr_gt_zero[of 2 b] by simp
  1998 
  1999 lemma real_of_float_pprt[simp]: fixes a::float shows "real (pprt a) = pprt (real a)"
  2000   unfolding pprt_def sup_float_def max_def sup_real_def by auto
  2001 
  2002 lemma real_of_float_nprt[simp]: fixes a::float shows "real (nprt a) = nprt (real a)"
  2003   unfolding nprt_def inf_float_def min_def inf_real_def by auto
  2004 
  2005 lift_definition int_floor_fl :: "float \<Rightarrow> int" is floor .
  2006 
  2007 lemma compute_int_floor_fl[code]:
  2008   "int_floor_fl (Float m e) = (if 0 \<le> e then m * 2 ^ nat e else m div (2 ^ (nat (-e))))"
  2009   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  2010 hide_fact (open) compute_int_floor_fl
  2011 
  2012 lift_definition floor_fl :: "float \<Rightarrow> float" is "\<lambda>x. real (floor x)" by simp
  2013 
  2014 lemma compute_floor_fl[code]:
  2015   "floor_fl (Float m e) = (if 0 \<le> e then Float m e else Float (m div (2 ^ (nat (-e)))) 0)"
  2016   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  2017 hide_fact (open) compute_floor_fl
  2018 
  2019 lemma floor_fl: "real (floor_fl x) \<le> real x" by transfer simp
  2020 
  2021 lemma int_floor_fl: "real (int_floor_fl x) \<le> real x" by transfer simp
  2022 
  2023 lemma floor_pos_exp: "exponent (floor_fl x) \<ge> 0"
  2024 proof (cases "floor_fl x = float_of 0")
  2025   case True
  2026   then show ?thesis by (simp add: floor_fl_def)
  2027 next
  2028   case False
  2029   have eq: "floor_fl x = Float \<lfloor>real x\<rfloor> 0" by transfer simp
  2030   obtain i where "\<lfloor>real x\<rfloor> = mantissa (floor_fl x) * 2 ^ i" "0 = exponent (floor_fl x) - int i"
  2031     by (rule denormalize_shift[OF eq[THEN eq_reflection] False])
  2032   then show ?thesis by simp
  2033 qed
  2034 
  2035 lemma compute_mantissa[code]:
  2036   "mantissa (Float m e) = (if m = 0 then 0 else if 2 dvd m then mantissa (normfloat (Float m e)) else m)"
  2037   by (auto simp: mantissa_float Float.abs_eq)
  2038 
  2039 lemma compute_exponent[code]:
  2040   "exponent (Float m e) = (if m = 0 then 0 else if 2 dvd m then exponent (normfloat (Float m e)) else e)"
  2041   by (auto simp: exponent_float Float.abs_eq)
  2042 
  2043 end
  2044