src/HOL/Code_Numeral.thy
author haftmann
Thu Sep 18 18:48:04 2014 +0200 (2014-09-18)
changeset 58399 c5430cf9aa87
parent 58390 b74d8470b98e
child 58400 d0d3c30806b4
permissions -rw-r--r--
tuned
     1 (*  Title:      HOL/Code_Numeral.thy
     2     Author:     Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 header {* Numeric types for code generation onto target language numerals only *}
     6 
     7 theory Code_Numeral
     8 imports Nat_Transfer Divides Lifting
     9 begin
    10 
    11 subsection {* Type of target language integers *}
    12 
    13 typedef integer = "UNIV \<Colon> int set"
    14   morphisms int_of_integer integer_of_int ..
    15 
    16 setup_lifting (no_code) type_definition_integer
    17 
    18 lemma integer_eq_iff:
    19   "k = l \<longleftrightarrow> int_of_integer k = int_of_integer l"
    20   by transfer rule
    21 
    22 lemma integer_eqI:
    23   "int_of_integer k = int_of_integer l \<Longrightarrow> k = l"
    24   using integer_eq_iff [of k l] by simp
    25 
    26 lemma int_of_integer_integer_of_int [simp]:
    27   "int_of_integer (integer_of_int k) = k"
    28   by transfer rule
    29 
    30 lemma integer_of_int_int_of_integer [simp]:
    31   "integer_of_int (int_of_integer k) = k"
    32   by transfer rule
    33 
    34 instantiation integer :: ring_1
    35 begin
    36 
    37 lift_definition zero_integer :: integer
    38   is "0 :: int"
    39   .
    40 
    41 declare zero_integer.rep_eq [simp]
    42 
    43 lift_definition one_integer :: integer
    44   is "1 :: int"
    45   .
    46 
    47 declare one_integer.rep_eq [simp]
    48 
    49 lift_definition plus_integer :: "integer \<Rightarrow> integer \<Rightarrow> integer"
    50   is "plus :: int \<Rightarrow> int \<Rightarrow> int"
    51   .
    52 
    53 declare plus_integer.rep_eq [simp]
    54 
    55 lift_definition uminus_integer :: "integer \<Rightarrow> integer"
    56   is "uminus :: int \<Rightarrow> int"
    57   .
    58 
    59 declare uminus_integer.rep_eq [simp]
    60 
    61 lift_definition minus_integer :: "integer \<Rightarrow> integer \<Rightarrow> integer"
    62   is "minus :: int \<Rightarrow> int \<Rightarrow> int"
    63   .
    64 
    65 declare minus_integer.rep_eq [simp]
    66 
    67 lift_definition times_integer :: "integer \<Rightarrow> integer \<Rightarrow> integer"
    68   is "times :: int \<Rightarrow> int \<Rightarrow> int"
    69   .
    70 
    71 declare times_integer.rep_eq [simp]
    72 
    73 instance proof
    74 qed (transfer, simp add: algebra_simps)+
    75 
    76 end
    77 
    78 lemma [transfer_rule]:
    79   "rel_fun HOL.eq pcr_integer (of_nat :: nat \<Rightarrow> int) (of_nat :: nat \<Rightarrow> integer)"
    80   by (unfold of_nat_def [abs_def]) transfer_prover
    81 
    82 lemma [transfer_rule]:
    83   "rel_fun HOL.eq pcr_integer (\<lambda>k :: int. k :: int) (of_int :: int \<Rightarrow> integer)"
    84 proof -
    85   have "rel_fun HOL.eq pcr_integer (of_int :: int \<Rightarrow> int) (of_int :: int \<Rightarrow> integer)"
    86     by (unfold of_int_of_nat [abs_def]) transfer_prover
    87   then show ?thesis by (simp add: id_def)
    88 qed
    89 
    90 lemma [transfer_rule]:
    91   "rel_fun HOL.eq pcr_integer (numeral :: num \<Rightarrow> int) (numeral :: num \<Rightarrow> integer)"
    92 proof -
    93   have "rel_fun HOL.eq pcr_integer (numeral :: num \<Rightarrow> int) (\<lambda>n. of_int (numeral n))"
    94     by transfer_prover
    95   then show ?thesis by simp
    96 qed
    97 
    98 lemma [transfer_rule]:
    99   "rel_fun HOL.eq (rel_fun HOL.eq pcr_integer) (Num.sub :: _ \<Rightarrow> _ \<Rightarrow> int) (Num.sub :: _ \<Rightarrow> _ \<Rightarrow> integer)"
   100   by (unfold Num.sub_def [abs_def]) transfer_prover
   101 
   102 lemma int_of_integer_of_nat [simp]:
   103   "int_of_integer (of_nat n) = of_nat n"
   104   by transfer rule
   105 
   106 lift_definition integer_of_nat :: "nat \<Rightarrow> integer"
   107   is "of_nat :: nat \<Rightarrow> int"
   108   .
   109 
   110 lemma integer_of_nat_eq_of_nat [code]:
   111   "integer_of_nat = of_nat"
   112   by transfer rule
   113 
   114 lemma int_of_integer_integer_of_nat [simp]:
   115   "int_of_integer (integer_of_nat n) = of_nat n"
   116   by transfer rule
   117 
   118 lift_definition nat_of_integer :: "integer \<Rightarrow> nat"
   119   is Int.nat
   120   .
   121 
   122 lemma nat_of_integer_of_nat [simp]:
   123   "nat_of_integer (of_nat n) = n"
   124   by transfer simp
   125 
   126 lemma int_of_integer_of_int [simp]:
   127   "int_of_integer (of_int k) = k"
   128   by transfer simp
   129 
   130 lemma nat_of_integer_integer_of_nat [simp]:
   131   "nat_of_integer (integer_of_nat n) = n"
   132   by transfer simp
   133 
   134 lemma integer_of_int_eq_of_int [simp, code_abbrev]:
   135   "integer_of_int = of_int"
   136   by transfer (simp add: fun_eq_iff)
   137 
   138 lemma of_int_integer_of [simp]:
   139   "of_int (int_of_integer k) = (k :: integer)"
   140   by transfer rule
   141 
   142 lemma int_of_integer_numeral [simp]:
   143   "int_of_integer (numeral k) = numeral k"
   144   by transfer rule
   145 
   146 lemma int_of_integer_sub [simp]:
   147   "int_of_integer (Num.sub k l) = Num.sub k l"
   148   by transfer rule
   149 
   150 instantiation integer :: "{ring_div, equal, linordered_idom}"
   151 begin
   152 
   153 lift_definition div_integer :: "integer \<Rightarrow> integer \<Rightarrow> integer"
   154   is "Divides.div :: int \<Rightarrow> int \<Rightarrow> int"
   155   .
   156 
   157 declare div_integer.rep_eq [simp]
   158 
   159 lift_definition mod_integer :: "integer \<Rightarrow> integer \<Rightarrow> integer"
   160   is "Divides.mod :: int \<Rightarrow> int \<Rightarrow> int"
   161   .
   162 
   163 declare mod_integer.rep_eq [simp]
   164 
   165 lift_definition abs_integer :: "integer \<Rightarrow> integer"
   166   is "abs :: int \<Rightarrow> int"
   167   .
   168 
   169 declare abs_integer.rep_eq [simp]
   170 
   171 lift_definition sgn_integer :: "integer \<Rightarrow> integer"
   172   is "sgn :: int \<Rightarrow> int"
   173   .
   174 
   175 declare sgn_integer.rep_eq [simp]
   176 
   177 lift_definition less_eq_integer :: "integer \<Rightarrow> integer \<Rightarrow> bool"
   178   is "less_eq :: int \<Rightarrow> int \<Rightarrow> bool"
   179   .
   180 
   181 lift_definition less_integer :: "integer \<Rightarrow> integer \<Rightarrow> bool"
   182   is "less :: int \<Rightarrow> int \<Rightarrow> bool"
   183   .
   184 
   185 lift_definition equal_integer :: "integer \<Rightarrow> integer \<Rightarrow> bool"
   186   is "HOL.equal :: int \<Rightarrow> int \<Rightarrow> bool"
   187   .
   188 
   189 instance proof
   190 qed (transfer, simp add: algebra_simps equal less_le_not_le [symmetric] mult_strict_right_mono linear)+
   191 
   192 end
   193 
   194 lemma [transfer_rule]:
   195   "rel_fun pcr_integer (rel_fun pcr_integer pcr_integer) (min :: _ \<Rightarrow> _ \<Rightarrow> int) (min :: _ \<Rightarrow> _ \<Rightarrow> integer)"
   196   by (unfold min_def [abs_def]) transfer_prover
   197 
   198 lemma [transfer_rule]:
   199   "rel_fun pcr_integer (rel_fun pcr_integer pcr_integer) (max :: _ \<Rightarrow> _ \<Rightarrow> int) (max :: _ \<Rightarrow> _ \<Rightarrow> integer)"
   200   by (unfold max_def [abs_def]) transfer_prover
   201 
   202 lemma int_of_integer_min [simp]:
   203   "int_of_integer (min k l) = min (int_of_integer k) (int_of_integer l)"
   204   by transfer rule
   205 
   206 lemma int_of_integer_max [simp]:
   207   "int_of_integer (max k l) = max (int_of_integer k) (int_of_integer l)"
   208   by transfer rule
   209 
   210 lemma nat_of_integer_non_positive [simp]:
   211   "k \<le> 0 \<Longrightarrow> nat_of_integer k = 0"
   212   by transfer simp
   213 
   214 lemma of_nat_of_integer [simp]:
   215   "of_nat (nat_of_integer k) = max 0 k"
   216   by transfer auto
   217 
   218 instance integer :: semiring_numeral_div
   219   by intro_classes (transfer,
   220     fact semiring_numeral_div_class.diff_invert_add1
   221     semiring_numeral_div_class.le_add_diff_inverse2
   222     semiring_numeral_div_class.mult_div_cancel
   223     semiring_numeral_div_class.div_less
   224     semiring_numeral_div_class.mod_less
   225     semiring_numeral_div_class.div_positive
   226     semiring_numeral_div_class.mod_less_eq_dividend
   227     semiring_numeral_div_class.pos_mod_bound
   228     semiring_numeral_div_class.pos_mod_sign
   229     semiring_numeral_div_class.mod_mult2_eq
   230     semiring_numeral_div_class.div_mult2_eq
   231     semiring_numeral_div_class.discrete)+
   232 
   233 lemma integer_of_nat_0: "integer_of_nat 0 = 0"
   234 by transfer simp
   235 
   236 lemma integer_of_nat_1: "integer_of_nat 1 = 1"
   237 by transfer simp
   238 
   239 lemma integer_of_nat_numeral:
   240   "integer_of_nat (numeral n) = numeral n"
   241 by transfer simp
   242 
   243 subsection {* Code theorems for target language integers *}
   244 
   245 text {* Constructors *}
   246 
   247 definition Pos :: "num \<Rightarrow> integer"
   248 where
   249   [simp, code_abbrev]: "Pos = numeral"
   250 
   251 lemma [transfer_rule]:
   252   "rel_fun HOL.eq pcr_integer numeral Pos"
   253   by simp transfer_prover
   254 
   255 definition Neg :: "num \<Rightarrow> integer"
   256 where
   257   [simp, code_abbrev]: "Neg n = - Pos n"
   258 
   259 lemma [transfer_rule]:
   260   "rel_fun HOL.eq pcr_integer (\<lambda>n. - numeral n) Neg"
   261   by (simp add: Neg_def [abs_def]) transfer_prover
   262 
   263 code_datatype "0::integer" Pos Neg
   264 
   265 
   266 text {* Auxiliary operations *}
   267 
   268 lift_definition dup :: "integer \<Rightarrow> integer"
   269   is "\<lambda>k::int. k + k"
   270   .
   271 
   272 lemma dup_code [code]:
   273   "dup 0 = 0"
   274   "dup (Pos n) = Pos (Num.Bit0 n)"
   275   "dup (Neg n) = Neg (Num.Bit0 n)"
   276   by (transfer, simp only: numeral_Bit0 minus_add_distrib)+
   277 
   278 lift_definition sub :: "num \<Rightarrow> num \<Rightarrow> integer"
   279   is "\<lambda>m n. numeral m - numeral n :: int"
   280   .
   281 
   282 lemma sub_code [code]:
   283   "sub Num.One Num.One = 0"
   284   "sub (Num.Bit0 m) Num.One = Pos (Num.BitM m)"
   285   "sub (Num.Bit1 m) Num.One = Pos (Num.Bit0 m)"
   286   "sub Num.One (Num.Bit0 n) = Neg (Num.BitM n)"
   287   "sub Num.One (Num.Bit1 n) = Neg (Num.Bit0 n)"
   288   "sub (Num.Bit0 m) (Num.Bit0 n) = dup (sub m n)"
   289   "sub (Num.Bit1 m) (Num.Bit1 n) = dup (sub m n)"
   290   "sub (Num.Bit1 m) (Num.Bit0 n) = dup (sub m n) + 1"
   291   "sub (Num.Bit0 m) (Num.Bit1 n) = dup (sub m n) - 1"
   292   by (transfer, simp add: dbl_def dbl_inc_def dbl_dec_def)+
   293 
   294 
   295 text {* Implementations *}
   296 
   297 lemma one_integer_code [code, code_unfold]:
   298   "1 = Pos Num.One"
   299   by simp
   300 
   301 lemma plus_integer_code [code]:
   302   "k + 0 = (k::integer)"
   303   "0 + l = (l::integer)"
   304   "Pos m + Pos n = Pos (m + n)"
   305   "Pos m + Neg n = sub m n"
   306   "Neg m + Pos n = sub n m"
   307   "Neg m + Neg n = Neg (m + n)"
   308   by (transfer, simp)+
   309 
   310 lemma uminus_integer_code [code]:
   311   "uminus 0 = (0::integer)"
   312   "uminus (Pos m) = Neg m"
   313   "uminus (Neg m) = Pos m"
   314   by simp_all
   315 
   316 lemma minus_integer_code [code]:
   317   "k - 0 = (k::integer)"
   318   "0 - l = uminus (l::integer)"
   319   "Pos m - Pos n = sub m n"
   320   "Pos m - Neg n = Pos (m + n)"
   321   "Neg m - Pos n = Neg (m + n)"
   322   "Neg m - Neg n = sub n m"
   323   by (transfer, simp)+
   324 
   325 lemma abs_integer_code [code]:
   326   "\<bar>k\<bar> = (if (k::integer) < 0 then - k else k)"
   327   by simp
   328 
   329 lemma sgn_integer_code [code]:
   330   "sgn k = (if k = 0 then 0 else if (k::integer) < 0 then - 1 else 1)"
   331   by simp
   332 
   333 lemma times_integer_code [code]:
   334   "k * 0 = (0::integer)"
   335   "0 * l = (0::integer)"
   336   "Pos m * Pos n = Pos (m * n)"
   337   "Pos m * Neg n = Neg (m * n)"
   338   "Neg m * Pos n = Neg (m * n)"
   339   "Neg m * Neg n = Pos (m * n)"
   340   by simp_all
   341 
   342 definition divmod_integer :: "integer \<Rightarrow> integer \<Rightarrow> integer \<times> integer"
   343 where
   344   "divmod_integer k l = (k div l, k mod l)"
   345 
   346 lemma fst_divmod [simp]:
   347   "fst (divmod_integer k l) = k div l"
   348   by (simp add: divmod_integer_def)
   349 
   350 lemma snd_divmod [simp]:
   351   "snd (divmod_integer k l) = k mod l"
   352   by (simp add: divmod_integer_def)
   353 
   354 definition divmod_abs :: "integer \<Rightarrow> integer \<Rightarrow> integer \<times> integer"
   355 where
   356   "divmod_abs k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
   357 
   358 lemma fst_divmod_abs [simp]:
   359   "fst (divmod_abs k l) = \<bar>k\<bar> div \<bar>l\<bar>"
   360   by (simp add: divmod_abs_def)
   361 
   362 lemma snd_divmod_abs [simp]:
   363   "snd (divmod_abs k l) = \<bar>k\<bar> mod \<bar>l\<bar>"
   364   by (simp add: divmod_abs_def)
   365 
   366 lemma divmod_abs_code [code]:
   367   "divmod_abs (Pos k) (Pos l) = divmod k l"
   368   "divmod_abs (Neg k) (Neg l) = divmod k l"
   369   "divmod_abs (Neg k) (Pos l) = divmod k l"
   370   "divmod_abs (Pos k) (Neg l) = divmod k l"
   371   "divmod_abs j 0 = (0, \<bar>j\<bar>)"
   372   "divmod_abs 0 j = (0, 0)"
   373   by (simp_all add: prod_eq_iff)
   374 
   375 lemma divmod_integer_code [code]:
   376   "divmod_integer k l =
   377     (if k = 0 then (0, 0) else if l = 0 then (0, k) else
   378     (apsnd \<circ> times \<circ> sgn) l (if sgn k = sgn l
   379       then divmod_abs k l
   380       else (let (r, s) = divmod_abs k l in
   381         if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
   382 proof -
   383   have aux1: "\<And>k l::int. sgn k = sgn l \<longleftrightarrow> k = 0 \<and> l = 0 \<or> 0 < l \<and> 0 < k \<or> l < 0 \<and> k < 0"
   384     by (auto simp add: sgn_if)
   385   have aux2: "\<And>q::int. - int_of_integer k = int_of_integer l * q \<longleftrightarrow> int_of_integer k = int_of_integer l * - q" by auto
   386   show ?thesis
   387     by (simp add: prod_eq_iff integer_eq_iff case_prod_beta aux1)
   388       (auto simp add: zdiv_zminus1_eq_if zmod_zminus1_eq_if div_minus_right mod_minus_right aux2)
   389 qed
   390 
   391 lemma div_integer_code [code]:
   392   "k div l = fst (divmod_integer k l)"
   393   by simp
   394 
   395 lemma mod_integer_code [code]:
   396   "k mod l = snd (divmod_integer k l)"
   397   by simp
   398 
   399 lemma equal_integer_code [code]:
   400   "HOL.equal 0 (0::integer) \<longleftrightarrow> True"
   401   "HOL.equal 0 (Pos l) \<longleftrightarrow> False"
   402   "HOL.equal 0 (Neg l) \<longleftrightarrow> False"
   403   "HOL.equal (Pos k) 0 \<longleftrightarrow> False"
   404   "HOL.equal (Pos k) (Pos l) \<longleftrightarrow> HOL.equal k l"
   405   "HOL.equal (Pos k) (Neg l) \<longleftrightarrow> False"
   406   "HOL.equal (Neg k) 0 \<longleftrightarrow> False"
   407   "HOL.equal (Neg k) (Pos l) \<longleftrightarrow> False"
   408   "HOL.equal (Neg k) (Neg l) \<longleftrightarrow> HOL.equal k l"
   409   by (simp_all add: equal)
   410 
   411 lemma equal_integer_refl [code nbe]:
   412   "HOL.equal (k::integer) k \<longleftrightarrow> True"
   413   by (fact equal_refl)
   414 
   415 lemma less_eq_integer_code [code]:
   416   "0 \<le> (0::integer) \<longleftrightarrow> True"
   417   "0 \<le> Pos l \<longleftrightarrow> True"
   418   "0 \<le> Neg l \<longleftrightarrow> False"
   419   "Pos k \<le> 0 \<longleftrightarrow> False"
   420   "Pos k \<le> Pos l \<longleftrightarrow> k \<le> l"
   421   "Pos k \<le> Neg l \<longleftrightarrow> False"
   422   "Neg k \<le> 0 \<longleftrightarrow> True"
   423   "Neg k \<le> Pos l \<longleftrightarrow> True"
   424   "Neg k \<le> Neg l \<longleftrightarrow> l \<le> k"
   425   by simp_all
   426 
   427 lemma less_integer_code [code]:
   428   "0 < (0::integer) \<longleftrightarrow> False"
   429   "0 < Pos l \<longleftrightarrow> True"
   430   "0 < Neg l \<longleftrightarrow> False"
   431   "Pos k < 0 \<longleftrightarrow> False"
   432   "Pos k < Pos l \<longleftrightarrow> k < l"
   433   "Pos k < Neg l \<longleftrightarrow> False"
   434   "Neg k < 0 \<longleftrightarrow> True"
   435   "Neg k < Pos l \<longleftrightarrow> True"
   436   "Neg k < Neg l \<longleftrightarrow> l < k"
   437   by simp_all
   438 
   439 lift_definition integer_of_num :: "num \<Rightarrow> integer"
   440   is "numeral :: num \<Rightarrow> int"
   441   .
   442 
   443 lemma integer_of_num [code]:
   444   "integer_of_num num.One = 1"
   445   "integer_of_num (num.Bit0 n) = (let k = integer_of_num n in k + k)"
   446   "integer_of_num (num.Bit1 n) = (let k = integer_of_num n in k + k + 1)"
   447   by (transfer, simp only: numeral.simps Let_def)+
   448 
   449 lift_definition num_of_integer :: "integer \<Rightarrow> num"
   450   is "num_of_nat \<circ> nat"
   451   .
   452 
   453 lemma num_of_integer_code [code]:
   454   "num_of_integer k = (if k \<le> 1 then Num.One
   455      else let
   456        (l, j) = divmod_integer k 2;
   457        l' = num_of_integer l;
   458        l'' = l' + l'
   459      in if j = 0 then l'' else l'' + Num.One)"
   460 proof -
   461   {
   462     assume "int_of_integer k mod 2 = 1"
   463     then have "nat (int_of_integer k mod 2) = nat 1" by simp
   464     moreover assume *: "1 < int_of_integer k"
   465     ultimately have **: "nat (int_of_integer k) mod 2 = 1" by (simp add: nat_mod_distrib)
   466     have "num_of_nat (nat (int_of_integer k)) =
   467       num_of_nat (2 * (nat (int_of_integer k) div 2) + nat (int_of_integer k) mod 2)"
   468       by simp
   469     then have "num_of_nat (nat (int_of_integer k)) =
   470       num_of_nat (nat (int_of_integer k) div 2 + nat (int_of_integer k) div 2 + nat (int_of_integer k) mod 2)"
   471       by (simp add: mult_2)
   472     with ** have "num_of_nat (nat (int_of_integer k)) =
   473       num_of_nat (nat (int_of_integer k) div 2 + nat (int_of_integer k) div 2 + 1)"
   474       by simp
   475   }
   476   note aux = this
   477   show ?thesis
   478     by (auto simp add: num_of_integer_def nat_of_integer_def Let_def case_prod_beta
   479       not_le integer_eq_iff less_eq_integer_def
   480       nat_mult_distrib nat_div_distrib num_of_nat_One num_of_nat_plus_distrib
   481        mult_2 [where 'a=nat] aux add_One)
   482 qed
   483 
   484 lemma nat_of_integer_code [code]:
   485   "nat_of_integer k = (if k \<le> 0 then 0
   486      else let
   487        (l, j) = divmod_integer k 2;
   488        l' = nat_of_integer l;
   489        l'' = l' + l'
   490      in if j = 0 then l'' else l'' + 1)"
   491 proof -
   492   obtain j where "k = integer_of_int j"
   493   proof
   494     show "k = integer_of_int (int_of_integer k)" by simp
   495   qed
   496   moreover have "2 * (j div 2) = j - j mod 2"
   497     by (simp add: zmult_div_cancel mult.commute)
   498   ultimately show ?thesis
   499     by (auto simp add: split_def Let_def mod_integer_def nat_of_integer_def not_le
   500       nat_add_distrib [symmetric] Suc_nat_eq_nat_zadd1)
   501       (auto simp add: mult_2 [symmetric])
   502 qed
   503 
   504 lemma int_of_integer_code [code]:
   505   "int_of_integer k = (if k < 0 then - (int_of_integer (- k))
   506      else if k = 0 then 0
   507      else let
   508        (l, j) = divmod_integer k 2;
   509        l' = 2 * int_of_integer l
   510      in if j = 0 then l' else l' + 1)"
   511   by (auto simp add: split_def Let_def integer_eq_iff zmult_div_cancel)
   512 
   513 lemma integer_of_int_code [code]:
   514   "integer_of_int k = (if k < 0 then - (integer_of_int (- k))
   515      else if k = 0 then 0
   516      else let
   517        (l, j) = divmod_int k 2;
   518        l' = 2 * integer_of_int l
   519      in if j = 0 then l' else l' + 1)"
   520   by (auto simp add: split_def Let_def integer_eq_iff zmult_div_cancel)
   521 
   522 hide_const (open) Pos Neg sub dup divmod_abs
   523 
   524 
   525 subsection {* Serializer setup for target language integers *}
   526 
   527 code_reserved Eval int Integer abs
   528 
   529 code_printing
   530   type_constructor integer \<rightharpoonup>
   531     (SML) "IntInf.int"
   532     and (OCaml) "Big'_int.big'_int"
   533     and (Haskell) "Integer"
   534     and (Scala) "BigInt"
   535     and (Eval) "int"
   536 | class_instance integer :: equal \<rightharpoonup>
   537     (Haskell) -
   538 
   539 code_printing
   540   constant "0::integer" \<rightharpoonup>
   541     (SML) "0"
   542     and (OCaml) "Big'_int.zero'_big'_int"
   543     and (Haskell) "0"
   544     and (Scala) "BigInt(0)"
   545 
   546 setup {*
   547   fold (fn target =>
   548     Numeral.add_code @{const_name Code_Numeral.Pos} I Code_Printer.literal_numeral target
   549     #> Numeral.add_code @{const_name Code_Numeral.Neg} (op ~) Code_Printer.literal_numeral target)
   550     ["SML", "OCaml", "Haskell", "Scala"]
   551 *}
   552 
   553 code_printing
   554   constant "plus :: integer \<Rightarrow> _ \<Rightarrow> _" \<rightharpoonup>
   555     (SML) "IntInf.+ ((_), (_))"
   556     and (OCaml) "Big'_int.add'_big'_int"
   557     and (Haskell) infixl 6 "+"
   558     and (Scala) infixl 7 "+"
   559     and (Eval) infixl 8 "+"
   560 | constant "uminus :: integer \<Rightarrow> _" \<rightharpoonup>
   561     (SML) "IntInf.~"
   562     and (OCaml) "Big'_int.minus'_big'_int"
   563     and (Haskell) "negate"
   564     and (Scala) "!(- _)"
   565     and (Eval) "~/ _"
   566 | constant "minus :: integer \<Rightarrow> _" \<rightharpoonup>
   567     (SML) "IntInf.- ((_), (_))"
   568     and (OCaml) "Big'_int.sub'_big'_int"
   569     and (Haskell) infixl 6 "-"
   570     and (Scala) infixl 7 "-"
   571     and (Eval) infixl 8 "-"
   572 | constant Code_Numeral.dup \<rightharpoonup>
   573     (SML) "IntInf.*/ (2,/ (_))"
   574     and (OCaml) "Big'_int.mult'_big'_int/ (Big'_int.big'_int'_of'_int/ 2)"
   575     and (Haskell) "!(2 * _)"
   576     and (Scala) "!(2 * _)"
   577     and (Eval) "!(2 * _)"
   578 | constant Code_Numeral.sub \<rightharpoonup>
   579     (SML) "!(raise/ Fail/ \"sub\")"
   580     and (OCaml) "failwith/ \"sub\""
   581     and (Haskell) "error/ \"sub\""
   582     and (Scala) "!sys.error(\"sub\")"
   583 | constant "times :: integer \<Rightarrow> _ \<Rightarrow> _" \<rightharpoonup>
   584     (SML) "IntInf.* ((_), (_))"
   585     and (OCaml) "Big'_int.mult'_big'_int"
   586     and (Haskell) infixl 7 "*"
   587     and (Scala) infixl 8 "*"
   588     and (Eval) infixl 9 "*"
   589 | constant Code_Numeral.divmod_abs \<rightharpoonup>
   590     (SML) "IntInf.divMod/ (IntInf.abs _,/ IntInf.abs _)"
   591     and (OCaml) "Big'_int.quomod'_big'_int/ (Big'_int.abs'_big'_int _)/ (Big'_int.abs'_big'_int _)"
   592     and (Haskell) "divMod/ (abs _)/ (abs _)"
   593     and (Scala) "!((k: BigInt) => (l: BigInt) =>/ if (l == 0)/ (BigInt(0), k) else/ (k.abs '/% l.abs))"
   594     and (Eval) "Integer.div'_mod/ (abs _)/ (abs _)"
   595 | constant "HOL.equal :: integer \<Rightarrow> _ \<Rightarrow> bool" \<rightharpoonup>
   596     (SML) "!((_ : IntInf.int) = _)"
   597     and (OCaml) "Big'_int.eq'_big'_int"
   598     and (Haskell) infix 4 "=="
   599     and (Scala) infixl 5 "=="
   600     and (Eval) infixl 6 "="
   601 | constant "less_eq :: integer \<Rightarrow> _ \<Rightarrow> bool" \<rightharpoonup>
   602     (SML) "IntInf.<= ((_), (_))"
   603     and (OCaml) "Big'_int.le'_big'_int"
   604     and (Haskell) infix 4 "<="
   605     and (Scala) infixl 4 "<="
   606     and (Eval) infixl 6 "<="
   607 | constant "less :: integer \<Rightarrow> _ \<Rightarrow> bool" \<rightharpoonup>
   608     (SML) "IntInf.< ((_), (_))"
   609     and (OCaml) "Big'_int.lt'_big'_int"
   610     and (Haskell) infix 4 "<"
   611     and (Scala) infixl 4 "<"
   612     and (Eval) infixl 6 "<"
   613 
   614 code_identifier
   615   code_module Code_Numeral \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   616 
   617 
   618 subsection {* Type of target language naturals *}
   619 
   620 typedef natural = "UNIV \<Colon> nat set"
   621   morphisms nat_of_natural natural_of_nat ..
   622 
   623 setup_lifting (no_code) type_definition_natural
   624 
   625 lemma natural_eq_iff [termination_simp]:
   626   "m = n \<longleftrightarrow> nat_of_natural m = nat_of_natural n"
   627   by transfer rule
   628 
   629 lemma natural_eqI:
   630   "nat_of_natural m = nat_of_natural n \<Longrightarrow> m = n"
   631   using natural_eq_iff [of m n] by simp
   632 
   633 lemma nat_of_natural_of_nat_inverse [simp]:
   634   "nat_of_natural (natural_of_nat n) = n"
   635   by transfer rule
   636 
   637 lemma natural_of_nat_of_natural_inverse [simp]:
   638   "natural_of_nat (nat_of_natural n) = n"
   639   by transfer rule
   640 
   641 instantiation natural :: "{comm_monoid_diff, semiring_1}"
   642 begin
   643 
   644 lift_definition zero_natural :: natural
   645   is "0 :: nat"
   646   .
   647 
   648 declare zero_natural.rep_eq [simp]
   649 
   650 lift_definition one_natural :: natural
   651   is "1 :: nat"
   652   .
   653 
   654 declare one_natural.rep_eq [simp]
   655 
   656 lift_definition plus_natural :: "natural \<Rightarrow> natural \<Rightarrow> natural"
   657   is "plus :: nat \<Rightarrow> nat \<Rightarrow> nat"
   658   .
   659 
   660 declare plus_natural.rep_eq [simp]
   661 
   662 lift_definition minus_natural :: "natural \<Rightarrow> natural \<Rightarrow> natural"
   663   is "minus :: nat \<Rightarrow> nat \<Rightarrow> nat"
   664   .
   665 
   666 declare minus_natural.rep_eq [simp]
   667 
   668 lift_definition times_natural :: "natural \<Rightarrow> natural \<Rightarrow> natural"
   669   is "times :: nat \<Rightarrow> nat \<Rightarrow> nat"
   670   .
   671 
   672 declare times_natural.rep_eq [simp]
   673 
   674 instance proof
   675 qed (transfer, simp add: algebra_simps)+
   676 
   677 end
   678 
   679 lemma [transfer_rule]:
   680   "rel_fun HOL.eq pcr_natural (\<lambda>n::nat. n) (of_nat :: nat \<Rightarrow> natural)"
   681 proof -
   682   have "rel_fun HOL.eq pcr_natural (of_nat :: nat \<Rightarrow> nat) (of_nat :: nat \<Rightarrow> natural)"
   683     by (unfold of_nat_def [abs_def]) transfer_prover
   684   then show ?thesis by (simp add: id_def)
   685 qed
   686 
   687 lemma [transfer_rule]:
   688   "rel_fun HOL.eq pcr_natural (numeral :: num \<Rightarrow> nat) (numeral :: num \<Rightarrow> natural)"
   689 proof -
   690   have "rel_fun HOL.eq pcr_natural (numeral :: num \<Rightarrow> nat) (\<lambda>n. of_nat (numeral n))"
   691     by transfer_prover
   692   then show ?thesis by simp
   693 qed
   694 
   695 lemma nat_of_natural_of_nat [simp]:
   696   "nat_of_natural (of_nat n) = n"
   697   by transfer rule
   698 
   699 lemma natural_of_nat_of_nat [simp, code_abbrev]:
   700   "natural_of_nat = of_nat"
   701   by transfer rule
   702 
   703 lemma of_nat_of_natural [simp]:
   704   "of_nat (nat_of_natural n) = n"
   705   by transfer rule
   706 
   707 lemma nat_of_natural_numeral [simp]:
   708   "nat_of_natural (numeral k) = numeral k"
   709   by transfer rule
   710 
   711 instantiation natural :: "{semiring_div, equal, linordered_semiring}"
   712 begin
   713 
   714 lift_definition div_natural :: "natural \<Rightarrow> natural \<Rightarrow> natural"
   715   is "Divides.div :: nat \<Rightarrow> nat \<Rightarrow> nat"
   716   .
   717 
   718 declare div_natural.rep_eq [simp]
   719 
   720 lift_definition mod_natural :: "natural \<Rightarrow> natural \<Rightarrow> natural"
   721   is "Divides.mod :: nat \<Rightarrow> nat \<Rightarrow> nat"
   722   .
   723 
   724 declare mod_natural.rep_eq [simp]
   725 
   726 lift_definition less_eq_natural :: "natural \<Rightarrow> natural \<Rightarrow> bool"
   727   is "less_eq :: nat \<Rightarrow> nat \<Rightarrow> bool"
   728   .
   729 
   730 declare less_eq_natural.rep_eq [termination_simp]
   731 
   732 lift_definition less_natural :: "natural \<Rightarrow> natural \<Rightarrow> bool"
   733   is "less :: nat \<Rightarrow> nat \<Rightarrow> bool"
   734   .
   735 
   736 declare less_natural.rep_eq [termination_simp]
   737 
   738 lift_definition equal_natural :: "natural \<Rightarrow> natural \<Rightarrow> bool"
   739   is "HOL.equal :: nat \<Rightarrow> nat \<Rightarrow> bool"
   740   .
   741 
   742 instance proof
   743 qed (transfer, simp add: algebra_simps equal less_le_not_le [symmetric] linear)+
   744 
   745 end
   746 
   747 lemma [transfer_rule]:
   748   "rel_fun pcr_natural (rel_fun pcr_natural pcr_natural) (min :: _ \<Rightarrow> _ \<Rightarrow> nat) (min :: _ \<Rightarrow> _ \<Rightarrow> natural)"
   749   by (unfold min_def [abs_def]) transfer_prover
   750 
   751 lemma [transfer_rule]:
   752   "rel_fun pcr_natural (rel_fun pcr_natural pcr_natural) (max :: _ \<Rightarrow> _ \<Rightarrow> nat) (max :: _ \<Rightarrow> _ \<Rightarrow> natural)"
   753   by (unfold max_def [abs_def]) transfer_prover
   754 
   755 lemma nat_of_natural_min [simp]:
   756   "nat_of_natural (min k l) = min (nat_of_natural k) (nat_of_natural l)"
   757   by transfer rule
   758 
   759 lemma nat_of_natural_max [simp]:
   760   "nat_of_natural (max k l) = max (nat_of_natural k) (nat_of_natural l)"
   761   by transfer rule
   762 
   763 lift_definition natural_of_integer :: "integer \<Rightarrow> natural"
   764   is "nat :: int \<Rightarrow> nat"
   765   .
   766 
   767 lift_definition integer_of_natural :: "natural \<Rightarrow> integer"
   768   is "of_nat :: nat \<Rightarrow> int"
   769   .
   770 
   771 lemma natural_of_integer_of_natural [simp]:
   772   "natural_of_integer (integer_of_natural n) = n"
   773   by transfer simp
   774 
   775 lemma integer_of_natural_of_integer [simp]:
   776   "integer_of_natural (natural_of_integer k) = max 0 k"
   777   by transfer auto
   778 
   779 lemma int_of_integer_of_natural [simp]:
   780   "int_of_integer (integer_of_natural n) = of_nat (nat_of_natural n)"
   781   by transfer rule
   782 
   783 lemma integer_of_natural_of_nat [simp]:
   784   "integer_of_natural (of_nat n) = of_nat n"
   785   by transfer rule
   786 
   787 lemma [measure_function]:
   788   "is_measure nat_of_natural"
   789   by (rule is_measure_trivial)
   790 
   791 
   792 subsection {* Inductive representation of target language naturals *}
   793 
   794 lift_definition Suc :: "natural \<Rightarrow> natural"
   795   is Nat.Suc
   796   .
   797 
   798 declare Suc.rep_eq [simp]
   799 
   800 old_rep_datatype "0::natural" Suc
   801   by (transfer, fact nat.induct nat.inject nat.distinct)+
   802 
   803 lemma natural_cases [case_names nat, cases type: natural]:
   804   fixes m :: natural
   805   assumes "\<And>n. m = of_nat n \<Longrightarrow> P"
   806   shows P
   807   using assms by transfer blast
   808 
   809 lemma [simp, code]: "size_natural = nat_of_natural"
   810 proof (rule ext)
   811   fix n
   812   show "size_natural n = nat_of_natural n"
   813     by (induct n) simp_all
   814 qed
   815 
   816 lemma [simp, code]: "size = nat_of_natural"
   817 proof (rule ext)
   818   fix n
   819   show "size n = nat_of_natural n"
   820     by (induct n) simp_all
   821 qed
   822 
   823 lemma natural_decr [termination_simp]:
   824   "n \<noteq> 0 \<Longrightarrow> nat_of_natural n - Nat.Suc 0 < nat_of_natural n"
   825   by transfer simp
   826 
   827 lemma natural_zero_minus_one: "(0::natural) - 1 = 0"
   828   by (rule zero_diff)
   829 
   830 lemma Suc_natural_minus_one: "Suc n - 1 = n"
   831   by transfer simp
   832 
   833 hide_const (open) Suc
   834 
   835 
   836 subsection {* Code refinement for target language naturals *}
   837 
   838 lift_definition Nat :: "integer \<Rightarrow> natural"
   839   is nat
   840   .
   841 
   842 lemma [code_post]:
   843   "Nat 0 = 0"
   844   "Nat 1 = 1"
   845   "Nat (numeral k) = numeral k"
   846   by (transfer, simp)+
   847 
   848 lemma [code abstype]:
   849   "Nat (integer_of_natural n) = n"
   850   by transfer simp
   851 
   852 lemma [code abstract]:
   853   "integer_of_natural (natural_of_nat n) = of_nat n"
   854   by simp
   855 
   856 lemma [code abstract]:
   857   "integer_of_natural (natural_of_integer k) = max 0 k"
   858   by simp
   859 
   860 lemma [code_abbrev]:
   861   "natural_of_integer (Code_Numeral.Pos k) = numeral k"
   862   by transfer simp
   863 
   864 lemma [code abstract]:
   865   "integer_of_natural 0 = 0"
   866   by transfer simp
   867 
   868 lemma [code abstract]:
   869   "integer_of_natural 1 = 1"
   870   by transfer simp
   871 
   872 lemma [code abstract]:
   873   "integer_of_natural (Code_Numeral.Suc n) = integer_of_natural n + 1"
   874   by transfer simp
   875 
   876 lemma [code]:
   877   "nat_of_natural = nat_of_integer \<circ> integer_of_natural"
   878   by transfer (simp add: fun_eq_iff)
   879 
   880 lemma [code, code_unfold]:
   881   "case_natural f g n = (if n = 0 then f else g (n - 1))"
   882   by (cases n rule: natural.exhaust) (simp_all, simp add: Suc_def)
   883 
   884 declare natural.rec [code del]
   885 
   886 lemma [code abstract]:
   887   "integer_of_natural (m + n) = integer_of_natural m + integer_of_natural n"
   888   by transfer simp
   889 
   890 lemma [code abstract]:
   891   "integer_of_natural (m - n) = max 0 (integer_of_natural m - integer_of_natural n)"
   892   by transfer simp
   893 
   894 lemma [code abstract]:
   895   "integer_of_natural (m * n) = integer_of_natural m * integer_of_natural n"
   896   by transfer (simp add: of_nat_mult)
   897 
   898 lemma [code abstract]:
   899   "integer_of_natural (m div n) = integer_of_natural m div integer_of_natural n"
   900   by transfer (simp add: zdiv_int)
   901 
   902 lemma [code abstract]:
   903   "integer_of_natural (m mod n) = integer_of_natural m mod integer_of_natural n"
   904   by transfer (simp add: zmod_int)
   905 
   906 lemma [code]:
   907   "HOL.equal m n \<longleftrightarrow> HOL.equal (integer_of_natural m) (integer_of_natural n)"
   908   by transfer (simp add: equal)
   909 
   910 lemma [code nbe]: "HOL.equal n (n::natural) \<longleftrightarrow> True"
   911   by (rule equal_class.equal_refl)
   912 
   913 lemma [code]: "m \<le> n \<longleftrightarrow> integer_of_natural m \<le> integer_of_natural n"
   914   by transfer simp
   915 
   916 lemma [code]: "m < n \<longleftrightarrow> integer_of_natural m < integer_of_natural n"
   917   by transfer simp
   918 
   919 hide_const (open) Nat
   920 
   921 lifting_update integer.lifting
   922 lifting_forget integer.lifting
   923 
   924 lifting_update natural.lifting
   925 lifting_forget natural.lifting
   926 
   927 code_reflect Code_Numeral
   928   datatypes natural = _
   929   functions integer_of_natural natural_of_integer
   930 
   931 end