src/Pure/sign.ML
author wenzelm
Sun Apr 09 18:51:19 2006 +0200 (2006-04-09)
changeset 19384 c5ee8f756683
parent 19366 a2040baa9444
child 19391 4812d28c90a6
permissions -rw-r--r--
abbrevs: mode does not affect name space;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_arities: (xstring * string list * string) list -> theory -> theory
    19   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    20   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    21   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    22   val add_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    23   val add_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    24   val del_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    25   val del_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    26   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    27   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    28   val add_abbrevs: string * bool -> (bstring * string * mixfix) list -> theory -> theory
    29   val add_abbrevs_i: string * bool -> (bstring * term * mixfix) list -> theory -> theory
    30   val add_const_constraint: xstring * string option -> theory -> theory
    31   val add_const_constraint_i: string * typ option -> theory -> theory
    32   val add_classes: (bstring * xstring list) list -> theory -> theory
    33   val add_classes_i: (bstring * class list) list -> theory -> theory
    34   val add_classrel: (xstring * xstring) list -> theory -> theory
    35   val add_classrel_i: (class * class) list -> theory -> theory
    36   val add_trfuns:
    37     (string * (ast list -> ast)) list *
    38     (string * (term list -> term)) list *
    39     (string * (term list -> term)) list *
    40     (string * (ast list -> ast)) list -> theory -> theory
    41   val add_trfunsT:
    42     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    43   val add_advanced_trfuns:
    44     (string * (Context.generic -> ast list -> ast)) list *
    45     (string * (Context.generic -> term list -> term)) list *
    46     (string * (Context.generic -> term list -> term)) list *
    47     (string * (Context.generic -> ast list -> ast)) list -> theory -> theory
    48   val add_advanced_trfunsT:
    49     (string * (Context.generic -> bool -> typ -> term list -> term)) list -> theory -> theory
    50   val add_tokentrfuns:
    51     (string * string * (string -> string * real)) list -> theory -> theory
    52   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    53     -> theory -> theory
    54   val parse_ast_translation: bool * string -> theory -> theory
    55   val parse_translation: bool * string -> theory -> theory
    56   val print_translation: bool * string -> theory -> theory
    57   val typed_print_translation: bool * string -> theory -> theory
    58   val print_ast_translation: bool * string -> theory -> theory
    59   val token_translation: string -> theory -> theory
    60   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    61   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    62   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    63   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    64   val add_path: string -> theory -> theory
    65   val parent_path: theory -> theory
    66   val root_path: theory -> theory
    67   val absolute_path: theory -> theory
    68   val local_path: theory -> theory
    69   val no_base_names: theory -> theory
    70   val qualified_names: theory -> theory
    71   val sticky_prefix: string -> theory -> theory
    72   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    73     theory -> theory
    74   val restore_naming: theory -> theory -> theory
    75   val hide_classes: bool -> xstring list -> theory -> theory
    76   val hide_classes_i: bool -> string list -> theory -> theory
    77   val hide_types: bool -> xstring list -> theory -> theory
    78   val hide_types_i: bool -> string list -> theory -> theory
    79   val hide_consts: bool -> xstring list -> theory -> theory
    80   val hide_consts_i: bool -> string list -> theory -> theory
    81   val hide_names: bool -> string * xstring list -> theory -> theory
    82   val hide_names_i: bool -> string * string list -> theory -> theory
    83 end
    84 
    85 signature SIGN =
    86 sig
    87   val init_data: theory -> theory
    88   val rep_sg: theory ->
    89    {naming: NameSpace.naming,
    90     syn: Syntax.syntax,
    91     tsig: Type.tsig,
    92     consts: Consts.T}
    93   val naming_of: theory -> NameSpace.naming
    94   val base_name: string -> bstring
    95   val full_name: theory -> bstring -> string
    96   val full_name_path: theory -> string -> bstring -> string
    97   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    98   val syn_of: theory -> Syntax.syntax
    99   val tsig_of: theory -> Type.tsig
   100   val classes_of: theory -> Sorts.classes
   101   val arities_of: theory -> Sorts.arities
   102   val classes: theory -> class list
   103   val defaultS: theory -> sort
   104   val subsort: theory -> sort * sort -> bool
   105   val of_sort: theory -> typ * sort -> bool
   106   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
   107   val universal_witness: theory -> (typ * sort) option
   108   val all_sorts_nonempty: theory -> bool
   109   val typ_instance: theory -> typ * typ -> bool
   110   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   111   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   112   val is_logtype: theory -> string -> bool
   113   val consts_of: theory -> Consts.T
   114   val const_constraint: theory -> string -> typ option
   115   val the_const_constraint: theory -> string -> typ
   116   val const_type: theory -> string -> typ option
   117   val the_const_type: theory -> string -> typ
   118   val declared_tyname: theory -> string -> bool
   119   val declared_const: theory -> string -> bool
   120   val const_monomorphic: theory -> string -> bool
   121   val const_typargs: theory -> string * typ -> typ list
   122   val const_instance: theory -> string * typ list -> typ
   123   val class_space: theory -> NameSpace.T
   124   val type_space: theory -> NameSpace.T
   125   val const_space: theory -> NameSpace.T
   126   val intern_class: theory -> xstring -> string
   127   val extern_class: theory -> string -> xstring
   128   val intern_type: theory -> xstring -> string
   129   val extern_type: theory -> string -> xstring
   130   val intern_const: theory -> xstring -> string
   131   val extern_const: theory -> string -> xstring
   132   val intern_sort: theory -> sort -> sort
   133   val extern_sort: theory -> sort -> sort
   134   val intern_typ: theory -> typ -> typ
   135   val extern_typ: theory -> typ -> typ
   136   val intern_term: theory -> term -> term
   137   val extern_term: (string -> xstring) -> theory -> term -> term
   138   val intern_tycons: theory -> typ -> typ
   139   val pretty_term': Context.generic -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   140   val pretty_term: theory -> term -> Pretty.T
   141   val pretty_typ: theory -> typ -> Pretty.T
   142   val pretty_sort: theory -> sort -> Pretty.T
   143   val pretty_classrel: theory -> class list -> Pretty.T
   144   val pretty_arity: theory -> arity -> Pretty.T
   145   val string_of_term: theory -> term -> string
   146   val string_of_typ: theory -> typ -> string
   147   val string_of_sort: theory -> sort -> string
   148   val string_of_classrel: theory -> class list -> string
   149   val string_of_arity: theory -> arity -> string
   150   val pprint_term: theory -> term -> pprint_args -> unit
   151   val pprint_typ: theory -> typ -> pprint_args -> unit
   152   val pp: theory -> Pretty.pp
   153   val certify_class: theory -> class -> class
   154   val certify_sort: theory -> sort -> sort
   155   val certify_typ: theory -> typ -> typ
   156   val certify_typ_syntax: theory -> typ -> typ
   157   val certify_typ_abbrev: theory -> typ -> typ
   158   val certify': bool -> bool -> Pretty.pp -> Consts.T -> theory -> term -> term * typ * int
   159   val certify_term: theory -> term -> term * typ * int
   160   val certify_prop: theory -> term -> term * typ * int
   161   val cert_term: theory -> term -> term
   162   val cert_prop: theory -> term -> term
   163   val no_vars: Pretty.pp -> term -> term
   164   val cert_def: Pretty.pp -> term -> (string * typ) * term
   165   val read_class: theory -> xstring -> class
   166   val read_sort': Syntax.syntax -> Context.generic -> string -> sort
   167   val read_sort: theory -> string -> sort
   168   val read_classrel: theory -> xstring * xstring -> class * class
   169   val cert_classrel: theory -> class * class -> class * class
   170   val read_arity: theory -> xstring * string list * string -> arity
   171   val cert_arity: theory -> arity -> arity
   172   val read_typ': Syntax.syntax -> Context.generic ->
   173     (indexname -> sort option) -> string -> typ
   174   val read_typ_syntax': Syntax.syntax -> Context.generic ->
   175     (indexname -> sort option) -> string -> typ
   176   val read_typ_abbrev': Syntax.syntax -> Context.generic ->
   177     (indexname -> sort option) -> string -> typ
   178   val read_typ: theory * (indexname -> sort option) -> string -> typ
   179   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   180   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   181   val read_tyname: theory -> string -> typ
   182   val read_const: theory -> string -> term
   183   val infer_types_simult: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   184     (indexname -> sort option) -> string list -> bool
   185     -> (term list * typ) list -> term list * (indexname * typ) list
   186   val infer_types: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   187     (indexname -> sort option) -> string list -> bool
   188     -> term list * typ -> term * (indexname * typ) list
   189   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   190     Context.generic -> (indexname -> typ option) * (indexname -> sort option) ->
   191     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   192   val read_def_terms:
   193     theory * (indexname -> typ option) * (indexname -> sort option) ->
   194     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   195   val simple_read_term: theory -> typ -> string -> term
   196   val read_term: theory -> string -> term
   197   val read_prop: theory -> string -> term
   198   include SIGN_THEORY
   199 end
   200 
   201 structure Sign: SIGN =
   202 struct
   203 
   204 
   205 (** datatype sign **)
   206 
   207 datatype sign = Sign of
   208  {naming: NameSpace.naming,     (*common naming conventions*)
   209   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   210   tsig: Type.tsig,              (*order-sorted signature of types*)
   211   consts: Consts.T};            (*polymorphic constants*)
   212 
   213 fun make_sign (naming, syn, tsig, consts) =
   214   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   215 
   216 structure SignData = TheoryDataFun
   217 (struct
   218   val name = "Pure/sign";
   219   type T = sign;
   220   val copy = I;
   221   fun extend (Sign {syn, tsig, consts, ...}) =
   222     make_sign (NameSpace.default_naming, syn, tsig, consts);
   223 
   224   val empty =
   225     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   226 
   227   fun merge pp (sign1, sign2) =
   228     let
   229       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   230       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   231 
   232       val naming = NameSpace.default_naming;
   233       val syn = Syntax.merge_syntaxes syn1 syn2;
   234       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   235       val consts = Consts.merge (consts1, consts2);
   236     in make_sign (naming, syn, tsig, consts) end;
   237 
   238   fun print _ _ = ();
   239 end);
   240 
   241 val init_data = SignData.init;
   242 
   243 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   244 
   245 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   246   make_sign (f (naming, syn, tsig, consts)));
   247 
   248 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   249 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   250 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   251 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   252 
   253 
   254 (* naming *)
   255 
   256 val naming_of = #naming o rep_sg;
   257 val base_name = NameSpace.base;
   258 val full_name = NameSpace.full o naming_of;
   259 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   260 val declare_name = NameSpace.declare o naming_of;
   261 
   262 
   263 (* syntax *)
   264 
   265 val syn_of = #syn o rep_sg;
   266 
   267 
   268 (* type signature *)
   269 
   270 val tsig_of = #tsig o rep_sg;
   271 val classes_of = snd o #classes o Type.rep_tsig o tsig_of;
   272 val arities_of = #arities o Type.rep_tsig o tsig_of;
   273 val classes = Type.classes o tsig_of;
   274 val defaultS = Type.defaultS o tsig_of;
   275 val subsort = Type.subsort o tsig_of;
   276 val of_sort = Type.of_sort o tsig_of;
   277 val witness_sorts = Type.witness_sorts o tsig_of;
   278 val universal_witness = Type.universal_witness o tsig_of;
   279 val all_sorts_nonempty = is_some o universal_witness;
   280 val typ_instance = Type.typ_instance o tsig_of;
   281 val typ_match = Type.typ_match o tsig_of;
   282 val typ_unify = Type.unify o tsig_of;
   283 fun is_logtype thy c = c mem_string Type.logical_types (tsig_of thy);
   284 
   285 
   286 (* polymorphic constants *)
   287 
   288 val consts_of = #consts o rep_sg;
   289 val the_const_constraint = Consts.constraint o consts_of;
   290 val const_constraint = try o the_const_constraint;
   291 val the_const_type = Consts.declaration o consts_of;
   292 val const_type = try o the_const_type;
   293 val const_monomorphic = Consts.monomorphic o consts_of;
   294 val const_typargs = Consts.typargs o consts_of;
   295 val const_instance = Consts.instance o consts_of;
   296 
   297 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   298 val declared_const = is_some oo const_constraint;
   299 
   300 
   301 
   302 (** intern / extern names **)
   303 
   304 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   305 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   306 val const_space = Consts.space_of o consts_of;
   307 
   308 val intern_class = NameSpace.intern o class_space;
   309 val extern_class = NameSpace.extern o class_space;
   310 val intern_type = NameSpace.intern o type_space;
   311 val extern_type = NameSpace.extern o type_space;
   312 val intern_const = NameSpace.intern o const_space;
   313 val extern_const = NameSpace.extern o const_space;
   314 
   315 val intern_sort = map o intern_class;
   316 val extern_sort = map o extern_class;
   317 
   318 local
   319 
   320 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   321   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   322   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   323 
   324 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   325   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   326   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   327   | map_term _ _ _ (t as Bound _) = t
   328   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   329   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   330 
   331 val add_classesT = Term.fold_atyps
   332   (fn TFree (_, S) => fold (insert (op =)) S
   333     | TVar (_, S) => fold (insert (op =)) S
   334     | _ => I);
   335 
   336 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   337   | add_tyconsT _ = I;
   338 
   339 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   340 
   341 fun mapping add_names f t =
   342   let
   343     fun f' x = let val y = f x in if x = y then NONE else SOME (x, y) end;
   344     val tab = List.mapPartial f' (add_names t []);
   345     fun get x = the_default x (AList.lookup (op =) tab x);
   346   in get end;
   347 
   348 fun typ_mapping f g thy T =
   349   T |> map_typ
   350     (mapping add_classesT (f thy) T)
   351     (mapping add_tyconsT (g thy) T);
   352 
   353 fun term_mapping f g h thy t =
   354   t |> map_term
   355     (mapping (Term.fold_types add_classesT) (f thy) t)
   356     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   357     (mapping add_consts (h thy) t);
   358 
   359 in
   360 
   361 val intern_typ = typ_mapping intern_class intern_type;
   362 val extern_typ = typ_mapping extern_class extern_type;
   363 val intern_term = term_mapping intern_class intern_type intern_const;
   364 fun extern_term h = term_mapping extern_class extern_type (K h);
   365 val intern_tycons = typ_mapping (K I) intern_type;
   366 
   367 end;
   368 
   369 
   370 
   371 (** pretty printing of terms, types etc. **)
   372 
   373 fun pretty_term' context syn ext t =
   374   let val curried = Context.exists_name Context.CPureN (Context.theory_of context)
   375   in Syntax.pretty_term ext context syn curried t end;
   376 
   377 fun pretty_term thy t =
   378   pretty_term' (Context.Theory thy) (syn_of thy) (Consts.extern (consts_of thy))
   379     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   380 
   381 fun pretty_typ thy T = Syntax.pretty_typ (Context.Theory thy) (syn_of thy) (extern_typ thy T);
   382 fun pretty_sort thy S = Syntax.pretty_sort (Context.Theory thy) (syn_of thy) (extern_sort thy S);
   383 
   384 fun pretty_classrel thy cs = Pretty.block (List.concat
   385   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   386 
   387 fun pretty_arity thy (a, Ss, S) =
   388   let
   389     val a' = extern_type thy a;
   390     val dom =
   391       if null Ss then []
   392       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   393   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   394 
   395 val string_of_term = Pretty.string_of oo pretty_term;
   396 val string_of_typ = Pretty.string_of oo pretty_typ;
   397 val string_of_sort = Pretty.string_of oo pretty_sort;
   398 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   399 val string_of_arity = Pretty.string_of oo pretty_arity;
   400 
   401 val pprint_term = (Pretty.pprint o Pretty.quote) oo pretty_term;
   402 val pprint_typ = (Pretty.pprint o Pretty.quote) oo pretty_typ;
   403 
   404 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   405   pretty_classrel thy, pretty_arity thy);
   406 
   407 
   408 
   409 (** certify entities **)    (*exception TYPE*)
   410 
   411 (* certify wrt. type signature *)
   412 
   413 fun certify cert = cert o tsig_of o Context.check_thy;
   414 
   415 val certify_class      = certify Type.cert_class;
   416 val certify_sort       = certify Type.cert_sort;
   417 val certify_typ        = certify Type.cert_typ;
   418 val certify_typ_syntax = certify Type.cert_typ_syntax;
   419 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   420 
   421 
   422 (* certify term/prop *)
   423 
   424 local
   425 
   426 fun type_check pp tm =
   427   let
   428     fun err_appl why bs t T u U =
   429       let
   430         val xs = map Free bs;           (*we do not rename here*)
   431         val t' = subst_bounds (xs, t);
   432         val u' = subst_bounds (xs, u);
   433         val msg = cat_lines
   434           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   435       in raise TYPE (msg, [T, U], [t', u']) end;
   436 
   437     fun typ_of (_, Const (_, T)) = T
   438       | typ_of (_, Free  (_, T)) = T
   439       | typ_of (_, Var (_, T)) = T
   440       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   441           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   442       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   443       | typ_of (bs, t $ u) =
   444           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   445             (case T of
   446               Type ("fun", [T1, T2]) =>
   447                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   448             | _ => err_appl "Operator not of function type" bs t T u U)
   449           end;
   450   in typ_of ([], tm) end;
   451 
   452 fun err msg = raise TYPE (msg, [], []);
   453 
   454 fun check_vars (t $ u) = (check_vars t; check_vars u)
   455   | check_vars (Abs (_, _, t)) = check_vars t
   456   | check_vars (Var (xi as (_, i), _)) =
   457       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   458   | check_vars _ = ();
   459 
   460 in
   461 
   462 fun certify' normalize prop pp consts thy tm =
   463   let
   464     val _ = Context.check_thy thy;
   465     val _ = check_vars tm;
   466     val tm' = Term.map_term_types (certify_typ thy) tm;
   467     val T = type_check pp tm';
   468     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   469     val tm'' = Consts.certify pp (tsig_of thy) consts tm';
   470     val tm'' = if normalize then tm'' else tm';
   471   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   472 
   473 fun certify_term thy = certify' true false (pp thy) (consts_of thy) thy;
   474 fun certify_prop thy = certify' true true (pp thy) (consts_of thy) thy;
   475 
   476 fun cert_term_abbrev thy = #1 o certify' false false (pp thy) (consts_of thy) thy;
   477 val cert_term = #1 oo certify_term;
   478 val cert_prop = #1 oo certify_prop;
   479 
   480 end;
   481 
   482 
   483 (* specifications *)
   484 
   485 fun no_vars pp tm =
   486   (case (Term.term_vars tm, Term.term_tvars tm) of
   487     ([], []) => tm
   488   | (ts, ixns) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   489       (Pretty.str "Illegal schematic variable(s) in term:" ::
   490        map (Pretty.term pp) ts @ map (Pretty.typ pp o TVar) ixns)))));
   491 
   492 fun cert_def pp tm =
   493   let val ((lhs, rhs), _) = tm
   494     |> no_vars pp
   495     |> Logic.strip_imp_concl
   496     |> Logic.dest_def pp Term.is_Const (K false) (K false)
   497   in (Term.dest_Const (Term.head_of lhs), rhs) end
   498   handle TERM (msg, _) => error msg;
   499 
   500 
   501 
   502 (** read and certify entities **)    (*exception ERROR*)
   503 
   504 (* classes and sorts *)
   505 
   506 fun read_class thy c = certify_class thy (intern_class thy c);
   507 
   508 fun read_sort' syn context str =
   509   let
   510     val thy = Context.theory_of context;
   511     val _ = Context.check_thy thy;
   512     val S = intern_sort thy (Syntax.read_sort context syn str);
   513   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   514 
   515 fun read_sort thy str = read_sort' (syn_of thy) (Context.Theory thy) str;
   516 
   517 
   518 (* class relations *)
   519 
   520 fun prep_classrel prep thy raw_rel =
   521   let val rel = Library.pairself (prep thy) raw_rel
   522   in Type.add_classrel (pp thy) [rel] (tsig_of thy); rel end;
   523 
   524 val read_classrel = prep_classrel read_class;
   525 val cert_classrel = prep_classrel certify_class;
   526 
   527 
   528 (* type arities *)
   529 
   530 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   531   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   532   in Type.add_arities (pp thy) [arity] (tsig_of thy); arity end;
   533 
   534 val read_arity = prep_arity intern_type read_sort;
   535 val cert_arity = prep_arity (K I) certify_sort;
   536 
   537 
   538 (* types *)
   539 
   540 local
   541 
   542 fun gen_read_typ' cert syn context def_sort str =
   543   let
   544     val thy = Context.theory_of context;
   545     val _ = Context.check_thy thy;
   546     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   547     val T = intern_tycons thy (Syntax.read_typ context syn get_sort (intern_sort thy) str);
   548   in cert thy T handle TYPE (msg, _, _) => error msg end
   549   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   550 
   551 fun gen_read_typ cert (thy, def_sort) str =
   552   gen_read_typ' cert (syn_of thy) (Context.Theory thy) def_sort str;
   553 
   554 in
   555 
   556 fun no_def_sort thy = (thy: theory, K NONE);
   557 
   558 val read_typ'        = gen_read_typ' certify_typ;
   559 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   560 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   561 val read_typ         = gen_read_typ certify_typ;
   562 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   563 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   564 
   565 end;
   566 
   567 
   568 (* type and constant names *)
   569 
   570 fun read_tyname thy raw_c =
   571   let val c = intern_type thy raw_c in
   572     (case Symtab.lookup (#2 (#types (Type.rep_tsig (tsig_of thy)))) c of
   573       SOME (Type.LogicalType n, _) => Type (c, replicate n dummyT)
   574     | _ => error ("Undeclared type constructor: " ^ quote c))
   575   end;
   576 
   577 val read_const = Consts.read_const o consts_of;
   578 
   579 
   580 
   581 (** infer_types **)         (*exception ERROR*)
   582 
   583 (*
   584   def_type: partial map from indexnames to types (constrains Frees and Vars)
   585   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   586   used: list of already used type variables
   587   freeze: if true then generated parameters are turned into TFrees, else TVars
   588 
   589   termss: lists of alternative parses (only one combination should be type-correct)
   590   typs: expected types
   591 *)
   592 
   593 fun infer_types_simult pp thy consts def_type def_sort used freeze args =
   594   let
   595     val termss = fold_rev (multiply o fst) args [[]];
   596     val typs =
   597       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   598 
   599     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   600         (try (Consts.constraint consts)) def_type def_sort (Consts.intern consts)
   601         (intern_tycons thy) (intern_sort thy) used freeze typs ts)
   602       handle TYPE (msg, _, _) => Exn (ERROR msg);
   603 
   604     val err_results = map infer termss;
   605     val errs = List.mapPartial (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   606     val results = List.mapPartial get_result err_results;
   607 
   608     val ambiguity = length termss;
   609     fun ambig_msg () =
   610       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   611         "Got more than one parse tree.\n\
   612         \Retry with smaller Syntax.ambiguity_level for more information."
   613       else "";
   614   in
   615     if null results then (cat_error (ambig_msg ()) (cat_lines errs))
   616     else if length results = 1 then
   617       (if ambiguity > ! Syntax.ambiguity_level then
   618         warning "Fortunately, only one parse tree is type correct.\n\
   619           \You may still want to disambiguate your grammar or your input."
   620       else (); hd results)
   621     else (cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   622       cat_lines (map (Pretty.string_of_term pp) (List.concat (map fst results)))))
   623   end;
   624 
   625 fun infer_types pp thy consts def_type def_sort used freeze tsT =
   626   apfst hd (infer_types_simult pp thy consts def_type def_sort used freeze [tsT]);
   627 
   628 
   629 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   630 
   631 fun read_def_terms' pp is_logtype syn consts context (types, sorts) used freeze sTs =
   632   let
   633     val thy = Context.theory_of context;
   634     fun read (s, T) =
   635       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   636       in (Syntax.read context is_logtype syn T' s, T') end;
   637   in infer_types_simult pp thy consts types sorts used freeze (map read sTs) end;
   638 
   639 fun read_def_terms (thy, types, sorts) =
   640   read_def_terms' (pp thy) (is_logtype thy) (syn_of thy) (consts_of thy)
   641     (Context.Theory thy) (types, sorts);
   642 
   643 fun simple_read_term thy T s =
   644   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   645   in t end
   646   handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   647 
   648 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   649 fun read_prop thy = simple_read_term thy propT;
   650 
   651 
   652 
   653 (** signature extension functions **)  (*exception ERROR/TYPE*)
   654 
   655 (* add default sort *)
   656 
   657 fun gen_add_defsort prep_sort s thy =
   658   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   659 
   660 val add_defsort = gen_add_defsort read_sort;
   661 val add_defsort_i = gen_add_defsort certify_sort;
   662 
   663 
   664 (* add type constructors *)
   665 
   666 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   667   let
   668     val syn' = Syntax.extend_type_gram types syn;
   669     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   670     val tsig' = Type.add_types naming decls tsig;
   671   in (naming, syn', tsig', consts) end);
   672 
   673 fun add_typedecls decls thy =
   674   let
   675     fun type_of (a, vs, mx) =
   676       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   677       else error ("Duplicate parameters in type declaration: " ^ quote a);
   678   in add_types (map type_of decls) thy end;
   679 
   680 
   681 (* add nonterminals *)
   682 
   683 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   684   let
   685     val syn' = Syntax.extend_consts ns syn;
   686     val tsig' = Type.add_nonterminals naming ns tsig;
   687   in (naming, syn', tsig', consts) end);
   688 
   689 
   690 (* add type abbreviations *)
   691 
   692 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   693   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   694     let
   695       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   696       val a' = Syntax.type_name a mx;
   697       val abbr = (a', vs, prep_typ thy rhs)
   698         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   699       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   700     in (naming, syn', tsig', consts) end);
   701 
   702 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   703 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   704 
   705 
   706 (* add type arities *)
   707 
   708 fun gen_add_arities int_type prep_sort arities thy = thy |> map_tsig (fn tsig =>
   709   let
   710     fun prep_arity (a, Ss, S) = (int_type thy a, map (prep_sort thy) Ss, prep_sort thy S)
   711       handle ERROR msg => cat_error msg ("in arity for type " ^ quote a);
   712     val tsig' = Type.add_arities (pp thy) (map prep_arity arities) tsig;
   713   in tsig' end);
   714 
   715 val add_arities = gen_add_arities intern_type read_sort;
   716 val add_arities_i = gen_add_arities (K I) certify_sort;
   717 
   718 
   719 (* modify syntax *)
   720 
   721 fun gen_syntax change_gram prep_typ prmode args thy =
   722   let
   723     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   724       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   725   in thy |> map_syn (change_gram (is_logtype thy) prmode (map prep args)) end;
   726 
   727 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   728 
   729 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   730 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   731 val add_syntax = add_modesyntax Syntax.default_mode;
   732 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   733 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   734 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   735 
   736 
   737 (* add constants *)
   738 
   739 local
   740 
   741 fun gen_add_consts prep_typ raw_args thy =
   742   let
   743     val prepT = Compress.typ thy o Type.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   744     fun prep (c, T, mx) = ((c, prepT T, mx) handle TYPE (msg, _, _) => error msg)
   745       handle ERROR msg =>
   746         cat_error msg ("in declaration of constant " ^ quote (Syntax.const_name c mx));
   747     val args = map prep raw_args;
   748     val decls = args |> map (fn (c, T, mx) => ((Syntax.const_name c mx, T), true));
   749   in
   750     thy
   751     |> map_consts (fold (Consts.declare (naming_of thy)) decls)
   752     |> add_syntax_i args
   753   end;
   754 
   755 in
   756 
   757 val add_consts = gen_add_consts (read_typ o no_def_sort);
   758 val add_consts_i = gen_add_consts certify_typ;
   759 
   760 end;
   761 
   762 
   763 (* add abbreviations *)
   764 
   765 local
   766 
   767 fun gen_abbrevs prep_term (mode, inout) = fold (fn (raw_c, raw_t, raw_mx) => fn thy =>
   768   let
   769     val prep_tm =
   770       Compress.term thy o Logic.varify o no_vars (pp thy) o Term.no_dummy_patterns o prep_term thy;
   771 
   772     val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   773     val (c', b) = Syntax.mixfix_const (full_name thy c) mx;
   774     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg)
   775       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   776     val T = Term.fastype_of t;
   777   in
   778     thy
   779     |> map_consts (Consts.abbreviate (pp thy) (tsig_of thy) (naming_of thy) mode ((c, t), b))
   780     |> map_syn (Syntax.extend_consts [c])
   781     |> add_modesyntax_i (mode, inout) [(c', T, mx)]
   782   end);
   783 
   784 in
   785 
   786 val add_abbrevs = gen_abbrevs read_term;
   787 val add_abbrevs_i = gen_abbrevs cert_term_abbrev;
   788 
   789 end;
   790 
   791 
   792 (* add constraints *)
   793 
   794 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   795   let
   796     val c = int_const thy raw_c;
   797     fun prepT raw_T =
   798       let val T = Type.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   799       in cert_term thy (Const (c, T)); T end
   800       handle TYPE (msg, _, _) => error msg;
   801   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   802 
   803 val add_const_constraint = gen_add_constraint intern_const (read_typ o no_def_sort);
   804 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   805 
   806 
   807 (* add type classes *)
   808 
   809 fun gen_add_class int_class (bclass, raw_classes) thy =
   810   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   811     let
   812       val classes = map (int_class thy) raw_classes;
   813       val syn' = Syntax.extend_consts [bclass] syn;
   814       val tsig' = Type.add_classes (pp thy) naming [(bclass, classes)] tsig;
   815     in (naming, syn', tsig', consts) end)
   816   |> add_consts_i [(Logic.const_of_class bclass, a_itselfT --> propT, NoSyn)];
   817 
   818 val add_classes = fold (gen_add_class intern_class);
   819 val add_classes_i = fold (gen_add_class (K I));
   820 
   821 
   822 (* add to classrel *)
   823 
   824 fun gen_add_classrel int_class raw_pairs thy = thy |> map_tsig (fn tsig =>
   825   let
   826     val pairs = map (pairself (int_class thy)) raw_pairs;
   827     val tsig' = Type.add_classrel (pp thy) pairs tsig;
   828   in tsig' end);
   829 
   830 val add_classrel = gen_add_classrel intern_class;
   831 val add_classrel_i = gen_add_classrel (K I);
   832 
   833 
   834 (* add translation functions *)
   835 
   836 local
   837 
   838 fun mk trs = map Syntax.mk_trfun trs;
   839 
   840 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   841   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   842 
   843 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   844 
   845 in
   846 
   847 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   848 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   849 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   850 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   851 
   852 end;
   853 
   854 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   855 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   856 
   857 
   858 (* compile translation functions *)
   859 
   860 local
   861 
   862 fun advancedT false = ""
   863   | advancedT true = "Context.generic -> ";
   864 
   865 fun advancedN false = ""
   866   | advancedN true = "advanced_";
   867 
   868 in
   869 
   870 fun parse_ast_translation (a, txt) =
   871   txt |> Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   872       "Syntax.ast list -> Syntax.ast)) list")
   873     ("Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], [])");
   874 
   875 fun parse_translation (a, txt) =
   876   txt |> Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   877       "term list -> term)) list")
   878     ("Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], [])");
   879 
   880 fun print_translation (a, txt) =
   881   txt |> Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   882       "term list -> term)) list")
   883     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, [])");
   884 
   885 fun print_ast_translation (a, txt) =
   886   txt |> Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   887       "Syntax.ast list -> Syntax.ast)) list")
   888     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation)");
   889 
   890 fun typed_print_translation (a, txt) =
   891   txt |> Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   892       "bool -> typ -> term list -> term)) list")
   893     ("Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation");
   894 
   895 val token_translation =
   896   Context.use_let "val token_translation: (string * string * (string -> string * real)) list"
   897     "Sign.add_tokentrfuns token_translation";
   898 
   899 end;
   900 
   901 
   902 (* translation rules *)
   903 
   904 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   905   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   906   in f (Context.Theory thy) (is_logtype thy) syn rules syn end);
   907 
   908 val add_trrules = gen_trrules Syntax.extend_trrules;
   909 val del_trrules = gen_trrules Syntax.remove_trrules;
   910 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   911 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   912 
   913 
   914 (* modify naming *)
   915 
   916 val add_path        = map_naming o NameSpace.add_path;
   917 val no_base_names   = map_naming NameSpace.no_base_names;
   918 val qualified_names = map_naming NameSpace.qualified_names;
   919 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   920 val set_policy      = map_naming o NameSpace.set_policy;
   921 val restore_naming  = map_naming o K o naming_of;
   922 
   923 val parent_path   = add_path "..";
   924 val root_path     = add_path "/";
   925 val absolute_path = add_path "//";
   926 
   927 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   928 
   929 
   930 (* hide names *)
   931 
   932 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   933 val hide_classes_i = map_tsig oo Type.hide_classes;
   934 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   935 val hide_types_i = map_tsig oo Type.hide_types;
   936 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   937 val hide_consts_i = map_consts oo (fold o Consts.hide);
   938 
   939 local
   940 
   941 val kinds =
   942  [("class", (intern_class, can o certify_class, hide_classes_i)),
   943   ("type", (intern_type, declared_tyname, hide_types_i)),
   944   ("const", (intern_const, declared_const, hide_consts_i))];
   945 
   946 fun gen_hide int b (kind, xnames) thy =
   947   (case AList.lookup (op =) kinds kind of
   948     SOME (intern, check, hide) =>
   949       let
   950         val names = if int then map (intern thy) xnames else xnames;
   951         val bads = filter_out (check thy) names;
   952       in
   953         if null bads then hide b names thy
   954         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   955       end
   956   | NONE => error ("Bad name space specification: " ^ quote kind));
   957 
   958 in
   959 
   960 val hide_names = gen_hide true;
   961 val hide_names_i = gen_hide false;
   962 
   963 end;
   964 
   965 end;