src/HOL/Probability/Infinite_Product_Measure.thy
author immler@in.tum.de
Wed Nov 07 11:33:27 2012 +0100 (2012-11-07)
changeset 50039 bfd5198cbe40
parent 50038 8e32c9254535
child 50040 5da32dc55cd8
permissions -rw-r--r--
added projective_family; generalized generator in product_prob_space to projective_family
     1 (*  Title:      HOL/Probability/Infinite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 header {*Infinite Product Measure*}
     6 
     7 theory Infinite_Product_Measure
     8   imports Probability_Measure Caratheodory Projective_Family
     9 begin
    10 
    11 lemma split_merge: "P (merge I J (x,y) i) \<longleftrightarrow> (i \<in> I \<longrightarrow> P (x i)) \<and> (i \<in> J - I \<longrightarrow> P (y i)) \<and> (i \<notin> I \<union> J \<longrightarrow> P undefined)"
    12   unfolding merge_def by auto
    13 
    14 lemma extensional_merge_sub: "I \<union> J \<subseteq> K \<Longrightarrow> merge I J (x, y) \<in> extensional K"
    15   unfolding merge_def extensional_def by auto
    16 
    17 lemma injective_vimage_restrict:
    18   assumes J: "J \<subseteq> I"
    19   and sets: "A \<subseteq> (\<Pi>\<^isub>E i\<in>J. S i)" "B \<subseteq> (\<Pi>\<^isub>E i\<in>J. S i)" and ne: "(\<Pi>\<^isub>E i\<in>I. S i) \<noteq> {}"
    20   and eq: "(\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^isub>E i\<in>I. S i) = (\<lambda>x. restrict x J) -` B \<inter> (\<Pi>\<^isub>E i\<in>I. S i)"
    21   shows "A = B"
    22 proof  (intro set_eqI)
    23   fix x
    24   from ne obtain y where y: "\<And>i. i \<in> I \<Longrightarrow> y i \<in> S i" by auto
    25   have "J \<inter> (I - J) = {}" by auto
    26   show "x \<in> A \<longleftrightarrow> x \<in> B"
    27   proof cases
    28     assume x: "x \<in> (\<Pi>\<^isub>E i\<in>J. S i)"
    29     have "x \<in> A \<longleftrightarrow> merge J (I - J) (x,y) \<in> (\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^isub>E i\<in>I. S i)"
    30       using y x `J \<subseteq> I` by (auto simp add: Pi_iff extensional_restrict extensional_merge_sub split: split_merge)
    31     then show "x \<in> A \<longleftrightarrow> x \<in> B"
    32       using y x `J \<subseteq> I` by (auto simp add: Pi_iff extensional_restrict extensional_merge_sub eq split: split_merge)
    33   next
    34     assume "x \<notin> (\<Pi>\<^isub>E i\<in>J. S i)" with sets show "x \<in> A \<longleftrightarrow> x \<in> B" by auto
    35   qed
    36 qed
    37 
    38 lemma (in product_prob_space) distr_restrict:
    39   assumes "J \<noteq> {}" "J \<subseteq> K" "finite K"
    40   shows "(\<Pi>\<^isub>M i\<in>J. M i) = distr (\<Pi>\<^isub>M i\<in>K. M i) (\<Pi>\<^isub>M i\<in>J. M i) (\<lambda>f. restrict f J)" (is "?P = ?D")
    41 proof (rule measure_eqI_generator_eq)
    42   have "finite J" using `J \<subseteq> K` `finite K` by (auto simp add: finite_subset)
    43   interpret J: finite_product_prob_space M J proof qed fact
    44   interpret K: finite_product_prob_space M K proof qed fact
    45 
    46   let ?J = "{Pi\<^isub>E J E | E. \<forall>i\<in>J. E i \<in> sets (M i)}"
    47   let ?F = "\<lambda>i. \<Pi>\<^isub>E k\<in>J. space (M k)"
    48   let ?\<Omega> = "(\<Pi>\<^isub>E k\<in>J. space (M k))"
    49   show "Int_stable ?J"
    50     by (rule Int_stable_PiE)
    51   show "range ?F \<subseteq> ?J" "(\<Union>i. ?F i) = ?\<Omega>"
    52     using `finite J` by (auto intro!: prod_algebraI_finite)
    53   { fix i show "emeasure ?P (?F i) \<noteq> \<infinity>" by simp }
    54   show "?J \<subseteq> Pow ?\<Omega>" by (auto simp: Pi_iff dest: sets_into_space)
    55   show "sets (\<Pi>\<^isub>M i\<in>J. M i) = sigma_sets ?\<Omega> ?J" "sets ?D = sigma_sets ?\<Omega> ?J"
    56     using `finite J` by (simp_all add: sets_PiM prod_algebra_eq_finite Pi_iff)
    57   
    58   fix X assume "X \<in> ?J"
    59   then obtain E where [simp]: "X = Pi\<^isub>E J E" and E: "\<forall>i\<in>J. E i \<in> sets (M i)" by auto
    60   with `finite J` have X: "X \<in> sets (Pi\<^isub>M J M)"
    61     by simp
    62 
    63   have "emeasure ?P X = (\<Prod> i\<in>J. emeasure (M i) (E i))"
    64     using E by (simp add: J.measure_times)
    65   also have "\<dots> = (\<Prod> i\<in>J. emeasure (M i) (if i \<in> J then E i else space (M i)))"
    66     by simp
    67   also have "\<dots> = (\<Prod> i\<in>K. emeasure (M i) (if i \<in> J then E i else space (M i)))"
    68     using `finite K` `J \<subseteq> K`
    69     by (intro setprod_mono_one_left) (auto simp: M.emeasure_space_1)
    70   also have "\<dots> = emeasure (Pi\<^isub>M K M) (\<Pi>\<^isub>E i\<in>K. if i \<in> J then E i else space (M i))"
    71     using E by (simp add: K.measure_times)
    72   also have "(\<Pi>\<^isub>E i\<in>K. if i \<in> J then E i else space (M i)) = (\<lambda>f. restrict f J) -` Pi\<^isub>E J E \<inter> (\<Pi>\<^isub>E i\<in>K. space (M i))"
    73     using `J \<subseteq> K` sets_into_space E by (force simp:  Pi_iff split: split_if_asm)
    74   finally show "emeasure (Pi\<^isub>M J M) X = emeasure ?D X"
    75     using X `J \<subseteq> K` apply (subst emeasure_distr)
    76     by (auto intro!: measurable_restrict_subset simp: space_PiM)
    77 qed
    78 
    79 lemma (in product_prob_space) emeasure_prod_emb[simp]:
    80   assumes L: "J \<noteq> {}" "J \<subseteq> L" "finite L" and X: "X \<in> sets (Pi\<^isub>M J M)"
    81   shows "emeasure (Pi\<^isub>M L M) (prod_emb L M J X) = emeasure (Pi\<^isub>M J M) X"
    82   by (subst distr_restrict[OF L])
    83      (simp add: prod_emb_def space_PiM emeasure_distr measurable_restrict_subset L X)
    84 
    85 sublocale product_prob_space \<subseteq> projective_family I "\<lambda>J. PiM J M" M
    86 proof
    87   fix J::"'i set" assume "finite J"
    88   interpret f: finite_product_prob_space M J proof qed fact
    89   show "emeasure (Pi\<^isub>M J M) (space (Pi\<^isub>M J M)) \<noteq> \<infinity>" by simp
    90 qed simp_all
    91 
    92 lemma (in projective_family) prod_emb_injective:
    93   assumes "J \<noteq> {}" "J \<subseteq> L" "finite J" and sets: "X \<in> sets (Pi\<^isub>M J M)" "Y \<in> sets (Pi\<^isub>M J M)"
    94   assumes "prod_emb L M J X = prod_emb L M J Y"
    95   shows "X = Y"
    96 proof (rule injective_vimage_restrict)
    97   show "X \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))" "Y \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))"
    98     using sets[THEN sets_into_space] by (auto simp: space_PiM)
    99   have "\<forall>i\<in>L. \<exists>x. x \<in> space (M i)"
   100       using M.not_empty by auto
   101   from bchoice[OF this]
   102   show "(\<Pi>\<^isub>E i\<in>L. space (M i)) \<noteq> {}" by auto
   103   show "(\<lambda>x. restrict x J) -` X \<inter> (\<Pi>\<^isub>E i\<in>L. space (M i)) = (\<lambda>x. restrict x J) -` Y \<inter> (\<Pi>\<^isub>E i\<in>L. space (M i))"
   104     using `prod_emb L M J X = prod_emb L M J Y` by (simp add: prod_emb_def)
   105 qed fact
   106 
   107 abbreviation (in projective_family)
   108   "emb L K X \<equiv> prod_emb L M K X"
   109 
   110 definition (in projective_family) generator :: "('i \<Rightarrow> 'a) set set" where
   111   "generator = (\<Union>J\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. emb I J ` sets (Pi\<^isub>M J M))"
   112 
   113 lemma (in projective_family) generatorI':
   114   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> emb I J X \<in> generator"
   115   unfolding generator_def by auto
   116 
   117 lemma (in projective_family) algebra_generator:
   118   assumes "I \<noteq> {}" shows "algebra (\<Pi>\<^isub>E i\<in>I. space (M i)) generator" (is "algebra ?\<Omega> ?G")
   119   unfolding algebra_def algebra_axioms_def ring_of_sets_iff
   120 proof (intro conjI ballI)
   121   let ?G = generator
   122   show "?G \<subseteq> Pow ?\<Omega>"
   123     by (auto simp: generator_def prod_emb_def)
   124   from `I \<noteq> {}` obtain i where "i \<in> I" by auto
   125   then show "{} \<in> ?G"
   126     by (auto intro!: exI[of _ "{i}"] image_eqI[where x="\<lambda>i. {}"]
   127              simp: sigma_sets.Empty generator_def prod_emb_def)
   128   from `i \<in> I` show "?\<Omega> \<in> ?G"
   129     by (auto intro!: exI[of _ "{i}"] image_eqI[where x="Pi\<^isub>E {i} (\<lambda>i. space (M i))"]
   130              simp: generator_def prod_emb_def)
   131   fix A assume "A \<in> ?G"
   132   then obtain JA XA where XA: "JA \<noteq> {}" "finite JA" "JA \<subseteq> I" "XA \<in> sets (Pi\<^isub>M JA M)" and A: "A = emb I JA XA"
   133     by (auto simp: generator_def)
   134   fix B assume "B \<in> ?G"
   135   then obtain JB XB where XB: "JB \<noteq> {}" "finite JB" "JB \<subseteq> I" "XB \<in> sets (Pi\<^isub>M JB M)" and B: "B = emb I JB XB"
   136     by (auto simp: generator_def)
   137   let ?RA = "emb (JA \<union> JB) JA XA"
   138   let ?RB = "emb (JA \<union> JB) JB XB"
   139   have *: "A - B = emb I (JA \<union> JB) (?RA - ?RB)" "A \<union> B = emb I (JA \<union> JB) (?RA \<union> ?RB)"
   140     using XA A XB B by auto
   141   show "A - B \<in> ?G" "A \<union> B \<in> ?G"
   142     unfolding * using XA XB by (safe intro!: generatorI') auto
   143 qed
   144 
   145 lemma (in projective_family) sets_PiM_generator:
   146   "sets (PiM I M) = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) generator"
   147 proof cases
   148   assume "I = {}" then show ?thesis
   149     unfolding generator_def
   150     by (auto simp: sets_PiM_empty sigma_sets_empty_eq cong: conj_cong)
   151 next
   152   assume "I \<noteq> {}"
   153   show ?thesis
   154   proof
   155     show "sets (Pi\<^isub>M I M) \<subseteq> sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) generator"
   156       unfolding sets_PiM
   157     proof (safe intro!: sigma_sets_subseteq)
   158       fix A assume "A \<in> prod_algebra I M" with `I \<noteq> {}` show "A \<in> generator"
   159         by (auto intro!: generatorI' sets_PiM_I_finite elim!: prod_algebraE)
   160     qed
   161   qed (auto simp: generator_def space_PiM[symmetric] intro!: sigma_sets_subset)
   162 qed
   163 
   164 lemma (in projective_family) generatorI:
   165   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> A = emb I J X \<Longrightarrow> A \<in> generator"
   166   unfolding generator_def by auto
   167 
   168 definition (in projective_family)
   169   "\<mu>G A =
   170     (THE x. \<forall>J. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> J \<subseteq> I \<longrightarrow> (\<forall>X\<in>sets (Pi\<^isub>M J M). A = emb I J X \<longrightarrow> x = emeasure (PiP J M P) X))"
   171 
   172 lemma (in projective_family) \<mu>G_spec:
   173   assumes J: "J \<noteq> {}" "finite J" "J \<subseteq> I" "A = emb I J X" "X \<in> sets (Pi\<^isub>M J M)"
   174   shows "\<mu>G A = emeasure (PiP J M P) X"
   175   unfolding \<mu>G_def
   176 proof (intro the_equality allI impI ballI)
   177   fix K Y assume K: "K \<noteq> {}" "finite K" "K \<subseteq> I" "A = emb I K Y" "Y \<in> sets (Pi\<^isub>M K M)"
   178   have "emeasure (PiP K M P) Y = emeasure (PiP (K \<union> J) M P) (emb (K \<union> J) K Y)"
   179     using K J by simp
   180   also have "emb (K \<union> J) K Y = emb (K \<union> J) J X"
   181     using K J by (simp add: prod_emb_injective[of "K \<union> J" I])
   182   also have "emeasure (PiP (K \<union> J) M P) (emb (K \<union> J) J X) = emeasure (PiP J M P) X"
   183     using K J by simp
   184   finally show "emeasure (PiP J M P) X = emeasure (PiP K M P) Y" ..
   185 qed (insert J, force)
   186 
   187 lemma (in projective_family) \<mu>G_eq:
   188   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> \<mu>G (emb I J X) = emeasure (PiP J M P) X"
   189   by (intro \<mu>G_spec) auto
   190 
   191 lemma (in projective_family) generator_Ex:
   192   assumes *: "A \<in> generator"
   193   shows "\<exists>J X. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I \<and> X \<in> sets (Pi\<^isub>M J M) \<and> A = emb I J X \<and> \<mu>G A = emeasure (PiP J M P) X"
   194 proof -
   195   from * obtain J X where J: "J \<noteq> {}" "finite J" "J \<subseteq> I" "A = emb I J X" "X \<in> sets (Pi\<^isub>M J M)"
   196     unfolding generator_def by auto
   197   with \<mu>G_spec[OF this] show ?thesis by auto
   198 qed
   199 
   200 lemma (in projective_family) generatorE:
   201   assumes A: "A \<in> generator"
   202   obtains J X where "J \<noteq> {}" "finite J" "J \<subseteq> I" "X \<in> sets (Pi\<^isub>M J M)" "emb I J X = A" "\<mu>G A = emeasure (PiP J M P) X"
   203 proof -
   204   from generator_Ex[OF A] obtain X J where "J \<noteq> {}" "finite J" "J \<subseteq> I" "X \<in> sets (Pi\<^isub>M J M)" "emb I J X = A"
   205     "\<mu>G A = emeasure (PiP J M P) X" by auto
   206   then show thesis by (intro that) auto
   207 qed
   208 
   209 lemma (in projective_family) merge_sets:
   210   "J \<inter> K = {} \<Longrightarrow> A \<in> sets (Pi\<^isub>M (J \<union> K) M) \<Longrightarrow> x \<in> space (Pi\<^isub>M J M) \<Longrightarrow> (\<lambda>y. merge J K (x,y)) -` A \<inter> space (Pi\<^isub>M K M) \<in> sets (Pi\<^isub>M K M)"
   211   by simp
   212 
   213 lemma (in projective_family) merge_emb:
   214   assumes "K \<subseteq> I" "J \<subseteq> I" and y: "y \<in> space (Pi\<^isub>M J M)"
   215   shows "((\<lambda>x. merge J (I - J) (y, x)) -` emb I K X \<inter> space (Pi\<^isub>M I M)) =
   216     emb I (K - J) ((\<lambda>x. merge J (K - J) (y, x)) -` emb (J \<union> K) K X \<inter> space (Pi\<^isub>M (K - J) M))"
   217 proof -
   218   have [simp]: "\<And>x J K L. merge J K (y, restrict x L) = merge J (K \<inter> L) (y, x)"
   219     by (auto simp: restrict_def merge_def)
   220   have [simp]: "\<And>x J K L. restrict (merge J K (y, x)) L = merge (J \<inter> L) (K \<inter> L) (y, x)"
   221     by (auto simp: restrict_def merge_def)
   222   have [simp]: "(I - J) \<inter> K = K - J" using `K \<subseteq> I` `J \<subseteq> I` by auto
   223   have [simp]: "(K - J) \<inter> (K \<union> J) = K - J" by auto
   224   have [simp]: "(K - J) \<inter> K = K - J" by auto
   225   from y `K \<subseteq> I` `J \<subseteq> I` show ?thesis
   226     by (simp split: split_merge add: prod_emb_def Pi_iff extensional_merge_sub set_eq_iff space_PiM)
   227        auto
   228 qed
   229 
   230 lemma (in projective_family) positive_\<mu>G:
   231   assumes "I \<noteq> {}"
   232   shows "positive generator \<mu>G"
   233 proof -
   234   interpret G!: algebra "\<Pi>\<^isub>E i\<in>I. space (M i)" generator by (rule algebra_generator) fact
   235   show ?thesis
   236   proof (intro positive_def[THEN iffD2] conjI ballI)
   237     from generatorE[OF G.empty_sets] guess J X . note this[simp]
   238     interpret J: finite_product_sigma_finite M J by default fact
   239     have "X = {}"
   240       by (rule prod_emb_injective[of J I]) simp_all
   241     then show "\<mu>G {} = 0" by simp
   242   next
   243     fix A assume "A \<in> generator"
   244     from generatorE[OF this] guess J X . note this[simp]
   245     interpret J: finite_product_sigma_finite M J by default fact
   246     show "0 \<le> \<mu>G A" by (simp add: emeasure_nonneg)
   247   qed
   248 qed
   249 
   250 lemma (in projective_family) additive_\<mu>G:
   251   assumes "I \<noteq> {}"
   252   shows "additive generator \<mu>G"
   253 proof -
   254   interpret G!: algebra "\<Pi>\<^isub>E i\<in>I. space (M i)" generator by (rule algebra_generator) fact
   255   show ?thesis
   256   proof (intro additive_def[THEN iffD2] ballI impI)
   257     fix A assume "A \<in> generator" with generatorE guess J X . note J = this
   258     fix B assume "B \<in> generator" with generatorE guess K Y . note K = this
   259     assume "A \<inter> B = {}"
   260     have JK: "J \<union> K \<noteq> {}" "J \<union> K \<subseteq> I" "finite (J \<union> K)"
   261       using J K by auto
   262     interpret JK: finite_product_sigma_finite M "J \<union> K" by default fact
   263     have JK_disj: "emb (J \<union> K) J X \<inter> emb (J \<union> K) K Y = {}"
   264       apply (rule prod_emb_injective[of "J \<union> K" I])
   265       apply (insert `A \<inter> B = {}` JK J K)
   266       apply (simp_all add: Int prod_emb_Int)
   267       done
   268     have AB: "A = emb I (J \<union> K) (emb (J \<union> K) J X)" "B = emb I (J \<union> K) (emb (J \<union> K) K Y)"
   269       using J K by simp_all
   270     then have "\<mu>G (A \<union> B) = \<mu>G (emb I (J \<union> K) (emb (J \<union> K) J X \<union> emb (J \<union> K) K Y))"
   271       by simp
   272     also have "\<dots> = emeasure (PiP (J \<union> K) M P) (emb (J \<union> K) J X \<union> emb (J \<union> K) K Y)"
   273       using JK J(1, 4) K(1, 4) by (simp add: \<mu>G_eq Un del: prod_emb_Un)
   274     also have "\<dots> = \<mu>G A + \<mu>G B"
   275       using J K JK_disj by (simp add: plus_emeasure[symmetric])
   276     finally show "\<mu>G (A \<union> B) = \<mu>G A + \<mu>G B" .
   277   qed
   278 qed
   279 
   280 lemma (in product_prob_space) PiP_PiM_finite[simp]:
   281   assumes "J \<noteq> {}" "finite J" "J \<subseteq> I" shows "PiP J M (\<lambda>J. PiM J M) = PiM J M"
   282   using assms by (simp add: PiP_finite)
   283 
   284 lemma (in product_prob_space) emeasure_PiM_emb_not_empty:
   285   assumes X: "J \<noteq> {}" "J \<subseteq> I" "finite J" "\<forall>i\<in>J. X i \<in> sets (M i)"
   286   shows "emeasure (Pi\<^isub>M I M) (emb I J (Pi\<^isub>E J X)) = emeasure (Pi\<^isub>M J M) (Pi\<^isub>E J X)"
   287 proof cases
   288   assume "finite I" with X show ?thesis by simp
   289 next
   290   let ?\<Omega> = "\<Pi>\<^isub>E i\<in>I. space (M i)"
   291   let ?G = generator
   292   assume "\<not> finite I"
   293   then have I_not_empty: "I \<noteq> {}" by auto
   294   interpret G!: algebra ?\<Omega> generator by (rule algebra_generator) fact
   295   note \<mu>G_mono =
   296     G.additive_increasing[OF positive_\<mu>G[OF I_not_empty] additive_\<mu>G[OF I_not_empty], THEN increasingD]
   297 
   298   { fix Z J assume J: "J \<noteq> {}" "finite J" "J \<subseteq> I" and Z: "Z \<in> ?G"
   299 
   300     from `infinite I` `finite J` obtain k where k: "k \<in> I" "k \<notin> J"
   301       by (metis rev_finite_subset subsetI)
   302     moreover from Z guess K' X' by (rule generatorE)
   303     moreover def K \<equiv> "insert k K'"
   304     moreover def X \<equiv> "emb K K' X'"
   305     ultimately have K: "K \<noteq> {}" "finite K" "K \<subseteq> I" "X \<in> sets (Pi\<^isub>M K M)" "Z = emb I K X"
   306       "K - J \<noteq> {}" "K - J \<subseteq> I" "\<mu>G Z = emeasure (Pi\<^isub>M K M) X"
   307       by (auto simp: subset_insertI)
   308     let ?M = "\<lambda>y. (\<lambda>x. merge J (K - J) (y, x)) -` emb (J \<union> K) K X \<inter> space (Pi\<^isub>M (K - J) M)"
   309     { fix y assume y: "y \<in> space (Pi\<^isub>M J M)"
   310       note * = merge_emb[OF `K \<subseteq> I` `J \<subseteq> I` y, of X]
   311       moreover
   312       have **: "?M y \<in> sets (Pi\<^isub>M (K - J) M)"
   313         using J K y by (intro merge_sets) auto
   314       ultimately
   315       have ***: "((\<lambda>x. merge J (I - J) (y, x)) -` Z \<inter> space (Pi\<^isub>M I M)) \<in> ?G"
   316         using J K by (intro generatorI) auto
   317       have "\<mu>G ((\<lambda>x. merge J (I - J) (y, x)) -` emb I K X \<inter> space (Pi\<^isub>M I M)) = emeasure (Pi\<^isub>M (K - J) M) (?M y)"
   318         unfolding * using K J by (subst \<mu>G_eq[OF _ _ _ **]) auto
   319       note * ** *** this }
   320     note merge_in_G = this
   321 
   322     have "finite (K - J)" using K by auto
   323 
   324     interpret J: finite_product_prob_space M J by default fact+
   325     interpret KmJ: finite_product_prob_space M "K - J" by default fact+
   326 
   327     have "\<mu>G Z = emeasure (Pi\<^isub>M (J \<union> (K - J)) M) (emb (J \<union> (K - J)) K X)"
   328       using K J by simp
   329     also have "\<dots> = (\<integral>\<^isup>+ x. emeasure (Pi\<^isub>M (K - J) M) (?M x) \<partial>Pi\<^isub>M J M)"
   330       using K J by (subst emeasure_fold_integral) auto
   331     also have "\<dots> = (\<integral>\<^isup>+ y. \<mu>G ((\<lambda>x. merge J (I - J) (y, x)) -` Z \<inter> space (Pi\<^isub>M I M)) \<partial>Pi\<^isub>M J M)"
   332       (is "_ = (\<integral>\<^isup>+x. \<mu>G (?MZ x) \<partial>Pi\<^isub>M J M)")
   333     proof (intro positive_integral_cong)
   334       fix x assume x: "x \<in> space (Pi\<^isub>M J M)"
   335       with K merge_in_G(2)[OF this]
   336       show "emeasure (Pi\<^isub>M (K - J) M) (?M x) = \<mu>G (?MZ x)"
   337         unfolding `Z = emb I K X` merge_in_G(1)[OF x] by (subst \<mu>G_eq) auto
   338     qed
   339     finally have fold: "\<mu>G Z = (\<integral>\<^isup>+x. \<mu>G (?MZ x) \<partial>Pi\<^isub>M J M)" .
   340 
   341     { fix x assume x: "x \<in> space (Pi\<^isub>M J M)"
   342       then have "\<mu>G (?MZ x) \<le> 1"
   343         unfolding merge_in_G(4)[OF x] `Z = emb I K X`
   344         by (intro KmJ.measure_le_1 merge_in_G(2)[OF x]) }
   345     note le_1 = this
   346 
   347     let ?q = "\<lambda>y. \<mu>G ((\<lambda>x. merge J (I - J) (y,x)) -` Z \<inter> space (Pi\<^isub>M I M))"
   348     have "?q \<in> borel_measurable (Pi\<^isub>M J M)"
   349       unfolding `Z = emb I K X` using J K merge_in_G(3)
   350       by (simp add: merge_in_G  \<mu>G_eq emeasure_fold_measurable cong: measurable_cong)
   351     note this fold le_1 merge_in_G(3) }
   352   note fold = this
   353 
   354   have "\<exists>\<mu>. (\<forall>s\<in>?G. \<mu> s = \<mu>G s) \<and> measure_space ?\<Omega> (sigma_sets ?\<Omega> ?G) \<mu>"
   355   proof (rule G.caratheodory_empty_continuous[OF positive_\<mu>G additive_\<mu>G])
   356     fix A assume "A \<in> ?G"
   357     with generatorE guess J X . note JX = this
   358     interpret JK: finite_product_prob_space M J by default fact+ 
   359     from JX show "\<mu>G A \<noteq> \<infinity>" by simp
   360   next
   361     fix A assume A: "range A \<subseteq> ?G" "decseq A" "(\<Inter>i. A i) = {}"
   362     then have "decseq (\<lambda>i. \<mu>G (A i))"
   363       by (auto intro!: \<mu>G_mono simp: decseq_def)
   364     moreover
   365     have "(INF i. \<mu>G (A i)) = 0"
   366     proof (rule ccontr)
   367       assume "(INF i. \<mu>G (A i)) \<noteq> 0" (is "?a \<noteq> 0")
   368       moreover have "0 \<le> ?a"
   369         using A positive_\<mu>G[OF I_not_empty] by (auto intro!: INF_greatest simp: positive_def)
   370       ultimately have "0 < ?a" by auto
   371 
   372       have "\<forall>n. \<exists>J X. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I \<and> X \<in> sets (Pi\<^isub>M J M) \<and> A n = emb I J X \<and> \<mu>G (A n) = emeasure (PiP J M (\<lambda>J. (Pi\<^isub>M J M))) X"
   373         using A by (intro allI generator_Ex) auto
   374       then obtain J' X' where J': "\<And>n. J' n \<noteq> {}" "\<And>n. finite (J' n)" "\<And>n. J' n \<subseteq> I" "\<And>n. X' n \<in> sets (Pi\<^isub>M (J' n) M)"
   375         and A': "\<And>n. A n = emb I (J' n) (X' n)"
   376         unfolding choice_iff by blast
   377       moreover def J \<equiv> "\<lambda>n. (\<Union>i\<le>n. J' i)"
   378       moreover def X \<equiv> "\<lambda>n. emb (J n) (J' n) (X' n)"
   379       ultimately have J: "\<And>n. J n \<noteq> {}" "\<And>n. finite (J n)" "\<And>n. J n \<subseteq> I" "\<And>n. X n \<in> sets (Pi\<^isub>M (J n) M)"
   380         by auto
   381       with A' have A_eq: "\<And>n. A n = emb I (J n) (X n)" "\<And>n. A n \<in> ?G"
   382         unfolding J_def X_def by (subst prod_emb_trans) (insert A, auto)
   383 
   384       have J_mono: "\<And>n m. n \<le> m \<Longrightarrow> J n \<subseteq> J m"
   385         unfolding J_def by force
   386 
   387       interpret J: finite_product_prob_space M "J i" for i by default fact+
   388 
   389       have a_le_1: "?a \<le> 1"
   390         using \<mu>G_spec[of "J 0" "A 0" "X 0"] J A_eq
   391         by (auto intro!: INF_lower2[of 0] J.measure_le_1)
   392 
   393       let ?M = "\<lambda>K Z y. (\<lambda>x. merge K (I - K) (y, x)) -` Z \<inter> space (Pi\<^isub>M I M)"
   394 
   395       { fix Z k assume Z: "range Z \<subseteq> ?G" "decseq Z" "\<forall>n. ?a / 2^k \<le> \<mu>G (Z n)"
   396         then have Z_sets: "\<And>n. Z n \<in> ?G" by auto
   397         fix J' assume J': "J' \<noteq> {}" "finite J'" "J' \<subseteq> I"
   398         interpret J': finite_product_prob_space M J' by default fact+
   399 
   400         let ?q = "\<lambda>n y. \<mu>G (?M J' (Z n) y)"
   401         let ?Q = "\<lambda>n. ?q n -` {?a / 2^(k+1) ..} \<inter> space (Pi\<^isub>M J' M)"
   402         { fix n
   403           have "?q n \<in> borel_measurable (Pi\<^isub>M J' M)"
   404             using Z J' by (intro fold(1)) auto
   405           then have "?Q n \<in> sets (Pi\<^isub>M J' M)"
   406             by (rule measurable_sets) auto }
   407         note Q_sets = this
   408 
   409         have "?a / 2^(k+1) \<le> (INF n. emeasure (Pi\<^isub>M J' M) (?Q n))"
   410         proof (intro INF_greatest)
   411           fix n
   412           have "?a / 2^k \<le> \<mu>G (Z n)" using Z by auto
   413           also have "\<dots> \<le> (\<integral>\<^isup>+ x. indicator (?Q n) x + ?a / 2^(k+1) \<partial>Pi\<^isub>M J' M)"
   414             unfolding fold(2)[OF J' `Z n \<in> ?G`]
   415           proof (intro positive_integral_mono)
   416             fix x assume x: "x \<in> space (Pi\<^isub>M J' M)"
   417             then have "?q n x \<le> 1 + 0"
   418               using J' Z fold(3) Z_sets by auto
   419             also have "\<dots> \<le> 1 + ?a / 2^(k+1)"
   420               using `0 < ?a` by (intro add_mono) auto
   421             finally have "?q n x \<le> 1 + ?a / 2^(k+1)" .
   422             with x show "?q n x \<le> indicator (?Q n) x + ?a / 2^(k+1)"
   423               by (auto split: split_indicator simp del: power_Suc)
   424           qed
   425           also have "\<dots> = emeasure (Pi\<^isub>M J' M) (?Q n) + ?a / 2^(k+1)"
   426             using `0 \<le> ?a` Q_sets J'.emeasure_space_1
   427             by (subst positive_integral_add) auto
   428           finally show "?a / 2^(k+1) \<le> emeasure (Pi\<^isub>M J' M) (?Q n)" using `?a \<le> 1`
   429             by (cases rule: ereal2_cases[of ?a "emeasure (Pi\<^isub>M J' M) (?Q n)"])
   430                (auto simp: field_simps)
   431         qed
   432         also have "\<dots> = emeasure (Pi\<^isub>M J' M) (\<Inter>n. ?Q n)"
   433         proof (intro INF_emeasure_decseq)
   434           show "range ?Q \<subseteq> sets (Pi\<^isub>M J' M)" using Q_sets by auto
   435           show "decseq ?Q"
   436             unfolding decseq_def
   437           proof (safe intro!: vimageI[OF refl])
   438             fix m n :: nat assume "m \<le> n"
   439             fix x assume x: "x \<in> space (Pi\<^isub>M J' M)"
   440             assume "?a / 2^(k+1) \<le> ?q n x"
   441             also have "?q n x \<le> ?q m x"
   442             proof (rule \<mu>G_mono)
   443               from fold(4)[OF J', OF Z_sets x]
   444               show "?M J' (Z n) x \<in> ?G" "?M J' (Z m) x \<in> ?G" by auto
   445               show "?M J' (Z n) x \<subseteq> ?M J' (Z m) x"
   446                 using `decseq Z`[THEN decseqD, OF `m \<le> n`] by auto
   447             qed
   448             finally show "?a / 2^(k+1) \<le> ?q m x" .
   449           qed
   450         qed simp
   451         finally have "(\<Inter>n. ?Q n) \<noteq> {}"
   452           using `0 < ?a` `?a \<le> 1` by (cases ?a) (auto simp: divide_le_0_iff power_le_zero_eq)
   453         then have "\<exists>w\<in>space (Pi\<^isub>M J' M). \<forall>n. ?a / 2 ^ (k + 1) \<le> ?q n w" by auto }
   454       note Ex_w = this
   455 
   456       let ?q = "\<lambda>k n y. \<mu>G (?M (J k) (A n) y)"
   457 
   458       have "\<forall>n. ?a / 2 ^ 0 \<le> \<mu>G (A n)" by (auto intro: INF_lower)
   459       from Ex_w[OF A(1,2) this J(1-3), of 0] guess w0 .. note w0 = this
   460 
   461       let ?P =
   462         "\<lambda>k wk w. w \<in> space (Pi\<^isub>M (J (Suc k)) M) \<and> restrict w (J k) = wk \<and>
   463           (\<forall>n. ?a / 2 ^ (Suc k + 1) \<le> ?q (Suc k) n w)"
   464       def w \<equiv> "nat_rec w0 (\<lambda>k wk. Eps (?P k wk))"
   465 
   466       { fix k have w: "w k \<in> space (Pi\<^isub>M (J k) M) \<and>
   467           (\<forall>n. ?a / 2 ^ (k + 1) \<le> ?q k n (w k)) \<and> (k \<noteq> 0 \<longrightarrow> restrict (w k) (J (k - 1)) = w (k - 1))"
   468         proof (induct k)
   469           case 0 with w0 show ?case
   470             unfolding w_def nat_rec_0 by auto
   471         next
   472           case (Suc k)
   473           then have wk: "w k \<in> space (Pi\<^isub>M (J k) M)" by auto
   474           have "\<exists>w'. ?P k (w k) w'"
   475           proof cases
   476             assume [simp]: "J k = J (Suc k)"
   477             show ?thesis
   478             proof (intro exI[of _ "w k"] conjI allI)
   479               fix n
   480               have "?a / 2 ^ (Suc k + 1) \<le> ?a / 2 ^ (k + 1)"
   481                 using `0 < ?a` `?a \<le> 1` by (cases ?a) (auto simp: field_simps)
   482               also have "\<dots> \<le> ?q k n (w k)" using Suc by auto
   483               finally show "?a / 2 ^ (Suc k + 1) \<le> ?q (Suc k) n (w k)" by simp
   484             next
   485               show "w k \<in> space (Pi\<^isub>M (J (Suc k)) M)"
   486                 using Suc by simp
   487               then show "restrict (w k) (J k) = w k"
   488                 by (simp add: extensional_restrict space_PiM)
   489             qed
   490           next
   491             assume "J k \<noteq> J (Suc k)"
   492             with J_mono[of k "Suc k"] have "J (Suc k) - J k \<noteq> {}" (is "?D \<noteq> {}") by auto
   493             have "range (\<lambda>n. ?M (J k) (A n) (w k)) \<subseteq> ?G"
   494               "decseq (\<lambda>n. ?M (J k) (A n) (w k))"
   495               "\<forall>n. ?a / 2 ^ (k + 1) \<le> \<mu>G (?M (J k) (A n) (w k))"
   496               using `decseq A` fold(4)[OF J(1-3) A_eq(2), of "w k" k] Suc
   497               by (auto simp: decseq_def)
   498             from Ex_w[OF this `?D \<noteq> {}`] J[of "Suc k"]
   499             obtain w' where w': "w' \<in> space (Pi\<^isub>M ?D M)"
   500               "\<forall>n. ?a / 2 ^ (Suc k + 1) \<le> \<mu>G (?M ?D (?M (J k) (A n) (w k)) w')" by auto
   501             let ?w = "merge (J k) ?D (w k, w')"
   502             have [simp]: "\<And>x. merge (J k) (I - J k) (w k, merge ?D (I - ?D) (w', x)) =
   503               merge (J (Suc k)) (I - (J (Suc k))) (?w, x)"
   504               using J(3)[of "Suc k"] J(3)[of k] J_mono[of k "Suc k"]
   505               by (auto intro!: ext split: split_merge)
   506             have *: "\<And>n. ?M ?D (?M (J k) (A n) (w k)) w' = ?M (J (Suc k)) (A n) ?w"
   507               using w'(1) J(3)[of "Suc k"]
   508               by (auto simp: space_PiM split: split_merge intro!: extensional_merge_sub) force+
   509             show ?thesis
   510               apply (rule exI[of _ ?w])
   511               using w' J_mono[of k "Suc k"] wk unfolding *
   512               apply (auto split: split_merge intro!: extensional_merge_sub ext simp: space_PiM)
   513               apply (force simp: extensional_def)
   514               done
   515           qed
   516           then have "?P k (w k) (w (Suc k))"
   517             unfolding w_def nat_rec_Suc unfolding w_def[symmetric]
   518             by (rule someI_ex)
   519           then show ?case by auto
   520         qed
   521         moreover
   522         then have "w k \<in> space (Pi\<^isub>M (J k) M)" by auto
   523         moreover
   524         from w have "?a / 2 ^ (k + 1) \<le> ?q k k (w k)" by auto
   525         then have "?M (J k) (A k) (w k) \<noteq> {}"
   526           using positive_\<mu>G[OF I_not_empty, unfolded positive_def] `0 < ?a` `?a \<le> 1`
   527           by (cases ?a) (auto simp: divide_le_0_iff power_le_zero_eq)
   528         then obtain x where "x \<in> ?M (J k) (A k) (w k)" by auto
   529         then have "merge (J k) (I - J k) (w k, x) \<in> A k" by auto
   530         then have "\<exists>x\<in>A k. restrict x (J k) = w k"
   531           using `w k \<in> space (Pi\<^isub>M (J k) M)`
   532           by (intro rev_bexI) (auto intro!: ext simp: extensional_def space_PiM)
   533         ultimately have "w k \<in> space (Pi\<^isub>M (J k) M)"
   534           "\<exists>x\<in>A k. restrict x (J k) = w k"
   535           "k \<noteq> 0 \<Longrightarrow> restrict (w k) (J (k - 1)) = w (k - 1)"
   536           by auto }
   537       note w = this
   538 
   539       { fix k l i assume "k \<le> l" "i \<in> J k"
   540         { fix l have "w k i = w (k + l) i"
   541           proof (induct l)
   542             case (Suc l)
   543             from `i \<in> J k` J_mono[of k "k + l"] have "i \<in> J (k + l)" by auto
   544             with w(3)[of "k + Suc l"]
   545             have "w (k + l) i = w (k + Suc l) i"
   546               by (auto simp: restrict_def fun_eq_iff split: split_if_asm)
   547             with Suc show ?case by simp
   548           qed simp }
   549         from this[of "l - k"] `k \<le> l` have "w l i = w k i" by simp }
   550       note w_mono = this
   551 
   552       def w' \<equiv> "\<lambda>i. if i \<in> (\<Union>k. J k) then w (LEAST k. i \<in> J k) i else if i \<in> I then (SOME x. x \<in> space (M i)) else undefined"
   553       { fix i k assume k: "i \<in> J k"
   554         have "w k i = w (LEAST k. i \<in> J k) i"
   555           by (intro w_mono Least_le k LeastI[of _ k])
   556         then have "w' i = w k i"
   557           unfolding w'_def using k by auto }
   558       note w'_eq = this
   559       have w'_simps1: "\<And>i. i \<notin> I \<Longrightarrow> w' i = undefined"
   560         using J by (auto simp: w'_def)
   561       have w'_simps2: "\<And>i. i \<notin> (\<Union>k. J k) \<Longrightarrow> i \<in> I \<Longrightarrow> w' i \<in> space (M i)"
   562         using J by (auto simp: w'_def intro!: someI_ex[OF M.not_empty[unfolded ex_in_conv[symmetric]]])
   563       { fix i assume "i \<in> I" then have "w' i \<in> space (M i)"
   564           using w(1) by (cases "i \<in> (\<Union>k. J k)") (force simp: w'_simps2 w'_eq space_PiM)+ }
   565       note w'_simps[simp] = w'_eq w'_simps1 w'_simps2 this
   566 
   567       have w': "w' \<in> space (Pi\<^isub>M I M)"
   568         using w(1) by (auto simp add: Pi_iff extensional_def space_PiM)
   569 
   570       { fix n
   571         have "restrict w' (J n) = w n" using w(1)
   572           by (auto simp add: fun_eq_iff restrict_def Pi_iff extensional_def space_PiM)
   573         with w[of n] obtain x where "x \<in> A n" "restrict x (J n) = restrict w' (J n)" by auto
   574         then have "w' \<in> A n" unfolding A_eq using w' by (auto simp: prod_emb_def space_PiM) }
   575       then have "w' \<in> (\<Inter>i. A i)" by auto
   576       with `(\<Inter>i. A i) = {}` show False by auto
   577     qed
   578     ultimately show "(\<lambda>i. \<mu>G (A i)) ----> 0"
   579       using LIMSEQ_ereal_INFI[of "\<lambda>i. \<mu>G (A i)"] by simp
   580   qed fact+
   581   then guess \<mu> .. note \<mu> = this
   582   show ?thesis
   583   proof (subst emeasure_extend_measure_Pair[OF PiM_def, of I M \<mu> J X])
   584     from assms show "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))"
   585       by (simp add: Pi_iff)
   586   next
   587     fix J X assume J: "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))"
   588     then show "emb I J (Pi\<^isub>E J X) \<in> Pow (\<Pi>\<^isub>E i\<in>I. space (M i))"
   589       by (auto simp: Pi_iff prod_emb_def dest: sets_into_space)
   590     have "emb I J (Pi\<^isub>E J X) \<in> generator"
   591       using J `I \<noteq> {}` by (intro generatorI') (auto simp: Pi_iff)
   592     then have "\<mu> (emb I J (Pi\<^isub>E J X)) = \<mu>G (emb I J (Pi\<^isub>E J X))"
   593       using \<mu> by simp
   594     also have "\<dots> = (\<Prod> j\<in>J. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   595       using J  `I \<noteq> {}` by (subst \<mu>G_spec[OF _ _ _ refl]) (auto simp: emeasure_PiM Pi_iff)
   596     also have "\<dots> = (\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}.
   597       if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   598       using J `I \<noteq> {}` by (intro setprod_mono_one_right) (auto simp: M.emeasure_space_1)
   599     finally show "\<mu> (emb I J (Pi\<^isub>E J X)) = \<dots>" .
   600   next
   601     let ?F = "\<lambda>j. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j))"
   602     have "(\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}. ?F j) = (\<Prod>j\<in>J. ?F j)"
   603       using X `I \<noteq> {}` by (intro setprod_mono_one_right) (auto simp: M.emeasure_space_1)
   604     then show "(\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}. ?F j) =
   605       emeasure (Pi\<^isub>M J M) (Pi\<^isub>E J X)"
   606       using X by (auto simp add: emeasure_PiM) 
   607   next
   608     show "positive (sets (Pi\<^isub>M I M)) \<mu>" "countably_additive (sets (Pi\<^isub>M I M)) \<mu>"
   609       using \<mu> unfolding sets_PiM_generator by (auto simp: measure_space_def)
   610   qed
   611 qed
   612 
   613 sublocale product_prob_space \<subseteq> P: prob_space "Pi\<^isub>M I M"
   614 proof
   615   show "emeasure (Pi\<^isub>M I M) (space (Pi\<^isub>M I M)) = 1"
   616   proof cases
   617     assume "I = {}" then show ?thesis by (simp add: space_PiM_empty)
   618   next
   619     assume "I \<noteq> {}"
   620     then obtain i where "i \<in> I" by auto
   621     moreover then have "emb I {i} (\<Pi>\<^isub>E i\<in>{i}. space (M i)) = (space (Pi\<^isub>M I M))"
   622       by (auto simp: prod_emb_def space_PiM)
   623     ultimately show ?thesis
   624       using emeasure_PiM_emb_not_empty[of "{i}" "\<lambda>i. space (M i)"]
   625       by (simp add: emeasure_PiM emeasure_space_1)
   626   qed
   627 qed
   628 
   629 lemma (in product_prob_space) emeasure_PiM_emb:
   630   assumes X: "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   631   shows "emeasure (Pi\<^isub>M I M) (emb I J (Pi\<^isub>E J X)) = (\<Prod> i\<in>J. emeasure (M i) (X i))"
   632 proof cases
   633   assume "J = {}"
   634   moreover have "emb I {} {\<lambda>x. undefined} = space (Pi\<^isub>M I M)"
   635     by (auto simp: space_PiM prod_emb_def)
   636   ultimately show ?thesis
   637     by (simp add: space_PiM_empty P.emeasure_space_1)
   638 next
   639   assume "J \<noteq> {}" with X show ?thesis
   640     by (subst emeasure_PiM_emb_not_empty) (auto simp: emeasure_PiM)
   641 qed
   642 
   643 lemma (in product_prob_space) emeasure_PiM_Collect:
   644   assumes X: "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   645   shows "emeasure (Pi\<^isub>M I M) {x\<in>space (Pi\<^isub>M I M). \<forall>i\<in>J. x i \<in> X i} = (\<Prod> i\<in>J. emeasure (M i) (X i))"
   646 proof -
   647   have "{x\<in>space (Pi\<^isub>M I M). \<forall>i\<in>J. x i \<in> X i} = emb I J (Pi\<^isub>E J X)"
   648     unfolding prod_emb_def using assms by (auto simp: space_PiM Pi_iff)
   649   with emeasure_PiM_emb[OF assms] show ?thesis by simp
   650 qed
   651 
   652 lemma (in product_prob_space) emeasure_PiM_Collect_single:
   653   assumes X: "i \<in> I" "A \<in> sets (M i)"
   654   shows "emeasure (Pi\<^isub>M I M) {x\<in>space (Pi\<^isub>M I M). x i \<in> A} = emeasure (M i) A"
   655   using emeasure_PiM_Collect[of "{i}" "\<lambda>i. A"] assms
   656   by simp
   657 
   658 lemma (in product_prob_space) measure_PiM_emb:
   659   assumes "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   660   shows "measure (PiM I M) (emb I J (Pi\<^isub>E J X)) = (\<Prod> i\<in>J. measure (M i) (X i))"
   661   using emeasure_PiM_emb[OF assms]
   662   unfolding emeasure_eq_measure M.emeasure_eq_measure by (simp add: setprod_ereal)
   663 
   664 lemma sets_Collect_single':
   665   "i \<in> I \<Longrightarrow> {x\<in>space (M i). P x} \<in> sets (M i) \<Longrightarrow> {x\<in>space (PiM I M). P (x i)} \<in> sets (PiM I M)"
   666   using sets_Collect_single[of i I "{x\<in>space (M i). P x}" M]
   667   by (simp add: space_PiM Pi_iff cong: conj_cong)
   668 
   669 lemma (in finite_product_prob_space) finite_measure_PiM_emb:
   670   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> measure (PiM I M) (Pi\<^isub>E I A) = (\<Prod>i\<in>I. measure (M i) (A i))"
   671   using measure_PiM_emb[of I A] finite_index prod_emb_PiE_same_index[OF sets_into_space, of I A M]
   672   by auto
   673 
   674 lemma (in product_prob_space) PiM_component:
   675   assumes "i \<in> I"
   676   shows "distr (PiM I M) (M i) (\<lambda>\<omega>. \<omega> i) = M i"
   677 proof (rule measure_eqI[symmetric])
   678   fix A assume "A \<in> sets (M i)"
   679   moreover have "((\<lambda>\<omega>. \<omega> i) -` A \<inter> space (PiM I M)) = {x\<in>space (PiM I M). x i \<in> A}"
   680     by auto
   681   ultimately show "emeasure (M i) A = emeasure (distr (PiM I M) (M i) (\<lambda>\<omega>. \<omega> i)) A"
   682     by (auto simp: `i\<in>I` emeasure_distr measurable_component_singleton emeasure_PiM_Collect_single)
   683 qed simp
   684 
   685 lemma (in product_prob_space) PiM_eq:
   686   assumes "I \<noteq> {}"
   687   assumes "sets M' = sets (PiM I M)"
   688   assumes eq: "\<And>J F. finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>j. j \<in> J \<Longrightarrow> F j \<in> sets (M j)) \<Longrightarrow>
   689     emeasure M' (prod_emb I M J (\<Pi>\<^isub>E j\<in>J. F j)) = (\<Prod>j\<in>J. emeasure (M j) (F j))"
   690   shows "M' = (PiM I M)"
   691 proof (rule measure_eqI_generator_eq[symmetric, OF Int_stable_prod_algebra prod_algebra_sets_into_space])
   692   show "sets (PiM I M) = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) (prod_algebra I M)"
   693     by (rule sets_PiM)
   694   then show "sets M' = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) (prod_algebra I M)"
   695     unfolding `sets M' = sets (PiM I M)` by simp
   696 
   697   def i \<equiv> "SOME i. i \<in> I"
   698   with `I \<noteq> {}` have i: "i \<in> I"
   699     by (auto intro: someI_ex)
   700 
   701   def A \<equiv> "\<lambda>n::nat. prod_emb I M {i} (\<Pi>\<^isub>E j\<in>{i}. space (M i))"
   702   then show "range A \<subseteq> prod_algebra I M"
   703     by (auto intro!: prod_algebraI i)
   704 
   705   have A_eq: "\<And>i. A i = space (PiM I M)"
   706     by (auto simp: prod_emb_def space_PiM Pi_iff A_def i)
   707   show "(\<Union>i. A i) = (\<Pi>\<^isub>E i\<in>I. space (M i))"
   708     unfolding A_eq by (auto simp: space_PiM)
   709   show "\<And>i. emeasure (PiM I M) (A i) \<noteq> \<infinity>"
   710     unfolding A_eq P.emeasure_space_1 by simp
   711 next
   712   fix X assume X: "X \<in> prod_algebra I M"
   713   then obtain J E where X: "X = prod_emb I M J (PIE j:J. E j)"
   714     and J: "finite J" "J \<subseteq> I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets (M j)"
   715     by (force elim!: prod_algebraE)
   716   from eq[OF J] have "emeasure M' X = (\<Prod>j\<in>J. emeasure (M j) (E j))"
   717     by (simp add: X)
   718   also have "\<dots> = emeasure (PiM I M) X"
   719     unfolding X using J by (intro emeasure_PiM_emb[symmetric]) auto
   720   finally show "emeasure (PiM I M) X = emeasure M' X" ..
   721 qed
   722 
   723 subsection {* Sequence space *}
   724 
   725 lemma measurable_nat_case: "(\<lambda>(x, \<omega>). nat_case x \<omega>) \<in> measurable (M \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)) (\<Pi>\<^isub>M i\<in>UNIV. M)"
   726 proof (rule measurable_PiM_single)
   727   show "(\<lambda>(x, \<omega>). nat_case x \<omega>) \<in> space (M \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)) \<rightarrow> (UNIV \<rightarrow>\<^isub>E space M)"
   728     by (auto simp: space_pair_measure space_PiM Pi_iff split: nat.split)
   729   fix i :: nat and A assume A: "A \<in> sets M"
   730   then have *: "{\<omega> \<in> space (M \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)). prod_case nat_case \<omega> i \<in> A} =
   731     (case i of 0 \<Rightarrow> A \<times> space (\<Pi>\<^isub>M i\<in>UNIV. M) | Suc n \<Rightarrow> space M \<times> {\<omega>\<in>space (\<Pi>\<^isub>M i\<in>UNIV. M). \<omega> n \<in> A})"
   732     by (auto simp: space_PiM space_pair_measure split: nat.split dest: sets_into_space)
   733   show "{\<omega> \<in> space (M \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)). prod_case nat_case \<omega> i \<in> A} \<in> sets (M \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M))"
   734     unfolding * by (auto simp: A split: nat.split intro!: sets_Collect_single)
   735 qed
   736 
   737 lemma measurable_nat_case':
   738   assumes f: "f \<in> measurable N M" and g: "g \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)"
   739   shows "(\<lambda>x. nat_case (f x) (g x)) \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)"
   740   using measurable_compose[OF measurable_Pair[OF f g] measurable_nat_case] by simp
   741 
   742 definition comb_seq :: "nat \<Rightarrow> (nat \<Rightarrow> 'a) \<Rightarrow> (nat \<Rightarrow> 'a) \<Rightarrow> (nat \<Rightarrow> 'a)" where
   743   "comb_seq i \<omega> \<omega>' j = (if j < i then \<omega> j else \<omega>' (j - i))"
   744 
   745 lemma split_comb_seq: "P (comb_seq i \<omega> \<omega>' j) \<longleftrightarrow> (j < i \<longrightarrow> P (\<omega> j)) \<and> (\<forall>k. j = i + k \<longrightarrow> P (\<omega>' k))"
   746   by (auto simp: comb_seq_def not_less)
   747 
   748 lemma split_comb_seq_asm: "P (comb_seq i \<omega> \<omega>' j) \<longleftrightarrow> \<not> ((j < i \<and> \<not> P (\<omega> j)) \<or> (\<exists>k. j = i + k \<and> \<not> P (\<omega>' k)))"
   749   by (auto simp: comb_seq_def)
   750 
   751 lemma measurable_comb_seq: "(\<lambda>(\<omega>, \<omega>'). comb_seq i \<omega> \<omega>') \<in> measurable ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)) (\<Pi>\<^isub>M i\<in>UNIV. M)"
   752 proof (rule measurable_PiM_single)
   753   show "(\<lambda>(\<omega>, \<omega>'). comb_seq i \<omega> \<omega>') \<in> space ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)) \<rightarrow> (UNIV \<rightarrow>\<^isub>E space M)"
   754     by (auto simp: space_pair_measure space_PiM Pi_iff split: split_comb_seq)
   755   fix j :: nat and A assume A: "A \<in> sets M"
   756   then have *: "{\<omega> \<in> space ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)). prod_case (comb_seq i) \<omega> j \<in> A} =
   757     (if j < i then {\<omega> \<in> space (\<Pi>\<^isub>M i\<in>UNIV. M). \<omega> j \<in> A} \<times> space (\<Pi>\<^isub>M i\<in>UNIV. M)
   758               else space (\<Pi>\<^isub>M i\<in>UNIV. M) \<times> {\<omega> \<in> space (\<Pi>\<^isub>M i\<in>UNIV. M). \<omega> (j - i) \<in> A})"
   759     by (auto simp: space_PiM space_pair_measure comb_seq_def dest: sets_into_space)
   760   show "{\<omega> \<in> space ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M)). prod_case (comb_seq i) \<omega> j \<in> A} \<in> sets ((\<Pi>\<^isub>M i\<in>UNIV. M) \<Otimes>\<^isub>M (\<Pi>\<^isub>M i\<in>UNIV. M))"
   761     unfolding * by (auto simp: A intro!: sets_Collect_single)
   762 qed
   763 
   764 lemma measurable_comb_seq':
   765   assumes f: "f \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)" and g: "g \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)"
   766   shows "(\<lambda>x. comb_seq i (f x) (g x)) \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)"
   767   using measurable_compose[OF measurable_Pair[OF f g] measurable_comb_seq] by simp
   768 
   769 locale sequence_space = product_prob_space "\<lambda>i. M" "UNIV :: nat set" for M
   770 begin
   771 
   772 abbreviation "S \<equiv> \<Pi>\<^isub>M i\<in>UNIV::nat set. M"
   773 
   774 lemma infprod_in_sets[intro]:
   775   fixes E :: "nat \<Rightarrow> 'a set" assumes E: "\<And>i. E i \<in> sets M"
   776   shows "Pi UNIV E \<in> sets S"
   777 proof -
   778   have "Pi UNIV E = (\<Inter>i. emb UNIV {..i} (\<Pi>\<^isub>E j\<in>{..i}. E j))"
   779     using E E[THEN sets_into_space]
   780     by (auto simp: prod_emb_def Pi_iff extensional_def) blast
   781   with E show ?thesis by auto
   782 qed
   783 
   784 lemma measure_PiM_countable:
   785   fixes E :: "nat \<Rightarrow> 'a set" assumes E: "\<And>i. E i \<in> sets M"
   786   shows "(\<lambda>n. \<Prod>i\<le>n. measure M (E i)) ----> measure S (Pi UNIV E)"
   787 proof -
   788   let ?E = "\<lambda>n. emb UNIV {..n} (Pi\<^isub>E {.. n} E)"
   789   have "\<And>n. (\<Prod>i\<le>n. measure M (E i)) = measure S (?E n)"
   790     using E by (simp add: measure_PiM_emb)
   791   moreover have "Pi UNIV E = (\<Inter>n. ?E n)"
   792     using E E[THEN sets_into_space]
   793     by (auto simp: prod_emb_def extensional_def Pi_iff) blast
   794   moreover have "range ?E \<subseteq> sets S"
   795     using E by auto
   796   moreover have "decseq ?E"
   797     by (auto simp: prod_emb_def Pi_iff decseq_def)
   798   ultimately show ?thesis
   799     by (simp add: finite_Lim_measure_decseq)
   800 qed
   801 
   802 lemma nat_eq_diff_eq: 
   803   fixes a b c :: nat
   804   shows "c \<le> b \<Longrightarrow> a = b - c \<longleftrightarrow> a + c = b"
   805   by auto
   806 
   807 lemma PiM_comb_seq:
   808   "distr (S \<Otimes>\<^isub>M S) S (\<lambda>(\<omega>, \<omega>'). comb_seq i \<omega> \<omega>') = S" (is "?D = _")
   809 proof (rule PiM_eq)
   810   let ?I = "UNIV::nat set" and ?M = "\<lambda>n. M"
   811   let "distr _ _ ?f" = "?D"
   812 
   813   fix J E assume J: "finite J" "J \<subseteq> ?I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets M"
   814   let ?X = "prod_emb ?I ?M J (\<Pi>\<^isub>E j\<in>J. E j)"
   815   have "\<And>j x. j \<in> J \<Longrightarrow> x \<in> E j \<Longrightarrow> x \<in> space M"
   816     using J(3)[THEN sets_into_space] by (auto simp: space_PiM Pi_iff subset_eq)
   817   with J have "?f -` ?X \<inter> space (S \<Otimes>\<^isub>M S) =
   818     (prod_emb ?I ?M (J \<inter> {..<i}) (PIE j:J \<inter> {..<i}. E j)) \<times>
   819     (prod_emb ?I ?M ((op + i) -` J) (PIE j:(op + i) -` J. E (i + j)))" (is "_ = ?E \<times> ?F")
   820    by (auto simp: space_pair_measure space_PiM prod_emb_def all_conj_distrib Pi_iff
   821                split: split_comb_seq split_comb_seq_asm)
   822   then have "emeasure ?D ?X = emeasure (S \<Otimes>\<^isub>M S) (?E \<times> ?F)"
   823     by (subst emeasure_distr[OF measurable_comb_seq])
   824        (auto intro!: sets_PiM_I simp: split_beta' J)
   825   also have "\<dots> = emeasure S ?E * emeasure S ?F"
   826     using J by (intro P.emeasure_pair_measure_Times)  (auto intro!: sets_PiM_I finite_vimageI simp: inj_on_def)
   827   also have "emeasure S ?F = (\<Prod>j\<in>(op + i) -` J. emeasure M (E (i + j)))"
   828     using J by (intro emeasure_PiM_emb) (simp_all add: finite_vimageI inj_on_def)
   829   also have "\<dots> = (\<Prod>j\<in>J - (J \<inter> {..<i}). emeasure M (E j))"
   830     by (rule strong_setprod_reindex_cong[where f="\<lambda>x. x - i"])
   831        (auto simp: image_iff Bex_def not_less nat_eq_diff_eq ac_simps cong: conj_cong intro!: inj_onI)
   832   also have "emeasure S ?E = (\<Prod>j\<in>J \<inter> {..<i}. emeasure M (E j))"
   833     using J by (intro emeasure_PiM_emb) simp_all
   834   also have "(\<Prod>j\<in>J \<inter> {..<i}. emeasure M (E j)) * (\<Prod>j\<in>J - (J \<inter> {..<i}). emeasure M (E j)) = (\<Prod>j\<in>J. emeasure M (E j))"
   835     by (subst mult_commute) (auto simp: J setprod_subset_diff[symmetric])
   836   finally show "emeasure ?D ?X = (\<Prod>j\<in>J. emeasure M (E j))" .
   837 qed simp_all
   838 
   839 lemma PiM_iter:
   840   "distr (M \<Otimes>\<^isub>M S) S (\<lambda>(s, \<omega>). nat_case s \<omega>) = S" (is "?D = _")
   841 proof (rule PiM_eq)
   842   let ?I = "UNIV::nat set" and ?M = "\<lambda>n. M"
   843   let "distr _ _ ?f" = "?D"
   844 
   845   fix J E assume J: "finite J" "J \<subseteq> ?I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets M"
   846   let ?X = "prod_emb ?I ?M J (PIE j:J. E j)"
   847   have "\<And>j x. j \<in> J \<Longrightarrow> x \<in> E j \<Longrightarrow> x \<in> space M"
   848     using J(3)[THEN sets_into_space] by (auto simp: space_PiM Pi_iff subset_eq)
   849   with J have "?f -` ?X \<inter> space (M \<Otimes>\<^isub>M S) = (if 0 \<in> J then E 0 else space M) \<times>
   850     (prod_emb ?I ?M (Suc -` J) (PIE j:Suc -` J. E (Suc j)))" (is "_ = ?E \<times> ?F")
   851    by (auto simp: space_pair_measure space_PiM Pi_iff prod_emb_def all_conj_distrib
   852       split: nat.split nat.split_asm)
   853   then have "emeasure ?D ?X = emeasure (M \<Otimes>\<^isub>M S) (?E \<times> ?F)"
   854     by (subst emeasure_distr[OF measurable_nat_case])
   855        (auto intro!: sets_PiM_I simp: split_beta' J)
   856   also have "\<dots> = emeasure M ?E * emeasure S ?F"
   857     using J by (intro P.emeasure_pair_measure_Times) (auto intro!: sets_PiM_I finite_vimageI)
   858   also have "emeasure S ?F = (\<Prod>j\<in>Suc -` J. emeasure M (E (Suc j)))"
   859     using J by (intro emeasure_PiM_emb) (simp_all add: finite_vimageI)
   860   also have "\<dots> = (\<Prod>j\<in>J - {0}. emeasure M (E j))"
   861     by (rule strong_setprod_reindex_cong[where f="\<lambda>x. x - 1"])
   862        (auto simp: image_iff Bex_def not_less nat_eq_diff_eq ac_simps cong: conj_cong intro!: inj_onI)
   863   also have "emeasure M ?E * (\<Prod>j\<in>J - {0}. emeasure M (E j)) = (\<Prod>j\<in>J. emeasure M (E j))"
   864     by (auto simp: M.emeasure_space_1 setprod.remove J)
   865   finally show "emeasure ?D ?X = (\<Prod>j\<in>J. emeasure M (E j))" .
   866 qed simp_all
   867 
   868 end
   869 
   870 end