src/HOL/Deriv.thy
author hoelzl
Thu Feb 05 11:34:42 2009 +0100 (2009-02-05)
changeset 29803 c56a5571f60a
parent 29667 53103fc8ffa3
child 29975 28c5322f0df3
child 30240 5b25fee0362c
permissions -rw-r--r--
Added derivation lemmas for power series and theorems for the pi, arcus tangens and logarithm series
     1 (*  Title       : Deriv.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6     GMVT by Benjamin Porter, 2005
     7 *)
     8 
     9 header{* Differentiation *}
    10 
    11 theory Deriv
    12 imports Lim Polynomial
    13 begin
    14 
    15 text{*Standard Definitions*}
    16 
    17 definition
    18   deriv :: "['a::real_normed_field \<Rightarrow> 'a, 'a, 'a] \<Rightarrow> bool"
    19     --{*Differentiation: D is derivative of function f at x*}
    20           ("(DERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60) where
    21   "DERIV f x :> D = ((%h. (f(x + h) - f x) / h) -- 0 --> D)"
    22 
    23 consts
    24   Bolzano_bisect :: "[real*real=>bool, real, real, nat] => (real*real)"
    25 primrec
    26   "Bolzano_bisect P a b 0 = (a,b)"
    27   "Bolzano_bisect P a b (Suc n) =
    28       (let (x,y) = Bolzano_bisect P a b n
    29        in if P(x, (x+y)/2) then ((x+y)/2, y)
    30                             else (x, (x+y)/2))"
    31 
    32 
    33 subsection {* Derivatives *}
    34 
    35 lemma DERIV_iff: "(DERIV f x :> D) = ((%h. (f(x + h) - f(x))/h) -- 0 --> D)"
    36 by (simp add: deriv_def)
    37 
    38 lemma DERIV_D: "DERIV f x :> D ==> (%h. (f(x + h) - f(x))/h) -- 0 --> D"
    39 by (simp add: deriv_def)
    40 
    41 lemma DERIV_const [simp]: "DERIV (\<lambda>x. k) x :> 0"
    42 by (simp add: deriv_def)
    43 
    44 lemma DERIV_ident [simp]: "DERIV (\<lambda>x. x) x :> 1"
    45 by (simp add: deriv_def cong: LIM_cong)
    46 
    47 lemma add_diff_add:
    48   fixes a b c d :: "'a::ab_group_add"
    49   shows "(a + c) - (b + d) = (a - b) + (c - d)"
    50 by simp
    51 
    52 lemma DERIV_add:
    53   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x + g x) x :> D + E"
    54 by (simp only: deriv_def add_diff_add add_divide_distrib LIM_add)
    55 
    56 lemma DERIV_minus:
    57   "DERIV f x :> D \<Longrightarrow> DERIV (\<lambda>x. - f x) x :> - D"
    58 by (simp only: deriv_def minus_diff_minus divide_minus_left LIM_minus)
    59 
    60 lemma DERIV_diff:
    61   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x - g x) x :> D - E"
    62 by (simp only: diff_def DERIV_add DERIV_minus)
    63 
    64 lemma DERIV_add_minus:
    65   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x + - g x) x :> D + - E"
    66 by (simp only: DERIV_add DERIV_minus)
    67 
    68 lemma DERIV_isCont: "DERIV f x :> D \<Longrightarrow> isCont f x"
    69 proof (unfold isCont_iff)
    70   assume "DERIV f x :> D"
    71   hence "(\<lambda>h. (f(x+h) - f(x)) / h) -- 0 --> D"
    72     by (rule DERIV_D)
    73   hence "(\<lambda>h. (f(x+h) - f(x)) / h * h) -- 0 --> D * 0"
    74     by (intro LIM_mult LIM_ident)
    75   hence "(\<lambda>h. (f(x+h) - f(x)) * (h / h)) -- 0 --> 0"
    76     by simp
    77   hence "(\<lambda>h. f(x+h) - f(x)) -- 0 --> 0"
    78     by (simp cong: LIM_cong)
    79   thus "(\<lambda>h. f(x+h)) -- 0 --> f(x)"
    80     by (simp add: LIM_def)
    81 qed
    82 
    83 lemma DERIV_mult_lemma:
    84   fixes a b c d :: "'a::real_field"
    85   shows "(a * b - c * d) / h = a * ((b - d) / h) + ((a - c) / h) * d"
    86 by (simp add: diff_minus add_divide_distrib [symmetric] ring_distribs)
    87 
    88 lemma DERIV_mult':
    89   assumes f: "DERIV f x :> D"
    90   assumes g: "DERIV g x :> E"
    91   shows "DERIV (\<lambda>x. f x * g x) x :> f x * E + D * g x"
    92 proof (unfold deriv_def)
    93   from f have "isCont f x"
    94     by (rule DERIV_isCont)
    95   hence "(\<lambda>h. f(x+h)) -- 0 --> f x"
    96     by (simp only: isCont_iff)
    97   hence "(\<lambda>h. f(x+h) * ((g(x+h) - g x) / h) +
    98               ((f(x+h) - f x) / h) * g x)
    99           -- 0 --> f x * E + D * g x"
   100     by (intro LIM_add LIM_mult LIM_const DERIV_D f g)
   101   thus "(\<lambda>h. (f(x+h) * g(x+h) - f x * g x) / h)
   102          -- 0 --> f x * E + D * g x"
   103     by (simp only: DERIV_mult_lemma)
   104 qed
   105 
   106 lemma DERIV_mult:
   107      "[| DERIV f x :> Da; DERIV g x :> Db |]
   108       ==> DERIV (%x. f x * g x) x :> (Da * g(x)) + (Db * f(x))"
   109 by (drule (1) DERIV_mult', simp only: mult_commute add_commute)
   110 
   111 lemma DERIV_unique:
   112       "[| DERIV f x :> D; DERIV f x :> E |] ==> D = E"
   113 apply (simp add: deriv_def)
   114 apply (blast intro: LIM_unique)
   115 done
   116 
   117 text{*Differentiation of finite sum*}
   118 
   119 lemma DERIV_sumr [rule_format (no_asm)]:
   120      "(\<forall>r. m \<le> r & r < (m + n) --> DERIV (%x. f r x) x :> (f' r x))
   121       --> DERIV (%x. \<Sum>n=m..<n::nat. f n x :: real) x :> (\<Sum>r=m..<n. f' r x)"
   122 apply (induct "n")
   123 apply (auto intro: DERIV_add)
   124 done
   125 
   126 text{*Alternative definition for differentiability*}
   127 
   128 lemma DERIV_LIM_iff:
   129      "((%h. (f(a + h) - f(a)) / h) -- 0 --> D) =
   130       ((%x. (f(x)-f(a)) / (x-a)) -- a --> D)"
   131 apply (rule iffI)
   132 apply (drule_tac k="- a" in LIM_offset)
   133 apply (simp add: diff_minus)
   134 apply (drule_tac k="a" in LIM_offset)
   135 apply (simp add: add_commute)
   136 done
   137 
   138 lemma DERIV_iff2: "(DERIV f x :> D) = ((%z. (f(z) - f(x)) / (z-x)) -- x --> D)"
   139 by (simp add: deriv_def diff_minus [symmetric] DERIV_LIM_iff)
   140 
   141 lemma inverse_diff_inverse:
   142   "\<lbrakk>(a::'a::division_ring) \<noteq> 0; b \<noteq> 0\<rbrakk>
   143    \<Longrightarrow> inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
   144 by (simp add: algebra_simps)
   145 
   146 lemma DERIV_inverse_lemma:
   147   "\<lbrakk>a \<noteq> 0; b \<noteq> (0::'a::real_normed_field)\<rbrakk>
   148    \<Longrightarrow> (inverse a - inverse b) / h
   149      = - (inverse a * ((a - b) / h) * inverse b)"
   150 by (simp add: inverse_diff_inverse)
   151 
   152 lemma DERIV_inverse':
   153   assumes der: "DERIV f x :> D"
   154   assumes neq: "f x \<noteq> 0"
   155   shows "DERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x) * D * inverse (f x))"
   156     (is "DERIV _ _ :> ?E")
   157 proof (unfold DERIV_iff2)
   158   from der have lim_f: "f -- x --> f x"
   159     by (rule DERIV_isCont [unfolded isCont_def])
   160 
   161   from neq have "0 < norm (f x)" by simp
   162   with LIM_D [OF lim_f] obtain s
   163     where s: "0 < s"
   164     and less_fx: "\<And>z. \<lbrakk>z \<noteq> x; norm (z - x) < s\<rbrakk>
   165                   \<Longrightarrow> norm (f z - f x) < norm (f x)"
   166     by fast
   167 
   168   show "(\<lambda>z. (inverse (f z) - inverse (f x)) / (z - x)) -- x --> ?E"
   169   proof (rule LIM_equal2 [OF s])
   170     fix z
   171     assume "z \<noteq> x" "norm (z - x) < s"
   172     hence "norm (f z - f x) < norm (f x)" by (rule less_fx)
   173     hence "f z \<noteq> 0" by auto
   174     thus "(inverse (f z) - inverse (f x)) / (z - x) =
   175           - (inverse (f z) * ((f z - f x) / (z - x)) * inverse (f x))"
   176       using neq by (rule DERIV_inverse_lemma)
   177   next
   178     from der have "(\<lambda>z. (f z - f x) / (z - x)) -- x --> D"
   179       by (unfold DERIV_iff2)
   180     thus "(\<lambda>z. - (inverse (f z) * ((f z - f x) / (z - x)) * inverse (f x)))
   181           -- x --> ?E"
   182       by (intro LIM_mult LIM_inverse LIM_minus LIM_const lim_f neq)
   183   qed
   184 qed
   185 
   186 lemma DERIV_divide:
   187   "\<lbrakk>DERIV f x :> D; DERIV g x :> E; g x \<noteq> 0\<rbrakk>
   188    \<Longrightarrow> DERIV (\<lambda>x. f x / g x) x :> (D * g x - f x * E) / (g x * g x)"
   189 apply (subgoal_tac "f x * - (inverse (g x) * E * inverse (g x)) +
   190           D * inverse (g x) = (D * g x - f x * E) / (g x * g x)")
   191 apply (erule subst)
   192 apply (unfold divide_inverse)
   193 apply (erule DERIV_mult')
   194 apply (erule (1) DERIV_inverse')
   195 apply (simp add: ring_distribs nonzero_inverse_mult_distrib)
   196 apply (simp add: mult_ac)
   197 done
   198 
   199 lemma DERIV_power_Suc:
   200   fixes f :: "'a \<Rightarrow> 'a::{real_normed_field,recpower}"
   201   assumes f: "DERIV f x :> D"
   202   shows "DERIV (\<lambda>x. f x ^ Suc n) x :> (1 + of_nat n) * (D * f x ^ n)"
   203 proof (induct n)
   204 case 0
   205   show ?case by (simp add: power_Suc f)
   206 case (Suc k)
   207   from DERIV_mult' [OF f Suc] show ?case
   208     apply (simp only: of_nat_Suc ring_distribs mult_1_left)
   209     apply (simp only: power_Suc algebra_simps)
   210     done
   211 qed
   212 
   213 lemma DERIV_power:
   214   fixes f :: "'a \<Rightarrow> 'a::{real_normed_field,recpower}"
   215   assumes f: "DERIV f x :> D"
   216   shows "DERIV (\<lambda>x. f x ^ n) x :> of_nat n * (D * f x ^ (n - Suc 0))"
   217 by (cases "n", simp, simp add: DERIV_power_Suc f)
   218 
   219 
   220 (* ------------------------------------------------------------------------ *)
   221 (* Caratheodory formulation of derivative at a point: standard proof        *)
   222 (* ------------------------------------------------------------------------ *)
   223 
   224 lemma CARAT_DERIV:
   225      "(DERIV f x :> l) =
   226       (\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) & isCont g x & g x = l)"
   227       (is "?lhs = ?rhs")
   228 proof
   229   assume der: "DERIV f x :> l"
   230   show "\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) \<and> isCont g x \<and> g x = l"
   231   proof (intro exI conjI)
   232     let ?g = "(%z. if z = x then l else (f z - f x) / (z-x))"
   233     show "\<forall>z. f z - f x = ?g z * (z-x)" by simp
   234     show "isCont ?g x" using der
   235       by (simp add: isCont_iff DERIV_iff diff_minus
   236                cong: LIM_equal [rule_format])
   237     show "?g x = l" by simp
   238   qed
   239 next
   240   assume "?rhs"
   241   then obtain g where
   242     "(\<forall>z. f z - f x = g z * (z-x))" and "isCont g x" and "g x = l" by blast
   243   thus "(DERIV f x :> l)"
   244      by (auto simp add: isCont_iff DERIV_iff cong: LIM_cong)
   245 qed
   246 
   247 lemma DERIV_chain':
   248   assumes f: "DERIV f x :> D"
   249   assumes g: "DERIV g (f x) :> E"
   250   shows "DERIV (\<lambda>x. g (f x)) x :> E * D"
   251 proof (unfold DERIV_iff2)
   252   obtain d where d: "\<forall>y. g y - g (f x) = d y * (y - f x)"
   253     and cont_d: "isCont d (f x)" and dfx: "d (f x) = E"
   254     using CARAT_DERIV [THEN iffD1, OF g] by fast
   255   from f have "f -- x --> f x"
   256     by (rule DERIV_isCont [unfolded isCont_def])
   257   with cont_d have "(\<lambda>z. d (f z)) -- x --> d (f x)"
   258     by (rule isCont_LIM_compose)
   259   hence "(\<lambda>z. d (f z) * ((f z - f x) / (z - x)))
   260           -- x --> d (f x) * D"
   261     by (rule LIM_mult [OF _ f [unfolded DERIV_iff2]])
   262   thus "(\<lambda>z. (g (f z) - g (f x)) / (z - x)) -- x --> E * D"
   263     by (simp add: d dfx real_scaleR_def)
   264 qed
   265 
   266 (* let's do the standard proof though theorem *)
   267 (* LIM_mult2 follows from a NS proof          *)
   268 
   269 lemma DERIV_cmult:
   270       "DERIV f x :> D ==> DERIV (%x. c * f x) x :> c*D"
   271 by (drule DERIV_mult' [OF DERIV_const], simp)
   272 
   273 (* standard version *)
   274 lemma DERIV_chain: "[| DERIV f (g x) :> Da; DERIV g x :> Db |] ==> DERIV (f o g) x :> Da * Db"
   275 by (drule (1) DERIV_chain', simp add: o_def real_scaleR_def mult_commute)
   276 
   277 lemma DERIV_chain2: "[| DERIV f (g x) :> Da; DERIV g x :> Db |] ==> DERIV (%x. f (g x)) x :> Da * Db"
   278 by (auto dest: DERIV_chain simp add: o_def)
   279 
   280 (*derivative of linear multiplication*)
   281 lemma DERIV_cmult_Id [simp]: "DERIV (op * c) x :> c"
   282 by (cut_tac c = c and x = x in DERIV_ident [THEN DERIV_cmult], simp)
   283 
   284 lemma DERIV_pow: "DERIV (%x. x ^ n) x :> real n * (x ^ (n - Suc 0))"
   285 apply (cut_tac DERIV_power [OF DERIV_ident])
   286 apply (simp add: real_scaleR_def real_of_nat_def)
   287 done
   288 
   289 text{*Power of -1*}
   290 
   291 lemma DERIV_inverse:
   292   fixes x :: "'a::{real_normed_field,recpower}"
   293   shows "x \<noteq> 0 ==> DERIV (%x. inverse(x)) x :> (-(inverse x ^ Suc (Suc 0)))"
   294 by (drule DERIV_inverse' [OF DERIV_ident]) (simp add: power_Suc)
   295 
   296 text{*Derivative of inverse*}
   297 lemma DERIV_inverse_fun:
   298   fixes x :: "'a::{real_normed_field,recpower}"
   299   shows "[| DERIV f x :> d; f(x) \<noteq> 0 |]
   300       ==> DERIV (%x. inverse(f x)) x :> (- (d * inverse(f(x) ^ Suc (Suc 0))))"
   301 by (drule (1) DERIV_inverse') (simp add: mult_ac power_Suc nonzero_inverse_mult_distrib)
   302 
   303 text{*Derivative of quotient*}
   304 lemma DERIV_quotient:
   305   fixes x :: "'a::{real_normed_field,recpower}"
   306   shows "[| DERIV f x :> d; DERIV g x :> e; g(x) \<noteq> 0 |]
   307        ==> DERIV (%y. f(y) / (g y)) x :> (d*g(x) - (e*f(x))) / (g(x) ^ Suc (Suc 0))"
   308 by (drule (2) DERIV_divide) (simp add: mult_commute power_Suc)
   309 
   310 
   311 subsection {* Differentiability predicate *}
   312 
   313 definition
   314   differentiable :: "['a::real_normed_field \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
   315     (infixl "differentiable" 60) where
   316   "f differentiable x = (\<exists>D. DERIV f x :> D)"
   317 
   318 lemma differentiableE [elim?]:
   319   assumes "f differentiable x"
   320   obtains df where "DERIV f x :> df"
   321   using prems unfolding differentiable_def ..
   322 
   323 lemma differentiableD: "f differentiable x ==> \<exists>D. DERIV f x :> D"
   324 by (simp add: differentiable_def)
   325 
   326 lemma differentiableI: "DERIV f x :> D ==> f differentiable x"
   327 by (force simp add: differentiable_def)
   328 
   329 lemma differentiable_ident [simp]: "(\<lambda>x. x) differentiable x"
   330   by (rule DERIV_ident [THEN differentiableI])
   331 
   332 lemma differentiable_const [simp]: "(\<lambda>z. a) differentiable x"
   333   by (rule DERIV_const [THEN differentiableI])
   334 
   335 lemma differentiable_compose:
   336   assumes f: "f differentiable (g x)"
   337   assumes g: "g differentiable x"
   338   shows "(\<lambda>x. f (g x)) differentiable x"
   339 proof -
   340   from `f differentiable (g x)` obtain df where "DERIV f (g x) :> df" ..
   341   moreover
   342   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   343   ultimately
   344   have "DERIV (\<lambda>x. f (g x)) x :> df * dg" by (rule DERIV_chain2)
   345   thus ?thesis by (rule differentiableI)
   346 qed
   347 
   348 lemma differentiable_sum [simp]:
   349   assumes "f differentiable x"
   350   and "g differentiable x"
   351   shows "(\<lambda>x. f x + g x) differentiable x"
   352 proof -
   353   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   354   moreover
   355   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   356   ultimately
   357   have "DERIV (\<lambda>x. f x + g x) x :> df + dg" by (rule DERIV_add)
   358   thus ?thesis by (rule differentiableI)
   359 qed
   360 
   361 lemma differentiable_minus [simp]:
   362   assumes "f differentiable x"
   363   shows "(\<lambda>x. - f x) differentiable x"
   364 proof -
   365   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   366   hence "DERIV (\<lambda>x. - f x) x :> - df" by (rule DERIV_minus)
   367   thus ?thesis by (rule differentiableI)
   368 qed
   369 
   370 lemma differentiable_diff [simp]:
   371   assumes "f differentiable x"
   372   assumes "g differentiable x"
   373   shows "(\<lambda>x. f x - g x) differentiable x"
   374   unfolding diff_minus using prems by simp
   375 
   376 lemma differentiable_mult [simp]:
   377   assumes "f differentiable x"
   378   assumes "g differentiable x"
   379   shows "(\<lambda>x. f x * g x) differentiable x"
   380 proof -
   381   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   382   moreover
   383   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   384   ultimately
   385   have "DERIV (\<lambda>x. f x * g x) x :> df * g x + dg * f x" by (rule DERIV_mult)
   386   thus ?thesis by (rule differentiableI)
   387 qed
   388 
   389 lemma differentiable_inverse [simp]:
   390   assumes "f differentiable x" and "f x \<noteq> 0"
   391   shows "(\<lambda>x. inverse (f x)) differentiable x"
   392 proof -
   393   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   394   hence "DERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x) * df * inverse (f x))"
   395     using `f x \<noteq> 0` by (rule DERIV_inverse')
   396   thus ?thesis by (rule differentiableI)
   397 qed
   398 
   399 lemma differentiable_divide [simp]:
   400   assumes "f differentiable x"
   401   assumes "g differentiable x" and "g x \<noteq> 0"
   402   shows "(\<lambda>x. f x / g x) differentiable x"
   403   unfolding divide_inverse using prems by simp
   404 
   405 lemma differentiable_power [simp]:
   406   fixes f :: "'a::{recpower,real_normed_field} \<Rightarrow> 'a"
   407   assumes "f differentiable x"
   408   shows "(\<lambda>x. f x ^ n) differentiable x"
   409   by (induct n, simp, simp add: power_Suc prems)
   410 
   411 
   412 subsection {* Nested Intervals and Bisection *}
   413 
   414 text{*Lemmas about nested intervals and proof by bisection (cf.Harrison).
   415      All considerably tidied by lcp.*}
   416 
   417 lemma lemma_f_mono_add [rule_format (no_asm)]: "(\<forall>n. (f::nat=>real) n \<le> f (Suc n)) --> f m \<le> f(m + no)"
   418 apply (induct "no")
   419 apply (auto intro: order_trans)
   420 done
   421 
   422 lemma f_inc_g_dec_Beq_f: "[| \<forall>n. f(n) \<le> f(Suc n);
   423          \<forall>n. g(Suc n) \<le> g(n);
   424          \<forall>n. f(n) \<le> g(n) |]
   425       ==> Bseq (f :: nat \<Rightarrow> real)"
   426 apply (rule_tac k = "f 0" and K = "g 0" in BseqI2, rule allI)
   427 apply (induct_tac "n")
   428 apply (auto intro: order_trans)
   429 apply (rule_tac y = "g (Suc na)" in order_trans)
   430 apply (induct_tac [2] "na")
   431 apply (auto intro: order_trans)
   432 done
   433 
   434 lemma f_inc_g_dec_Beq_g: "[| \<forall>n. f(n) \<le> f(Suc n);
   435          \<forall>n. g(Suc n) \<le> g(n);
   436          \<forall>n. f(n) \<le> g(n) |]
   437       ==> Bseq (g :: nat \<Rightarrow> real)"
   438 apply (subst Bseq_minus_iff [symmetric])
   439 apply (rule_tac g = "%x. - (f x)" in f_inc_g_dec_Beq_f)
   440 apply auto
   441 done
   442 
   443 lemma f_inc_imp_le_lim:
   444   fixes f :: "nat \<Rightarrow> real"
   445   shows "\<lbrakk>\<forall>n. f n \<le> f (Suc n); convergent f\<rbrakk> \<Longrightarrow> f n \<le> lim f"
   446 apply (rule linorder_not_less [THEN iffD1])
   447 apply (auto simp add: convergent_LIMSEQ_iff LIMSEQ_iff monoseq_Suc)
   448 apply (drule real_less_sum_gt_zero)
   449 apply (drule_tac x = "f n + - lim f" in spec, safe)
   450 apply (drule_tac P = "%na. no\<le>na --> ?Q na" and x = "no + n" in spec, auto)
   451 apply (subgoal_tac "lim f \<le> f (no + n) ")
   452 apply (drule_tac no=no and m=n in lemma_f_mono_add)
   453 apply (auto simp add: add_commute)
   454 apply (induct_tac "no")
   455 apply simp
   456 apply (auto intro: order_trans simp add: diff_minus abs_if)
   457 done
   458 
   459 lemma lim_uminus: "convergent g ==> lim (%x. - g x) = - (lim g)"
   460 apply (rule LIMSEQ_minus [THEN limI])
   461 apply (simp add: convergent_LIMSEQ_iff)
   462 done
   463 
   464 lemma g_dec_imp_lim_le:
   465   fixes g :: "nat \<Rightarrow> real"
   466   shows "\<lbrakk>\<forall>n. g (Suc n) \<le> g(n); convergent g\<rbrakk> \<Longrightarrow> lim g \<le> g n"
   467 apply (subgoal_tac "- (g n) \<le> - (lim g) ")
   468 apply (cut_tac [2] f = "%x. - (g x)" in f_inc_imp_le_lim)
   469 apply (auto simp add: lim_uminus convergent_minus_iff [symmetric])
   470 done
   471 
   472 lemma lemma_nest: "[| \<forall>n. f(n) \<le> f(Suc n);
   473          \<forall>n. g(Suc n) \<le> g(n);
   474          \<forall>n. f(n) \<le> g(n) |]
   475       ==> \<exists>l m :: real. l \<le> m &  ((\<forall>n. f(n) \<le> l) & f ----> l) &
   476                             ((\<forall>n. m \<le> g(n)) & g ----> m)"
   477 apply (subgoal_tac "monoseq f & monoseq g")
   478 prefer 2 apply (force simp add: LIMSEQ_iff monoseq_Suc)
   479 apply (subgoal_tac "Bseq f & Bseq g")
   480 prefer 2 apply (blast intro: f_inc_g_dec_Beq_f f_inc_g_dec_Beq_g)
   481 apply (auto dest!: Bseq_monoseq_convergent simp add: convergent_LIMSEQ_iff)
   482 apply (rule_tac x = "lim f" in exI)
   483 apply (rule_tac x = "lim g" in exI)
   484 apply (auto intro: LIMSEQ_le)
   485 apply (auto simp add: f_inc_imp_le_lim g_dec_imp_lim_le convergent_LIMSEQ_iff)
   486 done
   487 
   488 lemma lemma_nest_unique: "[| \<forall>n. f(n) \<le> f(Suc n);
   489          \<forall>n. g(Suc n) \<le> g(n);
   490          \<forall>n. f(n) \<le> g(n);
   491          (%n. f(n) - g(n)) ----> 0 |]
   492       ==> \<exists>l::real. ((\<forall>n. f(n) \<le> l) & f ----> l) &
   493                 ((\<forall>n. l \<le> g(n)) & g ----> l)"
   494 apply (drule lemma_nest, auto)
   495 apply (subgoal_tac "l = m")
   496 apply (drule_tac [2] X = f in LIMSEQ_diff)
   497 apply (auto intro: LIMSEQ_unique)
   498 done
   499 
   500 text{*The universal quantifiers below are required for the declaration
   501   of @{text Bolzano_nest_unique} below.*}
   502 
   503 lemma Bolzano_bisect_le:
   504  "a \<le> b ==> \<forall>n. fst (Bolzano_bisect P a b n) \<le> snd (Bolzano_bisect P a b n)"
   505 apply (rule allI)
   506 apply (induct_tac "n")
   507 apply (auto simp add: Let_def split_def)
   508 done
   509 
   510 lemma Bolzano_bisect_fst_le_Suc: "a \<le> b ==>
   511    \<forall>n. fst(Bolzano_bisect P a b n) \<le> fst (Bolzano_bisect P a b (Suc n))"
   512 apply (rule allI)
   513 apply (induct_tac "n")
   514 apply (auto simp add: Bolzano_bisect_le Let_def split_def)
   515 done
   516 
   517 lemma Bolzano_bisect_Suc_le_snd: "a \<le> b ==>
   518    \<forall>n. snd(Bolzano_bisect P a b (Suc n)) \<le> snd (Bolzano_bisect P a b n)"
   519 apply (rule allI)
   520 apply (induct_tac "n")
   521 apply (auto simp add: Bolzano_bisect_le Let_def split_def)
   522 done
   523 
   524 lemma eq_divide_2_times_iff: "((x::real) = y / (2 * z)) = (2 * x = y/z)"
   525 apply (auto)
   526 apply (drule_tac f = "%u. (1/2) *u" in arg_cong)
   527 apply (simp)
   528 done
   529 
   530 lemma Bolzano_bisect_diff:
   531      "a \<le> b ==>
   532       snd(Bolzano_bisect P a b n) - fst(Bolzano_bisect P a b n) =
   533       (b-a) / (2 ^ n)"
   534 apply (induct "n")
   535 apply (auto simp add: eq_divide_2_times_iff add_divide_distrib Let_def split_def)
   536 done
   537 
   538 lemmas Bolzano_nest_unique =
   539     lemma_nest_unique
   540     [OF Bolzano_bisect_fst_le_Suc Bolzano_bisect_Suc_le_snd Bolzano_bisect_le]
   541 
   542 
   543 lemma not_P_Bolzano_bisect:
   544   assumes P:    "!!a b c. [| P(a,b); P(b,c); a \<le> b; b \<le> c|] ==> P(a,c)"
   545       and notP: "~ P(a,b)"
   546       and le:   "a \<le> b"
   547   shows "~ P(fst(Bolzano_bisect P a b n), snd(Bolzano_bisect P a b n))"
   548 proof (induct n)
   549   case 0 show ?case using notP by simp
   550  next
   551   case (Suc n)
   552   thus ?case
   553  by (auto simp del: surjective_pairing [symmetric]
   554              simp add: Let_def split_def Bolzano_bisect_le [OF le]
   555      P [of "fst (Bolzano_bisect P a b n)" _ "snd (Bolzano_bisect P a b n)"])
   556 qed
   557 
   558 (*Now we re-package P_prem as a formula*)
   559 lemma not_P_Bolzano_bisect':
   560      "[| \<forall>a b c. P(a,b) & P(b,c) & a \<le> b & b \<le> c --> P(a,c);
   561          ~ P(a,b);  a \<le> b |] ==>
   562       \<forall>n. ~ P(fst(Bolzano_bisect P a b n), snd(Bolzano_bisect P a b n))"
   563 by (blast elim!: not_P_Bolzano_bisect [THEN [2] rev_notE])
   564 
   565 
   566 
   567 lemma lemma_BOLZANO:
   568      "[| \<forall>a b c. P(a,b) & P(b,c) & a \<le> b & b \<le> c --> P(a,c);
   569          \<forall>x. \<exists>d::real. 0 < d &
   570                 (\<forall>a b. a \<le> x & x \<le> b & (b-a) < d --> P(a,b));
   571          a \<le> b |]
   572       ==> P(a,b)"
   573 apply (rule Bolzano_nest_unique [where P1=P, THEN exE], assumption+)
   574 apply (rule LIMSEQ_minus_cancel)
   575 apply (simp (no_asm_simp) add: Bolzano_bisect_diff LIMSEQ_divide_realpow_zero)
   576 apply (rule ccontr)
   577 apply (drule not_P_Bolzano_bisect', assumption+)
   578 apply (rename_tac "l")
   579 apply (drule_tac x = l in spec, clarify)
   580 apply (simp add: LIMSEQ_def)
   581 apply (drule_tac P = "%r. 0<r --> ?Q r" and x = "d/2" in spec)
   582 apply (drule_tac P = "%r. 0<r --> ?Q r" and x = "d/2" in spec)
   583 apply (drule real_less_half_sum, auto)
   584 apply (drule_tac x = "fst (Bolzano_bisect P a b (no + noa))" in spec)
   585 apply (drule_tac x = "snd (Bolzano_bisect P a b (no + noa))" in spec)
   586 apply safe
   587 apply (simp_all (no_asm_simp))
   588 apply (rule_tac y = "abs (fst (Bolzano_bisect P a b (no + noa)) - l) + abs (snd (Bolzano_bisect P a b (no + noa)) - l)" in order_le_less_trans)
   589 apply (simp (no_asm_simp) add: abs_if)
   590 apply (rule real_sum_of_halves [THEN subst])
   591 apply (rule add_strict_mono)
   592 apply (simp_all add: diff_minus [symmetric])
   593 done
   594 
   595 
   596 lemma lemma_BOLZANO2: "((\<forall>a b c. (a \<le> b & b \<le> c & P(a,b) & P(b,c)) --> P(a,c)) &
   597        (\<forall>x. \<exists>d::real. 0 < d &
   598                 (\<forall>a b. a \<le> x & x \<le> b & (b-a) < d --> P(a,b))))
   599       --> (\<forall>a b. a \<le> b --> P(a,b))"
   600 apply clarify
   601 apply (blast intro: lemma_BOLZANO)
   602 done
   603 
   604 
   605 subsection {* Intermediate Value Theorem *}
   606 
   607 text {*Prove Contrapositive by Bisection*}
   608 
   609 lemma IVT: "[| f(a::real) \<le> (y::real); y \<le> f(b);
   610          a \<le> b;
   611          (\<forall>x. a \<le> x & x \<le> b --> isCont f x) |]
   612       ==> \<exists>x. a \<le> x & x \<le> b & f(x) = y"
   613 apply (rule contrapos_pp, assumption)
   614 apply (cut_tac P = "% (u,v) . a \<le> u & u \<le> v & v \<le> b --> ~ (f (u) \<le> y & y \<le> f (v))" in lemma_BOLZANO2)
   615 apply safe
   616 apply simp_all
   617 apply (simp add: isCont_iff LIM_def)
   618 apply (rule ccontr)
   619 apply (subgoal_tac "a \<le> x & x \<le> b")
   620  prefer 2
   621  apply simp
   622  apply (drule_tac P = "%d. 0<d --> ?P d" and x = 1 in spec, arith)
   623 apply (drule_tac x = x in spec)+
   624 apply simp
   625 apply (drule_tac P = "%r. ?P r --> (\<exists>s>0. ?Q r s) " and x = "\<bar>y - f x\<bar>" in spec)
   626 apply safe
   627 apply simp
   628 apply (drule_tac x = s in spec, clarify)
   629 apply (cut_tac x = "f x" and y = y in linorder_less_linear, safe)
   630 apply (drule_tac x = "ba-x" in spec)
   631 apply (simp_all add: abs_if)
   632 apply (drule_tac x = "aa-x" in spec)
   633 apply (case_tac "x \<le> aa", simp_all)
   634 done
   635 
   636 lemma IVT2: "[| f(b::real) \<le> (y::real); y \<le> f(a);
   637          a \<le> b;
   638          (\<forall>x. a \<le> x & x \<le> b --> isCont f x)
   639       |] ==> \<exists>x. a \<le> x & x \<le> b & f(x) = y"
   640 apply (subgoal_tac "- f a \<le> -y & -y \<le> - f b", clarify)
   641 apply (drule IVT [where f = "%x. - f x"], assumption)
   642 apply (auto intro: isCont_minus)
   643 done
   644 
   645 (*HOL style here: object-level formulations*)
   646 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
   647       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
   648       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
   649 apply (blast intro: IVT)
   650 done
   651 
   652 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
   653       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
   654       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
   655 apply (blast intro: IVT2)
   656 done
   657 
   658 text{*By bisection, function continuous on closed interval is bounded above*}
   659 
   660 lemma isCont_bounded:
   661      "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   662       ==> \<exists>M::real. \<forall>x::real. a \<le> x & x \<le> b --> f(x) \<le> M"
   663 apply (cut_tac P = "% (u,v) . a \<le> u & u \<le> v & v \<le> b --> (\<exists>M. \<forall>x. u \<le> x & x \<le> v --> f x \<le> M)" in lemma_BOLZANO2)
   664 apply safe
   665 apply simp_all
   666 apply (rename_tac x xa ya M Ma)
   667 apply (cut_tac x = M and y = Ma in linorder_linear, safe)
   668 apply (rule_tac x = Ma in exI, clarify)
   669 apply (cut_tac x = xb and y = xa in linorder_linear, force)
   670 apply (rule_tac x = M in exI, clarify)
   671 apply (cut_tac x = xb and y = xa in linorder_linear, force)
   672 apply (case_tac "a \<le> x & x \<le> b")
   673 apply (rule_tac [2] x = 1 in exI)
   674 prefer 2 apply force
   675 apply (simp add: LIM_def isCont_iff)
   676 apply (drule_tac x = x in spec, auto)
   677 apply (erule_tac V = "\<forall>M. \<exists>x. a \<le> x & x \<le> b & ~ f x \<le> M" in thin_rl)
   678 apply (drule_tac x = 1 in spec, auto)
   679 apply (rule_tac x = s in exI, clarify)
   680 apply (rule_tac x = "\<bar>f x\<bar> + 1" in exI, clarify)
   681 apply (drule_tac x = "xa-x" in spec)
   682 apply (auto simp add: abs_ge_self)
   683 done
   684 
   685 text{*Refine the above to existence of least upper bound*}
   686 
   687 lemma lemma_reals_complete: "((\<exists>x. x \<in> S) & (\<exists>y. isUb UNIV S (y::real))) -->
   688       (\<exists>t. isLub UNIV S t)"
   689 by (blast intro: reals_complete)
   690 
   691 lemma isCont_has_Ub: "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   692          ==> \<exists>M::real. (\<forall>x::real. a \<le> x & x \<le> b --> f(x) \<le> M) &
   693                    (\<forall>N. N < M --> (\<exists>x. a \<le> x & x \<le> b & N < f(x)))"
   694 apply (cut_tac S = "Collect (%y. \<exists>x. a \<le> x & x \<le> b & y = f x)"
   695         in lemma_reals_complete)
   696 apply auto
   697 apply (drule isCont_bounded, assumption)
   698 apply (auto simp add: isUb_def leastP_def isLub_def setge_def setle_def)
   699 apply (rule exI, auto)
   700 apply (auto dest!: spec simp add: linorder_not_less)
   701 done
   702 
   703 text{*Now show that it attains its upper bound*}
   704 
   705 lemma isCont_eq_Ub:
   706   assumes le: "a \<le> b"
   707       and con: "\<forall>x::real. a \<le> x & x \<le> b --> isCont f x"
   708   shows "\<exists>M::real. (\<forall>x. a \<le> x & x \<le> b --> f(x) \<le> M) &
   709              (\<exists>x. a \<le> x & x \<le> b & f(x) = M)"
   710 proof -
   711   from isCont_has_Ub [OF le con]
   712   obtain M where M1: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
   713              and M2: "!!N. N<M ==> \<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x"  by blast
   714   show ?thesis
   715   proof (intro exI, intro conjI)
   716     show " \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M" by (rule M1)
   717     show "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M"
   718     proof (rule ccontr)
   719       assume "\<not> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
   720       with M1 have M3: "\<forall>x. a \<le> x & x \<le> b --> f x < M"
   721         by (fastsimp simp add: linorder_not_le [symmetric])
   722       hence "\<forall>x. a \<le> x & x \<le> b --> isCont (%x. inverse (M - f x)) x"
   723         by (auto simp add: isCont_inverse isCont_diff con)
   724       from isCont_bounded [OF le this]
   725       obtain k where k: "!!x. a \<le> x & x \<le> b --> inverse (M - f x) \<le> k" by auto
   726       have Minv: "!!x. a \<le> x & x \<le> b --> 0 < inverse (M - f (x))"
   727         by (simp add: M3 algebra_simps)
   728       have "!!x. a \<le> x & x \<le> b --> inverse (M - f x) < k+1" using k
   729         by (auto intro: order_le_less_trans [of _ k])
   730       with Minv
   731       have "!!x. a \<le> x & x \<le> b --> inverse(k+1) < inverse(inverse(M - f x))"
   732         by (intro strip less_imp_inverse_less, simp_all)
   733       hence invlt: "!!x. a \<le> x & x \<le> b --> inverse(k+1) < M - f x"
   734         by simp
   735       have "M - inverse (k+1) < M" using k [of a] Minv [of a] le
   736         by (simp, arith)
   737       from M2 [OF this]
   738       obtain x where ax: "a \<le> x & x \<le> b & M - inverse(k+1) < f x" ..
   739       thus False using invlt [of x] by force
   740     qed
   741   qed
   742 qed
   743 
   744 
   745 text{*Same theorem for lower bound*}
   746 
   747 lemma isCont_eq_Lb: "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   748          ==> \<exists>M::real. (\<forall>x::real. a \<le> x & x \<le> b --> M \<le> f(x)) &
   749                    (\<exists>x. a \<le> x & x \<le> b & f(x) = M)"
   750 apply (subgoal_tac "\<forall>x. a \<le> x & x \<le> b --> isCont (%x. - (f x)) x")
   751 prefer 2 apply (blast intro: isCont_minus)
   752 apply (drule_tac f = "(%x. - (f x))" in isCont_eq_Ub)
   753 apply safe
   754 apply auto
   755 done
   756 
   757 
   758 text{*Another version.*}
   759 
   760 lemma isCont_Lb_Ub: "[|a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   761       ==> \<exists>L M::real. (\<forall>x::real. a \<le> x & x \<le> b --> L \<le> f(x) & f(x) \<le> M) &
   762           (\<forall>y. L \<le> y & y \<le> M --> (\<exists>x. a \<le> x & x \<le> b & (f(x) = y)))"
   763 apply (frule isCont_eq_Lb)
   764 apply (frule_tac [2] isCont_eq_Ub)
   765 apply (assumption+, safe)
   766 apply (rule_tac x = "f x" in exI)
   767 apply (rule_tac x = "f xa" in exI, simp, safe)
   768 apply (cut_tac x = x and y = xa in linorder_linear, safe)
   769 apply (cut_tac f = f and a = x and b = xa and y = y in IVT_objl)
   770 apply (cut_tac [2] f = f and a = xa and b = x and y = y in IVT2_objl, safe)
   771 apply (rule_tac [2] x = xb in exI)
   772 apply (rule_tac [4] x = xb in exI, simp_all)
   773 done
   774 
   775 
   776 text{*If @{term "0 < f'(x)"} then @{term x} is Locally Strictly Increasing At The Right*}
   777 
   778 lemma DERIV_left_inc:
   779   fixes f :: "real => real"
   780   assumes der: "DERIV f x :> l"
   781       and l:   "0 < l"
   782   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x + h)"
   783 proof -
   784   from l der [THEN DERIV_D, THEN LIM_D [where r = "l"]]
   785   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l)"
   786     by (simp add: diff_minus)
   787   then obtain s
   788         where s:   "0 < s"
   789           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l"
   790     by auto
   791   thus ?thesis
   792   proof (intro exI conjI strip)
   793     show "0<s" using s .
   794     fix h::real
   795     assume "0 < h" "h < s"
   796     with all [of h] show "f x < f (x+h)"
   797     proof (simp add: abs_if pos_less_divide_eq diff_minus [symmetric]
   798     split add: split_if_asm)
   799       assume "~ (f (x+h) - f x) / h < l" and h: "0 < h"
   800       with l
   801       have "0 < (f (x+h) - f x) / h" by arith
   802       thus "f x < f (x+h)"
   803   by (simp add: pos_less_divide_eq h)
   804     qed
   805   qed
   806 qed
   807 
   808 lemma DERIV_left_dec:
   809   fixes f :: "real => real"
   810   assumes der: "DERIV f x :> l"
   811       and l:   "l < 0"
   812   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x-h)"
   813 proof -
   814   from l der [THEN DERIV_D, THEN LIM_D [where r = "-l"]]
   815   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l)"
   816     by (simp add: diff_minus)
   817   then obtain s
   818         where s:   "0 < s"
   819           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l"
   820     by auto
   821   thus ?thesis
   822   proof (intro exI conjI strip)
   823     show "0<s" using s .
   824     fix h::real
   825     assume "0 < h" "h < s"
   826     with all [of "-h"] show "f x < f (x-h)"
   827     proof (simp add: abs_if pos_less_divide_eq diff_minus [symmetric]
   828     split add: split_if_asm)
   829       assume " - ((f (x-h) - f x) / h) < l" and h: "0 < h"
   830       with l
   831       have "0 < (f (x-h) - f x) / h" by arith
   832       thus "f x < f (x-h)"
   833   by (simp add: pos_less_divide_eq h)
   834     qed
   835   qed
   836 qed
   837 
   838 lemma DERIV_local_max:
   839   fixes f :: "real => real"
   840   assumes der: "DERIV f x :> l"
   841       and d:   "0 < d"
   842       and le:  "\<forall>y. \<bar>x-y\<bar> < d --> f(y) \<le> f(x)"
   843   shows "l = 0"
   844 proof (cases rule: linorder_cases [of l 0])
   845   case equal thus ?thesis .
   846 next
   847   case less
   848   from DERIV_left_dec [OF der less]
   849   obtain d' where d': "0 < d'"
   850              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x-h)" by blast
   851   from real_lbound_gt_zero [OF d d']
   852   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   853   with lt le [THEN spec [where x="x-e"]]
   854   show ?thesis by (auto simp add: abs_if)
   855 next
   856   case greater
   857   from DERIV_left_inc [OF der greater]
   858   obtain d' where d': "0 < d'"
   859              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x + h)" by blast
   860   from real_lbound_gt_zero [OF d d']
   861   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   862   with lt le [THEN spec [where x="x+e"]]
   863   show ?thesis by (auto simp add: abs_if)
   864 qed
   865 
   866 
   867 text{*Similar theorem for a local minimum*}
   868 lemma DERIV_local_min:
   869   fixes f :: "real => real"
   870   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) \<le> f(y) |] ==> l = 0"
   871 by (drule DERIV_minus [THEN DERIV_local_max], auto)
   872 
   873 
   874 text{*In particular, if a function is locally flat*}
   875 lemma DERIV_local_const:
   876   fixes f :: "real => real"
   877   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) = f(y) |] ==> l = 0"
   878 by (auto dest!: DERIV_local_max)
   879 
   880 text{*Lemma about introducing open ball in open interval*}
   881 lemma lemma_interval_lt:
   882      "[| a < x;  x < b |]
   883       ==> \<exists>d::real. 0 < d & (\<forall>y. \<bar>x-y\<bar> < d --> a < y & y < b)"
   884 
   885 apply (simp add: abs_less_iff)
   886 apply (insert linorder_linear [of "x-a" "b-x"], safe)
   887 apply (rule_tac x = "x-a" in exI)
   888 apply (rule_tac [2] x = "b-x" in exI, auto)
   889 done
   890 
   891 lemma lemma_interval: "[| a < x;  x < b |] ==>
   892         \<exists>d::real. 0 < d &  (\<forall>y. \<bar>x-y\<bar> < d --> a \<le> y & y \<le> b)"
   893 apply (drule lemma_interval_lt, auto)
   894 apply (auto intro!: exI)
   895 done
   896 
   897 text{*Rolle's Theorem.
   898    If @{term f} is defined and continuous on the closed interval
   899    @{text "[a,b]"} and differentiable on the open interval @{text "(a,b)"},
   900    and @{term "f(a) = f(b)"},
   901    then there exists @{text "x0 \<in> (a,b)"} such that @{term "f'(x0) = 0"}*}
   902 theorem Rolle:
   903   assumes lt: "a < b"
   904       and eq: "f(a) = f(b)"
   905       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
   906       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable x"
   907   shows "\<exists>z::real. a < z & z < b & DERIV f z :> 0"
   908 proof -
   909   have le: "a \<le> b" using lt by simp
   910   from isCont_eq_Ub [OF le con]
   911   obtain x where x_max: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f z \<le> f x"
   912              and alex: "a \<le> x" and xleb: "x \<le> b"
   913     by blast
   914   from isCont_eq_Lb [OF le con]
   915   obtain x' where x'_min: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f x' \<le> f z"
   916               and alex': "a \<le> x'" and x'leb: "x' \<le> b"
   917     by blast
   918   show ?thesis
   919   proof cases
   920     assume axb: "a < x & x < b"
   921         --{*@{term f} attains its maximum within the interval*}
   922     hence ax: "a<x" and xb: "x<b" by arith + 
   923     from lemma_interval [OF ax xb]
   924     obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   925       by blast
   926     hence bound': "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> f y \<le> f x" using x_max
   927       by blast
   928     from differentiableD [OF dif [OF axb]]
   929     obtain l where der: "DERIV f x :> l" ..
   930     have "l=0" by (rule DERIV_local_max [OF der d bound'])
   931         --{*the derivative at a local maximum is zero*}
   932     thus ?thesis using ax xb der by auto
   933   next
   934     assume notaxb: "~ (a < x & x < b)"
   935     hence xeqab: "x=a | x=b" using alex xleb by arith
   936     hence fb_eq_fx: "f b = f x" by (auto simp add: eq)
   937     show ?thesis
   938     proof cases
   939       assume ax'b: "a < x' & x' < b"
   940         --{*@{term f} attains its minimum within the interval*}
   941       hence ax': "a<x'" and x'b: "x'<b" by arith+ 
   942       from lemma_interval [OF ax' x'b]
   943       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   944   by blast
   945       hence bound': "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> f x' \<le> f y" using x'_min
   946   by blast
   947       from differentiableD [OF dif [OF ax'b]]
   948       obtain l where der: "DERIV f x' :> l" ..
   949       have "l=0" by (rule DERIV_local_min [OF der d bound'])
   950         --{*the derivative at a local minimum is zero*}
   951       thus ?thesis using ax' x'b der by auto
   952     next
   953       assume notax'b: "~ (a < x' & x' < b)"
   954         --{*@{term f} is constant througout the interval*}
   955       hence x'eqab: "x'=a | x'=b" using alex' x'leb by arith
   956       hence fb_eq_fx': "f b = f x'" by (auto simp add: eq)
   957       from dense [OF lt]
   958       obtain r where ar: "a < r" and rb: "r < b" by blast
   959       from lemma_interval [OF ar rb]
   960       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   961   by blast
   962       have eq_fb: "\<forall>z. a \<le> z --> z \<le> b --> f z = f b"
   963       proof (clarify)
   964         fix z::real
   965         assume az: "a \<le> z" and zb: "z \<le> b"
   966         show "f z = f b"
   967         proof (rule order_antisym)
   968           show "f z \<le> f b" by (simp add: fb_eq_fx x_max az zb)
   969           show "f b \<le> f z" by (simp add: fb_eq_fx' x'_min az zb)
   970         qed
   971       qed
   972       have bound': "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> f r = f y"
   973       proof (intro strip)
   974         fix y::real
   975         assume lt: "\<bar>r-y\<bar> < d"
   976         hence "f y = f b" by (simp add: eq_fb bound)
   977         thus "f r = f y" by (simp add: eq_fb ar rb order_less_imp_le)
   978       qed
   979       from differentiableD [OF dif [OF conjI [OF ar rb]]]
   980       obtain l where der: "DERIV f r :> l" ..
   981       have "l=0" by (rule DERIV_local_const [OF der d bound'])
   982         --{*the derivative of a constant function is zero*}
   983       thus ?thesis using ar rb der by auto
   984     qed
   985   qed
   986 qed
   987 
   988 
   989 subsection{*Mean Value Theorem*}
   990 
   991 lemma lemma_MVT:
   992      "f a - (f b - f a)/(b-a) * a = f b - (f b - f a)/(b-a) * (b::real)"
   993 proof cases
   994   assume "a=b" thus ?thesis by simp
   995 next
   996   assume "a\<noteq>b"
   997   hence ba: "b-a \<noteq> 0" by arith
   998   show ?thesis
   999     by (rule real_mult_left_cancel [OF ba, THEN iffD1],
  1000         simp add: right_diff_distrib,
  1001         simp add: left_diff_distrib)
  1002 qed
  1003 
  1004 theorem MVT:
  1005   assumes lt:  "a < b"
  1006       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
  1007       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable x"
  1008   shows "\<exists>l z::real. a < z & z < b & DERIV f z :> l &
  1009                    (f(b) - f(a) = (b-a) * l)"
  1010 proof -
  1011   let ?F = "%x. f x - ((f b - f a) / (b-a)) * x"
  1012   have contF: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?F x" using con
  1013     by (fast intro: isCont_diff isCont_const isCont_mult isCont_ident)
  1014   have difF: "\<forall>x. a < x \<and> x < b \<longrightarrow> ?F differentiable x"
  1015   proof (clarify)
  1016     fix x::real
  1017     assume ax: "a < x" and xb: "x < b"
  1018     from differentiableD [OF dif [OF conjI [OF ax xb]]]
  1019     obtain l where der: "DERIV f x :> l" ..
  1020     show "?F differentiable x"
  1021       by (rule differentiableI [where D = "l - (f b - f a)/(b-a)"],
  1022           blast intro: DERIV_diff DERIV_cmult_Id der)
  1023   qed
  1024   from Rolle [where f = ?F, OF lt lemma_MVT contF difF]
  1025   obtain z where az: "a < z" and zb: "z < b" and der: "DERIV ?F z :> 0"
  1026     by blast
  1027   have "DERIV (%x. ((f b - f a)/(b-a)) * x) z :> (f b - f a)/(b-a)"
  1028     by (rule DERIV_cmult_Id)
  1029   hence derF: "DERIV (\<lambda>x. ?F x + (f b - f a) / (b - a) * x) z
  1030                    :> 0 + (f b - f a) / (b - a)"
  1031     by (rule DERIV_add [OF der])
  1032   show ?thesis
  1033   proof (intro exI conjI)
  1034     show "a < z" using az .
  1035     show "z < b" using zb .
  1036     show "f b - f a = (b - a) * ((f b - f a)/(b-a))" by (simp)
  1037     show "DERIV f z :> ((f b - f a)/(b-a))"  using derF by simp
  1038   qed
  1039 qed
  1040 
  1041 lemma MVT2:
  1042      "[| a < b; \<forall>x. a \<le> x & x \<le> b --> DERIV f x :> f'(x) |]
  1043       ==> \<exists>z::real. a < z & z < b & (f b - f a = (b - a) * f'(z))"
  1044 apply (drule MVT)
  1045 apply (blast intro: DERIV_isCont)
  1046 apply (force dest: order_less_imp_le simp add: differentiable_def)
  1047 apply (blast dest: DERIV_unique order_less_imp_le)
  1048 done
  1049 
  1050 
  1051 text{*A function is constant if its derivative is 0 over an interval.*}
  1052 
  1053 lemma DERIV_isconst_end:
  1054   fixes f :: "real => real"
  1055   shows "[| a < b;
  1056          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1057          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1058         ==> f b = f a"
  1059 apply (drule MVT, assumption)
  1060 apply (blast intro: differentiableI)
  1061 apply (auto dest!: DERIV_unique simp add: diff_eq_eq)
  1062 done
  1063 
  1064 lemma DERIV_isconst1:
  1065   fixes f :: "real => real"
  1066   shows "[| a < b;
  1067          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1068          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1069         ==> \<forall>x. a \<le> x & x \<le> b --> f x = f a"
  1070 apply safe
  1071 apply (drule_tac x = a in order_le_imp_less_or_eq, safe)
  1072 apply (drule_tac b = x in DERIV_isconst_end, auto)
  1073 done
  1074 
  1075 lemma DERIV_isconst2:
  1076   fixes f :: "real => real"
  1077   shows "[| a < b;
  1078          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1079          \<forall>x. a < x & x < b --> DERIV f x :> 0;
  1080          a \<le> x; x \<le> b |]
  1081         ==> f x = f a"
  1082 apply (blast dest: DERIV_isconst1)
  1083 done
  1084 
  1085 lemma DERIV_isconst3: fixes a b x y :: real
  1086   assumes "a < b" and "x \<in> {a <..< b}" and "y \<in> {a <..< b}"
  1087   assumes derivable: "\<And>x. x \<in> {a <..< b} \<Longrightarrow> DERIV f x :> 0"
  1088   shows "f x = f y"
  1089 proof (cases "x = y")
  1090   case False
  1091   let ?a = "min x y"
  1092   let ?b = "max x y"
  1093   
  1094   have "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> DERIV f z :> 0"
  1095   proof (rule allI, rule impI)
  1096     fix z :: real assume "?a \<le> z \<and> z \<le> ?b"
  1097     hence "a < z" and "z < b" using `x \<in> {a <..< b}` and `y \<in> {a <..< b}` by auto
  1098     hence "z \<in> {a<..<b}" by auto
  1099     thus "DERIV f z :> 0" by (rule derivable)
  1100   qed
  1101   hence isCont: "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> isCont f z"
  1102     and DERIV: "\<forall>z. ?a < z \<and> z < ?b \<longrightarrow> DERIV f z :> 0" using DERIV_isCont by auto
  1103 
  1104   have "?a < ?b" using `x \<noteq> y` by auto
  1105   from DERIV_isconst2[OF this isCont DERIV, of x] and DERIV_isconst2[OF this isCont DERIV, of y]
  1106   show ?thesis by auto
  1107 qed auto
  1108 
  1109 lemma DERIV_isconst_all:
  1110   fixes f :: "real => real"
  1111   shows "\<forall>x. DERIV f x :> 0 ==> f(x) = f(y)"
  1112 apply (rule linorder_cases [of x y])
  1113 apply (blast intro: sym DERIV_isCont DERIV_isconst_end)+
  1114 done
  1115 
  1116 lemma DERIV_const_ratio_const:
  1117   fixes f :: "real => real"
  1118   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a)) = (b-a) * k"
  1119 apply (rule linorder_cases [of a b], auto)
  1120 apply (drule_tac [!] f = f in MVT)
  1121 apply (auto dest: DERIV_isCont DERIV_unique simp add: differentiable_def)
  1122 apply (auto dest: DERIV_unique simp add: ring_distribs diff_minus)
  1123 done
  1124 
  1125 lemma DERIV_const_ratio_const2:
  1126   fixes f :: "real => real"
  1127   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a))/(b-a) = k"
  1128 apply (rule_tac c1 = "b-a" in real_mult_right_cancel [THEN iffD1])
  1129 apply (auto dest!: DERIV_const_ratio_const simp add: mult_assoc)
  1130 done
  1131 
  1132 lemma real_average_minus_first [simp]: "((a + b) /2 - a) = (b-a)/(2::real)"
  1133 by (simp)
  1134 
  1135 lemma real_average_minus_second [simp]: "((b + a)/2 - a) = (b-a)/(2::real)"
  1136 by (simp)
  1137 
  1138 text{*Gallileo's "trick": average velocity = av. of end velocities*}
  1139 
  1140 lemma DERIV_const_average:
  1141   fixes v :: "real => real"
  1142   assumes neq: "a \<noteq> (b::real)"
  1143       and der: "\<forall>x. DERIV v x :> k"
  1144   shows "v ((a + b)/2) = (v a + v b)/2"
  1145 proof (cases rule: linorder_cases [of a b])
  1146   case equal with neq show ?thesis by simp
  1147 next
  1148   case less
  1149   have "(v b - v a) / (b - a) = k"
  1150     by (rule DERIV_const_ratio_const2 [OF neq der])
  1151   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1152   moreover have "(v ((a + b) / 2) - v a) / ((a + b) / 2 - a) = k"
  1153     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1154   ultimately show ?thesis using neq by force
  1155 next
  1156   case greater
  1157   have "(v b - v a) / (b - a) = k"
  1158     by (rule DERIV_const_ratio_const2 [OF neq der])
  1159   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1160   moreover have " (v ((b + a) / 2) - v a) / ((b + a) / 2 - a) = k"
  1161     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1162   ultimately show ?thesis using neq by (force simp add: add_commute)
  1163 qed
  1164 
  1165 
  1166 text{*Dull lemma: an continuous injection on an interval must have a
  1167 strict maximum at an end point, not in the middle.*}
  1168 
  1169 lemma lemma_isCont_inj:
  1170   fixes f :: "real \<Rightarrow> real"
  1171   assumes d: "0 < d"
  1172       and inj [rule_format]: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1173       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1174   shows "\<exists>z. \<bar>z-x\<bar> \<le> d & f x < f z"
  1175 proof (rule ccontr)
  1176   assume  "~ (\<exists>z. \<bar>z-x\<bar> \<le> d & f x < f z)"
  1177   hence all [rule_format]: "\<forall>z. \<bar>z - x\<bar> \<le> d --> f z \<le> f x" by auto
  1178   show False
  1179   proof (cases rule: linorder_le_cases [of "f(x-d)" "f(x+d)"])
  1180     case le
  1181     from d cont all [of "x+d"]
  1182     have flef: "f(x+d) \<le> f x"
  1183      and xlex: "x - d \<le> x"
  1184      and cont': "\<forall>z. x - d \<le> z \<and> z \<le> x \<longrightarrow> isCont f z"
  1185        by (auto simp add: abs_if)
  1186     from IVT [OF le flef xlex cont']
  1187     obtain x' where "x-d \<le> x'" "x' \<le> x" "f x' = f(x+d)" by blast
  1188     moreover
  1189     hence "g(f x') = g (f(x+d))" by simp
  1190     ultimately show False using d inj [of x'] inj [of "x+d"]
  1191       by (simp add: abs_le_iff)
  1192   next
  1193     case ge
  1194     from d cont all [of "x-d"]
  1195     have flef: "f(x-d) \<le> f x"
  1196      and xlex: "x \<le> x+d"
  1197      and cont': "\<forall>z. x \<le> z \<and> z \<le> x+d \<longrightarrow> isCont f z"
  1198        by (auto simp add: abs_if)
  1199     from IVT2 [OF ge flef xlex cont']
  1200     obtain x' where "x \<le> x'" "x' \<le> x+d" "f x' = f(x-d)" by blast
  1201     moreover
  1202     hence "g(f x') = g (f(x-d))" by simp
  1203     ultimately show False using d inj [of x'] inj [of "x-d"]
  1204       by (simp add: abs_le_iff)
  1205   qed
  1206 qed
  1207 
  1208 
  1209 text{*Similar version for lower bound.*}
  1210 
  1211 lemma lemma_isCont_inj2:
  1212   fixes f g :: "real \<Rightarrow> real"
  1213   shows "[|0 < d; \<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z;
  1214         \<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z |]
  1215       ==> \<exists>z. \<bar>z-x\<bar> \<le> d & f z < f x"
  1216 apply (insert lemma_isCont_inj
  1217           [where f = "%x. - f x" and g = "%y. g(-y)" and x = x and d = d])
  1218 apply (simp add: isCont_minus linorder_not_le)
  1219 done
  1220 
  1221 text{*Show there's an interval surrounding @{term "f(x)"} in
  1222 @{text "f[[x - d, x + d]]"} .*}
  1223 
  1224 lemma isCont_inj_range:
  1225   fixes f :: "real \<Rightarrow> real"
  1226   assumes d: "0 < d"
  1227       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1228       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1229   shows "\<exists>e>0. \<forall>y. \<bar>y - f x\<bar> \<le> e --> (\<exists>z. \<bar>z-x\<bar> \<le> d & f z = y)"
  1230 proof -
  1231   have "x-d \<le> x+d" "\<forall>z. x-d \<le> z \<and> z \<le> x+d \<longrightarrow> isCont f z" using cont d
  1232     by (auto simp add: abs_le_iff)
  1233   from isCont_Lb_Ub [OF this]
  1234   obtain L M
  1235   where all1 [rule_format]: "\<forall>z. x-d \<le> z \<and> z \<le> x+d \<longrightarrow> L \<le> f z \<and> f z \<le> M"
  1236     and all2 [rule_format]:
  1237            "\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>z. x-d \<le> z \<and> z \<le> x+d \<and> f z = y)"
  1238     by auto
  1239   with d have "L \<le> f x & f x \<le> M" by simp
  1240   moreover have "L \<noteq> f x"
  1241   proof -
  1242     from lemma_isCont_inj2 [OF d inj cont]
  1243     obtain u where "\<bar>u - x\<bar> \<le> d" "f u < f x"  by auto
  1244     thus ?thesis using all1 [of u] by arith
  1245   qed
  1246   moreover have "f x \<noteq> M"
  1247   proof -
  1248     from lemma_isCont_inj [OF d inj cont]
  1249     obtain u where "\<bar>u - x\<bar> \<le> d" "f x < f u"  by auto
  1250     thus ?thesis using all1 [of u] by arith
  1251   qed
  1252   ultimately have "L < f x & f x < M" by arith
  1253   hence "0 < f x - L" "0 < M - f x" by arith+
  1254   from real_lbound_gt_zero [OF this]
  1255   obtain e where e: "0 < e" "e < f x - L" "e < M - f x" by auto
  1256   thus ?thesis
  1257   proof (intro exI conjI)
  1258     show "0<e" using e(1) .
  1259     show "\<forall>y. \<bar>y - f x\<bar> \<le> e \<longrightarrow> (\<exists>z. \<bar>z - x\<bar> \<le> d \<and> f z = y)"
  1260     proof (intro strip)
  1261       fix y::real
  1262       assume "\<bar>y - f x\<bar> \<le> e"
  1263       with e have "L \<le> y \<and> y \<le> M" by arith
  1264       from all2 [OF this]
  1265       obtain z where "x - d \<le> z" "z \<le> x + d" "f z = y" by blast
  1266       thus "\<exists>z. \<bar>z - x\<bar> \<le> d \<and> f z = y" 
  1267         by (force simp add: abs_le_iff)
  1268     qed
  1269   qed
  1270 qed
  1271 
  1272 
  1273 text{*Continuity of inverse function*}
  1274 
  1275 lemma isCont_inverse_function:
  1276   fixes f g :: "real \<Rightarrow> real"
  1277   assumes d: "0 < d"
  1278       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1279       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1280   shows "isCont g (f x)"
  1281 proof (simp add: isCont_iff LIM_eq)
  1282   show "\<forall>r. 0 < r \<longrightarrow>
  1283          (\<exists>s>0. \<forall>z. z\<noteq>0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>g(f x + z) - g(f x)\<bar> < r)"
  1284   proof (intro strip)
  1285     fix r::real
  1286     assume r: "0<r"
  1287     from real_lbound_gt_zero [OF r d]
  1288     obtain e where e: "0 < e" and e_lt: "e < r \<and> e < d" by blast
  1289     with inj cont
  1290     have e_simps: "\<forall>z. \<bar>z-x\<bar> \<le> e --> g (f z) = z"
  1291                   "\<forall>z. \<bar>z-x\<bar> \<le> e --> isCont f z"   by auto
  1292     from isCont_inj_range [OF e this]
  1293     obtain e' where e': "0 < e'"
  1294         and all: "\<forall>y. \<bar>y - f x\<bar> \<le> e' \<longrightarrow> (\<exists>z. \<bar>z - x\<bar> \<le> e \<and> f z = y)"
  1295           by blast
  1296     show "\<exists>s>0. \<forall>z. z\<noteq>0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>g(f x + z) - g(f x)\<bar> < r"
  1297     proof (intro exI conjI)
  1298       show "0<e'" using e' .
  1299       show "\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < e' \<longrightarrow> \<bar>g (f x + z) - g (f x)\<bar> < r"
  1300       proof (intro strip)
  1301         fix z::real
  1302         assume z: "z \<noteq> 0 \<and> \<bar>z\<bar> < e'"
  1303         with e e_lt e_simps all [rule_format, of "f x + z"]
  1304         show "\<bar>g (f x + z) - g (f x)\<bar> < r" by force
  1305       qed
  1306     qed
  1307   qed
  1308 qed
  1309 
  1310 text {* Derivative of inverse function *}
  1311 
  1312 lemma DERIV_inverse_function:
  1313   fixes f g :: "real \<Rightarrow> real"
  1314   assumes der: "DERIV f (g x) :> D"
  1315   assumes neq: "D \<noteq> 0"
  1316   assumes a: "a < x" and b: "x < b"
  1317   assumes inj: "\<forall>y. a < y \<and> y < b \<longrightarrow> f (g y) = y"
  1318   assumes cont: "isCont g x"
  1319   shows "DERIV g x :> inverse D"
  1320 unfolding DERIV_iff2
  1321 proof (rule LIM_equal2)
  1322   show "0 < min (x - a) (b - x)"
  1323     using a b by arith 
  1324 next
  1325   fix y
  1326   assume "norm (y - x) < min (x - a) (b - x)"
  1327   hence "a < y" and "y < b" 
  1328     by (simp_all add: abs_less_iff)
  1329   thus "(g y - g x) / (y - x) =
  1330         inverse ((f (g y) - x) / (g y - g x))"
  1331     by (simp add: inj)
  1332 next
  1333   have "(\<lambda>z. (f z - f (g x)) / (z - g x)) -- g x --> D"
  1334     by (rule der [unfolded DERIV_iff2])
  1335   hence 1: "(\<lambda>z. (f z - x) / (z - g x)) -- g x --> D"
  1336     using inj a b by simp
  1337   have 2: "\<exists>d>0. \<forall>y. y \<noteq> x \<and> norm (y - x) < d \<longrightarrow> g y \<noteq> g x"
  1338   proof (safe intro!: exI)
  1339     show "0 < min (x - a) (b - x)"
  1340       using a b by simp
  1341   next
  1342     fix y
  1343     assume "norm (y - x) < min (x - a) (b - x)"
  1344     hence y: "a < y" "y < b"
  1345       by (simp_all add: abs_less_iff)
  1346     assume "g y = g x"
  1347     hence "f (g y) = f (g x)" by simp
  1348     hence "y = x" using inj y a b by simp
  1349     also assume "y \<noteq> x"
  1350     finally show False by simp
  1351   qed
  1352   have "(\<lambda>y. (f (g y) - x) / (g y - g x)) -- x --> D"
  1353     using cont 1 2 by (rule isCont_LIM_compose2)
  1354   thus "(\<lambda>y. inverse ((f (g y) - x) / (g y - g x)))
  1355         -- x --> inverse D"
  1356     using neq by (rule LIM_inverse)
  1357 qed
  1358 
  1359 theorem GMVT:
  1360   fixes a b :: real
  1361   assumes alb: "a < b"
  1362   and fc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1363   and fd: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable x"
  1364   and gc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont g x"
  1365   and gd: "\<forall>x. a < x \<and> x < b \<longrightarrow> g differentiable x"
  1366   shows "\<exists>g'c f'c c. DERIV g c :> g'c \<and> DERIV f c :> f'c \<and> a < c \<and> c < b \<and> ((f b - f a) * g'c) = ((g b - g a) * f'c)"
  1367 proof -
  1368   let ?h = "\<lambda>x. (f b - f a)*(g x) - (g b - g a)*(f x)"
  1369   from prems have "a < b" by simp
  1370   moreover have "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?h x"
  1371   proof -
  1372     have "\<forall>x. a <= x \<and> x <= b \<longrightarrow> isCont (\<lambda>x. f b - f a) x" by simp
  1373     with gc have "\<forall>x. a <= x \<and> x <= b \<longrightarrow> isCont (\<lambda>x. (f b - f a) * g x) x"
  1374       by (auto intro: isCont_mult)
  1375     moreover
  1376     have "\<forall>x. a <= x \<and> x <= b \<longrightarrow> isCont (\<lambda>x. g b - g a) x" by simp
  1377     with fc have "\<forall>x. a <= x \<and> x <= b \<longrightarrow> isCont (\<lambda>x. (g b - g a) * f x) x"
  1378       by (auto intro: isCont_mult)
  1379     ultimately show ?thesis
  1380       by (fastsimp intro: isCont_diff)
  1381   qed
  1382   moreover
  1383   have "\<forall>x. a < x \<and> x < b \<longrightarrow> ?h differentiable x"
  1384   proof -
  1385     have "\<forall>x. a < x \<and> x < b \<longrightarrow> (\<lambda>x. f b - f a) differentiable x" by (simp add: differentiable_const)
  1386     with gd have "\<forall>x. a < x \<and> x < b \<longrightarrow> (\<lambda>x. (f b - f a) * g x) differentiable x" by (simp add: differentiable_mult)
  1387     moreover
  1388     have "\<forall>x. a < x \<and> x < b \<longrightarrow> (\<lambda>x. g b - g a) differentiable x" by (simp add: differentiable_const)
  1389     with fd have "\<forall>x. a < x \<and> x < b \<longrightarrow> (\<lambda>x. (g b - g a) * f x) differentiable x" by (simp add: differentiable_mult)
  1390     ultimately show ?thesis by (simp add: differentiable_diff)
  1391   qed
  1392   ultimately have "\<exists>l z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" by (rule MVT)
  1393   then obtain l where ldef: "\<exists>z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1394   then obtain c where cdef: "a < c \<and> c < b \<and> DERIV ?h c :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1395 
  1396   from cdef have cint: "a < c \<and> c < b" by auto
  1397   with gd have "g differentiable c" by simp
  1398   hence "\<exists>D. DERIV g c :> D" by (rule differentiableD)
  1399   then obtain g'c where g'cdef: "DERIV g c :> g'c" ..
  1400 
  1401   from cdef have "a < c \<and> c < b" by auto
  1402   with fd have "f differentiable c" by simp
  1403   hence "\<exists>D. DERIV f c :> D" by (rule differentiableD)
  1404   then obtain f'c where f'cdef: "DERIV f c :> f'c" ..
  1405 
  1406   from cdef have "DERIV ?h c :> l" by auto
  1407   moreover
  1408   {
  1409     have "DERIV (\<lambda>x. (f b - f a) * g x) c :> g'c * (f b - f a)"
  1410       apply (insert DERIV_const [where k="f b - f a"])
  1411       apply (drule meta_spec [of _ c])
  1412       apply (drule DERIV_mult [OF _ g'cdef])
  1413       by simp
  1414     moreover have "DERIV (\<lambda>x. (g b - g a) * f x) c :> f'c * (g b - g a)"
  1415       apply (insert DERIV_const [where k="g b - g a"])
  1416       apply (drule meta_spec [of _ c])
  1417       apply (drule DERIV_mult [OF _ f'cdef])
  1418       by simp
  1419     ultimately have "DERIV ?h c :>  g'c * (f b - f a) - f'c * (g b - g a)"
  1420       by (simp add: DERIV_diff)
  1421   }
  1422   ultimately have leq: "l =  g'c * (f b - f a) - f'c * (g b - g a)" by (rule DERIV_unique)
  1423 
  1424   {
  1425     from cdef have "?h b - ?h a = (b - a) * l" by auto
  1426     also with leq have "\<dots> = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1427     finally have "?h b - ?h a = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1428   }
  1429   moreover
  1430   {
  1431     have "?h b - ?h a =
  1432          ((f b)*(g b) - (f a)*(g b) - (g b)*(f b) + (g a)*(f b)) -
  1433           ((f b)*(g a) - (f a)*(g a) - (g b)*(f a) + (g a)*(f a))"
  1434       by (simp add: algebra_simps)
  1435     hence "?h b - ?h a = 0" by auto
  1436   }
  1437   ultimately have "(b - a) * (g'c * (f b - f a) - f'c * (g b - g a)) = 0" by auto
  1438   with alb have "g'c * (f b - f a) - f'c * (g b - g a) = 0" by simp
  1439   hence "g'c * (f b - f a) = f'c * (g b - g a)" by simp
  1440   hence "(f b - f a) * g'c = (g b - g a) * f'c" by (simp add: mult_ac)
  1441 
  1442   with g'cdef f'cdef cint show ?thesis by auto
  1443 qed
  1444 
  1445 lemma lemma_DERIV_subst: "[| DERIV f x :> D; D = E |] ==> DERIV f x :> E"
  1446 by auto
  1447 
  1448 
  1449 subsection {* Derivatives of univariate polynomials *}
  1450 
  1451 definition
  1452   pderiv :: "'a::real_normed_field poly \<Rightarrow> 'a poly" where
  1453   "pderiv = poly_rec 0 (\<lambda>a p p'. p + pCons 0 p')"
  1454 
  1455 lemma pderiv_0 [simp]: "pderiv 0 = 0"
  1456   unfolding pderiv_def by (simp add: poly_rec_0)
  1457 
  1458 lemma pderiv_pCons: "pderiv (pCons a p) = p + pCons 0 (pderiv p)"
  1459   unfolding pderiv_def by (simp add: poly_rec_pCons)
  1460 
  1461 lemma coeff_pderiv: "coeff (pderiv p) n = of_nat (Suc n) * coeff p (Suc n)"
  1462   apply (induct p arbitrary: n, simp)
  1463   apply (simp add: pderiv_pCons coeff_pCons algebra_simps split: nat.split)
  1464   done
  1465 
  1466 lemma pderiv_eq_0_iff: "pderiv p = 0 \<longleftrightarrow> degree p = 0"
  1467   apply (rule iffI)
  1468   apply (cases p, simp)
  1469   apply (simp add: expand_poly_eq coeff_pderiv del: of_nat_Suc)
  1470   apply (simp add: expand_poly_eq coeff_pderiv coeff_eq_0)
  1471   done
  1472 
  1473 lemma degree_pderiv: "degree (pderiv p) = degree p - 1"
  1474   apply (rule order_antisym [OF degree_le])
  1475   apply (simp add: coeff_pderiv coeff_eq_0)
  1476   apply (cases "degree p", simp)
  1477   apply (rule le_degree)
  1478   apply (simp add: coeff_pderiv del: of_nat_Suc)
  1479   apply (rule subst, assumption)
  1480   apply (rule leading_coeff_neq_0, clarsimp)
  1481   done
  1482 
  1483 lemma pderiv_singleton [simp]: "pderiv [:a:] = 0"
  1484 by (simp add: pderiv_pCons)
  1485 
  1486 lemma pderiv_add: "pderiv (p + q) = pderiv p + pderiv q"
  1487 by (rule poly_ext, simp add: coeff_pderiv algebra_simps)
  1488 
  1489 lemma pderiv_minus: "pderiv (- p) = - pderiv p"
  1490 by (rule poly_ext, simp add: coeff_pderiv)
  1491 
  1492 lemma pderiv_diff: "pderiv (p - q) = pderiv p - pderiv q"
  1493 by (rule poly_ext, simp add: coeff_pderiv algebra_simps)
  1494 
  1495 lemma pderiv_smult: "pderiv (smult a p) = smult a (pderiv p)"
  1496 by (rule poly_ext, simp add: coeff_pderiv algebra_simps)
  1497 
  1498 lemma pderiv_mult: "pderiv (p * q) = p * pderiv q + q * pderiv p"
  1499 apply (induct p)
  1500 apply simp
  1501 apply (simp add: pderiv_add pderiv_smult pderiv_pCons algebra_simps)
  1502 done
  1503 
  1504 lemma pderiv_power_Suc:
  1505   "pderiv (p ^ Suc n) = smult (of_nat (Suc n)) (p ^ n) * pderiv p"
  1506 apply (induct n)
  1507 apply simp
  1508 apply (subst power_Suc)
  1509 apply (subst pderiv_mult)
  1510 apply (erule ssubst)
  1511 apply (simp add: smult_add_left algebra_simps)
  1512 done
  1513 
  1514 lemma DERIV_cmult2: "DERIV f x :> D ==> DERIV (%x. (f x) * c :: real) x :> D * c"
  1515 by (simp add: DERIV_cmult mult_commute [of _ c])
  1516 
  1517 lemma DERIV_pow2: "DERIV (%x. x ^ Suc n) x :> real (Suc n) * (x ^ n)"
  1518 by (rule lemma_DERIV_subst, rule DERIV_pow, simp)
  1519 declare DERIV_pow2 [simp] DERIV_pow [simp]
  1520 
  1521 lemma DERIV_add_const: "DERIV f x :> D ==>  DERIV (%x. a + f x :: 'a::real_normed_field) x :> D"
  1522 by (rule lemma_DERIV_subst, rule DERIV_add, auto)
  1523 
  1524 lemma poly_DERIV[simp]: "DERIV (%x. poly p x) x :> poly (pderiv p) x"
  1525 apply (induct p)
  1526 apply simp
  1527 apply (simp add: pderiv_pCons)
  1528 apply (rule lemma_DERIV_subst)
  1529 apply (rule DERIV_add DERIV_mult DERIV_const DERIV_ident | assumption)+
  1530 apply simp
  1531 done
  1532 
  1533 text{* Consequences of the derivative theorem above*}
  1534 
  1535 lemma poly_differentiable[simp]: "(%x. poly p x) differentiable (x::real)"
  1536 apply (simp add: differentiable_def)
  1537 apply (blast intro: poly_DERIV)
  1538 done
  1539 
  1540 lemma poly_isCont[simp]: "isCont (%x. poly p x) (x::real)"
  1541 by (rule poly_DERIV [THEN DERIV_isCont])
  1542 
  1543 lemma poly_IVT_pos: "[| a < b; poly p (a::real) < 0; 0 < poly p b |]
  1544       ==> \<exists>x. a < x & x < b & (poly p x = 0)"
  1545 apply (cut_tac f = "%x. poly p x" and a = a and b = b and y = 0 in IVT_objl)
  1546 apply (auto simp add: order_le_less)
  1547 done
  1548 
  1549 lemma poly_IVT_neg: "[| (a::real) < b; 0 < poly p a; poly p b < 0 |]
  1550       ==> \<exists>x. a < x & x < b & (poly p x = 0)"
  1551 by (insert poly_IVT_pos [where p = "- p" ]) simp
  1552 
  1553 lemma poly_MVT: "(a::real) < b ==>
  1554      \<exists>x. a < x & x < b & (poly p b - poly p a = (b - a) * poly (pderiv p) x)"
  1555 apply (drule_tac f = "poly p" in MVT, auto)
  1556 apply (rule_tac x = z in exI)
  1557 apply (auto simp add: real_mult_left_cancel poly_DERIV [THEN DERIV_unique])
  1558 done
  1559 
  1560 text{*Lemmas for Derivatives*}
  1561 
  1562 (* FIXME
  1563 lemma lemma_order_pderiv [rule_format]:
  1564      "\<forall>p q a. 0 < n &
  1565        poly (pderiv p) \<noteq> poly [] &
  1566        poly p = poly ([- a, 1] %^ n *** q) & ~ [- a, 1] divides q
  1567        --> n = Suc (order a (pderiv p))"
  1568 apply (induct "n", safe)
  1569 apply (rule order_unique_lemma, rule conjI, assumption)
  1570 apply (subgoal_tac "\<forall>r. r divides (pderiv p) = r divides (pderiv ([-a, 1] %^ Suc n *** q))")
  1571 apply (drule_tac [2] poly_pderiv_welldef)
  1572  prefer 2 apply (simp add: divides_def del: pmult_Cons pexp_Suc) 
  1573 apply (simp del: pmult_Cons pexp_Suc) 
  1574 apply (rule conjI)
  1575 apply (simp add: divides_def fun_eq del: pmult_Cons pexp_Suc)
  1576 apply (rule_tac x = "[-a, 1] *** (pderiv q) +++ real (Suc n) %* q" in exI)
  1577 apply (simp add: poly_pderiv_mult poly_pderiv_exp_prime poly_add poly_mult poly_cmult right_distrib mult_ac del: pmult_Cons pexp_Suc)
  1578 apply (simp add: poly_mult right_distrib left_distrib mult_ac del: pmult_Cons)
  1579 apply (erule_tac V = "\<forall>r. r divides pderiv p = r divides pderiv ([- a, 1] %^ Suc n *** q)" in thin_rl)
  1580 apply (unfold divides_def)
  1581 apply (simp (no_asm) add: poly_pderiv_mult poly_pderiv_exp_prime fun_eq poly_add poly_mult del: pmult_Cons pexp_Suc)
  1582 apply (rule contrapos_np, assumption)
  1583 apply (rotate_tac 3, erule contrapos_np)
  1584 apply (simp del: pmult_Cons pexp_Suc, safe)
  1585 apply (rule_tac x = "inverse (real (Suc n)) %* (qa +++ -- (pderiv q))" in exI)
  1586 apply (subgoal_tac "poly ([-a, 1] %^ n *** q) = poly ([-a, 1] %^ n *** ([-a, 1] *** (inverse (real (Suc n)) %* (qa +++ -- (pderiv q))))) ")
  1587 apply (drule poly_mult_left_cancel [THEN iffD1], simp)
  1588 apply (simp add: fun_eq poly_mult poly_add poly_cmult poly_minus del: pmult_Cons mult_cancel_left, safe)
  1589 apply (rule_tac c1 = "real (Suc n)" in real_mult_left_cancel [THEN iffD1])
  1590 apply (simp (no_asm))
  1591 apply (subgoal_tac "real (Suc n) * (poly ([- a, 1] %^ n) xa * poly q xa) =
  1592           (poly qa xa + - poly (pderiv q) xa) *
  1593           (poly ([- a, 1] %^ n) xa *
  1594            ((- a + xa) * (inverse (real (Suc n)) * real (Suc n))))")
  1595 apply (simp only: mult_ac)  
  1596 apply (rotate_tac 2)
  1597 apply (drule_tac x = xa in spec)
  1598 apply (simp add: left_distrib mult_ac del: pmult_Cons)
  1599 done
  1600 
  1601 lemma order_pderiv: "[| poly (pderiv p) \<noteq> poly []; order a p \<noteq> 0 |]
  1602       ==> (order a p = Suc (order a (pderiv p)))"
  1603 apply (case_tac "poly p = poly []")
  1604 apply (auto dest: pderiv_zero)
  1605 apply (drule_tac a = a and p = p in order_decomp)
  1606 using neq0_conv
  1607 apply (blast intro: lemma_order_pderiv)
  1608 done
  1609 
  1610 text{*Now justify the standard squarefree decomposition, i.e. f / gcd(f,f'). *}
  1611 
  1612 lemma poly_squarefree_decomp_order: "[| poly (pderiv p) \<noteq> poly [];
  1613          poly p = poly (q *** d);
  1614          poly (pderiv p) = poly (e *** d);
  1615          poly d = poly (r *** p +++ s *** pderiv p)
  1616       |] ==> order a q = (if order a p = 0 then 0 else 1)"
  1617 apply (subgoal_tac "order a p = order a q + order a d")
  1618 apply (rule_tac [2] s = "order a (q *** d)" in trans)
  1619 prefer 2 apply (blast intro: order_poly)
  1620 apply (rule_tac [2] order_mult)
  1621  prefer 2 apply force
  1622 apply (case_tac "order a p = 0", simp)
  1623 apply (subgoal_tac "order a (pderiv p) = order a e + order a d")
  1624 apply (rule_tac [2] s = "order a (e *** d)" in trans)
  1625 prefer 2 apply (blast intro: order_poly)
  1626 apply (rule_tac [2] order_mult)
  1627  prefer 2 apply force
  1628 apply (case_tac "poly p = poly []")
  1629 apply (drule_tac p = p in pderiv_zero, simp)
  1630 apply (drule order_pderiv, assumption)
  1631 apply (subgoal_tac "order a (pderiv p) \<le> order a d")
  1632 apply (subgoal_tac [2] " ([-a, 1] %^ (order a (pderiv p))) divides d")
  1633  prefer 2 apply (simp add: poly_entire order_divides)
  1634 apply (subgoal_tac [2] " ([-a, 1] %^ (order a (pderiv p))) divides p & ([-a, 1] %^ (order a (pderiv p))) divides (pderiv p) ")
  1635  prefer 3 apply (simp add: order_divides)
  1636  prefer 2 apply (simp add: divides_def del: pexp_Suc pmult_Cons, safe)
  1637 apply (rule_tac x = "r *** qa +++ s *** qaa" in exI)
  1638 apply (simp add: fun_eq poly_add poly_mult left_distrib right_distrib mult_ac del: pexp_Suc pmult_Cons, auto)
  1639 done
  1640 
  1641 
  1642 lemma poly_squarefree_decomp_order2: "[| poly (pderiv p) \<noteq> poly [];
  1643          poly p = poly (q *** d);
  1644          poly (pderiv p) = poly (e *** d);
  1645          poly d = poly (r *** p +++ s *** pderiv p)
  1646       |] ==> \<forall>a. order a q = (if order a p = 0 then 0 else 1)"
  1647 apply (blast intro: poly_squarefree_decomp_order)
  1648 done
  1649 
  1650 lemma order_pderiv2: "[| poly (pderiv p) \<noteq> poly []; order a p \<noteq> 0 |]
  1651       ==> (order a (pderiv p) = n) = (order a p = Suc n)"
  1652 apply (auto dest: order_pderiv)
  1653 done
  1654 
  1655 lemma rsquarefree_roots:
  1656   "rsquarefree p = (\<forall>a. ~(poly p a = 0 & poly (pderiv p) a = 0))"
  1657 apply (simp add: rsquarefree_def)
  1658 apply (case_tac "poly p = poly []", simp, simp)
  1659 apply (case_tac "poly (pderiv p) = poly []")
  1660 apply simp
  1661 apply (drule pderiv_iszero, clarify)
  1662 apply (subgoal_tac "\<forall>a. order a p = order a [h]")
  1663 apply (simp add: fun_eq)
  1664 apply (rule allI)
  1665 apply (cut_tac p = "[h]" and a = a in order_root)
  1666 apply (simp add: fun_eq)
  1667 apply (blast intro: order_poly)
  1668 apply (auto simp add: order_root order_pderiv2)
  1669 apply (erule_tac x="a" in allE, simp)
  1670 done
  1671 
  1672 lemma poly_squarefree_decomp: "[| poly (pderiv p) \<noteq> poly [];
  1673          poly p = poly (q *** d);
  1674          poly (pderiv p) = poly (e *** d);
  1675          poly d = poly (r *** p +++ s *** pderiv p)
  1676       |] ==> rsquarefree q & (\<forall>a. (poly q a = 0) = (poly p a = 0))"
  1677 apply (frule poly_squarefree_decomp_order2, assumption+) 
  1678 apply (case_tac "poly p = poly []")
  1679 apply (blast dest: pderiv_zero)
  1680 apply (simp (no_asm) add: rsquarefree_def order_root del: pmult_Cons)
  1681 apply (simp add: poly_entire del: pmult_Cons)
  1682 done
  1683 *)
  1684 
  1685 subsection {* Theorems about Limits *}
  1686 
  1687 (* need to rename second isCont_inverse *)
  1688 
  1689 lemma isCont_inv_fun:
  1690   fixes f g :: "real \<Rightarrow> real"
  1691   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1692          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1693       ==> isCont g (f x)"
  1694 by (rule isCont_inverse_function)
  1695 
  1696 lemma isCont_inv_fun_inv:
  1697   fixes f g :: "real \<Rightarrow> real"
  1698   shows "[| 0 < d;  
  1699          \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1700          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1701        ==> \<exists>e. 0 < e &  
  1702              (\<forall>y. 0 < \<bar>y - f(x)\<bar> & \<bar>y - f(x)\<bar> < e --> f(g(y)) = y)"
  1703 apply (drule isCont_inj_range)
  1704 prefer 2 apply (assumption, assumption, auto)
  1705 apply (rule_tac x = e in exI, auto)
  1706 apply (rotate_tac 2)
  1707 apply (drule_tac x = y in spec, auto)
  1708 done
  1709 
  1710 
  1711 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1712 lemma LIM_fun_gt_zero:
  1713      "[| f -- c --> (l::real); 0 < l |]  
  1714          ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> 0 < f x)"
  1715 apply (auto simp add: LIM_def)
  1716 apply (drule_tac x = "l/2" in spec, safe, force)
  1717 apply (rule_tac x = s in exI)
  1718 apply (auto simp only: abs_less_iff)
  1719 done
  1720 
  1721 lemma LIM_fun_less_zero:
  1722      "[| f -- c --> (l::real); l < 0 |]  
  1723       ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> f x < 0)"
  1724 apply (auto simp add: LIM_def)
  1725 apply (drule_tac x = "-l/2" in spec, safe, force)
  1726 apply (rule_tac x = s in exI)
  1727 apply (auto simp only: abs_less_iff)
  1728 done
  1729 
  1730 
  1731 lemma LIM_fun_not_zero:
  1732      "[| f -- c --> (l::real); l \<noteq> 0 |] 
  1733       ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> f x \<noteq> 0)"
  1734 apply (cut_tac x = l and y = 0 in linorder_less_linear, auto)
  1735 apply (drule LIM_fun_less_zero)
  1736 apply (drule_tac [3] LIM_fun_gt_zero)
  1737 apply force+
  1738 done
  1739 
  1740 end