src/HOL/Library/Product_Vector.thy
author huffman
Wed Jun 03 09:58:11 2009 -0700 (2009-06-03)
changeset 31417 c12b25b7f015
parent 31415 80686a815b59
child 31491 f7310185481d
permissions -rw-r--r--
replace class open with class topo
     1 (*  Title:      HOL/Library/Product_Vector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Cartesian Products as Vector Spaces *}
     6 
     7 theory Product_Vector
     8 imports Inner_Product Product_plus
     9 begin
    10 
    11 subsection {* Product is a real vector space *}
    12 
    13 instantiation "*" :: (real_vector, real_vector) real_vector
    14 begin
    15 
    16 definition scaleR_prod_def:
    17   "scaleR r A = (scaleR r (fst A), scaleR r (snd A))"
    18 
    19 lemma fst_scaleR [simp]: "fst (scaleR r A) = scaleR r (fst A)"
    20   unfolding scaleR_prod_def by simp
    21 
    22 lemma snd_scaleR [simp]: "snd (scaleR r A) = scaleR r (snd A)"
    23   unfolding scaleR_prod_def by simp
    24 
    25 lemma scaleR_Pair [simp]: "scaleR r (a, b) = (scaleR r a, scaleR r b)"
    26   unfolding scaleR_prod_def by simp
    27 
    28 instance proof
    29   fix a b :: real and x y :: "'a \<times> 'b"
    30   show "scaleR a (x + y) = scaleR a x + scaleR a y"
    31     by (simp add: expand_prod_eq scaleR_right_distrib)
    32   show "scaleR (a + b) x = scaleR a x + scaleR b x"
    33     by (simp add: expand_prod_eq scaleR_left_distrib)
    34   show "scaleR a (scaleR b x) = scaleR (a * b) x"
    35     by (simp add: expand_prod_eq)
    36   show "scaleR 1 x = x"
    37     by (simp add: expand_prod_eq)
    38 qed
    39 
    40 end
    41 
    42 subsection {* Product is a topological space *}
    43 
    44 instantiation
    45   "*" :: (topological_space, topological_space) topological_space
    46 begin
    47 
    48 definition topo_prod_def:
    49   "topo = {S. \<forall>x\<in>S. \<exists>A\<in>topo. \<exists>B\<in>topo. x \<in> A \<times> B \<and> A \<times> B \<subseteq> S}"
    50 
    51 instance proof
    52   show "(UNIV :: ('a \<times> 'b) set) \<in> topo"
    53     unfolding topo_prod_def by (auto intro: topo_UNIV)
    54 next
    55   fix S T :: "('a \<times> 'b) set"
    56   assume "S \<in> topo" "T \<in> topo" thus "S \<inter> T \<in> topo"
    57     unfolding topo_prod_def
    58     apply clarify
    59     apply (drule (1) bspec)+
    60     apply (clarify, rename_tac Sa Ta Sb Tb)
    61     apply (rule_tac x="Sa \<inter> Ta" in rev_bexI)
    62     apply (simp add: topo_Int)
    63     apply (rule_tac x="Sb \<inter> Tb" in rev_bexI)
    64     apply (simp add: topo_Int)
    65     apply fast
    66     done
    67 next
    68   fix T :: "('a \<times> 'b) set set"
    69   assume "T \<subseteq> topo" thus "\<Union>T \<in> topo"
    70     unfolding topo_prod_def Bex_def by fast
    71 qed
    72 
    73 end
    74 
    75 subsection {* Product is a metric space *}
    76 
    77 instantiation
    78   "*" :: (metric_space, metric_space) metric_space
    79 begin
    80 
    81 definition dist_prod_def:
    82   "dist (x::'a \<times> 'b) y = sqrt ((dist (fst x) (fst y))\<twosuperior> + (dist (snd x) (snd y))\<twosuperior>)"
    83 
    84 lemma dist_Pair_Pair: "dist (a, b) (c, d) = sqrt ((dist a c)\<twosuperior> + (dist b d)\<twosuperior>)"
    85   unfolding dist_prod_def by simp
    86 
    87 instance proof
    88   fix x y :: "'a \<times> 'b"
    89   show "dist x y = 0 \<longleftrightarrow> x = y"
    90     unfolding dist_prod_def
    91     by (simp add: expand_prod_eq)
    92 next
    93   fix x y z :: "'a \<times> 'b"
    94   show "dist x y \<le> dist x z + dist y z"
    95     unfolding dist_prod_def
    96     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
    97     apply (rule real_sqrt_le_mono)
    98     apply (rule order_trans [OF add_mono])
    99     apply (rule power_mono [OF dist_triangle2 [of _ _ "fst z"] zero_le_dist])
   100     apply (rule power_mono [OF dist_triangle2 [of _ _ "snd z"] zero_le_dist])
   101     apply (simp only: real_sum_squared_expand)
   102     done
   103 next
   104   (* FIXME: long proof! *)
   105   (* Maybe it would be easier to define topological spaces *)
   106   (* in terms of neighborhoods instead of open sets? *)
   107   show "topo = {S::('a \<times> 'b) set. \<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S}"
   108     unfolding topo_prod_def topo_dist
   109     apply (safe, rename_tac S a b)
   110     apply (drule (1) bspec)
   111     apply clarify
   112     apply (drule (1) bspec)+
   113     apply (clarify, rename_tac r s)
   114     apply (rule_tac x="min r s" in exI, simp)
   115     apply (clarify, rename_tac c d)
   116     apply (erule subsetD)
   117     apply (simp add: dist_Pair_Pair)
   118     apply (rule conjI)
   119     apply (drule spec, erule mp)
   120     apply (erule le_less_trans [OF real_sqrt_sum_squares_ge1])
   121     apply (drule spec, erule mp)
   122     apply (erule le_less_trans [OF real_sqrt_sum_squares_ge2])
   123 
   124     apply (rename_tac S a b)
   125     apply (drule (1) bspec)
   126     apply clarify
   127     apply (subgoal_tac "\<exists>r>0. \<exists>s>0. e = sqrt (r\<twosuperior> + s\<twosuperior>)")
   128     apply clarify
   129     apply (rule_tac x="{y. dist y a < r}" in rev_bexI)
   130     apply clarify
   131     apply (rule_tac x="r - dist x a" in exI, rule conjI, simp)
   132     apply clarify
   133     apply (rule le_less_trans [OF dist_triangle])
   134     apply (erule less_le_trans [OF add_strict_right_mono], simp)
   135     apply (rule_tac x="{y. dist y b < s}" in rev_bexI)
   136     apply clarify
   137     apply (rule_tac x="s - dist x b" in exI, rule conjI, simp)
   138     apply clarify
   139     apply (rule le_less_trans [OF dist_triangle])
   140     apply (erule less_le_trans [OF add_strict_right_mono], simp)
   141     apply (rule conjI)
   142     apply simp
   143     apply (clarify, rename_tac c d)
   144     apply (drule spec, erule mp)
   145     apply (simp add: dist_Pair_Pair add_strict_mono power_strict_mono)
   146     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
   147     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
   148     apply (simp add: power_divide)
   149     done
   150 qed
   151 
   152 end
   153 
   154 subsection {* Continuity of operations *}
   155 
   156 lemma dist_fst_le: "dist (fst x) (fst y) \<le> dist x y"
   157 unfolding dist_prod_def by simp
   158 
   159 lemma dist_snd_le: "dist (snd x) (snd y) \<le> dist x y"
   160 unfolding dist_prod_def by simp
   161 
   162 lemma tendsto_fst:
   163   assumes "tendsto f a net"
   164   shows "tendsto (\<lambda>x. fst (f x)) (fst a) net"
   165 proof (rule tendstoI)
   166   fix r :: real assume "0 < r"
   167   have "eventually (\<lambda>x. dist (f x) a < r) net"
   168     using `tendsto f a net` `0 < r` by (rule tendstoD)
   169   thus "eventually (\<lambda>x. dist (fst (f x)) (fst a) < r) net"
   170     by (rule eventually_elim1)
   171        (rule le_less_trans [OF dist_fst_le])
   172 qed
   173 
   174 lemma tendsto_snd:
   175   assumes "tendsto f a net"
   176   shows "tendsto (\<lambda>x. snd (f x)) (snd a) net"
   177 proof (rule tendstoI)
   178   fix r :: real assume "0 < r"
   179   have "eventually (\<lambda>x. dist (f x) a < r) net"
   180     using `tendsto f a net` `0 < r` by (rule tendstoD)
   181   thus "eventually (\<lambda>x. dist (snd (f x)) (snd a) < r) net"
   182     by (rule eventually_elim1)
   183        (rule le_less_trans [OF dist_snd_le])
   184 qed
   185 
   186 lemma tendsto_Pair:
   187   assumes "tendsto X a net" and "tendsto Y b net"
   188   shows "tendsto (\<lambda>i. (X i, Y i)) (a, b) net"
   189 proof (rule tendstoI)
   190   fix r :: real assume "0 < r"
   191   then have "0 < r / sqrt 2" (is "0 < ?s")
   192     by (simp add: divide_pos_pos)
   193   have "eventually (\<lambda>i. dist (X i) a < ?s) net"
   194     using `tendsto X a net` `0 < ?s` by (rule tendstoD)
   195   moreover
   196   have "eventually (\<lambda>i. dist (Y i) b < ?s) net"
   197     using `tendsto Y b net` `0 < ?s` by (rule tendstoD)
   198   ultimately
   199   show "eventually (\<lambda>i. dist (X i, Y i) (a, b) < r) net"
   200     by (rule eventually_elim2)
   201        (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
   202 qed
   203 
   204 lemma LIMSEQ_fst: "(X ----> a) \<Longrightarrow> (\<lambda>n. fst (X n)) ----> fst a"
   205 unfolding LIMSEQ_conv_tendsto by (rule tendsto_fst)
   206 
   207 lemma LIMSEQ_snd: "(X ----> a) \<Longrightarrow> (\<lambda>n. snd (X n)) ----> snd a"
   208 unfolding LIMSEQ_conv_tendsto by (rule tendsto_snd)
   209 
   210 lemma LIMSEQ_Pair:
   211   assumes "X ----> a" and "Y ----> b"
   212   shows "(\<lambda>n. (X n, Y n)) ----> (a, b)"
   213 using assms unfolding LIMSEQ_conv_tendsto
   214 by (rule tendsto_Pair)
   215 
   216 lemma LIM_fst: "f -- x --> a \<Longrightarrow> (\<lambda>x. fst (f x)) -- x --> fst a"
   217 unfolding LIM_conv_tendsto by (rule tendsto_fst)
   218 
   219 lemma LIM_snd: "f -- x --> a \<Longrightarrow> (\<lambda>x. snd (f x)) -- x --> snd a"
   220 unfolding LIM_conv_tendsto by (rule tendsto_snd)
   221 
   222 lemma LIM_Pair:
   223   assumes "f -- x --> a" and "g -- x --> b"
   224   shows "(\<lambda>x. (f x, g x)) -- x --> (a, b)"
   225 using assms unfolding LIM_conv_tendsto
   226 by (rule tendsto_Pair)
   227 
   228 lemma Cauchy_fst: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. fst (X n))"
   229 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_fst_le])
   230 
   231 lemma Cauchy_snd: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. snd (X n))"
   232 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_snd_le])
   233 
   234 lemma Cauchy_Pair:
   235   assumes "Cauchy X" and "Cauchy Y"
   236   shows "Cauchy (\<lambda>n. (X n, Y n))"
   237 proof (rule metric_CauchyI)
   238   fix r :: real assume "0 < r"
   239   then have "0 < r / sqrt 2" (is "0 < ?s")
   240     by (simp add: divide_pos_pos)
   241   obtain M where M: "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < ?s"
   242     using metric_CauchyD [OF `Cauchy X` `0 < ?s`] ..
   243   obtain N where N: "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (Y m) (Y n) < ?s"
   244     using metric_CauchyD [OF `Cauchy Y` `0 < ?s`] ..
   245   have "\<forall>m\<ge>max M N. \<forall>n\<ge>max M N. dist (X m, Y m) (X n, Y n) < r"
   246     using M N by (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
   247   then show "\<exists>n0. \<forall>m\<ge>n0. \<forall>n\<ge>n0. dist (X m, Y m) (X n, Y n) < r" ..
   248 qed
   249 
   250 lemma isCont_Pair [simp]:
   251   "\<lbrakk>isCont f x; isCont g x\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) x"
   252   unfolding isCont_def by (rule LIM_Pair)
   253 
   254 subsection {* Product is a complete metric space *}
   255 
   256 instance "*" :: (complete_space, complete_space) complete_space
   257 proof
   258   fix X :: "nat \<Rightarrow> 'a \<times> 'b" assume "Cauchy X"
   259   have 1: "(\<lambda>n. fst (X n)) ----> lim (\<lambda>n. fst (X n))"
   260     using Cauchy_fst [OF `Cauchy X`]
   261     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   262   have 2: "(\<lambda>n. snd (X n)) ----> lim (\<lambda>n. snd (X n))"
   263     using Cauchy_snd [OF `Cauchy X`]
   264     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   265   have "X ----> (lim (\<lambda>n. fst (X n)), lim (\<lambda>n. snd (X n)))"
   266     using LIMSEQ_Pair [OF 1 2] by simp
   267   then show "convergent X"
   268     by (rule convergentI)
   269 qed
   270 
   271 subsection {* Product is a normed vector space *}
   272 
   273 instantiation
   274   "*" :: (real_normed_vector, real_normed_vector) real_normed_vector
   275 begin
   276 
   277 definition norm_prod_def:
   278   "norm x = sqrt ((norm (fst x))\<twosuperior> + (norm (snd x))\<twosuperior>)"
   279 
   280 definition sgn_prod_def:
   281   "sgn (x::'a \<times> 'b) = scaleR (inverse (norm x)) x"
   282 
   283 lemma norm_Pair: "norm (a, b) = sqrt ((norm a)\<twosuperior> + (norm b)\<twosuperior>)"
   284   unfolding norm_prod_def by simp
   285 
   286 instance proof
   287   fix r :: real and x y :: "'a \<times> 'b"
   288   show "0 \<le> norm x"
   289     unfolding norm_prod_def by simp
   290   show "norm x = 0 \<longleftrightarrow> x = 0"
   291     unfolding norm_prod_def
   292     by (simp add: expand_prod_eq)
   293   show "norm (x + y) \<le> norm x + norm y"
   294     unfolding norm_prod_def
   295     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
   296     apply (simp add: add_mono power_mono norm_triangle_ineq)
   297     done
   298   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   299     unfolding norm_prod_def
   300     apply (simp add: norm_scaleR power_mult_distrib)
   301     apply (simp add: right_distrib [symmetric])
   302     apply (simp add: real_sqrt_mult_distrib)
   303     done
   304   show "sgn x = scaleR (inverse (norm x)) x"
   305     by (rule sgn_prod_def)
   306   show "dist x y = norm (x - y)"
   307     unfolding dist_prod_def norm_prod_def
   308     by (simp add: dist_norm)
   309 qed
   310 
   311 end
   312 
   313 instance "*" :: (banach, banach) banach ..
   314 
   315 subsection {* Product is an inner product space *}
   316 
   317 instantiation "*" :: (real_inner, real_inner) real_inner
   318 begin
   319 
   320 definition inner_prod_def:
   321   "inner x y = inner (fst x) (fst y) + inner (snd x) (snd y)"
   322 
   323 lemma inner_Pair [simp]: "inner (a, b) (c, d) = inner a c + inner b d"
   324   unfolding inner_prod_def by simp
   325 
   326 instance proof
   327   fix r :: real
   328   fix x y z :: "'a::real_inner * 'b::real_inner"
   329   show "inner x y = inner y x"
   330     unfolding inner_prod_def
   331     by (simp add: inner_commute)
   332   show "inner (x + y) z = inner x z + inner y z"
   333     unfolding inner_prod_def
   334     by (simp add: inner_left_distrib)
   335   show "inner (scaleR r x) y = r * inner x y"
   336     unfolding inner_prod_def
   337     by (simp add: inner_scaleR_left right_distrib)
   338   show "0 \<le> inner x x"
   339     unfolding inner_prod_def
   340     by (intro add_nonneg_nonneg inner_ge_zero)
   341   show "inner x x = 0 \<longleftrightarrow> x = 0"
   342     unfolding inner_prod_def expand_prod_eq
   343     by (simp add: add_nonneg_eq_0_iff)
   344   show "norm x = sqrt (inner x x)"
   345     unfolding norm_prod_def inner_prod_def
   346     by (simp add: power2_norm_eq_inner)
   347 qed
   348 
   349 end
   350 
   351 subsection {* Pair operations are linear *}
   352 
   353 interpretation fst: bounded_linear fst
   354   apply (unfold_locales)
   355   apply (rule fst_add)
   356   apply (rule fst_scaleR)
   357   apply (rule_tac x="1" in exI, simp add: norm_Pair)
   358   done
   359 
   360 interpretation snd: bounded_linear snd
   361   apply (unfold_locales)
   362   apply (rule snd_add)
   363   apply (rule snd_scaleR)
   364   apply (rule_tac x="1" in exI, simp add: norm_Pair)
   365   done
   366 
   367 text {* TODO: move to NthRoot *}
   368 lemma sqrt_add_le_add_sqrt:
   369   assumes x: "0 \<le> x" and y: "0 \<le> y"
   370   shows "sqrt (x + y) \<le> sqrt x + sqrt y"
   371 apply (rule power2_le_imp_le)
   372 apply (simp add: real_sum_squared_expand add_nonneg_nonneg x y)
   373 apply (simp add: mult_nonneg_nonneg x y)
   374 apply (simp add: add_nonneg_nonneg x y)
   375 done
   376 
   377 lemma bounded_linear_Pair:
   378   assumes f: "bounded_linear f"
   379   assumes g: "bounded_linear g"
   380   shows "bounded_linear (\<lambda>x. (f x, g x))"
   381 proof
   382   interpret f: bounded_linear f by fact
   383   interpret g: bounded_linear g by fact
   384   fix x y and r :: real
   385   show "(f (x + y), g (x + y)) = (f x, g x) + (f y, g y)"
   386     by (simp add: f.add g.add)
   387   show "(f (r *\<^sub>R x), g (r *\<^sub>R x)) = r *\<^sub>R (f x, g x)"
   388     by (simp add: f.scaleR g.scaleR)
   389   obtain Kf where "0 < Kf" and norm_f: "\<And>x. norm (f x) \<le> norm x * Kf"
   390     using f.pos_bounded by fast
   391   obtain Kg where "0 < Kg" and norm_g: "\<And>x. norm (g x) \<le> norm x * Kg"
   392     using g.pos_bounded by fast
   393   have "\<forall>x. norm (f x, g x) \<le> norm x * (Kf + Kg)"
   394     apply (rule allI)
   395     apply (simp add: norm_Pair)
   396     apply (rule order_trans [OF sqrt_add_le_add_sqrt], simp, simp)
   397     apply (simp add: right_distrib)
   398     apply (rule add_mono [OF norm_f norm_g])
   399     done
   400   then show "\<exists>K. \<forall>x. norm (f x, g x) \<le> norm x * K" ..
   401 qed
   402 
   403 subsection {* Frechet derivatives involving pairs *}
   404 
   405 lemma FDERIV_Pair:
   406   assumes f: "FDERIV f x :> f'" and g: "FDERIV g x :> g'"
   407   shows "FDERIV (\<lambda>x. (f x, g x)) x :> (\<lambda>h. (f' h, g' h))"
   408 apply (rule FDERIV_I)
   409 apply (rule bounded_linear_Pair)
   410 apply (rule FDERIV_bounded_linear [OF f])
   411 apply (rule FDERIV_bounded_linear [OF g])
   412 apply (simp add: norm_Pair)
   413 apply (rule real_LIM_sandwich_zero)
   414 apply (rule LIM_add_zero)
   415 apply (rule FDERIV_D [OF f])
   416 apply (rule FDERIV_D [OF g])
   417 apply (rename_tac h)
   418 apply (simp add: divide_nonneg_pos)
   419 apply (rename_tac h)
   420 apply (subst add_divide_distrib [symmetric])
   421 apply (rule divide_right_mono [OF _ norm_ge_zero])
   422 apply (rule order_trans [OF sqrt_add_le_add_sqrt])
   423 apply simp
   424 apply simp
   425 apply simp
   426 done
   427 
   428 end