src/HOL/MicroJava/J/TypeRel.thy
author haftmann
Wed Oct 11 10:49:28 2006 +0200 (2006-10-11)
changeset 20970 c2a342e548a9
parent 18576 8d98b7711e47
child 22271 51a80e238b29
permissions -rw-r--r--
added code lemma
     1 (*  Title:      HOL/MicroJava/J/TypeRel.thy
     2     ID:         $Id$
     3     Author:     David von Oheimb
     4     Copyright   1999 Technische Universitaet Muenchen
     5 *)
     6 
     7 header {* \isaheader{Relations between Java Types} *}
     8 
     9 theory TypeRel imports Decl begin
    10 
    11 consts
    12   subcls1 :: "'c prog => (cname \<times> cname) set"  -- "subclass"
    13   widen   :: "'c prog => (ty    \<times> ty   ) set"  -- "widening"
    14   cast    :: "'c prog => (ty    \<times> ty   ) set"  -- "casting"
    15 
    16 syntax (xsymbols)
    17   subcls1 :: "'c prog => [cname, cname] => bool" ("_ \<turnstile> _ \<prec>C1 _" [71,71,71] 70)
    18   subcls  :: "'c prog => [cname, cname] => bool" ("_ \<turnstile> _ \<preceq>C _"  [71,71,71] 70)
    19   widen   :: "'c prog => [ty   , ty   ] => bool" ("_ \<turnstile> _ \<preceq> _"   [71,71,71] 70)
    20   cast    :: "'c prog => [ty   , ty   ] => bool" ("_ \<turnstile> _ \<preceq>? _"  [71,71,71] 70)
    21 
    22 syntax
    23   subcls1 :: "'c prog => [cname, cname] => bool" ("_ |- _ <=C1 _" [71,71,71] 70)
    24   subcls  :: "'c prog => [cname, cname] => bool" ("_ |- _ <=C _"  [71,71,71] 70)
    25   widen   :: "'c prog => [ty   , ty   ] => bool" ("_ |- _ <= _"   [71,71,71] 70)
    26   cast    :: "'c prog => [ty   , ty   ] => bool" ("_ |- _ <=? _"  [71,71,71] 70)
    27 
    28 translations
    29   "G\<turnstile>C \<prec>C1 D" == "(C,D) \<in> subcls1 G"
    30   "G\<turnstile>C \<preceq>C  D" == "(C,D) \<in> (subcls1 G)^*"
    31   "G\<turnstile>S \<preceq>   T" == "(S,T) \<in> widen   G"
    32   "G\<turnstile>C \<preceq>?  D" == "(C,D) \<in> cast    G"
    33 
    34 -- "direct subclass, cf. 8.1.3"
    35 inductive "subcls1 G" intros
    36   subcls1I: "\<lbrakk>class G C = Some (D,rest); C \<noteq> Object\<rbrakk> \<Longrightarrow> G\<turnstile>C\<prec>C1D"
    37   
    38 lemma subcls1D: 
    39   "G\<turnstile>C\<prec>C1D \<Longrightarrow> C \<noteq> Object \<and> (\<exists>fs ms. class G C = Some (D,fs,ms))"
    40 apply (erule subcls1.elims)
    41 apply auto
    42 done
    43 
    44 lemma subcls1_def2: 
    45   "subcls1 G = 
    46      (SIGMA C: {C. is_class G C} . {D. C\<noteq>Object \<and> fst (the (class G C))=D})"
    47   by (auto simp add: is_class_def dest: subcls1D intro: subcls1I)
    48 
    49 lemma finite_subcls1: "finite (subcls1 G)"
    50 apply(subst subcls1_def2)
    51 apply(rule finite_SigmaI [OF finite_is_class])
    52 apply(rule_tac B = "{fst (the (class G C))}" in finite_subset)
    53 apply  auto
    54 done
    55 
    56 lemma subcls_is_class: "(C,D) \<in> (subcls1 G)^+ ==> is_class G C"
    57 apply (unfold is_class_def)
    58 apply(erule trancl_trans_induct)
    59 apply (auto dest!: subcls1D)
    60 done
    61 
    62 lemma subcls_is_class2 [rule_format (no_asm)]: 
    63   "G\<turnstile>C\<preceq>C D \<Longrightarrow> is_class G D \<longrightarrow> is_class G C"
    64 apply (unfold is_class_def)
    65 apply (erule rtrancl_induct)
    66 apply  (drule_tac [2] subcls1D)
    67 apply  auto
    68 done
    69 
    70 constdefs
    71   class_rec :: "'c prog \<Rightarrow> cname \<Rightarrow> 'a \<Rightarrow>
    72     (cname \<Rightarrow> fdecl list \<Rightarrow> 'c mdecl list \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> 'a"
    73   "class_rec G == wfrec ((subcls1 G)^-1)
    74     (\<lambda>r C t f. case class G C of
    75          None \<Rightarrow> arbitrary
    76        | Some (D,fs,ms) \<Rightarrow> 
    77            f C fs ms (if C = Object then t else r D t f))"
    78 
    79 lemma class_rec_lemma: "wf ((subcls1 G)^-1) \<Longrightarrow> class G C = Some (D,fs,ms) \<Longrightarrow>
    80  class_rec G C t f = f C fs ms (if C=Object then t else class_rec G D t f)"
    81   by (simp add: class_rec_def wfrec cut_apply [OF converseI [OF subcls1I]])
    82 
    83 definition
    84   "wf_class G = wf ((subcls1 G)^-1)"
    85 
    86 lemma class_rec_func [code func]:
    87   "class_rec G C t f = (if wf_class G then
    88     (case class G C
    89       of None \<Rightarrow> arbitrary
    90        | Some (D, fs, ms) \<Rightarrow> f C fs ms (if C = Object then t else class_rec G D t f))
    91     else class_rec G C t f)"
    92 proof (cases "wf_class G")
    93   case False then show ?thesis by auto
    94 next
    95   case True
    96   from `wf_class G` have wf: "wf ((subcls1 G)^-1)"
    97     unfolding wf_class_def .
    98   show ?thesis
    99   proof (cases "class G C")
   100     case None
   101     with wf show ?thesis
   102       by (simp add: class_rec_def wfrec cut_apply [OF converseI [OF subcls1I]])
   103   next
   104     case (Some x) show ?thesis
   105     proof (cases x)
   106       case (fields D fs ms)
   107       then have is_some: "class G C = Some (D, fs, ms)" using Some by simp
   108       note class_rec = class_rec_lemma [OF wf is_some]
   109       show ?thesis unfolding class_rec by (simp add: is_some)
   110     qed
   111   qed
   112 qed
   113 
   114 consts
   115 
   116   method :: "'c prog \<times> cname => ( sig   \<rightharpoonup> cname \<times> ty \<times> 'c)" (* ###curry *)
   117   field  :: "'c prog \<times> cname => ( vname \<rightharpoonup> cname \<times> ty     )" (* ###curry *)
   118   fields :: "'c prog \<times> cname => ((vname \<times> cname) \<times> ty) list" (* ###curry *)
   119 
   120 -- "methods of a class, with inheritance, overriding and hiding, cf. 8.4.6"
   121 defs method_def: "method \<equiv> \<lambda>(G,C). class_rec G C empty (\<lambda>C fs ms ts.
   122                            ts ++ map_of (map (\<lambda>(s,m). (s,(C,m))) ms))"
   123 
   124 lemma method_rec_lemma: "[|class G C = Some (D,fs,ms); wf ((subcls1 G)^-1)|] ==>
   125   method (G,C) = (if C = Object then empty else method (G,D)) ++  
   126   map_of (map (\<lambda>(s,m). (s,(C,m))) ms)"
   127 apply (unfold method_def)
   128 apply (simp split del: split_if)
   129 apply (erule (1) class_rec_lemma [THEN trans]);
   130 apply auto
   131 done
   132 
   133 
   134 -- "list of fields of a class, including inherited and hidden ones"
   135 defs fields_def: "fields \<equiv> \<lambda>(G,C). class_rec G C []    (\<lambda>C fs ms ts.
   136                            map (\<lambda>(fn,ft). ((fn,C),ft)) fs @ ts)"
   137 
   138 lemma fields_rec_lemma: "[|class G C = Some (D,fs,ms); wf ((subcls1 G)^-1)|] ==>
   139  fields (G,C) = 
   140   map (\<lambda>(fn,ft). ((fn,C),ft)) fs @ (if C = Object then [] else fields (G,D))"
   141 apply (unfold fields_def)
   142 apply (simp split del: split_if)
   143 apply (erule (1) class_rec_lemma [THEN trans]);
   144 apply auto
   145 done
   146 
   147 
   148 defs field_def: "field == map_of o (map (\<lambda>((fn,fd),ft). (fn,(fd,ft)))) o fields"
   149 
   150 lemma field_fields: 
   151 "field (G,C) fn = Some (fd, fT) \<Longrightarrow> map_of (fields (G,C)) (fn, fd) = Some fT"
   152 apply (unfold field_def)
   153 apply (rule table_of_remap_SomeD)
   154 apply simp
   155 done
   156 
   157 
   158 -- "widening, viz. method invocation conversion,cf. 5.3 i.e. sort of syntactic subtyping"
   159 inductive "widen G" intros 
   160   refl   [intro!, simp]:       "G\<turnstile>      T \<preceq> T"   -- "identity conv., cf. 5.1.1"
   161   subcls         : "G\<turnstile>C\<preceq>C D ==> G\<turnstile>Class C \<preceq> Class D"
   162   null   [intro!]:             "G\<turnstile>     NT \<preceq> RefT R"
   163 
   164 -- "casting conversion, cf. 5.5 / 5.1.5"
   165 -- "left out casts on primitve types"
   166 inductive "cast G" intros
   167   widen:  "G\<turnstile> C\<preceq> D ==> G\<turnstile>C \<preceq>? D"
   168   subcls: "G\<turnstile> D\<preceq>C C ==> G\<turnstile>Class C \<preceq>? Class D"
   169 
   170 lemma widen_PrimT_RefT [iff]: "(G\<turnstile>PrimT pT\<preceq>RefT rT) = False"
   171 apply (rule iffI)
   172 apply (erule widen.elims)
   173 apply auto
   174 done
   175 
   176 lemma widen_RefT: "G\<turnstile>RefT R\<preceq>T ==> \<exists>t. T=RefT t"
   177 apply (ind_cases "G\<turnstile>S\<preceq>T")
   178 apply auto
   179 done
   180 
   181 lemma widen_RefT2: "G\<turnstile>S\<preceq>RefT R ==> \<exists>t. S=RefT t"
   182 apply (ind_cases "G\<turnstile>S\<preceq>T")
   183 apply auto
   184 done
   185 
   186 lemma widen_Class: "G\<turnstile>Class C\<preceq>T ==> \<exists>D. T=Class D"
   187 apply (ind_cases "G\<turnstile>S\<preceq>T")
   188 apply auto
   189 done
   190 
   191 lemma widen_Class_NullT [iff]: "(G\<turnstile>Class C\<preceq>NT) = False"
   192 apply (rule iffI)
   193 apply (ind_cases "G\<turnstile>S\<preceq>T")
   194 apply auto
   195 done
   196 
   197 lemma widen_Class_Class [iff]: "(G\<turnstile>Class C\<preceq> Class D) = (G\<turnstile>C\<preceq>C D)"
   198 apply (rule iffI)
   199 apply (ind_cases "G\<turnstile>S\<preceq>T")
   200 apply (auto elim: widen.subcls)
   201 done
   202 
   203 lemma widen_NT_Class [simp]: "G \<turnstile> T \<preceq> NT \<Longrightarrow> G \<turnstile> T \<preceq> Class D"
   204 by (ind_cases "G \<turnstile> T \<preceq> NT",  auto)
   205 
   206 lemma cast_PrimT_RefT [iff]: "(G\<turnstile>PrimT pT\<preceq>? RefT rT) = False"
   207 apply (rule iffI)
   208 apply (erule cast.elims)
   209 apply auto
   210 done
   211 
   212 lemma cast_RefT: "G \<turnstile> C \<preceq>? Class D \<Longrightarrow> \<exists> rT. C = RefT rT"
   213 apply (erule cast.cases)
   214 apply simp apply (erule widen.cases) 
   215 apply auto
   216 done
   217 
   218 theorem widen_trans[trans]: "\<lbrakk>G\<turnstile>S\<preceq>U; G\<turnstile>U\<preceq>T\<rbrakk> \<Longrightarrow> G\<turnstile>S\<preceq>T"
   219 proof -
   220   assume "G\<turnstile>S\<preceq>U" thus "\<And>T. G\<turnstile>U\<preceq>T \<Longrightarrow> G\<turnstile>S\<preceq>T"
   221   proof induct
   222     case (refl T T') thus "G\<turnstile>T\<preceq>T'" .
   223   next
   224     case (subcls C D T)
   225     then obtain E where "T = Class E" by (blast dest: widen_Class)
   226     with subcls show "G\<turnstile>Class C\<preceq>T" by (auto elim: rtrancl_trans)
   227   next
   228     case (null R RT)
   229     then obtain rt where "RT = RefT rt" by (blast dest: widen_RefT)
   230     thus "G\<turnstile>NT\<preceq>RT" by auto
   231   qed
   232 qed
   233 
   234 end