src/HOL/Product_Type.thy
author nipkow
Tue May 20 16:00:00 2014 +0200 (2014-05-20)
changeset 57016 c44ce6f4067d
parent 56626 6532efd66a70
child 57091 1fa9c19ba2c9
permissions -rw-r--r--
added unit :: linorder
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 keywords "inductive_set" "coinductive_set" :: thy_decl
    11 begin
    12 
    13 subsection {* @{typ bool} is a datatype *}
    14 
    15 free_constructors case_bool for =: True | False
    16 by auto
    17 
    18 text {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    19 
    20 setup {* Sign.mandatory_path "old" *}
    21 
    22 rep_datatype True False by (auto intro: bool_induct)
    23 
    24 setup {* Sign.parent_path *}
    25 
    26 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    27 
    28 setup {* Sign.mandatory_path "bool" *}
    29 
    30 lemmas induct = old.bool.induct
    31 lemmas inducts = old.bool.inducts
    32 lemmas rec = old.bool.rec
    33 lemmas simps = bool.distinct bool.case bool.rec
    34 
    35 setup {* Sign.parent_path *}
    36 
    37 declare case_split [cases type: bool]
    38   -- "prefer plain propositional version"
    39 
    40 lemma
    41   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    42     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    43     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P"
    44     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    45     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    46   by (simp_all add: equal)
    47 
    48 lemma If_case_cert:
    49   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    50   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    51   using assms by simp_all
    52 
    53 setup {*
    54   Code.add_case @{thm If_case_cert}
    55 *}
    56 
    57 code_printing
    58   constant "HOL.equal :: bool \<Rightarrow> bool \<Rightarrow> bool" \<rightharpoonup> (Haskell) infix 4 "=="
    59 | class_instance "bool" :: "equal" \<rightharpoonup> (Haskell) -
    60 
    61 
    62 subsection {* The @{text unit} type *}
    63 
    64 typedef unit = "{True}"
    65   by auto
    66 
    67 definition Unity :: unit  ("'(')")
    68   where "() = Abs_unit True"
    69 
    70 lemma unit_eq [no_atp]: "u = ()"
    71   by (induct u) (simp add: Unity_def)
    72 
    73 text {*
    74   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    75   this rule directly --- it loops!
    76 *}
    77 
    78 simproc_setup unit_eq ("x::unit") = {*
    79   fn _ => fn _ => fn ct =>
    80     if HOLogic.is_unit (term_of ct) then NONE
    81     else SOME (mk_meta_eq @{thm unit_eq})
    82 *}
    83 
    84 free_constructors case_unit for "()"
    85 by auto
    86 
    87 text {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    88 
    89 setup {* Sign.mandatory_path "old" *}
    90 
    91 rep_datatype "()" by simp
    92 
    93 setup {* Sign.parent_path *}
    94 
    95 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    96 
    97 setup {* Sign.mandatory_path "unit" *}
    98 
    99 lemmas induct = old.unit.induct
   100 lemmas inducts = old.unit.inducts
   101 lemmas rec = old.unit.rec
   102 lemmas simps = unit.case unit.rec
   103 
   104 setup {* Sign.parent_path *}
   105 
   106 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
   107   by simp
   108 
   109 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
   110   by (rule triv_forall_equality)
   111 
   112 text {*
   113   This rewrite counters the effect of simproc @{text unit_eq} on @{term
   114   [source] "%u::unit. f u"}, replacing it by @{term [source]
   115   f} rather than by @{term [source] "%u. f ()"}.
   116 *}
   117 
   118 lemma unit_abs_eta_conv [simp]: "(%u::unit. f ()) = f"
   119   by (rule ext) simp
   120 
   121 lemma UNIV_unit:
   122   "UNIV = {()}" by auto
   123 
   124 instantiation unit :: default
   125 begin
   126 
   127 definition "default = ()"
   128 
   129 instance ..
   130 
   131 end
   132 
   133 instantiation unit :: linorder
   134 begin
   135 
   136 definition less_eq_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool" where
   137 "less_eq_unit _ _ = True"
   138 
   139 definition less_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool" where
   140 "less_unit _ _ = False"
   141 
   142 declare less_eq_unit_def [simp] less_unit_def [simp]
   143 
   144 instance
   145 proof qed auto
   146 
   147 end
   148 
   149 lemma [code]:
   150   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   151 
   152 code_printing
   153   type_constructor unit \<rightharpoonup>
   154     (SML) "unit"
   155     and (OCaml) "unit"
   156     and (Haskell) "()"
   157     and (Scala) "Unit"
   158 | constant Unity \<rightharpoonup>
   159     (SML) "()"
   160     and (OCaml) "()"
   161     and (Haskell) "()"
   162     and (Scala) "()"
   163 | class_instance unit :: equal \<rightharpoonup>
   164     (Haskell) -
   165 | constant "HOL.equal :: unit \<Rightarrow> unit \<Rightarrow> bool" \<rightharpoonup>
   166     (Haskell) infix 4 "=="
   167 
   168 code_reserved SML
   169   unit
   170 
   171 code_reserved OCaml
   172   unit
   173 
   174 code_reserved Scala
   175   Unit
   176 
   177 
   178 subsection {* The product type *}
   179 
   180 subsubsection {* Type definition *}
   181 
   182 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   183   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   184 
   185 definition "prod = {f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   186 
   187 typedef ('a, 'b) prod (infixr "*" 20) = "prod :: ('a \<Rightarrow> 'b \<Rightarrow> bool) set"
   188   unfolding prod_def by auto
   189 
   190 type_notation (xsymbols)
   191   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   192 type_notation (HTML output)
   193   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   194 
   195 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   196   "Pair a b = Abs_prod (Pair_Rep a b)"
   197 
   198 lemma prod_cases: "(\<And>a b. P (Pair a b)) \<Longrightarrow> P p"
   199   by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   200 
   201 free_constructors case_prod for Pair fst snd
   202 proof -
   203   fix P :: bool and p :: "'a \<times> 'b"
   204   show "(\<And>x1 x2. p = Pair x1 x2 \<Longrightarrow> P) \<Longrightarrow> P"
   205     by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   206 next
   207   fix a c :: 'a and b d :: 'b
   208   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   209     by (auto simp add: Pair_Rep_def fun_eq_iff)
   210   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   211     by (auto simp add: prod_def)
   212   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   213     by (simp add: Pair_def Abs_prod_inject)
   214 qed
   215 
   216 text {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
   217 
   218 setup {* Sign.mandatory_path "old" *}
   219 
   220 rep_datatype Pair
   221 by (erule prod_cases) (rule prod.inject)
   222 
   223 setup {* Sign.parent_path *}
   224 
   225 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   226 
   227 setup {* Sign.mandatory_path "prod" *}
   228 
   229 declare
   230   old.prod.inject[iff del]
   231 
   232 lemmas induct = old.prod.induct
   233 lemmas inducts = old.prod.inducts
   234 lemmas rec = old.prod.rec
   235 lemmas simps = prod.inject prod.case prod.rec
   236 
   237 setup {* Sign.parent_path *}
   238 
   239 declare prod.case [nitpick_simp del]
   240 declare prod.weak_case_cong [cong del]
   241 
   242 
   243 subsubsection {* Tuple syntax *}
   244 
   245 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   246   "split \<equiv> case_prod"
   247 
   248 text {*
   249   Patterns -- extends pre-defined type @{typ pttrn} used in
   250   abstractions.
   251 *}
   252 
   253 nonterminal tuple_args and patterns
   254 
   255 syntax
   256   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   257   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   258   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   259   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   260   ""            :: "pttrn => patterns"                  ("_")
   261   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   262 
   263 translations
   264   "(x, y)" == "CONST Pair x y"
   265   "_pattern x y" => "CONST Pair x y"
   266   "_patterns x y" => "CONST Pair x y"
   267   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   268   "%(x, y, zs). b" == "CONST case_prod (%x (y, zs). b)"
   269   "%(x, y). b" == "CONST case_prod (%x y. b)"
   270   "_abs (CONST Pair x y) t" => "%(x, y). t"
   271   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   272      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   273 
   274 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   275   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   276 print_translation {*
   277   let
   278     fun split_tr' [Abs (x, T, t as (Abs abs))] =
   279           (* split (%x y. t) => %(x,y) t *)
   280           let
   281             val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   282             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   283           in
   284             Syntax.const @{syntax_const "_abs"} $
   285               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   286           end
   287       | split_tr' [Abs (x, T, (s as Const (@{const_syntax case_prod}, _) $ t))] =
   288           (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   289           let
   290             val Const (@{syntax_const "_abs"}, _) $
   291               (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   292             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   293           in
   294             Syntax.const @{syntax_const "_abs"} $
   295               (Syntax.const @{syntax_const "_pattern"} $ x' $
   296                 (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   297           end
   298       | split_tr' [Const (@{const_syntax case_prod}, _) $ t] =
   299           (* split (split (%x y z. t)) => %((x, y), z). t *)
   300           split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   301       | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   302           (* split (%pttrn z. t) => %(pttrn,z). t *)
   303           let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   304             Syntax.const @{syntax_const "_abs"} $
   305               (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   306           end
   307       | split_tr' _ = raise Match;
   308   in [(@{const_syntax case_prod}, K split_tr')] end
   309 *}
   310 
   311 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   312 typed_print_translation {*
   313   let
   314     fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   315       | split_guess_names_tr' T [Abs (x, xT, t)] =
   316           (case (head_of t) of
   317             Const (@{const_syntax case_prod}, _) => raise Match
   318           | _ =>
   319             let 
   320               val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   321               val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   322               val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   323             in
   324               Syntax.const @{syntax_const "_abs"} $
   325                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   326             end)
   327       | split_guess_names_tr' T [t] =
   328           (case head_of t of
   329             Const (@{const_syntax case_prod}, _) => raise Match
   330           | _ =>
   331             let
   332               val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   333               val (y, t') =
   334                 Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   335               val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   336             in
   337               Syntax.const @{syntax_const "_abs"} $
   338                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   339             end)
   340       | split_guess_names_tr' _ _ = raise Match;
   341   in [(@{const_syntax case_prod}, K split_guess_names_tr')] end
   342 *}
   343 
   344 (* Force eta-contraction for terms of the form "Q A (%p. case_prod P p)"
   345    where Q is some bounded quantifier or set operator.
   346    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   347    whereas we want "Q (x,y):A. P x y".
   348    Otherwise prevent eta-contraction.
   349 *)
   350 print_translation {*
   351   let
   352     fun contract Q tr ctxt ts =
   353       (case ts of
   354         [A, Abs (_, _, (s as Const (@{const_syntax case_prod},_) $ t) $ Bound 0)] =>
   355           if Term.is_dependent t then tr ctxt ts
   356           else Syntax.const Q $ A $ s
   357       | _ => tr ctxt ts);
   358   in
   359     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   360      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   361      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFIMUM} @{syntax_const "_INF"},
   362      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPREMUM} @{syntax_const "_SUP"}]
   363     |> map (fn (Q, tr) => (Q, contract Q tr))
   364   end
   365 *}
   366 
   367 subsubsection {* Code generator setup *}
   368 
   369 code_printing
   370   type_constructor prod \<rightharpoonup>
   371     (SML) infix 2 "*"
   372     and (OCaml) infix 2 "*"
   373     and (Haskell) "!((_),/ (_))"
   374     and (Scala) "((_),/ (_))"
   375 | constant Pair \<rightharpoonup>
   376     (SML) "!((_),/ (_))"
   377     and (OCaml) "!((_),/ (_))"
   378     and (Haskell) "!((_),/ (_))"
   379     and (Scala) "!((_),/ (_))"
   380 | class_instance  prod :: equal \<rightharpoonup>
   381     (Haskell) -
   382 | constant "HOL.equal :: 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool" \<rightharpoonup>
   383     (Haskell) infix 4 "=="
   384 
   385 
   386 subsubsection {* Fundamental operations and properties *}
   387 
   388 lemma Pair_inject:
   389   assumes "(a, b) = (a', b')"
   390     and "a = a' ==> b = b' ==> R"
   391   shows R
   392   using assms by simp
   393 
   394 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   395   by (cases p) simp
   396 
   397 code_printing
   398   constant fst \<rightharpoonup> (Haskell) "fst"
   399 | constant snd \<rightharpoonup> (Haskell) "snd"
   400 
   401 lemma case_prod_unfold [nitpick_unfold]: "case_prod = (%c p. c (fst p) (snd p))"
   402   by (simp add: fun_eq_iff split: prod.split)
   403 
   404 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   405   by simp
   406 
   407 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   408   by simp
   409 
   410 lemmas surjective_pairing = prod.collapse [symmetric]
   411 
   412 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   413   by (cases s, cases t) simp
   414 
   415 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   416   by (simp add: prod_eq_iff)
   417 
   418 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   419   by (fact prod.case)
   420 
   421 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   422   by (rule split_conv [THEN iffD2])
   423 
   424 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   425   by (rule split_conv [THEN iffD1])
   426 
   427 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   428   by (simp add: fun_eq_iff split: prod.split)
   429 
   430 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   431   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   432   by (simp add: fun_eq_iff split: prod.split)
   433 
   434 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   435   by (cases x) simp
   436 
   437 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   438   by (cases p) simp
   439 
   440 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   441   by (simp add: case_prod_unfold)
   442 
   443 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   444   -- {* Prevents simplification of @{term c}: much faster *}
   445   by (fact prod.weak_case_cong)
   446 
   447 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   448   by (simp add: split_eta)
   449 
   450 lemma split_paired_all [no_atp]: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   451 proof
   452   fix a b
   453   assume "!!x. PROP P x"
   454   then show "PROP P (a, b)" .
   455 next
   456   fix x
   457   assume "!!a b. PROP P (a, b)"
   458   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   459 qed
   460 
   461 lemma case_prod_distrib: "f (case x of (x, y) \<Rightarrow> g x y) = (case x of (x, y) \<Rightarrow> f (g x y))"
   462   by (cases x) simp
   463 
   464 text {*
   465   The rule @{thm [source] split_paired_all} does not work with the
   466   Simplifier because it also affects premises in congrence rules,
   467   where this can lead to premises of the form @{text "!!a b. ... =
   468   ?P(a, b)"} which cannot be solved by reflexivity.
   469 *}
   470 
   471 lemmas split_tupled_all = split_paired_all unit_all_eq2
   472 
   473 ML {*
   474   (* replace parameters of product type by individual component parameters *)
   475   local (* filtering with exists_paired_all is an essential optimization *)
   476     fun exists_paired_all (Const (@{const_name Pure.all}, _) $ Abs (_, T, t)) =
   477           can HOLogic.dest_prodT T orelse exists_paired_all t
   478       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   479       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   480       | exists_paired_all _ = false;
   481     val ss =
   482       simpset_of
   483        (put_simpset HOL_basic_ss @{context}
   484         addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   485         addsimprocs [@{simproc unit_eq}]);
   486   in
   487     fun split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   488       if exists_paired_all t then safe_full_simp_tac (put_simpset ss ctxt) i else no_tac);
   489 
   490     fun unsafe_split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   491       if exists_paired_all t then full_simp_tac (put_simpset ss ctxt) i else no_tac);
   492 
   493     fun split_all ctxt th =
   494       if exists_paired_all (Thm.prop_of th)
   495       then full_simplify (put_simpset ss ctxt) th else th;
   496   end;
   497 *}
   498 
   499 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_all_tac", split_all_tac)) *}
   500 
   501 lemma split_paired_All [simp, no_atp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   502   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   503   by fast
   504 
   505 lemma split_paired_Ex [simp, no_atp]: "(EX x. P x) = (EX a b. P (a, b))"
   506   by fast
   507 
   508 lemma split_paired_The [no_atp]: "(THE x. P x) = (THE (a, b). P (a, b))"
   509   -- {* Can't be added to simpset: loops! *}
   510   by (simp add: split_eta)
   511 
   512 text {*
   513   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   514   @{thm [source] split_eta} as a rewrite rule is not general enough,
   515   and using @{thm [source] cond_split_eta} directly would render some
   516   existing proofs very inefficient; similarly for @{text
   517   split_beta}.
   518 *}
   519 
   520 ML {*
   521 local
   522   val cond_split_eta_ss =
   523     simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms cond_split_eta});
   524   fun Pair_pat k 0 (Bound m) = (m = k)
   525     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   526         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   527     | Pair_pat _ _ _ = false;
   528   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   529     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   530     | no_args k i (Bound m) = m < k orelse m > k + i
   531     | no_args _ _ _ = true;
   532   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   533     | split_pat tp i (Const (@{const_name case_prod}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   534     | split_pat tp i _ = NONE;
   535   fun metaeq ctxt lhs rhs = mk_meta_eq (Goal.prove ctxt [] []
   536         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   537         (K (simp_tac (put_simpset cond_split_eta_ss ctxt) 1)));
   538 
   539   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   540     | beta_term_pat k i (t $ u) =
   541         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   542     | beta_term_pat k i t = no_args k i t;
   543   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   544     | eta_term_pat _ _ _ = false;
   545   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   546     | subst arg k i (t $ u) =
   547         if Pair_pat k i (t $ u) then incr_boundvars k arg
   548         else (subst arg k i t $ subst arg k i u)
   549     | subst arg k i t = t;
   550 in
   551   fun beta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t) $ arg) =
   552         (case split_pat beta_term_pat 1 t of
   553           SOME (i, f) => SOME (metaeq ctxt s (subst arg 0 i f))
   554         | NONE => NONE)
   555     | beta_proc _ _ = NONE;
   556   fun eta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t)) =
   557         (case split_pat eta_term_pat 1 t of
   558           SOME (_, ft) => SOME (metaeq ctxt s (let val (f $ arg) = ft in f end))
   559         | NONE => NONE)
   560     | eta_proc _ _ = NONE;
   561 end;
   562 *}
   563 simproc_setup split_beta ("split f z") = {* fn _ => fn ctxt => fn ct => beta_proc ctxt (term_of ct) *}
   564 simproc_setup split_eta ("split f") = {* fn _ => fn ctxt => fn ct => eta_proc ctxt (term_of ct) *}
   565 
   566 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   567   by (subst surjective_pairing, rule split_conv)
   568 
   569 lemma split_beta': "(\<lambda>(x,y). f x y) = (\<lambda>x. f (fst x) (snd x))"
   570   by (auto simp: fun_eq_iff)
   571 
   572 
   573 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   574   -- {* For use with @{text split} and the Simplifier. *}
   575   by (insert surj_pair [of p], clarify, simp)
   576 
   577 text {*
   578   @{thm [source] split_split} could be declared as @{text "[split]"}
   579   done after the Splitter has been speeded up significantly;
   580   precompute the constants involved and don't do anything unless the
   581   current goal contains one of those constants.
   582 *}
   583 
   584 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   585 by (subst split_split, simp)
   586 
   587 text {*
   588   \medskip @{term split} used as a logical connective or set former.
   589 
   590   \medskip These rules are for use with @{text blast}; could instead
   591   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   592 
   593 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   594   apply (simp only: split_tupled_all)
   595   apply (simp (no_asm_simp))
   596   done
   597 
   598 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   599   apply (simp only: split_tupled_all)
   600   apply (simp (no_asm_simp))
   601   done
   602 
   603 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   604   by (induct p) auto
   605 
   606 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   607   by (induct p) auto
   608 
   609 lemma splitE2:
   610   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   611 proof -
   612   assume q: "Q (split P z)"
   613   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   614   show R
   615     apply (rule r surjective_pairing)+
   616     apply (rule split_beta [THEN subst], rule q)
   617     done
   618 qed
   619 
   620 lemma splitD': "split R (a,b) c ==> R a b c"
   621   by simp
   622 
   623 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   624   by simp
   625 
   626 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   627 by (simp only: split_tupled_all, simp)
   628 
   629 lemma mem_splitE:
   630   assumes major: "z \<in> split c p"
   631     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   632   shows Q
   633   by (rule major [unfolded case_prod_unfold] cases surjective_pairing)+
   634 
   635 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   636 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   637 
   638 ML {*
   639 local (* filtering with exists_p_split is an essential optimization *)
   640   fun exists_p_split (Const (@{const_name case_prod},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   641     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   642     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   643     | exists_p_split _ = false;
   644 in
   645 fun split_conv_tac ctxt = SUBGOAL (fn (t, i) =>
   646   if exists_p_split t
   647   then safe_full_simp_tac (put_simpset HOL_basic_ss ctxt addsimps @{thms split_conv}) i
   648   else no_tac);
   649 end;
   650 *}
   651 
   652 (* This prevents applications of splitE for already splitted arguments leading
   653    to quite time-consuming computations (in particular for nested tuples) *)
   654 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_conv_tac", split_conv_tac)) *}
   655 
   656 lemma split_eta_SetCompr [simp, no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   657   by (rule ext) fast
   658 
   659 lemma split_eta_SetCompr2 [simp, no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   660   by (rule ext) fast
   661 
   662 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   663   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   664   by (rule ext) blast
   665 
   666 (* Do NOT make this a simp rule as it
   667    a) only helps in special situations
   668    b) can lead to nontermination in the presence of split_def
   669 *)
   670 lemma split_comp_eq: 
   671   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   672   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   673   by (rule ext) auto
   674 
   675 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   676   apply (rule_tac x = "(a, b)" in image_eqI)
   677    apply auto
   678   done
   679 
   680 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   681   by blast
   682 
   683 (*
   684 the following  would be slightly more general,
   685 but cannot be used as rewrite rule:
   686 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   687 ### ?y = .x
   688 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   689 by (rtac some_equality 1)
   690 by ( Simp_tac 1)
   691 by (split_all_tac 1)
   692 by (Asm_full_simp_tac 1)
   693 qed "The_split_eq";
   694 *)
   695 
   696 text {*
   697   Setup of internal @{text split_rule}.
   698 *}
   699 
   700 lemmas case_prodI = prod.case [THEN iffD2]
   701 
   702 lemma case_prodI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> case_prod c p"
   703   by (fact splitI2)
   704 
   705 lemma case_prodI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> case_prod c p x"
   706   by (fact splitI2')
   707 
   708 lemma case_prodE: "case_prod c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   709   by (fact splitE)
   710 
   711 lemma case_prodE': "case_prod c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   712   by (fact splitE')
   713 
   714 declare case_prodI [intro!]
   715 
   716 lemma case_prod_beta:
   717   "case_prod f p = f (fst p) (snd p)"
   718   by (fact split_beta)
   719 
   720 lemma prod_cases3 [cases type]:
   721   obtains (fields) a b c where "y = (a, b, c)"
   722   by (cases y, case_tac b) blast
   723 
   724 lemma prod_induct3 [case_names fields, induct type]:
   725     "(!!a b c. P (a, b, c)) ==> P x"
   726   by (cases x) blast
   727 
   728 lemma prod_cases4 [cases type]:
   729   obtains (fields) a b c d where "y = (a, b, c, d)"
   730   by (cases y, case_tac c) blast
   731 
   732 lemma prod_induct4 [case_names fields, induct type]:
   733     "(!!a b c d. P (a, b, c, d)) ==> P x"
   734   by (cases x) blast
   735 
   736 lemma prod_cases5 [cases type]:
   737   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   738   by (cases y, case_tac d) blast
   739 
   740 lemma prod_induct5 [case_names fields, induct type]:
   741     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   742   by (cases x) blast
   743 
   744 lemma prod_cases6 [cases type]:
   745   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   746   by (cases y, case_tac e) blast
   747 
   748 lemma prod_induct6 [case_names fields, induct type]:
   749     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   750   by (cases x) blast
   751 
   752 lemma prod_cases7 [cases type]:
   753   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   754   by (cases y, case_tac f) blast
   755 
   756 lemma prod_induct7 [case_names fields, induct type]:
   757     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   758   by (cases x) blast
   759 
   760 lemma split_def:
   761   "split = (\<lambda>c p. c (fst p) (snd p))"
   762   by (fact case_prod_unfold)
   763 
   764 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   765   "internal_split == split"
   766 
   767 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   768   by (simp only: internal_split_def split_conv)
   769 
   770 ML_file "Tools/split_rule.ML"
   771 setup Split_Rule.setup
   772 
   773 hide_const internal_split
   774 
   775 
   776 subsubsection {* Derived operations *}
   777 
   778 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   779   "curry = (\<lambda>c x y. c (x, y))"
   780 
   781 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   782   by (simp add: curry_def)
   783 
   784 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   785   by (simp add: curry_def)
   786 
   787 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   788   by (simp add: curry_def)
   789 
   790 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   791   by (simp add: curry_def)
   792 
   793 lemma curry_split [simp]: "curry (split f) = f"
   794   by (simp add: curry_def split_def)
   795 
   796 lemma split_curry [simp]: "split (curry f) = f"
   797   by (simp add: curry_def split_def)
   798 
   799 lemma curry_K: "curry (\<lambda>x. c) = (\<lambda>x y. c)"
   800 by(simp add: fun_eq_iff)
   801 
   802 text {*
   803   The composition-uncurry combinator.
   804 *}
   805 
   806 notation fcomp (infixl "\<circ>>" 60)
   807 
   808 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   809   "f \<circ>\<rightarrow> g = (\<lambda>x. case_prod g (f x))"
   810 
   811 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   812   by (simp add: fun_eq_iff scomp_def case_prod_unfold)
   813 
   814 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = case_prod g (f x)"
   815   by (simp add: scomp_unfold case_prod_unfold)
   816 
   817 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   818   by (simp add: fun_eq_iff)
   819 
   820 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   821   by (simp add: fun_eq_iff)
   822 
   823 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   824   by (simp add: fun_eq_iff scomp_unfold)
   825 
   826 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   827   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   828 
   829 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   830   by (simp add: fun_eq_iff scomp_unfold)
   831 
   832 code_printing
   833   constant scomp \<rightharpoonup> (Eval) infixl 3 "#->"
   834 
   835 no_notation fcomp (infixl "\<circ>>" 60)
   836 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   837 
   838 text {*
   839   @{term map_prod} --- action of the product functor upon
   840   functions.
   841 *}
   842 
   843 definition map_prod :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   844   "map_prod f g = (\<lambda>(x, y). (f x, g y))"
   845 
   846 lemma map_prod_simp [simp, code]:
   847   "map_prod f g (a, b) = (f a, g b)"
   848   by (simp add: map_prod_def)
   849 
   850 functor map_prod: map_prod
   851   by (auto simp add: split_paired_all)
   852 
   853 lemma fst_map_prod [simp]:
   854   "fst (map_prod f g x) = f (fst x)"
   855   by (cases x) simp_all
   856 
   857 lemma snd_prod_fun [simp]:
   858   "snd (map_prod f g x) = g (snd x)"
   859   by (cases x) simp_all
   860 
   861 lemma fst_comp_map_prod [simp]:
   862   "fst \<circ> map_prod f g = f \<circ> fst"
   863   by (rule ext) simp_all
   864 
   865 lemma snd_comp_map_prod [simp]:
   866   "snd \<circ> map_prod f g = g \<circ> snd"
   867   by (rule ext) simp_all
   868 
   869 lemma map_prod_compose:
   870   "map_prod (f1 o f2) (g1 o g2) = (map_prod f1 g1 o map_prod f2 g2)"
   871   by (rule ext) (simp add: map_prod.compositionality comp_def)
   872 
   873 lemma map_prod_ident [simp]:
   874   "map_prod (%x. x) (%y. y) = (%z. z)"
   875   by (rule ext) (simp add: map_prod.identity)
   876 
   877 lemma map_prod_imageI [intro]:
   878   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_prod f g ` R"
   879   by (rule image_eqI) simp_all
   880 
   881 lemma prod_fun_imageE [elim!]:
   882   assumes major: "c \<in> map_prod f g ` R"
   883     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   884   shows P
   885   apply (rule major [THEN imageE])
   886   apply (case_tac x)
   887   apply (rule cases)
   888   apply simp_all
   889   done
   890 
   891 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   892   "apfst f = map_prod f id"
   893 
   894 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   895   "apsnd f = map_prod id f"
   896 
   897 lemma apfst_conv [simp, code]:
   898   "apfst f (x, y) = (f x, y)" 
   899   by (simp add: apfst_def)
   900 
   901 lemma apsnd_conv [simp, code]:
   902   "apsnd f (x, y) = (x, f y)" 
   903   by (simp add: apsnd_def)
   904 
   905 lemma fst_apfst [simp]:
   906   "fst (apfst f x) = f (fst x)"
   907   by (cases x) simp
   908 
   909 lemma fst_comp_apfst [simp]:
   910   "fst \<circ> apfst f = f \<circ> fst"
   911   by (simp add: fun_eq_iff)
   912 
   913 lemma fst_apsnd [simp]:
   914   "fst (apsnd f x) = fst x"
   915   by (cases x) simp
   916 
   917 lemma fst_comp_apsnd [simp]:
   918   "fst \<circ> apsnd f = fst"
   919   by (simp add: fun_eq_iff)
   920 
   921 lemma snd_apfst [simp]:
   922   "snd (apfst f x) = snd x"
   923   by (cases x) simp
   924 
   925 lemma snd_comp_apfst [simp]:
   926   "snd \<circ> apfst f = snd"
   927   by (simp add: fun_eq_iff)
   928 
   929 lemma snd_apsnd [simp]:
   930   "snd (apsnd f x) = f (snd x)"
   931   by (cases x) simp
   932 
   933 lemma snd_comp_apsnd [simp]:
   934   "snd \<circ> apsnd f = f \<circ> snd"
   935   by (simp add: fun_eq_iff)
   936 
   937 lemma apfst_compose:
   938   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   939   by (cases x) simp
   940 
   941 lemma apsnd_compose:
   942   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   943   by (cases x) simp
   944 
   945 lemma apfst_apsnd [simp]:
   946   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   947   by (cases x) simp
   948 
   949 lemma apsnd_apfst [simp]:
   950   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   951   by (cases x) simp
   952 
   953 lemma apfst_id [simp] :
   954   "apfst id = id"
   955   by (simp add: fun_eq_iff)
   956 
   957 lemma apsnd_id [simp] :
   958   "apsnd id = id"
   959   by (simp add: fun_eq_iff)
   960 
   961 lemma apfst_eq_conv [simp]:
   962   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   963   by (cases x) simp
   964 
   965 lemma apsnd_eq_conv [simp]:
   966   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   967   by (cases x) simp
   968 
   969 lemma apsnd_apfst_commute:
   970   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   971   by simp
   972 
   973 context
   974 begin
   975 
   976 local_setup {* Local_Theory.map_naming (Name_Space.mandatory_path "prod") *}
   977 
   978 definition swap :: "'a \<times> 'b \<Rightarrow> 'b \<times> 'a"
   979 where
   980   "swap p = (snd p, fst p)"
   981 
   982 end
   983 
   984 lemma swap_simp [simp]:
   985   "prod.swap (x, y) = (y, x)"
   986   by (simp add: prod.swap_def)
   987 
   988 lemma pair_in_swap_image [simp]:
   989   "(y, x) \<in> prod.swap ` A \<longleftrightarrow> (x, y) \<in> A"
   990   by (auto intro!: image_eqI)
   991 
   992 lemma inj_swap [simp]:
   993   "inj_on prod.swap A"
   994   by (rule inj_onI) auto
   995 
   996 lemma swap_inj_on:
   997   "inj_on (\<lambda>(i, j). (j, i)) A"
   998   by (rule inj_onI) auto
   999 
  1000 lemma case_swap [simp]:
  1001   "(case prod.swap p of (y, x) \<Rightarrow> f x y) = (case p of (x, y) \<Rightarrow> f x y)"
  1002   by (cases p) simp
  1003 
  1004 text {*
  1005   Disjoint union of a family of sets -- Sigma.
  1006 *}
  1007 
  1008 definition Sigma :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<times> 'b) set" where
  1009   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
  1010 
  1011 abbreviation
  1012   Times :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set"
  1013     (infixr "<*>" 80) where
  1014   "A <*> B == Sigma A (%_. B)"
  1015 
  1016 notation (xsymbols)
  1017   Times  (infixr "\<times>" 80)
  1018 
  1019 notation (HTML output)
  1020   Times  (infixr "\<times>" 80)
  1021 
  1022 hide_const (open) Times
  1023 
  1024 syntax
  1025   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
  1026 translations
  1027   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
  1028 
  1029 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
  1030   by (unfold Sigma_def) blast
  1031 
  1032 lemma SigmaE [elim!]:
  1033     "[| c: Sigma A B;
  1034         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
  1035      |] ==> P"
  1036   -- {* The general elimination rule. *}
  1037   by (unfold Sigma_def) blast
  1038 
  1039 text {*
  1040   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
  1041   eigenvariables.
  1042 *}
  1043 
  1044 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1045   by blast
  1046 
  1047 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1048   by blast
  1049 
  1050 lemma SigmaE2:
  1051     "[| (a, b) : Sigma A B;
  1052         [| a:A;  b:B(a) |] ==> P
  1053      |] ==> P"
  1054   by blast
  1055 
  1056 lemma Sigma_cong:
  1057      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1058       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1059   by auto
  1060 
  1061 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1062   by blast
  1063 
  1064 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1065   by blast
  1066 
  1067 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1068   by blast
  1069 
  1070 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1071   by auto
  1072 
  1073 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1074   by auto
  1075 
  1076 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1077   by auto
  1078 
  1079 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1080   by blast
  1081 
  1082 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1083   by blast
  1084 
  1085 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1086   by (blast elim: equalityE)
  1087 
  1088 lemma SetCompr_Sigma_eq:
  1089     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1090   by blast
  1091 
  1092 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1093   by blast
  1094 
  1095 lemma UN_Times_distrib:
  1096   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1097   -- {* Suggested by Pierre Chartier *}
  1098   by blast
  1099 
  1100 lemma split_paired_Ball_Sigma [simp, no_atp]:
  1101     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1102   by blast
  1103 
  1104 lemma split_paired_Bex_Sigma [simp, no_atp]:
  1105     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1106   by blast
  1107 
  1108 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1109   by blast
  1110 
  1111 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1112   by blast
  1113 
  1114 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1115   by blast
  1116 
  1117 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1118   by blast
  1119 
  1120 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1121   by blast
  1122 
  1123 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1124   by blast
  1125 
  1126 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1127   by blast
  1128 
  1129 text {*
  1130   Non-dependent versions are needed to avoid the need for higher-order
  1131   matching, especially when the rules are re-oriented.
  1132 *}
  1133 
  1134 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1135   by (fact Sigma_Un_distrib1)
  1136 
  1137 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1138   by (fact Sigma_Int_distrib1)
  1139 
  1140 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1141   by (fact Sigma_Diff_distrib1)
  1142 
  1143 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1144   by auto
  1145 
  1146 lemma times_eq_iff: "A \<times> B = C \<times> D \<longleftrightarrow> A = C \<and> B = D \<or> ((A = {} \<or> B = {}) \<and> (C = {} \<or> D = {}))"
  1147   by auto
  1148 
  1149 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1150   by force
  1151 
  1152 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1153   by force
  1154 
  1155 lemma vimage_fst:
  1156   "fst -` A = A \<times> UNIV"
  1157   by auto
  1158 
  1159 lemma vimage_snd:
  1160   "snd -` A = UNIV \<times> A"
  1161   by auto
  1162 
  1163 lemma insert_times_insert[simp]:
  1164   "insert a A \<times> insert b B =
  1165    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1166 by blast
  1167 
  1168 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1169   apply auto
  1170   apply (case_tac "f x")
  1171   apply auto
  1172   done
  1173 
  1174 lemma times_Int_times: "A \<times> B \<inter> C \<times> D = (A \<inter> C) \<times> (B \<inter> D)"
  1175   by auto
  1176 
  1177 lemma product_swap:
  1178   "prod.swap ` (A \<times> B) = B \<times> A"
  1179   by (auto simp add: set_eq_iff)
  1180 
  1181 lemma swap_product:
  1182   "(\<lambda>(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1183   by (auto simp add: set_eq_iff)
  1184 
  1185 lemma image_split_eq_Sigma:
  1186   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1187 proof (safe intro!: imageI)
  1188   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1189   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1190     using * eq[symmetric] by auto
  1191 qed simp_all
  1192 
  1193 definition product :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
  1194   [code_abbrev]: "product A B = A \<times> B"
  1195 
  1196 hide_const (open) product
  1197 
  1198 lemma member_product:
  1199   "x \<in> Product_Type.product A B \<longleftrightarrow> x \<in> A \<times> B"
  1200   by (simp add: product_def)
  1201 
  1202 text {* The following @{const map_prod} lemmas are due to Joachim Breitner: *}
  1203 
  1204 lemma map_prod_inj_on:
  1205   assumes "inj_on f A" and "inj_on g B"
  1206   shows "inj_on (map_prod f g) (A \<times> B)"
  1207 proof (rule inj_onI)
  1208   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1209   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1210   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1211   assume "map_prod f g x = map_prod f g y"
  1212   hence "fst (map_prod f g x) = fst (map_prod f g y)" by (auto)
  1213   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1214   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1215   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1216   moreover from `map_prod f g x = map_prod f g y`
  1217   have "snd (map_prod f g x) = snd (map_prod f g y)" by (auto)
  1218   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1219   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1220   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1221   ultimately show "x = y" by(rule prod_eqI)
  1222 qed
  1223 
  1224 lemma map_prod_surj:
  1225   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1226   assumes "surj f" and "surj g"
  1227   shows "surj (map_prod f g)"
  1228 unfolding surj_def
  1229 proof
  1230   fix y :: "'b \<times> 'd"
  1231   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1232   moreover
  1233   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1234   ultimately have "(fst y, snd y) = map_prod f g (a,b)" by auto
  1235   thus "\<exists>x. y = map_prod f g x" by auto
  1236 qed
  1237 
  1238 lemma map_prod_surj_on:
  1239   assumes "f ` A = A'" and "g ` B = B'"
  1240   shows "map_prod f g ` (A \<times> B) = A' \<times> B'"
  1241 unfolding image_def
  1242 proof(rule set_eqI,rule iffI)
  1243   fix x :: "'a \<times> 'c"
  1244   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_prod f g x}"
  1245   then obtain y where "y \<in> A \<times> B" and "x = map_prod f g y" by blast
  1246   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1247   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1248   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1249   with `x = map_prod f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1250 next
  1251   fix x :: "'a \<times> 'c"
  1252   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1253   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1254   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1255   moreover from `image g B = B'` and `snd x \<in> B'`
  1256   obtain b where "b \<in> B" and "snd x = g b" by auto
  1257   ultimately have "(fst x, snd x) = map_prod f g (a,b)" by auto
  1258   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1259   ultimately have "\<exists>y \<in> A \<times> B. x = map_prod f g y" by auto
  1260   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_prod f g y}" by auto
  1261 qed
  1262 
  1263 
  1264 subsection {* Simproc for rewriting a set comprehension into a pointfree expression *}
  1265 
  1266 ML_file "Tools/set_comprehension_pointfree.ML"
  1267 
  1268 setup {*
  1269   Code_Preproc.map_pre (fn ctxt => ctxt addsimprocs
  1270     [Raw_Simplifier.make_simproc {name = "set comprehension", lhss = [@{cpat "Collect ?P"}],
  1271     proc = K Set_Comprehension_Pointfree.code_simproc, identifier = []}])
  1272 *}
  1273 
  1274 
  1275 subsection {* Inductively defined sets *}
  1276 
  1277 (* simplify {(x1, ..., xn). (x1, ..., xn) : S} to S *)
  1278 simproc_setup Collect_mem ("Collect t") = {*
  1279   fn _ => fn ctxt => fn ct =>
  1280     (case term_of ct of
  1281       S as Const (@{const_name Collect}, Type (@{type_name fun}, [_, T])) $ t =>
  1282         let val (u, _, ps) = HOLogic.strip_psplits t in
  1283           (case u of
  1284             (c as Const (@{const_name Set.member}, _)) $ q $ S' =>
  1285               (case try (HOLogic.strip_ptuple ps) q of
  1286                 NONE => NONE
  1287               | SOME ts =>
  1288                   if not (Term.is_open S') andalso
  1289                     ts = map Bound (length ps downto 0)
  1290                   then
  1291                     let val simp =
  1292                       full_simp_tac (put_simpset HOL_basic_ss ctxt
  1293                         addsimps [@{thm split_paired_all}, @{thm split_conv}]) 1
  1294                     in
  1295                       SOME (Goal.prove ctxt [] []
  1296                         (Const (@{const_name Pure.eq}, T --> T --> propT) $ S $ S')
  1297                         (K (EVERY
  1298                           [rtac eq_reflection 1, rtac @{thm subset_antisym} 1,
  1299                            rtac subsetI 1, dtac CollectD 1, simp,
  1300                            rtac subsetI 1, rtac CollectI 1, simp])))
  1301                     end
  1302                   else NONE)
  1303           | _ => NONE)
  1304         end
  1305     | _ => NONE)
  1306 *}
  1307 ML_file "Tools/inductive_set.ML"
  1308 
  1309 
  1310 subsection {* Legacy theorem bindings and duplicates *}
  1311 
  1312 lemma PairE:
  1313   obtains x y where "p = (x, y)"
  1314   by (fact prod.exhaust)
  1315 
  1316 lemmas Pair_eq = prod.inject
  1317 lemmas fst_conv = prod.sel(1)
  1318 lemmas snd_conv = prod.sel(2)
  1319 lemmas pair_collapse = prod.collapse
  1320 lemmas split = split_conv
  1321 lemmas Pair_fst_snd_eq = prod_eq_iff
  1322 
  1323 hide_const (open) prod
  1324 
  1325 end