src/HOL/Orderings.thy
author haftmann
Fri Aug 24 14:14:18 2007 +0200 (2007-08-24)
changeset 24422 c0b5ff9e9e4d
parent 24286 7619080e49f0
child 24641 448edc627ee4
permissions -rw-r--r--
moved class dense_linear_order to Orderings.thy
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports Set Fun
    10 uses
    11   (*"~~/src/Provers/quasi.ML"*)
    12   "~~/src/Provers/order.ML"
    13 begin
    14 
    15 subsection {* Partial orders *}
    16 
    17 class order = ord +
    18   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
    19   and order_refl [iff]: "x \<sqsubseteq> x"
    20   and order_trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    21   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
    22 
    23 begin
    24 
    25 text {* Reflexivity. *}
    26 
    27 lemma eq_refl: "x = y \<Longrightarrow> x \<^loc>\<le> y"
    28     -- {* This form is useful with the classical reasoner. *}
    29 by (erule ssubst) (rule order_refl)
    30 
    31 lemma less_irrefl [iff]: "\<not> x \<^loc>< x"
    32 by (simp add: less_le)
    33 
    34 lemma le_less: "x \<^loc>\<le> y \<longleftrightarrow> x \<^loc>< y \<or> x = y"
    35     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    36 by (simp add: less_le) blast
    37 
    38 lemma le_imp_less_or_eq: "x \<^loc>\<le> y \<Longrightarrow> x \<^loc>< y \<or> x = y"
    39 unfolding less_le by blast
    40 
    41 lemma less_imp_le: "x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y"
    42 unfolding less_le by blast
    43 
    44 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    45 by (erule contrapos_pn, erule subst, rule less_irrefl)
    46 
    47 
    48 text {* Useful for simplification, but too risky to include by default. *}
    49 
    50 lemma less_imp_not_eq: "x \<^loc>< y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
    51 by auto
    52 
    53 lemma less_imp_not_eq2: "x \<^loc>< y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
    54 by auto
    55 
    56 
    57 text {* Transitivity rules for calculational reasoning *}
    58 
    59 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<^loc>\<le> b \<Longrightarrow> a \<^loc>< b"
    60 by (simp add: less_le)
    61 
    62 lemma le_neq_trans: "a \<^loc>\<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<^loc>< b"
    63 by (simp add: less_le)
    64 
    65 
    66 text {* Asymmetry. *}
    67 
    68 lemma less_not_sym: "x \<^loc>< y \<Longrightarrow> \<not> (y \<^loc>< x)"
    69 by (simp add: less_le antisym)
    70 
    71 lemma less_asym: "x \<^loc>< y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<^loc>< x) \<Longrightarrow> P"
    72 by (drule less_not_sym, erule contrapos_np) simp
    73 
    74 lemma eq_iff: "x = y \<longleftrightarrow> x \<^loc>\<le> y \<and> y \<^loc>\<le> x"
    75 by (blast intro: antisym)
    76 
    77 lemma antisym_conv: "y \<^loc>\<le> x \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
    78 by (blast intro: antisym)
    79 
    80 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    81 by (erule contrapos_pn, erule subst, rule less_irrefl)
    82 
    83 
    84 text {* Transitivity. *}
    85 
    86 lemma less_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    87 by (simp add: less_le) (blast intro: order_trans antisym)
    88 
    89 lemma le_less_trans: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    90 by (simp add: less_le) (blast intro: order_trans antisym)
    91 
    92 lemma less_le_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<^loc>< z"
    93 by (simp add: less_le) (blast intro: order_trans antisym)
    94 
    95 
    96 text {* Useful for simplification, but too risky to include by default. *}
    97 
    98 lemma less_imp_not_less: "x \<^loc>< y \<Longrightarrow> (\<not> y \<^loc>< x) \<longleftrightarrow> True"
    99 by (blast elim: less_asym)
   100 
   101 lemma less_imp_triv: "x \<^loc>< y \<Longrightarrow> (y \<^loc>< x \<longrightarrow> P) \<longleftrightarrow> True"
   102 by (blast elim: less_asym)
   103 
   104 
   105 text {* Transitivity rules for calculational reasoning *}
   106 
   107 lemma less_asym': "a \<^loc>< b \<Longrightarrow> b \<^loc>< a \<Longrightarrow> P"
   108 by (rule less_asym)
   109 
   110 
   111 text {* Reverse order *}
   112 
   113 lemma order_reverse:
   114   "order (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   115 by unfold_locales
   116    (simp add: less_le, auto intro: antisym order_trans)
   117 
   118 end
   119 
   120 
   121 subsection {* Linear (total) orders *}
   122 
   123 class linorder = order +
   124   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   125 begin
   126 
   127 lemma less_linear: "x \<^loc>< y \<or> x = y \<or> y \<^loc>< x"
   128 unfolding less_le using less_le linear by blast
   129 
   130 lemma le_less_linear: "x \<^loc>\<le> y \<or> y \<^loc>< x"
   131 by (simp add: le_less less_linear)
   132 
   133 lemma le_cases [case_names le ge]:
   134   "(x \<^loc>\<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>\<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   135 using linear by blast
   136 
   137 lemma linorder_cases [case_names less equal greater]:
   138   "(x \<^loc>< y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> P) \<Longrightarrow> P"
   139 using less_linear by blast
   140 
   141 lemma not_less: "\<not> x \<^loc>< y \<longleftrightarrow> y \<^loc>\<le> x"
   142 apply (simp add: less_le)
   143 using linear apply (blast intro: antisym)
   144 done
   145 
   146 lemma not_less_iff_gr_or_eq:
   147  "\<not>(x \<^loc>< y) \<longleftrightarrow> (x \<^loc>> y | x = y)"
   148 apply(simp add:not_less le_less)
   149 apply blast
   150 done
   151 
   152 lemma not_le: "\<not> x \<^loc>\<le> y \<longleftrightarrow> y \<^loc>< x"
   153 apply (simp add: less_le)
   154 using linear apply (blast intro: antisym)
   155 done
   156 
   157 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<^loc>< y \<or> y \<^loc>< x"
   158 by (cut_tac x = x and y = y in less_linear, auto)
   159 
   160 lemma neqE: "x \<noteq> y \<Longrightarrow> (x \<^loc>< y \<Longrightarrow> R) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> R) \<Longrightarrow> R"
   161 by (simp add: neq_iff) blast
   162 
   163 lemma antisym_conv1: "\<not> x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   164 by (blast intro: antisym dest: not_less [THEN iffD1])
   165 
   166 lemma antisym_conv2: "x \<^loc>\<le> y \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   167 by (blast intro: antisym dest: not_less [THEN iffD1])
   168 
   169 lemma antisym_conv3: "\<not> y \<^loc>< x \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   170 by (blast intro: antisym dest: not_less [THEN iffD1])
   171 
   172 text{*Replacing the old Nat.leI*}
   173 lemma leI: "\<not> x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> x"
   174 unfolding not_less .
   175 
   176 lemma leD: "y \<^loc>\<le> x \<Longrightarrow> \<not> x \<^loc>< y"
   177 unfolding not_less .
   178 
   179 (*FIXME inappropriate name (or delete altogether)*)
   180 lemma not_leE: "\<not> y \<^loc>\<le> x \<Longrightarrow> x \<^loc>< y"
   181 unfolding not_le .
   182 
   183 
   184 text {* Reverse order *}
   185 
   186 lemma linorder_reverse:
   187   "linorder (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   188 by unfold_locales
   189   (simp add: less_le, auto intro: antisym order_trans simp add: linear)
   190 
   191 
   192 text {* min/max *}
   193 
   194 text {* for historic reasons, definitions are done in context ord *}
   195 
   196 definition (in ord)
   197   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   198   [code unfold, code inline del]: "min a b = (if a \<^loc>\<le> b then a else b)"
   199 
   200 definition (in ord)
   201   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   202   [code unfold, code inline del]: "max a b = (if a \<^loc>\<le> b then b else a)"
   203 
   204 lemma min_le_iff_disj:
   205   "min x y \<^loc>\<le> z \<longleftrightarrow> x \<^loc>\<le> z \<or> y \<^loc>\<le> z"
   206 unfolding min_def using linear by (auto intro: order_trans)
   207 
   208 lemma le_max_iff_disj:
   209   "z \<^loc>\<le> max x y \<longleftrightarrow> z \<^loc>\<le> x \<or> z \<^loc>\<le> y"
   210 unfolding max_def using linear by (auto intro: order_trans)
   211 
   212 lemma min_less_iff_disj:
   213   "min x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<or> y \<^loc>< z"
   214 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   215 
   216 lemma less_max_iff_disj:
   217   "z \<^loc>< max x y \<longleftrightarrow> z \<^loc>< x \<or> z \<^loc>< y"
   218 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   219 
   220 lemma min_less_iff_conj [simp]:
   221   "z \<^loc>< min x y \<longleftrightarrow> z \<^loc>< x \<and> z \<^loc>< y"
   222 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   223 
   224 lemma max_less_iff_conj [simp]:
   225   "max x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<and> y \<^loc>< z"
   226 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   227 
   228 lemma split_min [noatp]:
   229   "P (min i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P i) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P j)"
   230 by (simp add: min_def)
   231 
   232 lemma split_max [noatp]:
   233   "P (max i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P j) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P i)"
   234 by (simp add: max_def)
   235 
   236 end
   237 
   238 
   239 subsection {* Reasoning tools setup *}
   240 
   241 ML {*
   242 local
   243 
   244 fun decomp_gen sort thy (Trueprop $ t) =
   245   let
   246     fun of_sort t =
   247       let
   248         val T = type_of t
   249       in
   250         (* exclude numeric types: linear arithmetic subsumes transitivity *)
   251         T <> HOLogic.natT andalso T <> HOLogic.intT
   252           andalso T <> HOLogic.realT andalso Sign.of_sort thy (T, sort)
   253       end;
   254     fun dec (Const (@{const_name Not}, _) $ t) = (case dec t
   255           of NONE => NONE
   256            | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   257       | dec (Const (@{const_name "op ="},  _) $ t1 $ t2) =
   258           if of_sort t1
   259           then SOME (t1, "=", t2)
   260           else NONE
   261       | dec (Const (@{const_name HOL.less_eq},  _) $ t1 $ t2) =
   262           if of_sort t1
   263           then SOME (t1, "<=", t2)
   264           else NONE
   265       | dec (Const (@{const_name HOL.less},  _) $ t1 $ t2) =
   266           if of_sort t1
   267           then SOME (t1, "<", t2)
   268           else NONE
   269       | dec _ = NONE;
   270   in dec t end;
   271 
   272 in
   273 
   274 (* sorry - there is no preorder class
   275 structure Quasi_Tac = Quasi_Tac_Fun (
   276 struct
   277   val le_trans = thm "order_trans";
   278   val le_refl = thm "order_refl";
   279   val eqD1 = thm "order_eq_refl";
   280   val eqD2 = thm "sym" RS thm "order_eq_refl";
   281   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   282   val less_imp_le = thm "order_less_imp_le";
   283   val le_neq_trans = thm "order_le_neq_trans";
   284   val neq_le_trans = thm "order_neq_le_trans";
   285   val less_imp_neq = thm "less_imp_neq";
   286   val decomp_trans = decomp_gen ["Orderings.preorder"];
   287   val decomp_quasi = decomp_gen ["Orderings.preorder"];
   288 end);*)
   289 
   290 structure Order_Tac = Order_Tac_Fun (
   291 struct
   292   val less_reflE = @{thm less_irrefl} RS @{thm notE};
   293   val le_refl = @{thm order_refl};
   294   val less_imp_le = @{thm less_imp_le};
   295   val not_lessI = @{thm not_less} RS @{thm iffD2};
   296   val not_leI = @{thm not_le} RS @{thm iffD2};
   297   val not_lessD = @{thm not_less} RS @{thm iffD1};
   298   val not_leD = @{thm not_le} RS @{thm iffD1};
   299   val eqI = @{thm antisym};
   300   val eqD1 = @{thm eq_refl};
   301   val eqD2 = @{thm sym} RS @{thm eq_refl};
   302   val less_trans = @{thm less_trans};
   303   val less_le_trans = @{thm less_le_trans};
   304   val le_less_trans = @{thm le_less_trans};
   305   val le_trans = @{thm order_trans};
   306   val le_neq_trans = @{thm le_neq_trans};
   307   val neq_le_trans = @{thm neq_le_trans};
   308   val less_imp_neq = @{thm less_imp_neq};
   309   val eq_neq_eq_imp_neq = @{thm eq_neq_eq_imp_neq};
   310   val not_sym = @{thm not_sym};
   311   val decomp_part = decomp_gen ["Orderings.order"];
   312   val decomp_lin = decomp_gen ["Orderings.linorder"];
   313 end);
   314 
   315 end;
   316 *}
   317 
   318 setup {*
   319 let
   320 
   321 fun prp t thm = (#prop (rep_thm thm) = t);
   322 
   323 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   324   let val prems = prems_of_ss ss;
   325       val less = Const (@{const_name less}, T);
   326       val t = HOLogic.mk_Trueprop(le $ s $ r);
   327   in case find_first (prp t) prems of
   328        NONE =>
   329          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   330          in case find_first (prp t) prems of
   331               NONE => NONE
   332             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   333          end
   334      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   335   end
   336   handle THM _ => NONE;
   337 
   338 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   339   let val prems = prems_of_ss ss;
   340       val le = Const (@{const_name less_eq}, T);
   341       val t = HOLogic.mk_Trueprop(le $ r $ s);
   342   in case find_first (prp t) prems of
   343        NONE =>
   344          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   345          in case find_first (prp t) prems of
   346               NONE => NONE
   347             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   348          end
   349      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   350   end
   351   handle THM _ => NONE;
   352 
   353 fun add_simprocs procs thy =
   354   (Simplifier.change_simpset_of thy (fn ss => ss
   355     addsimprocs (map (fn (name, raw_ts, proc) =>
   356       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   357 fun add_solver name tac thy =
   358   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   359     (mk_solver name (K tac))); thy);
   360 
   361 in
   362   add_simprocs [
   363        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   364        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   365      ]
   366   #> add_solver "Trans_linear" Order_Tac.linear_tac
   367   #> add_solver "Trans_partial" Order_Tac.partial_tac
   368   (* Adding the transitivity reasoners also as safe solvers showed a slight
   369      speed up, but the reasoning strength appears to be not higher (at least
   370      no breaking of additional proofs in the entire HOL distribution, as
   371      of 5 March 2004, was observed). *)
   372 end
   373 *}
   374 
   375 
   376 subsection {* Dense orders *}
   377 
   378 class dense_linear_order = linorder + 
   379   assumes gt_ex: "\<exists>y. x \<sqsubset> y" 
   380   and lt_ex: "\<exists>y. y \<sqsubset> x"
   381   and dense: "x \<sqsubset> y \<Longrightarrow> (\<exists>z. x \<sqsubset> z \<and> z \<sqsubset> y)"
   382   (*see further theory Dense_Linear_Order*)
   383 
   384 lemma interval_empty_iff:
   385   fixes x y z :: "'a\<Colon>dense_linear_order"
   386   shows "{y. x < y \<and> y < z} = {} \<longleftrightarrow> \<not> x < z"
   387   by (auto dest: dense)
   388 
   389 subsection {* Name duplicates *}
   390 
   391 lemmas order_less_le = less_le
   392 lemmas order_eq_refl = order_class.eq_refl
   393 lemmas order_less_irrefl = order_class.less_irrefl
   394 lemmas order_le_less = order_class.le_less
   395 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   396 lemmas order_less_imp_le = order_class.less_imp_le
   397 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   398 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   399 lemmas order_neq_le_trans = order_class.neq_le_trans
   400 lemmas order_le_neq_trans = order_class.le_neq_trans
   401 
   402 lemmas order_antisym = antisym
   403 lemmas order_less_not_sym = order_class.less_not_sym
   404 lemmas order_less_asym = order_class.less_asym
   405 lemmas order_eq_iff = order_class.eq_iff
   406 lemmas order_antisym_conv = order_class.antisym_conv
   407 lemmas order_less_trans = order_class.less_trans
   408 lemmas order_le_less_trans = order_class.le_less_trans
   409 lemmas order_less_le_trans = order_class.less_le_trans
   410 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   411 lemmas order_less_imp_triv = order_class.less_imp_triv
   412 lemmas order_less_asym' = order_class.less_asym'
   413 
   414 lemmas linorder_linear = linear
   415 lemmas linorder_less_linear = linorder_class.less_linear
   416 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   417 lemmas linorder_le_cases = linorder_class.le_cases
   418 lemmas linorder_not_less = linorder_class.not_less
   419 lemmas linorder_not_le = linorder_class.not_le
   420 lemmas linorder_neq_iff = linorder_class.neq_iff
   421 lemmas linorder_neqE = linorder_class.neqE
   422 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   423 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   424 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   425 
   426 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj
   427 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj
   428 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj
   429 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj
   430 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj
   431 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj
   432 lemmas split_min = linorder_class.split_min
   433 lemmas split_max = linorder_class.split_max
   434 
   435 
   436 subsection {* Bounded quantifiers *}
   437 
   438 syntax
   439   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   440   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   441   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   442   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   443 
   444   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   445   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   446   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   447   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   448 
   449 syntax (xsymbols)
   450   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   451   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   452   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   453   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   454 
   455   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   456   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   457   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   458   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   459 
   460 syntax (HOL)
   461   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   462   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   463   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   464   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   465 
   466 syntax (HTML output)
   467   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   468   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   469   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   470   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   471 
   472   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   473   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   474   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   475   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   476 
   477 translations
   478   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   479   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   480   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   481   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   482   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   483   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   484   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   485   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   486 
   487 print_translation {*
   488 let
   489   val All_binder = Syntax.binder_name @{const_syntax All};
   490   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   491   val impl = @{const_syntax "op -->"};
   492   val conj = @{const_syntax "op &"};
   493   val less = @{const_syntax less};
   494   val less_eq = @{const_syntax less_eq};
   495 
   496   val trans =
   497    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   498     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   499     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   500     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   501 
   502   fun matches_bound v t = 
   503      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   504               | _ => false
   505   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   506   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   507 
   508   fun tr' q = (q,
   509     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   510       (case AList.lookup (op =) trans (q, c, d) of
   511         NONE => raise Match
   512       | SOME (l, g) =>
   513           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   514           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   515           else raise Match)
   516      | _ => raise Match);
   517 in [tr' All_binder, tr' Ex_binder] end
   518 *}
   519 
   520 
   521 subsection {* Transitivity reasoning *}
   522 
   523 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   524 by (rule subst)
   525 
   526 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   527 by (rule ssubst)
   528 
   529 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   530 by (rule subst)
   531 
   532 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   533 by (rule ssubst)
   534 
   535 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   536   (!!x y. x < y ==> f x < f y) ==> f a < c"
   537 proof -
   538   assume r: "!!x y. x < y ==> f x < f y"
   539   assume "a < b" hence "f a < f b" by (rule r)
   540   also assume "f b < c"
   541   finally (order_less_trans) show ?thesis .
   542 qed
   543 
   544 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   545   (!!x y. x < y ==> f x < f y) ==> a < f c"
   546 proof -
   547   assume r: "!!x y. x < y ==> f x < f y"
   548   assume "a < f b"
   549   also assume "b < c" hence "f b < f c" by (rule r)
   550   finally (order_less_trans) show ?thesis .
   551 qed
   552 
   553 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   554   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   555 proof -
   556   assume r: "!!x y. x <= y ==> f x <= f y"
   557   assume "a <= b" hence "f a <= f b" by (rule r)
   558   also assume "f b < c"
   559   finally (order_le_less_trans) show ?thesis .
   560 qed
   561 
   562 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   563   (!!x y. x < y ==> f x < f y) ==> a < f c"
   564 proof -
   565   assume r: "!!x y. x < y ==> f x < f y"
   566   assume "a <= f b"
   567   also assume "b < c" hence "f b < f c" by (rule r)
   568   finally (order_le_less_trans) show ?thesis .
   569 qed
   570 
   571 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   572   (!!x y. x < y ==> f x < f y) ==> f a < c"
   573 proof -
   574   assume r: "!!x y. x < y ==> f x < f y"
   575   assume "a < b" hence "f a < f b" by (rule r)
   576   also assume "f b <= c"
   577   finally (order_less_le_trans) show ?thesis .
   578 qed
   579 
   580 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   581   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   582 proof -
   583   assume r: "!!x y. x <= y ==> f x <= f y"
   584   assume "a < f b"
   585   also assume "b <= c" hence "f b <= f c" by (rule r)
   586   finally (order_less_le_trans) show ?thesis .
   587 qed
   588 
   589 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   590   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   591 proof -
   592   assume r: "!!x y. x <= y ==> f x <= f y"
   593   assume "a <= f b"
   594   also assume "b <= c" hence "f b <= f c" by (rule r)
   595   finally (order_trans) show ?thesis .
   596 qed
   597 
   598 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   599   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   600 proof -
   601   assume r: "!!x y. x <= y ==> f x <= f y"
   602   assume "a <= b" hence "f a <= f b" by (rule r)
   603   also assume "f b <= c"
   604   finally (order_trans) show ?thesis .
   605 qed
   606 
   607 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   608   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   609 proof -
   610   assume r: "!!x y. x <= y ==> f x <= f y"
   611   assume "a <= b" hence "f a <= f b" by (rule r)
   612   also assume "f b = c"
   613   finally (ord_le_eq_trans) show ?thesis .
   614 qed
   615 
   616 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   617   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   618 proof -
   619   assume r: "!!x y. x <= y ==> f x <= f y"
   620   assume "a = f b"
   621   also assume "b <= c" hence "f b <= f c" by (rule r)
   622   finally (ord_eq_le_trans) show ?thesis .
   623 qed
   624 
   625 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   626   (!!x y. x < y ==> f x < f y) ==> f a < c"
   627 proof -
   628   assume r: "!!x y. x < y ==> f x < f y"
   629   assume "a < b" hence "f a < f b" by (rule r)
   630   also assume "f b = c"
   631   finally (ord_less_eq_trans) show ?thesis .
   632 qed
   633 
   634 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   635   (!!x y. x < y ==> f x < f y) ==> a < f c"
   636 proof -
   637   assume r: "!!x y. x < y ==> f x < f y"
   638   assume "a = f b"
   639   also assume "b < c" hence "f b < f c" by (rule r)
   640   finally (ord_eq_less_trans) show ?thesis .
   641 qed
   642 
   643 text {*
   644   Note that this list of rules is in reverse order of priorities.
   645 *}
   646 
   647 lemmas order_trans_rules [trans] =
   648   order_less_subst2
   649   order_less_subst1
   650   order_le_less_subst2
   651   order_le_less_subst1
   652   order_less_le_subst2
   653   order_less_le_subst1
   654   order_subst2
   655   order_subst1
   656   ord_le_eq_subst
   657   ord_eq_le_subst
   658   ord_less_eq_subst
   659   ord_eq_less_subst
   660   forw_subst
   661   back_subst
   662   rev_mp
   663   mp
   664   order_neq_le_trans
   665   order_le_neq_trans
   666   order_less_trans
   667   order_less_asym'
   668   order_le_less_trans
   669   order_less_le_trans
   670   order_trans
   671   order_antisym
   672   ord_le_eq_trans
   673   ord_eq_le_trans
   674   ord_less_eq_trans
   675   ord_eq_less_trans
   676   trans
   677 
   678 
   679 (* FIXME cleanup *)
   680 
   681 text {* These support proving chains of decreasing inequalities
   682     a >= b >= c ... in Isar proofs. *}
   683 
   684 lemma xt1:
   685   "a = b ==> b > c ==> a > c"
   686   "a > b ==> b = c ==> a > c"
   687   "a = b ==> b >= c ==> a >= c"
   688   "a >= b ==> b = c ==> a >= c"
   689   "(x::'a::order) >= y ==> y >= x ==> x = y"
   690   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   691   "(x::'a::order) > y ==> y >= z ==> x > z"
   692   "(x::'a::order) >= y ==> y > z ==> x > z"
   693   "(a::'a::order) > b ==> b > a ==> P"
   694   "(x::'a::order) > y ==> y > z ==> x > z"
   695   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   696   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   697   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   698   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   699   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   700   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   701 by auto
   702 
   703 lemma xt2:
   704   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   705 by (subgoal_tac "f b >= f c", force, force)
   706 
   707 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   708     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   709 by (subgoal_tac "f a >= f b", force, force)
   710 
   711 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   712   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   713 by (subgoal_tac "f b >= f c", force, force)
   714 
   715 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   716     (!!x y. x > y ==> f x > f y) ==> f a > c"
   717 by (subgoal_tac "f a > f b", force, force)
   718 
   719 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   720     (!!x y. x > y ==> f x > f y) ==> a > f c"
   721 by (subgoal_tac "f b > f c", force, force)
   722 
   723 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   724     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   725 by (subgoal_tac "f a >= f b", force, force)
   726 
   727 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   728     (!!x y. x > y ==> f x > f y) ==> a > f c"
   729 by (subgoal_tac "f b > f c", force, force)
   730 
   731 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   732     (!!x y. x > y ==> f x > f y) ==> f a > c"
   733 by (subgoal_tac "f a > f b", force, force)
   734 
   735 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   736 
   737 (* 
   738   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   739   for the wrong thing in an Isar proof.
   740 
   741   The extra transitivity rules can be used as follows: 
   742 
   743 lemma "(a::'a::order) > z"
   744 proof -
   745   have "a >= b" (is "_ >= ?rhs")
   746     sorry
   747   also have "?rhs >= c" (is "_ >= ?rhs")
   748     sorry
   749   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   750     sorry
   751   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   752     sorry
   753   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   754     sorry
   755   also (xtrans) have "?rhs > z"
   756     sorry
   757   finally (xtrans) show ?thesis .
   758 qed
   759 
   760   Alternatively, one can use "declare xtrans [trans]" and then
   761   leave out the "(xtrans)" above.
   762 *)
   763 
   764 subsection {* Order on bool *}
   765 
   766 instance bool :: order 
   767   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   768   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   769   by intro_classes (auto simp add: le_bool_def less_bool_def)
   770 lemmas [code func del] = le_bool_def less_bool_def
   771 
   772 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   773 by (simp add: le_bool_def)
   774 
   775 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   776 by (simp add: le_bool_def)
   777 
   778 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   779 by (simp add: le_bool_def)
   780 
   781 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   782 by (simp add: le_bool_def)
   783 
   784 lemma [code func]:
   785   "False \<le> b \<longleftrightarrow> True"
   786   "True \<le> b \<longleftrightarrow> b"
   787   "False < b \<longleftrightarrow> b"
   788   "True < b \<longleftrightarrow> False"
   789   unfolding le_bool_def less_bool_def by simp_all
   790 
   791 
   792 subsection {* Order on sets *}
   793 
   794 instance set :: (type) order
   795   by (intro_classes,
   796       (assumption | rule subset_refl subset_trans subset_antisym psubset_eq)+)
   797 
   798 lemmas basic_trans_rules [trans] =
   799   order_trans_rules set_rev_mp set_mp
   800 
   801 
   802 subsection {* Order on functions *}
   803 
   804 instance "fun" :: (type, ord) ord
   805   le_fun_def: "f \<le> g \<equiv> \<forall>x. f x \<le> g x"
   806   less_fun_def: "f < g \<equiv> f \<le> g \<and> f \<noteq> g" ..
   807 
   808 lemmas [code func del] = le_fun_def less_fun_def
   809 
   810 instance "fun" :: (type, order) order
   811   by default
   812     (auto simp add: le_fun_def less_fun_def expand_fun_eq
   813        intro: order_trans order_antisym)
   814 
   815 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
   816   unfolding le_fun_def by simp
   817 
   818 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
   819   unfolding le_fun_def by simp
   820 
   821 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
   822   unfolding le_fun_def by simp
   823 
   824 text {*
   825   Handy introduction and elimination rules for @{text "\<le>"}
   826   on unary and binary predicates
   827 *}
   828 
   829 lemma predicate1I [Pure.intro!, intro!]:
   830   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
   831   shows "P \<le> Q"
   832   apply (rule le_funI)
   833   apply (rule le_boolI)
   834   apply (rule PQ)
   835   apply assumption
   836   done
   837 
   838 lemma predicate1D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
   839   apply (erule le_funE)
   840   apply (erule le_boolE)
   841   apply assumption+
   842   done
   843 
   844 lemma predicate2I [Pure.intro!, intro!]:
   845   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
   846   shows "P \<le> Q"
   847   apply (rule le_funI)+
   848   apply (rule le_boolI)
   849   apply (rule PQ)
   850   apply assumption
   851   done
   852 
   853 lemma predicate2D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
   854   apply (erule le_funE)+
   855   apply (erule le_boolE)
   856   apply assumption+
   857   done
   858 
   859 lemma rev_predicate1D: "P x ==> P <= Q ==> Q x"
   860   by (rule predicate1D)
   861 
   862 lemma rev_predicate2D: "P x y ==> P <= Q ==> Q x y"
   863   by (rule predicate2D)
   864 
   865 
   866 subsection {* Monotonicity, least value operator and min/max *}
   867 
   868 locale mono =
   869   fixes f
   870   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
   871 
   872 lemmas monoI [intro?] = mono.intro
   873   and monoD [dest?] = mono.mono
   874 
   875 lemma LeastI2_order:
   876   "[| P (x::'a::order);
   877       !!y. P y ==> x <= y;
   878       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
   879    ==> Q (Least P)"
   880 apply (unfold Least_def)
   881 apply (rule theI2)
   882   apply (blast intro: order_antisym)+
   883 done
   884 
   885 lemma Least_mono:
   886   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
   887     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
   888     -- {* Courtesy of Stephan Merz *}
   889   apply clarify
   890   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
   891   apply (rule LeastI2_order)
   892   apply (auto elim: monoD intro!: order_antisym)
   893   done
   894 
   895 lemma Least_equality:
   896   "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
   897 apply (simp add: Least_def)
   898 apply (rule the_equality)
   899 apply (auto intro!: order_antisym)
   900 done
   901 
   902 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
   903 by (simp add: min_def)
   904 
   905 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
   906 by (simp add: max_def)
   907 
   908 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
   909 apply (simp add: min_def)
   910 apply (blast intro: order_antisym)
   911 done
   912 
   913 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
   914 apply (simp add: max_def)
   915 apply (blast intro: order_antisym)
   916 done
   917 
   918 lemma min_of_mono:
   919   "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
   920 by (simp add: min_def)
   921 
   922 lemma max_of_mono:
   923   "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
   924 by (simp add: max_def)
   925 
   926 
   927 subsection {* legacy ML bindings *}
   928 
   929 ML {*
   930 val monoI = @{thm monoI};
   931 *}
   932 
   933 end