src/HOL/HOL.thy
author krauss
Tue Apr 08 18:30:40 2008 +0200 (2008-04-08)
changeset 26580 c3e597a476fd
parent 26555 046e63c9165c
child 26661 53e541e5b432
permissions -rw-r--r--
Generic conversion and tactic "atomize_elim" to convert elimination rules
to the object logic
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports CPure
    10 uses
    11   ("hologic.ML")
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Provers/project_rule.ML"
    17   "~~/src/Provers/hypsubst.ML"
    18   "~~/src/Provers/splitter.ML"
    19   "~~/src/Provers/classical.ML"
    20   "~~/src/Provers/blast.ML"
    21   "~~/src/Provers/clasimp.ML"
    22   "~~/src/Provers/eqsubst.ML"
    23   "~~/src/Provers/quantifier1.ML"
    24   ("simpdata.ML")
    25   "~~/src/Tools/random_word.ML"
    26   "~~/src/Tools/atomize_elim.ML"
    27   "~~/src/Tools/induct.ML"
    28   "~~/src/Tools/code/code_name.ML"
    29   "~~/src/Tools/code/code_funcgr.ML"
    30   "~~/src/Tools/code/code_thingol.ML"
    31   "~~/src/Tools/code/code_target.ML"
    32   "~~/src/Tools/code/code_package.ML"
    33   "~~/src/Tools/nbe.ML"
    34 begin
    35 
    36 subsection {* Primitive logic *}
    37 
    38 subsubsection {* Core syntax *}
    39 
    40 classes type
    41 defaultsort type
    42 setup {* ObjectLogic.add_base_sort @{sort type} *}
    43 
    44 arities
    45   "fun" :: (type, type) type
    46   itself :: (type) type
    47 
    48 global
    49 
    50 typedecl bool
    51 
    52 judgment
    53   Trueprop      :: "bool => prop"                   ("(_)" 5)
    54 
    55 consts
    56   Not           :: "bool => bool"                   ("~ _" [40] 40)
    57   True          :: bool
    58   False         :: bool
    59   arbitrary     :: 'a
    60 
    61   The           :: "('a => bool) => 'a"
    62   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    63   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    64   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    65   Let           :: "['a, 'a => 'b] => 'b"
    66 
    67   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    68   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    69   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    70   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    71 
    72 local
    73 
    74 consts
    75   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    76 
    77 
    78 subsubsection {* Additional concrete syntax *}
    79 
    80 notation (output)
    81   "op ="  (infix "=" 50)
    82 
    83 abbreviation
    84   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    85   "x ~= y == ~ (x = y)"
    86 
    87 notation (output)
    88   not_equal  (infix "~=" 50)
    89 
    90 notation (xsymbols)
    91   Not  ("\<not> _" [40] 40) and
    92   "op &"  (infixr "\<and>" 35) and
    93   "op |"  (infixr "\<or>" 30) and
    94   "op -->"  (infixr "\<longrightarrow>" 25) and
    95   not_equal  (infix "\<noteq>" 50)
    96 
    97 notation (HTML output)
    98   Not  ("\<not> _" [40] 40) and
    99   "op &"  (infixr "\<and>" 35) and
   100   "op |"  (infixr "\<or>" 30) and
   101   not_equal  (infix "\<noteq>" 50)
   102 
   103 abbreviation (iff)
   104   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   105   "A <-> B == A = B"
   106 
   107 notation (xsymbols)
   108   iff  (infixr "\<longleftrightarrow>" 25)
   109 
   110 
   111 nonterminals
   112   letbinds  letbind
   113   case_syn  cases_syn
   114 
   115 syntax
   116   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   117 
   118   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   119   ""            :: "letbind => letbinds"                 ("_")
   120   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   121   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   122 
   123   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   124   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   125   ""            :: "case_syn => cases_syn"               ("_")
   126   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   127 
   128 translations
   129   "THE x. P"              == "The (%x. P)"
   130   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   131   "let x = a in e"        == "Let a (%x. e)"
   132 
   133 print_translation {*
   134 (* To avoid eta-contraction of body: *)
   135 [("The", fn [Abs abs] =>
   136      let val (x,t) = atomic_abs_tr' abs
   137      in Syntax.const "_The" $ x $ t end)]
   138 *}
   139 
   140 syntax (xsymbols)
   141   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   142 
   143 notation (xsymbols)
   144   All  (binder "\<forall>" 10) and
   145   Ex  (binder "\<exists>" 10) and
   146   Ex1  (binder "\<exists>!" 10)
   147 
   148 notation (HTML output)
   149   All  (binder "\<forall>" 10) and
   150   Ex  (binder "\<exists>" 10) and
   151   Ex1  (binder "\<exists>!" 10)
   152 
   153 notation (HOL)
   154   All  (binder "! " 10) and
   155   Ex  (binder "? " 10) and
   156   Ex1  (binder "?! " 10)
   157 
   158 
   159 subsubsection {* Axioms and basic definitions *}
   160 
   161 axioms
   162   eq_reflection:  "(x=y) ==> (x==y)"
   163 
   164   refl:           "t = (t::'a)"
   165 
   166   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   167     -- {*Extensionality is built into the meta-logic, and this rule expresses
   168          a related property.  It is an eta-expanded version of the traditional
   169          rule, and similar to the ABS rule of HOL*}
   170 
   171   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   172 
   173   impI:           "(P ==> Q) ==> P-->Q"
   174   mp:             "[| P-->Q;  P |] ==> Q"
   175 
   176 
   177 defs
   178   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   179   All_def:      "All(P)    == (P = (%x. True))"
   180   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   181   False_def:    "False     == (!P. P)"
   182   not_def:      "~ P       == P-->False"
   183   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   184   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   185   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   186 
   187 axioms
   188   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   189   True_or_False:  "(P=True) | (P=False)"
   190 
   191 defs
   192   Let_def:      "Let s f == f(s)"
   193   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   194 
   195 finalconsts
   196   "op ="
   197   "op -->"
   198   The
   199   arbitrary
   200 
   201 axiomatization
   202   undefined :: 'a
   203 
   204 axiomatization where
   205   undefined_fun: "undefined x = undefined"
   206 
   207 
   208 subsubsection {* Generic classes and algebraic operations *}
   209 
   210 class default = type +
   211   fixes default :: 'a
   212 
   213 class zero = type + 
   214   fixes zero :: 'a  ("0")
   215 
   216 class one = type +
   217   fixes one  :: 'a  ("1")
   218 
   219 hide (open) const zero one
   220 
   221 class plus = type +
   222   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   223 
   224 class minus = type +
   225   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   226 
   227 class uminus = type +
   228   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   229 
   230 class times = type +
   231   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   232 
   233 class inverse = type +
   234   fixes inverse :: "'a \<Rightarrow> 'a"
   235     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   236 
   237 class abs = type +
   238   fixes abs :: "'a \<Rightarrow> 'a"
   239 begin
   240 
   241 notation (xsymbols)
   242   abs  ("\<bar>_\<bar>")
   243 
   244 notation (HTML output)
   245   abs  ("\<bar>_\<bar>")
   246 
   247 end
   248 
   249 class sgn = type +
   250   fixes sgn :: "'a \<Rightarrow> 'a"
   251 
   252 class ord = type +
   253   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   254     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   255 begin
   256 
   257 notation
   258   less_eq  ("op <=") and
   259   less_eq  ("(_/ <= _)" [51, 51] 50) and
   260   less  ("op <") and
   261   less  ("(_/ < _)"  [51, 51] 50)
   262   
   263 notation (xsymbols)
   264   less_eq  ("op \<le>") and
   265   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   266 
   267 notation (HTML output)
   268   less_eq  ("op \<le>") and
   269   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   270 
   271 abbreviation (input)
   272   greater_eq  (infix ">=" 50) where
   273   "x >= y \<equiv> y <= x"
   274 
   275 notation (input)
   276   greater_eq  (infix "\<ge>" 50)
   277 
   278 abbreviation (input)
   279   greater  (infix ">" 50) where
   280   "x > y \<equiv> y < x"
   281 
   282 definition
   283   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   284   "Least P == (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> less_eq x y))"
   285 
   286 end
   287 
   288 syntax
   289   "_index1"  :: index    ("\<^sub>1")
   290 translations
   291   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   292 
   293 typed_print_translation {*
   294 let
   295   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   296     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   297     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   298 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   299 *} -- {* show types that are presumably too general *}
   300 
   301 
   302 subsection {* Fundamental rules *}
   303 
   304 subsubsection {* Equality *}
   305 
   306 text {* Thanks to Stephan Merz *}
   307 lemma subst:
   308   assumes eq: "s = t" and p: "P s"
   309   shows "P t"
   310 proof -
   311   from eq have meta: "s \<equiv> t"
   312     by (rule eq_reflection)
   313   from p show ?thesis
   314     by (unfold meta)
   315 qed
   316 
   317 lemma sym: "s = t ==> t = s"
   318   by (erule subst) (rule refl)
   319 
   320 lemma ssubst: "t = s ==> P s ==> P t"
   321   by (drule sym) (erule subst)
   322 
   323 lemma trans: "[| r=s; s=t |] ==> r=t"
   324   by (erule subst)
   325 
   326 lemma meta_eq_to_obj_eq: 
   327   assumes meq: "A == B"
   328   shows "A = B"
   329   by (unfold meq) (rule refl)
   330 
   331 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   332      (* a = b
   333         |   |
   334         c = d   *)
   335 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   336 apply (rule trans)
   337 apply (rule trans)
   338 apply (rule sym)
   339 apply assumption+
   340 done
   341 
   342 text {* For calculational reasoning: *}
   343 
   344 lemma forw_subst: "a = b ==> P b ==> P a"
   345   by (rule ssubst)
   346 
   347 lemma back_subst: "P a ==> a = b ==> P b"
   348   by (rule subst)
   349 
   350 
   351 subsubsection {*Congruence rules for application*}
   352 
   353 (*similar to AP_THM in Gordon's HOL*)
   354 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   355 apply (erule subst)
   356 apply (rule refl)
   357 done
   358 
   359 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   360 lemma arg_cong: "x=y ==> f(x)=f(y)"
   361 apply (erule subst)
   362 apply (rule refl)
   363 done
   364 
   365 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   366 apply (erule ssubst)+
   367 apply (rule refl)
   368 done
   369 
   370 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   371 apply (erule subst)+
   372 apply (rule refl)
   373 done
   374 
   375 
   376 subsubsection {*Equality of booleans -- iff*}
   377 
   378 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   379   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   380 
   381 lemma iffD2: "[| P=Q; Q |] ==> P"
   382   by (erule ssubst)
   383 
   384 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   385   by (erule iffD2)
   386 
   387 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   388   by (drule sym) (rule iffD2)
   389 
   390 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   391   by (drule sym) (rule rev_iffD2)
   392 
   393 lemma iffE:
   394   assumes major: "P=Q"
   395     and minor: "[| P --> Q; Q --> P |] ==> R"
   396   shows R
   397   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   398 
   399 
   400 subsubsection {*True*}
   401 
   402 lemma TrueI: "True"
   403   unfolding True_def by (rule refl)
   404 
   405 lemma eqTrueI: "P ==> P = True"
   406   by (iprover intro: iffI TrueI)
   407 
   408 lemma eqTrueE: "P = True ==> P"
   409   by (erule iffD2) (rule TrueI)
   410 
   411 
   412 subsubsection {*Universal quantifier*}
   413 
   414 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   415   unfolding All_def by (iprover intro: ext eqTrueI assms)
   416 
   417 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   418 apply (unfold All_def)
   419 apply (rule eqTrueE)
   420 apply (erule fun_cong)
   421 done
   422 
   423 lemma allE:
   424   assumes major: "ALL x. P(x)"
   425     and minor: "P(x) ==> R"
   426   shows R
   427   by (iprover intro: minor major [THEN spec])
   428 
   429 lemma all_dupE:
   430   assumes major: "ALL x. P(x)"
   431     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   432   shows R
   433   by (iprover intro: minor major major [THEN spec])
   434 
   435 
   436 subsubsection {* False *}
   437 
   438 text {*
   439   Depends upon @{text spec}; it is impossible to do propositional
   440   logic before quantifiers!
   441 *}
   442 
   443 lemma FalseE: "False ==> P"
   444   apply (unfold False_def)
   445   apply (erule spec)
   446   done
   447 
   448 lemma False_neq_True: "False = True ==> P"
   449   by (erule eqTrueE [THEN FalseE])
   450 
   451 
   452 subsubsection {* Negation *}
   453 
   454 lemma notI:
   455   assumes "P ==> False"
   456   shows "~P"
   457   apply (unfold not_def)
   458   apply (iprover intro: impI assms)
   459   done
   460 
   461 lemma False_not_True: "False ~= True"
   462   apply (rule notI)
   463   apply (erule False_neq_True)
   464   done
   465 
   466 lemma True_not_False: "True ~= False"
   467   apply (rule notI)
   468   apply (drule sym)
   469   apply (erule False_neq_True)
   470   done
   471 
   472 lemma notE: "[| ~P;  P |] ==> R"
   473   apply (unfold not_def)
   474   apply (erule mp [THEN FalseE])
   475   apply assumption
   476   done
   477 
   478 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   479   by (erule notE [THEN notI]) (erule meta_mp)
   480 
   481 
   482 subsubsection {*Implication*}
   483 
   484 lemma impE:
   485   assumes "P-->Q" "P" "Q ==> R"
   486   shows "R"
   487 by (iprover intro: assms mp)
   488 
   489 (* Reduces Q to P-->Q, allowing substitution in P. *)
   490 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   491 by (iprover intro: mp)
   492 
   493 lemma contrapos_nn:
   494   assumes major: "~Q"
   495       and minor: "P==>Q"
   496   shows "~P"
   497 by (iprover intro: notI minor major [THEN notE])
   498 
   499 (*not used at all, but we already have the other 3 combinations *)
   500 lemma contrapos_pn:
   501   assumes major: "Q"
   502       and minor: "P ==> ~Q"
   503   shows "~P"
   504 by (iprover intro: notI minor major notE)
   505 
   506 lemma not_sym: "t ~= s ==> s ~= t"
   507   by (erule contrapos_nn) (erule sym)
   508 
   509 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   510   by (erule subst, erule ssubst, assumption)
   511 
   512 (*still used in HOLCF*)
   513 lemma rev_contrapos:
   514   assumes pq: "P ==> Q"
   515       and nq: "~Q"
   516   shows "~P"
   517 apply (rule nq [THEN contrapos_nn])
   518 apply (erule pq)
   519 done
   520 
   521 subsubsection {*Existential quantifier*}
   522 
   523 lemma exI: "P x ==> EX x::'a. P x"
   524 apply (unfold Ex_def)
   525 apply (iprover intro: allI allE impI mp)
   526 done
   527 
   528 lemma exE:
   529   assumes major: "EX x::'a. P(x)"
   530       and minor: "!!x. P(x) ==> Q"
   531   shows "Q"
   532 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   533 apply (iprover intro: impI [THEN allI] minor)
   534 done
   535 
   536 
   537 subsubsection {*Conjunction*}
   538 
   539 lemma conjI: "[| P; Q |] ==> P&Q"
   540 apply (unfold and_def)
   541 apply (iprover intro: impI [THEN allI] mp)
   542 done
   543 
   544 lemma conjunct1: "[| P & Q |] ==> P"
   545 apply (unfold and_def)
   546 apply (iprover intro: impI dest: spec mp)
   547 done
   548 
   549 lemma conjunct2: "[| P & Q |] ==> Q"
   550 apply (unfold and_def)
   551 apply (iprover intro: impI dest: spec mp)
   552 done
   553 
   554 lemma conjE:
   555   assumes major: "P&Q"
   556       and minor: "[| P; Q |] ==> R"
   557   shows "R"
   558 apply (rule minor)
   559 apply (rule major [THEN conjunct1])
   560 apply (rule major [THEN conjunct2])
   561 done
   562 
   563 lemma context_conjI:
   564   assumes "P" "P ==> Q" shows "P & Q"
   565 by (iprover intro: conjI assms)
   566 
   567 
   568 subsubsection {*Disjunction*}
   569 
   570 lemma disjI1: "P ==> P|Q"
   571 apply (unfold or_def)
   572 apply (iprover intro: allI impI mp)
   573 done
   574 
   575 lemma disjI2: "Q ==> P|Q"
   576 apply (unfold or_def)
   577 apply (iprover intro: allI impI mp)
   578 done
   579 
   580 lemma disjE:
   581   assumes major: "P|Q"
   582       and minorP: "P ==> R"
   583       and minorQ: "Q ==> R"
   584   shows "R"
   585 by (iprover intro: minorP minorQ impI
   586                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   587 
   588 
   589 subsubsection {*Classical logic*}
   590 
   591 lemma classical:
   592   assumes prem: "~P ==> P"
   593   shows "P"
   594 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   595 apply assumption
   596 apply (rule notI [THEN prem, THEN eqTrueI])
   597 apply (erule subst)
   598 apply assumption
   599 done
   600 
   601 lemmas ccontr = FalseE [THEN classical, standard]
   602 
   603 (*notE with premises exchanged; it discharges ~R so that it can be used to
   604   make elimination rules*)
   605 lemma rev_notE:
   606   assumes premp: "P"
   607       and premnot: "~R ==> ~P"
   608   shows "R"
   609 apply (rule ccontr)
   610 apply (erule notE [OF premnot premp])
   611 done
   612 
   613 (*Double negation law*)
   614 lemma notnotD: "~~P ==> P"
   615 apply (rule classical)
   616 apply (erule notE)
   617 apply assumption
   618 done
   619 
   620 lemma contrapos_pp:
   621   assumes p1: "Q"
   622       and p2: "~P ==> ~Q"
   623   shows "P"
   624 by (iprover intro: classical p1 p2 notE)
   625 
   626 
   627 subsubsection {*Unique existence*}
   628 
   629 lemma ex1I:
   630   assumes "P a" "!!x. P(x) ==> x=a"
   631   shows "EX! x. P(x)"
   632 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   633 
   634 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   635 lemma ex_ex1I:
   636   assumes ex_prem: "EX x. P(x)"
   637       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   638   shows "EX! x. P(x)"
   639 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   640 
   641 lemma ex1E:
   642   assumes major: "EX! x. P(x)"
   643       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   644   shows "R"
   645 apply (rule major [unfolded Ex1_def, THEN exE])
   646 apply (erule conjE)
   647 apply (iprover intro: minor)
   648 done
   649 
   650 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   651 apply (erule ex1E)
   652 apply (rule exI)
   653 apply assumption
   654 done
   655 
   656 
   657 subsubsection {*THE: definite description operator*}
   658 
   659 lemma the_equality:
   660   assumes prema: "P a"
   661       and premx: "!!x. P x ==> x=a"
   662   shows "(THE x. P x) = a"
   663 apply (rule trans [OF _ the_eq_trivial])
   664 apply (rule_tac f = "The" in arg_cong)
   665 apply (rule ext)
   666 apply (rule iffI)
   667  apply (erule premx)
   668 apply (erule ssubst, rule prema)
   669 done
   670 
   671 lemma theI:
   672   assumes "P a" and "!!x. P x ==> x=a"
   673   shows "P (THE x. P x)"
   674 by (iprover intro: assms the_equality [THEN ssubst])
   675 
   676 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   677 apply (erule ex1E)
   678 apply (erule theI)
   679 apply (erule allE)
   680 apply (erule mp)
   681 apply assumption
   682 done
   683 
   684 (*Easier to apply than theI: only one occurrence of P*)
   685 lemma theI2:
   686   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   687   shows "Q (THE x. P x)"
   688 by (iprover intro: assms theI)
   689 
   690 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   691 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   692            elim:allE impE)
   693 
   694 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   695 apply (rule the_equality)
   696 apply  assumption
   697 apply (erule ex1E)
   698 apply (erule all_dupE)
   699 apply (drule mp)
   700 apply  assumption
   701 apply (erule ssubst)
   702 apply (erule allE)
   703 apply (erule mp)
   704 apply assumption
   705 done
   706 
   707 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   708 apply (rule the_equality)
   709 apply (rule refl)
   710 apply (erule sym)
   711 done
   712 
   713 
   714 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   715 
   716 lemma disjCI:
   717   assumes "~Q ==> P" shows "P|Q"
   718 apply (rule classical)
   719 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   720 done
   721 
   722 lemma excluded_middle: "~P | P"
   723 by (iprover intro: disjCI)
   724 
   725 text {*
   726   case distinction as a natural deduction rule.
   727   Note that @{term "~P"} is the second case, not the first
   728 *}
   729 lemma case_split_thm:
   730   assumes prem1: "P ==> Q"
   731       and prem2: "~P ==> Q"
   732   shows "Q"
   733 apply (rule excluded_middle [THEN disjE])
   734 apply (erule prem2)
   735 apply (erule prem1)
   736 done
   737 lemmas case_split = case_split_thm [case_names True False]
   738 
   739 (*Classical implies (-->) elimination. *)
   740 lemma impCE:
   741   assumes major: "P-->Q"
   742       and minor: "~P ==> R" "Q ==> R"
   743   shows "R"
   744 apply (rule excluded_middle [of P, THEN disjE])
   745 apply (iprover intro: minor major [THEN mp])+
   746 done
   747 
   748 (*This version of --> elimination works on Q before P.  It works best for
   749   those cases in which P holds "almost everywhere".  Can't install as
   750   default: would break old proofs.*)
   751 lemma impCE':
   752   assumes major: "P-->Q"
   753       and minor: "Q ==> R" "~P ==> R"
   754   shows "R"
   755 apply (rule excluded_middle [of P, THEN disjE])
   756 apply (iprover intro: minor major [THEN mp])+
   757 done
   758 
   759 (*Classical <-> elimination. *)
   760 lemma iffCE:
   761   assumes major: "P=Q"
   762       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   763   shows "R"
   764 apply (rule major [THEN iffE])
   765 apply (iprover intro: minor elim: impCE notE)
   766 done
   767 
   768 lemma exCI:
   769   assumes "ALL x. ~P(x) ==> P(a)"
   770   shows "EX x. P(x)"
   771 apply (rule ccontr)
   772 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   773 done
   774 
   775 
   776 subsubsection {* Intuitionistic Reasoning *}
   777 
   778 lemma impE':
   779   assumes 1: "P --> Q"
   780     and 2: "Q ==> R"
   781     and 3: "P --> Q ==> P"
   782   shows R
   783 proof -
   784   from 3 and 1 have P .
   785   with 1 have Q by (rule impE)
   786   with 2 show R .
   787 qed
   788 
   789 lemma allE':
   790   assumes 1: "ALL x. P x"
   791     and 2: "P x ==> ALL x. P x ==> Q"
   792   shows Q
   793 proof -
   794   from 1 have "P x" by (rule spec)
   795   from this and 1 show Q by (rule 2)
   796 qed
   797 
   798 lemma notE':
   799   assumes 1: "~ P"
   800     and 2: "~ P ==> P"
   801   shows R
   802 proof -
   803   from 2 and 1 have P .
   804   with 1 show R by (rule notE)
   805 qed
   806 
   807 lemma TrueE: "True ==> P ==> P" .
   808 lemma notFalseE: "~ False ==> P ==> P" .
   809 
   810 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   811   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   812   and [Pure.elim 2] = allE notE' impE'
   813   and [Pure.intro] = exI disjI2 disjI1
   814 
   815 lemmas [trans] = trans
   816   and [sym] = sym not_sym
   817   and [Pure.elim?] = iffD1 iffD2 impE
   818 
   819 use "hologic.ML"
   820 
   821 
   822 subsubsection {* Atomizing meta-level connectives *}
   823 
   824 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   825 proof
   826   assume "!!x. P x"
   827   then show "ALL x. P x" ..
   828 next
   829   assume "ALL x. P x"
   830   then show "!!x. P x" by (rule allE)
   831 qed
   832 
   833 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   834 proof
   835   assume r: "A ==> B"
   836   show "A --> B" by (rule impI) (rule r)
   837 next
   838   assume "A --> B" and A
   839   then show B by (rule mp)
   840 qed
   841 
   842 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   843 proof
   844   assume r: "A ==> False"
   845   show "~A" by (rule notI) (rule r)
   846 next
   847   assume "~A" and A
   848   then show False by (rule notE)
   849 qed
   850 
   851 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   852 proof
   853   assume "x == y"
   854   show "x = y" by (unfold `x == y`) (rule refl)
   855 next
   856   assume "x = y"
   857   then show "x == y" by (rule eq_reflection)
   858 qed
   859 
   860 lemma atomize_conj [atomize]:
   861   includes meta_conjunction_syntax
   862   shows "(A && B) == Trueprop (A & B)"
   863 proof
   864   assume conj: "A && B"
   865   show "A & B"
   866   proof (rule conjI)
   867     from conj show A by (rule conjunctionD1)
   868     from conj show B by (rule conjunctionD2)
   869   qed
   870 next
   871   assume conj: "A & B"
   872   show "A && B"
   873   proof -
   874     from conj show A ..
   875     from conj show B ..
   876   qed
   877 qed
   878 
   879 lemmas [symmetric, rulify] = atomize_all atomize_imp
   880   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   881 
   882 
   883 subsubsection {* Atomizing elimination rules *}
   884 
   885 setup AtomizeElim.setup
   886 
   887 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   888   by rule iprover+
   889 
   890 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   891   by rule iprover+
   892 
   893 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   894   by rule iprover+
   895 
   896 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   897 
   898 
   899 subsection {* Package setup *}
   900 
   901 subsubsection {* Classical Reasoner setup *}
   902 
   903 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   904   by (rule classical) iprover
   905 
   906 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   907   by (rule classical) iprover
   908 
   909 lemma thin_refl:
   910   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   911 
   912 ML {*
   913 structure Hypsubst = HypsubstFun(
   914 struct
   915   structure Simplifier = Simplifier
   916   val dest_eq = HOLogic.dest_eq
   917   val dest_Trueprop = HOLogic.dest_Trueprop
   918   val dest_imp = HOLogic.dest_imp
   919   val eq_reflection = @{thm eq_reflection}
   920   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   921   val imp_intr = @{thm impI}
   922   val rev_mp = @{thm rev_mp}
   923   val subst = @{thm subst}
   924   val sym = @{thm sym}
   925   val thin_refl = @{thm thin_refl};
   926 end);
   927 open Hypsubst;
   928 
   929 structure Classical = ClassicalFun(
   930 struct
   931   val imp_elim = @{thm imp_elim}
   932   val not_elim = @{thm notE}
   933   val swap = @{thm swap}
   934   val classical = @{thm classical}
   935   val sizef = Drule.size_of_thm
   936   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   937 end);
   938 
   939 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   940 open BasicClassical;
   941 
   942 ML_Context.value_antiq "claset"
   943   (Scan.succeed ("claset", "Classical.local_claset_of (ML_Context.the_local_context ())"));
   944 
   945 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   946 
   947 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "Theorems blacklisted for ATP");
   948 *}
   949 
   950 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   951   These theorems typically produce clauses that are prolific (match too many equality or
   952   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   953 
   954 setup {*
   955 let
   956   (*prevent substitution on bool*)
   957   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   958     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   959       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   960 in
   961   Hypsubst.hypsubst_setup
   962   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   963   #> Classical.setup
   964   #> ResAtpset.setup
   965   #> ResBlacklist.setup
   966 end
   967 *}
   968 
   969 declare iffI [intro!]
   970   and notI [intro!]
   971   and impI [intro!]
   972   and disjCI [intro!]
   973   and conjI [intro!]
   974   and TrueI [intro!]
   975   and refl [intro!]
   976 
   977 declare iffCE [elim!]
   978   and FalseE [elim!]
   979   and impCE [elim!]
   980   and disjE [elim!]
   981   and conjE [elim!]
   982   and conjE [elim!]
   983 
   984 declare ex_ex1I [intro!]
   985   and allI [intro!]
   986   and the_equality [intro]
   987   and exI [intro]
   988 
   989 declare exE [elim!]
   990   allE [elim]
   991 
   992 ML {* val HOL_cs = @{claset} *}
   993 
   994 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   995   apply (erule swap)
   996   apply (erule (1) meta_mp)
   997   done
   998 
   999 declare ex_ex1I [rule del, intro! 2]
  1000   and ex1I [intro]
  1001 
  1002 lemmas [intro?] = ext
  1003   and [elim?] = ex1_implies_ex
  1004 
  1005 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
  1006 lemma alt_ex1E [elim!]:
  1007   assumes major: "\<exists>!x. P x"
  1008       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
  1009   shows R
  1010 apply (rule ex1E [OF major])
  1011 apply (rule prem)
  1012 apply (tactic {* ares_tac @{thms allI} 1 *})+
  1013 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
  1014 apply iprover
  1015 done
  1016 
  1017 ML {*
  1018 structure Blast = BlastFun
  1019 (
  1020   type claset = Classical.claset
  1021   val equality_name = @{const_name "op ="}
  1022   val not_name = @{const_name Not}
  1023   val notE = @{thm notE}
  1024   val ccontr = @{thm ccontr}
  1025   val contr_tac = Classical.contr_tac
  1026   val dup_intr = Classical.dup_intr
  1027   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1028   val claset = Classical.claset
  1029   val rep_cs = Classical.rep_cs
  1030   val cla_modifiers = Classical.cla_modifiers
  1031   val cla_meth' = Classical.cla_meth'
  1032 );
  1033 val Blast_tac = Blast.Blast_tac;
  1034 val blast_tac = Blast.blast_tac;
  1035 *}
  1036 
  1037 setup Blast.setup
  1038 
  1039 
  1040 subsubsection {* Simplifier *}
  1041 
  1042 lemma eta_contract_eq: "(%s. f s) = f" ..
  1043 
  1044 lemma simp_thms:
  1045   shows not_not: "(~ ~ P) = P"
  1046   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1047   and
  1048     "(P ~= Q) = (P = (~Q))"
  1049     "(P | ~P) = True"    "(~P | P) = True"
  1050     "(x = x) = True"
  1051   and not_True_eq_False: "(\<not> True) = False"
  1052   and not_False_eq_True: "(\<not> False) = True"
  1053   and
  1054     "(~P) ~= P"  "P ~= (~P)"
  1055     "(True=P) = P"
  1056   and eq_True: "(P = True) = P"
  1057   and "(False=P) = (~P)"
  1058   and eq_False: "(P = False) = (\<not> P)"
  1059   and
  1060     "(True --> P) = P"  "(False --> P) = True"
  1061     "(P --> True) = True"  "(P --> P) = True"
  1062     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1063     "(P & True) = P"  "(True & P) = P"
  1064     "(P & False) = False"  "(False & P) = False"
  1065     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1066     "(P & ~P) = False"    "(~P & P) = False"
  1067     "(P | True) = True"  "(True | P) = True"
  1068     "(P | False) = P"  "(False | P) = P"
  1069     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1070     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1071     -- {* needed for the one-point-rule quantifier simplification procs *}
  1072     -- {* essential for termination!! *} and
  1073     "!!P. (EX x. x=t & P(x)) = P(t)"
  1074     "!!P. (EX x. t=x & P(x)) = P(t)"
  1075     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1076     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1077   by (blast, blast, blast, blast, blast, iprover+)
  1078 
  1079 lemma disj_absorb: "(A | A) = A"
  1080   by blast
  1081 
  1082 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1083   by blast
  1084 
  1085 lemma conj_absorb: "(A & A) = A"
  1086   by blast
  1087 
  1088 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1089   by blast
  1090 
  1091 lemma eq_ac:
  1092   shows eq_commute: "(a=b) = (b=a)"
  1093     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1094     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1095 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1096 
  1097 lemma conj_comms:
  1098   shows conj_commute: "(P&Q) = (Q&P)"
  1099     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1100 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1101 
  1102 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1103 
  1104 lemma disj_comms:
  1105   shows disj_commute: "(P|Q) = (Q|P)"
  1106     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1107 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1108 
  1109 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1110 
  1111 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1112 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1113 
  1114 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1115 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1116 
  1117 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1118 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1119 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1120 
  1121 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1122 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1123 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1124 
  1125 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1126 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1127 
  1128 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1129   by iprover
  1130 
  1131 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1132 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1133 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1134 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1135 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1136 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1137   by blast
  1138 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1139 
  1140 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1141 
  1142 
  1143 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1144   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1145   -- {* cases boil down to the same thing. *}
  1146   by blast
  1147 
  1148 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1149 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1150 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1151 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1152 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1153 
  1154 declare All_def [noatp]
  1155 
  1156 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1157 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1158 
  1159 text {*
  1160   \medskip The @{text "&"} congruence rule: not included by default!
  1161   May slow rewrite proofs down by as much as 50\% *}
  1162 
  1163 lemma conj_cong:
  1164     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1165   by iprover
  1166 
  1167 lemma rev_conj_cong:
  1168     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1169   by iprover
  1170 
  1171 text {* The @{text "|"} congruence rule: not included by default! *}
  1172 
  1173 lemma disj_cong:
  1174     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1175   by blast
  1176 
  1177 
  1178 text {* \medskip if-then-else rules *}
  1179 
  1180 lemma if_True: "(if True then x else y) = x"
  1181   by (unfold if_def) blast
  1182 
  1183 lemma if_False: "(if False then x else y) = y"
  1184   by (unfold if_def) blast
  1185 
  1186 lemma if_P: "P ==> (if P then x else y) = x"
  1187   by (unfold if_def) blast
  1188 
  1189 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1190   by (unfold if_def) blast
  1191 
  1192 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1193   apply (rule case_split [of Q])
  1194    apply (simplesubst if_P)
  1195     prefer 3 apply (simplesubst if_not_P, blast+)
  1196   done
  1197 
  1198 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1199 by (simplesubst split_if, blast)
  1200 
  1201 lemmas if_splits [noatp] = split_if split_if_asm
  1202 
  1203 lemma if_cancel: "(if c then x else x) = x"
  1204 by (simplesubst split_if, blast)
  1205 
  1206 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1207 by (simplesubst split_if, blast)
  1208 
  1209 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1210   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1211   by (rule split_if)
  1212 
  1213 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1214   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1215   apply (simplesubst split_if, blast)
  1216   done
  1217 
  1218 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1219 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1220 
  1221 text {* \medskip let rules for simproc *}
  1222 
  1223 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1224   by (unfold Let_def)
  1225 
  1226 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1227   by (unfold Let_def)
  1228 
  1229 text {*
  1230   The following copy of the implication operator is useful for
  1231   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1232   its premise.
  1233 *}
  1234 
  1235 constdefs
  1236   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1237   [code func del]: "simp_implies \<equiv> op ==>"
  1238 
  1239 lemma simp_impliesI:
  1240   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1241   shows "PROP P =simp=> PROP Q"
  1242   apply (unfold simp_implies_def)
  1243   apply (rule PQ)
  1244   apply assumption
  1245   done
  1246 
  1247 lemma simp_impliesE:
  1248   assumes PQ: "PROP P =simp=> PROP Q"
  1249   and P: "PROP P"
  1250   and QR: "PROP Q \<Longrightarrow> PROP R"
  1251   shows "PROP R"
  1252   apply (rule QR)
  1253   apply (rule PQ [unfolded simp_implies_def])
  1254   apply (rule P)
  1255   done
  1256 
  1257 lemma simp_implies_cong:
  1258   assumes PP' :"PROP P == PROP P'"
  1259   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1260   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1261 proof (unfold simp_implies_def, rule equal_intr_rule)
  1262   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1263   and P': "PROP P'"
  1264   from PP' [symmetric] and P' have "PROP P"
  1265     by (rule equal_elim_rule1)
  1266   then have "PROP Q" by (rule PQ)
  1267   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1268 next
  1269   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1270   and P: "PROP P"
  1271   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1272   then have "PROP Q'" by (rule P'Q')
  1273   with P'QQ' [OF P', symmetric] show "PROP Q"
  1274     by (rule equal_elim_rule1)
  1275 qed
  1276 
  1277 lemma uncurry:
  1278   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1279   shows "P \<and> Q \<longrightarrow> R"
  1280   using assms by blast
  1281 
  1282 lemma iff_allI:
  1283   assumes "\<And>x. P x = Q x"
  1284   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1285   using assms by blast
  1286 
  1287 lemma iff_exI:
  1288   assumes "\<And>x. P x = Q x"
  1289   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1290   using assms by blast
  1291 
  1292 lemma all_comm:
  1293   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1294   by blast
  1295 
  1296 lemma ex_comm:
  1297   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1298   by blast
  1299 
  1300 use "simpdata.ML"
  1301 ML {* open Simpdata *}
  1302 
  1303 setup {*
  1304   Simplifier.method_setup Splitter.split_modifiers
  1305   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1306   #> Splitter.setup
  1307   #> clasimp_setup
  1308   #> EqSubst.setup
  1309 *}
  1310 
  1311 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1312 
  1313 simproc_setup neq ("x = y") = {* fn _ =>
  1314 let
  1315   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1316   fun is_neq eq lhs rhs thm =
  1317     (case Thm.prop_of thm of
  1318       _ $ (Not $ (eq' $ l' $ r')) =>
  1319         Not = HOLogic.Not andalso eq' = eq andalso
  1320         r' aconv lhs andalso l' aconv rhs
  1321     | _ => false);
  1322   fun proc ss ct =
  1323     (case Thm.term_of ct of
  1324       eq $ lhs $ rhs =>
  1325         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1326           SOME thm => SOME (thm RS neq_to_EQ_False)
  1327         | NONE => NONE)
  1328      | _ => NONE);
  1329 in proc end;
  1330 *}
  1331 
  1332 simproc_setup let_simp ("Let x f") = {*
  1333 let
  1334   val (f_Let_unfold, x_Let_unfold) =
  1335     let val [(_$(f$x)$_)] = prems_of @{thm Let_unfold}
  1336     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1337   val (f_Let_folded, x_Let_folded) =
  1338     let val [(_$(f$x)$_)] = prems_of @{thm Let_folded}
  1339     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1340   val g_Let_folded =
  1341     let val [(_$_$(g$_))] = prems_of @{thm Let_folded} in cterm_of @{theory} g end;
  1342 
  1343   fun proc _ ss ct =
  1344     let
  1345       val ctxt = Simplifier.the_context ss;
  1346       val thy = ProofContext.theory_of ctxt;
  1347       val t = Thm.term_of ct;
  1348       val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1349     in Option.map (hd o Variable.export ctxt' ctxt o single)
  1350       (case t' of Const ("Let",_) $ x $ f => (* x and f are already in normal form *)
  1351         if is_Free x orelse is_Bound x orelse is_Const x
  1352         then SOME @{thm Let_def}
  1353         else
  1354           let
  1355             val n = case f of (Abs (x,_,_)) => x | _ => "x";
  1356             val cx = cterm_of thy x;
  1357             val {T=xT,...} = rep_cterm cx;
  1358             val cf = cterm_of thy f;
  1359             val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1360             val (_$_$g) = prop_of fx_g;
  1361             val g' = abstract_over (x,g);
  1362           in (if (g aconv g')
  1363                then
  1364                   let
  1365                     val rl =
  1366                       cterm_instantiate [(f_Let_unfold,cf),(x_Let_unfold,cx)] @{thm Let_unfold};
  1367                   in SOME (rl OF [fx_g]) end
  1368                else if Term.betapply (f,x) aconv g then NONE (*avoid identity conversion*)
  1369                else let
  1370                      val abs_g'= Abs (n,xT,g');
  1371                      val g'x = abs_g'$x;
  1372                      val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1373                      val rl = cterm_instantiate
  1374                                [(f_Let_folded,cterm_of thy f),(x_Let_folded,cx),
  1375                                 (g_Let_folded,cterm_of thy abs_g')]
  1376                                @{thm Let_folded};
  1377                    in SOME (rl OF [transitive fx_g g_g'x])
  1378                    end)
  1379           end
  1380       | _ => NONE)
  1381     end
  1382 in proc end *}
  1383 
  1384 
  1385 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1386 proof
  1387   assume "True \<Longrightarrow> PROP P"
  1388   from this [OF TrueI] show "PROP P" .
  1389 next
  1390   assume "PROP P"
  1391   then show "PROP P" .
  1392 qed
  1393 
  1394 lemma ex_simps:
  1395   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1396   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1397   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1398   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1399   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1400   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1401   -- {* Miniscoping: pushing in existential quantifiers. *}
  1402   by (iprover | blast)+
  1403 
  1404 lemma all_simps:
  1405   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1406   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1407   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1408   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1409   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1410   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1411   -- {* Miniscoping: pushing in universal quantifiers. *}
  1412   by (iprover | blast)+
  1413 
  1414 lemmas [simp] =
  1415   triv_forall_equality (*prunes params*)
  1416   True_implies_equals  (*prune asms `True'*)
  1417   if_True
  1418   if_False
  1419   if_cancel
  1420   if_eq_cancel
  1421   imp_disjL
  1422   (*In general it seems wrong to add distributive laws by default: they
  1423     might cause exponential blow-up.  But imp_disjL has been in for a while
  1424     and cannot be removed without affecting existing proofs.  Moreover,
  1425     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1426     grounds that it allows simplification of R in the two cases.*)
  1427   conj_assoc
  1428   disj_assoc
  1429   de_Morgan_conj
  1430   de_Morgan_disj
  1431   imp_disj1
  1432   imp_disj2
  1433   not_imp
  1434   disj_not1
  1435   not_all
  1436   not_ex
  1437   cases_simp
  1438   the_eq_trivial
  1439   the_sym_eq_trivial
  1440   ex_simps
  1441   all_simps
  1442   simp_thms
  1443 
  1444 lemmas [cong] = imp_cong simp_implies_cong
  1445 lemmas [split] = split_if
  1446 
  1447 ML {* val HOL_ss = @{simpset} *}
  1448 
  1449 text {* Simplifies x assuming c and y assuming ~c *}
  1450 lemma if_cong:
  1451   assumes "b = c"
  1452       and "c \<Longrightarrow> x = u"
  1453       and "\<not> c \<Longrightarrow> y = v"
  1454   shows "(if b then x else y) = (if c then u else v)"
  1455   unfolding if_def using assms by simp
  1456 
  1457 text {* Prevents simplification of x and y:
  1458   faster and allows the execution of functional programs. *}
  1459 lemma if_weak_cong [cong]:
  1460   assumes "b = c"
  1461   shows "(if b then x else y) = (if c then x else y)"
  1462   using assms by (rule arg_cong)
  1463 
  1464 text {* Prevents simplification of t: much faster *}
  1465 lemma let_weak_cong:
  1466   assumes "a = b"
  1467   shows "(let x = a in t x) = (let x = b in t x)"
  1468   using assms by (rule arg_cong)
  1469 
  1470 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1471 lemma eq_cong2:
  1472   assumes "u = u'"
  1473   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1474   using assms by simp
  1475 
  1476 lemma if_distrib:
  1477   "f (if c then x else y) = (if c then f x else f y)"
  1478   by simp
  1479 
  1480 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1481   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1482 lemma restrict_to_left:
  1483   assumes "x = y"
  1484   shows "(x = z) = (y = z)"
  1485   using assms by simp
  1486 
  1487 
  1488 subsubsection {* Generic cases and induction *}
  1489 
  1490 text {* Rule projections: *}
  1491 
  1492 ML {*
  1493 structure ProjectRule = ProjectRuleFun
  1494 (
  1495   val conjunct1 = @{thm conjunct1};
  1496   val conjunct2 = @{thm conjunct2};
  1497   val mp = @{thm mp};
  1498 )
  1499 *}
  1500 
  1501 constdefs
  1502   induct_forall where "induct_forall P == \<forall>x. P x"
  1503   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1504   induct_equal where "induct_equal x y == x = y"
  1505   induct_conj where "induct_conj A B == A \<and> B"
  1506 
  1507 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1508   by (unfold atomize_all induct_forall_def)
  1509 
  1510 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1511   by (unfold atomize_imp induct_implies_def)
  1512 
  1513 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1514   by (unfold atomize_eq induct_equal_def)
  1515 
  1516 lemma induct_conj_eq:
  1517   includes meta_conjunction_syntax
  1518   shows "(A && B) == Trueprop (induct_conj A B)"
  1519   by (unfold atomize_conj induct_conj_def)
  1520 
  1521 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1522 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1523 lemmas induct_rulify_fallback =
  1524   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1525 
  1526 
  1527 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1528     induct_conj (induct_forall A) (induct_forall B)"
  1529   by (unfold induct_forall_def induct_conj_def) iprover
  1530 
  1531 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1532     induct_conj (induct_implies C A) (induct_implies C B)"
  1533   by (unfold induct_implies_def induct_conj_def) iprover
  1534 
  1535 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1536 proof
  1537   assume r: "induct_conj A B ==> PROP C" and A B
  1538   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1539 next
  1540   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1541   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1542 qed
  1543 
  1544 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1545 
  1546 hide const induct_forall induct_implies induct_equal induct_conj
  1547 
  1548 text {* Method setup. *}
  1549 
  1550 ML {*
  1551   structure Induct = InductFun
  1552   (
  1553     val cases_default = @{thm case_split}
  1554     val atomize = @{thms induct_atomize}
  1555     val rulify = @{thms induct_rulify}
  1556     val rulify_fallback = @{thms induct_rulify_fallback}
  1557   );
  1558 *}
  1559 
  1560 setup Induct.setup
  1561 
  1562 
  1563 subsection {* Other simple lemmas and lemma duplicates *}
  1564 
  1565 lemma Let_0 [simp]: "Let 0 f = f 0"
  1566   unfolding Let_def ..
  1567 
  1568 lemma Let_1 [simp]: "Let 1 f = f 1"
  1569   unfolding Let_def ..
  1570 
  1571 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1572   by blast+
  1573 
  1574 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1575   apply (rule iffI)
  1576   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1577   apply (fast dest!: theI')
  1578   apply (fast intro: ext the1_equality [symmetric])
  1579   apply (erule ex1E)
  1580   apply (rule allI)
  1581   apply (rule ex1I)
  1582   apply (erule spec)
  1583   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1584   apply (erule impE)
  1585   apply (rule allI)
  1586   apply (rule_tac P = "xa = x" in case_split_thm)
  1587   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1588   done
  1589 
  1590 lemma mk_left_commute:
  1591   fixes f (infix "\<otimes>" 60)
  1592   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1593           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1594   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1595   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1596 
  1597 lemmas eq_sym_conv = eq_commute
  1598 
  1599 lemma nnf_simps:
  1600   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1601   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1602   "(\<not> \<not>(P)) = P"
  1603 by blast+
  1604 
  1605 
  1606 subsection {* Basic ML bindings *}
  1607 
  1608 ML {*
  1609 val FalseE = @{thm FalseE}
  1610 val Let_def = @{thm Let_def}
  1611 val TrueI = @{thm TrueI}
  1612 val allE = @{thm allE}
  1613 val allI = @{thm allI}
  1614 val all_dupE = @{thm all_dupE}
  1615 val arg_cong = @{thm arg_cong}
  1616 val box_equals = @{thm box_equals}
  1617 val ccontr = @{thm ccontr}
  1618 val classical = @{thm classical}
  1619 val conjE = @{thm conjE}
  1620 val conjI = @{thm conjI}
  1621 val conjunct1 = @{thm conjunct1}
  1622 val conjunct2 = @{thm conjunct2}
  1623 val disjCI = @{thm disjCI}
  1624 val disjE = @{thm disjE}
  1625 val disjI1 = @{thm disjI1}
  1626 val disjI2 = @{thm disjI2}
  1627 val eq_reflection = @{thm eq_reflection}
  1628 val ex1E = @{thm ex1E}
  1629 val ex1I = @{thm ex1I}
  1630 val ex1_implies_ex = @{thm ex1_implies_ex}
  1631 val exE = @{thm exE}
  1632 val exI = @{thm exI}
  1633 val excluded_middle = @{thm excluded_middle}
  1634 val ext = @{thm ext}
  1635 val fun_cong = @{thm fun_cong}
  1636 val iffD1 = @{thm iffD1}
  1637 val iffD2 = @{thm iffD2}
  1638 val iffI = @{thm iffI}
  1639 val impE = @{thm impE}
  1640 val impI = @{thm impI}
  1641 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1642 val mp = @{thm mp}
  1643 val notE = @{thm notE}
  1644 val notI = @{thm notI}
  1645 val not_all = @{thm not_all}
  1646 val not_ex = @{thm not_ex}
  1647 val not_iff = @{thm not_iff}
  1648 val not_not = @{thm not_not}
  1649 val not_sym = @{thm not_sym}
  1650 val refl = @{thm refl}
  1651 val rev_mp = @{thm rev_mp}
  1652 val spec = @{thm spec}
  1653 val ssubst = @{thm ssubst}
  1654 val subst = @{thm subst}
  1655 val sym = @{thm sym}
  1656 val trans = @{thm trans}
  1657 *}
  1658 
  1659 
  1660 subsection {* Code generator basic setup -- see further @{text Code_Setup.thy} *}
  1661 
  1662 setup "CodeName.setup #> CodeTarget.setup #> Nbe.setup"
  1663 
  1664 code_datatype Trueprop "prop"
  1665 
  1666 code_datatype "TYPE('a\<Colon>{})"
  1667 
  1668 lemma Let_case_cert:
  1669   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1670   shows "CASE x \<equiv> f x"
  1671   using assms by simp_all
  1672 
  1673 lemma If_case_cert:
  1674   includes meta_conjunction_syntax
  1675   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1676   shows "(CASE True \<equiv> f) && (CASE False \<equiv> g)"
  1677   using assms by simp_all
  1678 
  1679 setup {*
  1680   Code.add_case @{thm Let_case_cert}
  1681   #> Code.add_case @{thm If_case_cert}
  1682   #> Code.add_undefined @{const_name undefined}
  1683 *}
  1684 
  1685 class eq = type +
  1686   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1687   assumes eq: "eq x y \<longleftrightarrow> x = y "
  1688 begin
  1689 
  1690 lemma equals_eq [code inline, code func]: "op = \<equiv> eq"
  1691   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule eq)
  1692 
  1693 declare equals_eq [symmetric, code post]
  1694 
  1695 end
  1696 
  1697 setup {*
  1698   Sign.hide_names_i true ("const", ["HOL.eq"])
  1699   #> CodeUnit.add_const_alias @{thm equals_eq}
  1700 *}
  1701 
  1702 lemma [code func]:
  1703   shows "False \<and> x \<longleftrightarrow> False"
  1704     and "True \<and> x \<longleftrightarrow> x"
  1705     and "x \<and> False \<longleftrightarrow> False"
  1706     and "x \<and> True \<longleftrightarrow> x" by simp_all
  1707 
  1708 lemma [code func]:
  1709   shows "False \<or> x \<longleftrightarrow> x"
  1710     and "True \<or> x \<longleftrightarrow> True"
  1711     and "x \<or> False \<longleftrightarrow> x"
  1712     and "x \<or> True \<longleftrightarrow> True" by simp_all
  1713 
  1714 lemma [code func]:
  1715   shows "\<not> True \<longleftrightarrow> False"
  1716     and "\<not> False \<longleftrightarrow> True" by (rule HOL.simp_thms)+
  1717 
  1718 
  1719 
  1720 subsection {* Legacy tactics and ML bindings *}
  1721 
  1722 ML {*
  1723 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1724 
  1725 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1726 local
  1727   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1728     | wrong_prem (Bound _) = true
  1729     | wrong_prem _ = false;
  1730   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1731 in
  1732   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1733   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1734 end;
  1735 
  1736 val all_conj_distrib = thm "all_conj_distrib";
  1737 val all_simps = thms "all_simps";
  1738 val atomize_not = thm "atomize_not";
  1739 val case_split = thm "case_split";
  1740 val case_split_thm = thm "case_split_thm"
  1741 val cases_simp = thm "cases_simp";
  1742 val choice_eq = thm "choice_eq"
  1743 val cong = thm "cong"
  1744 val conj_comms = thms "conj_comms";
  1745 val conj_cong = thm "conj_cong";
  1746 val de_Morgan_conj = thm "de_Morgan_conj";
  1747 val de_Morgan_disj = thm "de_Morgan_disj";
  1748 val disj_assoc = thm "disj_assoc";
  1749 val disj_comms = thms "disj_comms";
  1750 val disj_cong = thm "disj_cong";
  1751 val eq_ac = thms "eq_ac";
  1752 val eq_cong2 = thm "eq_cong2"
  1753 val Eq_FalseI = thm "Eq_FalseI";
  1754 val Eq_TrueI = thm "Eq_TrueI";
  1755 val Ex1_def = thm "Ex1_def"
  1756 val ex_disj_distrib = thm "ex_disj_distrib";
  1757 val ex_simps = thms "ex_simps";
  1758 val if_cancel = thm "if_cancel";
  1759 val if_eq_cancel = thm "if_eq_cancel";
  1760 val if_False = thm "if_False";
  1761 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1762 val iff = thm "iff"
  1763 val if_splits = thms "if_splits";
  1764 val if_True = thm "if_True";
  1765 val if_weak_cong = thm "if_weak_cong"
  1766 val imp_all = thm "imp_all";
  1767 val imp_cong = thm "imp_cong";
  1768 val imp_conjL = thm "imp_conjL";
  1769 val imp_conjR = thm "imp_conjR";
  1770 val imp_conv_disj = thm "imp_conv_disj";
  1771 val simp_implies_def = thm "simp_implies_def";
  1772 val simp_thms = thms "simp_thms";
  1773 val split_if = thm "split_if";
  1774 val the1_equality = thm "the1_equality"
  1775 val theI = thm "theI"
  1776 val theI' = thm "theI'"
  1777 val True_implies_equals = thm "True_implies_equals";
  1778 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1779 
  1780 *}
  1781 
  1782 end