src/HOL/Library/Multiset.thy
author wenzelm
Wed Mar 05 09:59:48 2014 +0100 (2014-03-05)
changeset 55913 c1409c103b77
parent 55811 aa1acc25126b
child 55945 e96383acecf9
permissions -rw-r--r--
proper UTF-8;
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3     Author:     Andrei Popescu, TU Muenchen
     4 *)
     5 
     6 header {* (Finite) multisets *}
     7 
     8 theory Multiset
     9 imports Main
    10 begin
    11 
    12 subsection {* The type of multisets *}
    13 
    14 definition "multiset = {f :: 'a => nat. finite {x. f x > 0}}"
    15 
    16 typedef 'a multiset = "multiset :: ('a => nat) set"
    17   morphisms count Abs_multiset
    18   unfolding multiset_def
    19 proof
    20   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    21 qed
    22 
    23 setup_lifting type_definition_multiset
    24 
    25 abbreviation Melem :: "'a => 'a multiset => bool"  ("(_/ :# _)" [50, 51] 50) where
    26   "a :# M == 0 < count M a"
    27 
    28 notation (xsymbols)
    29   Melem (infix "\<in>#" 50)
    30 
    31 lemma multiset_eq_iff:
    32   "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    33   by (simp only: count_inject [symmetric] fun_eq_iff)
    34 
    35 lemma multiset_eqI:
    36   "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    37   using multiset_eq_iff by auto
    38 
    39 text {*
    40  \medskip Preservation of the representing set @{term multiset}.
    41 *}
    42 
    43 lemma const0_in_multiset:
    44   "(\<lambda>a. 0) \<in> multiset"
    45   by (simp add: multiset_def)
    46 
    47 lemma only1_in_multiset:
    48   "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    49   by (simp add: multiset_def)
    50 
    51 lemma union_preserves_multiset:
    52   "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    53   by (simp add: multiset_def)
    54 
    55 lemma diff_preserves_multiset:
    56   assumes "M \<in> multiset"
    57   shows "(\<lambda>a. M a - N a) \<in> multiset"
    58 proof -
    59   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    60     by auto
    61   with assms show ?thesis
    62     by (auto simp add: multiset_def intro: finite_subset)
    63 qed
    64 
    65 lemma filter_preserves_multiset:
    66   assumes "M \<in> multiset"
    67   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    68 proof -
    69   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    70     by auto
    71   with assms show ?thesis
    72     by (auto simp add: multiset_def intro: finite_subset)
    73 qed
    74 
    75 lemmas in_multiset = const0_in_multiset only1_in_multiset
    76   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    77 
    78 
    79 subsection {* Representing multisets *}
    80 
    81 text {* Multiset enumeration *}
    82 
    83 instantiation multiset :: (type) cancel_comm_monoid_add
    84 begin
    85 
    86 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    87 by (rule const0_in_multiset)
    88 
    89 abbreviation Mempty :: "'a multiset" ("{#}") where
    90   "Mempty \<equiv> 0"
    91 
    92 lift_definition plus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    93 by (rule union_preserves_multiset)
    94 
    95 instance
    96 by default (transfer, simp add: fun_eq_iff)+
    97 
    98 end
    99 
   100 lift_definition single :: "'a => 'a multiset" is "\<lambda>a b. if b = a then 1 else 0"
   101 by (rule only1_in_multiset)
   102 
   103 syntax
   104   "_multiset" :: "args => 'a multiset"    ("{#(_)#}")
   105 translations
   106   "{#x, xs#}" == "{#x#} + {#xs#}"
   107   "{#x#}" == "CONST single x"
   108 
   109 lemma count_empty [simp]: "count {#} a = 0"
   110   by (simp add: zero_multiset.rep_eq)
   111 
   112 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   113   by (simp add: single.rep_eq)
   114 
   115 
   116 subsection {* Basic operations *}
   117 
   118 subsubsection {* Union *}
   119 
   120 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   121   by (simp add: plus_multiset.rep_eq)
   122 
   123 
   124 subsubsection {* Difference *}
   125 
   126 instantiation multiset :: (type) comm_monoid_diff
   127 begin
   128 
   129 lift_definition minus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
   130 by (rule diff_preserves_multiset)
   131  
   132 instance
   133 by default (transfer, simp add: fun_eq_iff)+
   134 
   135 end
   136 
   137 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   138   by (simp add: minus_multiset.rep_eq)
   139 
   140 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   141   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
   142 
   143 lemma diff_cancel[simp]: "A - A = {#}"
   144   by (fact Groups.diff_cancel)
   145 
   146 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
   147   by (fact add_diff_cancel_right')
   148 
   149 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
   150   by (fact add_diff_cancel_left')
   151 
   152 lemma diff_right_commute:
   153   "(M::'a multiset) - N - Q = M - Q - N"
   154   by (fact diff_right_commute)
   155 
   156 lemma diff_add:
   157   "(M::'a multiset) - (N + Q) = M - N - Q"
   158   by (rule sym) (fact diff_diff_add)
   159   
   160 lemma insert_DiffM:
   161   "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   162   by (clarsimp simp: multiset_eq_iff)
   163 
   164 lemma insert_DiffM2 [simp]:
   165   "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   166   by (clarsimp simp: multiset_eq_iff)
   167 
   168 lemma diff_union_swap:
   169   "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
   170   by (auto simp add: multiset_eq_iff)
   171 
   172 lemma diff_union_single_conv:
   173   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   174   by (simp add: multiset_eq_iff)
   175 
   176 
   177 subsubsection {* Equality of multisets *}
   178 
   179 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   180   by (simp add: multiset_eq_iff)
   181 
   182 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   183   by (auto simp add: multiset_eq_iff)
   184 
   185 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   186   by (auto simp add: multiset_eq_iff)
   187 
   188 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   189   by (auto simp add: multiset_eq_iff)
   190 
   191 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
   192   by (auto simp add: multiset_eq_iff)
   193 
   194 lemma diff_single_trivial:
   195   "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   196   by (auto simp add: multiset_eq_iff)
   197 
   198 lemma diff_single_eq_union:
   199   "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
   200   by auto
   201 
   202 lemma union_single_eq_diff:
   203   "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
   204   by (auto dest: sym)
   205 
   206 lemma union_single_eq_member:
   207   "M + {#x#} = N \<Longrightarrow> x \<in># N"
   208   by auto
   209 
   210 lemma union_is_single:
   211   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}" (is "?lhs = ?rhs")
   212 proof
   213   assume ?rhs then show ?lhs by auto
   214 next
   215   assume ?lhs then show ?rhs
   216     by (simp add: multiset_eq_iff split:if_splits) (metis add_is_1)
   217 qed
   218 
   219 lemma single_is_union:
   220   "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   221   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   222 
   223 lemma add_eq_conv_diff:
   224   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"  (is "?lhs = ?rhs")
   225 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   226 proof
   227   assume ?rhs then show ?lhs
   228   by (auto simp add: add_assoc add_commute [of "{#b#}"])
   229     (drule sym, simp add: add_assoc [symmetric])
   230 next
   231   assume ?lhs
   232   show ?rhs
   233   proof (cases "a = b")
   234     case True with `?lhs` show ?thesis by simp
   235   next
   236     case False
   237     from `?lhs` have "a \<in># N + {#b#}" by (rule union_single_eq_member)
   238     with False have "a \<in># N" by auto
   239     moreover from `?lhs` have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
   240     moreover note False
   241     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
   242   qed
   243 qed
   244 
   245 lemma insert_noteq_member: 
   246   assumes BC: "B + {#b#} = C + {#c#}"
   247    and bnotc: "b \<noteq> c"
   248   shows "c \<in># B"
   249 proof -
   250   have "c \<in># C + {#c#}" by simp
   251   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   252   then have "c \<in># B + {#b#}" using BC by simp
   253   then show "c \<in># B" using nc by simp
   254 qed
   255 
   256 lemma add_eq_conv_ex:
   257   "(M + {#a#} = N + {#b#}) =
   258     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   259   by (auto simp add: add_eq_conv_diff)
   260 
   261 lemma multi_member_split:
   262   "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   263   by (rule_tac x = "M - {#x#}" in exI, simp)
   264 
   265 
   266 subsubsection {* Pointwise ordering induced by count *}
   267 
   268 instantiation multiset :: (type) ordered_ab_semigroup_add_imp_le
   269 begin
   270 
   271 lift_definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" is "\<lambda> A B. (\<forall>a. A a \<le> B a)" .
   272 
   273 lemmas mset_le_def = less_eq_multiset_def
   274 
   275 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
   276   mset_less_def: "(A::'a multiset) < B \<longleftrightarrow> A \<le> B \<and> A \<noteq> B"
   277 
   278 instance
   279   by default (auto simp add: mset_le_def mset_less_def multiset_eq_iff intro: order_trans antisym)
   280 
   281 end
   282 
   283 lemma mset_less_eqI:
   284   "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le> B"
   285   by (simp add: mset_le_def)
   286 
   287 lemma mset_le_exists_conv:
   288   "(A::'a multiset) \<le> B \<longleftrightarrow> (\<exists>C. B = A + C)"
   289 apply (unfold mset_le_def, rule iffI, rule_tac x = "B - A" in exI)
   290 apply (auto intro: multiset_eq_iff [THEN iffD2])
   291 done
   292 
   293 instance multiset :: (type) ordered_cancel_comm_monoid_diff
   294   by default (simp, fact mset_le_exists_conv)
   295 
   296 lemma mset_le_mono_add_right_cancel [simp]:
   297   "(A::'a multiset) + C \<le> B + C \<longleftrightarrow> A \<le> B"
   298   by (fact add_le_cancel_right)
   299 
   300 lemma mset_le_mono_add_left_cancel [simp]:
   301   "C + (A::'a multiset) \<le> C + B \<longleftrightarrow> A \<le> B"
   302   by (fact add_le_cancel_left)
   303 
   304 lemma mset_le_mono_add:
   305   "(A::'a multiset) \<le> B \<Longrightarrow> C \<le> D \<Longrightarrow> A + C \<le> B + D"
   306   by (fact add_mono)
   307 
   308 lemma mset_le_add_left [simp]:
   309   "(A::'a multiset) \<le> A + B"
   310   unfolding mset_le_def by auto
   311 
   312 lemma mset_le_add_right [simp]:
   313   "B \<le> (A::'a multiset) + B"
   314   unfolding mset_le_def by auto
   315 
   316 lemma mset_le_single:
   317   "a :# B \<Longrightarrow> {#a#} \<le> B"
   318   by (simp add: mset_le_def)
   319 
   320 lemma multiset_diff_union_assoc:
   321   "C \<le> B \<Longrightarrow> (A::'a multiset) + B - C = A + (B - C)"
   322   by (simp add: multiset_eq_iff mset_le_def)
   323 
   324 lemma mset_le_multiset_union_diff_commute:
   325   "B \<le> A \<Longrightarrow> (A::'a multiset) - B + C = A + C - B"
   326 by (simp add: multiset_eq_iff mset_le_def)
   327 
   328 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le> M"
   329 by(simp add: mset_le_def)
   330 
   331 lemma mset_lessD: "A < B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   332 apply (clarsimp simp: mset_le_def mset_less_def)
   333 apply (erule_tac x=x in allE)
   334 apply auto
   335 done
   336 
   337 lemma mset_leD: "A \<le> B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   338 apply (clarsimp simp: mset_le_def mset_less_def)
   339 apply (erule_tac x = x in allE)
   340 apply auto
   341 done
   342   
   343 lemma mset_less_insertD: "(A + {#x#} < B) \<Longrightarrow> (x \<in># B \<and> A < B)"
   344 apply (rule conjI)
   345  apply (simp add: mset_lessD)
   346 apply (clarsimp simp: mset_le_def mset_less_def)
   347 apply safe
   348  apply (erule_tac x = a in allE)
   349  apply (auto split: split_if_asm)
   350 done
   351 
   352 lemma mset_le_insertD: "(A + {#x#} \<le> B) \<Longrightarrow> (x \<in># B \<and> A \<le> B)"
   353 apply (rule conjI)
   354  apply (simp add: mset_leD)
   355 apply (force simp: mset_le_def mset_less_def split: split_if_asm)
   356 done
   357 
   358 lemma mset_less_of_empty[simp]: "A < {#} \<longleftrightarrow> False"
   359   by (auto simp add: mset_less_def mset_le_def multiset_eq_iff)
   360 
   361 lemma empty_le[simp]: "{#} \<le> A"
   362   unfolding mset_le_exists_conv by auto
   363 
   364 lemma le_empty[simp]: "(M \<le> {#}) = (M = {#})"
   365   unfolding mset_le_exists_conv by auto
   366 
   367 lemma multi_psub_of_add_self[simp]: "A < A + {#x#}"
   368   by (auto simp: mset_le_def mset_less_def)
   369 
   370 lemma multi_psub_self[simp]: "(A::'a multiset) < A = False"
   371   by simp
   372 
   373 lemma mset_less_add_bothsides:
   374   "T + {#x#} < S + {#x#} \<Longrightarrow> T < S"
   375   by (fact add_less_imp_less_right)
   376 
   377 lemma mset_less_empty_nonempty:
   378   "{#} < S \<longleftrightarrow> S \<noteq> {#}"
   379   by (auto simp: mset_le_def mset_less_def)
   380 
   381 lemma mset_less_diff_self:
   382   "c \<in># B \<Longrightarrow> B - {#c#} < B"
   383   by (auto simp: mset_le_def mset_less_def multiset_eq_iff)
   384 
   385 
   386 subsubsection {* Intersection *}
   387 
   388 instantiation multiset :: (type) semilattice_inf
   389 begin
   390 
   391 definition inf_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   392   multiset_inter_def: "inf_multiset A B = A - (A - B)"
   393 
   394 instance
   395 proof -
   396   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" by arith
   397   show "OFCLASS('a multiset, semilattice_inf_class)"
   398     by default (auto simp add: multiset_inter_def mset_le_def aux)
   399 qed
   400 
   401 end
   402 
   403 abbreviation multiset_inter :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
   404   "multiset_inter \<equiv> inf"
   405 
   406 lemma multiset_inter_count [simp]:
   407   "count (A #\<inter> B) x = min (count A x) (count B x)"
   408   by (simp add: multiset_inter_def)
   409 
   410 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   411   by (rule multiset_eqI) auto
   412 
   413 lemma multiset_union_diff_commute:
   414   assumes "B #\<inter> C = {#}"
   415   shows "A + B - C = A - C + B"
   416 proof (rule multiset_eqI)
   417   fix x
   418   from assms have "min (count B x) (count C x) = 0"
   419     by (auto simp add: multiset_eq_iff)
   420   then have "count B x = 0 \<or> count C x = 0"
   421     by auto
   422   then show "count (A + B - C) x = count (A - C + B) x"
   423     by auto
   424 qed
   425 
   426 lemma empty_inter [simp]:
   427   "{#} #\<inter> M = {#}"
   428   by (simp add: multiset_eq_iff)
   429 
   430 lemma inter_empty [simp]:
   431   "M #\<inter> {#} = {#}"
   432   by (simp add: multiset_eq_iff)
   433 
   434 lemma inter_add_left1:
   435   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = M #\<inter> N"
   436   by (simp add: multiset_eq_iff)
   437 
   438 lemma inter_add_left2:
   439   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = (M #\<inter> (N - {#x#})) + {#x#}"
   440   by (simp add: multiset_eq_iff)
   441 
   442 lemma inter_add_right1:
   443   "\<not> x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = N #\<inter> M"
   444   by (simp add: multiset_eq_iff)
   445 
   446 lemma inter_add_right2:
   447   "x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = ((N - {#x#}) #\<inter> M) + {#x#}"
   448   by (simp add: multiset_eq_iff)
   449 
   450 
   451 subsubsection {* Bounded union *}
   452 
   453 instantiation multiset :: (type) semilattice_sup
   454 begin
   455 
   456 definition sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   457   "sup_multiset A B = A + (B - A)"
   458 
   459 instance
   460 proof -
   461   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" by arith
   462   show "OFCLASS('a multiset, semilattice_sup_class)"
   463     by default (auto simp add: sup_multiset_def mset_le_def aux)
   464 qed
   465 
   466 end
   467 
   468 abbreviation sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<union>" 70) where
   469   "sup_multiset \<equiv> sup"
   470 
   471 lemma sup_multiset_count [simp]:
   472   "count (A #\<union> B) x = max (count A x) (count B x)"
   473   by (simp add: sup_multiset_def)
   474 
   475 lemma empty_sup [simp]:
   476   "{#} #\<union> M = M"
   477   by (simp add: multiset_eq_iff)
   478 
   479 lemma sup_empty [simp]:
   480   "M #\<union> {#} = M"
   481   by (simp add: multiset_eq_iff)
   482 
   483 lemma sup_add_left1:
   484   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> N) + {#x#}"
   485   by (simp add: multiset_eq_iff)
   486 
   487 lemma sup_add_left2:
   488   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> (N - {#x#})) + {#x#}"
   489   by (simp add: multiset_eq_iff)
   490 
   491 lemma sup_add_right1:
   492   "\<not> x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = (N #\<union> M) + {#x#}"
   493   by (simp add: multiset_eq_iff)
   494 
   495 lemma sup_add_right2:
   496   "x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = ((N - {#x#}) #\<union> M) + {#x#}"
   497   by (simp add: multiset_eq_iff)
   498 
   499 
   500 subsubsection {* Filter (with comprehension syntax) *}
   501 
   502 text {* Multiset comprehension *}
   503 
   504 lift_definition filter :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
   505 by (rule filter_preserves_multiset)
   506 
   507 hide_const (open) filter
   508 
   509 lemma count_filter [simp]:
   510   "count (Multiset.filter P M) a = (if P a then count M a else 0)"
   511   by (simp add: filter.rep_eq)
   512 
   513 lemma filter_empty [simp]:
   514   "Multiset.filter P {#} = {#}"
   515   by (rule multiset_eqI) simp
   516 
   517 lemma filter_single [simp]:
   518   "Multiset.filter P {#x#} = (if P x then {#x#} else {#})"
   519   by (rule multiset_eqI) simp
   520 
   521 lemma filter_union [simp]:
   522   "Multiset.filter P (M + N) = Multiset.filter P M + Multiset.filter P N"
   523   by (rule multiset_eqI) simp
   524 
   525 lemma filter_diff [simp]:
   526   "Multiset.filter P (M - N) = Multiset.filter P M - Multiset.filter P N"
   527   by (rule multiset_eqI) simp
   528 
   529 lemma filter_inter [simp]:
   530   "Multiset.filter P (M #\<inter> N) = Multiset.filter P M #\<inter> Multiset.filter P N"
   531   by (rule multiset_eqI) simp
   532 
   533 syntax
   534   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ :# _./ _#})")
   535 syntax (xsymbol)
   536   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ \<in># _./ _#})")
   537 translations
   538   "{#x \<in># M. P#}" == "CONST Multiset.filter (\<lambda>x. P) M"
   539 
   540 
   541 subsubsection {* Set of elements *}
   542 
   543 definition set_of :: "'a multiset => 'a set" where
   544   "set_of M = {x. x :# M}"
   545 
   546 lemma set_of_empty [simp]: "set_of {#} = {}"
   547 by (simp add: set_of_def)
   548 
   549 lemma set_of_single [simp]: "set_of {#b#} = {b}"
   550 by (simp add: set_of_def)
   551 
   552 lemma set_of_union [simp]: "set_of (M + N) = set_of M \<union> set_of N"
   553 by (auto simp add: set_of_def)
   554 
   555 lemma set_of_eq_empty_iff [simp]: "(set_of M = {}) = (M = {#})"
   556 by (auto simp add: set_of_def multiset_eq_iff)
   557 
   558 lemma mem_set_of_iff [simp]: "(x \<in> set_of M) = (x :# M)"
   559 by (auto simp add: set_of_def)
   560 
   561 lemma set_of_filter [simp]: "set_of {# x:#M. P x #} = set_of M \<inter> {x. P x}"
   562 by (auto simp add: set_of_def)
   563 
   564 lemma finite_set_of [iff]: "finite (set_of M)"
   565   using count [of M] by (simp add: multiset_def set_of_def)
   566 
   567 lemma finite_Collect_mem [iff]: "finite {x. x :# M}"
   568   unfolding set_of_def[symmetric] by simp
   569 
   570 lemma set_of_mono: "A \<le> B \<Longrightarrow> set_of A \<subseteq> set_of B"  
   571   by (metis mset_leD subsetI mem_set_of_iff)
   572 
   573 subsubsection {* Size *}
   574 
   575 instantiation multiset :: (type) size
   576 begin
   577 
   578 definition size_def:
   579   "size M = setsum (count M) (set_of M)"
   580 
   581 instance ..
   582 
   583 end
   584 
   585 lemma size_empty [simp]: "size {#} = 0"
   586 by (simp add: size_def)
   587 
   588 lemma size_single [simp]: "size {#b#} = 1"
   589 by (simp add: size_def)
   590 
   591 lemma setsum_count_Int:
   592   "finite A ==> setsum (count N) (A \<inter> set_of N) = setsum (count N) A"
   593 apply (induct rule: finite_induct)
   594  apply simp
   595 apply (simp add: Int_insert_left set_of_def)
   596 done
   597 
   598 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   599 apply (unfold size_def)
   600 apply (subgoal_tac "count (M + N) = (\<lambda>a. count M a + count N a)")
   601  prefer 2
   602  apply (rule ext, simp)
   603 apply (simp (no_asm_simp) add: setsum_Un_nat setsum_addf setsum_count_Int)
   604 apply (subst Int_commute)
   605 apply (simp (no_asm_simp) add: setsum_count_Int)
   606 done
   607 
   608 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   609 by (auto simp add: size_def multiset_eq_iff)
   610 
   611 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   612 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   613 
   614 lemma size_eq_Suc_imp_elem: "size M = Suc n ==> \<exists>a. a :# M"
   615 apply (unfold size_def)
   616 apply (drule setsum_SucD)
   617 apply auto
   618 done
   619 
   620 lemma size_eq_Suc_imp_eq_union:
   621   assumes "size M = Suc n"
   622   shows "\<exists>a N. M = N + {#a#}"
   623 proof -
   624   from assms obtain a where "a \<in># M"
   625     by (erule size_eq_Suc_imp_elem [THEN exE])
   626   then have "M = M - {#a#} + {#a#}" by simp
   627   then show ?thesis by blast
   628 qed
   629 
   630 
   631 subsection {* Induction and case splits *}
   632 
   633 theorem multiset_induct [case_names empty add, induct type: multiset]:
   634   assumes empty: "P {#}"
   635   assumes add: "\<And>M x. P M \<Longrightarrow> P (M + {#x#})"
   636   shows "P M"
   637 proof (induct n \<equiv> "size M" arbitrary: M)
   638   case 0 thus "P M" by (simp add: empty)
   639 next
   640   case (Suc k)
   641   obtain N x where "M = N + {#x#}"
   642     using `Suc k = size M` [symmetric]
   643     using size_eq_Suc_imp_eq_union by fast
   644   with Suc add show "P M" by simp
   645 qed
   646 
   647 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   648 by (induct M) auto
   649 
   650 lemma multiset_cases [cases type]:
   651   obtains (empty) "M = {#}"
   652     | (add) N x where "M = N + {#x#}"
   653   using assms by (induct M) simp_all
   654 
   655 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   656 by (cases "B = {#}") (auto dest: multi_member_split)
   657 
   658 lemma multiset_partition: "M = {# x:#M. P x #} + {# x:#M. \<not> P x #}"
   659 apply (subst multiset_eq_iff)
   660 apply auto
   661 done
   662 
   663 lemma mset_less_size: "(A::'a multiset) < B \<Longrightarrow> size A < size B"
   664 proof (induct A arbitrary: B)
   665   case (empty M)
   666   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
   667   then obtain M' x where "M = M' + {#x#}" 
   668     by (blast dest: multi_nonempty_split)
   669   then show ?case by simp
   670 next
   671   case (add S x T)
   672   have IH: "\<And>B. S < B \<Longrightarrow> size S < size B" by fact
   673   have SxsubT: "S + {#x#} < T" by fact
   674   then have "x \<in># T" and "S < T" by (auto dest: mset_less_insertD)
   675   then obtain T' where T: "T = T' + {#x#}" 
   676     by (blast dest: multi_member_split)
   677   then have "S < T'" using SxsubT 
   678     by (blast intro: mset_less_add_bothsides)
   679   then have "size S < size T'" using IH by simp
   680   then show ?case using T by simp
   681 qed
   682 
   683 
   684 subsubsection {* Strong induction and subset induction for multisets *}
   685 
   686 text {* Well-foundedness of proper subset operator: *}
   687 
   688 text {* proper multiset subset *}
   689 
   690 definition
   691   mset_less_rel :: "('a multiset * 'a multiset) set" where
   692   "mset_less_rel = {(A,B). A < B}"
   693 
   694 lemma multiset_add_sub_el_shuffle: 
   695   assumes "c \<in># B" and "b \<noteq> c" 
   696   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
   697 proof -
   698   from `c \<in># B` obtain A where B: "B = A + {#c#}" 
   699     by (blast dest: multi_member_split)
   700   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
   701   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}" 
   702     by (simp add: add_ac)
   703   then show ?thesis using B by simp
   704 qed
   705 
   706 lemma wf_mset_less_rel: "wf mset_less_rel"
   707 apply (unfold mset_less_rel_def)
   708 apply (rule wf_measure [THEN wf_subset, where f1=size])
   709 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
   710 done
   711 
   712 text {* The induction rules: *}
   713 
   714 lemma full_multiset_induct [case_names less]:
   715 assumes ih: "\<And>B. \<forall>(A::'a multiset). A < B \<longrightarrow> P A \<Longrightarrow> P B"
   716 shows "P B"
   717 apply (rule wf_mset_less_rel [THEN wf_induct])
   718 apply (rule ih, auto simp: mset_less_rel_def)
   719 done
   720 
   721 lemma multi_subset_induct [consumes 2, case_names empty add]:
   722 assumes "F \<le> A"
   723   and empty: "P {#}"
   724   and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
   725 shows "P F"
   726 proof -
   727   from `F \<le> A`
   728   show ?thesis
   729   proof (induct F)
   730     show "P {#}" by fact
   731   next
   732     fix x F
   733     assume P: "F \<le> A \<Longrightarrow> P F" and i: "F + {#x#} \<le> A"
   734     show "P (F + {#x#})"
   735     proof (rule insert)
   736       from i show "x \<in># A" by (auto dest: mset_le_insertD)
   737       from i have "F \<le> A" by (auto dest: mset_le_insertD)
   738       with P show "P F" .
   739     qed
   740   qed
   741 qed
   742 
   743 
   744 subsection {* The fold combinator *}
   745 
   746 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
   747 where
   748   "fold f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_of M)"
   749 
   750 lemma fold_mset_empty [simp]:
   751   "fold f s {#} = s"
   752   by (simp add: fold_def)
   753 
   754 context comp_fun_commute
   755 begin
   756 
   757 lemma fold_mset_insert:
   758   "fold f s (M + {#x#}) = f x (fold f s M)"
   759 proof -
   760   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
   761     by (fact comp_fun_commute_funpow)
   762   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (M + {#x#}) y"
   763     by (fact comp_fun_commute_funpow)
   764   show ?thesis
   765   proof (cases "x \<in> set_of M")
   766     case False
   767     then have *: "count (M + {#x#}) x = 1" by simp
   768     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s (set_of M) =
   769       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_of M)"
   770       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   771     with False * show ?thesis
   772       by (simp add: fold_def del: count_union)
   773   next
   774     case True
   775     def N \<equiv> "set_of M - {x}"
   776     from N_def True have *: "set_of M = insert x N" "x \<notin> N" "finite N" by auto
   777     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s N =
   778       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
   779       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   780     with * show ?thesis by (simp add: fold_def del: count_union) simp
   781   qed
   782 qed
   783 
   784 corollary fold_mset_single [simp]:
   785   "fold f s {#x#} = f x s"
   786 proof -
   787   have "fold f s ({#} + {#x#}) = f x s" by (simp only: fold_mset_insert) simp
   788   then show ?thesis by simp
   789 qed
   790 
   791 lemma fold_mset_fun_left_comm:
   792   "f x (fold f s M) = fold f (f x s) M"
   793   by (induct M) (simp_all add: fold_mset_insert fun_left_comm)
   794 
   795 lemma fold_mset_union [simp]:
   796   "fold f s (M + N) = fold f (fold f s M) N"
   797 proof (induct M)
   798   case empty then show ?case by simp
   799 next
   800   case (add M x)
   801   have "M + {#x#} + N = (M + N) + {#x#}"
   802     by (simp add: add_ac)
   803   with add show ?case by (simp add: fold_mset_insert fold_mset_fun_left_comm)
   804 qed
   805 
   806 lemma fold_mset_fusion:
   807   assumes "comp_fun_commute g"
   808   shows "(\<And>x y. h (g x y) = f x (h y)) \<Longrightarrow> h (fold g w A) = fold f (h w) A" (is "PROP ?P")
   809 proof -
   810   interpret comp_fun_commute g by (fact assms)
   811   show "PROP ?P" by (induct A) auto
   812 qed
   813 
   814 end
   815 
   816 text {*
   817   A note on code generation: When defining some function containing a
   818   subterm @{term "fold F"}, code generation is not automatic. When
   819   interpreting locale @{text left_commutative} with @{text F}, the
   820   would be code thms for @{const fold} become thms like
   821   @{term "fold F z {#} = z"} where @{text F} is not a pattern but
   822   contains defined symbols, i.e.\ is not a code thm. Hence a separate
   823   constant with its own code thms needs to be introduced for @{text
   824   F}. See the image operator below.
   825 *}
   826 
   827 
   828 subsection {* Image *}
   829 
   830 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
   831   "image_mset f = fold (plus o single o f) {#}"
   832 
   833 lemma comp_fun_commute_mset_image:
   834   "comp_fun_commute (plus o single o f)"
   835 proof
   836 qed (simp add: add_ac fun_eq_iff)
   837 
   838 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
   839   by (simp add: image_mset_def)
   840 
   841 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
   842 proof -
   843   interpret comp_fun_commute "plus o single o f"
   844     by (fact comp_fun_commute_mset_image)
   845   show ?thesis by (simp add: image_mset_def)
   846 qed
   847 
   848 lemma image_mset_union [simp]:
   849   "image_mset f (M + N) = image_mset f M + image_mset f N"
   850 proof -
   851   interpret comp_fun_commute "plus o single o f"
   852     by (fact comp_fun_commute_mset_image)
   853   show ?thesis by (induct N) (simp_all add: image_mset_def add_ac)
   854 qed
   855 
   856 corollary image_mset_insert:
   857   "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
   858   by simp
   859 
   860 lemma set_of_image_mset [simp]:
   861   "set_of (image_mset f M) = image f (set_of M)"
   862   by (induct M) simp_all
   863 
   864 lemma size_image_mset [simp]:
   865   "size (image_mset f M) = size M"
   866   by (induct M) simp_all
   867 
   868 lemma image_mset_is_empty_iff [simp]:
   869   "image_mset f M = {#} \<longleftrightarrow> M = {#}"
   870   by (cases M) auto
   871 
   872 syntax
   873   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   874       ("({#_/. _ :# _#})")
   875 translations
   876   "{#e. x:#M#}" == "CONST image_mset (%x. e) M"
   877 
   878 syntax
   879   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   880       ("({#_/ | _ :# _./ _#})")
   881 translations
   882   "{#e | x:#M. P#}" => "{#e. x :# {# x:#M. P#}#}"
   883 
   884 text {*
   885   This allows to write not just filters like @{term "{#x:#M. x<c#}"}
   886   but also images like @{term "{#x+x. x:#M #}"} and @{term [source]
   887   "{#x+x|x:#M. x<c#}"}, where the latter is currently displayed as
   888   @{term "{#x+x|x:#M. x<c#}"}.
   889 *}
   890 
   891 functor image_mset: image_mset
   892 proof -
   893   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
   894   proof
   895     fix A
   896     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
   897       by (induct A) simp_all
   898   qed
   899   show "image_mset id = id"
   900   proof
   901     fix A
   902     show "image_mset id A = id A"
   903       by (induct A) simp_all
   904   qed
   905 qed
   906 
   907 declare image_mset.identity [simp]
   908 
   909 
   910 subsection {* Further conversions *}
   911 
   912 primrec multiset_of :: "'a list \<Rightarrow> 'a multiset" where
   913   "multiset_of [] = {#}" |
   914   "multiset_of (a # x) = multiset_of x + {# a #}"
   915 
   916 lemma in_multiset_in_set:
   917   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
   918   by (induct xs) simp_all
   919 
   920 lemma count_multiset_of:
   921   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
   922   by (induct xs) simp_all
   923 
   924 lemma multiset_of_zero_iff[simp]: "(multiset_of x = {#}) = (x = [])"
   925 by (induct x) auto
   926 
   927 lemma multiset_of_zero_iff_right[simp]: "({#} = multiset_of x) = (x = [])"
   928 by (induct x) auto
   929 
   930 lemma set_of_multiset_of[simp]: "set_of (multiset_of x) = set x"
   931 by (induct x) auto
   932 
   933 lemma mem_set_multiset_eq: "x \<in> set xs = (x :# multiset_of xs)"
   934 by (induct xs) auto
   935 
   936 lemma size_multiset_of [simp]: "size (multiset_of xs) = length xs"
   937   by (induct xs) simp_all
   938 
   939 lemma multiset_of_append [simp]:
   940   "multiset_of (xs @ ys) = multiset_of xs + multiset_of ys"
   941   by (induct xs arbitrary: ys) (auto simp: add_ac)
   942 
   943 lemma multiset_of_filter:
   944   "multiset_of (filter P xs) = {#x :# multiset_of xs. P x #}"
   945   by (induct xs) simp_all
   946 
   947 lemma multiset_of_rev [simp]:
   948   "multiset_of (rev xs) = multiset_of xs"
   949   by (induct xs) simp_all
   950 
   951 lemma surj_multiset_of: "surj multiset_of"
   952 apply (unfold surj_def)
   953 apply (rule allI)
   954 apply (rule_tac M = y in multiset_induct)
   955  apply auto
   956 apply (rule_tac x = "x # xa" in exI)
   957 apply auto
   958 done
   959 
   960 lemma set_count_greater_0: "set x = {a. count (multiset_of x) a > 0}"
   961 by (induct x) auto
   962 
   963 lemma distinct_count_atmost_1:
   964   "distinct x = (! a. count (multiset_of x) a = (if a \<in> set x then 1 else 0))"
   965 apply (induct x, simp, rule iffI, simp_all)
   966 apply (rename_tac a b)
   967 apply (rule conjI)
   968 apply (simp_all add: set_of_multiset_of [THEN sym] del: set_of_multiset_of)
   969 apply (erule_tac x = a in allE, simp, clarify)
   970 apply (erule_tac x = aa in allE, simp)
   971 done
   972 
   973 lemma multiset_of_eq_setD:
   974   "multiset_of xs = multiset_of ys \<Longrightarrow> set xs = set ys"
   975 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
   976 
   977 lemma set_eq_iff_multiset_of_eq_distinct:
   978   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
   979     (set x = set y) = (multiset_of x = multiset_of y)"
   980 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
   981 
   982 lemma set_eq_iff_multiset_of_remdups_eq:
   983    "(set x = set y) = (multiset_of (remdups x) = multiset_of (remdups y))"
   984 apply (rule iffI)
   985 apply (simp add: set_eq_iff_multiset_of_eq_distinct[THEN iffD1])
   986 apply (drule distinct_remdups [THEN distinct_remdups
   987       [THEN set_eq_iff_multiset_of_eq_distinct [THEN iffD2]]])
   988 apply simp
   989 done
   990 
   991 lemma multiset_of_compl_union [simp]:
   992   "multiset_of [x\<leftarrow>xs. P x] + multiset_of [x\<leftarrow>xs. \<not>P x] = multiset_of xs"
   993   by (induct xs) (auto simp: add_ac)
   994 
   995 lemma count_multiset_of_length_filter:
   996   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
   997   by (induct xs) auto
   998 
   999 lemma nth_mem_multiset_of: "i < length ls \<Longrightarrow> (ls ! i) :# multiset_of ls"
  1000 apply (induct ls arbitrary: i)
  1001  apply simp
  1002 apply (case_tac i)
  1003  apply auto
  1004 done
  1005 
  1006 lemma multiset_of_remove1[simp]:
  1007   "multiset_of (remove1 a xs) = multiset_of xs - {#a#}"
  1008 by (induct xs) (auto simp add: multiset_eq_iff)
  1009 
  1010 lemma multiset_of_eq_length:
  1011   assumes "multiset_of xs = multiset_of ys"
  1012   shows "length xs = length ys"
  1013   using assms by (metis size_multiset_of)
  1014 
  1015 lemma multiset_of_eq_length_filter:
  1016   assumes "multiset_of xs = multiset_of ys"
  1017   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
  1018   using assms by (metis count_multiset_of)
  1019 
  1020 lemma fold_multiset_equiv:
  1021   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1022     and equiv: "multiset_of xs = multiset_of ys"
  1023   shows "List.fold f xs = List.fold f ys"
  1024 using f equiv [symmetric]
  1025 proof (induct xs arbitrary: ys)
  1026   case Nil then show ?case by simp
  1027 next
  1028   case (Cons x xs)
  1029   then have *: "set ys = set (x # xs)" by (blast dest: multiset_of_eq_setD)
  1030   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x" 
  1031     by (rule Cons.prems(1)) (simp_all add: *)
  1032   moreover from * have "x \<in> set ys" by simp
  1033   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x" by (fact fold_remove1_split)
  1034   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)" by (auto intro: Cons.hyps)
  1035   ultimately show ?case by simp
  1036 qed
  1037 
  1038 lemma multiset_of_insort [simp]:
  1039   "multiset_of (insort x xs) = multiset_of xs + {#x#}"
  1040   by (induct xs) (simp_all add: ac_simps)
  1041 
  1042 lemma in_multiset_of:
  1043   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
  1044   by (induct xs) simp_all
  1045 
  1046 lemma multiset_of_map:
  1047   "multiset_of (map f xs) = image_mset f (multiset_of xs)"
  1048   by (induct xs) simp_all
  1049 
  1050 definition multiset_of_set :: "'a set \<Rightarrow> 'a multiset"
  1051 where
  1052   "multiset_of_set = folding.F (\<lambda>x M. {#x#} + M) {#}"
  1053 
  1054 interpretation multiset_of_set!: folding "\<lambda>x M. {#x#} + M" "{#}"
  1055 where
  1056   "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set"
  1057 proof -
  1058   interpret comp_fun_commute "\<lambda>x M. {#x#} + M" by default (simp add: fun_eq_iff ac_simps)
  1059   show "folding (\<lambda>x M. {#x#} + M)" by default (fact comp_fun_commute)
  1060   from multiset_of_set_def show "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set" ..
  1061 qed
  1062 
  1063 lemma count_multiset_of_set [simp]:
  1064   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (multiset_of_set A) x = 1" (is "PROP ?P")
  1065   "\<not> finite A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?Q")
  1066   "x \<notin> A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?R")
  1067 proof -
  1068   { fix A
  1069     assume "x \<notin> A"
  1070     have "count (multiset_of_set A) x = 0"
  1071     proof (cases "finite A")
  1072       case False then show ?thesis by simp
  1073     next
  1074       case True from True `x \<notin> A` show ?thesis by (induct A) auto
  1075     qed
  1076   } note * = this
  1077   then show "PROP ?P" "PROP ?Q" "PROP ?R"
  1078   by (auto elim!: Set.set_insert)
  1079 qed -- {* TODO: maybe define @{const multiset_of_set} also in terms of @{const Abs_multiset} *}
  1080 
  1081 context linorder
  1082 begin
  1083 
  1084 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
  1085 where
  1086   "sorted_list_of_multiset M = fold insort [] M"
  1087 
  1088 lemma sorted_list_of_multiset_empty [simp]:
  1089   "sorted_list_of_multiset {#} = []"
  1090   by (simp add: sorted_list_of_multiset_def)
  1091 
  1092 lemma sorted_list_of_multiset_singleton [simp]:
  1093   "sorted_list_of_multiset {#x#} = [x]"
  1094 proof -
  1095   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1096   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1097 qed
  1098 
  1099 lemma sorted_list_of_multiset_insert [simp]:
  1100   "sorted_list_of_multiset (M + {#x#}) = List.insort x (sorted_list_of_multiset M)"
  1101 proof -
  1102   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1103   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1104 qed
  1105 
  1106 end
  1107 
  1108 lemma multiset_of_sorted_list_of_multiset [simp]:
  1109   "multiset_of (sorted_list_of_multiset M) = M"
  1110   by (induct M) simp_all
  1111 
  1112 lemma sorted_list_of_multiset_multiset_of [simp]:
  1113   "sorted_list_of_multiset (multiset_of xs) = sort xs"
  1114   by (induct xs) simp_all
  1115 
  1116 lemma finite_set_of_multiset_of_set:
  1117   assumes "finite A"
  1118   shows "set_of (multiset_of_set A) = A"
  1119   using assms by (induct A) simp_all
  1120 
  1121 lemma infinite_set_of_multiset_of_set:
  1122   assumes "\<not> finite A"
  1123   shows "set_of (multiset_of_set A) = {}"
  1124   using assms by simp
  1125 
  1126 lemma set_sorted_list_of_multiset [simp]:
  1127   "set (sorted_list_of_multiset M) = set_of M"
  1128   by (induct M) (simp_all add: set_insort)
  1129 
  1130 lemma sorted_list_of_multiset_of_set [simp]:
  1131   "sorted_list_of_multiset (multiset_of_set A) = sorted_list_of_set A"
  1132   by (cases "finite A") (induct A rule: finite_induct, simp_all add: ac_simps)
  1133 
  1134 
  1135 subsection {* Big operators *}
  1136 
  1137 no_notation times (infixl "*" 70)
  1138 no_notation Groups.one ("1")
  1139 
  1140 locale comm_monoid_mset = comm_monoid
  1141 begin
  1142 
  1143 definition F :: "'a multiset \<Rightarrow> 'a"
  1144 where
  1145   eq_fold: "F M = Multiset.fold f 1 M"
  1146 
  1147 lemma empty [simp]:
  1148   "F {#} = 1"
  1149   by (simp add: eq_fold)
  1150 
  1151 lemma singleton [simp]:
  1152   "F {#x#} = x"
  1153 proof -
  1154   interpret comp_fun_commute
  1155     by default (simp add: fun_eq_iff left_commute)
  1156   show ?thesis by (simp add: eq_fold)
  1157 qed
  1158 
  1159 lemma union [simp]:
  1160   "F (M + N) = F M * F N"
  1161 proof -
  1162   interpret comp_fun_commute f
  1163     by default (simp add: fun_eq_iff left_commute)
  1164   show ?thesis by (induct N) (simp_all add: left_commute eq_fold)
  1165 qed
  1166 
  1167 end
  1168 
  1169 notation times (infixl "*" 70)
  1170 notation Groups.one ("1")
  1171 
  1172 context comm_monoid_add
  1173 begin
  1174 
  1175 definition msetsum :: "'a multiset \<Rightarrow> 'a"
  1176 where
  1177   "msetsum = comm_monoid_mset.F plus 0"
  1178 
  1179 sublocale msetsum!: comm_monoid_mset plus 0
  1180 where
  1181   "comm_monoid_mset.F plus 0 = msetsum"
  1182 proof -
  1183   show "comm_monoid_mset plus 0" ..
  1184   from msetsum_def show "comm_monoid_mset.F plus 0 = msetsum" ..
  1185 qed
  1186 
  1187 lemma setsum_unfold_msetsum:
  1188   "setsum f A = msetsum (image_mset f (multiset_of_set A))"
  1189   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1190 
  1191 abbreviation msetsum_image :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b multiset \<Rightarrow> 'a"
  1192 where
  1193   "msetsum_image f M \<equiv> msetsum (image_mset f M)"
  1194 
  1195 end
  1196 
  1197 syntax
  1198   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1199       ("(3SUM _:#_. _)" [0, 51, 10] 10)
  1200 
  1201 syntax (xsymbols)
  1202   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1203       ("(3\<Sum>_:#_. _)" [0, 51, 10] 10)
  1204 
  1205 syntax (HTML output)
  1206   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1207       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1208 
  1209 translations
  1210   "SUM i :# A. b" == "CONST msetsum_image (\<lambda>i. b) A"
  1211 
  1212 context comm_monoid_mult
  1213 begin
  1214 
  1215 definition msetprod :: "'a multiset \<Rightarrow> 'a"
  1216 where
  1217   "msetprod = comm_monoid_mset.F times 1"
  1218 
  1219 sublocale msetprod!: comm_monoid_mset times 1
  1220 where
  1221   "comm_monoid_mset.F times 1 = msetprod"
  1222 proof -
  1223   show "comm_monoid_mset times 1" ..
  1224   from msetprod_def show "comm_monoid_mset.F times 1 = msetprod" ..
  1225 qed
  1226 
  1227 lemma msetprod_empty:
  1228   "msetprod {#} = 1"
  1229   by (fact msetprod.empty)
  1230 
  1231 lemma msetprod_singleton:
  1232   "msetprod {#x#} = x"
  1233   by (fact msetprod.singleton)
  1234 
  1235 lemma msetprod_Un:
  1236   "msetprod (A + B) = msetprod A * msetprod B" 
  1237   by (fact msetprod.union)
  1238 
  1239 lemma setprod_unfold_msetprod:
  1240   "setprod f A = msetprod (image_mset f (multiset_of_set A))"
  1241   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1242 
  1243 lemma msetprod_multiplicity:
  1244   "msetprod M = setprod (\<lambda>x. x ^ count M x) (set_of M)"
  1245   by (simp add: Multiset.fold_def setprod.eq_fold msetprod.eq_fold funpow_times_power comp_def)
  1246 
  1247 abbreviation msetprod_image :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b multiset \<Rightarrow> 'a"
  1248 where
  1249   "msetprod_image f M \<equiv> msetprod (image_mset f M)"
  1250 
  1251 end
  1252 
  1253 syntax
  1254   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1255       ("(3PROD _:#_. _)" [0, 51, 10] 10)
  1256 
  1257 syntax (xsymbols)
  1258   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1259       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1260 
  1261 syntax (HTML output)
  1262   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1263       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1264 
  1265 translations
  1266   "PROD i :# A. b" == "CONST msetprod_image (\<lambda>i. b) A"
  1267 
  1268 lemma (in comm_semiring_1) dvd_msetprod:
  1269   assumes "x \<in># A"
  1270   shows "x dvd msetprod A"
  1271 proof -
  1272   from assms have "A = (A - {#x#}) + {#x#}" by simp
  1273   then obtain B where "A = B + {#x#}" ..
  1274   then show ?thesis by simp
  1275 qed
  1276 
  1277 
  1278 subsection {* Cardinality *}
  1279 
  1280 definition mcard :: "'a multiset \<Rightarrow> nat"
  1281 where
  1282   "mcard = msetsum \<circ> image_mset (\<lambda>_. 1)"
  1283 
  1284 lemma mcard_empty [simp]:
  1285   "mcard {#} = 0"
  1286   by (simp add: mcard_def)
  1287 
  1288 lemma mcard_singleton [simp]:
  1289   "mcard {#a#} = Suc 0"
  1290   by (simp add: mcard_def)
  1291 
  1292 lemma mcard_plus [simp]:
  1293   "mcard (M + N) = mcard M + mcard N"
  1294   by (simp add: mcard_def)
  1295 
  1296 lemma mcard_empty_iff [simp]:
  1297   "mcard M = 0 \<longleftrightarrow> M = {#}"
  1298   by (induct M) simp_all
  1299 
  1300 lemma mcard_unfold_setsum:
  1301   "mcard M = setsum (count M) (set_of M)"
  1302 proof (induct M)
  1303   case empty then show ?case by simp
  1304 next
  1305   case (add M x) then show ?case
  1306     by (cases "x \<in> set_of M")
  1307       (simp_all del: mem_set_of_iff add: setsum.distrib setsum.delta' insert_absorb, simp)
  1308 qed
  1309 
  1310 lemma size_eq_mcard:
  1311   "size = mcard"
  1312   by (simp add: fun_eq_iff size_def mcard_unfold_setsum)
  1313 
  1314 lemma mcard_multiset_of:
  1315   "mcard (multiset_of xs) = length xs"
  1316   by (induct xs) simp_all
  1317 
  1318 
  1319 subsection {* Alternative representations *}
  1320 
  1321 subsubsection {* Lists *}
  1322 
  1323 context linorder
  1324 begin
  1325 
  1326 lemma multiset_of_insort [simp]:
  1327   "multiset_of (insort_key k x xs) = {#x#} + multiset_of xs"
  1328   by (induct xs) (simp_all add: ac_simps)
  1329  
  1330 lemma multiset_of_sort [simp]:
  1331   "multiset_of (sort_key k xs) = multiset_of xs"
  1332   by (induct xs) (simp_all add: ac_simps)
  1333 
  1334 text {*
  1335   This lemma shows which properties suffice to show that a function
  1336   @{text "f"} with @{text "f xs = ys"} behaves like sort.
  1337 *}
  1338 
  1339 lemma properties_for_sort_key:
  1340   assumes "multiset_of ys = multiset_of xs"
  1341   and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  1342   and "sorted (map f ys)"
  1343   shows "sort_key f xs = ys"
  1344 using assms
  1345 proof (induct xs arbitrary: ys)
  1346   case Nil then show ?case by simp
  1347 next
  1348   case (Cons x xs)
  1349   from Cons.prems(2) have
  1350     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  1351     by (simp add: filter_remove1)
  1352   with Cons.prems have "sort_key f xs = remove1 x ys"
  1353     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  1354   moreover from Cons.prems have "x \<in> set ys"
  1355     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
  1356   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  1357 qed
  1358 
  1359 lemma properties_for_sort:
  1360   assumes multiset: "multiset_of ys = multiset_of xs"
  1361   and "sorted ys"
  1362   shows "sort xs = ys"
  1363 proof (rule properties_for_sort_key)
  1364   from multiset show "multiset_of ys = multiset_of xs" .
  1365   from `sorted ys` show "sorted (map (\<lambda>x. x) ys)" by simp
  1366   from multiset have "\<And>k. length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)"
  1367     by (rule multiset_of_eq_length_filter)
  1368   then have "\<And>k. replicate (length (filter (\<lambda>y. k = y) ys)) k = replicate (length (filter (\<lambda>x. k = x) xs)) k"
  1369     by simp
  1370   then show "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs"
  1371     by (simp add: replicate_length_filter)
  1372 qed
  1373 
  1374 lemma sort_key_by_quicksort:
  1375   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  1376     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  1377     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  1378 proof (rule properties_for_sort_key)
  1379   show "multiset_of ?rhs = multiset_of ?lhs"
  1380     by (rule multiset_eqI) (auto simp add: multiset_of_filter)
  1381 next
  1382   show "sorted (map f ?rhs)"
  1383     by (auto simp add: sorted_append intro: sorted_map_same)
  1384 next
  1385   fix l
  1386   assume "l \<in> set ?rhs"
  1387   let ?pivot = "f (xs ! (length xs div 2))"
  1388   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  1389   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  1390     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  1391   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  1392   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  1393   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  1394     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  1395   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  1396   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  1397   proof (cases "f l" ?pivot rule: linorder_cases)
  1398     case less
  1399     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  1400     with less show ?thesis
  1401       by (simp add: filter_sort [symmetric] ** ***)
  1402   next
  1403     case equal then show ?thesis
  1404       by (simp add: * less_le)
  1405   next
  1406     case greater
  1407     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  1408     with greater show ?thesis
  1409       by (simp add: filter_sort [symmetric] ** ***)
  1410   qed
  1411 qed
  1412 
  1413 lemma sort_by_quicksort:
  1414   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  1415     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  1416     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  1417   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  1418 
  1419 text {* A stable parametrized quicksort *}
  1420 
  1421 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  1422   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  1423 
  1424 lemma part_code [code]:
  1425   "part f pivot [] = ([], [], [])"
  1426   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  1427      if x' < pivot then (x # lts, eqs, gts)
  1428      else if x' > pivot then (lts, eqs, x # gts)
  1429      else (lts, x # eqs, gts))"
  1430   by (auto simp add: part_def Let_def split_def)
  1431 
  1432 lemma sort_key_by_quicksort_code [code]:
  1433   "sort_key f xs = (case xs of [] \<Rightarrow> []
  1434     | [x] \<Rightarrow> xs
  1435     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  1436     | _ \<Rightarrow> (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1437        in sort_key f lts @ eqs @ sort_key f gts))"
  1438 proof (cases xs)
  1439   case Nil then show ?thesis by simp
  1440 next
  1441   case (Cons _ ys) note hyps = Cons show ?thesis
  1442   proof (cases ys)
  1443     case Nil with hyps show ?thesis by simp
  1444   next
  1445     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  1446     proof (cases zs)
  1447       case Nil with hyps show ?thesis by auto
  1448     next
  1449       case Cons 
  1450       from sort_key_by_quicksort [of f xs]
  1451       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1452         in sort_key f lts @ eqs @ sort_key f gts)"
  1453       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  1454       with hyps Cons show ?thesis by (simp only: list.cases)
  1455     qed
  1456   qed
  1457 qed
  1458 
  1459 end
  1460 
  1461 hide_const (open) part
  1462 
  1463 lemma multiset_of_remdups_le: "multiset_of (remdups xs) \<le> multiset_of xs"
  1464   by (induct xs) (auto intro: order_trans)
  1465 
  1466 lemma multiset_of_update:
  1467   "i < length ls \<Longrightarrow> multiset_of (ls[i := v]) = multiset_of ls - {#ls ! i#} + {#v#}"
  1468 proof (induct ls arbitrary: i)
  1469   case Nil then show ?case by simp
  1470 next
  1471   case (Cons x xs)
  1472   show ?case
  1473   proof (cases i)
  1474     case 0 then show ?thesis by simp
  1475   next
  1476     case (Suc i')
  1477     with Cons show ?thesis
  1478       apply simp
  1479       apply (subst add_assoc)
  1480       apply (subst add_commute [of "{#v#}" "{#x#}"])
  1481       apply (subst add_assoc [symmetric])
  1482       apply simp
  1483       apply (rule mset_le_multiset_union_diff_commute)
  1484       apply (simp add: mset_le_single nth_mem_multiset_of)
  1485       done
  1486   qed
  1487 qed
  1488 
  1489 lemma multiset_of_swap:
  1490   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  1491     multiset_of (ls[j := ls ! i, i := ls ! j]) = multiset_of ls"
  1492   by (cases "i = j") (simp_all add: multiset_of_update nth_mem_multiset_of)
  1493 
  1494 
  1495 subsection {* The multiset order *}
  1496 
  1497 subsubsection {* Well-foundedness *}
  1498 
  1499 definition mult1 :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1500   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
  1501       (\<forall>b. b :# K --> (b, a) \<in> r)}"
  1502 
  1503 definition mult :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1504   "mult r = (mult1 r)\<^sup>+"
  1505 
  1506 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  1507 by (simp add: mult1_def)
  1508 
  1509 lemma less_add: "(N, M0 + {#a#}) \<in> mult1 r ==>
  1510     (\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
  1511     (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K)"
  1512   (is "_ \<Longrightarrow> ?case1 (mult1 r) \<or> ?case2")
  1513 proof (unfold mult1_def)
  1514   let ?r = "\<lambda>K a. \<forall>b. b :# K --> (b, a) \<in> r"
  1515   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
  1516   let ?case1 = "?case1 {(N, M). ?R N M}"
  1517 
  1518   assume "(N, M0 + {#a#}) \<in> {(N, M). ?R N M}"
  1519   then have "\<exists>a' M0' K.
  1520       M0 + {#a#} = M0' + {#a'#} \<and> N = M0' + K \<and> ?r K a'" by simp
  1521   then show "?case1 \<or> ?case2"
  1522   proof (elim exE conjE)
  1523     fix a' M0' K
  1524     assume N: "N = M0' + K" and r: "?r K a'"
  1525     assume "M0 + {#a#} = M0' + {#a'#}"
  1526     then have "M0 = M0' \<and> a = a' \<or>
  1527         (\<exists>K'. M0 = K' + {#a'#} \<and> M0' = K' + {#a#})"
  1528       by (simp only: add_eq_conv_ex)
  1529     then show ?thesis
  1530     proof (elim disjE conjE exE)
  1531       assume "M0 = M0'" "a = a'"
  1532       with N r have "?r K a \<and> N = M0 + K" by simp
  1533       then have ?case2 .. then show ?thesis ..
  1534     next
  1535       fix K'
  1536       assume "M0' = K' + {#a#}"
  1537       with N have n: "N = K' + K + {#a#}" by (simp add: add_ac)
  1538 
  1539       assume "M0 = K' + {#a'#}"
  1540       with r have "?R (K' + K) M0" by blast
  1541       with n have ?case1 by simp then show ?thesis ..
  1542     qed
  1543   qed
  1544 qed
  1545 
  1546 lemma all_accessible: "wf r ==> \<forall>M. M \<in> Wellfounded.acc (mult1 r)"
  1547 proof
  1548   let ?R = "mult1 r"
  1549   let ?W = "Wellfounded.acc ?R"
  1550   {
  1551     fix M M0 a
  1552     assume M0: "M0 \<in> ?W"
  1553       and wf_hyp: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1554       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R --> M + {#a#} \<in> ?W"
  1555     have "M0 + {#a#} \<in> ?W"
  1556     proof (rule accI [of "M0 + {#a#}"])
  1557       fix N
  1558       assume "(N, M0 + {#a#}) \<in> ?R"
  1559       then have "((\<exists>M. (M, M0) \<in> ?R \<and> N = M + {#a#}) \<or>
  1560           (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K))"
  1561         by (rule less_add)
  1562       then show "N \<in> ?W"
  1563       proof (elim exE disjE conjE)
  1564         fix M assume "(M, M0) \<in> ?R" and N: "N = M + {#a#}"
  1565         from acc_hyp have "(M, M0) \<in> ?R --> M + {#a#} \<in> ?W" ..
  1566         from this and `(M, M0) \<in> ?R` have "M + {#a#} \<in> ?W" ..
  1567         then show "N \<in> ?W" by (simp only: N)
  1568       next
  1569         fix K
  1570         assume N: "N = M0 + K"
  1571         assume "\<forall>b. b :# K --> (b, a) \<in> r"
  1572         then have "M0 + K \<in> ?W"
  1573         proof (induct K)
  1574           case empty
  1575           from M0 show "M0 + {#} \<in> ?W" by simp
  1576         next
  1577           case (add K x)
  1578           from add.prems have "(x, a) \<in> r" by simp
  1579           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
  1580           moreover from add have "M0 + K \<in> ?W" by simp
  1581           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
  1582           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add_assoc)
  1583         qed
  1584         then show "N \<in> ?W" by (simp only: N)
  1585       qed
  1586     qed
  1587   } note tedious_reasoning = this
  1588 
  1589   assume wf: "wf r"
  1590   fix M
  1591   show "M \<in> ?W"
  1592   proof (induct M)
  1593     show "{#} \<in> ?W"
  1594     proof (rule accI)
  1595       fix b assume "(b, {#}) \<in> ?R"
  1596       with not_less_empty show "b \<in> ?W" by contradiction
  1597     qed
  1598 
  1599     fix M a assume "M \<in> ?W"
  1600     from wf have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1601     proof induct
  1602       fix a
  1603       assume r: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1604       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1605       proof
  1606         fix M assume "M \<in> ?W"
  1607         then show "M + {#a#} \<in> ?W"
  1608           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  1609       qed
  1610     qed
  1611     from this and `M \<in> ?W` show "M + {#a#} \<in> ?W" ..
  1612   qed
  1613 qed
  1614 
  1615 theorem wf_mult1: "wf r ==> wf (mult1 r)"
  1616 by (rule acc_wfI) (rule all_accessible)
  1617 
  1618 theorem wf_mult: "wf r ==> wf (mult r)"
  1619 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  1620 
  1621 
  1622 subsubsection {* Closure-free presentation *}
  1623 
  1624 text {* One direction. *}
  1625 
  1626 lemma mult_implies_one_step:
  1627   "trans r ==> (M, N) \<in> mult r ==>
  1628     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
  1629     (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r)"
  1630 apply (unfold mult_def mult1_def set_of_def)
  1631 apply (erule converse_trancl_induct, clarify)
  1632  apply (rule_tac x = M0 in exI, simp, clarify)
  1633 apply (case_tac "a :# K")
  1634  apply (rule_tac x = I in exI)
  1635  apply (simp (no_asm))
  1636  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
  1637  apply (simp (no_asm_simp) add: add_assoc [symmetric])
  1638  apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong)
  1639  apply (simp add: diff_union_single_conv)
  1640  apply (simp (no_asm_use) add: trans_def)
  1641  apply blast
  1642 apply (subgoal_tac "a :# I")
  1643  apply (rule_tac x = "I - {#a#}" in exI)
  1644  apply (rule_tac x = "J + {#a#}" in exI)
  1645  apply (rule_tac x = "K + Ka" in exI)
  1646  apply (rule conjI)
  1647   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1648  apply (rule conjI)
  1649   apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong, simp)
  1650   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1651  apply (simp (no_asm_use) add: trans_def)
  1652  apply blast
  1653 apply (subgoal_tac "a :# (M0 + {#a#})")
  1654  apply simp
  1655 apply (simp (no_asm))
  1656 done
  1657 
  1658 lemma one_step_implies_mult_aux:
  1659   "trans r ==>
  1660     \<forall>I J K. (size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r))
  1661       --> (I + K, I + J) \<in> mult r"
  1662 apply (induct_tac n, auto)
  1663 apply (frule size_eq_Suc_imp_eq_union, clarify)
  1664 apply (rename_tac "J'", simp)
  1665 apply (erule notE, auto)
  1666 apply (case_tac "J' = {#}")
  1667  apply (simp add: mult_def)
  1668  apply (rule r_into_trancl)
  1669  apply (simp add: mult1_def set_of_def, blast)
  1670 txt {* Now we know @{term "J' \<noteq> {#}"}. *}
  1671 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
  1672 apply (erule_tac P = "\<forall>k \<in> set_of K. ?P k" in rev_mp)
  1673 apply (erule ssubst)
  1674 apply (simp add: Ball_def, auto)
  1675 apply (subgoal_tac
  1676   "((I + {# x :# K. (x, a) \<in> r #}) + {# x :# K. (x, a) \<notin> r #},
  1677     (I + {# x :# K. (x, a) \<in> r #}) + J') \<in> mult r")
  1678  prefer 2
  1679  apply force
  1680 apply (simp (no_asm_use) add: add_assoc [symmetric] mult_def)
  1681 apply (erule trancl_trans)
  1682 apply (rule r_into_trancl)
  1683 apply (simp add: mult1_def set_of_def)
  1684 apply (rule_tac x = a in exI)
  1685 apply (rule_tac x = "I + J'" in exI)
  1686 apply (simp add: add_ac)
  1687 done
  1688 
  1689 lemma one_step_implies_mult:
  1690   "trans r ==> J \<noteq> {#} ==> \<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r
  1691     ==> (I + K, I + J) \<in> mult r"
  1692 using one_step_implies_mult_aux by blast
  1693 
  1694 
  1695 subsubsection {* Partial-order properties *}
  1696 
  1697 definition less_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
  1698   "M' <# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  1699 
  1700 definition le_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
  1701   "M' <=# M \<longleftrightarrow> M' <# M \<or> M' = M"
  1702 
  1703 notation (xsymbols) less_multiset (infix "\<subset>#" 50)
  1704 notation (xsymbols) le_multiset (infix "\<subseteq>#" 50)
  1705 
  1706 interpretation multiset_order: order le_multiset less_multiset
  1707 proof -
  1708   have irrefl: "\<And>M :: 'a multiset. \<not> M \<subset># M"
  1709   proof
  1710     fix M :: "'a multiset"
  1711     assume "M \<subset># M"
  1712     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  1713     have "trans {(x'::'a, x). x' < x}"
  1714       by (rule transI) simp
  1715     moreover note MM
  1716     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  1717       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})"
  1718       by (rule mult_implies_one_step)
  1719     then obtain I J K where "M = I + J" and "M = I + K"
  1720       and "J \<noteq> {#}" and "(\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})" by blast
  1721     then have aux1: "K \<noteq> {#}" and aux2: "\<forall>k\<in>set_of K. \<exists>j\<in>set_of K. k < j" by auto
  1722     have "finite (set_of K)" by simp
  1723     moreover note aux2
  1724     ultimately have "set_of K = {}"
  1725       by (induct rule: finite_induct) (auto intro: order_less_trans)
  1726     with aux1 show False by simp
  1727   qed
  1728   have trans: "\<And>K M N :: 'a multiset. K \<subset># M \<Longrightarrow> M \<subset># N \<Longrightarrow> K \<subset># N"
  1729     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  1730   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset"
  1731     by default (auto simp add: le_multiset_def irrefl dest: trans)
  1732 qed
  1733 
  1734 lemma mult_less_irrefl [elim!]: "M \<subset># (M::'a::order multiset) ==> R"
  1735   by simp
  1736 
  1737 
  1738 subsubsection {* Monotonicity of multiset union *}
  1739 
  1740 lemma mult1_union: "(B, D) \<in> mult1 r ==> (C + B, C + D) \<in> mult1 r"
  1741 apply (unfold mult1_def)
  1742 apply auto
  1743 apply (rule_tac x = a in exI)
  1744 apply (rule_tac x = "C + M0" in exI)
  1745 apply (simp add: add_assoc)
  1746 done
  1747 
  1748 lemma union_less_mono2: "B \<subset># D ==> C + B \<subset># C + (D::'a::order multiset)"
  1749 apply (unfold less_multiset_def mult_def)
  1750 apply (erule trancl_induct)
  1751  apply (blast intro: mult1_union)
  1752 apply (blast intro: mult1_union trancl_trans)
  1753 done
  1754 
  1755 lemma union_less_mono1: "B \<subset># D ==> B + C \<subset># D + (C::'a::order multiset)"
  1756 apply (subst add_commute [of B C])
  1757 apply (subst add_commute [of D C])
  1758 apply (erule union_less_mono2)
  1759 done
  1760 
  1761 lemma union_less_mono:
  1762   "A \<subset># C ==> B \<subset># D ==> A + B \<subset># C + (D::'a::order multiset)"
  1763   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
  1764 
  1765 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
  1766 proof
  1767 qed (auto simp add: le_multiset_def intro: union_less_mono2)
  1768 
  1769 
  1770 subsection {* Termination proofs with multiset orders *}
  1771 
  1772 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1773   and multi_member_this: "x \<in># {# x #} + XS"
  1774   and multi_member_last: "x \<in># {# x #}"
  1775   by auto
  1776 
  1777 definition "ms_strict = mult pair_less"
  1778 definition "ms_weak = ms_strict \<union> Id"
  1779 
  1780 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1781 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1782 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1783 
  1784 lemma smsI:
  1785   "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1786   unfolding ms_strict_def
  1787 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1788 
  1789 lemma wmsI:
  1790   "(set_of A, set_of B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1791   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1792 unfolding ms_weak_def ms_strict_def
  1793 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1794 
  1795 inductive pw_leq
  1796 where
  1797   pw_leq_empty: "pw_leq {#} {#}"
  1798 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1799 
  1800 lemma pw_leq_lstep:
  1801   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1802 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1803 
  1804 lemma pw_leq_split:
  1805   assumes "pw_leq X Y"
  1806   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1807   using assms
  1808 proof (induct)
  1809   case pw_leq_empty thus ?case by auto
  1810 next
  1811   case (pw_leq_step x y X Y)
  1812   then obtain A B Z where
  1813     [simp]: "X = A + Z" "Y = B + Z" 
  1814       and 1[simp]: "(set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#})" 
  1815     by auto
  1816   from pw_leq_step have "x = y \<or> (x, y) \<in> pair_less" 
  1817     unfolding pair_leq_def by auto
  1818   thus ?case
  1819   proof
  1820     assume [simp]: "x = y"
  1821     have
  1822       "{#x#} + X = A + ({#y#}+Z) 
  1823       \<and> {#y#} + Y = B + ({#y#}+Z)
  1824       \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1825       by (auto simp: add_ac)
  1826     thus ?case by (intro exI)
  1827   next
  1828     assume A: "(x, y) \<in> pair_less"
  1829     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1830     have "{#x#} + X = ?A' + Z"
  1831       "{#y#} + Y = ?B' + Z"
  1832       by (auto simp add: add_ac)
  1833     moreover have 
  1834       "(set_of ?A', set_of ?B') \<in> max_strict"
  1835       using 1 A unfolding max_strict_def 
  1836       by (auto elim!: max_ext.cases)
  1837     ultimately show ?thesis by blast
  1838   qed
  1839 qed
  1840 
  1841 lemma 
  1842   assumes pwleq: "pw_leq Z Z'"
  1843   shows ms_strictI: "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1844   and   ms_weakI1:  "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1845   and   ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1846 proof -
  1847   from pw_leq_split[OF pwleq] 
  1848   obtain A' B' Z''
  1849     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1850     and mx_or_empty: "(set_of A', set_of B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1851     by blast
  1852   {
  1853     assume max: "(set_of A, set_of B) \<in> max_strict"
  1854     from mx_or_empty
  1855     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1856     proof
  1857       assume max': "(set_of A', set_of B') \<in> max_strict"
  1858       with max have "(set_of (A + A'), set_of (B + B')) \<in> max_strict"
  1859         by (auto simp: max_strict_def intro: max_ext_additive)
  1860       thus ?thesis by (rule smsI) 
  1861     next
  1862       assume [simp]: "A' = {#} \<and> B' = {#}"
  1863       show ?thesis by (rule smsI) (auto intro: max)
  1864     qed
  1865     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add:add_ac)
  1866     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1867   }
  1868   from mx_or_empty
  1869   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1870   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:add_ac)
  1871 qed
  1872 
  1873 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  1874 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1875 and nonempty_single: "{# x #} \<noteq> {#}"
  1876 by auto
  1877 
  1878 setup {*
  1879 let
  1880   fun msetT T = Type (@{type_name multiset}, [T]);
  1881 
  1882   fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  1883     | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1884     | mk_mset T (x :: xs) =
  1885           Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1886                 mk_mset T [x] $ mk_mset T xs
  1887 
  1888   fun mset_member_tac m i =
  1889       (if m <= 0 then
  1890            rtac @{thm multi_member_this} i ORELSE rtac @{thm multi_member_last} i
  1891        else
  1892            rtac @{thm multi_member_skip} i THEN mset_member_tac (m - 1) i)
  1893 
  1894   val mset_nonempty_tac =
  1895       rtac @{thm nonempty_plus} ORELSE' rtac @{thm nonempty_single}
  1896 
  1897   val regroup_munion_conv =
  1898       Function_Lib.regroup_conv @{const_abbrev Mempty} @{const_name plus}
  1899         (map (fn t => t RS eq_reflection) (@{thms add_ac} @ @{thms empty_neutral}))
  1900 
  1901   fun unfold_pwleq_tac i =
  1902     (rtac @{thm pw_leq_step} i THEN (fn st => unfold_pwleq_tac (i + 1) st))
  1903       ORELSE (rtac @{thm pw_leq_lstep} i)
  1904       ORELSE (rtac @{thm pw_leq_empty} i)
  1905 
  1906   val set_of_simps = [@{thm set_of_empty}, @{thm set_of_single}, @{thm set_of_union},
  1907                       @{thm Un_insert_left}, @{thm Un_empty_left}]
  1908 in
  1909   ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset 
  1910   {
  1911     msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  1912     mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  1913     mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_of_simps,
  1914     smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  1915     reduction_pair= @{thm ms_reduction_pair}
  1916   })
  1917 end
  1918 *}
  1919 
  1920 
  1921 subsection {* Legacy theorem bindings *}
  1922 
  1923 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  1924 
  1925 lemma union_commute: "M + N = N + (M::'a multiset)"
  1926   by (fact add_commute)
  1927 
  1928 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  1929   by (fact add_assoc)
  1930 
  1931 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  1932   by (fact add_left_commute)
  1933 
  1934 lemmas union_ac = union_assoc union_commute union_lcomm
  1935 
  1936 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  1937   by (fact add_right_cancel)
  1938 
  1939 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  1940   by (fact add_left_cancel)
  1941 
  1942 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  1943   by (fact add_imp_eq)
  1944 
  1945 lemma mset_less_trans: "(M::'a multiset) < K \<Longrightarrow> K < N \<Longrightarrow> M < N"
  1946   by (fact order_less_trans)
  1947 
  1948 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
  1949   by (fact inf.commute)
  1950 
  1951 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
  1952   by (fact inf.assoc [symmetric])
  1953 
  1954 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
  1955   by (fact inf.left_commute)
  1956 
  1957 lemmas multiset_inter_ac =
  1958   multiset_inter_commute
  1959   multiset_inter_assoc
  1960   multiset_inter_left_commute
  1961 
  1962 lemma mult_less_not_refl:
  1963   "\<not> M \<subset># (M::'a::order multiset)"
  1964   by (fact multiset_order.less_irrefl)
  1965 
  1966 lemma mult_less_trans:
  1967   "K \<subset># M ==> M \<subset># N ==> K \<subset># (N::'a::order multiset)"
  1968   by (fact multiset_order.less_trans)
  1969     
  1970 lemma mult_less_not_sym:
  1971   "M \<subset># N ==> \<not> N \<subset># (M::'a::order multiset)"
  1972   by (fact multiset_order.less_not_sym)
  1973 
  1974 lemma mult_less_asym:
  1975   "M \<subset># N ==> (\<not> P ==> N \<subset># (M::'a::order multiset)) ==> P"
  1976   by (fact multiset_order.less_asym)
  1977 
  1978 ML {*
  1979 fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T]))
  1980                       (Const _ $ t') =
  1981     let
  1982       val (maybe_opt, ps) =
  1983         Nitpick_Model.dest_plain_fun t' ||> op ~~
  1984         ||> map (apsnd (snd o HOLogic.dest_number))
  1985       fun elems_for t =
  1986         case AList.lookup (op =) ps t of
  1987           SOME n => replicate n t
  1988         | NONE => [Const (maybe_name, elem_T --> elem_T) $ t]
  1989     in
  1990       case maps elems_for (all_values elem_T) @
  1991            (if maybe_opt then [Const (Nitpick_Model.unrep (), elem_T)]
  1992             else []) of
  1993         [] => Const (@{const_name zero_class.zero}, T)
  1994       | ts => foldl1 (fn (t1, t2) =>
  1995                          Const (@{const_name plus_class.plus}, T --> T --> T)
  1996                          $ t1 $ t2)
  1997                      (map (curry (op $) (Const (@{const_name single},
  1998                                                 elem_T --> T))) ts)
  1999     end
  2000   | multiset_postproc _ _ _ _ t = t
  2001 *}
  2002 
  2003 declaration {*
  2004 Nitpick_Model.register_term_postprocessor @{typ "'a multiset"}
  2005     multiset_postproc
  2006 *}
  2007 
  2008 hide_const (open) fold
  2009 
  2010 
  2011 subsection {* Naive implementation using lists *}
  2012 
  2013 code_datatype multiset_of
  2014 
  2015 lemma [code]:
  2016   "{#} = multiset_of []"
  2017   by simp
  2018 
  2019 lemma [code]:
  2020   "{#x#} = multiset_of [x]"
  2021   by simp
  2022 
  2023 lemma union_code [code]:
  2024   "multiset_of xs + multiset_of ys = multiset_of (xs @ ys)"
  2025   by simp
  2026 
  2027 lemma [code]:
  2028   "image_mset f (multiset_of xs) = multiset_of (map f xs)"
  2029   by (simp add: multiset_of_map)
  2030 
  2031 lemma [code]:
  2032   "Multiset.filter f (multiset_of xs) = multiset_of (filter f xs)"
  2033   by (simp add: multiset_of_filter)
  2034 
  2035 lemma [code]:
  2036   "multiset_of xs - multiset_of ys = multiset_of (fold remove1 ys xs)"
  2037   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute)
  2038 
  2039 lemma [code]:
  2040   "multiset_of xs #\<inter> multiset_of ys =
  2041     multiset_of (snd (fold (\<lambda>x (ys, zs).
  2042       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
  2043 proof -
  2044   have "\<And>zs. multiset_of (snd (fold (\<lambda>x (ys, zs).
  2045     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
  2046       (multiset_of xs #\<inter> multiset_of ys) + multiset_of zs"
  2047     by (induct xs arbitrary: ys)
  2048       (auto simp add: mem_set_multiset_eq inter_add_right1 inter_add_right2 ac_simps)
  2049   then show ?thesis by simp
  2050 qed
  2051 
  2052 lemma [code]:
  2053   "multiset_of xs #\<union> multiset_of ys =
  2054     multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
  2055 proof -
  2056   have "\<And>zs. multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
  2057       (multiset_of xs #\<union> multiset_of ys) + multiset_of zs"
  2058     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
  2059   then show ?thesis by simp
  2060 qed
  2061 
  2062 lemma [code_unfold]:
  2063   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
  2064   by (simp add: in_multiset_of)
  2065 
  2066 lemma [code]:
  2067   "count (multiset_of xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
  2068 proof -
  2069   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (multiset_of xs) x + n"
  2070     by (induct xs) simp_all
  2071   then show ?thesis by simp
  2072 qed
  2073 
  2074 lemma [code]:
  2075   "set_of (multiset_of xs) = set xs"
  2076   by simp
  2077 
  2078 lemma [code]:
  2079   "sorted_list_of_multiset (multiset_of xs) = sort xs"
  2080   by (induct xs) simp_all
  2081 
  2082 lemma [code]: -- {* not very efficient, but representation-ignorant! *}
  2083   "multiset_of_set A = multiset_of (sorted_list_of_set A)"
  2084   apply (cases "finite A")
  2085   apply simp_all
  2086   apply (induct A rule: finite_induct)
  2087   apply (simp_all add: union_commute)
  2088   done
  2089 
  2090 lemma [code]:
  2091   "mcard (multiset_of xs) = length xs"
  2092   by (simp add: mcard_multiset_of)
  2093 
  2094 fun ms_lesseq_impl :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool option" where 
  2095   "ms_lesseq_impl [] ys = Some (ys \<noteq> [])"
  2096 | "ms_lesseq_impl (Cons x xs) ys = (case List.extract (op = x) ys of 
  2097      None \<Rightarrow> None
  2098    | Some (ys1,_,ys2) \<Rightarrow> ms_lesseq_impl xs (ys1 @ ys2))"
  2099 
  2100 lemma ms_lesseq_impl: "(ms_lesseq_impl xs ys = None \<longleftrightarrow> \<not> multiset_of xs \<le> multiset_of ys) \<and>
  2101   (ms_lesseq_impl xs ys = Some True \<longleftrightarrow> multiset_of xs < multiset_of ys) \<and>
  2102   (ms_lesseq_impl xs ys = Some False \<longrightarrow> multiset_of xs = multiset_of ys)"
  2103 proof (induct xs arbitrary: ys)
  2104   case (Nil ys)
  2105   show ?case by (auto simp: mset_less_empty_nonempty)
  2106 next
  2107   case (Cons x xs ys)
  2108   show ?case
  2109   proof (cases "List.extract (op = x) ys")
  2110     case None
  2111     hence x: "x \<notin> set ys" by (simp add: extract_None_iff)
  2112     {
  2113       assume "multiset_of (x # xs) \<le> multiset_of ys"
  2114       from set_of_mono[OF this] x have False by simp
  2115     } note nle = this
  2116     moreover
  2117     {
  2118       assume "multiset_of (x # xs) < multiset_of ys"
  2119       hence "multiset_of (x # xs) \<le> multiset_of ys" by auto
  2120       from nle[OF this] have False .
  2121     }
  2122     ultimately show ?thesis using None by auto
  2123   next
  2124     case (Some res)
  2125     obtain ys1 y ys2 where res: "res = (ys1,y,ys2)" by (cases res, auto)
  2126     note Some = Some[unfolded res]
  2127     from extract_SomeE[OF Some] have "ys = ys1 @ x # ys2" by simp
  2128     hence id: "multiset_of ys = multiset_of (ys1 @ ys2) + {#x#}" 
  2129       by (auto simp: ac_simps)
  2130     show ?thesis unfolding ms_lesseq_impl.simps
  2131       unfolding Some option.simps split
  2132       unfolding id
  2133       using Cons[of "ys1 @ ys2"]
  2134       unfolding mset_le_def mset_less_def by auto
  2135   qed
  2136 qed
  2137 
  2138 lemma [code]: "multiset_of xs \<le> multiset_of ys \<longleftrightarrow> ms_lesseq_impl xs ys \<noteq> None"
  2139   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2140 
  2141 lemma [code]: "multiset_of xs < multiset_of ys \<longleftrightarrow> ms_lesseq_impl xs ys = Some True"
  2142   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2143 
  2144 instantiation multiset :: (equal) equal
  2145 begin
  2146 
  2147 definition
  2148   [code del]: "HOL.equal A (B :: 'a multiset) \<longleftrightarrow> A = B"
  2149 lemma [code]: "HOL.equal (multiset_of xs) (multiset_of ys) \<longleftrightarrow> ms_lesseq_impl xs ys = Some False"
  2150   unfolding equal_multiset_def
  2151   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2152 
  2153 instance
  2154   by default (simp add: equal_multiset_def)
  2155 end
  2156 
  2157 lemma [code]:
  2158   "msetsum (multiset_of xs) = listsum xs"
  2159   by (induct xs) (simp_all add: add.commute)
  2160 
  2161 lemma [code]:
  2162   "msetprod (multiset_of xs) = fold times xs 1"
  2163 proof -
  2164   have "\<And>x. fold times xs x = msetprod (multiset_of xs) * x"
  2165     by (induct xs) (simp_all add: mult.assoc)
  2166   then show ?thesis by simp
  2167 qed
  2168 
  2169 lemma [code]:
  2170   "size = mcard"
  2171   by (fact size_eq_mcard)
  2172 
  2173 text {*
  2174   Exercise for the casual reader: add implementations for @{const le_multiset}
  2175   and @{const less_multiset} (multiset order).
  2176 *}
  2177 
  2178 text {* Quickcheck generators *}
  2179 
  2180 definition (in term_syntax)
  2181   msetify :: "'a\<Colon>typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
  2182     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  2183   [code_unfold]: "msetify xs = Code_Evaluation.valtermify multiset_of {\<cdot>} xs"
  2184 
  2185 notation fcomp (infixl "\<circ>>" 60)
  2186 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2187 
  2188 instantiation multiset :: (random) random
  2189 begin
  2190 
  2191 definition
  2192   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
  2193 
  2194 instance ..
  2195 
  2196 end
  2197 
  2198 no_notation fcomp (infixl "\<circ>>" 60)
  2199 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2200 
  2201 instantiation multiset :: (full_exhaustive) full_exhaustive
  2202 begin
  2203 
  2204 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
  2205 where
  2206   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
  2207 
  2208 instance ..
  2209 
  2210 end
  2211 
  2212 hide_const (open) msetify
  2213 
  2214 
  2215 subsection {* BNF setup *}
  2216 
  2217 lemma setsum_gt_0_iff:
  2218 fixes f :: "'a \<Rightarrow> nat" assumes "finite A"
  2219 shows "setsum f A > 0 \<longleftrightarrow> (\<exists> a \<in> A. f a > 0)"
  2220 (is "?L \<longleftrightarrow> ?R")
  2221 proof-
  2222   have "?L \<longleftrightarrow> \<not> setsum f A = 0" by fast
  2223   also have "... \<longleftrightarrow> (\<exists> a \<in> A. f a \<noteq> 0)" using assms by simp
  2224   also have "... \<longleftrightarrow> ?R" by simp
  2225   finally show ?thesis .
  2226 qed
  2227 
  2228 lift_definition mmap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" is
  2229   "\<lambda>h f b. setsum f {a. h a = b \<and> f a > 0} :: nat"
  2230 unfolding multiset_def proof safe
  2231   fix h :: "'a \<Rightarrow> 'b" and f :: "'a \<Rightarrow> nat"
  2232   assume fin: "finite {a. 0 < f a}"  (is "finite ?A")
  2233   show "finite {b. 0 < setsum f {a. h a = b \<and> 0 < f a}}"
  2234   (is "finite {b. 0 < setsum f (?As b)}")
  2235   proof- let ?B = "{b. 0 < setsum f (?As b)}"
  2236     have "\<And> b. finite (?As b)" using fin by simp
  2237     hence B: "?B = {b. ?As b \<noteq> {}}" by (auto simp add: setsum_gt_0_iff)
  2238     hence "?B \<subseteq> h ` ?A" by auto
  2239     thus ?thesis using finite_surj[OF fin] by auto
  2240   qed
  2241 qed
  2242 
  2243 lemma mmap_id0: "mmap id = id"
  2244 proof (intro ext multiset_eqI)
  2245   fix f a show "count (mmap id f) a = count (id f) a"
  2246   proof (cases "count f a = 0")
  2247     case False
  2248     hence 1: "{aa. aa = a \<and> aa \<in># f} = {a}" by auto
  2249     thus ?thesis by transfer auto
  2250   qed (transfer, simp)
  2251 qed
  2252 
  2253 lemma inj_on_setsum_inv:
  2254 assumes 1: "(0::nat) < setsum (count f) {a. h a = b' \<and> a \<in># f}" (is "0 < setsum (count f) ?A'")
  2255 and     2: "{a. h a = b \<and> a \<in># f} = {a. h a = b' \<and> a \<in># f}" (is "?A = ?A'")
  2256 shows "b = b'"
  2257 using assms by (auto simp add: setsum_gt_0_iff)
  2258 
  2259 lemma mmap_comp:
  2260 fixes h1 :: "'a \<Rightarrow> 'b" and h2 :: "'b \<Rightarrow> 'c"
  2261 shows "mmap (h2 o h1) = mmap h2 o mmap h1"
  2262 proof (intro ext multiset_eqI)
  2263   fix f :: "'a multiset" fix c :: 'c
  2264   let ?A = "{a. h2 (h1 a) = c \<and> a \<in># f}"
  2265   let ?As = "\<lambda> b. {a. h1 a = b \<and> a \<in># f}"
  2266   let ?B = "{b. h2 b = c \<and> 0 < setsum (count f) (?As b)}"
  2267   have 0: "{?As b | b.  b \<in> ?B} = ?As ` ?B" by auto
  2268   have "\<And> b. finite (?As b)" by transfer (simp add: multiset_def)
  2269   hence "?B = {b. h2 b = c \<and> ?As b \<noteq> {}}" by (auto simp add: setsum_gt_0_iff)
  2270   hence A: "?A = \<Union> {?As b | b.  b \<in> ?B}" by auto
  2271   have "setsum (count f) ?A = setsum (setsum (count f)) {?As b | b.  b \<in> ?B}"
  2272     unfolding A by transfer (intro setsum_Union_disjoint, auto simp: multiset_def)
  2273   also have "... = setsum (setsum (count f)) (?As ` ?B)" unfolding 0 ..
  2274   also have "... = setsum (setsum (count f) o ?As) ?B"
  2275     by(intro setsum_reindex) (auto simp add: setsum_gt_0_iff inj_on_def)
  2276   also have "... = setsum (\<lambda> b. setsum (count f) (?As b)) ?B" unfolding comp_def ..
  2277   finally have "setsum (count f) ?A = setsum (\<lambda> b. setsum (count f) (?As b)) ?B" .
  2278   thus "count (mmap (h2 \<circ> h1) f) c = count ((mmap h2 \<circ> mmap h1) f) c"
  2279     by transfer (unfold comp_apply, blast)
  2280 qed
  2281 
  2282 lemma mmap_cong:
  2283 assumes "\<And>a. a \<in># M \<Longrightarrow> f a = g a"
  2284 shows "mmap f M = mmap g M"
  2285 using assms by transfer (auto intro!: setsum_cong)
  2286 
  2287 context
  2288 begin
  2289 interpretation lifting_syntax .
  2290 
  2291 lemma set_of_transfer[transfer_rule]: "(pcr_multiset op = ===> op =) (\<lambda>f. {a. 0 < f a}) set_of"
  2292   unfolding set_of_def pcr_multiset_def cr_multiset_def fun_rel_def by auto
  2293 
  2294 end
  2295 
  2296 lemma set_of_mmap: "set_of o mmap h = image h o set_of"
  2297 proof (rule ext, unfold comp_apply)
  2298   fix M show "set_of (mmap h M) = h ` set_of M"
  2299     by transfer (auto simp add: multiset_def setsum_gt_0_iff)
  2300 qed
  2301 
  2302 lemma multiset_of_surj:
  2303   "multiset_of ` {as. set as \<subseteq> A} = {M. set_of M \<subseteq> A}"
  2304 proof safe
  2305   fix M assume M: "set_of M \<subseteq> A"
  2306   obtain as where eq: "M = multiset_of as" using surj_multiset_of unfolding surj_def by auto
  2307   hence "set as \<subseteq> A" using M by auto
  2308   thus "M \<in> multiset_of ` {as. set as \<subseteq> A}" using eq by auto
  2309 next
  2310   show "\<And>x xa xb. \<lbrakk>set xa \<subseteq> A; xb \<in> set_of (multiset_of xa)\<rbrakk> \<Longrightarrow> xb \<in> A"
  2311   by (erule set_mp) (unfold set_of_multiset_of)
  2312 qed
  2313 
  2314 lemma card_of_set_of:
  2315 "(card_of {M. set_of M \<subseteq> A}, card_of {as. set as \<subseteq> A}) \<in> ordLeq"
  2316 apply(rule surj_imp_ordLeq[of _ multiset_of]) using multiset_of_surj by auto
  2317 
  2318 lemma nat_sum_induct:
  2319 assumes "\<And>n1 n2. (\<And> m1 m2. m1 + m2 < n1 + n2 \<Longrightarrow> phi m1 m2) \<Longrightarrow> phi n1 n2"
  2320 shows "phi (n1::nat) (n2::nat)"
  2321 proof-
  2322   let ?chi = "\<lambda> n1n2 :: nat * nat. phi (fst n1n2) (snd n1n2)"
  2323   have "?chi (n1,n2)"
  2324   apply(induct rule: measure_induct[of "\<lambda> n1n2. fst n1n2 + snd n1n2" ?chi])
  2325   using assms by (metis fstI sndI)
  2326   thus ?thesis by simp
  2327 qed
  2328 
  2329 lemma matrix_count:
  2330 fixes ct1 ct2 :: "nat \<Rightarrow> nat"
  2331 assumes "setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2}"
  2332 shows
  2333 "\<exists> ct. (\<forall> i1 \<le> n1. setsum (\<lambda> i2. ct i1 i2) {..<Suc n2} = ct1 i1) \<and>
  2334        (\<forall> i2 \<le> n2. setsum (\<lambda> i1. ct i1 i2) {..<Suc n1} = ct2 i2)"
  2335 (is "?phi ct1 ct2 n1 n2")
  2336 proof-
  2337   have "\<forall> ct1 ct2 :: nat \<Rightarrow> nat.
  2338         setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2} \<longrightarrow> ?phi ct1 ct2 n1 n2"
  2339   proof(induct rule: nat_sum_induct[of
  2340 "\<lambda> n1 n2. \<forall> ct1 ct2 :: nat \<Rightarrow> nat.
  2341      setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2} \<longrightarrow> ?phi ct1 ct2 n1 n2"],
  2342       clarify)
  2343   fix n1 n2 :: nat and ct1 ct2 :: "nat \<Rightarrow> nat"
  2344   assume IH: "\<And> m1 m2. m1 + m2 < n1 + n2 \<Longrightarrow>
  2345                 \<forall> dt1 dt2 :: nat \<Rightarrow> nat.
  2346                 setsum dt1 {..<Suc m1} = setsum dt2 {..<Suc m2} \<longrightarrow> ?phi dt1 dt2 m1 m2"
  2347   and ss: "setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2}"
  2348   show "?phi ct1 ct2 n1 n2"
  2349   proof(cases n1)
  2350     case 0 note n1 = 0
  2351     show ?thesis
  2352     proof(cases n2)
  2353       case 0 note n2 = 0
  2354       let ?ct = "\<lambda> i1 i2. ct2 0"
  2355       show ?thesis apply(rule exI[of _ ?ct]) using n1 n2 ss by simp
  2356     next
  2357       case (Suc m2) note n2 = Suc
  2358       let ?ct = "\<lambda> i1 i2. ct2 i2"
  2359       show ?thesis apply(rule exI[of _ ?ct]) using n1 n2 ss by auto
  2360     qed
  2361   next
  2362     case (Suc m1) note n1 = Suc
  2363     show ?thesis
  2364     proof(cases n2)
  2365       case 0 note n2 = 0
  2366       let ?ct = "\<lambda> i1 i2. ct1 i1"
  2367       show ?thesis apply(rule exI[of _ ?ct]) using n1 n2 ss by auto
  2368     next
  2369       case (Suc m2) note n2 = Suc
  2370       show ?thesis
  2371       proof(cases "ct1 n1 \<le> ct2 n2")
  2372         case True
  2373         def dt2 \<equiv> "\<lambda> i2. if i2 = n2 then ct2 i2 - ct1 n1 else ct2 i2"
  2374         have "setsum ct1 {..<Suc m1} = setsum dt2 {..<Suc n2}"
  2375         unfolding dt2_def using ss n1 True by auto
  2376         hence "?phi ct1 dt2 m1 n2" using IH[of m1 n2] n1 by simp
  2377         then obtain dt where
  2378         1: "\<And> i1. i1 \<le> m1 \<Longrightarrow> setsum (\<lambda> i2. dt i1 i2) {..<Suc n2} = ct1 i1" and
  2379         2: "\<And> i2. i2 \<le> n2 \<Longrightarrow> setsum (\<lambda> i1. dt i1 i2) {..<Suc m1} = dt2 i2" by auto
  2380         let ?ct = "\<lambda> i1 i2. if i1 = n1 then (if i2 = n2 then ct1 n1 else 0)
  2381                                        else dt i1 i2"
  2382         show ?thesis apply(rule exI[of _ ?ct])
  2383         using n1 n2 1 2 True unfolding dt2_def by simp
  2384       next
  2385         case False
  2386         hence False: "ct2 n2 < ct1 n1" by simp
  2387         def dt1 \<equiv> "\<lambda> i1. if i1 = n1 then ct1 i1 - ct2 n2 else ct1 i1"
  2388         have "setsum dt1 {..<Suc n1} = setsum ct2 {..<Suc m2}"
  2389         unfolding dt1_def using ss n2 False by auto
  2390         hence "?phi dt1 ct2 n1 m2" using IH[of n1 m2] n2 by simp
  2391         then obtain dt where
  2392         1: "\<And> i1. i1 \<le> n1 \<Longrightarrow> setsum (\<lambda> i2. dt i1 i2) {..<Suc m2} = dt1 i1" and
  2393         2: "\<And> i2. i2 \<le> m2 \<Longrightarrow> setsum (\<lambda> i1. dt i1 i2) {..<Suc n1} = ct2 i2" by force
  2394         let ?ct = "\<lambda> i1 i2. if i2 = n2 then (if i1 = n1 then ct2 n2 else 0)
  2395                                        else dt i1 i2"
  2396         show ?thesis apply(rule exI[of _ ?ct])
  2397         using n1 n2 1 2 False unfolding dt1_def by simp
  2398       qed
  2399     qed
  2400   qed
  2401   qed
  2402   thus ?thesis using assms by auto
  2403 qed
  2404 
  2405 definition
  2406 "inj2 u B1 B2 \<equiv>
  2407  \<forall> b1 b1' b2 b2'. {b1,b1'} \<subseteq> B1 \<and> {b2,b2'} \<subseteq> B2 \<and> u b1 b2 = u b1' b2'
  2408                   \<longrightarrow> b1 = b1' \<and> b2 = b2'"
  2409 
  2410 lemma matrix_setsum_finite:
  2411 assumes B1: "B1 \<noteq> {}" "finite B1" and B2: "B2 \<noteq> {}" "finite B2" and u: "inj2 u B1 B2"
  2412 and ss: "setsum N1 B1 = setsum N2 B2"
  2413 shows "\<exists> M :: 'a \<Rightarrow> nat.
  2414             (\<forall> b1 \<in> B1. setsum (\<lambda> b2. M (u b1 b2)) B2 = N1 b1) \<and>
  2415             (\<forall> b2 \<in> B2. setsum (\<lambda> b1. M (u b1 b2)) B1 = N2 b2)"
  2416 proof-
  2417   obtain n1 where "card B1 = Suc n1" using B1 by (metis card_insert finite.simps)
  2418   then obtain e1 where e1: "bij_betw e1 {..<Suc n1} B1"
  2419   using ex_bij_betw_finite_nat[OF B1(2)] by (metis atLeast0LessThan bij_betw_the_inv_into)
  2420   hence e1_inj: "inj_on e1 {..<Suc n1}" and e1_surj: "e1 ` {..<Suc n1} = B1"
  2421   unfolding bij_betw_def by auto
  2422   def f1 \<equiv> "inv_into {..<Suc n1} e1"
  2423   have f1: "bij_betw f1 B1 {..<Suc n1}"
  2424   and f1e1[simp]: "\<And> i1. i1 < Suc n1 \<Longrightarrow> f1 (e1 i1) = i1"
  2425   and e1f1[simp]: "\<And> b1. b1 \<in> B1 \<Longrightarrow> e1 (f1 b1) = b1" unfolding f1_def
  2426   apply (metis bij_betw_inv_into e1, metis bij_betw_inv_into_left e1 lessThan_iff)
  2427   by (metis e1_surj f_inv_into_f)
  2428   (*  *)
  2429   obtain n2 where "card B2 = Suc n2" using B2 by (metis card_insert finite.simps)
  2430   then obtain e2 where e2: "bij_betw e2 {..<Suc n2} B2"
  2431   using ex_bij_betw_finite_nat[OF B2(2)] by (metis atLeast0LessThan bij_betw_the_inv_into)
  2432   hence e2_inj: "inj_on e2 {..<Suc n2}" and e2_surj: "e2 ` {..<Suc n2} = B2"
  2433   unfolding bij_betw_def by auto
  2434   def f2 \<equiv> "inv_into {..<Suc n2} e2"
  2435   have f2: "bij_betw f2 B2 {..<Suc n2}"
  2436   and f2e2[simp]: "\<And> i2. i2 < Suc n2 \<Longrightarrow> f2 (e2 i2) = i2"
  2437   and e2f2[simp]: "\<And> b2. b2 \<in> B2 \<Longrightarrow> e2 (f2 b2) = b2" unfolding f2_def
  2438   apply (metis bij_betw_inv_into e2, metis bij_betw_inv_into_left e2 lessThan_iff)
  2439   by (metis e2_surj f_inv_into_f)
  2440   (*  *)
  2441   let ?ct1 = "N1 o e1"  let ?ct2 = "N2 o e2"
  2442   have ss: "setsum ?ct1 {..<Suc n1} = setsum ?ct2 {..<Suc n2}"
  2443   unfolding setsum_reindex[OF e1_inj, symmetric] setsum_reindex[OF e2_inj, symmetric]
  2444   e1_surj e2_surj using ss .
  2445   obtain ct where
  2446   ct1: "\<And> i1. i1 \<le> n1 \<Longrightarrow> setsum (\<lambda> i2. ct i1 i2) {..<Suc n2} = ?ct1 i1" and
  2447   ct2: "\<And> i2. i2 \<le> n2 \<Longrightarrow> setsum (\<lambda> i1. ct i1 i2) {..<Suc n1} = ?ct2 i2"
  2448   using matrix_count[OF ss] by blast
  2449   (*  *)
  2450   def A \<equiv> "{u b1 b2 | b1 b2. b1 \<in> B1 \<and> b2 \<in> B2}"
  2451   have "\<forall> a \<in> A. \<exists> b1b2 \<in> B1 <*> B2. u (fst b1b2) (snd b1b2) = a"
  2452   unfolding A_def Ball_def mem_Collect_eq by auto
  2453   then obtain h1h2 where h12:
  2454   "\<And>a. a \<in> A \<Longrightarrow> u (fst (h1h2 a)) (snd (h1h2 a)) = a \<and> h1h2 a \<in> B1 <*> B2" by metis
  2455   def h1 \<equiv> "fst o h1h2"  def h2 \<equiv> "snd o h1h2"
  2456   have h12[simp]: "\<And>a. a \<in> A \<Longrightarrow> u (h1 a) (h2 a) = a"
  2457                   "\<And> a. a \<in> A \<Longrightarrow> h1 a \<in> B1"  "\<And> a. a \<in> A \<Longrightarrow> h2 a \<in> B2"
  2458   using h12 unfolding h1_def h2_def by force+
  2459   {fix b1 b2 assume b1: "b1 \<in> B1" and b2: "b2 \<in> B2"
  2460    hence inA: "u b1 b2 \<in> A" unfolding A_def by auto
  2461    hence "u b1 b2 = u (h1 (u b1 b2)) (h2 (u b1 b2))" by auto
  2462    moreover have "h1 (u b1 b2) \<in> B1" "h2 (u b1 b2) \<in> B2" using inA by auto
  2463    ultimately have "h1 (u b1 b2) = b1 \<and> h2 (u b1 b2) = b2"
  2464    using u b1 b2 unfolding inj2_def by fastforce
  2465   }
  2466   hence h1[simp]: "\<And> b1 b2. \<lbrakk>b1 \<in> B1; b2 \<in> B2\<rbrakk> \<Longrightarrow> h1 (u b1 b2) = b1" and
  2467         h2[simp]: "\<And> b1 b2. \<lbrakk>b1 \<in> B1; b2 \<in> B2\<rbrakk> \<Longrightarrow> h2 (u b1 b2) = b2" by auto
  2468   def M \<equiv> "\<lambda> a. ct (f1 (h1 a)) (f2 (h2 a))"
  2469   show ?thesis
  2470   apply(rule exI[of _ M]) proof safe
  2471     fix b1 assume b1: "b1 \<in> B1"
  2472     hence f1b1: "f1 b1 \<le> n1" using f1 unfolding bij_betw_def
  2473     by (metis image_eqI lessThan_iff less_Suc_eq_le)
  2474     have "(\<Sum>b2\<in>B2. M (u b1 b2)) = (\<Sum>i2<Suc n2. ct (f1 b1) (f2 (e2 i2)))"
  2475     unfolding e2_surj[symmetric] setsum_reindex[OF e2_inj]
  2476     unfolding M_def comp_def apply(intro setsum_cong) apply force
  2477     by (metis e2_surj b1 h1 h2 imageI)
  2478     also have "... = N1 b1" using b1 ct1[OF f1b1] by simp
  2479     finally show "(\<Sum>b2\<in>B2. M (u b1 b2)) = N1 b1" .
  2480   next
  2481     fix b2 assume b2: "b2 \<in> B2"
  2482     hence f2b2: "f2 b2 \<le> n2" using f2 unfolding bij_betw_def
  2483     by (metis image_eqI lessThan_iff less_Suc_eq_le)
  2484     have "(\<Sum>b1\<in>B1. M (u b1 b2)) = (\<Sum>i1<Suc n1. ct (f1 (e1 i1)) (f2 b2))"
  2485     unfolding e1_surj[symmetric] setsum_reindex[OF e1_inj]
  2486     unfolding M_def comp_def apply(intro setsum_cong) apply force
  2487     by (metis e1_surj b2 h1 h2 imageI)
  2488     also have "... = N2 b2" using b2 ct2[OF f2b2] by simp
  2489     finally show "(\<Sum>b1\<in>B1. M (u b1 b2)) = N2 b2" .
  2490   qed
  2491 qed
  2492 
  2493 lemma supp_vimage_mmap: "set_of M \<subseteq> f -` (set_of (mmap f M))"
  2494   by transfer (auto simp: multiset_def setsum_gt_0_iff)
  2495 
  2496 lemma mmap_ge_0: "b \<in># mmap f M \<longleftrightarrow> (\<exists>a. a \<in># M \<and> f a = b)"
  2497   by transfer (auto simp: multiset_def setsum_gt_0_iff)
  2498 
  2499 lemma finite_twosets:
  2500 assumes "finite B1" and "finite B2"
  2501 shows "finite {u b1 b2 |b1 b2. b1 \<in> B1 \<and> b2 \<in> B2}"  (is "finite ?A")
  2502 proof-
  2503   have A: "?A = (\<lambda> b1b2. u (fst b1b2) (snd b1b2)) ` (B1 <*> B2)" by force
  2504   show ?thesis unfolding A using finite_cartesian_product[OF assms] by auto
  2505 qed
  2506 
  2507 (* Weak pullbacks: *)
  2508 definition wpull where
  2509 "wpull A B1 B2 f1 f2 p1 p2 \<longleftrightarrow>
  2510  (\<forall> b1 b2. b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2 \<longrightarrow> (\<exists> a \<in> A. p1 a = b1 \<and> p2 a = b2))"
  2511 
  2512 (* Weak pseudo-pullbacks *)
  2513 definition wppull where
  2514 "wppull A B1 B2 f1 f2 e1 e2 p1 p2 \<longleftrightarrow>
  2515  (\<forall> b1 b2. b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2 \<longrightarrow>
  2516            (\<exists> a \<in> A. e1 (p1 a) = e1 b1 \<and> e2 (p2 a) = e2 b2))"
  2517 
  2518 
  2519 (* The pullback of sets *)
  2520 definition thePull where
  2521 "thePull B1 B2 f1 f2 = {(b1,b2). b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2}"
  2522 
  2523 lemma wpull_thePull:
  2524 "wpull (thePull B1 B2 f1 f2) B1 B2 f1 f2 fst snd"
  2525 unfolding wpull_def thePull_def by auto
  2526 
  2527 lemma wppull_thePull:
  2528 assumes "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
  2529 shows
  2530 "\<exists> j. \<forall> a' \<in> thePull B1 B2 f1 f2.
  2531    j a' \<in> A \<and>
  2532    e1 (p1 (j a')) = e1 (fst a') \<and> e2 (p2 (j a')) = e2 (snd a')"
  2533 (is "\<exists> j. \<forall> a' \<in> ?A'. ?phi a' (j a')")
  2534 proof(rule bchoice[of ?A' ?phi], default)
  2535   fix a' assume a': "a' \<in> ?A'"
  2536   hence "fst a' \<in> B1" unfolding thePull_def by auto
  2537   moreover
  2538   from a' have "snd a' \<in> B2" unfolding thePull_def by auto
  2539   moreover have "f1 (fst a') = f2 (snd a')"
  2540   using a' unfolding csquare_def thePull_def by auto
  2541   ultimately show "\<exists> ja'. ?phi a' ja'"
  2542   using assms unfolding wppull_def by blast
  2543 qed
  2544 
  2545 lemma wpull_wppull:
  2546 assumes wp: "wpull A' B1 B2 f1 f2 p1' p2'" and
  2547 1: "\<forall> a' \<in> A'. j a' \<in> A \<and> e1 (p1 (j a')) = e1 (p1' a') \<and> e2 (p2 (j a')) = e2 (p2' a')"
  2548 shows "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
  2549 unfolding wppull_def proof safe
  2550   fix b1 b2
  2551   assume b1: "b1 \<in> B1" and b2: "b2 \<in> B2" and f: "f1 b1 = f2 b2"
  2552   then obtain a' where a': "a' \<in> A'" and b1: "b1 = p1' a'" and b2: "b2 = p2' a'"
  2553   using wp unfolding wpull_def by blast
  2554   show "\<exists>a\<in>A. e1 (p1 a) = e1 b1 \<and> e2 (p2 a) = e2 b2"
  2555   apply (rule bexI[of _ "j a'"]) unfolding b1 b2 using a' 1 by auto
  2556 qed
  2557 
  2558 lemma wppull_fstOp_sndOp:
  2559 shows "wppull (Collect (split (P OO Q))) (Collect (split P)) (Collect (split Q))
  2560   snd fst fst snd (BNF_Def.fstOp P Q) (BNF_Def.sndOp P Q)"
  2561 using pick_middlep unfolding wppull_def fstOp_def sndOp_def relcompp.simps by auto
  2562 
  2563 lemma wpull_mmap:
  2564 fixes A :: "'a set" and B1 :: "'b1 set" and B2 :: "'b2 set"
  2565 assumes wp: "wpull A B1 B2 f1 f2 p1 p2"
  2566 shows
  2567 "wpull {M. set_of M \<subseteq> A}
  2568        {N1. set_of N1 \<subseteq> B1} {N2. set_of N2 \<subseteq> B2}
  2569        (mmap f1) (mmap f2) (mmap p1) (mmap p2)"
  2570 unfolding wpull_def proof (safe, unfold Bex_def mem_Collect_eq)
  2571   fix N1 :: "'b1 multiset" and N2 :: "'b2 multiset"
  2572   assume mmap': "mmap f1 N1 = mmap f2 N2"
  2573   and N1[simp]: "set_of N1 \<subseteq> B1"
  2574   and N2[simp]: "set_of N2 \<subseteq> B2"
  2575   def P \<equiv> "mmap f1 N1"
  2576   have P1: "P = mmap f1 N1" and P2: "P = mmap f2 N2" unfolding P_def using mmap' by auto
  2577   note P = P1 P2
  2578   have fin_N1[simp]: "finite (set_of N1)"
  2579    and fin_N2[simp]: "finite (set_of N2)"
  2580    and fin_P[simp]: "finite (set_of P)" by auto
  2581 
  2582   def set1 \<equiv> "\<lambda> c. {b1 \<in> set_of N1. f1 b1 = c}"
  2583   have set1[simp]: "\<And> c b1. b1 \<in> set1 c \<Longrightarrow> f1 b1 = c" unfolding set1_def by auto
  2584   have fin_set1: "\<And> c. c \<in> set_of P \<Longrightarrow> finite (set1 c)"
  2585     using N1(1) unfolding set1_def multiset_def by auto
  2586   have set1_NE: "\<And> c. c \<in> set_of P \<Longrightarrow> set1 c \<noteq> {}"
  2587    unfolding set1_def set_of_def P mmap_ge_0 by auto
  2588   have supp_N1_set1: "set_of N1 = (\<Union> c \<in> set_of P. set1 c)"
  2589     using supp_vimage_mmap[of N1 f1] unfolding set1_def P1 by auto
  2590   hence set1_inclN1: "\<And>c. c \<in> set_of P \<Longrightarrow> set1 c \<subseteq> set_of N1" by auto
  2591   hence set1_incl: "\<And> c. c \<in> set_of P \<Longrightarrow> set1 c \<subseteq> B1" using N1 by blast
  2592   have set1_disj: "\<And> c c'. c \<noteq> c' \<Longrightarrow> set1 c \<inter> set1 c' = {}"
  2593     unfolding set1_def by auto
  2594   have setsum_set1: "\<And> c. setsum (count N1) (set1 c) = count P c"
  2595     unfolding P1 set1_def by transfer (auto intro: setsum_cong)
  2596 
  2597   def set2 \<equiv> "\<lambda> c. {b2 \<in> set_of N2. f2 b2 = c}"
  2598   have set2[simp]: "\<And> c b2. b2 \<in> set2 c \<Longrightarrow> f2 b2 = c" unfolding set2_def by auto
  2599   have fin_set2: "\<And> c. c \<in> set_of P \<Longrightarrow> finite (set2 c)"
  2600   using N2(1) unfolding set2_def multiset_def by auto
  2601   have set2_NE: "\<And> c. c \<in> set_of P \<Longrightarrow> set2 c \<noteq> {}"
  2602     unfolding set2_def P2 mmap_ge_0 set_of_def by auto
  2603   have supp_N2_set2: "set_of N2 = (\<Union> c \<in> set_of P. set2 c)"
  2604     using supp_vimage_mmap[of N2 f2] unfolding set2_def P2 by auto
  2605   hence set2_inclN2: "\<And>c. c \<in> set_of P \<Longrightarrow> set2 c \<subseteq> set_of N2" by auto
  2606   hence set2_incl: "\<And> c. c \<in> set_of P \<Longrightarrow> set2 c \<subseteq> B2" using N2 by blast
  2607   have set2_disj: "\<And> c c'. c \<noteq> c' \<Longrightarrow> set2 c \<inter> set2 c' = {}"
  2608     unfolding set2_def by auto
  2609   have setsum_set2: "\<And> c. setsum (count N2) (set2 c) = count P c"
  2610     unfolding P2 set2_def by transfer (auto intro: setsum_cong)
  2611 
  2612   have ss: "\<And> c. c \<in> set_of P \<Longrightarrow> setsum (count N1) (set1 c) = setsum (count N2) (set2 c)"
  2613     unfolding setsum_set1 setsum_set2 ..
  2614   have "\<forall> c \<in> set_of P. \<forall> b1b2 \<in> (set1 c) \<times> (set2 c).
  2615           \<exists> a \<in> A. p1 a = fst b1b2 \<and> p2 a = snd b1b2"
  2616     using wp set1_incl set2_incl unfolding wpull_def Ball_def mem_Collect_eq
  2617     by simp (metis set1 set2 set_rev_mp)
  2618   then obtain uu where uu:
  2619   "\<forall> c \<in> set_of P. \<forall> b1b2 \<in> (set1 c) \<times> (set2 c).
  2620      uu c b1b2 \<in> A \<and> p1 (uu c b1b2) = fst b1b2 \<and> p2 (uu c b1b2) = snd b1b2" by metis
  2621   def u \<equiv> "\<lambda> c b1 b2. uu c (b1,b2)"
  2622   have u[simp]:
  2623   "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> u c b1 b2 \<in> A"
  2624   "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> p1 (u c b1 b2) = b1"
  2625   "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> p2 (u c b1 b2) = b2"
  2626     using uu unfolding u_def by auto
  2627   {fix c assume c: "c \<in> set_of P"
  2628    have "inj2 (u c) (set1 c) (set2 c)" unfolding inj2_def proof clarify
  2629      fix b1 b1' b2 b2'
  2630      assume "{b1, b1'} \<subseteq> set1 c" "{b2, b2'} \<subseteq> set2 c" and 0: "u c b1 b2 = u c b1' b2'"
  2631      hence "p1 (u c b1 b2) = b1 \<and> p2 (u c b1 b2) = b2 \<and>
  2632             p1 (u c b1' b2') = b1' \<and> p2 (u c b1' b2') = b2'"
  2633      using u(2)[OF c] u(3)[OF c] by simp metis
  2634      thus "b1 = b1' \<and> b2 = b2'" using 0 by auto
  2635    qed
  2636   } note inj = this
  2637   def sset \<equiv> "\<lambda> c. {u c b1 b2 | b1 b2. b1 \<in> set1 c \<and> b2 \<in> set2 c}"
  2638   have fin_sset[simp]: "\<And> c. c \<in> set_of P \<Longrightarrow> finite (sset c)" unfolding sset_def
  2639     using fin_set1 fin_set2 finite_twosets by blast
  2640   have sset_A: "\<And> c. c \<in> set_of P \<Longrightarrow> sset c \<subseteq> A" unfolding sset_def by auto
  2641   {fix c a assume c: "c \<in> set_of P" and ac: "a \<in> sset c"
  2642    then obtain b1 b2 where b1: "b1 \<in> set1 c" and b2: "b2 \<in> set2 c"
  2643    and a: "a = u c b1 b2" unfolding sset_def by auto
  2644    have "p1 a \<in> set1 c" and p2a: "p2 a \<in> set2 c"
  2645    using ac a b1 b2 c u(2) u(3) by simp+
  2646    hence "u c (p1 a) (p2 a) = a" unfolding a using b1 b2 inj[OF c]
  2647    unfolding inj2_def by (metis c u(2) u(3))
  2648   } note u_p12[simp] = this
  2649   {fix c a assume c: "c \<in> set_of P" and ac: "a \<in> sset c"
  2650    hence "p1 a \<in> set1 c" unfolding sset_def by auto
  2651   }note p1[simp] = this
  2652   {fix c a assume c: "c \<in> set_of P" and ac: "a \<in> sset c"
  2653    hence "p2 a \<in> set2 c" unfolding sset_def by auto
  2654   }note p2[simp] = this
  2655 
  2656   {fix c assume c: "c \<in> set_of P"
  2657    hence "\<exists> M. (\<forall> b1 \<in> set1 c. setsum (\<lambda> b2. M (u c b1 b2)) (set2 c) = count N1 b1) \<and>
  2658                (\<forall> b2 \<in> set2 c. setsum (\<lambda> b1. M (u c b1 b2)) (set1 c) = count N2 b2)"
  2659    unfolding sset_def
  2660    using matrix_setsum_finite[OF set1_NE[OF c] fin_set1[OF c]
  2661                                  set2_NE[OF c] fin_set2[OF c] inj[OF c] ss[OF c]] by auto
  2662   }
  2663   then obtain Ms where
  2664   ss1: "\<And> c b1. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c\<rbrakk> \<Longrightarrow>
  2665                    setsum (\<lambda> b2. Ms c (u c b1 b2)) (set2 c) = count N1 b1" and
  2666   ss2: "\<And> c b2. \<lbrakk>c \<in> set_of P; b2 \<in> set2 c\<rbrakk> \<Longrightarrow>
  2667                    setsum (\<lambda> b1. Ms c (u c b1 b2)) (set1 c) = count N2 b2"
  2668   by metis
  2669   def SET \<equiv> "\<Union> c \<in> set_of P. sset c"
  2670   have fin_SET[simp]: "finite SET" unfolding SET_def apply(rule finite_UN_I) by auto
  2671   have SET_A: "SET \<subseteq> A" unfolding SET_def using sset_A by blast
  2672   have u_SET[simp]: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> u c b1 b2 \<in> SET"
  2673     unfolding SET_def sset_def by blast
  2674   {fix c a assume c: "c \<in> set_of P" and a: "a \<in> SET" and p1a: "p1 a \<in> set1 c"
  2675    then obtain c' where c': "c' \<in> set_of P" and ac': "a \<in> sset c'"
  2676     unfolding SET_def by auto
  2677    hence "p1 a \<in> set1 c'" unfolding sset_def by auto
  2678    hence eq: "c = c'" using p1a c c' set1_disj by auto
  2679    hence "a \<in> sset c" using ac' by simp
  2680   } note p1_rev = this
  2681   {fix c a assume c: "c \<in> set_of P" and a: "a \<in> SET" and p2a: "p2 a \<in> set2 c"
  2682    then obtain c' where c': "c' \<in> set_of P" and ac': "a \<in> sset c'"
  2683    unfolding SET_def by auto
  2684    hence "p2 a \<in> set2 c'" unfolding sset_def by auto
  2685    hence eq: "c = c'" using p2a c c' set2_disj by auto
  2686    hence "a \<in> sset c" using ac' by simp
  2687   } note p2_rev = this
  2688 
  2689   have "\<forall> a \<in> SET. \<exists> c \<in> set_of P. a \<in> sset c" unfolding SET_def by auto
  2690   then obtain h where h: "\<forall> a \<in> SET. h a \<in> set_of P \<and> a \<in> sset (h a)" by metis
  2691   have h_u[simp]: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk>
  2692                       \<Longrightarrow> h (u c b1 b2) = c"
  2693   by (metis h p2 set2 u(3) u_SET)
  2694   have h_u1: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk>
  2695                       \<Longrightarrow> h (u c b1 b2) = f1 b1"
  2696   using h unfolding sset_def by auto
  2697   have h_u2: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk>
  2698                       \<Longrightarrow> h (u c b1 b2) = f2 b2"
  2699   using h unfolding sset_def by auto
  2700   def M \<equiv>
  2701     "Abs_multiset (\<lambda> a. if a \<in> SET \<and> p1 a \<in> set_of N1 \<and> p2 a \<in> set_of N2 then Ms (h a) a else 0)"
  2702   have "(\<lambda> a. if a \<in> SET \<and> p1 a \<in> set_of N1 \<and> p2 a \<in> set_of N2 then Ms (h a) a else 0) \<in> multiset"
  2703     unfolding multiset_def by auto
  2704   hence [transfer_rule]: "pcr_multiset op = (\<lambda> a. if a \<in> SET \<and> p1 a \<in> set_of N1 \<and> p2 a \<in> set_of N2 then Ms (h a) a else 0) M"
  2705     unfolding M_def pcr_multiset_def cr_multiset_def by (auto simp: Abs_multiset_inverse)
  2706   have sM: "set_of M \<subseteq> SET" "set_of M \<subseteq> p1 -` (set_of N1)" "set_of M \<subseteq> p2 -` set_of N2"
  2707     by (transfer, auto split: split_if_asm)+
  2708   show "\<exists>M. set_of M \<subseteq> A \<and> mmap p1 M = N1 \<and> mmap p2 M = N2"
  2709   proof(rule exI[of _ M], safe)
  2710     fix a assume *: "a \<in> set_of M"
  2711     from SET_A show "a \<in> A"
  2712     proof (cases "a \<in> SET")
  2713       case False thus ?thesis using * by transfer' auto
  2714     qed blast
  2715   next
  2716     show "mmap p1 M = N1"
  2717     proof(intro multiset_eqI)
  2718       fix b1
  2719       let ?K = "{a. p1 a = b1 \<and> a \<in># M}"
  2720       have "setsum (count M) ?K = count N1 b1"
  2721       proof(cases "b1 \<in> set_of N1")
  2722         case False
  2723         hence "?K = {}" using sM(2) by auto
  2724         thus ?thesis using False by auto
  2725       next
  2726         case True
  2727         def c \<equiv> "f1 b1"
  2728         have c: "c \<in> set_of P" and b1: "b1 \<in> set1 c"
  2729           unfolding set1_def c_def P1 using True by (auto simp: comp_eq_dest[OF set_of_mmap])
  2730         with sM(1) have "setsum (count M) ?K = setsum (count M) {a. p1 a = b1 \<and> a \<in> SET}"
  2731           by transfer (force intro: setsum_mono_zero_cong_left split: split_if_asm)
  2732         also have "... = setsum (count M) ((\<lambda> b2. u c b1 b2) ` (set2 c))"
  2733           apply(rule setsum_cong) using c b1 proof safe
  2734           fix a assume p1a: "p1 a \<in> set1 c" and "c \<in> set_of P" and "a \<in> SET"
  2735           hence ac: "a \<in> sset c" using p1_rev by auto
  2736           hence "a = u c (p1 a) (p2 a)" using c by auto
  2737           moreover have "p2 a \<in> set2 c" using ac c by auto
  2738           ultimately show "a \<in> u c (p1 a) ` set2 c" by auto
  2739         qed auto
  2740         also have "... = setsum (\<lambda> b2. count M (u c b1 b2)) (set2 c)"
  2741           unfolding comp_def[symmetric] apply(rule setsum_reindex)
  2742           using inj unfolding inj_on_def inj2_def using b1 c u(3) by blast
  2743         also have "... = count N1 b1" unfolding ss1[OF c b1, symmetric]
  2744           apply(rule setsum_cong[OF refl]) apply (transfer fixing: Ms u c b1 set2)
  2745           using True h_u[OF c b1] set2_def u(2,3)[OF c b1] u_SET[OF c b1] by fastforce
  2746         finally show ?thesis .
  2747       qed
  2748       thus "count (mmap p1 M) b1 = count N1 b1" by transfer
  2749     qed
  2750   next
  2751     show "mmap p2 M = N2"
  2752     proof(intro multiset_eqI)
  2753       fix b2
  2754       let ?K = "{a. p2 a = b2 \<and> a \<in># M}"
  2755       have "setsum (count M) ?K = count N2 b2"
  2756       proof(cases "b2 \<in> set_of N2")
  2757         case False
  2758         hence "?K = {}" using sM(3) by auto
  2759         thus ?thesis using False by auto
  2760       next
  2761         case True
  2762         def c \<equiv> "f2 b2"
  2763         have c: "c \<in> set_of P" and b2: "b2 \<in> set2 c"
  2764           unfolding set2_def c_def P2 using True by (auto simp: comp_eq_dest[OF set_of_mmap])
  2765         with sM(1) have "setsum (count M) ?K = setsum (count M) {a. p2 a = b2 \<and> a \<in> SET}"
  2766           by transfer (force intro: setsum_mono_zero_cong_left split: split_if_asm)
  2767         also have "... = setsum (count M) ((\<lambda> b1. u c b1 b2) ` (set1 c))"
  2768           apply(rule setsum_cong) using c b2 proof safe
  2769           fix a assume p2a: "p2 a \<in> set2 c" and "c \<in> set_of P" and "a \<in> SET"
  2770           hence ac: "a \<in> sset c" using p2_rev by auto
  2771           hence "a = u c (p1 a) (p2 a)" using c by auto
  2772           moreover have "p1 a \<in> set1 c" using ac c by auto
  2773           ultimately show "a \<in> (\<lambda>x. u c x (p2 a)) ` set1 c" by auto
  2774         qed auto
  2775         also have "... = setsum (count M o (\<lambda> b1. u c b1 b2)) (set1 c)"
  2776           apply(rule setsum_reindex)
  2777           using inj unfolding inj_on_def inj2_def using b2 c u(2) by blast
  2778         also have "... = setsum (\<lambda> b1. count M (u c b1 b2)) (set1 c)" by simp
  2779         also have "... = count N2 b2" unfolding ss2[OF c b2, symmetric] comp_def
  2780           apply(rule setsum_cong[OF refl]) apply (transfer fixing: Ms u c b2 set1)
  2781           using True h_u1[OF c _ b2] u(2,3)[OF c _ b2] u_SET[OF c _ b2] set1_def by fastforce
  2782         finally show ?thesis .
  2783       qed
  2784       thus "count (mmap p2 M) b2 = count N2 b2" by transfer
  2785     qed
  2786   qed
  2787 qed
  2788 
  2789 lemma set_of_bd: "(card_of (set_of x), natLeq) \<in> ordLeq"
  2790   by transfer
  2791     (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
  2792 
  2793 lemma wppull_mmap:
  2794   assumes "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
  2795   shows "wppull {M. set_of M \<subseteq> A} {N1. set_of N1 \<subseteq> B1} {N2. set_of N2 \<subseteq> B2}
  2796     (mmap f1) (mmap f2) (mmap e1) (mmap e2) (mmap p1) (mmap p2)"
  2797 proof -
  2798   from assms obtain j where j: "\<forall>a'\<in>thePull B1 B2 f1 f2.
  2799     j a' \<in> A \<and> e1 (p1 (j a')) = e1 (fst a') \<and> e2 (p2 (j a')) = e2 (snd a')" 
  2800     by (blast dest: wppull_thePull)
  2801   then show ?thesis
  2802     by (intro wpull_wppull[OF wpull_mmap[OF wpull_thePull], of _ _ _ _ "mmap j"])
  2803       (auto simp: comp_eq_dest_lhs[OF mmap_comp[symmetric]] comp_eq_dest[OF set_of_mmap]
  2804         intro!: mmap_cong simp del: mem_set_of_iff simp: mem_set_of_iff[symmetric])
  2805 qed
  2806 
  2807 bnf "'a multiset"
  2808   map: mmap
  2809   sets: set_of 
  2810   bd: natLeq
  2811   wits: "{#}"
  2812 by (auto simp add: mmap_id0 mmap_comp set_of_mmap natLeq_card_order natLeq_cinfinite set_of_bd
  2813   Grp_def relcompp.simps intro: mmap_cong)
  2814   (metis wppull_mmap[OF wppull_fstOp_sndOp, unfolded wppull_def
  2815     o_eq_dest_lhs[OF mmap_comp[symmetric]] fstOp_def sndOp_def comp_def, simplified])
  2816 
  2817 inductive rel_multiset' where
  2818   Zero[intro]: "rel_multiset' R {#} {#}"
  2819 | Plus[intro]: "\<lbrakk>R a b; rel_multiset' R M N\<rbrakk> \<Longrightarrow> rel_multiset' R (M + {#a#}) (N + {#b#})"
  2820 
  2821 lemma map_multiset_Zero_iff[simp]: "mmap f M = {#} \<longleftrightarrow> M = {#}"
  2822 by (metis image_is_empty multiset.set_map set_of_eq_empty_iff)
  2823 
  2824 lemma map_multiset_Zero[simp]: "mmap f {#} = {#}" by simp
  2825 
  2826 lemma rel_multiset_Zero: "rel_multiset R {#} {#}"
  2827 unfolding rel_multiset_def Grp_def by auto
  2828 
  2829 declare multiset.count[simp]
  2830 declare Abs_multiset_inverse[simp]
  2831 declare multiset.count_inverse[simp]
  2832 declare union_preserves_multiset[simp]
  2833 
  2834 lemma map_multiset_Plus[simp]: "mmap f (M1 + M2) = mmap f M1 + mmap f M2"
  2835 proof (intro multiset_eqI, transfer fixing: f)
  2836   fix x :: 'a and M1 M2 :: "'b \<Rightarrow> nat"
  2837   assume "M1 \<in> multiset" "M2 \<in> multiset"
  2838   hence "setsum M1 {a. f a = x \<and> 0 < M1 a} = setsum M1 {a. f a = x \<and> 0 < M1 a + M2 a}"
  2839         "setsum M2 {a. f a = x \<and> 0 < M2 a} = setsum M2 {a. f a = x \<and> 0 < M1 a + M2 a}"
  2840     by (auto simp: multiset_def intro!: setsum_mono_zero_cong_left)
  2841   then show "(\<Sum>a | f a = x \<and> 0 < M1 a + M2 a. M1 a + M2 a) =
  2842        setsum M1 {a. f a = x \<and> 0 < M1 a} +
  2843        setsum M2 {a. f a = x \<and> 0 < M2 a}"
  2844     by (auto simp: setsum.distrib[symmetric])
  2845 qed
  2846 
  2847 lemma map_multiset_single[simp]: "mmap f {#a#} = {#f a#}"
  2848   by transfer auto
  2849 
  2850 lemma rel_multiset_Plus:
  2851 assumes ab: "R a b" and MN: "rel_multiset R M N"
  2852 shows "rel_multiset R (M + {#a#}) (N + {#b#})"
  2853 proof-
  2854   {fix y assume "R a b" and "set_of y \<subseteq> {(x, y). R x y}"
  2855    hence "\<exists>ya. mmap fst y + {#a#} = mmap fst ya \<and>
  2856                mmap snd y + {#b#} = mmap snd ya \<and>
  2857                set_of ya \<subseteq> {(x, y). R x y}"
  2858    apply(intro exI[of _ "y + {#(a,b)#}"]) by auto
  2859   }
  2860   thus ?thesis
  2861   using assms
  2862   unfolding rel_multiset_def Grp_def by force
  2863 qed
  2864 
  2865 lemma rel_multiset'_imp_rel_multiset:
  2866 "rel_multiset' R M N \<Longrightarrow> rel_multiset R M N"
  2867 apply(induct rule: rel_multiset'.induct)
  2868 using rel_multiset_Zero rel_multiset_Plus by auto
  2869 
  2870 lemma mcard_mmap[simp]: "mcard (mmap f M) = mcard M"
  2871 proof -
  2872   def A \<equiv> "\<lambda> b. {a. f a = b \<and> a \<in># M}"
  2873   let ?B = "{b. 0 < setsum (count M) (A b)}"
  2874   have "{b. \<exists>a. f a = b \<and> a \<in># M} \<subseteq> f ` {a. a \<in># M}" by auto
  2875   moreover have "finite (f ` {a. a \<in># M})" apply(rule finite_imageI)
  2876   using finite_Collect_mem .
  2877   ultimately have fin: "finite {b. \<exists>a. f a = b \<and> a \<in># M}" by(rule finite_subset)
  2878   have i: "inj_on A ?B" unfolding inj_on_def A_def apply clarsimp
  2879     by (metis (lifting, full_types) mem_Collect_eq neq0_conv setsum.neutral)
  2880   have 0: "\<And> b. 0 < setsum (count M) (A b) \<longleftrightarrow> (\<exists> a \<in> A b. count M a > 0)"
  2881   apply safe
  2882     apply (metis less_not_refl setsum_gt_0_iff setsum_infinite)
  2883     by (metis A_def finite_Collect_conjI finite_Collect_mem setsum_gt_0_iff)
  2884   hence AB: "A ` ?B = {A b | b. \<exists> a \<in> A b. count M a > 0}" by auto
  2885 
  2886   have "setsum (\<lambda> x. setsum (count M) (A x)) ?B = setsum (setsum (count M) o A) ?B"
  2887   unfolding comp_def ..
  2888   also have "... = (\<Sum>x\<in> A ` ?B. setsum (count M) x)"
  2889   unfolding setsum.reindex [OF i, symmetric] ..
  2890   also have "... = setsum (count M) (\<Union>x\<in>A ` {b. 0 < setsum (count M) (A b)}. x)"
  2891   (is "_ = setsum (count M) ?J")
  2892   apply(rule setsum.UNION_disjoint[symmetric])
  2893   using 0 fin unfolding A_def by auto
  2894   also have "?J = {a. a \<in># M}" unfolding AB unfolding A_def by auto
  2895   finally have "setsum (\<lambda> x. setsum (count M) (A x)) ?B =
  2896                 setsum (count M) {a. a \<in># M}" .
  2897   then show ?thesis unfolding mcard_unfold_setsum A_def by transfer
  2898 qed
  2899 
  2900 lemma rel_multiset_mcard:
  2901 assumes "rel_multiset R M N"
  2902 shows "mcard M = mcard N"
  2903 using assms unfolding rel_multiset_def Grp_def by auto
  2904 
  2905 lemma multiset_induct2[case_names empty addL addR]:
  2906 assumes empty: "P {#} {#}"
  2907 and addL: "\<And>M N a. P M N \<Longrightarrow> P (M + {#a#}) N"
  2908 and addR: "\<And>M N a. P M N \<Longrightarrow> P M (N + {#a#})"
  2909 shows "P M N"
  2910 apply(induct N rule: multiset_induct)
  2911   apply(induct M rule: multiset_induct, rule empty, erule addL)
  2912   apply(induct M rule: multiset_induct, erule addR, erule addR)
  2913 done
  2914 
  2915 lemma multiset_induct2_mcard[consumes 1, case_names empty add]:
  2916 assumes c: "mcard M = mcard N"
  2917 and empty: "P {#} {#}"
  2918 and add: "\<And>M N a b. P M N \<Longrightarrow> P (M + {#a#}) (N + {#b#})"
  2919 shows "P M N"
  2920 using c proof(induct M arbitrary: N rule: measure_induct_rule[of mcard])
  2921   case (less M)  show ?case
  2922   proof(cases "M = {#}")
  2923     case True hence "N = {#}" using less.prems by auto
  2924     thus ?thesis using True empty by auto
  2925   next
  2926     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2927     have "N \<noteq> {#}" using False less.prems by auto
  2928     then obtain N1 b where N: "N = N1 + {#b#}" by (metis multi_nonempty_split)
  2929     have "mcard M1 = mcard N1" using less.prems unfolding M N by auto
  2930     thus ?thesis using M N less.hyps add by auto
  2931   qed
  2932 qed
  2933 
  2934 lemma msed_map_invL:
  2935 assumes "mmap f (M + {#a#}) = N"
  2936 shows "\<exists> N1. N = N1 + {#f a#} \<and> mmap f M = N1"
  2937 proof-
  2938   have "f a \<in># N"
  2939   using assms multiset.set_map[of f "M + {#a#}"] by auto
  2940   then obtain N1 where N: "N = N1 + {#f a#}" using multi_member_split by metis
  2941   have "mmap f M = N1" using assms unfolding N by simp
  2942   thus ?thesis using N by blast
  2943 qed
  2944 
  2945 lemma msed_map_invR:
  2946 assumes "mmap f M = N + {#b#}"
  2947 shows "\<exists> M1 a. M = M1 + {#a#} \<and> f a = b \<and> mmap f M1 = N"
  2948 proof-
  2949   obtain a where a: "a \<in># M" and fa: "f a = b"
  2950   using multiset.set_map[of f M] unfolding assms
  2951   by (metis image_iff mem_set_of_iff union_single_eq_member)
  2952   then obtain M1 where M: "M = M1 + {#a#}" using multi_member_split by metis
  2953   have "mmap f M1 = N" using assms unfolding M fa[symmetric] by simp
  2954   thus ?thesis using M fa by blast
  2955 qed
  2956 
  2957 lemma msed_rel_invL:
  2958 assumes "rel_multiset R (M + {#a#}) N"
  2959 shows "\<exists> N1 b. N = N1 + {#b#} \<and> R a b \<and> rel_multiset R M N1"
  2960 proof-
  2961   obtain K where KM: "mmap fst K = M + {#a#}"
  2962   and KN: "mmap snd K = N" and sK: "set_of K \<subseteq> {(a, b). R a b}"
  2963   using assms
  2964   unfolding rel_multiset_def Grp_def by auto
  2965   obtain K1 ab where K: "K = K1 + {#ab#}" and a: "fst ab = a"
  2966   and K1M: "mmap fst K1 = M" using msed_map_invR[OF KM] by auto
  2967   obtain N1 where N: "N = N1 + {#snd ab#}" and K1N1: "mmap snd K1 = N1"
  2968   using msed_map_invL[OF KN[unfolded K]] by auto
  2969   have Rab: "R a (snd ab)" using sK a unfolding K by auto
  2970   have "rel_multiset R M N1" using sK K1M K1N1
  2971   unfolding K rel_multiset_def Grp_def by auto
  2972   thus ?thesis using N Rab by auto
  2973 qed
  2974 
  2975 lemma msed_rel_invR:
  2976 assumes "rel_multiset R M (N + {#b#})"
  2977 shows "\<exists> M1 a. M = M1 + {#a#} \<and> R a b \<and> rel_multiset R M1 N"
  2978 proof-
  2979   obtain K where KN: "mmap snd K = N + {#b#}"
  2980   and KM: "mmap fst K = M" and sK: "set_of K \<subseteq> {(a, b). R a b}"
  2981   using assms
  2982   unfolding rel_multiset_def Grp_def by auto
  2983   obtain K1 ab where K: "K = K1 + {#ab#}" and b: "snd ab = b"
  2984   and K1N: "mmap snd K1 = N" using msed_map_invR[OF KN] by auto
  2985   obtain M1 where M: "M = M1 + {#fst ab#}" and K1M1: "mmap fst K1 = M1"
  2986   using msed_map_invL[OF KM[unfolded K]] by auto
  2987   have Rab: "R (fst ab) b" using sK b unfolding K by auto
  2988   have "rel_multiset R M1 N" using sK K1N K1M1
  2989   unfolding K rel_multiset_def Grp_def by auto
  2990   thus ?thesis using M Rab by auto
  2991 qed
  2992 
  2993 lemma rel_multiset_imp_rel_multiset':
  2994 assumes "rel_multiset R M N"
  2995 shows "rel_multiset' R M N"
  2996 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of mcard])
  2997   case (less M)
  2998   have c: "mcard M = mcard N" using rel_multiset_mcard[OF less.prems] .
  2999   show ?case
  3000   proof(cases "M = {#}")
  3001     case True hence "N = {#}" using c by simp
  3002     thus ?thesis using True rel_multiset'.Zero by auto
  3003   next
  3004     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  3005     obtain N1 b where N: "N = N1 + {#b#}" and R: "R a b" and ms: "rel_multiset R M1 N1"
  3006     using msed_rel_invL[OF less.prems[unfolded M]] by auto
  3007     have "rel_multiset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
  3008     thus ?thesis using rel_multiset'.Plus[of R a b, OF R] unfolding M N by simp
  3009   qed
  3010 qed
  3011 
  3012 lemma rel_multiset_rel_multiset':
  3013 "rel_multiset R M N = rel_multiset' R M N"
  3014 using  rel_multiset_imp_rel_multiset' rel_multiset'_imp_rel_multiset by auto
  3015 
  3016 (* The main end product for rel_multiset: inductive characterization *)
  3017 theorems rel_multiset_induct[case_names empty add, induct pred: rel_multiset] =
  3018          rel_multiset'.induct[unfolded rel_multiset_rel_multiset'[symmetric]]
  3019 
  3020 end