src/HOL/Nat.thy
author wenzelm
Wed Aug 22 22:55:41 2012 +0200 (2012-08-22)
changeset 48891 c0eafbd55de3
parent 48560 e0875d956a6b
child 49388 1ffd5a055acf
permissions -rw-r--r--
prefer ML_file over old uses;
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 begin
    13 
    14 ML_file "~~/src/Tools/rat.ML"
    15 ML_file "Tools/arith_data.ML"
    16 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    17 
    18 
    19 subsection {* Type @{text ind} *}
    20 
    21 typedecl ind
    22 
    23 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    24   -- {* the axiom of infinity in 2 parts *}
    25   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    26   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    27 
    28 subsection {* Type nat *}
    29 
    30 text {* Type definition *}
    31 
    32 inductive Nat :: "ind \<Rightarrow> bool" where
    33   Zero_RepI: "Nat Zero_Rep"
    34 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    35 
    36 typedef (open) nat = "{n. Nat n}"
    37   morphisms Rep_Nat Abs_Nat
    38   using Nat.Zero_RepI by auto
    39 
    40 lemma Nat_Rep_Nat:
    41   "Nat (Rep_Nat n)"
    42   using Rep_Nat by simp
    43 
    44 lemma Nat_Abs_Nat_inverse:
    45   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    46   using Abs_Nat_inverse by simp
    47 
    48 lemma Nat_Abs_Nat_inject:
    49   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    50   using Abs_Nat_inject by simp
    51 
    52 instantiation nat :: zero
    53 begin
    54 
    55 definition Zero_nat_def:
    56   "0 = Abs_Nat Zero_Rep"
    57 
    58 instance ..
    59 
    60 end
    61 
    62 definition Suc :: "nat \<Rightarrow> nat" where
    63   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    67 
    68 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    69   by (rule not_sym, rule Suc_not_Zero not_sym)
    70 
    71 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    72   by (rule iffI, rule Suc_Rep_inject) simp_all
    73 
    74 rep_datatype "0 \<Colon> nat" Suc
    75   apply (unfold Zero_nat_def Suc_def)
    76   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    77    apply (erule Nat_Rep_Nat [THEN Nat.induct])
    78    apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    79     apply (simp_all add: Nat_Abs_Nat_inject Nat_Rep_Nat
    80       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep
    81       Suc_Rep_not_Zero_Rep [symmetric]
    82       Suc_Rep_inject' Rep_Nat_inject)
    83   done
    84 
    85 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    86   -- {* for backward compatibility -- names of variables differ *}
    87   fixes n
    88   assumes "P 0"
    89     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    90   shows "P n"
    91   using assms by (rule nat.induct)
    92 
    93 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    94 
    95 lemmas nat_rec_0 = nat.recs(1)
    96   and nat_rec_Suc = nat.recs(2)
    97 
    98 lemmas nat_case_0 = nat.cases(1)
    99   and nat_case_Suc = nat.cases(2)
   100    
   101 
   102 text {* Injectiveness and distinctness lemmas *}
   103 
   104 lemma inj_Suc[simp]: "inj_on Suc N"
   105   by (simp add: inj_on_def)
   106 
   107 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   108 by (rule notE, rule Suc_not_Zero)
   109 
   110 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   111 by (rule Suc_neq_Zero, erule sym)
   112 
   113 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   114 by (rule inj_Suc [THEN injD])
   115 
   116 lemma n_not_Suc_n: "n \<noteq> Suc n"
   117 by (induct n) simp_all
   118 
   119 lemma Suc_n_not_n: "Suc n \<noteq> n"
   120 by (rule not_sym, rule n_not_Suc_n)
   121 
   122 text {* A special form of induction for reasoning
   123   about @{term "m < n"} and @{term "m - n"} *}
   124 
   125 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   126     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   127   apply (rule_tac x = m in spec)
   128   apply (induct n)
   129   prefer 2
   130   apply (rule allI)
   131   apply (induct_tac x, iprover+)
   132   done
   133 
   134 
   135 subsection {* Arithmetic operators *}
   136 
   137 instantiation nat :: "{minus, comm_monoid_add}"
   138 begin
   139 
   140 primrec plus_nat where
   141   add_0:      "0 + n = (n\<Colon>nat)"
   142 | add_Suc:  "Suc m + n = Suc (m + n)"
   143 
   144 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   145   by (induct m) simp_all
   146 
   147 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   148   by (induct m) simp_all
   149 
   150 declare add_0 [code]
   151 
   152 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   153   by simp
   154 
   155 primrec minus_nat where
   156   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   157 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   158 
   159 declare diff_Suc [simp del]
   160 
   161 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   162   by (induct n) (simp_all add: diff_Suc)
   163 
   164 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   165   by (induct n) (simp_all add: diff_Suc)
   166 
   167 instance proof
   168   fix n m q :: nat
   169   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   170   show "n + m = m + n" by (induct n) simp_all
   171   show "0 + n = n" by simp
   172 qed
   173 
   174 end
   175 
   176 hide_fact (open) add_0 add_0_right diff_0
   177 
   178 instantiation nat :: comm_semiring_1_cancel
   179 begin
   180 
   181 definition
   182   One_nat_def [simp]: "1 = Suc 0"
   183 
   184 primrec times_nat where
   185   mult_0:     "0 * n = (0\<Colon>nat)"
   186 | mult_Suc: "Suc m * n = n + (m * n)"
   187 
   188 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   189   by (induct m) simp_all
   190 
   191 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   192   by (induct m) (simp_all add: add_left_commute)
   193 
   194 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   195   by (induct m) (simp_all add: add_assoc)
   196 
   197 instance proof
   198   fix n m q :: nat
   199   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   200   show "1 * n = n" unfolding One_nat_def by simp
   201   show "n * m = m * n" by (induct n) simp_all
   202   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   203   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   204   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   205 qed
   206 
   207 end
   208 
   209 subsubsection {* Addition *}
   210 
   211 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   212   by (rule add_assoc)
   213 
   214 lemma nat_add_commute: "m + n = n + (m::nat)"
   215   by (rule add_commute)
   216 
   217 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   218   by (rule add_left_commute)
   219 
   220 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   221   by (rule add_left_cancel)
   222 
   223 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   224   by (rule add_right_cancel)
   225 
   226 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   227 
   228 lemma add_is_0 [iff]:
   229   fixes m n :: nat
   230   shows "(m + n = 0) = (m = 0 & n = 0)"
   231   by (cases m) simp_all
   232 
   233 lemma add_is_1:
   234   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   235   by (cases m) simp_all
   236 
   237 lemma one_is_add:
   238   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   239   by (rule trans, rule eq_commute, rule add_is_1)
   240 
   241 lemma add_eq_self_zero:
   242   fixes m n :: nat
   243   shows "m + n = m \<Longrightarrow> n = 0"
   244   by (induct m) simp_all
   245 
   246 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   247   apply (induct k)
   248    apply simp
   249   apply(drule comp_inj_on[OF _ inj_Suc])
   250   apply (simp add:o_def)
   251   done
   252 
   253 lemma Suc_eq_plus1: "Suc n = n + 1"
   254   unfolding One_nat_def by simp
   255 
   256 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   257   unfolding One_nat_def by simp
   258 
   259 
   260 subsubsection {* Difference *}
   261 
   262 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   263   by (induct m) simp_all
   264 
   265 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   266   by (induct i j rule: diff_induct) simp_all
   267 
   268 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   269   by (simp add: diff_diff_left)
   270 
   271 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   272   by (simp add: diff_diff_left add_commute)
   273 
   274 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   275   by (induct n) simp_all
   276 
   277 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   278   by (simp add: diff_add_inverse add_commute [of m n])
   279 
   280 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   281   by (induct k) simp_all
   282 
   283 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   284   by (simp add: diff_cancel add_commute)
   285 
   286 lemma diff_add_0: "n - (n + m) = (0::nat)"
   287   by (induct n) simp_all
   288 
   289 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   290   unfolding One_nat_def by simp
   291 
   292 text {* Difference distributes over multiplication *}
   293 
   294 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   295 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   296 
   297 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   298 by (simp add: diff_mult_distrib mult_commute [of k])
   299   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   300 
   301 
   302 subsubsection {* Multiplication *}
   303 
   304 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   305   by (rule mult_assoc)
   306 
   307 lemma nat_mult_commute: "m * n = n * (m::nat)"
   308   by (rule mult_commute)
   309 
   310 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   311   by (rule right_distrib)
   312 
   313 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   314   by (induct m) auto
   315 
   316 lemmas nat_distrib =
   317   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   318 
   319 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   320   apply (induct m)
   321    apply simp
   322   apply (induct n)
   323    apply auto
   324   done
   325 
   326 lemma one_eq_mult_iff [simp,no_atp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   327   apply (rule trans)
   328   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   329   done
   330 
   331 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   332   unfolding One_nat_def by (rule mult_eq_1_iff)
   333 
   334 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   335   unfolding One_nat_def by (rule one_eq_mult_iff)
   336 
   337 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   338 proof -
   339   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   340   proof (induct n arbitrary: m)
   341     case 0 then show "m = 0" by simp
   342   next
   343     case (Suc n) then show "m = Suc n"
   344       by (cases m) (simp_all add: eq_commute [of "0"])
   345   qed
   346   then show ?thesis by auto
   347 qed
   348 
   349 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   350   by (simp add: mult_commute)
   351 
   352 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   353   by (subst mult_cancel1) simp
   354 
   355 
   356 subsection {* Orders on @{typ nat} *}
   357 
   358 subsubsection {* Operation definition *}
   359 
   360 instantiation nat :: linorder
   361 begin
   362 
   363 primrec less_eq_nat where
   364   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   365 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   366 
   367 declare less_eq_nat.simps [simp del]
   368 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   369 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   370 
   371 definition less_nat where
   372   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   373 
   374 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   375   by (simp add: less_eq_nat.simps(2))
   376 
   377 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   378   unfolding less_eq_Suc_le ..
   379 
   380 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   381   by (induct n) (simp_all add: less_eq_nat.simps(2))
   382 
   383 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   384   by (simp add: less_eq_Suc_le)
   385 
   386 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   387   by simp
   388 
   389 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   390   by (simp add: less_eq_Suc_le)
   391 
   392 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   393   by (simp add: less_eq_Suc_le)
   394 
   395 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   396   by (induct m arbitrary: n)
   397     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   398 
   399 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   400   by (cases n) (auto intro: le_SucI)
   401 
   402 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   403   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   404 
   405 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   406   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   407 
   408 instance
   409 proof
   410   fix n m :: nat
   411   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   412   proof (induct n arbitrary: m)
   413     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   414   next
   415     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   416   qed
   417 next
   418   fix n :: nat show "n \<le> n" by (induct n) simp_all
   419 next
   420   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   421   then show "n = m"
   422     by (induct n arbitrary: m)
   423       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   424 next
   425   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   426   then show "n \<le> q"
   427   proof (induct n arbitrary: m q)
   428     case 0 show ?case by simp
   429   next
   430     case (Suc n) then show ?case
   431       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   432         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   433         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   434   qed
   435 next
   436   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   437     by (induct n arbitrary: m)
   438       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   439 qed
   440 
   441 end
   442 
   443 instantiation nat :: bot
   444 begin
   445 
   446 definition bot_nat :: nat where
   447   "bot_nat = 0"
   448 
   449 instance proof
   450 qed (simp add: bot_nat_def)
   451 
   452 end
   453 
   454 subsubsection {* Introduction properties *}
   455 
   456 lemma lessI [iff]: "n < Suc n"
   457   by (simp add: less_Suc_eq_le)
   458 
   459 lemma zero_less_Suc [iff]: "0 < Suc n"
   460   by (simp add: less_Suc_eq_le)
   461 
   462 
   463 subsubsection {* Elimination properties *}
   464 
   465 lemma less_not_refl: "~ n < (n::nat)"
   466   by (rule order_less_irrefl)
   467 
   468 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   469   by (rule not_sym) (rule less_imp_neq) 
   470 
   471 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   472   by (rule less_imp_neq)
   473 
   474 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   475   by (rule notE, rule less_not_refl)
   476 
   477 lemma less_zeroE: "(n::nat) < 0 ==> R"
   478   by (rule notE) (rule not_less0)
   479 
   480 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   481   unfolding less_Suc_eq_le le_less ..
   482 
   483 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   484   by (simp add: less_Suc_eq)
   485 
   486 lemma less_one [iff, no_atp]: "(n < (1::nat)) = (n = 0)"
   487   unfolding One_nat_def by (rule less_Suc0)
   488 
   489 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   490   by simp
   491 
   492 text {* "Less than" is antisymmetric, sort of *}
   493 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   494   unfolding not_less less_Suc_eq_le by (rule antisym)
   495 
   496 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   497   by (rule linorder_neq_iff)
   498 
   499 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   500   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   501   shows "P n m"
   502   apply (rule less_linear [THEN disjE])
   503   apply (erule_tac [2] disjE)
   504   apply (erule lessCase)
   505   apply (erule sym [THEN eqCase])
   506   apply (erule major)
   507   done
   508 
   509 
   510 subsubsection {* Inductive (?) properties *}
   511 
   512 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   513   unfolding less_eq_Suc_le [of m] le_less by simp 
   514 
   515 lemma lessE:
   516   assumes major: "i < k"
   517   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   518   shows P
   519 proof -
   520   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   521     unfolding less_eq_Suc_le by (induct k) simp_all
   522   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   523     by (clarsimp simp add: less_le)
   524   with p1 p2 show P by auto
   525 qed
   526 
   527 lemma less_SucE: assumes major: "m < Suc n"
   528   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   529   apply (rule major [THEN lessE])
   530   apply (rule eq, blast)
   531   apply (rule less, blast)
   532   done
   533 
   534 lemma Suc_lessE: assumes major: "Suc i < k"
   535   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   536   apply (rule major [THEN lessE])
   537   apply (erule lessI [THEN minor])
   538   apply (erule Suc_lessD [THEN minor], assumption)
   539   done
   540 
   541 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   542   by simp
   543 
   544 lemma less_trans_Suc:
   545   assumes le: "i < j" shows "j < k ==> Suc i < k"
   546   apply (induct k, simp_all)
   547   apply (insert le)
   548   apply (simp add: less_Suc_eq)
   549   apply (blast dest: Suc_lessD)
   550   done
   551 
   552 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   553 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   554   unfolding not_less less_Suc_eq_le ..
   555 
   556 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   557   unfolding not_le Suc_le_eq ..
   558 
   559 text {* Properties of "less than or equal" *}
   560 
   561 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   562   unfolding less_Suc_eq_le .
   563 
   564 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   565   unfolding not_le less_Suc_eq_le ..
   566 
   567 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   568   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   569 
   570 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   571   by (drule le_Suc_eq [THEN iffD1], iprover+)
   572 
   573 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   574   unfolding Suc_le_eq .
   575 
   576 text {* Stronger version of @{text Suc_leD} *}
   577 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   578   unfolding Suc_le_eq .
   579 
   580 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   581   unfolding less_eq_Suc_le by (rule Suc_leD)
   582 
   583 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   584 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   585 
   586 
   587 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   588 
   589 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   590   unfolding le_less .
   591 
   592 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   593   by (rule le_less)
   594 
   595 text {* Useful with @{text blast}. *}
   596 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   597   by auto
   598 
   599 lemma le_refl: "n \<le> (n::nat)"
   600   by simp
   601 
   602 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   603   by (rule order_trans)
   604 
   605 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   606   by (rule antisym)
   607 
   608 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   609   by (rule less_le)
   610 
   611 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   612   unfolding less_le ..
   613 
   614 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   615   by (rule linear)
   616 
   617 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   618 
   619 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   620   unfolding less_Suc_eq_le by auto
   621 
   622 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   623   unfolding not_less by (rule le_less_Suc_eq)
   624 
   625 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   626 
   627 text {* These two rules ease the use of primitive recursion.
   628 NOTE USE OF @{text "=="} *}
   629 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   630 by simp
   631 
   632 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   633 by simp
   634 
   635 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   636 by (cases n) simp_all
   637 
   638 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   639 by (cases n) simp_all
   640 
   641 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   642 by (cases n) simp_all
   643 
   644 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   645 by (cases n) simp_all
   646 
   647 text {* This theorem is useful with @{text blast} *}
   648 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   649 by (rule neq0_conv[THEN iffD1], iprover)
   650 
   651 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   652 by (fast intro: not0_implies_Suc)
   653 
   654 lemma not_gr0 [iff,no_atp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   655 using neq0_conv by blast
   656 
   657 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   658 by (induct m') simp_all
   659 
   660 text {* Useful in certain inductive arguments *}
   661 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   662 by (cases m) simp_all
   663 
   664 
   665 subsubsection {* Monotonicity of Addition *}
   666 
   667 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   668 by (simp add: diff_Suc split: nat.split)
   669 
   670 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   671 unfolding One_nat_def by (rule Suc_pred)
   672 
   673 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   674 by (induct k) simp_all
   675 
   676 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   677 by (induct k) simp_all
   678 
   679 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   680 by(auto dest:gr0_implies_Suc)
   681 
   682 text {* strict, in 1st argument *}
   683 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   684 by (induct k) simp_all
   685 
   686 text {* strict, in both arguments *}
   687 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   688   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   689   apply (induct j, simp_all)
   690   done
   691 
   692 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   693 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   694   apply (induct n)
   695   apply (simp_all add: order_le_less)
   696   apply (blast elim!: less_SucE
   697                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   698   done
   699 
   700 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   701 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   702 apply(auto simp: gr0_conv_Suc)
   703 apply (induct_tac m)
   704 apply (simp_all add: add_less_mono)
   705 done
   706 
   707 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   708 instance nat :: linordered_semidom
   709 proof
   710   fix i j k :: nat
   711   show "0 < (1::nat)" by simp
   712   show "i \<le> j ==> k + i \<le> k + j" by simp
   713   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   714 qed
   715 
   716 instance nat :: no_zero_divisors
   717 proof
   718   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   719 qed
   720 
   721 
   722 subsubsection {* @{term min} and @{term max} *}
   723 
   724 lemma mono_Suc: "mono Suc"
   725 by (rule monoI) simp
   726 
   727 lemma min_0L [simp]: "min 0 n = (0::nat)"
   728 by (rule min_absorb1) simp
   729 
   730 lemma min_0R [simp]: "min n 0 = (0::nat)"
   731 by (rule min_absorb2) simp
   732 
   733 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   734 by (simp add: mono_Suc min_of_mono)
   735 
   736 lemma min_Suc1:
   737    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   738 by (simp split: nat.split)
   739 
   740 lemma min_Suc2:
   741    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   742 by (simp split: nat.split)
   743 
   744 lemma max_0L [simp]: "max 0 n = (n::nat)"
   745 by (rule max_absorb2) simp
   746 
   747 lemma max_0R [simp]: "max n 0 = (n::nat)"
   748 by (rule max_absorb1) simp
   749 
   750 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   751 by (simp add: mono_Suc max_of_mono)
   752 
   753 lemma max_Suc1:
   754    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   755 by (simp split: nat.split)
   756 
   757 lemma max_Suc2:
   758    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   759 by (simp split: nat.split)
   760 
   761 lemma nat_mult_min_left:
   762   fixes m n q :: nat
   763   shows "min m n * q = min (m * q) (n * q)"
   764   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   765 
   766 lemma nat_mult_min_right:
   767   fixes m n q :: nat
   768   shows "m * min n q = min (m * n) (m * q)"
   769   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   770 
   771 lemma nat_add_max_left:
   772   fixes m n q :: nat
   773   shows "max m n + q = max (m + q) (n + q)"
   774   by (simp add: max_def)
   775 
   776 lemma nat_add_max_right:
   777   fixes m n q :: nat
   778   shows "m + max n q = max (m + n) (m + q)"
   779   by (simp add: max_def)
   780 
   781 lemma nat_mult_max_left:
   782   fixes m n q :: nat
   783   shows "max m n * q = max (m * q) (n * q)"
   784   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   785 
   786 lemma nat_mult_max_right:
   787   fixes m n q :: nat
   788   shows "m * max n q = max (m * n) (m * q)"
   789   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   790 
   791 
   792 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   793 
   794 text {* Complete induction, aka course-of-values induction *}
   795 
   796 instance nat :: wellorder proof
   797   fix P and n :: nat
   798   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   799   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   800   proof (induct n)
   801     case (0 n)
   802     have "P 0" by (rule step) auto
   803     thus ?case using 0 by auto
   804   next
   805     case (Suc m n)
   806     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   807     thus ?case
   808     proof
   809       assume "n \<le> m" thus "P n" by (rule Suc(1))
   810     next
   811       assume n: "n = Suc m"
   812       show "P n"
   813         by (rule step) (rule Suc(1), simp add: n le_simps)
   814     qed
   815   qed
   816   then show "P n" by auto
   817 qed
   818 
   819 lemma Least_Suc:
   820      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   821   apply (cases n, auto)
   822   apply (frule LeastI)
   823   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   824   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   825   apply (erule_tac [2] Least_le)
   826   apply (cases "LEAST x. P x", auto)
   827   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   828   apply (blast intro: order_antisym)
   829   done
   830 
   831 lemma Least_Suc2:
   832    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   833   apply (erule (1) Least_Suc [THEN ssubst])
   834   apply simp
   835   done
   836 
   837 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   838   apply (cases n)
   839    apply blast
   840   apply (rule_tac x="LEAST k. P(k)" in exI)
   841   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   842   done
   843 
   844 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   845   unfolding One_nat_def
   846   apply (cases n)
   847    apply blast
   848   apply (frule (1) ex_least_nat_le)
   849   apply (erule exE)
   850   apply (case_tac k)
   851    apply simp
   852   apply (rename_tac k1)
   853   apply (rule_tac x=k1 in exI)
   854   apply (auto simp add: less_eq_Suc_le)
   855   done
   856 
   857 lemma nat_less_induct:
   858   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   859   using assms less_induct by blast
   860 
   861 lemma measure_induct_rule [case_names less]:
   862   fixes f :: "'a \<Rightarrow> nat"
   863   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   864   shows "P a"
   865 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   866 
   867 text {* old style induction rules: *}
   868 lemma measure_induct:
   869   fixes f :: "'a \<Rightarrow> nat"
   870   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   871   by (rule measure_induct_rule [of f P a]) iprover
   872 
   873 lemma full_nat_induct:
   874   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   875   shows "P n"
   876   by (rule less_induct) (auto intro: step simp:le_simps)
   877 
   878 text{*An induction rule for estabilishing binary relations*}
   879 lemma less_Suc_induct:
   880   assumes less:  "i < j"
   881      and  step:  "!!i. P i (Suc i)"
   882      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   883   shows "P i j"
   884 proof -
   885   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   886   have "P i (Suc (i + k))"
   887   proof (induct k)
   888     case 0
   889     show ?case by (simp add: step)
   890   next
   891     case (Suc k)
   892     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   893     hence "i < Suc (i + k)" by (simp add: add_commute)
   894     from trans[OF this lessI Suc step]
   895     show ?case by simp
   896   qed
   897   thus "P i j" by (simp add: j)
   898 qed
   899 
   900 text {* The method of infinite descent, frequently used in number theory.
   901 Provided by Roelof Oosterhuis.
   902 $P(n)$ is true for all $n\in\mathbb{N}$ if
   903 \begin{itemize}
   904   \item case ``0'': given $n=0$ prove $P(n)$,
   905   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   906         a smaller integer $m$ such that $\neg P(m)$.
   907 \end{itemize} *}
   908 
   909 text{* A compact version without explicit base case: *}
   910 lemma infinite_descent:
   911   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   912 by (induct n rule: less_induct) auto
   913 
   914 lemma infinite_descent0[case_names 0 smaller]: 
   915   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   916 by (rule infinite_descent) (case_tac "n>0", auto)
   917 
   918 text {*
   919 Infinite descent using a mapping to $\mathbb{N}$:
   920 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   921 \begin{itemize}
   922 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   923 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   924 \end{itemize}
   925 NB: the proof also shows how to use the previous lemma. *}
   926 
   927 corollary infinite_descent0_measure [case_names 0 smaller]:
   928   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   929     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   930   shows "P x"
   931 proof -
   932   obtain n where "n = V x" by auto
   933   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   934   proof (induct n rule: infinite_descent0)
   935     case 0 -- "i.e. $V(x) = 0$"
   936     with A0 show "P x" by auto
   937   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   938     case (smaller n)
   939     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   940     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   941     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   942     then show ?case by auto
   943   qed
   944   ultimately show "P x" by auto
   945 qed
   946 
   947 text{* Again, without explicit base case: *}
   948 lemma infinite_descent_measure:
   949 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   950 proof -
   951   from assms obtain n where "n = V x" by auto
   952   moreover have "!!x. V x = n \<Longrightarrow> P x"
   953   proof (induct n rule: infinite_descent, auto)
   954     fix x assume "\<not> P x"
   955     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   956   qed
   957   ultimately show "P x" by auto
   958 qed
   959 
   960 text {* A [clumsy] way of lifting @{text "<"}
   961   monotonicity to @{text "\<le>"} monotonicity *}
   962 lemma less_mono_imp_le_mono:
   963   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   964 by (simp add: order_le_less) (blast)
   965 
   966 
   967 text {* non-strict, in 1st argument *}
   968 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   969 by (rule add_right_mono)
   970 
   971 text {* non-strict, in both arguments *}
   972 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   973 by (rule add_mono)
   974 
   975 lemma le_add2: "n \<le> ((m + n)::nat)"
   976 by (insert add_right_mono [of 0 m n], simp)
   977 
   978 lemma le_add1: "n \<le> ((n + m)::nat)"
   979 by (simp add: add_commute, rule le_add2)
   980 
   981 lemma less_add_Suc1: "i < Suc (i + m)"
   982 by (rule le_less_trans, rule le_add1, rule lessI)
   983 
   984 lemma less_add_Suc2: "i < Suc (m + i)"
   985 by (rule le_less_trans, rule le_add2, rule lessI)
   986 
   987 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   988 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   989 
   990 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   991 by (rule le_trans, assumption, rule le_add1)
   992 
   993 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   994 by (rule le_trans, assumption, rule le_add2)
   995 
   996 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   997 by (rule less_le_trans, assumption, rule le_add1)
   998 
   999 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1000 by (rule less_le_trans, assumption, rule le_add2)
  1001 
  1002 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1003 apply (rule le_less_trans [of _ "i+j"])
  1004 apply (simp_all add: le_add1)
  1005 done
  1006 
  1007 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1008 apply (rule notI)
  1009 apply (drule add_lessD1)
  1010 apply (erule less_irrefl [THEN notE])
  1011 done
  1012 
  1013 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1014 by (simp add: add_commute)
  1015 
  1016 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1017 apply (rule order_trans [of _ "m+k"])
  1018 apply (simp_all add: le_add1)
  1019 done
  1020 
  1021 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1022 apply (simp add: add_commute)
  1023 apply (erule add_leD1)
  1024 done
  1025 
  1026 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1027 by (blast dest: add_leD1 add_leD2)
  1028 
  1029 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1030 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1031 by (force simp del: add_Suc_right
  1032     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1033 
  1034 
  1035 subsubsection {* More results about difference *}
  1036 
  1037 text {* Addition is the inverse of subtraction:
  1038   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1039 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1040 by (induct m n rule: diff_induct) simp_all
  1041 
  1042 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1043 by (simp add: add_diff_inverse linorder_not_less)
  1044 
  1045 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1046 by (simp add: add_commute)
  1047 
  1048 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1049 by (induct m n rule: diff_induct) simp_all
  1050 
  1051 lemma diff_less_Suc: "m - n < Suc m"
  1052 apply (induct m n rule: diff_induct)
  1053 apply (erule_tac [3] less_SucE)
  1054 apply (simp_all add: less_Suc_eq)
  1055 done
  1056 
  1057 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1058 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1059 
  1060 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1061   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1062 
  1063 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1064 by (rule le_less_trans, rule diff_le_self)
  1065 
  1066 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1067 by (cases n) (auto simp add: le_simps)
  1068 
  1069 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1070 by (induct j k rule: diff_induct) simp_all
  1071 
  1072 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1073 by (simp add: add_commute diff_add_assoc)
  1074 
  1075 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1076 by (auto simp add: diff_add_inverse2)
  1077 
  1078 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1079 by (induct m n rule: diff_induct) simp_all
  1080 
  1081 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1082 by (rule iffD2, rule diff_is_0_eq)
  1083 
  1084 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1085 by (induct m n rule: diff_induct) simp_all
  1086 
  1087 lemma less_imp_add_positive:
  1088   assumes "i < j"
  1089   shows "\<exists>k::nat. 0 < k & i + k = j"
  1090 proof
  1091   from assms show "0 < j - i & i + (j - i) = j"
  1092     by (simp add: order_less_imp_le)
  1093 qed
  1094 
  1095 text {* a nice rewrite for bounded subtraction *}
  1096 lemma nat_minus_add_max:
  1097   fixes n m :: nat
  1098   shows "n - m + m = max n m"
  1099     by (simp add: max_def not_le order_less_imp_le)
  1100 
  1101 lemma nat_diff_split:
  1102   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1103     -- {* elimination of @{text -} on @{text nat} *}
  1104 by (cases "a < b")
  1105   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1106     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1107 
  1108 lemma nat_diff_split_asm:
  1109   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1110     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1111 by (auto split: nat_diff_split)
  1112 
  1113 lemma Suc_pred': "0 < n ==> n = Suc(n - 1)"
  1114   by simp
  1115 
  1116 lemma add_eq_if: "(m::nat) + n = (if m=0 then n else Suc ((m - 1) + n))"
  1117   unfolding One_nat_def by (cases m) simp_all
  1118 
  1119 lemma mult_eq_if: "(m::nat) * n = (if m=0 then 0 else n + ((m - 1) * n))"
  1120   unfolding One_nat_def by (cases m) simp_all
  1121 
  1122 lemma Suc_diff_eq_diff_pred: "0 < n ==> Suc m - n = m - (n - 1)"
  1123   unfolding One_nat_def by (cases n) simp_all
  1124 
  1125 lemma diff_Suc_eq_diff_pred: "m - Suc n = (m - 1) - n"
  1126   unfolding One_nat_def by (cases m) simp_all
  1127 
  1128 lemma Let_Suc [simp]: "Let (Suc n) f == f (Suc n)"
  1129   by (fact Let_def)
  1130 
  1131 
  1132 subsubsection {* Monotonicity of Multiplication *}
  1133 
  1134 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1135 by (simp add: mult_right_mono)
  1136 
  1137 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1138 by (simp add: mult_left_mono)
  1139 
  1140 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1141 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1142 by (simp add: mult_mono)
  1143 
  1144 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1145 by (simp add: mult_strict_right_mono)
  1146 
  1147 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1148       there are no negative numbers.*}
  1149 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1150   apply (induct m)
  1151    apply simp
  1152   apply (case_tac n)
  1153    apply simp_all
  1154   done
  1155 
  1156 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1157   apply (induct m)
  1158    apply simp
  1159   apply (case_tac n)
  1160    apply simp_all
  1161   done
  1162 
  1163 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1164   apply (safe intro!: mult_less_mono1)
  1165   apply (cases k, auto)
  1166   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1167   apply (blast intro: mult_le_mono1)
  1168   done
  1169 
  1170 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1171 by (simp add: mult_commute [of k])
  1172 
  1173 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1174 by (simp add: linorder_not_less [symmetric], auto)
  1175 
  1176 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1177 by (simp add: linorder_not_less [symmetric], auto)
  1178 
  1179 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1180 by (subst mult_less_cancel1) simp
  1181 
  1182 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1183 by (subst mult_le_cancel1) simp
  1184 
  1185 lemma le_square: "m \<le> m * (m::nat)"
  1186   by (cases m) (auto intro: le_add1)
  1187 
  1188 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1189   by (cases m) (auto intro: le_add1)
  1190 
  1191 text {* Lemma for @{text gcd} *}
  1192 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1193   apply (drule sym)
  1194   apply (rule disjCI)
  1195   apply (rule nat_less_cases, erule_tac [2] _)
  1196    apply (drule_tac [2] mult_less_mono2)
  1197     apply (auto)
  1198   done
  1199 
  1200 text {* the lattice order on @{typ nat} *}
  1201 
  1202 instantiation nat :: distrib_lattice
  1203 begin
  1204 
  1205 definition
  1206   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1207 
  1208 definition
  1209   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1210 
  1211 instance by intro_classes
  1212   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1213     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1214 
  1215 end
  1216 
  1217 
  1218 subsection {* Natural operation of natural numbers on functions *}
  1219 
  1220 text {*
  1221   We use the same logical constant for the power operations on
  1222   functions and relations, in order to share the same syntax.
  1223 *}
  1224 
  1225 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1226 
  1227 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1228   "f ^^ n \<equiv> compow n f"
  1229 
  1230 notation (latex output)
  1231   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1232 
  1233 notation (HTML output)
  1234   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1235 
  1236 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1237 
  1238 overloading
  1239   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1240 begin
  1241 
  1242 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1243   "funpow 0 f = id"
  1244 | "funpow (Suc n) f = f o funpow n f"
  1245 
  1246 end
  1247 
  1248 text {* for code generation *}
  1249 
  1250 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1251   funpow_code_def [code_abbrev]: "funpow = compow"
  1252 
  1253 lemma [code]:
  1254   "funpow (Suc n) f = f o funpow n f"
  1255   "funpow 0 f = id"
  1256   by (simp_all add: funpow_code_def)
  1257 
  1258 hide_const (open) funpow
  1259 
  1260 lemma funpow_add:
  1261   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1262   by (induct m) simp_all
  1263 
  1264 lemma funpow_mult:
  1265   fixes f :: "'a \<Rightarrow> 'a"
  1266   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1267   by (induct n) (simp_all add: funpow_add)
  1268 
  1269 lemma funpow_swap1:
  1270   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1271 proof -
  1272   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1273   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1274   also have "\<dots> = (f ^^ n) (f x)" by simp
  1275   finally show ?thesis .
  1276 qed
  1277 
  1278 lemma comp_funpow:
  1279   fixes f :: "'a \<Rightarrow> 'a"
  1280   shows "comp f ^^ n = comp (f ^^ n)"
  1281   by (induct n) simp_all
  1282 
  1283 
  1284 subsection {* Kleene iteration *}
  1285 
  1286 lemma Kleene_iter_lpfp: assumes "mono f" and "f p \<le> p" shows "(f^^k) bot \<le> p"
  1287 proof(induction k)
  1288   case 0 show ?case by simp
  1289 next
  1290   case Suc
  1291   from monoD[OF assms(1) Suc] assms(2)
  1292   show ?case by simp
  1293 qed
  1294 
  1295 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1296 shows "lfp f = (f^^k) bot"
  1297 proof(rule antisym)
  1298   show "lfp f \<le> (f^^k) bot"
  1299   proof(rule lfp_lowerbound)
  1300     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1301   qed
  1302 next
  1303   show "(f^^k) bot \<le> lfp f"
  1304     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1305 qed
  1306 
  1307 
  1308 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1309 
  1310 context semiring_1
  1311 begin
  1312 
  1313 definition of_nat :: "nat \<Rightarrow> 'a" where
  1314   "of_nat n = (plus 1 ^^ n) 0"
  1315 
  1316 lemma of_nat_simps [simp]:
  1317   shows of_nat_0: "of_nat 0 = 0"
  1318     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1319   by (simp_all add: of_nat_def)
  1320 
  1321 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1322   by (simp add: of_nat_def)
  1323 
  1324 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1325   by (induct m) (simp_all add: add_ac)
  1326 
  1327 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1328   by (induct m) (simp_all add: add_ac left_distrib)
  1329 
  1330 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1331   "of_nat_aux inc 0 i = i"
  1332 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1333 
  1334 lemma of_nat_code:
  1335   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1336 proof (induct n)
  1337   case 0 then show ?case by simp
  1338 next
  1339   case (Suc n)
  1340   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1341     by (induct n) simp_all
  1342   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1343     by simp
  1344   with Suc show ?case by (simp add: add_commute)
  1345 qed
  1346 
  1347 end
  1348 
  1349 declare of_nat_code [code]
  1350 
  1351 text{*Class for unital semirings with characteristic zero.
  1352  Includes non-ordered rings like the complex numbers.*}
  1353 
  1354 class semiring_char_0 = semiring_1 +
  1355   assumes inj_of_nat: "inj of_nat"
  1356 begin
  1357 
  1358 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1359   by (auto intro: inj_of_nat injD)
  1360 
  1361 text{*Special cases where either operand is zero*}
  1362 
  1363 lemma of_nat_0_eq_iff [simp, no_atp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1364   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1365 
  1366 lemma of_nat_eq_0_iff [simp, no_atp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1367   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1368 
  1369 end
  1370 
  1371 context linordered_semidom
  1372 begin
  1373 
  1374 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1375   by (induct n) simp_all
  1376 
  1377 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1378   by (simp add: not_less)
  1379 
  1380 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1381   by (induct m n rule: diff_induct, simp_all add: add_pos_nonneg)
  1382 
  1383 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1384   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1385 
  1386 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1387   by simp
  1388 
  1389 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1390   by simp
  1391 
  1392 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1393 
  1394 subclass semiring_char_0 proof
  1395 qed (auto intro!: injI simp add: eq_iff)
  1396 
  1397 text{*Special cases where either operand is zero*}
  1398 
  1399 lemma of_nat_le_0_iff [simp, no_atp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1400   by (rule of_nat_le_iff [of _ 0, simplified])
  1401 
  1402 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1403   by (rule of_nat_less_iff [of 0, simplified])
  1404 
  1405 end
  1406 
  1407 context ring_1
  1408 begin
  1409 
  1410 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1411 by (simp add: algebra_simps of_nat_add [symmetric])
  1412 
  1413 end
  1414 
  1415 context linordered_idom
  1416 begin
  1417 
  1418 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1419   unfolding abs_if by auto
  1420 
  1421 end
  1422 
  1423 lemma of_nat_id [simp]: "of_nat n = n"
  1424   by (induct n) simp_all
  1425 
  1426 lemma of_nat_eq_id [simp]: "of_nat = id"
  1427   by (auto simp add: fun_eq_iff)
  1428 
  1429 
  1430 subsection {* The Set of Natural Numbers *}
  1431 
  1432 context semiring_1
  1433 begin
  1434 
  1435 definition Nats  :: "'a set" where
  1436   "Nats = range of_nat"
  1437 
  1438 notation (xsymbols)
  1439   Nats  ("\<nat>")
  1440 
  1441 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1442   by (simp add: Nats_def)
  1443 
  1444 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1445 apply (simp add: Nats_def)
  1446 apply (rule range_eqI)
  1447 apply (rule of_nat_0 [symmetric])
  1448 done
  1449 
  1450 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1451 apply (simp add: Nats_def)
  1452 apply (rule range_eqI)
  1453 apply (rule of_nat_1 [symmetric])
  1454 done
  1455 
  1456 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1457 apply (auto simp add: Nats_def)
  1458 apply (rule range_eqI)
  1459 apply (rule of_nat_add [symmetric])
  1460 done
  1461 
  1462 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1463 apply (auto simp add: Nats_def)
  1464 apply (rule range_eqI)
  1465 apply (rule of_nat_mult [symmetric])
  1466 done
  1467 
  1468 lemma Nats_cases [cases set: Nats]:
  1469   assumes "x \<in> \<nat>"
  1470   obtains (of_nat) n where "x = of_nat n"
  1471   unfolding Nats_def
  1472 proof -
  1473   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1474   then obtain n where "x = of_nat n" ..
  1475   then show thesis ..
  1476 qed
  1477 
  1478 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1479   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1480   by (rule Nats_cases) auto
  1481 
  1482 end
  1483 
  1484 
  1485 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1486 
  1487 lemma subst_equals:
  1488   assumes 1: "t = s" and 2: "u = t"
  1489   shows "u = s"
  1490   using 2 1 by (rule trans)
  1491 
  1492 setup Arith_Data.setup
  1493 
  1494 ML_file "Tools/nat_arith.ML"
  1495 
  1496 simproc_setup nateq_cancel_sums
  1497   ("(l::nat) + m = n" | "(l::nat) = m + n" | "Suc m = n" | "m = Suc n") =
  1498   {* fn phi => fn ss => try Nat_Arith.cancel_eq_conv *}
  1499 
  1500 simproc_setup natless_cancel_sums
  1501   ("(l::nat) + m < n" | "(l::nat) < m + n" | "Suc m < n" | "m < Suc n") =
  1502   {* fn phi => fn ss => try Nat_Arith.cancel_less_conv *}
  1503 
  1504 simproc_setup natle_cancel_sums
  1505   ("(l::nat) + m \<le> n" | "(l::nat) \<le> m + n" | "Suc m \<le> n" | "m \<le> Suc n") =
  1506   {* fn phi => fn ss => try Nat_Arith.cancel_le_conv *}
  1507 
  1508 simproc_setup natdiff_cancel_sums
  1509   ("(l::nat) + m - n" | "(l::nat) - (m + n)" | "Suc m - n" | "m - Suc n") =
  1510   {* fn phi => fn ss => try Nat_Arith.cancel_diff_conv *}
  1511 
  1512 ML_file "Tools/lin_arith.ML"
  1513 setup {* Lin_Arith.global_setup *}
  1514 declaration {* K Lin_Arith.setup *}
  1515 
  1516 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1517   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1518 (* Because of this simproc, the arithmetic solver is really only
  1519 useful to detect inconsistencies among the premises for subgoals which are
  1520 *not* themselves (in)equalities, because the latter activate
  1521 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1522 solver all the time rather than add the additional check. *)
  1523 
  1524 
  1525 lemmas [arith_split] = nat_diff_split split_min split_max
  1526 
  1527 context order
  1528 begin
  1529 
  1530 lemma lift_Suc_mono_le:
  1531   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1532   shows "f n \<le> f n'"
  1533 proof (cases "n < n'")
  1534   case True
  1535   thus ?thesis
  1536     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1537 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1538 
  1539 lemma lift_Suc_mono_less:
  1540   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1541   shows "f n < f n'"
  1542 using `n < n'`
  1543 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1544 
  1545 lemma lift_Suc_mono_less_iff:
  1546   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1547 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1548          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1549 
  1550 end
  1551 
  1552 lemma mono_iff_le_Suc: "mono f = (\<forall>n. f n \<le> f (Suc n))"
  1553   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1554 
  1555 lemma mono_nat_linear_lb:
  1556   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1557 apply(induct_tac k)
  1558  apply simp
  1559 apply(erule_tac x="m+n" in meta_allE)
  1560 apply(erule_tac x="Suc(m+n)" in meta_allE)
  1561 apply simp
  1562 done
  1563 
  1564 
  1565 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1566 
  1567 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1568 by arith
  1569 
  1570 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1571 by arith
  1572 
  1573 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1574 by arith
  1575 
  1576 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1577 by arith
  1578 
  1579 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1580 by arith
  1581 
  1582 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1583 by arith
  1584 
  1585 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1586   second premise n\<le>m*)
  1587 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1588 by arith
  1589 
  1590 text {* Simplification of relational expressions involving subtraction *}
  1591 
  1592 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1593 by (simp split add: nat_diff_split)
  1594 
  1595 hide_fact (open) diff_diff_eq
  1596 
  1597 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1598 by (auto split add: nat_diff_split)
  1599 
  1600 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1601 by (auto split add: nat_diff_split)
  1602 
  1603 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1604 by (auto split add: nat_diff_split)
  1605 
  1606 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1607 
  1608 (* Monotonicity of subtraction in first argument *)
  1609 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1610 by (simp split add: nat_diff_split)
  1611 
  1612 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1613 by (simp split add: nat_diff_split)
  1614 
  1615 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1616 by (simp split add: nat_diff_split)
  1617 
  1618 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1619 by (simp split add: nat_diff_split)
  1620 
  1621 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1622 by auto
  1623 
  1624 lemma inj_on_diff_nat: 
  1625   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1626   shows "inj_on (\<lambda>n. n - k) N"
  1627 proof (rule inj_onI)
  1628   fix x y
  1629   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1630   with k_le_n have "x - k + k = y - k + k" by auto
  1631   with a k_le_n show "x = y" by auto
  1632 qed
  1633 
  1634 text{*Rewriting to pull differences out*}
  1635 
  1636 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1637 by arith
  1638 
  1639 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1640 by arith
  1641 
  1642 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1643 by arith
  1644 
  1645 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1646 by simp
  1647 
  1648 (*The others are
  1649       i - j - k = i - (j + k),
  1650       k \<le> j ==> j - k + i = j + i - k,
  1651       k \<le> j ==> i + (j - k) = i + j - k *)
  1652 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1653 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1654 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1655 
  1656 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1657 Least_Suc}, since there appears to be no need.*}
  1658 
  1659 text{*Lemmas for ex/Factorization*}
  1660 
  1661 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1662 by (cases m) auto
  1663 
  1664 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1665 by (cases m) auto
  1666 
  1667 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1668 by (cases m) auto
  1669 
  1670 text {* Specialized induction principles that work "backwards": *}
  1671 
  1672 lemma inc_induct[consumes 1, case_names base step]:
  1673   assumes less: "i <= j"
  1674   assumes base: "P j"
  1675   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1676   shows "P i"
  1677   using less
  1678 proof (induct d=="j - i" arbitrary: i)
  1679   case (0 i)
  1680   hence "i = j" by simp
  1681   with base show ?case by simp
  1682 next
  1683   case (Suc d i)
  1684   hence "i < j" "P (Suc i)"
  1685     by simp_all
  1686   thus "P i" by (rule step)
  1687 qed
  1688 
  1689 lemma strict_inc_induct[consumes 1, case_names base step]:
  1690   assumes less: "i < j"
  1691   assumes base: "!!i. j = Suc i ==> P i"
  1692   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1693   shows "P i"
  1694   using less
  1695 proof (induct d=="j - i - 1" arbitrary: i)
  1696   case (0 i)
  1697   with `i < j` have "j = Suc i" by simp
  1698   with base show ?case by simp
  1699 next
  1700   case (Suc d i)
  1701   hence "i < j" "P (Suc i)"
  1702     by simp_all
  1703   thus "P i" by (rule step)
  1704 qed
  1705 
  1706 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1707   using inc_induct[of "k - i" k P, simplified] by blast
  1708 
  1709 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1710   using inc_induct[of 0 k P] by blast
  1711 
  1712 text {* Further induction rule similar to @{thm inc_induct} *}
  1713 
  1714 lemma dec_induct[consumes 1, case_names base step]:
  1715   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1716   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1717 
  1718  
  1719 subsection {* The divides relation on @{typ nat} *}
  1720 
  1721 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1722 unfolding dvd_def by simp
  1723 
  1724 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1725 by (simp add: dvd_def)
  1726 
  1727 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1728 by (simp add: dvd_def)
  1729 
  1730 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1731   unfolding dvd_def
  1732   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1733 
  1734 text {* @{term "op dvd"} is a partial order *}
  1735 
  1736 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1737   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1738 
  1739 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1740 unfolding dvd_def
  1741 by (blast intro: diff_mult_distrib2 [symmetric])
  1742 
  1743 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1744   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1745   apply (blast intro: dvd_add)
  1746   done
  1747 
  1748 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1749 by (drule_tac m = m in dvd_diff_nat, auto)
  1750 
  1751 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1752   apply (rule iffI)
  1753    apply (erule_tac [2] dvd_add)
  1754    apply (rule_tac [2] dvd_refl)
  1755   apply (subgoal_tac "n = (n+k) -k")
  1756    prefer 2 apply simp
  1757   apply (erule ssubst)
  1758   apply (erule dvd_diff_nat)
  1759   apply (rule dvd_refl)
  1760   done
  1761 
  1762 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1763   unfolding dvd_def
  1764   apply (erule exE)
  1765   apply (simp add: mult_ac)
  1766   done
  1767 
  1768 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1769   apply auto
  1770    apply (subgoal_tac "m*n dvd m*1")
  1771    apply (drule dvd_mult_cancel, auto)
  1772   done
  1773 
  1774 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1775   apply (subst mult_commute)
  1776   apply (erule dvd_mult_cancel1)
  1777   done
  1778 
  1779 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1780 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1781 
  1782 lemma nat_dvd_not_less:
  1783   fixes m n :: nat
  1784   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1785 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1786 
  1787 
  1788 subsection {* aliasses *}
  1789 
  1790 lemma nat_mult_1: "(1::nat) * n = n"
  1791   by simp
  1792  
  1793 lemma nat_mult_1_right: "n * (1::nat) = n"
  1794   by simp
  1795 
  1796 
  1797 subsection {* size of a datatype value *}
  1798 
  1799 class size =
  1800   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1801 
  1802 
  1803 subsection {* code module namespace *}
  1804 
  1805 code_modulename SML
  1806   Nat Arith
  1807 
  1808 code_modulename OCaml
  1809   Nat Arith
  1810 
  1811 code_modulename Haskell
  1812   Nat Arith
  1813 
  1814 hide_const (open) of_nat_aux
  1815 
  1816 end