src/HOL/Nitpick.thy
author blanchet
Thu Dec 17 15:22:11 2009 +0100 (2009-12-17)
changeset 34124 c4628a1dcf75
parent 33747 3aa6b9911252
child 34938 f4d3daddac42
permissions -rw-r--r--
added support for binary nat/int representation to Nitpick
     1 (*  Title:      HOL/Nitpick.thy
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2008, 2009
     4 
     5 Nitpick: Yet another counterexample generator for Isabelle/HOL.
     6 *)
     7 
     8 header {* Nitpick: Yet Another Counterexample Generator for Isabelle/HOL *}
     9 
    10 theory Nitpick
    11 imports Map SAT
    12 uses ("Tools/Nitpick/kodkod.ML")
    13      ("Tools/Nitpick/kodkod_sat.ML")
    14      ("Tools/Nitpick/nitpick_util.ML")
    15      ("Tools/Nitpick/nitpick_hol.ML")
    16      ("Tools/Nitpick/nitpick_mono.ML")
    17      ("Tools/Nitpick/nitpick_scope.ML")
    18      ("Tools/Nitpick/nitpick_peephole.ML")
    19      ("Tools/Nitpick/nitpick_rep.ML")
    20      ("Tools/Nitpick/nitpick_nut.ML")
    21      ("Tools/Nitpick/nitpick_kodkod.ML")
    22      ("Tools/Nitpick/nitpick_model.ML")
    23      ("Tools/Nitpick/nitpick.ML")
    24      ("Tools/Nitpick/nitpick_isar.ML")
    25      ("Tools/Nitpick/nitpick_tests.ML")
    26      ("Tools/Nitpick/minipick.ML")
    27 begin
    28 
    29 typedecl bisim_iterator
    30 
    31 axiomatization unknown :: 'a
    32            and undefined_fast_The :: 'a
    33            and undefined_fast_Eps :: 'a
    34            and bisim :: "bisim_iterator \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
    35            and bisim_iterator_max :: bisim_iterator
    36            and Tha :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    37 
    38 datatype ('a, 'b) pair_box = PairBox 'a 'b
    39 datatype ('a, 'b) fun_box = FunBox "('a \<Rightarrow> 'b)"
    40 
    41 typedecl unsigned_bit
    42 typedecl signed_bit
    43 
    44 datatype 'a word = Word "('a set)"
    45 
    46 text {*
    47 Alternative definitions.
    48 *}
    49 
    50 lemma If_def [nitpick_def]:
    51 "(if P then Q else R) \<equiv> (P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> R)"
    52 by (rule eq_reflection) (rule if_bool_eq_conj)
    53 
    54 lemma Ex1_def [nitpick_def]:
    55 "Ex1 P \<equiv> \<exists>x. P = {x}"
    56 apply (rule eq_reflection)
    57 apply (simp add: Ex1_def expand_set_eq)
    58 apply (rule iffI)
    59  apply (erule exE)
    60  apply (erule conjE)
    61  apply (rule_tac x = x in exI)
    62  apply (rule allI)
    63  apply (rename_tac y)
    64  apply (erule_tac x = y in allE)
    65 by (auto simp: mem_def)
    66 
    67 lemma rtrancl_def [nitpick_def]: "r\<^sup>* \<equiv> (r\<^sup>+)\<^sup>="
    68 by simp
    69 
    70 lemma rtranclp_def [nitpick_def]:
    71 "rtranclp r a b \<equiv> (a = b \<or> tranclp r a b)"
    72 by (rule eq_reflection) (auto dest: rtranclpD)
    73 
    74 lemma tranclp_def [nitpick_def]:
    75 "tranclp r a b \<equiv> trancl (split r) (a, b)"
    76 by (simp add: trancl_def Collect_def mem_def)
    77 
    78 definition refl' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    79 "refl' r \<equiv> \<forall>x. (x, x) \<in> r"
    80 
    81 definition wf' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    82 "wf' r \<equiv> acyclic r \<and> (finite r \<or> unknown)"
    83 
    84 axiomatization wf_wfrec :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b"
    85 
    86 definition wf_wfrec' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    87 [nitpick_simp]: "wf_wfrec' R F x = F (Recdef.cut (wf_wfrec R F) R x) x"
    88 
    89 definition wfrec' ::  "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    90 "wfrec' R F x \<equiv> if wf R then wf_wfrec' R F x
    91                 else THE y. wfrec_rel R (%f x. F (Recdef.cut f R x) x) x y"
    92 
    93 definition card' :: "('a \<Rightarrow> bool) \<Rightarrow> nat" where
    94 "card' X \<equiv> length (SOME xs. set xs = X \<and> distinct xs)"
    95 
    96 definition setsum' :: "('a \<Rightarrow> 'b\<Colon>comm_monoid_add) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b" where
    97 "setsum' f A \<equiv> if finite A then listsum (map f (SOME xs. set xs = A \<and> distinct xs)) else 0"
    98 
    99 inductive fold_graph' :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b \<Rightarrow> bool" where
   100 "fold_graph' f z {} z" |
   101 "\<lbrakk>x \<in> A; fold_graph' f z (A - {x}) y\<rbrakk> \<Longrightarrow> fold_graph' f z A (f x y)"
   102 
   103 text {*
   104 The following lemmas are not strictly necessary but they help the
   105 \textit{special\_level} optimization.
   106 *}
   107 
   108 lemma The_psimp [nitpick_psimp]:
   109 "P = {x} \<Longrightarrow> The P = x"
   110 by (subgoal_tac "{x} = (\<lambda>y. y = x)") (auto simp: mem_def)
   111 
   112 lemma Eps_psimp [nitpick_psimp]:
   113 "\<lbrakk>P x; \<not> P y; Eps P = y\<rbrakk> \<Longrightarrow> Eps P = x"
   114 apply (case_tac "P (Eps P)")
   115  apply auto
   116 apply (erule contrapos_np)
   117 by (rule someI)
   118 
   119 lemma unit_case_def [nitpick_def]:
   120 "unit_case x u \<equiv> x"
   121 apply (subgoal_tac "u = ()")
   122  apply (simp only: unit.cases)
   123 by simp
   124 
   125 declare unit.cases [nitpick_simp del]
   126 
   127 lemma nat_case_def [nitpick_def]:
   128 "nat_case x f n \<equiv> if n = 0 then x else f (n - 1)"
   129 apply (rule eq_reflection)
   130 by (case_tac n) auto
   131 
   132 declare nat.cases [nitpick_simp del]
   133 
   134 lemma list_size_simp [nitpick_simp]:
   135 "list_size f xs = (if xs = [] then 0
   136                    else Suc (f (hd xs) + list_size f (tl xs)))"
   137 "size xs = (if xs = [] then 0 else Suc (size (tl xs)))"
   138 by (case_tac xs) auto
   139 
   140 text {*
   141 Auxiliary definitions used to provide an alternative representation for
   142 @{text rat} and @{text real}.
   143 *}
   144 
   145 function nat_gcd :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   146 [simp del]: "nat_gcd x y = (if y = 0 then x else nat_gcd y (x mod y))"
   147 by auto
   148 termination
   149 apply (relation "measure (\<lambda>(x, y). x + y + (if y > x then 1 else 0))")
   150  apply auto
   151  apply (metis mod_less_divisor xt1(9))
   152 by (metis mod_mod_trivial mod_self nat_neq_iff xt1(10))
   153 
   154 definition nat_lcm :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   155 "nat_lcm x y = x * y div (nat_gcd x y)"
   156 
   157 definition int_gcd :: "int \<Rightarrow> int \<Rightarrow> int" where
   158 "int_gcd x y = int (nat_gcd (nat (abs x)) (nat (abs y)))"
   159 
   160 definition int_lcm :: "int \<Rightarrow> int \<Rightarrow> int" where
   161 "int_lcm x y = int (nat_lcm (nat (abs x)) (nat (abs y)))"
   162 
   163 definition Frac :: "int \<times> int \<Rightarrow> bool" where
   164 "Frac \<equiv> \<lambda>(a, b). b > 0 \<and> int_gcd a b = 1"
   165 
   166 axiomatization Abs_Frac :: "int \<times> int \<Rightarrow> 'a"
   167            and Rep_Frac :: "'a \<Rightarrow> int \<times> int"
   168 
   169 definition zero_frac :: 'a where
   170 "zero_frac \<equiv> Abs_Frac (0, 1)"
   171 
   172 definition one_frac :: 'a where
   173 "one_frac \<equiv> Abs_Frac (1, 1)"
   174 
   175 definition num :: "'a \<Rightarrow> int" where
   176 "num \<equiv> fst o Rep_Frac"
   177 
   178 definition denom :: "'a \<Rightarrow> int" where
   179 "denom \<equiv> snd o Rep_Frac"
   180 
   181 function norm_frac :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
   182 [simp del]: "norm_frac a b = (if b < 0 then norm_frac (- a) (- b)
   183                               else if a = 0 \<or> b = 0 then (0, 1)
   184                               else let c = int_gcd a b in (a div c, b div c))"
   185 by pat_completeness auto
   186 termination by (relation "measure (\<lambda>(_, b). if b < 0 then 1 else 0)") auto
   187 
   188 definition frac :: "int \<Rightarrow> int \<Rightarrow> 'a" where
   189 "frac a b \<equiv> Abs_Frac (norm_frac a b)"
   190 
   191 definition plus_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   192 [nitpick_simp]:
   193 "plus_frac q r = (let d = int_lcm (denom q) (denom r) in
   194                     frac (num q * (d div denom q) + num r * (d div denom r)) d)"
   195 
   196 definition times_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   197 [nitpick_simp]:
   198 "times_frac q r = frac (num q * num r) (denom q * denom r)"
   199 
   200 definition uminus_frac :: "'a \<Rightarrow> 'a" where
   201 "uminus_frac q \<equiv> Abs_Frac (- num q, denom q)"
   202 
   203 definition number_of_frac :: "int \<Rightarrow> 'a" where
   204 "number_of_frac n \<equiv> Abs_Frac (n, 1)"
   205 
   206 definition inverse_frac :: "'a \<Rightarrow> 'a" where
   207 "inverse_frac q \<equiv> frac (denom q) (num q)"
   208 
   209 definition less_eq_frac :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where
   210 [nitpick_simp]:
   211 "less_eq_frac q r \<longleftrightarrow> num (plus_frac q (uminus_frac r)) \<le> 0"
   212 
   213 definition of_frac :: "'a \<Rightarrow> 'b\<Colon>{inverse,ring_1}" where
   214 "of_frac q \<equiv> of_int (num q) / of_int (denom q)"
   215 
   216 (* While Nitpick normally avoids to unfold definitions for locales, it
   217    unfortunately needs to unfold them when dealing with the following built-in
   218    constants. A cleaner approach would be to change "Nitpick_HOL" and
   219    "Nitpick_Nut" so that they handle the unexpanded overloaded constants
   220    directly, but this is slightly more tricky to implement. *)
   221 lemmas [nitpick_def] = div_int_inst.div_int div_int_inst.mod_int
   222     div_nat_inst.div_nat div_nat_inst.mod_nat lower_semilattice_fun_inst.inf_fun
   223     minus_fun_inst.minus_fun minus_int_inst.minus_int minus_nat_inst.minus_nat
   224     one_int_inst.one_int one_nat_inst.one_nat ord_fun_inst.less_eq_fun
   225     ord_int_inst.less_eq_int ord_int_inst.less_int ord_nat_inst.less_eq_nat
   226     ord_nat_inst.less_nat plus_int_inst.plus_int plus_nat_inst.plus_nat
   227     times_int_inst.times_int times_nat_inst.times_nat uminus_int_inst.uminus_int
   228     upper_semilattice_fun_inst.sup_fun zero_int_inst.zero_int
   229     zero_nat_inst.zero_nat
   230 
   231 use "Tools/Nitpick/kodkod.ML"
   232 use "Tools/Nitpick/kodkod_sat.ML"
   233 use "Tools/Nitpick/nitpick_util.ML"
   234 use "Tools/Nitpick/nitpick_hol.ML"
   235 use "Tools/Nitpick/nitpick_mono.ML"
   236 use "Tools/Nitpick/nitpick_scope.ML"
   237 use "Tools/Nitpick/nitpick_peephole.ML"
   238 use "Tools/Nitpick/nitpick_rep.ML"
   239 use "Tools/Nitpick/nitpick_nut.ML"
   240 use "Tools/Nitpick/nitpick_kodkod.ML"
   241 use "Tools/Nitpick/nitpick_model.ML"
   242 use "Tools/Nitpick/nitpick.ML"
   243 use "Tools/Nitpick/nitpick_isar.ML"
   244 use "Tools/Nitpick/nitpick_tests.ML"
   245 use "Tools/Nitpick/minipick.ML"
   246 
   247 setup {* Nitpick_Isar.setup *}
   248 
   249 hide (open) const unknown undefined_fast_The undefined_fast_Eps bisim 
   250     bisim_iterator_max Tha PairBox FunBox Word refl' wf' wf_wfrec wf_wfrec'
   251     wfrec' card' setsum' fold_graph' nat_gcd nat_lcm int_gcd int_lcm Frac
   252     Abs_Frac Rep_Frac zero_frac one_frac num denom norm_frac frac plus_frac
   253     times_frac uminus_frac number_of_frac inverse_frac less_eq_frac of_frac
   254 hide (open) type bisim_iterator pair_box fun_box unsigned_bit signed_bit word
   255 hide (open) fact If_def Ex1_def rtrancl_def rtranclp_def tranclp_def refl'_def
   256     wf'_def wf_wfrec'_def wfrec'_def card'_def setsum'_def fold_graph'_def
   257     The_psimp Eps_psimp unit_case_def nat_case_def list_size_simp nat_gcd_def
   258     nat_lcm_def int_gcd_def int_lcm_def Frac_def zero_frac_def one_frac_def
   259     num_def denom_def norm_frac_def frac_def plus_frac_def times_frac_def
   260     uminus_frac_def number_of_frac_def inverse_frac_def less_eq_frac_def
   261     of_frac_def
   262 
   263 end