src/HOL/Power.thy
author haftmann
Sat Jul 09 13:26:16 2016 +0200 (2016-07-09)
changeset 63417 c184ec919c70
parent 63040 eb4ddd18d635
child 63648 f9f3006a5579
permissions -rw-r--r--
more lemmas to emphasize {0::nat..(<)n} as canonical representation of intervals on nat
* * *
more rules for setsum, setprod on intervals
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 section \<open>Exponentiation\<close>
     7 
     8 theory Power
     9 imports Num
    10 begin
    11 
    12 subsection \<open>Powers for Arbitrary Monoids\<close>
    13 
    14 class power = one + times
    15 begin
    16 
    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a"  (infixr "^" 80)
    18 where
    19   power_0: "a ^ 0 = 1"
    20 | power_Suc: "a ^ Suc n = a * a ^ n"
    21 
    22 notation (latex output)
    23   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    24 
    25 text \<open>Special syntax for squares.\<close>
    26 abbreviation power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999)
    27   where "x\<^sup>2 \<equiv> x ^ 2"
    28 
    29 end
    30 
    31 context monoid_mult
    32 begin
    33 
    34 subclass power .
    35 
    36 lemma power_one [simp]:
    37   "1 ^ n = 1"
    38   by (induct n) simp_all
    39 
    40 lemma power_one_right [simp]:
    41   "a ^ 1 = a"
    42   by simp
    43 
    44 lemma power_Suc0_right [simp]:
    45   "a ^ Suc 0 = a"
    46   by simp
    47 
    48 lemma power_commutes:
    49   "a ^ n * a = a * a ^ n"
    50   by (induct n) (simp_all add: mult.assoc)
    51 
    52 lemma power_Suc2:
    53   "a ^ Suc n = a ^ n * a"
    54   by (simp add: power_commutes)
    55 
    56 lemma power_add:
    57   "a ^ (m + n) = a ^ m * a ^ n"
    58   by (induct m) (simp_all add: algebra_simps)
    59 
    60 lemma power_mult:
    61   "a ^ (m * n) = (a ^ m) ^ n"
    62   by (induct n) (simp_all add: power_add)
    63 
    64 lemma power2_eq_square: "a\<^sup>2 = a * a"
    65   by (simp add: numeral_2_eq_2)
    66 
    67 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    68   by (simp add: numeral_3_eq_3 mult.assoc)
    69 
    70 lemma power_even_eq:
    71   "a ^ (2 * n) = (a ^ n)\<^sup>2"
    72   by (subst mult.commute) (simp add: power_mult)
    73 
    74 lemma power_odd_eq:
    75   "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
    76   by (simp add: power_even_eq)
    77 
    78 lemma power_numeral_even:
    79   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    80   unfolding numeral_Bit0 power_add Let_def ..
    81 
    82 lemma power_numeral_odd:
    83   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
    84   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
    85   unfolding power_Suc power_add Let_def mult.assoc ..
    86 
    87 lemma funpow_times_power:
    88   "(times x ^^ f x) = times (x ^ f x)"
    89 proof (induct "f x" arbitrary: f)
    90   case 0 then show ?case by (simp add: fun_eq_iff)
    91 next
    92   case (Suc n)
    93   define g where "g x = f x - 1" for x
    94   with Suc have "n = g x" by simp
    95   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
    96   moreover from Suc g_def have "f x = g x + 1" by simp
    97   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult.assoc)
    98 qed
    99 
   100 lemma power_commuting_commutes:
   101   assumes "x * y = y * x"
   102   shows "x ^ n * y = y * x ^n"
   103 proof (induct n)
   104   case (Suc n)
   105   have "x ^ Suc n * y = x ^ n * y * x"
   106     by (subst power_Suc2) (simp add: assms ac_simps)
   107   also have "\<dots> = y * x ^ Suc n"
   108     unfolding Suc power_Suc2
   109     by (simp add: ac_simps)
   110   finally show ?case .
   111 qed simp
   112 
   113 lemma power_minus_mult:
   114   "0 < n \<Longrightarrow> a ^ (n - 1) * a = a ^ n"
   115   by (simp add: power_commutes split add: nat_diff_split)
   116 
   117 end
   118 
   119 context comm_monoid_mult
   120 begin
   121 
   122 lemma power_mult_distrib [field_simps]:
   123   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   124   by (induct n) (simp_all add: ac_simps)
   125 
   126 end
   127 
   128 text\<open>Extract constant factors from powers\<close>
   129 declare power_mult_distrib [where a = "numeral w" for w, simp]
   130 declare power_mult_distrib [where b = "numeral w" for w, simp]
   131 
   132 lemma power_add_numeral [simp]:
   133   fixes a :: "'a :: monoid_mult"
   134   shows "a^numeral m * a^numeral n = a^numeral (m + n)"
   135   by (simp add: power_add [symmetric])
   136 
   137 lemma power_add_numeral2 [simp]:
   138   fixes a :: "'a :: monoid_mult"
   139   shows "a^numeral m * (a^numeral n * b) = a^numeral (m + n) * b"
   140   by (simp add: mult.assoc [symmetric])
   141 
   142 lemma power_mult_numeral [simp]:
   143   fixes a :: "'a :: monoid_mult"
   144   shows"(a^numeral m)^numeral n = a^numeral (m * n)"
   145   by (simp only: numeral_mult power_mult)
   146 
   147 context semiring_numeral
   148 begin
   149 
   150 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   151   by (simp only: sqr_conv_mult numeral_mult)
   152 
   153 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   154   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   155     numeral_sqr numeral_mult power_add power_one_right)
   156 
   157 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   158   by (rule numeral_pow [symmetric])
   159 
   160 end
   161 
   162 context semiring_1
   163 begin
   164 
   165 lemma of_nat_power [simp]:
   166   "of_nat (m ^ n) = of_nat m ^ n"
   167   by (induct n) simp_all
   168 
   169 lemma zero_power:
   170   "0 < n \<Longrightarrow> 0 ^ n = 0"
   171   by (cases n) simp_all
   172 
   173 lemma power_zero_numeral [simp]:
   174   "0 ^ numeral k = 0"
   175   by (simp add: numeral_eq_Suc)
   176 
   177 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
   178   by (rule power_zero_numeral)
   179 
   180 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
   181   by (rule power_one)
   182 
   183 lemma power_0_Suc [simp]:
   184   "0 ^ Suc n = 0"
   185   by simp
   186 
   187 text\<open>It looks plausible as a simprule, but its effect can be strange.\<close>
   188 lemma power_0_left:
   189   "0 ^ n = (if n = 0 then 1 else 0)"
   190   by (cases n) simp_all
   191 
   192 end
   193 
   194 context comm_semiring_1
   195 begin
   196 
   197 text \<open>The divides relation\<close>
   198 
   199 lemma le_imp_power_dvd:
   200   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   201 proof
   202   have "a ^ n = a ^ (m + (n - m))"
   203     using \<open>m \<le> n\<close> by simp
   204   also have "\<dots> = a ^ m * a ^ (n - m)"
   205     by (rule power_add)
   206   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   207 qed
   208 
   209 lemma power_le_dvd:
   210   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   211   by (rule dvd_trans [OF le_imp_power_dvd])
   212 
   213 lemma dvd_power_same:
   214   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   215   by (induct n) (auto simp add: mult_dvd_mono)
   216 
   217 lemma dvd_power_le:
   218   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   219   by (rule power_le_dvd [OF dvd_power_same])
   220 
   221 lemma dvd_power [simp]:
   222   assumes "n > (0::nat) \<or> x = 1"
   223   shows "x dvd (x ^ n)"
   224 using assms proof
   225   assume "0 < n"
   226   then have "x ^ n = x ^ Suc (n - 1)" by simp
   227   then show "x dvd (x ^ n)" by simp
   228 next
   229   assume "x = 1"
   230   then show "x dvd (x ^ n)" by simp
   231 qed
   232 
   233 end
   234 
   235 context semiring_1_no_zero_divisors
   236 begin
   237 
   238 subclass power .
   239 
   240 lemma power_eq_0_iff [simp]:
   241   "a ^ n = 0 \<longleftrightarrow> a = 0 \<and> n > 0"
   242   by (induct n) auto
   243 
   244 lemma power_not_zero:
   245   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   246   by (induct n) auto
   247 
   248 lemma zero_eq_power2 [simp]:
   249   "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
   250   unfolding power2_eq_square by simp
   251 
   252 end
   253 
   254 context ring_1
   255 begin
   256 
   257 lemma power_minus:
   258   "(- a) ^ n = (- 1) ^ n * a ^ n"
   259 proof (induct n)
   260   case 0 show ?case by simp
   261 next
   262   case (Suc n) then show ?case
   263     by (simp del: power_Suc add: power_Suc2 mult.assoc)
   264 qed
   265 
   266 lemma power_minus': "NO_MATCH 1 x \<Longrightarrow> (-x) ^ n = (-1)^n * x ^ n"
   267   by (rule power_minus)
   268 
   269 lemma power_minus_Bit0:
   270   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   271   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   272     power_one_right mult_minus_left mult_minus_right minus_minus)
   273 
   274 lemma power_minus_Bit1:
   275   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   276   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   277 
   278 lemma power2_minus [simp]:
   279   "(- a)\<^sup>2 = a\<^sup>2"
   280   by (fact power_minus_Bit0)
   281 
   282 lemma power_minus1_even [simp]:
   283   "(- 1) ^ (2*n) = 1"
   284 proof (induct n)
   285   case 0 show ?case by simp
   286 next
   287   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   288 qed
   289 
   290 lemma power_minus1_odd:
   291   "(- 1) ^ Suc (2*n) = -1"
   292   by simp
   293 
   294 lemma power_minus_even [simp]:
   295   "(-a) ^ (2*n) = a ^ (2*n)"
   296   by (simp add: power_minus [of a])
   297 
   298 end
   299 
   300 context ring_1_no_zero_divisors
   301 begin
   302 
   303 lemma power2_eq_1_iff:
   304   "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   305   using square_eq_1_iff [of a] by (simp add: power2_eq_square)
   306 
   307 end
   308 
   309 context idom
   310 begin
   311 
   312 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
   313   unfolding power2_eq_square by (rule square_eq_iff)
   314 
   315 end
   316 
   317 context algebraic_semidom
   318 begin
   319 
   320 lemma div_power:
   321   assumes "b dvd a"
   322   shows "(a div b) ^ n = a ^ n div b ^ n"
   323   using assms by (induct n) (simp_all add: div_mult_div_if_dvd dvd_power_same)
   324 
   325 lemma is_unit_power_iff:
   326   "is_unit (a ^ n) \<longleftrightarrow> is_unit a \<or> n = 0"
   327   by (induct n) (auto simp add: is_unit_mult_iff)
   328 
   329 end
   330 
   331 context normalization_semidom
   332 begin
   333 
   334 lemma normalize_power:
   335   "normalize (a ^ n) = normalize a ^ n"
   336   by (induct n) (simp_all add: normalize_mult)
   337 
   338 lemma unit_factor_power:
   339   "unit_factor (a ^ n) = unit_factor a ^ n"
   340   by (induct n) (simp_all add: unit_factor_mult)
   341 
   342 end
   343 
   344 context division_ring
   345 begin
   346 
   347 text\<open>Perhaps these should be simprules.\<close>
   348 lemma power_inverse [field_simps, divide_simps]:
   349   "inverse a ^ n = inverse (a ^ n)"
   350 proof (cases "a = 0")
   351   case True then show ?thesis by (simp add: power_0_left)
   352 next
   353   case False then have "inverse (a ^ n) = inverse a ^ n"
   354     by (induct n) (simp_all add: nonzero_inverse_mult_distrib power_commutes)
   355   then show ?thesis by simp
   356 qed
   357 
   358 lemma power_one_over [field_simps, divide_simps]:
   359   "(1 / a) ^ n = 1 / a ^ n"
   360   using power_inverse [of a] by (simp add: divide_inverse)
   361 
   362 end
   363 
   364 context field
   365 begin
   366 
   367 lemma power_diff:
   368   assumes nz: "a \<noteq> 0"
   369   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   370   by (induct m n rule: diff_induct) (simp_all add: nz power_not_zero)
   371 
   372 lemma power_divide [field_simps, divide_simps]:
   373   "(a / b) ^ n = a ^ n / b ^ n"
   374   by (induct n) simp_all
   375 
   376 end
   377 
   378 
   379 subsection \<open>Exponentiation on ordered types\<close>
   380 
   381 context linordered_semidom
   382 begin
   383 
   384 lemma zero_less_power [simp]:
   385   "0 < a \<Longrightarrow> 0 < a ^ n"
   386   by (induct n) simp_all
   387 
   388 lemma zero_le_power [simp]:
   389   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   390   by (induct n) simp_all
   391 
   392 lemma power_mono:
   393   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   394   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   395 
   396 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   397   using power_mono [of 1 a n] by simp
   398 
   399 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   400   using power_mono [of a 1 n] by simp
   401 
   402 lemma power_gt1_lemma:
   403   assumes gt1: "1 < a"
   404   shows "1 < a * a ^ n"
   405 proof -
   406   from gt1 have "0 \<le> a"
   407     by (fact order_trans [OF zero_le_one less_imp_le])
   408   have "1 * 1 < a * 1" using gt1 by simp
   409   also have "\<dots> \<le> a * a ^ n" using gt1
   410     by (simp only: mult_mono \<open>0 \<le> a\<close> one_le_power order_less_imp_le
   411         zero_le_one order_refl)
   412   finally show ?thesis by simp
   413 qed
   414 
   415 lemma power_gt1:
   416   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   417   by (simp add: power_gt1_lemma)
   418 
   419 lemma one_less_power [simp]:
   420   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   421   by (cases n) (simp_all add: power_gt1_lemma)
   422 
   423 lemma power_le_imp_le_exp:
   424   assumes gt1: "1 < a"
   425   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   426 proof (induct m arbitrary: n)
   427   case 0
   428   show ?case by simp
   429 next
   430   case (Suc m)
   431   show ?case
   432   proof (cases n)
   433     case 0
   434     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   435     with gt1 show ?thesis
   436       by (force simp only: power_gt1_lemma
   437           not_less [symmetric])
   438   next
   439     case (Suc n)
   440     with Suc.prems Suc.hyps show ?thesis
   441       by (force dest: mult_left_le_imp_le
   442           simp add: less_trans [OF zero_less_one gt1])
   443   qed
   444 qed
   445 
   446 lemma of_nat_zero_less_power_iff [simp]:
   447   "of_nat x ^ n > 0 \<longleftrightarrow> x > 0 \<or> n = 0"
   448   by (induct n) auto
   449 
   450 text\<open>Surely we can strengthen this? It holds for \<open>0<a<1\<close> too.\<close>
   451 lemma power_inject_exp [simp]:
   452   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   453   by (force simp add: order_antisym power_le_imp_le_exp)
   454 
   455 text\<open>Can relax the first premise to @{term "0<a"} in the case of the
   456 natural numbers.\<close>
   457 lemma power_less_imp_less_exp:
   458   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   459   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   460     power_le_imp_le_exp)
   461 
   462 lemma power_strict_mono [rule_format]:
   463   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   464   by (induct n)
   465    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   466 
   467 text\<open>Lemma for \<open>power_strict_decreasing\<close>\<close>
   468 lemma power_Suc_less:
   469   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   470   by (induct n)
   471     (auto simp add: mult_strict_left_mono)
   472 
   473 lemma power_strict_decreasing [rule_format]:
   474   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   475 proof (induct N)
   476   case 0 then show ?case by simp
   477 next
   478   case (Suc N) then show ?case
   479   apply (auto simp add: power_Suc_less less_Suc_eq)
   480   apply (subgoal_tac "a * a^N < 1 * a^n")
   481   apply simp
   482   apply (rule mult_strict_mono) apply auto
   483   done
   484 qed
   485 
   486 text\<open>Proof resembles that of \<open>power_strict_decreasing\<close>\<close>
   487 lemma power_decreasing [rule_format]:
   488   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   489 proof (induct N)
   490   case 0 then show ?case by simp
   491 next
   492   case (Suc N) then show ?case
   493   apply (auto simp add: le_Suc_eq)
   494   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   495   apply (rule mult_mono) apply auto
   496   done
   497 qed
   498 
   499 lemma power_Suc_less_one:
   500   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   501   using power_strict_decreasing [of 0 "Suc n" a] by simp
   502 
   503 text\<open>Proof again resembles that of \<open>power_strict_decreasing\<close>\<close>
   504 lemma power_increasing [rule_format]:
   505   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   506 proof (induct N)
   507   case 0 then show ?case by simp
   508 next
   509   case (Suc N) then show ?case
   510   apply (auto simp add: le_Suc_eq)
   511   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   512   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   513   done
   514 qed
   515 
   516 text\<open>Lemma for \<open>power_strict_increasing\<close>\<close>
   517 lemma power_less_power_Suc:
   518   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   519   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   520 
   521 lemma power_strict_increasing [rule_format]:
   522   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   523 proof (induct N)
   524   case 0 then show ?case by simp
   525 next
   526   case (Suc N) then show ?case
   527   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   528   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   529   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   530   done
   531 qed
   532 
   533 lemma power_increasing_iff [simp]:
   534   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   535   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   536 
   537 lemma power_strict_increasing_iff [simp]:
   538   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   539 by (blast intro: power_less_imp_less_exp power_strict_increasing)
   540 
   541 lemma power_le_imp_le_base:
   542   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   543     and ynonneg: "0 \<le> b"
   544   shows "a \<le> b"
   545 proof (rule ccontr)
   546   assume "~ a \<le> b"
   547   then have "b < a" by (simp only: linorder_not_le)
   548   then have "b ^ Suc n < a ^ Suc n"
   549     by (simp only: assms power_strict_mono)
   550   from le and this show False
   551     by (simp add: linorder_not_less [symmetric])
   552 qed
   553 
   554 lemma power_less_imp_less_base:
   555   assumes less: "a ^ n < b ^ n"
   556   assumes nonneg: "0 \<le> b"
   557   shows "a < b"
   558 proof (rule contrapos_pp [OF less])
   559   assume "~ a < b"
   560   hence "b \<le> a" by (simp only: linorder_not_less)
   561   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   562   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   563 qed
   564 
   565 lemma power_inject_base:
   566   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   567 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   568 
   569 lemma power_eq_imp_eq_base:
   570   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   571   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   572 
   573 lemma power_eq_iff_eq_base:
   574   "0 < n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a ^ n = b ^ n \<longleftrightarrow> a = b"
   575   using power_eq_imp_eq_base [of a n b] by auto
   576 
   577 lemma power2_le_imp_le:
   578   "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   579   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   580 
   581 lemma power2_less_imp_less:
   582   "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   583   by (rule power_less_imp_less_base)
   584 
   585 lemma power2_eq_imp_eq:
   586   "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   587   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   588 
   589 lemma power_Suc_le_self:
   590   shows "0 \<le> a \<Longrightarrow> a \<le> 1 \<Longrightarrow> a ^ Suc n \<le> a"
   591   using power_decreasing [of 1 "Suc n" a] by simp
   592 
   593 end
   594 
   595 context linordered_ring_strict
   596 begin
   597 
   598 lemma sum_squares_eq_zero_iff:
   599   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   600   by (simp add: add_nonneg_eq_0_iff)
   601 
   602 lemma sum_squares_le_zero_iff:
   603   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   604   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   605 
   606 lemma sum_squares_gt_zero_iff:
   607   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   608   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   609 
   610 end
   611 
   612 context linordered_idom
   613 begin
   614 
   615 lemma power_abs: "\<bar>a ^ n\<bar> = \<bar>a\<bar> ^ n"
   616   by (induct n) (auto simp add: abs_mult)
   617 
   618 lemma abs_power_minus [simp]: "\<bar>(-a) ^ n\<bar> = \<bar>a ^ n\<bar>"
   619   by (simp add: power_abs)
   620 
   621 lemma zero_less_power_abs_iff [simp]: "0 < \<bar>a\<bar> ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   622 proof (induct n)
   623   case 0 show ?case by simp
   624 next
   625   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   626 qed
   627 
   628 lemma zero_le_power_abs [simp]: "0 \<le> \<bar>a\<bar> ^ n"
   629   by (rule zero_le_power [OF abs_ge_zero])
   630 
   631 lemma zero_le_power2 [simp]:
   632   "0 \<le> a\<^sup>2"
   633   by (simp add: power2_eq_square)
   634 
   635 lemma zero_less_power2 [simp]:
   636   "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
   637   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   638 
   639 lemma power2_less_0 [simp]:
   640   "\<not> a\<^sup>2 < 0"
   641   by (force simp add: power2_eq_square mult_less_0_iff)
   642 
   643 lemma power2_less_eq_zero_iff [simp]:
   644   "a\<^sup>2 \<le> 0 \<longleftrightarrow> a = 0"
   645   by (simp add: le_less)
   646 
   647 lemma abs_power2 [simp]: "\<bar>a\<^sup>2\<bar> = a\<^sup>2"
   648   by (simp add: power2_eq_square)
   649 
   650 lemma power2_abs [simp]: "\<bar>a\<bar>\<^sup>2 = a\<^sup>2"
   651   by (simp add: power2_eq_square)
   652 
   653 lemma odd_power_less_zero:
   654   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   655 proof (induct n)
   656   case 0
   657   then show ?case by simp
   658 next
   659   case (Suc n)
   660   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   661     by (simp add: ac_simps power_add power2_eq_square)
   662   thus ?case
   663     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   664 qed
   665 
   666 lemma odd_0_le_power_imp_0_le:
   667   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   668   using odd_power_less_zero [of a n]
   669     by (force simp add: linorder_not_less [symmetric])
   670 
   671 lemma zero_le_even_power'[simp]:
   672   "0 \<le> a ^ (2*n)"
   673 proof (induct n)
   674   case 0
   675     show ?case by simp
   676 next
   677   case (Suc n)
   678     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)"
   679       by (simp add: ac_simps power_add power2_eq_square)
   680     thus ?case
   681       by (simp add: Suc zero_le_mult_iff)
   682 qed
   683 
   684 lemma sum_power2_ge_zero:
   685   "0 \<le> x\<^sup>2 + y\<^sup>2"
   686   by (intro add_nonneg_nonneg zero_le_power2)
   687 
   688 lemma not_sum_power2_lt_zero:
   689   "\<not> x\<^sup>2 + y\<^sup>2 < 0"
   690   unfolding not_less by (rule sum_power2_ge_zero)
   691 
   692 lemma sum_power2_eq_zero_iff:
   693   "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   694   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   695 
   696 lemma sum_power2_le_zero_iff:
   697   "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   698   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   699 
   700 lemma sum_power2_gt_zero_iff:
   701   "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   702   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   703 
   704 lemma abs_le_square_iff:
   705    "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> x\<^sup>2 \<le> y\<^sup>2"
   706 proof
   707   assume "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   708   then have "\<bar>x\<bar>\<^sup>2 \<le> \<bar>y\<bar>\<^sup>2" by (rule power_mono, simp)
   709   then show "x\<^sup>2 \<le> y\<^sup>2" by simp
   710 next
   711   assume "x\<^sup>2 \<le> y\<^sup>2"
   712   then show "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   713     by (auto intro!: power2_le_imp_le [OF _ abs_ge_zero])
   714 qed
   715 
   716 lemma abs_square_le_1:"x\<^sup>2 \<le> 1 \<longleftrightarrow> \<bar>x\<bar> \<le> 1"
   717   using abs_le_square_iff [of x 1]
   718   by simp
   719 
   720 lemma abs_square_eq_1: "x\<^sup>2 = 1 \<longleftrightarrow> \<bar>x\<bar> = 1"
   721   by (auto simp add: abs_if power2_eq_1_iff)
   722 
   723 lemma abs_square_less_1: "x\<^sup>2 < 1 \<longleftrightarrow> \<bar>x\<bar> < 1"
   724   using  abs_square_eq_1 [of x] abs_square_le_1 [of x]
   725   by (auto simp add: le_less)
   726 
   727 end
   728 
   729 
   730 subsection \<open>Miscellaneous rules\<close>
   731 
   732 lemma (in linordered_semidom) self_le_power:
   733   "1 \<le> a \<Longrightarrow> 0 < n \<Longrightarrow> a \<le> a ^ n"
   734   using power_increasing [of 1 n a] power_one_right [of a] by auto
   735 
   736 lemma (in power) power_eq_if:
   737   "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   738   unfolding One_nat_def by (cases m) simp_all
   739 
   740 lemma (in comm_semiring_1) power2_sum:
   741   "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
   742   by (simp add: algebra_simps power2_eq_square mult_2_right)
   743 
   744 lemma (in comm_ring_1) power2_diff:
   745   "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
   746   by (simp add: algebra_simps power2_eq_square mult_2_right)
   747 
   748 lemma (in comm_ring_1) power2_commute:
   749   "(x - y)\<^sup>2 = (y - x)\<^sup>2"
   750   by (simp add: algebra_simps power2_eq_square)
   751 
   752 lemma (in comm_ring_1) minus_power_mult_self:
   753   "(- a) ^ n * (- a) ^ n = a ^ (2 * n)"
   754   by (simp add: power_mult_distrib [symmetric]) (simp add: power2_eq_square [symmetric] power_mult [symmetric])
   755   
   756 lemma (in comm_ring_1) minus_one_mult_self [simp]:
   757   "(- 1) ^ n * (- 1) ^ n = 1"
   758   using minus_power_mult_self [of 1 n] by simp
   759 
   760 lemma (in comm_ring_1) left_minus_one_mult_self [simp]:
   761   "(- 1) ^ n * ((- 1) ^ n * a) = a"
   762   by (simp add: mult.assoc [symmetric])
   763 
   764 text \<open>Simprules for comparisons where common factors can be cancelled.\<close>
   765 
   766 lemmas zero_compare_simps =
   767     add_strict_increasing add_strict_increasing2 add_increasing
   768     zero_le_mult_iff zero_le_divide_iff
   769     zero_less_mult_iff zero_less_divide_iff
   770     mult_le_0_iff divide_le_0_iff
   771     mult_less_0_iff divide_less_0_iff
   772     zero_le_power2 power2_less_0
   773 
   774 
   775 subsection \<open>Exponentiation for the Natural Numbers\<close>
   776 
   777 lemma nat_one_le_power [simp]:
   778   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   779   by (rule one_le_power [of i n, unfolded One_nat_def])
   780 
   781 lemma nat_zero_less_power_iff [simp]:
   782   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   783   by (induct n) auto
   784 
   785 lemma nat_power_eq_Suc_0_iff [simp]:
   786   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   787   by (induct m) auto
   788 
   789 lemma power_Suc_0 [simp]:
   790   "Suc 0 ^ n = Suc 0"
   791   by simp
   792 
   793 text\<open>Valid for the naturals, but what if \<open>0<i<1\<close>?
   794 Premises cannot be weakened: consider the case where @{term "i=0"},
   795 @{term "m=1"} and @{term "n=0"}.\<close>
   796 lemma nat_power_less_imp_less:
   797   assumes nonneg: "0 < (i::nat)"
   798   assumes less: "i ^ m < i ^ n"
   799   shows "m < n"
   800 proof (cases "i = 1")
   801   case True with less power_one [where 'a = nat] show ?thesis by simp
   802 next
   803   case False with nonneg have "1 < i" by auto
   804   from power_strict_increasing_iff [OF this] less show ?thesis ..
   805 qed
   806 
   807 lemma power_dvd_imp_le:
   808   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   809   apply (rule power_le_imp_le_exp, assumption)
   810   apply (erule dvd_imp_le, simp)
   811   done
   812 
   813 lemma power2_nat_le_eq_le:
   814   fixes m n :: nat
   815   shows "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
   816   by (auto intro: power2_le_imp_le power_mono)
   817 
   818 lemma power2_nat_le_imp_le:
   819   fixes m n :: nat
   820   assumes "m\<^sup>2 \<le> n"
   821   shows "m \<le> n"
   822 proof (cases m)
   823   case 0 then show ?thesis by simp
   824 next
   825   case (Suc k)
   826   show ?thesis
   827   proof (rule ccontr)
   828     assume "\<not> m \<le> n"
   829     then have "n < m" by simp
   830     with assms Suc show False
   831       by (simp add: power2_eq_square)
   832   qed
   833 qed
   834 
   835 subsubsection \<open>Cardinality of the Powerset\<close>
   836 
   837 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
   838   unfolding UNIV_bool by simp
   839 
   840 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
   841 proof (induct rule: finite_induct)
   842   case empty
   843     show ?case by auto
   844 next
   845   case (insert x A)
   846   then have "inj_on (insert x) (Pow A)"
   847     unfolding inj_on_def by (blast elim!: equalityE)
   848   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A"
   849     by (simp add: mult_2 card_image Pow_insert insert.hyps)
   850   then show ?case using insert
   851     apply (simp add: Pow_insert)
   852     apply (subst card_Un_disjoint, auto)
   853     done
   854 qed
   855 
   856 
   857 subsection \<open>Code generator tweak\<close>
   858 
   859 code_identifier
   860   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   861 
   862 end