src/HOL/List.ML
author nipkow
Wed Jan 26 11:04:38 2000 +0100 (2000-01-26)
changeset 8144 c4b5cbfb90dd
parent 8118 746c5cf09bde
child 8254 84a5fe44520f
permissions -rw-r--r--
optimized xs[i:=x]!j lemmas.
     1 (*  Title:      HOL/List
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4     Copyright   1994 TU Muenchen
     5 
     6 List lemmas
     7 *)
     8 
     9 Goal "!x. xs ~= x#xs";
    10 by (induct_tac "xs" 1);
    11 by Auto_tac;
    12 qed_spec_mp "not_Cons_self";
    13 bind_thm("not_Cons_self2",not_Cons_self RS not_sym);
    14 Addsimps [not_Cons_self,not_Cons_self2];
    15 
    16 Goal "(xs ~= []) = (? y ys. xs = y#ys)";
    17 by (induct_tac "xs" 1);
    18 by Auto_tac;
    19 qed "neq_Nil_conv";
    20 
    21 (* Induction over the length of a list: *)
    22 val [prem] = Goal
    23   "(!!xs. (!ys. length ys < length xs --> P ys) ==> P xs) ==> P(xs)";
    24 by (rtac measure_induct 1 THEN etac prem 1);
    25 qed "length_induct";
    26 
    27 
    28 (** "lists": the list-forming operator over sets **)
    29 
    30 Goalw lists.defs "A<=B ==> lists A <= lists B";
    31 by (rtac lfp_mono 1);
    32 by (REPEAT (ares_tac basic_monos 1));
    33 qed "lists_mono";
    34 
    35 val listsE = lists.mk_cases "x#l : lists A";
    36 AddSEs [listsE];
    37 AddSIs lists.intrs;
    38 
    39 Goal "l: lists A ==> l: lists B --> l: lists (A Int B)";
    40 by (etac lists.induct 1);
    41 by (ALLGOALS Blast_tac);
    42 qed_spec_mp "lists_IntI";
    43 
    44 Goal "lists (A Int B) = lists A Int lists B";
    45 by (rtac (mono_Int RS equalityI) 1);
    46 by (simp_tac (simpset() addsimps [mono_def, lists_mono]) 1);
    47 by (blast_tac (claset() addSIs [lists_IntI]) 1);
    48 qed "lists_Int_eq";
    49 Addsimps [lists_Int_eq];
    50 
    51 
    52 (**  Case analysis **)
    53 section "Case analysis";
    54 
    55 val prems = Goal "[| P([]); !!x xs. P(x#xs) |] ==> P(xs)";
    56 by (induct_tac "xs" 1);
    57 by (REPEAT(resolve_tac prems 1));
    58 qed "list_cases";
    59 
    60 Goal "(xs=[] --> P([])) & (!y ys. xs=y#ys --> P(y#ys)) --> P(xs)";
    61 by (induct_tac "xs" 1);
    62 by (Blast_tac 1);
    63 by (Blast_tac 1);
    64 bind_thm("list_eq_cases",
    65   impI RSN (2,allI RSN (2,allI RSN (2,impI RS (conjI RS (result() RS mp))))));
    66 
    67 (** length **)
    68 (* needs to come before "@" because of thm append_eq_append_conv *)
    69 
    70 section "length";
    71 
    72 Goal "length(xs@ys) = length(xs)+length(ys)";
    73 by (induct_tac "xs" 1);
    74 by Auto_tac;
    75 qed"length_append";
    76 Addsimps [length_append];
    77 
    78 Goal "length (map f xs) = length xs";
    79 by (induct_tac "xs" 1);
    80 by Auto_tac;
    81 qed "length_map";
    82 Addsimps [length_map];
    83 
    84 Goal "length(rev xs) = length(xs)";
    85 by (induct_tac "xs" 1);
    86 by Auto_tac;
    87 qed "length_rev";
    88 Addsimps [length_rev];
    89 
    90 Goal "length(tl xs) = (length xs) - 1";
    91 by (exhaust_tac "xs" 1);
    92 by Auto_tac;
    93 qed "length_tl";
    94 Addsimps [length_tl];
    95 
    96 Goal "(length xs = 0) = (xs = [])";
    97 by (induct_tac "xs" 1);
    98 by Auto_tac;
    99 qed "length_0_conv";
   100 AddIffs [length_0_conv];
   101 
   102 Goal "(0 = length xs) = (xs = [])";
   103 by (induct_tac "xs" 1);
   104 by Auto_tac;
   105 qed "zero_length_conv";
   106 AddIffs [zero_length_conv];
   107 
   108 Goal "(0 < length xs) = (xs ~= [])";
   109 by (induct_tac "xs" 1);
   110 by Auto_tac;
   111 qed "length_greater_0_conv";
   112 AddIffs [length_greater_0_conv];
   113 
   114 Goal "(length xs = Suc n) = (? y ys. xs = y#ys & length ys = n)";
   115 by (induct_tac "xs" 1);
   116 by Auto_tac;
   117 qed "length_Suc_conv";
   118 
   119 (** @ - append **)
   120 
   121 section "@ - append";
   122 
   123 Goal "(xs@ys)@zs = xs@(ys@zs)";
   124 by (induct_tac "xs" 1);
   125 by Auto_tac;
   126 qed "append_assoc";
   127 Addsimps [append_assoc];
   128 
   129 Goal "xs @ [] = xs";
   130 by (induct_tac "xs" 1);
   131 by Auto_tac;
   132 qed "append_Nil2";
   133 Addsimps [append_Nil2];
   134 
   135 Goal "(xs@ys = []) = (xs=[] & ys=[])";
   136 by (induct_tac "xs" 1);
   137 by Auto_tac;
   138 qed "append_is_Nil_conv";
   139 AddIffs [append_is_Nil_conv];
   140 
   141 Goal "([] = xs@ys) = (xs=[] & ys=[])";
   142 by (induct_tac "xs" 1);
   143 by Auto_tac;
   144 qed "Nil_is_append_conv";
   145 AddIffs [Nil_is_append_conv];
   146 
   147 Goal "(xs @ ys = xs) = (ys=[])";
   148 by (induct_tac "xs" 1);
   149 by Auto_tac;
   150 qed "append_self_conv";
   151 
   152 Goal "(xs = xs @ ys) = (ys=[])";
   153 by (induct_tac "xs" 1);
   154 by Auto_tac;
   155 qed "self_append_conv";
   156 AddIffs [append_self_conv,self_append_conv];
   157 
   158 Goal "!ys. length xs = length ys | length us = length vs \
   159 \              --> (xs@us = ys@vs) = (xs=ys & us=vs)";
   160 by (induct_tac "xs" 1);
   161  by (rtac allI 1);
   162  by (exhaust_tac "ys" 1);
   163   by (Asm_simp_tac 1);
   164  by (Force_tac 1);
   165 by (rtac allI 1);
   166 by (exhaust_tac "ys" 1);
   167 by (Force_tac 1);
   168 by (Asm_simp_tac 1);
   169 qed_spec_mp "append_eq_append_conv";
   170 Addsimps [append_eq_append_conv];
   171 
   172 Goal "(xs @ ys = xs @ zs) = (ys=zs)";
   173 by (Simp_tac 1);
   174 qed "same_append_eq";
   175 
   176 Goal "(xs @ [x] = ys @ [y]) = (xs = ys & x = y)"; 
   177 by (Simp_tac 1);
   178 qed "append1_eq_conv";
   179 
   180 Goal "(ys @ xs = zs @ xs) = (ys=zs)";
   181 by (Simp_tac 1);
   182 qed "append_same_eq";
   183 
   184 AddSIs
   185  [same_append_eq RS iffD2, append1_eq_conv RS iffD2, append_same_eq RS iffD2];
   186 AddSDs
   187  [same_append_eq RS iffD1, append1_eq_conv RS iffD1, append_same_eq RS iffD1];
   188 
   189 Goal "(xs @ ys = ys) = (xs=[])";
   190 by (cut_inst_tac [("zs","[]")] append_same_eq 1);
   191 by Auto_tac;
   192 qed "append_self_conv2";
   193 
   194 Goal "(ys = xs @ ys) = (xs=[])";
   195 by (simp_tac (simpset() addsimps
   196      [simplify (simpset()) (read_instantiate[("ys","[]")]append_same_eq)]) 1);
   197 by (Blast_tac 1);
   198 qed "self_append_conv2";
   199 AddIffs [append_self_conv2,self_append_conv2];
   200 
   201 Goal "xs ~= [] --> hd xs # tl xs = xs";
   202 by (induct_tac "xs" 1);
   203 by Auto_tac;
   204 qed_spec_mp "hd_Cons_tl";
   205 Addsimps [hd_Cons_tl];
   206 
   207 Goal "hd(xs@ys) = (if xs=[] then hd ys else hd xs)";
   208 by (induct_tac "xs" 1);
   209 by Auto_tac;
   210 qed "hd_append";
   211 
   212 Goal "xs ~= [] ==> hd(xs @ ys) = hd xs";
   213 by (asm_simp_tac (simpset() addsimps [hd_append]
   214                            addsplits [list.split]) 1);
   215 qed "hd_append2";
   216 Addsimps [hd_append2];
   217 
   218 Goal "tl(xs@ys) = (case xs of [] => tl(ys) | z#zs => zs@ys)";
   219 by (simp_tac (simpset() addsplits [list.split]) 1);
   220 qed "tl_append";
   221 
   222 Goal "xs ~= [] ==> tl(xs @ ys) = (tl xs) @ ys";
   223 by (asm_simp_tac (simpset() addsimps [tl_append]
   224                            addsplits [list.split]) 1);
   225 qed "tl_append2";
   226 Addsimps [tl_append2];
   227 
   228 (* trivial rules for solving @-equations automatically *)
   229 
   230 Goal "xs = ys ==> xs = [] @ ys";
   231 by (Asm_simp_tac 1);
   232 qed "eq_Nil_appendI";
   233 
   234 Goal "[| x#xs1 = ys; xs = xs1 @ zs |] ==> x#xs = ys@zs";
   235 by (dtac sym 1);
   236 by (Asm_simp_tac 1);
   237 qed "Cons_eq_appendI";
   238 
   239 Goal "[| xs@xs1 = zs; ys = xs1 @ us |] ==> xs@ys = zs@us";
   240 by (dtac sym 1);
   241 by (Asm_simp_tac 1);
   242 qed "append_eq_appendI";
   243 
   244 
   245 (***
   246 Simplification procedure for all list equalities.
   247 Currently only tries to rearranges @ to see if
   248 - both lists end in a singleton list,
   249 - or both lists end in the same list.
   250 ***)
   251 local
   252 
   253 val list_eq_pattern =
   254   Thm.read_cterm (Theory.sign_of List.thy) ("(xs::'a list) = ys",HOLogic.boolT);
   255 
   256 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   257       (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   258   | last (Const("List.op @",_) $ _ $ ys) = last ys
   259   | last t = t;
   260 
   261 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   262   | list1 _ = false;
   263 
   264 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   265       (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   266   | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   267   | butlast xs = Const("List.list.Nil",fastype_of xs);
   268 
   269 val rearr_tac =
   270   simp_tac (HOL_basic_ss addsimps [append_assoc,append_Nil,append_Cons]);
   271 
   272 fun list_eq sg _ (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   273   let
   274     val lastl = last lhs and lastr = last rhs
   275     fun rearr conv =
   276       let val lhs1 = butlast lhs and rhs1 = butlast rhs
   277           val Type(_,listT::_) = eqT
   278           val appT = [listT,listT] ---> listT
   279           val app = Const("List.op @",appT)
   280           val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   281           val ct = cterm_of sg (HOLogic.mk_Trueprop(HOLogic.mk_eq(F,F2)))
   282           val thm = prove_goalw_cterm [] ct (K [rearr_tac 1])
   283             handle ERROR =>
   284             error("The error(s) above occurred while trying to prove " ^
   285                   string_of_cterm ct)
   286       in Some((conv RS (thm RS trans)) RS eq_reflection) end
   287 
   288   in if list1 lastl andalso list1 lastr
   289      then rearr append1_eq_conv
   290      else
   291      if lastl aconv lastr
   292      then rearr append_same_eq
   293      else None
   294   end;
   295 in
   296 val list_eq_simproc = mk_simproc "list_eq" [list_eq_pattern] list_eq;
   297 end;
   298 
   299 Addsimprocs [list_eq_simproc];
   300 
   301 
   302 (** map **)
   303 
   304 section "map";
   305 
   306 Goal "(!x. x : set xs --> f x = g x) --> map f xs = map g xs";
   307 by (induct_tac "xs" 1);
   308 by Auto_tac;
   309 bind_thm("map_ext", impI RS (allI RS (result() RS mp)));
   310 
   311 Goal "map (%x. x) = (%xs. xs)";
   312 by (rtac ext 1);
   313 by (induct_tac "xs" 1);
   314 by Auto_tac;
   315 qed "map_ident";
   316 Addsimps[map_ident];
   317 
   318 Goal "map f (xs@ys) = map f xs @ map f ys";
   319 by (induct_tac "xs" 1);
   320 by Auto_tac;
   321 qed "map_append";
   322 Addsimps[map_append];
   323 
   324 Goalw [o_def] "map (f o g) xs = map f (map g xs)";
   325 by (induct_tac "xs" 1);
   326 by Auto_tac;
   327 qed "map_compose";
   328 Addsimps[map_compose];
   329 
   330 Goal "rev(map f xs) = map f (rev xs)";
   331 by (induct_tac "xs" 1);
   332 by Auto_tac;
   333 qed "rev_map";
   334 
   335 (* a congruence rule for map: *)
   336 Goal "xs=ys ==> (!x. x : set ys --> f x = g x) --> map f xs = map g ys";
   337 by (hyp_subst_tac 1);
   338 by (induct_tac "ys" 1);
   339 by Auto_tac;
   340 bind_thm("map_cong", impI RSN (2,allI RSN (2, result() RS mp)));
   341 
   342 Goal "(map f xs = []) = (xs = [])";
   343 by (exhaust_tac "xs" 1);
   344 by Auto_tac;
   345 qed "map_is_Nil_conv";
   346 AddIffs [map_is_Nil_conv];
   347 
   348 Goal "([] = map f xs) = (xs = [])";
   349 by (exhaust_tac "xs" 1);
   350 by Auto_tac;
   351 qed "Nil_is_map_conv";
   352 AddIffs [Nil_is_map_conv];
   353 
   354 Goal "(map f xs = y#ys) = (? x xs'. xs = x#xs' & f x = y & map f xs' = ys)";
   355 by (exhaust_tac "xs" 1);
   356 by (ALLGOALS Asm_simp_tac);
   357 qed "map_eq_Cons";
   358 
   359 Goal "!xs. map f xs = map f ys --> (!x y. f x = f y --> x=y) --> xs=ys";
   360 by (induct_tac "ys" 1);
   361  by (Asm_simp_tac 1);
   362 by (fast_tac (claset() addss (simpset() addsimps [map_eq_Cons])) 1);
   363 qed_spec_mp "map_injective";
   364 
   365 Goal "inj f ==> inj (map f)";
   366 by (blast_tac (claset() addDs [map_injective,injD] addIs [injI]) 1);
   367 qed "inj_mapI";
   368 
   369 Goalw [inj_on_def] "inj (map f) ==> inj f";
   370 by (Clarify_tac 1);
   371 by (eres_inst_tac [("x","[x]")] ballE 1);
   372  by (eres_inst_tac [("x","[y]")] ballE 1);
   373   by (Asm_full_simp_tac 1);
   374  by (Blast_tac 1);
   375 by (Blast_tac 1);
   376 qed "inj_mapD";
   377 
   378 Goal "inj (map f) = inj f";
   379 by (blast_tac (claset() addDs [inj_mapD] addIs [inj_mapI]) 1);
   380 qed "inj_map";
   381 
   382 (** rev **)
   383 
   384 section "rev";
   385 
   386 Goal "rev(xs@ys) = rev(ys) @ rev(xs)";
   387 by (induct_tac "xs" 1);
   388 by Auto_tac;
   389 qed "rev_append";
   390 Addsimps[rev_append];
   391 
   392 Goal "rev(rev l) = l";
   393 by (induct_tac "l" 1);
   394 by Auto_tac;
   395 qed "rev_rev_ident";
   396 Addsimps[rev_rev_ident];
   397 
   398 Goal "(rev xs = []) = (xs = [])";
   399 by (induct_tac "xs" 1);
   400 by Auto_tac;
   401 qed "rev_is_Nil_conv";
   402 AddIffs [rev_is_Nil_conv];
   403 
   404 Goal "([] = rev xs) = (xs = [])";
   405 by (induct_tac "xs" 1);
   406 by Auto_tac;
   407 qed "Nil_is_rev_conv";
   408 AddIffs [Nil_is_rev_conv];
   409 
   410 Goal "!ys. (rev xs = rev ys) = (xs = ys)";
   411 by (induct_tac "xs" 1);
   412  by (Force_tac 1);
   413 by (rtac allI 1);
   414 by (exhaust_tac "ys" 1);
   415  by (Asm_simp_tac 1);
   416 by (Force_tac 1);
   417 qed_spec_mp "rev_is_rev_conv";
   418 AddIffs [rev_is_rev_conv];
   419 
   420 val prems = Goal "[| P []; !!x xs. P xs ==> P(xs@[x]) |] ==> P xs";
   421 by (stac (rev_rev_ident RS sym) 1);
   422 by (res_inst_tac [("list", "rev xs")] list.induct 1);
   423 by (ALLGOALS Simp_tac);
   424 by (resolve_tac prems 1);
   425 by (eresolve_tac prems 1);
   426 qed "rev_induct";
   427 
   428 fun rev_induct_tac xs = res_inst_tac [("xs",xs)] rev_induct;
   429 
   430 Goal  "(xs = [] --> P) -->  (!ys y. xs = ys@[y] --> P) --> P";
   431 by (res_inst_tac [("xs","xs")] rev_induct 1);
   432 by Auto_tac;
   433 bind_thm ("rev_exhaust",
   434   impI RSN (2,allI RSN (2,allI RSN (2,impI RS (result() RS mp RS mp)))));
   435 
   436 
   437 (** set **)
   438 
   439 section "set";
   440 
   441 Goal "finite (set xs)";
   442 by (induct_tac "xs" 1);
   443 by Auto_tac;
   444 qed "finite_set";
   445 AddIffs [finite_set];
   446 
   447 Goal "set (xs@ys) = (set xs Un set ys)";
   448 by (induct_tac "xs" 1);
   449 by Auto_tac;
   450 qed "set_append";
   451 Addsimps[set_append];
   452 
   453 Goal "set l <= set (x#l)";
   454 by Auto_tac;
   455 qed "set_subset_Cons";
   456 
   457 Goal "(set xs = {}) = (xs = [])";
   458 by (induct_tac "xs" 1);
   459 by Auto_tac;
   460 qed "set_empty";
   461 Addsimps [set_empty];
   462 
   463 Goal "set(rev xs) = set(xs)";
   464 by (induct_tac "xs" 1);
   465 by Auto_tac;
   466 qed "set_rev";
   467 Addsimps [set_rev];
   468 
   469 Goal "set(map f xs) = f``(set xs)";
   470 by (induct_tac "xs" 1);
   471 by Auto_tac;
   472 qed "set_map";
   473 Addsimps [set_map];
   474 
   475 Goal "set(filter P xs) = {x. x : set xs & P x}";
   476 by (induct_tac "xs" 1);
   477 by Auto_tac;
   478 qed "set_filter";
   479 Addsimps [set_filter];
   480 
   481 Goal "set[i..j(] = {k. i <= k & k < j}";
   482 by (induct_tac "j" 1);
   483 by Auto_tac;
   484 by (arith_tac 1);
   485 qed "set_upt";
   486 Addsimps [set_upt];
   487 
   488 Goal "!i < size xs. set(xs[i := x]) <= insert x (set xs)";
   489 by (induct_tac "xs" 1);
   490  by (Simp_tac 1);
   491 by (asm_simp_tac (simpset() addsplits [nat.split]) 1);
   492 by (Blast_tac 1);
   493 qed_spec_mp "set_list_update_subset";
   494 
   495 Goal "(x : set xs) = (? ys zs. xs = ys@x#zs)";
   496 by (induct_tac "xs" 1);
   497  by (Simp_tac 1);
   498 by (Asm_simp_tac 1);
   499 by (rtac iffI 1);
   500 by (blast_tac (claset() addIs [eq_Nil_appendI,Cons_eq_appendI]) 1);
   501 by (REPEAT(etac exE 1));
   502 by (exhaust_tac "ys" 1);
   503 by Auto_tac;
   504 qed "in_set_conv_decomp";
   505 
   506 
   507 (* eliminate `lists' in favour of `set' *)
   508 
   509 Goal "(xs : lists A) = (!x : set xs. x : A)";
   510 by (induct_tac "xs" 1);
   511 by Auto_tac;
   512 qed "in_lists_conv_set";
   513 
   514 bind_thm("in_listsD",in_lists_conv_set RS iffD1);
   515 AddSDs [in_listsD];
   516 bind_thm("in_listsI",in_lists_conv_set RS iffD2);
   517 AddSIs [in_listsI];
   518 
   519 (** mem **)
   520  
   521 section "mem";
   522 
   523 Goal "(x mem xs) = (x: set xs)";
   524 by (induct_tac "xs" 1);
   525 by Auto_tac;
   526 qed "set_mem_eq";
   527 
   528 
   529 (** list_all **)
   530 
   531 section "list_all";
   532 
   533 Goal "list_all P xs = (!x:set xs. P x)";
   534 by (induct_tac "xs" 1);
   535 by Auto_tac;
   536 qed "list_all_conv";
   537 
   538 Goal "list_all P (xs@ys) = (list_all P xs & list_all P ys)";
   539 by (induct_tac "xs" 1);
   540 by Auto_tac;
   541 qed "list_all_append";
   542 Addsimps [list_all_append];
   543 
   544 
   545 (** filter **)
   546 
   547 section "filter";
   548 
   549 Goal "filter P (xs@ys) = filter P xs @ filter P ys";
   550 by (induct_tac "xs" 1);
   551 by Auto_tac;
   552 qed "filter_append";
   553 Addsimps [filter_append];
   554 
   555 Goal "filter (%x. True) xs = xs";
   556 by (induct_tac "xs" 1);
   557 by Auto_tac;
   558 qed "filter_True";
   559 Addsimps [filter_True];
   560 
   561 Goal "filter (%x. False) xs = []";
   562 by (induct_tac "xs" 1);
   563 by Auto_tac;
   564 qed "filter_False";
   565 Addsimps [filter_False];
   566 
   567 Goal "length (filter P xs) <= length xs";
   568 by (induct_tac "xs" 1);
   569 by Auto_tac;
   570 qed "length_filter";
   571 Addsimps[length_filter];
   572 
   573 Goal "set (filter P xs) <= set xs";
   574 by Auto_tac;
   575 qed "filter_is_subset";
   576 Addsimps [filter_is_subset];
   577 
   578 
   579 section "concat";
   580 
   581 Goal  "concat(xs@ys) = concat(xs)@concat(ys)";
   582 by (induct_tac "xs" 1);
   583 by Auto_tac;
   584 qed"concat_append";
   585 Addsimps [concat_append];
   586 
   587 Goal "(concat xss = []) = (!xs:set xss. xs=[])";
   588 by (induct_tac "xss" 1);
   589 by Auto_tac;
   590 qed "concat_eq_Nil_conv";
   591 AddIffs [concat_eq_Nil_conv];
   592 
   593 Goal "([] = concat xss) = (!xs:set xss. xs=[])";
   594 by (induct_tac "xss" 1);
   595 by Auto_tac;
   596 qed "Nil_eq_concat_conv";
   597 AddIffs [Nil_eq_concat_conv];
   598 
   599 Goal  "set(concat xs) = Union(set `` set xs)";
   600 by (induct_tac "xs" 1);
   601 by Auto_tac;
   602 qed"set_concat";
   603 Addsimps [set_concat];
   604 
   605 Goal "map f (concat xs) = concat (map (map f) xs)"; 
   606 by (induct_tac "xs" 1);
   607 by Auto_tac;
   608 qed "map_concat";
   609 
   610 Goal "filter p (concat xs) = concat (map (filter p) xs)"; 
   611 by (induct_tac "xs" 1);
   612 by Auto_tac;
   613 qed"filter_concat"; 
   614 
   615 Goal "rev(concat xs) = concat (map rev (rev xs))";
   616 by (induct_tac "xs" 1);
   617 by Auto_tac;
   618 qed "rev_concat";
   619 
   620 (** nth **)
   621 
   622 section "nth";
   623 
   624 Goal "(x#xs)!0 = x";
   625 by Auto_tac;
   626 qed "nth_Cons_0";
   627 Addsimps [nth_Cons_0];
   628 
   629 Goal "(x#xs)!(Suc n) = xs!n";
   630 by Auto_tac;
   631 qed "nth_Cons_Suc";
   632 Addsimps [nth_Cons_Suc];
   633 
   634 Delsimps (thms "nth.simps");
   635 
   636 Goal "!n. (xs@ys)!n = (if n < length xs then xs!n else ys!(n - length xs))";
   637 by (induct_tac "xs" 1);
   638  by (Asm_simp_tac 1);
   639  by (rtac allI 1);
   640  by (exhaust_tac "n" 1);
   641   by Auto_tac;
   642 qed_spec_mp "nth_append";
   643 
   644 Goal "!n. n < length xs --> (map f xs)!n = f(xs!n)";
   645 by (induct_tac "xs" 1);
   646  by (Asm_full_simp_tac 1);
   647 by (rtac allI 1);
   648 by (induct_tac "n" 1);
   649 by Auto_tac;
   650 qed_spec_mp "nth_map";
   651 Addsimps [nth_map];
   652 
   653 Goal "set xs = {xs!i |i. i < length xs}";
   654 by (induct_tac "xs" 1);
   655  by (Simp_tac 1);
   656 by(Asm_simp_tac 1);
   657 by(Safe_tac);
   658   by(res_inst_tac [("x","0")] exI 1);
   659   by (Simp_tac 1);
   660  by(res_inst_tac [("x","Suc i")] exI 1);
   661  by(Asm_simp_tac 1);
   662 by(exhaust_tac "i" 1);
   663  by(Asm_full_simp_tac 1);
   664 by(rename_tac "j" 1);
   665  by(res_inst_tac [("x","j")] exI 1);
   666 by(Asm_simp_tac 1);
   667 qed "set_conv_nth";
   668 
   669 Goal "n < length xs ==> Ball (set xs) P --> P(xs!n)";
   670 by (simp_tac (simpset() addsimps [set_conv_nth]) 1);
   671 by(Blast_tac 1);
   672 qed_spec_mp "list_ball_nth";
   673 
   674 Goal "n < length xs ==> xs!n : set xs";
   675 by (simp_tac (simpset() addsimps [set_conv_nth]) 1);
   676 by(Blast_tac 1);
   677 qed_spec_mp "nth_mem";
   678 Addsimps [nth_mem];
   679 
   680 Goal "(!i. i < length xs --> P(xs!i)) --> (!x : set xs. P x)";
   681 by (simp_tac (simpset() addsimps [set_conv_nth]) 1);
   682 by(Blast_tac 1);
   683 qed_spec_mp "all_nth_imp_all_set";
   684 
   685 Goal "(!x : set xs. P x) = (!i. i<length xs --> P (xs ! i))";
   686 by (simp_tac (simpset() addsimps [set_conv_nth]) 1);
   687 by(Blast_tac 1);
   688 qed_spec_mp "all_set_conv_all_nth";
   689 
   690 
   691 (** list update **)
   692 
   693 section "list update";
   694 
   695 Goal "!i. length(xs[i:=x]) = length xs";
   696 by (induct_tac "xs" 1);
   697 by (Simp_tac 1);
   698 by (asm_full_simp_tac (simpset() addsplits [nat.split]) 1);
   699 qed_spec_mp "length_list_update";
   700 Addsimps [length_list_update];
   701 
   702 Goal "!i j. i < length xs  --> (xs[i:=x])!j = (if i=j then x else xs!j)";
   703 by (induct_tac "xs" 1);
   704  by (Simp_tac 1);
   705 by (auto_tac (claset(), simpset() addsimps [nth_Cons] addsplits [nat.split]));
   706 qed_spec_mp "nth_list_update";
   707 
   708 Goal "i < length xs  ==> (xs[i:=x])!i = x";
   709 by (asm_simp_tac (simpset() addsimps [nth_list_update]) 1);
   710 qed "nth_list_update_eq";
   711 Addsimps [nth_list_update_eq];
   712 
   713 Goal "!i j. i ~= j --> xs[i:=x]!j = xs!j";
   714 by (induct_tac "xs" 1);
   715  by (Simp_tac 1);
   716 by (auto_tac (claset(), simpset() addsimps [nth_Cons] addsplits [nat.split]));
   717 qed_spec_mp "nth_list_update_neq";
   718 Addsimps [nth_list_update_neq];
   719 
   720 Goal "!i. i < size xs --> xs[i:=x, i:=y] = xs[i:=y]";
   721 by (induct_tac "xs" 1);
   722  by (Simp_tac 1);
   723 by (asm_simp_tac (simpset() addsplits [nat.split]) 1);
   724 qed_spec_mp "list_update_overwrite";
   725 Addsimps [list_update_overwrite];
   726 
   727 Goal "!i < length xs. (xs[i := x] = xs) = (xs!i = x)";
   728 by (induct_tac "xs" 1);
   729  by (Simp_tac 1);
   730 by (simp_tac (simpset() addsplits [nat.split]) 1);
   731 by (Blast_tac 1);
   732 qed_spec_mp "list_update_same_conv";
   733 
   734 Goal "!i xy xs. length xs = length ys --> \
   735 \     (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])";
   736 by (induct_tac "ys" 1);
   737  by Auto_tac;
   738 by (exhaust_tac "xs" 1);
   739  by (auto_tac (claset(), simpset() addsplits [nat.split]));
   740 qed_spec_mp "update_zip";
   741 
   742 Goal "!i. set(xs[i:=x]) <= insert x (set xs)";
   743 by (induct_tac "xs" 1);
   744  by (asm_full_simp_tac (simpset() addsimps []) 1);
   745 by (asm_full_simp_tac (simpset() addsplits [nat.split]) 1);
   746 by (Fast_tac  1);
   747 qed_spec_mp "set_update_subset";
   748 
   749 
   750 (** last & butlast **)
   751 
   752 section "last / butlast";
   753 
   754 Goal "last(xs@[x]) = x";
   755 by (induct_tac "xs" 1);
   756 by Auto_tac;
   757 qed "last_snoc";
   758 Addsimps [last_snoc];
   759 
   760 Goal "butlast(xs@[x]) = xs";
   761 by (induct_tac "xs" 1);
   762 by Auto_tac;
   763 qed "butlast_snoc";
   764 Addsimps [butlast_snoc];
   765 
   766 Goal "length(butlast xs) = length xs - 1";
   767 by (res_inst_tac [("xs","xs")] rev_induct 1);
   768 by Auto_tac;
   769 qed "length_butlast";
   770 Addsimps [length_butlast];
   771 
   772 Goal "!ys. butlast (xs@ys) = (if ys=[] then butlast xs else xs@butlast ys)";
   773 by (induct_tac "xs" 1);
   774 by Auto_tac;
   775 qed_spec_mp "butlast_append";
   776 
   777 Goal "xs ~= [] --> butlast xs @ [last xs] = xs";
   778 by(induct_tac "xs" 1);
   779 by(ALLGOALS Asm_simp_tac);
   780 qed_spec_mp "append_butlast_last_id";
   781 Addsimps [append_butlast_last_id];
   782 
   783 Goal "x:set(butlast xs) --> x:set xs";
   784 by (induct_tac "xs" 1);
   785 by Auto_tac;
   786 qed_spec_mp "in_set_butlastD";
   787 
   788 Goal "x:set(butlast xs) | x:set(butlast ys) ==> x:set(butlast(xs@ys))";
   789 by (auto_tac (claset() addDs [in_set_butlastD],
   790 	      simpset() addsimps [butlast_append]));
   791 qed "in_set_butlast_appendI";
   792 
   793 (** take  & drop **)
   794 section "take & drop";
   795 
   796 Goal "take 0 xs = []";
   797 by (induct_tac "xs" 1);
   798 by Auto_tac;
   799 qed "take_0";
   800 
   801 Goal "drop 0 xs = xs";
   802 by (induct_tac "xs" 1);
   803 by Auto_tac;
   804 qed "drop_0";
   805 
   806 Goal "take (Suc n) (x#xs) = x # take n xs";
   807 by (Simp_tac 1);
   808 qed "take_Suc_Cons";
   809 
   810 Goal "drop (Suc n) (x#xs) = drop n xs";
   811 by (Simp_tac 1);
   812 qed "drop_Suc_Cons";
   813 
   814 Delsimps [take_Cons,drop_Cons];
   815 Addsimps [take_0,take_Suc_Cons,drop_0,drop_Suc_Cons];
   816 
   817 Goal "!xs. length(take n xs) = min (length xs) n";
   818 by (induct_tac "n" 1);
   819  by Auto_tac;
   820 by (exhaust_tac "xs" 1);
   821  by Auto_tac;
   822 qed_spec_mp "length_take";
   823 Addsimps [length_take];
   824 
   825 Goal "!xs. length(drop n xs) = (length xs - n)";
   826 by (induct_tac "n" 1);
   827  by Auto_tac;
   828 by (exhaust_tac "xs" 1);
   829  by Auto_tac;
   830 qed_spec_mp "length_drop";
   831 Addsimps [length_drop];
   832 
   833 Goal "!xs. length xs <= n --> take n xs = xs";
   834 by (induct_tac "n" 1);
   835  by Auto_tac;
   836 by (exhaust_tac "xs" 1);
   837  by Auto_tac;
   838 qed_spec_mp "take_all";
   839 Addsimps [take_all];
   840 
   841 Goal "!xs. length xs <= n --> drop n xs = []";
   842 by (induct_tac "n" 1);
   843  by Auto_tac;
   844 by (exhaust_tac "xs" 1);
   845  by Auto_tac;
   846 qed_spec_mp "drop_all";
   847 Addsimps [drop_all];
   848 
   849 Goal "!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)";
   850 by (induct_tac "n" 1);
   851  by Auto_tac;
   852 by (exhaust_tac "xs" 1);
   853  by Auto_tac;
   854 qed_spec_mp "take_append";
   855 Addsimps [take_append];
   856 
   857 Goal "!xs. drop n (xs@ys) = drop n xs @ drop (n - length xs) ys"; 
   858 by (induct_tac "n" 1);
   859  by Auto_tac;
   860 by (exhaust_tac "xs" 1);
   861  by Auto_tac;
   862 qed_spec_mp "drop_append";
   863 Addsimps [drop_append];
   864 
   865 Goal "!xs n. take n (take m xs) = take (min n m) xs"; 
   866 by (induct_tac "m" 1);
   867  by Auto_tac;
   868 by (exhaust_tac "xs" 1);
   869  by Auto_tac;
   870 by (exhaust_tac "na" 1);
   871  by Auto_tac;
   872 qed_spec_mp "take_take";
   873 Addsimps [take_take];
   874 
   875 Goal "!xs. drop n (drop m xs) = drop (n + m) xs"; 
   876 by (induct_tac "m" 1);
   877  by Auto_tac;
   878 by (exhaust_tac "xs" 1);
   879  by Auto_tac;
   880 qed_spec_mp "drop_drop";
   881 Addsimps [drop_drop];
   882 
   883 Goal "!xs n. take n (drop m xs) = drop m (take (n + m) xs)"; 
   884 by (induct_tac "m" 1);
   885  by Auto_tac;
   886 by (exhaust_tac "xs" 1);
   887  by Auto_tac;
   888 qed_spec_mp "take_drop";
   889 
   890 Goal "!xs. take n xs @ drop n xs = xs";
   891 by (induct_tac "n" 1);
   892  by Auto_tac;
   893 by (exhaust_tac "xs" 1);
   894  by Auto_tac;
   895 qed_spec_mp "append_take_drop_id";
   896 Addsimps [append_take_drop_id];
   897 
   898 Goal "!xs. take n (map f xs) = map f (take n xs)"; 
   899 by (induct_tac "n" 1);
   900  by Auto_tac;
   901 by (exhaust_tac "xs" 1);
   902  by Auto_tac;
   903 qed_spec_mp "take_map"; 
   904 
   905 Goal "!xs. drop n (map f xs) = map f (drop n xs)"; 
   906 by (induct_tac "n" 1);
   907  by Auto_tac;
   908 by (exhaust_tac "xs" 1);
   909  by Auto_tac;
   910 qed_spec_mp "drop_map";
   911 
   912 Goal "!n i. i < n --> (take n xs)!i = xs!i";
   913 by (induct_tac "xs" 1);
   914  by Auto_tac;
   915 by (exhaust_tac "n" 1);
   916  by (Blast_tac 1);
   917 by (exhaust_tac "i" 1);
   918  by Auto_tac;
   919 qed_spec_mp "nth_take";
   920 Addsimps [nth_take];
   921 
   922 Goal  "!xs i. n + i <= length xs --> (drop n xs)!i = xs!(n+i)";
   923 by (induct_tac "n" 1);
   924  by Auto_tac;
   925 by (exhaust_tac "xs" 1);
   926  by Auto_tac;
   927 qed_spec_mp "nth_drop";
   928 Addsimps [nth_drop];
   929 
   930 
   931 Goal
   932  "!zs. (xs@ys = zs) = (xs = take (length xs) zs & ys = drop (length xs) zs)";
   933 by(induct_tac "xs" 1);
   934  by(Simp_tac 1);
   935 by(Asm_full_simp_tac 1);
   936 by(Clarify_tac 1);
   937 by(exhaust_tac "zs" 1);
   938 by(Auto_tac);
   939 qed_spec_mp "append_eq_conv_conj";
   940 
   941 (** takeWhile & dropWhile **)
   942 
   943 section "takeWhile & dropWhile";
   944 
   945 Goal "takeWhile P xs @ dropWhile P xs = xs";
   946 by (induct_tac "xs" 1);
   947 by Auto_tac;
   948 qed "takeWhile_dropWhile_id";
   949 Addsimps [takeWhile_dropWhile_id];
   950 
   951 Goal  "x:set xs & ~P(x) --> takeWhile P (xs @ ys) = takeWhile P xs";
   952 by (induct_tac "xs" 1);
   953 by Auto_tac;
   954 bind_thm("takeWhile_append1", conjI RS (result() RS mp));
   955 Addsimps [takeWhile_append1];
   956 
   957 Goal "(!x:set xs. P(x)) --> takeWhile P (xs @ ys) = xs @ takeWhile P ys";
   958 by (induct_tac "xs" 1);
   959 by Auto_tac;
   960 bind_thm("takeWhile_append2", ballI RS (result() RS mp));
   961 Addsimps [takeWhile_append2];
   962 
   963 Goal "x:set xs & ~P(x) --> dropWhile P (xs @ ys) = (dropWhile P xs)@ys";
   964 by (induct_tac "xs" 1);
   965 by Auto_tac;
   966 bind_thm("dropWhile_append1", conjI RS (result() RS mp));
   967 Addsimps [dropWhile_append1];
   968 
   969 Goal "(!x:set xs. P(x)) --> dropWhile P (xs @ ys) = dropWhile P ys";
   970 by (induct_tac "xs" 1);
   971 by Auto_tac;
   972 bind_thm("dropWhile_append2", ballI RS (result() RS mp));
   973 Addsimps [dropWhile_append2];
   974 
   975 Goal "x:set(takeWhile P xs) --> x:set xs & P x";
   976 by (induct_tac "xs" 1);
   977 by Auto_tac;
   978 qed_spec_mp"set_take_whileD";
   979 
   980 (** zip **)
   981 section "zip";
   982 
   983 Goal "zip [] ys = []";
   984 by (induct_tac "ys" 1);
   985 by Auto_tac;
   986 qed "zip_Nil";
   987 Addsimps [zip_Nil];
   988 
   989 Goal "zip (x#xs) (y#ys) = (x,y)#zip xs ys";
   990 by (Simp_tac 1);
   991 qed "zip_Cons_Cons";
   992 Addsimps [zip_Cons_Cons];
   993 
   994 Delsimps(tl (thms"zip.simps"));
   995 
   996 Goal "!xs. length (zip xs ys) = min (length xs) (length ys)";
   997 by (induct_tac "ys" 1);
   998  by (Simp_tac 1);
   999 by (Clarify_tac 1);
  1000 by (exhaust_tac "xs" 1);
  1001  by (Auto_tac);
  1002 qed_spec_mp "length_zip";
  1003 Addsimps [length_zip];
  1004 
  1005 Goal
  1006  "!xs. zip (xs@ys) zs = \
  1007 \      zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)";
  1008 by(induct_tac "zs" 1);
  1009  by(Simp_tac 1);
  1010 by (Clarify_tac 1);
  1011 by(exhaust_tac "xs" 1);
  1012  by(Asm_simp_tac 1);
  1013 by(Asm_simp_tac 1);
  1014 qed_spec_mp "zip_append1";
  1015 
  1016 Goal
  1017  "!ys. zip xs (ys@zs) = \
  1018 \      zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs";
  1019 by(induct_tac "xs" 1);
  1020  by(Simp_tac 1);
  1021 by (Clarify_tac 1);
  1022 by(exhaust_tac "ys" 1);
  1023  by(Asm_simp_tac 1);
  1024 by(Asm_simp_tac 1);
  1025 qed_spec_mp "zip_append2";
  1026 
  1027 Goal
  1028  "[| length xs = length us; length ys = length vs |] ==> \
  1029 \ zip (xs@ys) (us@vs) = zip xs us @ zip ys vs";
  1030 by(asm_simp_tac (simpset() addsimps [zip_append1]) 1);
  1031 qed_spec_mp "zip_append";
  1032 Addsimps [zip_append];
  1033 
  1034 Goal "!xs. length xs = length ys --> zip (rev xs) (rev ys) = rev (zip xs ys)";
  1035 by (induct_tac "ys" 1);
  1036  by (Asm_full_simp_tac 1);
  1037 by (Asm_full_simp_tac 1);
  1038 by (Clarify_tac 1);
  1039 by (exhaust_tac "xs" 1);
  1040  by (Auto_tac);
  1041 qed_spec_mp "zip_rev";
  1042 
  1043 
  1044 Goal
  1045 "!i xs. i < length xs --> i < length ys --> (zip xs ys)!i = (xs!i, ys!i)";
  1046 by (induct_tac "ys" 1);
  1047  by (Simp_tac 1);
  1048 by (Clarify_tac 1);
  1049 by (exhaust_tac "xs" 1);
  1050  by (Auto_tac);
  1051 by (asm_full_simp_tac (simpset() addsimps (thms"nth.simps") addsplits [nat.split]) 1);
  1052 qed_spec_mp "nth_zip";
  1053 Addsimps [nth_zip];
  1054 
  1055 Goal "set(zip xs ys) = {(xs!i,ys!i) |i. i < min (length xs) (length ys)}";
  1056 by (simp_tac (simpset() addsimps [set_conv_nth]addcongs [rev_conj_cong]) 1);
  1057 qed_spec_mp "set_zip";
  1058 
  1059 Goal
  1060  "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]";
  1061 by (rtac sym 1);
  1062 by (asm_simp_tac (simpset() addsimps [update_zip]) 1);
  1063 qed_spec_mp "zip_update";
  1064 
  1065 Goal "!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)";
  1066 by (induct_tac "i" 1);
  1067  by (Auto_tac);
  1068 by (exhaust_tac "j" 1);
  1069  by (Auto_tac);
  1070 qed "zip_replicate";
  1071 Addsimps [zip_replicate];
  1072 
  1073 (** list_all2 **)
  1074 section "list_all2";
  1075 
  1076 Goalw [list_all2_def] "list_all2 P xs ys ==> length xs = length ys";
  1077 by(Asm_simp_tac 1);
  1078 qed "list_all2_lengthD";
  1079 
  1080 Goalw [list_all2_def] "list_all2 P [] ys = (ys=[])";
  1081 by (Simp_tac 1);
  1082 qed "list_all2_Nil";
  1083 AddIffs [list_all2_Nil];
  1084 
  1085 Goalw [list_all2_def] "list_all2 P xs [] = (xs=[])";
  1086 by (Simp_tac 1);
  1087 qed "list_all2_Nil2";
  1088 AddIffs [list_all2_Nil2];
  1089 
  1090 Goalw [list_all2_def]
  1091  "list_all2 P (x#xs) (y#ys) = (P x y & list_all2 P xs ys)";
  1092 by (Auto_tac);
  1093 qed "list_all2_Cons";
  1094 AddIffs[list_all2_Cons];
  1095 
  1096 Goalw [list_all2_def]
  1097  "list_all2 P (x#xs) ys = (? z zs. ys = z#zs & P x z & list_all2 P xs zs)";
  1098 by(exhaust_tac "ys" 1);
  1099 by(Auto_tac);
  1100 qed "list_all2_Cons1";
  1101 
  1102 Goalw [list_all2_def]
  1103  "list_all2 P xs (y#ys) = (? z zs. xs = z#zs & P z y & list_all2 P zs ys)";
  1104 by(exhaust_tac "xs" 1);
  1105 by(Auto_tac);
  1106 qed "list_all2_Cons2";
  1107 
  1108 Goalw [list_all2_def]
  1109  "list_all2 P (xs@ys) zs = \
  1110 \ (EX us vs. zs = us@vs & length us = length xs & length vs = length ys & \
  1111 \            list_all2 P xs us & list_all2 P ys vs)";
  1112 by(simp_tac (simpset() addsimps [zip_append1]) 1);
  1113 br iffI 1;
  1114  by(res_inst_tac [("x","take (length xs) zs")] exI 1);
  1115  by(res_inst_tac [("x","drop (length xs) zs")] exI 1);
  1116  by(asm_full_simp_tac (simpset() addsimps [min_def,eq_sym_conv]) 1);
  1117 by (Clarify_tac 1);
  1118 by(asm_full_simp_tac (simpset() addsimps [ball_Un]) 1);
  1119 qed "list_all2_append1";
  1120 
  1121 Goalw [list_all2_def]
  1122  "list_all2 P xs (ys@zs) = \
  1123 \ (EX us vs. xs = us@vs & length us = length ys & length vs = length zs & \
  1124 \            list_all2 P us ys & list_all2 P vs zs)";
  1125 by(simp_tac (simpset() addsimps [zip_append2]) 1);
  1126 br iffI 1;
  1127  by(res_inst_tac [("x","take (length ys) xs")] exI 1);
  1128  by(res_inst_tac [("x","drop (length ys) xs")] exI 1);
  1129  by(asm_full_simp_tac (simpset() addsimps [min_def,eq_sym_conv]) 1);
  1130 by (Clarify_tac 1);
  1131 by(asm_full_simp_tac (simpset() addsimps [ball_Un]) 1);
  1132 qed "list_all2_append2";
  1133 
  1134 Goalw [list_all2_def]
  1135   "list_all2 P xs ys = \
  1136 \  (length xs = length ys & (!i<length xs. P (xs!i) (ys!i)))";
  1137 by(force_tac (claset(), simpset() addsimps [set_zip]) 1);
  1138 qed "list_all2_conv_all_nth";
  1139 
  1140 (** foldl **)
  1141 section "foldl";
  1142 
  1143 Goal "!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys";
  1144 by (induct_tac "xs" 1);
  1145 by Auto_tac;
  1146 qed_spec_mp "foldl_append";
  1147 Addsimps [foldl_append];
  1148 
  1149 (* Note: `n <= foldl op+ n ns' looks simpler, but is more difficult to use
  1150    because it requires an additional transitivity step
  1151 *)
  1152 Goal "!n::nat. m <= n --> m <= foldl op+ n ns";
  1153 by (induct_tac "ns" 1);
  1154 by Auto_tac;
  1155 qed_spec_mp "start_le_sum";
  1156 
  1157 Goal "n : set ns ==> n <= foldl op+ 0 ns";
  1158 by (force_tac (claset() addIs [start_le_sum],
  1159               simpset() addsimps [in_set_conv_decomp]) 1);
  1160 qed "elem_le_sum";
  1161 
  1162 Goal "!m. (foldl op+ m ns = 0) = (m=0 & (!n : set ns. n=0))";
  1163 by (induct_tac "ns" 1);
  1164 by Auto_tac;
  1165 qed_spec_mp "sum_eq_0_conv";
  1166 AddIffs [sum_eq_0_conv];
  1167 
  1168 (** upto **)
  1169 
  1170 (* Does not terminate! *)
  1171 Goal "[i..j(] = (if i<j then i#[Suc i..j(] else [])";
  1172 by (induct_tac "j" 1);
  1173 by Auto_tac;
  1174 qed "upt_rec";
  1175 
  1176 Goal "j<=i ==> [i..j(] = []";
  1177 by (stac upt_rec 1);
  1178 by (Asm_simp_tac 1);
  1179 qed "upt_conv_Nil";
  1180 Addsimps [upt_conv_Nil];
  1181 
  1182 Goal "i<=j ==> [i..(Suc j)(] = [i..j(]@[j]";
  1183 by (Asm_simp_tac 1);
  1184 qed "upt_Suc";
  1185 
  1186 Goal "i<j ==> [i..j(] = i#[Suc i..j(]";
  1187 by (rtac trans 1);
  1188 by (stac upt_rec 1);
  1189 by (rtac refl 2);
  1190 by (Asm_simp_tac 1);
  1191 qed "upt_conv_Cons";
  1192 
  1193 Goal "length [i..j(] = j-i";
  1194 by (induct_tac "j" 1);
  1195  by (Simp_tac 1);
  1196 by (asm_simp_tac (simpset() addsimps [Suc_diff_le]) 1);
  1197 qed "length_upt";
  1198 Addsimps [length_upt];
  1199 
  1200 Goal "i+k < j --> [i..j(] ! k = i+k";
  1201 by (induct_tac "j" 1);
  1202  by (Simp_tac 1);
  1203 by (asm_simp_tac (simpset() addsimps [nth_append,less_diff_conv]@add_ac) 1);
  1204 by (Clarify_tac 1);
  1205 by (subgoal_tac "n=i+k" 1);
  1206  by (Asm_simp_tac 2);
  1207 by (Asm_simp_tac 1);
  1208 qed_spec_mp "nth_upt";
  1209 Addsimps [nth_upt];
  1210 
  1211 Goal "!i. i+m <= n --> take m [i..n(] = [i..i+m(]";
  1212 by (induct_tac "m" 1);
  1213  by (Simp_tac 1);
  1214 by (Clarify_tac 1);
  1215 by (stac upt_rec 1);
  1216 by (rtac sym 1);
  1217 by (stac upt_rec 1);
  1218 by (asm_simp_tac (simpset() delsimps (thms"upt.simps")) 1);
  1219 qed_spec_mp "take_upt";
  1220 Addsimps [take_upt];
  1221 
  1222 Goal "!m i. i < n-m --> (map f [m..n(]) ! i = f(m+i)";
  1223 by (induct_tac "n" 1);
  1224  by (Simp_tac 1);
  1225 by (Clarify_tac 1);
  1226 by (subgoal_tac "m < Suc n" 1);
  1227  by (arith_tac 2);
  1228 by (stac upt_rec 1);
  1229 by (asm_simp_tac (simpset() delsplits [split_if]) 1);
  1230 by (split_tac [split_if] 1);
  1231 by (rtac conjI 1);
  1232  by (simp_tac (simpset() addsimps [nth_Cons] addsplits [nat.split]) 1);
  1233  by (simp_tac (simpset() addsimps [nth_append] addsplits [nat.split]) 1);
  1234  by (Clarify_tac 1);
  1235  by (rtac conjI 1);
  1236   by (Clarify_tac 1);
  1237   by (subgoal_tac "Suc(m+nat) < n" 1);
  1238    by (arith_tac 2);
  1239   by (Asm_simp_tac 1);
  1240  by (Clarify_tac 1);
  1241  by (subgoal_tac "n = Suc(m+nat)" 1);
  1242   by (arith_tac 2);
  1243  by (Asm_simp_tac 1);
  1244 by (simp_tac (simpset() addsimps [nth_Cons] addsplits [nat.split]) 1);
  1245 by (arith_tac 1);
  1246 qed_spec_mp "nth_map_upt";
  1247 
  1248 Goal "ALL xs ys. k <= length xs --> k <= length ys -->  \
  1249 \        (ALL i. i < k --> xs!i = ys!i)  \
  1250 \     --> take k xs = take k ys";
  1251 by (induct_tac "k" 1);
  1252 by (ALLGOALS (asm_simp_tac (simpset() addsimps [less_Suc_eq_0_disj, 
  1253 						all_conj_distrib])));
  1254 by (Clarify_tac 1);
  1255 (*Both lists must be non-empty*)
  1256 by (exhaust_tac "xs" 1);
  1257 by (exhaust_tac "ys" 2);
  1258 by (ALLGOALS Clarify_tac);
  1259 (*prenexing's needed, not miniscoping*)
  1260 by (ALLGOALS (full_simp_tac (simpset() addsimps (all_simps RL [sym])  
  1261                                        delsimps (all_simps))));
  1262 by (Blast_tac 1);
  1263 qed_spec_mp "nth_take_lemma";
  1264 
  1265 Goal "[| length xs = length ys;  \
  1266 \        ALL i. i < length xs --> xs!i = ys!i |]  \
  1267 \     ==> xs = ys";
  1268 by (forward_tac [[le_refl, eq_imp_le] MRS nth_take_lemma] 1);
  1269 by (ALLGOALS (asm_full_simp_tac (simpset() addsimps [take_all])));
  1270 qed_spec_mp "nth_equalityI";
  1271 
  1272 (*The famous take-lemma*)
  1273 Goal "(ALL i. take i xs = take i ys) ==> xs = ys";
  1274 by (dres_inst_tac [("x", "max (length xs) (length ys)")] spec 1);
  1275 by (full_simp_tac (simpset() addsimps [le_max_iff_disj, take_all]) 1);
  1276 qed_spec_mp "take_equalityI";
  1277 
  1278 
  1279 (** nodups & remdups **)
  1280 section "nodups & remdups";
  1281 
  1282 Goal "set(remdups xs) = set xs";
  1283 by (induct_tac "xs" 1);
  1284  by (Simp_tac 1);
  1285 by (asm_full_simp_tac (simpset() addsimps [insert_absorb]) 1);
  1286 qed "set_remdups";
  1287 Addsimps [set_remdups];
  1288 
  1289 Goal "nodups(remdups xs)";
  1290 by (induct_tac "xs" 1);
  1291 by Auto_tac;
  1292 qed "nodups_remdups";
  1293 
  1294 Goal "nodups xs --> nodups (filter P xs)";
  1295 by (induct_tac "xs" 1);
  1296 by Auto_tac;
  1297 qed_spec_mp "nodups_filter";
  1298 
  1299 (** replicate **)
  1300 section "replicate";
  1301 
  1302 Goal "length(replicate n x) = n";
  1303 by (induct_tac "n" 1);
  1304 by Auto_tac;
  1305 qed "length_replicate";
  1306 Addsimps [length_replicate];
  1307 
  1308 Goal "map f (replicate n x) = replicate n (f x)";
  1309 by (induct_tac "n" 1);
  1310 by Auto_tac;
  1311 qed "map_replicate";
  1312 Addsimps [map_replicate];
  1313 
  1314 Goal "(replicate n x) @ (x#xs) = x # replicate n x @ xs";
  1315 by (induct_tac "n" 1);
  1316 by Auto_tac;
  1317 qed "replicate_app_Cons_same";
  1318 
  1319 Goal "rev(replicate n x) = replicate n x";
  1320 by (induct_tac "n" 1);
  1321  by (Simp_tac 1);
  1322 by (asm_simp_tac (simpset() addsimps [replicate_app_Cons_same]) 1);
  1323 qed "rev_replicate";
  1324 Addsimps [rev_replicate];
  1325 
  1326 Goal "replicate (n+m) x = replicate n x @ replicate m x";
  1327 by (induct_tac "n" 1);
  1328 by Auto_tac;
  1329 qed "replicate_add";
  1330 
  1331 Goal"n ~= 0 --> hd(replicate n x) = x";
  1332 by (induct_tac "n" 1);
  1333 by Auto_tac;
  1334 qed_spec_mp "hd_replicate";
  1335 Addsimps [hd_replicate];
  1336 
  1337 Goal "n ~= 0 --> tl(replicate n x) = replicate (n-1) x";
  1338 by (induct_tac "n" 1);
  1339 by Auto_tac;
  1340 qed_spec_mp "tl_replicate";
  1341 Addsimps [tl_replicate];
  1342 
  1343 Goal "n ~= 0 --> last(replicate n x) = x";
  1344 by (induct_tac "n" 1);
  1345 by Auto_tac;
  1346 qed_spec_mp "last_replicate";
  1347 Addsimps [last_replicate];
  1348 
  1349 Goal "!i. i<n --> (replicate n x)!i = x";
  1350 by (induct_tac "n" 1);
  1351  by (Simp_tac 1);
  1352 by (asm_simp_tac (simpset() addsimps [nth_Cons] addsplits [nat.split]) 1);
  1353 qed_spec_mp "nth_replicate";
  1354 Addsimps [nth_replicate];
  1355 
  1356 Goal "set(replicate (Suc n) x) = {x}";
  1357 by (induct_tac "n" 1);
  1358 by Auto_tac;
  1359 val lemma = result();
  1360 
  1361 Goal "n ~= 0 ==> set(replicate n x) = {x}";
  1362 by (fast_tac (claset() addSDs [not0_implies_Suc] addSIs [lemma]) 1);
  1363 qed "set_replicate";
  1364 Addsimps [set_replicate];
  1365 
  1366 Goal "set(replicate n x) = (if n=0 then {} else {x})";
  1367 by (Auto_tac);
  1368 qed "set_replicate_conv_if";
  1369 
  1370 Goal "x : set(replicate n y) --> x=y";
  1371 by (asm_simp_tac (simpset() addsimps [set_replicate_conv_if]) 1);
  1372 qed_spec_mp "in_set_replicateD";
  1373 
  1374 
  1375 (*** Lexcicographic orderings on lists ***)
  1376 section"Lexcicographic orderings on lists";
  1377 
  1378 Goal "wf r ==> wf(lexn r n)";
  1379 by (induct_tac "n" 1);
  1380 by (Simp_tac 1);
  1381 by (Simp_tac 1);
  1382 by (rtac wf_subset 1);
  1383 by (rtac Int_lower1 2);
  1384 by (rtac wf_prod_fun_image 1);
  1385 by (rtac injI 2);
  1386 by Auto_tac;
  1387 qed "wf_lexn";
  1388 
  1389 Goal "!xs ys. (xs,ys) : lexn r n --> length xs = n & length ys = n";
  1390 by (induct_tac "n" 1);
  1391 by Auto_tac;
  1392 qed_spec_mp "lexn_length";
  1393 
  1394 Goalw [lex_def] "wf r ==> wf(lex r)";
  1395 by (rtac wf_UN 1);
  1396 by (blast_tac (claset() addIs [wf_lexn]) 1);
  1397 by (Clarify_tac 1);
  1398 by (rename_tac "m n" 1);
  1399 by (subgoal_tac "m ~= n" 1);
  1400  by (Blast_tac 2);
  1401 by (blast_tac (claset() addDs [lexn_length,not_sym]) 1);
  1402 qed "wf_lex";
  1403 AddSIs [wf_lex];
  1404 
  1405 Goal
  1406  "lexn r n = \
  1407 \ {(xs,ys). length xs = n & length ys = n & \
  1408 \           (? xys x y xs' ys'. xs= xys @ x#xs' & ys= xys @ y#ys' & (x,y):r)}";
  1409 by (induct_tac "n" 1);
  1410  by (Simp_tac 1);
  1411  by (Blast_tac 1);
  1412 by (asm_full_simp_tac (simpset() 
  1413 				addsimps [lex_prod_def]) 1);
  1414 by (auto_tac (claset(), simpset()));
  1415   by (Blast_tac 1);
  1416  by (rename_tac "a xys x xs' y ys'" 1);
  1417  by (res_inst_tac [("x","a#xys")] exI 1);
  1418  by (Simp_tac 1);
  1419 by (exhaust_tac "xys" 1);
  1420  by (ALLGOALS (asm_full_simp_tac (simpset())));
  1421 by (Blast_tac 1);
  1422 qed "lexn_conv";
  1423 
  1424 Goalw [lex_def]
  1425  "lex r = \
  1426 \ {(xs,ys). length xs = length ys & \
  1427 \           (? xys x y xs' ys'. xs= xys @ x#xs' & ys= xys @ y#ys' & (x,y):r)}";
  1428 by (force_tac (claset(), simpset() addsimps [lexn_conv]) 1);
  1429 qed "lex_conv";
  1430 
  1431 Goalw [lexico_def] "wf r ==> wf(lexico r)";
  1432 by (Blast_tac 1);
  1433 qed "wf_lexico";
  1434 AddSIs [wf_lexico];
  1435 
  1436 Goalw
  1437  [lexico_def,diag_def,lex_prod_def,measure_def,inv_image_def]
  1438 "lexico r = {(xs,ys). length xs < length ys | \
  1439 \                     length xs = length ys & (xs,ys) : lex r}";
  1440 by (Simp_tac 1);
  1441 qed "lexico_conv";
  1442 
  1443 Goal "([],ys) ~: lex r";
  1444 by (simp_tac (simpset() addsimps [lex_conv]) 1);
  1445 qed "Nil_notin_lex";
  1446 
  1447 Goal "(xs,[]) ~: lex r";
  1448 by (simp_tac (simpset() addsimps [lex_conv]) 1);
  1449 qed "Nil2_notin_lex";
  1450 
  1451 AddIffs [Nil_notin_lex,Nil2_notin_lex];
  1452 
  1453 Goal "((x#xs,y#ys) : lex r) = \
  1454 \     ((x,y) : r & length xs = length ys | x=y & (xs,ys) : lex r)";
  1455 by (simp_tac (simpset() addsimps [lex_conv]) 1);
  1456 by (rtac iffI 1);
  1457  by (blast_tac (claset() addIs [Cons_eq_appendI]) 2);
  1458 by (REPEAT(eresolve_tac [conjE, exE] 1));
  1459 by (exhaust_tac "xys" 1);
  1460 by (Asm_full_simp_tac 1);
  1461 by (Asm_full_simp_tac 1);
  1462 by (Blast_tac 1);
  1463 qed "Cons_in_lex";
  1464 AddIffs [Cons_in_lex];
  1465 
  1466 
  1467 (*** Versions of some theorems above using binary numerals ***)
  1468 
  1469 AddIffs (map (rename_numerals thy) 
  1470 	  [length_0_conv, zero_length_conv, length_greater_0_conv,
  1471 	   sum_eq_0_conv]);
  1472 
  1473 Goal "take n (x#xs) = (if n = #0 then [] else x # take (n-#1) xs)";
  1474 by (exhaust_tac "n" 1);
  1475 by (ALLGOALS 
  1476     (asm_simp_tac (simpset() addsimps [numeral_0_eq_0, numeral_1_eq_1])));
  1477 qed "take_Cons'";
  1478 
  1479 Goal "drop n (x#xs) = (if n = #0 then x#xs else drop (n-#1) xs)";
  1480 by (exhaust_tac "n" 1);
  1481 by (ALLGOALS
  1482     (asm_simp_tac (simpset() addsimps [numeral_0_eq_0, numeral_1_eq_1])));
  1483 qed "drop_Cons'";
  1484 
  1485 Goal "(x#xs)!n = (if n = #0 then x else xs!(n-#1))";
  1486 by (exhaust_tac "n" 1);
  1487 by (ALLGOALS
  1488     (asm_simp_tac (simpset() addsimps [numeral_0_eq_0, numeral_1_eq_1])));
  1489 qed "nth_Cons'";
  1490 
  1491 Addsimps (map (inst "n" "number_of ?v") [take_Cons', drop_Cons', nth_Cons']);
  1492