src/HOL/Lifting_Set.thy
author desharna
Mon Sep 01 13:23:39 2014 +0200 (2014-09-01)
changeset 58104 c5316f843f72
parent 57599 7ef939f89776
child 58889 5b7a9633cfa8
permissions -rw-r--r--
generate 'rel_transfer' for BNFs
     1 (*  Title:      HOL/Lifting_Set.thy
     2     Author:     Brian Huffman and Ondrej Kuncar
     3 *)
     4 
     5 header {* Setup for Lifting/Transfer for the set type *}
     6 
     7 theory Lifting_Set
     8 imports Lifting
     9 begin
    10 
    11 subsection {* Relator and predicator properties *}
    12 
    13 lemma rel_setD1: "\<lbrakk> rel_set R A B; x \<in> A \<rbrakk> \<Longrightarrow> \<exists>y \<in> B. R x y"
    14   and rel_setD2: "\<lbrakk> rel_set R A B; y \<in> B \<rbrakk> \<Longrightarrow> \<exists>x \<in> A. R x y"
    15 by(simp_all add: rel_set_def)
    16 
    17 lemma rel_set_conversep [simp]: "rel_set A\<inverse>\<inverse> = (rel_set A)\<inverse>\<inverse>"
    18   unfolding rel_set_def by auto
    19 
    20 lemma rel_set_eq [relator_eq]: "rel_set (op =) = (op =)"
    21   unfolding rel_set_def fun_eq_iff by auto
    22 
    23 lemma rel_set_mono[relator_mono]:
    24   assumes "A \<le> B"
    25   shows "rel_set A \<le> rel_set B"
    26 using assms unfolding rel_set_def by blast
    27 
    28 lemma rel_set_OO[relator_distr]: "rel_set R OO rel_set S = rel_set (R OO S)"
    29   apply (rule sym)
    30   apply (intro ext, rename_tac X Z)
    31   apply (rule iffI)
    32   apply (rule_tac b="{y. (\<exists>x\<in>X. R x y) \<and> (\<exists>z\<in>Z. S y z)}" in relcomppI)
    33   apply (simp add: rel_set_def, fast)
    34   apply (simp add: rel_set_def, fast)
    35   apply (simp add: rel_set_def, fast)
    36   done
    37 
    38 lemma Domainp_set[relator_domain]:
    39   "Domainp (rel_set T) = (\<lambda>A. Ball A (Domainp T))"
    40 unfolding rel_set_def Domainp_iff[abs_def]
    41 apply (intro ext)
    42 apply (rule iffI) 
    43 apply blast
    44 apply (rename_tac A, rule_tac x="{y. \<exists>x\<in>A. T x y}" in exI, fast)
    45 done
    46 
    47 lemma left_total_rel_set[transfer_rule]: 
    48   "left_total A \<Longrightarrow> left_total (rel_set A)"
    49   unfolding left_total_def rel_set_def
    50   apply safe
    51   apply (rename_tac X, rule_tac x="{y. \<exists>x\<in>X. A x y}" in exI, fast)
    52 done
    53 
    54 lemma left_unique_rel_set[transfer_rule]: 
    55   "left_unique A \<Longrightarrow> left_unique (rel_set A)"
    56   unfolding left_unique_def rel_set_def
    57   by fast
    58 
    59 lemma right_total_rel_set [transfer_rule]:
    60   "right_total A \<Longrightarrow> right_total (rel_set A)"
    61 using left_total_rel_set[of "A\<inverse>\<inverse>"] by simp
    62 
    63 lemma right_unique_rel_set [transfer_rule]:
    64   "right_unique A \<Longrightarrow> right_unique (rel_set A)"
    65   unfolding right_unique_def rel_set_def by fast
    66 
    67 lemma bi_total_rel_set [transfer_rule]:
    68   "bi_total A \<Longrightarrow> bi_total (rel_set A)"
    69 by(simp add: bi_total_alt_def left_total_rel_set right_total_rel_set)
    70 
    71 lemma bi_unique_rel_set [transfer_rule]:
    72   "bi_unique A \<Longrightarrow> bi_unique (rel_set A)"
    73   unfolding bi_unique_def rel_set_def by fast
    74 
    75 lemma set_relator_eq_onp [relator_eq_onp]:
    76   "rel_set (eq_onp P) = eq_onp (\<lambda>A. Ball A P)"
    77   unfolding fun_eq_iff rel_set_def eq_onp_def Ball_def by fast
    78 
    79 lemma bi_unique_rel_set_lemma:
    80   assumes "bi_unique R" and "rel_set R X Y"
    81   obtains f where "Y = image f X" and "inj_on f X" and "\<forall>x\<in>X. R x (f x)"
    82 proof
    83   def f \<equiv> "\<lambda>x. THE y. R x y"
    84   { fix x assume "x \<in> X"
    85     with `rel_set R X Y` `bi_unique R` have "R x (f x)"
    86       by (simp add: bi_unique_def rel_set_def f_def) (metis theI)
    87     with assms `x \<in> X` 
    88     have  "R x (f x)" "\<forall>x'\<in>X. R x' (f x) \<longrightarrow> x = x'" "\<forall>y\<in>Y. R x y \<longrightarrow> y = f x" "f x \<in> Y"
    89       by (fastforce simp add: bi_unique_def rel_set_def)+ }
    90   note * = this
    91   moreover
    92   { fix y assume "y \<in> Y"
    93     with `rel_set R X Y` *(3) `y \<in> Y` have "\<exists>x\<in>X. y = f x"
    94       by (fastforce simp: rel_set_def) }
    95   ultimately show "\<forall>x\<in>X. R x (f x)" "Y = image f X" "inj_on f X"
    96     by (auto simp: inj_on_def image_iff)
    97 qed
    98 
    99 subsection {* Quotient theorem for the Lifting package *}
   100 
   101 lemma Quotient_set[quot_map]:
   102   assumes "Quotient R Abs Rep T"
   103   shows "Quotient (rel_set R) (image Abs) (image Rep) (rel_set T)"
   104   using assms unfolding Quotient_alt_def4
   105   apply (simp add: rel_set_OO[symmetric])
   106   apply (simp add: rel_set_def, fast)
   107   done
   108 
   109 subsection {* Transfer rules for the Transfer package *}
   110 
   111 subsubsection {* Unconditional transfer rules *}
   112 
   113 context
   114 begin
   115 interpretation lifting_syntax .
   116 
   117 lemma empty_transfer [transfer_rule]: "(rel_set A) {} {}"
   118   unfolding rel_set_def by simp
   119 
   120 lemma insert_transfer [transfer_rule]:
   121   "(A ===> rel_set A ===> rel_set A) insert insert"
   122   unfolding rel_fun_def rel_set_def by auto
   123 
   124 lemma union_transfer [transfer_rule]:
   125   "(rel_set A ===> rel_set A ===> rel_set A) union union"
   126   unfolding rel_fun_def rel_set_def by auto
   127 
   128 lemma Union_transfer [transfer_rule]:
   129   "(rel_set (rel_set A) ===> rel_set A) Union Union"
   130   unfolding rel_fun_def rel_set_def by simp fast
   131 
   132 lemma image_transfer [transfer_rule]:
   133   "((A ===> B) ===> rel_set A ===> rel_set B) image image"
   134   unfolding rel_fun_def rel_set_def by simp fast
   135 
   136 lemma UNION_transfer [transfer_rule]:
   137   "(rel_set A ===> (A ===> rel_set B) ===> rel_set B) UNION UNION"
   138   unfolding Union_image_eq [symmetric, abs_def] by transfer_prover
   139 
   140 lemma Ball_transfer [transfer_rule]:
   141   "(rel_set A ===> (A ===> op =) ===> op =) Ball Ball"
   142   unfolding rel_set_def rel_fun_def by fast
   143 
   144 lemma Bex_transfer [transfer_rule]:
   145   "(rel_set A ===> (A ===> op =) ===> op =) Bex Bex"
   146   unfolding rel_set_def rel_fun_def by fast
   147 
   148 lemma Pow_transfer [transfer_rule]:
   149   "(rel_set A ===> rel_set (rel_set A)) Pow Pow"
   150   apply (rule rel_funI, rename_tac X Y, rule rel_setI)
   151   apply (rename_tac X', rule_tac x="{y\<in>Y. \<exists>x\<in>X'. A x y}" in rev_bexI, clarsimp)
   152   apply (simp add: rel_set_def, fast)
   153   apply (rename_tac Y', rule_tac x="{x\<in>X. \<exists>y\<in>Y'. A x y}" in rev_bexI, clarsimp)
   154   apply (simp add: rel_set_def, fast)
   155   done
   156 
   157 lemma rel_set_transfer [transfer_rule]:
   158   "((A ===> B ===> op =) ===> rel_set A ===> rel_set B ===> op =) rel_set rel_set"
   159   unfolding rel_fun_def rel_set_def by fast
   160 
   161 lemma bind_transfer [transfer_rule]:
   162   "(rel_set A ===> (A ===> rel_set B) ===> rel_set B) Set.bind Set.bind"
   163   unfolding bind_UNION [abs_def] by transfer_prover
   164 
   165 lemma INF_parametric [transfer_rule]:
   166   "(rel_set A ===> (A ===> HOL.eq) ===> HOL.eq) INFIMUM INFIMUM"
   167   unfolding INF_def [abs_def] by transfer_prover
   168 
   169 lemma SUP_parametric [transfer_rule]:
   170   "(rel_set R ===> (R ===> HOL.eq) ===> HOL.eq) SUPREMUM SUPREMUM"
   171   unfolding SUP_def [abs_def] by transfer_prover
   172 
   173 
   174 subsubsection {* Rules requiring bi-unique, bi-total or right-total relations *}
   175 
   176 lemma member_transfer [transfer_rule]:
   177   assumes "bi_unique A"
   178   shows "(A ===> rel_set A ===> op =) (op \<in>) (op \<in>)"
   179   using assms unfolding rel_fun_def rel_set_def bi_unique_def by fast
   180 
   181 lemma right_total_Collect_transfer[transfer_rule]:
   182   assumes "right_total A"
   183   shows "((A ===> op =) ===> rel_set A) (\<lambda>P. Collect (\<lambda>x. P x \<and> Domainp A x)) Collect"
   184   using assms unfolding right_total_def rel_set_def rel_fun_def Domainp_iff by fast
   185 
   186 lemma Collect_transfer [transfer_rule]:
   187   assumes "bi_total A"
   188   shows "((A ===> op =) ===> rel_set A) Collect Collect"
   189   using assms unfolding rel_fun_def rel_set_def bi_total_def by fast
   190 
   191 lemma inter_transfer [transfer_rule]:
   192   assumes "bi_unique A"
   193   shows "(rel_set A ===> rel_set A ===> rel_set A) inter inter"
   194   using assms unfolding rel_fun_def rel_set_def bi_unique_def by fast
   195 
   196 lemma Diff_transfer [transfer_rule]:
   197   assumes "bi_unique A"
   198   shows "(rel_set A ===> rel_set A ===> rel_set A) (op -) (op -)"
   199   using assms unfolding rel_fun_def rel_set_def bi_unique_def
   200   unfolding Ball_def Bex_def Diff_eq
   201   by (safe, simp, metis, simp, metis)
   202 
   203 lemma subset_transfer [transfer_rule]:
   204   assumes [transfer_rule]: "bi_unique A"
   205   shows "(rel_set A ===> rel_set A ===> op =) (op \<subseteq>) (op \<subseteq>)"
   206   unfolding subset_eq [abs_def] by transfer_prover
   207 
   208 lemma right_total_UNIV_transfer[transfer_rule]: 
   209   assumes "right_total A"
   210   shows "(rel_set A) (Collect (Domainp A)) UNIV"
   211   using assms unfolding right_total_def rel_set_def Domainp_iff by blast
   212 
   213 lemma UNIV_transfer [transfer_rule]:
   214   assumes "bi_total A"
   215   shows "(rel_set A) UNIV UNIV"
   216   using assms unfolding rel_set_def bi_total_def by simp
   217 
   218 lemma right_total_Compl_transfer [transfer_rule]:
   219   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "right_total A"
   220   shows "(rel_set A ===> rel_set A) (\<lambda>S. uminus S \<inter> Collect (Domainp A)) uminus"
   221   unfolding Compl_eq [abs_def]
   222   by (subst Collect_conj_eq[symmetric]) transfer_prover
   223 
   224 lemma Compl_transfer [transfer_rule]:
   225   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "bi_total A"
   226   shows "(rel_set A ===> rel_set A) uminus uminus"
   227   unfolding Compl_eq [abs_def] by transfer_prover
   228 
   229 lemma right_total_Inter_transfer [transfer_rule]:
   230   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "right_total A"
   231   shows "(rel_set (rel_set A) ===> rel_set A) (\<lambda>S. Inter S \<inter> Collect (Domainp A)) Inter"
   232   unfolding Inter_eq[abs_def]
   233   by (subst Collect_conj_eq[symmetric]) transfer_prover
   234 
   235 lemma Inter_transfer [transfer_rule]:
   236   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "bi_total A"
   237   shows "(rel_set (rel_set A) ===> rel_set A) Inter Inter"
   238   unfolding Inter_eq [abs_def] by transfer_prover
   239 
   240 lemma filter_transfer [transfer_rule]:
   241   assumes [transfer_rule]: "bi_unique A"
   242   shows "((A ===> op=) ===> rel_set A ===> rel_set A) Set.filter Set.filter"
   243   unfolding Set.filter_def[abs_def] rel_fun_def rel_set_def by blast
   244 
   245 lemma finite_transfer [transfer_rule]:
   246   "bi_unique A \<Longrightarrow> (rel_set A ===> op =) finite finite"
   247   by (rule rel_funI, erule (1) bi_unique_rel_set_lemma)
   248      (auto dest: finite_imageD)
   249 
   250 lemma card_transfer [transfer_rule]:
   251   "bi_unique A \<Longrightarrow> (rel_set A ===> op =) card card"
   252   by (rule rel_funI, erule (1) bi_unique_rel_set_lemma)
   253      (simp add: card_image)
   254 
   255 lemma vimage_parametric [transfer_rule]:
   256   assumes [transfer_rule]: "bi_total A" "bi_unique B"
   257   shows "((A ===> B) ===> rel_set B ===> rel_set A) vimage vimage"
   258   unfolding vimage_def[abs_def] by transfer_prover
   259 
   260 lemma Image_parametric [transfer_rule]:
   261   assumes "bi_unique A"
   262   shows "(rel_set (rel_prod A B) ===> rel_set A ===> rel_set B) op `` op ``"
   263 by(intro rel_funI rel_setI)
   264   (force dest: rel_setD1 bi_uniqueDr[OF assms], force dest: rel_setD2 bi_uniqueDl[OF assms])
   265 
   266 end
   267 
   268 lemma (in comm_monoid_set) F_parametric [transfer_rule]:
   269   fixes A :: "'b \<Rightarrow> 'c \<Rightarrow> bool"
   270   assumes "bi_unique A"
   271   shows "rel_fun (rel_fun A (op =)) (rel_fun (rel_set A) (op =)) F F"
   272 proof(rule rel_funI)+
   273   fix f :: "'b \<Rightarrow> 'a" and g S T
   274   assume "rel_fun A (op =) f g" "rel_set A S T"
   275   with `bi_unique A` obtain i where "bij_betw i S T" "\<And>x. x \<in> S \<Longrightarrow> f x = g (i x)"
   276     by (auto elim: bi_unique_rel_set_lemma simp: rel_fun_def bij_betw_def)
   277   then show "F f S = F g T"
   278     by (simp add: reindex_bij_betw)
   279 qed
   280 
   281 lemmas setsum_parametric = setsum.F_parametric
   282 lemmas setprod_parametric = setprod.F_parametric
   283 
   284 end