src/HOL/Divides.thy
author wenzelm
Wed Aug 22 22:55:41 2012 +0200 (2012-08-22)
changeset 48891 c0eafbd55de3
parent 48561 12aa0cb2b447
child 49962 a8cc904a6820
permissions -rw-r--r--
prefer ML_file over old uses;
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Transfer
    10 begin
    11 
    12 ML_file "~~/src/Provers/Arith/cancel_div_mod.ML"
    13 
    14 subsection {* Syntactic division operations *}
    15 
    16 class div = dvd +
    17   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    18     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    19 
    20 
    21 subsection {* Abstract division in commutative semirings. *}
    22 
    23 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    24   assumes mod_div_equality: "a div b * b + a mod b = a"
    25     and div_by_0 [simp]: "a div 0 = 0"
    26     and div_0 [simp]: "0 div a = 0"
    27     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    28     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    29 begin
    30 
    31 text {* @{const div} and @{const mod} *}
    32 
    33 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    34   unfolding mult_commute [of b]
    35   by (rule mod_div_equality)
    36 
    37 lemma mod_div_equality': "a mod b + a div b * b = a"
    38   using mod_div_equality [of a b]
    39   by (simp only: add_ac)
    40 
    41 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    42   by (simp add: mod_div_equality)
    43 
    44 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    45   by (simp add: mod_div_equality2)
    46 
    47 lemma mod_by_0 [simp]: "a mod 0 = a"
    48   using mod_div_equality [of a zero] by simp
    49 
    50 lemma mod_0 [simp]: "0 mod a = 0"
    51   using mod_div_equality [of zero a] div_0 by simp
    52 
    53 lemma div_mult_self2 [simp]:
    54   assumes "b \<noteq> 0"
    55   shows "(a + b * c) div b = c + a div b"
    56   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    57 
    58 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    59 proof (cases "b = 0")
    60   case True then show ?thesis by simp
    61 next
    62   case False
    63   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    64     by (simp add: mod_div_equality)
    65   also from False div_mult_self1 [of b a c] have
    66     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    67       by (simp add: algebra_simps)
    68   finally have "a = a div b * b + (a + c * b) mod b"
    69     by (simp add: add_commute [of a] add_assoc left_distrib)
    70   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    71     by (simp add: mod_div_equality)
    72   then show ?thesis by simp
    73 qed
    74 
    75 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    76   by (simp add: mult_commute [of b])
    77 
    78 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    79   using div_mult_self2 [of b 0 a] by simp
    80 
    81 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    82   using div_mult_self1 [of b 0 a] by simp
    83 
    84 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    85   using mod_mult_self2 [of 0 b a] by simp
    86 
    87 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    88   using mod_mult_self1 [of 0 a b] by simp
    89 
    90 lemma div_by_1 [simp]: "a div 1 = a"
    91   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    92 
    93 lemma mod_by_1 [simp]: "a mod 1 = 0"
    94 proof -
    95   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    96   then have "a + a mod 1 = a + 0" by simp
    97   then show ?thesis by (rule add_left_imp_eq)
    98 qed
    99 
   100 lemma mod_self [simp]: "a mod a = 0"
   101   using mod_mult_self2_is_0 [of 1] by simp
   102 
   103 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   104   using div_mult_self2_is_id [of _ 1] by simp
   105 
   106 lemma div_add_self1 [simp]:
   107   assumes "b \<noteq> 0"
   108   shows "(b + a) div b = a div b + 1"
   109   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   110 
   111 lemma div_add_self2 [simp]:
   112   assumes "b \<noteq> 0"
   113   shows "(a + b) div b = a div b + 1"
   114   using assms div_add_self1 [of b a] by (simp add: add_commute)
   115 
   116 lemma mod_add_self1 [simp]:
   117   "(b + a) mod b = a mod b"
   118   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   119 
   120 lemma mod_add_self2 [simp]:
   121   "(a + b) mod b = a mod b"
   122   using mod_mult_self1 [of a 1 b] by simp
   123 
   124 lemma mod_div_decomp:
   125   fixes a b
   126   obtains q r where "q = a div b" and "r = a mod b"
   127     and "a = q * b + r"
   128 proof -
   129   from mod_div_equality have "a = a div b * b + a mod b" by simp
   130   moreover have "a div b = a div b" ..
   131   moreover have "a mod b = a mod b" ..
   132   note that ultimately show thesis by blast
   133 qed
   134 
   135 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   136 proof
   137   assume "b mod a = 0"
   138   with mod_div_equality [of b a] have "b div a * a = b" by simp
   139   then have "b = a * (b div a)" unfolding mult_commute ..
   140   then have "\<exists>c. b = a * c" ..
   141   then show "a dvd b" unfolding dvd_def .
   142 next
   143   assume "a dvd b"
   144   then have "\<exists>c. b = a * c" unfolding dvd_def .
   145   then obtain c where "b = a * c" ..
   146   then have "b mod a = a * c mod a" by simp
   147   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   148   then show "b mod a = 0" by simp
   149 qed
   150 
   151 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   152 proof (cases "b = 0")
   153   assume "b = 0"
   154   thus ?thesis by simp
   155 next
   156   assume "b \<noteq> 0"
   157   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   158     by (rule div_mult_self1 [symmetric])
   159   also have "\<dots> = a div b"
   160     by (simp only: mod_div_equality')
   161   also have "\<dots> = a div b + 0"
   162     by simp
   163   finally show ?thesis
   164     by (rule add_left_imp_eq)
   165 qed
   166 
   167 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   168 proof -
   169   have "a mod b mod b = (a mod b + a div b * b) mod b"
   170     by (simp only: mod_mult_self1)
   171   also have "\<dots> = a mod b"
   172     by (simp only: mod_div_equality')
   173   finally show ?thesis .
   174 qed
   175 
   176 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   177 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   178 
   179 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   180 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   181 
   182 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   183 by (drule dvd_div_mult_self) (simp add: mult_commute)
   184 
   185 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   186 apply (cases "a = 0")
   187  apply simp
   188 apply (auto simp: dvd_def mult_assoc)
   189 done
   190 
   191 lemma div_dvd_div[simp]:
   192   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   193 apply (cases "a = 0")
   194  apply simp
   195 apply (unfold dvd_def)
   196 apply auto
   197  apply(blast intro:mult_assoc[symmetric])
   198 apply(fastforce simp add: mult_assoc)
   199 done
   200 
   201 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   202   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   203    apply (simp add: mod_div_equality)
   204   apply (simp only: dvd_add dvd_mult)
   205   done
   206 
   207 text {* Addition respects modular equivalence. *}
   208 
   209 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   210 proof -
   211   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   212     by (simp only: mod_div_equality)
   213   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   214     by (simp only: add_ac)
   215   also have "\<dots> = (a mod c + b) mod c"
   216     by (rule mod_mult_self1)
   217   finally show ?thesis .
   218 qed
   219 
   220 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   221 proof -
   222   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   223     by (simp only: mod_div_equality)
   224   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   225     by (simp only: add_ac)
   226   also have "\<dots> = (a + b mod c) mod c"
   227     by (rule mod_mult_self1)
   228   finally show ?thesis .
   229 qed
   230 
   231 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   232 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   233 
   234 lemma mod_add_cong:
   235   assumes "a mod c = a' mod c"
   236   assumes "b mod c = b' mod c"
   237   shows "(a + b) mod c = (a' + b') mod c"
   238 proof -
   239   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   240     unfolding assms ..
   241   thus ?thesis
   242     by (simp only: mod_add_eq [symmetric])
   243 qed
   244 
   245 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   246   \<Longrightarrow> (x + y) div z = x div z + y div z"
   247 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   248 
   249 text {* Multiplication respects modular equivalence. *}
   250 
   251 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   252 proof -
   253   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   254     by (simp only: mod_div_equality)
   255   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   256     by (simp only: algebra_simps)
   257   also have "\<dots> = (a mod c * b) mod c"
   258     by (rule mod_mult_self1)
   259   finally show ?thesis .
   260 qed
   261 
   262 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   263 proof -
   264   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   265     by (simp only: mod_div_equality)
   266   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   267     by (simp only: algebra_simps)
   268   also have "\<dots> = (a * (b mod c)) mod c"
   269     by (rule mod_mult_self1)
   270   finally show ?thesis .
   271 qed
   272 
   273 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   274 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   275 
   276 lemma mod_mult_cong:
   277   assumes "a mod c = a' mod c"
   278   assumes "b mod c = b' mod c"
   279   shows "(a * b) mod c = (a' * b') mod c"
   280 proof -
   281   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   282     unfolding assms ..
   283   thus ?thesis
   284     by (simp only: mod_mult_eq [symmetric])
   285 qed
   286 
   287 text {* Exponentiation respects modular equivalence. *}
   288 
   289 lemma power_mod: "(a mod b)^n mod b = a^n mod b"
   290 apply (induct n, simp_all)
   291 apply (rule mod_mult_right_eq [THEN trans])
   292 apply (simp (no_asm_simp))
   293 apply (rule mod_mult_eq [symmetric])
   294 done
   295 
   296 lemma mod_mod_cancel:
   297   assumes "c dvd b"
   298   shows "a mod b mod c = a mod c"
   299 proof -
   300   from `c dvd b` obtain k where "b = c * k"
   301     by (rule dvdE)
   302   have "a mod b mod c = a mod (c * k) mod c"
   303     by (simp only: `b = c * k`)
   304   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   305     by (simp only: mod_mult_self1)
   306   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   307     by (simp only: add_ac mult_ac)
   308   also have "\<dots> = a mod c"
   309     by (simp only: mod_div_equality)
   310   finally show ?thesis .
   311 qed
   312 
   313 lemma div_mult_div_if_dvd:
   314   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   315   apply (cases "y = 0", simp)
   316   apply (cases "z = 0", simp)
   317   apply (auto elim!: dvdE simp add: algebra_simps)
   318   apply (subst mult_assoc [symmetric])
   319   apply (simp add: no_zero_divisors)
   320   done
   321 
   322 lemma div_mult_swap:
   323   assumes "c dvd b"
   324   shows "a * (b div c) = (a * b) div c"
   325 proof -
   326   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   327     by (simp only: div_mult_div_if_dvd one_dvd)
   328   then show ?thesis by (simp add: mult_commute)
   329 qed
   330    
   331 lemma div_mult_mult2 [simp]:
   332   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   333   by (drule div_mult_mult1) (simp add: mult_commute)
   334 
   335 lemma div_mult_mult1_if [simp]:
   336   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   337   by simp_all
   338 
   339 lemma mod_mult_mult1:
   340   "(c * a) mod (c * b) = c * (a mod b)"
   341 proof (cases "c = 0")
   342   case True then show ?thesis by simp
   343 next
   344   case False
   345   from mod_div_equality
   346   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   347   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   348     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   349   with mod_div_equality show ?thesis by simp 
   350 qed
   351   
   352 lemma mod_mult_mult2:
   353   "(a * c) mod (b * c) = (a mod b) * c"
   354   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   355 
   356 lemma mult_mod_left: "(a mod b) * c = (a * c) mod (b * c)"
   357   by (fact mod_mult_mult2 [symmetric])
   358 
   359 lemma mult_mod_right: "c * (a mod b) = (c * a) mod (c * b)"
   360   by (fact mod_mult_mult1 [symmetric])
   361 
   362 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   363   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   364 
   365 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   366 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   367 
   368 lemma div_power:
   369   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   370 apply (induct n)
   371  apply simp
   372 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   373 done
   374 
   375 lemma dvd_div_eq_mult:
   376   assumes "a \<noteq> 0" and "a dvd b"  
   377   shows "b div a = c \<longleftrightarrow> b = c * a"
   378 proof
   379   assume "b = c * a"
   380   then show "b div a = c" by (simp add: assms)
   381 next
   382   assume "b div a = c"
   383   then have "b div a * a = c * a" by simp
   384   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   385   ultimately show "b = c * a" by simp
   386 qed
   387    
   388 lemma dvd_div_div_eq_mult:
   389   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   390   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   391   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   392 
   393 end
   394 
   395 class ring_div = semiring_div + comm_ring_1
   396 begin
   397 
   398 subclass ring_1_no_zero_divisors ..
   399 
   400 text {* Negation respects modular equivalence. *}
   401 
   402 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   403 proof -
   404   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   405     by (simp only: mod_div_equality)
   406   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   407     by (simp only: minus_add_distrib minus_mult_left add_ac)
   408   also have "\<dots> = (- (a mod b)) mod b"
   409     by (rule mod_mult_self1)
   410   finally show ?thesis .
   411 qed
   412 
   413 lemma mod_minus_cong:
   414   assumes "a mod b = a' mod b"
   415   shows "(- a) mod b = (- a') mod b"
   416 proof -
   417   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   418     unfolding assms ..
   419   thus ?thesis
   420     by (simp only: mod_minus_eq [symmetric])
   421 qed
   422 
   423 text {* Subtraction respects modular equivalence. *}
   424 
   425 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   426   unfolding diff_minus
   427   by (intro mod_add_cong mod_minus_cong) simp_all
   428 
   429 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   430   unfolding diff_minus
   431   by (intro mod_add_cong mod_minus_cong) simp_all
   432 
   433 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   434   unfolding diff_minus
   435   by (intro mod_add_cong mod_minus_cong) simp_all
   436 
   437 lemma mod_diff_cong:
   438   assumes "a mod c = a' mod c"
   439   assumes "b mod c = b' mod c"
   440   shows "(a - b) mod c = (a' - b') mod c"
   441   unfolding diff_minus using assms
   442   by (intro mod_add_cong mod_minus_cong)
   443 
   444 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   445 apply (case_tac "y = 0") apply simp
   446 apply (auto simp add: dvd_def)
   447 apply (subgoal_tac "-(y * k) = y * - k")
   448  apply (erule ssubst)
   449  apply (erule div_mult_self1_is_id)
   450 apply simp
   451 done
   452 
   453 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   454 apply (case_tac "y = 0") apply simp
   455 apply (auto simp add: dvd_def)
   456 apply (subgoal_tac "y * k = -y * -k")
   457  apply (erule ssubst)
   458  apply (rule div_mult_self1_is_id)
   459  apply simp
   460 apply simp
   461 done
   462 
   463 lemma div_minus_minus [simp]: "(-a) div (-b) = a div b"
   464   using div_mult_mult1 [of "- 1" a b]
   465   unfolding neg_equal_0_iff_equal by simp
   466 
   467 lemma mod_minus_minus [simp]: "(-a) mod (-b) = - (a mod b)"
   468   using mod_mult_mult1 [of "- 1" a b] by simp
   469 
   470 lemma div_minus_right: "a div (-b) = (-a) div b"
   471   using div_minus_minus [of "-a" b] by simp
   472 
   473 lemma mod_minus_right: "a mod (-b) = - ((-a) mod b)"
   474   using mod_minus_minus [of "-a" b] by simp
   475 
   476 lemma div_minus1_right [simp]: "a div (-1) = -a"
   477   using div_minus_right [of a 1] by simp
   478 
   479 lemma mod_minus1_right [simp]: "a mod (-1) = 0"
   480   using mod_minus_right [of a 1] by simp
   481 
   482 end
   483 
   484 
   485 subsection {* Division on @{typ nat} *}
   486 
   487 text {*
   488   We define @{const div} and @{const mod} on @{typ nat} by means
   489   of a characteristic relation with two input arguments
   490   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   491   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   492 *}
   493 
   494 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   495   "divmod_nat_rel m n qr \<longleftrightarrow>
   496     m = fst qr * n + snd qr \<and>
   497       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   498 
   499 text {* @{const divmod_nat_rel} is total: *}
   500 
   501 lemma divmod_nat_rel_ex:
   502   obtains q r where "divmod_nat_rel m n (q, r)"
   503 proof (cases "n = 0")
   504   case True  with that show thesis
   505     by (auto simp add: divmod_nat_rel_def)
   506 next
   507   case False
   508   have "\<exists>q r. m = q * n + r \<and> r < n"
   509   proof (induct m)
   510     case 0 with `n \<noteq> 0`
   511     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   512     then show ?case by blast
   513   next
   514     case (Suc m) then obtain q' r'
   515       where m: "m = q' * n + r'" and n: "r' < n" by auto
   516     then show ?case proof (cases "Suc r' < n")
   517       case True
   518       from m n have "Suc m = q' * n + Suc r'" by simp
   519       with True show ?thesis by blast
   520     next
   521       case False then have "n \<le> Suc r'" by auto
   522       moreover from n have "Suc r' \<le> n" by auto
   523       ultimately have "n = Suc r'" by auto
   524       with m have "Suc m = Suc q' * n + 0" by simp
   525       with `n \<noteq> 0` show ?thesis by blast
   526     qed
   527   qed
   528   with that show thesis
   529     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   530 qed
   531 
   532 text {* @{const divmod_nat_rel} is injective: *}
   533 
   534 lemma divmod_nat_rel_unique:
   535   assumes "divmod_nat_rel m n qr"
   536     and "divmod_nat_rel m n qr'"
   537   shows "qr = qr'"
   538 proof (cases "n = 0")
   539   case True with assms show ?thesis
   540     by (cases qr, cases qr')
   541       (simp add: divmod_nat_rel_def)
   542 next
   543   case False
   544   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   545   apply (rule leI)
   546   apply (subst less_iff_Suc_add)
   547   apply (auto simp add: add_mult_distrib)
   548   done
   549   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   550     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   551   moreover from this assms have "snd qr = snd qr'"
   552     by (simp add: divmod_nat_rel_def)
   553   ultimately show ?thesis by (cases qr, cases qr') simp
   554 qed
   555 
   556 text {*
   557   We instantiate divisibility on the natural numbers by
   558   means of @{const divmod_nat_rel}:
   559 *}
   560 
   561 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   562   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   563 
   564 lemma divmod_nat_rel_divmod_nat:
   565   "divmod_nat_rel m n (divmod_nat m n)"
   566 proof -
   567   from divmod_nat_rel_ex
   568     obtain qr where rel: "divmod_nat_rel m n qr" .
   569   then show ?thesis
   570   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   571 qed
   572 
   573 lemma divmod_nat_unique:
   574   assumes "divmod_nat_rel m n qr" 
   575   shows "divmod_nat m n = qr"
   576   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   577 
   578 instantiation nat :: semiring_div
   579 begin
   580 
   581 definition div_nat where
   582   "m div n = fst (divmod_nat m n)"
   583 
   584 lemma fst_divmod_nat [simp]:
   585   "fst (divmod_nat m n) = m div n"
   586   by (simp add: div_nat_def)
   587 
   588 definition mod_nat where
   589   "m mod n = snd (divmod_nat m n)"
   590 
   591 lemma snd_divmod_nat [simp]:
   592   "snd (divmod_nat m n) = m mod n"
   593   by (simp add: mod_nat_def)
   594 
   595 lemma divmod_nat_div_mod:
   596   "divmod_nat m n = (m div n, m mod n)"
   597   by (simp add: prod_eq_iff)
   598 
   599 lemma div_nat_unique:
   600   assumes "divmod_nat_rel m n (q, r)" 
   601   shows "m div n = q"
   602   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   603 
   604 lemma mod_nat_unique:
   605   assumes "divmod_nat_rel m n (q, r)" 
   606   shows "m mod n = r"
   607   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   608 
   609 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   610   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   611 
   612 lemma divmod_nat_zero: "divmod_nat m 0 = (0, m)"
   613   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   614 
   615 lemma divmod_nat_zero_left: "divmod_nat 0 n = (0, 0)"
   616   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   617 
   618 lemma divmod_nat_base: "m < n \<Longrightarrow> divmod_nat m n = (0, m)"
   619   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   620 
   621 lemma divmod_nat_step:
   622   assumes "0 < n" and "n \<le> m"
   623   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   624 proof (rule divmod_nat_unique)
   625   have "divmod_nat_rel (m - n) n ((m - n) div n, (m - n) mod n)"
   626     by (rule divmod_nat_rel)
   627   thus "divmod_nat_rel m n (Suc ((m - n) div n), (m - n) mod n)"
   628     unfolding divmod_nat_rel_def using assms by auto
   629 qed
   630 
   631 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   632 
   633 lemma div_less [simp]:
   634   fixes m n :: nat
   635   assumes "m < n"
   636   shows "m div n = 0"
   637   using assms divmod_nat_base by (simp add: prod_eq_iff)
   638 
   639 lemma le_div_geq:
   640   fixes m n :: nat
   641   assumes "0 < n" and "n \<le> m"
   642   shows "m div n = Suc ((m - n) div n)"
   643   using assms divmod_nat_step by (simp add: prod_eq_iff)
   644 
   645 lemma mod_less [simp]:
   646   fixes m n :: nat
   647   assumes "m < n"
   648   shows "m mod n = m"
   649   using assms divmod_nat_base by (simp add: prod_eq_iff)
   650 
   651 lemma le_mod_geq:
   652   fixes m n :: nat
   653   assumes "n \<le> m"
   654   shows "m mod n = (m - n) mod n"
   655   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   656 
   657 instance proof
   658   fix m n :: nat
   659   show "m div n * n + m mod n = m"
   660     using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   661 next
   662   fix m n q :: nat
   663   assume "n \<noteq> 0"
   664   then show "(q + m * n) div n = m + q div n"
   665     by (induct m) (simp_all add: le_div_geq)
   666 next
   667   fix m n q :: nat
   668   assume "m \<noteq> 0"
   669   hence "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   670     unfolding divmod_nat_rel_def
   671     by (auto split: split_if_asm, simp_all add: algebra_simps)
   672   moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   673   ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   674   thus "(m * n) div (m * q) = n div q" by (rule div_nat_unique)
   675 next
   676   fix n :: nat show "n div 0 = 0"
   677     by (simp add: div_nat_def divmod_nat_zero)
   678 next
   679   fix n :: nat show "0 div n = 0"
   680     by (simp add: div_nat_def divmod_nat_zero_left)
   681 qed
   682 
   683 end
   684 
   685 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   686   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   687   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   688 
   689 text {* Simproc for cancelling @{const div} and @{const mod} *}
   690 
   691 ML {*
   692 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   693 (
   694   val div_name = @{const_name div};
   695   val mod_name = @{const_name mod};
   696   val mk_binop = HOLogic.mk_binop;
   697   val mk_plus = HOLogic.mk_binop @{const_name Groups.plus};
   698   val dest_plus = HOLogic.dest_bin @{const_name Groups.plus} HOLogic.natT;
   699   fun mk_sum [] = HOLogic.zero
   700     | mk_sum [t] = t
   701     | mk_sum (t :: ts) = mk_plus (t, mk_sum ts);
   702   fun dest_sum tm =
   703     if HOLogic.is_zero tm then []
   704     else
   705       (case try HOLogic.dest_Suc tm of
   706         SOME t => HOLogic.Suc_zero :: dest_sum t
   707       | NONE =>
   708           (case try dest_plus tm of
   709             SOME (t, u) => dest_sum t @ dest_sum u
   710           | NONE => [tm]));
   711 
   712   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   713 
   714   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   715     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   716 )
   717 *}
   718 
   719 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   720 
   721 
   722 subsubsection {* Quotient *}
   723 
   724 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   725 by (simp add: le_div_geq linorder_not_less)
   726 
   727 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   728 by (simp add: div_geq)
   729 
   730 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   731 by simp
   732 
   733 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   734 by simp
   735 
   736 
   737 subsubsection {* Remainder *}
   738 
   739 lemma mod_less_divisor [simp]:
   740   fixes m n :: nat
   741   assumes "n > 0"
   742   shows "m mod n < (n::nat)"
   743   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   744 
   745 lemma mod_less_eq_dividend [simp]:
   746   fixes m n :: nat
   747   shows "m mod n \<le> m"
   748 proof (rule add_leD2)
   749   from mod_div_equality have "m div n * n + m mod n = m" .
   750   then show "m div n * n + m mod n \<le> m" by auto
   751 qed
   752 
   753 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   754 by (simp add: le_mod_geq linorder_not_less)
   755 
   756 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   757 by (simp add: le_mod_geq)
   758 
   759 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   760 by (induct m) (simp_all add: mod_geq)
   761 
   762 (* a simple rearrangement of mod_div_equality: *)
   763 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   764   using mod_div_equality2 [of n m] by arith
   765 
   766 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   767   apply (drule mod_less_divisor [where m = m])
   768   apply simp
   769   done
   770 
   771 subsubsection {* Quotient and Remainder *}
   772 
   773 lemma divmod_nat_rel_mult1_eq:
   774   "divmod_nat_rel b c (q, r)
   775    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   776 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   777 
   778 lemma div_mult1_eq:
   779   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   780 by (blast intro: divmod_nat_rel_mult1_eq [THEN div_nat_unique] divmod_nat_rel)
   781 
   782 lemma divmod_nat_rel_add1_eq:
   783   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   784    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   785 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   786 
   787 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   788 lemma div_add1_eq:
   789   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   790 by (blast intro: divmod_nat_rel_add1_eq [THEN div_nat_unique] divmod_nat_rel)
   791 
   792 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   793   apply (cut_tac m = q and n = c in mod_less_divisor)
   794   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   795   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   796   apply (simp add: add_mult_distrib2)
   797   done
   798 
   799 lemma divmod_nat_rel_mult2_eq:
   800   "divmod_nat_rel a b (q, r)
   801    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   802 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   803 
   804 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   805 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_nat_unique])
   806 
   807 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   808 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_nat_unique])
   809 
   810 
   811 subsubsection {* Further Facts about Quotient and Remainder *}
   812 
   813 lemma div_1 [simp]: "m div Suc 0 = m"
   814 by (induct m) (simp_all add: div_geq)
   815 
   816 (* Monotonicity of div in first argument *)
   817 lemma div_le_mono [rule_format (no_asm)]:
   818     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   819 apply (case_tac "k=0", simp)
   820 apply (induct "n" rule: nat_less_induct, clarify)
   821 apply (case_tac "n<k")
   822 (* 1  case n<k *)
   823 apply simp
   824 (* 2  case n >= k *)
   825 apply (case_tac "m<k")
   826 (* 2.1  case m<k *)
   827 apply simp
   828 (* 2.2  case m>=k *)
   829 apply (simp add: div_geq diff_le_mono)
   830 done
   831 
   832 (* Antimonotonicity of div in second argument *)
   833 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   834 apply (subgoal_tac "0<n")
   835  prefer 2 apply simp
   836 apply (induct_tac k rule: nat_less_induct)
   837 apply (rename_tac "k")
   838 apply (case_tac "k<n", simp)
   839 apply (subgoal_tac "~ (k<m) ")
   840  prefer 2 apply simp
   841 apply (simp add: div_geq)
   842 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   843  prefer 2
   844  apply (blast intro: div_le_mono diff_le_mono2)
   845 apply (rule le_trans, simp)
   846 apply (simp)
   847 done
   848 
   849 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   850 apply (case_tac "n=0", simp)
   851 apply (subgoal_tac "m div n \<le> m div 1", simp)
   852 apply (rule div_le_mono2)
   853 apply (simp_all (no_asm_simp))
   854 done
   855 
   856 (* Similar for "less than" *)
   857 lemma div_less_dividend [simp]:
   858   "\<lbrakk>(1::nat) < n; 0 < m\<rbrakk> \<Longrightarrow> m div n < m"
   859 apply (induct m rule: nat_less_induct)
   860 apply (rename_tac "m")
   861 apply (case_tac "m<n", simp)
   862 apply (subgoal_tac "0<n")
   863  prefer 2 apply simp
   864 apply (simp add: div_geq)
   865 apply (case_tac "n<m")
   866  apply (subgoal_tac "(m-n) div n < (m-n) ")
   867   apply (rule impI less_trans_Suc)+
   868 apply assumption
   869   apply (simp_all)
   870 done
   871 
   872 text{*A fact for the mutilated chess board*}
   873 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   874 apply (case_tac "n=0", simp)
   875 apply (induct "m" rule: nat_less_induct)
   876 apply (case_tac "Suc (na) <n")
   877 (* case Suc(na) < n *)
   878 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   879 (* case n \<le> Suc(na) *)
   880 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   881 apply (auto simp add: Suc_diff_le le_mod_geq)
   882 done
   883 
   884 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   885 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   886 
   887 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   888 
   889 (*Loses information, namely we also have r<d provided d is nonzero*)
   890 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   891   apply (cut_tac a = m in mod_div_equality)
   892   apply (simp only: add_ac)
   893   apply (blast intro: sym)
   894   done
   895 
   896 lemma split_div:
   897  "P(n div k :: nat) =
   898  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   899  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   900 proof
   901   assume P: ?P
   902   show ?Q
   903   proof (cases)
   904     assume "k = 0"
   905     with P show ?Q by simp
   906   next
   907     assume not0: "k \<noteq> 0"
   908     thus ?Q
   909     proof (simp, intro allI impI)
   910       fix i j
   911       assume n: "n = k*i + j" and j: "j < k"
   912       show "P i"
   913       proof (cases)
   914         assume "i = 0"
   915         with n j P show "P i" by simp
   916       next
   917         assume "i \<noteq> 0"
   918         with not0 n j P show "P i" by(simp add:add_ac)
   919       qed
   920     qed
   921   qed
   922 next
   923   assume Q: ?Q
   924   show ?P
   925   proof (cases)
   926     assume "k = 0"
   927     with Q show ?P by simp
   928   next
   929     assume not0: "k \<noteq> 0"
   930     with Q have R: ?R by simp
   931     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   932     show ?P by simp
   933   qed
   934 qed
   935 
   936 lemma split_div_lemma:
   937   assumes "0 < n"
   938   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   939 proof
   940   assume ?rhs
   941   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   942   then have A: "n * q \<le> m" by simp
   943   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   944   then have "m < m + (n - (m mod n))" by simp
   945   then have "m < n + (m - (m mod n))" by simp
   946   with nq have "m < n + n * q" by simp
   947   then have B: "m < n * Suc q" by simp
   948   from A B show ?lhs ..
   949 next
   950   assume P: ?lhs
   951   then have "divmod_nat_rel m n (q, m - n * q)"
   952     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   953   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   954   have "(q, m - n * q) = (m div n, m mod n)" by auto
   955   then show ?rhs by simp
   956 qed
   957 
   958 theorem split_div':
   959   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   960    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   961   apply (case_tac "0 < n")
   962   apply (simp only: add: split_div_lemma)
   963   apply simp_all
   964   done
   965 
   966 lemma split_mod:
   967  "P(n mod k :: nat) =
   968  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   969  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   970 proof
   971   assume P: ?P
   972   show ?Q
   973   proof (cases)
   974     assume "k = 0"
   975     with P show ?Q by simp
   976   next
   977     assume not0: "k \<noteq> 0"
   978     thus ?Q
   979     proof (simp, intro allI impI)
   980       fix i j
   981       assume "n = k*i + j" "j < k"
   982       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   983     qed
   984   qed
   985 next
   986   assume Q: ?Q
   987   show ?P
   988   proof (cases)
   989     assume "k = 0"
   990     with Q show ?P by simp
   991   next
   992     assume not0: "k \<noteq> 0"
   993     with Q have R: ?R by simp
   994     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   995     show ?P by simp
   996   qed
   997 qed
   998 
   999 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
  1000   using mod_div_equality [of m n] by arith
  1001 
  1002 lemma div_mod_equality': "(m::nat) div n * n = m - m mod n"
  1003   using mod_div_equality [of m n] by arith
  1004 (* FIXME: very similar to mult_div_cancel *)
  1005 
  1006 
  1007 subsubsection {* An ``induction'' law for modulus arithmetic. *}
  1008 
  1009 lemma mod_induct_0:
  1010   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1011   and base: "P i" and i: "i<p"
  1012   shows "P 0"
  1013 proof (rule ccontr)
  1014   assume contra: "\<not>(P 0)"
  1015   from i have p: "0<p" by simp
  1016   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1017   proof
  1018     fix k
  1019     show "?A k"
  1020     proof (induct k)
  1021       show "?A 0" by simp  -- "by contradiction"
  1022     next
  1023       fix n
  1024       assume ih: "?A n"
  1025       show "?A (Suc n)"
  1026       proof (clarsimp)
  1027         assume y: "P (p - Suc n)"
  1028         have n: "Suc n < p"
  1029         proof (rule ccontr)
  1030           assume "\<not>(Suc n < p)"
  1031           hence "p - Suc n = 0"
  1032             by simp
  1033           with y contra show "False"
  1034             by simp
  1035         qed
  1036         hence n2: "Suc (p - Suc n) = p-n" by arith
  1037         from p have "p - Suc n < p" by arith
  1038         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1039           by blast
  1040         show "False"
  1041         proof (cases "n=0")
  1042           case True
  1043           with z n2 contra show ?thesis by simp
  1044         next
  1045           case False
  1046           with p have "p-n < p" by arith
  1047           with z n2 False ih show ?thesis by simp
  1048         qed
  1049       qed
  1050     qed
  1051   qed
  1052   moreover
  1053   from i obtain k where "0<k \<and> i+k=p"
  1054     by (blast dest: less_imp_add_positive)
  1055   hence "0<k \<and> i=p-k" by auto
  1056   moreover
  1057   note base
  1058   ultimately
  1059   show "False" by blast
  1060 qed
  1061 
  1062 lemma mod_induct:
  1063   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1064   and base: "P i" and i: "i<p" and j: "j<p"
  1065   shows "P j"
  1066 proof -
  1067   have "\<forall>j<p. P j"
  1068   proof
  1069     fix j
  1070     show "j<p \<longrightarrow> P j" (is "?A j")
  1071     proof (induct j)
  1072       from step base i show "?A 0"
  1073         by (auto elim: mod_induct_0)
  1074     next
  1075       fix k
  1076       assume ih: "?A k"
  1077       show "?A (Suc k)"
  1078       proof
  1079         assume suc: "Suc k < p"
  1080         hence k: "k<p" by simp
  1081         with ih have "P k" ..
  1082         with step k have "P (Suc k mod p)"
  1083           by blast
  1084         moreover
  1085         from suc have "Suc k mod p = Suc k"
  1086           by simp
  1087         ultimately
  1088         show "P (Suc k)" by simp
  1089       qed
  1090     qed
  1091   qed
  1092   with j show ?thesis by blast
  1093 qed
  1094 
  1095 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1096   by (simp add: numeral_2_eq_2 le_div_geq)
  1097 
  1098 lemma mod2_Suc_Suc [simp]: "Suc (Suc m) mod 2 = m mod 2"
  1099   by (simp add: numeral_2_eq_2 le_mod_geq)
  1100 
  1101 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1102 by (simp add: mult_2 [symmetric])
  1103 
  1104 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1105 proof -
  1106   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1107   moreover have "m mod 2 < 2" by simp
  1108   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1109   then show ?thesis by auto
  1110 qed
  1111 
  1112 text{*These lemmas collapse some needless occurrences of Suc:
  1113     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1114     We already have some rules to simplify operands smaller than 3.*}
  1115 
  1116 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1117 by (simp add: Suc3_eq_add_3)
  1118 
  1119 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1120 by (simp add: Suc3_eq_add_3)
  1121 
  1122 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1123 by (simp add: Suc3_eq_add_3)
  1124 
  1125 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1126 by (simp add: Suc3_eq_add_3)
  1127 
  1128 lemmas Suc_div_eq_add3_div_numeral [simp] = Suc_div_eq_add3_div [of _ "numeral v"] for v
  1129 lemmas Suc_mod_eq_add3_mod_numeral [simp] = Suc_mod_eq_add3_mod [of _ "numeral v"] for v
  1130 
  1131 
  1132 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1133 apply (induct "m")
  1134 apply (simp_all add: mod_Suc)
  1135 done
  1136 
  1137 declare Suc_times_mod_eq [of "numeral w", simp] for w
  1138 
  1139 lemma Suc_div_le_mono [simp]: "n div k \<le> (Suc n) div k"
  1140 by (simp add: div_le_mono)
  1141 
  1142 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1143 by (cases n) simp_all
  1144 
  1145 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1146 proof -
  1147   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1148   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1149 qed
  1150 
  1151   (* Potential use of algebra : Equality modulo n*)
  1152 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1153 by (simp add: mult_ac add_ac)
  1154 
  1155 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1156 proof -
  1157   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1158   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1159   finally show ?thesis .
  1160 qed
  1161 
  1162 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1163 apply (subst mod_Suc [of m]) 
  1164 apply (subst mod_Suc [of "m mod n"], simp) 
  1165 done
  1166 
  1167 lemma mod_2_not_eq_zero_eq_one_nat:
  1168   fixes n :: nat
  1169   shows "n mod 2 \<noteq> 0 \<longleftrightarrow> n mod 2 = 1"
  1170   by simp
  1171 
  1172 
  1173 subsection {* Division on @{typ int} *}
  1174 
  1175 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1176     --{*definition of quotient and remainder*}
  1177   "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1178     (if 0 < b then 0 \<le> r \<and> r < b else if b < 0 then b < r \<and> r \<le> 0 else q = 0))"
  1179 
  1180 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1181     --{*for the division algorithm*}
  1182     "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1183                          else (2 * q, r))"
  1184 
  1185 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1186 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1187   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1188      else adjust b (posDivAlg a (2 * b)))"
  1189 by auto
  1190 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1191   (auto simp add: mult_2)
  1192 
  1193 text{*algorithm for the case @{text "a<0, b>0"}*}
  1194 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1195   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1196      else adjust b (negDivAlg a (2 * b)))"
  1197 by auto
  1198 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1199   (auto simp add: mult_2)
  1200 
  1201 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1202 
  1203 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1204     --{*The full division algorithm considers all possible signs for a, b
  1205        including the special case @{text "a=0, b<0"} because 
  1206        @{term negDivAlg} requires @{term "a<0"}.*}
  1207   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1208                   else if a = 0 then (0, 0)
  1209                        else apsnd uminus (negDivAlg (-a) (-b))
  1210                else 
  1211                   if 0 < b then negDivAlg a b
  1212                   else apsnd uminus (posDivAlg (-a) (-b)))"
  1213 
  1214 instantiation int :: Divides.div
  1215 begin
  1216 
  1217 definition div_int where
  1218   "a div b = fst (divmod_int a b)"
  1219 
  1220 lemma fst_divmod_int [simp]:
  1221   "fst (divmod_int a b) = a div b"
  1222   by (simp add: div_int_def)
  1223 
  1224 definition mod_int where
  1225   "a mod b = snd (divmod_int a b)"
  1226 
  1227 lemma snd_divmod_int [simp]:
  1228   "snd (divmod_int a b) = a mod b"
  1229   by (simp add: mod_int_def)
  1230 
  1231 instance ..
  1232 
  1233 end
  1234 
  1235 lemma divmod_int_mod_div:
  1236   "divmod_int p q = (p div q, p mod q)"
  1237   by (simp add: prod_eq_iff)
  1238 
  1239 text{*
  1240 Here is the division algorithm in ML:
  1241 
  1242 \begin{verbatim}
  1243     fun posDivAlg (a,b) =
  1244       if a<b then (0,a)
  1245       else let val (q,r) = posDivAlg(a, 2*b)
  1246                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1247            end
  1248 
  1249     fun negDivAlg (a,b) =
  1250       if 0\<le>a+b then (~1,a+b)
  1251       else let val (q,r) = negDivAlg(a, 2*b)
  1252                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1253            end;
  1254 
  1255     fun negateSnd (q,r:int) = (q,~r);
  1256 
  1257     fun divmod (a,b) = if 0\<le>a then 
  1258                           if b>0 then posDivAlg (a,b) 
  1259                            else if a=0 then (0,0)
  1260                                 else negateSnd (negDivAlg (~a,~b))
  1261                        else 
  1262                           if 0<b then negDivAlg (a,b)
  1263                           else        negateSnd (posDivAlg (~a,~b));
  1264 \end{verbatim}
  1265 *}
  1266 
  1267 
  1268 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1269 
  1270 lemma unique_quotient_lemma:
  1271      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1272       ==> q' \<le> (q::int)"
  1273 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1274  prefer 2 apply (simp add: right_diff_distrib)
  1275 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1276 apply (erule_tac [2] order_le_less_trans)
  1277  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1278 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1279  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1280 apply (simp add: mult_less_cancel_left)
  1281 done
  1282 
  1283 lemma unique_quotient_lemma_neg:
  1284      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1285       ==> q \<le> (q'::int)"
  1286 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1287     auto)
  1288 
  1289 lemma unique_quotient:
  1290      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1291       ==> q = q'"
  1292 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1293 apply (blast intro: order_antisym
  1294              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1295              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1296 done
  1297 
  1298 
  1299 lemma unique_remainder:
  1300      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1301       ==> r = r'"
  1302 apply (subgoal_tac "q = q'")
  1303  apply (simp add: divmod_int_rel_def)
  1304 apply (blast intro: unique_quotient)
  1305 done
  1306 
  1307 
  1308 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1309 
  1310 text{*And positive divisors*}
  1311 
  1312 lemma adjust_eq [simp]:
  1313      "adjust b (q, r) = 
  1314       (let diff = r - b in  
  1315         if 0 \<le> diff then (2 * q + 1, diff)   
  1316                      else (2*q, r))"
  1317   by (simp add: Let_def adjust_def)
  1318 
  1319 declare posDivAlg.simps [simp del]
  1320 
  1321 text{*use with a simproc to avoid repeatedly proving the premise*}
  1322 lemma posDivAlg_eqn:
  1323      "0 < b ==>  
  1324       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1325 by (rule posDivAlg.simps [THEN trans], simp)
  1326 
  1327 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1328 theorem posDivAlg_correct:
  1329   assumes "0 \<le> a" and "0 < b"
  1330   shows "divmod_int_rel a b (posDivAlg a b)"
  1331   using assms
  1332   apply (induct a b rule: posDivAlg.induct)
  1333   apply auto
  1334   apply (simp add: divmod_int_rel_def)
  1335   apply (subst posDivAlg_eqn, simp add: right_distrib)
  1336   apply (case_tac "a < b")
  1337   apply simp_all
  1338   apply (erule splitE)
  1339   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1340   done
  1341 
  1342 
  1343 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1344 
  1345 text{*And positive divisors*}
  1346 
  1347 declare negDivAlg.simps [simp del]
  1348 
  1349 text{*use with a simproc to avoid repeatedly proving the premise*}
  1350 lemma negDivAlg_eqn:
  1351      "0 < b ==>  
  1352       negDivAlg a b =       
  1353        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1354 by (rule negDivAlg.simps [THEN trans], simp)
  1355 
  1356 (*Correctness of negDivAlg: it computes quotients correctly
  1357   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1358 lemma negDivAlg_correct:
  1359   assumes "a < 0" and "b > 0"
  1360   shows "divmod_int_rel a b (negDivAlg a b)"
  1361   using assms
  1362   apply (induct a b rule: negDivAlg.induct)
  1363   apply (auto simp add: linorder_not_le)
  1364   apply (simp add: divmod_int_rel_def)
  1365   apply (subst negDivAlg_eqn, assumption)
  1366   apply (case_tac "a + b < (0\<Colon>int)")
  1367   apply simp_all
  1368   apply (erule splitE)
  1369   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1370   done
  1371 
  1372 
  1373 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1374 
  1375 (*the case a=0*)
  1376 lemma divmod_int_rel_0: "divmod_int_rel 0 b (0, 0)"
  1377 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1378 
  1379 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1380 by (subst posDivAlg.simps, auto)
  1381 
  1382 lemma posDivAlg_0_right [simp]: "posDivAlg a 0 = (0, a)"
  1383 by (subst posDivAlg.simps, auto)
  1384 
  1385 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1386 by (subst negDivAlg.simps, auto)
  1387 
  1388 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (apsnd uminus qr)"
  1389 by (auto simp add: divmod_int_rel_def)
  1390 
  1391 lemma divmod_int_correct: "divmod_int_rel a b (divmod_int a b)"
  1392 apply (cases "b = 0", simp add: divmod_int_def divmod_int_rel_def)
  1393 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1394                     posDivAlg_correct negDivAlg_correct)
  1395 
  1396 lemma divmod_int_unique:
  1397   assumes "divmod_int_rel a b qr" 
  1398   shows "divmod_int a b = qr"
  1399   using assms divmod_int_correct [of a b]
  1400   using unique_quotient [of a b] unique_remainder [of a b]
  1401   by (metis pair_collapse)
  1402 
  1403 lemma divmod_int_rel_div_mod: "divmod_int_rel a b (a div b, a mod b)"
  1404   using divmod_int_correct by (simp add: divmod_int_mod_div)
  1405 
  1406 lemma div_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a div b = q"
  1407   by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1408 
  1409 lemma mod_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a mod b = r"
  1410   by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1411 
  1412 instance int :: ring_div
  1413 proof
  1414   fix a b :: int
  1415   show "a div b * b + a mod b = a"
  1416     using divmod_int_rel_div_mod [of a b]
  1417     unfolding divmod_int_rel_def by (simp add: mult_commute)
  1418 next
  1419   fix a b c :: int
  1420   assume "b \<noteq> 0"
  1421   hence "divmod_int_rel (a + c * b) b (c + a div b, a mod b)"
  1422     using divmod_int_rel_div_mod [of a b]
  1423     unfolding divmod_int_rel_def by (auto simp: algebra_simps)
  1424   thus "(a + c * b) div b = c + a div b"
  1425     by (rule div_int_unique)
  1426 next
  1427   fix a b c :: int
  1428   assume "c \<noteq> 0"
  1429   hence "\<And>q r. divmod_int_rel a b (q, r)
  1430     \<Longrightarrow> divmod_int_rel (c * a) (c * b) (q, c * r)"
  1431     unfolding divmod_int_rel_def
  1432     by - (rule linorder_cases [of 0 b], auto simp: algebra_simps
  1433       mult_less_0_iff zero_less_mult_iff mult_strict_right_mono
  1434       mult_strict_right_mono_neg zero_le_mult_iff mult_le_0_iff)
  1435   hence "divmod_int_rel (c * a) (c * b) (a div b, c * (a mod b))"
  1436     using divmod_int_rel_div_mod [of a b] .
  1437   thus "(c * a) div (c * b) = a div b"
  1438     by (rule div_int_unique)
  1439 next
  1440   fix a :: int show "a div 0 = 0"
  1441     by (rule div_int_unique, simp add: divmod_int_rel_def)
  1442 next
  1443   fix a :: int show "0 div a = 0"
  1444     by (rule div_int_unique, auto simp add: divmod_int_rel_def)
  1445 qed
  1446 
  1447 text{*Basic laws about division and remainder*}
  1448 
  1449 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1450   by (fact mod_div_equality2 [symmetric])
  1451 
  1452 text {* Tool setup *}
  1453 
  1454 (* FIXME: Theorem list add_0s doesn't exist, because Numeral0 has gone. *)
  1455 lemmas add_0s = add_0_left add_0_right
  1456 
  1457 ML {*
  1458 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1459 (
  1460   val div_name = @{const_name div};
  1461   val mod_name = @{const_name mod};
  1462   val mk_binop = HOLogic.mk_binop;
  1463   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1464   val dest_sum = Arith_Data.dest_sum;
  1465 
  1466   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
  1467 
  1468   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1469     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1470 )
  1471 *}
  1472 
  1473 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1474 
  1475 lemma pos_mod_conj: "(0::int) < b \<Longrightarrow> 0 \<le> a mod b \<and> a mod b < b"
  1476   using divmod_int_correct [of a b]
  1477   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1478 
  1479 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1480    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1481 
  1482 lemma neg_mod_conj: "b < (0::int) \<Longrightarrow> a mod b \<le> 0 \<and> b < a mod b"
  1483   using divmod_int_correct [of a b]
  1484   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1485 
  1486 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1487    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1488 
  1489 
  1490 subsubsection {* General Properties of div and mod *}
  1491 
  1492 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1493 apply (rule div_int_unique)
  1494 apply (auto simp add: divmod_int_rel_def)
  1495 done
  1496 
  1497 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1498 apply (rule div_int_unique)
  1499 apply (auto simp add: divmod_int_rel_def)
  1500 done
  1501 
  1502 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1503 apply (rule div_int_unique)
  1504 apply (auto simp add: divmod_int_rel_def)
  1505 done
  1506 
  1507 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1508 
  1509 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1510 apply (rule_tac q = 0 in mod_int_unique)
  1511 apply (auto simp add: divmod_int_rel_def)
  1512 done
  1513 
  1514 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1515 apply (rule_tac q = 0 in mod_int_unique)
  1516 apply (auto simp add: divmod_int_rel_def)
  1517 done
  1518 
  1519 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1520 apply (rule_tac q = "-1" in mod_int_unique)
  1521 apply (auto simp add: divmod_int_rel_def)
  1522 done
  1523 
  1524 text{*There is no @{text mod_neg_pos_trivial}.*}
  1525 
  1526 
  1527 subsubsection {* Laws for div and mod with Unary Minus *}
  1528 
  1529 lemma zminus1_lemma:
  1530      "divmod_int_rel a b (q, r) ==> b \<noteq> 0
  1531       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1532                           if r=0 then 0 else b-r)"
  1533 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1534 
  1535 
  1536 lemma zdiv_zminus1_eq_if:
  1537      "b \<noteq> (0::int)  
  1538       ==> (-a) div b =  
  1539           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1540 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN div_int_unique])
  1541 
  1542 lemma zmod_zminus1_eq_if:
  1543      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1544 apply (case_tac "b = 0", simp)
  1545 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN mod_int_unique])
  1546 done
  1547 
  1548 lemma zmod_zminus1_not_zero:
  1549   fixes k l :: int
  1550   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1551   unfolding zmod_zminus1_eq_if by auto
  1552 
  1553 lemma zdiv_zminus2_eq_if:
  1554      "b \<noteq> (0::int)  
  1555       ==> a div (-b) =  
  1556           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1557 by (simp add: zdiv_zminus1_eq_if div_minus_right)
  1558 
  1559 lemma zmod_zminus2_eq_if:
  1560      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1561 by (simp add: zmod_zminus1_eq_if mod_minus_right)
  1562 
  1563 lemma zmod_zminus2_not_zero:
  1564   fixes k l :: int
  1565   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1566   unfolding zmod_zminus2_eq_if by auto 
  1567 
  1568 
  1569 subsubsection {* Computation of Division and Remainder *}
  1570 
  1571 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1572 by (simp add: div_int_def divmod_int_def)
  1573 
  1574 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1575 by (simp add: mod_int_def divmod_int_def)
  1576 
  1577 text{*a positive, b positive *}
  1578 
  1579 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1580 by (simp add: div_int_def divmod_int_def)
  1581 
  1582 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1583 by (simp add: mod_int_def divmod_int_def)
  1584 
  1585 text{*a negative, b positive *}
  1586 
  1587 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1588 by (simp add: div_int_def divmod_int_def)
  1589 
  1590 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1591 by (simp add: mod_int_def divmod_int_def)
  1592 
  1593 text{*a positive, b negative *}
  1594 
  1595 lemma div_pos_neg:
  1596      "[| 0 < a;  b < 0 |] ==> a div b = fst (apsnd uminus (negDivAlg (-a) (-b)))"
  1597 by (simp add: div_int_def divmod_int_def)
  1598 
  1599 lemma mod_pos_neg:
  1600      "[| 0 < a;  b < 0 |] ==> a mod b = snd (apsnd uminus (negDivAlg (-a) (-b)))"
  1601 by (simp add: mod_int_def divmod_int_def)
  1602 
  1603 text{*a negative, b negative *}
  1604 
  1605 lemma div_neg_neg:
  1606      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (apsnd uminus (posDivAlg (-a) (-b)))"
  1607 by (simp add: div_int_def divmod_int_def)
  1608 
  1609 lemma mod_neg_neg:
  1610      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (apsnd uminus (posDivAlg (-a) (-b)))"
  1611 by (simp add: mod_int_def divmod_int_def)
  1612 
  1613 text {*Simplify expresions in which div and mod combine numerical constants*}
  1614 
  1615 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1616   by (rule div_int_unique [of a b q r]) (simp add: divmod_int_rel_def)
  1617 
  1618 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1619   by (rule div_int_unique [of a b q r],
  1620     simp add: divmod_int_rel_def)
  1621 
  1622 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1623   by (rule mod_int_unique [of a b q r],
  1624     simp add: divmod_int_rel_def)
  1625 
  1626 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1627   by (rule mod_int_unique [of a b q r],
  1628     simp add: divmod_int_rel_def)
  1629 
  1630 (* simprocs adapted from HOL/ex/Binary.thy *)
  1631 ML {*
  1632 local
  1633   val mk_number = HOLogic.mk_number HOLogic.intT
  1634   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1635   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1636   val zero = @{term "0 :: int"}
  1637   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1638   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1639   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1640     map (fn th => th RS sym) [@{thm numeral_1_eq_1}]
  1641   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1642     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1643   fun binary_proc proc ss ct =
  1644     (case Thm.term_of ct of
  1645       _ $ t $ u =>
  1646       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1647         SOME args => proc (Simplifier.the_context ss) args
  1648       | NONE => NONE)
  1649     | _ => NONE);
  1650 in
  1651   fun divmod_proc posrule negrule =
  1652     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1653       if b = 0 then NONE else let
  1654         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1655         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1656         val (goal2, goal3, rule) = if b > 0
  1657           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1658           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1659       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1660 end
  1661 *}
  1662 
  1663 simproc_setup binary_int_div
  1664   ("numeral m div numeral n :: int" |
  1665    "numeral m div neg_numeral n :: int" |
  1666    "neg_numeral m div numeral n :: int" |
  1667    "neg_numeral m div neg_numeral n :: int") =
  1668   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1669 
  1670 simproc_setup binary_int_mod
  1671   ("numeral m mod numeral n :: int" |
  1672    "numeral m mod neg_numeral n :: int" |
  1673    "neg_numeral m mod numeral n :: int" |
  1674    "neg_numeral m mod neg_numeral n :: int") =
  1675   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1676 
  1677 lemmas posDivAlg_eqn_numeral [simp] =
  1678     posDivAlg_eqn [of "numeral v" "numeral w", OF zero_less_numeral] for v w
  1679 
  1680 lemmas negDivAlg_eqn_numeral [simp] =
  1681     negDivAlg_eqn [of "numeral v" "neg_numeral w", OF zero_less_numeral] for v w
  1682 
  1683 
  1684 text{*Special-case simplification *}
  1685 
  1686 (** The last remaining special cases for constant arithmetic:
  1687     1 div z and 1 mod z **)
  1688 
  1689 lemmas div_pos_pos_1_numeral [simp] =
  1690   div_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1691 
  1692 lemmas div_pos_neg_1_numeral [simp] =
  1693   div_pos_neg [OF zero_less_one, of "neg_numeral w",
  1694   OF neg_numeral_less_zero] for w
  1695 
  1696 lemmas mod_pos_pos_1_numeral [simp] =
  1697   mod_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1698 
  1699 lemmas mod_pos_neg_1_numeral [simp] =
  1700   mod_pos_neg [OF zero_less_one, of "neg_numeral w",
  1701   OF neg_numeral_less_zero] for w
  1702 
  1703 lemmas posDivAlg_eqn_1_numeral [simp] =
  1704     posDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1705 
  1706 lemmas negDivAlg_eqn_1_numeral [simp] =
  1707     negDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1708 
  1709 
  1710 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1711 
  1712 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1713 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1714 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1715 apply (rule unique_quotient_lemma)
  1716 apply (erule subst)
  1717 apply (erule subst, simp_all)
  1718 done
  1719 
  1720 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1721 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1722 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1723 apply (rule unique_quotient_lemma_neg)
  1724 apply (erule subst)
  1725 apply (erule subst, simp_all)
  1726 done
  1727 
  1728 
  1729 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1730 
  1731 lemma q_pos_lemma:
  1732      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1733 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1734  apply (simp add: zero_less_mult_iff)
  1735 apply (simp add: right_distrib)
  1736 done
  1737 
  1738 lemma zdiv_mono2_lemma:
  1739      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1740          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1741       ==> q \<le> (q'::int)"
  1742 apply (frule q_pos_lemma, assumption+) 
  1743 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1744  apply (simp add: mult_less_cancel_left)
  1745 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1746  prefer 2 apply simp
  1747 apply (simp (no_asm_simp) add: right_distrib)
  1748 apply (subst add_commute, rule add_less_le_mono, arith)
  1749 apply (rule mult_right_mono, auto)
  1750 done
  1751 
  1752 lemma zdiv_mono2:
  1753      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1754 apply (subgoal_tac "b \<noteq> 0")
  1755  prefer 2 apply arith
  1756 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1757 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1758 apply (rule zdiv_mono2_lemma)
  1759 apply (erule subst)
  1760 apply (erule subst, simp_all)
  1761 done
  1762 
  1763 lemma q_neg_lemma:
  1764      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1765 apply (subgoal_tac "b'*q' < 0")
  1766  apply (simp add: mult_less_0_iff, arith)
  1767 done
  1768 
  1769 lemma zdiv_mono2_neg_lemma:
  1770      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1771          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1772       ==> q' \<le> (q::int)"
  1773 apply (frule q_neg_lemma, assumption+) 
  1774 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1775  apply (simp add: mult_less_cancel_left)
  1776 apply (simp add: right_distrib)
  1777 apply (subgoal_tac "b*q' \<le> b'*q'")
  1778  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1779 done
  1780 
  1781 lemma zdiv_mono2_neg:
  1782      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1783 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1784 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1785 apply (rule zdiv_mono2_neg_lemma)
  1786 apply (erule subst)
  1787 apply (erule subst, simp_all)
  1788 done
  1789 
  1790 
  1791 subsubsection {* More Algebraic Laws for div and mod *}
  1792 
  1793 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1794 
  1795 lemma zmult1_lemma:
  1796      "[| divmod_int_rel b c (q, r) |]  
  1797       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1798 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1799 
  1800 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1801 apply (case_tac "c = 0", simp)
  1802 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN div_int_unique])
  1803 done
  1804 
  1805 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1806 
  1807 lemma zadd1_lemma:
  1808      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1809       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1810 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1811 
  1812 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1813 lemma zdiv_zadd1_eq:
  1814      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1815 apply (case_tac "c = 0", simp)
  1816 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] div_int_unique)
  1817 done
  1818 
  1819 lemma posDivAlg_div_mod:
  1820   assumes "k \<ge> 0"
  1821   and "l \<ge> 0"
  1822   shows "posDivAlg k l = (k div l, k mod l)"
  1823 proof (cases "l = 0")
  1824   case True then show ?thesis by (simp add: posDivAlg.simps)
  1825 next
  1826   case False with assms posDivAlg_correct
  1827     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1828     by simp
  1829   from div_int_unique [OF this] mod_int_unique [OF this]
  1830   show ?thesis by simp
  1831 qed
  1832 
  1833 lemma negDivAlg_div_mod:
  1834   assumes "k < 0"
  1835   and "l > 0"
  1836   shows "negDivAlg k l = (k div l, k mod l)"
  1837 proof -
  1838   from assms have "l \<noteq> 0" by simp
  1839   from assms negDivAlg_correct
  1840     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1841     by simp
  1842   from div_int_unique [OF this] mod_int_unique [OF this]
  1843   show ?thesis by simp
  1844 qed
  1845 
  1846 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1847 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1848 
  1849 (* REVISIT: should this be generalized to all semiring_div types? *)
  1850 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1851 
  1852 lemma zmod_zdiv_equality':
  1853   "(m\<Colon>int) mod n = m - (m div n) * n"
  1854   using mod_div_equality [of m n] by arith
  1855 
  1856 
  1857 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1858 
  1859 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1860   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1861   to cause particular problems.*)
  1862 
  1863 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1864 
  1865 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1866 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1867  apply (simp add: algebra_simps)
  1868 apply (rule order_le_less_trans)
  1869  apply (erule_tac [2] mult_strict_right_mono)
  1870  apply (rule mult_left_mono_neg)
  1871   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1872  apply (simp)
  1873 apply (simp)
  1874 done
  1875 
  1876 lemma zmult2_lemma_aux2:
  1877      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1878 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1879  apply arith
  1880 apply (simp add: mult_le_0_iff)
  1881 done
  1882 
  1883 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1884 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1885 apply arith
  1886 apply (simp add: zero_le_mult_iff)
  1887 done
  1888 
  1889 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1890 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1891  apply (simp add: right_diff_distrib)
  1892 apply (rule order_less_le_trans)
  1893  apply (erule mult_strict_right_mono)
  1894  apply (rule_tac [2] mult_left_mono)
  1895   apply simp
  1896  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1897 apply simp
  1898 done
  1899 
  1900 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  1901       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1902 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1903                    zero_less_mult_iff right_distrib [symmetric] 
  1904                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4 mult_less_0_iff split: split_if_asm)
  1905 
  1906 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1907 apply (case_tac "b = 0", simp)
  1908 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN div_int_unique])
  1909 done
  1910 
  1911 lemma zmod_zmult2_eq:
  1912      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  1913 apply (case_tac "b = 0", simp)
  1914 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN mod_int_unique])
  1915 done
  1916 
  1917 lemma div_pos_geq:
  1918   fixes k l :: int
  1919   assumes "0 < l" and "l \<le> k"
  1920   shows "k div l = (k - l) div l + 1"
  1921 proof -
  1922   have "k = (k - l) + l" by simp
  1923   then obtain j where k: "k = j + l" ..
  1924   with assms show ?thesis by simp
  1925 qed
  1926 
  1927 lemma mod_pos_geq:
  1928   fixes k l :: int
  1929   assumes "0 < l" and "l \<le> k"
  1930   shows "k mod l = (k - l) mod l"
  1931 proof -
  1932   have "k = (k - l) + l" by simp
  1933   then obtain j where k: "k = j + l" ..
  1934   with assms show ?thesis by simp
  1935 qed
  1936 
  1937 
  1938 subsubsection {* Splitting Rules for div and mod *}
  1939 
  1940 text{*The proofs of the two lemmas below are essentially identical*}
  1941 
  1942 lemma split_pos_lemma:
  1943  "0<k ==> 
  1944     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  1945 apply (rule iffI, clarify)
  1946  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1947  apply (subst mod_add_eq) 
  1948  apply (subst zdiv_zadd1_eq) 
  1949  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  1950 txt{*converse direction*}
  1951 apply (drule_tac x = "n div k" in spec) 
  1952 apply (drule_tac x = "n mod k" in spec, simp)
  1953 done
  1954 
  1955 lemma split_neg_lemma:
  1956  "k<0 ==>
  1957     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  1958 apply (rule iffI, clarify)
  1959  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1960  apply (subst mod_add_eq) 
  1961  apply (subst zdiv_zadd1_eq) 
  1962  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  1963 txt{*converse direction*}
  1964 apply (drule_tac x = "n div k" in spec) 
  1965 apply (drule_tac x = "n mod k" in spec, simp)
  1966 done
  1967 
  1968 lemma split_zdiv:
  1969  "P(n div k :: int) =
  1970   ((k = 0 --> P 0) & 
  1971    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  1972    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  1973 apply (case_tac "k=0", simp)
  1974 apply (simp only: linorder_neq_iff)
  1975 apply (erule disjE) 
  1976  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  1977                       split_neg_lemma [of concl: "%x y. P x"])
  1978 done
  1979 
  1980 lemma split_zmod:
  1981  "P(n mod k :: int) =
  1982   ((k = 0 --> P n) & 
  1983    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  1984    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  1985 apply (case_tac "k=0", simp)
  1986 apply (simp only: linorder_neq_iff)
  1987 apply (erule disjE) 
  1988  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  1989                       split_neg_lemma [of concl: "%x y. P y"])
  1990 done
  1991 
  1992 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  1993   when these are applied to some constant that is of the form
  1994   @{term "numeral k"}: *}
  1995 declare split_zdiv [of _ _ "numeral k", arith_split] for k
  1996 declare split_zmod [of _ _ "numeral k", arith_split] for k
  1997 
  1998 
  1999 subsubsection {* Computing @{text "div"} and @{text "mod"} with shifting *}
  2000 
  2001 lemma pos_divmod_int_rel_mult_2:
  2002   assumes "0 \<le> b"
  2003   assumes "divmod_int_rel a b (q, r)"
  2004   shows "divmod_int_rel (1 + 2*a) (2*b) (q, 1 + 2*r)"
  2005   using assms unfolding divmod_int_rel_def by auto
  2006 
  2007 lemma neg_divmod_int_rel_mult_2:
  2008   assumes "b \<le> 0"
  2009   assumes "divmod_int_rel (a + 1) b (q, r)"
  2010   shows "divmod_int_rel (1 + 2*a) (2*b) (q, 2*r - 1)"
  2011   using assms unfolding divmod_int_rel_def by auto
  2012 
  2013 text{*computing div by shifting *}
  2014 
  2015 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2016   using pos_divmod_int_rel_mult_2 [OF _ divmod_int_rel_div_mod]
  2017   by (rule div_int_unique)
  2018 
  2019 lemma neg_zdiv_mult_2: 
  2020   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2021   using neg_divmod_int_rel_mult_2 [OF A divmod_int_rel_div_mod]
  2022   by (rule div_int_unique)
  2023 
  2024 (* FIXME: add rules for negative numerals *)
  2025 lemma zdiv_numeral_Bit0 [simp]:
  2026   "numeral (Num.Bit0 v) div numeral (Num.Bit0 w) =
  2027     numeral v div (numeral w :: int)"
  2028   unfolding numeral.simps unfolding mult_2 [symmetric]
  2029   by (rule div_mult_mult1, simp)
  2030 
  2031 lemma zdiv_numeral_Bit1 [simp]:
  2032   "numeral (Num.Bit1 v) div numeral (Num.Bit0 w) =  
  2033     (numeral v div (numeral w :: int))"
  2034   unfolding numeral.simps
  2035   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2036   by (rule pos_zdiv_mult_2, simp)
  2037 
  2038 lemma pos_zmod_mult_2:
  2039   fixes a b :: int
  2040   assumes "0 \<le> a"
  2041   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2042   using pos_divmod_int_rel_mult_2 [OF assms divmod_int_rel_div_mod]
  2043   by (rule mod_int_unique)
  2044 
  2045 lemma neg_zmod_mult_2:
  2046   fixes a b :: int
  2047   assumes "a \<le> 0"
  2048   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2049   using neg_divmod_int_rel_mult_2 [OF assms divmod_int_rel_div_mod]
  2050   by (rule mod_int_unique)
  2051 
  2052 (* FIXME: add rules for negative numerals *)
  2053 lemma zmod_numeral_Bit0 [simp]:
  2054   "numeral (Num.Bit0 v) mod numeral (Num.Bit0 w) =  
  2055     (2::int) * (numeral v mod numeral w)"
  2056   unfolding numeral_Bit0 [of v] numeral_Bit0 [of w]
  2057   unfolding mult_2 [symmetric] by (rule mod_mult_mult1)
  2058 
  2059 lemma zmod_numeral_Bit1 [simp]:
  2060   "numeral (Num.Bit1 v) mod numeral (Num.Bit0 w) =
  2061     2 * (numeral v mod numeral w) + (1::int)"
  2062   unfolding numeral_Bit1 [of v] numeral_Bit0 [of w]
  2063   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2064   by (rule pos_zmod_mult_2, simp)
  2065 
  2066 lemma zdiv_eq_0_iff:
  2067  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2068 proof
  2069   assume ?L
  2070   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2071   with `?L` show ?R by blast
  2072 next
  2073   assume ?R thus ?L
  2074     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2075 qed
  2076 
  2077 
  2078 subsubsection {* Quotients of Signs *}
  2079 
  2080 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2081 apply (subgoal_tac "a div b \<le> -1", force)
  2082 apply (rule order_trans)
  2083 apply (rule_tac a' = "-1" in zdiv_mono1)
  2084 apply (auto simp add: div_eq_minus1)
  2085 done
  2086 
  2087 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2088 by (drule zdiv_mono1_neg, auto)
  2089 
  2090 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2091 by (drule zdiv_mono1, auto)
  2092 
  2093 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2094 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2095 They should all be simp rules unless that causes too much search. *}
  2096 
  2097 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2098 apply auto
  2099 apply (drule_tac [2] zdiv_mono1)
  2100 apply (auto simp add: linorder_neq_iff)
  2101 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2102 apply (blast intro: div_neg_pos_less0)
  2103 done
  2104 
  2105 lemma neg_imp_zdiv_nonneg_iff:
  2106   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2107 apply (subst div_minus_minus [symmetric])
  2108 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2109 done
  2110 
  2111 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2112 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2113 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2114 
  2115 lemma pos_imp_zdiv_pos_iff:
  2116   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2117 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2118 by arith
  2119 
  2120 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2121 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2122 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2123 
  2124 lemma nonneg1_imp_zdiv_pos_iff:
  2125   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2126 apply rule
  2127  apply rule
  2128   using div_pos_pos_trivial[of a b]apply arith
  2129  apply(cases "b=0")apply simp
  2130  using div_nonneg_neg_le0[of a b]apply arith
  2131 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2132 done
  2133 
  2134 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2135 apply (rule split_zmod[THEN iffD2])
  2136 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2137 done
  2138 
  2139 
  2140 subsubsection {* The Divides Relation *}
  2141 
  2142 lemma dvd_neg_numeral_left [simp]:
  2143   fixes y :: "'a::comm_ring_1"
  2144   shows "(neg_numeral k) dvd y \<longleftrightarrow> (numeral k) dvd y"
  2145   unfolding neg_numeral_def minus_dvd_iff ..
  2146 
  2147 lemma dvd_neg_numeral_right [simp]:
  2148   fixes x :: "'a::comm_ring_1"
  2149   shows "x dvd (neg_numeral k) \<longleftrightarrow> x dvd (numeral k)"
  2150   unfolding neg_numeral_def dvd_minus_iff ..
  2151 
  2152 lemmas dvd_eq_mod_eq_0_numeral [simp] =
  2153   dvd_eq_mod_eq_0 [of "numeral x" "numeral y"] for x y
  2154 
  2155 
  2156 subsubsection {* Further properties *}
  2157 
  2158 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2159   using zmod_zdiv_equality[where a="m" and b="n"]
  2160   by (simp add: algebra_simps) (* FIXME: generalize *)
  2161 
  2162 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2163 apply (subst split_div, auto)
  2164 apply (subst split_zdiv, auto)
  2165 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2166 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2167 done
  2168 
  2169 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2170 apply (subst split_mod, auto)
  2171 apply (subst split_zmod, auto)
  2172 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2173        in unique_remainder)
  2174 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2175 done
  2176 
  2177 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2178 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2179 
  2180 text{*Suggested by Matthias Daum*}
  2181 lemma int_power_div_base:
  2182      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2183 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2184  apply (erule ssubst)
  2185  apply (simp only: power_add)
  2186  apply simp_all
  2187 done
  2188 
  2189 text {* by Brian Huffman *}
  2190 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2191 by (rule mod_minus_eq [symmetric])
  2192 
  2193 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2194 by (rule mod_diff_left_eq [symmetric])
  2195 
  2196 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2197 by (rule mod_diff_right_eq [symmetric])
  2198 
  2199 lemmas zmod_simps =
  2200   mod_add_left_eq  [symmetric]
  2201   mod_add_right_eq [symmetric]
  2202   mod_mult_right_eq[symmetric]
  2203   mod_mult_left_eq [symmetric]
  2204   power_mod
  2205   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2206 
  2207 text {* Distributive laws for function @{text nat}. *}
  2208 
  2209 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2210 apply (rule linorder_cases [of y 0])
  2211 apply (simp add: div_nonneg_neg_le0)
  2212 apply simp
  2213 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2214 done
  2215 
  2216 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2217 lemma nat_mod_distrib:
  2218   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2219 apply (case_tac "y = 0", simp)
  2220 apply (simp add: nat_eq_iff zmod_int)
  2221 done
  2222 
  2223 text  {* transfer setup *}
  2224 
  2225 lemma transfer_nat_int_functions:
  2226     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2227     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2228   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2229 
  2230 lemma transfer_nat_int_function_closures:
  2231     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2232     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2233   apply (cases "y = 0")
  2234   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2235   apply (cases "y = 0")
  2236   apply auto
  2237 done
  2238 
  2239 declare transfer_morphism_nat_int [transfer add return:
  2240   transfer_nat_int_functions
  2241   transfer_nat_int_function_closures
  2242 ]
  2243 
  2244 lemma transfer_int_nat_functions:
  2245     "(int x) div (int y) = int (x div y)"
  2246     "(int x) mod (int y) = int (x mod y)"
  2247   by (auto simp add: zdiv_int zmod_int)
  2248 
  2249 lemma transfer_int_nat_function_closures:
  2250     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2251     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2252   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2253 
  2254 declare transfer_morphism_int_nat [transfer add return:
  2255   transfer_int_nat_functions
  2256   transfer_int_nat_function_closures
  2257 ]
  2258 
  2259 text{*Suggested by Matthias Daum*}
  2260 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2261 apply (subgoal_tac "nat x div nat k < nat x")
  2262  apply (simp add: nat_div_distrib [symmetric])
  2263 apply (rule Divides.div_less_dividend, simp_all)
  2264 done
  2265 
  2266 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2267 proof
  2268   assume H: "x mod n = y mod n"
  2269   hence "x mod n - y mod n = 0" by simp
  2270   hence "(x mod n - y mod n) mod n = 0" by simp 
  2271   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2272   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2273 next
  2274   assume H: "n dvd x - y"
  2275   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2276   hence "x = n*k + y" by simp
  2277   hence "x mod n = (n*k + y) mod n" by simp
  2278   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2279 qed
  2280 
  2281 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2282   shows "\<exists>q. x = y + n * q"
  2283 proof-
  2284   from xy have th: "int x - int y = int (x - y)" by simp 
  2285   from xyn have "int x mod int n = int y mod int n" 
  2286     by (simp add: zmod_int [symmetric])
  2287   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2288   hence "n dvd x - y" by (simp add: th zdvd_int)
  2289   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2290 qed
  2291 
  2292 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2293   (is "?lhs = ?rhs")
  2294 proof
  2295   assume H: "x mod n = y mod n"
  2296   {assume xy: "x \<le> y"
  2297     from H have th: "y mod n = x mod n" by simp
  2298     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2299       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2300   moreover
  2301   {assume xy: "y \<le> x"
  2302     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2303       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2304   ultimately  show ?rhs using linear[of x y] by blast  
  2305 next
  2306   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2307   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2308   thus  ?lhs by simp
  2309 qed
  2310 
  2311 lemma div_nat_numeral [simp]:
  2312   "(numeral v :: nat) div numeral v' = nat (numeral v div numeral v')"
  2313   by (simp add: nat_div_distrib)
  2314 
  2315 lemma one_div_nat_numeral [simp]:
  2316   "Suc 0 div numeral v' = nat (1 div numeral v')"
  2317   by (subst nat_div_distrib, simp_all)
  2318 
  2319 lemma mod_nat_numeral [simp]:
  2320   "(numeral v :: nat) mod numeral v' = nat (numeral v mod numeral v')"
  2321   by (simp add: nat_mod_distrib)
  2322 
  2323 lemma one_mod_nat_numeral [simp]:
  2324   "Suc 0 mod numeral v' = nat (1 mod numeral v')"
  2325   by (subst nat_mod_distrib) simp_all
  2326 
  2327 lemma mod_2_not_eq_zero_eq_one_int:
  2328   fixes k :: int
  2329   shows "k mod 2 \<noteq> 0 \<longleftrightarrow> k mod 2 = 1"
  2330   by auto
  2331 
  2332 
  2333 subsubsection {* Tools setup *}
  2334 
  2335 text {* Nitpick *}
  2336 
  2337 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2338 
  2339 
  2340 subsubsection {* Code generation *}
  2341 
  2342 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2343   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2344 
  2345 lemma pdivmod_posDivAlg [code]:
  2346   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2347 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2348 
  2349 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2350   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2351     then pdivmod k l
  2352     else (let (r, s) = pdivmod k l in
  2353        if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2354 proof -
  2355   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2356   show ?thesis
  2357     by (simp add: divmod_int_mod_div pdivmod_def)
  2358       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2359       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2360 qed
  2361 
  2362 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2363   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2364     then pdivmod k l
  2365     else (let (r, s) = pdivmod k l in
  2366       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2367 proof -
  2368   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2369     by (auto simp add: not_less sgn_if)
  2370   then show ?thesis by (simp add: divmod_int_pdivmod)
  2371 qed
  2372 
  2373 code_modulename SML
  2374   Divides Arith
  2375 
  2376 code_modulename OCaml
  2377   Divides Arith
  2378 
  2379 code_modulename Haskell
  2380   Divides Arith
  2381 
  2382 end