src/Pure/library.ML
author wenzelm
Tue Jul 24 19:44:35 2007 +0200 (2007-07-24)
changeset 23963 c2ee97a963db
parent 23937 66e1f24d655d
child 24023 6fd65e2e0dba
permissions -rw-r--r--
moved exception capture/release to structure Exn;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val flip: ('a -> 'b -> 'c) -> 'b -> 'a -> 'c
    26   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    27   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    28   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    29   val ? : bool * ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    34 
    35   (*errors*)
    36   exception SYS_ERROR of string
    37   val sys_error: string -> 'a
    38   exception ERROR of string
    39   val error: string -> 'a
    40   val cat_error: string -> string -> 'a
    41   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    42 
    43   (*pairs*)
    44   val pair: 'a -> 'b -> 'a * 'b
    45   val rpair: 'a -> 'b -> 'b * 'a
    46   val fst: 'a * 'b -> 'a
    47   val snd: 'a * 'b -> 'b
    48   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    51   val swap: 'a * 'b -> 'b * 'a
    52   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    53   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    54   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    55 
    56   (*booleans*)
    57   val equal: ''a -> ''a -> bool
    58   val not_equal: ''a -> ''a -> bool
    59   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    61   val exists: ('a -> bool) -> 'a list -> bool
    62   val forall: ('a -> bool) -> 'a list -> bool
    63   val set: bool ref -> bool
    64   val reset: bool ref -> bool
    65   val toggle: bool ref -> bool
    66   val change: 'a ref -> ('a -> 'a) -> unit
    67   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    69 
    70   (*lists*)
    71   exception UnequalLengths
    72   val single: 'a -> 'a list
    73   val the_single: 'a list -> 'a
    74   val singleton: ('a list -> 'b list) -> 'a -> 'b
    75   val apply: ('a -> 'a) list -> 'a -> 'a
    76   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    77   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    78   val flat: 'a list list -> 'a list
    79   val unflat: 'a list list -> 'b list -> 'b list list
    80   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    81   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    82   val maps: ('a -> 'b list) -> 'a list -> 'b list
    83   val chop: int -> 'a list -> 'a list * 'a list
    84   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    85   val nth: 'a list -> int -> 'a
    86   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    87   val nth_list: 'a list list -> int -> 'a list
    88   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    89   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val split_last: 'a list -> 'a list * 'a
    91   val find_index: ('a -> bool) -> 'a list -> int
    92   val find_index_eq: ''a -> ''a list -> int
    93   val find_first: ('a -> bool) -> 'a list -> 'a option
    94   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    95   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    96   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    97   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    98   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
    99   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   100   val ~~ : 'a list * 'b list -> ('a * 'b) list
   101   val split_list: ('a * 'b) list -> 'a list * 'b list
   102   val separate: 'a -> 'a list -> 'a list
   103   val replicate: int -> 'a -> 'a list
   104   val multiply: 'a list -> 'a list list -> 'a list list
   105   val product: 'a list -> 'b list -> ('a * 'b) list
   106   val filter: ('a -> bool) -> 'a list -> 'a list
   107   val filter_out: ('a -> bool) -> 'a list -> 'a list
   108   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   109   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   110   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   111   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   112   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   113   val prefixes1: 'a list -> 'a list list
   114   val prefixes: 'a list -> 'a list list
   115   val suffixes1: 'a list -> 'a list list
   116   val suffixes: 'a list -> 'a list list
   117 
   118   (*integers*)
   119   val inc: int ref -> int
   120   val dec: int ref -> int
   121   val upto: int * int -> int list
   122   val downto: int * int -> int list
   123   val radixpand: int * int -> int list
   124   val radixstring: int * string * int -> string
   125   val string_of_int: int -> string
   126   val signed_string_of_int: int -> string
   127   val string_of_indexname: string * int -> string
   128   val read_intinf: int -> string list -> IntInf.int * string list
   129   val read_int: string list -> int * string list
   130   val oct_char: string -> string
   131 
   132   (*strings*)
   133   val nth_string: string -> int -> string
   134   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   135   val exists_string: (string -> bool) -> string -> bool
   136   val forall_string: (string -> bool) -> string -> bool
   137   val enclose: string -> string -> string -> string
   138   val unenclose: string -> string
   139   val quote: string -> string
   140   val space_implode: string -> string list -> string
   141   val commas: string list -> string
   142   val commas_quote: string list -> string
   143   val cat_lines: string list -> string
   144   val space_explode: string -> string -> string list
   145   val split_lines: string -> string list
   146   val prefix_lines: string -> string -> string
   147   val untabify: string list -> string list
   148   val prefix: string -> string -> string
   149   val suffix: string -> string -> string
   150   val unprefix: string -> string -> string
   151   val unsuffix: string -> string -> string
   152   val replicate_string: int -> string -> string
   153   val translate_string: (string -> string) -> string -> string
   154 
   155   (*lists as sets -- see also Pure/General/ord_list.ML*)
   156   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   157   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   158   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   159   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   160   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   161   val mem: ''a * ''a list -> bool
   162   val mem_int: int * int list -> bool
   163   val mem_string: string * string list -> bool
   164   val union: ''a list * ''a list -> ''a list
   165   val union_int: int list * int list -> int list
   166   val union_string: string list * string list -> string list
   167   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   168   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   169   val inter: ''a list * ''a list -> ''a list
   170   val inter_int: int list * int list -> int list
   171   val inter_string: string list * string list -> string list
   172   val subset: ''a list * ''a list -> bool
   173   val subset_int: int list * int list -> bool
   174   val subset_string: string list * string list -> bool
   175   val eq_set: ''a list * ''a list -> bool
   176   val eq_set_string: string list * string list -> bool
   177   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   178   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   179   val \ : ''a list * ''a -> ''a list
   180   val \\ : ''a list * ''a list -> ''a list
   181   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   182   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   183   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   184 
   185   (*lists as multisets*)
   186   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   187   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   188 
   189   (*orders*)
   190   val is_equal: order -> bool
   191   val rev_order: order -> order
   192   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   193   val int_ord: int * int -> order
   194   val string_ord: string * string -> order
   195   val fast_string_ord: string * string -> order
   196   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   197   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   198   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   199   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   200   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   201   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   202   val sort_strings: string list -> string list
   203   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   204 
   205   (*random numbers*)
   206   exception RANDOM
   207   val random: unit -> real
   208   val random_range: int -> int -> int
   209   val one_of: 'a list -> 'a
   210   val frequency: (int * 'a) list -> 'a
   211 
   212   (*misc*)
   213   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   214   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   215   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   216   val gensym: string -> string
   217   type stamp
   218   val stamp: unit -> stamp
   219   type serial
   220   val serial: unit -> serial
   221   val serial_string: unit -> string
   222   structure Object: sig type T end
   223 end;
   224 
   225 signature LIBRARY =
   226 sig
   227   include BASIC_LIBRARY
   228   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   229   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   230   val take: int * 'a list -> 'a list
   231   val drop: int * 'a list -> 'a list
   232   val last_elem: 'a list -> 'a
   233 end;
   234 
   235 structure Library: LIBRARY =
   236 struct
   237 
   238 (* functions *)
   239 
   240 fun undefined _ = raise Match;
   241 
   242 fun I x = x;
   243 fun K x = fn _ => x;
   244 fun flip f x y = f y x;
   245 fun curry f x y = f (x, y);
   246 fun uncurry f (x, y) = f x y;
   247 
   248 (*application and structured results -- old version*)
   249 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   250 
   251 (*conditional application*)
   252 fun b ? f = fn x => if b then f x else x;
   253 
   254 (*composition with multiple args*)
   255 fun (f oo g) x y = f (g x y);
   256 fun (f ooo g) x y z = f (g x y z);
   257 fun (f oooo g) x y z w = f (g x y z w);
   258 
   259 (*function exponentiation: f(...(f x)...) with n applications of f*)
   260 fun funpow 0 _ x = x
   261   | funpow n f x = funpow (n - 1) f (f x);
   262 
   263 
   264 (* errors *)
   265 
   266 exception SYS_ERROR of string;
   267 fun sys_error msg = raise SYS_ERROR msg;
   268 
   269 exception ERROR of string;
   270 fun error msg = raise ERROR msg;
   271 
   272 fun cat_error "" msg = error msg
   273   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   274 
   275 fun assert_all pred list msg =
   276   let
   277     fun ass [] = ()
   278       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   279   in ass list end;
   280 
   281 
   282 (* pairs *)
   283 
   284 fun pair x y = (x, y);
   285 fun rpair x y = (y, x);
   286 
   287 fun fst (x, y) = x;
   288 fun snd (x, y) = y;
   289 
   290 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   291 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   292 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   293 
   294 fun swap (x, y) = (y, x);
   295 
   296 fun apfst f (x, y) = (f x, y);
   297 fun apsnd f (x, y) = (x, f y);
   298 fun pairself f (x, y) = (f x, f y);
   299 
   300 
   301 (* booleans *)
   302 
   303 (*polymorphic equality*)
   304 fun equal x y = x = y;
   305 fun not_equal x y = x <> y;
   306 
   307 (*combining predicates*)
   308 fun p orf q = fn x => p x orelse q x;
   309 fun p andf q = fn x => p x andalso q x;
   310 
   311 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   312 fun exists (pred: 'a -> bool) : 'a list -> bool =
   313   let fun boolf [] = false
   314         | boolf (x :: xs) = pred x orelse boolf xs
   315   in boolf end;
   316 
   317 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   318 fun forall (pred: 'a -> bool) : 'a list -> bool =
   319   let fun boolf [] = true
   320         | boolf (x :: xs) = pred x andalso boolf xs
   321   in boolf end;
   322 
   323 
   324 (* flags *)
   325 
   326 fun set flag = (flag := true; true);
   327 fun reset flag = (flag := false; false);
   328 fun toggle flag = (flag := not (! flag); ! flag);
   329 
   330 fun change r f = r := f (! r);
   331 
   332 (*temporarily set flag during execution*)
   333 fun setmp_noncritical flag value f x =
   334   let
   335     val orig_value = ! flag;
   336     val _ = flag := value;
   337     val result = Exn.capture f x;
   338     val _ = flag := orig_value;
   339   in Exn.release result end;
   340 
   341 fun setmp flag value f x = CRITICAL (fn () => setmp_noncritical flag value f x);
   342 
   343 
   344 
   345 (** lists **)
   346 
   347 exception UnequalLengths;
   348 
   349 fun single x = [x];
   350 
   351 fun the_single [x] = x
   352   | the_single _ = raise Empty;
   353 
   354 fun singleton f x = the_single (f [x]);
   355 
   356 fun apply [] x = x
   357   | apply (f :: fs) x = apply fs (f x);
   358 
   359 
   360 (* fold -- old versions *)
   361 
   362 (*the following versions of fold are designed to fit nicely with infixes*)
   363 
   364 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   365     for operators that associate to the left (TAIL RECURSIVE)*)
   366 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   367   let fun itl (e, [])  = e
   368         | itl (e, a::l) = itl (f(e, a), l)
   369   in  itl end;
   370 
   371 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   372     for operators that associate to the right (not tail recursive)*)
   373 fun foldr f (l, e) =
   374   let fun itr [] = e
   375         | itr (a::l) = f(a, itr l)
   376   in  itr l  end;
   377 
   378 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   379     for n > 0, operators that associate to the right (not tail recursive)*)
   380 fun foldr1 f [] = raise Empty
   381   | foldr1 f l =
   382       let fun itr [x] = x
   383             | itr (x::l) = f(x, itr l)
   384       in  itr l  end;
   385 
   386 fun foldl_map f =
   387   let
   388     fun fold_aux (x, []) = (x, [])
   389       | fold_aux (x, y :: ys) =
   390           let
   391             val (x', y') = f (x, y);
   392             val (x'', ys') = fold_aux (x', ys);
   393           in (x'', y' :: ys') end;
   394   in fold_aux end;
   395 
   396 
   397 (* basic list functions *)
   398 
   399 fun eq_list eq (list1, list2) =
   400   let
   401     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   402       | eq_lst _ = true;
   403   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   404 
   405 fun maps f [] = []
   406   | maps f (x :: xs) = f x @ maps f xs;
   407 
   408 fun chop 0 xs = ([], xs)
   409   | chop _ [] = ([], [])
   410   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   411 
   412 (*take the first n elements from a list*)
   413 fun take (n, []) = []
   414   | take (n, x :: xs) =
   415       if n > 0 then x :: take (n - 1, xs) else [];
   416 
   417 (*drop the first n elements from a list*)
   418 fun drop (n, []) = []
   419   | drop (n, x :: xs) =
   420       if n > 0 then drop (n - 1, xs) else x :: xs;
   421 
   422 fun dropwhile P [] = []
   423   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   424 
   425 (*return nth element of a list, where 0 designates the first element;
   426   raise Subscript if list too short*)
   427 fun nth xs i = List.nth (xs, i);
   428 
   429 fun nth_list xss i = nth xss i handle Subscript => [];
   430 
   431 fun nth_map 0 f (x :: xs) = f x :: xs
   432   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   433   | nth_map _ _ [] = raise Subscript;
   434 
   435 fun map_index f =
   436   let
   437     fun mapp _ [] = []
   438       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   439   in mapp 0 end;
   440 
   441 fun fold_index f =
   442   let
   443     fun fold_aux _ [] y = y
   444       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   445   in fold_aux 0 end;
   446 
   447 val last_elem = List.last;
   448 
   449 (*rear decomposition*)
   450 fun split_last [] = raise Empty
   451   | split_last [x] = ([], x)
   452   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   453 
   454 (*find the position of an element in a list*)
   455 fun find_index pred =
   456   let fun find _ [] = ~1
   457         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   458   in find 0 end;
   459 
   460 fun find_index_eq x = find_index (equal x);
   461 
   462 (*find first element satisfying predicate*)
   463 val find_first = List.find;
   464 
   465 (*get first element by lookup function*)
   466 fun get_first _ [] = NONE
   467   | get_first f (x :: xs) =
   468       (case f x of
   469         NONE => get_first f xs
   470       | some => some);
   471 
   472 fun get_index f =
   473   let
   474     fun get _ [] = NONE
   475       | get i (x :: xs) =
   476           case f x
   477            of NONE => get (i + 1) xs
   478             | SOME y => SOME (i, y)
   479   in get 0 end;
   480 
   481 val flat = List.concat;
   482 
   483 fun unflat (xs :: xss) ys =
   484       let val (ps, qs) = chop (length xs) ys
   485       in ps :: unflat xss qs end
   486   | unflat [] [] = []
   487   | unflat _ _ = raise UnequalLengths;
   488 
   489 fun burrow f xss = unflat xss (f (flat xss));
   490 
   491 fun fold_burrow f xss s =
   492   apfst (unflat xss) (f (flat xss) s);
   493 
   494 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   495 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   496   | separate _ xs = xs;
   497 
   498 (*make the list [x, x, ..., x] of length n*)
   499 fun replicate n (x: 'a) : 'a list =
   500   let fun rep (0, xs) = xs
   501         | rep (n, xs) = rep (n - 1, x :: xs)
   502   in
   503     if n < 0 then raise Subscript
   504     else rep (n, [])
   505   end;
   506 
   507 fun translate_string f = String.translate (f o String.str);
   508 
   509 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   510 fun multiply [] _ = []
   511   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   512 
   513 (*direct product*)
   514 fun product _ [] = []
   515   | product [] _ = []
   516   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   517 
   518 
   519 (* filter *)
   520 
   521 (*copy the list preserving elements that satisfy the predicate*)
   522 val filter = List.filter;
   523 fun filter_out f = filter (not o f);
   524 val map_filter = List.mapPartial;
   525 
   526 
   527 (* lists of pairs *)
   528 
   529 exception UnequalLengths;
   530 
   531 fun map2 _ [] [] = []
   532   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   533   | map2 _ _ _ = raise UnequalLengths;
   534 
   535 fun fold2 f [] [] z = z
   536   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   537   | fold2 f _ _ _ = raise UnequalLengths;
   538 
   539 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   540   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   541   | zip_options _ [] = []
   542   | zip_options [] _ = raise UnequalLengths;
   543 
   544 (*combine two lists forming a list of pairs:
   545   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   546 fun [] ~~ [] = []
   547   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   548   | _ ~~ _ = raise UnequalLengths;
   549 
   550 (*inverse of ~~; the old 'split':
   551   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   552 val split_list = ListPair.unzip;
   553 
   554 
   555 (* prefixes, suffixes *)
   556 
   557 fun is_prefix _ [] _ = true
   558   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   559   | is_prefix eq _ _ = false;
   560 
   561 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   562    where xi is the first element that does not satisfy the predicate*)
   563 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   564   let fun take (rxs, []) = (rev rxs, [])
   565         | take (rxs, x :: xs) =
   566             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   567   in  take([], xs)  end;
   568 
   569 fun chop_prefix eq ([], ys) = ([], ([], ys))
   570   | chop_prefix eq (xs, []) = ([], (xs, []))
   571   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   572       if eq (x, y) then
   573         let val (ps', xys'') = chop_prefix eq (xs', ys')
   574         in (x :: ps', xys'') end
   575       else ([], (xs, ys));
   576 
   577 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   578    where xi is the last element that does not satisfy the predicate*)
   579 fun take_suffix _ [] = ([], [])
   580   | take_suffix pred (x :: xs) =
   581       (case take_suffix pred xs of
   582         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   583       | (prfx, sffx) => (x :: prfx, sffx));
   584 
   585 fun prefixes1 [] = []
   586   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   587 
   588 fun prefixes xs = [] :: prefixes1 xs;
   589 
   590 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   591 fun suffixes xs = [] :: suffixes1 xs;
   592 
   593 
   594 
   595 (** integers **)
   596 
   597 fun inc i = (i := ! i + 1; ! i);
   598 fun dec i = (i := ! i - 1; ! i);
   599 
   600 
   601 (* lists of integers *)
   602 
   603 (*make the list [from, from + 1, ..., to]*)
   604 fun (i upto j) =
   605   if i > j then [] else i :: (i + 1 upto j);
   606 
   607 (*make the list [from, from - 1, ..., to]*)
   608 fun (i downto j) =
   609   if i < j then [] else i :: (i - 1 downto j);
   610 
   611 
   612 (* convert integers to strings *)
   613 
   614 (*expand the number in the given base;
   615   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   616 fun radixpand (base, num) : int list =
   617   let
   618     fun radix (n, tail) =
   619       if n < base then n :: tail
   620       else radix (n div base, (n mod base) :: tail)
   621   in radix (num, []) end;
   622 
   623 (*expands a number into a string of characters starting from "zerochar";
   624   example: radixstring (2, "0", 8) gives "1000"*)
   625 fun radixstring (base, zerochar, num) =
   626   let val offset = ord zerochar;
   627       fun chrof n = chr (offset + n)
   628   in implode (map chrof (radixpand (base, num))) end;
   629 
   630 
   631 val string_of_int = Int.toString;
   632 
   633 fun signed_string_of_int i =
   634   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   635 
   636 fun string_of_indexname (a, 0) = a
   637   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   638 
   639 
   640 (* read integers *)
   641 
   642 fun read_intinf radix cs =
   643   let
   644     val zero = ord "0";
   645     val limit = zero + radix;
   646     fun scan (num, []) = (num, [])
   647       | scan (num, c :: cs) =
   648         if zero <= ord c andalso ord c < limit then
   649           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   650         else (num, c :: cs);
   651   in scan (IntInf.fromInt 0, cs) end;
   652 
   653 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   654 
   655 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   656 
   657 
   658 
   659 (** strings **)
   660 
   661 (* functions tuned for strings, avoiding explode *)
   662 
   663 fun nth_string str i =
   664   (case try String.substring (str, i, 1) of
   665     SOME s => s
   666   | NONE => raise Subscript);
   667 
   668 fun fold_string f str x0 =
   669   let
   670     val n = size str;
   671     fun iter (x, i) =
   672       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   673   in iter (x0, 0) end;
   674 
   675 fun exists_string pred str =
   676   let
   677     val n = size str;
   678     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   679   in ex 0 end;
   680 
   681 fun forall_string pred = not o exists_string (not o pred);
   682 
   683 (*enclose in brackets*)
   684 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   685 fun unenclose str = String.substring (str, 1, size str - 2);
   686 
   687 (*simple quoting (does not escape special chars)*)
   688 val quote = enclose "\"" "\"";
   689 
   690 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   691 fun space_implode a bs = implode (separate a bs);
   692 
   693 val commas = space_implode ", ";
   694 val commas_quote = commas o map quote;
   695 
   696 (*concatenate messages, one per line, into a string*)
   697 val cat_lines = space_implode "\n";
   698 
   699 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   700 fun space_explode _ "" = []
   701   | space_explode sep s = String.fields (fn c => str c = sep) s;
   702 
   703 val split_lines = space_explode "\n";
   704 
   705 fun prefix_lines "" txt = txt
   706   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   707 
   708 fun untabify chs =
   709   let
   710     val tab_width = 8;
   711 
   712     fun untab pos [] ys = rev ys
   713       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   714       | untab pos ("\t" :: xs) ys =
   715           let val d = tab_width - (pos mod tab_width)
   716           in untab (pos + d) xs (funpow d (cons " ") ys) end
   717       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   718   in
   719     if not (exists (fn c => c = "\t") chs) then chs
   720     else untab 0 chs []
   721   end;
   722 
   723 fun prefix prfx s = prfx ^ s;
   724 fun suffix sffx s = s ^ sffx;
   725 
   726 fun unprefix prfx s =
   727   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   728   else raise Fail "unprefix";
   729 
   730 fun unsuffix sffx s =
   731   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   732   else raise Fail "unsuffix";
   733 
   734 fun replicate_string 0 _ = ""
   735   | replicate_string 1 a = a
   736   | replicate_string k a =
   737       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   738       else replicate_string (k div 2) (a ^ a) ^ a;
   739 
   740 
   741 
   742 (** lists as sets -- see also Pure/General/ord_list.ML **)
   743 
   744 (*canonical member, insert, remove*)
   745 fun member eq list x =
   746   let
   747     fun memb [] = false
   748       | memb (y :: ys) = eq (x, y) orelse memb ys;
   749   in memb list end;
   750 
   751 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   752 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   753 
   754 fun subtract eq = fold (remove eq);
   755 
   756 fun merge _ ([], ys) = ys
   757   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   758 
   759 (*old-style infixes*)
   760 fun x mem xs = member (op =) xs x;
   761 fun (x: int) mem_int xs = member (op =) xs x;
   762 fun (x: string) mem_string xs = member (op =) xs x;
   763 
   764 
   765 (*union of sets represented as lists: no repetitions*)
   766 fun xs union [] = xs
   767   | [] union ys = ys
   768   | (x :: xs) union ys = xs union (insert (op =) x ys);
   769 
   770 (*union of sets, optimized version for ints*)
   771 fun (xs:int list) union_int [] = xs
   772   | [] union_int ys = ys
   773   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   774 
   775 (*union of sets, optimized version for strings*)
   776 fun (xs:string list) union_string [] = xs
   777   | [] union_string ys = ys
   778   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   779 
   780 (*generalized union*)
   781 fun gen_union eq (xs, []) = xs
   782   | gen_union eq ([], ys) = ys
   783   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   784 
   785 
   786 (*intersection*)
   787 fun [] inter ys = []
   788   | (x :: xs) inter ys =
   789       if x mem ys then x :: (xs inter ys) else xs inter ys;
   790 
   791 (*intersection, optimized version for ints*)
   792 fun ([]:int list) inter_int ys = []
   793   | (x :: xs) inter_int ys =
   794       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   795 
   796 (*intersection, optimized version for strings *)
   797 fun ([]:string list) inter_string ys = []
   798   | (x :: xs) inter_string ys =
   799       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   800 
   801 (*generalized intersection*)
   802 fun gen_inter eq ([], ys) = []
   803   | gen_inter eq (x::xs, ys) =
   804       if member eq ys x then x :: gen_inter eq (xs, ys)
   805       else gen_inter eq (xs, ys);
   806 
   807 
   808 (*subset*)
   809 fun [] subset ys = true
   810   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   811 
   812 (*subset, optimized version for ints*)
   813 fun ([]: int list) subset_int ys = true
   814   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   815 
   816 (*subset, optimized version for strings*)
   817 fun ([]: string list) subset_string ys = true
   818   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   819 
   820 (*set equality*)
   821 fun eq_set (xs, ys) =
   822   xs = ys orelse (xs subset ys andalso ys subset xs);
   823 
   824 (*set equality for strings*)
   825 fun eq_set_string ((xs: string list), ys) =
   826   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   827 
   828 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   829 
   830 fun gen_eq_set eq (xs, ys) =
   831   eq_list eq (xs, ys) orelse
   832     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   833 
   834 
   835 (*removing an element from a list WITHOUT duplicates*)
   836 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   837   | [] \ x = [];
   838 fun ys \\ xs = foldl (op \) (ys,xs);
   839 
   840 
   841 (*makes a list of the distinct members of the input; preserves order, takes
   842   first of equal elements*)
   843 fun distinct eq lst =
   844   let
   845     fun dist (rev_seen, []) = rev rev_seen
   846       | dist (rev_seen, x :: xs) =
   847           if member eq rev_seen x then dist (rev_seen, xs)
   848           else dist (x :: rev_seen, xs);
   849   in dist ([], lst) end;
   850 
   851 (*returns a list containing all repeated elements exactly once; preserves
   852   order, takes first of equal elements*)
   853 fun duplicates eq lst =
   854   let
   855     fun dups (rev_dups, []) = rev rev_dups
   856       | dups (rev_dups, x :: xs) =
   857           if member eq rev_dups x orelse not (member eq xs x) then
   858             dups (rev_dups, xs)
   859           else dups (x :: rev_dups, xs);
   860   in dups ([], lst) end;
   861 
   862 fun has_duplicates eq =
   863   let
   864     fun dups [] = false
   865       | dups (x :: xs) = member eq xs x orelse dups xs;
   866   in dups end;
   867 
   868 
   869 
   870 (** lists as multisets **)
   871 
   872 fun remove1 _ _ [] = raise Empty
   873   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   874 
   875 fun submultiset _ ([], _)  = true
   876   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   877 
   878 
   879 
   880 (** orders **)
   881 
   882 fun is_equal EQUAL = true
   883   | is_equal _ = false;
   884 
   885 fun rev_order LESS = GREATER
   886   | rev_order EQUAL = EQUAL
   887   | rev_order GREATER = LESS;
   888 
   889 (*assume rel is a linear strict order*)
   890 fun make_ord rel (x, y) =
   891   if rel (x, y) then LESS
   892   else if rel (y, x) then GREATER
   893   else EQUAL;
   894 
   895 val int_ord = Int.compare;
   896 val string_ord = String.compare;
   897 
   898 fun fast_string_ord (s1, s2) =
   899   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   900 
   901 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   902   | option_ord _ (NONE, NONE) = EQUAL
   903   | option_ord _ (NONE, SOME _) = LESS
   904   | option_ord _ (SOME _, NONE) = GREATER;
   905 
   906 (*lexicographic product*)
   907 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   908   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   909 
   910 (*dictionary order -- in general NOT well-founded!*)
   911 fun dict_ord elem_ord (x :: xs, y :: ys) =
   912       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   913   | dict_ord _ ([], []) = EQUAL
   914   | dict_ord _ ([], _ :: _) = LESS
   915   | dict_ord _ (_ :: _, []) = GREATER;
   916 
   917 (*lexicographic product of lists*)
   918 fun list_ord elem_ord (xs, ys) =
   919   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   920 
   921 
   922 (* sorting *)
   923 
   924 (*quicksort -- stable, i.e. does not reorder equal elements*)
   925 fun quicksort unique ord =
   926   let
   927     fun qsort [] = []
   928       | qsort (xs as [_]) = xs
   929       | qsort (xs as [x, y]) =
   930           (case ord (x, y) of
   931             LESS => xs
   932           | EQUAL => if unique then [x] else xs
   933           | GREATER => [y, x])
   934       | qsort xs =
   935           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   936           in qsort lts @ eqs @ qsort gts end
   937     and part _ [] = ([], [], [])
   938       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   939     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   940       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   941       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   942       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   943   in qsort end;
   944 
   945 fun sort ord = quicksort false ord;
   946 fun sort_distinct ord = quicksort true ord;
   947 
   948 val sort_strings = sort string_ord;
   949 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   950 
   951 
   952 
   953 (** random numbers **)
   954 
   955 exception RANDOM;
   956 
   957 fun rmod x y = x - y * Real.realFloor (x / y);
   958 
   959 local
   960   val a = 16807.0;
   961   val m = 2147483647.0;
   962   val random_seed = ref 1.0;
   963 in
   964 
   965 fun random () = CRITICAL (fn () =>
   966   let val r = rmod (a * ! random_seed) m
   967   in (random_seed := r; r) end);
   968 
   969 end;
   970 
   971 fun random_range l h =
   972   if h < l orelse l < 0 then raise RANDOM
   973   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   974 
   975 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   976 
   977 fun frequency xs =
   978   let
   979     val sum = foldl op + (0, map fst xs);
   980     fun pick n ((k: int, x) :: xs) =
   981       if n <= k then x else pick (n - k) xs
   982   in pick (random_range 1 sum) xs end;
   983 
   984 
   985 
   986 (** misc **)
   987 
   988 fun divide_and_conquer decomp x =
   989   let val (ys, recomb) = decomp x
   990   in recomb (map (divide_and_conquer decomp) ys) end;
   991 
   992 
   993 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
   994    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
   995 fun partition_list p i j =
   996   let fun part k xs =
   997             if k>j then
   998               (case xs of [] => []
   999                          | _ => raise Fail "partition_list")
  1000             else
  1001             let val (ns, rest) = List.partition (p k) xs;
  1002             in  ns :: part(k+1)rest  end
  1003   in  part i end;
  1004 
  1005 fun partition_eq (eq:'a * 'a -> bool) =
  1006   let
  1007     fun part [] = []
  1008       | part (x :: ys) =
  1009           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1010           in (x::xs)::(part xs') end
  1011   in part end;
  1012 
  1013 
  1014 
  1015 (* generating identifiers *)
  1016 
  1017 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1018 local
  1019 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1020 fun gensym_char i =
  1021   if i<26 then chr (ord "A" + i)
  1022   else if i<52 then chr (ord "a" + i - 26)
  1023   else chr (ord "0" + i - 52);
  1024 
  1025 val char_vec = Vector.tabulate (62, gensym_char);
  1026 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1027 
  1028 val gensym_seed = ref 0;
  1029 
  1030 in
  1031   fun gensym pre = pre ^ newid (CRITICAL (fn () => inc gensym_seed));
  1032 end;
  1033 
  1034 
  1035 (* stamps and serial numbers *)
  1036 
  1037 type stamp = unit ref;
  1038 val stamp: unit -> stamp = ref;
  1039 
  1040 type serial = int;
  1041 local val count = ref 0
  1042 in fun serial () = CRITICAL (fn () => inc count) end;
  1043 
  1044 val serial_string = string_of_int o serial;
  1045 
  1046 
  1047 (* generic objects *)
  1048 
  1049 (*note that the builtin exception datatype may be extended by new
  1050   constructors at any time*)
  1051 structure Object = struct type T = exn end;
  1052 
  1053 end;
  1054 
  1055 structure BasicLibrary: BASIC_LIBRARY = Library;
  1056 open BasicLibrary;