src/HOL/Num.thy
author wenzelm
Wed Aug 22 22:55:41 2012 +0200 (2012-08-22)
changeset 48891 c0eafbd55de3
parent 47300 2284a40e0f57
child 49690 a6814de45b69
permissions -rw-r--r--
prefer ML_file over old uses;
     1 (*  Title:      HOL/Num.thy
     2     Author:     Florian Haftmann
     3     Author:     Brian Huffman
     4 *)
     5 
     6 header {* Binary Numerals *}
     7 
     8 theory Num
     9 imports Datatype
    10 begin
    11 
    12 subsection {* The @{text num} type *}
    13 
    14 datatype num = One | Bit0 num | Bit1 num
    15 
    16 text {* Increment function for type @{typ num} *}
    17 
    18 primrec inc :: "num \<Rightarrow> num" where
    19   "inc One = Bit0 One" |
    20   "inc (Bit0 x) = Bit1 x" |
    21   "inc (Bit1 x) = Bit0 (inc x)"
    22 
    23 text {* Converting between type @{typ num} and type @{typ nat} *}
    24 
    25 primrec nat_of_num :: "num \<Rightarrow> nat" where
    26   "nat_of_num One = Suc 0" |
    27   "nat_of_num (Bit0 x) = nat_of_num x + nat_of_num x" |
    28   "nat_of_num (Bit1 x) = Suc (nat_of_num x + nat_of_num x)"
    29 
    30 primrec num_of_nat :: "nat \<Rightarrow> num" where
    31   "num_of_nat 0 = One" |
    32   "num_of_nat (Suc n) = (if 0 < n then inc (num_of_nat n) else One)"
    33 
    34 lemma nat_of_num_pos: "0 < nat_of_num x"
    35   by (induct x) simp_all
    36 
    37 lemma nat_of_num_neq_0: " nat_of_num x \<noteq> 0"
    38   by (induct x) simp_all
    39 
    40 lemma nat_of_num_inc: "nat_of_num (inc x) = Suc (nat_of_num x)"
    41   by (induct x) simp_all
    42 
    43 lemma num_of_nat_double:
    44   "0 < n \<Longrightarrow> num_of_nat (n + n) = Bit0 (num_of_nat n)"
    45   by (induct n) simp_all
    46 
    47 text {*
    48   Type @{typ num} is isomorphic to the strictly positive
    49   natural numbers.
    50 *}
    51 
    52 lemma nat_of_num_inverse: "num_of_nat (nat_of_num x) = x"
    53   by (induct x) (simp_all add: num_of_nat_double nat_of_num_pos)
    54 
    55 lemma num_of_nat_inverse: "0 < n \<Longrightarrow> nat_of_num (num_of_nat n) = n"
    56   by (induct n) (simp_all add: nat_of_num_inc)
    57 
    58 lemma num_eq_iff: "x = y \<longleftrightarrow> nat_of_num x = nat_of_num y"
    59   apply safe
    60   apply (drule arg_cong [where f=num_of_nat])
    61   apply (simp add: nat_of_num_inverse)
    62   done
    63 
    64 lemma num_induct [case_names One inc]:
    65   fixes P :: "num \<Rightarrow> bool"
    66   assumes One: "P One"
    67     and inc: "\<And>x. P x \<Longrightarrow> P (inc x)"
    68   shows "P x"
    69 proof -
    70   obtain n where n: "Suc n = nat_of_num x"
    71     by (cases "nat_of_num x", simp_all add: nat_of_num_neq_0)
    72   have "P (num_of_nat (Suc n))"
    73   proof (induct n)
    74     case 0 show ?case using One by simp
    75   next
    76     case (Suc n)
    77     then have "P (inc (num_of_nat (Suc n)))" by (rule inc)
    78     then show "P (num_of_nat (Suc (Suc n)))" by simp
    79   qed
    80   with n show "P x"
    81     by (simp add: nat_of_num_inverse)
    82 qed
    83 
    84 text {*
    85   From now on, there are two possible models for @{typ num}:
    86   as positive naturals (rule @{text "num_induct"})
    87   and as digit representation (rules @{text "num.induct"}, @{text "num.cases"}).
    88 *}
    89 
    90 
    91 subsection {* Numeral operations *}
    92 
    93 instantiation num :: "{plus,times,linorder}"
    94 begin
    95 
    96 definition [code del]:
    97   "m + n = num_of_nat (nat_of_num m + nat_of_num n)"
    98 
    99 definition [code del]:
   100   "m * n = num_of_nat (nat_of_num m * nat_of_num n)"
   101 
   102 definition [code del]:
   103   "m \<le> n \<longleftrightarrow> nat_of_num m \<le> nat_of_num n"
   104 
   105 definition [code del]:
   106   "m < n \<longleftrightarrow> nat_of_num m < nat_of_num n"
   107 
   108 instance
   109   by (default, auto simp add: less_num_def less_eq_num_def num_eq_iff)
   110 
   111 end
   112 
   113 lemma nat_of_num_add: "nat_of_num (x + y) = nat_of_num x + nat_of_num y"
   114   unfolding plus_num_def
   115   by (intro num_of_nat_inverse add_pos_pos nat_of_num_pos)
   116 
   117 lemma nat_of_num_mult: "nat_of_num (x * y) = nat_of_num x * nat_of_num y"
   118   unfolding times_num_def
   119   by (intro num_of_nat_inverse mult_pos_pos nat_of_num_pos)
   120 
   121 lemma add_num_simps [simp, code]:
   122   "One + One = Bit0 One"
   123   "One + Bit0 n = Bit1 n"
   124   "One + Bit1 n = Bit0 (n + One)"
   125   "Bit0 m + One = Bit1 m"
   126   "Bit0 m + Bit0 n = Bit0 (m + n)"
   127   "Bit0 m + Bit1 n = Bit1 (m + n)"
   128   "Bit1 m + One = Bit0 (m + One)"
   129   "Bit1 m + Bit0 n = Bit1 (m + n)"
   130   "Bit1 m + Bit1 n = Bit0 (m + n + One)"
   131   by (simp_all add: num_eq_iff nat_of_num_add)
   132 
   133 lemma mult_num_simps [simp, code]:
   134   "m * One = m"
   135   "One * n = n"
   136   "Bit0 m * Bit0 n = Bit0 (Bit0 (m * n))"
   137   "Bit0 m * Bit1 n = Bit0 (m * Bit1 n)"
   138   "Bit1 m * Bit0 n = Bit0 (Bit1 m * n)"
   139   "Bit1 m * Bit1 n = Bit1 (m + n + Bit0 (m * n))"
   140   by (simp_all add: num_eq_iff nat_of_num_add
   141     nat_of_num_mult left_distrib right_distrib)
   142 
   143 lemma eq_num_simps:
   144   "One = One \<longleftrightarrow> True"
   145   "One = Bit0 n \<longleftrightarrow> False"
   146   "One = Bit1 n \<longleftrightarrow> False"
   147   "Bit0 m = One \<longleftrightarrow> False"
   148   "Bit1 m = One \<longleftrightarrow> False"
   149   "Bit0 m = Bit0 n \<longleftrightarrow> m = n"
   150   "Bit0 m = Bit1 n \<longleftrightarrow> False"
   151   "Bit1 m = Bit0 n \<longleftrightarrow> False"
   152   "Bit1 m = Bit1 n \<longleftrightarrow> m = n"
   153   by simp_all
   154 
   155 lemma le_num_simps [simp, code]:
   156   "One \<le> n \<longleftrightarrow> True"
   157   "Bit0 m \<le> One \<longleftrightarrow> False"
   158   "Bit1 m \<le> One \<longleftrightarrow> False"
   159   "Bit0 m \<le> Bit0 n \<longleftrightarrow> m \<le> n"
   160   "Bit0 m \<le> Bit1 n \<longleftrightarrow> m \<le> n"
   161   "Bit1 m \<le> Bit1 n \<longleftrightarrow> m \<le> n"
   162   "Bit1 m \<le> Bit0 n \<longleftrightarrow> m < n"
   163   using nat_of_num_pos [of n] nat_of_num_pos [of m]
   164   by (auto simp add: less_eq_num_def less_num_def)
   165 
   166 lemma less_num_simps [simp, code]:
   167   "m < One \<longleftrightarrow> False"
   168   "One < Bit0 n \<longleftrightarrow> True"
   169   "One < Bit1 n \<longleftrightarrow> True"
   170   "Bit0 m < Bit0 n \<longleftrightarrow> m < n"
   171   "Bit0 m < Bit1 n \<longleftrightarrow> m \<le> n"
   172   "Bit1 m < Bit1 n \<longleftrightarrow> m < n"
   173   "Bit1 m < Bit0 n \<longleftrightarrow> m < n"
   174   using nat_of_num_pos [of n] nat_of_num_pos [of m]
   175   by (auto simp add: less_eq_num_def less_num_def)
   176 
   177 text {* Rules using @{text One} and @{text inc} as constructors *}
   178 
   179 lemma add_One: "x + One = inc x"
   180   by (simp add: num_eq_iff nat_of_num_add nat_of_num_inc)
   181 
   182 lemma add_One_commute: "One + n = n + One"
   183   by (induct n) simp_all
   184 
   185 lemma add_inc: "x + inc y = inc (x + y)"
   186   by (simp add: num_eq_iff nat_of_num_add nat_of_num_inc)
   187 
   188 lemma mult_inc: "x * inc y = x * y + x"
   189   by (simp add: num_eq_iff nat_of_num_mult nat_of_num_add nat_of_num_inc)
   190 
   191 text {* The @{const num_of_nat} conversion *}
   192 
   193 lemma num_of_nat_One:
   194   "n \<le> 1 \<Longrightarrow> num_of_nat n = One"
   195   by (cases n) simp_all
   196 
   197 lemma num_of_nat_plus_distrib:
   198   "0 < m \<Longrightarrow> 0 < n \<Longrightarrow> num_of_nat (m + n) = num_of_nat m + num_of_nat n"
   199   by (induct n) (auto simp add: add_One add_One_commute add_inc)
   200 
   201 text {* A double-and-decrement function *}
   202 
   203 primrec BitM :: "num \<Rightarrow> num" where
   204   "BitM One = One" |
   205   "BitM (Bit0 n) = Bit1 (BitM n)" |
   206   "BitM (Bit1 n) = Bit1 (Bit0 n)"
   207 
   208 lemma BitM_plus_one: "BitM n + One = Bit0 n"
   209   by (induct n) simp_all
   210 
   211 lemma one_plus_BitM: "One + BitM n = Bit0 n"
   212   unfolding add_One_commute BitM_plus_one ..
   213 
   214 text {* Squaring and exponentiation *}
   215 
   216 primrec sqr :: "num \<Rightarrow> num" where
   217   "sqr One = One" |
   218   "sqr (Bit0 n) = Bit0 (Bit0 (sqr n))" |
   219   "sqr (Bit1 n) = Bit1 (Bit0 (sqr n + n))"
   220 
   221 primrec pow :: "num \<Rightarrow> num \<Rightarrow> num" where
   222   "pow x One = x" |
   223   "pow x (Bit0 y) = sqr (pow x y)" |
   224   "pow x (Bit1 y) = sqr (pow x y) * x"
   225 
   226 lemma nat_of_num_sqr: "nat_of_num (sqr x) = nat_of_num x * nat_of_num x"
   227   by (induct x, simp_all add: algebra_simps nat_of_num_add)
   228 
   229 lemma sqr_conv_mult: "sqr x = x * x"
   230   by (simp add: num_eq_iff nat_of_num_sqr nat_of_num_mult)
   231 
   232 
   233 subsection {* Binary numerals *}
   234 
   235 text {*
   236   We embed binary representations into a generic algebraic
   237   structure using @{text numeral}.
   238 *}
   239 
   240 class numeral = one + semigroup_add
   241 begin
   242 
   243 primrec numeral :: "num \<Rightarrow> 'a" where
   244   numeral_One: "numeral One = 1" |
   245   numeral_Bit0: "numeral (Bit0 n) = numeral n + numeral n" |
   246   numeral_Bit1: "numeral (Bit1 n) = numeral n + numeral n + 1"
   247 
   248 lemma one_plus_numeral_commute: "1 + numeral x = numeral x + 1"
   249   apply (induct x)
   250   apply simp
   251   apply (simp add: add_assoc [symmetric], simp add: add_assoc)
   252   apply (simp add: add_assoc [symmetric], simp add: add_assoc)
   253   done
   254 
   255 lemma numeral_inc: "numeral (inc x) = numeral x + 1"
   256 proof (induct x)
   257   case (Bit1 x)
   258   have "numeral x + (1 + numeral x) + 1 = numeral x + (numeral x + 1) + 1"
   259     by (simp only: one_plus_numeral_commute)
   260   with Bit1 show ?case
   261     by (simp add: add_assoc)
   262 qed simp_all
   263 
   264 declare numeral.simps [simp del]
   265 
   266 abbreviation "Numeral1 \<equiv> numeral One"
   267 
   268 declare numeral_One [code_post]
   269 
   270 end
   271 
   272 text {* Negative numerals. *}
   273 
   274 class neg_numeral = numeral + group_add
   275 begin
   276 
   277 definition neg_numeral :: "num \<Rightarrow> 'a" where
   278   "neg_numeral k = - numeral k"
   279 
   280 end
   281 
   282 text {* Numeral syntax. *}
   283 
   284 syntax
   285   "_Numeral" :: "num_const \<Rightarrow> 'a"    ("_")
   286 
   287 parse_translation {*
   288 let
   289   fun num_of_int n = if n > 0 then case IntInf.quotRem (n, 2)
   290      of (0, 1) => Syntax.const @{const_name One}
   291       | (n, 0) => Syntax.const @{const_name Bit0} $ num_of_int n
   292       | (n, 1) => Syntax.const @{const_name Bit1} $ num_of_int n
   293     else raise Match;
   294   val pos = Syntax.const @{const_name numeral}
   295   val neg = Syntax.const @{const_name neg_numeral}
   296   val one = Syntax.const @{const_name Groups.one}
   297   val zero = Syntax.const @{const_name Groups.zero}
   298   fun numeral_tr [(c as Const (@{syntax_const "_constrain"}, _)) $ t $ u] =
   299         c $ numeral_tr [t] $ u
   300     | numeral_tr [Const (num, _)] =
   301         let
   302           val {value, ...} = Lexicon.read_xnum num;
   303         in
   304           if value = 0 then zero else
   305           if value > 0
   306           then pos $ num_of_int value
   307           else neg $ num_of_int (~value)
   308         end
   309     | numeral_tr ts = raise TERM ("numeral_tr", ts);
   310 in [("_Numeral", numeral_tr)] end
   311 *}
   312 
   313 typed_print_translation (advanced) {*
   314 let
   315   fun dest_num (Const (@{const_syntax Bit0}, _) $ n) = 2 * dest_num n
   316     | dest_num (Const (@{const_syntax Bit1}, _) $ n) = 2 * dest_num n + 1
   317     | dest_num (Const (@{const_syntax One}, _)) = 1;
   318   fun num_tr' sign ctxt T [n] =
   319     let
   320       val k = dest_num n;
   321       val t' = Syntax.const @{syntax_const "_Numeral"} $
   322         Syntax.free (sign ^ string_of_int k);
   323     in
   324       case T of
   325         Type (@{type_name fun}, [_, T']) =>
   326           if not (Config.get ctxt show_types) andalso can Term.dest_Type T' then t'
   327           else Syntax.const @{syntax_const "_constrain"} $ t' $ Syntax_Phases.term_of_typ ctxt T'
   328       | T' => if T' = dummyT then t' else raise Match
   329     end;
   330 in [(@{const_syntax numeral}, num_tr' ""),
   331     (@{const_syntax neg_numeral}, num_tr' "-")] end
   332 *}
   333 
   334 ML_file "Tools/numeral.ML"
   335 
   336 
   337 subsection {* Class-specific numeral rules *}
   338 
   339 text {*
   340   @{const numeral} is a morphism.
   341 *}
   342 
   343 subsubsection {* Structures with addition: class @{text numeral} *}
   344 
   345 context numeral
   346 begin
   347 
   348 lemma numeral_add: "numeral (m + n) = numeral m + numeral n"
   349   by (induct n rule: num_induct)
   350      (simp_all only: numeral_One add_One add_inc numeral_inc add_assoc)
   351 
   352 lemma numeral_plus_numeral: "numeral m + numeral n = numeral (m + n)"
   353   by (rule numeral_add [symmetric])
   354 
   355 lemma numeral_plus_one: "numeral n + 1 = numeral (n + One)"
   356   using numeral_add [of n One] by (simp add: numeral_One)
   357 
   358 lemma one_plus_numeral: "1 + numeral n = numeral (One + n)"
   359   using numeral_add [of One n] by (simp add: numeral_One)
   360 
   361 lemma one_add_one: "1 + 1 = 2"
   362   using numeral_add [of One One] by (simp add: numeral_One)
   363 
   364 lemmas add_numeral_special =
   365   numeral_plus_one one_plus_numeral one_add_one
   366 
   367 end
   368 
   369 subsubsection {*
   370   Structures with negation: class @{text neg_numeral}
   371 *}
   372 
   373 context neg_numeral
   374 begin
   375 
   376 text {* Numerals form an abelian subgroup. *}
   377 
   378 inductive is_num :: "'a \<Rightarrow> bool" where
   379   "is_num 1" |
   380   "is_num x \<Longrightarrow> is_num (- x)" |
   381   "\<lbrakk>is_num x; is_num y\<rbrakk> \<Longrightarrow> is_num (x + y)"
   382 
   383 lemma is_num_numeral: "is_num (numeral k)"
   384   by (induct k, simp_all add: numeral.simps is_num.intros)
   385 
   386 lemma is_num_add_commute:
   387   "\<lbrakk>is_num x; is_num y\<rbrakk> \<Longrightarrow> x + y = y + x"
   388   apply (induct x rule: is_num.induct)
   389   apply (induct y rule: is_num.induct)
   390   apply simp
   391   apply (rule_tac a=x in add_left_imp_eq)
   392   apply (rule_tac a=x in add_right_imp_eq)
   393   apply (simp add: add_assoc minus_add_cancel)
   394   apply (simp add: add_assoc [symmetric], simp add: add_assoc)
   395   apply (rule_tac a=x in add_left_imp_eq)
   396   apply (rule_tac a=x in add_right_imp_eq)
   397   apply (simp add: add_assoc minus_add_cancel add_minus_cancel)
   398   apply (simp add: add_assoc, simp add: add_assoc [symmetric])
   399   done
   400 
   401 lemma is_num_add_left_commute:
   402   "\<lbrakk>is_num x; is_num y\<rbrakk> \<Longrightarrow> x + (y + z) = y + (x + z)"
   403   by (simp only: add_assoc [symmetric] is_num_add_commute)
   404 
   405 lemmas is_num_normalize =
   406   add_assoc is_num_add_commute is_num_add_left_commute
   407   is_num.intros is_num_numeral
   408   diff_minus minus_add add_minus_cancel minus_add_cancel
   409 
   410 definition dbl :: "'a \<Rightarrow> 'a" where "dbl x = x + x"
   411 definition dbl_inc :: "'a \<Rightarrow> 'a" where "dbl_inc x = x + x + 1"
   412 definition dbl_dec :: "'a \<Rightarrow> 'a" where "dbl_dec x = x + x - 1"
   413 
   414 definition sub :: "num \<Rightarrow> num \<Rightarrow> 'a" where
   415   "sub k l = numeral k - numeral l"
   416 
   417 lemma numeral_BitM: "numeral (BitM n) = numeral (Bit0 n) - 1"
   418   by (simp only: BitM_plus_one [symmetric] numeral_add numeral_One eq_diff_eq)
   419 
   420 lemma dbl_simps [simp]:
   421   "dbl (neg_numeral k) = neg_numeral (Bit0 k)"
   422   "dbl 0 = 0"
   423   "dbl 1 = 2"
   424   "dbl (numeral k) = numeral (Bit0 k)"
   425   unfolding dbl_def neg_numeral_def numeral.simps
   426   by (simp_all add: minus_add)
   427 
   428 lemma dbl_inc_simps [simp]:
   429   "dbl_inc (neg_numeral k) = neg_numeral (BitM k)"
   430   "dbl_inc 0 = 1"
   431   "dbl_inc 1 = 3"
   432   "dbl_inc (numeral k) = numeral (Bit1 k)"
   433   unfolding dbl_inc_def neg_numeral_def numeral.simps numeral_BitM
   434   by (simp_all add: is_num_normalize)
   435 
   436 lemma dbl_dec_simps [simp]:
   437   "dbl_dec (neg_numeral k) = neg_numeral (Bit1 k)"
   438   "dbl_dec 0 = -1"
   439   "dbl_dec 1 = 1"
   440   "dbl_dec (numeral k) = numeral (BitM k)"
   441   unfolding dbl_dec_def neg_numeral_def numeral.simps numeral_BitM
   442   by (simp_all add: is_num_normalize)
   443 
   444 lemma sub_num_simps [simp]:
   445   "sub One One = 0"
   446   "sub One (Bit0 l) = neg_numeral (BitM l)"
   447   "sub One (Bit1 l) = neg_numeral (Bit0 l)"
   448   "sub (Bit0 k) One = numeral (BitM k)"
   449   "sub (Bit1 k) One = numeral (Bit0 k)"
   450   "sub (Bit0 k) (Bit0 l) = dbl (sub k l)"
   451   "sub (Bit0 k) (Bit1 l) = dbl_dec (sub k l)"
   452   "sub (Bit1 k) (Bit0 l) = dbl_inc (sub k l)"
   453   "sub (Bit1 k) (Bit1 l) = dbl (sub k l)"
   454   unfolding dbl_def dbl_dec_def dbl_inc_def sub_def
   455   unfolding neg_numeral_def numeral.simps numeral_BitM
   456   by (simp_all add: is_num_normalize)
   457 
   458 lemma add_neg_numeral_simps:
   459   "numeral m + neg_numeral n = sub m n"
   460   "neg_numeral m + numeral n = sub n m"
   461   "neg_numeral m + neg_numeral n = neg_numeral (m + n)"
   462   unfolding sub_def diff_minus neg_numeral_def numeral_add numeral.simps
   463   by (simp_all add: is_num_normalize)
   464 
   465 lemma add_neg_numeral_special:
   466   "1 + neg_numeral m = sub One m"
   467   "neg_numeral m + 1 = sub One m"
   468   unfolding sub_def diff_minus neg_numeral_def numeral_add numeral.simps
   469   by (simp_all add: is_num_normalize)
   470 
   471 lemma diff_numeral_simps:
   472   "numeral m - numeral n = sub m n"
   473   "numeral m - neg_numeral n = numeral (m + n)"
   474   "neg_numeral m - numeral n = neg_numeral (m + n)"
   475   "neg_numeral m - neg_numeral n = sub n m"
   476   unfolding neg_numeral_def sub_def diff_minus numeral_add numeral.simps
   477   by (simp_all add: is_num_normalize)
   478 
   479 lemma diff_numeral_special:
   480   "1 - numeral n = sub One n"
   481   "1 - neg_numeral n = numeral (One + n)"
   482   "numeral m - 1 = sub m One"
   483   "neg_numeral m - 1 = neg_numeral (m + One)"
   484   unfolding neg_numeral_def sub_def diff_minus numeral_add numeral.simps
   485   by (simp_all add: is_num_normalize)
   486 
   487 lemma minus_one: "- 1 = -1"
   488   unfolding neg_numeral_def numeral.simps ..
   489 
   490 lemma minus_numeral: "- numeral n = neg_numeral n"
   491   unfolding neg_numeral_def ..
   492 
   493 lemma minus_neg_numeral: "- neg_numeral n = numeral n"
   494   unfolding neg_numeral_def by simp
   495 
   496 lemmas minus_numeral_simps [simp] =
   497   minus_one minus_numeral minus_neg_numeral
   498 
   499 end
   500 
   501 subsubsection {*
   502   Structures with multiplication: class @{text semiring_numeral}
   503 *}
   504 
   505 class semiring_numeral = semiring + monoid_mult
   506 begin
   507 
   508 subclass numeral ..
   509 
   510 lemma numeral_mult: "numeral (m * n) = numeral m * numeral n"
   511   apply (induct n rule: num_induct)
   512   apply (simp add: numeral_One)
   513   apply (simp add: mult_inc numeral_inc numeral_add right_distrib)
   514   done
   515 
   516 lemma numeral_times_numeral: "numeral m * numeral n = numeral (m * n)"
   517   by (rule numeral_mult [symmetric])
   518 
   519 end
   520 
   521 subsubsection {*
   522   Structures with a zero: class @{text semiring_1}
   523 *}
   524 
   525 context semiring_1
   526 begin
   527 
   528 subclass semiring_numeral ..
   529 
   530 lemma of_nat_numeral [simp]: "of_nat (numeral n) = numeral n"
   531   by (induct n,
   532     simp_all only: numeral.simps numeral_class.numeral.simps of_nat_add of_nat_1)
   533 
   534 lemma mult_2: "2 * z = z + z"
   535   unfolding one_add_one [symmetric] left_distrib by simp
   536 
   537 lemma mult_2_right: "z * 2 = z + z"
   538   unfolding one_add_one [symmetric] right_distrib by simp
   539 
   540 end
   541 
   542 lemma nat_of_num_numeral: "nat_of_num = numeral"
   543 proof
   544   fix n
   545   have "numeral n = nat_of_num n"
   546     by (induct n) (simp_all add: numeral.simps)
   547   then show "nat_of_num n = numeral n" by simp
   548 qed
   549 
   550 subsubsection {*
   551   Equality: class @{text semiring_char_0}
   552 *}
   553 
   554 context semiring_char_0
   555 begin
   556 
   557 lemma numeral_eq_iff: "numeral m = numeral n \<longleftrightarrow> m = n"
   558   unfolding of_nat_numeral [symmetric] nat_of_num_numeral [symmetric]
   559     of_nat_eq_iff num_eq_iff ..
   560 
   561 lemma numeral_eq_one_iff: "numeral n = 1 \<longleftrightarrow> n = One"
   562   by (rule numeral_eq_iff [of n One, unfolded numeral_One])
   563 
   564 lemma one_eq_numeral_iff: "1 = numeral n \<longleftrightarrow> One = n"
   565   by (rule numeral_eq_iff [of One n, unfolded numeral_One])
   566 
   567 lemma numeral_neq_zero: "numeral n \<noteq> 0"
   568   unfolding of_nat_numeral [symmetric] nat_of_num_numeral [symmetric]
   569   by (simp add: nat_of_num_pos)
   570 
   571 lemma zero_neq_numeral: "0 \<noteq> numeral n"
   572   unfolding eq_commute [of 0] by (rule numeral_neq_zero)
   573 
   574 lemmas eq_numeral_simps [simp] =
   575   numeral_eq_iff
   576   numeral_eq_one_iff
   577   one_eq_numeral_iff
   578   numeral_neq_zero
   579   zero_neq_numeral
   580 
   581 end
   582 
   583 subsubsection {*
   584   Comparisons: class @{text linordered_semidom}
   585 *}
   586 
   587 text {*  Could be perhaps more general than here. *}
   588 
   589 context linordered_semidom
   590 begin
   591 
   592 lemma numeral_le_iff: "numeral m \<le> numeral n \<longleftrightarrow> m \<le> n"
   593 proof -
   594   have "of_nat (numeral m) \<le> of_nat (numeral n) \<longleftrightarrow> m \<le> n"
   595     unfolding less_eq_num_def nat_of_num_numeral of_nat_le_iff ..
   596   then show ?thesis by simp
   597 qed
   598 
   599 lemma one_le_numeral: "1 \<le> numeral n"
   600 using numeral_le_iff [of One n] by (simp add: numeral_One)
   601 
   602 lemma numeral_le_one_iff: "numeral n \<le> 1 \<longleftrightarrow> n \<le> One"
   603 using numeral_le_iff [of n One] by (simp add: numeral_One)
   604 
   605 lemma numeral_less_iff: "numeral m < numeral n \<longleftrightarrow> m < n"
   606 proof -
   607   have "of_nat (numeral m) < of_nat (numeral n) \<longleftrightarrow> m < n"
   608     unfolding less_num_def nat_of_num_numeral of_nat_less_iff ..
   609   then show ?thesis by simp
   610 qed
   611 
   612 lemma not_numeral_less_one: "\<not> numeral n < 1"
   613   using numeral_less_iff [of n One] by (simp add: numeral_One)
   614 
   615 lemma one_less_numeral_iff: "1 < numeral n \<longleftrightarrow> One < n"
   616   using numeral_less_iff [of One n] by (simp add: numeral_One)
   617 
   618 lemma zero_le_numeral: "0 \<le> numeral n"
   619   by (induct n) (simp_all add: numeral.simps)
   620 
   621 lemma zero_less_numeral: "0 < numeral n"
   622   by (induct n) (simp_all add: numeral.simps add_pos_pos)
   623 
   624 lemma not_numeral_le_zero: "\<not> numeral n \<le> 0"
   625   by (simp add: not_le zero_less_numeral)
   626 
   627 lemma not_numeral_less_zero: "\<not> numeral n < 0"
   628   by (simp add: not_less zero_le_numeral)
   629 
   630 lemmas le_numeral_extra =
   631   zero_le_one not_one_le_zero
   632   order_refl [of 0] order_refl [of 1]
   633 
   634 lemmas less_numeral_extra =
   635   zero_less_one not_one_less_zero
   636   less_irrefl [of 0] less_irrefl [of 1]
   637 
   638 lemmas le_numeral_simps [simp] =
   639   numeral_le_iff
   640   one_le_numeral
   641   numeral_le_one_iff
   642   zero_le_numeral
   643   not_numeral_le_zero
   644 
   645 lemmas less_numeral_simps [simp] =
   646   numeral_less_iff
   647   one_less_numeral_iff
   648   not_numeral_less_one
   649   zero_less_numeral
   650   not_numeral_less_zero
   651 
   652 end
   653 
   654 subsubsection {*
   655   Multiplication and negation: class @{text ring_1}
   656 *}
   657 
   658 context ring_1
   659 begin
   660 
   661 subclass neg_numeral ..
   662 
   663 lemma mult_neg_numeral_simps:
   664   "neg_numeral m * neg_numeral n = numeral (m * n)"
   665   "neg_numeral m * numeral n = neg_numeral (m * n)"
   666   "numeral m * neg_numeral n = neg_numeral (m * n)"
   667   unfolding neg_numeral_def mult_minus_left mult_minus_right
   668   by (simp_all only: minus_minus numeral_mult)
   669 
   670 lemma mult_minus1 [simp]: "-1 * z = - z"
   671   unfolding neg_numeral_def numeral.simps mult_minus_left by simp
   672 
   673 lemma mult_minus1_right [simp]: "z * -1 = - z"
   674   unfolding neg_numeral_def numeral.simps mult_minus_right by simp
   675 
   676 end
   677 
   678 subsubsection {*
   679   Equality using @{text iszero} for rings with non-zero characteristic
   680 *}
   681 
   682 context ring_1
   683 begin
   684 
   685 definition iszero :: "'a \<Rightarrow> bool"
   686   where "iszero z \<longleftrightarrow> z = 0"
   687 
   688 lemma iszero_0 [simp]: "iszero 0"
   689   by (simp add: iszero_def)
   690 
   691 lemma not_iszero_1 [simp]: "\<not> iszero 1"
   692   by (simp add: iszero_def)
   693 
   694 lemma not_iszero_Numeral1: "\<not> iszero Numeral1"
   695   by (simp add: numeral_One)
   696 
   697 lemma iszero_neg_numeral [simp]:
   698   "iszero (neg_numeral w) \<longleftrightarrow> iszero (numeral w)"
   699   unfolding iszero_def neg_numeral_def
   700   by (rule neg_equal_0_iff_equal)
   701 
   702 lemma eq_iff_iszero_diff: "x = y \<longleftrightarrow> iszero (x - y)"
   703   unfolding iszero_def by (rule eq_iff_diff_eq_0)
   704 
   705 text {* The @{text "eq_numeral_iff_iszero"} lemmas are not declared
   706 @{text "[simp]"} by default, because for rings of characteristic zero,
   707 better simp rules are possible. For a type like integers mod @{text
   708 "n"}, type-instantiated versions of these rules should be added to the
   709 simplifier, along with a type-specific rule for deciding propositions
   710 of the form @{text "iszero (numeral w)"}.
   711 
   712 bh: Maybe it would not be so bad to just declare these as simp
   713 rules anyway? I should test whether these rules take precedence over
   714 the @{text "ring_char_0"} rules in the simplifier.
   715 *}
   716 
   717 lemma eq_numeral_iff_iszero:
   718   "numeral x = numeral y \<longleftrightarrow> iszero (sub x y)"
   719   "numeral x = neg_numeral y \<longleftrightarrow> iszero (numeral (x + y))"
   720   "neg_numeral x = numeral y \<longleftrightarrow> iszero (numeral (x + y))"
   721   "neg_numeral x = neg_numeral y \<longleftrightarrow> iszero (sub y x)"
   722   "numeral x = 1 \<longleftrightarrow> iszero (sub x One)"
   723   "1 = numeral y \<longleftrightarrow> iszero (sub One y)"
   724   "neg_numeral x = 1 \<longleftrightarrow> iszero (numeral (x + One))"
   725   "1 = neg_numeral y \<longleftrightarrow> iszero (numeral (One + y))"
   726   "numeral x = 0 \<longleftrightarrow> iszero (numeral x)"
   727   "0 = numeral y \<longleftrightarrow> iszero (numeral y)"
   728   "neg_numeral x = 0 \<longleftrightarrow> iszero (numeral x)"
   729   "0 = neg_numeral y \<longleftrightarrow> iszero (numeral y)"
   730   unfolding eq_iff_iszero_diff diff_numeral_simps diff_numeral_special
   731   by simp_all
   732 
   733 end
   734 
   735 subsubsection {*
   736   Equality and negation: class @{text ring_char_0}
   737 *}
   738 
   739 class ring_char_0 = ring_1 + semiring_char_0
   740 begin
   741 
   742 lemma not_iszero_numeral [simp]: "\<not> iszero (numeral w)"
   743   by (simp add: iszero_def)
   744 
   745 lemma neg_numeral_eq_iff: "neg_numeral m = neg_numeral n \<longleftrightarrow> m = n"
   746   by (simp only: neg_numeral_def neg_equal_iff_equal numeral_eq_iff)
   747 
   748 lemma numeral_neq_neg_numeral: "numeral m \<noteq> neg_numeral n"
   749   unfolding neg_numeral_def eq_neg_iff_add_eq_0
   750   by (simp add: numeral_plus_numeral)
   751 
   752 lemma neg_numeral_neq_numeral: "neg_numeral m \<noteq> numeral n"
   753   by (rule numeral_neq_neg_numeral [symmetric])
   754 
   755 lemma zero_neq_neg_numeral: "0 \<noteq> neg_numeral n"
   756   unfolding neg_numeral_def neg_0_equal_iff_equal by simp
   757 
   758 lemma neg_numeral_neq_zero: "neg_numeral n \<noteq> 0"
   759   unfolding neg_numeral_def neg_equal_0_iff_equal by simp
   760 
   761 lemma one_neq_neg_numeral: "1 \<noteq> neg_numeral n"
   762   using numeral_neq_neg_numeral [of One n] by (simp add: numeral_One)
   763 
   764 lemma neg_numeral_neq_one: "neg_numeral n \<noteq> 1"
   765   using neg_numeral_neq_numeral [of n One] by (simp add: numeral_One)
   766 
   767 lemmas eq_neg_numeral_simps [simp] =
   768   neg_numeral_eq_iff
   769   numeral_neq_neg_numeral neg_numeral_neq_numeral
   770   one_neq_neg_numeral neg_numeral_neq_one
   771   zero_neq_neg_numeral neg_numeral_neq_zero
   772 
   773 end
   774 
   775 subsubsection {*
   776   Structures with negation and order: class @{text linordered_idom}
   777 *}
   778 
   779 context linordered_idom
   780 begin
   781 
   782 subclass ring_char_0 ..
   783 
   784 lemma neg_numeral_le_iff: "neg_numeral m \<le> neg_numeral n \<longleftrightarrow> n \<le> m"
   785   by (simp only: neg_numeral_def neg_le_iff_le numeral_le_iff)
   786 
   787 lemma neg_numeral_less_iff: "neg_numeral m < neg_numeral n \<longleftrightarrow> n < m"
   788   by (simp only: neg_numeral_def neg_less_iff_less numeral_less_iff)
   789 
   790 lemma neg_numeral_less_zero: "neg_numeral n < 0"
   791   by (simp only: neg_numeral_def neg_less_0_iff_less zero_less_numeral)
   792 
   793 lemma neg_numeral_le_zero: "neg_numeral n \<le> 0"
   794   by (simp only: neg_numeral_def neg_le_0_iff_le zero_le_numeral)
   795 
   796 lemma not_zero_less_neg_numeral: "\<not> 0 < neg_numeral n"
   797   by (simp only: not_less neg_numeral_le_zero)
   798 
   799 lemma not_zero_le_neg_numeral: "\<not> 0 \<le> neg_numeral n"
   800   by (simp only: not_le neg_numeral_less_zero)
   801 
   802 lemma neg_numeral_less_numeral: "neg_numeral m < numeral n"
   803   using neg_numeral_less_zero zero_less_numeral by (rule less_trans)
   804 
   805 lemma neg_numeral_le_numeral: "neg_numeral m \<le> numeral n"
   806   by (simp only: less_imp_le neg_numeral_less_numeral)
   807 
   808 lemma not_numeral_less_neg_numeral: "\<not> numeral m < neg_numeral n"
   809   by (simp only: not_less neg_numeral_le_numeral)
   810 
   811 lemma not_numeral_le_neg_numeral: "\<not> numeral m \<le> neg_numeral n"
   812   by (simp only: not_le neg_numeral_less_numeral)
   813   
   814 lemma neg_numeral_less_one: "neg_numeral m < 1"
   815   by (rule neg_numeral_less_numeral [of m One, unfolded numeral_One])
   816 
   817 lemma neg_numeral_le_one: "neg_numeral m \<le> 1"
   818   by (rule neg_numeral_le_numeral [of m One, unfolded numeral_One])
   819 
   820 lemma not_one_less_neg_numeral: "\<not> 1 < neg_numeral m"
   821   by (simp only: not_less neg_numeral_le_one)
   822 
   823 lemma not_one_le_neg_numeral: "\<not> 1 \<le> neg_numeral m"
   824   by (simp only: not_le neg_numeral_less_one)
   825 
   826 lemma sub_non_negative:
   827   "sub n m \<ge> 0 \<longleftrightarrow> n \<ge> m"
   828   by (simp only: sub_def le_diff_eq) simp
   829 
   830 lemma sub_positive:
   831   "sub n m > 0 \<longleftrightarrow> n > m"
   832   by (simp only: sub_def less_diff_eq) simp
   833 
   834 lemma sub_non_positive:
   835   "sub n m \<le> 0 \<longleftrightarrow> n \<le> m"
   836   by (simp only: sub_def diff_le_eq) simp
   837 
   838 lemma sub_negative:
   839   "sub n m < 0 \<longleftrightarrow> n < m"
   840   by (simp only: sub_def diff_less_eq) simp
   841 
   842 lemmas le_neg_numeral_simps [simp] =
   843   neg_numeral_le_iff
   844   neg_numeral_le_numeral not_numeral_le_neg_numeral
   845   neg_numeral_le_zero not_zero_le_neg_numeral
   846   neg_numeral_le_one not_one_le_neg_numeral
   847 
   848 lemmas less_neg_numeral_simps [simp] =
   849   neg_numeral_less_iff
   850   neg_numeral_less_numeral not_numeral_less_neg_numeral
   851   neg_numeral_less_zero not_zero_less_neg_numeral
   852   neg_numeral_less_one not_one_less_neg_numeral
   853 
   854 lemma abs_numeral [simp]: "abs (numeral n) = numeral n"
   855   by simp
   856 
   857 lemma abs_neg_numeral [simp]: "abs (neg_numeral n) = numeral n"
   858   by (simp only: neg_numeral_def abs_minus_cancel abs_numeral)
   859 
   860 end
   861 
   862 subsubsection {*
   863   Natural numbers
   864 *}
   865 
   866 lemma Suc_1 [simp]: "Suc 1 = 2"
   867   unfolding Suc_eq_plus1 by (rule one_add_one)
   868 
   869 lemma Suc_numeral [simp]: "Suc (numeral n) = numeral (n + One)"
   870   unfolding Suc_eq_plus1 by (rule numeral_plus_one)
   871 
   872 definition pred_numeral :: "num \<Rightarrow> nat"
   873   where [code del]: "pred_numeral k = numeral k - 1"
   874 
   875 lemma numeral_eq_Suc: "numeral k = Suc (pred_numeral k)"
   876   unfolding pred_numeral_def by simp
   877 
   878 lemma eval_nat_numeral:
   879   "numeral One = Suc 0"
   880   "numeral (Bit0 n) = Suc (numeral (BitM n))"
   881   "numeral (Bit1 n) = Suc (numeral (Bit0 n))"
   882   by (simp_all add: numeral.simps BitM_plus_one)
   883 
   884 lemma pred_numeral_simps [simp]:
   885   "pred_numeral One = 0"
   886   "pred_numeral (Bit0 k) = numeral (BitM k)"
   887   "pred_numeral (Bit1 k) = numeral (Bit0 k)"
   888   unfolding pred_numeral_def eval_nat_numeral
   889   by (simp_all only: diff_Suc_Suc diff_0)
   890 
   891 lemma numeral_2_eq_2: "2 = Suc (Suc 0)"
   892   by (simp add: eval_nat_numeral)
   893 
   894 lemma numeral_3_eq_3: "3 = Suc (Suc (Suc 0))"
   895   by (simp add: eval_nat_numeral)
   896 
   897 lemma numeral_1_eq_Suc_0: "Numeral1 = Suc 0"
   898   by (simp only: numeral_One One_nat_def)
   899 
   900 lemma Suc_nat_number_of_add:
   901   "Suc (numeral v + n) = numeral (v + One) + n"
   902   by simp
   903 
   904 (*Maps #n to n for n = 1, 2*)
   905 lemmas numerals = numeral_One [where 'a=nat] numeral_2_eq_2
   906 
   907 text {* Comparisons involving @{term Suc}. *}
   908 
   909 lemma eq_numeral_Suc [simp]: "numeral k = Suc n \<longleftrightarrow> pred_numeral k = n"
   910   by (simp add: numeral_eq_Suc)
   911 
   912 lemma Suc_eq_numeral [simp]: "Suc n = numeral k \<longleftrightarrow> n = pred_numeral k"
   913   by (simp add: numeral_eq_Suc)
   914 
   915 lemma less_numeral_Suc [simp]: "numeral k < Suc n \<longleftrightarrow> pred_numeral k < n"
   916   by (simp add: numeral_eq_Suc)
   917 
   918 lemma less_Suc_numeral [simp]: "Suc n < numeral k \<longleftrightarrow> n < pred_numeral k"
   919   by (simp add: numeral_eq_Suc)
   920 
   921 lemma le_numeral_Suc [simp]: "numeral k \<le> Suc n \<longleftrightarrow> pred_numeral k \<le> n"
   922   by (simp add: numeral_eq_Suc)
   923 
   924 lemma le_Suc_numeral [simp]: "Suc n \<le> numeral k \<longleftrightarrow> n \<le> pred_numeral k"
   925   by (simp add: numeral_eq_Suc)
   926 
   927 lemma diff_Suc_numeral [simp]: "Suc n - numeral k = n - pred_numeral k"
   928   by (simp add: numeral_eq_Suc)
   929 
   930 lemma diff_numeral_Suc [simp]: "numeral k - Suc n = pred_numeral k - n"
   931   by (simp add: numeral_eq_Suc)
   932 
   933 lemma max_Suc_numeral [simp]:
   934   "max (Suc n) (numeral k) = Suc (max n (pred_numeral k))"
   935   by (simp add: numeral_eq_Suc)
   936 
   937 lemma max_numeral_Suc [simp]:
   938   "max (numeral k) (Suc n) = Suc (max (pred_numeral k) n)"
   939   by (simp add: numeral_eq_Suc)
   940 
   941 lemma min_Suc_numeral [simp]:
   942   "min (Suc n) (numeral k) = Suc (min n (pred_numeral k))"
   943   by (simp add: numeral_eq_Suc)
   944 
   945 lemma min_numeral_Suc [simp]:
   946   "min (numeral k) (Suc n) = Suc (min (pred_numeral k) n)"
   947   by (simp add: numeral_eq_Suc)
   948 
   949 text {* For @{term nat_case} and @{term nat_rec}. *}
   950 
   951 lemma nat_case_numeral [simp]:
   952   "nat_case a f (numeral v) = (let pv = pred_numeral v in f pv)"
   953   by (simp add: numeral_eq_Suc)
   954 
   955 lemma nat_case_add_eq_if [simp]:
   956   "nat_case a f ((numeral v) + n) = (let pv = pred_numeral v in f (pv + n))"
   957   by (simp add: numeral_eq_Suc)
   958 
   959 lemma nat_rec_numeral [simp]:
   960   "nat_rec a f (numeral v) =
   961     (let pv = pred_numeral v in f pv (nat_rec a f pv))"
   962   by (simp add: numeral_eq_Suc Let_def)
   963 
   964 lemma nat_rec_add_eq_if [simp]:
   965   "nat_rec a f (numeral v + n) =
   966     (let pv = pred_numeral v in f (pv + n) (nat_rec a f (pv + n)))"
   967   by (simp add: numeral_eq_Suc Let_def)
   968 
   969 text {* Case analysis on @{term "n < 2"} *}
   970 
   971 lemma less_2_cases: "n < 2 \<Longrightarrow> n = 0 \<or> n = Suc 0"
   972   by (auto simp add: numeral_2_eq_2)
   973 
   974 text {* Removal of Small Numerals: 0, 1 and (in additive positions) 2 *}
   975 text {* bh: Are these rules really a good idea? *}
   976 
   977 lemma add_2_eq_Suc [simp]: "2 + n = Suc (Suc n)"
   978   by simp
   979 
   980 lemma add_2_eq_Suc' [simp]: "n + 2 = Suc (Suc n)"
   981   by simp
   982 
   983 text {* Can be used to eliminate long strings of Sucs, but not by default. *}
   984 
   985 lemma Suc3_eq_add_3: "Suc (Suc (Suc n)) = 3 + n"
   986   by simp
   987 
   988 lemmas nat_1_add_1 = one_add_one [where 'a=nat] (* legacy *)
   989 
   990 
   991 subsection {* Numeral equations as default simplification rules *}
   992 
   993 declare (in numeral) numeral_One [simp]
   994 declare (in numeral) numeral_plus_numeral [simp]
   995 declare (in numeral) add_numeral_special [simp]
   996 declare (in neg_numeral) add_neg_numeral_simps [simp]
   997 declare (in neg_numeral) add_neg_numeral_special [simp]
   998 declare (in neg_numeral) diff_numeral_simps [simp]
   999 declare (in neg_numeral) diff_numeral_special [simp]
  1000 declare (in semiring_numeral) numeral_times_numeral [simp]
  1001 declare (in ring_1) mult_neg_numeral_simps [simp]
  1002 
  1003 subsection {* Setting up simprocs *}
  1004 
  1005 lemma mult_numeral_1: "Numeral1 * a = (a::'a::semiring_numeral)"
  1006   by simp
  1007 
  1008 lemma mult_numeral_1_right: "a * Numeral1 = (a::'a::semiring_numeral)"
  1009   by simp
  1010 
  1011 lemma divide_numeral_1: "a / Numeral1 = (a::'a::field)"
  1012   by simp
  1013 
  1014 lemma inverse_numeral_1:
  1015   "inverse Numeral1 = (Numeral1::'a::division_ring)"
  1016   by simp
  1017 
  1018 text{*Theorem lists for the cancellation simprocs. The use of a binary
  1019 numeral for 1 reduces the number of special cases.*}
  1020 
  1021 lemmas mult_1s =
  1022   mult_numeral_1 mult_numeral_1_right 
  1023   mult_minus1 mult_minus1_right
  1024 
  1025 setup {*
  1026   Reorient_Proc.add
  1027     (fn Const (@{const_name numeral}, _) $ _ => true
  1028     | Const (@{const_name neg_numeral}, _) $ _ => true
  1029     | _ => false)
  1030 *}
  1031 
  1032 simproc_setup reorient_numeral
  1033   ("numeral w = x" | "neg_numeral w = y") = Reorient_Proc.proc
  1034 
  1035 
  1036 subsubsection {* Simplification of arithmetic operations on integer constants. *}
  1037 
  1038 lemmas arith_special = (* already declared simp above *)
  1039   add_numeral_special add_neg_numeral_special
  1040   diff_numeral_special minus_one
  1041 
  1042 (* rules already in simpset *)
  1043 lemmas arith_extra_simps =
  1044   numeral_plus_numeral add_neg_numeral_simps add_0_left add_0_right
  1045   minus_numeral minus_neg_numeral minus_zero minus_one
  1046   diff_numeral_simps diff_0 diff_0_right
  1047   numeral_times_numeral mult_neg_numeral_simps
  1048   mult_zero_left mult_zero_right
  1049   abs_numeral abs_neg_numeral
  1050 
  1051 text {*
  1052   For making a minimal simpset, one must include these default simprules.
  1053   Also include @{text simp_thms}.
  1054 *}
  1055 
  1056 lemmas arith_simps =
  1057   add_num_simps mult_num_simps sub_num_simps
  1058   BitM.simps dbl_simps dbl_inc_simps dbl_dec_simps
  1059   abs_zero abs_one arith_extra_simps
  1060 
  1061 text {* Simplification of relational operations *}
  1062 
  1063 lemmas eq_numeral_extra =
  1064   zero_neq_one one_neq_zero
  1065 
  1066 lemmas rel_simps =
  1067   le_num_simps less_num_simps eq_num_simps
  1068   le_numeral_simps le_neg_numeral_simps le_numeral_extra
  1069   less_numeral_simps less_neg_numeral_simps less_numeral_extra
  1070   eq_numeral_simps eq_neg_numeral_simps eq_numeral_extra
  1071 
  1072 
  1073 subsubsection {* Simplification of arithmetic when nested to the right. *}
  1074 
  1075 lemma add_numeral_left [simp]:
  1076   "numeral v + (numeral w + z) = (numeral(v + w) + z)"
  1077   by (simp_all add: add_assoc [symmetric])
  1078 
  1079 lemma add_neg_numeral_left [simp]:
  1080   "numeral v + (neg_numeral w + y) = (sub v w + y)"
  1081   "neg_numeral v + (numeral w + y) = (sub w v + y)"
  1082   "neg_numeral v + (neg_numeral w + y) = (neg_numeral(v + w) + y)"
  1083   by (simp_all add: add_assoc [symmetric])
  1084 
  1085 lemma mult_numeral_left [simp]:
  1086   "numeral v * (numeral w * z) = (numeral(v * w) * z :: 'a::semiring_numeral)"
  1087   "neg_numeral v * (numeral w * y) = (neg_numeral(v * w) * y :: 'b::ring_1)"
  1088   "numeral v * (neg_numeral w * y) = (neg_numeral(v * w) * y :: 'b::ring_1)"
  1089   "neg_numeral v * (neg_numeral w * y) = (numeral(v * w) * y :: 'b::ring_1)"
  1090   by (simp_all add: mult_assoc [symmetric])
  1091 
  1092 hide_const (open) One Bit0 Bit1 BitM inc pow sqr sub dbl dbl_inc dbl_dec
  1093 
  1094 subsection {* code module namespace *}
  1095 
  1096 code_modulename SML
  1097   Num Arith
  1098 
  1099 code_modulename OCaml
  1100   Num Arith
  1101 
  1102 code_modulename Haskell
  1103   Num Arith
  1104 
  1105 end