src/Pure/pattern.ML
author wenzelm
Sat Jun 05 13:07:49 2004 +0200 (2004-06-05)
changeset 14875 c48d086264c4
parent 14861 ca5cae7fb65a
child 14981 e73f8140af78
permissions -rw-r--r--
avoid implicit arguments via refs;
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 
     6 Unification of Higher-Order Patterns.
     7 
     8 See also:
     9 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
    10 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    11 
    12 TODO: optimize red by special-casing it
    13 *)
    14 
    15 infix aeconv;
    16 
    17 signature PATTERN =
    18 sig
    19   val trace_unify_fail  : bool ref
    20   val aeconv            : term * term -> bool
    21   val eta_contract      : term -> term
    22   val eta_long          : typ list -> term -> term
    23   val beta_eta_contract : term -> term
    24   val eta_contract_atom : term -> term
    25   val match             : Type.tsig -> term * term
    26                           -> (indexname*typ)list * (indexname*term)list
    27   val first_order_match : Type.tsig -> term * term
    28                           -> (indexname*typ)list * (indexname*term)list
    29   val matches           : Type.tsig -> term * term -> bool
    30   val matches_subterm   : Type.tsig -> term * term -> bool
    31   val unify             : Sign.sg * Envir.env * (term * term)list -> Envir.env
    32   val first_order       : term -> bool
    33   val pattern           : term -> bool
    34   val rewrite_term      : Type.tsig -> (term * term) list -> (term -> term option) list
    35                           -> term -> term
    36   exception Unif
    37   exception MATCH
    38   exception Pattern
    39 end;
    40 
    41 structure Pattern : PATTERN =
    42 struct
    43 
    44 exception Unif;
    45 exception Pattern;
    46 
    47 val trace_unify_fail = ref false;
    48 
    49 fun string_of_term sg env binders t = Sign.string_of_term sg
    50   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    51 
    52 fun bname binders i = fst(nth_elem(i,binders));
    53 fun bnames binders is = space_implode " " (map (bname binders) is);
    54 
    55 fun typ_clash sg (tye,T,U) =
    56   if !trace_unify_fail
    57   then let val t = Sign.string_of_typ sg (Envir.norm_type tye T)
    58            and u = Sign.string_of_typ sg (Envir.norm_type tye U)
    59        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    60   else ()
    61 
    62 fun clash a b =
    63   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    64 
    65 fun boundVar binders i =
    66   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    67 
    68 fun clashBB binders i j =
    69   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    70   else ()
    71 
    72 fun clashB binders i s =
    73   if !trace_unify_fail then clash (boundVar binders i) s
    74   else ()
    75 
    76 fun proj_fail sg (env,binders,F,is,t) =
    77   if !trace_unify_fail
    78   then let val f = Syntax.string_of_vname F
    79            val xs = bnames binders is
    80            val u = string_of_term sg env binders t
    81            val ys = bnames binders (loose_bnos t \\ is)
    82        in tracing("Cannot unify variable " ^ f ^
    83                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    84                "\nTerm contains additional bound variable(s) " ^ ys)
    85        end
    86   else ()
    87 
    88 fun ocheck_fail sg (F,t,binders,env) =
    89   if !trace_unify_fail
    90   then let val f = Syntax.string_of_vname F
    91            val u = string_of_term sg env binders t
    92        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
    93                   "\nCannot unify!\n")
    94        end
    95   else ()
    96 
    97 fun occurs(F,t,env) =
    98     let fun occ(Var(G,_))   = (case Envir.lookup(env,G) of
    99                                  Some(t) => occ t
   100                                | None    => F=G)
   101           | occ(t1$t2)      = occ t1 orelse occ t2
   102           | occ(Abs(_,_,t)) = occ t
   103           | occ _           = false
   104     in occ t end;
   105 
   106 
   107 fun mapbnd f =
   108     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   109           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   110           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   111           | mpb _ atom           = atom
   112     in mpb 0 end;
   113 
   114 fun idx [] j     = raise Unif
   115   | idx(i::is) j = if i=j then length is else idx is j;
   116 
   117 fun at xs i = nth_elem (i,xs);
   118 
   119 fun mkabs (binders,is,t)  =
   120     let fun mk(i::is) = let val (x,T) = nth_elem(i,binders)
   121                         in Abs(x,T,mk is) end
   122           | mk []     = t
   123     in mk is end;
   124 
   125 val incr = mapbnd (fn i => i+1);
   126 
   127 fun ints_of []             = []
   128   | ints_of (Bound i ::bs) =
   129       let val is = ints_of bs
   130       in if i mem_int is then raise Pattern else i::is end
   131   | ints_of _              = raise Pattern;
   132 
   133 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   134 
   135 
   136 fun app (s,(i::is)) = app (s$Bound(i),is)
   137   | app (s,[])      = s;
   138 
   139 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   140   | red t            []      [] = t
   141   | red t            is      jn = app (mapbnd (at jn) t,is);
   142 
   143 
   144 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   145 fun split_type (T,0,Ts)                    = (Ts,T)
   146   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   147   | split_type _                           = error("split_type");
   148 
   149 fun type_of_G (env as Envir.Envir {iTs, ...}) (T,n,is) =
   150   let val (Ts, U) = split_type (Envir.norm_type iTs T, n, [])
   151   in map (at Ts) is ---> U end;
   152 
   153 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   154 
   155 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   156   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   157   in Envir.update((F,mkhnf(binders,is,G,js)),env') end;
   158 
   159 
   160 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   161 fun mk_proj_list is =
   162     let fun mk(i::is,j) = if is_some i then j :: mk(is,j-1) else mk(is,j-1)
   163           | mk([],_)    = []
   164     in mk(is,length is - 1) end;
   165 
   166 fun proj(s,env,binders,is) =
   167     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   168         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   169               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   170                             in (Abs(a,T,t'),env') end
   171             | t => (case strip_comb t of
   172                 (c as Const _,ts) =>
   173                          let val (ts',env') = prs(ts,env,d,binders)
   174                          in (list_comb(c,ts'),env') end
   175                  | (f as Free _,ts) =>
   176                          let val (ts',env') = prs(ts,env,d,binders)
   177                          in (list_comb(f,ts'),env') end
   178                  | (Bound(i),ts) =>
   179                          let val j = trans d i
   180                              val (ts',env') = prs(ts,env,d,binders)
   181                          in (list_comb(Bound j,ts'),env') end
   182                  | (Var(F as (a,_),Fty),ts) =>
   183                       let val js = ints_of' env ts;
   184                           val js' = map (try (trans d)) js;
   185                           val ks = mk_proj_list js';
   186                           val ls = mapfilter I js'
   187                           val Hty = type_of_G env (Fty,length js,ks)
   188                           val (env',H) = Envir.genvar a (env,Hty)
   189                           val env'' =
   190                                 Envir.update((F,mkhnf(binders,js,H,ks)),env')
   191                       in (app(H,ls),env'') end
   192                  | _  => raise Pattern))
   193         and prs(s::ss,env,d,binders) =
   194               let val (s',env1) = pr(s,env,d,binders)
   195                   val (ss',env2) = prs(ss,env1,d,binders)
   196               in (s'::ss',env2) end
   197           | prs([],env,_,_) = ([],env)
   198    in if downto0(is,length binders - 1) then (s,env)
   199       else pr(s,env,0,binders)
   200    end;
   201 
   202 
   203 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   204 fun mk_ff_list(is,js) =
   205     let fun mk([],[],_)        = []
   206           | mk(i::is,j::js, k) = if i=j then k :: mk(is,js,k-1)
   207                                         else mk(is,js,k-1)
   208           | mk _               = error"mk_ff_list"
   209     in mk(is,js,length is-1) end;
   210 
   211 fun flexflex1(env,binders,F,Fty,is,js) =
   212   if is=js then env
   213   else let val ks = mk_ff_list(is,js)
   214        in mknewhnf(env,binders,is,F,Fty,ks) end;
   215 
   216 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   217   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   218             if js subset_int is
   219             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   220                  in Envir.update((F,t),env) end
   221             else let val ks = is inter_int js
   222                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   223                      val (env',H) = Envir.genvar a (env,Hty)
   224                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   225                  in Envir.update((G,lam js), Envir.update((F,lam is),env'))
   226                  end;
   227   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   228 
   229 fun unify_types sg (T,U, env as Envir.Envir{asol,iTs,maxidx}) =
   230   if T=U then env
   231   else let val (iTs',maxidx') = Type.unify (Sign.tsig_of sg) (iTs, maxidx) (U, T)
   232        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   233        handle Type.TUNIFY => (typ_clash sg (iTs,T,U); raise Unif);
   234 
   235 fun unif sg binders (env,(s,t)) = case (Envir.head_norm env s, Envir.head_norm env t) of
   236       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   237          let val name = if ns = "" then nt else ns
   238          in unif sg ((name,Ts)::binders) (env,(ts,tt)) end
   239     | (Abs(ns,Ts,ts),t) => unif sg ((ns,Ts)::binders) (env,(ts,(incr t)$Bound(0)))
   240     | (t,Abs(nt,Tt,tt)) => unif sg ((nt,Tt)::binders) (env,((incr t)$Bound(0),tt))
   241     | p => cases sg (binders,env,p)
   242 
   243 and cases sg (binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   244        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   245          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   246                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   247       | ((Var(F,_),ss),_)             => flexrigid sg (env,binders,F,ints_of' env ss,t)
   248       | (_,(Var(F,_),ts))             => flexrigid sg (env,binders,F,ints_of' env ts,s)
   249       | ((Const c,ss),(Const d,ts))   => rigidrigid sg (env,binders,c,d,ss,ts)
   250       | ((Free(f),ss),(Free(g),ts))   => rigidrigid sg (env,binders,f,g,ss,ts)
   251       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB sg (env,binders,i,j,ss,ts)
   252       | ((Abs(_),_),_)                => raise Pattern
   253       | (_,(Abs(_),_))                => raise Pattern
   254       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   255       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   256       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   257       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   258       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   259       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   260 
   261 
   262 and rigidrigid sg (env,binders,(a,Ta),(b,Tb),ss,ts) =
   263       if a<>b then (clash a b; raise Unif)
   264       else foldl (unif sg binders) (unify_types sg (Ta,Tb,env), ss~~ts)
   265 
   266 and rigidrigidB sg (env,binders,i,j,ss,ts) =
   267      if i <> j then (clashBB binders i j; raise Unif)
   268      else foldl (unif sg binders) (env ,ss~~ts)
   269 
   270 and flexrigid sg (params as (env,binders,F,is,t)) =
   271       if occurs(F,t,env) then (ocheck_fail sg (F,t,binders,env); raise Unif)
   272       else (let val (u,env') = proj(t,env,binders,is)
   273             in Envir.update((F,mkabs(binders,is,u)),env') end
   274             handle Unif => (proj_fail sg params; raise Unif));
   275 
   276 fun unify(sg,env,tus) = foldl (unif sg []) (env,tus);
   277 
   278 
   279 (*Eta-contract a term (fully)*)
   280 
   281 fun eta_contract t =
   282   let
   283     exception SAME;
   284     fun eta (Abs (a, T, body)) =
   285       ((case eta body of
   286           body' as (f $ Bound 0) =>
   287             if loose_bvar1 (f, 0) then Abs(a, T, body')
   288             else incr_boundvars ~1 f
   289         | body' => Abs (a, T, body')) handle SAME =>
   290        (case body of
   291           (f $ Bound 0) =>
   292             if loose_bvar1 (f, 0) then raise SAME
   293             else incr_boundvars ~1 f
   294         | _ => raise SAME))
   295       | eta (f $ t) =
   296           (let val f' = eta f
   297            in f' $ etah t end handle SAME => f $ eta t)
   298       | eta _ = raise SAME
   299     and etah t = (eta t handle SAME => t)
   300   in etah t end;
   301 
   302 val beta_eta_contract = eta_contract o Envir.beta_norm;
   303 
   304 (*Eta-contract a term from outside: just enough to reduce it to an atom
   305 DOESN'T QUITE WORK!
   306 *)
   307 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   308       (case  eta_contract2 body  of
   309         body' as (f $ Bound 0) =>
   310             if loose_bvar1(f,0) then Abs(a,T,body')
   311             else eta_contract_atom (incr_boundvars ~1 f)
   312       | _ => t0)
   313   | eta_contract_atom t = t
   314 and eta_contract2 (f$t) = f $ eta_contract_atom t
   315   | eta_contract2 t     = eta_contract_atom t;
   316 
   317 (* put a term into eta long beta normal form *)
   318 fun eta_long Ts (Abs (s, T, t)) = Abs (s, T, eta_long (T :: Ts) t)
   319   | eta_long Ts t = (case strip_comb t of
   320       (Abs _, _) => eta_long Ts (Envir.beta_norm t)
   321     | (u, ts) =>
   322       let
   323         val Us = binder_types (fastype_of1 (Ts, t));
   324         val i = length Us
   325       in list_abs (map (pair "x") Us,
   326         list_comb (incr_boundvars i u, map (eta_long (rev Us @ Ts))
   327           (map (incr_boundvars i) ts @ map Bound (i - 1 downto 0))))
   328       end);
   329 
   330 
   331 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   332   Note that Consts and Vars may have more than one type.*)
   333 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   334 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   335   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   336   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   337   | aconv_aux (Bound i,    Bound j)    = i=j
   338   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   339   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   340   | aconv_aux _ =  false;
   341 
   342 
   343 (*** Matching ***)
   344 
   345 exception MATCH;
   346 
   347 fun typ_match tsig args = (Type.typ_match tsig args)
   348                           handle Type.TYPE_MATCH => raise MATCH;
   349 
   350 (*First-order matching;
   351   fomatch tsig (pattern, object) returns a (tyvar,typ)list and (var,term)list.
   352   The pattern and object may have variables in common.
   353   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   354   Object is eta-contracted on the fly (by eta-expanding the pattern).
   355   Precondition: the pattern is already eta-contracted!
   356   Note: types are matched on the fly *)
   357 fun fomatch tsig =
   358   let
   359     fun mtch (instsp as (tyinsts,insts)) = fn
   360         (Var(ixn,T), t)  =>
   361           if loose_bvar(t,0) then raise MATCH
   362           else (case assoc_string_int(insts,ixn) of
   363                   None => (typ_match tsig (tyinsts, (T, fastype_of t)),
   364                            (ixn,t)::insts)
   365                 | Some u => if t aeconv u then instsp else raise MATCH)
   366       | (Free (a,T), Free (b,U)) =>
   367           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   368       | (Const (a,T), Const (b,U))  =>
   369           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   370       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   371       | (Abs(_,T,t), Abs(_,U,u))  =>
   372           mtch (typ_match tsig (tyinsts,(T,U)),insts) (t,u)
   373       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   374       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   375       | _ => raise MATCH
   376   in mtch end;
   377 
   378 fun first_order_match tsig = apfst Vartab.dest o fomatch tsig (Vartab.empty, []);
   379 
   380 (* Matching of higher-order patterns *)
   381 
   382 fun match_bind(itms,binders,ixn,is,t) =
   383   let val js = loose_bnos t
   384   in if null is
   385      then if null js then (ixn,t)::itms else raise MATCH
   386      else if js subset_int is
   387           then let val t' = if downto0(is,length binders - 1) then t
   388                             else mapbnd (idx is) t
   389                in (ixn, mkabs(binders,is,t')) :: itms end
   390           else raise MATCH
   391   end;
   392 
   393 fun match tsg (po as (pat,obj)) =
   394 let
   395   (* Pre: pat and obj have same type *)
   396   fun mtch binders (env as (iTs,itms),(pat,obj)) =
   397     case pat of
   398       Abs(ns,Ts,ts) =>
   399         (case obj of
   400            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (env,(ts,tt))
   401          | _ => let val Tt = typ_subst_TVars_Vartab iTs Ts
   402                 in mtch((ns,Tt)::binders)(env,(ts,(incr obj)$Bound(0))) end)
   403     | _ => (case obj of
   404               Abs(nt,Tt,tt) =>
   405                 mtch((nt,Tt)::binders)(env,((incr pat)$Bound(0),tt))
   406             | _ => cases(binders,env,pat,obj))
   407 
   408   and cases(binders,env as (iTs,itms),pat,obj) =
   409     let val (ph,pargs) = strip_comb pat
   410         fun rigrig1(iTs,oargs) =
   411               foldl (mtch binders) ((iTs,itms), pargs~~oargs)
   412         fun rigrig2((a,Ta),(b,Tb),oargs) =
   413               if a<> b then raise MATCH
   414               else rigrig1(typ_match tsg (iTs,(Ta,Tb)), oargs)
   415     in case ph of
   416          Var(ixn,_) =>
   417            let val is = ints_of pargs
   418            in case assoc_string_int(itms,ixn) of
   419                 None => (iTs,match_bind(itms,binders,ixn,is,obj))
   420               | Some u => if obj aeconv (red u is []) then env
   421                           else raise MATCH
   422            end
   423        | _ =>
   424            let val (oh,oargs) = strip_comb obj
   425            in case (ph,oh) of
   426                 (Const c,Const d) => rigrig2(c,d,oargs)
   427               | (Free f,Free g)   => rigrig2(f,g,oargs)
   428               | (Bound i,Bound j) => if i<>j then raise MATCH
   429                                      else rigrig1(iTs,oargs)
   430               | (Abs _, _)        => raise Pattern
   431               | (_, Abs _)        => raise Pattern
   432               | _                 => raise MATCH
   433            end
   434     end;
   435 
   436   val pT = fastype_of pat
   437   and oT = fastype_of obj
   438   val iTs = typ_match tsg (Vartab.empty, (pT,oT))
   439   val insts2 = (iTs,[])
   440 
   441 in apfst Vartab.dest (mtch [] (insts2, po)
   442    handle Pattern => fomatch tsg insts2 po)
   443 end;
   444 
   445 (*Predicate: does the pattern match the object?*)
   446 fun matches tsig po = (match tsig po; true) handle MATCH => false;
   447 
   448 (* Does pat match a subterm of obj? *)
   449 fun matches_subterm tsig (pat,obj) =
   450   let fun msub(bounds,obj) = matches tsig (pat,obj) orelse
   451             case obj of
   452               Abs(x,T,t) => let val y = variant bounds x
   453                                 val f = Free(":" ^ y,T)
   454                             in msub(x::bounds,subst_bound(f,t)) end
   455             | s$t => msub(bounds,s) orelse msub(bounds,t)
   456             | _ => false
   457   in msub([],obj) end;
   458 
   459 fun first_order(Abs(_,_,t)) = first_order t
   460   | first_order(t $ u) = first_order t andalso first_order u andalso
   461                          not(is_Var t)
   462   | first_order _ = true;
   463 
   464 fun pattern(Abs(_,_,t)) = pattern t
   465   | pattern(t) = let val (head,args) = strip_comb t
   466                  in if is_Var head
   467                     then let val _ = ints_of args in true end
   468                          handle Pattern => false
   469                     else forall pattern args
   470                  end;
   471 
   472 
   473 (* rewriting -- simple but fast *)
   474 
   475 fun rewrite_term tsig rules procs tm =
   476   let
   477     val skel0 = Bound 0;
   478 
   479     val rhs_names =
   480       foldr (fn ((_, rhs), names) => add_term_free_names (rhs, names)) (rules, []);
   481 
   482     fun variant_absfree (x, T, t) =
   483       let
   484         val x' = variant (add_term_free_names (t, rhs_names)) x;
   485         val t' = subst_bound (Free (x', T), t);
   486       in (fn u => Abs (x, T, abstract_over (Free (x', T), u)), t') end;
   487 
   488     fun match_rew tm (tm1, tm2) =
   489       let val rtm = if_none (Term.rename_abs tm1 tm tm2) tm2
   490       in Some (subst_vars (match tsig (tm1, tm)) rtm, rtm)
   491         handle MATCH => None
   492       end;
   493 
   494     fun rew (Abs (_, _, body) $ t) = Some (subst_bound (t, body), skel0)
   495       | rew tm = (case get_first (match_rew tm) rules of
   496           None => apsome (rpair skel0) (get_first (fn p => p tm) procs)
   497         | x => x);
   498 
   499     fun rew1 (Var _) _ = None
   500       | rew1 skel tm = (case rew2 skel tm of
   501           Some tm1 => (case rew tm1 of
   502               Some (tm2, skel') => Some (if_none (rew1 skel' tm2) tm2)
   503             | None => Some tm1)
   504         | None => (case rew tm of
   505               Some (tm1, skel') => Some (if_none (rew1 skel' tm1) tm1)
   506             | None => None))
   507 
   508     and rew2 skel (tm1 $ tm2) = (case tm1 of
   509             Abs (_, _, body) =>
   510               let val tm' = subst_bound (tm2, body)
   511               in Some (if_none (rew2 skel0 tm') tm') end
   512           | _ =>
   513             let val (skel1, skel2) = (case skel of
   514                 skel1 $ skel2 => (skel1, skel2)
   515               | _ => (skel0, skel0))
   516             in case rew1 skel1 tm1 of
   517                 Some tm1' => (case rew1 skel2 tm2 of
   518                     Some tm2' => Some (tm1' $ tm2')
   519                   | None => Some (tm1' $ tm2))
   520               | None => (case rew1 skel2 tm2 of
   521                     Some tm2' => Some (tm1 $ tm2')
   522                   | None => None)
   523             end)
   524       | rew2 skel (Abs (x, T, tm)) =
   525           let
   526             val (abs, tm') = variant_absfree (x, T, tm);
   527             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   528           in case rew1 skel' tm' of
   529               Some tm'' => Some (abs tm'')
   530             | None => None
   531           end
   532       | rew2 _ _ = None
   533 
   534   in if_none (rew1 skel0 tm) tm end;
   535 
   536 end;
   537 
   538 val trace_unify_fail = Pattern.trace_unify_fail;