src/HOLCF/Tools/fixrec.ML
author wenzelm
Thu Nov 19 14:46:33 2009 +0100 (2009-11-19)
changeset 33766 c679f05600cd
parent 33726 0878aecbf119
child 35525 fa231b86cb1e
permissions -rw-r--r--
adapted Local_Theory.define -- eliminated odd thm kind;
     1 (*  Title:      HOLCF/Tools/fixrec.ML
     2     Author:     Amber Telfer and Brian Huffman
     3 
     4 Recursive function definition package for HOLCF.
     5 *)
     6 
     7 signature FIXREC =
     8 sig
     9   val add_fixrec: bool -> (binding * typ option * mixfix) list
    10     -> (Attrib.binding * term) list -> local_theory -> local_theory
    11   val add_fixrec_cmd: bool -> (binding * string option * mixfix) list
    12     -> (Attrib.binding * string) list -> local_theory -> local_theory
    13   val add_fixpat: Thm.binding * term list -> theory -> theory
    14   val add_fixpat_cmd: Attrib.binding * string list -> theory -> theory
    15   val add_matchers: (string * string) list -> theory -> theory
    16   val fixrec_simp_add: attribute
    17   val fixrec_simp_del: attribute
    18   val fixrec_simp_tac: Proof.context -> int -> tactic
    19   val setup: theory -> theory
    20 end;
    21 
    22 structure Fixrec :> FIXREC =
    23 struct
    24 
    25 val def_cont_fix_eq = @{thm def_cont_fix_eq};
    26 val def_cont_fix_ind = @{thm def_cont_fix_ind};
    27 
    28 
    29 fun fixrec_err s = error ("fixrec definition error:\n" ^ s);
    30 fun fixrec_eq_err thy s eq =
    31   fixrec_err (s ^ "\nin\n" ^ quote (Syntax.string_of_term_global thy eq));
    32 
    33 (*************************************************************************)
    34 (***************************** building types ****************************)
    35 (*************************************************************************)
    36 
    37 (* ->> is taken from holcf_logic.ML *)
    38 fun cfunT (T, U) = Type(@{type_name "->"}, [T, U]);
    39 
    40 infixr 6 ->>; val (op ->>) = cfunT;
    41 
    42 fun dest_cfunT (Type(@{type_name "->"}, [T, U])) = (T, U)
    43   | dest_cfunT T = raise TYPE ("dest_cfunT", [T], []);
    44 
    45 fun maybeT T = Type(@{type_name "maybe"}, [T]);
    46 
    47 fun dest_maybeT (Type(@{type_name "maybe"}, [T])) = T
    48   | dest_maybeT T = raise TYPE ("dest_maybeT", [T], []);
    49 
    50 fun tupleT [] = HOLogic.unitT
    51   | tupleT [T] = T
    52   | tupleT (T :: Ts) = HOLogic.mk_prodT (T, tupleT Ts);
    53 
    54 local
    55 
    56 fun binder_cfun (Type(@{type_name "->"},[T, U])) = T :: binder_cfun U
    57   | binder_cfun (Type(@{type_name "fun"},[T, U])) = T :: binder_cfun U
    58   | binder_cfun _   =  [];
    59 
    60 fun body_cfun (Type(@{type_name "->"},[T, U])) = body_cfun U
    61   | body_cfun (Type(@{type_name "fun"},[T, U])) = body_cfun U
    62   | body_cfun T   =  T;
    63 
    64 fun strip_cfun T : typ list * typ =
    65   (binder_cfun T, body_cfun T);
    66 
    67 fun cfunsT (Ts, U) = List.foldr cfunT U Ts;
    68 
    69 in
    70 
    71 fun matchT (T, U) =
    72   body_cfun T ->> cfunsT (binder_cfun T, U) ->> U;
    73 
    74 end
    75 
    76 (*************************************************************************)
    77 (***************************** building terms ****************************)
    78 (*************************************************************************)
    79 
    80 val mk_trp = HOLogic.mk_Trueprop;
    81 
    82 (* splits a cterm into the right and lefthand sides of equality *)
    83 fun dest_eqs t = HOLogic.dest_eq (HOLogic.dest_Trueprop t);
    84 
    85 (* similar to Thm.head_of, but for continuous application *)
    86 fun chead_of (Const(@{const_name Rep_CFun},_)$f$t) = chead_of f
    87   | chead_of u = u;
    88 
    89 fun capply_const (S, T) =
    90   Const(@{const_name Rep_CFun}, (S ->> T) --> (S --> T));
    91 
    92 fun cabs_const (S, T) =
    93   Const(@{const_name Abs_CFun}, (S --> T) --> (S ->> T));
    94 
    95 fun mk_cabs t =
    96   let val T = Term.fastype_of t
    97   in cabs_const (Term.domain_type T, Term.range_type T) $ t end
    98 
    99 fun mk_capply (t, u) =
   100   let val (S, T) =
   101     case Term.fastype_of t of
   102         Type(@{type_name "->"}, [S, T]) => (S, T)
   103       | _ => raise TERM ("mk_capply " ^ ML_Syntax.print_list ML_Syntax.print_term [t, u], [t, u]);
   104   in capply_const (S, T) $ t $ u end;
   105 
   106 infix 0 ==;  val (op ==) = Logic.mk_equals;
   107 infix 1 ===; val (op ===) = HOLogic.mk_eq;
   108 infix 9 `  ; val (op `) = mk_capply;
   109 
   110 (* builds the expression (LAM v. rhs) *)
   111 fun big_lambda v rhs =
   112   cabs_const (Term.fastype_of v, Term.fastype_of rhs) $ Term.lambda v rhs;
   113 
   114 (* builds the expression (LAM v1 v2 .. vn. rhs) *)
   115 fun big_lambdas [] rhs = rhs
   116   | big_lambdas (v::vs) rhs = big_lambda v (big_lambdas vs rhs);
   117 
   118 fun mk_return t =
   119   let val T = Term.fastype_of t
   120   in Const(@{const_name Fixrec.return}, T ->> maybeT T) ` t end;
   121 
   122 fun mk_bind (t, u) =
   123   let val (T, mU) = dest_cfunT (Term.fastype_of u);
   124       val bindT = maybeT T ->> (T ->> mU) ->> mU;
   125   in Const(@{const_name Fixrec.bind}, bindT) ` t ` u end;
   126 
   127 fun mk_mplus (t, u) =
   128   let val mT = Term.fastype_of t
   129   in Const(@{const_name Fixrec.mplus}, mT ->> mT ->> mT) ` t ` u end;
   130 
   131 fun mk_run t =
   132   let val mT = Term.fastype_of t
   133       val T = dest_maybeT mT
   134   in Const(@{const_name Fixrec.run}, mT ->> T) ` t end;
   135 
   136 fun mk_fix t =
   137   let val (T, _) = dest_cfunT (Term.fastype_of t)
   138   in Const(@{const_name fix}, (T ->> T) ->> T) ` t end;
   139 
   140 fun mk_cont t =
   141   let val T = Term.fastype_of t
   142   in Const(@{const_name cont}, T --> HOLogic.boolT) $ t end;
   143 
   144 val mk_fst = HOLogic.mk_fst
   145 val mk_snd = HOLogic.mk_snd
   146 
   147 (* builds the expression (v1,v2,..,vn) *)
   148 fun mk_tuple [] = HOLogic.unit
   149 |   mk_tuple (t::[]) = t
   150 |   mk_tuple (t::ts) = HOLogic.mk_prod (t, mk_tuple ts);
   151 
   152 (* builds the expression (%(v1,v2,..,vn). rhs) *)
   153 fun lambda_tuple [] rhs = Term.lambda (Free("unit", HOLogic.unitT)) rhs
   154   | lambda_tuple (v::[]) rhs = Term.lambda v rhs
   155   | lambda_tuple (v::vs) rhs =
   156       HOLogic.mk_split (Term.lambda v (lambda_tuple vs rhs));
   157 
   158 
   159 (*************************************************************************)
   160 (************* fixed-point definitions and unfolding theorems ************)
   161 (*************************************************************************)
   162 
   163 structure FixrecUnfoldData = Generic_Data
   164 (
   165   type T = thm Symtab.table;
   166   val empty = Symtab.empty;
   167   val extend = I;
   168   fun merge data : T = Symtab.merge (K true) data;
   169 );
   170 
   171 local
   172 
   173 fun name_of (Const (n, T)) = n
   174   | name_of (Free (n, T)) = n
   175   | name_of _ = fixrec_err "name_of"
   176 
   177 val lhs_name =
   178   name_of o fst o HOLogic.dest_eq o HOLogic.dest_Trueprop o prop_of;
   179 
   180 in
   181 
   182 val add_unfold : attribute =
   183   Thm.declaration_attribute
   184     (fn th => FixrecUnfoldData.map (Symtab.insert (K true) (lhs_name th, th)));
   185 
   186 end
   187 
   188 fun add_fixdefs
   189   (fixes : ((binding * typ) * mixfix) list)
   190   (spec : (Attrib.binding * term) list)
   191   (lthy : local_theory) =
   192   let
   193     val thy = ProofContext.theory_of lthy;
   194     val names = map (Binding.name_of o fst o fst) fixes;
   195     val all_names = space_implode "_" names;
   196     val (lhss, rhss) = ListPair.unzip (map (dest_eqs o snd) spec);
   197     val functional = lambda_tuple lhss (mk_tuple rhss);
   198     val fixpoint = mk_fix (mk_cabs functional);
   199     
   200     val cont_thm =
   201       Goal.prove lthy [] [] (mk_trp (mk_cont functional))
   202         (K (simp_tac (simpset_of lthy) 1));
   203 
   204     fun one_def (l as Free(n,_)) r =
   205           let val b = Long_Name.base_name n
   206           in ((Binding.name (b^"_def"), []), r) end
   207       | one_def _ _ = fixrec_err "fixdefs: lhs not of correct form";
   208     fun defs [] _ = []
   209       | defs (l::[]) r = [one_def l r]
   210       | defs (l::ls) r = one_def l (mk_fst r) :: defs ls (mk_snd r);
   211     val fixdefs = defs lhss fixpoint;
   212     val (fixdef_thms : (term * (string * thm)) list, lthy') = lthy
   213       |> fold_map Local_Theory.define (map (apfst fst) fixes ~~ fixdefs);
   214     fun pair_equalI (thm1, thm2) = @{thm Pair_equalI} OF [thm1, thm2];
   215     val tuple_fixdef_thm = foldr1 pair_equalI (map (snd o snd) fixdef_thms);
   216     val P = Var (("P", 0), map Term.fastype_of lhss ---> HOLogic.boolT);
   217     val predicate = lambda_tuple lhss (list_comb (P, lhss));
   218     val tuple_induct_thm = (def_cont_fix_ind OF [tuple_fixdef_thm, cont_thm])
   219       |> Drule.instantiate' [] [SOME (Thm.cterm_of thy predicate)]
   220       |> LocalDefs.unfold lthy @{thms split_paired_all split_conv split_strict};
   221     val tuple_unfold_thm = (def_cont_fix_eq OF [tuple_fixdef_thm, cont_thm])
   222       |> LocalDefs.unfold lthy' @{thms split_conv};
   223     fun unfolds [] thm = []
   224       | unfolds (n::[]) thm = [(n, thm)]
   225       | unfolds (n::ns) thm = let
   226           val thmL = thm RS @{thm Pair_eqD1};
   227           val thmR = thm RS @{thm Pair_eqD2};
   228         in (n, thmL) :: unfolds ns thmR end;
   229     val unfold_thms = unfolds names tuple_unfold_thm;
   230     val induct_note : Attrib.binding * Thm.thm list =
   231       let
   232         val thm_name = Binding.name (all_names ^ "_induct");
   233       in
   234         ((thm_name, []), [tuple_induct_thm])
   235       end;
   236     fun unfold_note (name, thm) : Attrib.binding * Thm.thm list =
   237       let
   238         val thm_name = Binding.name (name ^ "_unfold");
   239         val src = Attrib.internal (K add_unfold);
   240       in
   241         ((thm_name, [src]), [thm])
   242       end;
   243     val (thmss, lthy'') = lthy'
   244       |> fold_map Local_Theory.note (induct_note :: map unfold_note unfold_thms);
   245   in
   246     (lthy'', names, fixdef_thms, map snd unfold_thms)
   247   end;
   248 
   249 (*************************************************************************)
   250 (*********** monadic notation and pattern matching compilation ***********)
   251 (*************************************************************************)
   252 
   253 structure FixrecMatchData = Theory_Data
   254 (
   255   type T = string Symtab.table;
   256   val empty = Symtab.empty;
   257   val extend = I;
   258   fun merge data = Symtab.merge (K true) data;
   259 );
   260 
   261 (* associate match functions with pattern constants *)
   262 fun add_matchers ms = FixrecMatchData.map (fold Symtab.update ms);
   263 
   264 fun taken_names (t : term) : bstring list =
   265   let
   266     fun taken (Const(a,_), bs) = insert (op =) (Long_Name.base_name a) bs
   267       | taken (Free(a,_) , bs) = insert (op =) a bs
   268       | taken (f $ u     , bs) = taken (f, taken (u, bs))
   269       | taken (Abs(a,_,t), bs) = taken (t, insert (op =) a bs)
   270       | taken (_         , bs) = bs;
   271   in
   272     taken (t, [])
   273   end;
   274 
   275 (* builds a monadic term for matching a constructor pattern *)
   276 fun pre_build match_name pat rhs vs taken =
   277   case pat of
   278     Const(@{const_name Rep_CFun},_)$f$(v as Free(n,T)) =>
   279       pre_build match_name f rhs (v::vs) taken
   280   | Const(@{const_name Rep_CFun},_)$f$x =>
   281       let val (rhs', v, taken') = pre_build match_name x rhs [] taken;
   282       in pre_build match_name f rhs' (v::vs) taken' end
   283   | f$(v as Free(n,T)) =>
   284       pre_build match_name f rhs (v::vs) taken
   285   | f$x =>
   286       let val (rhs', v, taken') = pre_build match_name x rhs [] taken;
   287       in pre_build match_name f rhs' (v::vs) taken' end
   288   | Const(c,T) =>
   289       let
   290         val n = Name.variant taken "v";
   291         fun result_type (Type(@{type_name "->"},[_,T])) (x::xs) = result_type T xs
   292           | result_type (Type (@{type_name "fun"},[_,T])) (x::xs) = result_type T xs
   293           | result_type T _ = T;
   294         val v = Free(n, result_type T vs);
   295         val m = Const(match_name c, matchT (T, fastype_of rhs));
   296         val k = big_lambdas vs rhs;
   297       in
   298         (m`v`k, v, n::taken)
   299       end
   300   | Free(n,_) => fixrec_err ("expected constructor, found free variable " ^ quote n)
   301   | _ => fixrec_err "pre_build: invalid pattern";
   302 
   303 (* builds a monadic term for matching a function definition pattern *)
   304 (* returns (name, arity, matcher) *)
   305 fun building match_name pat rhs vs taken =
   306   case pat of
   307     Const(@{const_name Rep_CFun}, _)$f$(v as Free(n,T)) =>
   308       building match_name f rhs (v::vs) taken
   309   | Const(@{const_name Rep_CFun}, _)$f$x =>
   310       let val (rhs', v, taken') = pre_build match_name x rhs [] taken;
   311       in building match_name f rhs' (v::vs) taken' end
   312   | Free(_,_) => ((pat, length vs), big_lambdas vs rhs)
   313   | Const(_,_) => ((pat, length vs), big_lambdas vs rhs)
   314   | _ => fixrec_err ("function is not declared as constant in theory: "
   315                     ^ ML_Syntax.print_term pat);
   316 
   317 fun strip_alls t =
   318   if Logic.is_all t then strip_alls (snd (Logic.dest_all t)) else t;
   319 
   320 fun match_eq match_name eq =
   321   let
   322     val (lhs,rhs) = dest_eqs (Logic.strip_imp_concl (strip_alls eq));
   323   in
   324     building match_name lhs (mk_return rhs) [] (taken_names eq)
   325   end;
   326 
   327 (* returns the sum (using +++) of the terms in ms *)
   328 (* also applies "run" to the result! *)
   329 fun fatbar arity ms =
   330   let
   331     fun LAM_Ts 0 t = ([], Term.fastype_of t)
   332       | LAM_Ts n (_ $ Abs(_,T,t)) =
   333           let val (Ts, U) = LAM_Ts (n-1) t in (T::Ts, U) end
   334       | LAM_Ts _ _ = fixrec_err "fatbar: internal error, not enough LAMs";
   335     fun unLAM 0 t = t
   336       | unLAM n (_$Abs(_,_,t)) = unLAM (n-1) t
   337       | unLAM _ _ = fixrec_err "fatbar: internal error, not enough LAMs";
   338     fun reLAM ([], U) t = t
   339       | reLAM (T::Ts, U) t = reLAM (Ts, T ->> U) (cabs_const(T,U)$Abs("",T,t));
   340     val msum = foldr1 mk_mplus (map (unLAM arity) ms);
   341     val (Ts, U) = LAM_Ts arity (hd ms)
   342   in
   343     reLAM (rev Ts, dest_maybeT U) (mk_run msum)
   344   end;
   345 
   346 (* this is the pattern-matching compiler function *)
   347 fun compile_pats match_name eqs =
   348   let
   349     val (((n::names),(a::arities)),mats) =
   350       apfst ListPair.unzip (ListPair.unzip (map (match_eq match_name) eqs));
   351     val cname = if forall (fn x => n=x) names then n
   352           else fixrec_err "all equations in block must define the same function";
   353     val arity = if forall (fn x => a=x) arities then a
   354           else fixrec_err "all equations in block must have the same arity";
   355     val rhs = fatbar arity mats;
   356   in
   357     mk_trp (cname === rhs)
   358   end;
   359 
   360 (*************************************************************************)
   361 (********************** Proving associated theorems **********************)
   362 (*************************************************************************)
   363 
   364 structure FixrecSimpData = Generic_Data
   365 (
   366   type T = simpset;
   367   val empty =
   368     HOL_basic_ss
   369       addsimps simp_thms
   370       addsimps [@{thm beta_cfun}]
   371       addsimprocs [@{simproc cont_proc}];
   372   val extend = I;
   373   val merge = merge_ss;
   374 );
   375 
   376 fun fixrec_simp_tac ctxt =
   377   let
   378     val tab = FixrecUnfoldData.get (Context.Proof ctxt);
   379     val ss = FixrecSimpData.get (Context.Proof ctxt);
   380     fun concl t =
   381       if Logic.is_all t then concl (snd (Logic.dest_all t))
   382       else HOLogic.dest_Trueprop (Logic.strip_imp_concl t);
   383     fun tac (t, i) =
   384       let
   385         val Const (c, T) = chead_of (fst (HOLogic.dest_eq (concl t)));
   386         val unfold_thm = the (Symtab.lookup tab c);
   387         val rule = unfold_thm RS @{thm ssubst_lhs};
   388       in
   389         CHANGED (rtac rule i THEN asm_simp_tac ss i)
   390       end
   391   in
   392     SUBGOAL (fn ti => the_default no_tac (try tac ti))
   393   end;
   394 
   395 val fixrec_simp_add : attribute =
   396   Thm.declaration_attribute
   397     (fn th => FixrecSimpData.map (fn ss => ss addsimps [th]));
   398 
   399 val fixrec_simp_del : attribute =
   400   Thm.declaration_attribute
   401     (fn th => FixrecSimpData.map (fn ss => ss delsimps [th]));
   402 
   403 (* proves a block of pattern matching equations as theorems, using unfold *)
   404 fun make_simps ctxt (unfold_thm, eqns : (Attrib.binding * term) list) =
   405   let
   406     val tacs =
   407       [rtac (unfold_thm RS @{thm ssubst_lhs}) 1,
   408        asm_simp_tac (simpset_of ctxt) 1];
   409     fun prove_term t = Goal.prove ctxt [] [] t (K (EVERY tacs));
   410     fun prove_eqn (bind, eqn_t) = (bind, prove_term eqn_t);
   411   in
   412     map prove_eqn eqns
   413   end;
   414 
   415 (*************************************************************************)
   416 (************************* Main fixrec function **************************)
   417 (*************************************************************************)
   418 
   419 local
   420 (* code adapted from HOL/Tools/primrec.ML *)
   421 
   422 fun gen_fixrec
   423   prep_spec
   424   (strict : bool)
   425   raw_fixes
   426   raw_spec
   427   (lthy : local_theory) =
   428   let
   429     val (fixes : ((binding * typ) * mixfix) list,
   430          spec : (Attrib.binding * term) list) =
   431           fst (prep_spec raw_fixes raw_spec lthy);
   432     val chead_of_spec =
   433       chead_of o fst o dest_eqs o Logic.strip_imp_concl o strip_alls o snd;
   434     fun name_of (Free (n, _)) = n
   435       | name_of t = fixrec_err ("unknown term");
   436     val all_names = map (name_of o chead_of_spec) spec;
   437     val names = distinct (op =) all_names;
   438     fun block_of_name n =
   439       map_filter
   440         (fn (m,eq) => if m = n then SOME eq else NONE)
   441         (all_names ~~ spec);
   442     val blocks = map block_of_name names;
   443 
   444     val matcher_tab = FixrecMatchData.get (ProofContext.theory_of lthy);
   445     fun match_name c =
   446       case Symtab.lookup matcher_tab c of SOME m => m
   447         | NONE => fixrec_err ("unknown pattern constructor: " ^ c);
   448 
   449     val matches = map (compile_pats match_name) (map (map snd) blocks);
   450     val spec' = map (pair Attrib.empty_binding) matches;
   451     val (lthy', cnames, fixdef_thms, unfold_thms) =
   452       add_fixdefs fixes spec' lthy;
   453   in
   454     if strict then let (* only prove simp rules if strict = true *)
   455       val simps : (Attrib.binding * thm) list list =
   456         map (make_simps lthy') (unfold_thms ~~ blocks);
   457       fun mk_bind n : Attrib.binding =
   458        (Binding.name (n ^ "_simps"),
   459          [Attrib.internal (K Simplifier.simp_add)]);
   460       val simps1 : (Attrib.binding * thm list) list =
   461         map (fn (n,xs) => (mk_bind n, map snd xs)) (names ~~ simps);
   462       val simps2 : (Attrib.binding * thm list) list =
   463         map (apsnd (fn thm => [thm])) (flat simps);
   464       val (_, lthy'') = lthy'
   465         |> fold_map Local_Theory.note (simps1 @ simps2);
   466     in
   467       lthy''
   468     end
   469     else lthy'
   470   end;
   471 
   472 in
   473 
   474 val add_fixrec = gen_fixrec Specification.check_spec;
   475 val add_fixrec_cmd = gen_fixrec Specification.read_spec;
   476 
   477 end; (* local *)
   478 
   479 (*************************************************************************)
   480 (******************************** Fixpat *********************************)
   481 (*************************************************************************)
   482 
   483 fun fix_pat thy t = 
   484   let
   485     val T = fastype_of t;
   486     val eq = mk_trp (HOLogic.eq_const T $ t $ Var (("x",0),T));
   487     val cname = case chead_of t of Const(c,_) => c | _ =>
   488               fixrec_err "function is not declared as constant in theory";
   489     val unfold_thm = PureThy.get_thm thy (cname^"_unfold");
   490     val simp = Goal.prove_global thy [] [] eq
   491           (fn _ => EVERY [stac unfold_thm 1, simp_tac (global_simpset_of thy) 1]);
   492   in simp end;
   493 
   494 fun gen_add_fixpat prep_term prep_attrib ((name, srcs), strings) thy =
   495   let
   496     val atts = map (prep_attrib thy) srcs;
   497     val ts = map (prep_term thy) strings;
   498     val simps = map (fix_pat thy) ts;
   499   in
   500     (snd o PureThy.add_thmss [((name, simps), atts)]) thy
   501   end;
   502 
   503 val add_fixpat = gen_add_fixpat Sign.cert_term (K I);
   504 val add_fixpat_cmd = gen_add_fixpat Syntax.read_term_global Attrib.attribute;
   505 
   506 
   507 (*************************************************************************)
   508 (******************************** Parsers ********************************)
   509 (*************************************************************************)
   510 
   511 local structure P = OuterParse and K = OuterKeyword in
   512 
   513 val _ = OuterSyntax.local_theory "fixrec" "define recursive functions (HOLCF)" K.thy_decl
   514   ((P.opt_keyword "permissive" >> not) -- P.fixes -- SpecParse.where_alt_specs
   515     >> (fn ((strict, fixes), specs) => add_fixrec_cmd strict fixes specs));
   516 
   517 val _ = OuterSyntax.command "fixpat" "define rewrites for fixrec functions" K.thy_decl
   518   (SpecParse.specs >> (Toplevel.theory o add_fixpat_cmd));
   519 
   520 end;
   521 
   522 val setup =
   523   Attrib.setup @{binding fixrec_simp}
   524                      (Attrib.add_del fixrec_simp_add fixrec_simp_del)
   525                      "declaration of fixrec simp rule"
   526   #> Method.setup @{binding fixrec_simp}
   527                      (Scan.succeed (SIMPLE_METHOD' o fixrec_simp_tac))
   528                      "pattern prover for fixrec constants";
   529 
   530 end;