src/Pure/Tools/find_theorems.ML
author kleing
Wed Oct 21 16:41:22 2009 +1100 (2009-10-21)
changeset 33036 c61fe520602b
parent 33029 2fefe039edf1
child 33039 5018f6a76b3f
permissions -rw-r--r--
find_theorems: better handling of abbreviations (by Timothy Bourke)
     1 (*  Title:      Pure/Tools/find_theorems.ML
     2     Author:     Rafal Kolanski and Gerwin Klein, NICTA
     3 
     4 Retrieve theorems from proof context.
     5 *)
     6 
     7 signature FIND_THEOREMS =
     8 sig
     9   datatype 'term criterion =
    10     Name of string | Intro | IntroIff | Elim | Dest | Solves | Simp of 'term |
    11     Pattern of 'term
    12   val tac_limit: int Unsynchronized.ref
    13   val limit: int Unsynchronized.ref
    14   val find_theorems: Proof.context -> thm option -> int option -> bool ->
    15     (bool * string criterion) list -> int option * (Facts.ref * thm) list
    16   val pretty_thm: Proof.context -> Facts.ref * thm -> Pretty.T
    17   val print_theorems: Proof.context -> thm option -> int option -> bool ->
    18     (bool * string criterion) list -> unit
    19 end;
    20 
    21 structure FindTheorems: FIND_THEOREMS =
    22 struct
    23 
    24 (** search criteria **)
    25 
    26 datatype 'term criterion =
    27   Name of string | Intro | IntroIff | Elim | Dest | Solves | Simp of 'term |
    28   Pattern of 'term;
    29 
    30 fun apply_dummies tm =
    31   strip_abs tm
    32   |> fst
    33   |> map (Term.dummy_pattern o snd)
    34   |> betapplys o pair tm
    35   |> (fn x => Term.replace_dummy_patterns x 1)
    36   |> fst;
    37 
    38 fun parse_pattern ctxt nm =
    39   let
    40     val nm' = case Syntax.parse_term ctxt nm of Const (n, _) => n | _ => nm;
    41     val consts = ProofContext.consts_of ctxt;
    42   in
    43     nm'
    44     |> Consts.intern consts
    45     |> Consts.the_abbreviation consts
    46     |> snd
    47     |> apply_dummies
    48     handle TYPE _ => ProofContext.read_term_pattern ctxt nm
    49   end;
    50 
    51 fun read_criterion _ (Name name) = Name name
    52   | read_criterion _ Intro = Intro
    53   | read_criterion _ IntroIff = IntroIff
    54   | read_criterion _ Elim = Elim
    55   | read_criterion _ Dest = Dest
    56   | read_criterion _ Solves = Solves
    57   | read_criterion ctxt (Simp str) = Simp (ProofContext.read_term_pattern ctxt str)
    58   | read_criterion ctxt (Pattern str) = Pattern (parse_pattern ctxt str);
    59 
    60 fun pretty_criterion ctxt (b, c) =
    61   let
    62     fun prfx s = if b then s else "-" ^ s;
    63   in
    64     (case c of
    65       Name name => Pretty.str (prfx "name: " ^ quote name)
    66     | Intro => Pretty.str (prfx "intro")
    67     | IntroIff => Pretty.str (prfx "introiff")
    68     | Elim => Pretty.str (prfx "elim")
    69     | Dest => Pretty.str (prfx "dest")
    70     | Solves => Pretty.str (prfx "solves")
    71     | Simp pat => Pretty.block [Pretty.str (prfx "simp:"), Pretty.brk 1,
    72         Pretty.quote (Syntax.pretty_term ctxt (Term.show_dummy_patterns pat))]
    73     | Pattern pat => Pretty.enclose (prfx " \"") "\""
    74         [Syntax.pretty_term ctxt (Term.show_dummy_patterns pat)])
    75   end;
    76 
    77 
    78 
    79 (** search criterion filters **)
    80 
    81 (*generated filters are to be of the form
    82   input: (Facts.ref * thm)
    83   output: (p:int, s:int) option, where
    84     NONE indicates no match
    85     p is the primary sorting criterion
    86       (eg. number of assumptions in the theorem)
    87     s is the secondary sorting criterion
    88       (eg. size of the substitution for intro, elim and dest)
    89   when applying a set of filters to a thm, fold results in:
    90     (biggest p, sum of all s)
    91   currently p and s only matter for intro, elim, dest and simp filters,
    92   otherwise the default ordering is used.
    93 *)
    94 
    95 
    96 (* matching theorems *)
    97 
    98 fun is_nontrivial thy = Term.is_Const o Term.head_of o ObjectLogic.drop_judgment thy;
    99 
   100 (*educated guesses on HOL*)  (* FIXME broken *)
   101 val boolT = Type ("bool", []);
   102 val iff_const = Const ("op =", boolT --> boolT --> boolT);
   103 
   104 (*extract terms from term_src, refine them to the parts that concern us,
   105   if po try match them against obj else vice versa.
   106   trivial matches are ignored.
   107   returns: smallest substitution size*)
   108 fun is_matching_thm doiff (extract_terms, refine_term) ctxt po obj term_src =
   109   let
   110     val thy = ProofContext.theory_of ctxt;
   111 
   112     fun check_match pat = Pattern.matches thy (if po then (pat, obj) else (obj, pat));
   113     fun matches pat =
   114       let
   115         val jpat = ObjectLogic.drop_judgment thy pat;
   116         val c = Term.head_of jpat;
   117         val pats =
   118           if Term.is_Const c
   119           then
   120             if doiff andalso c = iff_const then
   121               (pat :: map (ObjectLogic.ensure_propT thy) (snd (strip_comb jpat)))
   122                 |> filter (is_nontrivial thy)
   123             else [pat]
   124           else [];
   125       in filter check_match pats end;
   126 
   127     fun substsize pat =
   128       let val (_, subst) =
   129         Pattern.match thy (if po then (pat, obj) else (obj, pat)) (Vartab.empty, Vartab.empty)
   130       in Vartab.fold (fn (_, (_, t)) => fn n => size_of_term t + n) subst 0 end;
   131 
   132     fun bestmatch [] = NONE
   133       | bestmatch xs = SOME (foldl1 Int.min xs);
   134 
   135     val match_thm = matches o refine_term;
   136   in
   137     maps match_thm (extract_terms term_src)
   138     |> map substsize
   139     |> bestmatch
   140   end;
   141 
   142 
   143 (* filter_name *)
   144 
   145 fun filter_name str_pat (thmref, _) =
   146   if match_string str_pat (Facts.name_of_ref thmref)
   147   then SOME (0, 0) else NONE;
   148 
   149 
   150 (* filter intro/elim/dest/solves rules *)
   151 
   152 fun filter_dest ctxt goal (_, thm) =
   153   let
   154     val extract_dest =
   155      (fn thm => if Thm.no_prems thm then [] else [Thm.full_prop_of thm],
   156       hd o Logic.strip_imp_prems);
   157     val prems = Logic.prems_of_goal goal 1;
   158 
   159     fun try_subst prem = is_matching_thm false extract_dest ctxt true prem thm;
   160     val successful = prems |> map_filter try_subst;
   161   in
   162     (*if possible, keep best substitution (one with smallest size)*)
   163     (*dest rules always have assumptions, so a dest with one
   164       assumption is as good as an intro rule with none*)
   165     if not (null successful)
   166     then SOME (Thm.nprems_of thm - 1, foldl1 Int.min successful) else NONE
   167   end;
   168 
   169 fun filter_intro doiff ctxt goal (_, thm) =
   170   let
   171     val extract_intro = (single o Thm.full_prop_of, Logic.strip_imp_concl);
   172     val concl = Logic.concl_of_goal goal 1;
   173     val ss = is_matching_thm doiff extract_intro ctxt true concl thm;
   174   in
   175     if is_some ss then SOME (Thm.nprems_of thm, the ss) else NONE
   176   end;
   177 
   178 fun filter_elim ctxt goal (_, thm) =
   179   if not (Thm.no_prems thm) then
   180     let
   181       val rule = Thm.full_prop_of thm;
   182       val prems = Logic.prems_of_goal goal 1;
   183       val goal_concl = Logic.concl_of_goal goal 1;
   184       val rule_mp = hd (Logic.strip_imp_prems rule);
   185       val rule_concl = Logic.strip_imp_concl rule;
   186       fun combine t1 t2 = Const ("*combine*", dummyT --> dummyT) $ (t1 $ t2);
   187       val rule_tree = combine rule_mp rule_concl;
   188       fun goal_tree prem = combine prem goal_concl;
   189       fun try_subst prem =
   190         is_matching_thm false (single, I) ctxt true (goal_tree prem) rule_tree;
   191       val successful = prems |> map_filter try_subst;
   192     in
   193       (*elim rules always have assumptions, so an elim with one
   194         assumption is as good as an intro rule with none*)
   195       if is_nontrivial (ProofContext.theory_of ctxt) (Thm.major_prem_of thm)
   196         andalso not (null successful)
   197       then SOME (Thm.nprems_of thm - 1, foldl1 Int.min successful) else NONE
   198     end
   199   else NONE
   200 
   201 val tac_limit = Unsynchronized.ref 5;
   202 
   203 fun filter_solves ctxt goal =
   204   let
   205     fun etacn thm i = Seq.take (! tac_limit) o etac thm i;
   206     fun try_thm thm =
   207       if Thm.no_prems thm then rtac thm 1 goal
   208       else (etacn thm THEN_ALL_NEW (Goal.norm_hhf_tac THEN' Method.assm_tac ctxt)) 1 goal;
   209   in
   210     fn (_, thm) =>
   211       if is_some (Seq.pull (try_thm thm))
   212       then SOME (Thm.nprems_of thm, 0) else NONE
   213   end;
   214 
   215 
   216 (* filter_simp *)
   217 
   218 fun filter_simp ctxt t (_, thm) =
   219   let
   220     val mksimps = Simplifier.mksimps (simpset_of ctxt);
   221     val extract_simp =
   222       (map Thm.full_prop_of o mksimps, #1 o Logic.dest_equals o Logic.strip_imp_concl);
   223     val ss = is_matching_thm false extract_simp ctxt false t thm;
   224   in
   225     if is_some ss then SOME (Thm.nprems_of thm, the ss) else NONE
   226   end;
   227 
   228 
   229 (* filter_pattern *)
   230 
   231 fun get_names t = Term.add_const_names t (Term.add_free_names t []);
   232 fun get_thm_names (_, thm) = get_names (Thm.full_prop_of thm);
   233 
   234 (*Including all constants and frees is only sound because
   235   matching uses higher-order patterns. If full matching
   236   were used, then constants that may be subject to
   237   beta-reduction after substitution of frees should
   238   not be included for LHS set because they could be
   239   thrown away by the substituted function.
   240   e.g. for (?F 1 2) do not include 1 or 2, if it were
   241        possible for ?F to be (% x y. 3)
   242   The largest possible set should always be included on
   243   the RHS.*)
   244 
   245 fun filter_pattern ctxt pat =
   246   let
   247     val pat_consts = get_names pat;
   248 
   249     fun check (t, NONE) = check (t, SOME (get_thm_names t))
   250       | check ((_, thm), c as SOME thm_consts) =
   251          (if pat_consts subset_string thm_consts andalso
   252             Pattern.matches_subterm (ProofContext.theory_of ctxt) (pat, Thm.full_prop_of thm)
   253           then SOME (0, 0) else NONE, c);
   254   in check end;
   255 
   256 
   257 (* interpret criteria as filters *)
   258 
   259 local
   260 
   261 fun err_no_goal c =
   262   error ("Current goal required for " ^ c ^ " search criterion");
   263 
   264 val fix_goal = Thm.prop_of;
   265 
   266 fun filter_crit _ _ (Name name) = apfst (filter_name name)
   267   | filter_crit _ NONE Intro = err_no_goal "intro"
   268   | filter_crit _ NONE Elim = err_no_goal "elim"
   269   | filter_crit _ NONE Dest = err_no_goal "dest"
   270   | filter_crit _ NONE Solves = err_no_goal "solves"
   271   | filter_crit ctxt (SOME goal) Intro = apfst (filter_intro false ctxt (fix_goal goal))
   272   | filter_crit ctxt (SOME goal) IntroIff = apfst (filter_intro true ctxt (fix_goal goal))
   273   | filter_crit ctxt (SOME goal) Elim = apfst (filter_elim ctxt (fix_goal goal))
   274   | filter_crit ctxt (SOME goal) Dest = apfst (filter_dest ctxt (fix_goal goal))
   275   | filter_crit ctxt (SOME goal) Solves = apfst (filter_solves ctxt goal)
   276   | filter_crit ctxt _ (Simp pat) = apfst (filter_simp ctxt pat)
   277   | filter_crit ctxt _ (Pattern pat) = filter_pattern ctxt pat;
   278 
   279 fun opt_not x = if is_some x then NONE else SOME (0, 0);
   280 
   281 fun opt_add (SOME (a, x)) (SOME (b, y)) = SOME (Int.max (a, b), x + y : int)
   282   | opt_add _ _ = NONE;
   283 
   284 fun app_filters thm =
   285   let
   286     fun app (NONE, _, _) = NONE
   287       | app (SOME v, _, []) = SOME (v, thm)
   288       | app (r, consts, f :: fs) =
   289           let val (r', consts') = f (thm, consts)
   290           in app (opt_add r r', consts', fs) end;
   291   in app end;
   292 
   293 
   294 in
   295 
   296 fun filter_criterion ctxt opt_goal (b, c) =
   297   (if b then I else (apfst opt_not)) o filter_crit ctxt opt_goal c;
   298 
   299 fun sorted_filter filters thms =
   300   let
   301     fun eval_filters thm = app_filters thm (SOME (0, 0), NONE, filters);
   302 
   303     (*filters return: (number of assumptions, substitution size) option, so
   304       sort (desc. in both cases) according to number of assumptions first,
   305       then by the substitution size*)
   306     fun thm_ord (((p0, s0), _), ((p1, s1), _)) =
   307       prod_ord int_ord int_ord ((p1, s1), (p0, s0));
   308   in map_filter eval_filters thms |> sort thm_ord |> map #2 end;
   309 
   310 fun lazy_filter filters =
   311   let
   312     fun lazy_match thms = Seq.make (fn () => first_match thms)
   313 
   314     and first_match [] = NONE
   315       | first_match (thm :: thms) =
   316           (case app_filters thm (SOME (0, 0), NONE, filters) of
   317             NONE => first_match thms
   318           | SOME (_, t) => SOME (t, lazy_match thms));
   319   in lazy_match end;
   320 
   321 end;
   322 
   323 
   324 (* removing duplicates, preferring nicer names, roughly n log n *)
   325 
   326 local
   327 
   328 val index_ord = option_ord (K EQUAL);
   329 val hidden_ord = bool_ord o pairself NameSpace.is_hidden;
   330 val qual_ord = int_ord o pairself (length o Long_Name.explode);
   331 val txt_ord = int_ord o pairself size;
   332 
   333 fun nicer_name (x, i) (y, j) =
   334   (case hidden_ord (x, y) of EQUAL =>
   335     (case index_ord (i, j) of EQUAL =>
   336       (case qual_ord (x, y) of EQUAL => txt_ord (x, y) | ord => ord)
   337     | ord => ord)
   338   | ord => ord) <> GREATER;
   339 
   340 fun rem_cdups nicer xs =
   341   let
   342     fun rem_c rev_seen [] = rev rev_seen
   343       | rem_c rev_seen [x] = rem_c (x :: rev_seen) []
   344       | rem_c rev_seen ((x as ((n, t), _)) :: (y as ((n', t'), _)) :: xs) =
   345           if Thm.eq_thm_prop (t, t')
   346           then rem_c rev_seen ((if nicer n n' then x else y) :: xs)
   347           else rem_c (x :: rev_seen) (y :: xs)
   348   in rem_c [] xs end;
   349 
   350 in
   351 
   352 fun nicer_shortest ctxt =
   353   let
   354     (* FIXME global name space!? *)
   355     val space = Facts.space_of (PureThy.facts_of (ProofContext.theory_of ctxt));
   356 
   357     val shorten =
   358       NameSpace.extern_flags {long_names = false, short_names = false, unique_names = false} space;
   359 
   360     fun nicer (Facts.Named ((x, _), i)) (Facts.Named ((y, _), j)) =
   361           nicer_name (shorten x, i) (shorten y, j)
   362       | nicer (Facts.Fact _) (Facts.Named _) = true
   363       | nicer (Facts.Named _) (Facts.Fact _) = false;
   364   in nicer end;
   365 
   366 fun rem_thm_dups nicer xs =
   367   xs ~~ (1 upto length xs)
   368   |> sort (TermOrd.fast_term_ord o pairself (Thm.prop_of o #2 o #1))
   369   |> rem_cdups nicer
   370   |> sort (int_ord o pairself #2)
   371   |> map #1;
   372 
   373 end;
   374 
   375 
   376 (* print_theorems *)
   377 
   378 fun all_facts_of ctxt =
   379   maps Facts.selections
   380    (Facts.dest_static [] (PureThy.facts_of (ProofContext.theory_of ctxt)) @
   381     Facts.dest_static [] (ProofContext.facts_of ctxt));
   382 
   383 val limit = Unsynchronized.ref 40;
   384 
   385 fun find_theorems ctxt opt_goal opt_limit rem_dups raw_criteria =
   386   let
   387     val assms =
   388       ProofContext.get_fact ctxt (Facts.named "local.assms")
   389         handle ERROR _ => [];
   390     val add_prems = Seq.hd o TRY (Method.insert_tac assms 1);
   391     val opt_goal' = Option.map add_prems opt_goal;
   392 
   393     val criteria = map (apsnd (read_criterion ctxt)) raw_criteria;
   394     val filters = map (filter_criterion ctxt opt_goal') criteria;
   395 
   396     fun find_all facts =
   397       let
   398         val raw_matches = sorted_filter filters facts;
   399 
   400         val matches =
   401           if rem_dups
   402           then rem_thm_dups (nicer_shortest ctxt) raw_matches
   403           else raw_matches;
   404 
   405         val len = length matches;
   406         val lim = the_default (! limit) opt_limit;
   407       in (SOME len, Library.drop (len - lim, matches)) end;
   408 
   409     val find =
   410       if rem_dups orelse is_none opt_limit
   411       then find_all
   412       else pair NONE o Seq.list_of o Seq.take (the opt_limit) o lazy_filter filters;
   413 
   414   in find (all_facts_of ctxt) end;
   415 
   416 
   417 fun pretty_thm ctxt (thmref, thm) = Pretty.block
   418   [Pretty.str (Facts.string_of_ref thmref), Pretty.str ":", Pretty.brk 1,
   419     Display.pretty_thm ctxt thm];
   420 
   421 fun print_theorems ctxt opt_goal opt_limit rem_dups raw_criteria =
   422   let
   423     val start = start_timing ();
   424 
   425     val criteria = map (apsnd (read_criterion ctxt)) raw_criteria;
   426     val (foundo, thms) = find_theorems ctxt opt_goal opt_limit rem_dups raw_criteria;
   427     val returned = length thms;
   428 
   429     val tally_msg =
   430       (case foundo of
   431         NONE => "displaying " ^ string_of_int returned ^ " theorems"
   432       | SOME found =>
   433           "found " ^ string_of_int found ^ " theorems" ^
   434             (if returned < found
   435              then " (" ^ string_of_int returned ^ " displayed)"
   436              else ""));
   437 
   438     val end_msg = " in " ^ Time.toString (#cpu (end_timing start)) ^ " secs";
   439   in
   440     Pretty.big_list "searched for:" (map (pretty_criterion ctxt) criteria)
   441         :: Pretty.str "" ::
   442      (if null thms then [Pretty.str ("nothing found" ^ end_msg)]
   443       else
   444         [Pretty.str (tally_msg ^ end_msg ^ ":"), Pretty.str ""] @
   445         map (pretty_thm ctxt) thms)
   446     |> Pretty.chunks |> Pretty.writeln
   447   end;
   448 
   449 
   450 
   451 (** command syntax **)
   452 
   453 fun find_theorems_cmd ((opt_lim, rem_dups), spec) =
   454   Toplevel.unknown_theory o Toplevel.keep (fn state =>
   455     let
   456       val proof_state = Toplevel.enter_proof_body state;
   457       val ctxt = Proof.context_of proof_state;
   458       val opt_goal = try Proof.flat_goal proof_state |> Option.map #2;
   459     in print_theorems ctxt opt_goal opt_lim rem_dups spec end);
   460 
   461 local
   462 
   463 structure P = OuterParse and K = OuterKeyword;
   464 
   465 val criterion =
   466   P.reserved "name" |-- P.!!! (P.$$$ ":" |-- P.xname) >> Name ||
   467   P.reserved "intro" >> K Intro ||
   468   P.reserved "introiff" >> K IntroIff ||
   469   P.reserved "elim" >> K Elim ||
   470   P.reserved "dest" >> K Dest ||
   471   P.reserved "solves" >> K Solves ||
   472   P.reserved "simp" |-- P.!!! (P.$$$ ":" |-- P.term) >> Simp ||
   473   P.term >> Pattern;
   474 
   475 val options =
   476   Scan.optional
   477     (P.$$$ "(" |--
   478       P.!!! (Scan.option P.nat -- Scan.optional (P.reserved "with_dups" >> K false) true
   479         --| P.$$$ ")")) (NONE, true);
   480 in
   481 
   482 val _ =
   483   OuterSyntax.improper_command "find_theorems" "print theorems meeting specified criteria" K.diag
   484     (options -- Scan.repeat (((Scan.option P.minus >> is_none) -- criterion))
   485       >> (Toplevel.no_timing oo find_theorems_cmd));
   486 
   487 end;
   488 
   489 end;