src/HOL/Set.thy
author ballarin
Thu Feb 19 15:57:34 2004 +0100 (2004-02-19)
changeset 14398 c5c47703f763
parent 14381 1189a8212a12
child 14479 0eca4aabf371
permissions -rw-r--r--
Efficient, graph-based reasoner for linear and partial orders.
+ Setup as solver in the HOL simplifier.
     1 (*  Title:      HOL/Set.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 *)
     6 
     7 header {* Set theory for higher-order logic *}
     8 
     9 theory Set = HOL:
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 typedecl 'a set
    19 arities set :: (type) type
    20 
    21 consts
    22   "{}"          :: "'a set"                             ("{}")
    23   UNIV          :: "'a set"
    24   insert        :: "'a => 'a set => 'a set"
    25   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    26   Int           :: "'a set => 'a set => 'a set"          (infixl 70)
    27   Un            :: "'a set => 'a set => 'a set"          (infixl 65)
    28   UNION         :: "'a set => ('a => 'b set) => 'b set"  -- "general union"
    29   INTER         :: "'a set => ('a => 'b set) => 'b set"  -- "general intersection"
    30   Union         :: "'a set set => 'a set"                -- "union of a set"
    31   Inter         :: "'a set set => 'a set"                -- "intersection of a set"
    32   Pow           :: "'a set => 'a set set"                -- "powerset"
    33   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    34   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    35   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    36 
    37 syntax
    38   "op :"        :: "'a => 'a set => bool"                ("op :")
    39 consts
    40   "op :"        :: "'a => 'a set => bool"                ("(_/ : _)" [50, 51] 50)  -- "membership"
    41 
    42 local
    43 
    44 instance set :: (type) ord ..
    45 instance set :: (type) minus ..
    46 
    47 
    48 subsection {* Additional concrete syntax *}
    49 
    50 syntax
    51   range         :: "('a => 'b) => 'b set"             -- "of function"
    52 
    53   "op ~:"       :: "'a => 'a set => bool"                 ("op ~:")  -- "non-membership"
    54   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ ~: _)" [50, 51] 50)
    55 
    56   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    57   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    58   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
    59 
    60   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" 10)
    61   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" 10)
    62   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" 10)
    63   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" 10)
    64 
    65   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    66   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (HOL)
    69   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    70   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    71 
    72 translations
    73   "range f"     == "f`UNIV"
    74   "x ~: y"      == "~ (x : y)"
    75   "{x, xs}"     == "insert x {xs}"
    76   "{x}"         == "insert x {}"
    77   "{x. P}"      == "Collect (%x. P)"
    78   "UN x y. B"   == "UN x. UN y. B"
    79   "UN x. B"     == "UNION UNIV (%x. B)"
    80   "UN x. B"     == "UN x:UNIV. B"
    81   "INT x y. B"  == "INT x. INT y. B"
    82   "INT x. B"    == "INTER UNIV (%x. B)"
    83   "INT x. B"    == "INT x:UNIV. B"
    84   "UN x:A. B"   == "UNION A (%x. B)"
    85   "INT x:A. B"  == "INTER A (%x. B)"
    86   "ALL x:A. P"  == "Ball A (%x. P)"
    87   "EX x:A. P"   == "Bex A (%x. P)"
    88 
    89 syntax (output)
    90   "_setle"      :: "'a set => 'a set => bool"             ("op <=")
    91   "_setle"      :: "'a set => 'a set => bool"             ("(_/ <= _)" [50, 51] 50)
    92   "_setless"    :: "'a set => 'a set => bool"             ("op <")
    93   "_setless"    :: "'a set => 'a set => bool"             ("(_/ < _)" [50, 51] 50)
    94 
    95 syntax (xsymbols)
    96   "_setle"      :: "'a set => 'a set => bool"             ("op \<subseteq>")
    97   "_setle"      :: "'a set => 'a set => bool"             ("(_/ \<subseteq> _)" [50, 51] 50)
    98   "_setless"    :: "'a set => 'a set => bool"             ("op \<subset>")
    99   "_setless"    :: "'a set => 'a set => bool"             ("(_/ \<subset> _)" [50, 51] 50)
   100   "op Int"      :: "'a set => 'a set => 'a set"           (infixl "\<inter>" 70)
   101   "op Un"       :: "'a set => 'a set => 'a set"           (infixl "\<union>" 65)
   102   "op :"        :: "'a => 'a set => bool"                 ("op \<in>")
   103   "op :"        :: "'a => 'a set => bool"                 ("(_/ \<in> _)" [50, 51] 50)
   104   "op ~:"       :: "'a => 'a set => bool"                 ("op \<notin>")
   105   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ \<notin> _)" [50, 51] 50)
   106   Union         :: "'a set set => 'a set"                 ("\<Union>_" [90] 90)
   107   Inter         :: "'a set set => 'a set"                 ("\<Inter>_" [90] 90)
   108   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   109   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   110 
   111 syntax (input)
   112   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" 10)
   113   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" 10)
   114   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" 10)
   115   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" 10)
   116 
   117 syntax (xsymbols)
   118   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>\<^bsub>_\<^esub>/ _)" 10)
   119   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>\<^bsub>_\<^esub>/ _)" 10)
   120   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>\<^bsub>_\<in>_\<^esub>/ _)" 10)
   121   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>\<^bsub>_\<in>_\<^esub>/ _)" 10)
   122 
   123 translations
   124   "op \<subseteq>" => "op <= :: _ set => _ set => bool"
   125   "op \<subset>" => "op <  :: _ set => _ set => bool"
   126 
   127 
   128 typed_print_translation {*
   129   let
   130     fun le_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   131           list_comb (Syntax.const "_setle", ts)
   132       | le_tr' _ _ _ = raise Match;
   133 
   134     fun less_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   135           list_comb (Syntax.const "_setless", ts)
   136       | less_tr' _ _ _ = raise Match;
   137   in [("op <=", le_tr'), ("op <", less_tr')] end
   138 *}
   139 
   140 text {*
   141   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   142   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   143   only translated if @{text "[0..n] subset bvs(e)"}.
   144 *}
   145 
   146 parse_translation {*
   147   let
   148     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   149 
   150     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   151       | nvars _ = 1;
   152 
   153     fun setcompr_tr [e, idts, b] =
   154       let
   155         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   156         val P = Syntax.const "op &" $ eq $ b;
   157         val exP = ex_tr [idts, P];
   158       in Syntax.const "Collect" $ Abs ("", dummyT, exP) end;
   159 
   160   in [("@SetCompr", setcompr_tr)] end;
   161 *}
   162 
   163 (* To avoid eta-contraction of body: *)
   164 print_translation {*
   165 let
   166   fun btr' syn [A,Abs abs] =
   167     let val (x,t) = atomic_abs_tr' abs
   168     in Syntax.const syn $ x $ A $ t end
   169 in
   170 [("Ball", btr' "_Ball"),("Bex", btr' "_Bex"),
   171  ("UNION", btr' "@UNION"),("INTER", btr' "@INTER")]
   172 end
   173 *}
   174 
   175 print_translation {*
   176 let
   177   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   178 
   179   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   180     let
   181       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   182         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   183             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   184             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   185         | check _ = false
   186 
   187         fun tr' (_ $ abs) =
   188           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   189           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   190     in if check (P, 0) then tr' P
   191        else let val (x,t) = atomic_abs_tr' abs
   192             in Syntax.const "@Coll" $ x $ t end
   193     end;
   194   in [("Collect", setcompr_tr')] end;
   195 *}
   196 
   197 
   198 subsection {* Rules and definitions *}
   199 
   200 text {* Isomorphisms between predicates and sets. *}
   201 
   202 axioms
   203   mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   204   Collect_mem_eq [simp]: "{x. x:A} = A"
   205 
   206 defs
   207   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   208   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   209 
   210 defs (overloaded)
   211   subset_def:   "A <= B         == ALL x:A. x:B"
   212   psubset_def:  "A < B          == (A::'a set) <= B & ~ A=B"
   213   Compl_def:    "- A            == {x. ~x:A}"
   214   set_diff_def: "A - B          == {x. x:A & ~x:B}"
   215 
   216 defs
   217   Un_def:       "A Un B         == {x. x:A | x:B}"
   218   Int_def:      "A Int B        == {x. x:A & x:B}"
   219   INTER_def:    "INTER A B      == {y. ALL x:A. y: B(x)}"
   220   UNION_def:    "UNION A B      == {y. EX x:A. y: B(x)}"
   221   Inter_def:    "Inter S        == (INT x:S. x)"
   222   Union_def:    "Union S        == (UN x:S. x)"
   223   Pow_def:      "Pow A          == {B. B <= A}"
   224   empty_def:    "{}             == {x. False}"
   225   UNIV_def:     "UNIV           == {x. True}"
   226   insert_def:   "insert a B     == {x. x=a} Un B"
   227   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   228 
   229 
   230 subsection {* Lemmas and proof tool setup *}
   231 
   232 subsubsection {* Relating predicates and sets *}
   233 
   234 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   235   by simp
   236 
   237 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   238   by simp
   239 
   240 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   241   by simp
   242 
   243 lemmas CollectE = CollectD [elim_format]
   244 
   245 
   246 subsubsection {* Bounded quantifiers *}
   247 
   248 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   249   by (simp add: Ball_def)
   250 
   251 lemmas strip = impI allI ballI
   252 
   253 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   254   by (simp add: Ball_def)
   255 
   256 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   257   by (unfold Ball_def) blast
   258 ML {* bind_thm("rev_ballE",permute_prems 1 1 (thm "ballE")) *}
   259 
   260 text {*
   261   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   262   @{prop "a:A"}; creates assumption @{prop "P a"}.
   263 *}
   264 
   265 ML {*
   266   local val ballE = thm "ballE"
   267   in fun ball_tac i = etac ballE i THEN contr_tac (i + 1) end;
   268 *}
   269 
   270 text {*
   271   Gives better instantiation for bound:
   272 *}
   273 
   274 ML_setup {*
   275   claset_ref() := claset() addbefore ("bspec", datac (thm "bspec") 1);
   276 *}
   277 
   278 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   279   -- {* Normally the best argument order: @{prop "P x"} constrains the
   280     choice of @{prop "x:A"}. *}
   281   by (unfold Bex_def) blast
   282 
   283 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   284   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   285   by (unfold Bex_def) blast
   286 
   287 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   288   by (unfold Bex_def) blast
   289 
   290 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   291   by (unfold Bex_def) blast
   292 
   293 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   294   -- {* Trival rewrite rule. *}
   295   by (simp add: Ball_def)
   296 
   297 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   298   -- {* Dual form for existentials. *}
   299   by (simp add: Bex_def)
   300 
   301 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   302   by blast
   303 
   304 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   305   by blast
   306 
   307 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   308   by blast
   309 
   310 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   311   by blast
   312 
   313 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   314   by blast
   315 
   316 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   317   by blast
   318 
   319 ML_setup {*
   320   local
   321     val Ball_def = thm "Ball_def";
   322     val Bex_def = thm "Bex_def";
   323 
   324     val prove_bex_tac =
   325       rewrite_goals_tac [Bex_def] THEN Quantifier1.prove_one_point_ex_tac;
   326     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   327 
   328     val prove_ball_tac =
   329       rewrite_goals_tac [Ball_def] THEN Quantifier1.prove_one_point_all_tac;
   330     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   331   in
   332     val defBEX_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   333       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   334     val defBALL_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   335       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   336   end;
   337 
   338   Addsimprocs [defBALL_regroup, defBEX_regroup];
   339 *}
   340 
   341 
   342 subsubsection {* Congruence rules *}
   343 
   344 lemma ball_cong [cong]:
   345   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   346     (ALL x:A. P x) = (ALL x:B. Q x)"
   347   by (simp add: Ball_def)
   348 
   349 lemma bex_cong [cong]:
   350   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   351     (EX x:A. P x) = (EX x:B. Q x)"
   352   by (simp add: Bex_def cong: conj_cong)
   353 
   354 
   355 subsubsection {* Subsets *}
   356 
   357 lemma subsetI [intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   358   by (simp add: subset_def)
   359 
   360 text {*
   361   \medskip Map the type @{text "'a set => anything"} to just @{typ
   362   'a}; for overloading constants whose first argument has type @{typ
   363   "'a set"}.
   364 *}
   365 
   366 lemma subsetD [elim]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   367   -- {* Rule in Modus Ponens style. *}
   368   by (unfold subset_def) blast
   369 
   370 declare subsetD [intro?] -- FIXME
   371 
   372 lemma rev_subsetD: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   373   -- {* The same, with reversed premises for use with @{text erule} --
   374       cf @{text rev_mp}. *}
   375   by (rule subsetD)
   376 
   377 declare rev_subsetD [intro?] -- FIXME
   378 
   379 text {*
   380   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   381 *}
   382 
   383 ML {*
   384   local val rev_subsetD = thm "rev_subsetD"
   385   in fun impOfSubs th = th RSN (2, rev_subsetD) end;
   386 *}
   387 
   388 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   389   -- {* Classical elimination rule. *}
   390   by (unfold subset_def) blast
   391 
   392 text {*
   393   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   394   creates the assumption @{prop "c \<in> B"}.
   395 *}
   396 
   397 ML {*
   398   local val subsetCE = thm "subsetCE"
   399   in fun set_mp_tac i = etac subsetCE i THEN mp_tac i end;
   400 *}
   401 
   402 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   403   by blast
   404 
   405 lemma subset_refl: "A \<subseteq> A"
   406   by fast
   407 
   408 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   409   by blast
   410 
   411 
   412 subsubsection {* Equality *}
   413 
   414 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   415   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   416    apply (rule Collect_mem_eq)
   417   apply (rule Collect_mem_eq)
   418   done
   419 
   420 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   421   -- {* Anti-symmetry of the subset relation. *}
   422   by (rules intro: set_ext subsetD)
   423 
   424 lemmas equalityI [intro!] = subset_antisym
   425 
   426 text {*
   427   \medskip Equality rules from ZF set theory -- are they appropriate
   428   here?
   429 *}
   430 
   431 lemma equalityD1: "A = B ==> A \<subseteq> B"
   432   by (simp add: subset_refl)
   433 
   434 lemma equalityD2: "A = B ==> B \<subseteq> A"
   435   by (simp add: subset_refl)
   436 
   437 text {*
   438   \medskip Be careful when adding this to the claset as @{text
   439   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   440   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   441 *}
   442 
   443 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   444   by (simp add: subset_refl)
   445 
   446 lemma equalityCE [elim]:
   447     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   448   by blast
   449 
   450 text {*
   451   \medskip Lemma for creating induction formulae -- for "pattern
   452   matching" on @{text p}.  To make the induction hypotheses usable,
   453   apply @{text spec} or @{text bspec} to put universal quantifiers over the free
   454   variables in @{text p}.
   455 *}
   456 
   457 lemma setup_induction: "p:A ==> (!!z. z:A ==> p = z --> R) ==> R"
   458   by simp
   459 
   460 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   461   by simp
   462 
   463 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   464   by simp
   465 
   466 
   467 subsubsection {* The universal set -- UNIV *}
   468 
   469 lemma UNIV_I [simp]: "x : UNIV"
   470   by (simp add: UNIV_def)
   471 
   472 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   473 
   474 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   475   by simp
   476 
   477 lemma subset_UNIV: "A \<subseteq> UNIV"
   478   by (rule subsetI) (rule UNIV_I)
   479 
   480 text {*
   481   \medskip Eta-contracting these two rules (to remove @{text P})
   482   causes them to be ignored because of their interaction with
   483   congruence rules.
   484 *}
   485 
   486 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   487   by (simp add: Ball_def)
   488 
   489 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   490   by (simp add: Bex_def)
   491 
   492 
   493 subsubsection {* The empty set *}
   494 
   495 lemma empty_iff [simp]: "(c : {}) = False"
   496   by (simp add: empty_def)
   497 
   498 lemma emptyE [elim!]: "a : {} ==> P"
   499   by simp
   500 
   501 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   502     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   503   by blast
   504 
   505 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   506   by blast
   507 
   508 lemma equals0D: "A = {} ==> a \<notin> A"
   509     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   510   by blast
   511 
   512 lemma ball_empty [simp]: "Ball {} P = True"
   513   by (simp add: Ball_def)
   514 
   515 lemma bex_empty [simp]: "Bex {} P = False"
   516   by (simp add: Bex_def)
   517 
   518 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   519   by (blast elim: equalityE)
   520 
   521 
   522 subsubsection {* The Powerset operator -- Pow *}
   523 
   524 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   525   by (simp add: Pow_def)
   526 
   527 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   528   by (simp add: Pow_def)
   529 
   530 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   531   by (simp add: Pow_def)
   532 
   533 lemma Pow_bottom: "{} \<in> Pow B"
   534   by simp
   535 
   536 lemma Pow_top: "A \<in> Pow A"
   537   by (simp add: subset_refl)
   538 
   539 
   540 subsubsection {* Set complement *}
   541 
   542 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   543   by (unfold Compl_def) blast
   544 
   545 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   546   by (unfold Compl_def) blast
   547 
   548 text {*
   549   \medskip This form, with negated conclusion, works well with the
   550   Classical prover.  Negated assumptions behave like formulae on the
   551   right side of the notional turnstile ... *}
   552 
   553 lemma ComplD: "c : -A ==> c~:A"
   554   by (unfold Compl_def) blast
   555 
   556 lemmas ComplE [elim!] = ComplD [elim_format]
   557 
   558 
   559 subsubsection {* Binary union -- Un *}
   560 
   561 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   562   by (unfold Un_def) blast
   563 
   564 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   565   by simp
   566 
   567 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   568   by simp
   569 
   570 text {*
   571   \medskip Classical introduction rule: no commitment to @{prop A} vs
   572   @{prop B}.
   573 *}
   574 
   575 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   576   by auto
   577 
   578 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   579   by (unfold Un_def) blast
   580 
   581 
   582 subsubsection {* Binary intersection -- Int *}
   583 
   584 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   585   by (unfold Int_def) blast
   586 
   587 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   588   by simp
   589 
   590 lemma IntD1: "c : A Int B ==> c:A"
   591   by simp
   592 
   593 lemma IntD2: "c : A Int B ==> c:B"
   594   by simp
   595 
   596 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   597   by simp
   598 
   599 
   600 subsubsection {* Set difference *}
   601 
   602 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   603   by (unfold set_diff_def) blast
   604 
   605 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   606   by simp
   607 
   608 lemma DiffD1: "c : A - B ==> c : A"
   609   by simp
   610 
   611 lemma DiffD2: "c : A - B ==> c : B ==> P"
   612   by simp
   613 
   614 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   615   by simp
   616 
   617 
   618 subsubsection {* Augmenting a set -- insert *}
   619 
   620 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   621   by (unfold insert_def) blast
   622 
   623 lemma insertI1: "a : insert a B"
   624   by simp
   625 
   626 lemma insertI2: "a : B ==> a : insert b B"
   627   by simp
   628 
   629 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   630   by (unfold insert_def) blast
   631 
   632 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   633   -- {* Classical introduction rule. *}
   634   by auto
   635 
   636 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   637   by auto
   638 
   639 
   640 subsubsection {* Singletons, using insert *}
   641 
   642 lemma singletonI [intro!]: "a : {a}"
   643     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   644   by (rule insertI1)
   645 
   646 lemma singletonD: "b : {a} ==> b = a"
   647   by blast
   648 
   649 lemmas singletonE [elim!] = singletonD [elim_format]
   650 
   651 lemma singleton_iff: "(b : {a}) = (b = a)"
   652   by blast
   653 
   654 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   655   by blast
   656 
   657 lemma singleton_insert_inj_eq [iff]: "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   658   by blast
   659 
   660 lemma singleton_insert_inj_eq' [iff]: "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   661   by blast
   662 
   663 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   664   by fast
   665 
   666 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   667   by blast
   668 
   669 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   670   by blast
   671 
   672 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   673   by blast
   674 
   675 
   676 subsubsection {* Unions of families *}
   677 
   678 text {*
   679   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   680 *}
   681 
   682 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   683   by (unfold UNION_def) blast
   684 
   685 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   686   -- {* The order of the premises presupposes that @{term A} is rigid;
   687     @{term b} may be flexible. *}
   688   by auto
   689 
   690 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   691   by (unfold UNION_def) blast
   692 
   693 lemma UN_cong [cong]:
   694     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   695   by (simp add: UNION_def)
   696 
   697 
   698 subsubsection {* Intersections of families *}
   699 
   700 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   701 
   702 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   703   by (unfold INTER_def) blast
   704 
   705 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   706   by (unfold INTER_def) blast
   707 
   708 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   709   by auto
   710 
   711 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   712   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   713   by (unfold INTER_def) blast
   714 
   715 lemma INT_cong [cong]:
   716     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   717   by (simp add: INTER_def)
   718 
   719 
   720 subsubsection {* Union *}
   721 
   722 lemma Union_iff [simp]: "(A : Union C) = (EX X:C. A:X)"
   723   by (unfold Union_def) blast
   724 
   725 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   726   -- {* The order of the premises presupposes that @{term C} is rigid;
   727     @{term A} may be flexible. *}
   728   by auto
   729 
   730 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   731   by (unfold Union_def) blast
   732 
   733 
   734 subsubsection {* Inter *}
   735 
   736 lemma Inter_iff [simp]: "(A : Inter C) = (ALL X:C. A:X)"
   737   by (unfold Inter_def) blast
   738 
   739 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   740   by (simp add: Inter_def)
   741 
   742 text {*
   743   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   744   contains @{term A} as an element, but @{prop "A:X"} can hold when
   745   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   746 *}
   747 
   748 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   749   by auto
   750 
   751 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   752   -- {* ``Classical'' elimination rule -- does not require proving
   753     @{prop "X:C"}. *}
   754   by (unfold Inter_def) blast
   755 
   756 text {*
   757   \medskip Image of a set under a function.  Frequently @{term b} does
   758   not have the syntactic form of @{term "f x"}.
   759 *}
   760 
   761 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   762   by (unfold image_def) blast
   763 
   764 lemma imageI: "x : A ==> f x : f ` A"
   765   by (rule image_eqI) (rule refl)
   766 
   767 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   768   -- {* This version's more effective when we already have the
   769     required @{term x}. *}
   770   by (unfold image_def) blast
   771 
   772 lemma imageE [elim!]:
   773   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   774   -- {* The eta-expansion gives variable-name preservation. *}
   775   by (unfold image_def) blast
   776 
   777 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   778   by blast
   779 
   780 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   781   by blast
   782 
   783 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   784   -- {* This rewrite rule would confuse users if made default. *}
   785   by blast
   786 
   787 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   788   apply safe
   789    prefer 2 apply fast
   790   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
   791   done
   792 
   793 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   794   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   795     @{text hypsubst}, but breaks too many existing proofs. *}
   796   by blast
   797 
   798 text {*
   799   \medskip Range of a function -- just a translation for image!
   800 *}
   801 
   802 lemma range_eqI: "b = f x ==> b \<in> range f"
   803   by simp
   804 
   805 lemma rangeI: "f x \<in> range f"
   806   by simp
   807 
   808 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   809   by blast
   810 
   811 
   812 subsubsection {* Set reasoning tools *}
   813 
   814 text {*
   815   Rewrite rules for boolean case-splitting: faster than @{text
   816   "split_if [split]"}.
   817 *}
   818 
   819 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   820   by (rule split_if)
   821 
   822 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   823   by (rule split_if)
   824 
   825 text {*
   826   Split ifs on either side of the membership relation.  Not for @{text
   827   "[simp]"} -- can cause goals to blow up!
   828 *}
   829 
   830 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   831   by (rule split_if)
   832 
   833 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   834   by (rule split_if)
   835 
   836 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   837 
   838 lemmas mem_simps =
   839   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   840   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   841   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   842 
   843 (*Would like to add these, but the existing code only searches for the
   844   outer-level constant, which in this case is just "op :"; we instead need
   845   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   846   apply, then the formula should be kept.
   847   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]),
   848    ("op Int", [IntD1,IntD2]),
   849    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   850  *)
   851 
   852 ML_setup {*
   853   val mksimps_pairs = [("Ball", [thm "bspec"])] @ mksimps_pairs;
   854   simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   855 *}
   856 
   857 declare subset_UNIV [simp] subset_refl [simp]
   858 
   859 
   860 subsubsection {* The ``proper subset'' relation *}
   861 
   862 lemma psubsetI [intro!]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
   863   by (unfold psubset_def) blast
   864 
   865 lemma psubsetE [elim!]: 
   866     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
   867   by (unfold psubset_def) blast
   868 
   869 lemma psubset_insert_iff:
   870   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
   871   by (auto simp add: psubset_def subset_insert_iff)
   872 
   873 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
   874   by (simp only: psubset_def)
   875 
   876 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
   877   by (simp add: psubset_eq)
   878 
   879 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
   880 apply (unfold psubset_def)
   881 apply (auto dest: subset_antisym)
   882 done
   883 
   884 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
   885 apply (unfold psubset_def)
   886 apply (auto dest: subsetD)
   887 done
   888 
   889 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
   890   by (auto simp add: psubset_eq)
   891 
   892 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
   893   by (auto simp add: psubset_eq)
   894 
   895 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
   896   by (unfold psubset_def) blast
   897 
   898 lemma atomize_ball:
   899     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
   900   by (simp only: Ball_def atomize_all atomize_imp)
   901 
   902 declare atomize_ball [symmetric, rulify]
   903 
   904 
   905 subsection {* Further set-theory lemmas *}
   906 
   907 subsubsection {* Derived rules involving subsets. *}
   908 
   909 text {* @{text insert}. *}
   910 
   911 lemma subset_insertI: "B \<subseteq> insert a B"
   912   apply (rule subsetI)
   913   apply (erule insertI2)
   914   done
   915 
   916 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
   917 by blast
   918 
   919 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
   920   by blast
   921 
   922 
   923 text {* \medskip Big Union -- least upper bound of a set. *}
   924 
   925 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   926   by (rules intro: subsetI UnionI)
   927 
   928 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   929   by (rules intro: subsetI elim: UnionE dest: subsetD)
   930 
   931 
   932 text {* \medskip General union. *}
   933 
   934 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   935   by blast
   936 
   937 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   938   by (rules intro: subsetI elim: UN_E dest: subsetD)
   939 
   940 
   941 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
   942 
   943 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
   944   by blast
   945 
   946 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   947   by (rules intro: InterI subsetI dest: subsetD)
   948 
   949 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   950   by blast
   951 
   952 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   953   by (rules intro: INT_I subsetI dest: subsetD)
   954 
   955 
   956 text {* \medskip Finite Union -- the least upper bound of two sets. *}
   957 
   958 lemma Un_upper1: "A \<subseteq> A \<union> B"
   959   by blast
   960 
   961 lemma Un_upper2: "B \<subseteq> A \<union> B"
   962   by blast
   963 
   964 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
   965   by blast
   966 
   967 
   968 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
   969 
   970 lemma Int_lower1: "A \<inter> B \<subseteq> A"
   971   by blast
   972 
   973 lemma Int_lower2: "A \<inter> B \<subseteq> B"
   974   by blast
   975 
   976 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
   977   by blast
   978 
   979 
   980 text {* \medskip Set difference. *}
   981 
   982 lemma Diff_subset: "A - B \<subseteq> A"
   983   by blast
   984 
   985 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
   986 by blast
   987 
   988 
   989 text {* \medskip Monotonicity. *}
   990 
   991 lemma mono_Un: includes mono shows "f A \<union> f B \<subseteq> f (A \<union> B)"
   992   apply (rule Un_least)
   993    apply (rule Un_upper1 [THEN mono])
   994   apply (rule Un_upper2 [THEN mono])
   995   done
   996 
   997 lemma mono_Int: includes mono shows "f (A \<inter> B) \<subseteq> f A \<inter> f B"
   998   apply (rule Int_greatest)
   999    apply (rule Int_lower1 [THEN mono])
  1000   apply (rule Int_lower2 [THEN mono])
  1001   done
  1002 
  1003 
  1004 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
  1005 
  1006 text {* @{text "{}"}. *}
  1007 
  1008 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1009   -- {* supersedes @{text "Collect_False_empty"} *}
  1010   by auto
  1011 
  1012 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1013   by blast
  1014 
  1015 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1016   by (unfold psubset_def) blast
  1017 
  1018 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1019   by auto
  1020 
  1021 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1022   by blast
  1023 
  1024 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1025   by blast
  1026 
  1027 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1028   by blast
  1029 
  1030 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1031   by blast
  1032 
  1033 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1034   by blast
  1035 
  1036 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1037   by blast
  1038 
  1039 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1040   by blast
  1041 
  1042 
  1043 text {* \medskip @{text insert}. *}
  1044 
  1045 lemma insert_is_Un: "insert a A = {a} Un A"
  1046   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1047   by blast
  1048 
  1049 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1050   by blast
  1051 
  1052 lemmas empty_not_insert [simp] = insert_not_empty [symmetric, standard]
  1053 
  1054 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1055   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1056   -- {* with \emph{quadratic} running time *}
  1057   by blast
  1058 
  1059 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1060   by blast
  1061 
  1062 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1063   by blast
  1064 
  1065 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1066   by blast
  1067 
  1068 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1069   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1070   apply (rule_tac x = "A - {a}" in exI, blast)
  1071   done
  1072 
  1073 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1074   by auto
  1075 
  1076 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1077   by blast
  1078 
  1079 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1080 by blast
  1081 
  1082 lemma insert_disjoint[simp]:
  1083  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1084 by blast
  1085 
  1086 lemma disjoint_insert[simp]:
  1087  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1088 by blast
  1089 
  1090 text {* \medskip @{text image}. *}
  1091 
  1092 lemma image_empty [simp]: "f`{} = {}"
  1093   by blast
  1094 
  1095 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1096   by blast
  1097 
  1098 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1099   by blast
  1100 
  1101 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1102   by blast
  1103 
  1104 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1105   by blast
  1106 
  1107 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1108   by blast
  1109 
  1110 lemma image_Collect: "f ` {x. P x} = {f x | x. P x}"
  1111   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS, *}
  1112   -- {* with its implicit quantifier and conjunction.  Also image enjoys better *}
  1113   -- {* equational properties than does the RHS. *}
  1114   by blast
  1115 
  1116 lemma if_image_distrib [simp]:
  1117   "(\<lambda>x. if P x then f x else g x) ` S
  1118     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1119   by (auto simp add: image_def)
  1120 
  1121 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1122   by (simp add: image_def)
  1123 
  1124 
  1125 text {* \medskip @{text range}. *}
  1126 
  1127 lemma full_SetCompr_eq: "{u. \<exists>x. u = f x} = range f"
  1128   by auto
  1129 
  1130 lemma range_composition [simp]: "range (\<lambda>x. f (g x)) = f`range g"
  1131 by (subst image_image, simp)
  1132 
  1133 
  1134 text {* \medskip @{text Int} *}
  1135 
  1136 lemma Int_absorb [simp]: "A \<inter> A = A"
  1137   by blast
  1138 
  1139 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1140   by blast
  1141 
  1142 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1143   by blast
  1144 
  1145 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1146   by blast
  1147 
  1148 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1149   by blast
  1150 
  1151 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1152   -- {* Intersection is an AC-operator *}
  1153 
  1154 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1155   by blast
  1156 
  1157 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1158   by blast
  1159 
  1160 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1161   by blast
  1162 
  1163 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1164   by blast
  1165 
  1166 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1167   by blast
  1168 
  1169 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1170   by blast
  1171 
  1172 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1173   by blast
  1174 
  1175 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1176   by blast
  1177 
  1178 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1179   by blast
  1180 
  1181 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1182   by blast
  1183 
  1184 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1185   by blast
  1186 
  1187 lemma Int_UNIV [simp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1188   by blast
  1189 
  1190 lemma Int_subset_iff: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1191   by blast
  1192 
  1193 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1194   by blast
  1195 
  1196 
  1197 text {* \medskip @{text Un}. *}
  1198 
  1199 lemma Un_absorb [simp]: "A \<union> A = A"
  1200   by blast
  1201 
  1202 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1203   by blast
  1204 
  1205 lemma Un_commute: "A \<union> B = B \<union> A"
  1206   by blast
  1207 
  1208 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1209   by blast
  1210 
  1211 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1212   by blast
  1213 
  1214 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1215   -- {* Union is an AC-operator *}
  1216 
  1217 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1218   by blast
  1219 
  1220 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1221   by blast
  1222 
  1223 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1224   by blast
  1225 
  1226 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1227   by blast
  1228 
  1229 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1230   by blast
  1231 
  1232 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1233   by blast
  1234 
  1235 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1236   by blast
  1237 
  1238 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1239   by blast
  1240 
  1241 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1242   by blast
  1243 
  1244 lemma Int_insert_left:
  1245     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1246   by auto
  1247 
  1248 lemma Int_insert_right:
  1249     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1250   by auto
  1251 
  1252 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1253   by blast
  1254 
  1255 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1256   by blast
  1257 
  1258 lemma Un_Int_crazy:
  1259     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1260   by blast
  1261 
  1262 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1263   by blast
  1264 
  1265 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1266   by blast
  1267 
  1268 lemma Un_subset_iff: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1269   by blast
  1270 
  1271 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1272   by blast
  1273 
  1274 
  1275 text {* \medskip Set complement *}
  1276 
  1277 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1278   by blast
  1279 
  1280 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1281   by blast
  1282 
  1283 lemma Compl_partition: "A \<union> -A = UNIV"
  1284   by blast
  1285 
  1286 lemma Compl_partition2: "-A \<union> A = UNIV"
  1287   by blast
  1288 
  1289 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1290   by blast
  1291 
  1292 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1293   by blast
  1294 
  1295 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1296   by blast
  1297 
  1298 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1299   by blast
  1300 
  1301 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1302   by blast
  1303 
  1304 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1305   by blast
  1306 
  1307 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1308   -- {* Halmos, Naive Set Theory, page 16. *}
  1309   by blast
  1310 
  1311 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1312   by blast
  1313 
  1314 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1315   by blast
  1316 
  1317 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1318   by blast
  1319 
  1320 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1321   by blast
  1322 
  1323 
  1324 text {* \medskip @{text Union}. *}
  1325 
  1326 lemma Union_empty [simp]: "Union({}) = {}"
  1327   by blast
  1328 
  1329 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1330   by blast
  1331 
  1332 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1333   by blast
  1334 
  1335 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1336   by blast
  1337 
  1338 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1339   by blast
  1340 
  1341 lemma Union_empty_conv [iff]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1342   by blast
  1343 
  1344 lemma empty_Union_conv [iff]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1345   by blast
  1346 
  1347 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1348   by blast
  1349 
  1350 
  1351 text {* \medskip @{text Inter}. *}
  1352 
  1353 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1354   by blast
  1355 
  1356 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1357   by blast
  1358 
  1359 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1360   by blast
  1361 
  1362 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1363   by blast
  1364 
  1365 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1366   by blast
  1367 
  1368 lemma Inter_UNIV_conv [iff]:
  1369   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1370   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1371   by blast+
  1372 
  1373 
  1374 text {*
  1375   \medskip @{text UN} and @{text INT}.
  1376 
  1377   Basic identities: *}
  1378 
  1379 lemma UN_empty [simp]: "(\<Union>x\<in>{}. B x) = {}"
  1380   by blast
  1381 
  1382 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1383   by blast
  1384 
  1385 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1386   by blast
  1387 
  1388 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1389   by blast
  1390 
  1391 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1392   by blast
  1393 
  1394 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1395   by blast
  1396 
  1397 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1398   by blast
  1399 
  1400 lemma UN_Un: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1401   by blast
  1402 
  1403 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1404   by blast
  1405 
  1406 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1407   by blast
  1408 
  1409 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1410   by blast
  1411 
  1412 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1413   by blast
  1414 
  1415 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1416   by blast
  1417 
  1418 lemma INT_insert_distrib:
  1419     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1420   by blast
  1421 
  1422 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1423   by blast
  1424 
  1425 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1426   by blast
  1427 
  1428 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1429   by blast
  1430 
  1431 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1432   by auto
  1433 
  1434 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1435   by auto
  1436 
  1437 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1438   by blast
  1439 
  1440 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1441   -- {* Look: it has an \emph{existential} quantifier *}
  1442   by blast
  1443 
  1444 lemma UNION_empty_conv[iff]:
  1445   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1446   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1447 by blast+
  1448 
  1449 lemma INTER_UNIV_conv[iff]:
  1450  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1451  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1452 by blast+
  1453 
  1454 
  1455 text {* \medskip Distributive laws: *}
  1456 
  1457 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1458   by blast
  1459 
  1460 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1461   by blast
  1462 
  1463 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1464   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1465   -- {* Union of a family of unions *}
  1466   by blast
  1467 
  1468 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1469   -- {* Equivalent version *}
  1470   by blast
  1471 
  1472 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1473   by blast
  1474 
  1475 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1476   by blast
  1477 
  1478 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1479   -- {* Equivalent version *}
  1480   by blast
  1481 
  1482 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1483   -- {* Halmos, Naive Set Theory, page 35. *}
  1484   by blast
  1485 
  1486 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1487   by blast
  1488 
  1489 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1490   by blast
  1491 
  1492 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1493   by blast
  1494 
  1495 
  1496 text {* \medskip Bounded quantifiers.
  1497 
  1498   The following are not added to the default simpset because
  1499   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1500 
  1501 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1502   by blast
  1503 
  1504 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1505   by blast
  1506 
  1507 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1508   by blast
  1509 
  1510 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1511   by blast
  1512 
  1513 
  1514 text {* \medskip Set difference. *}
  1515 
  1516 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1517   by blast
  1518 
  1519 lemma Diff_eq_empty_iff [simp]: "(A - B = {}) = (A \<subseteq> B)"
  1520   by blast
  1521 
  1522 lemma Diff_cancel [simp]: "A - A = {}"
  1523   by blast
  1524 
  1525 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1526 by blast
  1527 
  1528 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1529   by (blast elim: equalityE)
  1530 
  1531 lemma empty_Diff [simp]: "{} - A = {}"
  1532   by blast
  1533 
  1534 lemma Diff_empty [simp]: "A - {} = A"
  1535   by blast
  1536 
  1537 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1538   by blast
  1539 
  1540 lemma Diff_insert0 [simp]: "x \<notin> A ==> A - insert x B = A - B"
  1541   by blast
  1542 
  1543 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1544   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1545   by blast
  1546 
  1547 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1548   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1549   by blast
  1550 
  1551 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1552   by auto
  1553 
  1554 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1555   by blast
  1556 
  1557 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1558 by blast
  1559 
  1560 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1561   by blast
  1562 
  1563 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1564   by auto
  1565 
  1566 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1567   by blast
  1568 
  1569 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1570   by blast
  1571 
  1572 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1573   by blast
  1574 
  1575 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1576   by blast
  1577 
  1578 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1579   by blast
  1580 
  1581 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1582   by blast
  1583 
  1584 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1585   by blast
  1586 
  1587 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1588   by blast
  1589 
  1590 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1591   by blast
  1592 
  1593 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1594   by blast
  1595 
  1596 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1597   by blast
  1598 
  1599 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1600   by auto
  1601 
  1602 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1603   by blast
  1604 
  1605 
  1606 text {* \medskip Quantification over type @{typ bool}. *}
  1607 
  1608 lemma all_bool_eq: "(\<forall>b::bool. P b) = (P True & P False)"
  1609   apply auto
  1610   apply (tactic {* case_tac "b" 1 *}, auto)
  1611   done
  1612 
  1613 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1614   by (rule conjI [THEN all_bool_eq [THEN iffD2], THEN spec])
  1615 
  1616 lemma ex_bool_eq: "(\<exists>b::bool. P b) = (P True | P False)"
  1617   apply auto
  1618   apply (tactic {* case_tac "b" 1 *}, auto)
  1619   done
  1620 
  1621 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1622   by (auto simp add: split_if_mem2)
  1623 
  1624 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1625   apply auto
  1626   apply (tactic {* case_tac "b" 1 *}, auto)
  1627   done
  1628 
  1629 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1630   apply auto
  1631   apply (tactic {* case_tac "b" 1 *}, auto)
  1632   done
  1633 
  1634 
  1635 text {* \medskip @{text Pow} *}
  1636 
  1637 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1638   by (auto simp add: Pow_def)
  1639 
  1640 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1641   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1642 
  1643 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1644   by (blast intro: exI [where ?x = "- u", standard])
  1645 
  1646 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1647   by blast
  1648 
  1649 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1650   by blast
  1651 
  1652 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1653   by blast
  1654 
  1655 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1656   by blast
  1657 
  1658 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1659   by blast
  1660 
  1661 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1662   by blast
  1663 
  1664 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1665   by blast
  1666 
  1667 
  1668 text {* \medskip Miscellany. *}
  1669 
  1670 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1671   by blast
  1672 
  1673 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1674   by blast
  1675 
  1676 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1677   by (unfold psubset_def) blast
  1678 
  1679 lemma all_not_in_conv [iff]: "(\<forall>x. x \<notin> A) = (A = {})"
  1680   by blast
  1681 
  1682 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1683   by blast
  1684 
  1685 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1686   by rules
  1687 
  1688 
  1689 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1690            and Intersections. *}
  1691 
  1692 lemma UN_simps [simp]:
  1693   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1694   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1695   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1696   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1697   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1698   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1699   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1700   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1701   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1702   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1703   by auto
  1704 
  1705 lemma INT_simps [simp]:
  1706   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1707   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1708   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1709   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1710   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1711   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1712   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1713   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1714   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1715   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1716   by auto
  1717 
  1718 lemma ball_simps [simp]:
  1719   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1720   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1721   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1722   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1723   "!!P. (ALL x:{}. P x) = True"
  1724   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1725   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1726   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1727   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1728   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1729   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1730   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1731   by auto
  1732 
  1733 lemma bex_simps [simp]:
  1734   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1735   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1736   "!!P. (EX x:{}. P x) = False"
  1737   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1738   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1739   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1740   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1741   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1742   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1743   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1744   by auto
  1745 
  1746 lemma ball_conj_distrib:
  1747   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1748   by blast
  1749 
  1750 lemma bex_disj_distrib:
  1751   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1752   by blast
  1753 
  1754 
  1755 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1756 
  1757 lemma UN_extend_simps:
  1758   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  1759   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  1760   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  1761   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  1762   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  1763   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  1764   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  1765   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  1766   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  1767   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  1768   by auto
  1769 
  1770 lemma INT_extend_simps:
  1771   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  1772   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  1773   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  1774   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  1775   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  1776   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  1777   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  1778   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  1779   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  1780   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  1781   by auto
  1782 
  1783 
  1784 subsubsection {* Monotonicity of various operations *}
  1785 
  1786 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1787   by blast
  1788 
  1789 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1790   by blast
  1791 
  1792 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  1793   by blast
  1794 
  1795 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  1796   by blast
  1797 
  1798 lemma UN_mono:
  1799   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1800     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1801   by (blast dest: subsetD)
  1802 
  1803 lemma INT_anti_mono:
  1804   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1805     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1806   -- {* The last inclusion is POSITIVE! *}
  1807   by (blast dest: subsetD)
  1808 
  1809 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1810   by blast
  1811 
  1812 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1813   by blast
  1814 
  1815 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1816   by blast
  1817 
  1818 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1819   by blast
  1820 
  1821 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1822   by blast
  1823 
  1824 text {* \medskip Monotonicity of implications. *}
  1825 
  1826 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1827   apply (rule impI)
  1828   apply (erule subsetD, assumption)
  1829   done
  1830 
  1831 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1832   by rules
  1833 
  1834 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1835   by rules
  1836 
  1837 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1838   by rules
  1839 
  1840 lemma imp_refl: "P --> P" ..
  1841 
  1842 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1843   by rules
  1844 
  1845 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1846   by rules
  1847 
  1848 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  1849   by blast
  1850 
  1851 lemma Int_Collect_mono:
  1852     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  1853   by blast
  1854 
  1855 lemmas basic_monos =
  1856   subset_refl imp_refl disj_mono conj_mono
  1857   ex_mono Collect_mono in_mono
  1858 
  1859 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  1860   by rules
  1861 
  1862 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  1863   by rules
  1864 
  1865 lemma Least_mono:
  1866   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1867     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1868     -- {* Courtesy of Stephan Merz *}
  1869   apply clarify
  1870   apply (erule_tac P = "%x. x : S" in LeastI2, fast)
  1871   apply (rule LeastI2)
  1872   apply (auto elim: monoD intro!: order_antisym)
  1873   done
  1874 
  1875 
  1876 subsection {* Inverse image of a function *}
  1877 
  1878 constdefs
  1879   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  1880   "f -` B == {x. f x : B}"
  1881 
  1882 
  1883 subsubsection {* Basic rules *}
  1884 
  1885 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  1886   by (unfold vimage_def) blast
  1887 
  1888 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  1889   by simp
  1890 
  1891 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  1892   by (unfold vimage_def) blast
  1893 
  1894 lemma vimageI2: "f a : A ==> a : f -` A"
  1895   by (unfold vimage_def) fast
  1896 
  1897 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  1898   by (unfold vimage_def) blast
  1899 
  1900 lemma vimageD: "a : f -` A ==> f a : A"
  1901   by (unfold vimage_def) fast
  1902 
  1903 
  1904 subsubsection {* Equations *}
  1905 
  1906 lemma vimage_empty [simp]: "f -` {} = {}"
  1907   by blast
  1908 
  1909 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  1910   by blast
  1911 
  1912 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  1913   by blast
  1914 
  1915 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  1916   by fast
  1917 
  1918 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  1919   by blast
  1920 
  1921 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  1922   by blast
  1923 
  1924 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  1925   by blast
  1926 
  1927 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  1928   by blast
  1929 
  1930 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  1931   by blast
  1932 
  1933 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  1934   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  1935   by blast
  1936 
  1937 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  1938   by blast
  1939 
  1940 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  1941   by blast
  1942 
  1943 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  1944   -- {* NOT suitable for rewriting *}
  1945   by blast
  1946 
  1947 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  1948   -- {* monotonicity *}
  1949   by blast
  1950 
  1951 
  1952 subsection {* Transitivity rules for calculational reasoning *}
  1953 
  1954 lemma forw_subst: "a = b ==> P b ==> P a"
  1955   by (rule ssubst)
  1956 
  1957 lemma back_subst: "P a ==> a = b ==> P b"
  1958   by (rule subst)
  1959 
  1960 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  1961   by (rule subsetD)
  1962 
  1963 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  1964   by (rule subsetD)
  1965 
  1966 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
  1967   by (rule subst)
  1968 
  1969 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
  1970   by (rule ssubst)
  1971 
  1972 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
  1973   by (rule subst)
  1974 
  1975 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
  1976   by (rule ssubst)
  1977 
  1978 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
  1979   (!!x y. x < y ==> f x < f y) ==> f a < c"
  1980 proof -
  1981   assume r: "!!x y. x < y ==> f x < f y"
  1982   assume "a < b" hence "f a < f b" by (rule r)
  1983   also assume "f b < c"
  1984   finally (order_less_trans) show ?thesis .
  1985 qed
  1986 
  1987 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
  1988   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1989 proof -
  1990   assume r: "!!x y. x < y ==> f x < f y"
  1991   assume "a < f b"
  1992   also assume "b < c" hence "f b < f c" by (rule r)
  1993   finally (order_less_trans) show ?thesis .
  1994 qed
  1995 
  1996 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
  1997   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
  1998 proof -
  1999   assume r: "!!x y. x <= y ==> f x <= f y"
  2000   assume "a <= b" hence "f a <= f b" by (rule r)
  2001   also assume "f b < c"
  2002   finally (order_le_less_trans) show ?thesis .
  2003 qed
  2004 
  2005 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
  2006   (!!x y. x < y ==> f x < f y) ==> a < f c"
  2007 proof -
  2008   assume r: "!!x y. x < y ==> f x < f y"
  2009   assume "a <= f b"
  2010   also assume "b < c" hence "f b < f c" by (rule r)
  2011   finally (order_le_less_trans) show ?thesis .
  2012 qed
  2013 
  2014 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
  2015   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2016 proof -
  2017   assume r: "!!x y. x < y ==> f x < f y"
  2018   assume "a < b" hence "f a < f b" by (rule r)
  2019   also assume "f b <= c"
  2020   finally (order_less_le_trans) show ?thesis .
  2021 qed
  2022 
  2023 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
  2024   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
  2025 proof -
  2026   assume r: "!!x y. x <= y ==> f x <= f y"
  2027   assume "a < f b"
  2028   also assume "b <= c" hence "f b <= f c" by (rule r)
  2029   finally (order_less_le_trans) show ?thesis .
  2030 qed
  2031 
  2032 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
  2033   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2034 proof -
  2035   assume r: "!!x y. x <= y ==> f x <= f y"
  2036   assume "a <= f b"
  2037   also assume "b <= c" hence "f b <= f c" by (rule r)
  2038   finally (order_trans) show ?thesis .
  2039 qed
  2040 
  2041 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
  2042   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2043 proof -
  2044   assume r: "!!x y. x <= y ==> f x <= f y"
  2045   assume "a <= b" hence "f a <= f b" by (rule r)
  2046   also assume "f b <= c"
  2047   finally (order_trans) show ?thesis .
  2048 qed
  2049 
  2050 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
  2051   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2052 proof -
  2053   assume r: "!!x y. x <= y ==> f x <= f y"
  2054   assume "a <= b" hence "f a <= f b" by (rule r)
  2055   also assume "f b = c"
  2056   finally (ord_le_eq_trans) show ?thesis .
  2057 qed
  2058 
  2059 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
  2060   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2061 proof -
  2062   assume r: "!!x y. x <= y ==> f x <= f y"
  2063   assume "a = f b"
  2064   also assume "b <= c" hence "f b <= f c" by (rule r)
  2065   finally (ord_eq_le_trans) show ?thesis .
  2066 qed
  2067 
  2068 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
  2069   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2070 proof -
  2071   assume r: "!!x y. x < y ==> f x < f y"
  2072   assume "a < b" hence "f a < f b" by (rule r)
  2073   also assume "f b = c"
  2074   finally (ord_less_eq_trans) show ?thesis .
  2075 qed
  2076 
  2077 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
  2078   (!!x y. x < y ==> f x < f y) ==> a < f c"
  2079 proof -
  2080   assume r: "!!x y. x < y ==> f x < f y"
  2081   assume "a = f b"
  2082   also assume "b < c" hence "f b < f c" by (rule r)
  2083   finally (ord_eq_less_trans) show ?thesis .
  2084 qed
  2085 
  2086 text {*
  2087   Note that this list of rules is in reverse order of priorities.
  2088 *}
  2089 
  2090 lemmas basic_trans_rules [trans] =
  2091   order_less_subst2
  2092   order_less_subst1
  2093   order_le_less_subst2
  2094   order_le_less_subst1
  2095   order_less_le_subst2
  2096   order_less_le_subst1
  2097   order_subst2
  2098   order_subst1
  2099   ord_le_eq_subst
  2100   ord_eq_le_subst
  2101   ord_less_eq_subst
  2102   ord_eq_less_subst
  2103   forw_subst
  2104   back_subst
  2105   rev_mp
  2106   mp
  2107   set_rev_mp
  2108   set_mp
  2109   order_neq_le_trans
  2110   order_le_neq_trans
  2111   order_less_trans
  2112   order_less_asym'
  2113   order_le_less_trans
  2114   order_less_le_trans
  2115   order_trans
  2116   order_antisym
  2117   ord_le_eq_trans
  2118   ord_eq_le_trans
  2119   ord_less_eq_trans
  2120   ord_eq_less_trans
  2121   trans
  2122 
  2123 end