src/HOL/Real/RealVector.thy
author huffman
Sat May 12 18:16:30 2007 +0200 (2007-05-12)
changeset 22942 bf718970e5ef
parent 22912 c477862c566d
child 22972 3e96b98d37c6
permissions -rw-r--r--
add lemma additive.setsum
     1 (*  Title       : RealVector.thy
     2     ID:         $Id$
     3     Author      : Brian Huffman
     4 *)
     5 
     6 header {* Vector Spaces and Algebras over the Reals *}
     7 
     8 theory RealVector
     9 imports RealPow
    10 begin
    11 
    12 subsection {* Locale for additive functions *}
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 
    18 lemma (in additive) zero: "f 0 = 0"
    19 proof -
    20   have "f 0 = f (0 + 0)" by simp
    21   also have "\<dots> = f 0 + f 0" by (rule add)
    22   finally show "f 0 = 0" by simp
    23 qed
    24 
    25 lemma (in additive) minus: "f (- x) = - f x"
    26 proof -
    27   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    28   also have "\<dots> = - f x + f x" by (simp add: zero)
    29   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    30 qed
    31 
    32 lemma (in additive) diff: "f (x - y) = f x - f y"
    33 by (simp add: diff_def add minus)
    34 
    35 lemma (in additive) setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    36 apply (cases "finite A")
    37 apply (induct set: finite)
    38 apply (simp add: zero)
    39 apply (simp add: add)
    40 apply (simp add: zero)
    41 done
    42 
    43 
    44 subsection {* Real vector spaces *}
    45 
    46 class scaleR = type +
    47   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a"
    48 
    49 notation
    50   scaleR (infixr "*#" 75)
    51 
    52 abbreviation
    53   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a::scaleR" (infixl "'/#" 70) where
    54   "x /# r == scaleR (inverse r) x"
    55 
    56 notation (xsymbols)
    57   scaleR (infixr "*\<^sub>R" 75) and
    58   divideR (infixl "'/\<^sub>R" 70)
    59 
    60 instance real :: scaleR
    61   real_scaleR_def: "scaleR a x \<equiv> a * x" ..
    62 
    63 axclass real_vector < scaleR, ab_group_add
    64   scaleR_right_distrib: "scaleR a (x + y) = scaleR a x + scaleR a y"
    65   scaleR_left_distrib: "scaleR (a + b) x = scaleR a x + scaleR b x"
    66   scaleR_scaleR [simp]: "scaleR a (scaleR b x) = scaleR (a * b) x"
    67   scaleR_one [simp]: "scaleR 1 x = x"
    68 
    69 axclass real_algebra < real_vector, ring
    70   mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
    71   mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
    72 
    73 axclass real_algebra_1 < real_algebra, ring_1
    74 
    75 axclass real_div_algebra < real_algebra_1, division_ring
    76 
    77 axclass real_field < real_div_algebra, field
    78 
    79 instance real :: real_field
    80 apply (intro_classes, unfold real_scaleR_def)
    81 apply (rule right_distrib)
    82 apply (rule left_distrib)
    83 apply (rule mult_assoc [symmetric])
    84 apply (rule mult_1_left)
    85 apply (rule mult_assoc)
    86 apply (rule mult_left_commute)
    87 done
    88 
    89 lemma scaleR_left_commute:
    90   fixes x :: "'a::real_vector"
    91   shows "scaleR a (scaleR b x) = scaleR b (scaleR a x)"
    92 by (simp add: mult_commute)
    93 
    94 lemma additive_scaleR_right: "additive (\<lambda>x. scaleR a x::'a::real_vector)"
    95 by (rule additive.intro, rule scaleR_right_distrib)
    96 
    97 lemma additive_scaleR_left: "additive (\<lambda>a. scaleR a x::'a::real_vector)"
    98 by (rule additive.intro, rule scaleR_left_distrib)
    99 
   100 lemmas scaleR_zero_left [simp] =
   101   additive.zero [OF additive_scaleR_left, standard]
   102 
   103 lemmas scaleR_zero_right [simp] =
   104   additive.zero [OF additive_scaleR_right, standard]
   105 
   106 lemmas scaleR_minus_left [simp] =
   107   additive.minus [OF additive_scaleR_left, standard]
   108 
   109 lemmas scaleR_minus_right [simp] =
   110   additive.minus [OF additive_scaleR_right, standard]
   111 
   112 lemmas scaleR_left_diff_distrib =
   113   additive.diff [OF additive_scaleR_left, standard]
   114 
   115 lemmas scaleR_right_diff_distrib =
   116   additive.diff [OF additive_scaleR_right, standard]
   117 
   118 lemma scaleR_eq_0_iff:
   119   fixes x :: "'a::real_vector"
   120   shows "(scaleR a x = 0) = (a = 0 \<or> x = 0)"
   121 proof cases
   122   assume "a = 0" thus ?thesis by simp
   123 next
   124   assume anz [simp]: "a \<noteq> 0"
   125   { assume "scaleR a x = 0"
   126     hence "scaleR (inverse a) (scaleR a x) = 0" by simp
   127     hence "x = 0" by simp }
   128   thus ?thesis by force
   129 qed
   130 
   131 lemma scaleR_left_imp_eq:
   132   fixes x y :: "'a::real_vector"
   133   shows "\<lbrakk>a \<noteq> 0; scaleR a x = scaleR a y\<rbrakk> \<Longrightarrow> x = y"
   134 proof -
   135   assume nonzero: "a \<noteq> 0"
   136   assume "scaleR a x = scaleR a y"
   137   hence "scaleR a (x - y) = 0"
   138      by (simp add: scaleR_right_diff_distrib)
   139   hence "x - y = 0"
   140      by (simp add: scaleR_eq_0_iff nonzero)
   141   thus "x = y" by simp
   142 qed
   143 
   144 lemma scaleR_right_imp_eq:
   145   fixes x y :: "'a::real_vector"
   146   shows "\<lbrakk>x \<noteq> 0; scaleR a x = scaleR b x\<rbrakk> \<Longrightarrow> a = b"
   147 proof -
   148   assume nonzero: "x \<noteq> 0"
   149   assume "scaleR a x = scaleR b x"
   150   hence "scaleR (a - b) x = 0"
   151      by (simp add: scaleR_left_diff_distrib)
   152   hence "a - b = 0"
   153      by (simp add: scaleR_eq_0_iff nonzero)
   154   thus "a = b" by simp
   155 qed
   156 
   157 lemma scaleR_cancel_left:
   158   fixes x y :: "'a::real_vector"
   159   shows "(scaleR a x = scaleR a y) = (x = y \<or> a = 0)"
   160 by (auto intro: scaleR_left_imp_eq)
   161 
   162 lemma scaleR_cancel_right:
   163   fixes x y :: "'a::real_vector"
   164   shows "(scaleR a x = scaleR b x) = (a = b \<or> x = 0)"
   165 by (auto intro: scaleR_right_imp_eq)
   166 
   167 lemma nonzero_inverse_scaleR_distrib:
   168   fixes x :: "'a::real_div_algebra" shows
   169   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   170 by (rule inverse_unique, simp)
   171 
   172 lemma inverse_scaleR_distrib:
   173   fixes x :: "'a::{real_div_algebra,division_by_zero}"
   174   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   175 apply (case_tac "a = 0", simp)
   176 apply (case_tac "x = 0", simp)
   177 apply (erule (1) nonzero_inverse_scaleR_distrib)
   178 done
   179 
   180 
   181 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   182 @{term of_real} *}
   183 
   184 definition
   185   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   186   "of_real r = scaleR r 1"
   187 
   188 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   189 by (simp add: of_real_def)
   190 
   191 lemma of_real_0 [simp]: "of_real 0 = 0"
   192 by (simp add: of_real_def)
   193 
   194 lemma of_real_1 [simp]: "of_real 1 = 1"
   195 by (simp add: of_real_def)
   196 
   197 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   198 by (simp add: of_real_def scaleR_left_distrib)
   199 
   200 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   201 by (simp add: of_real_def)
   202 
   203 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   204 by (simp add: of_real_def scaleR_left_diff_distrib)
   205 
   206 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   207 by (simp add: of_real_def mult_commute)
   208 
   209 lemma nonzero_of_real_inverse:
   210   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   211    inverse (of_real x :: 'a::real_div_algebra)"
   212 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   213 
   214 lemma of_real_inverse [simp]:
   215   "of_real (inverse x) =
   216    inverse (of_real x :: 'a::{real_div_algebra,division_by_zero})"
   217 by (simp add: of_real_def inverse_scaleR_distrib)
   218 
   219 lemma nonzero_of_real_divide:
   220   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   221    (of_real x / of_real y :: 'a::real_field)"
   222 by (simp add: divide_inverse nonzero_of_real_inverse)
   223 
   224 lemma of_real_divide [simp]:
   225   "of_real (x / y) =
   226    (of_real x / of_real y :: 'a::{real_field,division_by_zero})"
   227 by (simp add: divide_inverse)
   228 
   229 lemma of_real_power [simp]:
   230   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1,recpower}) ^ n"
   231 by (induct n) (simp_all add: power_Suc)
   232 
   233 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   234 by (simp add: of_real_def scaleR_cancel_right)
   235 
   236 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   237 
   238 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   239 proof
   240   fix r
   241   show "of_real r = id r"
   242     by (simp add: of_real_def real_scaleR_def)
   243 qed
   244 
   245 text{*Collapse nested embeddings*}
   246 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   247 by (induct n) auto
   248 
   249 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   250 by (cases z rule: int_diff_cases, simp)
   251 
   252 lemma of_real_number_of_eq:
   253   "of_real (number_of w) = (number_of w :: 'a::{number_ring,real_algebra_1})"
   254 by (simp add: number_of_eq)
   255 
   256 text{*Every real algebra has characteristic zero*}
   257 instance real_algebra_1 < ring_char_0
   258 proof
   259   fix w z :: int
   260   assume "of_int w = (of_int z::'a)"
   261   hence "of_real (of_int w) = (of_real (of_int z)::'a)"
   262     by (simp only: of_real_of_int_eq)
   263   thus "w = z"
   264     by (simp only: of_real_eq_iff of_int_eq_iff)
   265 qed
   266 
   267 
   268 subsection {* The Set of Real Numbers *}
   269 
   270 definition
   271   Reals :: "'a::real_algebra_1 set" where
   272   "Reals \<equiv> range of_real"
   273 
   274 notation (xsymbols)
   275   Reals  ("\<real>")
   276 
   277 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   278 by (simp add: Reals_def)
   279 
   280 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   281 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   282 
   283 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   284 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   285 
   286 lemma Reals_number_of [simp]:
   287   "(number_of w::'a::{number_ring,real_algebra_1}) \<in> Reals"
   288 by (subst of_real_number_of_eq [symmetric], rule Reals_of_real)
   289 
   290 lemma Reals_0 [simp]: "0 \<in> Reals"
   291 apply (unfold Reals_def)
   292 apply (rule range_eqI)
   293 apply (rule of_real_0 [symmetric])
   294 done
   295 
   296 lemma Reals_1 [simp]: "1 \<in> Reals"
   297 apply (unfold Reals_def)
   298 apply (rule range_eqI)
   299 apply (rule of_real_1 [symmetric])
   300 done
   301 
   302 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   303 apply (auto simp add: Reals_def)
   304 apply (rule range_eqI)
   305 apply (rule of_real_add [symmetric])
   306 done
   307 
   308 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   309 apply (auto simp add: Reals_def)
   310 apply (rule range_eqI)
   311 apply (rule of_real_minus [symmetric])
   312 done
   313 
   314 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   315 apply (auto simp add: Reals_def)
   316 apply (rule range_eqI)
   317 apply (rule of_real_diff [symmetric])
   318 done
   319 
   320 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   321 apply (auto simp add: Reals_def)
   322 apply (rule range_eqI)
   323 apply (rule of_real_mult [symmetric])
   324 done
   325 
   326 lemma nonzero_Reals_inverse:
   327   fixes a :: "'a::real_div_algebra"
   328   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   329 apply (auto simp add: Reals_def)
   330 apply (rule range_eqI)
   331 apply (erule nonzero_of_real_inverse [symmetric])
   332 done
   333 
   334 lemma Reals_inverse [simp]:
   335   fixes a :: "'a::{real_div_algebra,division_by_zero}"
   336   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   337 apply (auto simp add: Reals_def)
   338 apply (rule range_eqI)
   339 apply (rule of_real_inverse [symmetric])
   340 done
   341 
   342 lemma nonzero_Reals_divide:
   343   fixes a b :: "'a::real_field"
   344   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   345 apply (auto simp add: Reals_def)
   346 apply (rule range_eqI)
   347 apply (erule nonzero_of_real_divide [symmetric])
   348 done
   349 
   350 lemma Reals_divide [simp]:
   351   fixes a b :: "'a::{real_field,division_by_zero}"
   352   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   353 apply (auto simp add: Reals_def)
   354 apply (rule range_eqI)
   355 apply (rule of_real_divide [symmetric])
   356 done
   357 
   358 lemma Reals_power [simp]:
   359   fixes a :: "'a::{real_algebra_1,recpower}"
   360   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   361 apply (auto simp add: Reals_def)
   362 apply (rule range_eqI)
   363 apply (rule of_real_power [symmetric])
   364 done
   365 
   366 lemma Reals_cases [cases set: Reals]:
   367   assumes "q \<in> \<real>"
   368   obtains (of_real) r where "q = of_real r"
   369   unfolding Reals_def
   370 proof -
   371   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   372   then obtain r where "q = of_real r" ..
   373   then show thesis ..
   374 qed
   375 
   376 lemma Reals_induct [case_names of_real, induct set: Reals]:
   377   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   378   by (rule Reals_cases) auto
   379 
   380 
   381 subsection {* Real normed vector spaces *}
   382 
   383 class norm = type +
   384   fixes norm :: "'a \<Rightarrow> real"
   385 
   386 instance real :: norm
   387   real_norm_def [simp]: "norm r \<equiv> \<bar>r\<bar>" ..
   388 
   389 axclass real_normed_vector < real_vector, norm
   390   norm_ge_zero [simp]: "0 \<le> norm x"
   391   norm_eq_zero [simp]: "(norm x = 0) = (x = 0)"
   392   norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   393   norm_scaleR: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   394 
   395 axclass real_normed_algebra < real_algebra, real_normed_vector
   396   norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   397 
   398 axclass real_normed_algebra_1 < real_algebra_1, real_normed_algebra
   399   norm_one [simp]: "norm 1 = 1"
   400 
   401 axclass real_normed_div_algebra < real_div_algebra, real_normed_vector
   402   norm_mult: "norm (x * y) = norm x * norm y"
   403 
   404 axclass real_normed_field < real_field, real_normed_div_algebra
   405 
   406 instance real_normed_div_algebra < real_normed_algebra_1
   407 proof
   408   fix x y :: 'a
   409   show "norm (x * y) \<le> norm x * norm y"
   410     by (simp add: norm_mult)
   411 next
   412   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   413     by (rule norm_mult)
   414   thus "norm (1::'a) = 1" by simp
   415 qed
   416 
   417 instance real :: real_normed_field
   418 apply (intro_classes, unfold real_norm_def real_scaleR_def)
   419 apply (rule abs_ge_zero)
   420 apply (rule abs_eq_0)
   421 apply (rule abs_triangle_ineq)
   422 apply (rule abs_mult)
   423 apply (rule abs_mult)
   424 done
   425 
   426 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   427 by simp
   428 
   429 lemma zero_less_norm_iff [simp]:
   430   fixes x :: "'a::real_normed_vector"
   431   shows "(0 < norm x) = (x \<noteq> 0)"
   432 by (simp add: order_less_le)
   433 
   434 lemma norm_not_less_zero [simp]:
   435   fixes x :: "'a::real_normed_vector"
   436   shows "\<not> norm x < 0"
   437 by (simp add: linorder_not_less)
   438 
   439 lemma norm_le_zero_iff [simp]:
   440   fixes x :: "'a::real_normed_vector"
   441   shows "(norm x \<le> 0) = (x = 0)"
   442 by (simp add: order_le_less)
   443 
   444 lemma norm_minus_cancel [simp]:
   445   fixes x :: "'a::real_normed_vector"
   446   shows "norm (- x) = norm x"
   447 proof -
   448   have "norm (- x) = norm (scaleR (- 1) x)"
   449     by (simp only: scaleR_minus_left scaleR_one)
   450   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   451     by (rule norm_scaleR)
   452   finally show ?thesis by simp
   453 qed
   454 
   455 lemma norm_minus_commute:
   456   fixes a b :: "'a::real_normed_vector"
   457   shows "norm (a - b) = norm (b - a)"
   458 proof -
   459   have "norm (- (b - a)) = norm (b - a)"
   460     by (rule norm_minus_cancel)
   461   thus ?thesis by simp
   462 qed
   463 
   464 lemma norm_triangle_ineq2:
   465   fixes a b :: "'a::real_normed_vector"
   466   shows "norm a - norm b \<le> norm (a - b)"
   467 proof -
   468   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   469     by (rule norm_triangle_ineq)
   470   thus ?thesis by simp
   471 qed
   472 
   473 lemma norm_triangle_ineq3:
   474   fixes a b :: "'a::real_normed_vector"
   475   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   476 apply (subst abs_le_iff)
   477 apply auto
   478 apply (rule norm_triangle_ineq2)
   479 apply (subst norm_minus_commute)
   480 apply (rule norm_triangle_ineq2)
   481 done
   482 
   483 lemma norm_triangle_ineq4:
   484   fixes a b :: "'a::real_normed_vector"
   485   shows "norm (a - b) \<le> norm a + norm b"
   486 proof -
   487   have "norm (a + - b) \<le> norm a + norm (- b)"
   488     by (rule norm_triangle_ineq)
   489   thus ?thesis
   490     by (simp only: diff_minus norm_minus_cancel)
   491 qed
   492 
   493 lemma norm_diff_ineq:
   494   fixes a b :: "'a::real_normed_vector"
   495   shows "norm a - norm b \<le> norm (a + b)"
   496 proof -
   497   have "norm a - norm (- b) \<le> norm (a - - b)"
   498     by (rule norm_triangle_ineq2)
   499   thus ?thesis by simp
   500 qed
   501 
   502 lemma norm_diff_triangle_ineq:
   503   fixes a b c d :: "'a::real_normed_vector"
   504   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   505 proof -
   506   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   507     by (simp add: diff_minus add_ac)
   508   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   509     by (rule norm_triangle_ineq)
   510   finally show ?thesis .
   511 qed
   512 
   513 lemma abs_norm_cancel [simp]:
   514   fixes a :: "'a::real_normed_vector"
   515   shows "\<bar>norm a\<bar> = norm a"
   516 by (rule abs_of_nonneg [OF norm_ge_zero])
   517 
   518 lemma norm_add_less:
   519   fixes x y :: "'a::real_normed_vector"
   520   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   521 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   522 
   523 lemma norm_mult_less:
   524   fixes x y :: "'a::real_normed_algebra"
   525   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   526 apply (rule order_le_less_trans [OF norm_mult_ineq])
   527 apply (simp add: mult_strict_mono')
   528 done
   529 
   530 lemma norm_of_real [simp]:
   531   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   532 unfolding of_real_def by (simp add: norm_scaleR)
   533 
   534 lemma norm_number_of [simp]:
   535   "norm (number_of w::'a::{number_ring,real_normed_algebra_1})
   536     = \<bar>number_of w\<bar>"
   537 by (subst of_real_number_of_eq [symmetric], rule norm_of_real)
   538 
   539 lemma norm_of_int [simp]:
   540   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   541 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   542 
   543 lemma norm_of_nat [simp]:
   544   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   545 apply (subst of_real_of_nat_eq [symmetric])
   546 apply (subst norm_of_real, simp)
   547 done
   548 
   549 lemma nonzero_norm_inverse:
   550   fixes a :: "'a::real_normed_div_algebra"
   551   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   552 apply (rule inverse_unique [symmetric])
   553 apply (simp add: norm_mult [symmetric])
   554 done
   555 
   556 lemma norm_inverse:
   557   fixes a :: "'a::{real_normed_div_algebra,division_by_zero}"
   558   shows "norm (inverse a) = inverse (norm a)"
   559 apply (case_tac "a = 0", simp)
   560 apply (erule nonzero_norm_inverse)
   561 done
   562 
   563 lemma nonzero_norm_divide:
   564   fixes a b :: "'a::real_normed_field"
   565   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   566 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   567 
   568 lemma norm_divide:
   569   fixes a b :: "'a::{real_normed_field,division_by_zero}"
   570   shows "norm (a / b) = norm a / norm b"
   571 by (simp add: divide_inverse norm_mult norm_inverse)
   572 
   573 lemma norm_power_ineq:
   574   fixes x :: "'a::{real_normed_algebra_1,recpower}"
   575   shows "norm (x ^ n) \<le> norm x ^ n"
   576 proof (induct n)
   577   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   578 next
   579   case (Suc n)
   580   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   581     by (rule norm_mult_ineq)
   582   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   583     using norm_ge_zero by (rule mult_left_mono)
   584   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   585     by (simp add: power_Suc)
   586 qed
   587 
   588 lemma norm_power:
   589   fixes x :: "'a::{real_normed_div_algebra,recpower}"
   590   shows "norm (x ^ n) = norm x ^ n"
   591 by (induct n) (simp_all add: power_Suc norm_mult)
   592 
   593 
   594 subsection {* Bounded Linear and Bilinear Operators *}
   595 
   596 locale bounded_linear = additive +
   597   constrains f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
   598   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
   599   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
   600 
   601 lemma (in bounded_linear) pos_bounded:
   602   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
   603 proof -
   604   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
   605     using bounded by fast
   606   show ?thesis
   607   proof (intro exI impI conjI allI)
   608     show "0 < max 1 K"
   609       by (rule order_less_le_trans [OF zero_less_one le_maxI1])
   610   next
   611     fix x
   612     have "norm (f x) \<le> norm x * K" using K .
   613     also have "\<dots> \<le> norm x * max 1 K"
   614       by (rule mult_left_mono [OF le_maxI2 norm_ge_zero])
   615     finally show "norm (f x) \<le> norm x * max 1 K" .
   616   qed
   617 qed
   618 
   619 lemma (in bounded_linear) nonneg_bounded:
   620   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
   621 proof -
   622   from pos_bounded
   623   show ?thesis by (auto intro: order_less_imp_le)
   624 qed
   625 
   626 locale bounded_bilinear =
   627   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
   628                  \<Rightarrow> 'c::real_normed_vector"
   629     (infixl "**" 70)
   630   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
   631   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
   632   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
   633   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
   634   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
   635 
   636 lemma (in bounded_bilinear) pos_bounded:
   637   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
   638 apply (cut_tac bounded, erule exE)
   639 apply (rule_tac x="max 1 K" in exI, safe)
   640 apply (rule order_less_le_trans [OF zero_less_one le_maxI1])
   641 apply (drule spec, drule spec, erule order_trans)
   642 apply (rule mult_left_mono [OF le_maxI2])
   643 apply (intro mult_nonneg_nonneg norm_ge_zero)
   644 done
   645 
   646 lemma (in bounded_bilinear) nonneg_bounded:
   647   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
   648 proof -
   649   from pos_bounded
   650   show ?thesis by (auto intro: order_less_imp_le)
   651 qed
   652 
   653 lemma (in bounded_bilinear) additive_right: "additive (\<lambda>b. prod a b)"
   654 by (rule additive.intro, rule add_right)
   655 
   656 lemma (in bounded_bilinear) additive_left: "additive (\<lambda>a. prod a b)"
   657 by (rule additive.intro, rule add_left)
   658 
   659 lemma (in bounded_bilinear) zero_left: "prod 0 b = 0"
   660 by (rule additive.zero [OF additive_left])
   661 
   662 lemma (in bounded_bilinear) zero_right: "prod a 0 = 0"
   663 by (rule additive.zero [OF additive_right])
   664 
   665 lemma (in bounded_bilinear) minus_left: "prod (- a) b = - prod a b"
   666 by (rule additive.minus [OF additive_left])
   667 
   668 lemma (in bounded_bilinear) minus_right: "prod a (- b) = - prod a b"
   669 by (rule additive.minus [OF additive_right])
   670 
   671 lemma (in bounded_bilinear) diff_left:
   672   "prod (a - a') b = prod a b - prod a' b"
   673 by (rule additive.diff [OF additive_left])
   674 
   675 lemma (in bounded_bilinear) diff_right:
   676   "prod a (b - b') = prod a b - prod a b'"
   677 by (rule additive.diff [OF additive_right])
   678 
   679 lemma (in bounded_bilinear) bounded_linear_left:
   680   "bounded_linear (\<lambda>a. a ** b)"
   681 apply (unfold_locales)
   682 apply (rule add_left)
   683 apply (rule scaleR_left)
   684 apply (cut_tac bounded, safe)
   685 apply (rule_tac x="norm b * K" in exI)
   686 apply (simp add: mult_ac)
   687 done
   688 
   689 lemma (in bounded_bilinear) bounded_linear_right:
   690   "bounded_linear (\<lambda>b. a ** b)"
   691 apply (unfold_locales)
   692 apply (rule add_right)
   693 apply (rule scaleR_right)
   694 apply (cut_tac bounded, safe)
   695 apply (rule_tac x="norm a * K" in exI)
   696 apply (simp add: mult_ac)
   697 done
   698 
   699 lemma (in bounded_bilinear) prod_diff_prod:
   700   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
   701 by (simp add: diff_left diff_right)
   702 
   703 interpretation bounded_bilinear_mult:
   704   bounded_bilinear ["op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra"]
   705 apply (rule bounded_bilinear.intro)
   706 apply (rule left_distrib)
   707 apply (rule right_distrib)
   708 apply (rule mult_scaleR_left)
   709 apply (rule mult_scaleR_right)
   710 apply (rule_tac x="1" in exI)
   711 apply (simp add: norm_mult_ineq)
   712 done
   713 
   714 interpretation bounded_linear_mult_left:
   715   bounded_linear ["(\<lambda>x::'a::real_normed_algebra. x * y)"]
   716 by (rule bounded_bilinear_mult.bounded_linear_left)
   717 
   718 interpretation bounded_linear_mult_right:
   719   bounded_linear ["(\<lambda>y::'a::real_normed_algebra. x * y)"]
   720 by (rule bounded_bilinear_mult.bounded_linear_right)
   721 
   722 interpretation bounded_bilinear_scaleR:
   723   bounded_bilinear ["scaleR"]
   724 apply (rule bounded_bilinear.intro)
   725 apply (rule scaleR_left_distrib)
   726 apply (rule scaleR_right_distrib)
   727 apply (simp add: real_scaleR_def)
   728 apply (rule scaleR_left_commute)
   729 apply (rule_tac x="1" in exI)
   730 apply (simp add: norm_scaleR)
   731 done
   732 
   733 interpretation bounded_linear_of_real:
   734   bounded_linear ["\<lambda>r. of_real r"]
   735 apply (unfold of_real_def)
   736 apply (rule bounded_bilinear_scaleR.bounded_linear_left)
   737 done
   738 
   739 end