src/Pure/Isar/theory_target.ML
author wenzelm
Sun Mar 07 11:57:16 2010 +0100 (2010-03-07)
changeset 35624 c4e29a0bb8c1
parent 35205 611b90bb89bc
child 35717 1856c0172cf2
permissions -rw-r--r--
modernized structure Local_Defs;
     1 (*  Title:      Pure/Isar/theory_target.ML
     2     Author:     Makarius
     3     Author:     Florian Haftmann, TU Muenchen
     4 
     5 Common theory/locale/class/instantiation/overloading targets.
     6 *)
     7 
     8 signature THEORY_TARGET =
     9 sig
    10   val peek: local_theory ->
    11    {target: string,
    12     is_locale: bool,
    13     is_class: bool,
    14     instantiation: string list * (string * sort) list * sort,
    15     overloading: (string * (string * typ) * bool) list}
    16   val init: string option -> theory -> local_theory
    17   val context_cmd: xstring -> theory -> local_theory
    18   val instantiation: string list * (string * sort) list * sort -> theory -> local_theory
    19   val instantiation_cmd: xstring list * xstring list * xstring -> theory -> local_theory
    20   val overloading: (string * (string * typ) * bool) list -> theory -> local_theory
    21   val overloading_cmd: (string * string * bool) list -> theory -> local_theory
    22 end;
    23 
    24 structure Theory_Target: THEORY_TARGET =
    25 struct
    26 
    27 (* context data *)
    28 
    29 datatype target = Target of {target: string, is_locale: bool,
    30   is_class: bool, instantiation: string list * (string * sort) list * sort,
    31   overloading: (string * (string * typ) * bool) list};
    32 
    33 fun make_target target is_locale is_class instantiation overloading =
    34   Target {target = target, is_locale = is_locale,
    35     is_class = is_class, instantiation = instantiation, overloading = overloading};
    36 
    37 val global_target = make_target "" false false ([], [], []) [];
    38 
    39 structure Data = Proof_Data
    40 (
    41   type T = target;
    42   fun init _ = global_target;
    43 );
    44 
    45 val peek = (fn Target args => args) o Data.get;
    46 
    47 
    48 (* pretty *)
    49 
    50 fun pretty_thy ctxt target is_class =
    51   let
    52     val thy = ProofContext.theory_of ctxt;
    53     val target_name = (if is_class then "class " else "locale ") ^ Locale.extern thy target;
    54     val fixes =
    55       map (fn (x, T) => (Binding.name x, SOME T, NoSyn)) (#1 (ProofContext.inferred_fixes ctxt));
    56     val assumes =
    57       map (fn A => (Attrib.empty_binding, [(Thm.term_of A, [])])) (Assumption.all_assms_of ctxt);
    58     val elems =
    59       (if null fixes then [] else [Element.Fixes fixes]) @
    60       (if null assumes then [] else [Element.Assumes assumes]);
    61   in
    62     if target = "" then []
    63     else if null elems then [Pretty.str target_name]
    64     else [Pretty.big_list (target_name ^ " =")
    65       (map (Pretty.chunks o Element.pretty_ctxt ctxt) elems)]
    66   end;
    67 
    68 fun pretty (Target {target, is_class, instantiation, overloading, ...}) ctxt =
    69   Pretty.block [Pretty.str "theory", Pretty.brk 1,
    70       Pretty.str (Context.theory_name (ProofContext.theory_of ctxt))] ::
    71     (if not (null overloading) then [Overloading.pretty ctxt]
    72      else if not (null (#1 instantiation)) then [Class_Target.pretty_instantiation ctxt]
    73      else pretty_thy ctxt target is_class);
    74 
    75 
    76 (* generic declarations *)
    77 
    78 local
    79 
    80 fun direct_decl decl =
    81   let val decl0 = Morphism.form decl in
    82     Local_Theory.theory (Context.theory_map decl0) #>
    83     Local_Theory.target (Context.proof_map decl0)
    84   end;
    85 
    86 fun target_decl add (Target {target, ...}) pervasive decl lthy =
    87   let
    88     val global_decl = Morphism.transform (Local_Theory.global_morphism lthy) decl;
    89     val target_decl = Morphism.transform (Local_Theory.target_morphism lthy) decl;
    90   in
    91     if target = "" then
    92       lthy
    93       |> direct_decl global_decl
    94     else
    95       lthy
    96       |> pervasive ? direct_decl global_decl
    97       |> Local_Theory.target (add target target_decl)
    98   end;
    99 
   100 in
   101 
   102 val type_syntax = target_decl Locale.add_type_syntax;
   103 val term_syntax = target_decl Locale.add_term_syntax;
   104 val declaration = target_decl Locale.add_declaration;
   105 
   106 end;
   107 
   108 fun class_target (Target {target, ...}) f =
   109   Local_Theory.raw_theory f #>
   110   Local_Theory.target (Class_Target.refresh_syntax target);
   111 
   112 
   113 (* notes *)
   114 
   115 fun import_export_proof ctxt (name, raw_th) =
   116   let
   117     val thy = ProofContext.theory_of ctxt;
   118     val thy_ctxt = ProofContext.init thy;
   119     val certT = Thm.ctyp_of thy;
   120     val cert = Thm.cterm_of thy;
   121 
   122     (*export assumes/defines*)
   123     val th = Goal.norm_result raw_th;
   124     val (defs, th') = Local_Defs.export ctxt thy_ctxt th;
   125     val concl_conv = MetaSimplifier.rewrite true defs (Thm.cprop_of th);
   126     val assms = map (MetaSimplifier.rewrite_rule defs o Thm.assume) (Assumption.all_assms_of ctxt);
   127     val nprems = Thm.nprems_of th' - Thm.nprems_of th;
   128 
   129     (*export fixes*)
   130     val tfrees = map TFree (Thm.fold_terms Term.add_tfrees th' []);
   131     val frees = map Free (Thm.fold_terms Term.add_frees th' []);
   132     val (th'' :: vs) = (th' :: map (Drule.mk_term o cert) (map Logic.mk_type tfrees @ frees))
   133       |> Variable.export ctxt thy_ctxt
   134       |> Drule.zero_var_indexes_list;
   135 
   136     (*thm definition*)
   137     val result = PureThy.name_thm true true name th'';
   138 
   139     (*import fixes*)
   140     val (tvars, vars) =
   141       chop (length tfrees) (map (Thm.term_of o Drule.dest_term) vs)
   142       |>> map Logic.dest_type;
   143 
   144     val instT = map_filter (fn (TVar v, T) => SOME (v, T) | _ => NONE) (tvars ~~ tfrees);
   145     val inst = filter (is_Var o fst) (vars ~~ frees);
   146     val cinstT = map (pairself certT o apfst TVar) instT;
   147     val cinst = map (pairself (cert o Term.map_types (Term_Subst.instantiateT instT))) inst;
   148     val result' = Thm.instantiate (cinstT, cinst) result;
   149 
   150     (*import assumes/defines*)
   151     val assm_tac = FIRST' (map (fn assm => Tactic.compose_tac (false, assm, 0)) assms);
   152     val result'' =
   153       (case SINGLE (Seq.INTERVAL assm_tac 1 nprems) result' of
   154         NONE => raise THM ("Failed to re-import result", 0, [result'])
   155       | SOME res => Local_Defs.trans_props ctxt [res, Thm.symmetric concl_conv])
   156       |> Goal.norm_result
   157       |> PureThy.name_thm false false name;
   158 
   159   in (result'', result) end;
   160 
   161 fun notes (Target {target, is_locale, ...}) kind facts lthy =
   162   let
   163     val thy = ProofContext.theory_of lthy;
   164     val facts' = facts
   165       |> map (fn (a, bs) => (a, PureThy.burrow_fact (PureThy.name_multi
   166           (Local_Theory.full_name lthy (fst a))) bs))
   167       |> PureThy.map_facts (import_export_proof lthy);
   168     val local_facts = PureThy.map_facts #1 facts'
   169       |> Attrib.map_facts (Attrib.attribute_i thy);
   170     val target_facts = PureThy.map_facts #1 facts'
   171       |> is_locale ? Element.facts_map (Element.morph_ctxt (Local_Theory.target_morphism lthy));
   172     val global_facts = PureThy.map_facts #2 facts'
   173       |> Attrib.map_facts (if is_locale then K I else Attrib.attribute_i thy);
   174   in
   175     lthy
   176     |> Local_Theory.theory (PureThy.note_thmss kind global_facts #> snd)
   177     |> not is_locale ? Local_Theory.target (ProofContext.note_thmss kind global_facts #> snd)
   178     |> is_locale ? Local_Theory.target (Locale.add_thmss target kind target_facts)
   179     |> ProofContext.note_thmss kind local_facts
   180   end;
   181 
   182 
   183 (* declare_const *)
   184 
   185 fun fork_mixfix (Target {is_locale, is_class, ...}) mx =
   186   if not is_locale then (NoSyn, NoSyn, mx)
   187   else if not is_class then (NoSyn, mx, NoSyn)
   188   else (mx, NoSyn, NoSyn);
   189 
   190 fun locale_const (Target {target, is_class, ...}) (prmode as (mode, _)) ((b, mx), rhs) phi =
   191   let
   192     val b' = Morphism.binding phi b;
   193     val rhs' = Morphism.term phi rhs;
   194     val arg = (b', Term.close_schematic_term rhs');
   195     val same_shape = Term.aconv_untyped (rhs, rhs');
   196     (* FIXME workaround based on educated guess *)
   197     val prefix' = Binding.prefix_of b';
   198     val class_global =
   199       Binding.eq_name (b, b') andalso
   200       not (null prefix') andalso
   201       fst (snd (split_last prefix')) = Class_Target.class_prefix target;
   202   in
   203     not (is_class andalso (same_shape orelse class_global)) ?
   204       (Context.mapping_result
   205         (Sign.add_abbrev PrintMode.internal arg)
   206         (ProofContext.add_abbrev PrintMode.internal arg)
   207       #-> (fn (lhs' as Const (d, _), _) =>
   208           same_shape ?
   209             (Context.mapping (Sign.revert_abbrev mode d) (ProofContext.revert_abbrev mode d) #>
   210              Morphism.form (ProofContext.target_notation true prmode [(lhs', mx)]))))
   211   end;
   212 
   213 fun syntax_error c = error ("Illegal mixfix syntax for overloaded constant " ^ quote c);
   214 
   215 fun declare_const (ta as Target {target, is_locale, is_class, ...}) depends ((b, T), mx) lthy =
   216   let
   217     val xs = filter depends (#1 (ProofContext.inferred_fixes (Local_Theory.target_of lthy)));
   218     val U = map #2 xs ---> T;
   219     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   220     val (const, lthy') = lthy |>
   221       (case Class_Target.instantiation_param lthy b of
   222         SOME c' =>
   223           if mx3 <> NoSyn then syntax_error c'
   224           else Local_Theory.theory_result (AxClass.declare_overloaded (c', U))
   225             ##> Class_Target.confirm_declaration b
   226         | NONE =>
   227             (case Overloading.operation lthy b of
   228               SOME (c', _) =>
   229                 if mx3 <> NoSyn then syntax_error c'
   230                 else Local_Theory.theory_result (Overloading.declare (c', U))
   231                   ##> Overloading.confirm b
   232             | NONE => Local_Theory.theory_result (Sign.declare_const ((b, U), mx3))));
   233     val t = Term.list_comb (const, map Free xs);
   234   in
   235     lthy'
   236     |> is_locale ? term_syntax ta false (locale_const ta Syntax.mode_default ((b, mx2), t))
   237     |> is_class ? class_target ta (Class_Target.declare target ((b, mx1), t))
   238     |> Local_Defs.add_def ((b, NoSyn), t)
   239   end;
   240 
   241 
   242 (* abbrev *)
   243 
   244 fun abbrev (ta as Target {target, is_locale, is_class, ...}) prmode ((b, mx), t) lthy =
   245   let
   246     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   247     val target_ctxt = Local_Theory.target_of lthy;
   248 
   249     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   250     val t' = Assumption.export_term lthy target_ctxt t;
   251     val xs = map Free (rev (Variable.add_fixed target_ctxt t' []));
   252     val u = fold_rev lambda xs t';
   253     val global_rhs =
   254       singleton (Variable.export_terms (Variable.declare_term u target_ctxt) thy_ctxt) u;
   255   in
   256     lthy |>
   257      (if is_locale then
   258         Local_Theory.theory_result (Sign.add_abbrev PrintMode.internal (b, global_rhs))
   259         #-> (fn (lhs, _) =>
   260           let val lhs' = Term.list_comb (Logic.unvarify lhs, xs) in
   261             term_syntax ta false (locale_const ta prmode ((b, mx2), lhs')) #>
   262             is_class ? class_target ta (Class_Target.abbrev target prmode ((b, mx1), t'))
   263           end)
   264       else
   265         Local_Theory.theory
   266           (Sign.add_abbrev (#1 prmode) (b, global_rhs) #-> (fn (lhs, _) =>
   267            Sign.notation true prmode [(lhs, mx3)])))
   268     |> ProofContext.add_abbrev PrintMode.internal (b, t) |> snd
   269     |> Local_Defs.fixed_abbrev ((b, NoSyn), t)
   270   end;
   271 
   272 
   273 (* define *)
   274 
   275 fun define ta ((b, mx), ((name, atts), rhs)) lthy =
   276   let
   277     val thy = ProofContext.theory_of lthy;
   278     val thy_ctxt = ProofContext.init thy;
   279 
   280     val name' = Thm.def_binding_optional b name;
   281     val (rhs', rhs_conv) =
   282       Local_Defs.export_cterm lthy thy_ctxt (Thm.cterm_of thy rhs) |>> Thm.term_of;
   283     val xs = Variable.add_fixed (Local_Theory.target_of lthy) rhs' [];
   284     val T = Term.fastype_of rhs;
   285 
   286     (*const*)
   287     val ((lhs, local_def), lthy2) = lthy |> declare_const ta (member (op =) xs) ((b, T), mx);
   288     val (_, lhs') = Logic.dest_equals (Thm.prop_of local_def);
   289 
   290     (*def*)
   291     val (global_def, lthy3) = lthy2
   292       |> Local_Theory.theory_result
   293         (case Overloading.operation lthy b of
   294           SOME (_, checked) => Overloading.define checked name' (fst (dest_Const lhs'), rhs')
   295         | NONE =>
   296             if is_none (Class_Target.instantiation_param lthy b)
   297             then Thm.add_def false false (name', Logic.mk_equals (lhs', rhs'))
   298             else AxClass.define_overloaded name' (fst (dest_Const lhs'), rhs'));
   299     val def = Local_Defs.trans_terms lthy3
   300       [(*c == global.c xs*)     local_def,
   301        (*global.c xs == rhs'*)  global_def,
   302        (*rhs' == rhs*)          Thm.symmetric rhs_conv];
   303 
   304     (*note*)
   305     val ([(res_name, [res])], lthy4) = lthy3
   306       |> notes ta "" [((name', atts), [([def], [])])];
   307   in ((lhs, (res_name, res)), lthy4) end;
   308 
   309 
   310 (* init various targets *)
   311 
   312 local
   313 
   314 fun init_target _ NONE = global_target
   315   | init_target thy (SOME target) =
   316       if Locale.defined thy target
   317       then make_target target true (Class_Target.is_class thy target) ([], [], []) []
   318       else error ("No such locale: " ^ quote target);
   319 
   320 fun init_ctxt (Target {target, is_locale, is_class, instantiation, overloading}) =
   321   if not (null (#1 instantiation)) then Class_Target.init_instantiation instantiation
   322   else if not (null overloading) then Overloading.init overloading
   323   else if not is_locale then ProofContext.init
   324   else if not is_class then Locale.init target
   325   else Class_Target.init target;
   326 
   327 fun init_lthy (ta as Target {target, instantiation, overloading, ...}) =
   328   Data.put ta #>
   329   Local_Theory.init NONE (Long_Name.base_name target)
   330    {pretty = pretty ta,
   331     abbrev = abbrev ta,
   332     define = define ta,
   333     notes = notes ta,
   334     type_syntax = type_syntax ta,
   335     term_syntax = term_syntax ta,
   336     declaration = declaration ta,
   337     reinit = fn lthy => init_lthy_ctxt ta (ProofContext.theory_of lthy),
   338     exit = Local_Theory.target_of o
   339       (if not (null (#1 instantiation)) then Class_Target.conclude_instantiation
   340        else if not (null overloading) then Overloading.conclude
   341        else I)}
   342 and init_lthy_ctxt ta = init_lthy ta o init_ctxt ta;
   343 
   344 fun gen_overloading prep_const raw_ops thy =
   345   let
   346     val ctxt = ProofContext.init thy;
   347     val ops = raw_ops |> map (fn (name, const, checked) =>
   348       (name, Term.dest_Const (prep_const ctxt const), checked));
   349   in thy |> init_lthy_ctxt (make_target "" false false ([], [], []) ops) end;
   350 
   351 in
   352 
   353 fun init target thy = init_lthy_ctxt (init_target thy target) thy;
   354 
   355 fun context_cmd "-" thy = init NONE thy
   356   | context_cmd target thy = init (SOME (Locale.intern thy target)) thy;
   357 
   358 fun instantiation arities = init_lthy_ctxt (make_target "" false false arities []);
   359 fun instantiation_cmd arities thy = instantiation (Class_Target.read_multi_arity thy arities) thy;
   360 
   361 val overloading = gen_overloading (fn ctxt => Syntax.check_term ctxt o Const);
   362 val overloading_cmd = gen_overloading Syntax.read_term;
   363 
   364 end;
   365 
   366 end;
   367