src/HOL/List.thy
author bulwahn
Sat Feb 25 09:07:37 2012 +0100 (2012-02-25)
changeset 46669 c1d2ab32174a
parent 46664 1f6c140f9c72
child 46698 f1dfcf8be88d
permissions -rw-r--r--
one general list_all2_update_cong instead of two special ones
     1 (*  Title:      HOL/List.thy
     2     Author:     Tobias Nipkow
     3 *)
     4 
     5 header {* The datatype of finite lists *}
     6 
     7 theory List
     8 imports Plain Presburger Code_Numeral Quotient ATP
     9 uses
    10   ("Tools/list_code.ML")
    11   ("Tools/list_to_set_comprehension.ML")
    12 begin
    13 
    14 datatype 'a list =
    15     Nil    ("[]")
    16   | Cons 'a  "'a list"    (infixr "#" 65)
    17 
    18 syntax
    19   -- {* list Enumeration *}
    20   "_list" :: "args => 'a list"    ("[(_)]")
    21 
    22 translations
    23   "[x, xs]" == "x#[xs]"
    24   "[x]" == "x#[]"
    25 
    26 
    27 subsection {* Basic list processing functions *}
    28 
    29 primrec
    30   hd :: "'a list \<Rightarrow> 'a" where
    31   "hd (x # xs) = x"
    32 
    33 primrec
    34   tl :: "'a list \<Rightarrow> 'a list" where
    35     "tl [] = []"
    36   | "tl (x # xs) = xs"
    37 
    38 primrec
    39   last :: "'a list \<Rightarrow> 'a" where
    40   "last (x # xs) = (if xs = [] then x else last xs)"
    41 
    42 primrec
    43   butlast :: "'a list \<Rightarrow> 'a list" where
    44     "butlast []= []"
    45   | "butlast (x # xs) = (if xs = [] then [] else x # butlast xs)"
    46 
    47 primrec
    48   set :: "'a list \<Rightarrow> 'a set" where
    49     "set [] = {}"
    50   | "set (x # xs) = insert x (set xs)"
    51 
    52 definition
    53   coset :: "'a list \<Rightarrow> 'a set" where
    54   [simp]: "coset xs = - set xs"
    55 
    56 primrec
    57   map :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b list" where
    58     "map f [] = []"
    59   | "map f (x # xs) = f x # map f xs"
    60 
    61 primrec
    62   append :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list" (infixr "@" 65) where
    63     append_Nil:"[] @ ys = ys"
    64   | append_Cons: "(x#xs) @ ys = x # xs @ ys"
    65 
    66 primrec
    67   rev :: "'a list \<Rightarrow> 'a list" where
    68     "rev [] = []"
    69   | "rev (x # xs) = rev xs @ [x]"
    70 
    71 primrec
    72   filter:: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list" where
    73     "filter P [] = []"
    74   | "filter P (x # xs) = (if P x then x # filter P xs else filter P xs)"
    75 
    76 syntax
    77   -- {* Special syntax for filter *}
    78   "_filter" :: "[pttrn, 'a list, bool] => 'a list"    ("(1[_<-_./ _])")
    79 
    80 translations
    81   "[x<-xs . P]"== "CONST filter (%x. P) xs"
    82 
    83 syntax (xsymbols)
    84   "_filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<leftarrow>_ ./ _])")
    85 syntax (HTML output)
    86   "_filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<leftarrow>_ ./ _])")
    87 
    88 primrec -- {* canonical argument order *}
    89   fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b \<Rightarrow> 'b" where
    90     "fold f [] = id"
    91   | "fold f (x # xs) = fold f xs \<circ> f x"
    92 
    93 definition 
    94   foldr :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b \<Rightarrow> 'b" where
    95   [code_abbrev]: "foldr f xs = fold f (rev xs)"
    96 
    97 definition
    98   foldl :: "('b \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a list \<Rightarrow> 'b" where
    99   "foldl f s xs = fold (\<lambda>x s. f s x)  xs s"
   100 
   101 primrec
   102   concat:: "'a list list \<Rightarrow> 'a list" where
   103     "concat [] = []"
   104   | "concat (x # xs) = x @ concat xs"
   105 
   106 definition (in monoid_add)
   107   listsum :: "'a list \<Rightarrow> 'a" where
   108   "listsum xs = foldr plus xs 0"
   109 
   110 primrec
   111   drop:: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   112     drop_Nil: "drop n [] = []"
   113   | drop_Cons: "drop n (x # xs) = (case n of 0 \<Rightarrow> x # xs | Suc m \<Rightarrow> drop m xs)"
   114   -- {*Warning: simpset does not contain this definition, but separate
   115        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   116 
   117 primrec
   118   take:: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   119     take_Nil:"take n [] = []"
   120   | take_Cons: "take n (x # xs) = (case n of 0 \<Rightarrow> [] | Suc m \<Rightarrow> x # take m xs)"
   121   -- {*Warning: simpset does not contain this definition, but separate
   122        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   123 
   124 primrec
   125   nth :: "'a list => nat => 'a" (infixl "!" 100) where
   126   nth_Cons: "(x # xs) ! n = (case n of 0 \<Rightarrow> x | Suc k \<Rightarrow> xs ! k)"
   127   -- {*Warning: simpset does not contain this definition, but separate
   128        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   129 
   130 primrec
   131   list_update :: "'a list \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a list" where
   132     "list_update [] i v = []"
   133   | "list_update (x # xs) i v = (case i of 0 \<Rightarrow> v # xs | Suc j \<Rightarrow> x # list_update xs j v)"
   134 
   135 nonterminal lupdbinds and lupdbind
   136 
   137 syntax
   138   "_lupdbind":: "['a, 'a] => lupdbind"    ("(2_ :=/ _)")
   139   "" :: "lupdbind => lupdbinds"    ("_")
   140   "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds"    ("_,/ _")
   141   "_LUpdate" :: "['a, lupdbinds] => 'a"    ("_/[(_)]" [900,0] 900)
   142 
   143 translations
   144   "_LUpdate xs (_lupdbinds b bs)" == "_LUpdate (_LUpdate xs b) bs"
   145   "xs[i:=x]" == "CONST list_update xs i x"
   146 
   147 primrec
   148   takeWhile :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   149     "takeWhile P [] = []"
   150   | "takeWhile P (x # xs) = (if P x then x # takeWhile P xs else [])"
   151 
   152 primrec
   153   dropWhile :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   154     "dropWhile P [] = []"
   155   | "dropWhile P (x # xs) = (if P x then dropWhile P xs else x # xs)"
   156 
   157 primrec
   158   zip :: "'a list \<Rightarrow> 'b list \<Rightarrow> ('a \<times> 'b) list" where
   159     "zip xs [] = []"
   160   | zip_Cons: "zip xs (y # ys) = (case xs of [] => [] | z # zs => (z, y) # zip zs ys)"
   161   -- {*Warning: simpset does not contain this definition, but separate
   162        theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   163 
   164 primrec 
   165   upt :: "nat \<Rightarrow> nat \<Rightarrow> nat list" ("(1[_..</_'])") where
   166     upt_0: "[i..<0] = []"
   167   | upt_Suc: "[i..<(Suc j)] = (if i <= j then [i..<j] @ [j] else [])"
   168 
   169 definition
   170   insert :: "'a \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   171   "insert x xs = (if x \<in> set xs then xs else x # xs)"
   172 
   173 hide_const (open) insert
   174 hide_fact (open) insert_def
   175 
   176 primrec
   177   remove1 :: "'a \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   178     "remove1 x [] = []"
   179   | "remove1 x (y # xs) = (if x = y then xs else y # remove1 x xs)"
   180 
   181 primrec
   182   removeAll :: "'a \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   183     "removeAll x [] = []"
   184   | "removeAll x (y # xs) = (if x = y then removeAll x xs else y # removeAll x xs)"
   185 
   186 primrec
   187   distinct :: "'a list \<Rightarrow> bool" where
   188     "distinct [] \<longleftrightarrow> True"
   189   | "distinct (x # xs) \<longleftrightarrow> x \<notin> set xs \<and> distinct xs"
   190 
   191 primrec
   192   remdups :: "'a list \<Rightarrow> 'a list" where
   193     "remdups [] = []"
   194   | "remdups (x # xs) = (if x \<in> set xs then remdups xs else x # remdups xs)"
   195 
   196 primrec
   197   replicate :: "nat \<Rightarrow> 'a \<Rightarrow> 'a list" where
   198     replicate_0: "replicate 0 x = []"
   199   | replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   200 
   201 text {*
   202   Function @{text size} is overloaded for all datatypes. Users may
   203   refer to the list version as @{text length}. *}
   204 
   205 abbreviation
   206   length :: "'a list \<Rightarrow> nat" where
   207   "length \<equiv> size"
   208 
   209 primrec rotate1 :: "'a list \<Rightarrow> 'a list" where
   210   "rotate1 [] = []" |
   211   "rotate1 (x # xs) = xs @ [x]"
   212 
   213 definition
   214   rotate :: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   215   "rotate n = rotate1 ^^ n"
   216 
   217 definition
   218   list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool" where
   219   "list_all2 P xs ys =
   220     (length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y))"
   221 
   222 definition
   223   sublist :: "'a list => nat set => 'a list" where
   224   "sublist xs A = map fst (filter (\<lambda>p. snd p \<in> A) (zip xs [0..<size xs]))"
   225 
   226 fun splice :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list" where
   227 "splice [] ys = ys" |
   228 "splice xs [] = xs" |
   229 "splice (x#xs) (y#ys) = x # y # splice xs ys"
   230 
   231 text{*
   232 \begin{figure}[htbp]
   233 \fbox{
   234 \begin{tabular}{l}
   235 @{lemma "[a,b]@[c,d] = [a,b,c,d]" by simp}\\
   236 @{lemma "length [a,b,c] = 3" by simp}\\
   237 @{lemma "set [a,b,c] = {a,b,c}" by simp}\\
   238 @{lemma "map f [a,b,c] = [f a, f b, f c]" by simp}\\
   239 @{lemma "rev [a,b,c] = [c,b,a]" by simp}\\
   240 @{lemma "hd [a,b,c,d] = a" by simp}\\
   241 @{lemma "tl [a,b,c,d] = [b,c,d]" by simp}\\
   242 @{lemma "last [a,b,c,d] = d" by simp}\\
   243 @{lemma "butlast [a,b,c,d] = [a,b,c]" by simp}\\
   244 @{lemma[source] "filter (\<lambda>n::nat. n<2) [0,2,1] = [0,1]" by simp}\\
   245 @{lemma "concat [[a,b],[c,d,e],[],[f]] = [a,b,c,d,e,f]" by simp}\\
   246 @{lemma "fold f [a,b,c] x = f c (f b (f a x))" by simp}\\
   247 @{lemma "foldr f [a,b,c] x = f a (f b (f c x))" by (simp add: foldr_def)}\\
   248 @{lemma "foldl f x [a,b,c] = f (f (f x a) b) c" by (simp add: foldl_def)}\\
   249 @{lemma "zip [a,b,c] [x,y,z] = [(a,x),(b,y),(c,z)]" by simp}\\
   250 @{lemma "zip [a,b] [x,y,z] = [(a,x),(b,y)]" by simp}\\
   251 @{lemma "splice [a,b,c] [x,y,z] = [a,x,b,y,c,z]" by simp}\\
   252 @{lemma "splice [a,b,c,d] [x,y] = [a,x,b,y,c,d]" by simp}\\
   253 @{lemma "take 2 [a,b,c,d] = [a,b]" by simp}\\
   254 @{lemma "take 6 [a,b,c,d] = [a,b,c,d]" by simp}\\
   255 @{lemma "drop 2 [a,b,c,d] = [c,d]" by simp}\\
   256 @{lemma "drop 6 [a,b,c,d] = []" by simp}\\
   257 @{lemma "takeWhile (%n::nat. n<3) [1,2,3,0] = [1,2]" by simp}\\
   258 @{lemma "dropWhile (%n::nat. n<3) [1,2,3,0] = [3,0]" by simp}\\
   259 @{lemma "distinct [2,0,1::nat]" by simp}\\
   260 @{lemma "remdups [2,0,2,1::nat,2] = [0,1,2]" by simp}\\
   261 @{lemma "List.insert 2 [0::nat,1,2] = [0,1,2]" by (simp add: List.insert_def)}\\
   262 @{lemma "List.insert 3 [0::nat,1,2] = [3,0,1,2]" by (simp add: List.insert_def)}\\
   263 @{lemma "remove1 2 [2,0,2,1::nat,2] = [0,2,1,2]" by simp}\\
   264 @{lemma "removeAll 2 [2,0,2,1::nat,2] = [0,1]" by simp}\\
   265 @{lemma "nth [a,b,c,d] 2 = c" by simp}\\
   266 @{lemma "[a,b,c,d][2 := x] = [a,b,x,d]" by simp}\\
   267 @{lemma "sublist [a,b,c,d,e] {0,2,3} = [a,c,d]" by (simp add:sublist_def)}\\
   268 @{lemma "rotate1 [a,b,c,d] = [b,c,d,a]" by simp}\\
   269 @{lemma "rotate 3 [a,b,c,d] = [d,a,b,c]" by (simp add:rotate_def eval_nat_numeral)}\\
   270 @{lemma "replicate 4 a = [a,a,a,a]" by (simp add:eval_nat_numeral)}\\
   271 @{lemma "[2..<5] = [2,3,4]" by (simp add:eval_nat_numeral)}\\
   272 @{lemma "listsum [1,2,3::nat] = 6" by (simp add: listsum_def foldr_def)}
   273 \end{tabular}}
   274 \caption{Characteristic examples}
   275 \label{fig:Characteristic}
   276 \end{figure}
   277 Figure~\ref{fig:Characteristic} shows characteristic examples
   278 that should give an intuitive understanding of the above functions.
   279 *}
   280 
   281 text{* The following simple sort functions are intended for proofs,
   282 not for efficient implementations. *}
   283 
   284 context linorder
   285 begin
   286 
   287 inductive sorted :: "'a list \<Rightarrow> bool" where
   288   Nil [iff]: "sorted []"
   289 | Cons: "\<forall>y\<in>set xs. x \<le> y \<Longrightarrow> sorted xs \<Longrightarrow> sorted (x # xs)"
   290 
   291 lemma sorted_single [iff]:
   292   "sorted [x]"
   293   by (rule sorted.Cons) auto
   294 
   295 lemma sorted_many:
   296   "x \<le> y \<Longrightarrow> sorted (y # zs) \<Longrightarrow> sorted (x # y # zs)"
   297   by (rule sorted.Cons) (cases "y # zs" rule: sorted.cases, auto)
   298 
   299 lemma sorted_many_eq [simp, code]:
   300   "sorted (x # y # zs) \<longleftrightarrow> x \<le> y \<and> sorted (y # zs)"
   301   by (auto intro: sorted_many elim: sorted.cases)
   302 
   303 lemma [code]:
   304   "sorted [] \<longleftrightarrow> True"
   305   "sorted [x] \<longleftrightarrow> True"
   306   by simp_all
   307 
   308 primrec insort_key :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b \<Rightarrow> 'b list \<Rightarrow> 'b list" where
   309   "insort_key f x [] = [x]" |
   310   "insort_key f x (y#ys) = (if f x \<le> f y then (x#y#ys) else y#(insort_key f x ys))"
   311 
   312 definition sort_key :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b list \<Rightarrow> 'b list" where
   313   "sort_key f xs = foldr (insort_key f) xs []"
   314 
   315 definition insort_insert_key :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b \<Rightarrow> 'b list \<Rightarrow> 'b list" where
   316   "insort_insert_key f x xs = (if f x \<in> f ` set xs then xs else insort_key f x xs)"
   317 
   318 abbreviation "sort \<equiv> sort_key (\<lambda>x. x)"
   319 abbreviation "insort \<equiv> insort_key (\<lambda>x. x)"
   320 abbreviation "insort_insert \<equiv> insort_insert_key (\<lambda>x. x)"
   321 
   322 end
   323 
   324 
   325 subsubsection {* List comprehension *}
   326 
   327 text{* Input syntax for Haskell-like list comprehension notation.
   328 Typical example: @{text"[(x,y). x \<leftarrow> xs, y \<leftarrow> ys, x \<noteq> y]"},
   329 the list of all pairs of distinct elements from @{text xs} and @{text ys}.
   330 The syntax is as in Haskell, except that @{text"|"} becomes a dot
   331 (like in Isabelle's set comprehension): @{text"[e. x \<leftarrow> xs, \<dots>]"} rather than
   332 \verb![e| x <- xs, ...]!.
   333 
   334 The qualifiers after the dot are
   335 \begin{description}
   336 \item[generators] @{text"p \<leftarrow> xs"},
   337  where @{text p} is a pattern and @{text xs} an expression of list type, or
   338 \item[guards] @{text"b"}, where @{text b} is a boolean expression.
   339 %\item[local bindings] @ {text"let x = e"}.
   340 \end{description}
   341 
   342 Just like in Haskell, list comprehension is just a shorthand. To avoid
   343 misunderstandings, the translation into desugared form is not reversed
   344 upon output. Note that the translation of @{text"[e. x \<leftarrow> xs]"} is
   345 optmized to @{term"map (%x. e) xs"}.
   346 
   347 It is easy to write short list comprehensions which stand for complex
   348 expressions. During proofs, they may become unreadable (and
   349 mangled). In such cases it can be advisable to introduce separate
   350 definitions for the list comprehensions in question.  *}
   351 
   352 nonterminal lc_qual and lc_quals
   353 
   354 syntax
   355   "_listcompr" :: "'a \<Rightarrow> lc_qual \<Rightarrow> lc_quals \<Rightarrow> 'a list"  ("[_ . __")
   356   "_lc_gen" :: "'a \<Rightarrow> 'a list \<Rightarrow> lc_qual"  ("_ <- _")
   357   "_lc_test" :: "bool \<Rightarrow> lc_qual" ("_")
   358   (*"_lc_let" :: "letbinds => lc_qual"  ("let _")*)
   359   "_lc_end" :: "lc_quals" ("]")
   360   "_lc_quals" :: "lc_qual \<Rightarrow> lc_quals \<Rightarrow> lc_quals"  (", __")
   361   "_lc_abs" :: "'a => 'b list => 'b list"
   362 
   363 (* These are easier than ML code but cannot express the optimized
   364    translation of [e. p<-xs]
   365 translations
   366   "[e. p<-xs]" => "concat(map (_lc_abs p [e]) xs)"
   367   "_listcompr e (_lc_gen p xs) (_lc_quals Q Qs)"
   368    => "concat (map (_lc_abs p (_listcompr e Q Qs)) xs)"
   369   "[e. P]" => "if P then [e] else []"
   370   "_listcompr e (_lc_test P) (_lc_quals Q Qs)"
   371    => "if P then (_listcompr e Q Qs) else []"
   372   "_listcompr e (_lc_let b) (_lc_quals Q Qs)"
   373    => "_Let b (_listcompr e Q Qs)"
   374 *)
   375 
   376 syntax (xsymbols)
   377   "_lc_gen" :: "'a \<Rightarrow> 'a list \<Rightarrow> lc_qual"  ("_ \<leftarrow> _")
   378 syntax (HTML output)
   379   "_lc_gen" :: "'a \<Rightarrow> 'a list \<Rightarrow> lc_qual"  ("_ \<leftarrow> _")
   380 
   381 parse_translation (advanced) {*
   382   let
   383     val NilC = Syntax.const @{const_syntax Nil};
   384     val ConsC = Syntax.const @{const_syntax Cons};
   385     val mapC = Syntax.const @{const_syntax map};
   386     val concatC = Syntax.const @{const_syntax concat};
   387     val IfC = Syntax.const @{const_syntax If};
   388 
   389     fun single x = ConsC $ x $ NilC;
   390 
   391     fun pat_tr ctxt p e opti = (* %x. case x of p => e | _ => [] *)
   392       let
   393         (* FIXME proper name context!? *)
   394         val x =
   395           Free (singleton (Name.variant_list (fold Term.add_free_names [p, e] [])) "x", dummyT);
   396         val e = if opti then single e else e;
   397         val case1 = Syntax.const @{syntax_const "_case1"} $ p $ e;
   398         val case2 =
   399           Syntax.const @{syntax_const "_case1"} $
   400             Syntax.const @{const_syntax dummy_pattern} $ NilC;
   401         val cs = Syntax.const @{syntax_const "_case2"} $ case1 $ case2;
   402       in Syntax_Trans.abs_tr [x, Datatype_Case.case_tr false ctxt [x, cs]] end;
   403 
   404     fun abs_tr ctxt p e opti =
   405       (case Term_Position.strip_positions p of
   406         Free (s, T) =>
   407           let
   408             val thy = Proof_Context.theory_of ctxt;
   409             val s' = Proof_Context.intern_const ctxt s;
   410           in
   411             if Sign.declared_const thy s'
   412             then (pat_tr ctxt p e opti, false)
   413             else (Syntax_Trans.abs_tr [p, e], true)
   414           end
   415       | _ => (pat_tr ctxt p e opti, false));
   416 
   417     fun lc_tr ctxt [e, Const (@{syntax_const "_lc_test"}, _) $ b, qs] =
   418           let
   419             val res =
   420               (case qs of
   421                 Const (@{syntax_const "_lc_end"}, _) => single e
   422               | Const (@{syntax_const "_lc_quals"}, _) $ q $ qs => lc_tr ctxt [e, q, qs]);
   423           in IfC $ b $ res $ NilC end
   424       | lc_tr ctxt
   425             [e, Const (@{syntax_const "_lc_gen"}, _) $ p $ es,
   426               Const(@{syntax_const "_lc_end"}, _)] =
   427           (case abs_tr ctxt p e true of
   428             (f, true) => mapC $ f $ es
   429           | (f, false) => concatC $ (mapC $ f $ es))
   430       | lc_tr ctxt
   431             [e, Const (@{syntax_const "_lc_gen"}, _) $ p $ es,
   432               Const (@{syntax_const "_lc_quals"}, _) $ q $ qs] =
   433           let val e' = lc_tr ctxt [e, q, qs];
   434           in concatC $ (mapC $ (fst (abs_tr ctxt p e' false)) $ es) end;
   435 
   436   in [(@{syntax_const "_listcompr"}, lc_tr)] end
   437 *}
   438 
   439 ML {*
   440   let
   441     val read = Syntax.read_term @{context};
   442     fun check s1 s2 = read s1 aconv read s2 orelse error ("Check failed: " ^ quote s1);
   443   in
   444     check "[(x,y,z). b]" "if b then [(x, y, z)] else []";
   445     check "[(x,y,z). x\<leftarrow>xs]" "map (\<lambda>x. (x, y, z)) xs";
   446     check "[e x y. x\<leftarrow>xs, y\<leftarrow>ys]" "concat (map (\<lambda>x. map (\<lambda>y. e x y) ys) xs)";
   447     check "[(x,y,z). x<a, x>b]" "if x < a then if b < x then [(x, y, z)] else [] else []";
   448     check "[(x,y,z). x\<leftarrow>xs, x>b]" "concat (map (\<lambda>x. if b < x then [(x, y, z)] else []) xs)";
   449     check "[(x,y,z). x<a, x\<leftarrow>xs]" "if x < a then map (\<lambda>x. (x, y, z)) xs else []";
   450     check "[(x,y). Cons True x \<leftarrow> xs]"
   451       "concat (map (\<lambda>xa. case xa of [] \<Rightarrow> [] | True # x \<Rightarrow> [(x, y)] | False # x \<Rightarrow> []) xs)";
   452     check "[(x,y,z). Cons x [] \<leftarrow> xs]"
   453       "concat (map (\<lambda>xa. case xa of [] \<Rightarrow> [] | [x] \<Rightarrow> [(x, y, z)] | x # aa # lista \<Rightarrow> []) xs)";
   454     check "[(x,y,z). x<a, x>b, x=d]"
   455       "if x < a then if b < x then if x = d then [(x, y, z)] else [] else [] else []";
   456     check "[(x,y,z). x<a, x>b, y\<leftarrow>ys]"
   457       "if x < a then if b < x then map (\<lambda>y. (x, y, z)) ys else [] else []";
   458     check "[(x,y,z). x<a, x\<leftarrow>xs,y>b]"
   459       "if x < a then concat (map (\<lambda>x. if b < y then [(x, y, z)] else []) xs) else []";
   460     check "[(x,y,z). x<a, x\<leftarrow>xs, y\<leftarrow>ys]"
   461       "if x < a then concat (map (\<lambda>x. map (\<lambda>y. (x, y, z)) ys) xs) else []";
   462     check "[(x,y,z). x\<leftarrow>xs, x>b, y<a]"
   463       "concat (map (\<lambda>x. if b < x then if y < a then [(x, y, z)] else [] else []) xs)";
   464     check "[(x,y,z). x\<leftarrow>xs, x>b, y\<leftarrow>ys]"
   465       "concat (map (\<lambda>x. if b < x then map (\<lambda>y. (x, y, z)) ys else []) xs)";
   466     check "[(x,y,z). x\<leftarrow>xs, y\<leftarrow>ys,y>x]"
   467       "concat (map (\<lambda>x. concat (map (\<lambda>y. if x < y then [(x, y, z)] else []) ys)) xs)";
   468     check "[(x,y,z). x\<leftarrow>xs, y\<leftarrow>ys,z\<leftarrow>zs]"
   469       "concat (map (\<lambda>x. concat (map (\<lambda>y. map (\<lambda>z. (x, y, z)) zs) ys)) xs)"
   470   end;
   471 *}
   472 
   473 (*
   474 term "[(x,y). x\<leftarrow>xs, let xx = x+x, y\<leftarrow>ys, y \<noteq> xx]"
   475 *)
   476 
   477 
   478 use "Tools/list_to_set_comprehension.ML"
   479 
   480 simproc_setup list_to_set_comprehension ("set xs") = {* K List_to_Set_Comprehension.simproc *}
   481 
   482 code_datatype set coset
   483 
   484 hide_const (open) coset
   485 
   486 subsubsection {* @{const Nil} and @{const Cons} *}
   487 
   488 lemma not_Cons_self [simp]:
   489   "xs \<noteq> x # xs"
   490 by (induct xs) auto
   491 
   492 lemma not_Cons_self2 [simp]:
   493   "x # xs \<noteq> xs"
   494 by (rule not_Cons_self [symmetric])
   495 
   496 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   497 by (induct xs) auto
   498 
   499 lemma length_induct:
   500   "(\<And>xs. \<forall>ys. length ys < length xs \<longrightarrow> P ys \<Longrightarrow> P xs) \<Longrightarrow> P xs"
   501 by (rule measure_induct [of length]) iprover
   502 
   503 lemma list_nonempty_induct [consumes 1, case_names single cons]:
   504   assumes "xs \<noteq> []"
   505   assumes single: "\<And>x. P [x]"
   506   assumes cons: "\<And>x xs. xs \<noteq> [] \<Longrightarrow> P xs \<Longrightarrow> P (x # xs)"
   507   shows "P xs"
   508 using `xs \<noteq> []` proof (induct xs)
   509   case Nil then show ?case by simp
   510 next
   511   case (Cons x xs) show ?case proof (cases xs)
   512     case Nil with single show ?thesis by simp
   513   next
   514     case Cons then have "xs \<noteq> []" by simp
   515     moreover with Cons.hyps have "P xs" .
   516     ultimately show ?thesis by (rule cons)
   517   qed
   518 qed
   519 
   520 lemma inj_split_Cons: "inj_on (\<lambda>(xs, n). n#xs) X"
   521   by (auto intro!: inj_onI)
   522 
   523 subsubsection {* @{const length} *}
   524 
   525 text {*
   526   Needs to come before @{text "@"} because of theorem @{text
   527   append_eq_append_conv}.
   528 *}
   529 
   530 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   531 by (induct xs) auto
   532 
   533 lemma length_map [simp]: "length (map f xs) = length xs"
   534 by (induct xs) auto
   535 
   536 lemma length_rev [simp]: "length (rev xs) = length xs"
   537 by (induct xs) auto
   538 
   539 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   540 by (cases xs) auto
   541 
   542 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   543 by (induct xs) auto
   544 
   545 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   546 by (induct xs) auto
   547 
   548 lemma length_pos_if_in_set: "x : set xs \<Longrightarrow> length xs > 0"
   549 by auto
   550 
   551 lemma length_Suc_conv:
   552 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   553 by (induct xs) auto
   554 
   555 lemma Suc_length_conv:
   556 "(Suc n = length xs) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   557 apply (induct xs, simp, simp)
   558 apply blast
   559 done
   560 
   561 lemma impossible_Cons: "length xs <= length ys ==> xs = x # ys = False"
   562   by (induct xs) auto
   563 
   564 lemma list_induct2 [consumes 1, case_names Nil Cons]:
   565   "length xs = length ys \<Longrightarrow> P [] [] \<Longrightarrow>
   566    (\<And>x xs y ys. length xs = length ys \<Longrightarrow> P xs ys \<Longrightarrow> P (x#xs) (y#ys))
   567    \<Longrightarrow> P xs ys"
   568 proof (induct xs arbitrary: ys)
   569   case Nil then show ?case by simp
   570 next
   571   case (Cons x xs ys) then show ?case by (cases ys) simp_all
   572 qed
   573 
   574 lemma list_induct3 [consumes 2, case_names Nil Cons]:
   575   "length xs = length ys \<Longrightarrow> length ys = length zs \<Longrightarrow> P [] [] [] \<Longrightarrow>
   576    (\<And>x xs y ys z zs. length xs = length ys \<Longrightarrow> length ys = length zs \<Longrightarrow> P xs ys zs \<Longrightarrow> P (x#xs) (y#ys) (z#zs))
   577    \<Longrightarrow> P xs ys zs"
   578 proof (induct xs arbitrary: ys zs)
   579   case Nil then show ?case by simp
   580 next
   581   case (Cons x xs ys zs) then show ?case by (cases ys, simp_all)
   582     (cases zs, simp_all)
   583 qed
   584 
   585 lemma list_induct4 [consumes 3, case_names Nil Cons]:
   586   "length xs = length ys \<Longrightarrow> length ys = length zs \<Longrightarrow> length zs = length ws \<Longrightarrow>
   587    P [] [] [] [] \<Longrightarrow> (\<And>x xs y ys z zs w ws. length xs = length ys \<Longrightarrow>
   588    length ys = length zs \<Longrightarrow> length zs = length ws \<Longrightarrow> P xs ys zs ws \<Longrightarrow>
   589    P (x#xs) (y#ys) (z#zs) (w#ws)) \<Longrightarrow> P xs ys zs ws"
   590 proof (induct xs arbitrary: ys zs ws)
   591   case Nil then show ?case by simp
   592 next
   593   case (Cons x xs ys zs ws) then show ?case by ((cases ys, simp_all), (cases zs,simp_all)) (cases ws, simp_all)
   594 qed
   595 
   596 lemma list_induct2': 
   597   "\<lbrakk> P [] [];
   598   \<And>x xs. P (x#xs) [];
   599   \<And>y ys. P [] (y#ys);
   600    \<And>x xs y ys. P xs ys  \<Longrightarrow> P (x#xs) (y#ys) \<rbrakk>
   601  \<Longrightarrow> P xs ys"
   602 by (induct xs arbitrary: ys) (case_tac x, auto)+
   603 
   604 lemma neq_if_length_neq: "length xs \<noteq> length ys \<Longrightarrow> (xs = ys) == False"
   605 by (rule Eq_FalseI) auto
   606 
   607 simproc_setup list_neq ("(xs::'a list) = ys") = {*
   608 (*
   609 Reduces xs=ys to False if xs and ys cannot be of the same length.
   610 This is the case if the atomic sublists of one are a submultiset
   611 of those of the other list and there are fewer Cons's in one than the other.
   612 *)
   613 
   614 let
   615 
   616 fun len (Const(@{const_name Nil},_)) acc = acc
   617   | len (Const(@{const_name Cons},_) $ _ $ xs) (ts,n) = len xs (ts,n+1)
   618   | len (Const(@{const_name append},_) $ xs $ ys) acc = len xs (len ys acc)
   619   | len (Const(@{const_name rev},_) $ xs) acc = len xs acc
   620   | len (Const(@{const_name map},_) $ _ $ xs) acc = len xs acc
   621   | len t (ts,n) = (t::ts,n);
   622 
   623 fun list_neq _ ss ct =
   624   let
   625     val (Const(_,eqT) $ lhs $ rhs) = Thm.term_of ct;
   626     val (ls,m) = len lhs ([],0) and (rs,n) = len rhs ([],0);
   627     fun prove_neq() =
   628       let
   629         val Type(_,listT::_) = eqT;
   630         val size = HOLogic.size_const listT;
   631         val eq_len = HOLogic.mk_eq (size $ lhs, size $ rhs);
   632         val neq_len = HOLogic.mk_Trueprop (HOLogic.Not $ eq_len);
   633         val thm = Goal.prove (Simplifier.the_context ss) [] [] neq_len
   634           (K (simp_tac (Simplifier.inherit_context ss @{simpset}) 1));
   635       in SOME (thm RS @{thm neq_if_length_neq}) end
   636   in
   637     if m < n andalso submultiset (op aconv) (ls,rs) orelse
   638        n < m andalso submultiset (op aconv) (rs,ls)
   639     then prove_neq() else NONE
   640   end;
   641 in list_neq end;
   642 *}
   643 
   644 
   645 subsubsection {* @{text "@"} -- append *}
   646 
   647 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   648 by (induct xs) auto
   649 
   650 lemma append_Nil2 [simp]: "xs @ [] = xs"
   651 by (induct xs) auto
   652 
   653 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   654 by (induct xs) auto
   655 
   656 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   657 by (induct xs) auto
   658 
   659 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   660 by (induct xs) auto
   661 
   662 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   663 by (induct xs) auto
   664 
   665 lemma append_eq_append_conv [simp, no_atp]:
   666  "length xs = length ys \<or> length us = length vs
   667  ==> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   668 apply (induct xs arbitrary: ys)
   669  apply (case_tac ys, simp, force)
   670 apply (case_tac ys, force, simp)
   671 done
   672 
   673 lemma append_eq_append_conv2: "(xs @ ys = zs @ ts) =
   674   (EX us. xs = zs @ us & us @ ys = ts | xs @ us = zs & ys = us@ ts)"
   675 apply (induct xs arbitrary: ys zs ts)
   676  apply fastforce
   677 apply(case_tac zs)
   678  apply simp
   679 apply fastforce
   680 done
   681 
   682 lemma same_append_eq [iff, induct_simp]: "(xs @ ys = xs @ zs) = (ys = zs)"
   683 by simp
   684 
   685 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   686 by simp
   687 
   688 lemma append_same_eq [iff, induct_simp]: "(ys @ xs = zs @ xs) = (ys = zs)"
   689 by simp
   690 
   691 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   692 using append_same_eq [of _ _ "[]"] by auto
   693 
   694 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   695 using append_same_eq [of "[]"] by auto
   696 
   697 lemma hd_Cons_tl [simp,no_atp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   698 by (induct xs) auto
   699 
   700 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   701 by (induct xs) auto
   702 
   703 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   704 by (simp add: hd_append split: list.split)
   705 
   706 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   707 by (simp split: list.split)
   708 
   709 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   710 by (simp add: tl_append split: list.split)
   711 
   712 
   713 lemma Cons_eq_append_conv: "x#xs = ys@zs =
   714  (ys = [] & x#xs = zs | (EX ys'. x#ys' = ys & xs = ys'@zs))"
   715 by(cases ys) auto
   716 
   717 lemma append_eq_Cons_conv: "(ys@zs = x#xs) =
   718  (ys = [] & zs = x#xs | (EX ys'. ys = x#ys' & ys'@zs = xs))"
   719 by(cases ys) auto
   720 
   721 
   722 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   723 
   724 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   725 by simp
   726 
   727 lemma Cons_eq_appendI:
   728 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   729 by (drule sym) simp
   730 
   731 lemma append_eq_appendI:
   732 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   733 by (drule sym) simp
   734 
   735 
   736 text {*
   737 Simplification procedure for all list equalities.
   738 Currently only tries to rearrange @{text "@"} to see if
   739 - both lists end in a singleton list,
   740 - or both lists end in the same list.
   741 *}
   742 
   743 simproc_setup list_eq ("(xs::'a list) = ys")  = {*
   744   let
   745     fun last (cons as Const (@{const_name Cons}, _) $ _ $ xs) =
   746           (case xs of Const (@{const_name Nil}, _) => cons | _ => last xs)
   747       | last (Const(@{const_name append},_) $ _ $ ys) = last ys
   748       | last t = t;
   749     
   750     fun list1 (Const(@{const_name Cons},_) $ _ $ Const(@{const_name Nil},_)) = true
   751       | list1 _ = false;
   752     
   753     fun butlast ((cons as Const(@{const_name Cons},_) $ x) $ xs) =
   754           (case xs of Const (@{const_name Nil}, _) => xs | _ => cons $ butlast xs)
   755       | butlast ((app as Const (@{const_name append}, _) $ xs) $ ys) = app $ butlast ys
   756       | butlast xs = Const(@{const_name Nil}, fastype_of xs);
   757     
   758     val rearr_ss =
   759       HOL_basic_ss addsimps [@{thm append_assoc}, @{thm append_Nil}, @{thm append_Cons}];
   760     
   761     fun list_eq ss (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   762       let
   763         val lastl = last lhs and lastr = last rhs;
   764         fun rearr conv =
   765           let
   766             val lhs1 = butlast lhs and rhs1 = butlast rhs;
   767             val Type(_,listT::_) = eqT
   768             val appT = [listT,listT] ---> listT
   769             val app = Const(@{const_name append},appT)
   770             val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   771             val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (F,F2));
   772             val thm = Goal.prove (Simplifier.the_context ss) [] [] eq
   773               (K (simp_tac (Simplifier.inherit_context ss rearr_ss) 1));
   774           in SOME ((conv RS (thm RS trans)) RS eq_reflection) end;
   775       in
   776         if list1 lastl andalso list1 lastr then rearr @{thm append1_eq_conv}
   777         else if lastl aconv lastr then rearr @{thm append_same_eq}
   778         else NONE
   779       end;
   780   in fn _ => fn ss => fn ct => list_eq ss (term_of ct) end;
   781 *}
   782 
   783 
   784 subsubsection {* @{text map} *}
   785 
   786 lemma hd_map:
   787   "xs \<noteq> [] \<Longrightarrow> hd (map f xs) = f (hd xs)"
   788   by (cases xs) simp_all
   789 
   790 lemma map_tl:
   791   "map f (tl xs) = tl (map f xs)"
   792   by (cases xs) simp_all
   793 
   794 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   795 by (induct xs) simp_all
   796 
   797 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   798 by (rule ext, induct_tac xs) auto
   799 
   800 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   801 by (induct xs) auto
   802 
   803 lemma map_map [simp]: "map f (map g xs) = map (f \<circ> g) xs"
   804 by (induct xs) auto
   805 
   806 lemma map_comp_map[simp]: "((map f) o (map g)) = map(f o g)"
   807 apply(rule ext)
   808 apply(simp)
   809 done
   810 
   811 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   812 by (induct xs) auto
   813 
   814 lemma map_eq_conv[simp]: "(map f xs = map g xs) = (!x : set xs. f x = g x)"
   815 by (induct xs) auto
   816 
   817 lemma map_cong [fundef_cong]:
   818   "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> f x = g x) \<Longrightarrow> map f xs = map g ys"
   819   by simp
   820 
   821 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   822 by (cases xs) auto
   823 
   824 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   825 by (cases xs) auto
   826 
   827 lemma map_eq_Cons_conv:
   828  "(map f xs = y#ys) = (\<exists>z zs. xs = z#zs \<and> f z = y \<and> map f zs = ys)"
   829 by (cases xs) auto
   830 
   831 lemma Cons_eq_map_conv:
   832  "(x#xs = map f ys) = (\<exists>z zs. ys = z#zs \<and> x = f z \<and> xs = map f zs)"
   833 by (cases ys) auto
   834 
   835 lemmas map_eq_Cons_D = map_eq_Cons_conv [THEN iffD1]
   836 lemmas Cons_eq_map_D = Cons_eq_map_conv [THEN iffD1]
   837 declare map_eq_Cons_D [dest!]  Cons_eq_map_D [dest!]
   838 
   839 lemma ex_map_conv:
   840   "(EX xs. ys = map f xs) = (ALL y : set ys. EX x. y = f x)"
   841 by(induct ys, auto simp add: Cons_eq_map_conv)
   842 
   843 lemma map_eq_imp_length_eq:
   844   assumes "map f xs = map g ys"
   845   shows "length xs = length ys"
   846 using assms proof (induct ys arbitrary: xs)
   847   case Nil then show ?case by simp
   848 next
   849   case (Cons y ys) then obtain z zs where xs: "xs = z # zs" by auto
   850   from Cons xs have "map f zs = map g ys" by simp
   851   moreover with Cons have "length zs = length ys" by blast
   852   with xs show ?case by simp
   853 qed
   854   
   855 lemma map_inj_on:
   856  "[| map f xs = map f ys; inj_on f (set xs Un set ys) |]
   857   ==> xs = ys"
   858 apply(frule map_eq_imp_length_eq)
   859 apply(rotate_tac -1)
   860 apply(induct rule:list_induct2)
   861  apply simp
   862 apply(simp)
   863 apply (blast intro:sym)
   864 done
   865 
   866 lemma inj_on_map_eq_map:
   867  "inj_on f (set xs Un set ys) \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   868 by(blast dest:map_inj_on)
   869 
   870 lemma map_injective:
   871  "map f xs = map f ys ==> inj f ==> xs = ys"
   872 by (induct ys arbitrary: xs) (auto dest!:injD)
   873 
   874 lemma inj_map_eq_map[simp]: "inj f \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   875 by(blast dest:map_injective)
   876 
   877 lemma inj_mapI: "inj f ==> inj (map f)"
   878 by (iprover dest: map_injective injD intro: inj_onI)
   879 
   880 lemma inj_mapD: "inj (map f) ==> inj f"
   881 apply (unfold inj_on_def, clarify)
   882 apply (erule_tac x = "[x]" in ballE)
   883  apply (erule_tac x = "[y]" in ballE, simp, blast)
   884 apply blast
   885 done
   886 
   887 lemma inj_map[iff]: "inj (map f) = inj f"
   888 by (blast dest: inj_mapD intro: inj_mapI)
   889 
   890 lemma inj_on_mapI: "inj_on f (\<Union>(set ` A)) \<Longrightarrow> inj_on (map f) A"
   891 apply(rule inj_onI)
   892 apply(erule map_inj_on)
   893 apply(blast intro:inj_onI dest:inj_onD)
   894 done
   895 
   896 lemma map_idI: "(\<And>x. x \<in> set xs \<Longrightarrow> f x = x) \<Longrightarrow> map f xs = xs"
   897 by (induct xs, auto)
   898 
   899 lemma map_fun_upd [simp]: "y \<notin> set xs \<Longrightarrow> map (f(y:=v)) xs = map f xs"
   900 by (induct xs) auto
   901 
   902 lemma map_fst_zip[simp]:
   903   "length xs = length ys \<Longrightarrow> map fst (zip xs ys) = xs"
   904 by (induct rule:list_induct2, simp_all)
   905 
   906 lemma map_snd_zip[simp]:
   907   "length xs = length ys \<Longrightarrow> map snd (zip xs ys) = ys"
   908 by (induct rule:list_induct2, simp_all)
   909 
   910 enriched_type map: map
   911   by (simp_all add: fun_eq_iff id_def)
   912 
   913 
   914 subsubsection {* @{text rev} *}
   915 
   916 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   917 by (induct xs) auto
   918 
   919 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   920 by (induct xs) auto
   921 
   922 lemma rev_swap: "(rev xs = ys) = (xs = rev ys)"
   923 by auto
   924 
   925 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   926 by (induct xs) auto
   927 
   928 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   929 by (induct xs) auto
   930 
   931 lemma rev_singleton_conv [simp]: "(rev xs = [x]) = (xs = [x])"
   932 by (cases xs) auto
   933 
   934 lemma singleton_rev_conv [simp]: "([x] = rev xs) = (xs = [x])"
   935 by (cases xs) auto
   936 
   937 lemma rev_is_rev_conv [iff, no_atp]: "(rev xs = rev ys) = (xs = ys)"
   938 apply (induct xs arbitrary: ys, force)
   939 apply (case_tac ys, simp, force)
   940 done
   941 
   942 lemma inj_on_rev[iff]: "inj_on rev A"
   943 by(simp add:inj_on_def)
   944 
   945 lemma rev_induct [case_names Nil snoc]:
   946   "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   947 apply(simplesubst rev_rev_ident[symmetric])
   948 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   949 done
   950 
   951 lemma rev_exhaust [case_names Nil snoc]:
   952   "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   953 by (induct xs rule: rev_induct) auto
   954 
   955 lemmas rev_cases = rev_exhaust
   956 
   957 lemma rev_eq_Cons_iff[iff]: "(rev xs = y#ys) = (xs = rev ys @ [y])"
   958 by(rule rev_cases[of xs]) auto
   959 
   960 
   961 subsubsection {* @{text set} *}
   962 
   963 lemma finite_set [iff]: "finite (set xs)"
   964 by (induct xs) auto
   965 
   966 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   967 by (induct xs) auto
   968 
   969 lemma hd_in_set[simp]: "xs \<noteq> [] \<Longrightarrow> hd xs : set xs"
   970 by(cases xs) auto
   971 
   972 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   973 by auto
   974 
   975 lemma set_ConsD: "y \<in> set (x # xs) \<Longrightarrow> y=x \<or> y \<in> set xs" 
   976 by auto
   977 
   978 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   979 by (induct xs) auto
   980 
   981 lemma set_empty2[iff]: "({} = set xs) = (xs = [])"
   982 by(induct xs) auto
   983 
   984 lemma set_rev [simp]: "set (rev xs) = set xs"
   985 by (induct xs) auto
   986 
   987 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   988 by (induct xs) auto
   989 
   990 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   991 by (induct xs) auto
   992 
   993 lemma set_upt [simp]: "set[i..<j] = {i..<j}"
   994 by (induct j) auto
   995 
   996 
   997 lemma split_list: "x : set xs \<Longrightarrow> \<exists>ys zs. xs = ys @ x # zs"
   998 proof (induct xs)
   999   case Nil thus ?case by simp
  1000 next
  1001   case Cons thus ?case by (auto intro: Cons_eq_appendI)
  1002 qed
  1003 
  1004 lemma in_set_conv_decomp: "x \<in> set xs \<longleftrightarrow> (\<exists>ys zs. xs = ys @ x # zs)"
  1005   by (auto elim: split_list)
  1006 
  1007 lemma split_list_first: "x : set xs \<Longrightarrow> \<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set ys"
  1008 proof (induct xs)
  1009   case Nil thus ?case by simp
  1010 next
  1011   case (Cons a xs)
  1012   show ?case
  1013   proof cases
  1014     assume "x = a" thus ?case using Cons by fastforce
  1015   next
  1016     assume "x \<noteq> a" thus ?case using Cons by(fastforce intro!: Cons_eq_appendI)
  1017   qed
  1018 qed
  1019 
  1020 lemma in_set_conv_decomp_first:
  1021   "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set ys)"
  1022   by (auto dest!: split_list_first)
  1023 
  1024 lemma split_list_last: "x \<in> set xs \<Longrightarrow> \<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set zs"
  1025 proof (induct xs rule: rev_induct)
  1026   case Nil thus ?case by simp
  1027 next
  1028   case (snoc a xs)
  1029   show ?case
  1030   proof cases
  1031     assume "x = a" thus ?case using snoc by (metis List.set.simps(1) emptyE)
  1032   next
  1033     assume "x \<noteq> a" thus ?case using snoc by fastforce
  1034   qed
  1035 qed
  1036 
  1037 lemma in_set_conv_decomp_last:
  1038   "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set zs)"
  1039   by (auto dest!: split_list_last)
  1040 
  1041 lemma split_list_prop: "\<exists>x \<in> set xs. P x \<Longrightarrow> \<exists>ys x zs. xs = ys @ x # zs & P x"
  1042 proof (induct xs)
  1043   case Nil thus ?case by simp
  1044 next
  1045   case Cons thus ?case
  1046     by(simp add:Bex_def)(metis append_Cons append.simps(1))
  1047 qed
  1048 
  1049 lemma split_list_propE:
  1050   assumes "\<exists>x \<in> set xs. P x"
  1051   obtains ys x zs where "xs = ys @ x # zs" and "P x"
  1052 using split_list_prop [OF assms] by blast
  1053 
  1054 lemma split_list_first_prop:
  1055   "\<exists>x \<in> set xs. P x \<Longrightarrow>
  1056    \<exists>ys x zs. xs = ys@x#zs \<and> P x \<and> (\<forall>y \<in> set ys. \<not> P y)"
  1057 proof (induct xs)
  1058   case Nil thus ?case by simp
  1059 next
  1060   case (Cons x xs)
  1061   show ?case
  1062   proof cases
  1063     assume "P x"
  1064     thus ?thesis by simp (metis Un_upper1 contra_subsetD in_set_conv_decomp_first self_append_conv2 set_append)
  1065   next
  1066     assume "\<not> P x"
  1067     hence "\<exists>x\<in>set xs. P x" using Cons(2) by simp
  1068     thus ?thesis using `\<not> P x` Cons(1) by (metis append_Cons set_ConsD)
  1069   qed
  1070 qed
  1071 
  1072 lemma split_list_first_propE:
  1073   assumes "\<exists>x \<in> set xs. P x"
  1074   obtains ys x zs where "xs = ys @ x # zs" and "P x" and "\<forall>y \<in> set ys. \<not> P y"
  1075 using split_list_first_prop [OF assms] by blast
  1076 
  1077 lemma split_list_first_prop_iff:
  1078   "(\<exists>x \<in> set xs. P x) \<longleftrightarrow>
  1079    (\<exists>ys x zs. xs = ys@x#zs \<and> P x \<and> (\<forall>y \<in> set ys. \<not> P y))"
  1080 by (rule, erule split_list_first_prop) auto
  1081 
  1082 lemma split_list_last_prop:
  1083   "\<exists>x \<in> set xs. P x \<Longrightarrow>
  1084    \<exists>ys x zs. xs = ys@x#zs \<and> P x \<and> (\<forall>z \<in> set zs. \<not> P z)"
  1085 proof(induct xs rule:rev_induct)
  1086   case Nil thus ?case by simp
  1087 next
  1088   case (snoc x xs)
  1089   show ?case
  1090   proof cases
  1091     assume "P x" thus ?thesis by (metis emptyE set_empty)
  1092   next
  1093     assume "\<not> P x"
  1094     hence "\<exists>x\<in>set xs. P x" using snoc(2) by simp
  1095     thus ?thesis using `\<not> P x` snoc(1) by fastforce
  1096   qed
  1097 qed
  1098 
  1099 lemma split_list_last_propE:
  1100   assumes "\<exists>x \<in> set xs. P x"
  1101   obtains ys x zs where "xs = ys @ x # zs" and "P x" and "\<forall>z \<in> set zs. \<not> P z"
  1102 using split_list_last_prop [OF assms] by blast
  1103 
  1104 lemma split_list_last_prop_iff:
  1105   "(\<exists>x \<in> set xs. P x) \<longleftrightarrow>
  1106    (\<exists>ys x zs. xs = ys@x#zs \<and> P x \<and> (\<forall>z \<in> set zs. \<not> P z))"
  1107 by (metis split_list_last_prop [where P=P] in_set_conv_decomp)
  1108 
  1109 lemma finite_list: "finite A ==> EX xs. set xs = A"
  1110   by (erule finite_induct)
  1111     (auto simp add: set.simps(2) [symmetric] simp del: set.simps(2))
  1112 
  1113 lemma card_length: "card (set xs) \<le> length xs"
  1114 by (induct xs) (auto simp add: card_insert_if)
  1115 
  1116 lemma set_minus_filter_out:
  1117   "set xs - {y} = set (filter (\<lambda>x. \<not> (x = y)) xs)"
  1118   by (induct xs) auto
  1119 
  1120 
  1121 subsubsection {* @{text filter} *}
  1122 
  1123 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
  1124 by (induct xs) auto
  1125 
  1126 lemma rev_filter: "rev (filter P xs) = filter P (rev xs)"
  1127 by (induct xs) simp_all
  1128 
  1129 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
  1130 by (induct xs) auto
  1131 
  1132 lemma length_filter_le [simp]: "length (filter P xs) \<le> length xs"
  1133 by (induct xs) (auto simp add: le_SucI)
  1134 
  1135 lemma sum_length_filter_compl:
  1136   "length(filter P xs) + length(filter (%x. ~P x) xs) = length xs"
  1137 by(induct xs) simp_all
  1138 
  1139 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
  1140 by (induct xs) auto
  1141 
  1142 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
  1143 by (induct xs) auto
  1144 
  1145 lemma filter_empty_conv: "(filter P xs = []) = (\<forall>x\<in>set xs. \<not> P x)" 
  1146 by (induct xs) simp_all
  1147 
  1148 lemma filter_id_conv: "(filter P xs = xs) = (\<forall>x\<in>set xs. P x)"
  1149 apply (induct xs)
  1150  apply auto
  1151 apply(cut_tac P=P and xs=xs in length_filter_le)
  1152 apply simp
  1153 done
  1154 
  1155 lemma filter_map:
  1156   "filter P (map f xs) = map f (filter (P o f) xs)"
  1157 by (induct xs) simp_all
  1158 
  1159 lemma length_filter_map[simp]:
  1160   "length (filter P (map f xs)) = length(filter (P o f) xs)"
  1161 by (simp add:filter_map)
  1162 
  1163 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
  1164 by auto
  1165 
  1166 lemma length_filter_less:
  1167   "\<lbrakk> x : set xs; ~ P x \<rbrakk> \<Longrightarrow> length(filter P xs) < length xs"
  1168 proof (induct xs)
  1169   case Nil thus ?case by simp
  1170 next
  1171   case (Cons x xs) thus ?case
  1172     apply (auto split:split_if_asm)
  1173     using length_filter_le[of P xs] apply arith
  1174   done
  1175 qed
  1176 
  1177 lemma length_filter_conv_card:
  1178  "length(filter p xs) = card{i. i < length xs & p(xs!i)}"
  1179 proof (induct xs)
  1180   case Nil thus ?case by simp
  1181 next
  1182   case (Cons x xs)
  1183   let ?S = "{i. i < length xs & p(xs!i)}"
  1184   have fin: "finite ?S" by(fast intro: bounded_nat_set_is_finite)
  1185   show ?case (is "?l = card ?S'")
  1186   proof (cases)
  1187     assume "p x"
  1188     hence eq: "?S' = insert 0 (Suc ` ?S)"
  1189       by(auto simp: image_def split:nat.split dest:gr0_implies_Suc)
  1190     have "length (filter p (x # xs)) = Suc(card ?S)"
  1191       using Cons `p x` by simp
  1192     also have "\<dots> = Suc(card(Suc ` ?S))" using fin
  1193       by (simp add: card_image)
  1194     also have "\<dots> = card ?S'" using eq fin
  1195       by (simp add:card_insert_if) (simp add:image_def)
  1196     finally show ?thesis .
  1197   next
  1198     assume "\<not> p x"
  1199     hence eq: "?S' = Suc ` ?S"
  1200       by(auto simp add: image_def split:nat.split elim:lessE)
  1201     have "length (filter p (x # xs)) = card ?S"
  1202       using Cons `\<not> p x` by simp
  1203     also have "\<dots> = card(Suc ` ?S)" using fin
  1204       by (simp add: card_image)
  1205     also have "\<dots> = card ?S'" using eq fin
  1206       by (simp add:card_insert_if)
  1207     finally show ?thesis .
  1208   qed
  1209 qed
  1210 
  1211 lemma Cons_eq_filterD:
  1212  "x#xs = filter P ys \<Longrightarrow>
  1213   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
  1214   (is "_ \<Longrightarrow> \<exists>us vs. ?P ys us vs")
  1215 proof(induct ys)
  1216   case Nil thus ?case by simp
  1217 next
  1218   case (Cons y ys)
  1219   show ?case (is "\<exists>x. ?Q x")
  1220   proof cases
  1221     assume Py: "P y"
  1222     show ?thesis
  1223     proof cases
  1224       assume "x = y"
  1225       with Py Cons.prems have "?Q []" by simp
  1226       then show ?thesis ..
  1227     next
  1228       assume "x \<noteq> y"
  1229       with Py Cons.prems show ?thesis by simp
  1230     qed
  1231   next
  1232     assume "\<not> P y"
  1233     with Cons obtain us vs where "?P (y#ys) (y#us) vs" by fastforce
  1234     then have "?Q (y#us)" by simp
  1235     then show ?thesis ..
  1236   qed
  1237 qed
  1238 
  1239 lemma filter_eq_ConsD:
  1240  "filter P ys = x#xs \<Longrightarrow>
  1241   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
  1242 by(rule Cons_eq_filterD) simp
  1243 
  1244 lemma filter_eq_Cons_iff:
  1245  "(filter P ys = x#xs) =
  1246   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
  1247 by(auto dest:filter_eq_ConsD)
  1248 
  1249 lemma Cons_eq_filter_iff:
  1250  "(x#xs = filter P ys) =
  1251   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
  1252 by(auto dest:Cons_eq_filterD)
  1253 
  1254 lemma filter_cong[fundef_cong]:
  1255  "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> P x = Q x) \<Longrightarrow> filter P xs = filter Q ys"
  1256 apply simp
  1257 apply(erule thin_rl)
  1258 by (induct ys) simp_all
  1259 
  1260 
  1261 subsubsection {* List partitioning *}
  1262 
  1263 primrec partition :: "('a \<Rightarrow> bool) \<Rightarrow>'a list \<Rightarrow> 'a list \<times> 'a list" where
  1264   "partition P [] = ([], [])"
  1265   | "partition P (x # xs) = 
  1266       (let (yes, no) = partition P xs
  1267       in if P x then (x # yes, no) else (yes, x # no))"
  1268 
  1269 lemma partition_filter1:
  1270     "fst (partition P xs) = filter P xs"
  1271 by (induct xs) (auto simp add: Let_def split_def)
  1272 
  1273 lemma partition_filter2:
  1274     "snd (partition P xs) = filter (Not o P) xs"
  1275 by (induct xs) (auto simp add: Let_def split_def)
  1276 
  1277 lemma partition_P:
  1278   assumes "partition P xs = (yes, no)"
  1279   shows "(\<forall>p \<in> set yes.  P p) \<and> (\<forall>p  \<in> set no. \<not> P p)"
  1280 proof -
  1281   from assms have "yes = fst (partition P xs)" and "no = snd (partition P xs)"
  1282     by simp_all
  1283   then show ?thesis by (simp_all add: partition_filter1 partition_filter2)
  1284 qed
  1285 
  1286 lemma partition_set:
  1287   assumes "partition P xs = (yes, no)"
  1288   shows "set yes \<union> set no = set xs"
  1289 proof -
  1290   from assms have "yes = fst (partition P xs)" and "no = snd (partition P xs)"
  1291     by simp_all
  1292   then show ?thesis by (auto simp add: partition_filter1 partition_filter2) 
  1293 qed
  1294 
  1295 lemma partition_filter_conv[simp]:
  1296   "partition f xs = (filter f xs,filter (Not o f) xs)"
  1297 unfolding partition_filter2[symmetric]
  1298 unfolding partition_filter1[symmetric] by simp
  1299 
  1300 declare partition.simps[simp del]
  1301 
  1302 
  1303 subsubsection {* @{text concat} *}
  1304 
  1305 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
  1306 by (induct xs) auto
  1307 
  1308 lemma concat_eq_Nil_conv [simp]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
  1309 by (induct xss) auto
  1310 
  1311 lemma Nil_eq_concat_conv [simp]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
  1312 by (induct xss) auto
  1313 
  1314 lemma set_concat [simp]: "set (concat xs) = (UN x:set xs. set x)"
  1315 by (induct xs) auto
  1316 
  1317 lemma concat_map_singleton[simp]: "concat(map (%x. [f x]) xs) = map f xs"
  1318 by (induct xs) auto
  1319 
  1320 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
  1321 by (induct xs) auto
  1322 
  1323 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
  1324 by (induct xs) auto
  1325 
  1326 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
  1327 by (induct xs) auto
  1328 
  1329 lemma concat_eq_concat_iff: "\<forall>(x, y) \<in> set (zip xs ys). length x = length y ==> length xs = length ys ==> (concat xs = concat ys) = (xs = ys)"
  1330 proof (induct xs arbitrary: ys)
  1331   case (Cons x xs ys)
  1332   thus ?case by (cases ys) auto
  1333 qed (auto)
  1334 
  1335 lemma concat_injective: "concat xs = concat ys ==> length xs = length ys ==> \<forall>(x, y) \<in> set (zip xs ys). length x = length y ==> xs = ys"
  1336 by (simp add: concat_eq_concat_iff)
  1337 
  1338 
  1339 subsubsection {* @{text nth} *}
  1340 
  1341 lemma nth_Cons_0 [simp, code]: "(x # xs)!0 = x"
  1342 by auto
  1343 
  1344 lemma nth_Cons_Suc [simp, code]: "(x # xs)!(Suc n) = xs!n"
  1345 by auto
  1346 
  1347 declare nth.simps [simp del]
  1348 
  1349 lemma nth_Cons_pos[simp]: "0 < n \<Longrightarrow> (x#xs) ! n = xs ! (n - 1)"
  1350 by(auto simp: Nat.gr0_conv_Suc)
  1351 
  1352 lemma nth_append:
  1353   "(xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
  1354 apply (induct xs arbitrary: n, simp)
  1355 apply (case_tac n, auto)
  1356 done
  1357 
  1358 lemma nth_append_length [simp]: "(xs @ x # ys) ! length xs = x"
  1359 by (induct xs) auto
  1360 
  1361 lemma nth_append_length_plus[simp]: "(xs @ ys) ! (length xs + n) = ys ! n"
  1362 by (induct xs) auto
  1363 
  1364 lemma nth_map [simp]: "n < length xs ==> (map f xs)!n = f(xs!n)"
  1365 apply (induct xs arbitrary: n, simp)
  1366 apply (case_tac n, auto)
  1367 done
  1368 
  1369 lemma nth_tl:
  1370   assumes "n < length (tl x)" shows "tl x ! n = x ! Suc n"
  1371 using assms by (induct x) auto
  1372 
  1373 lemma hd_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd xs = xs!0"
  1374 by(cases xs) simp_all
  1375 
  1376 
  1377 lemma list_eq_iff_nth_eq:
  1378  "(xs = ys) = (length xs = length ys \<and> (ALL i<length xs. xs!i = ys!i))"
  1379 apply(induct xs arbitrary: ys)
  1380  apply force
  1381 apply(case_tac ys)
  1382  apply simp
  1383 apply(simp add:nth_Cons split:nat.split)apply blast
  1384 done
  1385 
  1386 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
  1387 apply (induct xs, simp, simp)
  1388 apply safe
  1389 apply (metis nat_case_0 nth.simps zero_less_Suc)
  1390 apply (metis less_Suc_eq_0_disj nth_Cons_Suc)
  1391 apply (case_tac i, simp)
  1392 apply (metis diff_Suc_Suc nat_case_Suc nth.simps zero_less_diff)
  1393 done
  1394 
  1395 lemma in_set_conv_nth: "(x \<in> set xs) = (\<exists>i < length xs. xs!i = x)"
  1396 by(auto simp:set_conv_nth)
  1397 
  1398 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
  1399 by (auto simp add: set_conv_nth)
  1400 
  1401 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
  1402 by (auto simp add: set_conv_nth)
  1403 
  1404 lemma all_nth_imp_all_set:
  1405 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
  1406 by (auto simp add: set_conv_nth)
  1407 
  1408 lemma all_set_conv_all_nth:
  1409 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
  1410 by (auto simp add: set_conv_nth)
  1411 
  1412 lemma rev_nth:
  1413   "n < size xs \<Longrightarrow> rev xs ! n = xs ! (length xs - Suc n)"
  1414 proof (induct xs arbitrary: n)
  1415   case Nil thus ?case by simp
  1416 next
  1417   case (Cons x xs)
  1418   hence n: "n < Suc (length xs)" by simp
  1419   moreover
  1420   { assume "n < length xs"
  1421     with n obtain n' where "length xs - n = Suc n'"
  1422       by (cases "length xs - n", auto)
  1423     moreover
  1424     then have "length xs - Suc n = n'" by simp
  1425     ultimately
  1426     have "xs ! (length xs - Suc n) = (x # xs) ! (length xs - n)" by simp
  1427   }
  1428   ultimately
  1429   show ?case by (clarsimp simp add: Cons nth_append)
  1430 qed
  1431 
  1432 lemma Skolem_list_nth:
  1433   "(ALL i<k. EX x. P i x) = (EX xs. size xs = k & (ALL i<k. P i (xs!i)))"
  1434   (is "_ = (EX xs. ?P k xs)")
  1435 proof(induct k)
  1436   case 0 show ?case by simp
  1437 next
  1438   case (Suc k)
  1439   show ?case (is "?L = ?R" is "_ = (EX xs. ?P' xs)")
  1440   proof
  1441     assume "?R" thus "?L" using Suc by auto
  1442   next
  1443     assume "?L"
  1444     with Suc obtain x xs where "?P k xs & P k x" by (metis less_Suc_eq)
  1445     hence "?P'(xs@[x])" by(simp add:nth_append less_Suc_eq)
  1446     thus "?R" ..
  1447   qed
  1448 qed
  1449 
  1450 
  1451 subsubsection {* @{text list_update} *}
  1452 
  1453 lemma length_list_update [simp]: "length(xs[i:=x]) = length xs"
  1454 by (induct xs arbitrary: i) (auto split: nat.split)
  1455 
  1456 lemma nth_list_update:
  1457 "i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
  1458 by (induct xs arbitrary: i j) (auto simp add: nth_Cons split: nat.split)
  1459 
  1460 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
  1461 by (simp add: nth_list_update)
  1462 
  1463 lemma nth_list_update_neq [simp]: "i \<noteq> j ==> xs[i:=x]!j = xs!j"
  1464 by (induct xs arbitrary: i j) (auto simp add: nth_Cons split: nat.split)
  1465 
  1466 lemma list_update_id[simp]: "xs[i := xs!i] = xs"
  1467 by (induct xs arbitrary: i) (simp_all split:nat.splits)
  1468 
  1469 lemma list_update_beyond[simp]: "length xs \<le> i \<Longrightarrow> xs[i:=x] = xs"
  1470 apply (induct xs arbitrary: i)
  1471  apply simp
  1472 apply (case_tac i)
  1473 apply simp_all
  1474 done
  1475 
  1476 lemma list_update_nonempty[simp]: "xs[k:=x] = [] \<longleftrightarrow> xs=[]"
  1477 by(metis length_0_conv length_list_update)
  1478 
  1479 lemma list_update_same_conv:
  1480 "i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
  1481 by (induct xs arbitrary: i) (auto split: nat.split)
  1482 
  1483 lemma list_update_append1:
  1484  "i < size xs \<Longrightarrow> (xs @ ys)[i:=x] = xs[i:=x] @ ys"
  1485 apply (induct xs arbitrary: i, simp)
  1486 apply(simp split:nat.split)
  1487 done
  1488 
  1489 lemma list_update_append:
  1490   "(xs @ ys) [n:= x] = 
  1491   (if n < length xs then xs[n:= x] @ ys else xs @ (ys [n-length xs:= x]))"
  1492 by (induct xs arbitrary: n) (auto split:nat.splits)
  1493 
  1494 lemma list_update_length [simp]:
  1495  "(xs @ x # ys)[length xs := y] = (xs @ y # ys)"
  1496 by (induct xs, auto)
  1497 
  1498 lemma map_update: "map f (xs[k:= y]) = (map f xs)[k := f y]"
  1499 by(induct xs arbitrary: k)(auto split:nat.splits)
  1500 
  1501 lemma rev_update:
  1502   "k < length xs \<Longrightarrow> rev (xs[k:= y]) = (rev xs)[length xs - k - 1 := y]"
  1503 by (induct xs arbitrary: k) (auto simp: list_update_append split:nat.splits)
  1504 
  1505 lemma update_zip:
  1506   "(zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
  1507 by (induct ys arbitrary: i xy xs) (auto, case_tac xs, auto split: nat.split)
  1508 
  1509 lemma set_update_subset_insert: "set(xs[i:=x]) <= insert x (set xs)"
  1510 by (induct xs arbitrary: i) (auto split: nat.split)
  1511 
  1512 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
  1513 by (blast dest!: set_update_subset_insert [THEN subsetD])
  1514 
  1515 lemma set_update_memI: "n < length xs \<Longrightarrow> x \<in> set (xs[n := x])"
  1516 by (induct xs arbitrary: n) (auto split:nat.splits)
  1517 
  1518 lemma list_update_overwrite[simp]:
  1519   "xs [i := x, i := y] = xs [i := y]"
  1520 apply (induct xs arbitrary: i) apply simp
  1521 apply (case_tac i, simp_all)
  1522 done
  1523 
  1524 lemma list_update_swap:
  1525   "i \<noteq> i' \<Longrightarrow> xs [i := x, i' := x'] = xs [i' := x', i := x]"
  1526 apply (induct xs arbitrary: i i')
  1527 apply simp
  1528 apply (case_tac i, case_tac i')
  1529 apply auto
  1530 apply (case_tac i')
  1531 apply auto
  1532 done
  1533 
  1534 lemma list_update_code [code]:
  1535   "[][i := y] = []"
  1536   "(x # xs)[0 := y] = y # xs"
  1537   "(x # xs)[Suc i := y] = x # xs[i := y]"
  1538   by simp_all
  1539 
  1540 
  1541 subsubsection {* @{text last} and @{text butlast} *}
  1542 
  1543 lemma last_snoc [simp]: "last (xs @ [x]) = x"
  1544 by (induct xs) auto
  1545 
  1546 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
  1547 by (induct xs) auto
  1548 
  1549 lemma last_ConsL: "xs = [] \<Longrightarrow> last(x#xs) = x"
  1550   by simp
  1551 
  1552 lemma last_ConsR: "xs \<noteq> [] \<Longrightarrow> last(x#xs) = last xs"
  1553   by simp
  1554 
  1555 lemma last_append: "last(xs @ ys) = (if ys = [] then last xs else last ys)"
  1556 by (induct xs) (auto)
  1557 
  1558 lemma last_appendL[simp]: "ys = [] \<Longrightarrow> last(xs @ ys) = last xs"
  1559 by(simp add:last_append)
  1560 
  1561 lemma last_appendR[simp]: "ys \<noteq> [] \<Longrightarrow> last(xs @ ys) = last ys"
  1562 by(simp add:last_append)
  1563 
  1564 lemma last_tl: "xs = [] \<or> tl xs \<noteq> [] \<Longrightarrow>last (tl xs) = last xs"
  1565 by (induct xs) simp_all
  1566 
  1567 lemma butlast_tl: "butlast (tl xs) = tl (butlast xs)"
  1568 by (induct xs) simp_all
  1569 
  1570 lemma hd_rev: "xs \<noteq> [] \<Longrightarrow> hd(rev xs) = last xs"
  1571 by(rule rev_exhaust[of xs]) simp_all
  1572 
  1573 lemma last_rev: "xs \<noteq> [] \<Longrightarrow> last(rev xs) = hd xs"
  1574 by(cases xs) simp_all
  1575 
  1576 lemma last_in_set[simp]: "as \<noteq> [] \<Longrightarrow> last as \<in> set as"
  1577 by (induct as) auto
  1578 
  1579 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
  1580 by (induct xs rule: rev_induct) auto
  1581 
  1582 lemma butlast_append:
  1583   "butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
  1584 by (induct xs arbitrary: ys) auto
  1585 
  1586 lemma append_butlast_last_id [simp]:
  1587 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
  1588 by (induct xs) auto
  1589 
  1590 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
  1591 by (induct xs) (auto split: split_if_asm)
  1592 
  1593 lemma in_set_butlast_appendI:
  1594 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
  1595 by (auto dest: in_set_butlastD simp add: butlast_append)
  1596 
  1597 lemma last_drop[simp]: "n < length xs \<Longrightarrow> last (drop n xs) = last xs"
  1598 apply (induct xs arbitrary: n)
  1599  apply simp
  1600 apply (auto split:nat.split)
  1601 done
  1602 
  1603 lemma nth_butlast:
  1604   assumes "n < length (butlast xs)" shows "butlast xs ! n = xs ! n"
  1605 proof (cases xs)
  1606   case (Cons y ys)
  1607   moreover from assms have "butlast xs ! n = (butlast xs @ [last xs]) ! n"
  1608     by (simp add: nth_append)
  1609   ultimately show ?thesis using append_butlast_last_id by simp
  1610 qed simp
  1611 
  1612 lemma last_conv_nth: "xs\<noteq>[] \<Longrightarrow> last xs = xs!(length xs - 1)"
  1613 by(induct xs)(auto simp:neq_Nil_conv)
  1614 
  1615 lemma butlast_conv_take: "butlast xs = take (length xs - 1) xs"
  1616 by (induct xs, simp, case_tac xs, simp_all)
  1617 
  1618 lemma last_list_update:
  1619   "xs \<noteq> [] \<Longrightarrow> last(xs[k:=x]) = (if k = size xs - 1 then x else last xs)"
  1620 by (auto simp: last_conv_nth)
  1621 
  1622 lemma butlast_list_update:
  1623   "butlast(xs[k:=x]) =
  1624  (if k = size xs - 1 then butlast xs else (butlast xs)[k:=x])"
  1625 apply(cases xs rule:rev_cases)
  1626 apply simp
  1627 apply(simp add:list_update_append split:nat.splits)
  1628 done
  1629 
  1630 lemma last_map:
  1631   "xs \<noteq> [] \<Longrightarrow> last (map f xs) = f (last xs)"
  1632   by (cases xs rule: rev_cases) simp_all
  1633 
  1634 lemma map_butlast:
  1635   "map f (butlast xs) = butlast (map f xs)"
  1636   by (induct xs) simp_all
  1637 
  1638 lemma snoc_eq_iff_butlast:
  1639   "xs @ [x] = ys \<longleftrightarrow> (ys \<noteq> [] & butlast ys = xs & last ys = x)"
  1640 by (metis append_butlast_last_id append_is_Nil_conv butlast_snoc last_snoc not_Cons_self)
  1641 
  1642 
  1643 subsubsection {* @{text take} and @{text drop} *}
  1644 
  1645 lemma take_0 [simp]: "take 0 xs = []"
  1646 by (induct xs) auto
  1647 
  1648 lemma drop_0 [simp]: "drop 0 xs = xs"
  1649 by (induct xs) auto
  1650 
  1651 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
  1652 by simp
  1653 
  1654 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
  1655 by simp
  1656 
  1657 declare take_Cons [simp del] and drop_Cons [simp del]
  1658 
  1659 lemma take_1_Cons [simp]: "take 1 (x # xs) = [x]"
  1660   unfolding One_nat_def by simp
  1661 
  1662 lemma drop_1_Cons [simp]: "drop 1 (x # xs) = xs"
  1663   unfolding One_nat_def by simp
  1664 
  1665 lemma take_Suc: "xs ~= [] ==> take (Suc n) xs = hd xs # take n (tl xs)"
  1666 by(clarsimp simp add:neq_Nil_conv)
  1667 
  1668 lemma drop_Suc: "drop (Suc n) xs = drop n (tl xs)"
  1669 by(cases xs, simp_all)
  1670 
  1671 lemma take_tl: "take n (tl xs) = tl (take (Suc n) xs)"
  1672 by (induct xs arbitrary: n) simp_all
  1673 
  1674 lemma drop_tl: "drop n (tl xs) = tl(drop n xs)"
  1675 by(induct xs arbitrary: n, simp_all add:drop_Cons drop_Suc split:nat.split)
  1676 
  1677 lemma tl_take: "tl (take n xs) = take (n - 1) (tl xs)"
  1678 by (cases n, simp, cases xs, auto)
  1679 
  1680 lemma tl_drop: "tl (drop n xs) = drop n (tl xs)"
  1681 by (simp only: drop_tl)
  1682 
  1683 lemma nth_via_drop: "drop n xs = y#ys \<Longrightarrow> xs!n = y"
  1684 apply (induct xs arbitrary: n, simp)
  1685 apply(simp add:drop_Cons nth_Cons split:nat.splits)
  1686 done
  1687 
  1688 lemma take_Suc_conv_app_nth:
  1689   "i < length xs \<Longrightarrow> take (Suc i) xs = take i xs @ [xs!i]"
  1690 apply (induct xs arbitrary: i, simp)
  1691 apply (case_tac i, auto)
  1692 done
  1693 
  1694 lemma drop_Suc_conv_tl:
  1695   "i < length xs \<Longrightarrow> (xs!i) # (drop (Suc i) xs) = drop i xs"
  1696 apply (induct xs arbitrary: i, simp)
  1697 apply (case_tac i, auto)
  1698 done
  1699 
  1700 lemma length_take [simp]: "length (take n xs) = min (length xs) n"
  1701 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1702 
  1703 lemma length_drop [simp]: "length (drop n xs) = (length xs - n)"
  1704 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1705 
  1706 lemma take_all [simp]: "length xs <= n ==> take n xs = xs"
  1707 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1708 
  1709 lemma drop_all [simp]: "length xs <= n ==> drop n xs = []"
  1710 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1711 
  1712 lemma take_append [simp]:
  1713   "take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
  1714 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1715 
  1716 lemma drop_append [simp]:
  1717   "drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
  1718 by (induct n arbitrary: xs) (auto, case_tac xs, auto)
  1719 
  1720 lemma take_take [simp]: "take n (take m xs) = take (min n m) xs"
  1721 apply (induct m arbitrary: xs n, auto)
  1722 apply (case_tac xs, auto)
  1723 apply (case_tac n, auto)
  1724 done
  1725 
  1726 lemma drop_drop [simp]: "drop n (drop m xs) = drop (n + m) xs"
  1727 apply (induct m arbitrary: xs, auto)
  1728 apply (case_tac xs, auto)
  1729 done
  1730 
  1731 lemma take_drop: "take n (drop m xs) = drop m (take (n + m) xs)"
  1732 apply (induct m arbitrary: xs n, auto)
  1733 apply (case_tac xs, auto)
  1734 done
  1735 
  1736 lemma drop_take: "drop n (take m xs) = take (m-n) (drop n xs)"
  1737 apply(induct xs arbitrary: m n)
  1738  apply simp
  1739 apply(simp add: take_Cons drop_Cons split:nat.split)
  1740 done
  1741 
  1742 lemma append_take_drop_id [simp]: "take n xs @ drop n xs = xs"
  1743 apply (induct n arbitrary: xs, auto)
  1744 apply (case_tac xs, auto)
  1745 done
  1746 
  1747 lemma take_eq_Nil[simp]: "(take n xs = []) = (n = 0 \<or> xs = [])"
  1748 apply(induct xs arbitrary: n)
  1749  apply simp
  1750 apply(simp add:take_Cons split:nat.split)
  1751 done
  1752 
  1753 lemma drop_eq_Nil[simp]: "(drop n xs = []) = (length xs <= n)"
  1754 apply(induct xs arbitrary: n)
  1755 apply simp
  1756 apply(simp add:drop_Cons split:nat.split)
  1757 done
  1758 
  1759 lemma take_map: "take n (map f xs) = map f (take n xs)"
  1760 apply (induct n arbitrary: xs, auto)
  1761 apply (case_tac xs, auto)
  1762 done
  1763 
  1764 lemma drop_map: "drop n (map f xs) = map f (drop n xs)"
  1765 apply (induct n arbitrary: xs, auto)
  1766 apply (case_tac xs, auto)
  1767 done
  1768 
  1769 lemma rev_take: "rev (take i xs) = drop (length xs - i) (rev xs)"
  1770 apply (induct xs arbitrary: i, auto)
  1771 apply (case_tac i, auto)
  1772 done
  1773 
  1774 lemma rev_drop: "rev (drop i xs) = take (length xs - i) (rev xs)"
  1775 apply (induct xs arbitrary: i, auto)
  1776 apply (case_tac i, auto)
  1777 done
  1778 
  1779 lemma nth_take [simp]: "i < n ==> (take n xs)!i = xs!i"
  1780 apply (induct xs arbitrary: i n, auto)
  1781 apply (case_tac n, blast)
  1782 apply (case_tac i, auto)
  1783 done
  1784 
  1785 lemma nth_drop [simp]:
  1786   "n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
  1787 apply (induct n arbitrary: xs i, auto)
  1788 apply (case_tac xs, auto)
  1789 done
  1790 
  1791 lemma butlast_take:
  1792   "n <= length xs ==> butlast (take n xs) = take (n - 1) xs"
  1793 by (simp add: butlast_conv_take min_max.inf_absorb1 min_max.inf_absorb2)
  1794 
  1795 lemma butlast_drop: "butlast (drop n xs) = drop n (butlast xs)"
  1796 by (simp add: butlast_conv_take drop_take add_ac)
  1797 
  1798 lemma take_butlast: "n < length xs ==> take n (butlast xs) = take n xs"
  1799 by (simp add: butlast_conv_take min_max.inf_absorb1)
  1800 
  1801 lemma drop_butlast: "drop n (butlast xs) = butlast (drop n xs)"
  1802 by (simp add: butlast_conv_take drop_take add_ac)
  1803 
  1804 lemma hd_drop_conv_nth: "n < length xs \<Longrightarrow> hd(drop n xs) = xs!n"
  1805 by(simp add: hd_conv_nth)
  1806 
  1807 lemma set_take_subset_set_take:
  1808   "m <= n \<Longrightarrow> set(take m xs) <= set(take n xs)"
  1809 apply (induct xs arbitrary: m n)
  1810 apply simp
  1811 apply (case_tac n)
  1812 apply (auto simp: take_Cons)
  1813 done
  1814 
  1815 lemma set_take_subset: "set(take n xs) \<subseteq> set xs"
  1816 by(induct xs arbitrary: n)(auto simp:take_Cons split:nat.split)
  1817 
  1818 lemma set_drop_subset: "set(drop n xs) \<subseteq> set xs"
  1819 by(induct xs arbitrary: n)(auto simp:drop_Cons split:nat.split)
  1820 
  1821 lemma set_drop_subset_set_drop:
  1822   "m >= n \<Longrightarrow> set(drop m xs) <= set(drop n xs)"
  1823 apply(induct xs arbitrary: m n)
  1824 apply(auto simp:drop_Cons split:nat.split)
  1825 apply (metis set_drop_subset subset_iff)
  1826 done
  1827 
  1828 lemma in_set_takeD: "x : set(take n xs) \<Longrightarrow> x : set xs"
  1829 using set_take_subset by fast
  1830 
  1831 lemma in_set_dropD: "x : set(drop n xs) \<Longrightarrow> x : set xs"
  1832 using set_drop_subset by fast
  1833 
  1834 lemma append_eq_conv_conj:
  1835   "(xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
  1836 apply (induct xs arbitrary: zs, simp, clarsimp)
  1837 apply (case_tac zs, auto)
  1838 done
  1839 
  1840 lemma take_add: 
  1841   "take (i+j) xs = take i xs @ take j (drop i xs)"
  1842 apply (induct xs arbitrary: i, auto) 
  1843 apply (case_tac i, simp_all)
  1844 done
  1845 
  1846 lemma append_eq_append_conv_if:
  1847  "(xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>1 @ ys\<^isub>2) =
  1848   (if size xs\<^isub>1 \<le> size ys\<^isub>1
  1849    then xs\<^isub>1 = take (size xs\<^isub>1) ys\<^isub>1 \<and> xs\<^isub>2 = drop (size xs\<^isub>1) ys\<^isub>1 @ ys\<^isub>2
  1850    else take (size ys\<^isub>1) xs\<^isub>1 = ys\<^isub>1 \<and> drop (size ys\<^isub>1) xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>2)"
  1851 apply(induct xs\<^isub>1 arbitrary: ys\<^isub>1)
  1852  apply simp
  1853 apply(case_tac ys\<^isub>1)
  1854 apply simp_all
  1855 done
  1856 
  1857 lemma take_hd_drop:
  1858   "n < length xs \<Longrightarrow> take n xs @ [hd (drop n xs)] = take (Suc n) xs"
  1859 apply(induct xs arbitrary: n)
  1860 apply simp
  1861 apply(simp add:drop_Cons split:nat.split)
  1862 done
  1863 
  1864 lemma id_take_nth_drop:
  1865  "i < length xs \<Longrightarrow> xs = take i xs @ xs!i # drop (Suc i) xs" 
  1866 proof -
  1867   assume si: "i < length xs"
  1868   hence "xs = take (Suc i) xs @ drop (Suc i) xs" by auto
  1869   moreover
  1870   from si have "take (Suc i) xs = take i xs @ [xs!i]"
  1871     apply (rule_tac take_Suc_conv_app_nth) by arith
  1872   ultimately show ?thesis by auto
  1873 qed
  1874   
  1875 lemma upd_conv_take_nth_drop:
  1876  "i < length xs \<Longrightarrow> xs[i:=a] = take i xs @ a # drop (Suc i) xs"
  1877 proof -
  1878   assume i: "i < length xs"
  1879   have "xs[i:=a] = (take i xs @ xs!i # drop (Suc i) xs)[i:=a]"
  1880     by(rule arg_cong[OF id_take_nth_drop[OF i]])
  1881   also have "\<dots> = take i xs @ a # drop (Suc i) xs"
  1882     using i by (simp add: list_update_append)
  1883   finally show ?thesis .
  1884 qed
  1885 
  1886 lemma nth_drop':
  1887   "i < length xs \<Longrightarrow> xs ! i # drop (Suc i) xs = drop i xs"
  1888 apply (induct i arbitrary: xs)
  1889 apply (simp add: neq_Nil_conv)
  1890 apply (erule exE)+
  1891 apply simp
  1892 apply (case_tac xs)
  1893 apply simp_all
  1894 done
  1895 
  1896 
  1897 subsubsection {* @{text takeWhile} and @{text dropWhile} *}
  1898 
  1899 lemma length_takeWhile_le: "length (takeWhile P xs) \<le> length xs"
  1900   by (induct xs) auto
  1901 
  1902 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
  1903 by (induct xs) auto
  1904 
  1905 lemma takeWhile_append1 [simp]:
  1906 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
  1907 by (induct xs) auto
  1908 
  1909 lemma takeWhile_append2 [simp]:
  1910 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
  1911 by (induct xs) auto
  1912 
  1913 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
  1914 by (induct xs) auto
  1915 
  1916 lemma takeWhile_nth: "j < length (takeWhile P xs) \<Longrightarrow> takeWhile P xs ! j = xs ! j"
  1917 apply (subst (3) takeWhile_dropWhile_id[symmetric]) unfolding nth_append by auto
  1918 
  1919 lemma dropWhile_nth: "j < length (dropWhile P xs) \<Longrightarrow> dropWhile P xs ! j = xs ! (j + length (takeWhile P xs))"
  1920 apply (subst (3) takeWhile_dropWhile_id[symmetric]) unfolding nth_append by auto
  1921 
  1922 lemma length_dropWhile_le: "length (dropWhile P xs) \<le> length xs"
  1923 by (induct xs) auto
  1924 
  1925 lemma dropWhile_append1 [simp]:
  1926 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
  1927 by (induct xs) auto
  1928 
  1929 lemma dropWhile_append2 [simp]:
  1930 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
  1931 by (induct xs) auto
  1932 
  1933 lemma dropWhile_append3:
  1934   "\<not> P y \<Longrightarrow>dropWhile P (xs @ y # ys) = dropWhile P xs @ y # ys"
  1935 by (induct xs) auto
  1936 
  1937 lemma dropWhile_last:
  1938   "x \<in> set xs \<Longrightarrow> \<not> P x \<Longrightarrow> last (dropWhile P xs) = last xs"
  1939 by (auto simp add: dropWhile_append3 in_set_conv_decomp)
  1940 
  1941 lemma set_dropWhileD: "x \<in> set (dropWhile P xs) \<Longrightarrow> x \<in> set xs"
  1942 by (induct xs) (auto split: split_if_asm)
  1943 
  1944 lemma set_takeWhileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
  1945 by (induct xs) (auto split: split_if_asm)
  1946 
  1947 lemma takeWhile_eq_all_conv[simp]:
  1948  "(takeWhile P xs = xs) = (\<forall>x \<in> set xs. P x)"
  1949 by(induct xs, auto)
  1950 
  1951 lemma dropWhile_eq_Nil_conv[simp]:
  1952  "(dropWhile P xs = []) = (\<forall>x \<in> set xs. P x)"
  1953 by(induct xs, auto)
  1954 
  1955 lemma dropWhile_eq_Cons_conv:
  1956  "(dropWhile P xs = y#ys) = (xs = takeWhile P xs @ y # ys & \<not> P y)"
  1957 by(induct xs, auto)
  1958 
  1959 lemma distinct_takeWhile[simp]: "distinct xs ==> distinct (takeWhile P xs)"
  1960 by (induct xs) (auto dest: set_takeWhileD)
  1961 
  1962 lemma distinct_dropWhile[simp]: "distinct xs ==> distinct (dropWhile P xs)"
  1963 by (induct xs) auto
  1964 
  1965 lemma takeWhile_map: "takeWhile P (map f xs) = map f (takeWhile (P \<circ> f) xs)"
  1966 by (induct xs) auto
  1967 
  1968 lemma dropWhile_map: "dropWhile P (map f xs) = map f (dropWhile (P \<circ> f) xs)"
  1969 by (induct xs) auto
  1970 
  1971 lemma takeWhile_eq_take: "takeWhile P xs = take (length (takeWhile P xs)) xs"
  1972 by (induct xs) auto
  1973 
  1974 lemma dropWhile_eq_drop: "dropWhile P xs = drop (length (takeWhile P xs)) xs"
  1975 by (induct xs) auto
  1976 
  1977 lemma hd_dropWhile:
  1978   "dropWhile P xs \<noteq> [] \<Longrightarrow> \<not> P (hd (dropWhile P xs))"
  1979 using assms by (induct xs) auto
  1980 
  1981 lemma takeWhile_eq_filter:
  1982   assumes "\<And> x. x \<in> set (dropWhile P xs) \<Longrightarrow> \<not> P x"
  1983   shows "takeWhile P xs = filter P xs"
  1984 proof -
  1985   have A: "filter P xs = filter P (takeWhile P xs @ dropWhile P xs)"
  1986     by simp
  1987   have B: "filter P (dropWhile P xs) = []"
  1988     unfolding filter_empty_conv using assms by blast
  1989   have "filter P xs = takeWhile P xs"
  1990     unfolding A filter_append B
  1991     by (auto simp add: filter_id_conv dest: set_takeWhileD)
  1992   thus ?thesis ..
  1993 qed
  1994 
  1995 lemma takeWhile_eq_take_P_nth:
  1996   "\<lbrakk> \<And> i. \<lbrakk> i < n ; i < length xs \<rbrakk> \<Longrightarrow> P (xs ! i) ; n < length xs \<Longrightarrow> \<not> P (xs ! n) \<rbrakk> \<Longrightarrow>
  1997   takeWhile P xs = take n xs"
  1998 proof (induct xs arbitrary: n)
  1999   case (Cons x xs)
  2000   thus ?case
  2001   proof (cases n)
  2002     case (Suc n') note this[simp]
  2003     have "P x" using Cons.prems(1)[of 0] by simp
  2004     moreover have "takeWhile P xs = take n' xs"
  2005     proof (rule Cons.hyps)
  2006       case goal1 thus "P (xs ! i)" using Cons.prems(1)[of "Suc i"] by simp
  2007     next case goal2 thus ?case using Cons by auto
  2008     qed
  2009     ultimately show ?thesis by simp
  2010    qed simp
  2011 qed simp
  2012 
  2013 lemma nth_length_takeWhile:
  2014   "length (takeWhile P xs) < length xs \<Longrightarrow> \<not> P (xs ! length (takeWhile P xs))"
  2015 by (induct xs) auto
  2016 
  2017 lemma length_takeWhile_less_P_nth:
  2018   assumes all: "\<And> i. i < j \<Longrightarrow> P (xs ! i)" and "j \<le> length xs"
  2019   shows "j \<le> length (takeWhile P xs)"
  2020 proof (rule classical)
  2021   assume "\<not> ?thesis"
  2022   hence "length (takeWhile P xs) < length xs" using assms by simp
  2023   thus ?thesis using all `\<not> ?thesis` nth_length_takeWhile[of P xs] by auto
  2024 qed
  2025 
  2026 text{* The following two lemmmas could be generalized to an arbitrary
  2027 property. *}
  2028 
  2029 lemma takeWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  2030  takeWhile (\<lambda>y. y \<noteq> x) (rev xs) = rev (tl (dropWhile (\<lambda>y. y \<noteq> x) xs))"
  2031 by(induct xs) (auto simp: takeWhile_tail[where l="[]"])
  2032 
  2033 lemma dropWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  2034   dropWhile (\<lambda>y. y \<noteq> x) (rev xs) = x # rev (takeWhile (\<lambda>y. y \<noteq> x) xs)"
  2035 apply(induct xs)
  2036  apply simp
  2037 apply auto
  2038 apply(subst dropWhile_append2)
  2039 apply auto
  2040 done
  2041 
  2042 lemma takeWhile_not_last:
  2043  "distinct xs \<Longrightarrow> takeWhile (\<lambda>y. y \<noteq> last xs) xs = butlast xs"
  2044 apply(induct xs)
  2045  apply simp
  2046 apply(case_tac xs)
  2047 apply(auto)
  2048 done
  2049 
  2050 lemma takeWhile_cong [fundef_cong]:
  2051   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  2052   ==> takeWhile P l = takeWhile Q k"
  2053 by (induct k arbitrary: l) (simp_all)
  2054 
  2055 lemma dropWhile_cong [fundef_cong]:
  2056   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  2057   ==> dropWhile P l = dropWhile Q k"
  2058 by (induct k arbitrary: l, simp_all)
  2059 
  2060 
  2061 subsubsection {* @{text zip} *}
  2062 
  2063 lemma zip_Nil [simp]: "zip [] ys = []"
  2064 by (induct ys) auto
  2065 
  2066 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
  2067 by simp
  2068 
  2069 declare zip_Cons [simp del]
  2070 
  2071 lemma [code]:
  2072   "zip [] ys = []"
  2073   "zip xs [] = []"
  2074   "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
  2075   by (fact zip_Nil zip.simps(1) zip_Cons_Cons)+
  2076 
  2077 lemma zip_Cons1:
  2078  "zip (x#xs) ys = (case ys of [] \<Rightarrow> [] | y#ys \<Rightarrow> (x,y)#zip xs ys)"
  2079 by(auto split:list.split)
  2080 
  2081 lemma length_zip [simp]:
  2082 "length (zip xs ys) = min (length xs) (length ys)"
  2083 by (induct xs ys rule:list_induct2') auto
  2084 
  2085 lemma zip_obtain_same_length:
  2086   assumes "\<And>zs ws n. length zs = length ws \<Longrightarrow> n = min (length xs) (length ys)
  2087     \<Longrightarrow> zs = take n xs \<Longrightarrow> ws = take n ys \<Longrightarrow> P (zip zs ws)"
  2088   shows "P (zip xs ys)"
  2089 proof -
  2090   let ?n = "min (length xs) (length ys)"
  2091   have "P (zip (take ?n xs) (take ?n ys))"
  2092     by (rule assms) simp_all
  2093   moreover have "zip xs ys = zip (take ?n xs) (take ?n ys)"
  2094   proof (induct xs arbitrary: ys)
  2095     case Nil then show ?case by simp
  2096   next
  2097     case (Cons x xs) then show ?case by (cases ys) simp_all
  2098   qed
  2099   ultimately show ?thesis by simp
  2100 qed
  2101 
  2102 lemma zip_append1:
  2103 "zip (xs @ ys) zs =
  2104 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
  2105 by (induct xs zs rule:list_induct2') auto
  2106 
  2107 lemma zip_append2:
  2108 "zip xs (ys @ zs) =
  2109 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
  2110 by (induct xs ys rule:list_induct2') auto
  2111 
  2112 lemma zip_append [simp]:
  2113  "[| length xs = length us |] ==>
  2114 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
  2115 by (simp add: zip_append1)
  2116 
  2117 lemma zip_rev:
  2118 "length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
  2119 by (induct rule:list_induct2, simp_all)
  2120 
  2121 lemma zip_map_map:
  2122   "zip (map f xs) (map g ys) = map (\<lambda> (x, y). (f x, g y)) (zip xs ys)"
  2123 proof (induct xs arbitrary: ys)
  2124   case (Cons x xs) note Cons_x_xs = Cons.hyps
  2125   show ?case
  2126   proof (cases ys)
  2127     case (Cons y ys')
  2128     show ?thesis unfolding Cons using Cons_x_xs by simp
  2129   qed simp
  2130 qed simp
  2131 
  2132 lemma zip_map1:
  2133   "zip (map f xs) ys = map (\<lambda>(x, y). (f x, y)) (zip xs ys)"
  2134 using zip_map_map[of f xs "\<lambda>x. x" ys] by simp
  2135 
  2136 lemma zip_map2:
  2137   "zip xs (map f ys) = map (\<lambda>(x, y). (x, f y)) (zip xs ys)"
  2138 using zip_map_map[of "\<lambda>x. x" xs f ys] by simp
  2139 
  2140 lemma map_zip_map:
  2141   "map f (zip (map g xs) ys) = map (%(x,y). f(g x, y)) (zip xs ys)"
  2142 unfolding zip_map1 by auto
  2143 
  2144 lemma map_zip_map2:
  2145   "map f (zip xs (map g ys)) = map (%(x,y). f(x, g y)) (zip xs ys)"
  2146 unfolding zip_map2 by auto
  2147 
  2148 text{* Courtesy of Andreas Lochbihler: *}
  2149 lemma zip_same_conv_map: "zip xs xs = map (\<lambda>x. (x, x)) xs"
  2150 by(induct xs) auto
  2151 
  2152 lemma nth_zip [simp]:
  2153 "[| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
  2154 apply (induct ys arbitrary: i xs, simp)
  2155 apply (case_tac xs)
  2156  apply (simp_all add: nth.simps split: nat.split)
  2157 done
  2158 
  2159 lemma set_zip:
  2160 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
  2161 by(simp add: set_conv_nth cong: rev_conj_cong)
  2162 
  2163 lemma zip_same: "((a,b) \<in> set (zip xs xs)) = (a \<in> set xs \<and> a = b)"
  2164 by(induct xs) auto
  2165 
  2166 lemma zip_update:
  2167   "zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
  2168 by(rule sym, simp add: update_zip)
  2169 
  2170 lemma zip_replicate [simp]:
  2171   "zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
  2172 apply (induct i arbitrary: j, auto)
  2173 apply (case_tac j, auto)
  2174 done
  2175 
  2176 lemma take_zip:
  2177   "take n (zip xs ys) = zip (take n xs) (take n ys)"
  2178 apply (induct n arbitrary: xs ys)
  2179  apply simp
  2180 apply (case_tac xs, simp)
  2181 apply (case_tac ys, simp_all)
  2182 done
  2183 
  2184 lemma drop_zip:
  2185   "drop n (zip xs ys) = zip (drop n xs) (drop n ys)"
  2186 apply (induct n arbitrary: xs ys)
  2187  apply simp
  2188 apply (case_tac xs, simp)
  2189 apply (case_tac ys, simp_all)
  2190 done
  2191 
  2192 lemma zip_takeWhile_fst: "zip (takeWhile P xs) ys = takeWhile (P \<circ> fst) (zip xs ys)"
  2193 proof (induct xs arbitrary: ys)
  2194   case (Cons x xs) thus ?case by (cases ys) auto
  2195 qed simp
  2196 
  2197 lemma zip_takeWhile_snd: "zip xs (takeWhile P ys) = takeWhile (P \<circ> snd) (zip xs ys)"
  2198 proof (induct xs arbitrary: ys)
  2199   case (Cons x xs) thus ?case by (cases ys) auto
  2200 qed simp
  2201 
  2202 lemma set_zip_leftD:
  2203   "(x,y)\<in> set (zip xs ys) \<Longrightarrow> x \<in> set xs"
  2204 by (induct xs ys rule:list_induct2') auto
  2205 
  2206 lemma set_zip_rightD:
  2207   "(x,y)\<in> set (zip xs ys) \<Longrightarrow> y \<in> set ys"
  2208 by (induct xs ys rule:list_induct2') auto
  2209 
  2210 lemma in_set_zipE:
  2211   "(x,y) : set(zip xs ys) \<Longrightarrow> (\<lbrakk> x : set xs; y : set ys \<rbrakk> \<Longrightarrow> R) \<Longrightarrow> R"
  2212 by(blast dest: set_zip_leftD set_zip_rightD)
  2213 
  2214 lemma zip_map_fst_snd:
  2215   "zip (map fst zs) (map snd zs) = zs"
  2216   by (induct zs) simp_all
  2217 
  2218 lemma zip_eq_conv:
  2219   "length xs = length ys \<Longrightarrow> zip xs ys = zs \<longleftrightarrow> map fst zs = xs \<and> map snd zs = ys"
  2220   by (auto simp add: zip_map_fst_snd)
  2221 
  2222 
  2223 subsubsection {* @{text list_all2} *}
  2224 
  2225 lemma list_all2_lengthD [intro?]: 
  2226   "list_all2 P xs ys ==> length xs = length ys"
  2227 by (simp add: list_all2_def)
  2228 
  2229 lemma list_all2_Nil [iff, code]: "list_all2 P [] ys = (ys = [])"
  2230 by (simp add: list_all2_def)
  2231 
  2232 lemma list_all2_Nil2 [iff, code]: "list_all2 P xs [] = (xs = [])"
  2233 by (simp add: list_all2_def)
  2234 
  2235 lemma list_all2_Cons [iff, code]:
  2236   "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
  2237 by (auto simp add: list_all2_def)
  2238 
  2239 lemma list_all2_Cons1:
  2240 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
  2241 by (cases ys) auto
  2242 
  2243 lemma list_all2_Cons2:
  2244 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
  2245 by (cases xs) auto
  2246 
  2247 lemma list_all2_induct
  2248   [consumes 1, case_names Nil Cons, induct set: list_all2]:
  2249   assumes P: "list_all2 P xs ys"
  2250   assumes Nil: "R [] []"
  2251   assumes Cons: "\<And>x xs y ys. \<lbrakk>P x y; R xs ys\<rbrakk> \<Longrightarrow> R (x # xs) (y # ys)"
  2252   shows "R xs ys"
  2253 using P
  2254 by (induct xs arbitrary: ys) (auto simp add: list_all2_Cons1 Nil Cons)
  2255 
  2256 lemma list_all2_rev [iff]:
  2257 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
  2258 by (simp add: list_all2_def zip_rev cong: conj_cong)
  2259 
  2260 lemma list_all2_rev1:
  2261 "list_all2 P (rev xs) ys = list_all2 P xs (rev ys)"
  2262 by (subst list_all2_rev [symmetric]) simp
  2263 
  2264 lemma list_all2_append1:
  2265 "list_all2 P (xs @ ys) zs =
  2266 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
  2267 list_all2 P xs us \<and> list_all2 P ys vs)"
  2268 apply (simp add: list_all2_def zip_append1)
  2269 apply (rule iffI)
  2270  apply (rule_tac x = "take (length xs) zs" in exI)
  2271  apply (rule_tac x = "drop (length xs) zs" in exI)
  2272  apply (force split: nat_diff_split simp add: min_def, clarify)
  2273 apply (simp add: ball_Un)
  2274 done
  2275 
  2276 lemma list_all2_append2:
  2277 "list_all2 P xs (ys @ zs) =
  2278 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  2279 list_all2 P us ys \<and> list_all2 P vs zs)"
  2280 apply (simp add: list_all2_def zip_append2)
  2281 apply (rule iffI)
  2282  apply (rule_tac x = "take (length ys) xs" in exI)
  2283  apply (rule_tac x = "drop (length ys) xs" in exI)
  2284  apply (force split: nat_diff_split simp add: min_def, clarify)
  2285 apply (simp add: ball_Un)
  2286 done
  2287 
  2288 lemma list_all2_append:
  2289   "length xs = length ys \<Longrightarrow>
  2290   list_all2 P (xs@us) (ys@vs) = (list_all2 P xs ys \<and> list_all2 P us vs)"
  2291 by (induct rule:list_induct2, simp_all)
  2292 
  2293 lemma list_all2_appendI [intro?, trans]:
  2294   "\<lbrakk> list_all2 P a b; list_all2 P c d \<rbrakk> \<Longrightarrow> list_all2 P (a@c) (b@d)"
  2295 by (simp add: list_all2_append list_all2_lengthD)
  2296 
  2297 lemma list_all2_conv_all_nth:
  2298 "list_all2 P xs ys =
  2299 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  2300 by (force simp add: list_all2_def set_zip)
  2301 
  2302 lemma list_all2_trans:
  2303   assumes tr: "!!a b c. P1 a b ==> P2 b c ==> P3 a c"
  2304   shows "!!bs cs. list_all2 P1 as bs ==> list_all2 P2 bs cs ==> list_all2 P3 as cs"
  2305         (is "!!bs cs. PROP ?Q as bs cs")
  2306 proof (induct as)
  2307   fix x xs bs assume I1: "!!bs cs. PROP ?Q xs bs cs"
  2308   show "!!cs. PROP ?Q (x # xs) bs cs"
  2309   proof (induct bs)
  2310     fix y ys cs assume I2: "!!cs. PROP ?Q (x # xs) ys cs"
  2311     show "PROP ?Q (x # xs) (y # ys) cs"
  2312       by (induct cs) (auto intro: tr I1 I2)
  2313   qed simp
  2314 qed simp
  2315 
  2316 lemma list_all2_all_nthI [intro?]:
  2317   "length a = length b \<Longrightarrow> (\<And>n. n < length a \<Longrightarrow> P (a!n) (b!n)) \<Longrightarrow> list_all2 P a b"
  2318 by (simp add: list_all2_conv_all_nth)
  2319 
  2320 lemma list_all2I:
  2321   "\<forall>x \<in> set (zip a b). split P x \<Longrightarrow> length a = length b \<Longrightarrow> list_all2 P a b"
  2322 by (simp add: list_all2_def)
  2323 
  2324 lemma list_all2_nthD:
  2325   "\<lbrakk> list_all2 P xs ys; p < size xs \<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  2326 by (simp add: list_all2_conv_all_nth)
  2327 
  2328 lemma list_all2_nthD2:
  2329   "\<lbrakk>list_all2 P xs ys; p < size ys\<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  2330 by (frule list_all2_lengthD) (auto intro: list_all2_nthD)
  2331 
  2332 lemma list_all2_map1: 
  2333   "list_all2 P (map f as) bs = list_all2 (\<lambda>x y. P (f x) y) as bs"
  2334 by (simp add: list_all2_conv_all_nth)
  2335 
  2336 lemma list_all2_map2: 
  2337   "list_all2 P as (map f bs) = list_all2 (\<lambda>x y. P x (f y)) as bs"
  2338 by (auto simp add: list_all2_conv_all_nth)
  2339 
  2340 lemma list_all2_refl [intro?]:
  2341   "(\<And>x. P x x) \<Longrightarrow> list_all2 P xs xs"
  2342 by (simp add: list_all2_conv_all_nth)
  2343 
  2344 lemma list_all2_update_cong:
  2345   "\<lbrakk> list_all2 P xs ys; P x y \<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  2346 by (cases "i < length ys") (auto simp add: list_all2_conv_all_nth nth_list_update)
  2347 
  2348 lemma list_all2_takeI [simp,intro?]:
  2349   "list_all2 P xs ys \<Longrightarrow> list_all2 P (take n xs) (take n ys)"
  2350 apply (induct xs arbitrary: n ys)
  2351  apply simp
  2352 apply (clarsimp simp add: list_all2_Cons1)
  2353 apply (case_tac n)
  2354 apply auto
  2355 done
  2356 
  2357 lemma list_all2_dropI [simp,intro?]:
  2358   "list_all2 P as bs \<Longrightarrow> list_all2 P (drop n as) (drop n bs)"
  2359 apply (induct as arbitrary: n bs, simp)
  2360 apply (clarsimp simp add: list_all2_Cons1)
  2361 apply (case_tac n, simp, simp)
  2362 done
  2363 
  2364 lemma list_all2_mono [intro?]:
  2365   "list_all2 P xs ys \<Longrightarrow> (\<And>xs ys. P xs ys \<Longrightarrow> Q xs ys) \<Longrightarrow> list_all2 Q xs ys"
  2366 apply (induct xs arbitrary: ys, simp)
  2367 apply (case_tac ys, auto)
  2368 done
  2369 
  2370 lemma list_all2_eq:
  2371   "xs = ys \<longleftrightarrow> list_all2 (op =) xs ys"
  2372 by (induct xs ys rule: list_induct2') auto
  2373 
  2374 lemma list_eq_iff_zip_eq:
  2375   "xs = ys \<longleftrightarrow> length xs = length ys \<and> (\<forall>(x,y) \<in> set (zip xs ys). x = y)"
  2376 by(auto simp add: set_zip list_all2_eq list_all2_conv_all_nth cong: conj_cong)
  2377 
  2378 
  2379 subsubsection {* @{const fold} with canonical argument order *}
  2380 
  2381 lemma fold_remove1_split:
  2382   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  2383     and x: "x \<in> set xs"
  2384   shows "fold f xs = fold f (remove1 x xs) \<circ> f x"
  2385   using assms by (induct xs) (auto simp add: o_assoc [symmetric])
  2386 
  2387 lemma fold_cong [fundef_cong]:
  2388   "a = b \<Longrightarrow> xs = ys \<Longrightarrow> (\<And>x. x \<in> set xs \<Longrightarrow> f x = g x)
  2389     \<Longrightarrow> fold f xs a = fold g ys b"
  2390   by (induct ys arbitrary: a b xs) simp_all
  2391 
  2392 lemma fold_id:
  2393   assumes "\<And>x. x \<in> set xs \<Longrightarrow> f x = id"
  2394   shows "fold f xs = id"
  2395   using assms by (induct xs) simp_all
  2396 
  2397 lemma fold_commute:
  2398   assumes "\<And>x. x \<in> set xs \<Longrightarrow> h \<circ> g x = f x \<circ> h"
  2399   shows "h \<circ> fold g xs = fold f xs \<circ> h"
  2400   using assms by (induct xs) (simp_all add: fun_eq_iff)
  2401 
  2402 lemma fold_commute_apply:
  2403   assumes "\<And>x. x \<in> set xs \<Longrightarrow> h \<circ> g x = f x \<circ> h"
  2404   shows "h (fold g xs s) = fold f xs (h s)"
  2405 proof -
  2406   from assms have "h \<circ> fold g xs = fold f xs \<circ> h" by (rule fold_commute)
  2407   then show ?thesis by (simp add: fun_eq_iff)
  2408 qed
  2409 
  2410 lemma fold_invariant: 
  2411   assumes "\<And>x. x \<in> set xs \<Longrightarrow> Q x" and "P s"
  2412     and "\<And>x s. Q x \<Longrightarrow> P s \<Longrightarrow> P (f x s)"
  2413   shows "P (fold f xs s)"
  2414   using assms by (induct xs arbitrary: s) simp_all
  2415 
  2416 lemma fold_append [simp]:
  2417   "fold f (xs @ ys) = fold f ys \<circ> fold f xs"
  2418   by (induct xs) simp_all
  2419 
  2420 lemma fold_map [code_unfold]:
  2421   "fold g (map f xs) = fold (g o f) xs"
  2422   by (induct xs) simp_all
  2423 
  2424 lemma fold_rev:
  2425   assumes "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f y \<circ> f x = f x \<circ> f y"
  2426   shows "fold f (rev xs) = fold f xs"
  2427 using assms by (induct xs) (simp_all add: fold_commute_apply fun_eq_iff)
  2428 
  2429 lemma fold_Cons_rev:
  2430   "fold Cons xs = append (rev xs)"
  2431   by (induct xs) simp_all
  2432 
  2433 lemma rev_conv_fold [code]:
  2434   "rev xs = fold Cons xs []"
  2435   by (simp add: fold_Cons_rev)
  2436 
  2437 lemma fold_append_concat_rev:
  2438   "fold append xss = append (concat (rev xss))"
  2439   by (induct xss) simp_all
  2440 
  2441 text {* @{const Finite_Set.fold} and @{const fold} *}
  2442 
  2443 lemma (in comp_fun_commute) fold_set_fold_remdups:
  2444   "Finite_Set.fold f y (set xs) = fold f (remdups xs) y"
  2445   by (rule sym, induct xs arbitrary: y) (simp_all add: fold_fun_comm insert_absorb)
  2446 
  2447 lemma (in comp_fun_idem) fold_set_fold:
  2448   "Finite_Set.fold f y (set xs) = fold f xs y"
  2449   by (rule sym, induct xs arbitrary: y) (simp_all add: fold_fun_comm)
  2450 
  2451 lemma (in ab_semigroup_idem_mult) fold1_set_fold:
  2452   assumes "xs \<noteq> []"
  2453   shows "Finite_Set.fold1 times (set xs) = fold times (tl xs) (hd xs)"
  2454 proof -
  2455   interpret comp_fun_idem times by (fact comp_fun_idem)
  2456   from assms obtain y ys where xs: "xs = y # ys"
  2457     by (cases xs) auto
  2458   show ?thesis
  2459   proof (cases "set ys = {}")
  2460     case True with xs show ?thesis by simp
  2461   next
  2462     case False
  2463     then have "fold1 times (insert y (set ys)) = Finite_Set.fold times y (set ys)"
  2464       by (simp only: finite_set fold1_eq_fold_idem)
  2465     with xs show ?thesis by (simp add: fold_set_fold mult_commute)
  2466   qed
  2467 qed
  2468 
  2469 lemma union_set_fold:
  2470   "set xs \<union> A = fold Set.insert xs A"
  2471 proof -
  2472   interpret comp_fun_idem Set.insert
  2473     by (fact comp_fun_idem_insert)
  2474   show ?thesis by (simp add: union_fold_insert fold_set_fold)
  2475 qed
  2476 
  2477 lemma minus_set_fold:
  2478   "A - set xs = fold Set.remove xs A"
  2479 proof -
  2480   interpret comp_fun_idem Set.remove
  2481     by (fact comp_fun_idem_remove)
  2482   show ?thesis
  2483     by (simp add: minus_fold_remove [of _ A] fold_set_fold)
  2484 qed
  2485 
  2486 lemma (in lattice) Inf_fin_set_fold:
  2487   "Inf_fin (set (x # xs)) = fold inf xs x"
  2488 proof -
  2489   interpret ab_semigroup_idem_mult "inf :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2490     by (fact ab_semigroup_idem_mult_inf)
  2491   show ?thesis
  2492     by (simp add: Inf_fin_def fold1_set_fold del: set.simps)
  2493 qed
  2494 
  2495 lemma (in lattice) Sup_fin_set_fold:
  2496   "Sup_fin (set (x # xs)) = fold sup xs x"
  2497 proof -
  2498   interpret ab_semigroup_idem_mult "sup :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2499     by (fact ab_semigroup_idem_mult_sup)
  2500   show ?thesis
  2501     by (simp add: Sup_fin_def fold1_set_fold del: set.simps)
  2502 qed
  2503 
  2504 lemma (in linorder) Min_fin_set_fold:
  2505   "Min (set (x # xs)) = fold min xs x"
  2506 proof -
  2507   interpret ab_semigroup_idem_mult "min :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2508     by (fact ab_semigroup_idem_mult_min)
  2509   show ?thesis
  2510     by (simp add: Min_def fold1_set_fold del: set.simps)
  2511 qed
  2512 
  2513 lemma (in linorder) Max_fin_set_fold:
  2514   "Max (set (x # xs)) = fold max xs x"
  2515 proof -
  2516   interpret ab_semigroup_idem_mult "max :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2517     by (fact ab_semigroup_idem_mult_max)
  2518   show ?thesis
  2519     by (simp add: Max_def fold1_set_fold del: set.simps)
  2520 qed
  2521 
  2522 lemma (in complete_lattice) Inf_set_fold:
  2523   "Inf (set xs) = fold inf xs top"
  2524 proof -
  2525   interpret comp_fun_idem "inf :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2526     by (fact comp_fun_idem_inf)
  2527   show ?thesis by (simp add: Inf_fold_inf fold_set_fold inf_commute)
  2528 qed
  2529 
  2530 lemma (in complete_lattice) Sup_set_fold:
  2531   "Sup (set xs) = fold sup xs bot"
  2532 proof -
  2533   interpret comp_fun_idem "sup :: 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2534     by (fact comp_fun_idem_sup)
  2535   show ?thesis by (simp add: Sup_fold_sup fold_set_fold sup_commute)
  2536 qed
  2537 
  2538 lemma (in complete_lattice) INF_set_fold:
  2539   "INFI (set xs) f = fold (inf \<circ> f) xs top"
  2540   unfolding INF_def set_map [symmetric] Inf_set_fold fold_map ..
  2541 
  2542 lemma (in complete_lattice) SUP_set_fold:
  2543   "SUPR (set xs) f = fold (sup \<circ> f) xs bot"
  2544   unfolding SUP_def set_map [symmetric] Sup_set_fold fold_map ..
  2545 
  2546 
  2547 subsubsection {* Fold variants: @{const foldr} and @{const foldl} *}
  2548 
  2549 text {* Correspondence *}
  2550 
  2551 lemma foldr_foldl: -- {* The ``Third Duality Theorem'' in Bird \& Wadler: *}
  2552   "foldr f xs a = foldl (\<lambda>x y. f y x) a (rev xs)"
  2553   by (simp add: foldr_def foldl_def)
  2554 
  2555 lemma foldl_foldr:
  2556   "foldl f a xs = foldr (\<lambda>x y. f y x) (rev xs) a"
  2557   by (simp add: foldr_def foldl_def)
  2558 
  2559 lemma foldr_fold:
  2560   assumes "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f y \<circ> f x = f x \<circ> f y"
  2561   shows "foldr f xs = fold f xs"
  2562   using assms unfolding foldr_def by (rule fold_rev)
  2563 
  2564 lemma
  2565   foldr_Nil [code, simp]: "foldr f [] = id"
  2566   and foldr_Cons [code, simp]: "foldr f (x # xs) = f x \<circ> foldr f xs"
  2567   by (simp_all add: foldr_def)
  2568 
  2569 lemma
  2570   foldl_Nil [simp]: "foldl f a [] = a"
  2571   and foldl_Cons [simp]: "foldl f a (x # xs) = foldl f (f a x) xs"
  2572   by (simp_all add: foldl_def)
  2573 
  2574 lemma foldr_cong [fundef_cong]:
  2575   "a = b \<Longrightarrow> l = k \<Longrightarrow> (\<And>a x. x \<in> set l \<Longrightarrow> f x a = g x a) \<Longrightarrow> foldr f l a = foldr g k b"
  2576   by (auto simp add: foldr_def intro!: fold_cong)
  2577 
  2578 lemma foldl_cong [fundef_cong]:
  2579   "a = b \<Longrightarrow> l = k \<Longrightarrow> (\<And>a x. x \<in> set l \<Longrightarrow> f a x = g a x) \<Longrightarrow> foldl f a l = foldl g b k"
  2580   by (auto simp add: foldl_def intro!: fold_cong)
  2581 
  2582 lemma foldr_append [simp]:
  2583   "foldr f (xs @ ys) a = foldr f xs (foldr f ys a)"
  2584   by (simp add: foldr_def)
  2585 
  2586 lemma foldl_append [simp]:
  2587   "foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  2588   by (simp add: foldl_def)
  2589 
  2590 lemma foldr_map [code_unfold]:
  2591   "foldr g (map f xs) a = foldr (g o f) xs a"
  2592   by (simp add: foldr_def fold_map rev_map)
  2593 
  2594 lemma foldl_map [code_unfold]:
  2595   "foldl g a (map f xs) = foldl (\<lambda>a x. g a (f x)) a xs"
  2596   by (simp add: foldl_def fold_map comp_def)
  2597 
  2598 text {* Executing operations in terms of @{const foldr} -- tail-recursive! *}
  2599 
  2600 lemma concat_conv_foldr [code]:
  2601   "concat xss = foldr append xss []"
  2602   by (simp add: fold_append_concat_rev foldr_def)
  2603 
  2604 lemma minus_set_foldr [code]:
  2605   "A - set xs = foldr Set.remove xs A"
  2606 proof -
  2607   have "\<And>x y :: 'a. Set.remove y \<circ> Set.remove x = Set.remove x \<circ> Set.remove y"
  2608     by (auto simp add: remove_def)
  2609   then show ?thesis by (simp add: minus_set_fold foldr_fold)
  2610 qed
  2611 
  2612 lemma subtract_coset_filter [code]:
  2613   "A - List.coset xs = set (List.filter (\<lambda>x. x \<in> A) xs)"
  2614   by auto
  2615 
  2616 lemma union_set_foldr [code]:
  2617   "set xs \<union> A = foldr Set.insert xs A"
  2618 proof -
  2619   have "\<And>x y :: 'a. insert y \<circ> insert x = insert x \<circ> insert y"
  2620     by auto
  2621   then show ?thesis by (simp add: union_set_fold foldr_fold)
  2622 qed
  2623 
  2624 lemma union_coset_foldr [code]:
  2625   "List.coset xs \<union> A = List.coset (List.filter (\<lambda>x. x \<notin> A) xs)"
  2626   by auto
  2627 
  2628 lemma inter_set_filer [code]:
  2629   "A \<inter> set xs = set (List.filter (\<lambda>x. x \<in> A) xs)"
  2630   by auto
  2631 
  2632 lemma inter_coset_foldr [code]:
  2633   "A \<inter> List.coset xs = foldr Set.remove xs A"
  2634   by (simp add: Diff_eq [symmetric] minus_set_foldr)
  2635 
  2636 lemma (in lattice) Inf_fin_set_foldr [code]:
  2637   "Inf_fin (set (x # xs)) = foldr inf xs x"
  2638   by (simp add: Inf_fin_set_fold ac_simps foldr_fold fun_eq_iff del: set.simps)
  2639 
  2640 lemma (in lattice) Sup_fin_set_foldr [code]:
  2641   "Sup_fin (set (x # xs)) = foldr sup xs x"
  2642   by (simp add: Sup_fin_set_fold ac_simps foldr_fold fun_eq_iff del: set.simps)
  2643 
  2644 lemma (in linorder) Min_fin_set_foldr [code]:
  2645   "Min (set (x # xs)) = foldr min xs x"
  2646   by (simp add: Min_fin_set_fold ac_simps foldr_fold fun_eq_iff del: set.simps)
  2647 
  2648 lemma (in linorder) Max_fin_set_foldr [code]:
  2649   "Max (set (x # xs)) = foldr max xs x"
  2650   by (simp add: Max_fin_set_fold ac_simps foldr_fold fun_eq_iff del: set.simps)
  2651 
  2652 lemma (in complete_lattice) Inf_set_foldr:
  2653   "Inf (set xs) = foldr inf xs top"
  2654   by (simp add: Inf_set_fold ac_simps foldr_fold fun_eq_iff)
  2655 
  2656 lemma (in complete_lattice) Sup_set_foldr:
  2657   "Sup (set xs) = foldr sup xs bot"
  2658   by (simp add: Sup_set_fold ac_simps foldr_fold fun_eq_iff)
  2659 
  2660 declare Inf_set_foldr [where 'a = "'a set", code] Sup_set_foldr [where 'a = "'a set", code]
  2661 
  2662 lemma (in complete_lattice) INF_set_foldr [code]:
  2663   "INFI (set xs) f = foldr (inf \<circ> f) xs top"
  2664   by (simp only: INF_def Inf_set_foldr foldr_map set_map [symmetric])
  2665 
  2666 lemma (in complete_lattice) SUP_set_foldr [code]:
  2667   "SUPR (set xs) f = foldr (sup \<circ> f) xs bot"
  2668   by (simp only: SUP_def Sup_set_foldr foldr_map set_map [symmetric])
  2669 
  2670 
  2671 subsubsection {* @{text upt} *}
  2672 
  2673 lemma upt_rec[code]: "[i..<j] = (if i<j then i#[Suc i..<j] else [])"
  2674 -- {* simp does not terminate! *}
  2675 by (induct j) auto
  2676 
  2677 lemmas upt_rec_number_of[simp] = upt_rec[of "number_of m" "number_of n"] for m n
  2678 
  2679 lemma upt_conv_Nil [simp]: "j <= i ==> [i..<j] = []"
  2680 by (subst upt_rec) simp
  2681 
  2682 lemma upt_eq_Nil_conv[simp]: "([i..<j] = []) = (j = 0 \<or> j <= i)"
  2683 by(induct j)simp_all
  2684 
  2685 lemma upt_eq_Cons_conv:
  2686  "([i..<j] = x#xs) = (i < j & i = x & [i+1..<j] = xs)"
  2687 apply(induct j arbitrary: x xs)
  2688  apply simp
  2689 apply(clarsimp simp add: append_eq_Cons_conv)
  2690 apply arith
  2691 done
  2692 
  2693 lemma upt_Suc_append: "i <= j ==> [i..<(Suc j)] = [i..<j]@[j]"
  2694 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  2695 by simp
  2696 
  2697 lemma upt_conv_Cons: "i < j ==> [i..<j] = i # [Suc i..<j]"
  2698   by (simp add: upt_rec)
  2699 
  2700 lemma upt_add_eq_append: "i<=j ==> [i..<j+k] = [i..<j]@[j..<j+k]"
  2701 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  2702 by (induct k) auto
  2703 
  2704 lemma length_upt [simp]: "length [i..<j] = j - i"
  2705 by (induct j) (auto simp add: Suc_diff_le)
  2706 
  2707 lemma nth_upt [simp]: "i + k < j ==> [i..<j] ! k = i + k"
  2708 apply (induct j)
  2709 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  2710 done
  2711 
  2712 
  2713 lemma hd_upt[simp]: "i < j \<Longrightarrow> hd[i..<j] = i"
  2714 by(simp add:upt_conv_Cons)
  2715 
  2716 lemma last_upt[simp]: "i < j \<Longrightarrow> last[i..<j] = j - 1"
  2717 apply(cases j)
  2718  apply simp
  2719 by(simp add:upt_Suc_append)
  2720 
  2721 lemma take_upt [simp]: "i+m <= n ==> take m [i..<n] = [i..<i+m]"
  2722 apply (induct m arbitrary: i, simp)
  2723 apply (subst upt_rec)
  2724 apply (rule sym)
  2725 apply (subst upt_rec)
  2726 apply (simp del: upt.simps)
  2727 done
  2728 
  2729 lemma drop_upt[simp]: "drop m [i..<j] = [i+m..<j]"
  2730 apply(induct j)
  2731 apply auto
  2732 done
  2733 
  2734 lemma map_Suc_upt: "map Suc [m..<n] = [Suc m..<Suc n]"
  2735 by (induct n) auto
  2736 
  2737 lemma nth_map_upt: "i < n-m ==> (map f [m..<n]) ! i = f(m+i)"
  2738 apply (induct n m  arbitrary: i rule: diff_induct)
  2739 prefer 3 apply (subst map_Suc_upt[symmetric])
  2740 apply (auto simp add: less_diff_conv)
  2741 done
  2742 
  2743 lemma nth_take_lemma:
  2744   "k <= length xs ==> k <= length ys ==>
  2745      (!!i. i < k --> xs!i = ys!i) ==> take k xs = take k ys"
  2746 apply (atomize, induct k arbitrary: xs ys)
  2747 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib, clarify)
  2748 txt {* Both lists must be non-empty *}
  2749 apply (case_tac xs, simp)
  2750 apply (case_tac ys, clarify)
  2751  apply (simp (no_asm_use))
  2752 apply clarify
  2753 txt {* prenexing's needed, not miniscoping *}
  2754 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  2755 apply blast
  2756 done
  2757 
  2758 lemma nth_equalityI:
  2759  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  2760   by (frule nth_take_lemma [OF le_refl eq_imp_le]) simp_all
  2761 
  2762 lemma map_nth:
  2763   "map (\<lambda>i. xs ! i) [0..<length xs] = xs"
  2764   by (rule nth_equalityI, auto)
  2765 
  2766 (* needs nth_equalityI *)
  2767 lemma list_all2_antisym:
  2768   "\<lbrakk> (\<And>x y. \<lbrakk>P x y; Q y x\<rbrakk> \<Longrightarrow> x = y); list_all2 P xs ys; list_all2 Q ys xs \<rbrakk> 
  2769   \<Longrightarrow> xs = ys"
  2770   apply (simp add: list_all2_conv_all_nth) 
  2771   apply (rule nth_equalityI, blast, simp)
  2772   done
  2773 
  2774 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  2775 -- {* The famous take-lemma. *}
  2776 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  2777 apply (simp add: le_max_iff_disj)
  2778 done
  2779 
  2780 
  2781 lemma take_Cons':
  2782      "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  2783 by (cases n) simp_all
  2784 
  2785 lemma drop_Cons':
  2786      "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  2787 by (cases n) simp_all
  2788 
  2789 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  2790 by (cases n) simp_all
  2791 
  2792 lemmas take_Cons_number_of = take_Cons'[of "number_of v"] for v
  2793 lemmas drop_Cons_number_of = drop_Cons'[of "number_of v"] for v
  2794 lemmas nth_Cons_number_of = nth_Cons'[of _ _ "number_of v"] for v
  2795 
  2796 declare take_Cons_number_of [simp] 
  2797         drop_Cons_number_of [simp] 
  2798         nth_Cons_number_of [simp] 
  2799 
  2800 
  2801 subsubsection {* @{text upto}: interval-list on @{typ int} *}
  2802 
  2803 (* FIXME make upto tail recursive? *)
  2804 
  2805 function upto :: "int \<Rightarrow> int \<Rightarrow> int list" ("(1[_../_])") where
  2806 "upto i j = (if i \<le> j then i # [i+1..j] else [])"
  2807 by auto
  2808 termination
  2809 by(relation "measure(%(i::int,j). nat(j - i + 1))") auto
  2810 
  2811 declare upto.simps[code, simp del]
  2812 
  2813 lemmas upto_rec_number_of[simp] = upto.simps[of "number_of m" "number_of n"] for m n
  2814 
  2815 lemma upto_empty[simp]: "j < i \<Longrightarrow> [i..j] = []"
  2816 by(simp add: upto.simps)
  2817 
  2818 lemma set_upto[simp]: "set[i..j] = {i..j}"
  2819 proof(induct i j rule:upto.induct)
  2820   case (1 i j)
  2821   from this show ?case
  2822     unfolding upto.simps[of i j] simp_from_to[of i j] by auto
  2823 qed
  2824 
  2825 
  2826 subsubsection {* @{text "distinct"} and @{text remdups} *}
  2827 
  2828 lemma distinct_tl:
  2829   "distinct xs \<Longrightarrow> distinct (tl xs)"
  2830   by (cases xs) simp_all
  2831 
  2832 lemma distinct_append [simp]:
  2833 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  2834 by (induct xs) auto
  2835 
  2836 lemma distinct_rev[simp]: "distinct(rev xs) = distinct xs"
  2837 by(induct xs) auto
  2838 
  2839 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  2840 by (induct xs) (auto simp add: insert_absorb)
  2841 
  2842 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  2843 by (induct xs) auto
  2844 
  2845 lemma distinct_remdups_id: "distinct xs ==> remdups xs = xs"
  2846 by (induct xs, auto)
  2847 
  2848 lemma remdups_id_iff_distinct [simp]: "remdups xs = xs \<longleftrightarrow> distinct xs"
  2849 by (metis distinct_remdups distinct_remdups_id)
  2850 
  2851 lemma finite_distinct_list: "finite A \<Longrightarrow> EX xs. set xs = A & distinct xs"
  2852 by (metis distinct_remdups finite_list set_remdups)
  2853 
  2854 lemma remdups_eq_nil_iff [simp]: "(remdups x = []) = (x = [])"
  2855 by (induct x, auto)
  2856 
  2857 lemma remdups_eq_nil_right_iff [simp]: "([] = remdups x) = (x = [])"
  2858 by (induct x, auto)
  2859 
  2860 lemma length_remdups_leq[iff]: "length(remdups xs) <= length xs"
  2861 by (induct xs) auto
  2862 
  2863 lemma length_remdups_eq[iff]:
  2864   "(length (remdups xs) = length xs) = (remdups xs = xs)"
  2865 apply(induct xs)
  2866  apply auto
  2867 apply(subgoal_tac "length (remdups xs) <= length xs")
  2868  apply arith
  2869 apply(rule length_remdups_leq)
  2870 done
  2871 
  2872 lemma remdups_filter: "remdups(filter P xs) = filter P (remdups xs)"
  2873 apply(induct xs)
  2874 apply auto
  2875 done
  2876 
  2877 lemma distinct_map:
  2878   "distinct(map f xs) = (distinct xs & inj_on f (set xs))"
  2879 by (induct xs) auto
  2880 
  2881 
  2882 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  2883 by (induct xs) auto
  2884 
  2885 lemma distinct_upt[simp]: "distinct[i..<j]"
  2886 by (induct j) auto
  2887 
  2888 lemma distinct_upto[simp]: "distinct[i..j]"
  2889 apply(induct i j rule:upto.induct)
  2890 apply(subst upto.simps)
  2891 apply(simp)
  2892 done
  2893 
  2894 lemma distinct_take[simp]: "distinct xs \<Longrightarrow> distinct (take i xs)"
  2895 apply(induct xs arbitrary: i)
  2896  apply simp
  2897 apply (case_tac i)
  2898  apply simp_all
  2899 apply(blast dest:in_set_takeD)
  2900 done
  2901 
  2902 lemma distinct_drop[simp]: "distinct xs \<Longrightarrow> distinct (drop i xs)"
  2903 apply(induct xs arbitrary: i)
  2904  apply simp
  2905 apply (case_tac i)
  2906  apply simp_all
  2907 done
  2908 
  2909 lemma distinct_list_update:
  2910 assumes d: "distinct xs" and a: "a \<notin> set xs - {xs!i}"
  2911 shows "distinct (xs[i:=a])"
  2912 proof (cases "i < length xs")
  2913   case True
  2914   with a have "a \<notin> set (take i xs @ xs ! i # drop (Suc i) xs) - {xs!i}"
  2915     apply (drule_tac id_take_nth_drop) by simp
  2916   with d True show ?thesis
  2917     apply (simp add: upd_conv_take_nth_drop)
  2918     apply (drule subst [OF id_take_nth_drop]) apply assumption
  2919     apply simp apply (cases "a = xs!i") apply simp by blast
  2920 next
  2921   case False with d show ?thesis by auto
  2922 qed
  2923 
  2924 lemma distinct_concat:
  2925   assumes "distinct xs"
  2926   and "\<And> ys. ys \<in> set xs \<Longrightarrow> distinct ys"
  2927   and "\<And> ys zs. \<lbrakk> ys \<in> set xs ; zs \<in> set xs ; ys \<noteq> zs \<rbrakk> \<Longrightarrow> set ys \<inter> set zs = {}"
  2928   shows "distinct (concat xs)"
  2929   using assms by (induct xs) auto
  2930 
  2931 text {* It is best to avoid this indexed version of distinct, but
  2932 sometimes it is useful. *}
  2933 
  2934 lemma distinct_conv_nth:
  2935 "distinct xs = (\<forall>i < size xs. \<forall>j < size xs. i \<noteq> j --> xs!i \<noteq> xs!j)"
  2936 apply (induct xs, simp, simp)
  2937 apply (rule iffI, clarsimp)
  2938  apply (case_tac i)
  2939 apply (case_tac j, simp)
  2940 apply (simp add: set_conv_nth)
  2941  apply (case_tac j)
  2942 apply (clarsimp simp add: set_conv_nth, simp)
  2943 apply (rule conjI)
  2944 (*TOO SLOW
  2945 apply (metis Zero_neq_Suc gr0_conv_Suc in_set_conv_nth lessI less_trans_Suc nth_Cons' nth_Cons_Suc)
  2946 *)
  2947  apply (clarsimp simp add: set_conv_nth)
  2948  apply (erule_tac x = 0 in allE, simp)
  2949  apply (erule_tac x = "Suc i" in allE, simp, clarsimp)
  2950 (*TOO SLOW
  2951 apply (metis Suc_Suc_eq lessI less_trans_Suc nth_Cons_Suc)
  2952 *)
  2953 apply (erule_tac x = "Suc i" in allE, simp)
  2954 apply (erule_tac x = "Suc j" in allE, simp)
  2955 done
  2956 
  2957 lemma nth_eq_iff_index_eq:
  2958  "\<lbrakk> distinct xs; i < length xs; j < length xs \<rbrakk> \<Longrightarrow> (xs!i = xs!j) = (i = j)"
  2959 by(auto simp: distinct_conv_nth)
  2960 
  2961 lemma distinct_card: "distinct xs ==> card (set xs) = size xs"
  2962 by (induct xs) auto
  2963 
  2964 lemma card_distinct: "card (set xs) = size xs ==> distinct xs"
  2965 proof (induct xs)
  2966   case Nil thus ?case by simp
  2967 next
  2968   case (Cons x xs)
  2969   show ?case
  2970   proof (cases "x \<in> set xs")
  2971     case False with Cons show ?thesis by simp
  2972   next
  2973     case True with Cons.prems
  2974     have "card (set xs) = Suc (length xs)"
  2975       by (simp add: card_insert_if split: split_if_asm)
  2976     moreover have "card (set xs) \<le> length xs" by (rule card_length)
  2977     ultimately have False by simp
  2978     thus ?thesis ..
  2979   qed
  2980 qed
  2981 
  2982 lemma distinct_length_filter: "distinct xs \<Longrightarrow> length (filter P xs) = card ({x. P x} Int set xs)"
  2983 by (induct xs) (auto)
  2984 
  2985 lemma not_distinct_decomp: "~ distinct ws ==> EX xs ys zs y. ws = xs@[y]@ys@[y]@zs"
  2986 apply (induct n == "length ws" arbitrary:ws) apply simp
  2987 apply(case_tac ws) apply simp
  2988 apply (simp split:split_if_asm)
  2989 apply (metis Cons_eq_appendI eq_Nil_appendI split_list)
  2990 done
  2991 
  2992 lemma not_distinct_conv_prefix:
  2993   defines "dec as xs y ys \<equiv> y \<in> set xs \<and> distinct xs \<and> as = xs @ y # ys"
  2994   shows "\<not>distinct as \<longleftrightarrow> (\<exists>xs y ys. dec as xs y ys)" (is "?L = ?R")
  2995 proof
  2996   assume "?L" then show "?R"
  2997   proof (induct "length as" arbitrary: as rule: less_induct)
  2998     case less
  2999     obtain xs ys zs y where decomp: "as = (xs @ y # ys) @ y # zs"
  3000       using not_distinct_decomp[OF less.prems] by auto
  3001     show ?case
  3002     proof (cases "distinct (xs @ y # ys)")
  3003       case True
  3004       with decomp have "dec as (xs @ y # ys) y zs" by (simp add: dec_def)
  3005       then show ?thesis by blast
  3006     next
  3007       case False
  3008       with less decomp obtain xs' y' ys' where "dec (xs @ y # ys) xs' y' ys'"
  3009         by atomize_elim auto
  3010       with decomp have "dec as xs' y' (ys' @ y # zs)" by (simp add: dec_def)
  3011       then show ?thesis by blast
  3012     qed
  3013   qed
  3014 qed (auto simp: dec_def)
  3015 
  3016 lemma length_remdups_concat:
  3017   "length (remdups (concat xss)) = card (\<Union>xs\<in>set xss. set xs)"
  3018   by (simp add: distinct_card [symmetric])
  3019 
  3020 lemma length_remdups_card_conv: "length(remdups xs) = card(set xs)"
  3021 proof -
  3022   have xs: "concat[xs] = xs" by simp
  3023   from length_remdups_concat[of "[xs]"] show ?thesis unfolding xs by simp
  3024 qed
  3025 
  3026 lemma remdups_remdups:
  3027   "remdups (remdups xs) = remdups xs"
  3028   by (induct xs) simp_all
  3029 
  3030 lemma distinct_butlast:
  3031   assumes "distinct xs"
  3032   shows "distinct (butlast xs)"
  3033 proof (cases "xs = []")
  3034   case False
  3035     from `xs \<noteq> []` obtain ys y where "xs = ys @ [y]" by (cases xs rule: rev_cases) auto
  3036     with `distinct xs` show ?thesis by simp
  3037 qed (auto)
  3038 
  3039 lemma remdups_map_remdups:
  3040   "remdups (map f (remdups xs)) = remdups (map f xs)"
  3041   by (induct xs) simp_all
  3042 
  3043 lemma distinct_zipI1:
  3044   assumes "distinct xs"
  3045   shows "distinct (zip xs ys)"
  3046 proof (rule zip_obtain_same_length)
  3047   fix xs' :: "'a list" and ys' :: "'b list" and n
  3048   assume "length xs' = length ys'"
  3049   assume "xs' = take n xs"
  3050   with assms have "distinct xs'" by simp
  3051   with `length xs' = length ys'` show "distinct (zip xs' ys')"
  3052     by (induct xs' ys' rule: list_induct2) (auto elim: in_set_zipE)
  3053 qed
  3054 
  3055 lemma distinct_zipI2:
  3056   assumes "distinct ys"
  3057   shows "distinct (zip xs ys)"
  3058 proof (rule zip_obtain_same_length)
  3059   fix xs' :: "'b list" and ys' :: "'a list" and n
  3060   assume "length xs' = length ys'"
  3061   assume "ys' = take n ys"
  3062   with assms have "distinct ys'" by simp
  3063   with `length xs' = length ys'` show "distinct (zip xs' ys')"
  3064     by (induct xs' ys' rule: list_induct2) (auto elim: in_set_zipE)
  3065 qed
  3066 
  3067 (* The next two lemmas help Sledgehammer. *)
  3068 
  3069 lemma distinct_singleton: "distinct [x]" by simp
  3070 
  3071 lemma distinct_length_2_or_more:
  3072 "distinct (a # b # xs) \<longleftrightarrow> (a \<noteq> b \<and> distinct (a # xs) \<and> distinct (b # xs))"
  3073 by (metis distinct.simps(2) hd.simps hd_in_set list.simps(2) set_ConsD set_rev_mp set_subset_Cons)
  3074 
  3075 subsubsection {* List summation: @{const listsum} and @{text"\<Sum>"}*}
  3076 
  3077 lemma (in monoid_add) listsum_simps [simp]:
  3078   "listsum [] = 0"
  3079   "listsum (x # xs) = x + listsum xs"
  3080   by (simp_all add: listsum_def)
  3081 
  3082 lemma (in monoid_add) listsum_append [simp]:
  3083   "listsum (xs @ ys) = listsum xs + listsum ys"
  3084   by (induct xs) (simp_all add: add.assoc)
  3085 
  3086 lemma (in comm_monoid_add) listsum_rev [simp]:
  3087   "listsum (rev xs) = listsum xs"
  3088   by (simp add: listsum_def foldr_def fold_rev fun_eq_iff add_ac)
  3089 
  3090 lemma (in monoid_add) fold_plus_listsum_rev:
  3091   "fold plus xs = plus (listsum (rev xs))"
  3092 proof
  3093   fix x
  3094   have "fold plus xs x = fold plus xs (x + 0)" by simp
  3095   also have "\<dots> = fold plus (x # xs) 0" by simp
  3096   also have "\<dots> = foldr plus (rev xs @ [x]) 0" by (simp add: foldr_def)
  3097   also have "\<dots> = listsum (rev xs @ [x])" by (simp add: listsum_def)
  3098   also have "\<dots> = listsum (rev xs) + listsum [x]" by simp
  3099   finally show "fold plus xs x = listsum (rev xs) + x" by simp
  3100 qed
  3101 
  3102 lemma (in semigroup_add) foldl_assoc:
  3103   "foldl plus (x + y) zs = x + foldl plus y zs"
  3104   by (simp add: foldl_def fold_commute_apply [symmetric] fun_eq_iff add_assoc)
  3105 
  3106 lemma (in ab_semigroup_add) foldr_conv_foldl:
  3107   "foldr plus xs a = foldl plus a xs"
  3108   by (simp add: foldl_def foldr_fold fun_eq_iff add_ac)
  3109 
  3110 text {*
  3111   Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  3112   difficult to use because it requires an additional transitivity step.
  3113 *}
  3114 
  3115 lemma start_le_sum:
  3116   fixes m n :: nat
  3117   shows "m \<le> n \<Longrightarrow> m \<le> foldl plus n ns"
  3118   by (simp add: foldl_def add_commute fold_plus_listsum_rev)
  3119 
  3120 lemma elem_le_sum:
  3121   fixes m n :: nat 
  3122   shows "n \<in> set ns \<Longrightarrow> n \<le> foldl plus 0 ns"
  3123   by (force intro: start_le_sum simp add: in_set_conv_decomp)
  3124 
  3125 lemma sum_eq_0_conv [iff]:
  3126   fixes m :: nat
  3127   shows "foldl plus m ns = 0 \<longleftrightarrow> m = 0 \<and> (\<forall>n \<in> set ns. n = 0)"
  3128   by (induct ns arbitrary: m) auto
  3129 
  3130 text{* Some syntactic sugar for summing a function over a list: *}
  3131 
  3132 syntax
  3133   "_listsum" :: "pttrn => 'a list => 'b => 'b"    ("(3SUM _<-_. _)" [0, 51, 10] 10)
  3134 syntax (xsymbols)
  3135   "_listsum" :: "pttrn => 'a list => 'b => 'b"    ("(3\<Sum>_\<leftarrow>_. _)" [0, 51, 10] 10)
  3136 syntax (HTML output)
  3137   "_listsum" :: "pttrn => 'a list => 'b => 'b"    ("(3\<Sum>_\<leftarrow>_. _)" [0, 51, 10] 10)
  3138 
  3139 translations -- {* Beware of argument permutation! *}
  3140   "SUM x<-xs. b" == "CONST listsum (CONST map (%x. b) xs)"
  3141   "\<Sum>x\<leftarrow>xs. b" == "CONST listsum (CONST map (%x. b) xs)"
  3142 
  3143 lemma (in comm_monoid_add) listsum_map_remove1:
  3144   "x \<in> set xs \<Longrightarrow> listsum (map f xs) = f x + listsum (map f (remove1 x xs))"
  3145   by (induct xs) (auto simp add: ac_simps)
  3146 
  3147 lemma (in monoid_add) list_size_conv_listsum:
  3148   "list_size f xs = listsum (map f xs) + size xs"
  3149   by (induct xs) auto
  3150 
  3151 lemma (in monoid_add) length_concat:
  3152   "length (concat xss) = listsum (map length xss)"
  3153   by (induct xss) simp_all
  3154 
  3155 lemma (in monoid_add) listsum_map_filter:
  3156   assumes "\<And>x. x \<in> set xs \<Longrightarrow> \<not> P x \<Longrightarrow> f x = 0"
  3157   shows "listsum (map f (filter P xs)) = listsum (map f xs)"
  3158   using assms by (induct xs) auto
  3159 
  3160 lemma (in monoid_add) distinct_listsum_conv_Setsum:
  3161   "distinct xs \<Longrightarrow> listsum xs = Setsum (set xs)"
  3162   by (induct xs) simp_all
  3163 
  3164 lemma listsum_eq_0_nat_iff_nat [simp]:
  3165   "listsum ns = (0::nat) \<longleftrightarrow> (\<forall>n \<in> set ns. n = 0)"
  3166   by (simp add: listsum_def foldr_conv_foldl)
  3167 
  3168 lemma elem_le_listsum_nat:
  3169   "k < size ns \<Longrightarrow> ns ! k \<le> listsum (ns::nat list)"
  3170 apply(induct ns arbitrary: k)
  3171  apply simp
  3172 apply(fastforce simp add:nth_Cons split: nat.split)
  3173 done
  3174 
  3175 lemma listsum_update_nat:
  3176   "k<size ns \<Longrightarrow> listsum (ns[k := (n::nat)]) = listsum ns + n - ns ! k"
  3177 apply(induct ns arbitrary:k)
  3178  apply (auto split:nat.split)
  3179 apply(drule elem_le_listsum_nat)
  3180 apply arith
  3181 done
  3182 
  3183 lemma (in monoid_add) listsum_triv:
  3184   "(\<Sum>x\<leftarrow>xs. r) = of_nat (length xs) * r"
  3185   by (induct xs) (simp_all add: left_distrib)
  3186 
  3187 lemma (in monoid_add) listsum_0 [simp]:
  3188   "(\<Sum>x\<leftarrow>xs. 0) = 0"
  3189   by (induct xs) (simp_all add: left_distrib)
  3190 
  3191 text{* For non-Abelian groups @{text xs} needs to be reversed on one side: *}
  3192 lemma (in ab_group_add) uminus_listsum_map:
  3193   "- listsum (map f xs) = listsum (map (uminus \<circ> f) xs)"
  3194   by (induct xs) simp_all
  3195 
  3196 lemma (in comm_monoid_add) listsum_addf:
  3197   "(\<Sum>x\<leftarrow>xs. f x + g x) = listsum (map f xs) + listsum (map g xs)"
  3198   by (induct xs) (simp_all add: algebra_simps)
  3199 
  3200 lemma (in ab_group_add) listsum_subtractf:
  3201   "(\<Sum>x\<leftarrow>xs. f x - g x) = listsum (map f xs) - listsum (map g xs)"
  3202   by (induct xs) (simp_all add: algebra_simps)
  3203 
  3204 lemma (in semiring_0) listsum_const_mult:
  3205   "(\<Sum>x\<leftarrow>xs. c * f x) = c * (\<Sum>x\<leftarrow>xs. f x)"
  3206   by (induct xs) (simp_all add: algebra_simps)
  3207 
  3208 lemma (in semiring_0) listsum_mult_const:
  3209   "(\<Sum>x\<leftarrow>xs. f x * c) = (\<Sum>x\<leftarrow>xs. f x) * c"
  3210   by (induct xs) (simp_all add: algebra_simps)
  3211 
  3212 lemma (in ordered_ab_group_add_abs) listsum_abs:
  3213   "\<bar>listsum xs\<bar> \<le> listsum (map abs xs)"
  3214   by (induct xs) (simp_all add: order_trans [OF abs_triangle_ineq])
  3215 
  3216 lemma listsum_mono:
  3217   fixes f g :: "'a \<Rightarrow> 'b::{monoid_add, ordered_ab_semigroup_add}"
  3218   shows "(\<And>x. x \<in> set xs \<Longrightarrow> f x \<le> g x) \<Longrightarrow> (\<Sum>x\<leftarrow>xs. f x) \<le> (\<Sum>x\<leftarrow>xs. g x)"
  3219   by (induct xs) (simp, simp add: add_mono)
  3220 
  3221 lemma (in monoid_add) listsum_distinct_conv_setsum_set:
  3222   "distinct xs \<Longrightarrow> listsum (map f xs) = setsum f (set xs)"
  3223   by (induct xs) simp_all
  3224 
  3225 lemma (in monoid_add) interv_listsum_conv_setsum_set_nat:
  3226   "listsum (map f [m..<n]) = setsum f (set [m..<n])"
  3227   by (simp add: listsum_distinct_conv_setsum_set)
  3228 
  3229 lemma (in monoid_add) interv_listsum_conv_setsum_set_int:
  3230   "listsum (map f [k..l]) = setsum f (set [k..l])"
  3231   by (simp add: listsum_distinct_conv_setsum_set)
  3232 
  3233 text {* General equivalence between @{const listsum} and @{const setsum} *}
  3234 lemma (in monoid_add) listsum_setsum_nth:
  3235   "listsum xs = (\<Sum> i = 0 ..< length xs. xs ! i)"
  3236   using interv_listsum_conv_setsum_set_nat [of "op ! xs" 0 "length xs"] by (simp add: map_nth)
  3237 
  3238 
  3239 subsubsection {* @{const insert} *}
  3240 
  3241 lemma in_set_insert [simp]:
  3242   "x \<in> set xs \<Longrightarrow> List.insert x xs = xs"
  3243   by (simp add: List.insert_def)
  3244 
  3245 lemma not_in_set_insert [simp]:
  3246   "x \<notin> set xs \<Longrightarrow> List.insert x xs = x # xs"
  3247   by (simp add: List.insert_def)
  3248 
  3249 lemma insert_Nil [simp]:
  3250   "List.insert x [] = [x]"
  3251   by simp
  3252 
  3253 lemma set_insert [simp]:
  3254   "set (List.insert x xs) = insert x (set xs)"
  3255   by (auto simp add: List.insert_def)
  3256 
  3257 lemma distinct_insert [simp]:
  3258   "distinct xs \<Longrightarrow> distinct (List.insert x xs)"
  3259   by (simp add: List.insert_def)
  3260 
  3261 lemma insert_remdups:
  3262   "List.insert x (remdups xs) = remdups (List.insert x xs)"
  3263   by (simp add: List.insert_def)
  3264 
  3265 
  3266 subsubsection {* @{text remove1} *}
  3267 
  3268 lemma remove1_append:
  3269   "remove1 x (xs @ ys) =
  3270   (if x \<in> set xs then remove1 x xs @ ys else xs @ remove1 x ys)"
  3271 by (induct xs) auto
  3272 
  3273 lemma remove1_commute: "remove1 x (remove1 y zs) = remove1 y (remove1 x zs)"
  3274 by (induct zs) auto
  3275 
  3276 lemma in_set_remove1[simp]:
  3277   "a \<noteq> b \<Longrightarrow> a : set(remove1 b xs) = (a : set xs)"
  3278 apply (induct xs)
  3279 apply auto
  3280 done
  3281 
  3282 lemma set_remove1_subset: "set(remove1 x xs) <= set xs"
  3283 apply(induct xs)
  3284  apply simp
  3285 apply simp
  3286 apply blast
  3287 done
  3288 
  3289 lemma set_remove1_eq [simp]: "distinct xs ==> set(remove1 x xs) = set xs - {x}"
  3290 apply(induct xs)
  3291  apply simp
  3292 apply simp
  3293 apply blast
  3294 done
  3295 
  3296 lemma length_remove1:
  3297   "length(remove1 x xs) = (if x : set xs then length xs - 1 else length xs)"
  3298 apply (induct xs)
  3299  apply (auto dest!:length_pos_if_in_set)
  3300 done
  3301 
  3302 lemma remove1_filter_not[simp]:
  3303   "\<not> P x \<Longrightarrow> remove1 x (filter P xs) = filter P xs"
  3304 by(induct xs) auto
  3305 
  3306 lemma filter_remove1:
  3307   "filter Q (remove1 x xs) = remove1 x (filter Q xs)"
  3308 by (induct xs) auto
  3309 
  3310 lemma notin_set_remove1[simp]: "x ~: set xs ==> x ~: set(remove1 y xs)"
  3311 apply(insert set_remove1_subset)
  3312 apply fast
  3313 done
  3314 
  3315 lemma distinct_remove1[simp]: "distinct xs ==> distinct(remove1 x xs)"
  3316 by (induct xs) simp_all
  3317 
  3318 lemma remove1_remdups:
  3319   "distinct xs \<Longrightarrow> remove1 x (remdups xs) = remdups (remove1 x xs)"
  3320   by (induct xs) simp_all
  3321 
  3322 lemma remove1_idem:
  3323   assumes "x \<notin> set xs"
  3324   shows "remove1 x xs = xs"
  3325   using assms by (induct xs) simp_all
  3326 
  3327 
  3328 subsubsection {* @{text removeAll} *}
  3329 
  3330 lemma removeAll_filter_not_eq:
  3331   "removeAll x = filter (\<lambda>y. x \<noteq> y)"
  3332 proof
  3333   fix xs
  3334   show "removeAll x xs = filter (\<lambda>y. x \<noteq> y) xs"
  3335     by (induct xs) auto
  3336 qed
  3337 
  3338 lemma removeAll_append[simp]:
  3339   "removeAll x (xs @ ys) = removeAll x xs @ removeAll x ys"
  3340 by (induct xs) auto
  3341 
  3342 lemma set_removeAll[simp]: "set(removeAll x xs) = set xs - {x}"
  3343 by (induct xs) auto
  3344 
  3345 lemma removeAll_id[simp]: "x \<notin> set xs \<Longrightarrow> removeAll x xs = xs"
  3346 by (induct xs) auto
  3347 
  3348 (* Needs count:: 'a \<Rightarrow> 'a list \<Rightarrow> nat
  3349 lemma length_removeAll:
  3350   "length(removeAll x xs) = length xs - count x xs"
  3351 *)
  3352 
  3353 lemma removeAll_filter_not[simp]:
  3354   "\<not> P x \<Longrightarrow> removeAll x (filter P xs) = filter P xs"
  3355 by(induct xs) auto
  3356 
  3357 lemma distinct_removeAll:
  3358   "distinct xs \<Longrightarrow> distinct (removeAll x xs)"
  3359   by (simp add: removeAll_filter_not_eq)
  3360 
  3361 lemma distinct_remove1_removeAll:
  3362   "distinct xs ==> remove1 x xs = removeAll x xs"
  3363 by (induct xs) simp_all
  3364 
  3365 lemma map_removeAll_inj_on: "inj_on f (insert x (set xs)) \<Longrightarrow>
  3366   map f (removeAll x xs) = removeAll (f x) (map f xs)"
  3367 by (induct xs) (simp_all add:inj_on_def)
  3368 
  3369 lemma map_removeAll_inj: "inj f \<Longrightarrow>
  3370   map f (removeAll x xs) = removeAll (f x) (map f xs)"
  3371 by(metis map_removeAll_inj_on subset_inj_on subset_UNIV)
  3372 
  3373 
  3374 subsubsection {* @{text replicate} *}
  3375 
  3376 lemma length_replicate [simp]: "length (replicate n x) = n"
  3377 by (induct n) auto
  3378 
  3379 lemma Ex_list_of_length: "\<exists>xs. length xs = n"
  3380 by (rule exI[of _ "replicate n undefined"]) simp
  3381 
  3382 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  3383 by (induct n) auto
  3384 
  3385 lemma map_replicate_const:
  3386   "map (\<lambda> x. k) lst = replicate (length lst) k"
  3387   by (induct lst) auto
  3388 
  3389 lemma replicate_app_Cons_same:
  3390 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  3391 by (induct n) auto
  3392 
  3393 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  3394 apply (induct n, simp)
  3395 apply (simp add: replicate_app_Cons_same)
  3396 done
  3397 
  3398 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  3399 by (induct n) auto
  3400 
  3401 text{* Courtesy of Matthias Daum: *}
  3402 lemma append_replicate_commute:
  3403   "replicate n x @ replicate k x = replicate k x @ replicate n x"
  3404 apply (simp add: replicate_add [THEN sym])
  3405 apply (simp add: add_commute)
  3406 done
  3407 
  3408 text{* Courtesy of Andreas Lochbihler: *}
  3409 lemma filter_replicate:
  3410   "filter P (replicate n x) = (if P x then replicate n x else [])"
  3411 by(induct n) auto
  3412 
  3413 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  3414 by (induct n) auto
  3415 
  3416 lemma tl_replicate [simp]: "tl (replicate n x) = replicate (n - 1) x"
  3417 by (induct n) auto
  3418 
  3419 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  3420 by (atomize (full), induct n) auto
  3421 
  3422 lemma nth_replicate[simp]: "i < n ==> (replicate n x)!i = x"
  3423 apply (induct n arbitrary: i, simp)
  3424 apply (simp add: nth_Cons split: nat.split)
  3425 done
  3426 
  3427 text{* Courtesy of Matthias Daum (2 lemmas): *}
  3428 lemma take_replicate[simp]: "take i (replicate k x) = replicate (min i k) x"
  3429 apply (case_tac "k \<le> i")
  3430  apply  (simp add: min_def)
  3431 apply (drule not_leE)
  3432 apply (simp add: min_def)
  3433 apply (subgoal_tac "replicate k x = replicate i x @ replicate (k - i) x")
  3434  apply  simp
  3435 apply (simp add: replicate_add [symmetric])
  3436 done
  3437 
  3438 lemma drop_replicate[simp]: "drop i (replicate k x) = replicate (k-i) x"
  3439 apply (induct k arbitrary: i)
  3440  apply simp
  3441 apply clarsimp
  3442 apply (case_tac i)
  3443  apply simp
  3444 apply clarsimp
  3445 done
  3446 
  3447 
  3448 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  3449 by (induct n) auto
  3450 
  3451 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  3452 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  3453 
  3454 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  3455 by auto
  3456 
  3457 lemma in_set_replicate[simp]: "(x : set (replicate n y)) = (x = y & n \<noteq> 0)"
  3458 by (simp add: set_replicate_conv_if)
  3459 
  3460 lemma Ball_set_replicate[simp]:
  3461   "(ALL x : set(replicate n a). P x) = (P a | n=0)"
  3462 by(simp add: set_replicate_conv_if)
  3463 
  3464 lemma Bex_set_replicate[simp]:
  3465   "(EX x : set(replicate n a). P x) = (P a & n\<noteq>0)"
  3466 by(simp add: set_replicate_conv_if)
  3467 
  3468 lemma replicate_append_same:
  3469   "replicate i x @ [x] = x # replicate i x"
  3470   by (induct i) simp_all
  3471 
  3472 lemma map_replicate_trivial:
  3473   "map (\<lambda>i. x) [0..<i] = replicate i x"
  3474   by (induct i) (simp_all add: replicate_append_same)
  3475 
  3476 lemma concat_replicate_trivial[simp]:
  3477   "concat (replicate i []) = []"
  3478   by (induct i) (auto simp add: map_replicate_const)
  3479 
  3480 lemma replicate_empty[simp]: "(replicate n x = []) \<longleftrightarrow> n=0"
  3481 by (induct n) auto
  3482 
  3483 lemma empty_replicate[simp]: "([] = replicate n x) \<longleftrightarrow> n=0"
  3484 by (induct n) auto
  3485 
  3486 lemma replicate_eq_replicate[simp]:
  3487   "(replicate m x = replicate n y) \<longleftrightarrow> (m=n & (m\<noteq>0 \<longrightarrow> x=y))"
  3488 apply(induct m arbitrary: n)
  3489  apply simp
  3490 apply(induct_tac n)
  3491 apply auto
  3492 done
  3493 
  3494 lemma replicate_length_filter:
  3495   "replicate (length (filter (\<lambda>y. x = y) xs)) x = filter (\<lambda>y. x = y) xs"
  3496   by (induct xs) auto
  3497 
  3498 lemma comm_append_are_replicate:
  3499   fixes xs ys :: "'a list"
  3500   assumes "xs \<noteq> []" "ys \<noteq> []"
  3501   assumes "xs @ ys = ys @ xs"
  3502   shows "\<exists>m n zs. concat (replicate m zs) = xs \<and> concat (replicate n zs) = ys"
  3503   using assms
  3504 proof (induct "length (xs @ ys)" arbitrary: xs ys rule: less_induct)
  3505   case less
  3506 
  3507   def xs' \<equiv> "if (length xs \<le> length ys) then xs else ys"
  3508     and ys' \<equiv> "if (length xs \<le> length ys) then ys else xs"
  3509   then have
  3510     prems': "length xs' \<le> length ys'"
  3511             "xs' @ ys' = ys' @ xs'"
  3512       and "xs' \<noteq> []"
  3513       and len: "length (xs @ ys) = length (xs' @ ys')"
  3514     using less by (auto intro: less.hyps)
  3515 
  3516   from prems'
  3517   obtain ws where "ys' = xs' @ ws"
  3518     by (auto simp: append_eq_append_conv2)
  3519 
  3520   have "\<exists>m n zs. concat (replicate m zs) = xs' \<and> concat (replicate n zs) = ys'"
  3521   proof (cases "ws = []")
  3522     case True
  3523     then have "concat (replicate 1 xs') = xs'"
  3524       and "concat (replicate 1 xs') = ys'"
  3525       using `ys' = xs' @ ws` by auto
  3526     then show ?thesis by blast
  3527   next
  3528     case False
  3529     from `ys' = xs' @ ws` and `xs' @ ys' = ys' @ xs'`
  3530     have "xs' @ ws = ws @ xs'" by simp
  3531     then have "\<exists>m n zs. concat (replicate m zs) = xs' \<and> concat (replicate n zs) = ws"
  3532       using False and `xs' \<noteq> []` and `ys' = xs' @ ws` and len
  3533       by (intro less.hyps) auto
  3534     then obtain m n zs where "concat (replicate m zs) = xs'"
  3535       and "concat (replicate n zs) = ws" by blast
  3536     moreover
  3537     then have "concat (replicate (m + n) zs) = ys'"
  3538       using `ys' = xs' @ ws`
  3539       by (simp add: replicate_add)
  3540     ultimately
  3541     show ?thesis by blast
  3542   qed
  3543   then show ?case
  3544     using xs'_def ys'_def by metis
  3545 qed
  3546 
  3547 lemma comm_append_is_replicate:
  3548   fixes xs ys :: "'a list"
  3549   assumes "xs \<noteq> []" "ys \<noteq> []"
  3550   assumes "xs @ ys = ys @ xs"
  3551   shows "\<exists>n zs. n > 1 \<and> concat (replicate n zs) = xs @ ys"
  3552 
  3553 proof -
  3554   obtain m n zs where "concat (replicate m zs) = xs"
  3555     and "concat (replicate n zs) = ys"
  3556     using assms by (metis comm_append_are_replicate)
  3557   then have "m + n > 1" and "concat (replicate (m+n) zs) = xs @ ys"
  3558     using `xs \<noteq> []` and `ys \<noteq> []`
  3559     by (auto simp: replicate_add)
  3560   then show ?thesis by blast
  3561 qed
  3562 
  3563 
  3564 subsubsection{*@{text rotate1} and @{text rotate}*}
  3565 
  3566 lemma rotate0[simp]: "rotate 0 = id"
  3567 by(simp add:rotate_def)
  3568 
  3569 lemma rotate_Suc[simp]: "rotate (Suc n) xs = rotate1(rotate n xs)"
  3570 by(simp add:rotate_def)
  3571 
  3572 lemma rotate_add:
  3573   "rotate (m+n) = rotate m o rotate n"
  3574 by(simp add:rotate_def funpow_add)
  3575 
  3576 lemma rotate_rotate: "rotate m (rotate n xs) = rotate (m+n) xs"
  3577 by(simp add:rotate_add)
  3578 
  3579 lemma rotate1_rotate_swap: "rotate1 (rotate n xs) = rotate n (rotate1 xs)"
  3580 by(simp add:rotate_def funpow_swap1)
  3581 
  3582 lemma rotate1_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate1 xs = xs"
  3583 by(cases xs) simp_all
  3584 
  3585 lemma rotate_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate n xs = xs"
  3586 apply(induct n)
  3587  apply simp
  3588 apply (simp add:rotate_def)
  3589 done
  3590 
  3591 lemma rotate1_hd_tl: "xs \<noteq> [] \<Longrightarrow> rotate1 xs = tl xs @ [hd xs]"
  3592 by (cases xs) simp_all
  3593 
  3594 lemma rotate_drop_take:
  3595   "rotate n xs = drop (n mod length xs) xs @ take (n mod length xs) xs"
  3596 apply(induct n)
  3597  apply simp
  3598 apply(simp add:rotate_def)
  3599 apply(cases "xs = []")
  3600  apply (simp)
  3601 apply(case_tac "n mod length xs = 0")
  3602  apply(simp add:mod_Suc)
  3603  apply(simp add: rotate1_hd_tl drop_Suc take_Suc)
  3604 apply(simp add:mod_Suc rotate1_hd_tl drop_Suc[symmetric] drop_tl[symmetric]
  3605                 take_hd_drop linorder_not_le)
  3606 done
  3607 
  3608 lemma rotate_conv_mod: "rotate n xs = rotate (n mod length xs) xs"
  3609 by(simp add:rotate_drop_take)
  3610 
  3611 lemma rotate_id[simp]: "n mod length xs = 0 \<Longrightarrow> rotate n xs = xs"
  3612 by(simp add:rotate_drop_take)
  3613 
  3614 lemma length_rotate1[simp]: "length(rotate1 xs) = length xs"
  3615 by (cases xs) simp_all
  3616 
  3617 lemma length_rotate[simp]: "length(rotate n xs) = length xs"
  3618 by (induct n arbitrary: xs) (simp_all add:rotate_def)
  3619 
  3620 lemma distinct1_rotate[simp]: "distinct(rotate1 xs) = distinct xs"
  3621 by (cases xs) auto
  3622 
  3623 lemma distinct_rotate[simp]: "distinct(rotate n xs) = distinct xs"
  3624 by (induct n) (simp_all add:rotate_def)
  3625 
  3626 lemma rotate_map: "rotate n (map f xs) = map f (rotate n xs)"
  3627 by(simp add:rotate_drop_take take_map drop_map)
  3628 
  3629 lemma set_rotate1[simp]: "set(rotate1 xs) = set xs"
  3630 by (cases xs) auto
  3631 
  3632 lemma set_rotate[simp]: "set(rotate n xs) = set xs"
  3633 by (induct n) (simp_all add:rotate_def)
  3634 
  3635 lemma rotate1_is_Nil_conv[simp]: "(rotate1 xs = []) = (xs = [])"
  3636 by (cases xs) auto
  3637 
  3638 lemma rotate_is_Nil_conv[simp]: "(rotate n xs = []) = (xs = [])"
  3639 by (induct n) (simp_all add:rotate_def)
  3640 
  3641 lemma rotate_rev:
  3642   "rotate n (rev xs) = rev(rotate (length xs - (n mod length xs)) xs)"
  3643 apply(simp add:rotate_drop_take rev_drop rev_take)
  3644 apply(cases "length xs = 0")
  3645  apply simp
  3646 apply(cases "n mod length xs = 0")
  3647  apply simp
  3648 apply(simp add:rotate_drop_take rev_drop rev_take)
  3649 done
  3650 
  3651 lemma hd_rotate_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd(rotate n xs) = xs!(n mod length xs)"
  3652 apply(simp add:rotate_drop_take hd_append hd_drop_conv_nth hd_conv_nth)
  3653 apply(subgoal_tac "length xs \<noteq> 0")
  3654  prefer 2 apply simp
  3655 using mod_less_divisor[of "length xs" n] by arith
  3656 
  3657 
  3658 subsubsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  3659 
  3660 lemma sublist_empty [simp]: "sublist xs {} = []"
  3661 by (auto simp add: sublist_def)
  3662 
  3663 lemma sublist_nil [simp]: "sublist [] A = []"
  3664 by (auto simp add: sublist_def)
  3665 
  3666 lemma length_sublist:
  3667   "length(sublist xs I) = card{i. i < length xs \<and> i : I}"
  3668 by(simp add: sublist_def length_filter_conv_card cong:conj_cong)
  3669 
  3670 lemma sublist_shift_lemma_Suc:
  3671   "map fst (filter (%p. P(Suc(snd p))) (zip xs is)) =
  3672    map fst (filter (%p. P(snd p)) (zip xs (map Suc is)))"
  3673 apply(induct xs arbitrary: "is")
  3674  apply simp
  3675 apply (case_tac "is")
  3676  apply simp
  3677 apply simp
  3678 done
  3679 
  3680 lemma sublist_shift_lemma:
  3681      "map fst [p<-zip xs [i..<i + length xs] . snd p : A] =
  3682       map fst [p<-zip xs [0..<length xs] . snd p + i : A]"
  3683 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  3684 
  3685 lemma sublist_append:
  3686      "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  3687 apply (unfold sublist_def)
  3688 apply (induct l' rule: rev_induct, simp)
  3689 apply (simp add: upt_add_eq_append[of 0] sublist_shift_lemma)
  3690 apply (simp add: add_commute)
  3691 done
  3692 
  3693 lemma sublist_Cons:
  3694 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  3695 apply (induct l rule: rev_induct)
  3696  apply (simp add: sublist_def)
  3697 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  3698 done
  3699 
  3700 lemma set_sublist: "set(sublist xs I) = {xs!i|i. i<size xs \<and> i \<in> I}"
  3701 apply(induct xs arbitrary: I)
  3702 apply(auto simp: sublist_Cons nth_Cons split:nat.split dest!: gr0_implies_Suc)
  3703 done
  3704 
  3705 lemma set_sublist_subset: "set(sublist xs I) \<subseteq> set xs"
  3706 by(auto simp add:set_sublist)
  3707 
  3708 lemma notin_set_sublistI[simp]: "x \<notin> set xs \<Longrightarrow> x \<notin> set(sublist xs I)"
  3709 by(auto simp add:set_sublist)
  3710 
  3711 lemma in_set_sublistD: "x \<in> set(sublist xs I) \<Longrightarrow> x \<in> set xs"
  3712 by(auto simp add:set_sublist)
  3713 
  3714 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  3715 by (simp add: sublist_Cons)
  3716 
  3717 
  3718 lemma distinct_sublistI[simp]: "distinct xs \<Longrightarrow> distinct(sublist xs I)"
  3719 apply(induct xs arbitrary: I)
  3720  apply simp
  3721 apply(auto simp add:sublist_Cons)
  3722 done
  3723 
  3724 
  3725 lemma sublist_upt_eq_take [simp]: "sublist l {..<n} = take n l"
  3726 apply (induct l rule: rev_induct, simp)
  3727 apply (simp split: nat_diff_split add: sublist_append)
  3728 done
  3729 
  3730 lemma filter_in_sublist:
  3731  "distinct xs \<Longrightarrow> filter (%x. x \<in> set(sublist xs s)) xs = sublist xs s"
  3732 proof (induct xs arbitrary: s)
  3733   case Nil thus ?case by simp
  3734 next
  3735   case (Cons a xs)
  3736   moreover hence "!x. x: set xs \<longrightarrow> x \<noteq> a" by auto
  3737   ultimately show ?case by(simp add: sublist_Cons cong:filter_cong)
  3738 qed
  3739 
  3740 
  3741 subsubsection {* @{const splice} *}
  3742 
  3743 lemma splice_Nil2 [simp, code]: "splice xs [] = xs"
  3744 by (cases xs) simp_all
  3745 
  3746 declare splice.simps(1,3)[code]
  3747 declare splice.simps(2)[simp del]
  3748 
  3749 lemma length_splice[simp]: "length(splice xs ys) = length xs + length ys"
  3750 by (induct xs ys rule: splice.induct) auto
  3751 
  3752 
  3753 subsubsection {* Transpose *}
  3754 
  3755 function transpose where
  3756 "transpose []             = []" |
  3757 "transpose ([]     # xss) = transpose xss" |
  3758 "transpose ((x#xs) # xss) =
  3759   (x # [h. (h#t) \<leftarrow> xss]) # transpose (xs # [t. (h#t) \<leftarrow> xss])"
  3760 by pat_completeness auto
  3761 
  3762 lemma transpose_aux_filter_head:
  3763   "concat (map (list_case [] (\<lambda>h t. [h])) xss) =
  3764   map (\<lambda>xs. hd xs) [ys\<leftarrow>xss . ys \<noteq> []]"
  3765   by (induct xss) (auto split: list.split)
  3766 
  3767 lemma transpose_aux_filter_tail:
  3768   "concat (map (list_case [] (\<lambda>h t. [t])) xss) =
  3769   map (\<lambda>xs. tl xs) [ys\<leftarrow>xss . ys \<noteq> []]"
  3770   by (induct xss) (auto split: list.split)
  3771 
  3772 lemma transpose_aux_max:
  3773   "max (Suc (length xs)) (foldr (\<lambda>xs. max (length xs)) xss 0) =
  3774   Suc (max (length xs) (foldr (\<lambda>x. max (length x - Suc 0)) [ys\<leftarrow>xss . ys\<noteq>[]] 0))"
  3775   (is "max _ ?foldB = Suc (max _ ?foldA)")
  3776 proof (cases "[ys\<leftarrow>xss . ys\<noteq>[]] = []")
  3777   case True
  3778   hence "foldr (\<lambda>xs. max (length xs)) xss 0 = 0"
  3779   proof (induct xss)
  3780     case (Cons x xs)
  3781     moreover hence "x = []" by (cases x) auto
  3782     ultimately show ?case by auto
  3783   qed simp
  3784   thus ?thesis using True by simp
  3785 next
  3786   case False
  3787 
  3788   have foldA: "?foldA = foldr (\<lambda>x. max (length x)) [ys\<leftarrow>xss . ys \<noteq> []] 0 - 1"
  3789     by (induct xss) auto
  3790   have foldB: "?foldB = foldr (\<lambda>x. max (length x)) [ys\<leftarrow>xss . ys \<noteq> []] 0"
  3791     by (induct xss) auto
  3792 
  3793   have "0 < ?foldB"
  3794   proof -
  3795     from False
  3796     obtain z zs where zs: "[ys\<leftarrow>xss . ys \<noteq> []] = z#zs" by (auto simp: neq_Nil_conv)
  3797     hence "z \<in> set ([ys\<leftarrow>xss . ys \<noteq> []])" by auto
  3798     hence "z \<noteq> []" by auto
  3799     thus ?thesis
  3800       unfolding foldB zs
  3801       by (auto simp: max_def intro: less_le_trans)
  3802   qed
  3803   thus ?thesis
  3804     unfolding foldA foldB max_Suc_Suc[symmetric]
  3805     by simp
  3806 qed
  3807 
  3808 termination transpose
  3809   by (relation "measure (\<lambda>xs. foldr (\<lambda>xs. max (length xs)) xs 0 + length xs)")
  3810      (auto simp: transpose_aux_filter_tail foldr_map comp_def transpose_aux_max less_Suc_eq_le)
  3811 
  3812 lemma transpose_empty: "(transpose xs = []) \<longleftrightarrow> (\<forall>x \<in> set xs. x = [])"
  3813   by (induct rule: transpose.induct) simp_all
  3814 
  3815 lemma length_transpose:
  3816   fixes xs :: "'a list list"
  3817   shows "length (transpose xs) = foldr (\<lambda>xs. max (length xs)) xs 0"
  3818   by (induct rule: transpose.induct)
  3819     (auto simp: transpose_aux_filter_tail foldr_map comp_def transpose_aux_max
  3820                 max_Suc_Suc[symmetric] simp del: max_Suc_Suc)
  3821 
  3822 lemma nth_transpose:
  3823   fixes xs :: "'a list list"
  3824   assumes "i < length (transpose xs)"
  3825   shows "transpose xs ! i = map (\<lambda>xs. xs ! i) [ys \<leftarrow> xs. i < length ys]"
  3826 using assms proof (induct arbitrary: i rule: transpose.induct)
  3827   case (3 x xs xss)
  3828   def XS == "(x # xs) # xss"
  3829   hence [simp]: "XS \<noteq> []" by auto
  3830   thus ?case
  3831   proof (cases i)
  3832     case 0
  3833     thus ?thesis by (simp add: transpose_aux_filter_head hd_conv_nth)
  3834   next
  3835     case (Suc j)
  3836     have *: "\<And>xss. xs # map tl xss = map tl ((x#xs)#xss)" by simp
  3837     have **: "\<And>xss. (x#xs) # filter (\<lambda>ys. ys \<noteq> []) xss = filter (\<lambda>ys. ys \<noteq> []) ((x#xs)#xss)" by simp
  3838     { fix x have "Suc j < length x \<longleftrightarrow> x \<noteq> [] \<and> j < length x - Suc 0"
  3839       by (cases x) simp_all
  3840     } note *** = this
  3841 
  3842     have j_less: "j < length (transpose (xs # concat (map (list_case [] (\<lambda>h t. [t])) xss)))"
  3843       using "3.prems" by (simp add: transpose_aux_filter_tail length_transpose Suc)
  3844 
  3845     show ?thesis
  3846       unfolding transpose.simps `i = Suc j` nth_Cons_Suc "3.hyps"[OF j_less]
  3847       apply (auto simp: transpose_aux_filter_tail filter_map comp_def length_transpose * ** *** XS_def[symmetric])
  3848       apply (rule_tac y=x in list.exhaust)
  3849       by auto
  3850   qed
  3851 qed simp_all
  3852 
  3853 lemma transpose_map_map:
  3854   "transpose (map (map f) xs) = map (map f) (transpose xs)"
  3855 proof (rule nth_equalityI, safe)
  3856   have [simp]: "length (transpose (map (map f) xs)) = length (transpose xs)"
  3857     by (simp add: length_transpose foldr_map comp_def)
  3858   show "length (transpose (map (map f) xs)) = length (map (map f) (transpose xs))" by simp
  3859 
  3860   fix i assume "i < length (transpose (map (map f) xs))"
  3861   thus "transpose (map (map f) xs) ! i = map (map f) (transpose xs) ! i"
  3862     by (simp add: nth_transpose filter_map comp_def)
  3863 qed
  3864 
  3865 
  3866 subsubsection {* (In)finiteness *}
  3867 
  3868 lemma finite_maxlen:
  3869   "finite (M::'a list set) ==> EX n. ALL s:M. size s < n"
  3870 proof (induct rule: finite.induct)
  3871   case emptyI show ?case by simp
  3872 next
  3873   case (insertI M xs)
  3874   then obtain n where "\<forall>s\<in>M. length s < n" by blast
  3875   hence "ALL s:insert xs M. size s < max n (size xs) + 1" by auto
  3876   thus ?case ..
  3877 qed
  3878 
  3879 lemma lists_length_Suc_eq:
  3880   "{xs. set xs \<subseteq> A \<and> length xs = Suc n} =
  3881     (\<lambda>(xs, n). n#xs) ` ({xs. set xs \<subseteq> A \<and> length xs = n} \<times> A)"
  3882   by (auto simp: length_Suc_conv)
  3883 
  3884 lemma
  3885   assumes "finite A"
  3886   shows finite_lists_length_eq: "finite {xs. set xs \<subseteq> A \<and> length xs = n}"
  3887   and card_lists_length_eq: "card {xs. set xs \<subseteq> A \<and> length xs = n} = (card A)^n"
  3888   using `finite A`
  3889   by (induct n)
  3890      (auto simp: card_image inj_split_Cons lists_length_Suc_eq cong: conj_cong)
  3891 
  3892 lemma finite_lists_length_le:
  3893   assumes "finite A" shows "finite {xs. set xs \<subseteq> A \<and> length xs \<le> n}"
  3894  (is "finite ?S")
  3895 proof-
  3896   have "?S = (\<Union>n\<in>{0..n}. {xs. set xs \<subseteq> A \<and> length xs = n})" by auto
  3897   thus ?thesis by (auto intro: finite_lists_length_eq[OF `finite A`])
  3898 qed
  3899 
  3900 lemma card_lists_length_le:
  3901   assumes "finite A" shows "card {xs. set xs \<subseteq> A \<and> length xs \<le> n} = (\<Sum>i\<le>n. card A^i)"
  3902 proof -
  3903   have "(\<Sum>i\<le>n. card A^i) = card (\<Union>i\<le>n. {xs. set xs \<subseteq> A \<and> length xs = i})"
  3904     using `finite A`
  3905     by (subst card_UN_disjoint)
  3906        (auto simp add: card_lists_length_eq finite_lists_length_eq)
  3907   also have "(\<Union>i\<le>n. {xs. set xs \<subseteq> A \<and> length xs = i}) = {xs. set xs \<subseteq> A \<and> length xs \<le> n}"
  3908     by auto
  3909   finally show ?thesis by simp
  3910 qed
  3911 
  3912 lemma card_lists_distinct_length_eq:
  3913   assumes "k < card A"
  3914   shows "card {xs. length xs = k \<and> distinct xs \<and> set xs \<subseteq> A} = \<Prod>{card A - k + 1 .. card A}"
  3915 using assms
  3916 proof (induct k)
  3917   case 0
  3918   then have "{xs. length xs = 0 \<and> distinct xs \<and> set xs \<subseteq> A} = {[]}" by auto
  3919   then show ?case by simp
  3920 next
  3921   case (Suc k)
  3922   let "?k_list" = "\<lambda>k xs. length xs = k \<and> distinct xs \<and> set xs \<subseteq> A"
  3923   have inj_Cons: "\<And>A. inj_on (\<lambda>(xs, n). n # xs) A"  by (rule inj_onI) auto
  3924 
  3925   from Suc have "k < card A" by simp
  3926   moreover have "finite A" using assms by (simp add: card_ge_0_finite)
  3927   moreover have "finite {xs. ?k_list k xs}"
  3928     using finite_lists_length_eq[OF `finite A`, of k]
  3929     by - (rule finite_subset, auto)
  3930   moreover have "\<And>i j. i \<noteq> j \<longrightarrow> {i} \<times> (A - set i) \<inter> {j} \<times> (A - set j) = {}"
  3931     by auto
  3932   moreover have "\<And>i. i \<in>Collect (?k_list k) \<Longrightarrow> card (A - set i) = card A - k"
  3933     by (simp add: card_Diff_subset distinct_card)
  3934   moreover have "{xs. ?k_list (Suc k) xs} =
  3935       (\<lambda>(xs, n). n#xs) ` \<Union>(\<lambda>xs. {xs} \<times> (A - set xs)) ` {xs. ?k_list k xs}"
  3936     by (auto simp: length_Suc_conv)
  3937   moreover
  3938   have "Suc (card A - Suc k) = card A - k" using Suc.prems by simp
  3939   then have "(card A - k) * \<Prod>{Suc (card A - k)..card A} = \<Prod>{Suc (card A - Suc k)..card A}"
  3940     by (subst setprod_insert[symmetric]) (simp add: atLeastAtMost_insertL)+
  3941   ultimately show ?case
  3942     by (simp add: card_image inj_Cons card_UN_disjoint Suc.hyps algebra_simps)
  3943 qed
  3944 
  3945 lemma infinite_UNIV_listI: "~ finite(UNIV::'a list set)"
  3946 apply(rule notI)
  3947 apply(drule finite_maxlen)
  3948 apply (metis UNIV_I length_replicate less_not_refl)
  3949 done
  3950 
  3951 
  3952 subsection {* Sorting *}
  3953 
  3954 text{* Currently it is not shown that @{const sort} returns a
  3955 permutation of its input because the nicest proof is via multisets,
  3956 which are not yet available. Alternatively one could define a function
  3957 that counts the number of occurrences of an element in a list and use
  3958 that instead of multisets to state the correctness property. *}
  3959 
  3960 context linorder
  3961 begin
  3962 
  3963 lemma length_insort [simp]:
  3964   "length (insort_key f x xs) = Suc (length xs)"
  3965   by (induct xs) simp_all
  3966 
  3967 lemma insort_key_left_comm:
  3968   assumes "f x \<noteq> f y"
  3969   shows "insort_key f y (insort_key f x xs) = insort_key f x (insort_key f y xs)"
  3970   by (induct xs) (auto simp add: assms dest: antisym)
  3971 
  3972 lemma insort_left_comm:
  3973   "insort x (insort y xs) = insort y (insort x xs)"
  3974   by (cases "x = y") (auto intro: insort_key_left_comm)
  3975 
  3976 lemma comp_fun_commute_insort:
  3977   "comp_fun_commute insort"
  3978 proof
  3979 qed (simp add: insort_left_comm fun_eq_iff)
  3980 
  3981 lemma sort_key_simps [simp]:
  3982   "sort_key f [] = []"
  3983   "sort_key f (x#xs) = insort_key f x (sort_key f xs)"
  3984   by (simp_all add: sort_key_def)
  3985 
  3986 lemma (in linorder) sort_key_conv_fold:
  3987   assumes "inj_on f (set xs)"
  3988   shows "sort_key f xs = fold (insort_key f) xs []"
  3989 proof -
  3990   have "fold (insort_key f) (rev xs) = fold (insort_key f) xs"
  3991   proof (rule fold_rev, rule ext)
  3992     fix zs
  3993     fix x y
  3994     assume "x \<in> set xs" "y \<in> set xs"
  3995     with assms have *: "f y = f x \<Longrightarrow> y = x" by (auto dest: inj_onD)
  3996     have **: "x = y \<longleftrightarrow> y = x" by auto
  3997     show "(insort_key f y \<circ> insort_key f x) zs = (insort_key f x \<circ> insort_key f y) zs"
  3998       by (induct zs) (auto intro: * simp add: **)
  3999   qed
  4000   then show ?thesis by (simp add: sort_key_def foldr_def)
  4001 qed
  4002 
  4003 lemma (in linorder) sort_conv_fold:
  4004   "sort xs = fold insort xs []"
  4005   by (rule sort_key_conv_fold) simp
  4006 
  4007 lemma length_sort[simp]: "length (sort_key f xs) = length xs"
  4008 by (induct xs, auto)
  4009 
  4010 lemma sorted_Cons: "sorted (x#xs) = (sorted xs & (ALL y:set xs. x <= y))"
  4011 apply(induct xs arbitrary: x) apply simp
  4012 by simp (blast intro: order_trans)
  4013 
  4014 lemma sorted_tl:
  4015   "sorted xs \<Longrightarrow> sorted (tl xs)"
  4016   by (cases xs) (simp_all add: sorted_Cons)
  4017 
  4018 lemma sorted_append:
  4019   "sorted (xs@ys) = (sorted xs & sorted ys & (\<forall>x \<in> set xs. \<forall>y \<in> set ys. x\<le>y))"
  4020 by (induct xs) (auto simp add:sorted_Cons)
  4021 
  4022 lemma sorted_nth_mono:
  4023   "sorted xs \<Longrightarrow> i \<le> j \<Longrightarrow> j < length xs \<Longrightarrow> xs!i \<le> xs!j"
  4024 by (induct xs arbitrary: i j) (auto simp:nth_Cons' sorted_Cons)
  4025 
  4026 lemma sorted_rev_nth_mono:
  4027   "sorted (rev xs) \<Longrightarrow> i \<le> j \<Longrightarrow> j < length xs \<Longrightarrow> xs!j \<le> xs!i"
  4028 using sorted_nth_mono[ of "rev xs" "length xs - j - 1" "length xs - i - 1"]
  4029       rev_nth[of "length xs - i - 1" "xs"] rev_nth[of "length xs - j - 1" "xs"]
  4030 by auto
  4031 
  4032 lemma sorted_nth_monoI:
  4033   "(\<And> i j. \<lbrakk> i \<le> j ; j < length xs \<rbrakk> \<Longrightarrow> xs ! i \<le> xs ! j) \<Longrightarrow> sorted xs"
  4034 proof (induct xs)
  4035   case (Cons x xs)
  4036   have "sorted xs"
  4037   proof (rule Cons.hyps)
  4038     fix i j assume "i \<le> j" and "j < length xs"
  4039     with Cons.prems[of "Suc i" "Suc j"]
  4040     show "xs ! i \<le> xs ! j" by auto
  4041   qed
  4042   moreover
  4043   {
  4044     fix y assume "y \<in> set xs"
  4045     then obtain j where "j < length xs" and "xs ! j = y"
  4046       unfolding in_set_conv_nth by blast
  4047     with Cons.prems[of 0 "Suc j"]
  4048     have "x \<le> y"
  4049       by auto
  4050   }
  4051   ultimately
  4052   show ?case
  4053     unfolding sorted_Cons by auto
  4054 qed simp
  4055 
  4056 lemma sorted_equals_nth_mono:
  4057   "sorted xs = (\<forall>j < length xs. \<forall>i \<le> j. xs ! i \<le> xs ! j)"
  4058 by (auto intro: sorted_nth_monoI sorted_nth_mono)
  4059 
  4060 lemma set_insort: "set(insort_key f x xs) = insert x (set xs)"
  4061 by (induct xs) auto
  4062 
  4063 lemma set_sort[simp]: "set(sort_key f xs) = set xs"
  4064 by (induct xs) (simp_all add:set_insort)
  4065 
  4066 lemma distinct_insort: "distinct (insort_key f x xs) = (x \<notin> set xs \<and> distinct xs)"
  4067 by(induct xs)(auto simp:set_insort)
  4068 
  4069 lemma distinct_sort[simp]: "distinct (sort_key f xs) = distinct xs"
  4070   by (induct xs) (simp_all add: distinct_insort)
  4071 
  4072 lemma sorted_insort_key: "sorted (map f (insort_key f x xs)) = sorted (map f xs)"
  4073   by (induct xs) (auto simp:sorted_Cons set_insort)
  4074 
  4075 lemma sorted_insort: "sorted (insort x xs) = sorted xs"
  4076   using sorted_insort_key [where f="\<lambda>x. x"] by simp
  4077 
  4078 theorem sorted_sort_key [simp]: "sorted (map f (sort_key f xs))"
  4079   by (induct xs) (auto simp:sorted_insort_key)
  4080 
  4081 theorem sorted_sort [simp]: "sorted (sort xs)"
  4082   using sorted_sort_key [where f="\<lambda>x. x"] by simp
  4083 
  4084 lemma sorted_butlast:
  4085   assumes "xs \<noteq> []" and "sorted xs"
  4086   shows "sorted (butlast xs)"
  4087 proof -
  4088   from `xs \<noteq> []` obtain ys y where "xs = ys @ [y]" by (cases xs rule: rev_cases) auto
  4089   with `sorted xs` show ?thesis by (simp add: sorted_append)
  4090 qed
  4091   
  4092 lemma insort_not_Nil [simp]:
  4093   "insort_key f a xs \<noteq> []"
  4094   by (induct xs) simp_all
  4095 
  4096 lemma insort_is_Cons: "\<forall>x\<in>set xs. f a \<le> f x \<Longrightarrow> insort_key f a xs = a # xs"
  4097 by (cases xs) auto
  4098 
  4099 lemma sorted_sort_id: "sorted xs \<Longrightarrow> sort xs = xs"
  4100   by (induct xs) (auto simp add: sorted_Cons insort_is_Cons)
  4101 
  4102 lemma sorted_map_remove1:
  4103   "sorted (map f xs) \<Longrightarrow> sorted (map f (remove1 x xs))"
  4104   by (induct xs) (auto simp add: sorted_Cons)
  4105 
  4106 lemma sorted_remove1: "sorted xs \<Longrightarrow> sorted (remove1 a xs)"
  4107   using sorted_map_remove1 [of "\<lambda>x. x"] by simp
  4108 
  4109 lemma insort_key_remove1:
  4110   assumes "a \<in> set xs" and "sorted (map f xs)" and "hd (filter (\<lambda>x. f a = f x) xs) = a"
  4111   shows "insort_key f a (remove1 a xs) = xs"
  4112 using assms proof (induct xs)
  4113   case (Cons x xs)
  4114   then show ?case
  4115   proof (cases "x = a")
  4116     case False
  4117     then have "f x \<noteq> f a" using Cons.prems by auto
  4118     then have "f x < f a" using Cons.prems by (auto simp: sorted_Cons)
  4119     with `f x \<noteq> f a` show ?thesis using Cons by (auto simp: sorted_Cons insort_is_Cons)
  4120   qed (auto simp: sorted_Cons insort_is_Cons)
  4121 qed simp
  4122 
  4123 lemma insort_remove1:
  4124   assumes "a \<in> set xs" and "sorted xs"
  4125   shows "insort a (remove1 a xs) = xs"
  4126 proof (rule insort_key_remove1)
  4127   from `a \<in> set xs` show "a \<in> set xs" .
  4128   from `sorted xs` show "sorted (map (\<lambda>x. x) xs)" by simp
  4129   from `a \<in> set xs` have "a \<in> set (filter (op = a) xs)" by auto
  4130   then have "set (filter (op = a) xs) \<noteq> {}" by auto
  4131   then have "filter (op = a) xs \<noteq> []" by (auto simp only: set_empty)
  4132   then have "length (filter (op = a) xs) > 0" by simp
  4133   then obtain n where n: "Suc n = length (filter (op = a) xs)"
  4134     by (cases "length (filter (op = a) xs)") simp_all
  4135   moreover have "replicate (Suc n) a = a # replicate n a"
  4136     by simp
  4137   ultimately show "hd (filter (op = a) xs) = a" by (simp add: replicate_length_filter)
  4138 qed
  4139 
  4140 lemma sorted_remdups[simp]:
  4141   "sorted l \<Longrightarrow> sorted (remdups l)"
  4142 by (induct l) (auto simp: sorted_Cons)
  4143 
  4144 lemma sorted_distinct_set_unique:
  4145 assumes "sorted xs" "distinct xs" "sorted ys" "distinct ys" "set xs = set ys"
  4146 shows "xs = ys"
  4147 proof -
  4148   from assms have 1: "length xs = length ys" by (auto dest!: distinct_card)
  4149   from assms show ?thesis
  4150   proof(induct rule:list_induct2[OF 1])
  4151     case 1 show ?case by simp
  4152   next
  4153     case 2 thus ?case by (simp add:sorted_Cons)
  4154        (metis Diff_insert_absorb antisym insertE insert_iff)
  4155   qed
  4156 qed
  4157 
  4158 lemma map_sorted_distinct_set_unique:
  4159   assumes "inj_on f (set xs \<union> set ys)"
  4160   assumes "sorted (map f xs)" "distinct (map f xs)"
  4161     "sorted (map f ys)" "distinct (map f ys)"
  4162   assumes "set xs = set ys"
  4163   shows "xs = ys"
  4164 proof -
  4165   from assms have "map f xs = map f ys"
  4166     by (simp add: sorted_distinct_set_unique)
  4167   moreover with `inj_on f (set xs \<union> set ys)` show "xs = ys"
  4168     by (blast intro: map_inj_on)
  4169 qed
  4170 
  4171 lemma finite_sorted_distinct_unique:
  4172 shows "finite A \<Longrightarrow> EX! xs. set xs = A & sorted xs & distinct xs"
  4173 apply(drule finite_distinct_list)
  4174 apply clarify
  4175 apply(rule_tac a="sort xs" in ex1I)
  4176 apply (auto simp: sorted_distinct_set_unique)
  4177 done
  4178 
  4179 lemma
  4180   assumes "sorted xs"
  4181   shows sorted_take: "sorted (take n xs)"
  4182   and sorted_drop: "sorted (drop n xs)"
  4183 proof -
  4184   from assms have "sorted (take n xs @ drop n xs)" by simp
  4185   then show "sorted (take n xs)" and "sorted (drop n xs)"
  4186     unfolding sorted_append by simp_all
  4187 qed
  4188 
  4189 lemma sorted_dropWhile: "sorted xs \<Longrightarrow> sorted (dropWhile P xs)"
  4190   by (auto dest: sorted_drop simp add: dropWhile_eq_drop)
  4191 
  4192 lemma sorted_takeWhile: "sorted xs \<Longrightarrow> sorted (takeWhile P xs)"
  4193   by (subst takeWhile_eq_take) (auto dest: sorted_take)
  4194 
  4195 lemma sorted_filter:
  4196   "sorted (map f xs) \<Longrightarrow> sorted (map f (filter P xs))"
  4197   by (induct xs) (simp_all add: sorted_Cons)
  4198 
  4199 lemma foldr_max_sorted:
  4200   assumes "sorted (rev xs)"
  4201   shows "foldr max xs y = (if xs = [] then y else max (xs ! 0) y)"
  4202 using assms proof (induct xs)
  4203   case (Cons x xs)
  4204   moreover hence "sorted (rev xs)" using sorted_append by auto
  4205   ultimately show ?case
  4206     by (cases xs, auto simp add: sorted_append max_def)
  4207 qed simp
  4208 
  4209 lemma filter_equals_takeWhile_sorted_rev:
  4210   assumes sorted: "sorted (rev (map f xs))"
  4211   shows "[x \<leftarrow> xs. t < f x] = takeWhile (\<lambda> x. t < f x) xs"
  4212     (is "filter ?P xs = ?tW")
  4213 proof (rule takeWhile_eq_filter[symmetric])
  4214   let "?dW" = "dropWhile ?P xs"
  4215   fix x assume "x \<in> set ?dW"
  4216   then obtain i where i: "i < length ?dW" and nth_i: "x = ?dW ! i"
  4217     unfolding in_set_conv_nth by auto
  4218   hence "length ?tW + i < length (?tW @ ?dW)"
  4219     unfolding length_append by simp
  4220   hence i': "length (map f ?tW) + i < length (map f xs)" by simp
  4221   have "(map f ?tW @ map f ?dW) ! (length (map f ?tW) + i) \<le>
  4222         (map f ?tW @ map f ?dW) ! (length (map f ?tW) + 0)"
  4223     using sorted_rev_nth_mono[OF sorted _ i', of "length ?tW"]
  4224     unfolding map_append[symmetric] by simp
  4225   hence "f x \<le> f (?dW ! 0)"
  4226     unfolding nth_append_length_plus nth_i
  4227     using i preorder_class.le_less_trans[OF le0 i] by simp
  4228   also have "... \<le> t"
  4229     using hd_dropWhile[of "?P" xs] le0[THEN preorder_class.le_less_trans, OF i]
  4230     using hd_conv_nth[of "?dW"] by simp
  4231   finally show "\<not> t < f x" by simp
  4232 qed
  4233 
  4234 lemma insort_insert_key_triv:
  4235   "f x \<in> f ` set xs \<Longrightarrow> insort_insert_key f x xs = xs"
  4236   by (simp add: insort_insert_key_def)
  4237 
  4238 lemma insort_insert_triv:
  4239   "x \<in> set xs \<Longrightarrow> insort_insert x xs = xs"
  4240   using insort_insert_key_triv [of "\<lambda>x. x"] by simp
  4241 
  4242 lemma insort_insert_insort_key:
  4243   "f x \<notin> f ` set xs \<Longrightarrow> insort_insert_key f x xs = insort_key f x xs"
  4244   by (simp add: insort_insert_key_def)
  4245 
  4246 lemma insort_insert_insort:
  4247   "x \<notin> set xs \<Longrightarrow> insort_insert x xs = insort x xs"
  4248   using insort_insert_insort_key [of "\<lambda>x. x"] by simp
  4249 
  4250 lemma set_insort_insert:
  4251   "set (insort_insert x xs) = insert x (set xs)"
  4252   by (auto simp add: insort_insert_key_def set_insort)
  4253 
  4254 lemma distinct_insort_insert:
  4255   assumes "distinct xs"
  4256   shows "distinct (insort_insert_key f x xs)"
  4257   using assms by (induct xs) (auto simp add: insort_insert_key_def set_insort)
  4258 
  4259 lemma sorted_insort_insert_key:
  4260   assumes "sorted (map f xs)"
  4261   shows "sorted (map f (insort_insert_key f x xs))"
  4262   using assms by (simp add: insort_insert_key_def sorted_insort_key)
  4263 
  4264 lemma sorted_insort_insert:
  4265   assumes "sorted xs"
  4266   shows "sorted (insort_insert x xs)"
  4267   using assms sorted_insort_insert_key [of "\<lambda>x. x"] by simp
  4268 
  4269 lemma filter_insort_triv:
  4270   "\<not> P x \<Longrightarrow> filter P (insort_key f x xs) = filter P xs"
  4271   by (induct xs) simp_all
  4272 
  4273 lemma filter_insort:
  4274   "sorted (map f xs) \<Longrightarrow> P x \<Longrightarrow> filter P (insort_key f x xs) = insort_key f x (filter P xs)"
  4275   using assms by (induct xs)
  4276     (auto simp add: sorted_Cons, subst insort_is_Cons, auto)
  4277 
  4278 lemma filter_sort:
  4279   "filter P (sort_key f xs) = sort_key f (filter P xs)"
  4280   by (induct xs) (simp_all add: filter_insort_triv filter_insort)
  4281 
  4282 lemma sorted_map_same:
  4283   "sorted (map f [x\<leftarrow>xs. f x = g xs])"
  4284 proof (induct xs arbitrary: g)
  4285   case Nil then show ?case by simp
  4286 next
  4287   case (Cons x xs)
  4288   then have "sorted (map f [y\<leftarrow>xs . f y = (\<lambda>xs. f x) xs])" .
  4289   moreover from Cons have "sorted (map f [y\<leftarrow>xs . f y = (g \<circ> Cons x) xs])" .
  4290   ultimately show ?case by (simp_all add: sorted_Cons)
  4291 qed
  4292 
  4293 lemma sorted_same:
  4294   "sorted [x\<leftarrow>xs. x = g xs]"
  4295   using sorted_map_same [of "\<lambda>x. x"] by simp
  4296 
  4297 lemma remove1_insort [simp]:
  4298   "remove1 x (insort x xs) = xs"
  4299   by (induct xs) simp_all
  4300 
  4301 end
  4302 
  4303 lemma sorted_upt[simp]: "sorted[i..<j]"
  4304 by (induct j) (simp_all add:sorted_append)
  4305 
  4306 lemma sorted_upto[simp]: "sorted[i..j]"
  4307 apply(induct i j rule:upto.induct)
  4308 apply(subst upto.simps)
  4309 apply(simp add:sorted_Cons)
  4310 done
  4311 
  4312 
  4313 subsubsection {* @{const transpose} on sorted lists *}
  4314 
  4315 lemma sorted_transpose[simp]:
  4316   shows "sorted (rev (map length (transpose xs)))"
  4317   by (auto simp: sorted_equals_nth_mono rev_nth nth_transpose
  4318     length_filter_conv_card intro: card_mono)
  4319 
  4320 lemma transpose_max_length:
  4321   "foldr (\<lambda>xs. max (length xs)) (transpose xs) 0 = length [x \<leftarrow> xs. x \<noteq> []]"
  4322   (is "?L = ?R")
  4323 proof (cases "transpose xs = []")
  4324   case False
  4325   have "?L = foldr max (map length (transpose xs)) 0"
  4326     by (simp add: foldr_map comp_def)
  4327   also have "... = length (transpose xs ! 0)"
  4328     using False sorted_transpose by (simp add: foldr_max_sorted)
  4329   finally show ?thesis
  4330     using False by (simp add: nth_transpose)
  4331 next
  4332   case True
  4333   hence "[x \<leftarrow> xs. x \<noteq> []] = []"
  4334     by (auto intro!: filter_False simp: transpose_empty)
  4335   thus ?thesis by (simp add: transpose_empty True)
  4336 qed
  4337 
  4338 lemma length_transpose_sorted:
  4339   fixes xs :: "'a list list"
  4340   assumes sorted: "sorted (rev (map length xs))"
  4341   shows "length (transpose xs) = (if xs = [] then 0 else length (xs ! 0))"
  4342 proof (cases "xs = []")
  4343   case False
  4344   thus ?thesis
  4345     using foldr_max_sorted[OF sorted] False
  4346     unfolding length_transpose foldr_map comp_def
  4347     by simp
  4348 qed simp
  4349 
  4350 lemma nth_nth_transpose_sorted[simp]:
  4351   fixes xs :: "'a list list"
  4352   assumes sorted: "sorted (rev (map length xs))"
  4353   and i: "i < length (transpose xs)"
  4354   and j: "j < length [ys \<leftarrow> xs. i < length ys]"
  4355   shows "transpose xs ! i ! j = xs ! j  ! i"
  4356   using j filter_equals_takeWhile_sorted_rev[OF sorted, of i]
  4357     nth_transpose[OF i] nth_map[OF j]
  4358   by (simp add: takeWhile_nth)
  4359 
  4360 lemma transpose_column_length:
  4361   fixes xs :: "'a list list"
  4362   assumes sorted: "sorted (rev (map length xs))" and "i < length xs"
  4363   shows "length (filter (\<lambda>ys. i < length ys) (transpose xs)) = length (xs ! i)"
  4364 proof -
  4365   have "xs \<noteq> []" using `i < length xs` by auto
  4366   note filter_equals_takeWhile_sorted_rev[OF sorted, simp]
  4367   { fix j assume "j \<le> i"
  4368     note sorted_rev_nth_mono[OF sorted, of j i, simplified, OF this `i < length xs`]
  4369   } note sortedE = this[consumes 1]
  4370 
  4371   have "{j. j < length (transpose xs) \<and> i < length (transpose xs ! j)}
  4372     = {..< length (xs ! i)}"
  4373   proof safe
  4374     fix j
  4375     assume "j < length (transpose xs)" and "i < length (transpose xs ! j)"
  4376     with this(2) nth_transpose[OF this(1)]
  4377     have "i < length (takeWhile (\<lambda>ys. j < length ys) xs)" by simp
  4378     from nth_mem[OF this] takeWhile_nth[OF this]
  4379     show "j < length (xs ! i)" by (auto dest: set_takeWhileD)
  4380   next
  4381     fix j assume "j < length (xs ! i)"
  4382     thus "j < length (transpose xs)"
  4383       using foldr_max_sorted[OF sorted] `xs \<noteq> []` sortedE[OF le0]
  4384       by (auto simp: length_transpose comp_def foldr_map)
  4385 
  4386     have "Suc i \<le> length (takeWhile (\<lambda>ys. j < length ys) xs)"
  4387       using `i < length xs` `j < length (xs ! i)` less_Suc_eq_le
  4388       by (auto intro!: length_takeWhile_less_P_nth dest!: sortedE)
  4389     with nth_transpose[OF `j < length (transpose xs)`]
  4390     show "i < length (transpose xs ! j)" by simp
  4391   qed
  4392   thus ?thesis by (simp add: length_filter_conv_card)
  4393 qed
  4394 
  4395 lemma transpose_column:
  4396   fixes xs :: "'a list list"
  4397   assumes sorted: "sorted (rev (map length xs))" and "i < length xs"
  4398   shows "map (\<lambda>ys. ys ! i) (filter (\<lambda>ys. i < length ys) (transpose xs))
  4399     = xs ! i" (is "?R = _")
  4400 proof (rule nth_equalityI, safe)
  4401   show length: "length ?R = length (xs ! i)"
  4402     using transpose_column_length[OF assms] by simp
  4403 
  4404   fix j assume j: "j < length ?R"
  4405   note * = less_le_trans[OF this, unfolded length_map, OF length_filter_le]
  4406   from j have j_less: "j < length (xs ! i)" using length by simp
  4407   have i_less_tW: "Suc i \<le> length (takeWhile (\<lambda>ys. Suc j \<le> length ys) xs)"
  4408   proof (rule length_takeWhile_less_P_nth)
  4409     show "Suc i \<le> length xs" using `i < length xs` by simp
  4410     fix k assume "k < Suc i"
  4411     hence "k \<le> i" by auto
  4412     with sorted_rev_nth_mono[OF sorted this] `i < length xs`
  4413     have "length (xs ! i) \<le> length (xs ! k)" by simp
  4414     thus "Suc j \<le> length (xs ! k)" using j_less by simp
  4415   qed
  4416   have i_less_filter: "i < length [ys\<leftarrow>xs . j < length ys]"
  4417     unfolding filter_equals_takeWhile_sorted_rev[OF sorted, of j]
  4418     using i_less_tW by (simp_all add: Suc_le_eq)
  4419   from j show "?R ! j = xs ! i ! j"
  4420     unfolding filter_equals_takeWhile_sorted_rev[OF sorted_transpose, of i]
  4421     by (simp add: takeWhile_nth nth_nth_transpose_sorted[OF sorted * i_less_filter])
  4422 qed
  4423 
  4424 lemma transpose_transpose:
  4425   fixes xs :: "'a list list"
  4426   assumes sorted: "sorted (rev (map length xs))"
  4427   shows "transpose (transpose xs) = takeWhile (\<lambda>x. x \<noteq> []) xs" (is "?L = ?R")
  4428 proof -
  4429   have len: "length ?L = length ?R"
  4430     unfolding length_transpose transpose_max_length
  4431     using filter_equals_takeWhile_sorted_rev[OF sorted, of 0]
  4432     by simp
  4433 
  4434   { fix i assume "i < length ?R"
  4435     with less_le_trans[OF _ length_takeWhile_le[of _ xs]]
  4436     have "i < length xs" by simp
  4437   } note * = this
  4438   show ?thesis
  4439     by (rule nth_equalityI)
  4440        (simp_all add: len nth_transpose transpose_column[OF sorted] * takeWhile_nth)
  4441 qed
  4442 
  4443 theorem transpose_rectangle:
  4444   assumes "xs = [] \<Longrightarrow> n = 0"
  4445   assumes rect: "\<And> i. i < length xs \<Longrightarrow> length (xs ! i) = n"
  4446   shows "transpose xs = map (\<lambda> i. map (\<lambda> j. xs ! j ! i) [0..<length xs]) [0..<n]"
  4447     (is "?trans = ?map")
  4448 proof (rule nth_equalityI)
  4449   have "sorted (rev (map length xs))"
  4450     by (auto simp: rev_nth rect intro!: sorted_nth_monoI)
  4451   from foldr_max_sorted[OF this] assms
  4452   show len: "length ?trans = length ?map"
  4453     by (simp_all add: length_transpose foldr_map comp_def)
  4454   moreover
  4455   { fix i assume "i < n" hence "[ys\<leftarrow>xs . i < length ys] = xs"
  4456       using rect by (auto simp: in_set_conv_nth intro!: filter_True) }
  4457   ultimately show "\<forall>i < length ?trans. ?trans ! i = ?map ! i"
  4458     by (auto simp: nth_transpose intro: nth_equalityI)
  4459 qed
  4460 
  4461 
  4462 subsubsection {* @{text sorted_list_of_set} *}
  4463 
  4464 text{* This function maps (finite) linearly ordered sets to sorted
  4465 lists. Warning: in most cases it is not a good idea to convert from
  4466 sets to lists but one should convert in the other direction (via
  4467 @{const set}). *}
  4468 
  4469 context linorder
  4470 begin
  4471 
  4472 definition sorted_list_of_set :: "'a set \<Rightarrow> 'a list" where
  4473   "sorted_list_of_set = Finite_Set.fold insort []"
  4474 
  4475 lemma sorted_list_of_set_empty [simp]:
  4476   "sorted_list_of_set {} = []"
  4477   by (simp add: sorted_list_of_set_def)
  4478 
  4479 lemma sorted_list_of_set_insert [simp]:
  4480   assumes "finite A"
  4481   shows "sorted_list_of_set (insert x A) = insort x (sorted_list_of_set (A - {x}))"
  4482 proof -
  4483   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  4484   with assms show ?thesis by (simp add: sorted_list_of_set_def fold_insert_remove)
  4485 qed
  4486 
  4487 lemma sorted_list_of_set [simp]:
  4488   "finite A \<Longrightarrow> set (sorted_list_of_set A) = A \<and> sorted (sorted_list_of_set A) 
  4489     \<and> distinct (sorted_list_of_set A)"
  4490   by (induct A rule: finite_induct) (simp_all add: set_insort sorted_insort distinct_insort)
  4491 
  4492 lemma sorted_list_of_set_sort_remdups:
  4493   "sorted_list_of_set (set xs) = sort (remdups xs)"
  4494 proof -
  4495   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  4496   show ?thesis by (simp add: sorted_list_of_set_def sort_conv_fold fold_set_fold_remdups)
  4497 qed
  4498 
  4499 lemma sorted_list_of_set_remove:
  4500   assumes "finite A"
  4501   shows "sorted_list_of_set (A - {x}) = remove1 x (sorted_list_of_set A)"
  4502 proof (cases "x \<in> A")
  4503   case False with assms have "x \<notin> set (sorted_list_of_set A)" by simp
  4504   with False show ?thesis by (simp add: remove1_idem)
  4505 next
  4506   case True then obtain B where A: "A = insert x B" by (rule Set.set_insert)
  4507   with assms show ?thesis by simp
  4508 qed
  4509 
  4510 end
  4511 
  4512 lemma sorted_list_of_set_range [simp]:
  4513   "sorted_list_of_set {m..<n} = [m..<n]"
  4514   by (rule sorted_distinct_set_unique) simp_all
  4515 
  4516 
  4517 subsubsection {* @{text lists}: the list-forming operator over sets *}
  4518 
  4519 inductive_set
  4520   lists :: "'a set => 'a list set"
  4521   for A :: "'a set"
  4522 where
  4523     Nil [intro!, simp]: "[]: lists A"
  4524   | Cons [intro!, simp, no_atp]: "[| a: A; l: lists A|] ==> a#l : lists A"
  4525 
  4526 inductive_cases listsE [elim!,no_atp]: "x#l : lists A"
  4527 inductive_cases listspE [elim!,no_atp]: "listsp A (x # l)"
  4528 
  4529 inductive_simps listsp_simps[code]:
  4530   "listsp A []"
  4531   "listsp A (x # xs)"
  4532 
  4533 lemma listsp_mono [mono]: "A \<le> B ==> listsp A \<le> listsp B"
  4534 by (rule predicate1I, erule listsp.induct, (blast dest: predicate1D)+)
  4535 
  4536 lemmas lists_mono = listsp_mono [to_set]
  4537 
  4538 lemma listsp_infI:
  4539   assumes l: "listsp A l" shows "listsp B l ==> listsp (inf A B) l" using l
  4540 by induct blast+
  4541 
  4542 lemmas lists_IntI = listsp_infI [to_set]
  4543 
  4544 lemma listsp_inf_eq [simp]: "listsp (inf A B) = inf (listsp A) (listsp B)"
  4545 proof (rule mono_inf [where f=listsp, THEN order_antisym])
  4546   show "mono listsp" by (simp add: mono_def listsp_mono)
  4547   show "inf (listsp A) (listsp B) \<le> listsp (inf A B)" by (blast intro!: listsp_infI predicate1I)
  4548 qed
  4549 
  4550 lemmas listsp_conj_eq [simp] = listsp_inf_eq [simplified inf_fun_def inf_bool_def]
  4551 
  4552 lemmas lists_Int_eq [simp] = listsp_inf_eq [to_set]
  4553 
  4554 lemma Cons_in_lists_iff[simp]: "x#xs : lists A \<longleftrightarrow> x:A \<and> xs : lists A"
  4555 by auto
  4556 
  4557 lemma append_in_listsp_conv [iff]:
  4558      "(listsp A (xs @ ys)) = (listsp A xs \<and> listsp A ys)"
  4559 by (induct xs) auto
  4560 
  4561 lemmas append_in_lists_conv [iff] = append_in_listsp_conv [to_set]
  4562 
  4563 lemma in_listsp_conv_set: "(listsp A xs) = (\<forall>x \<in> set xs. A x)"
  4564 -- {* eliminate @{text listsp} in favour of @{text set} *}
  4565 by (induct xs) auto
  4566 
  4567 lemmas in_lists_conv_set [code_unfold] = in_listsp_conv_set [to_set]
  4568 
  4569 lemma in_listspD [dest!,no_atp]: "listsp A xs ==> \<forall>x\<in>set xs. A x"
  4570 by (rule in_listsp_conv_set [THEN iffD1])
  4571 
  4572 lemmas in_listsD [dest!,no_atp] = in_listspD [to_set]
  4573 
  4574 lemma in_listspI [intro!,no_atp]: "\<forall>x\<in>set xs. A x ==> listsp A xs"
  4575 by (rule in_listsp_conv_set [THEN iffD2])
  4576 
  4577 lemmas in_listsI [intro!,no_atp] = in_listspI [to_set]
  4578 
  4579 lemma lists_eq_set: "lists A = {xs. set xs <= A}"
  4580 by auto
  4581 
  4582 lemma lists_empty [simp]: "lists {} = {[]}"
  4583 by auto
  4584 
  4585 lemma lists_UNIV [simp]: "lists UNIV = UNIV"
  4586 by auto
  4587 
  4588 
  4589 subsubsection {* Inductive definition for membership *}
  4590 
  4591 inductive ListMem :: "'a \<Rightarrow> 'a list \<Rightarrow> bool"
  4592 where
  4593     elem:  "ListMem x (x # xs)"
  4594   | insert:  "ListMem x xs \<Longrightarrow> ListMem x (y # xs)"
  4595 
  4596 lemma ListMem_iff: "(ListMem x xs) = (x \<in> set xs)"
  4597 apply (rule iffI)
  4598  apply (induct set: ListMem)
  4599   apply auto
  4600 apply (induct xs)
  4601  apply (auto intro: ListMem.intros)
  4602 done
  4603 
  4604 
  4605 subsubsection {* Lists as Cartesian products *}
  4606 
  4607 text{*@{text"set_Cons A Xs"}: the set of lists with head drawn from
  4608 @{term A} and tail drawn from @{term Xs}.*}
  4609 
  4610 definition
  4611   set_Cons :: "'a set \<Rightarrow> 'a list set \<Rightarrow> 'a list set" where
  4612   "set_Cons A XS = {z. \<exists>x xs. z = x # xs \<and> x \<in> A \<and> xs \<in> XS}"
  4613 
  4614 lemma set_Cons_sing_Nil [simp]: "set_Cons A {[]} = (%x. [x])`A"
  4615 by (auto simp add: set_Cons_def)
  4616 
  4617 text{*Yields the set of lists, all of the same length as the argument and
  4618 with elements drawn from the corresponding element of the argument.*}
  4619 
  4620 primrec
  4621   listset :: "'a set list \<Rightarrow> 'a list set" where
  4622      "listset [] = {[]}"
  4623   |  "listset (A # As) = set_Cons A (listset As)"
  4624 
  4625 
  4626 subsection {* Relations on Lists *}
  4627 
  4628 subsubsection {* Length Lexicographic Ordering *}
  4629 
  4630 text{*These orderings preserve well-foundedness: shorter lists 
  4631   precede longer lists. These ordering are not used in dictionaries.*}
  4632         
  4633 primrec -- {*The lexicographic ordering for lists of the specified length*}
  4634   lexn :: "('a \<times> 'a) set \<Rightarrow> nat \<Rightarrow> ('a list \<times> 'a list) set" where
  4635     "lexn r 0 = {}"
  4636   | "lexn r (Suc n) = (map_pair (%(x, xs). x#xs) (%(x, xs). x#xs) ` (r <*lex*> lexn r n)) Int
  4637       {(xs, ys). length xs = Suc n \<and> length ys = Suc n}"
  4638 
  4639 definition
  4640   lex :: "('a \<times> 'a) set \<Rightarrow> ('a list \<times> 'a list) set" where
  4641   "lex r = (\<Union>n. lexn r n)" -- {*Holds only between lists of the same length*}
  4642 
  4643 definition
  4644   lenlex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set" where
  4645   "lenlex r = inv_image (less_than <*lex*> lex r) (\<lambda>xs. (length xs, xs))"
  4646         -- {*Compares lists by their length and then lexicographically*}
  4647 
  4648 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  4649 apply (induct n, simp, simp)
  4650 apply(rule wf_subset)
  4651  prefer 2 apply (rule Int_lower1)
  4652 apply(rule wf_map_pair_image)
  4653  prefer 2 apply (rule inj_onI, auto)
  4654 done
  4655 
  4656 lemma lexn_length:
  4657   "(xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  4658 by (induct n arbitrary: xs ys) auto
  4659 
  4660 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  4661 apply (unfold lex_def)
  4662 apply (rule wf_UN)
  4663 apply (blast intro: wf_lexn, clarify)
  4664 apply (rename_tac m n)
  4665 apply (subgoal_tac "m \<noteq> n")
  4666  prefer 2 apply blast
  4667 apply (blast dest: lexn_length not_sym)
  4668 done
  4669 
  4670 lemma lexn_conv:
  4671   "lexn r n =
  4672     {(xs,ys). length xs = n \<and> length ys = n \<and>
  4673     (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  4674 apply (induct n, simp)
  4675 apply (simp add: image_Collect lex_prod_def, safe, blast)
  4676  apply (rule_tac x = "ab # xys" in exI, simp)
  4677 apply (case_tac xys, simp_all, blast)
  4678 done
  4679 
  4680 lemma lex_conv:
  4681   "lex r =
  4682     {(xs,ys). length xs = length ys \<and>
  4683     (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  4684 by (force simp add: lex_def lexn_conv)
  4685 
  4686 lemma wf_lenlex [intro!]: "wf r ==> wf (lenlex r)"
  4687 by (unfold lenlex_def) blast
  4688 
  4689 lemma lenlex_conv:
  4690     "lenlex r = {(xs,ys). length xs < length ys |
  4691                  length xs = length ys \<and> (xs, ys) : lex r}"
  4692 by (simp add: lenlex_def Id_on_def lex_prod_def inv_image_def)
  4693 
  4694 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  4695 by (simp add: lex_conv)
  4696 
  4697 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  4698 by (simp add:lex_conv)
  4699 
  4700 lemma Cons_in_lex [simp]:
  4701     "((x # xs, y # ys) : lex r) =
  4702       ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  4703 apply (simp add: lex_conv)
  4704 apply (rule iffI)
  4705  prefer 2 apply (blast intro: Cons_eq_appendI, clarify)
  4706 apply (case_tac xys, simp, simp)
  4707 apply blast
  4708 done
  4709 
  4710 
  4711 subsubsection {* Lexicographic Ordering *}
  4712 
  4713 text {* Classical lexicographic ordering on lists, ie. "a" < "ab" < "b".
  4714     This ordering does \emph{not} preserve well-foundedness.
  4715      Author: N. Voelker, March 2005. *} 
  4716 
  4717 definition
  4718   lexord :: "('a \<times> 'a) set \<Rightarrow> ('a list \<times> 'a list) set" where
  4719   "lexord r = {(x,y ). \<exists> a v. y = x @ a # v \<or>
  4720             (\<exists> u a b v w. (a,b) \<in> r \<and> x = u @ (a # v) \<and> y = u @ (b # w))}"
  4721 
  4722 lemma lexord_Nil_left[simp]:  "([],y) \<in> lexord r = (\<exists> a x. y = a # x)"
  4723 by (unfold lexord_def, induct_tac y, auto) 
  4724 
  4725 lemma lexord_Nil_right[simp]: "(x,[]) \<notin> lexord r"
  4726 by (unfold lexord_def, induct_tac x, auto)
  4727 
  4728 lemma lexord_cons_cons[simp]:
  4729      "((a # x, b # y) \<in> lexord r) = ((a,b)\<in> r | (a = b & (x,y)\<in> lexord r))"
  4730   apply (unfold lexord_def, safe, simp_all)
  4731   apply (case_tac u, simp, simp)
  4732   apply (case_tac u, simp, clarsimp, blast, blast, clarsimp)
  4733   apply (erule_tac x="b # u" in allE)
  4734   by force
  4735 
  4736 lemmas lexord_simps = lexord_Nil_left lexord_Nil_right lexord_cons_cons
  4737 
  4738 lemma lexord_append_rightI: "\<exists> b z. y = b # z \<Longrightarrow> (x, x @ y) \<in> lexord r"
  4739 by (induct_tac x, auto)  
  4740 
  4741 lemma lexord_append_left_rightI:
  4742      "(a,b) \<in> r \<Longrightarrow> (u @ a # x, u @ b # y) \<in> lexord r"
  4743 by (induct_tac u, auto)
  4744 
  4745 lemma lexord_append_leftI: " (u,v) \<in> lexord r \<Longrightarrow> (x @ u, x @ v) \<in> lexord r"
  4746 by (induct x, auto)
  4747 
  4748 lemma lexord_append_leftD:
  4749      "\<lbrakk> (x @ u, x @ v) \<in> lexord r; (! a. (a,a) \<notin> r) \<rbrakk> \<Longrightarrow> (u,v) \<in> lexord r"
  4750 by (erule rev_mp, induct_tac x, auto)
  4751 
  4752 lemma lexord_take_index_conv: 
  4753    "((x,y) : lexord r) = 
  4754     ((length x < length y \<and> take (length x) y = x) \<or> 
  4755      (\<exists>i. i < min(length x)(length y) & take i x = take i y & (x!i,y!i) \<in> r))"
  4756   apply (unfold lexord_def Let_def, clarsimp) 
  4757   apply (rule_tac f = "(% a b. a \<or> b)" in arg_cong2)
  4758   apply auto 
  4759   apply (rule_tac x="hd (drop (length x) y)" in exI)
  4760   apply (rule_tac x="tl (drop (length x) y)" in exI)
  4761   apply (erule subst, simp add: min_def) 
  4762   apply (rule_tac x ="length u" in exI, simp) 
  4763   apply (rule_tac x ="take i x" in exI) 
  4764   apply (rule_tac x ="x ! i" in exI) 
  4765   apply (rule_tac x ="y ! i" in exI, safe) 
  4766   apply (rule_tac x="drop (Suc i) x" in exI)
  4767   apply (drule sym, simp add: drop_Suc_conv_tl) 
  4768   apply (rule_tac x="drop (Suc i) y" in exI)
  4769   by (simp add: drop_Suc_conv_tl) 
  4770 
  4771 -- {* lexord is extension of partial ordering List.lex *} 
  4772 lemma lexord_lex: "(x,y) \<in> lex r = ((x,y) \<in> lexord r \<and> length x = length y)"
  4773   apply (rule_tac x = y in spec) 
  4774   apply (induct_tac x, clarsimp) 
  4775   by (clarify, case_tac x, simp, force)
  4776 
  4777 lemma lexord_irreflexive: "ALL x. (x,x) \<notin> r \<Longrightarrow> (xs,xs) \<notin> lexord r"
  4778 by (induct xs) auto
  4779 
  4780 text{* By Ren\'e Thiemann: *}
  4781 lemma lexord_partial_trans: 
  4782   "(\<And>x y z. x \<in> set xs \<Longrightarrow> (x,y) \<in> r \<Longrightarrow> (y,z) \<in> r \<Longrightarrow> (x,z) \<in> r)
  4783    \<Longrightarrow>  (xs,ys) \<in> lexord r  \<Longrightarrow>  (ys,zs) \<in> lexord r \<Longrightarrow>  (xs,zs) \<in> lexord r"
  4784 proof (induct xs arbitrary: ys zs)
  4785   case Nil
  4786   from Nil(3) show ?case unfolding lexord_def by (cases zs, auto)
  4787 next
  4788   case (Cons x xs yys zzs)
  4789   from Cons(3) obtain y ys where yys: "yys = y # ys" unfolding lexord_def
  4790     by (cases yys, auto)
  4791   note Cons = Cons[unfolded yys]
  4792   from Cons(3) have one: "(x,y) \<in> r \<or> x = y \<and> (xs,ys) \<in> lexord r" by auto
  4793   from Cons(4) obtain z zs where zzs: "zzs = z # zs" unfolding lexord_def
  4794     by (cases zzs, auto)
  4795   note Cons = Cons[unfolded zzs]
  4796   from Cons(4) have two: "(y,z) \<in> r \<or> y = z \<and> (ys,zs) \<in> lexord r" by auto
  4797   {
  4798     assume "(xs,ys) \<in> lexord r" and "(ys,zs) \<in> lexord r"
  4799     from Cons(1)[OF _ this] Cons(2)
  4800     have "(xs,zs) \<in> lexord r" by auto
  4801   } note ind1 = this
  4802   {
  4803     assume "(x,y) \<in> r" and "(y,z) \<in> r"
  4804     from Cons(2)[OF _ this] have "(x,z) \<in> r" by auto
  4805   } note ind2 = this
  4806   from one two ind1 ind2
  4807   have "(x,z) \<in> r \<or> x = z \<and> (xs,zs) \<in> lexord r" by blast
  4808   thus ?case unfolding zzs by auto
  4809 qed
  4810 
  4811 lemma lexord_trans: 
  4812     "\<lbrakk> (x, y) \<in> lexord r; (y, z) \<in> lexord r; trans r \<rbrakk> \<Longrightarrow> (x, z) \<in> lexord r"
  4813 by(auto simp: trans_def intro:lexord_partial_trans)
  4814 
  4815 lemma lexord_transI:  "trans r \<Longrightarrow> trans (lexord r)"
  4816 by (rule transI, drule lexord_trans, blast) 
  4817 
  4818 lemma lexord_linear: "(! a b. (a,b)\<in> r | a = b | (b,a) \<in> r) \<Longrightarrow> (x,y) : lexord r | x = y | (y,x) : lexord r"
  4819   apply (rule_tac x = y in spec) 
  4820   apply (induct_tac x, rule allI) 
  4821   apply (case_tac x, simp, simp) 
  4822   apply (rule allI, case_tac x, simp, simp) 
  4823   by blast
  4824 
  4825 
  4826 subsubsection {* Lexicographic combination of measure functions *}
  4827 
  4828 text {* These are useful for termination proofs *}
  4829 
  4830 definition
  4831   "measures fs = inv_image (lex less_than) (%a. map (%f. f a) fs)"
  4832 
  4833 lemma wf_measures[simp]: "wf (measures fs)"
  4834 unfolding measures_def
  4835 by blast
  4836 
  4837 lemma in_measures[simp]: 
  4838   "(x, y) \<in> measures [] = False"
  4839   "(x, y) \<in> measures (f # fs)
  4840          = (f x < f y \<or> (f x = f y \<and> (x, y) \<in> measures fs))"  
  4841 unfolding measures_def
  4842 by auto
  4843 
  4844 lemma measures_less: "f x < f y ==> (x, y) \<in> measures (f#fs)"
  4845 by simp
  4846 
  4847 lemma measures_lesseq: "f x <= f y ==> (x, y) \<in> measures fs ==> (x, y) \<in> measures (f#fs)"
  4848 by auto
  4849 
  4850 
  4851 subsubsection {* Lifting Relations to Lists: one element *}
  4852 
  4853 definition listrel1 :: "('a \<times> 'a) set \<Rightarrow> ('a list \<times> 'a list) set" where
  4854 "listrel1 r = {(xs,ys).
  4855    \<exists>us z z' vs. xs = us @ z # vs \<and> (z,z') \<in> r \<and> ys = us @ z' # vs}"
  4856 
  4857 lemma listrel1I:
  4858   "\<lbrakk> (x, y) \<in> r;  xs = us @ x # vs;  ys = us @ y # vs \<rbrakk> \<Longrightarrow>
  4859   (xs, ys) \<in> listrel1 r"
  4860 unfolding listrel1_def by auto
  4861 
  4862 lemma listrel1E:
  4863   "\<lbrakk> (xs, ys) \<in> listrel1 r;
  4864      !!x y us vs. \<lbrakk> (x, y) \<in> r;  xs = us @ x # vs;  ys = us @ y # vs \<rbrakk> \<Longrightarrow> P
  4865    \<rbrakk> \<Longrightarrow> P"
  4866 unfolding listrel1_def by auto
  4867 
  4868 lemma not_Nil_listrel1 [iff]: "([], xs) \<notin> listrel1 r"
  4869 unfolding listrel1_def by blast
  4870 
  4871 lemma not_listrel1_Nil [iff]: "(xs, []) \<notin> listrel1 r"
  4872 unfolding listrel1_def by blast
  4873 
  4874 lemma Cons_listrel1_Cons [iff]:
  4875   "(x # xs, y # ys) \<in> listrel1 r \<longleftrightarrow>
  4876    (x,y) \<in> r \<and> xs = ys \<or> x = y \<and> (xs, ys) \<in> listrel1 r"
  4877 by (simp add: listrel1_def Cons_eq_append_conv) (blast)
  4878 
  4879 lemma listrel1I1: "(x,y) \<in> r \<Longrightarrow> (x # xs, y # xs) \<in> listrel1 r"
  4880 by (metis Cons_listrel1_Cons)
  4881 
  4882 lemma listrel1I2: "(xs, ys) \<in> listrel1 r \<Longrightarrow> (x # xs, x # ys) \<in> listrel1 r"
  4883 by (metis Cons_listrel1_Cons)
  4884 
  4885 lemma append_listrel1I:
  4886   "(xs, ys) \<in> listrel1 r \<and> us = vs \<or> xs = ys \<and> (us, vs) \<in> listrel1 r
  4887     \<Longrightarrow> (xs @ us, ys @ vs) \<in> listrel1 r"
  4888 unfolding listrel1_def
  4889 by auto (blast intro: append_eq_appendI)+
  4890 
  4891 lemma Cons_listrel1E1[elim!]:
  4892   assumes "(x # xs, ys) \<in> listrel1 r"
  4893     and "\<And>y. ys = y # xs \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> R"
  4894     and "\<And>zs. ys = x # zs \<Longrightarrow> (xs, zs) \<in> listrel1 r \<Longrightarrow> R"
  4895   shows R
  4896 using assms by (cases ys) blast+
  4897 
  4898 lemma Cons_listrel1E2[elim!]:
  4899   assumes "(xs, y # ys) \<in> listrel1 r"
  4900     and "\<And>x. xs = x # ys \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> R"
  4901     and "\<And>zs. xs = y # zs \<Longrightarrow> (zs, ys) \<in> listrel1 r \<Longrightarrow> R"
  4902   shows R
  4903 using assms by (cases xs) blast+
  4904 
  4905 lemma snoc_listrel1_snoc_iff:
  4906   "(xs @ [x], ys @ [y]) \<in> listrel1 r
  4907     \<longleftrightarrow> (xs, ys) \<in> listrel1 r \<and> x = y \<or> xs = ys \<and> (x,y) \<in> r" (is "?L \<longleftrightarrow> ?R")
  4908 proof
  4909   assume ?L thus ?R
  4910     by (fastforce simp: listrel1_def snoc_eq_iff_butlast butlast_append)
  4911 next
  4912   assume ?R then show ?L unfolding listrel1_def by force
  4913 qed
  4914 
  4915 lemma listrel1_eq_len: "(xs,ys) \<in> listrel1 r \<Longrightarrow> length xs = length ys"
  4916 unfolding listrel1_def by auto
  4917 
  4918 lemma listrel1_mono:
  4919   "r \<subseteq> s \<Longrightarrow> listrel1 r \<subseteq> listrel1 s"
  4920 unfolding listrel1_def by blast
  4921 
  4922 
  4923 lemma listrel1_converse: "listrel1 (r^-1) = (listrel1 r)^-1"
  4924 unfolding listrel1_def by blast
  4925 
  4926 lemma in_listrel1_converse:
  4927   "(x,y) : listrel1 (r^-1) \<longleftrightarrow> (x,y) : (listrel1 r)^-1"
  4928 unfolding listrel1_def by blast
  4929 
  4930 lemma listrel1_iff_update:
  4931   "(xs,ys) \<in> (listrel1 r)
  4932    \<longleftrightarrow> (\<exists>y n. (xs ! n, y) \<in> r \<and> n < length xs \<and> ys = xs[n:=y])" (is "?L \<longleftrightarrow> ?R")
  4933 proof
  4934   assume "?L"
  4935   then obtain x y u v where "xs = u @ x # v"  "ys = u @ y # v"  "(x,y) \<in> r"
  4936     unfolding listrel1_def by auto
  4937   then have "ys = xs[length u := y]" and "length u < length xs"
  4938     and "(xs ! length u, y) \<in> r" by auto
  4939   then show "?R" by auto
  4940 next
  4941   assume "?R"
  4942   then obtain x y n where "(xs!n, y) \<in> r" "n < size xs" "ys = xs[n:=y]" "x = xs!n"
  4943     by auto
  4944   then obtain u v where "xs = u @ x # v" and "ys = u @ y # v" and "(x, y) \<in> r"
  4945     by (auto intro: upd_conv_take_nth_drop id_take_nth_drop)
  4946   then show "?L" by (auto simp: listrel1_def)
  4947 qed
  4948 
  4949 
  4950 text{* Accessible part and wellfoundedness: *}
  4951 
  4952 lemma Cons_acc_listrel1I [intro!]:
  4953   "x \<in> acc r \<Longrightarrow> xs \<in> acc (listrel1 r) \<Longrightarrow> (x # xs) \<in> acc (listrel1 r)"
  4954 apply (induct arbitrary: xs set: acc)
  4955 apply (erule thin_rl)
  4956 apply (erule acc_induct)
  4957 apply (rule accI)
  4958 apply (blast)
  4959 done
  4960 
  4961 lemma lists_accD: "xs \<in> lists (acc r) \<Longrightarrow> xs \<in> acc (listrel1 r)"
  4962 apply (induct set: lists)
  4963  apply (rule accI)
  4964  apply simp
  4965 apply (rule accI)
  4966 apply (fast dest: acc_downward)
  4967 done
  4968 
  4969 lemma lists_accI: "xs \<in> acc (listrel1 r) \<Longrightarrow> xs \<in> lists (acc r)"
  4970 apply (induct set: acc)
  4971 apply clarify
  4972 apply (rule accI)
  4973 apply (fastforce dest!: in_set_conv_decomp[THEN iffD1] simp: listrel1_def)
  4974 done
  4975 
  4976 lemma wf_listrel1_iff[simp]: "wf(listrel1 r) = wf r"
  4977 by(metis wf_acc_iff in_lists_conv_set lists_accI lists_accD Cons_in_lists_iff)
  4978 
  4979 
  4980 subsubsection {* Lifting Relations to Lists: all elements *}
  4981 
  4982 inductive_set
  4983   listrel :: "('a \<times> 'b) set \<Rightarrow> ('a list \<times> 'b list) set"
  4984   for r :: "('a \<times> 'b) set"
  4985 where
  4986     Nil:  "([],[]) \<in> listrel r"
  4987   | Cons: "[| (x,y) \<in> r; (xs,ys) \<in> listrel r |] ==> (x#xs, y#ys) \<in> listrel r"
  4988 
  4989 inductive_cases listrel_Nil1 [elim!]: "([],xs) \<in> listrel r"
  4990 inductive_cases listrel_Nil2 [elim!]: "(xs,[]) \<in> listrel r"
  4991 inductive_cases listrel_Cons1 [elim!]: "(y#ys,xs) \<in> listrel r"
  4992 inductive_cases listrel_Cons2 [elim!]: "(xs,y#ys) \<in> listrel r"
  4993 
  4994 
  4995 lemma listrel_eq_len:  "(xs, ys) \<in> listrel r \<Longrightarrow> length xs = length ys"
  4996 by(induct rule: listrel.induct) auto
  4997 
  4998 lemma listrel_iff_zip [code_unfold]: "(xs,ys) : listrel r \<longleftrightarrow>
  4999   length xs = length ys & (\<forall>(x,y) \<in> set(zip xs ys). (x,y) \<in> r)" (is "?L \<longleftrightarrow> ?R")
  5000 proof
  5001   assume ?L thus ?R by induct (auto intro: listrel_eq_len)
  5002 next
  5003   assume ?R thus ?L
  5004     apply (clarify)
  5005     by (induct rule: list_induct2) (auto intro: listrel.intros)
  5006 qed
  5007 
  5008 lemma listrel_iff_nth: "(xs,ys) : listrel r \<longleftrightarrow>
  5009   length xs = length ys & (\<forall>n < length xs. (xs!n, ys!n) \<in> r)" (is "?L \<longleftrightarrow> ?R")
  5010 by (auto simp add: all_set_conv_all_nth listrel_iff_zip)
  5011 
  5012 
  5013 lemma listrel_mono: "r \<subseteq> s \<Longrightarrow> listrel r \<subseteq> listrel s"
  5014 apply clarify  
  5015 apply (erule listrel.induct)
  5016 apply (blast intro: listrel.intros)+
  5017 done
  5018 
  5019 lemma listrel_subset: "r \<subseteq> A \<times> A \<Longrightarrow> listrel r \<subseteq> lists A \<times> lists A"
  5020 apply clarify 
  5021 apply (erule listrel.induct, auto) 
  5022 done
  5023 
  5024 lemma listrel_refl_on: "refl_on A r \<Longrightarrow> refl_on (lists A) (listrel r)" 
  5025 apply (simp add: refl_on_def listrel_subset Ball_def)
  5026 apply (rule allI) 
  5027 apply (induct_tac x) 
  5028 apply (auto intro: listrel.intros)
  5029 done
  5030 
  5031 lemma listrel_sym: "sym r \<Longrightarrow> sym (listrel r)" 
  5032 apply (auto simp add: sym_def)
  5033 apply (erule listrel.induct) 
  5034 apply (blast intro: listrel.intros)+
  5035 done
  5036 
  5037 lemma listrel_trans: "trans r \<Longrightarrow> trans (listrel r)" 
  5038 apply (simp add: trans_def)
  5039 apply (intro allI) 
  5040 apply (rule impI) 
  5041 apply (erule listrel.induct) 
  5042 apply (blast intro: listrel.intros)+
  5043 done
  5044 
  5045 theorem equiv_listrel: "equiv A r \<Longrightarrow> equiv (lists A) (listrel r)"
  5046 by (simp add: equiv_def listrel_refl_on listrel_sym listrel_trans) 
  5047 
  5048 lemma listrel_rtrancl_refl[iff]: "(xs,xs) : listrel(r^*)"
  5049 using listrel_refl_on[of UNIV, OF refl_rtrancl]
  5050 by(auto simp: refl_on_def)
  5051 
  5052 lemma listrel_rtrancl_trans:
  5053   "\<lbrakk> (xs,ys) : listrel(r^*);  (ys,zs) : listrel(r^*) \<rbrakk>
  5054   \<Longrightarrow> (xs,zs) : listrel(r^*)"
  5055 by (metis listrel_trans trans_def trans_rtrancl)
  5056 
  5057 
  5058 lemma listrel_Nil [simp]: "listrel r `` {[]} = {[]}"
  5059 by (blast intro: listrel.intros)
  5060 
  5061 lemma listrel_Cons:
  5062      "listrel r `` {x#xs} = set_Cons (r``{x}) (listrel r `` {xs})"
  5063 by (auto simp add: set_Cons_def intro: listrel.intros)
  5064 
  5065 text {* Relating @{term listrel1}, @{term listrel} and closures: *}
  5066 
  5067 lemma listrel1_rtrancl_subset_rtrancl_listrel1:
  5068   "listrel1 (r^*) \<subseteq> (listrel1 r)^*"
  5069 proof (rule subrelI)
  5070   fix xs ys assume 1: "(xs,ys) \<in> listrel1 (r^*)"
  5071   { fix x y us vs
  5072     have "(x,y) : r^* \<Longrightarrow> (us @ x # vs, us @ y # vs) : (listrel1 r)^*"
  5073     proof(induct rule: rtrancl.induct)
  5074       case rtrancl_refl show ?case by simp
  5075     next
  5076       case rtrancl_into_rtrancl thus ?case
  5077         by (metis listrel1I rtrancl.rtrancl_into_rtrancl)
  5078     qed }
  5079   thus "(xs,ys) \<in> (listrel1 r)^*" using 1 by(blast elim: listrel1E)
  5080 qed
  5081 
  5082 lemma rtrancl_listrel1_eq_len: "(x,y) \<in> (listrel1 r)^* \<Longrightarrow> length x = length y"
  5083 by (induct rule: rtrancl.induct) (auto intro: listrel1_eq_len)
  5084 
  5085 lemma rtrancl_listrel1_ConsI1:
  5086   "(xs,ys) : (listrel1 r)^* \<Longrightarrow> (x#xs,x#ys) : (listrel1 r)^*"
  5087 apply(induct rule: rtrancl.induct)
  5088  apply simp
  5089 by (metis listrel1I2 rtrancl.rtrancl_into_rtrancl)
  5090 
  5091 lemma rtrancl_listrel1_ConsI2:
  5092   "(x,y) \<in> r^* \<Longrightarrow> (xs, ys) \<in> (listrel1 r)^*
  5093   \<Longrightarrow> (x # xs, y # ys) \<in> (listrel1 r)^*"
  5094   by (blast intro: rtrancl_trans rtrancl_listrel1_ConsI1 
  5095     subsetD[OF listrel1_rtrancl_subset_rtrancl_listrel1 listrel1I1])
  5096 
  5097 lemma listrel1_subset_listrel:
  5098   "r \<subseteq> r' \<Longrightarrow> refl r' \<Longrightarrow> listrel1 r \<subseteq> listrel(r')"
  5099 by(auto elim!: listrel1E simp add: listrel_iff_zip set_zip refl_on_def)
  5100 
  5101 lemma listrel_reflcl_if_listrel1:
  5102   "(xs,ys) : listrel1 r \<Longrightarrow> (xs,ys) : listrel(r^*)"
  5103 by(erule listrel1E)(auto simp add: listrel_iff_zip set_zip)
  5104 
  5105 lemma listrel_rtrancl_eq_rtrancl_listrel1: "listrel (r^*) = (listrel1 r)^*"
  5106 proof
  5107   { fix x y assume "(x,y) \<in> listrel (r^*)"
  5108     then have "(x,y) \<in> (listrel1 r)^*"
  5109     by induct (auto intro: rtrancl_listrel1_ConsI2) }
  5110   then show "listrel (r^*) \<subseteq> (listrel1 r)^*"
  5111     by (rule subrelI)
  5112 next
  5113   show "listrel (r^*) \<supseteq> (listrel1 r)^*"
  5114   proof(rule subrelI)
  5115     fix xs ys assume "(xs,ys) \<in> (listrel1 r)^*"
  5116     then show "(xs,ys) \<in> listrel (r^*)"
  5117     proof induct
  5118       case base show ?case by(auto simp add: listrel_iff_zip set_zip)
  5119     next
  5120       case (step ys zs)
  5121       thus ?case  by (metis listrel_reflcl_if_listrel1 listrel_rtrancl_trans)
  5122     qed
  5123   qed
  5124 qed
  5125 
  5126 lemma rtrancl_listrel1_if_listrel:
  5127   "(xs,ys) : listrel r \<Longrightarrow> (xs,ys) : (listrel1 r)^*"
  5128 by(metis listrel_rtrancl_eq_rtrancl_listrel1 subsetD[OF listrel_mono] r_into_rtrancl subsetI)
  5129 
  5130 lemma listrel_subset_rtrancl_listrel1: "listrel r \<subseteq> (listrel1 r)^*"
  5131 by(fast intro:rtrancl_listrel1_if_listrel)
  5132 
  5133 
  5134 subsection {* Size function *}
  5135 
  5136 lemma [measure_function]: "is_measure f \<Longrightarrow> is_measure (list_size f)"
  5137 by (rule is_measure_trivial)
  5138 
  5139 lemma [measure_function]: "is_measure f \<Longrightarrow> is_measure (option_size f)"
  5140 by (rule is_measure_trivial)
  5141 
  5142 lemma list_size_estimation[termination_simp]: 
  5143   "x \<in> set xs \<Longrightarrow> y < f x \<Longrightarrow> y < list_size f xs"
  5144 by (induct xs) auto
  5145 
  5146 lemma list_size_estimation'[termination_simp]: 
  5147   "x \<in> set xs \<Longrightarrow> y \<le> f x \<Longrightarrow> y \<le> list_size f xs"
  5148 by (induct xs) auto
  5149 
  5150 lemma list_size_map[simp]: "list_size f (map g xs) = list_size (f o g) xs"
  5151 by (induct xs) auto
  5152 
  5153 lemma list_size_append[simp]: "list_size f (xs @ ys) = list_size f xs + list_size f ys"
  5154 by (induct xs, auto)
  5155 
  5156 lemma list_size_pointwise[termination_simp]: 
  5157   "(\<And>x. x \<in> set xs \<Longrightarrow> f x \<le> g x) \<Longrightarrow> list_size f xs \<le> list_size g xs"
  5158 by (induct xs) force+
  5159 
  5160 
  5161 subsection {* Monad operation *}
  5162 
  5163 definition bind :: "'a list \<Rightarrow> ('a \<Rightarrow> 'b list) \<Rightarrow> 'b list" where
  5164   "bind xs f = concat (map f xs)"
  5165 
  5166 hide_const (open) bind
  5167 
  5168 lemma bind_simps [simp]:
  5169   "List.bind [] f = []"
  5170   "List.bind (x # xs) f = f x @ List.bind xs f"
  5171   by (simp_all add: bind_def)
  5172 
  5173 
  5174 subsection {* Transfer *}
  5175 
  5176 definition
  5177   embed_list :: "nat list \<Rightarrow> int list"
  5178 where
  5179   "embed_list l = map int l"
  5180 
  5181 definition
  5182   nat_list :: "int list \<Rightarrow> bool"
  5183 where
  5184   "nat_list l = nat_set (set l)"
  5185 
  5186 definition
  5187   return_list :: "int list \<Rightarrow> nat list"
  5188 where
  5189   "return_list l = map nat l"
  5190 
  5191 lemma transfer_nat_int_list_return_embed: "nat_list l \<longrightarrow>
  5192     embed_list (return_list l) = l"
  5193   unfolding embed_list_def return_list_def nat_list_def nat_set_def
  5194   apply (induct l)
  5195   apply auto
  5196 done
  5197 
  5198 lemma transfer_nat_int_list_functions:
  5199   "l @ m = return_list (embed_list l @ embed_list m)"
  5200   "[] = return_list []"
  5201   unfolding return_list_def embed_list_def
  5202   apply auto
  5203   apply (induct l, auto)
  5204   apply (induct m, auto)
  5205 done
  5206 
  5207 (*
  5208 lemma transfer_nat_int_fold1: "fold f l x =
  5209     fold (%x. f (nat x)) (embed_list l) x";
  5210 *)
  5211 
  5212 
  5213 subsection {* Code generation *}
  5214 
  5215 subsubsection {* Counterparts for set-related operations *}
  5216 
  5217 definition member :: "'a list \<Rightarrow> 'a \<Rightarrow> bool" where
  5218   [code_abbrev]: "member xs x \<longleftrightarrow> x \<in> set xs"
  5219 
  5220 text {*
  5221   Use @{text member} only for generating executable code.  Otherwise use
  5222   @{prop "x \<in> set xs"} instead --- it is much easier to reason about.
  5223 *}
  5224 
  5225 lemma member_rec [code]:
  5226   "member (x # xs) y \<longleftrightarrow> x = y \<or> member xs y"
  5227   "member [] y \<longleftrightarrow> False"
  5228   by (auto simp add: member_def)
  5229 
  5230 lemma in_set_member (* FIXME delete candidate *):
  5231   "x \<in> set xs \<longleftrightarrow> member xs x"
  5232   by (simp add: member_def)
  5233 
  5234 definition list_all :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool" where
  5235   list_all_iff [code_abbrev]: "list_all P xs \<longleftrightarrow> Ball (set xs) P"
  5236 
  5237 definition list_ex :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool" where
  5238   list_ex_iff [code_abbrev]: "list_ex P xs \<longleftrightarrow> Bex (set xs) P"
  5239 
  5240 definition list_ex1 :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool" where
  5241   list_ex1_iff [code_abbrev]: "list_ex1 P xs \<longleftrightarrow> (\<exists>! x. x \<in> set xs \<and> P x)"
  5242 
  5243 text {*
  5244   Usually you should prefer @{text "\<forall>x\<in>set xs"}, @{text "\<exists>x\<in>set xs"}
  5245   and @{text "\<exists>!x. x\<in>set xs \<and> _"} over @{const list_all}, @{const list_ex}
  5246   and @{const list_ex1} in specifications.
  5247 *}
  5248 
  5249 lemma list_all_simps [simp, code]:
  5250   "list_all P (x # xs) \<longleftrightarrow> P x \<and> list_all P xs"
  5251   "list_all P [] \<longleftrightarrow> True"
  5252   by (simp_all add: list_all_iff)
  5253 
  5254 lemma list_ex_simps [simp, code]:
  5255   "list_ex P (x # xs) \<longleftrightarrow> P x \<or> list_ex P xs"
  5256   "list_ex P [] \<longleftrightarrow> False"
  5257   by (simp_all add: list_ex_iff)
  5258 
  5259 lemma list_ex1_simps [simp, code]:
  5260   "list_ex1 P [] = False"
  5261   "list_ex1 P (x # xs) = (if P x then list_all (\<lambda>y. \<not> P y \<or> x = y) xs else list_ex1 P xs)"
  5262   by (auto simp add: list_ex1_iff list_all_iff)
  5263 
  5264 lemma Ball_set_list_all: (* FIXME delete candidate *)
  5265   "Ball (set xs) P \<longleftrightarrow> list_all P xs"
  5266   by (simp add: list_all_iff)
  5267 
  5268 lemma Bex_set_list_ex: (* FIXME delete candidate *)
  5269   "Bex (set xs) P \<longleftrightarrow> list_ex P xs"
  5270   by (simp add: list_ex_iff)
  5271 
  5272 lemma list_all_append [simp]:
  5273   "list_all P (xs @ ys) \<longleftrightarrow> list_all P xs \<and> list_all P ys"
  5274   by (auto simp add: list_all_iff)
  5275 
  5276 lemma list_ex_append [simp]:
  5277   "list_ex P (xs @ ys) \<longleftrightarrow> list_ex P xs \<or> list_ex P ys"
  5278   by (auto simp add: list_ex_iff)
  5279 
  5280 lemma list_all_rev [simp]:
  5281   "list_all P (rev xs) \<longleftrightarrow> list_all P xs"
  5282   by (simp add: list_all_iff)
  5283 
  5284 lemma list_ex_rev [simp]:
  5285   "list_ex P (rev xs) \<longleftrightarrow> list_ex P xs"
  5286   by (simp add: list_ex_iff)
  5287 
  5288 lemma list_all_length:
  5289   "list_all P xs \<longleftrightarrow> (\<forall>n < length xs. P (xs ! n))"
  5290   by (auto simp add: list_all_iff set_conv_nth)
  5291 
  5292 lemma list_ex_length:
  5293   "list_ex P xs \<longleftrightarrow> (\<exists>n < length xs. P (xs ! n))"
  5294   by (auto simp add: list_ex_iff set_conv_nth)
  5295 
  5296 lemma list_all_cong [fundef_cong]:
  5297   "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> f x = g x) \<Longrightarrow> list_all f xs = list_all g ys"
  5298   by (simp add: list_all_iff)
  5299 
  5300 lemma list_any_cong [fundef_cong]:
  5301   "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> f x = g x) \<Longrightarrow> list_ex f xs = list_ex g ys"
  5302   by (simp add: list_ex_iff)
  5303 
  5304 text {* Executable checks for relations on sets *}
  5305 
  5306 definition listrel1p :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list \<Rightarrow> bool" where
  5307 "listrel1p r xs ys = ((xs, ys) \<in> listrel1 {(x, y). r x y})"
  5308 
  5309 lemma [code_unfold]:
  5310   "(xs, ys) \<in> listrel1 r = listrel1p (\<lambda>x y. (x, y) \<in> r) xs ys"
  5311 unfolding listrel1p_def by auto
  5312 
  5313 lemma [code]:
  5314   "listrel1p r [] xs = False"
  5315   "listrel1p r xs [] =  False"
  5316   "listrel1p r (x # xs) (y # ys) \<longleftrightarrow>
  5317      r x y \<and> xs = ys \<or> x = y \<and> listrel1p r xs ys"
  5318 by (simp add: listrel1p_def)+
  5319 
  5320 definition
  5321   lexordp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list \<Rightarrow> bool" where
  5322   "lexordp r xs ys = ((xs, ys) \<in> lexord {(x, y). r x y})"
  5323 
  5324 lemma [code_unfold]:
  5325   "(xs, ys) \<in> lexord r = lexordp (\<lambda>x y. (x, y) \<in> r) xs ys"
  5326 unfolding lexordp_def by auto
  5327 
  5328 lemma [code]:
  5329   "lexordp r xs [] = False"
  5330   "lexordp r [] (y#ys) = True"
  5331   "lexordp r (x # xs) (y # ys) = (r x y | (x = y & lexordp r xs ys))"
  5332 unfolding lexordp_def by auto
  5333 
  5334 text {* Bounded quantification and summation over nats. *}
  5335 
  5336 lemma atMost_upto [code_unfold]:
  5337   "{..n} = set [0..<Suc n]"
  5338   by auto
  5339 
  5340 lemma atLeast_upt [code_unfold]:
  5341   "{..<n} = set [0..<n]"
  5342   by auto
  5343 
  5344 lemma greaterThanLessThan_upt [code_unfold]:
  5345   "{n<..<m} = set [Suc n..<m]"
  5346   by auto
  5347 
  5348 lemmas atLeastLessThan_upt [code_unfold] = set_upt [symmetric]
  5349 
  5350 lemma greaterThanAtMost_upt [code_unfold]:
  5351   "{n<..m} = set [Suc n..<Suc m]"
  5352   by auto
  5353 
  5354 lemma atLeastAtMost_upt [code_unfold]:
  5355   "{n..m} = set [n..<Suc m]"
  5356   by auto
  5357 
  5358 lemma all_nat_less_eq [code_unfold]:
  5359   "(\<forall>m<n\<Colon>nat. P m) \<longleftrightarrow> (\<forall>m \<in> {0..<n}. P m)"
  5360   by auto
  5361 
  5362 lemma ex_nat_less_eq [code_unfold]:
  5363   "(\<exists>m<n\<Colon>nat. P m) \<longleftrightarrow> (\<exists>m \<in> {0..<n}. P m)"
  5364   by auto
  5365 
  5366 lemma all_nat_less [code_unfold]:
  5367   "(\<forall>m\<le>n\<Colon>nat. P m) \<longleftrightarrow> (\<forall>m \<in> {0..n}. P m)"
  5368   by auto
  5369 
  5370 lemma ex_nat_less [code_unfold]:
  5371   "(\<exists>m\<le>n\<Colon>nat. P m) \<longleftrightarrow> (\<exists>m \<in> {0..n}. P m)"
  5372   by auto
  5373 
  5374 lemma setsum_set_upt_conv_listsum_nat [code_unfold]:
  5375   "setsum f (set [m..<n]) = listsum (map f [m..<n])"
  5376   by (simp add: interv_listsum_conv_setsum_set_nat)
  5377 
  5378 text {* Summation over ints. *}
  5379 
  5380 lemma greaterThanLessThan_upto [code_unfold]:
  5381   "{i<..<j::int} = set [i+1..j - 1]"
  5382 by auto
  5383 
  5384 lemma atLeastLessThan_upto [code_unfold]:
  5385   "{i..<j::int} = set [i..j - 1]"
  5386 by auto
  5387 
  5388 lemma greaterThanAtMost_upto [code_unfold]:
  5389   "{i<..j::int} = set [i+1..j]"
  5390 by auto
  5391 
  5392 lemmas atLeastAtMost_upto [code_unfold] = set_upto [symmetric]
  5393 
  5394 lemma setsum_set_upto_conv_listsum_int [code_unfold]:
  5395   "setsum f (set [i..j::int]) = listsum (map f [i..j])"
  5396   by (simp add: interv_listsum_conv_setsum_set_int)
  5397 
  5398 
  5399 subsubsection {* Optimizing by rewriting *}
  5400 
  5401 definition null :: "'a list \<Rightarrow> bool" where
  5402   [code_abbrev]: "null xs \<longleftrightarrow> xs = []"
  5403 
  5404 text {*
  5405   Efficient emptyness check is implemented by @{const null}.
  5406 *}
  5407 
  5408 lemma null_rec [code]:
  5409   "null (x # xs) \<longleftrightarrow> False"
  5410   "null [] \<longleftrightarrow> True"
  5411   by (simp_all add: null_def)
  5412 
  5413 lemma eq_Nil_null: (* FIXME delete candidate *)
  5414   "xs = [] \<longleftrightarrow> null xs"
  5415   by (simp add: null_def)
  5416 
  5417 lemma equal_Nil_null [code_unfold]:
  5418   "HOL.equal xs [] \<longleftrightarrow> null xs"
  5419   by (simp add: equal eq_Nil_null)
  5420 
  5421 definition maps :: "('a \<Rightarrow> 'b list) \<Rightarrow> 'a list \<Rightarrow> 'b list" where
  5422   [code_abbrev]: "maps f xs = concat (map f xs)"
  5423 
  5424 definition map_filter :: "('a \<Rightarrow> 'b option) \<Rightarrow> 'a list \<Rightarrow> 'b list" where
  5425   [code_post]: "map_filter f xs = map (the \<circ> f) (filter (\<lambda>x. f x \<noteq> None) xs)"
  5426 
  5427 text {*
  5428   Operations @{const maps} and @{const map_filter} avoid
  5429   intermediate lists on execution -- do not use for proving.
  5430 *}
  5431 
  5432 lemma maps_simps [code]:
  5433   "maps f (x # xs) = f x @ maps f xs"
  5434   "maps f [] = []"
  5435   by (simp_all add: maps_def)
  5436 
  5437 lemma map_filter_simps [code]:
  5438   "map_filter f (x # xs) = (case f x of None \<Rightarrow> map_filter f xs | Some y \<Rightarrow> y # map_filter f xs)"
  5439   "map_filter f [] = []"
  5440   by (simp_all add: map_filter_def split: option.split)
  5441 
  5442 lemma concat_map_maps: (* FIXME delete candidate *)
  5443   "concat (map f xs) = maps f xs"
  5444   by (simp add: maps_def)
  5445 
  5446 lemma map_filter_map_filter [code_unfold]:
  5447   "map f (filter P xs) = map_filter (\<lambda>x. if P x then Some (f x) else None) xs"
  5448   by (simp add: map_filter_def)
  5449 
  5450 text {* Optimized code for @{text"\<forall>i\<in>{a..b::int}"} and @{text"\<forall>n:{a..<b::nat}"}
  5451 and similiarly for @{text"\<exists>"}. *}
  5452 
  5453 definition all_interval_nat :: "(nat \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> bool" where
  5454   "all_interval_nat P i j \<longleftrightarrow> (\<forall>n \<in> {i..<j}. P n)"
  5455 
  5456 lemma [code]:
  5457   "all_interval_nat P i j \<longleftrightarrow> i \<ge> j \<or> P i \<and> all_interval_nat P (Suc i) j"
  5458 proof -
  5459   have *: "\<And>n. P i \<Longrightarrow> \<forall>n\<in>{Suc i..<j}. P n \<Longrightarrow> i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P n"
  5460   proof -
  5461     fix n
  5462     assume "P i" "\<forall>n\<in>{Suc i..<j}. P n" "i \<le> n" "n < j"
  5463     then show "P n" by (cases "n = i") simp_all
  5464   qed
  5465   show ?thesis by (auto simp add: all_interval_nat_def intro: *)
  5466 qed
  5467 
  5468 lemma list_all_iff_all_interval_nat [code_unfold]:
  5469   "list_all P [i..<j] \<longleftrightarrow> all_interval_nat P i j"
  5470   by (simp add: list_all_iff all_interval_nat_def)
  5471 
  5472 lemma list_ex_iff_not_all_inverval_nat [code_unfold]:
  5473   "list_ex P [i..<j] \<longleftrightarrow> \<not> (all_interval_nat (Not \<circ> P) i j)"
  5474   by (simp add: list_ex_iff all_interval_nat_def)
  5475 
  5476 definition all_interval_int :: "(int \<Rightarrow> bool) \<Rightarrow> int \<Rightarrow> int \<Rightarrow> bool" where
  5477   "all_interval_int P i j \<longleftrightarrow> (\<forall>k \<in> {i..j}. P k)"
  5478 
  5479 lemma [code]:
  5480   "all_interval_int P i j \<longleftrightarrow> i > j \<or> P i \<and> all_interval_int P (i + 1) j"
  5481 proof -
  5482   have *: "\<And>k. P i \<Longrightarrow> \<forall>k\<in>{i+1..j}. P k \<Longrightarrow> i \<le> k \<Longrightarrow> k \<le> j \<Longrightarrow> P k"
  5483   proof -
  5484     fix k
  5485     assume "P i" "\<forall>k\<in>{i+1..j}. P k" "i \<le> k" "k \<le> j"
  5486     then show "P k" by (cases "k = i") simp_all
  5487   qed
  5488   show ?thesis by (auto simp add: all_interval_int_def intro: *)
  5489 qed
  5490 
  5491 lemma list_all_iff_all_interval_int [code_unfold]:
  5492   "list_all P [i..j] \<longleftrightarrow> all_interval_int P i j"
  5493   by (simp add: list_all_iff all_interval_int_def)
  5494 
  5495 lemma list_ex_iff_not_all_inverval_int [code_unfold]:
  5496   "list_ex P [i..j] \<longleftrightarrow> \<not> (all_interval_int (Not \<circ> P) i j)"
  5497   by (simp add: list_ex_iff all_interval_int_def)
  5498 
  5499 hide_const (open) member null maps map_filter all_interval_nat all_interval_int
  5500 
  5501 
  5502 subsubsection {* Pretty lists *}
  5503 
  5504 use "Tools/list_code.ML"
  5505 
  5506 code_type list
  5507   (SML "_ list")
  5508   (OCaml "_ list")
  5509   (Haskell "![(_)]")
  5510   (Scala "List[(_)]")
  5511 
  5512 code_const Nil
  5513   (SML "[]")
  5514   (OCaml "[]")
  5515   (Haskell "[]")
  5516   (Scala "!Nil")
  5517 
  5518 code_instance list :: equal
  5519   (Haskell -)
  5520 
  5521 code_const "HOL.equal \<Colon> 'a list \<Rightarrow> 'a list \<Rightarrow> bool"
  5522   (Haskell infix 4 "==")
  5523 
  5524 code_reserved SML
  5525   list
  5526 
  5527 code_reserved OCaml
  5528   list
  5529 
  5530 setup {* fold (List_Code.add_literal_list) ["SML", "OCaml", "Haskell", "Scala"] *}
  5531 
  5532 
  5533 subsubsection {* Use convenient predefined operations *}
  5534 
  5535 code_const "op @"
  5536   (SML infixr 7 "@")
  5537   (OCaml infixr 6 "@")
  5538   (Haskell infixr 5 "++")
  5539   (Scala infixl 7 "++")
  5540 
  5541 code_const map
  5542   (Haskell "map")
  5543 
  5544 code_const filter
  5545   (Haskell "filter")
  5546 
  5547 code_const concat
  5548   (Haskell "concat")
  5549 
  5550 code_const List.maps
  5551   (Haskell "concatMap")
  5552 
  5553 code_const rev
  5554   (Haskell "reverse")
  5555 
  5556 code_const zip
  5557   (Haskell "zip")
  5558 
  5559 code_const List.null
  5560   (Haskell "null")
  5561 
  5562 code_const takeWhile
  5563   (Haskell "takeWhile")
  5564 
  5565 code_const dropWhile
  5566   (Haskell "dropWhile")
  5567 
  5568 code_const list_all
  5569   (Haskell "all")
  5570 
  5571 code_const list_ex
  5572   (Haskell "any")
  5573 
  5574 
  5575 subsubsection {* Implementation of sets by lists *}
  5576 
  5577 text {* Basic operations *}
  5578 
  5579 lemma is_empty_set [code]:
  5580   "Set.is_empty (set xs) \<longleftrightarrow> List.null xs"
  5581   by (simp add: Set.is_empty_def null_def)
  5582 
  5583 lemma empty_set [code]:
  5584   "{} = set []"
  5585   by simp
  5586 
  5587 lemma UNIV_coset [code]:
  5588   "UNIV = List.coset []"
  5589   by simp
  5590 
  5591 lemma compl_set [code]:
  5592   "- set xs = List.coset xs"
  5593   by simp
  5594 
  5595 lemma compl_coset [code]:
  5596   "- List.coset xs = set xs"
  5597   by simp
  5598 
  5599 lemma [code]:
  5600   "x \<in> set xs \<longleftrightarrow> List.member xs x"
  5601   "x \<in> List.coset xs \<longleftrightarrow> \<not> List.member xs x"
  5602   by (simp_all add: member_def)
  5603 
  5604 lemma insert_code [code]:
  5605   "insert x (set xs) = set (List.insert x xs)"
  5606   "insert x (List.coset xs) = List.coset (removeAll x xs)"
  5607   by simp_all
  5608 
  5609 lemma remove_code [code]:
  5610   "Set.remove x (set xs) = set (removeAll x xs)"
  5611   "Set.remove x (List.coset xs) = List.coset (List.insert x xs)"
  5612   by (simp_all add: remove_def Compl_insert)
  5613 
  5614 lemma project_set [code]:
  5615   "Set.project P (set xs) = set (filter P xs)"
  5616   by auto
  5617 
  5618 lemma image_set [code]:
  5619   "image f (set xs) = set (map f xs)"
  5620   by simp
  5621 
  5622 lemma Ball_set [code]:
  5623   "Ball (set xs) P \<longleftrightarrow> list_all P xs"
  5624   by (simp add: list_all_iff)
  5625 
  5626 lemma Bex_set [code]:
  5627   "Bex (set xs) P \<longleftrightarrow> list_ex P xs"
  5628   by (simp add: list_ex_iff)
  5629 
  5630 lemma card_set [code]:
  5631   "card (set xs) = length (remdups xs)"
  5632 proof -
  5633   have "card (set (remdups xs)) = length (remdups xs)"
  5634     by (rule distinct_card) simp
  5635   then show ?thesis by simp
  5636 qed
  5637 
  5638 lemma the_elem_set [code]:
  5639   "the_elem (set [x]) = x"
  5640   by simp
  5641 
  5642 lemma Pow_set [code]:
  5643   "Pow (set []) = {{}}"
  5644   "Pow (set (x # xs)) = (let A = Pow (set xs) in A \<union> insert x ` A)"
  5645   by (simp_all add: Pow_insert Let_def)
  5646 
  5647 text {* Further operations on sets *}
  5648 
  5649 (* Minimal refinement of equality on sets *)
  5650 declare subset_eq[code del]
  5651 lemma subset_code [code]:
  5652   "set xs <= B \<longleftrightarrow> (ALL x : set xs. x : B)"
  5653   "List.coset xs <= List.coset ys \<longleftrightarrow> set ys <= set xs"
  5654   "List.coset [] <= set [] \<longleftrightarrow> False"
  5655 by auto
  5656 
  5657 lemma setsum_code [code]:
  5658   "setsum f (set xs) = listsum (map f (remdups xs))"
  5659 by (simp add: listsum_distinct_conv_setsum_set)
  5660 
  5661 definition map_project :: "('a \<Rightarrow> 'b option) \<Rightarrow> 'a set \<Rightarrow> 'b set" where
  5662   "map_project f A = {b. \<exists> a \<in> A. f a = Some b}"
  5663 
  5664 lemma [code]:
  5665   "map_project f (set xs) = set (List.map_filter f xs)"
  5666 unfolding map_project_def map_filter_def
  5667 by auto (metis (lifting, mono_tags) CollectI image_eqI o_apply the.simps)
  5668 
  5669 hide_const (open) map_project
  5670 
  5671 text {* Operations on relations *}
  5672 
  5673 lemma product_code [code]:
  5674   "Product_Type.product (set xs) (set ys) = set [(x, y). x \<leftarrow> xs, y \<leftarrow> ys]"
  5675   by (auto simp add: Product_Type.product_def)
  5676 
  5677 lemma Id_on_set [code]:
  5678   "Id_on (set xs) = set [(x, x). x \<leftarrow> xs]"
  5679   by (auto simp add: Id_on_def)
  5680 
  5681 lemma [code]:
  5682   "R `` S = List.map_project (%(x, y). if x : S then Some y else None) R"
  5683 unfolding map_project_def by (auto split: prod.split split_if_asm)
  5684 
  5685 lemma trancl_set_ntrancl [code]:
  5686   "trancl (set xs) = ntrancl (card (set xs) - 1) (set xs)"
  5687   by (simp add: finite_trancl_ntranl)
  5688 
  5689 lemma set_rel_comp [code]:
  5690   "set xys O set yzs = set ([(fst xy, snd yz). xy \<leftarrow> xys, yz \<leftarrow> yzs, snd xy = fst yz])"
  5691   by (auto simp add: Bex_def)
  5692 
  5693 lemma wf_set [code]:
  5694   "wf (set xs) = acyclic (set xs)"
  5695   by (simp add: wf_iff_acyclic_if_finite)
  5696 
  5697 end