src/HOL/HOL.thy
author haftmann
Wed Jan 02 15:14:02 2008 +0100 (2008-01-02)
changeset 25762 c03e9d04b3e4
parent 25741 2d102ddaca8b
child 25966 74f6817870f9
permissions -rw-r--r--
splitted class uminus from class minus
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports CPure
    10 uses
    11   ("hologic.ML")
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Provers/project_rule.ML"
    17   "~~/src/Provers/hypsubst.ML"
    18   "~~/src/Provers/splitter.ML"
    19   "~~/src/Provers/classical.ML"
    20   "~~/src/Provers/blast.ML"
    21   "~~/src/Provers/clasimp.ML"
    22   "~~/src/Provers/eqsubst.ML"
    23   "~~/src/Provers/quantifier1.ML"
    24   ("simpdata.ML")
    25   "~~/src/Tools/random_word.ML"
    26   "~~/src/Tools/induct.ML"
    27   "~~/src/Tools/code/code_name.ML"
    28   "~~/src/Tools/code/code_funcgr.ML"
    29   "~~/src/Tools/code/code_thingol.ML"
    30   "~~/src/Tools/code/code_target.ML"
    31   "~~/src/Tools/code/code_package.ML"
    32   "~~/src/Tools/nbe.ML"
    33 begin
    34 
    35 subsection {* Primitive logic *}
    36 
    37 subsubsection {* Core syntax *}
    38 
    39 classes type
    40 defaultsort type
    41 setup {* ObjectLogic.add_base_sort @{sort type} *}
    42 
    43 arities
    44   "fun" :: (type, type) type
    45   itself :: (type) type
    46 
    47 global
    48 
    49 typedecl bool
    50 
    51 judgment
    52   Trueprop      :: "bool => prop"                   ("(_)" 5)
    53 
    54 consts
    55   Not           :: "bool => bool"                   ("~ _" [40] 40)
    56   True          :: bool
    57   False         :: bool
    58   arbitrary     :: 'a
    59 
    60   The           :: "('a => bool) => 'a"
    61   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    62   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    63   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    64   Let           :: "['a, 'a => 'b] => 'b"
    65 
    66   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    67   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    68   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    69   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    70 
    71 local
    72 
    73 consts
    74   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    75 
    76 
    77 subsubsection {* Additional concrete syntax *}
    78 
    79 notation (output)
    80   "op ="  (infix "=" 50)
    81 
    82 abbreviation
    83   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    84   "x ~= y == ~ (x = y)"
    85 
    86 notation (output)
    87   not_equal  (infix "~=" 50)
    88 
    89 notation (xsymbols)
    90   Not  ("\<not> _" [40] 40) and
    91   "op &"  (infixr "\<and>" 35) and
    92   "op |"  (infixr "\<or>" 30) and
    93   "op -->"  (infixr "\<longrightarrow>" 25) and
    94   not_equal  (infix "\<noteq>" 50)
    95 
    96 notation (HTML output)
    97   Not  ("\<not> _" [40] 40) and
    98   "op &"  (infixr "\<and>" 35) and
    99   "op |"  (infixr "\<or>" 30) and
   100   not_equal  (infix "\<noteq>" 50)
   101 
   102 abbreviation (iff)
   103   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   104   "A <-> B == A = B"
   105 
   106 notation (xsymbols)
   107   iff  (infixr "\<longleftrightarrow>" 25)
   108 
   109 
   110 nonterminals
   111   letbinds  letbind
   112   case_syn  cases_syn
   113 
   114 syntax
   115   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   116 
   117   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   118   ""            :: "letbind => letbinds"                 ("_")
   119   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   120   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   121 
   122   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   123   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   124   ""            :: "case_syn => cases_syn"               ("_")
   125   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   126 
   127 translations
   128   "THE x. P"              == "The (%x. P)"
   129   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   130   "let x = a in e"        == "Let a (%x. e)"
   131 
   132 print_translation {*
   133 (* To avoid eta-contraction of body: *)
   134 [("The", fn [Abs abs] =>
   135      let val (x,t) = atomic_abs_tr' abs
   136      in Syntax.const "_The" $ x $ t end)]
   137 *}
   138 
   139 syntax (xsymbols)
   140   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   141 
   142 notation (xsymbols)
   143   All  (binder "\<forall>" 10) and
   144   Ex  (binder "\<exists>" 10) and
   145   Ex1  (binder "\<exists>!" 10)
   146 
   147 notation (HTML output)
   148   All  (binder "\<forall>" 10) and
   149   Ex  (binder "\<exists>" 10) and
   150   Ex1  (binder "\<exists>!" 10)
   151 
   152 notation (HOL)
   153   All  (binder "! " 10) and
   154   Ex  (binder "? " 10) and
   155   Ex1  (binder "?! " 10)
   156 
   157 
   158 subsubsection {* Axioms and basic definitions *}
   159 
   160 axioms
   161   eq_reflection:  "(x=y) ==> (x==y)"
   162 
   163   refl:           "t = (t::'a)"
   164 
   165   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   166     -- {*Extensionality is built into the meta-logic, and this rule expresses
   167          a related property.  It is an eta-expanded version of the traditional
   168          rule, and similar to the ABS rule of HOL*}
   169 
   170   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   171 
   172   impI:           "(P ==> Q) ==> P-->Q"
   173   mp:             "[| P-->Q;  P |] ==> Q"
   174 
   175 
   176 defs
   177   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   178   All_def:      "All(P)    == (P = (%x. True))"
   179   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   180   False_def:    "False     == (!P. P)"
   181   not_def:      "~ P       == P-->False"
   182   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   183   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   184   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   185 
   186 axioms
   187   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   188   True_or_False:  "(P=True) | (P=False)"
   189 
   190 defs
   191   Let_def:      "Let s f == f(s)"
   192   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   193 
   194 finalconsts
   195   "op ="
   196   "op -->"
   197   The
   198   arbitrary
   199 
   200 axiomatization
   201   undefined :: 'a
   202 
   203 axiomatization where
   204   undefined_fun: "undefined x = undefined"
   205 
   206 
   207 subsubsection {* Generic classes and algebraic operations *}
   208 
   209 class default = type +
   210   fixes default :: 'a
   211 
   212 class zero = type + 
   213   fixes zero :: 'a  ("0")
   214 
   215 class one = type +
   216   fixes one  :: 'a  ("1")
   217 
   218 hide (open) const zero one
   219 
   220 class plus = type +
   221   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   222 
   223 class minus = type +
   224   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   225 
   226 class uminus = type +
   227   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   228 
   229 class times = type +
   230   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   231 
   232 class inverse = type +
   233   fixes inverse :: "'a \<Rightarrow> 'a"
   234     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   235 
   236 class abs = type +
   237   fixes abs :: "'a \<Rightarrow> 'a"
   238 begin
   239 
   240 notation (xsymbols)
   241   abs  ("\<bar>_\<bar>")
   242 
   243 notation (HTML output)
   244   abs  ("\<bar>_\<bar>")
   245 
   246 end
   247 
   248 class sgn = type +
   249   fixes sgn :: "'a \<Rightarrow> 'a"
   250 
   251 class ord = type +
   252   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   253     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   254 begin
   255 
   256 notation
   257   less_eq  ("op <=") and
   258   less_eq  ("(_/ <= _)" [51, 51] 50) and
   259   less  ("op <") and
   260   less  ("(_/ < _)"  [51, 51] 50)
   261   
   262 notation (xsymbols)
   263   less_eq  ("op \<le>") and
   264   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   265 
   266 notation (HTML output)
   267   less_eq  ("op \<le>") and
   268   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   269 
   270 abbreviation (input)
   271   greater_eq  (infix ">=" 50) where
   272   "x >= y \<equiv> y <= x"
   273 
   274 notation (input)
   275   greater_eq  (infix "\<ge>" 50)
   276 
   277 abbreviation (input)
   278   greater  (infix ">" 50) where
   279   "x > y \<equiv> y < x"
   280 
   281 definition
   282   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   283   "Least P == (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> less_eq x y))"
   284 
   285 end
   286 
   287 syntax
   288   "_index1"  :: index    ("\<^sub>1")
   289 translations
   290   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   291 
   292 typed_print_translation {*
   293 let
   294   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   295     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   296     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   297 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   298 *} -- {* show types that are presumably too general *}
   299 
   300 
   301 subsection {* Fundamental rules *}
   302 
   303 subsubsection {* Equality *}
   304 
   305 text {* Thanks to Stephan Merz *}
   306 lemma subst:
   307   assumes eq: "s = t" and p: "P s"
   308   shows "P t"
   309 proof -
   310   from eq have meta: "s \<equiv> t"
   311     by (rule eq_reflection)
   312   from p show ?thesis
   313     by (unfold meta)
   314 qed
   315 
   316 lemma sym: "s = t ==> t = s"
   317   by (erule subst) (rule refl)
   318 
   319 lemma ssubst: "t = s ==> P s ==> P t"
   320   by (drule sym) (erule subst)
   321 
   322 lemma trans: "[| r=s; s=t |] ==> r=t"
   323   by (erule subst)
   324 
   325 lemma meta_eq_to_obj_eq: 
   326   assumes meq: "A == B"
   327   shows "A = B"
   328   by (unfold meq) (rule refl)
   329 
   330 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   331      (* a = b
   332         |   |
   333         c = d   *)
   334 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   335 apply (rule trans)
   336 apply (rule trans)
   337 apply (rule sym)
   338 apply assumption+
   339 done
   340 
   341 text {* For calculational reasoning: *}
   342 
   343 lemma forw_subst: "a = b ==> P b ==> P a"
   344   by (rule ssubst)
   345 
   346 lemma back_subst: "P a ==> a = b ==> P b"
   347   by (rule subst)
   348 
   349 
   350 subsubsection {*Congruence rules for application*}
   351 
   352 (*similar to AP_THM in Gordon's HOL*)
   353 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   354 apply (erule subst)
   355 apply (rule refl)
   356 done
   357 
   358 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   359 lemma arg_cong: "x=y ==> f(x)=f(y)"
   360 apply (erule subst)
   361 apply (rule refl)
   362 done
   363 
   364 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   365 apply (erule ssubst)+
   366 apply (rule refl)
   367 done
   368 
   369 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   370 apply (erule subst)+
   371 apply (rule refl)
   372 done
   373 
   374 
   375 subsubsection {*Equality of booleans -- iff*}
   376 
   377 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   378   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   379 
   380 lemma iffD2: "[| P=Q; Q |] ==> P"
   381   by (erule ssubst)
   382 
   383 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   384   by (erule iffD2)
   385 
   386 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   387   by (drule sym) (rule iffD2)
   388 
   389 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   390   by (drule sym) (rule rev_iffD2)
   391 
   392 lemma iffE:
   393   assumes major: "P=Q"
   394     and minor: "[| P --> Q; Q --> P |] ==> R"
   395   shows R
   396   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   397 
   398 
   399 subsubsection {*True*}
   400 
   401 lemma TrueI: "True"
   402   unfolding True_def by (rule refl)
   403 
   404 lemma eqTrueI: "P ==> P = True"
   405   by (iprover intro: iffI TrueI)
   406 
   407 lemma eqTrueE: "P = True ==> P"
   408   by (erule iffD2) (rule TrueI)
   409 
   410 
   411 subsubsection {*Universal quantifier*}
   412 
   413 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   414   unfolding All_def by (iprover intro: ext eqTrueI assms)
   415 
   416 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   417 apply (unfold All_def)
   418 apply (rule eqTrueE)
   419 apply (erule fun_cong)
   420 done
   421 
   422 lemma allE:
   423   assumes major: "ALL x. P(x)"
   424     and minor: "P(x) ==> R"
   425   shows R
   426   by (iprover intro: minor major [THEN spec])
   427 
   428 lemma all_dupE:
   429   assumes major: "ALL x. P(x)"
   430     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   431   shows R
   432   by (iprover intro: minor major major [THEN spec])
   433 
   434 
   435 subsubsection {* False *}
   436 
   437 text {*
   438   Depends upon @{text spec}; it is impossible to do propositional
   439   logic before quantifiers!
   440 *}
   441 
   442 lemma FalseE: "False ==> P"
   443   apply (unfold False_def)
   444   apply (erule spec)
   445   done
   446 
   447 lemma False_neq_True: "False = True ==> P"
   448   by (erule eqTrueE [THEN FalseE])
   449 
   450 
   451 subsubsection {* Negation *}
   452 
   453 lemma notI:
   454   assumes "P ==> False"
   455   shows "~P"
   456   apply (unfold not_def)
   457   apply (iprover intro: impI assms)
   458   done
   459 
   460 lemma False_not_True: "False ~= True"
   461   apply (rule notI)
   462   apply (erule False_neq_True)
   463   done
   464 
   465 lemma True_not_False: "True ~= False"
   466   apply (rule notI)
   467   apply (drule sym)
   468   apply (erule False_neq_True)
   469   done
   470 
   471 lemma notE: "[| ~P;  P |] ==> R"
   472   apply (unfold not_def)
   473   apply (erule mp [THEN FalseE])
   474   apply assumption
   475   done
   476 
   477 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   478   by (erule notE [THEN notI]) (erule meta_mp)
   479 
   480 
   481 subsubsection {*Implication*}
   482 
   483 lemma impE:
   484   assumes "P-->Q" "P" "Q ==> R"
   485   shows "R"
   486 by (iprover intro: assms mp)
   487 
   488 (* Reduces Q to P-->Q, allowing substitution in P. *)
   489 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   490 by (iprover intro: mp)
   491 
   492 lemma contrapos_nn:
   493   assumes major: "~Q"
   494       and minor: "P==>Q"
   495   shows "~P"
   496 by (iprover intro: notI minor major [THEN notE])
   497 
   498 (*not used at all, but we already have the other 3 combinations *)
   499 lemma contrapos_pn:
   500   assumes major: "Q"
   501       and minor: "P ==> ~Q"
   502   shows "~P"
   503 by (iprover intro: notI minor major notE)
   504 
   505 lemma not_sym: "t ~= s ==> s ~= t"
   506   by (erule contrapos_nn) (erule sym)
   507 
   508 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   509   by (erule subst, erule ssubst, assumption)
   510 
   511 (*still used in HOLCF*)
   512 lemma rev_contrapos:
   513   assumes pq: "P ==> Q"
   514       and nq: "~Q"
   515   shows "~P"
   516 apply (rule nq [THEN contrapos_nn])
   517 apply (erule pq)
   518 done
   519 
   520 subsubsection {*Existential quantifier*}
   521 
   522 lemma exI: "P x ==> EX x::'a. P x"
   523 apply (unfold Ex_def)
   524 apply (iprover intro: allI allE impI mp)
   525 done
   526 
   527 lemma exE:
   528   assumes major: "EX x::'a. P(x)"
   529       and minor: "!!x. P(x) ==> Q"
   530   shows "Q"
   531 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   532 apply (iprover intro: impI [THEN allI] minor)
   533 done
   534 
   535 
   536 subsubsection {*Conjunction*}
   537 
   538 lemma conjI: "[| P; Q |] ==> P&Q"
   539 apply (unfold and_def)
   540 apply (iprover intro: impI [THEN allI] mp)
   541 done
   542 
   543 lemma conjunct1: "[| P & Q |] ==> P"
   544 apply (unfold and_def)
   545 apply (iprover intro: impI dest: spec mp)
   546 done
   547 
   548 lemma conjunct2: "[| P & Q |] ==> Q"
   549 apply (unfold and_def)
   550 apply (iprover intro: impI dest: spec mp)
   551 done
   552 
   553 lemma conjE:
   554   assumes major: "P&Q"
   555       and minor: "[| P; Q |] ==> R"
   556   shows "R"
   557 apply (rule minor)
   558 apply (rule major [THEN conjunct1])
   559 apply (rule major [THEN conjunct2])
   560 done
   561 
   562 lemma context_conjI:
   563   assumes "P" "P ==> Q" shows "P & Q"
   564 by (iprover intro: conjI assms)
   565 
   566 
   567 subsubsection {*Disjunction*}
   568 
   569 lemma disjI1: "P ==> P|Q"
   570 apply (unfold or_def)
   571 apply (iprover intro: allI impI mp)
   572 done
   573 
   574 lemma disjI2: "Q ==> P|Q"
   575 apply (unfold or_def)
   576 apply (iprover intro: allI impI mp)
   577 done
   578 
   579 lemma disjE:
   580   assumes major: "P|Q"
   581       and minorP: "P ==> R"
   582       and minorQ: "Q ==> R"
   583   shows "R"
   584 by (iprover intro: minorP minorQ impI
   585                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   586 
   587 
   588 subsubsection {*Classical logic*}
   589 
   590 lemma classical:
   591   assumes prem: "~P ==> P"
   592   shows "P"
   593 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   594 apply assumption
   595 apply (rule notI [THEN prem, THEN eqTrueI])
   596 apply (erule subst)
   597 apply assumption
   598 done
   599 
   600 lemmas ccontr = FalseE [THEN classical, standard]
   601 
   602 (*notE with premises exchanged; it discharges ~R so that it can be used to
   603   make elimination rules*)
   604 lemma rev_notE:
   605   assumes premp: "P"
   606       and premnot: "~R ==> ~P"
   607   shows "R"
   608 apply (rule ccontr)
   609 apply (erule notE [OF premnot premp])
   610 done
   611 
   612 (*Double negation law*)
   613 lemma notnotD: "~~P ==> P"
   614 apply (rule classical)
   615 apply (erule notE)
   616 apply assumption
   617 done
   618 
   619 lemma contrapos_pp:
   620   assumes p1: "Q"
   621       and p2: "~P ==> ~Q"
   622   shows "P"
   623 by (iprover intro: classical p1 p2 notE)
   624 
   625 
   626 subsubsection {*Unique existence*}
   627 
   628 lemma ex1I:
   629   assumes "P a" "!!x. P(x) ==> x=a"
   630   shows "EX! x. P(x)"
   631 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   632 
   633 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   634 lemma ex_ex1I:
   635   assumes ex_prem: "EX x. P(x)"
   636       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   637   shows "EX! x. P(x)"
   638 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   639 
   640 lemma ex1E:
   641   assumes major: "EX! x. P(x)"
   642       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   643   shows "R"
   644 apply (rule major [unfolded Ex1_def, THEN exE])
   645 apply (erule conjE)
   646 apply (iprover intro: minor)
   647 done
   648 
   649 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   650 apply (erule ex1E)
   651 apply (rule exI)
   652 apply assumption
   653 done
   654 
   655 
   656 subsubsection {*THE: definite description operator*}
   657 
   658 lemma the_equality:
   659   assumes prema: "P a"
   660       and premx: "!!x. P x ==> x=a"
   661   shows "(THE x. P x) = a"
   662 apply (rule trans [OF _ the_eq_trivial])
   663 apply (rule_tac f = "The" in arg_cong)
   664 apply (rule ext)
   665 apply (rule iffI)
   666  apply (erule premx)
   667 apply (erule ssubst, rule prema)
   668 done
   669 
   670 lemma theI:
   671   assumes "P a" and "!!x. P x ==> x=a"
   672   shows "P (THE x. P x)"
   673 by (iprover intro: assms the_equality [THEN ssubst])
   674 
   675 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   676 apply (erule ex1E)
   677 apply (erule theI)
   678 apply (erule allE)
   679 apply (erule mp)
   680 apply assumption
   681 done
   682 
   683 (*Easier to apply than theI: only one occurrence of P*)
   684 lemma theI2:
   685   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   686   shows "Q (THE x. P x)"
   687 by (iprover intro: assms theI)
   688 
   689 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   690 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   691            elim:allE impE)
   692 
   693 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   694 apply (rule the_equality)
   695 apply  assumption
   696 apply (erule ex1E)
   697 apply (erule all_dupE)
   698 apply (drule mp)
   699 apply  assumption
   700 apply (erule ssubst)
   701 apply (erule allE)
   702 apply (erule mp)
   703 apply assumption
   704 done
   705 
   706 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   707 apply (rule the_equality)
   708 apply (rule refl)
   709 apply (erule sym)
   710 done
   711 
   712 
   713 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   714 
   715 lemma disjCI:
   716   assumes "~Q ==> P" shows "P|Q"
   717 apply (rule classical)
   718 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   719 done
   720 
   721 lemma excluded_middle: "~P | P"
   722 by (iprover intro: disjCI)
   723 
   724 text {*
   725   case distinction as a natural deduction rule.
   726   Note that @{term "~P"} is the second case, not the first
   727 *}
   728 lemma case_split_thm:
   729   assumes prem1: "P ==> Q"
   730       and prem2: "~P ==> Q"
   731   shows "Q"
   732 apply (rule excluded_middle [THEN disjE])
   733 apply (erule prem2)
   734 apply (erule prem1)
   735 done
   736 lemmas case_split = case_split_thm [case_names True False]
   737 
   738 (*Classical implies (-->) elimination. *)
   739 lemma impCE:
   740   assumes major: "P-->Q"
   741       and minor: "~P ==> R" "Q ==> R"
   742   shows "R"
   743 apply (rule excluded_middle [of P, THEN disjE])
   744 apply (iprover intro: minor major [THEN mp])+
   745 done
   746 
   747 (*This version of --> elimination works on Q before P.  It works best for
   748   those cases in which P holds "almost everywhere".  Can't install as
   749   default: would break old proofs.*)
   750 lemma impCE':
   751   assumes major: "P-->Q"
   752       and minor: "Q ==> R" "~P ==> R"
   753   shows "R"
   754 apply (rule excluded_middle [of P, THEN disjE])
   755 apply (iprover intro: minor major [THEN mp])+
   756 done
   757 
   758 (*Classical <-> elimination. *)
   759 lemma iffCE:
   760   assumes major: "P=Q"
   761       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   762   shows "R"
   763 apply (rule major [THEN iffE])
   764 apply (iprover intro: minor elim: impCE notE)
   765 done
   766 
   767 lemma exCI:
   768   assumes "ALL x. ~P(x) ==> P(a)"
   769   shows "EX x. P(x)"
   770 apply (rule ccontr)
   771 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   772 done
   773 
   774 
   775 subsubsection {* Intuitionistic Reasoning *}
   776 
   777 lemma impE':
   778   assumes 1: "P --> Q"
   779     and 2: "Q ==> R"
   780     and 3: "P --> Q ==> P"
   781   shows R
   782 proof -
   783   from 3 and 1 have P .
   784   with 1 have Q by (rule impE)
   785   with 2 show R .
   786 qed
   787 
   788 lemma allE':
   789   assumes 1: "ALL x. P x"
   790     and 2: "P x ==> ALL x. P x ==> Q"
   791   shows Q
   792 proof -
   793   from 1 have "P x" by (rule spec)
   794   from this and 1 show Q by (rule 2)
   795 qed
   796 
   797 lemma notE':
   798   assumes 1: "~ P"
   799     and 2: "~ P ==> P"
   800   shows R
   801 proof -
   802   from 2 and 1 have P .
   803   with 1 show R by (rule notE)
   804 qed
   805 
   806 lemma TrueE: "True ==> P ==> P" .
   807 lemma notFalseE: "~ False ==> P ==> P" .
   808 
   809 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   810   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   811   and [Pure.elim 2] = allE notE' impE'
   812   and [Pure.intro] = exI disjI2 disjI1
   813 
   814 lemmas [trans] = trans
   815   and [sym] = sym not_sym
   816   and [Pure.elim?] = iffD1 iffD2 impE
   817 
   818 use "hologic.ML"
   819 
   820 
   821 subsubsection {* Atomizing meta-level connectives *}
   822 
   823 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   824 proof
   825   assume "!!x. P x"
   826   then show "ALL x. P x" ..
   827 next
   828   assume "ALL x. P x"
   829   then show "!!x. P x" by (rule allE)
   830 qed
   831 
   832 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   833 proof
   834   assume r: "A ==> B"
   835   show "A --> B" by (rule impI) (rule r)
   836 next
   837   assume "A --> B" and A
   838   then show B by (rule mp)
   839 qed
   840 
   841 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   842 proof
   843   assume r: "A ==> False"
   844   show "~A" by (rule notI) (rule r)
   845 next
   846   assume "~A" and A
   847   then show False by (rule notE)
   848 qed
   849 
   850 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   851 proof
   852   assume "x == y"
   853   show "x = y" by (unfold `x == y`) (rule refl)
   854 next
   855   assume "x = y"
   856   then show "x == y" by (rule eq_reflection)
   857 qed
   858 
   859 lemma atomize_conj [atomize]:
   860   includes meta_conjunction_syntax
   861   shows "(A && B) == Trueprop (A & B)"
   862 proof
   863   assume conj: "A && B"
   864   show "A & B"
   865   proof (rule conjI)
   866     from conj show A by (rule conjunctionD1)
   867     from conj show B by (rule conjunctionD2)
   868   qed
   869 next
   870   assume conj: "A & B"
   871   show "A && B"
   872   proof -
   873     from conj show A ..
   874     from conj show B ..
   875   qed
   876 qed
   877 
   878 lemmas [symmetric, rulify] = atomize_all atomize_imp
   879   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   880 
   881 
   882 subsection {* Package setup *}
   883 
   884 subsubsection {* Classical Reasoner setup *}
   885 
   886 lemma thin_refl:
   887   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   888 
   889 ML {*
   890 structure Hypsubst = HypsubstFun(
   891 struct
   892   structure Simplifier = Simplifier
   893   val dest_eq = HOLogic.dest_eq
   894   val dest_Trueprop = HOLogic.dest_Trueprop
   895   val dest_imp = HOLogic.dest_imp
   896   val eq_reflection = @{thm HOL.eq_reflection}
   897   val rev_eq_reflection = @{thm HOL.meta_eq_to_obj_eq}
   898   val imp_intr = @{thm HOL.impI}
   899   val rev_mp = @{thm HOL.rev_mp}
   900   val subst = @{thm HOL.subst}
   901   val sym = @{thm HOL.sym}
   902   val thin_refl = @{thm thin_refl};
   903 end);
   904 open Hypsubst;
   905 
   906 structure Classical = ClassicalFun(
   907 struct
   908   val mp = @{thm HOL.mp}
   909   val not_elim = @{thm HOL.notE}
   910   val classical = @{thm HOL.classical}
   911   val sizef = Drule.size_of_thm
   912   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   913 end);
   914 
   915 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   916 open BasicClassical;
   917 
   918 ML_Context.value_antiq "claset"
   919   (Scan.succeed ("claset", "Classical.local_claset_of (ML_Context.the_local_context ())"));
   920 
   921 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   922 
   923 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "Theorems blacklisted for ATP");
   924 *}
   925 
   926 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   927   These theorems typically produce clauses that are prolific (match too many equality or
   928   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   929 
   930 setup {*
   931 let
   932   (*prevent substitution on bool*)
   933   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   934     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   935       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   936 in
   937   Hypsubst.hypsubst_setup
   938   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   939   #> Classical.setup
   940   #> ResAtpset.setup
   941   #> ResBlacklist.setup
   942 end
   943 *}
   944 
   945 declare iffI [intro!]
   946   and notI [intro!]
   947   and impI [intro!]
   948   and disjCI [intro!]
   949   and conjI [intro!]
   950   and TrueI [intro!]
   951   and refl [intro!]
   952 
   953 declare iffCE [elim!]
   954   and FalseE [elim!]
   955   and impCE [elim!]
   956   and disjE [elim!]
   957   and conjE [elim!]
   958   and conjE [elim!]
   959 
   960 declare ex_ex1I [intro!]
   961   and allI [intro!]
   962   and the_equality [intro]
   963   and exI [intro]
   964 
   965 declare exE [elim!]
   966   allE [elim]
   967 
   968 ML {* val HOL_cs = @{claset} *}
   969 
   970 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   971   apply (erule swap)
   972   apply (erule (1) meta_mp)
   973   done
   974 
   975 declare ex_ex1I [rule del, intro! 2]
   976   and ex1I [intro]
   977 
   978 lemmas [intro?] = ext
   979   and [elim?] = ex1_implies_ex
   980 
   981 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   982 lemma alt_ex1E [elim!]:
   983   assumes major: "\<exists>!x. P x"
   984       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   985   shows R
   986 apply (rule ex1E [OF major])
   987 apply (rule prem)
   988 apply (tactic {* ares_tac @{thms allI} 1 *})+
   989 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   990 apply iprover
   991 done
   992 
   993 ML {*
   994 structure Blast = BlastFun
   995 (
   996   type claset = Classical.claset
   997   val equality_name = @{const_name "op ="}
   998   val not_name = @{const_name Not}
   999   val notE = @{thm HOL.notE}
  1000   val ccontr = @{thm HOL.ccontr}
  1001   val contr_tac = Classical.contr_tac
  1002   val dup_intr = Classical.dup_intr
  1003   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1004   val claset = Classical.claset
  1005   val rep_cs = Classical.rep_cs
  1006   val cla_modifiers = Classical.cla_modifiers
  1007   val cla_meth' = Classical.cla_meth'
  1008 );
  1009 val Blast_tac = Blast.Blast_tac;
  1010 val blast_tac = Blast.blast_tac;
  1011 *}
  1012 
  1013 setup Blast.setup
  1014 
  1015 
  1016 subsubsection {* Simplifier *}
  1017 
  1018 lemma eta_contract_eq: "(%s. f s) = f" ..
  1019 
  1020 lemma simp_thms:
  1021   shows not_not: "(~ ~ P) = P"
  1022   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1023   and
  1024     "(P ~= Q) = (P = (~Q))"
  1025     "(P | ~P) = True"    "(~P | P) = True"
  1026     "(x = x) = True"
  1027   and not_True_eq_False: "(\<not> True) = False"
  1028   and not_False_eq_True: "(\<not> False) = True"
  1029   and
  1030     "(~P) ~= P"  "P ~= (~P)"
  1031     "(True=P) = P"
  1032   and eq_True: "(P = True) = P"
  1033   and "(False=P) = (~P)"
  1034   and eq_False: "(P = False) = (\<not> P)"
  1035   and
  1036     "(True --> P) = P"  "(False --> P) = True"
  1037     "(P --> True) = True"  "(P --> P) = True"
  1038     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1039     "(P & True) = P"  "(True & P) = P"
  1040     "(P & False) = False"  "(False & P) = False"
  1041     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1042     "(P & ~P) = False"    "(~P & P) = False"
  1043     "(P | True) = True"  "(True | P) = True"
  1044     "(P | False) = P"  "(False | P) = P"
  1045     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1046     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1047     -- {* needed for the one-point-rule quantifier simplification procs *}
  1048     -- {* essential for termination!! *} and
  1049     "!!P. (EX x. x=t & P(x)) = P(t)"
  1050     "!!P. (EX x. t=x & P(x)) = P(t)"
  1051     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1052     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1053   by (blast, blast, blast, blast, blast, iprover+)
  1054 
  1055 lemma disj_absorb: "(A | A) = A"
  1056   by blast
  1057 
  1058 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1059   by blast
  1060 
  1061 lemma conj_absorb: "(A & A) = A"
  1062   by blast
  1063 
  1064 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1065   by blast
  1066 
  1067 lemma eq_ac:
  1068   shows eq_commute: "(a=b) = (b=a)"
  1069     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1070     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1071 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1072 
  1073 lemma conj_comms:
  1074   shows conj_commute: "(P&Q) = (Q&P)"
  1075     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1076 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1077 
  1078 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1079 
  1080 lemma disj_comms:
  1081   shows disj_commute: "(P|Q) = (Q|P)"
  1082     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1083 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1084 
  1085 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1086 
  1087 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1088 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1089 
  1090 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1091 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1092 
  1093 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1094 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1095 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1096 
  1097 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1098 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1099 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1100 
  1101 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1102 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1103 
  1104 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1105   by iprover
  1106 
  1107 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1108 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1109 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1110 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1111 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1112 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1113   by blast
  1114 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1115 
  1116 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1117 
  1118 
  1119 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1120   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1121   -- {* cases boil down to the same thing. *}
  1122   by blast
  1123 
  1124 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1125 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1126 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1127 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1128 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1129 
  1130 declare All_def [noatp]
  1131 
  1132 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1133 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1134 
  1135 text {*
  1136   \medskip The @{text "&"} congruence rule: not included by default!
  1137   May slow rewrite proofs down by as much as 50\% *}
  1138 
  1139 lemma conj_cong:
  1140     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1141   by iprover
  1142 
  1143 lemma rev_conj_cong:
  1144     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1145   by iprover
  1146 
  1147 text {* The @{text "|"} congruence rule: not included by default! *}
  1148 
  1149 lemma disj_cong:
  1150     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1151   by blast
  1152 
  1153 
  1154 text {* \medskip if-then-else rules *}
  1155 
  1156 lemma if_True: "(if True then x else y) = x"
  1157   by (unfold if_def) blast
  1158 
  1159 lemma if_False: "(if False then x else y) = y"
  1160   by (unfold if_def) blast
  1161 
  1162 lemma if_P: "P ==> (if P then x else y) = x"
  1163   by (unfold if_def) blast
  1164 
  1165 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1166   by (unfold if_def) blast
  1167 
  1168 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1169   apply (rule case_split [of Q])
  1170    apply (simplesubst if_P)
  1171     prefer 3 apply (simplesubst if_not_P, blast+)
  1172   done
  1173 
  1174 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1175 by (simplesubst split_if, blast)
  1176 
  1177 lemmas if_splits [noatp] = split_if split_if_asm
  1178 
  1179 lemma if_cancel: "(if c then x else x) = x"
  1180 by (simplesubst split_if, blast)
  1181 
  1182 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1183 by (simplesubst split_if, blast)
  1184 
  1185 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1186   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1187   by (rule split_if)
  1188 
  1189 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1190   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1191   apply (simplesubst split_if, blast)
  1192   done
  1193 
  1194 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1195 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1196 
  1197 text {* \medskip let rules for simproc *}
  1198 
  1199 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1200   by (unfold Let_def)
  1201 
  1202 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1203   by (unfold Let_def)
  1204 
  1205 text {*
  1206   The following copy of the implication operator is useful for
  1207   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1208   its premise.
  1209 *}
  1210 
  1211 constdefs
  1212   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1213   "simp_implies \<equiv> op ==>"
  1214 
  1215 lemma simp_impliesI:
  1216   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1217   shows "PROP P =simp=> PROP Q"
  1218   apply (unfold simp_implies_def)
  1219   apply (rule PQ)
  1220   apply assumption
  1221   done
  1222 
  1223 lemma simp_impliesE:
  1224   assumes PQ: "PROP P =simp=> PROP Q"
  1225   and P: "PROP P"
  1226   and QR: "PROP Q \<Longrightarrow> PROP R"
  1227   shows "PROP R"
  1228   apply (rule QR)
  1229   apply (rule PQ [unfolded simp_implies_def])
  1230   apply (rule P)
  1231   done
  1232 
  1233 lemma simp_implies_cong:
  1234   assumes PP' :"PROP P == PROP P'"
  1235   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1236   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1237 proof (unfold simp_implies_def, rule equal_intr_rule)
  1238   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1239   and P': "PROP P'"
  1240   from PP' [symmetric] and P' have "PROP P"
  1241     by (rule equal_elim_rule1)
  1242   then have "PROP Q" by (rule PQ)
  1243   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1244 next
  1245   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1246   and P: "PROP P"
  1247   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1248   then have "PROP Q'" by (rule P'Q')
  1249   with P'QQ' [OF P', symmetric] show "PROP Q"
  1250     by (rule equal_elim_rule1)
  1251 qed
  1252 
  1253 lemma uncurry:
  1254   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1255   shows "P \<and> Q \<longrightarrow> R"
  1256   using assms by blast
  1257 
  1258 lemma iff_allI:
  1259   assumes "\<And>x. P x = Q x"
  1260   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1261   using assms by blast
  1262 
  1263 lemma iff_exI:
  1264   assumes "\<And>x. P x = Q x"
  1265   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1266   using assms by blast
  1267 
  1268 lemma all_comm:
  1269   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1270   by blast
  1271 
  1272 lemma ex_comm:
  1273   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1274   by blast
  1275 
  1276 use "simpdata.ML"
  1277 ML {* open Simpdata *}
  1278 
  1279 setup {*
  1280   Simplifier.method_setup Splitter.split_modifiers
  1281   #> (fn thy => (change_simpset_of thy (fn _ => Simpdata.simpset_simprocs); thy))
  1282   #> Splitter.setup
  1283   #> Clasimp.setup
  1284   #> EqSubst.setup
  1285 *}
  1286 
  1287 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1288 
  1289 simproc_setup neq ("x = y") = {* fn _ =>
  1290 let
  1291   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1292   fun is_neq eq lhs rhs thm =
  1293     (case Thm.prop_of thm of
  1294       _ $ (Not $ (eq' $ l' $ r')) =>
  1295         Not = HOLogic.Not andalso eq' = eq andalso
  1296         r' aconv lhs andalso l' aconv rhs
  1297     | _ => false);
  1298   fun proc ss ct =
  1299     (case Thm.term_of ct of
  1300       eq $ lhs $ rhs =>
  1301         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1302           SOME thm => SOME (thm RS neq_to_EQ_False)
  1303         | NONE => NONE)
  1304      | _ => NONE);
  1305 in proc end;
  1306 *}
  1307 
  1308 simproc_setup let_simp ("Let x f") = {*
  1309 let
  1310   val (f_Let_unfold, x_Let_unfold) =
  1311     let val [(_$(f$x)$_)] = prems_of @{thm Let_unfold}
  1312     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1313   val (f_Let_folded, x_Let_folded) =
  1314     let val [(_$(f$x)$_)] = prems_of @{thm Let_folded}
  1315     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1316   val g_Let_folded =
  1317     let val [(_$_$(g$_))] = prems_of @{thm Let_folded} in cterm_of @{theory} g end;
  1318 
  1319   fun proc _ ss ct =
  1320     let
  1321       val ctxt = Simplifier.the_context ss;
  1322       val thy = ProofContext.theory_of ctxt;
  1323       val t = Thm.term_of ct;
  1324       val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1325     in Option.map (hd o Variable.export ctxt' ctxt o single)
  1326       (case t' of Const ("Let",_) $ x $ f => (* x and f are already in normal form *)
  1327         if is_Free x orelse is_Bound x orelse is_Const x
  1328         then SOME @{thm Let_def}
  1329         else
  1330           let
  1331             val n = case f of (Abs (x,_,_)) => x | _ => "x";
  1332             val cx = cterm_of thy x;
  1333             val {T=xT,...} = rep_cterm cx;
  1334             val cf = cterm_of thy f;
  1335             val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1336             val (_$_$g) = prop_of fx_g;
  1337             val g' = abstract_over (x,g);
  1338           in (if (g aconv g')
  1339                then
  1340                   let
  1341                     val rl =
  1342                       cterm_instantiate [(f_Let_unfold,cf),(x_Let_unfold,cx)] @{thm Let_unfold};
  1343                   in SOME (rl OF [fx_g]) end
  1344                else if Term.betapply (f,x) aconv g then NONE (*avoid identity conversion*)
  1345                else let
  1346                      val abs_g'= Abs (n,xT,g');
  1347                      val g'x = abs_g'$x;
  1348                      val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1349                      val rl = cterm_instantiate
  1350                                [(f_Let_folded,cterm_of thy f),(x_Let_folded,cx),
  1351                                 (g_Let_folded,cterm_of thy abs_g')]
  1352                                @{thm Let_folded};
  1353                    in SOME (rl OF [transitive fx_g g_g'x])
  1354                    end)
  1355           end
  1356       | _ => NONE)
  1357     end
  1358 in proc end *}
  1359 
  1360 
  1361 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1362 proof
  1363   assume "True \<Longrightarrow> PROP P"
  1364   from this [OF TrueI] show "PROP P" .
  1365 next
  1366   assume "PROP P"
  1367   then show "PROP P" .
  1368 qed
  1369 
  1370 lemma ex_simps:
  1371   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1372   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1373   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1374   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1375   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1376   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1377   -- {* Miniscoping: pushing in existential quantifiers. *}
  1378   by (iprover | blast)+
  1379 
  1380 lemma all_simps:
  1381   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1382   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1383   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1384   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1385   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1386   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1387   -- {* Miniscoping: pushing in universal quantifiers. *}
  1388   by (iprover | blast)+
  1389 
  1390 lemmas [simp] =
  1391   triv_forall_equality (*prunes params*)
  1392   True_implies_equals  (*prune asms `True'*)
  1393   if_True
  1394   if_False
  1395   if_cancel
  1396   if_eq_cancel
  1397   imp_disjL
  1398   (*In general it seems wrong to add distributive laws by default: they
  1399     might cause exponential blow-up.  But imp_disjL has been in for a while
  1400     and cannot be removed without affecting existing proofs.  Moreover,
  1401     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1402     grounds that it allows simplification of R in the two cases.*)
  1403   conj_assoc
  1404   disj_assoc
  1405   de_Morgan_conj
  1406   de_Morgan_disj
  1407   imp_disj1
  1408   imp_disj2
  1409   not_imp
  1410   disj_not1
  1411   not_all
  1412   not_ex
  1413   cases_simp
  1414   the_eq_trivial
  1415   the_sym_eq_trivial
  1416   ex_simps
  1417   all_simps
  1418   simp_thms
  1419 
  1420 lemmas [cong] = imp_cong simp_implies_cong
  1421 lemmas [split] = split_if
  1422 
  1423 ML {* val HOL_ss = @{simpset} *}
  1424 
  1425 text {* Simplifies x assuming c and y assuming ~c *}
  1426 lemma if_cong:
  1427   assumes "b = c"
  1428       and "c \<Longrightarrow> x = u"
  1429       and "\<not> c \<Longrightarrow> y = v"
  1430   shows "(if b then x else y) = (if c then u else v)"
  1431   unfolding if_def using assms by simp
  1432 
  1433 text {* Prevents simplification of x and y:
  1434   faster and allows the execution of functional programs. *}
  1435 lemma if_weak_cong [cong]:
  1436   assumes "b = c"
  1437   shows "(if b then x else y) = (if c then x else y)"
  1438   using assms by (rule arg_cong)
  1439 
  1440 text {* Prevents simplification of t: much faster *}
  1441 lemma let_weak_cong:
  1442   assumes "a = b"
  1443   shows "(let x = a in t x) = (let x = b in t x)"
  1444   using assms by (rule arg_cong)
  1445 
  1446 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1447 lemma eq_cong2:
  1448   assumes "u = u'"
  1449   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1450   using assms by simp
  1451 
  1452 lemma if_distrib:
  1453   "f (if c then x else y) = (if c then f x else f y)"
  1454   by simp
  1455 
  1456 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1457   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1458 lemma restrict_to_left:
  1459   assumes "x = y"
  1460   shows "(x = z) = (y = z)"
  1461   using assms by simp
  1462 
  1463 
  1464 subsubsection {* Generic cases and induction *}
  1465 
  1466 text {* Rule projections: *}
  1467 
  1468 ML {*
  1469 structure ProjectRule = ProjectRuleFun
  1470 (
  1471   val conjunct1 = @{thm conjunct1};
  1472   val conjunct2 = @{thm conjunct2};
  1473   val mp = @{thm mp};
  1474 )
  1475 *}
  1476 
  1477 constdefs
  1478   induct_forall where "induct_forall P == \<forall>x. P x"
  1479   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1480   induct_equal where "induct_equal x y == x = y"
  1481   induct_conj where "induct_conj A B == A \<and> B"
  1482 
  1483 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1484   by (unfold atomize_all induct_forall_def)
  1485 
  1486 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1487   by (unfold atomize_imp induct_implies_def)
  1488 
  1489 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1490   by (unfold atomize_eq induct_equal_def)
  1491 
  1492 lemma induct_conj_eq:
  1493   includes meta_conjunction_syntax
  1494   shows "(A && B) == Trueprop (induct_conj A B)"
  1495   by (unfold atomize_conj induct_conj_def)
  1496 
  1497 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1498 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1499 lemmas induct_rulify_fallback =
  1500   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1501 
  1502 
  1503 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1504     induct_conj (induct_forall A) (induct_forall B)"
  1505   by (unfold induct_forall_def induct_conj_def) iprover
  1506 
  1507 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1508     induct_conj (induct_implies C A) (induct_implies C B)"
  1509   by (unfold induct_implies_def induct_conj_def) iprover
  1510 
  1511 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1512 proof
  1513   assume r: "induct_conj A B ==> PROP C" and A B
  1514   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1515 next
  1516   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1517   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1518 qed
  1519 
  1520 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1521 
  1522 hide const induct_forall induct_implies induct_equal induct_conj
  1523 
  1524 text {* Method setup. *}
  1525 
  1526 ML {*
  1527   structure Induct = InductFun
  1528   (
  1529     val cases_default = @{thm case_split}
  1530     val atomize = @{thms induct_atomize}
  1531     val rulify = @{thms induct_rulify}
  1532     val rulify_fallback = @{thms induct_rulify_fallback}
  1533   );
  1534 *}
  1535 
  1536 setup Induct.setup
  1537 
  1538 
  1539 subsection {* Other simple lemmas and lemma duplicates *}
  1540 
  1541 lemma Let_0 [simp]: "Let 0 f = f 0"
  1542   unfolding Let_def ..
  1543 
  1544 lemma Let_1 [simp]: "Let 1 f = f 1"
  1545   unfolding Let_def ..
  1546 
  1547 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1548   by blast+
  1549 
  1550 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1551   apply (rule iffI)
  1552   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1553   apply (fast dest!: theI')
  1554   apply (fast intro: ext the1_equality [symmetric])
  1555   apply (erule ex1E)
  1556   apply (rule allI)
  1557   apply (rule ex1I)
  1558   apply (erule spec)
  1559   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1560   apply (erule impE)
  1561   apply (rule allI)
  1562   apply (rule_tac P = "xa = x" in case_split_thm)
  1563   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1564   done
  1565 
  1566 lemma mk_left_commute:
  1567   fixes f (infix "\<otimes>" 60)
  1568   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1569           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1570   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1571   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1572 
  1573 lemmas eq_sym_conv = eq_commute
  1574 
  1575 lemma nnf_simps:
  1576   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1577   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1578   "(\<not> \<not>(P)) = P"
  1579 by blast+
  1580 
  1581 
  1582 subsection {* Basic ML bindings *}
  1583 
  1584 ML {*
  1585 val FalseE = @{thm FalseE}
  1586 val Let_def = @{thm Let_def}
  1587 val TrueI = @{thm TrueI}
  1588 val allE = @{thm allE}
  1589 val allI = @{thm allI}
  1590 val all_dupE = @{thm all_dupE}
  1591 val arg_cong = @{thm arg_cong}
  1592 val box_equals = @{thm box_equals}
  1593 val ccontr = @{thm ccontr}
  1594 val classical = @{thm classical}
  1595 val conjE = @{thm conjE}
  1596 val conjI = @{thm conjI}
  1597 val conjunct1 = @{thm conjunct1}
  1598 val conjunct2 = @{thm conjunct2}
  1599 val disjCI = @{thm disjCI}
  1600 val disjE = @{thm disjE}
  1601 val disjI1 = @{thm disjI1}
  1602 val disjI2 = @{thm disjI2}
  1603 val eq_reflection = @{thm eq_reflection}
  1604 val ex1E = @{thm ex1E}
  1605 val ex1I = @{thm ex1I}
  1606 val ex1_implies_ex = @{thm ex1_implies_ex}
  1607 val exE = @{thm exE}
  1608 val exI = @{thm exI}
  1609 val excluded_middle = @{thm excluded_middle}
  1610 val ext = @{thm ext}
  1611 val fun_cong = @{thm fun_cong}
  1612 val iffD1 = @{thm iffD1}
  1613 val iffD2 = @{thm iffD2}
  1614 val iffI = @{thm iffI}
  1615 val impE = @{thm impE}
  1616 val impI = @{thm impI}
  1617 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1618 val mp = @{thm mp}
  1619 val notE = @{thm notE}
  1620 val notI = @{thm notI}
  1621 val not_all = @{thm not_all}
  1622 val not_ex = @{thm not_ex}
  1623 val not_iff = @{thm not_iff}
  1624 val not_not = @{thm not_not}
  1625 val not_sym = @{thm not_sym}
  1626 val refl = @{thm refl}
  1627 val rev_mp = @{thm rev_mp}
  1628 val spec = @{thm spec}
  1629 val ssubst = @{thm ssubst}
  1630 val subst = @{thm subst}
  1631 val sym = @{thm sym}
  1632 val trans = @{thm trans}
  1633 *}
  1634 
  1635 
  1636 subsection {* Code generator basic setup -- see further @{text Code_Setup.thy} *}
  1637 
  1638 setup "CodeName.setup #> CodeTarget.setup #> Nbe.setup"
  1639 
  1640 class eq (attach "op =") = type
  1641 
  1642 lemma [code func]:
  1643   shows "False \<and> x \<longleftrightarrow> False"
  1644     and "True \<and> x \<longleftrightarrow> x"
  1645     and "x \<and> False \<longleftrightarrow> False"
  1646     and "x \<and> True \<longleftrightarrow> x" by simp_all
  1647 
  1648 lemma [code func]:
  1649   shows "False \<or> x \<longleftrightarrow> x"
  1650     and "True \<or> x \<longleftrightarrow> True"
  1651     and "x \<or> False \<longleftrightarrow> x"
  1652     and "x \<or> True \<longleftrightarrow> True" by simp_all
  1653 
  1654 lemma [code func]:
  1655   shows "\<not> True \<longleftrightarrow> False"
  1656     and "\<not> False \<longleftrightarrow> True" by (rule HOL.simp_thms)+
  1657 
  1658 code_datatype Trueprop "prop"
  1659 
  1660 code_datatype "TYPE('a\<Colon>{})"
  1661 
  1662 lemma Let_case_cert:
  1663   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1664   shows "CASE x \<equiv> f x"
  1665   using assms by simp_all
  1666 
  1667 lemma If_case_cert:
  1668   includes meta_conjunction_syntax
  1669   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1670   shows "(CASE True \<equiv> f) && (CASE False \<equiv> g)"
  1671   using assms by simp_all
  1672 
  1673 setup {*
  1674   Code.add_case @{thm Let_case_cert}
  1675   #> Code.add_case @{thm If_case_cert}
  1676   #> Code.add_undefined @{const_name undefined}
  1677 *}
  1678 
  1679 
  1680 subsection {* Legacy tactics and ML bindings *}
  1681 
  1682 ML {*
  1683 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1684 
  1685 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1686 local
  1687   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1688     | wrong_prem (Bound _) = true
  1689     | wrong_prem _ = false;
  1690   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1691 in
  1692   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1693   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1694 end;
  1695 
  1696 val all_conj_distrib = thm "all_conj_distrib";
  1697 val all_simps = thms "all_simps";
  1698 val atomize_not = thm "atomize_not";
  1699 val case_split = thm "case_split";
  1700 val case_split_thm = thm "case_split_thm"
  1701 val cases_simp = thm "cases_simp";
  1702 val choice_eq = thm "choice_eq"
  1703 val cong = thm "cong"
  1704 val conj_comms = thms "conj_comms";
  1705 val conj_cong = thm "conj_cong";
  1706 val de_Morgan_conj = thm "de_Morgan_conj";
  1707 val de_Morgan_disj = thm "de_Morgan_disj";
  1708 val disj_assoc = thm "disj_assoc";
  1709 val disj_comms = thms "disj_comms";
  1710 val disj_cong = thm "disj_cong";
  1711 val eq_ac = thms "eq_ac";
  1712 val eq_cong2 = thm "eq_cong2"
  1713 val Eq_FalseI = thm "Eq_FalseI";
  1714 val Eq_TrueI = thm "Eq_TrueI";
  1715 val Ex1_def = thm "Ex1_def"
  1716 val ex_disj_distrib = thm "ex_disj_distrib";
  1717 val ex_simps = thms "ex_simps";
  1718 val if_cancel = thm "if_cancel";
  1719 val if_eq_cancel = thm "if_eq_cancel";
  1720 val if_False = thm "if_False";
  1721 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1722 val iff = thm "iff"
  1723 val if_splits = thms "if_splits";
  1724 val if_True = thm "if_True";
  1725 val if_weak_cong = thm "if_weak_cong"
  1726 val imp_all = thm "imp_all";
  1727 val imp_cong = thm "imp_cong";
  1728 val imp_conjL = thm "imp_conjL";
  1729 val imp_conjR = thm "imp_conjR";
  1730 val imp_conv_disj = thm "imp_conv_disj";
  1731 val simp_implies_def = thm "simp_implies_def";
  1732 val simp_thms = thms "simp_thms";
  1733 val split_if = thm "split_if";
  1734 val the1_equality = thm "the1_equality"
  1735 val theI = thm "theI"
  1736 val theI' = thm "theI'"
  1737 val True_implies_equals = thm "True_implies_equals";
  1738 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1739 
  1740 *}
  1741 
  1742 end