src/HOL/Number_Theory/Residues.thy
author paulson <lp15@cam.ac.uk>
Tue Feb 28 15:17:57 2017 +0000 (2017-02-28)
changeset 65066 c64d778a593a
parent 64593 50c715579715
child 65416 f707dbcf11e3
permissions -rw-r--r--
tidied some messy proofs
     1 (*  Title:      HOL/Number_Theory/Residues.thy
     2     Author:     Jeremy Avigad
     3 
     4 An algebraic treatment of residue rings, and resulting proofs of
     5 Euler's theorem and Wilson's theorem.
     6 *)
     7 
     8 section \<open>Residue rings\<close>
     9 
    10 theory Residues
    11 imports Cong MiscAlgebra
    12 begin
    13 
    14 definition QuadRes :: "int \<Rightarrow> int \<Rightarrow> bool" where
    15   "QuadRes p a = (\<exists>y. ([y^2 = a] (mod p)))"
    16 
    17 definition Legendre :: "int \<Rightarrow> int \<Rightarrow> int" where
    18   "Legendre a p = (if ([a = 0] (mod p)) then 0
    19     else if QuadRes p a then 1
    20     else -1)"
    21 
    22 subsection \<open>A locale for residue rings\<close>
    23 
    24 definition residue_ring :: "int \<Rightarrow> int ring"
    25 where
    26   "residue_ring m =
    27     \<lparr>carrier = {0..m - 1},
    28      mult = \<lambda>x y. (x * y) mod m,
    29      one = 1,
    30      zero = 0,
    31      add = \<lambda>x y. (x + y) mod m\<rparr>"
    32 
    33 locale residues =
    34   fixes m :: int and R (structure)
    35   assumes m_gt_one: "m > 1"
    36   defines "R \<equiv> residue_ring m"
    37 begin
    38 
    39 lemma abelian_group: "abelian_group R"
    40 proof -
    41   have "\<exists>y\<in>{0..m - 1}. (x + y) mod m = 0" if "0 \<le> x" "x < m" for x
    42   proof (cases "x = 0")
    43     case True
    44     with m_gt_one show ?thesis by simp
    45   next
    46     case False
    47     then have "(x + (m - x)) mod m = 0"
    48       by simp
    49     with m_gt_one that show ?thesis
    50       by (metis False atLeastAtMost_iff diff_ge_0_iff_ge diff_left_mono int_one_le_iff_zero_less less_le)
    51   qed
    52   with m_gt_one show ?thesis
    53     by (fastforce simp add: R_def residue_ring_def mod_add_right_eq ac_simps  intro!: abelian_groupI)
    54 qed    
    55 
    56 lemma comm_monoid: "comm_monoid R"
    57   unfolding R_def residue_ring_def
    58   apply (rule comm_monoidI)
    59     using m_gt_one  apply auto
    60   apply (metis mod_mult_right_eq mult.assoc mult.commute)
    61   apply (metis mult.commute)
    62   done
    63 
    64 lemma cring: "cring R"
    65   apply (intro cringI abelian_group comm_monoid)
    66   unfolding R_def residue_ring_def
    67   apply (auto simp add: comm_semiring_class.distrib mod_add_eq mod_mult_left_eq)
    68   done
    69 
    70 end
    71 
    72 sublocale residues < cring
    73   by (rule cring)
    74 
    75 
    76 context residues
    77 begin
    78 
    79 text \<open>
    80   These lemmas translate back and forth between internal and
    81   external concepts.
    82 \<close>
    83 
    84 lemma res_carrier_eq: "carrier R = {0..m - 1}"
    85   unfolding R_def residue_ring_def by auto
    86 
    87 lemma res_add_eq: "x \<oplus> y = (x + y) mod m"
    88   unfolding R_def residue_ring_def by auto
    89 
    90 lemma res_mult_eq: "x \<otimes> y = (x * y) mod m"
    91   unfolding R_def residue_ring_def by auto
    92 
    93 lemma res_zero_eq: "\<zero> = 0"
    94   unfolding R_def residue_ring_def by auto
    95 
    96 lemma res_one_eq: "\<one> = 1"
    97   unfolding R_def residue_ring_def units_of_def by auto
    98 
    99 lemma res_units_eq: "Units R = {x. 0 < x \<and> x < m \<and> coprime x m}"
   100   using m_gt_one
   101   unfolding Units_def R_def residue_ring_def
   102   apply auto
   103   apply (subgoal_tac "x \<noteq> 0")
   104   apply auto
   105   apply (metis invertible_coprime_int)
   106   apply (subst (asm) coprime_iff_invertible'_int)
   107   apply (auto simp add: cong_int_def mult.commute)
   108   done
   109 
   110 lemma res_neg_eq: "\<ominus> x = (- x) mod m"
   111   using m_gt_one unfolding R_def a_inv_def m_inv_def residue_ring_def
   112   apply simp
   113   apply (rule the_equality)
   114   apply (simp add: mod_add_right_eq)
   115   apply (simp add: add.commute mod_add_right_eq)
   116   apply (metis add.right_neutral minus_add_cancel mod_add_right_eq mod_pos_pos_trivial)
   117   done
   118 
   119 lemma finite [iff]: "finite (carrier R)"
   120   by (subst res_carrier_eq) auto
   121 
   122 lemma finite_Units [iff]: "finite (Units R)"
   123   by (subst res_units_eq) auto
   124 
   125 text \<open>
   126   The function \<open>a \<mapsto> a mod m\<close> maps the integers to the
   127   residue classes. The following lemmas show that this mapping
   128   respects addition and multiplication on the integers.
   129 \<close>
   130 
   131 lemma mod_in_carrier [iff]: "a mod m \<in> carrier R"
   132   unfolding res_carrier_eq
   133   using insert m_gt_one by auto
   134 
   135 lemma add_cong: "(x mod m) \<oplus> (y mod m) = (x + y) mod m"
   136   unfolding R_def residue_ring_def
   137   by (auto simp add: mod_simps)
   138 
   139 lemma mult_cong: "(x mod m) \<otimes> (y mod m) = (x * y) mod m"
   140   unfolding R_def residue_ring_def
   141   by (auto simp add: mod_simps)
   142 
   143 lemma zero_cong: "\<zero> = 0"
   144   unfolding R_def residue_ring_def by auto
   145 
   146 lemma one_cong: "\<one> = 1 mod m"
   147   using m_gt_one unfolding R_def residue_ring_def by auto
   148 
   149 (* FIXME revise algebra library to use 1? *)
   150 lemma pow_cong: "(x mod m) (^) n = x^n mod m"
   151   using m_gt_one
   152   apply (induct n)
   153   apply (auto simp add: nat_pow_def one_cong)
   154   apply (metis mult.commute mult_cong)
   155   done
   156 
   157 lemma neg_cong: "\<ominus> (x mod m) = (- x) mod m"
   158   by (metis mod_minus_eq res_neg_eq)
   159 
   160 lemma (in residues) prod_cong: "finite A \<Longrightarrow> (\<Otimes>i\<in>A. (f i) mod m) = (\<Prod>i\<in>A. f i) mod m"
   161   by (induct set: finite) (auto simp: one_cong mult_cong)
   162 
   163 lemma (in residues) sum_cong: "finite A \<Longrightarrow> (\<Oplus>i\<in>A. (f i) mod m) = (\<Sum>i\<in>A. f i) mod m"
   164   by (induct set: finite) (auto simp: zero_cong add_cong)
   165 
   166 lemma mod_in_res_units [simp]:
   167   assumes "1 < m" and "coprime a m"
   168   shows "a mod m \<in> Units R"
   169 proof (cases "a mod m = 0")
   170   case True with assms show ?thesis
   171     by (auto simp add: res_units_eq gcd_red_int [symmetric])
   172 next
   173   case False
   174   from assms have "0 < m" by simp
   175   with pos_mod_sign [of m a] have "0 \<le> a mod m" .
   176   with False have "0 < a mod m" by simp
   177   with assms show ?thesis
   178     by (auto simp add: res_units_eq gcd_red_int [symmetric] ac_simps)
   179 qed
   180 
   181 lemma res_eq_to_cong: "(a mod m) = (b mod m) \<longleftrightarrow> [a = b] (mod m)"
   182   unfolding cong_int_def by auto
   183 
   184 
   185 text \<open>Simplifying with these will translate a ring equation in R to a congruence.\<close>
   186 lemmas res_to_cong_simps = add_cong mult_cong pow_cong one_cong
   187     prod_cong sum_cong neg_cong res_eq_to_cong
   188 
   189 text \<open>Other useful facts about the residue ring.\<close>
   190 lemma one_eq_neg_one: "\<one> = \<ominus> \<one> \<Longrightarrow> m = 2"
   191   apply (simp add: res_one_eq res_neg_eq)
   192   apply (metis add.commute add_diff_cancel mod_mod_trivial one_add_one uminus_add_conv_diff
   193     zero_neq_one zmod_zminus1_eq_if)
   194   done
   195 
   196 end
   197 
   198 
   199 subsection \<open>Prime residues\<close>
   200 
   201 locale residues_prime =
   202   fixes p :: nat and R (structure)
   203   assumes p_prime [intro]: "prime p"
   204   defines "R \<equiv> residue_ring (int p)"
   205 
   206 sublocale residues_prime < residues p
   207   unfolding R_def residues_def
   208   using p_prime apply auto
   209   apply (metis (full_types) of_nat_1 of_nat_less_iff prime_gt_1_nat)
   210   done
   211 
   212 context residues_prime
   213 begin
   214 
   215 lemma is_field: "field R"
   216 proof -
   217   have "\<And>x. \<lbrakk>gcd x (int p) \<noteq> 1; 0 \<le> x; x < int p\<rbrakk> \<Longrightarrow> x = 0"
   218     by (metis dual_order.order_iff_strict gcd.commute less_le_not_le p_prime prime_imp_coprime prime_nat_int_transfer zdvd_imp_le)
   219   then show ?thesis
   220   apply (intro cring.field_intro2 cring)
   221   apply (auto simp add: res_carrier_eq res_one_eq res_zero_eq res_units_eq)
   222     done
   223 qed
   224 
   225 lemma res_prime_units_eq: "Units R = {1..p - 1}"
   226   apply (subst res_units_eq)
   227   apply auto
   228   apply (subst gcd.commute)
   229   apply (auto simp add: p_prime prime_imp_coprime_int zdvd_not_zless)
   230   done
   231 
   232 end
   233 
   234 sublocale residues_prime < field
   235   by (rule is_field)
   236 
   237 
   238 section \<open>Test cases: Euler's theorem and Wilson's theorem\<close>
   239 
   240 subsection \<open>Euler's theorem\<close>
   241 
   242 text \<open>The definition of the totient function.\<close>
   243 
   244 definition phi :: "int \<Rightarrow> nat"
   245   where "phi m = card {x. 0 < x \<and> x < m \<and> coprime x m}"
   246 
   247 lemma phi_def_nat: "phi m = card {x. 0 < x \<and> x < nat m \<and> coprime x (nat m)}"
   248   unfolding phi_def
   249 proof (rule bij_betw_same_card [of nat])
   250   show "bij_betw nat {x. 0 < x \<and> x < m \<and> coprime x m} {x. 0 < x \<and> x < nat m \<and> coprime x (nat m)}"
   251     apply (auto simp add: inj_on_def bij_betw_def image_def)
   252      apply (metis dual_order.irrefl dual_order.strict_trans leI nat_1 transfer_nat_int_gcd(1))
   253     apply (metis One_nat_def of_nat_0 of_nat_1 of_nat_less_0_iff int_nat_eq nat_int
   254         transfer_int_nat_gcd(1) of_nat_less_iff)
   255     done
   256 qed
   257   
   258 lemma prime_phi:
   259   assumes "2 \<le> p" "phi p = p - 1"
   260   shows "prime p"
   261 proof -
   262   have *: "{x. 0 < x \<and> x < p \<and> coprime x p} = {1..p - 1}"
   263     using assms unfolding phi_def_nat
   264     by (intro card_seteq) fastforce+
   265   have False if **: "1 < x" "x < p" and "x dvd p" for x :: nat
   266   proof -
   267     from * have cop: "x \<in> {1..p - 1} \<Longrightarrow> coprime x p"
   268       by blast
   269     have "coprime x p"
   270       apply (rule cop)
   271       using ** apply auto
   272       done
   273     with \<open>x dvd p\<close> \<open>1 < x\<close> show ?thesis
   274       by auto
   275   qed
   276   then show ?thesis
   277     using \<open>2 \<le> p\<close>
   278     by (simp add: prime_nat_iff)
   279        (metis One_nat_def dvd_pos_nat nat_dvd_not_less nat_neq_iff not_gr0
   280               not_numeral_le_zero one_dvd)
   281 qed
   282 
   283 lemma phi_zero [simp]: "phi 0 = 0"
   284   unfolding phi_def by (auto simp add: card_eq_0_iff)
   285 
   286 lemma phi_one [simp]: "phi 1 = 0"
   287   by (auto simp add: phi_def card_eq_0_iff)
   288 
   289 lemma (in residues) phi_eq: "phi m = card (Units R)"
   290   by (simp add: phi_def res_units_eq)
   291 
   292 lemma (in residues) euler_theorem1:
   293   assumes a: "gcd a m = 1"
   294   shows "[a^phi m = 1] (mod m)"
   295 proof -
   296   have "a ^ phi m mod m = 1 mod m"
   297     by (metis assms finite_Units m_gt_one mod_in_res_units one_cong phi_eq pow_cong units_power_order_eq_one)
   298   then show ?thesis
   299     using res_eq_to_cong by blast
   300 qed
   301 
   302 text \<open>Outside the locale, we can relax the restriction \<open>m > 1\<close>.\<close>
   303 lemma euler_theorem:
   304   assumes "m \<ge> 0"
   305     and "gcd a m = 1"
   306   shows "[a^phi m = 1] (mod m)"
   307 proof (cases "m = 0 | m = 1")
   308   case True
   309   then show ?thesis by auto
   310 next
   311   case False
   312   with assms show ?thesis
   313     by (intro residues.euler_theorem1, unfold residues_def, auto)
   314 qed
   315 
   316 lemma (in residues_prime) phi_prime: "phi p = nat p - 1"
   317   by (simp add: residues.phi_eq residues_axioms residues_prime.res_prime_units_eq residues_prime_axioms)
   318 
   319 lemma phi_prime: "prime (int p) \<Longrightarrow> phi p = nat p - 1"
   320   by (simp add: residues_prime.intro residues_prime.phi_prime)
   321 
   322 lemma fermat_theorem:
   323   fixes a :: int
   324   assumes "prime (int p)"
   325     and "\<not> p dvd a"
   326   shows "[a^(p - 1) = 1] (mod p)"
   327 proof -
   328   from assms have "[a ^ phi p = 1] (mod p)"
   329     by (auto intro!: euler_theorem intro!: prime_imp_coprime_int[of p]
   330              simp: gcd.commute[of _ "int p"])
   331   also have "phi p = nat p - 1"
   332     by (rule phi_prime) (rule assms)
   333   finally show ?thesis
   334     by (metis nat_int)
   335 qed
   336 
   337 lemma fermat_theorem_nat:
   338   assumes "prime (int p)" and "\<not> p dvd a"
   339   shows "[a ^ (p - 1) = 1] (mod p)"
   340   using fermat_theorem [of p a] assms
   341   by (metis of_nat_1 of_nat_power transfer_int_nat_cong zdvd_int)
   342 
   343 
   344 subsection \<open>Wilson's theorem\<close>
   345 
   346 lemma (in field) inv_pair_lemma: "x \<in> Units R \<Longrightarrow> y \<in> Units R \<Longrightarrow>
   347     {x, inv x} \<noteq> {y, inv y} \<Longrightarrow> {x, inv x} \<inter> {y, inv y} = {}"
   348   apply auto
   349   apply (metis Units_inv_inv)+
   350   done
   351 
   352 lemma (in residues_prime) wilson_theorem1:
   353   assumes a: "p > 2"
   354   shows "[fact (p - 1) = (-1::int)] (mod p)"
   355 proof -
   356   let ?Inverse_Pairs = "{{x, inv x}| x. x \<in> Units R - {\<one>, \<ominus> \<one>}}"
   357   have UR: "Units R = {\<one>, \<ominus> \<one>} \<union> \<Union>?Inverse_Pairs"
   358     by auto
   359   have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) \<otimes> (\<Otimes>i\<in>\<Union>?Inverse_Pairs. i)"
   360     apply (subst UR)
   361     apply (subst finprod_Un_disjoint)
   362     apply (auto intro: funcsetI)
   363     using inv_one apply auto[1]
   364     using inv_eq_neg_one_eq apply auto
   365     done
   366   also have "(\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) = \<ominus> \<one>"
   367     apply (subst finprod_insert)
   368     apply auto
   369     apply (frule one_eq_neg_one)
   370     using a apply force
   371     done
   372   also have "(\<Otimes>i\<in>(\<Union>?Inverse_Pairs). i) = (\<Otimes>A\<in>?Inverse_Pairs. (\<Otimes>y\<in>A. y))"
   373     apply (subst finprod_Union_disjoint)
   374     apply auto
   375     apply (metis Units_inv_inv)+
   376     done
   377   also have "\<dots> = \<one>"
   378     apply (rule finprod_one)
   379     apply auto
   380     apply (subst finprod_insert)
   381     apply auto
   382     apply (metis inv_eq_self)
   383     done
   384   finally have "(\<Otimes>i\<in>Units R. i) = \<ominus> \<one>"
   385     by simp
   386   also have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>Units R. i mod p)"
   387     by (rule finprod_cong') (auto simp: res_units_eq)
   388   also have "\<dots> = (\<Prod>i\<in>Units R. i) mod p"
   389     by (rule prod_cong) auto
   390   also have "\<dots> = fact (p - 1) mod p"
   391     apply (simp add: fact_prod)
   392     using assms
   393     apply (subst res_prime_units_eq)
   394     apply (simp add: int_prod zmod_int prod_int_eq)
   395     done
   396   finally have "fact (p - 1) mod p = \<ominus> \<one>" .
   397   then show ?thesis
   398     by (metis of_nat_fact Divides.transfer_int_nat_functions(2)
   399       cong_int_def res_neg_eq res_one_eq)
   400 qed
   401 
   402 lemma wilson_theorem:
   403   assumes "prime p"
   404   shows "[fact (p - 1) = - 1] (mod p)"
   405 proof (cases "p = 2")
   406   case True
   407   then show ?thesis
   408     by (simp add: cong_int_def fact_prod)
   409 next
   410   case False
   411   then show ?thesis
   412     using assms prime_ge_2_nat
   413     by (metis residues_prime.wilson_theorem1 residues_prime.intro le_eq_less_or_eq)
   414 qed
   415 
   416 end