src/Pure/Thy/thy_parse.ML
author wenzelm
Fri Dec 09 16:44:31 1994 +0100 (1994-12-09)
changeset 777 c007eba368b7
parent 759 e0b172d01c37
child 865 b38c67991122
permissions -rw-r--r--
minor internal changes;
     1 (*  Title:      Pure/Thy/thy_parse.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The parser for theory files.
     6 *)
     7 
     8 infix 5 -- --$$ $$-- ^^;
     9 infix 3 >>;
    10 infix 0 ||;
    11 
    12 signature THY_PARSE =
    13 sig
    14   type token
    15   val !! : ('a -> 'b * 'c) -> 'a -> 'b * 'c
    16   val >> : ('a -> 'b * 'c) * ('b -> 'd) -> 'a -> 'd * 'c
    17   val || : ('a -> 'b) * ('a -> 'b) -> 'a -> 'b
    18   val -- : ('a -> 'b * 'c) * ('c -> 'd * 'e) -> 'a -> ('b * 'd) * 'e
    19   val ^^ : ('a -> string * 'b) * ('b -> string * 'c) -> 'a -> string * 'c
    20   val $$ : string -> token list -> string * token list
    21   val $$-- : string * (token list -> 'b * 'c) -> token list -> 'b * 'c
    22   val --$$ : ('a -> 'b * token list) * string -> 'a -> 'b * token list
    23   val ident: token list -> string * token list
    24   val long_ident: token list -> string * token list
    25   val long_id: token list -> string * token list
    26   val type_var: token list -> string * token list
    27   val type_args: token list -> string list * token list
    28   val nat: token list -> string * token list
    29   val string: token list -> string * token list
    30   val verbatim: token list -> string * token list
    31   val empty: 'a -> 'b list * 'a
    32   val optional: ('a -> 'b * 'a) -> 'b -> 'a -> 'b * 'a
    33   val repeat: ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    34   val repeat1: ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    35   val enum: string -> (token list -> 'a * token list)
    36     -> token list -> 'a list * token list
    37   val enum1: string -> (token list -> 'a * token list)
    38     -> token list -> 'a list * token list
    39   val list: (token list -> 'a * token list)
    40     -> token list -> 'a list * token list
    41   val list1: (token list -> 'a * token list)
    42     -> token list -> 'a list * token list
    43   val name: token list -> string * token list
    44   val sort: token list -> string * token list
    45   val opt_infix: token list -> string * token list
    46   val opt_mixfix: token list -> string * token list
    47   val opt_witness: token list -> string * token list
    48   type syntax
    49   val make_syntax: string list ->
    50     (string * (token list -> (string * string) * token list)) list -> syntax
    51   val parse_thy: syntax -> string -> string -> string
    52   val section: string -> string -> (token list -> string * token list)
    53     -> (string * (token list -> (string * string) * token list))
    54   val axm_section: string -> string
    55     -> (token list -> (string * string list) * token list)
    56     -> (string * (token list -> (string * string) * token list))
    57   val pure_keywords: string list
    58   val pure_sections:
    59     (string * (token list -> (string * string) * token list)) list
    60   (*items for building strings*)
    61   val cat: string -> string -> string
    62   val parens: string -> string
    63   val brackets: string -> string
    64   val mk_list: string list -> string
    65   val mk_big_list: string list -> string
    66   val mk_pair: string * string -> string
    67   val mk_triple: string * string * string -> string
    68   val strip_quotes: string -> string
    69 end;
    70 
    71 functor ThyParseFun(structure Symtab: SYMTAB and ThyScan: THY_SCAN): THY_PARSE =
    72 struct
    73 
    74 open ThyScan;
    75 
    76 
    77 (** parser toolbox **)
    78 
    79 type token = token_kind * string * int;
    80 
    81 
    82 (* errors *)
    83 
    84 exception SYNTAX_ERROR of string * string * int;
    85 
    86 fun syn_err s1 s2 n = raise SYNTAX_ERROR (s1, s2, n);
    87 
    88 fun eof_err () = error "Unexpected end-of-file";
    89 
    90 (*Similar to Prolog's cut: reports any syntax error instead of backtracking
    91   through a superior || *)
    92 fun !! parse toks = parse toks
    93   handle SYNTAX_ERROR (s1, s2, n) => error ("Syntax error on line " ^
    94     string_of_int n ^ ": " ^ s1 ^ " expected and " ^ s2 ^ " was found");
    95 
    96 
    97 (* parser combinators *)
    98 
    99 fun (parse >> f) toks = apfst f (parse toks);
   100 
   101 fun (parse1 || parse2) toks =
   102   parse1 toks handle SYNTAX_ERROR _ => parse2 toks;
   103 
   104 fun (parse1 -- parse2) toks =
   105   let
   106     val (x, toks') = parse1 toks;
   107     val (y, toks'') = parse2 toks';
   108   in
   109     ((x, y), toks'')
   110   end;
   111 
   112 fun (parse1 ^^ parse2) = parse1 -- parse2 >> op ^;
   113 
   114 
   115 (* generic parsers *)
   116 
   117 fun $$ a ((k, b, n) :: toks) =
   118       if k = Keyword andalso a = b then (a, toks)
   119       else syn_err (quote a) (quote b) n
   120   | $$ _ [] = eof_err ();
   121 
   122 fun (a $$-- parse) = $$ a -- parse >> #2;
   123 
   124 fun (parse --$$ a) = parse -- $$ a >> #1;
   125 
   126 
   127 fun kind k1 ((k2, s, n) :: toks) =
   128       if k1 = k2 then (s, toks)
   129       else syn_err (name_of_kind k1) (quote s) n
   130   | kind _ [] = eof_err ();
   131 
   132 val ident = kind Ident;
   133 val long_ident = kind LongIdent;
   134 val long_id = ident || long_ident;
   135 val type_var = kind TypeVar >> quote;
   136 val nat = kind Nat;
   137 val string = kind String;
   138 val verbatim = kind Verbatim;
   139 val eof = kind EOF;
   140 
   141 fun empty toks = ([], toks);
   142 
   143 fun optional parse def = parse || empty >> K def;
   144 
   145 fun repeat parse toks = (parse -- repeat parse >> op :: || empty) toks;
   146 fun repeat1 parse = parse -- repeat parse >> op ::;
   147 
   148 fun enum1 sep parse = parse -- repeat (sep $$-- parse) >> op ::;
   149 fun enum sep parse = enum1 sep parse || empty;
   150 
   151 val list = enum ",";
   152 val list1 = enum1 ",";
   153 
   154 
   155 
   156 (** theory parsers **)
   157 
   158 (* misc utilities *)
   159 
   160 fun cat s1 s2 = s1 ^ " " ^ s2;
   161 
   162 val parens = enclose "(" ")";
   163 val brackets = enclose "[" "]";
   164 
   165 val mk_list = brackets o commas;
   166 val mk_big_list = brackets o space_implode ",\n ";
   167 
   168 fun mk_pair (x, y) = parens (commas [x, y]);
   169 fun mk_triple (x, y, z) = parens (commas [x, y, z]);
   170 fun mk_triple1 ((x, y), z) = mk_triple (x, y, z);
   171 fun mk_triple2 (x, (y, z)) = mk_triple (x, y, z);
   172 
   173 val split_decls = flat o map (fn (xs, y) => map (rpair y) xs);
   174 
   175 fun strip_quotes str =
   176   implode (tl (take (size str - 1, explode str)));
   177 
   178 
   179 (* names *)
   180 
   181 val name = ident >> quote || string;
   182 val names = list name;
   183 val names1 = list1 name;
   184 val name_list = names >> mk_list;
   185 val name_list1 = names1 >> mk_list;
   186 
   187 
   188 (* classes *)
   189 
   190 val subclass = name -- optional ("<" $$-- !! name_list1) "[]";
   191 
   192 val class_decls = repeat1 (subclass >> mk_pair) >> mk_big_list;
   193 
   194 
   195 (* arities *)
   196 
   197 val sort =
   198   name >> brackets ||
   199   "{" $$-- name_list --$$ "}";
   200 
   201 val sort_list1 = list1 sort >> mk_list;
   202 
   203 
   204 val arity = optional ("(" $$-- !! (sort_list1 --$$")")) "[]" -- sort;
   205 
   206 val arity_decls = repeat1 (names1 --$$ "::" -- !! arity)
   207   >> (mk_big_list o map mk_triple2 o split_decls);
   208 
   209 
   210 (* mixfix annotations *)
   211 
   212 val infxl = "infixl" $$-- !! nat >> cat "Infixl";
   213 val infxr = "infixr" $$-- !! nat >> cat "Infixr";
   214 
   215 val binder = "binder" $$-- !! (string -- nat) >> (cat "Binder" o mk_pair);
   216 
   217 val opt_pris = optional ("[" $$-- !! (list nat --$$ "]")) [] >> mk_list;
   218 
   219 val mixfix = string -- !! (opt_pris -- optional nat "max_pri")
   220   >> (cat "Mixfix" o mk_triple2);
   221 
   222 fun opt_syn fx = optional ("(" $$-- fx --$$ ")") "NoSyn";
   223 
   224 val opt_infix = opt_syn (infxl || infxr);
   225 val opt_mixfix = opt_syn (mixfix || infxl || infxr || binder);
   226 
   227 
   228 (* types *)
   229 
   230 fun mk_old_type_decl ((ts, n), syn) =
   231   map (fn t => (mk_triple (t, n, syn), false)) ts;
   232 
   233 fun mk_type_decl (((xs, t), None), syn) =
   234       [(mk_triple (t, string_of_int (length xs), syn), false)]
   235   | mk_type_decl (((xs, t), Some rhs), syn) =
   236       [(parens (commas [t, mk_list xs, rhs, syn]), true)];
   237 
   238 fun mk_type_decls tys =
   239   "|> add_types\n" ^ mk_big_list (keyfilter tys false) ^ "\n\n\
   240   \|> add_tyabbrs\n" ^ mk_big_list (keyfilter tys true);
   241 
   242 
   243 val old_type_decl = names1 -- nat -- opt_infix >> mk_old_type_decl;
   244 
   245 val type_args =
   246   type_var >> (fn x => [x]) ||
   247   "(" $$-- !! (list1 type_var --$$ ")") ||
   248   empty >> K [];
   249 
   250 val type_decl = type_args -- name -- optional ("=" $$-- !! string >> Some) None
   251   -- opt_infix >> mk_type_decl;
   252 
   253 val type_decls = repeat1 (old_type_decl || type_decl) >> (mk_type_decls o flat);
   254 
   255 
   256 (* consts *)
   257 
   258 val const_decls = repeat1 (names1 --$$ "::" -- !! (string -- opt_mixfix))
   259   >> (mk_big_list o map mk_triple2 o split_decls);
   260 
   261 
   262 (* translations *)
   263 
   264 val trans_pat =
   265   optional ("(" $$-- !! (name --$$ ")")) "\"logic\"" -- string >> mk_pair;
   266 
   267 val trans_arrow =
   268   $$ "=>" >> K " |-> " ||
   269   $$ "<=" >> K " <-| " ||
   270   $$ "==" >> K " <-> ";
   271 
   272 val trans_decls = repeat1 (trans_pat ^^ !! (trans_arrow ^^ trans_pat))
   273   >> mk_big_list;
   274 
   275 
   276 (* ML translations *)
   277 
   278 val trfun_defs =
   279   " val parse_ast_translation = [];\n\
   280   \ val parse_translation = [];\n\
   281   \ val print_translation = [];\n\
   282   \ val print_ast_translation = [];";
   283 
   284 val trfun_args =
   285   "(parse_ast_translation, parse_translation, \
   286   \print_translation, print_ast_translation)";
   287 
   288 fun mk_mltrans txt =
   289   "let\n"
   290   ^ trfun_defs ^ "\n"
   291   ^ txt ^ "\n\
   292   \in\n\
   293   \ " ^ trfun_args ^ "\n\
   294   \end";
   295 
   296 val mltrans = verbatim >> mk_mltrans;
   297 
   298 
   299 (* axioms *)
   300 
   301 val mk_axms = mk_big_list o map (mk_pair o apfst quote);
   302 
   303 fun mk_axiom_decls axms = (mk_axms axms, map fst axms);
   304 
   305 val axiom_decls = repeat1 (ident -- !! string) >> mk_axiom_decls;
   306 
   307 
   308 (* axclass *)
   309 
   310 fun mk_axclass_decl ((c, cs), axms) =
   311   (mk_pair (c, cs) ^ "\n" ^ mk_axms axms,
   312     (strip_quotes c ^ "I") :: map fst axms);
   313 
   314 val axclass_decl = subclass -- repeat (ident -- !! string) >> mk_axclass_decl;
   315 
   316 
   317 (* instance *)
   318 
   319 fun mk_witness (axths, opt_tac) =
   320   mk_list (keyfilter axths false) ^ "\n" ^
   321   mk_list (keyfilter axths true) ^ "\n" ^
   322   opt_tac;
   323 
   324 val axm_or_thm =
   325   string >> rpair false ||
   326   long_id >> rpair true;
   327 
   328 
   329 val opt_witness =
   330   optional ("(" $$-- list1 axm_or_thm --$$ ")") [] --
   331   optional (verbatim >> (parens o cat "Some" o parens)) "None"
   332   >> mk_witness;
   333 
   334 val instance_decl =
   335   (name --$$ "<" -- name >> (pair "|> AxClass.add_inst_subclass" o mk_pair) ||
   336     name --$$ "::" -- arity >> (pair "|> AxClass.add_inst_arity" o mk_triple2))
   337   -- opt_witness
   338   >> (fn ((x, y), z) => (cat_lines [x, y, z]));
   339 
   340 
   341 
   342 (** theory syntax **)
   343 
   344 type syntax =
   345   lexicon * (token list -> (string * string) * token list) Symtab.table;
   346 
   347 fun make_syntax keywords sects =
   348   (make_lexicon (map fst sects @ keywords),
   349     Symtab.make sects handle Symtab.DUPS dups =>
   350       error ("Duplicate sections in theory file syntax: " ^ commas_quote dups));
   351 
   352 
   353 (* header *)
   354 
   355 fun mk_header (thy_name, bases) =
   356   (thy_name, "mk_base " ^ mk_list bases ^ " " ^ quote thy_name);
   357 
   358 val base =
   359   ident >> (cat "Thy" o quote) ||
   360   string >> cat "File";
   361 
   362 val header = ident --$$ "=" -- enum1 "+" base >> mk_header;
   363 
   364 
   365 (* extension *)
   366 
   367 fun mk_extension (txts, mltxt) =
   368   let
   369     val cat_sects = space_implode "\n\n" o filter_out (equal "");
   370     val (extxts, postxts) = split_list txts;
   371   in
   372     (cat_sects extxts, cat_sects postxts, mltxt)
   373   end;
   374 
   375 fun sect tab ((Keyword, s, n) :: toks) =
   376       (case Symtab.lookup (tab, s) of
   377         Some parse => !! parse toks
   378       | None => syn_err "section" s n)
   379   | sect _ ((_, s, n) :: _) = syn_err "section" s n
   380   | sect _ [] = eof_err ();
   381 
   382 fun extension sectab = "+" $$-- !! (repeat (sect sectab) --$$ "end") --
   383   optional ("ML" $$-- verbatim) "" >> mk_extension;
   384 
   385 
   386 (* theory definition *)
   387 
   388 fun mk_structure tname ((thy_name, old_thys), opt_txts) =
   389   if thy_name <> tname then
   390     error ("Filename \"" ^ tname ^ ".thy\" and theory name "
   391       ^ quote thy_name ^ " are different")
   392   else
   393     (case opt_txts of
   394       Some (extxt, postxt, mltxt) =>
   395         "val thy = " ^ old_thys ^ " true;\n\n\
   396         \structure " ^ thy_name ^ " =\n\
   397         \struct\n\
   398         \\n\
   399         \local\n"
   400         ^ trfun_defs ^ "\n\
   401         \in\n\
   402         \\n"
   403         ^ mltxt ^ "\n\
   404         \\n\
   405         \val thy = thy\n\
   406         \\n\
   407         \|> add_trfuns\n"
   408         ^ trfun_args ^ "\n\
   409         \\n"
   410         ^ extxt ^ "\n\
   411         \\n\
   412         \|> add_thyname " ^ quote thy_name ^ ";\n\
   413         \\n\
   414         \val () = store_theory (thy, " ^ quote thy_name ^ ");\n\
   415         \\n\
   416         \\n"
   417         ^ postxt ^ "\n\
   418         \\n\
   419         \end;\n\
   420         \end;\n"
   421     | None =>
   422         "val thy = " ^ old_thys ^ " false;\n\
   423         \\n\
   424         \structure " ^ thy_name ^ " =\n\
   425         \struct\n\
   426         \\n\
   427         \val thy = thy\n\
   428         \\n\
   429         \val () = store_theory (thy, " ^ quote thy_name ^ ");\n\
   430         \\n\
   431         \end;\n");
   432 
   433 fun theory_defn sectab tname =
   434   header -- optional (extension sectab >> Some) None -- eof
   435   >> (mk_structure tname o #1);
   436 
   437 fun parse_thy (lex, sectab) tname str =
   438   #1 (!! (theory_defn sectab tname) (tokenize lex str));
   439 
   440 
   441 (* standard sections *)
   442 
   443 fun mk_val ax = "val " ^ ax ^ " = get_axiom thy " ^ quote ax ^ ";";
   444 val mk_vals = cat_lines o map mk_val;
   445 
   446 fun mk_axm_sect "" (txt, axs) = (txt, mk_vals axs)
   447   | mk_axm_sect pretxt (txt, axs) = (pretxt ^ "\n" ^ txt, mk_vals axs);
   448 
   449 fun axm_section name pretxt parse =
   450   (name, parse >> mk_axm_sect pretxt);
   451 
   452 fun section name pretxt parse =
   453   axm_section name pretxt (parse >> rpair []);
   454 
   455 
   456 val pure_keywords =
   457  ["end", "ML", "mixfix", "infixr", "infixl", "binder", "=", "+", ",", "<",
   458   "{", "}", "(", ")", "[", "]", "::", "==", "=>", "<="];
   459 
   460 val pure_sections =
   461  [section "classes" "|> add_classes" class_decls,
   462   section "default" "|> add_defsort" sort,
   463   section "types" "" type_decls,
   464   section "arities" "|> add_arities" arity_decls,
   465   section "consts" "|> add_consts" const_decls,
   466   section "syntax" "|> add_syntax" const_decls,
   467   section "translations" "|> add_trrules" trans_decls,
   468   section "MLtrans" "|> add_trfuns" mltrans,
   469   section "MLtext" "" verbatim,
   470   axm_section "rules" "|> add_axioms" axiom_decls,
   471   axm_section "defs" "|> add_defs" axiom_decls,
   472   axm_section "axclass" "|> AxClass.add_axclass" axclass_decl,
   473   section "instance" "" instance_decl];
   474 
   475 
   476 end;