src/Pure/library.ML
author haftmann
Wed Oct 21 12:09:37 2009 +0200 (2009-10-21)
changeset 33049 c38f02fdf35d
parent 33040 cffdb7b28498
child 33050 fe166e8b9f07
permissions -rw-r--r--
curried inter as canonical list operation (beware of argument order)
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf mem mem_int mem_string
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*errors*)
    32   exception SYS_ERROR of string
    33   val sys_error: string -> 'a
    34   exception ERROR of string
    35   val error: string -> 'a
    36   val cat_error: string -> string -> 'a
    37   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    38 
    39   (*pairs*)
    40   val pair: 'a -> 'b -> 'a * 'b
    41   val rpair: 'a -> 'b -> 'b * 'a
    42   val fst: 'a * 'b -> 'a
    43   val snd: 'a * 'b -> 'b
    44   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    46   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    47   val swap: 'a * 'b -> 'b * 'a
    48   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    49   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    50   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    51 
    52   (*booleans*)
    53   val equal: ''a -> ''a -> bool
    54   val not_equal: ''a -> ''a -> bool
    55   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    56   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    57   val exists: ('a -> bool) -> 'a list -> bool
    58   val forall: ('a -> bool) -> 'a list -> bool
    59   val setmp_noncritical: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    60   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    61   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    62 
    63   (*lists*)
    64   exception UnequalLengths
    65   val single: 'a -> 'a list
    66   val the_single: 'a list -> 'a
    67   val singleton: ('a list -> 'b list) -> 'a -> 'b
    68   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    69   val apply: ('a -> 'a) list -> 'a -> 'a
    70   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    71   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    72   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    73   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    74   val flat: 'a list list -> 'a list
    75   val unflat: 'a list list -> 'b list -> 'b list list
    76   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    77   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    78   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    79   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    80   val maps: ('a -> 'b list) -> 'a list -> 'b list
    81   val filter: ('a -> bool) -> 'a list -> 'a list
    82   val filter_out: ('a -> bool) -> 'a list -> 'a list
    83   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    84   val chop: int -> 'a list -> 'a list * 'a list
    85   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    86   val nth: 'a list -> int -> 'a
    87   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    88   val nth_drop: int -> 'a list -> 'a list
    89   val nth_list: 'a list list -> int -> 'a list
    90   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    91   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    92   val split_last: 'a list -> 'a list * 'a
    93   val find_index: ('a -> bool) -> 'a list -> int
    94   val find_first: ('a -> bool) -> 'a list -> 'a option
    95   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    96   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    97   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    98   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    99   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   100   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   101   val ~~ : 'a list * 'b list -> ('a * 'b) list
   102   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   103   val split_list: ('a * 'b) list -> 'a list * 'b list
   104   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   105   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   106   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   107   val separate: 'a -> 'a list -> 'a list
   108   val surround: 'a -> 'a list -> 'a list
   109   val replicate: int -> 'a -> 'a list
   110   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   111   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   112   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   113   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   114   val prefixes1: 'a list -> 'a list list
   115   val prefixes: 'a list -> 'a list list
   116   val suffixes1: 'a list -> 'a list list
   117   val suffixes: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val upto: int * int -> int list
   121   val downto: int * int -> int list
   122   val radixpand: int * int -> int list
   123   val radixstring: int * string * int -> string
   124   val string_of_int: int -> string
   125   val signed_string_of_int: int -> string
   126   val string_of_indexname: string * int -> string
   127   val read_radix_int: int -> string list -> int * string list
   128   val read_int: string list -> int * string list
   129   val oct_char: string -> string
   130 
   131   (*strings*)
   132   val nth_string: string -> int -> string
   133   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   134   val exists_string: (string -> bool) -> string -> bool
   135   val forall_string: (string -> bool) -> string -> bool
   136   val first_field: string -> string -> (string * string) option
   137   val enclose: string -> string -> string -> string
   138   val unenclose: string -> string
   139   val quote: string -> string
   140   val space_implode: string -> string list -> string
   141   val commas: string list -> string
   142   val commas_quote: string list -> string
   143   val cat_lines: string list -> string
   144   val space_explode: string -> string -> string list
   145   val split_lines: string -> string list
   146   val prefix_lines: string -> string -> string
   147   val prefix: string -> string -> string
   148   val suffix: string -> string -> string
   149   val unprefix: string -> string -> string
   150   val unsuffix: string -> string -> string
   151   val replicate_string: int -> string -> string
   152   val translate_string: (string -> string) -> string -> string
   153   val match_string: string -> string -> bool
   154 
   155   (*lists as sets -- see also Pure/General/ord_list.ML*)
   156   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   157   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   158   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   159   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   160   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   161   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   162   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   163   val mem: ''a * ''a list -> bool
   164   val mem_int: int * int list -> bool
   165   val mem_string: string * string list -> bool
   166   val union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   167   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   168   val eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   169   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   170   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   171   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   172 
   173   (*lists as multisets*)
   174   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   175   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   176 
   177   (*orders*)
   178   val is_equal: order -> bool
   179   val rev_order: order -> order
   180   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   181   val bool_ord: bool * bool -> order
   182   val int_ord: int * int -> order
   183   val string_ord: string * string -> order
   184   val fast_string_ord: string * string -> order
   185   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   186   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   187   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   188   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   189   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   190   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   191   val sort_strings: string list -> string list
   192   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   193   val tag_list: int -> 'a list -> (int * 'a) list
   194   val untag_list: (int * 'a) list -> 'a list
   195   val order_list: (int * 'a) list -> 'a list
   196 
   197   (*random numbers*)
   198   exception RANDOM
   199   val random: unit -> real
   200   val random_range: int -> int -> int
   201   val one_of: 'a list -> 'a
   202   val frequency: (int * 'a) list -> 'a
   203 
   204   (*misc*)
   205   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   206   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   207     'a -> 'b -> 'c * 'b
   208   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   209   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   210   val gensym: string -> string
   211   type stamp
   212   val stamp: unit -> stamp
   213   type serial
   214   val serial: unit -> serial
   215   val serial_string: unit -> string
   216   structure Object: sig type T end
   217 end;
   218 
   219 signature LIBRARY =
   220 sig
   221   include BASIC_LIBRARY
   222   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   223   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   224   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   225   val take: int * 'a list -> 'a list
   226   val drop: int * 'a list -> 'a list
   227   val last_elem: 'a list -> 'a
   228 end;
   229 
   230 structure Library: LIBRARY =
   231 struct
   232 
   233 (* functions *)
   234 
   235 fun undefined _ = raise Match;
   236 
   237 fun I x = x;
   238 fun K x = fn _ => x;
   239 fun curry f x y = f (x, y);
   240 fun uncurry f (x, y) = f x y;
   241 
   242 (*conditional application*)
   243 fun b ? f = fn x => if b then f x else x;
   244 
   245 (*composition with multiple args*)
   246 fun (f oo g) x y = f (g x y);
   247 fun (f ooo g) x y z = f (g x y z);
   248 fun (f oooo g) x y z w = f (g x y z w);
   249 
   250 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   251 fun funpow (0 : int) _ = I
   252   | funpow n f = f #> funpow (n - 1) f;
   253 
   254 fun funpow_yield (0 : int) _ x = ([], x)
   255   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   256 
   257 (* errors *)
   258 
   259 exception SYS_ERROR of string;
   260 fun sys_error msg = raise SYS_ERROR msg;
   261 
   262 exception ERROR of string;
   263 fun error msg = raise ERROR msg;
   264 
   265 fun cat_error "" msg = error msg
   266   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   267 
   268 fun assert_all pred list msg =
   269   let
   270     fun ass [] = ()
   271       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   272   in ass list end;
   273 
   274 
   275 (* pairs *)
   276 
   277 fun pair x y = (x, y);
   278 fun rpair x y = (y, x);
   279 
   280 fun fst (x, y) = x;
   281 fun snd (x, y) = y;
   282 
   283 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   284 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   285 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   286 
   287 fun swap (x, y) = (y, x);
   288 
   289 fun apfst f (x, y) = (f x, y);
   290 fun apsnd f (x, y) = (x, f y);
   291 fun pairself f (x, y) = (f x, f y);
   292 
   293 
   294 (* booleans *)
   295 
   296 (*polymorphic equality*)
   297 fun equal x y = x = y;
   298 fun not_equal x y = x <> y;
   299 
   300 (*combining predicates*)
   301 fun p orf q = fn x => p x orelse q x;
   302 fun p andf q = fn x => p x andalso q x;
   303 
   304 val exists = List.exists;
   305 val forall = List.all;
   306 
   307 
   308 (* flags *)
   309 
   310 (*temporarily set flag during execution*)
   311 fun setmp_noncritical flag value f x =
   312   uninterruptible (fn restore_attributes => fn () =>
   313     let
   314       val orig_value = ! flag;
   315       val _ = flag := value;
   316       val result = Exn.capture (restore_attributes f) x;
   317       val _ = flag := orig_value;
   318     in Exn.release result end) ();
   319 
   320 fun setmp_CRITICAL flag value f x =
   321   NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   322 
   323 fun setmp_thread_data tag orig_data data f x =
   324   uninterruptible (fn restore_attributes => fn () =>
   325     let
   326       val _ = Thread.setLocal (tag, data);
   327       val result = Exn.capture (restore_attributes f) x;
   328       val _ = Thread.setLocal (tag, orig_data);
   329     in Exn.release result end) ();
   330 
   331 
   332 
   333 (** lists **)
   334 
   335 exception UnequalLengths;
   336 
   337 fun single x = [x];
   338 
   339 fun the_single [x] = x
   340   | the_single _ = raise Empty;
   341 
   342 fun singleton f x = the_single (f [x]);
   343 
   344 fun yield_singleton f x = f [x] #>> the_single;
   345 
   346 fun apply [] x = x
   347   | apply (f :: fs) x = apply fs (f x);
   348 
   349 fun perhaps_apply funs arg =
   350   let
   351     fun app [] res = res
   352       | app (f :: fs) (changed, x) =
   353           (case f x of
   354             NONE => app fs (changed, x)
   355           | SOME x' => app fs (true, x'));
   356   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   357 
   358 fun perhaps_loop f arg =
   359   let
   360     fun loop (changed, x) =
   361       (case f x of
   362         NONE => (changed, x)
   363       | SOME x' => loop (true, x'));
   364   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   365 
   366 
   367 (* fold -- old versions *)
   368 
   369 (*the following versions of fold are designed to fit nicely with infixes*)
   370 
   371 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   372     for operators that associate to the left (TAIL RECURSIVE)*)
   373 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   374   let fun itl (e, [])  = e
   375         | itl (e, a::l) = itl (f(e, a), l)
   376   in  itl end;
   377 
   378 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   379     for operators that associate to the right (not tail recursive)*)
   380 fun foldr f (l, e) =
   381   let fun itr [] = e
   382         | itr (a::l) = f(a, itr l)
   383   in  itr l  end;
   384 
   385 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   386     for operators that associate to the left (TAIL RECURSIVE)*)
   387 fun foldl1 f [] = raise Empty
   388   | foldl1 f (x :: xs) = foldl f (x, xs);
   389 
   390 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   391     for n > 0, operators that associate to the right (not tail recursive)*)
   392 fun foldr1 f [] = raise Empty
   393   | foldr1 f l =
   394       let fun itr [x] = x
   395             | itr (x::l) = f(x, itr l)
   396       in  itr l  end;
   397 
   398 fun foldl_map f =
   399   let
   400     fun fold_aux (x, []) = (x, [])
   401       | fold_aux (x, y :: ys) =
   402           let
   403             val (x', y') = f (x, y);
   404             val (x'', ys') = fold_aux (x', ys);
   405           in (x'', y' :: ys') end;
   406   in fold_aux end;
   407 
   408 
   409 (* basic list functions *)
   410 
   411 fun eq_list eq (list1, list2) =
   412   let
   413     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   414       | eq_lst _ = true;
   415   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   416 
   417 fun maps f [] = []
   418   | maps f (x :: xs) = f x @ maps f xs;
   419 
   420 val filter = List.filter;
   421 fun filter_out f = filter (not o f);
   422 val map_filter = List.mapPartial;
   423 
   424 fun chop (0: int) xs = ([], xs)
   425   | chop _ [] = ([], [])
   426   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   427 
   428 (*take the first n elements from a list*)
   429 fun take (n: int, []) = []
   430   | take (n, x :: xs) =
   431       if n > 0 then x :: take (n - 1, xs) else [];
   432 
   433 (*drop the first n elements from a list*)
   434 fun drop (n: int, []) = []
   435   | drop (n, x :: xs) =
   436       if n > 0 then drop (n - 1, xs) else x :: xs;
   437 
   438 fun dropwhile P [] = []
   439   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   440 
   441 (*return nth element of a list, where 0 designates the first element;
   442   raise Subscript if list too short*)
   443 fun nth xs i = List.nth (xs, i);
   444 
   445 fun nth_list xss i = nth xss i handle Subscript => [];
   446 
   447 fun nth_map 0 f (x :: xs) = f x :: xs
   448   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   449   | nth_map (_: int) _ [] = raise Subscript;
   450 
   451 fun nth_drop n xs =
   452   List.take (xs, n) @ List.drop (xs, n + 1);
   453 
   454 fun map_index f =
   455   let
   456     fun mapp (_: int) [] = []
   457       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   458   in mapp 0 end;
   459 
   460 fun fold_index f =
   461   let
   462     fun fold_aux (_: int) [] y = y
   463       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   464   in fold_aux 0 end;
   465 
   466 val last_elem = List.last;
   467 
   468 (*rear decomposition*)
   469 fun split_last [] = raise Empty
   470   | split_last [x] = ([], x)
   471   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   472 
   473 (*find position of first element satisfying a predicate*)
   474 fun find_index pred =
   475   let fun find (_: int) [] = ~1
   476         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   477   in find 0 end;
   478 
   479 (*find first element satisfying predicate*)
   480 val find_first = List.find;
   481 
   482 (*get first element by lookup function*)
   483 fun get_first _ [] = NONE
   484   | get_first f (x :: xs) =
   485       (case f x of
   486         NONE => get_first f xs
   487       | some => some);
   488 
   489 fun get_index f =
   490   let
   491     fun get (_: int) [] = NONE
   492       | get i (x :: xs) =
   493           case f x
   494            of NONE => get (i + 1) xs
   495             | SOME y => SOME (i, y)
   496   in get 0 end;
   497 
   498 val flat = List.concat;
   499 
   500 fun unflat (xs :: xss) ys =
   501       let val (ps, qs) = chop (length xs) ys
   502       in ps :: unflat xss qs end
   503   | unflat [] [] = []
   504   | unflat _ _ = raise UnequalLengths;
   505 
   506 fun burrow f xss = unflat xss (f (flat xss));
   507 
   508 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   509 
   510 fun fold_burrow f xss s =
   511   apfst (unflat xss) (f (flat xss) s);
   512 
   513 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   514 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   515   | separate _ xs = xs;
   516 
   517 fun surround s (x :: xs) = s :: x :: surround s xs
   518   | surround s [] = [s];
   519 
   520 (*make the list [x, x, ..., x] of length n*)
   521 fun replicate (n: int) x =
   522   let fun rep (0, xs) = xs
   523         | rep (n, xs) = rep (n - 1, x :: xs)
   524   in
   525     if n < 0 then raise Subscript
   526     else rep (n, [])
   527   end;
   528 
   529 
   530 (* direct product *)
   531 
   532 fun map_product f _ [] = []
   533   | map_product f [] _ = []
   534   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   535 
   536 fun fold_product f _ [] z = z
   537   | fold_product f [] _ z = z
   538   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   539 
   540 
   541 (* lists of pairs *)
   542 
   543 exception UnequalLengths;
   544 
   545 fun map2 _ [] [] = []
   546   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   547   | map2 _ _ _ = raise UnequalLengths;
   548 
   549 fun fold2 f [] [] z = z
   550   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   551   | fold2 f _ _ _ = raise UnequalLengths;
   552 
   553 fun map_split f [] = ([], [])
   554   | map_split f (x :: xs) =
   555       let
   556         val (y, w) = f x;
   557         val (ys, ws) = map_split f xs;
   558       in (y :: ys, w :: ws) end;
   559 
   560 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   561   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   562   | zip_options _ [] = []
   563   | zip_options [] _ = raise UnequalLengths;
   564 
   565 (*combine two lists forming a list of pairs:
   566   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   567 fun [] ~~ [] = []
   568   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   569   | _ ~~ _ = raise UnequalLengths;
   570 
   571 (*inverse of ~~; the old 'split':
   572   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   573 val split_list = ListPair.unzip;
   574 
   575 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   576 
   577 
   578 (* prefixes, suffixes *)
   579 
   580 fun is_prefix _ [] _ = true
   581   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   582   | is_prefix eq _ _ = false;
   583 
   584 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   585    where xi is the first element that does not satisfy the predicate*)
   586 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   587   let fun take (rxs, []) = (rev rxs, [])
   588         | take (rxs, x :: xs) =
   589             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   590   in  take([], xs)  end;
   591 
   592 fun chop_prefix eq ([], ys) = ([], ([], ys))
   593   | chop_prefix eq (xs, []) = ([], (xs, []))
   594   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   595       if eq (x, y) then
   596         let val (ps', xys'') = chop_prefix eq (xs', ys')
   597         in (x :: ps', xys'') end
   598       else ([], (xs, ys));
   599 
   600 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   601    where xi is the last element that does not satisfy the predicate*)
   602 fun take_suffix _ [] = ([], [])
   603   | take_suffix pred (x :: xs) =
   604       (case take_suffix pred xs of
   605         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   606       | (prfx, sffx) => (x :: prfx, sffx));
   607 
   608 fun prefixes1 [] = []
   609   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   610 
   611 fun prefixes xs = [] :: prefixes1 xs;
   612 
   613 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   614 fun suffixes xs = [] :: suffixes1 xs;
   615 
   616 
   617 
   618 (** integers **)
   619 
   620 (* lists of integers *)
   621 
   622 (*make the list [from, from + 1, ..., to]*)
   623 fun ((i: int) upto j) =
   624   if i > j then [] else i :: (i + 1 upto j);
   625 
   626 (*make the list [from, from - 1, ..., to]*)
   627 fun ((i: int) downto j) =
   628   if i < j then [] else i :: (i - 1 downto j);
   629 
   630 
   631 (* convert integers to strings *)
   632 
   633 (*expand the number in the given base;
   634   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   635 fun radixpand (base, num) : int list =
   636   let
   637     fun radix (n, tail) =
   638       if n < base then n :: tail
   639       else radix (n div base, (n mod base) :: tail)
   640   in radix (num, []) end;
   641 
   642 (*expands a number into a string of characters starting from "zerochar";
   643   example: radixstring (2, "0", 8) gives "1000"*)
   644 fun radixstring (base, zerochar, num) =
   645   let val offset = ord zerochar;
   646       fun chrof n = chr (offset + n)
   647   in implode (map chrof (radixpand (base, num))) end;
   648 
   649 
   650 val string_of_int = Int.toString;
   651 
   652 fun signed_string_of_int i =
   653   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   654 
   655 fun string_of_indexname (a, 0) = a
   656   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   657 
   658 
   659 (* read integers *)
   660 
   661 fun read_radix_int radix cs =
   662   let
   663     val zero = ord "0";
   664     val limit = zero + radix;
   665     fun scan (num, []) = (num, [])
   666       | scan (num, c :: cs) =
   667         if zero <= ord c andalso ord c < limit then
   668           scan (radix * num + (ord c - zero), cs)
   669         else (num, c :: cs);
   670   in scan (0, cs) end;
   671 
   672 val read_int = read_radix_int 10;
   673 
   674 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   675 
   676 
   677 
   678 (** strings **)
   679 
   680 (* functions tuned for strings, avoiding explode *)
   681 
   682 fun nth_string str i =
   683   (case try String.substring (str, i, 1) of
   684     SOME s => s
   685   | NONE => raise Subscript);
   686 
   687 fun fold_string f str x0 =
   688   let
   689     val n = size str;
   690     fun iter (x, i) =
   691       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   692   in iter (x0, 0) end;
   693 
   694 fun exists_string pred str =
   695   let
   696     val n = size str;
   697     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   698   in ex 0 end;
   699 
   700 fun forall_string pred = not o exists_string (not o pred);
   701 
   702 fun first_field sep str =
   703   let
   704     val n = size sep;
   705     val len = size str;
   706     fun find i =
   707       if i + n > len then NONE
   708       else if String.substring (str, i, n) = sep then SOME i
   709       else find (i + 1);
   710   in
   711     (case find 0 of
   712       NONE => NONE
   713     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   714   end;
   715 
   716 (*enclose in brackets*)
   717 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   718 fun unenclose str = String.substring (str, 1, size str - 2);
   719 
   720 (*simple quoting (does not escape special chars)*)
   721 val quote = enclose "\"" "\"";
   722 
   723 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   724 fun space_implode a bs = implode (separate a bs);
   725 
   726 val commas = space_implode ", ";
   727 val commas_quote = commas o map quote;
   728 
   729 (*concatenate messages, one per line, into a string*)
   730 val cat_lines = space_implode "\n";
   731 
   732 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   733 fun space_explode _ "" = []
   734   | space_explode sep s = String.fields (fn c => str c = sep) s;
   735 
   736 val split_lines = space_explode "\n";
   737 
   738 fun prefix_lines "" txt = txt
   739   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   740 
   741 fun prefix prfx s = prfx ^ s;
   742 fun suffix sffx s = s ^ sffx;
   743 
   744 fun unprefix prfx s =
   745   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   746   else raise Fail "unprefix";
   747 
   748 fun unsuffix sffx s =
   749   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   750   else raise Fail "unsuffix";
   751 
   752 fun replicate_string (0: int) _ = ""
   753   | replicate_string 1 a = a
   754   | replicate_string k a =
   755       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   756       else replicate_string (k div 2) (a ^ a) ^ a;
   757 
   758 fun translate_string f = String.translate (f o String.str);
   759 
   760 (*crude matching of str against simple glob pat*)
   761 fun match_string pat str =
   762   let
   763     fun match [] _ = true
   764       | match (p :: ps) s =
   765           size p <= size s andalso
   766             (case try (unprefix p) s of
   767               SOME s' => match ps s'
   768             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   769   in match (space_explode "*" pat) str end;
   770 
   771 (** lists as sets -- see also Pure/General/ord_list.ML **)
   772 
   773 (* canonical operations *)
   774 
   775 fun member eq list x =
   776   let
   777     fun memb [] = false
   778       | memb (y :: ys) = eq (x, y) orelse memb ys;
   779   in memb list end;
   780 
   781 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   782 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   783 fun update eq x xs = cons x (remove eq x xs);
   784 
   785 fun inter eq xs = filter (member eq xs);
   786 
   787 fun subtract eq = fold (remove eq);
   788 
   789 fun merge eq (xs, ys) =
   790   if pointer_eq (xs, ys) then xs
   791   else if null xs then ys
   792   else fold_rev (insert eq) ys xs;
   793 
   794 
   795 (* old-style infixes *)
   796 
   797 fun x mem xs = member (op =) xs x;
   798 fun (x: int) mem_int xs = member (op =) xs x;
   799 fun (x: string) mem_string xs = member (op =) xs x;
   800 
   801 (*union of sets represented as lists: no repetitions*)
   802 fun union eq (xs, []) = xs
   803   | union eq ([], ys) = ys
   804   | union eq (x :: xs, ys) = union eq (xs, insert eq x ys);
   805 
   806 (*subset*)
   807 fun subset eq (xs, ys) = forall (member eq ys) xs;
   808 
   809 (*set equality*)
   810 fun eq_set eq (xs, ys) =
   811   eq_list eq (xs, ys) orelse
   812     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   813 
   814 
   815 (*makes a list of the distinct members of the input; preserves order, takes
   816   first of equal elements*)
   817 fun distinct eq lst =
   818   let
   819     fun dist (rev_seen, []) = rev rev_seen
   820       | dist (rev_seen, x :: xs) =
   821           if member eq rev_seen x then dist (rev_seen, xs)
   822           else dist (x :: rev_seen, xs);
   823   in dist ([], lst) end;
   824 
   825 (*returns a list containing all repeated elements exactly once; preserves
   826   order, takes first of equal elements*)
   827 fun duplicates eq lst =
   828   let
   829     fun dups (rev_dups, []) = rev rev_dups
   830       | dups (rev_dups, x :: xs) =
   831           if member eq rev_dups x orelse not (member eq xs x) then
   832             dups (rev_dups, xs)
   833           else dups (x :: rev_dups, xs);
   834   in dups ([], lst) end;
   835 
   836 fun has_duplicates eq =
   837   let
   838     fun dups [] = false
   839       | dups (x :: xs) = member eq xs x orelse dups xs;
   840   in dups end;
   841 
   842 
   843 (* matrices *)
   844 
   845 fun map_transpose f xss =
   846   let
   847     val n = case distinct (op =) (map length xss)
   848      of [] => 0
   849       | [n] => n
   850       | _ => raise UnequalLengths;
   851   in map (fn m => f (map (fn xs => nth xs m) xss)) (0 upto n - 1) end;
   852 
   853 
   854 
   855 (** lists as multisets **)
   856 
   857 fun remove1 _ _ [] = raise Empty
   858   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   859 
   860 fun submultiset _ ([], _)  = true
   861   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   862 
   863 
   864 
   865 (** orders **)
   866 
   867 fun is_equal EQUAL = true
   868   | is_equal _ = false;
   869 
   870 fun rev_order LESS = GREATER
   871   | rev_order EQUAL = EQUAL
   872   | rev_order GREATER = LESS;
   873 
   874 (*assume rel is a linear strict order*)
   875 fun make_ord rel (x, y) =
   876   if rel (x, y) then LESS
   877   else if rel (y, x) then GREATER
   878   else EQUAL;
   879 
   880 fun bool_ord (false, true) = LESS
   881   | bool_ord (true, false) = GREATER
   882   | bool_ord _ = EQUAL;
   883 
   884 val int_ord = Int.compare;
   885 val string_ord = String.compare;
   886 
   887 fun fast_string_ord (s1, s2) =
   888   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   889 
   890 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   891   | option_ord _ (NONE, NONE) = EQUAL
   892   | option_ord _ (NONE, SOME _) = LESS
   893   | option_ord _ (SOME _, NONE) = GREATER;
   894 
   895 (*lexicographic product*)
   896 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   897   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   898 
   899 (*dictionary order -- in general NOT well-founded!*)
   900 fun dict_ord elem_ord (x :: xs, y :: ys) =
   901       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   902   | dict_ord _ ([], []) = EQUAL
   903   | dict_ord _ ([], _ :: _) = LESS
   904   | dict_ord _ (_ :: _, []) = GREATER;
   905 
   906 (*lexicographic product of lists*)
   907 fun list_ord elem_ord (xs, ys) =
   908   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   909 
   910 
   911 (* sorting *)
   912 
   913 (*quicksort -- stable, i.e. does not reorder equal elements*)
   914 fun quicksort unique ord =
   915   let
   916     fun qsort [] = []
   917       | qsort (xs as [_]) = xs
   918       | qsort (xs as [x, y]) =
   919           (case ord (x, y) of
   920             LESS => xs
   921           | EQUAL => if unique then [x] else xs
   922           | GREATER => [y, x])
   923       | qsort xs =
   924           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   925           in qsort lts @ eqs @ qsort gts end
   926     and part _ [] = ([], [], [])
   927       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   928     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   929       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   930       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   931       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   932   in qsort end;
   933 
   934 fun sort ord = quicksort false ord;
   935 fun sort_distinct ord = quicksort true ord;
   936 
   937 val sort_strings = sort string_ord;
   938 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   939 
   940 
   941 (* items tagged by integer index *)
   942 
   943 (*insert tags*)
   944 fun tag_list k [] = []
   945   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   946 
   947 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   948 fun untag_list [] = []
   949   | untag_list [(k: int, x)] = [x]
   950   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   951       if k = k' then untag_list rest
   952       else x :: untag_list rest;
   953 
   954 (*return list elements in original order*)
   955 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   956 
   957 
   958 
   959 (** random numbers **)
   960 
   961 exception RANDOM;
   962 
   963 fun rmod x y = x - y * Real.realFloor (x / y);
   964 
   965 local
   966   val a = 16807.0;
   967   val m = 2147483647.0;
   968   val random_seed = Unsynchronized.ref 1.0;
   969 in
   970 
   971 fun random () = CRITICAL (fn () =>
   972   let val r = rmod (a * ! random_seed) m
   973   in (random_seed := r; r) end);
   974 
   975 end;
   976 
   977 fun random_range l h =
   978   if h < l orelse l < 0 then raise RANDOM
   979   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   980 
   981 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   982 
   983 fun frequency xs =
   984   let
   985     val sum = foldl op + (0, map fst xs);
   986     fun pick n ((k: int, x) :: xs) =
   987       if n <= k then x else pick (n - k) xs
   988   in pick (random_range 1 sum) xs end;
   989 
   990 
   991 
   992 (** misc **)
   993 
   994 fun divide_and_conquer decomp x =
   995   let val (ys, recomb) = decomp x
   996   in recomb (map (divide_and_conquer decomp) ys) end;
   997 
   998 fun divide_and_conquer' decomp x s =
   999   let val ((ys, recomb), s') = decomp x s
  1000   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1001 
  1002 
  1003 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1004    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1005 fun partition_list p i j =
  1006   let fun part k xs =
  1007             if k>j then
  1008               (case xs of [] => []
  1009                          | _ => raise Fail "partition_list")
  1010             else
  1011             let val (ns, rest) = List.partition (p k) xs;
  1012             in  ns :: part(k+1)rest  end
  1013   in  part (i: int) end;
  1014 
  1015 fun partition_eq (eq:'a * 'a -> bool) =
  1016   let
  1017     fun part [] = []
  1018       | part (x :: ys) =
  1019           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1020           in (x::xs)::(part xs') end
  1021   in part end;
  1022 
  1023 
  1024 
  1025 (* generating identifiers *)
  1026 
  1027 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1028 local
  1029 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1030 fun gensym_char i =
  1031   if i<26 then chr (ord "A" + i)
  1032   else if i<52 then chr (ord "a" + i - 26)
  1033   else chr (ord "0" + i - 52);
  1034 
  1035 val char_vec = Vector.tabulate (62, gensym_char);
  1036 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1037 
  1038 val gensym_seed = Unsynchronized.ref (0: int);
  1039 
  1040 in
  1041   fun gensym pre =
  1042     pre ^ newid (NAMED_CRITICAL "gensym" (fn () => Unsynchronized.inc gensym_seed));
  1043 end;
  1044 
  1045 
  1046 (* stamps and serial numbers *)
  1047 
  1048 type stamp = unit Unsynchronized.ref;
  1049 val stamp: unit -> stamp = Unsynchronized.ref;
  1050 
  1051 type serial = int;
  1052 val serial = Multithreading.serial;
  1053 val serial_string = string_of_int o serial;
  1054 
  1055 
  1056 (* generic objects *)
  1057 
  1058 (*note that the builtin exception datatype may be extended by new
  1059   constructors at any time*)
  1060 structure Object = struct type T = exn end;
  1061 
  1062 end;
  1063 
  1064 structure Basic_Library: BASIC_LIBRARY = Library;
  1065 open Basic_Library;