src/HOL/Probability/Probability_Mass_Function.thy
author hoelzl
Thu Jan 22 14:51:08 2015 +0100 (2015-01-22)
changeset 59425 c5e79df8cc21
parent 59327 8a779359df67
child 59475 8300c4ddf493
permissions -rw-r--r--
import general thms from Density_Compiler
     1 (*  Title:      HOL/Probability/Probability_Mass_Function.thy
     2     Author:     Johannes Hölzl, TU München 
     3     Author:     Andreas Lochbihler, ETH Zurich
     4 *)
     5 
     6 section \<open> Probability mass function \<close>
     7 
     8 theory Probability_Mass_Function
     9 imports
    10   Giry_Monad
    11   "~~/src/HOL/Number_Theory/Binomial"
    12   "~~/src/HOL/Library/Multiset"
    13 begin
    14 
    15 lemma (in finite_measure) countable_support:
    16   "countable {x. measure M {x} \<noteq> 0}"
    17 proof cases
    18   assume "measure M (space M) = 0"
    19   with bounded_measure measure_le_0_iff have "{x. measure M {x} \<noteq> 0} = {}"
    20     by auto
    21   then show ?thesis
    22     by simp
    23 next
    24   let ?M = "measure M (space M)" and ?m = "\<lambda>x. measure M {x}"
    25   assume "?M \<noteq> 0"
    26   then have *: "{x. ?m x \<noteq> 0} = (\<Union>n. {x. ?M / Suc n < ?m x})"
    27     using reals_Archimedean[of "?m x / ?M" for x]
    28     by (auto simp: field_simps not_le[symmetric] measure_nonneg divide_le_0_iff measure_le_0_iff)
    29   have **: "\<And>n. finite {x. ?M / Suc n < ?m x}"
    30   proof (rule ccontr)
    31     fix n assume "infinite {x. ?M / Suc n < ?m x}" (is "infinite ?X")
    32     then obtain X where "finite X" "card X = Suc (Suc n)" "X \<subseteq> ?X"
    33       by (metis infinite_arbitrarily_large)
    34     from this(3) have *: "\<And>x. x \<in> X \<Longrightarrow> ?M / Suc n \<le> ?m x" 
    35       by auto
    36     { fix x assume "x \<in> X"
    37       from `?M \<noteq> 0` *[OF this] have "?m x \<noteq> 0" by (auto simp: field_simps measure_le_0_iff)
    38       then have "{x} \<in> sets M" by (auto dest: measure_notin_sets) }
    39     note singleton_sets = this
    40     have "?M < (\<Sum>x\<in>X. ?M / Suc n)"
    41       using `?M \<noteq> 0` 
    42       by (simp add: `card X = Suc (Suc n)` real_eq_of_nat[symmetric] real_of_nat_Suc field_simps less_le measure_nonneg)
    43     also have "\<dots> \<le> (\<Sum>x\<in>X. ?m x)"
    44       by (rule setsum_mono) fact
    45     also have "\<dots> = measure M (\<Union>x\<in>X. {x})"
    46       using singleton_sets `finite X`
    47       by (intro finite_measure_finite_Union[symmetric]) (auto simp: disjoint_family_on_def)
    48     finally have "?M < measure M (\<Union>x\<in>X. {x})" .
    49     moreover have "measure M (\<Union>x\<in>X. {x}) \<le> ?M"
    50       using singleton_sets[THEN sets.sets_into_space] by (intro finite_measure_mono) auto
    51     ultimately show False by simp
    52   qed
    53   show ?thesis
    54     unfolding * by (intro countable_UN countableI_type countable_finite[OF **])
    55 qed
    56 
    57 lemma (in finite_measure) AE_support_countable:
    58   assumes [simp]: "sets M = UNIV"
    59   shows "(AE x in M. measure M {x} \<noteq> 0) \<longleftrightarrow> (\<exists>S. countable S \<and> (AE x in M. x \<in> S))"
    60 proof
    61   assume "\<exists>S. countable S \<and> (AE x in M. x \<in> S)"
    62   then obtain S where S[intro]: "countable S" and ae: "AE x in M. x \<in> S"
    63     by auto
    64   then have "emeasure M (\<Union>x\<in>{x\<in>S. emeasure M {x} \<noteq> 0}. {x}) = 
    65     (\<integral>\<^sup>+ x. emeasure M {x} * indicator {x\<in>S. emeasure M {x} \<noteq> 0} x \<partial>count_space UNIV)"
    66     by (subst emeasure_UN_countable)
    67        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    68   also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} * indicator S x \<partial>count_space UNIV)"
    69     by (auto intro!: nn_integral_cong split: split_indicator)
    70   also have "\<dots> = emeasure M (\<Union>x\<in>S. {x})"
    71     by (subst emeasure_UN_countable)
    72        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    73   also have "\<dots> = emeasure M (space M)"
    74     using ae by (intro emeasure_eq_AE) auto
    75   finally have "emeasure M {x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0} = emeasure M (space M)"
    76     by (simp add: emeasure_single_in_space cong: rev_conj_cong)
    77   with finite_measure_compl[of "{x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0}"]
    78   have "AE x in M. x \<in> S \<and> emeasure M {x} \<noteq> 0"
    79     by (intro AE_I[OF order_refl]) (auto simp: emeasure_eq_measure set_diff_eq cong: conj_cong)
    80   then show "AE x in M. measure M {x} \<noteq> 0"
    81     by (auto simp: emeasure_eq_measure)
    82 qed (auto intro!: exI[of _ "{x. measure M {x} \<noteq> 0}"] countable_support)
    83 
    84 subsection {* PMF as measure *}
    85 
    86 typedef 'a pmf = "{M :: 'a measure. prob_space M \<and> sets M = UNIV \<and> (AE x in M. measure M {x} \<noteq> 0)}"
    87   morphisms measure_pmf Abs_pmf
    88   by (intro exI[of _ "uniform_measure (count_space UNIV) {undefined}"])
    89      (auto intro!: prob_space_uniform_measure AE_uniform_measureI)
    90 
    91 declare [[coercion measure_pmf]]
    92 
    93 lemma prob_space_measure_pmf: "prob_space (measure_pmf p)"
    94   using pmf.measure_pmf[of p] by auto
    95 
    96 interpretation measure_pmf!: prob_space "measure_pmf M" for M
    97   by (rule prob_space_measure_pmf)
    98 
    99 interpretation measure_pmf!: subprob_space "measure_pmf M" for M
   100   by (rule prob_space_imp_subprob_space) unfold_locales
   101 
   102 lemma subprob_space_measure_pmf: "subprob_space (measure_pmf x)"
   103   by unfold_locales
   104 
   105 locale pmf_as_measure
   106 begin
   107 
   108 setup_lifting type_definition_pmf
   109 
   110 end
   111 
   112 context
   113 begin
   114 
   115 interpretation pmf_as_measure .
   116 
   117 lift_definition pmf :: "'a pmf \<Rightarrow> 'a \<Rightarrow> real" is "\<lambda>M x. measure M {x}" .
   118 
   119 lift_definition set_pmf :: "'a pmf \<Rightarrow> 'a set" is "\<lambda>M. {x. measure M {x} \<noteq> 0}" .
   120 
   121 lift_definition map_pmf :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a pmf \<Rightarrow> 'b pmf" is
   122   "\<lambda>f M. distr M (count_space UNIV) f"
   123 proof safe
   124   fix M and f :: "'a \<Rightarrow> 'b"
   125   let ?D = "distr M (count_space UNIV) f"
   126   assume "prob_space M" and [simp]: "sets M = UNIV" and ae: "AE x in M. measure M {x} \<noteq> 0"
   127   interpret prob_space M by fact
   128   from ae have "AE x in M. measure M (f -` {f x}) \<noteq> 0"
   129   proof eventually_elim
   130     fix x
   131     have "measure M {x} \<le> measure M (f -` {f x})"
   132       by (intro finite_measure_mono) auto
   133     then show "measure M {x} \<noteq> 0 \<Longrightarrow> measure M (f -` {f x}) \<noteq> 0"
   134       using measure_nonneg[of M "{x}"] by auto
   135   qed
   136   then show "AE x in ?D. measure ?D {x} \<noteq> 0"
   137     by (simp add: AE_distr_iff measure_distr measurable_def)
   138 qed (auto simp: measurable_def prob_space.prob_space_distr)
   139 
   140 declare [[coercion set_pmf]]
   141 
   142 lemma countable_set_pmf [simp]: "countable (set_pmf p)"
   143   by transfer (metis prob_space.finite_measure finite_measure.countable_support)
   144 
   145 lemma sets_measure_pmf[simp]: "sets (measure_pmf p) = UNIV"
   146   by transfer metis
   147 
   148 lemma sets_measure_pmf_count_space[measurable_cong]:
   149   "sets (measure_pmf M) = sets (count_space UNIV)"
   150   by simp
   151 
   152 lemma space_measure_pmf[simp]: "space (measure_pmf p) = UNIV"
   153   using sets_eq_imp_space_eq[of "measure_pmf p" "count_space UNIV"] by simp
   154 
   155 lemma measure_pmf_in_subprob_algebra[measurable (raw)]: "measure_pmf x \<in> space (subprob_algebra (count_space UNIV))"
   156   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   157 
   158 lemma measurable_pmf_measure1[simp]: "measurable (M :: 'a pmf) N = UNIV \<rightarrow> space N"
   159   by (auto simp: measurable_def)
   160 
   161 lemma measurable_pmf_measure2[simp]: "measurable N (M :: 'a pmf) = measurable N (count_space UNIV)"
   162   by (intro measurable_cong_sets) simp_all
   163 
   164 lemma pmf_positive: "x \<in> set_pmf p \<Longrightarrow> 0 < pmf p x"
   165   by transfer (simp add: less_le measure_nonneg)
   166 
   167 lemma pmf_nonneg: "0 \<le> pmf p x"
   168   by transfer (simp add: measure_nonneg)
   169 
   170 lemma pmf_le_1: "pmf p x \<le> 1"
   171   by (simp add: pmf.rep_eq)
   172 
   173 lemma emeasure_pmf_single:
   174   fixes M :: "'a pmf"
   175   shows "emeasure M {x} = pmf M x"
   176   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   177 
   178 lemma AE_measure_pmf: "AE x in (M::'a pmf). x \<in> M"
   179   by transfer simp
   180 
   181 lemma emeasure_pmf_single_eq_zero_iff:
   182   fixes M :: "'a pmf"
   183   shows "emeasure M {y} = 0 \<longleftrightarrow> y \<notin> M"
   184   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   185 
   186 lemma AE_measure_pmf_iff: "(AE x in measure_pmf M. P x) \<longleftrightarrow> (\<forall>y\<in>M. P y)"
   187 proof -
   188   { fix y assume y: "y \<in> M" and P: "AE x in M. P x" "\<not> P y"
   189     with P have "AE x in M. x \<noteq> y"
   190       by auto
   191     with y have False
   192       by (simp add: emeasure_pmf_single_eq_zero_iff AE_iff_measurable[OF _ refl]) }
   193   then show ?thesis
   194     using AE_measure_pmf[of M] by auto
   195 qed
   196 
   197 lemma set_pmf_not_empty: "set_pmf M \<noteq> {}"
   198   using AE_measure_pmf[of M] by (intro notI) simp
   199 
   200 lemma set_pmf_iff: "x \<in> set_pmf M \<longleftrightarrow> pmf M x \<noteq> 0"
   201   by transfer simp
   202 
   203 lemma emeasure_measure_pmf_finite: "finite S \<Longrightarrow> emeasure (measure_pmf M) S = (\<Sum>s\<in>S. pmf M s)"
   204   by (subst emeasure_eq_setsum_singleton) (auto simp: emeasure_pmf_single)
   205 
   206 lemma measure_measure_pmf_finite: "finite S \<Longrightarrow> measure (measure_pmf M) S = setsum (pmf M) S"
   207   using emeasure_measure_pmf_finite[of S M] by(simp add: measure_pmf.emeasure_eq_measure)
   208 
   209 lemma nn_integral_measure_pmf_support:
   210   fixes f :: "'a \<Rightarrow> ereal"
   211   assumes f: "finite A" and nn: "\<And>x. x \<in> A \<Longrightarrow> 0 \<le> f x" "\<And>x. x \<in> set_pmf M \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = 0"
   212   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>A. f x * pmf M x)"
   213 proof -
   214   have "(\<integral>\<^sup>+x. f x \<partial>M) = (\<integral>\<^sup>+x. f x * indicator A x \<partial>M)"
   215     using nn by (intro nn_integral_cong_AE) (auto simp: AE_measure_pmf_iff split: split_indicator)
   216   also have "\<dots> = (\<Sum>x\<in>A. f x * emeasure M {x})"
   217     using assms by (intro nn_integral_indicator_finite) auto
   218   finally show ?thesis
   219     by (simp add: emeasure_measure_pmf_finite)
   220 qed
   221 
   222 lemma nn_integral_measure_pmf_finite:
   223   fixes f :: "'a \<Rightarrow> ereal"
   224   assumes f: "finite (set_pmf M)" and nn: "\<And>x. x \<in> set_pmf M \<Longrightarrow> 0 \<le> f x"
   225   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>set_pmf M. f x * pmf M x)"
   226   using assms by (intro nn_integral_measure_pmf_support) auto
   227 lemma integrable_measure_pmf_finite:
   228   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   229   shows "finite (set_pmf M) \<Longrightarrow> integrable M f"
   230   by (auto intro!: integrableI_bounded simp: nn_integral_measure_pmf_finite)
   231 
   232 lemma integral_measure_pmf:
   233   assumes [simp]: "finite A" and "\<And>a. a \<in> set_pmf M \<Longrightarrow> f a \<noteq> 0 \<Longrightarrow> a \<in> A"
   234   shows "(\<integral>x. f x \<partial>measure_pmf M) = (\<Sum>a\<in>A. f a * pmf M a)"
   235 proof -
   236   have "(\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x * indicator A x \<partial>measure_pmf M)"
   237     using assms(2) by (intro integral_cong_AE) (auto split: split_indicator simp: AE_measure_pmf_iff)
   238   also have "\<dots> = (\<Sum>a\<in>A. f a * pmf M a)"
   239     by (subst integral_indicator_finite_real) (auto simp: measure_def emeasure_measure_pmf_finite)
   240   finally show ?thesis .
   241 qed
   242 
   243 lemma integrable_pmf: "integrable (count_space X) (pmf M)"
   244 proof -
   245   have " (\<integral>\<^sup>+ x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+ x. pmf M x \<partial>count_space (M \<inter> X))"
   246     by (auto simp add: nn_integral_count_space_indicator set_pmf_iff intro!: nn_integral_cong split: split_indicator)
   247   then have "integrable (count_space X) (pmf M) = integrable (count_space (M \<inter> X)) (pmf M)"
   248     by (simp add: integrable_iff_bounded pmf_nonneg)
   249   then show ?thesis
   250     by (simp add: pmf.rep_eq measure_pmf.integrable_measure disjoint_family_on_def)
   251 qed
   252 
   253 lemma integral_pmf: "(\<integral>x. pmf M x \<partial>count_space X) = measure M X"
   254 proof -
   255   have "(\<integral>x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+x. pmf M x \<partial>count_space X)"
   256     by (simp add: pmf_nonneg integrable_pmf nn_integral_eq_integral)
   257   also have "\<dots> = (\<integral>\<^sup>+x. emeasure M {x} \<partial>count_space (X \<inter> M))"
   258     by (auto intro!: nn_integral_cong_AE split: split_indicator
   259              simp: pmf.rep_eq measure_pmf.emeasure_eq_measure nn_integral_count_space_indicator
   260                    AE_count_space set_pmf_iff)
   261   also have "\<dots> = emeasure M (X \<inter> M)"
   262     by (rule emeasure_countable_singleton[symmetric]) (auto intro: countable_set_pmf)
   263   also have "\<dots> = emeasure M X"
   264     by (auto intro!: emeasure_eq_AE simp: AE_measure_pmf_iff)
   265   finally show ?thesis
   266     by (simp add: measure_pmf.emeasure_eq_measure)
   267 qed
   268 
   269 lemma integral_pmf_restrict:
   270   "(f::'a \<Rightarrow> 'b::{banach, second_countable_topology}) \<in> borel_measurable (count_space UNIV) \<Longrightarrow>
   271     (\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x \<partial>restrict_space M M)"
   272   by (auto intro!: integral_cong_AE simp add: integral_restrict_space AE_measure_pmf_iff)
   273 
   274 lemma emeasure_pmf: "emeasure (M::'a pmf) M = 1"
   275 proof -
   276   have "emeasure (M::'a pmf) M = emeasure (M::'a pmf) (space M)"
   277     by (intro emeasure_eq_AE) (simp_all add: AE_measure_pmf)
   278   then show ?thesis
   279     using measure_pmf.emeasure_space_1 by simp
   280 qed
   281 
   282 lemma in_null_sets_measure_pmfI:
   283   "A \<inter> set_pmf p = {} \<Longrightarrow> A \<in> null_sets (measure_pmf p)"
   284 using emeasure_eq_0_AE[where ?P="\<lambda>x. x \<in> A" and M="measure_pmf p"]
   285 by(auto simp add: null_sets_def AE_measure_pmf_iff)
   286 
   287 lemma map_pmf_id[simp]: "map_pmf id = id"
   288   by (rule, transfer) (auto simp: emeasure_distr measurable_def intro!: measure_eqI)
   289 
   290 lemma map_pmf_ident[simp]: "map_pmf (\<lambda>x. x) = (\<lambda>x. x)"
   291   using map_pmf_id unfolding id_def .
   292 
   293 lemma map_pmf_compose: "map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g"
   294   by (rule, transfer) (simp add: distr_distr[symmetric, where N="count_space UNIV"] measurable_def) 
   295 
   296 lemma map_pmf_comp: "map_pmf f (map_pmf g M) = map_pmf (\<lambda>x. f (g x)) M"
   297   using map_pmf_compose[of f g] by (simp add: comp_def)
   298 
   299 lemma map_pmf_cong:
   300   assumes "p = q"
   301   shows "(\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g q"
   302   unfolding `p = q`[symmetric] measure_pmf_inject[symmetric] map_pmf.rep_eq
   303   by (auto simp add: emeasure_distr AE_measure_pmf_iff intro!: emeasure_eq_AE measure_eqI)
   304 
   305 lemma emeasure_map_pmf[simp]: "emeasure (map_pmf f M) X = emeasure M (f -` X)"
   306   unfolding map_pmf.rep_eq by (subst emeasure_distr) auto
   307 
   308 lemma nn_integral_map_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>map_pmf g M) = (\<integral>\<^sup>+x. f (g x) \<partial>M)"
   309   unfolding map_pmf.rep_eq by (intro nn_integral_distr) auto
   310 
   311 lemma ereal_pmf_map: "pmf (map_pmf f p) x = (\<integral>\<^sup>+ y. indicator (f -` {x}) y \<partial>measure_pmf p)"
   312 proof(transfer fixing: f x)
   313   fix p :: "'b measure"
   314   presume "prob_space p"
   315   then interpret prob_space p .
   316   presume "sets p = UNIV"
   317   then show "ereal (measure (distr p (count_space UNIV) f) {x}) = integral\<^sup>N p (indicator (f -` {x}))"
   318     by(simp add: measure_distr measurable_def emeasure_eq_measure)
   319 qed simp_all
   320 
   321 lemma pmf_set_map: 
   322   fixes f :: "'a \<Rightarrow> 'b"
   323   shows "set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
   324 proof (rule, transfer, clarsimp simp add: measure_distr measurable_def)
   325   fix f :: "'a \<Rightarrow> 'b" and M :: "'a measure"
   326   assume "prob_space M" and ae: "AE x in M. measure M {x} \<noteq> 0" and [simp]: "sets M = UNIV"
   327   interpret prob_space M by fact
   328   show "{x. measure M (f -` {x}) \<noteq> 0} = f ` {x. measure M {x} \<noteq> 0}"
   329   proof safe
   330     fix x assume "measure M (f -` {x}) \<noteq> 0"
   331     moreover have "measure M (f -` {x}) = measure M {y. f y = x \<and> measure M {y} \<noteq> 0}"
   332       using ae by (intro finite_measure_eq_AE) auto
   333     ultimately have "{y. f y = x \<and> measure M {y} \<noteq> 0} \<noteq> {}"
   334       by (metis measure_empty)
   335     then show "x \<in> f ` {x. measure M {x} \<noteq> 0}"
   336       by auto
   337   next
   338     fix x assume "measure M {x} \<noteq> 0"
   339     then have "0 < measure M {x}"
   340       using measure_nonneg[of M "{x}"] by auto
   341     also have "measure M {x} \<le> measure M (f -` {f x})"
   342       by (intro finite_measure_mono) auto
   343     finally show "measure M (f -` {f x}) = 0 \<Longrightarrow> False"
   344       by simp
   345   qed
   346 qed
   347 
   348 lemma set_map_pmf: "set_pmf (map_pmf f M) = f`set_pmf M"
   349   using pmf_set_map[of f] by (auto simp: comp_def fun_eq_iff)
   350 
   351 lemma nn_integral_pmf: "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = emeasure (measure_pmf p) A"
   352 proof -
   353   have "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = (\<integral>\<^sup>+ x. pmf p x \<partial>count_space (A \<inter> set_pmf p))"
   354     by(auto simp add: nn_integral_count_space_indicator indicator_def set_pmf_iff intro: nn_integral_cong)
   355   also have "\<dots> = emeasure (measure_pmf p) (\<Union>x\<in>A \<inter> set_pmf p. {x})"
   356     by(subst emeasure_UN_countable)(auto simp add: emeasure_pmf_single disjoint_family_on_def)
   357   also have "\<dots> = emeasure (measure_pmf p) ((\<Union>x\<in>A \<inter> set_pmf p. {x}) \<union> {x. x \<in> A \<and> x \<notin> set_pmf p})"
   358     by(rule emeasure_Un_null_set[symmetric])(auto intro: in_null_sets_measure_pmfI)
   359   also have "\<dots> = emeasure (measure_pmf p) A"
   360     by(auto intro: arg_cong2[where f=emeasure])
   361   finally show ?thesis .
   362 qed
   363 
   364 subsection {* PMFs as function *}
   365 
   366 context
   367   fixes f :: "'a \<Rightarrow> real"
   368   assumes nonneg: "\<And>x. 0 \<le> f x"
   369   assumes prob: "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   370 begin
   371 
   372 lift_definition embed_pmf :: "'a pmf" is "density (count_space UNIV) (ereal \<circ> f)"
   373 proof (intro conjI)
   374   have *[simp]: "\<And>x y. ereal (f y) * indicator {x} y = ereal (f x) * indicator {x} y"
   375     by (simp split: split_indicator)
   376   show "AE x in density (count_space UNIV) (ereal \<circ> f).
   377     measure (density (count_space UNIV) (ereal \<circ> f)) {x} \<noteq> 0"
   378     by (simp add: AE_density nonneg measure_def emeasure_density max_def)
   379   show "prob_space (density (count_space UNIV) (ereal \<circ> f))"
   380     by default (simp add: emeasure_density prob)
   381 qed simp
   382 
   383 lemma pmf_embed_pmf: "pmf embed_pmf x = f x"
   384 proof transfer
   385   have *[simp]: "\<And>x y. ereal (f y) * indicator {x} y = ereal (f x) * indicator {x} y"
   386     by (simp split: split_indicator)
   387   fix x show "measure (density (count_space UNIV) (ereal \<circ> f)) {x} = f x"
   388     by transfer (simp add: measure_def emeasure_density nonneg max_def)
   389 qed
   390 
   391 end
   392 
   393 lemma embed_pmf_transfer:
   394   "rel_fun (eq_onp (\<lambda>f. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ereal (f x) \<partial>count_space UNIV) = 1)) pmf_as_measure.cr_pmf (\<lambda>f. density (count_space UNIV) (ereal \<circ> f)) embed_pmf"
   395   by (auto simp: rel_fun_def eq_onp_def embed_pmf.transfer)
   396 
   397 lemma measure_pmf_eq_density: "measure_pmf p = density (count_space UNIV) (pmf p)"
   398 proof (transfer, elim conjE)
   399   fix M :: "'a measure" assume [simp]: "sets M = UNIV" and ae: "AE x in M. measure M {x} \<noteq> 0"
   400   assume "prob_space M" then interpret prob_space M .
   401   show "M = density (count_space UNIV) (\<lambda>x. ereal (measure M {x}))"
   402   proof (rule measure_eqI)
   403     fix A :: "'a set"
   404     have "(\<integral>\<^sup>+ x. ereal (measure M {x}) * indicator A x \<partial>count_space UNIV) = 
   405       (\<integral>\<^sup>+ x. emeasure M {x} * indicator (A \<inter> {x. measure M {x} \<noteq> 0}) x \<partial>count_space UNIV)"
   406       by (auto intro!: nn_integral_cong simp: emeasure_eq_measure split: split_indicator)
   407     also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} \<partial>count_space (A \<inter> {x. measure M {x} \<noteq> 0}))"
   408       by (subst nn_integral_restrict_space[symmetric]) (auto simp: restrict_count_space)
   409     also have "\<dots> = emeasure M (\<Union>x\<in>(A \<inter> {x. measure M {x} \<noteq> 0}). {x})"
   410       by (intro emeasure_UN_countable[symmetric] countable_Int2 countable_support)
   411          (auto simp: disjoint_family_on_def)
   412     also have "\<dots> = emeasure M A"
   413       using ae by (intro emeasure_eq_AE) auto
   414     finally show " emeasure M A = emeasure (density (count_space UNIV) (\<lambda>x. ereal (measure M {x}))) A"
   415       using emeasure_space_1 by (simp add: emeasure_density)
   416   qed simp
   417 qed
   418 
   419 lemma td_pmf_embed_pmf:
   420   "type_definition pmf embed_pmf {f::'a \<Rightarrow> real. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ereal (f x) \<partial>count_space UNIV) = 1}"
   421   unfolding type_definition_def
   422 proof safe
   423   fix p :: "'a pmf"
   424   have "(\<integral>\<^sup>+ x. 1 \<partial>measure_pmf p) = 1"
   425     using measure_pmf.emeasure_space_1[of p] by simp
   426   then show *: "(\<integral>\<^sup>+ x. ereal (pmf p x) \<partial>count_space UNIV) = 1"
   427     by (simp add: measure_pmf_eq_density nn_integral_density pmf_nonneg del: nn_integral_const)
   428 
   429   show "embed_pmf (pmf p) = p"
   430     by (intro measure_pmf_inject[THEN iffD1])
   431        (simp add: * embed_pmf.rep_eq pmf_nonneg measure_pmf_eq_density[of p] comp_def)
   432 next
   433   fix f :: "'a \<Rightarrow> real" assume "\<forall>x. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   434   then show "pmf (embed_pmf f) = f"
   435     by (auto intro!: pmf_embed_pmf)
   436 qed (rule pmf_nonneg)
   437 
   438 end
   439 
   440 locale pmf_as_function
   441 begin
   442 
   443 setup_lifting td_pmf_embed_pmf
   444 
   445 lemma set_pmf_transfer[transfer_rule]: 
   446   assumes "bi_total A"
   447   shows "rel_fun (pcr_pmf A) (rel_set A) (\<lambda>f. {x. f x \<noteq> 0}) set_pmf"  
   448   using `bi_total A`
   449   by (auto simp: pcr_pmf_def cr_pmf_def rel_fun_def rel_set_def bi_total_def Bex_def set_pmf_iff)
   450      metis+
   451 
   452 end
   453 
   454 context
   455 begin
   456 
   457 interpretation pmf_as_function .
   458 
   459 lemma pmf_eqI: "(\<And>i. pmf M i = pmf N i) \<Longrightarrow> M = N"
   460   by transfer auto
   461 
   462 lemma pmf_eq_iff: "M = N \<longleftrightarrow> (\<forall>i. pmf M i = pmf N i)"
   463   by (auto intro: pmf_eqI)
   464 
   465 end
   466 
   467 context
   468 begin
   469 
   470 interpretation pmf_as_function .
   471 
   472 subsubsection \<open> Bernoulli Distribution \<close>
   473 
   474 lift_definition bernoulli_pmf :: "real \<Rightarrow> bool pmf" is
   475   "\<lambda>p b. ((\<lambda>p. if b then p else 1 - p) \<circ> min 1 \<circ> max 0) p"
   476   by (auto simp: nn_integral_count_space_finite[where A="{False, True}"] UNIV_bool
   477            split: split_max split_min)
   478 
   479 lemma pmf_bernoulli_True[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) True = p"
   480   by transfer simp
   481 
   482 lemma pmf_bernoulli_False[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) False = 1 - p"
   483   by transfer simp
   484 
   485 lemma set_pmf_bernoulli: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (bernoulli_pmf p) = UNIV"
   486   by (auto simp add: set_pmf_iff UNIV_bool)
   487 
   488 lemma nn_integral_bernoulli_pmf[simp]: 
   489   assumes [simp]: "0 \<le> p" "p \<le> 1" "\<And>x. 0 \<le> f x"
   490   shows "(\<integral>\<^sup>+x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
   491   by (subst nn_integral_measure_pmf_support[of UNIV])
   492      (auto simp: UNIV_bool field_simps)
   493 
   494 lemma integral_bernoulli_pmf[simp]: 
   495   assumes [simp]: "0 \<le> p" "p \<le> 1"
   496   shows "(\<integral>x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
   497   by (subst integral_measure_pmf[of UNIV]) (auto simp: UNIV_bool)
   498 
   499 subsubsection \<open> Geometric Distribution \<close>
   500 
   501 lift_definition geometric_pmf :: "nat pmf" is "\<lambda>n. 1 / 2^Suc n"
   502 proof
   503   note geometric_sums[of "1 / 2"]
   504   note sums_mult[OF this, of "1 / 2"]
   505   from sums_suminf_ereal[OF this]
   506   show "(\<integral>\<^sup>+ x. ereal (1 / 2 ^ Suc x) \<partial>count_space UNIV) = 1"
   507     by (simp add: nn_integral_count_space_nat field_simps)
   508 qed simp
   509 
   510 lemma pmf_geometric[simp]: "pmf geometric_pmf n = 1 / 2^Suc n"
   511   by transfer rule
   512 
   513 lemma set_pmf_geometric[simp]: "set_pmf geometric_pmf = UNIV"
   514   by (auto simp: set_pmf_iff)
   515 
   516 subsubsection \<open> Uniform Multiset Distribution \<close>
   517 
   518 context
   519   fixes M :: "'a multiset" assumes M_not_empty: "M \<noteq> {#}"
   520 begin
   521 
   522 lift_definition pmf_of_multiset :: "'a pmf" is "\<lambda>x. count M x / size M"
   523 proof
   524   show "(\<integral>\<^sup>+ x. ereal (real (count M x) / real (size M)) \<partial>count_space UNIV) = 1"  
   525     using M_not_empty
   526     by (simp add: zero_less_divide_iff nn_integral_count_space nonempty_has_size
   527                   setsum_divide_distrib[symmetric])
   528        (auto simp: size_multiset_overloaded_eq intro!: setsum.cong)
   529 qed simp
   530 
   531 lemma pmf_of_multiset[simp]: "pmf pmf_of_multiset x = count M x / size M"
   532   by transfer rule
   533 
   534 lemma set_pmf_of_multiset[simp]: "set_pmf pmf_of_multiset = set_of M"
   535   by (auto simp: set_pmf_iff)
   536 
   537 end
   538 
   539 subsubsection \<open> Uniform Distribution \<close>
   540 
   541 context
   542   fixes S :: "'a set" assumes S_not_empty: "S \<noteq> {}" and S_finite: "finite S"
   543 begin
   544 
   545 lift_definition pmf_of_set :: "'a pmf" is "\<lambda>x. indicator S x / card S"
   546 proof
   547   show "(\<integral>\<^sup>+ x. ereal (indicator S x / real (card S)) \<partial>count_space UNIV) = 1"  
   548     using S_not_empty S_finite by (subst nn_integral_count_space'[of S]) auto
   549 qed simp
   550 
   551 lemma pmf_of_set[simp]: "pmf pmf_of_set x = indicator S x / card S"
   552   by transfer rule
   553 
   554 lemma set_pmf_of_set[simp]: "set_pmf pmf_of_set = S"
   555   using S_finite S_not_empty by (auto simp: set_pmf_iff)
   556 
   557 lemma emeasure_pmf_of_set[simp]: "emeasure pmf_of_set S = 1"
   558   by (rule measure_pmf.emeasure_eq_1_AE) (auto simp: AE_measure_pmf_iff)
   559 
   560 end
   561 
   562 subsubsection \<open> Poisson Distribution \<close>
   563 
   564 context
   565   fixes rate :: real assumes rate_pos: "0 < rate"
   566 begin
   567 
   568 lift_definition poisson_pmf :: "nat pmf" is "\<lambda>k. rate ^ k / fact k * exp (-rate)"
   569 proof
   570   (* Proof by Manuel Eberl *)
   571 
   572   have summable: "summable (\<lambda>x::nat. rate ^ x / fact x)" using summable_exp
   573     by (simp add: field_simps field_divide_inverse[symmetric])
   574   have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x * exp (-rate) \<partial>count_space UNIV) =
   575           exp (-rate) * (\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV)"
   576     by (simp add: field_simps nn_integral_cmult[symmetric])
   577   also from rate_pos have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV) = (\<Sum>x. rate ^ x / fact x)"
   578     by (simp_all add: nn_integral_count_space_nat suminf_ereal summable suminf_ereal_finite)
   579   also have "... = exp rate" unfolding exp_def
   580     by (simp add: field_simps field_divide_inverse[symmetric] transfer_int_nat_factorial)
   581   also have "ereal (exp (-rate)) * ereal (exp rate) = 1"
   582     by (simp add: mult_exp_exp)
   583   finally show "(\<integral>\<^sup>+ x. ereal (rate ^ x / real (fact x) * exp (- rate)) \<partial>count_space UNIV) = 1" .
   584 qed (simp add: rate_pos[THEN less_imp_le])
   585 
   586 lemma pmf_poisson[simp]: "pmf poisson_pmf k = rate ^ k / fact k * exp (-rate)"
   587   by transfer rule
   588 
   589 lemma set_pmf_poisson[simp]: "set_pmf poisson_pmf = UNIV"
   590   using rate_pos by (auto simp: set_pmf_iff)
   591 
   592 end
   593 
   594 subsubsection \<open> Binomial Distribution \<close>
   595 
   596 context
   597   fixes n :: nat and p :: real assumes p_nonneg: "0 \<le> p" and p_le_1: "p \<le> 1"
   598 begin
   599 
   600 lift_definition binomial_pmf :: "nat pmf" is "\<lambda>k. (n choose k) * p^k * (1 - p)^(n - k)"
   601 proof
   602   have "(\<integral>\<^sup>+k. ereal (real (n choose k) * p ^ k * (1 - p) ^ (n - k)) \<partial>count_space UNIV) =
   603     ereal (\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k))"
   604     using p_le_1 p_nonneg by (subst nn_integral_count_space') auto
   605   also have "(\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k)) = (p + (1 - p)) ^ n"
   606     by (subst binomial_ring) (simp add: atLeast0AtMost real_of_nat_def)
   607   finally show "(\<integral>\<^sup>+ x. ereal (real (n choose x) * p ^ x * (1 - p) ^ (n - x)) \<partial>count_space UNIV) = 1"
   608     by simp
   609 qed (insert p_nonneg p_le_1, simp)
   610 
   611 lemma pmf_binomial[simp]: "pmf binomial_pmf k = (n choose k) * p^k * (1 - p)^(n - k)"
   612   by transfer rule
   613 
   614 lemma set_pmf_binomial_eq: "set_pmf binomial_pmf = (if p = 0 then {0} else if p = 1 then {n} else {.. n})"
   615   using p_nonneg p_le_1 unfolding set_eq_iff set_pmf_iff pmf_binomial by (auto simp: set_pmf_iff)
   616 
   617 end
   618 
   619 end
   620 
   621 lemma set_pmf_binomial_0[simp]: "set_pmf (binomial_pmf n 0) = {0}"
   622   by (simp add: set_pmf_binomial_eq)
   623 
   624 lemma set_pmf_binomial_1[simp]: "set_pmf (binomial_pmf n 1) = {n}"
   625   by (simp add: set_pmf_binomial_eq)
   626 
   627 lemma set_pmf_binomial[simp]: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (binomial_pmf n p) = {..n}"
   628   by (simp add: set_pmf_binomial_eq)
   629 
   630 subsection \<open> Monad Interpretation \<close>
   631 
   632 lemma measurable_measure_pmf[measurable]:
   633   "(\<lambda>x. measure_pmf (M x)) \<in> measurable (count_space UNIV) (subprob_algebra (count_space UNIV))"
   634   by (auto simp: space_subprob_algebra intro!: prob_space_imp_subprob_space) unfold_locales
   635 
   636 lemma bind_pmf_cong:
   637   assumes "\<And>x. A x \<in> space (subprob_algebra N)" "\<And>x. B x \<in> space (subprob_algebra N)"
   638   assumes "\<And>i. i \<in> set_pmf x \<Longrightarrow> A i = B i"
   639   shows "bind (measure_pmf x) A = bind (measure_pmf x) B"
   640 proof (rule measure_eqI)
   641   show "sets (measure_pmf x \<guillemotright>= A) = sets (measure_pmf x \<guillemotright>= B)"
   642     using assms by (subst (1 2) sets_bind) (auto simp: space_subprob_algebra)
   643 next
   644   fix X assume "X \<in> sets (measure_pmf x \<guillemotright>= A)"
   645   then have X: "X \<in> sets N"
   646     using assms by (subst (asm) sets_bind) (auto simp: space_subprob_algebra)
   647   show "emeasure (measure_pmf x \<guillemotright>= A) X = emeasure (measure_pmf x \<guillemotright>= B) X"
   648     using assms
   649     by (subst (1 2) emeasure_bind[where N=N, OF _ _ X])
   650        (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   651 qed
   652 
   653 context
   654 begin
   655 
   656 interpretation pmf_as_measure .
   657 
   658 lift_definition join_pmf :: "'a pmf pmf \<Rightarrow> 'a pmf" is "\<lambda>M. measure_pmf M \<guillemotright>= measure_pmf"
   659 proof (intro conjI)
   660   fix M :: "'a pmf pmf"
   661 
   662   interpret bind: prob_space "measure_pmf M \<guillemotright>= measure_pmf"
   663     apply (intro measure_pmf.prob_space_bind[where S="count_space UNIV"] AE_I2)
   664     apply (auto intro!: subprob_space_measure_pmf simp: space_subprob_algebra)
   665     apply unfold_locales
   666     done
   667   show "prob_space (measure_pmf M \<guillemotright>= measure_pmf)"
   668     by intro_locales
   669   show "sets (measure_pmf M \<guillemotright>= measure_pmf) = UNIV"
   670     by (subst sets_bind) auto
   671   have "AE x in measure_pmf M \<guillemotright>= measure_pmf. emeasure (measure_pmf M \<guillemotright>= measure_pmf) {x} \<noteq> 0"
   672     by (auto simp: AE_bind[where B="count_space UNIV"] measure_pmf_in_subprob_algebra
   673                    emeasure_bind[where N="count_space UNIV"] AE_measure_pmf_iff nn_integral_0_iff_AE
   674                    measure_pmf.emeasure_eq_measure measure_le_0_iff set_pmf_iff pmf.rep_eq)
   675   then show "AE x in measure_pmf M \<guillemotright>= measure_pmf. measure (measure_pmf M \<guillemotright>= measure_pmf) {x} \<noteq> 0"
   676     unfolding bind.emeasure_eq_measure by simp
   677 qed
   678 
   679 lemma pmf_join: "pmf (join_pmf N) i = (\<integral>M. pmf M i \<partial>measure_pmf N)"
   680 proof (transfer fixing: N i)
   681   have N: "subprob_space (measure_pmf N)"
   682     by (rule prob_space_imp_subprob_space) intro_locales
   683   show "measure (measure_pmf N \<guillemotright>= measure_pmf) {i} = integral\<^sup>L (measure_pmf N) (\<lambda>M. measure M {i})"
   684     using measurable_measure_pmf[of "\<lambda>x. x"]
   685     by (intro subprob_space.measure_bind[where N="count_space UNIV", OF N]) auto
   686 qed (auto simp: Transfer.Rel_def rel_fun_def cr_pmf_def)
   687 
   688 lemma set_pmf_join_pmf: "set_pmf (join_pmf f) = (\<Union>p\<in>set_pmf f. set_pmf p)"
   689 apply(simp add: set_eq_iff set_pmf_iff pmf_join)
   690 apply(subst integral_nonneg_eq_0_iff_AE)
   691 apply(auto simp add: pmf_le_1 pmf_nonneg AE_measure_pmf_iff intro!: measure_pmf.integrable_const_bound[where B=1])
   692 done
   693 
   694 lift_definition return_pmf :: "'a \<Rightarrow> 'a pmf" is "return (count_space UNIV)"
   695   by (auto intro!: prob_space_return simp: AE_return measure_return)
   696 
   697 lemma join_return_pmf: "join_pmf (return_pmf M) = M"
   698   by (simp add: integral_return pmf_eq_iff pmf_join return_pmf.rep_eq)
   699 
   700 lemma map_return_pmf: "map_pmf f (return_pmf x) = return_pmf (f x)"
   701   by transfer (simp add: distr_return)
   702 
   703 lemma map_pmf_const[simp]: "map_pmf (\<lambda>_. c) M = return_pmf c"
   704   by transfer (auto simp: prob_space.distr_const)
   705 
   706 lemma set_return_pmf: "set_pmf (return_pmf x) = {x}"
   707   by transfer (auto simp add: measure_return split: split_indicator)
   708 
   709 lemma pmf_return: "pmf (return_pmf x) y = indicator {y} x"
   710   by transfer (simp add: measure_return)
   711 
   712 lemma nn_integral_return_pmf[simp]: "0 \<le> f x \<Longrightarrow> (\<integral>\<^sup>+x. f x \<partial>return_pmf x) = f x"
   713   unfolding return_pmf.rep_eq by (intro nn_integral_return) auto
   714 
   715 lemma emeasure_return_pmf[simp]: "emeasure (return_pmf x) X = indicator X x"
   716   unfolding return_pmf.rep_eq by (intro emeasure_return) auto
   717 
   718 end
   719 
   720 definition "bind_pmf M f = join_pmf (map_pmf f M)"
   721 
   722 lemma (in pmf_as_measure) bind_transfer[transfer_rule]:
   723   "rel_fun pmf_as_measure.cr_pmf (rel_fun (rel_fun op = pmf_as_measure.cr_pmf) pmf_as_measure.cr_pmf) op \<guillemotright>= bind_pmf"
   724 proof (auto simp: pmf_as_measure.cr_pmf_def rel_fun_def bind_pmf_def join_pmf.rep_eq map_pmf.rep_eq)
   725   fix M f and g :: "'a \<Rightarrow> 'b pmf" assume "\<forall>x. f x = measure_pmf (g x)"
   726   then have f: "f = (\<lambda>x. measure_pmf (g x))"
   727     by auto
   728   show "measure_pmf M \<guillemotright>= f = distr (measure_pmf M) (count_space UNIV) g \<guillemotright>= measure_pmf"
   729     unfolding f by (subst bind_distr[OF _ measurable_measure_pmf]) auto
   730 qed
   731 
   732 lemma pmf_bind: "pmf (bind_pmf N f) i = (\<integral>x. pmf (f x) i \<partial>measure_pmf N)"
   733   by (auto intro!: integral_distr simp: bind_pmf_def pmf_join map_pmf.rep_eq)
   734 
   735 lemma bind_return_pmf: "bind_pmf (return_pmf x) f = f x"
   736   unfolding bind_pmf_def map_return_pmf join_return_pmf ..
   737 
   738 lemma join_eq_bind_pmf: "join_pmf M = bind_pmf M id"
   739   by (simp add: bind_pmf_def)
   740 
   741 lemma bind_pmf_const[simp]: "bind_pmf M (\<lambda>x. c) = c"
   742   unfolding bind_pmf_def map_pmf_const join_return_pmf ..
   743 
   744 lemma set_bind_pmf: "set_pmf (bind_pmf M N) = (\<Union>M\<in>set_pmf M. set_pmf (N M))"
   745   apply (simp add: set_eq_iff set_pmf_iff pmf_bind)
   746   apply (subst integral_nonneg_eq_0_iff_AE)
   747   apply (auto simp: pmf_nonneg pmf_le_1 AE_measure_pmf_iff
   748               intro!: measure_pmf.integrable_const_bound[where B=1])
   749   done
   750 
   751 
   752 lemma measurable_pair_restrict_pmf2:
   753   assumes "countable A"
   754   assumes [measurable]: "\<And>y. y \<in> A \<Longrightarrow> (\<lambda>x. f (x, y)) \<in> measurable M L"
   755   shows "f \<in> measurable (M \<Otimes>\<^sub>M restrict_space (measure_pmf N) A) L" (is "f \<in> measurable ?M _")
   756 proof -
   757   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   758     by (simp add: restrict_count_space)
   759 
   760   show ?thesis
   761     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (fst b, a)" and g=snd and I=A,
   762                                             unfolded pair_collapse] assms)
   763         measurable
   764 qed
   765 
   766 lemma measurable_pair_restrict_pmf1:
   767   assumes "countable A"
   768   assumes [measurable]: "\<And>x. x \<in> A \<Longrightarrow> (\<lambda>y. f (x, y)) \<in> measurable N L"
   769   shows "f \<in> measurable (restrict_space (measure_pmf M) A \<Otimes>\<^sub>M N) L"
   770 proof -
   771   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   772     by (simp add: restrict_count_space)
   773 
   774   show ?thesis
   775     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (a, snd b)" and g=fst and I=A,
   776                                             unfolded pair_collapse] assms)
   777         measurable
   778 qed
   779                                 
   780 lemma bind_commute_pmf: "bind_pmf A (\<lambda>x. bind_pmf B (C x)) = bind_pmf B (\<lambda>y. bind_pmf A (\<lambda>x. C x y))"
   781   unfolding pmf_eq_iff pmf_bind
   782 proof
   783   fix i
   784   interpret B: prob_space "restrict_space B B"
   785     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   786        (auto simp: AE_measure_pmf_iff)
   787   interpret A: prob_space "restrict_space A A"
   788     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   789        (auto simp: AE_measure_pmf_iff)
   790 
   791   interpret AB: pair_prob_space "restrict_space A A" "restrict_space B B"
   792     by unfold_locales
   793 
   794   have "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>A)"
   795     by (rule integral_cong) (auto intro!: integral_pmf_restrict)
   796   also have "\<dots> = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>restrict_space A A)"
   797     by (intro integral_pmf_restrict B.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   798               countable_set_pmf borel_measurable_count_space)
   799   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>restrict_space B B)"
   800     by (rule AB.Fubini_integral[symmetric])
   801        (auto intro!: AB.integrable_const_bound[where B=1] measurable_pair_restrict_pmf2
   802              simp: pmf_nonneg pmf_le_1 measurable_restrict_space1)
   803   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>B)"
   804     by (intro integral_pmf_restrict[symmetric] A.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   805               countable_set_pmf borel_measurable_count_space)
   806   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)"
   807     by (rule integral_cong) (auto intro!: integral_pmf_restrict[symmetric])
   808   finally show "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)" .
   809 qed
   810 
   811 
   812 context
   813 begin
   814 
   815 interpretation pmf_as_measure .
   816 
   817 lemma measure_pmf_bind: "measure_pmf (bind_pmf M f) = (measure_pmf M \<guillemotright>= (\<lambda>x. measure_pmf (f x)))"
   818   by transfer simp
   819 
   820 lemma nn_integral_bind_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>bind_pmf M N) = (\<integral>\<^sup>+x. \<integral>\<^sup>+y. f y \<partial>N x \<partial>M)"
   821   using measurable_measure_pmf[of N]
   822   unfolding measure_pmf_bind
   823   apply (subst (1 3) nn_integral_max_0[symmetric])
   824   apply (intro nn_integral_bind[where B="count_space UNIV"])
   825   apply auto
   826   done
   827 
   828 lemma emeasure_bind_pmf[simp]: "emeasure (bind_pmf M N) X = (\<integral>\<^sup>+x. emeasure (N x) X \<partial>M)"
   829   using measurable_measure_pmf[of N]
   830   unfolding measure_pmf_bind
   831   by (subst emeasure_bind[where N="count_space UNIV"]) auto
   832 
   833 lemma bind_return_pmf': "bind_pmf N return_pmf = N"
   834 proof (transfer, clarify)
   835   fix N :: "'a measure" assume "sets N = UNIV" then show "N \<guillemotright>= return (count_space UNIV) = N"
   836     by (subst return_sets_cong[where N=N]) (simp_all add: bind_return')
   837 qed
   838 
   839 lemma bind_return_pmf'': "bind_pmf N (\<lambda>x. return_pmf (f x)) = map_pmf f N"
   840 proof (transfer, clarify)
   841   fix N :: "'b measure" and f :: "'b \<Rightarrow> 'a" assume "prob_space N" "sets N = UNIV"
   842   then show "N \<guillemotright>= (\<lambda>x. return (count_space UNIV) (f x)) = distr N (count_space UNIV) f"
   843     by (subst bind_return_distr[symmetric])
   844        (auto simp: prob_space.not_empty measurable_def comp_def)
   845 qed
   846 
   847 lemma bind_assoc_pmf: "bind_pmf (bind_pmf A B) C = bind_pmf A (\<lambda>x. bind_pmf (B x) C)"
   848   by transfer
   849      (auto intro!: bind_assoc[where N="count_space UNIV" and R="count_space UNIV"]
   850            simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space)
   851 
   852 end
   853 
   854 lemma map_join_pmf: "map_pmf f (join_pmf AA) = join_pmf (map_pmf (map_pmf f) AA)"
   855   unfolding bind_pmf_def[symmetric]
   856   unfolding bind_return_pmf''[symmetric] join_eq_bind_pmf bind_assoc_pmf
   857   by (simp add: bind_return_pmf'')
   858 
   859 definition "pair_pmf A B = bind_pmf A (\<lambda>x. bind_pmf B (\<lambda>y. return_pmf (x, y)))"
   860 
   861 lemma pmf_pair: "pmf (pair_pmf M N) (a, b) = pmf M a * pmf N b"
   862   unfolding pair_pmf_def pmf_bind pmf_return
   863   apply (subst integral_measure_pmf[where A="{b}"])
   864   apply (auto simp: indicator_eq_0_iff)
   865   apply (subst integral_measure_pmf[where A="{a}"])
   866   apply (auto simp: indicator_eq_0_iff setsum_nonneg_eq_0_iff pmf_nonneg)
   867   done
   868 
   869 lemma set_pair_pmf: "set_pmf (pair_pmf A B) = set_pmf A \<times> set_pmf B"
   870   unfolding pair_pmf_def set_bind_pmf set_return_pmf by auto
   871 
   872 lemma measure_pmf_in_subprob_space[measurable (raw)]:
   873   "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   874   by (simp add: space_subprob_algebra) intro_locales
   875 
   876 lemma nn_integral_pair_pmf': "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) \<partial>B \<partial>A)"
   877 proof -
   878   have "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+x. max 0 (f x) * indicator (A \<times> B) x \<partial>pair_pmf A B)"
   879     by (subst nn_integral_max_0[symmetric])
   880        (auto simp: AE_measure_pmf_iff set_pair_pmf intro!: nn_integral_cong_AE)
   881   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. max 0 (f (a, b)) * indicator (A \<times> B) (a, b) \<partial>B \<partial>A)"
   882     by (simp add: pair_pmf_def)
   883   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. max 0 (f (a, b)) \<partial>B \<partial>A)"
   884     by (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   885   finally show ?thesis
   886     unfolding nn_integral_max_0 .
   887 qed
   888 
   889 lemma pair_map_pmf1: "pair_pmf (map_pmf f A) B = map_pmf (apfst f) (pair_pmf A B)"
   890 proof (safe intro!: pmf_eqI)
   891   fix a :: "'a" and b :: "'b"
   892   have [simp]: "\<And>c d. indicator (apfst f -` {(a, b)}) (c, d) = indicator (f -` {a}) c * (indicator {b} d::ereal)"
   893     by (auto split: split_indicator)
   894 
   895   have "ereal (pmf (pair_pmf (map_pmf f A) B) (a, b)) =
   896          ereal (pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b))"
   897     unfolding pmf_pair ereal_pmf_map
   898     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_multc pmf_nonneg
   899                   emeasure_map_pmf[symmetric] del: emeasure_map_pmf)
   900   then show "pmf (pair_pmf (map_pmf f A) B) (a, b) = pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b)"
   901     by simp
   902 qed
   903 
   904 lemma pair_map_pmf2: "pair_pmf A (map_pmf f B) = map_pmf (apsnd f) (pair_pmf A B)"
   905 proof (safe intro!: pmf_eqI)
   906   fix a :: "'a" and b :: "'b"
   907   have [simp]: "\<And>c d. indicator (apsnd f -` {(a, b)}) (c, d) = indicator {a} c * (indicator (f -` {b}) d::ereal)"
   908     by (auto split: split_indicator)
   909 
   910   have "ereal (pmf (pair_pmf A (map_pmf f B)) (a, b)) =
   911          ereal (pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b))"
   912     unfolding pmf_pair ereal_pmf_map
   913     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_cmult nn_integral_multc pmf_nonneg
   914                   emeasure_map_pmf[symmetric] del: emeasure_map_pmf)
   915   then show "pmf (pair_pmf A (map_pmf f B)) (a, b) = pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b)"
   916     by simp
   917 qed
   918 
   919 lemma map_pair: "map_pmf (\<lambda>(a, b). (f a, g b)) (pair_pmf A B) = pair_pmf (map_pmf f A) (map_pmf g B)"
   920   by (simp add: pair_map_pmf2 pair_map_pmf1 map_pmf_comp split_beta')
   921 
   922 lemma bind_pair_pmf:
   923   assumes M[measurable]: "M \<in> measurable (count_space UNIV \<Otimes>\<^sub>M count_space UNIV) (subprob_algebra N)"
   924   shows "measure_pmf (pair_pmf A B) \<guillemotright>= M = (measure_pmf A \<guillemotright>= (\<lambda>x. measure_pmf B \<guillemotright>= (\<lambda>y. M (x, y))))"
   925     (is "?L = ?R")
   926 proof (rule measure_eqI)
   927   have M'[measurable]: "M \<in> measurable (pair_pmf A B) (subprob_algebra N)"
   928     using M[THEN measurable_space] by (simp_all add: space_pair_measure)
   929 
   930   note measurable_bind[where N="count_space UNIV", measurable]
   931   note measure_pmf_in_subprob_space[simp]
   932 
   933   have sets_eq_N: "sets ?L = N"
   934     by (subst sets_bind[OF sets_kernel[OF M']]) auto
   935   show "sets ?L = sets ?R"
   936     using measurable_space[OF M]
   937     by (simp add: sets_eq_N space_pair_measure space_subprob_algebra)
   938   fix X assume "X \<in> sets ?L"
   939   then have X[measurable]: "X \<in> sets N"
   940     unfolding sets_eq_N .
   941   then show "emeasure ?L X = emeasure ?R X"
   942     apply (simp add: emeasure_bind[OF _ M' X])
   943     apply (simp add: nn_integral_bind[where B="count_space UNIV"] pair_pmf_def measure_pmf_bind[of A]
   944       nn_integral_measure_pmf_finite set_return_pmf emeasure_nonneg pmf_return one_ereal_def[symmetric])
   945     apply (subst emeasure_bind[OF _ _ X])
   946     apply measurable
   947     apply (subst emeasure_bind[OF _ _ X])
   948     apply measurable
   949     done
   950 qed
   951 
   952 lemma join_map_return_pmf: "join_pmf (map_pmf return_pmf A) = A"
   953   unfolding bind_pmf_def[symmetric] bind_return_pmf' ..
   954 
   955 lemma map_fst_pair_pmf: "map_pmf fst (pair_pmf A B) = A"
   956   by (simp add: pair_pmf_def bind_return_pmf''[symmetric] bind_assoc_pmf bind_return_pmf bind_return_pmf')
   957 
   958 lemma map_snd_pair_pmf: "map_pmf snd (pair_pmf A B) = B"
   959   by (simp add: pair_pmf_def bind_return_pmf''[symmetric] bind_assoc_pmf bind_return_pmf bind_return_pmf')
   960 
   961 lemma nn_integral_pmf':
   962   "inj_on f A \<Longrightarrow> (\<integral>\<^sup>+x. pmf p (f x) \<partial>count_space A) = emeasure p (f ` A)"
   963   by (subst nn_integral_bij_count_space[where g=f and B="f`A"])
   964      (auto simp: bij_betw_def nn_integral_pmf)
   965 
   966 lemma pmf_le_0_iff[simp]: "pmf M p \<le> 0 \<longleftrightarrow> pmf M p = 0"
   967   using pmf_nonneg[of M p] by simp
   968 
   969 lemma min_pmf_0[simp]: "min (pmf M p) 0 = 0" "min 0 (pmf M p) = 0"
   970   using pmf_nonneg[of M p] by simp_all
   971 
   972 lemma pmf_eq_0_set_pmf: "pmf M p = 0 \<longleftrightarrow> p \<notin> set_pmf M"
   973   unfolding set_pmf_iff by simp
   974 
   975 lemma pmf_map_inj: "inj_on f (set_pmf M) \<Longrightarrow> x \<in> set_pmf M \<Longrightarrow> pmf (map_pmf f M) (f x) = pmf M x"
   976   by (auto simp: pmf.rep_eq map_pmf.rep_eq measure_distr AE_measure_pmf_iff inj_onD
   977            intro!: measure_pmf.finite_measure_eq_AE)
   978 
   979 inductive rel_pmf :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a pmf \<Rightarrow> 'b pmf \<Rightarrow> bool"
   980 for R p q
   981 where
   982   "\<lbrakk> \<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y; 
   983      map_pmf fst pq = p; map_pmf snd pq = q \<rbrakk>
   984   \<Longrightarrow> rel_pmf R p q"
   985 
   986 bnf pmf: "'a pmf" map: map_pmf sets: set_pmf bd : "natLeq" rel: rel_pmf
   987 proof -
   988   show "map_pmf id = id" by (rule map_pmf_id)
   989   show "\<And>f g. map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g" by (rule map_pmf_compose) 
   990   show "\<And>f g::'a \<Rightarrow> 'b. \<And>p. (\<And>x. x \<in> set_pmf p \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g p"
   991     by (intro map_pmf_cong refl)
   992 
   993   show "\<And>f::'a \<Rightarrow> 'b. set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
   994     by (rule pmf_set_map)
   995 
   996   { fix p :: "'s pmf"
   997     have "(card_of (set_pmf p), card_of (UNIV :: nat set)) \<in> ordLeq"
   998       by (rule card_of_ordLeqI[where f="to_nat_on (set_pmf p)"])
   999          (auto intro: countable_set_pmf)
  1000     also have "(card_of (UNIV :: nat set), natLeq) \<in> ordLeq"
  1001       by (metis Field_natLeq card_of_least natLeq_Well_order)
  1002     finally show "(card_of (set_pmf p), natLeq) \<in> ordLeq" . }
  1003 
  1004   show "\<And>R. rel_pmf R =
  1005          (BNF_Def.Grp {x. set_pmf x \<subseteq> {(x, y). R x y}} (map_pmf fst))\<inverse>\<inverse> OO
  1006          BNF_Def.Grp {x. set_pmf x \<subseteq> {(x, y). R x y}} (map_pmf snd)"
  1007      by (auto simp add: fun_eq_iff BNF_Def.Grp_def OO_def rel_pmf.simps)
  1008 
  1009   { fix p :: "'a pmf" and f :: "'a \<Rightarrow> 'b" and g x
  1010     assume p: "\<And>z. z \<in> set_pmf p \<Longrightarrow> f z = g z"
  1011       and x: "x \<in> set_pmf p"
  1012     thus "f x = g x" by simp }
  1013 
  1014   fix R :: "'a => 'b \<Rightarrow> bool" and S :: "'b \<Rightarrow> 'c \<Rightarrow> bool"
  1015   { fix p q r
  1016     assume pq: "rel_pmf R p q"
  1017       and qr:"rel_pmf S q r"
  1018     from pq obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1019       and p: "p = map_pmf fst pq" and q: "q = map_pmf snd pq" by cases auto
  1020     from qr obtain qr where qr: "\<And>y z. (y, z) \<in> set_pmf qr \<Longrightarrow> S y z"
  1021       and q': "q = map_pmf fst qr" and r: "r = map_pmf snd qr" by cases auto
  1022 
  1023     note pmf_nonneg[intro, simp]
  1024     let ?pq = "\<lambda>y x. pmf pq (x, y)"
  1025     let ?qr = "\<lambda>y z. pmf qr (y, z)"
  1026 
  1027     have nn_integral_pp2: "\<And>y. (\<integral>\<^sup>+ x. ?pq y x \<partial>count_space UNIV) = pmf q y"
  1028       by (simp add: nn_integral_pmf' inj_on_def q)
  1029          (auto simp add: ereal_pmf_map intro!: arg_cong2[where f=emeasure])
  1030     have nn_integral_rr1: "\<And>y. (\<integral>\<^sup>+ x. ?qr y x \<partial>count_space UNIV) = pmf q y"
  1031       by (simp add: nn_integral_pmf' inj_on_def q')
  1032          (auto simp add: ereal_pmf_map intro!: arg_cong2[where f=emeasure])
  1033     have eq: "\<And>y. (\<integral>\<^sup>+ x. ?pq y x \<partial>count_space UNIV) = (\<integral>\<^sup>+ z. ?qr y z \<partial>count_space UNIV)"
  1034       by(simp add: nn_integral_pp2 nn_integral_rr1)
  1035 
  1036     def assign \<equiv> "\<lambda>y x z. ?pq y x * ?qr y z / pmf q y"
  1037     have assign_nonneg [simp]: "\<And>y x z. 0 \<le> assign y x z" by(simp add: assign_def)
  1038     have assign_eq_0_outside: "\<And>y x z. \<lbrakk> ?pq y x = 0 \<or> ?qr y z = 0 \<rbrakk> \<Longrightarrow> assign y x z = 0"
  1039       by(auto simp add: assign_def)
  1040     have nn_integral_assign1: "\<And>y z. (\<integral>\<^sup>+ x. assign y x z \<partial>count_space UNIV) = ?qr y z"
  1041     proof -
  1042       fix y z
  1043       have "(\<integral>\<^sup>+ x. assign y x z \<partial>count_space UNIV) = 
  1044             (\<integral>\<^sup>+ x. ?pq y x \<partial>count_space UNIV) * (?qr y z / pmf q y)"
  1045         by(simp add: assign_def nn_integral_multc times_ereal.simps(1)[symmetric] divide_real_def mult.assoc del: times_ereal.simps(1))
  1046       also have "\<dots> = ?qr y z" by(auto simp add: image_iff q' pmf_eq_0_set_pmf set_map_pmf nn_integral_pp2)
  1047       finally show "?thesis y z" .
  1048     qed
  1049     have nn_integral_assign2: "\<And>y x. (\<integral>\<^sup>+ z. assign y x z \<partial>count_space UNIV) = ?pq y x"
  1050     proof -
  1051       fix x y
  1052       have "(\<integral>\<^sup>+ z. assign y x z \<partial>count_space UNIV) = (\<integral>\<^sup>+ z. ?qr y z \<partial>count_space UNIV) * (?pq y x / pmf q y)"
  1053         by(simp add: assign_def divide_real_def mult.commute[where a="?pq y x"] mult.assoc nn_integral_multc times_ereal.simps(1)[symmetric] del: times_ereal.simps(1))
  1054       also have "\<dots> = ?pq y x" by(auto simp add: image_iff pmf_eq_0_set_pmf set_map_pmf q nn_integral_rr1)
  1055       finally show "?thesis y x" .
  1056     qed
  1057 
  1058     def pqr \<equiv> "embed_pmf (\<lambda>(y, x, z). assign y x z)"
  1059     { fix y x z
  1060       have "assign y x z = pmf pqr (y, x, z)"
  1061         unfolding pqr_def
  1062       proof (subst pmf_embed_pmf)
  1063         have "(\<integral>\<^sup>+ x. ereal ((\<lambda>(y, x, z). assign y x z) x) \<partial>count_space UNIV) =
  1064           (\<integral>\<^sup>+ x. ereal ((\<lambda>(y, x, z). assign y x z) x) \<partial>(count_space ((\<lambda>((x, y), z). (y, x, z)) ` (pq \<times> r))))"
  1065           by (force simp add: pmf_eq_0_set_pmf r set_map_pmf split: split_indicator
  1066                     intro!: nn_integral_count_space_eq assign_eq_0_outside)
  1067         also have "\<dots> = (\<integral>\<^sup>+ x. ereal ((\<lambda>((x, y), z). assign y x z) x) \<partial>(count_space (pq \<times> r)))"
  1068           by (subst nn_integral_bij_count_space[OF inj_on_imp_bij_betw, symmetric])
  1069              (auto simp: inj_on_def intro!: nn_integral_cong)
  1070         also have "\<dots> = (\<integral>\<^sup>+ xy. \<integral>\<^sup>+z. ereal ((\<lambda>((x, y), z). assign y x z) (xy, z)) \<partial>count_space r \<partial>count_space pq)"
  1071           by (subst sigma_finite_measure.nn_integral_fst)
  1072              (auto simp: pair_measure_countable sigma_finite_measure_count_space_countable)
  1073         also have "\<dots> = (\<integral>\<^sup>+ xy. \<integral>\<^sup>+z. ereal ((\<lambda>((x, y), z). assign y x z) (xy, z)) \<partial>count_space UNIV \<partial>count_space pq)"
  1074           by (intro nn_integral_cong nn_integral_count_space_eq)
  1075              (force simp: r set_map_pmf pmf_eq_0_set_pmf intro!: assign_eq_0_outside)+
  1076         also have "\<dots> = (\<integral>\<^sup>+ z. ?pq (snd z) (fst z) \<partial>count_space pq)"
  1077           by (subst nn_integral_assign2[symmetric]) (auto intro!: nn_integral_cong)
  1078         finally show "(\<integral>\<^sup>+ x. ereal ((\<lambda>(y, x, z). assign y x z) x) \<partial>count_space UNIV) = 1"
  1079           by (simp add: nn_integral_pmf emeasure_pmf)
  1080       qed auto }
  1081     note a = this
  1082 
  1083     def pr \<equiv> "map_pmf (\<lambda>(y, x, z). (x, z)) pqr"
  1084 
  1085     have "rel_pmf (R OO S) p r"
  1086     proof
  1087       have pq_eq: "pq = map_pmf (\<lambda>(y, x, z). (x, y)) pqr"
  1088       proof (rule pmf_eqI)
  1089         fix i
  1090         show "pmf pq i = pmf (map_pmf (\<lambda>(y, x, z). (x, y)) pqr) i"
  1091           using nn_integral_assign2[of "snd i" "fst i", symmetric]
  1092           by (auto simp add: a nn_integral_pmf' inj_on_def ereal.inject[symmetric] ereal_pmf_map 
  1093                    simp del: ereal.inject intro!: arg_cong2[where f=emeasure])
  1094       qed
  1095       then show "map_pmf fst pr = p"
  1096         unfolding p pr_def by (simp add: map_pmf_comp split_beta)
  1097 
  1098       have qr_eq: "qr = map_pmf (\<lambda>(y, x, z). (y, z)) pqr"
  1099       proof (rule pmf_eqI)
  1100         fix i show "pmf qr i = pmf (map_pmf (\<lambda>(y, x, z). (y, z)) pqr) i"
  1101           using nn_integral_assign1[of "fst i" "snd i", symmetric]
  1102           by (auto simp add: a nn_integral_pmf' inj_on_def ereal.inject[symmetric] ereal_pmf_map 
  1103                    simp del: ereal.inject intro!: arg_cong2[where f=emeasure])
  1104       qed
  1105       then show "map_pmf snd pr = r"
  1106         unfolding r pr_def by (simp add: map_pmf_comp split_beta)
  1107 
  1108       fix x z assume "(x, z) \<in> set_pmf pr"
  1109       then have "\<exists>y. (x, y) \<in> set_pmf pq \<and> (y, z) \<in> set_pmf qr"
  1110         unfolding pr_def pq_eq qr_eq by (force simp: set_map_pmf)
  1111       with pq qr show "(R OO S) x z"
  1112         by blast
  1113     qed }
  1114   then show "rel_pmf R OO rel_pmf S \<le> rel_pmf (R OO S)"
  1115     by(auto simp add: le_fun_def)
  1116 qed (fact natLeq_card_order natLeq_cinfinite)+
  1117 
  1118 lemma rel_pmf_return_pmf1: "rel_pmf R (return_pmf x) M \<longleftrightarrow> (\<forall>a\<in>M. R x a)"
  1119 proof safe
  1120   fix a assume "a \<in> M" "rel_pmf R (return_pmf x) M"
  1121   then obtain pq where *: "\<And>a b. (a, b) \<in> set_pmf pq \<Longrightarrow> R a b"
  1122     and eq: "return_pmf x = map_pmf fst pq" "M = map_pmf snd pq"
  1123     by (force elim: rel_pmf.cases)
  1124   moreover have "set_pmf (return_pmf x) = {x}"
  1125     by (simp add: set_return_pmf)
  1126   with `a \<in> M` have "(x, a) \<in> pq"
  1127     by (force simp: eq set_map_pmf)
  1128   with * show "R x a"
  1129     by auto
  1130 qed (auto intro!: rel_pmf.intros[where pq="pair_pmf (return_pmf x) M"]
  1131           simp: map_fst_pair_pmf map_snd_pair_pmf set_pair_pmf set_return_pmf)
  1132 
  1133 lemma rel_pmf_return_pmf2: "rel_pmf R M (return_pmf x) \<longleftrightarrow> (\<forall>a\<in>M. R a x)"
  1134   by (subst pmf.rel_flip[symmetric]) (simp add: rel_pmf_return_pmf1)
  1135 
  1136 lemma rel_pmf_rel_prod:
  1137   "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B') \<longleftrightarrow> rel_pmf R A B \<and> rel_pmf S A' B'"
  1138 proof safe
  1139   assume "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1140   then obtain pq where pq: "\<And>a b c d. ((a, c), (b, d)) \<in> set_pmf pq \<Longrightarrow> R a b \<and> S c d"
  1141     and eq: "map_pmf fst pq = pair_pmf A A'" "map_pmf snd pq = pair_pmf B B'"
  1142     by (force elim: rel_pmf.cases)
  1143   show "rel_pmf R A B"
  1144   proof (rule rel_pmf.intros)
  1145     let ?f = "\<lambda>(a, b). (fst a, fst b)"
  1146     have [simp]: "(\<lambda>x. fst (?f x)) = fst o fst" "(\<lambda>x. snd (?f x)) = fst o snd"
  1147       by auto
  1148 
  1149     show "map_pmf fst (map_pmf ?f pq) = A"
  1150       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1151     show "map_pmf snd (map_pmf ?f pq) = B"
  1152       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1153 
  1154     fix a b assume "(a, b) \<in> set_pmf (map_pmf ?f pq)"
  1155     then obtain c d where "((a, c), (b, d)) \<in> set_pmf pq"
  1156       by (auto simp: set_map_pmf)
  1157     from pq[OF this] show "R a b" ..
  1158   qed
  1159   show "rel_pmf S A' B'"
  1160   proof (rule rel_pmf.intros)
  1161     let ?f = "\<lambda>(a, b). (snd a, snd b)"
  1162     have [simp]: "(\<lambda>x. fst (?f x)) = snd o fst" "(\<lambda>x. snd (?f x)) = snd o snd"
  1163       by auto
  1164 
  1165     show "map_pmf fst (map_pmf ?f pq) = A'"
  1166       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1167     show "map_pmf snd (map_pmf ?f pq) = B'"
  1168       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1169 
  1170     fix c d assume "(c, d) \<in> set_pmf (map_pmf ?f pq)"
  1171     then obtain a b where "((a, c), (b, d)) \<in> set_pmf pq"
  1172       by (auto simp: set_map_pmf)
  1173     from pq[OF this] show "S c d" ..
  1174   qed
  1175 next
  1176   assume "rel_pmf R A B" "rel_pmf S A' B'"
  1177   then obtain Rpq Spq
  1178     where Rpq: "\<And>a b. (a, b) \<in> set_pmf Rpq \<Longrightarrow> R a b"
  1179         "map_pmf fst Rpq = A" "map_pmf snd Rpq = B"
  1180       and Spq: "\<And>a b. (a, b) \<in> set_pmf Spq \<Longrightarrow> S a b"
  1181         "map_pmf fst Spq = A'" "map_pmf snd Spq = B'"
  1182     by (force elim: rel_pmf.cases)
  1183 
  1184   let ?f = "(\<lambda>((a, c), (b, d)). ((a, b), (c, d)))"
  1185   let ?pq = "map_pmf ?f (pair_pmf Rpq Spq)"
  1186   have [simp]: "(\<lambda>x. fst (?f x)) = (\<lambda>(a, b). (fst a, fst b))" "(\<lambda>x. snd (?f x)) = (\<lambda>(a, b). (snd a, snd b))"
  1187     by auto
  1188 
  1189   show "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1190     by (rule rel_pmf.intros[where pq="?pq"])
  1191        (auto simp: map_snd_pair_pmf map_fst_pair_pmf set_pair_pmf set_map_pmf map_pmf_comp Rpq Spq
  1192                    map_pair)
  1193 qed
  1194 
  1195 end
  1196