src/HOL/List.thy
author nipkow
Mon Aug 16 14:22:27 2004 +0200 (2004-08-16)
changeset 15131 c69542757a4d
parent 15113 fafcd72b9d4b
child 15140 322485b816ac
permissions -rw-r--r--
New theory header syntax.
     1 (*  Title:      HOL/List.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4 *)
     5 
     6 header {* The datatype of finite lists *}
     7 
     8 theory List
     9 import PreList
    10 begin
    11 
    12 datatype 'a list =
    13     Nil    ("[]")
    14   | Cons 'a  "'a list"    (infixr "#" 65)
    15 
    16 consts
    17   "@" :: "'a list => 'a list => 'a list"    (infixr 65)
    18   filter:: "('a => bool) => 'a list => 'a list"
    19   concat:: "'a list list => 'a list"
    20   foldl :: "('b => 'a => 'b) => 'b => 'a list => 'b"
    21   foldr :: "('a => 'b => 'b) => 'a list => 'b => 'b"
    22   hd:: "'a list => 'a"
    23   tl:: "'a list => 'a list"
    24   last:: "'a list => 'a"
    25   butlast :: "'a list => 'a list"
    26   set :: "'a list => 'a set"
    27   list_all:: "('a => bool) => ('a list => bool)"
    28   list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool"
    29   map :: "('a=>'b) => ('a list => 'b list)"
    30   mem :: "'a => 'a list => bool"    (infixl 55)
    31   nth :: "'a list => nat => 'a"    (infixl "!" 100)
    32   list_update :: "'a list => nat => 'a => 'a list"
    33   take:: "nat => 'a list => 'a list"
    34   drop:: "nat => 'a list => 'a list"
    35   takeWhile :: "('a => bool) => 'a list => 'a list"
    36   dropWhile :: "('a => bool) => 'a list => 'a list"
    37   rev :: "'a list => 'a list"
    38   zip :: "'a list => 'b list => ('a * 'b) list"
    39   upt :: "nat => nat => nat list" ("(1[_../_'(])")
    40   remdups :: "'a list => 'a list"
    41   remove1 :: "'a => 'a list => 'a list"
    42   null:: "'a list => bool"
    43   "distinct":: "'a list => bool"
    44   replicate :: "nat => 'a => 'a list"
    45 
    46 nonterminals lupdbinds lupdbind
    47 
    48 syntax
    49   -- {* list Enumeration *}
    50   "@list" :: "args => 'a list"    ("[(_)]")
    51 
    52   -- {* Special syntax for filter *}
    53   "@filter" :: "[pttrn, 'a list, bool] => 'a list"    ("(1[_:_./ _])")
    54 
    55   -- {* list update *}
    56   "_lupdbind":: "['a, 'a] => lupdbind"    ("(2_ :=/ _)")
    57   "" :: "lupdbind => lupdbinds"    ("_")
    58   "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds"    ("_,/ _")
    59   "_LUpdate" :: "['a, lupdbinds] => 'a"    ("_/[(_)]" [900,0] 900)
    60 
    61   upto:: "nat => nat => nat list"    ("(1[_../_])")
    62 
    63 translations
    64   "[x, xs]" == "x#[xs]"
    65   "[x]" == "x#[]"
    66   "[x:xs . P]"== "filter (%x. P) xs"
    67 
    68   "_LUpdate xs (_lupdbinds b bs)"== "_LUpdate (_LUpdate xs b) bs"
    69   "xs[i:=x]" == "list_update xs i x"
    70 
    71   "[i..j]" == "[i..(Suc j)(]"
    72 
    73 
    74 syntax (xsymbols)
    75   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    76 syntax (HTML output)
    77   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    78 
    79 
    80 text {*
    81   Function @{text size} is overloaded for all datatypes. Users may
    82   refer to the list version as @{text length}. *}
    83 
    84 syntax length :: "'a list => nat"
    85 translations "length" => "size :: _ list => nat"
    86 
    87 typed_print_translation {*
    88   let
    89     fun size_tr' _ (Type ("fun", (Type ("list", _) :: _))) [t] =
    90           Syntax.const "length" $ t
    91       | size_tr' _ _ _ = raise Match;
    92   in [("size", size_tr')] end
    93 *}
    94 
    95 primrec
    96 "hd(x#xs) = x"
    97 primrec
    98 "tl([]) = []"
    99 "tl(x#xs) = xs"
   100 primrec
   101 "null([]) = True"
   102 "null(x#xs) = False"
   103 primrec
   104 "last(x#xs) = (if xs=[] then x else last xs)"
   105 primrec
   106 "butlast []= []"
   107 "butlast(x#xs) = (if xs=[] then [] else x#butlast xs)"
   108 primrec
   109 "x mem [] = False"
   110 "x mem (y#ys) = (if y=x then True else x mem ys)"
   111 primrec
   112 "set [] = {}"
   113 "set (x#xs) = insert x (set xs)"
   114 primrec
   115 list_all_Nil:"list_all P [] = True"
   116 list_all_Cons: "list_all P (x#xs) = (P(x) \<and> list_all P xs)"
   117 primrec
   118 "map f [] = []"
   119 "map f (x#xs) = f(x)#map f xs"
   120 primrec
   121 append_Nil:"[]@ys = ys"
   122 append_Cons: "(x#xs)@ys = x#(xs@ys)"
   123 primrec
   124 "rev([]) = []"
   125 "rev(x#xs) = rev(xs) @ [x]"
   126 primrec
   127 "filter P [] = []"
   128 "filter P (x#xs) = (if P x then x#filter P xs else filter P xs)"
   129 primrec
   130 foldl_Nil:"foldl f a [] = a"
   131 foldl_Cons: "foldl f a (x#xs) = foldl f (f a x) xs"
   132 primrec
   133 "foldr f [] a = a"
   134 "foldr f (x#xs) a = f x (foldr f xs a)"
   135 primrec
   136 "concat([]) = []"
   137 "concat(x#xs) = x @ concat(xs)"
   138 primrec
   139 drop_Nil:"drop n [] = []"
   140 drop_Cons: "drop n (x#xs) = (case n of 0 => x#xs | Suc(m) => drop m xs)"
   141 -- {* Warning: simpset does not contain this definition *}
   142 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   143 primrec
   144 take_Nil:"take n [] = []"
   145 take_Cons: "take n (x#xs) = (case n of 0 => [] | Suc(m) => x # take m xs)"
   146 -- {* Warning: simpset does not contain this definition *}
   147 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   148 primrec
   149 nth_Cons:"(x#xs)!n = (case n of 0 => x | (Suc k) => xs!k)"
   150 -- {* Warning: simpset does not contain this definition *}
   151 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   152 primrec
   153 "[][i:=v] = []"
   154 "(x#xs)[i:=v] =
   155 (case i of 0 => v # xs
   156 | Suc j => x # xs[j:=v])"
   157 primrec
   158 "takeWhile P [] = []"
   159 "takeWhile P (x#xs) = (if P x then x#takeWhile P xs else [])"
   160 primrec
   161 "dropWhile P [] = []"
   162 "dropWhile P (x#xs) = (if P x then dropWhile P xs else x#xs)"
   163 primrec
   164 "zip xs [] = []"
   165 zip_Cons: "zip xs (y#ys) = (case xs of [] => [] | z#zs => (z,y)#zip zs ys)"
   166 -- {* Warning: simpset does not contain this definition *}
   167 -- {* but separate theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   168 primrec
   169 upt_0: "[i..0(] = []"
   170 upt_Suc: "[i..(Suc j)(] = (if i <= j then [i..j(] @ [j] else [])"
   171 primrec
   172 "distinct [] = True"
   173 "distinct (x#xs) = (x ~: set xs \<and> distinct xs)"
   174 primrec
   175 "remdups [] = []"
   176 "remdups (x#xs) = (if x : set xs then remdups xs else x # remdups xs)"
   177 primrec
   178 "remove1 x [] = []"
   179 "remove1 x (y#xs) = (if x=y then xs else y # remove1 x xs)"
   180 primrec
   181 replicate_0: "replicate 0 x = []"
   182 replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   183 defs
   184  list_all2_def:
   185  "list_all2 P xs ys == length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y)"
   186 
   187 
   188 subsection {* Lexicographic orderings on lists *}
   189 
   190 consts
   191 lexn :: "('a * 'a)set => nat => ('a list * 'a list)set"
   192 primrec
   193 "lexn r 0 = {}"
   194 "lexn r (Suc n) =
   195 (prod_fun (%(x,xs). x#xs) (%(x,xs). x#xs) ` (r <*lex*> lexn r n)) Int
   196 {(xs,ys). length xs = Suc n \<and> length ys = Suc n}"
   197 
   198 constdefs
   199 lex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   200 "lex r == \<Union>n. lexn r n"
   201 
   202 lexico :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   203 "lexico r == inv_image (less_than <*lex*> lex r) (%xs. (length xs, xs))"
   204 
   205 sublist :: "'a list => nat set => 'a list"
   206 "sublist xs A == map fst (filter (%p. snd p : A) (zip xs [0..size xs(]))"
   207 
   208 
   209 lemma not_Cons_self [simp]: "xs \<noteq> x # xs"
   210 by (induct xs) auto
   211 
   212 lemmas not_Cons_self2 [simp] = not_Cons_self [symmetric]
   213 
   214 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   215 by (induct xs) auto
   216 
   217 lemma length_induct:
   218 "(!!xs. \<forall>ys. length ys < length xs --> P ys ==> P xs) ==> P xs"
   219 by (rule measure_induct [of length]) rules
   220 
   221 
   222 subsection {* @{text lists}: the list-forming operator over sets *}
   223 
   224 consts lists :: "'a set => 'a list set"
   225 inductive "lists A"
   226 intros
   227 Nil [intro!]: "[]: lists A"
   228 Cons [intro!]: "[| a: A;l: lists A|] ==> a#l : lists A"
   229 
   230 inductive_cases listsE [elim!]: "x#l : lists A"
   231 
   232 lemma lists_mono [mono]: "A \<subseteq> B ==> lists A \<subseteq> lists B"
   233 by (unfold lists.defs) (blast intro!: lfp_mono)
   234 
   235 lemma lists_IntI:
   236   assumes l: "l: lists A" shows "l: lists B ==> l: lists (A Int B)" using l
   237   by induct blast+
   238 
   239 lemma lists_Int_eq [simp]: "lists (A \<inter> B) = lists A \<inter> lists B"
   240 proof (rule mono_Int [THEN equalityI])
   241   show "mono lists" by (simp add: mono_def lists_mono)
   242   show "lists A \<inter> lists B \<subseteq> lists (A \<inter> B)" by (blast intro: lists_IntI)
   243 qed
   244 
   245 lemma append_in_lists_conv [iff]:
   246      "(xs @ ys : lists A) = (xs : lists A \<and> ys : lists A)"
   247 by (induct xs) auto
   248 
   249 
   250 subsection {* @{text length} *}
   251 
   252 text {*
   253 Needs to come before @{text "@"} because of theorem @{text
   254 append_eq_append_conv}.
   255 *}
   256 
   257 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   258 by (induct xs) auto
   259 
   260 lemma length_map [simp]: "length (map f xs) = length xs"
   261 by (induct xs) auto
   262 
   263 lemma length_rev [simp]: "length (rev xs) = length xs"
   264 by (induct xs) auto
   265 
   266 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   267 by (cases xs) auto
   268 
   269 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   270 by (induct xs) auto
   271 
   272 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   273 by (induct xs) auto
   274 
   275 lemma length_Suc_conv:
   276 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   277 by (induct xs) auto
   278 
   279 lemma Suc_length_conv:
   280 "(Suc n = length xs) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   281 apply (induct xs, simp, simp)
   282 apply blast
   283 done
   284 
   285 lemma impossible_Cons [rule_format]: 
   286   "length xs <= length ys --> xs = x # ys = False"
   287 apply (induct xs, auto)
   288 done
   289 
   290 lemma list_induct2[consumes 1]: "\<And>ys.
   291  \<lbrakk> length xs = length ys;
   292    P [] [];
   293    \<And>x xs y ys. \<lbrakk> length xs = length ys; P xs ys \<rbrakk> \<Longrightarrow> P (x#xs) (y#ys) \<rbrakk>
   294  \<Longrightarrow> P xs ys"
   295 apply(induct xs)
   296  apply simp
   297 apply(case_tac ys)
   298  apply simp
   299 apply(simp)
   300 done
   301 
   302 subsection {* @{text "@"} -- append *}
   303 
   304 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   305 by (induct xs) auto
   306 
   307 lemma append_Nil2 [simp]: "xs @ [] = xs"
   308 by (induct xs) auto
   309 
   310 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   311 by (induct xs) auto
   312 
   313 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   314 by (induct xs) auto
   315 
   316 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   317 by (induct xs) auto
   318 
   319 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   320 by (induct xs) auto
   321 
   322 lemma append_eq_append_conv [simp]:
   323  "!!ys. length xs = length ys \<or> length us = length vs
   324  ==> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   325 apply (induct xs)
   326  apply (case_tac ys, simp, force)
   327 apply (case_tac ys, force, simp)
   328 done
   329 
   330 lemma append_eq_append_conv2: "!!ys zs ts.
   331  (xs @ ys = zs @ ts) =
   332  (EX us. xs = zs @ us & us @ ys = ts | xs @ us = zs & ys = us@ ts)"
   333 apply (induct xs)
   334  apply fastsimp
   335 apply(case_tac zs)
   336  apply simp
   337 apply fastsimp
   338 done
   339 
   340 lemma same_append_eq [iff]: "(xs @ ys = xs @ zs) = (ys = zs)"
   341 by simp
   342 
   343 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   344 by simp
   345 
   346 lemma append_same_eq [iff]: "(ys @ xs = zs @ xs) = (ys = zs)"
   347 by simp
   348 
   349 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   350 using append_same_eq [of _ _ "[]"] by auto
   351 
   352 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   353 using append_same_eq [of "[]"] by auto
   354 
   355 lemma hd_Cons_tl [simp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   356 by (induct xs) auto
   357 
   358 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   359 by (induct xs) auto
   360 
   361 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   362 by (simp add: hd_append split: list.split)
   363 
   364 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   365 by (simp split: list.split)
   366 
   367 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   368 by (simp add: tl_append split: list.split)
   369 
   370 
   371 lemma Cons_eq_append_conv: "x#xs = ys@zs =
   372  (ys = [] & x#xs = zs | (EX ys'. x#ys' = ys & xs = ys'@zs))"
   373 by(cases ys) auto
   374 
   375 
   376 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   377 
   378 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   379 by simp
   380 
   381 lemma Cons_eq_appendI:
   382 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   383 by (drule sym) simp
   384 
   385 lemma append_eq_appendI:
   386 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   387 by (drule sym) simp
   388 
   389 
   390 text {*
   391 Simplification procedure for all list equalities.
   392 Currently only tries to rearrange @{text "@"} to see if
   393 - both lists end in a singleton list,
   394 - or both lists end in the same list.
   395 *}
   396 
   397 ML_setup {*
   398 local
   399 
   400 val append_assoc = thm "append_assoc";
   401 val append_Nil = thm "append_Nil";
   402 val append_Cons = thm "append_Cons";
   403 val append1_eq_conv = thm "append1_eq_conv";
   404 val append_same_eq = thm "append_same_eq";
   405 
   406 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   407   (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   408   | last (Const("List.op @",_) $ _ $ ys) = last ys
   409   | last t = t;
   410 
   411 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   412   | list1 _ = false;
   413 
   414 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   415   (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   416   | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   417   | butlast xs = Const("List.list.Nil",fastype_of xs);
   418 
   419 val rearr_tac =
   420   simp_tac (HOL_basic_ss addsimps [append_assoc, append_Nil, append_Cons]);
   421 
   422 fun list_eq sg _ (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   423   let
   424     val lastl = last lhs and lastr = last rhs;
   425     fun rearr conv =
   426       let
   427         val lhs1 = butlast lhs and rhs1 = butlast rhs;
   428         val Type(_,listT::_) = eqT
   429         val appT = [listT,listT] ---> listT
   430         val app = Const("List.op @",appT)
   431         val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   432         val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (F,F2));
   433         val thm = Tactic.prove sg [] [] eq (K (rearr_tac 1));
   434       in Some ((conv RS (thm RS trans)) RS eq_reflection) end;
   435 
   436   in
   437     if list1 lastl andalso list1 lastr then rearr append1_eq_conv
   438     else if lastl aconv lastr then rearr append_same_eq
   439     else None
   440   end;
   441 
   442 in
   443 
   444 val list_eq_simproc =
   445   Simplifier.simproc (Theory.sign_of (the_context ())) "list_eq" ["(xs::'a list) = ys"] list_eq;
   446 
   447 end;
   448 
   449 Addsimprocs [list_eq_simproc];
   450 *}
   451 
   452 
   453 subsection {* @{text map} *}
   454 
   455 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   456 by (induct xs) simp_all
   457 
   458 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   459 by (rule ext, induct_tac xs) auto
   460 
   461 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   462 by (induct xs) auto
   463 
   464 lemma map_compose: "map (f o g) xs = map f (map g xs)"
   465 by (induct xs) (auto simp add: o_def)
   466 
   467 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   468 by (induct xs) auto
   469 
   470 lemma map_eq_conv[simp]: "(map f xs = map g xs) = (!x : set xs. f x = g x)"
   471 by (induct xs) auto
   472 
   473 lemma map_cong [recdef_cong]:
   474 "xs = ys ==> (!!x. x : set ys ==> f x = g x) ==> map f xs = map g ys"
   475 -- {* a congruence rule for @{text map} *}
   476 by simp
   477 
   478 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   479 by (cases xs) auto
   480 
   481 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   482 by (cases xs) auto
   483 
   484 lemma map_eq_Cons_conv[iff]:
   485  "(map f xs = y#ys) = (\<exists>z zs. xs = z#zs \<and> f z = y \<and> map f zs = ys)"
   486 by (cases xs) auto
   487 
   488 lemma Cons_eq_map_conv[iff]:
   489  "(x#xs = map f ys) = (\<exists>z zs. ys = z#zs \<and> x = f z \<and> xs = map f zs)"
   490 by (cases ys) auto
   491 
   492 lemma ex_map_conv:
   493   "(EX xs. ys = map f xs) = (ALL y : set ys. EX x. y = f x)"
   494 by(induct ys, auto)
   495 
   496 lemma map_eq_imp_length_eq:
   497   "!!xs. map f xs = map f ys ==> length xs = length ys"
   498 apply (induct ys)
   499  apply simp
   500 apply(simp (no_asm_use))
   501 apply clarify
   502 apply(simp (no_asm_use))
   503 apply fast
   504 done
   505 
   506 lemma map_inj_on:
   507  "[| map f xs = map f ys; inj_on f (set xs Un set ys) |]
   508   ==> xs = ys"
   509 apply(frule map_eq_imp_length_eq)
   510 apply(rotate_tac -1)
   511 apply(induct rule:list_induct2)
   512  apply simp
   513 apply(simp)
   514 apply (blast intro:sym)
   515 done
   516 
   517 lemma inj_on_map_eq_map:
   518  "inj_on f (set xs Un set ys) \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   519 by(blast dest:map_inj_on)
   520 
   521 lemma map_injective:
   522  "!!xs. map f xs = map f ys ==> inj f ==> xs = ys"
   523 by (induct ys) (auto dest!:injD)
   524 
   525 lemma inj_map_eq_map[simp]: "inj f \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   526 by(blast dest:map_injective)
   527 
   528 lemma inj_mapI: "inj f ==> inj (map f)"
   529 by (rules dest: map_injective injD intro: inj_onI)
   530 
   531 lemma inj_mapD: "inj (map f) ==> inj f"
   532 apply (unfold inj_on_def, clarify)
   533 apply (erule_tac x = "[x]" in ballE)
   534  apply (erule_tac x = "[y]" in ballE, simp, blast)
   535 apply blast
   536 done
   537 
   538 lemma inj_map[iff]: "inj (map f) = inj f"
   539 by (blast dest: inj_mapD intro: inj_mapI)
   540 
   541 lemma map_idI: "(\<And>x. x \<in> set xs \<Longrightarrow> f x = x) \<Longrightarrow> map f xs = xs"
   542 by (induct xs, auto)
   543 
   544 lemma map_fun_upd [simp]: "y \<notin> set xs \<Longrightarrow> map (f(y:=v)) xs = map f xs"
   545 by (induct xs) auto
   546 
   547 lemma map_fst_zip[simp]:
   548   "length xs = length ys \<Longrightarrow> map fst (zip xs ys) = xs"
   549 by (induct rule:list_induct2, simp_all)
   550 
   551 lemma map_snd_zip[simp]:
   552   "length xs = length ys \<Longrightarrow> map snd (zip xs ys) = ys"
   553 by (induct rule:list_induct2, simp_all)
   554 
   555 
   556 subsection {* @{text rev} *}
   557 
   558 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   559 by (induct xs) auto
   560 
   561 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   562 by (induct xs) auto
   563 
   564 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   565 by (induct xs) auto
   566 
   567 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   568 by (induct xs) auto
   569 
   570 lemma rev_is_rev_conv [iff]: "!!ys. (rev xs = rev ys) = (xs = ys)"
   571 apply (induct xs, force)
   572 apply (case_tac ys, simp, force)
   573 done
   574 
   575 lemma rev_induct [case_names Nil snoc]:
   576   "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   577 apply(subst rev_rev_ident[symmetric])
   578 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   579 done
   580 
   581 ML {* val rev_induct_tac = induct_thm_tac (thm "rev_induct") *}-- "compatibility"
   582 
   583 lemma rev_exhaust [case_names Nil snoc]:
   584   "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   585 by (induct xs rule: rev_induct) auto
   586 
   587 lemmas rev_cases = rev_exhaust
   588 
   589 
   590 subsection {* @{text set} *}
   591 
   592 lemma finite_set [iff]: "finite (set xs)"
   593 by (induct xs) auto
   594 
   595 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   596 by (induct xs) auto
   597 
   598 lemma hd_in_set: "l = x#xs \<Longrightarrow> x\<in>set l"
   599 by (case_tac l, auto)
   600 
   601 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   602 by auto
   603 
   604 lemma set_ConsD: "y \<in> set (x # xs) \<Longrightarrow> y=x \<or> y \<in> set xs" 
   605 by auto
   606 
   607 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   608 by (induct xs) auto
   609 
   610 lemma set_rev [simp]: "set (rev xs) = set xs"
   611 by (induct xs) auto
   612 
   613 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   614 by (induct xs) auto
   615 
   616 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   617 by (induct xs) auto
   618 
   619 lemma set_upt [simp]: "set[i..j(] = {k. i \<le> k \<and> k < j}"
   620 apply (induct j, simp_all)
   621 apply (erule ssubst, auto)
   622 done
   623 
   624 lemma in_set_conv_decomp: "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs)"
   625 proof (induct xs)
   626   case Nil show ?case by simp
   627   case (Cons a xs)
   628   show ?case
   629   proof 
   630     assume "x \<in> set (a # xs)"
   631     with prems show "\<exists>ys zs. a # xs = ys @ x # zs"
   632       by (simp, blast intro: Cons_eq_appendI)
   633   next
   634     assume "\<exists>ys zs. a # xs = ys @ x # zs"
   635     then obtain ys zs where eq: "a # xs = ys @ x # zs" by blast
   636     show "x \<in> set (a # xs)" 
   637       by (cases ys, auto simp add: eq)
   638   qed
   639 qed
   640 
   641 lemma in_lists_conv_set: "(xs : lists A) = (\<forall>x \<in> set xs. x : A)"
   642 -- {* eliminate @{text lists} in favour of @{text set} *}
   643 by (induct xs) auto
   644 
   645 lemma in_listsD [dest!]: "xs \<in> lists A ==> \<forall>x\<in>set xs. x \<in> A"
   646 by (rule in_lists_conv_set [THEN iffD1])
   647 
   648 lemma in_listsI [intro!]: "\<forall>x\<in>set xs. x \<in> A ==> xs \<in> lists A"
   649 by (rule in_lists_conv_set [THEN iffD2])
   650 
   651 lemma finite_list: "finite A ==> EX l. set l = A"
   652 apply (erule finite_induct, auto)
   653 apply (rule_tac x="x#l" in exI, auto)
   654 done
   655 
   656 lemma card_length: "card (set xs) \<le> length xs"
   657 by (induct xs) (auto simp add: card_insert_if)
   658 
   659 subsection {* @{text mem} *}
   660 
   661 lemma set_mem_eq: "(x mem xs) = (x : set xs)"
   662 by (induct xs) auto
   663 
   664 
   665 subsection {* @{text list_all} *}
   666 
   667 lemma list_all_conv: "list_all P xs = (\<forall>x \<in> set xs. P x)"
   668 by (induct xs) auto
   669 
   670 lemma list_all_append [simp]:
   671 "list_all P (xs @ ys) = (list_all P xs \<and> list_all P ys)"
   672 by (induct xs) auto
   673 
   674 
   675 subsection {* @{text filter} *}
   676 
   677 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
   678 by (induct xs) auto
   679 
   680 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
   681 by (induct xs) auto
   682 
   683 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
   684 by (induct xs) auto
   685 
   686 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
   687 by (induct xs) auto
   688 
   689 lemma length_filter [simp]: "length (filter P xs) \<le> length xs"
   690 by (induct xs) (auto simp add: le_SucI)
   691 
   692 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
   693 by auto
   694 
   695 
   696 subsection {* @{text concat} *}
   697 
   698 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
   699 by (induct xs) auto
   700 
   701 lemma concat_eq_Nil_conv [iff]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
   702 by (induct xss) auto
   703 
   704 lemma Nil_eq_concat_conv [iff]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
   705 by (induct xss) auto
   706 
   707 lemma set_concat [simp]: "set (concat xs) = \<Union>(set ` set xs)"
   708 by (induct xs) auto
   709 
   710 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
   711 by (induct xs) auto
   712 
   713 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
   714 by (induct xs) auto
   715 
   716 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
   717 by (induct xs) auto
   718 
   719 
   720 subsection {* @{text nth} *}
   721 
   722 lemma nth_Cons_0 [simp]: "(x # xs)!0 = x"
   723 by auto
   724 
   725 lemma nth_Cons_Suc [simp]: "(x # xs)!(Suc n) = xs!n"
   726 by auto
   727 
   728 declare nth.simps [simp del]
   729 
   730 lemma nth_append:
   731 "!!n. (xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
   732 apply (induct "xs", simp)
   733 apply (case_tac n, auto)
   734 done
   735 
   736 lemma nth_append_length [simp]: "(xs @ x # ys) ! length xs = x"
   737 by (induct "xs") auto
   738 
   739 lemma nth_append_length_plus[simp]: "(xs @ ys) ! (length xs + n) = ys ! n"
   740 by (induct "xs") auto
   741 
   742 lemma nth_map [simp]: "!!n. n < length xs ==> (map f xs)!n = f(xs!n)"
   743 apply (induct xs, simp)
   744 apply (case_tac n, auto)
   745 done
   746 
   747 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
   748 apply (induct_tac xs, simp, simp)
   749 apply safe
   750 apply (rule_tac x = 0 in exI, simp)
   751  apply (rule_tac x = "Suc i" in exI, simp)
   752 apply (case_tac i, simp)
   753 apply (rename_tac j)
   754 apply (rule_tac x = j in exI, simp)
   755 done
   756 
   757 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
   758 by (auto simp add: set_conv_nth)
   759 
   760 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
   761 by (auto simp add: set_conv_nth)
   762 
   763 lemma all_nth_imp_all_set:
   764 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
   765 by (auto simp add: set_conv_nth)
   766 
   767 lemma all_set_conv_all_nth:
   768 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
   769 by (auto simp add: set_conv_nth)
   770 
   771 
   772 subsection {* @{text list_update} *}
   773 
   774 lemma length_list_update [simp]: "!!i. length(xs[i:=x]) = length xs"
   775 by (induct xs) (auto split: nat.split)
   776 
   777 lemma nth_list_update:
   778 "!!i j. i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
   779 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   780 
   781 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
   782 by (simp add: nth_list_update)
   783 
   784 lemma nth_list_update_neq [simp]: "!!i j. i \<noteq> j ==> xs[i:=x]!j = xs!j"
   785 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   786 
   787 lemma list_update_overwrite [simp]:
   788 "!!i. i < size xs ==> xs[i:=x, i:=y] = xs[i:=y]"
   789 by (induct xs) (auto split: nat.split)
   790 
   791 lemma list_update_id[simp]: "!!i. i < length xs ==> xs[i := xs!i] = xs"
   792 apply (induct xs, simp)
   793 apply(simp split:nat.splits)
   794 done
   795 
   796 lemma list_update_same_conv:
   797 "!!i. i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
   798 by (induct xs) (auto split: nat.split)
   799 
   800 lemma list_update_append1:
   801  "!!i. i < size xs \<Longrightarrow> (xs @ ys)[i:=x] = xs[i:=x] @ ys"
   802 apply (induct xs, simp)
   803 apply(simp split:nat.split)
   804 done
   805 
   806 lemma list_update_length [simp]:
   807  "(xs @ x # ys)[length xs := y] = (xs @ y # ys)"
   808 by (induct xs, auto)
   809 
   810 lemma update_zip:
   811 "!!i xy xs. length xs = length ys ==>
   812 (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
   813 by (induct ys) (auto, case_tac xs, auto split: nat.split)
   814 
   815 lemma set_update_subset_insert: "!!i. set(xs[i:=x]) <= insert x (set xs)"
   816 by (induct xs) (auto split: nat.split)
   817 
   818 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
   819 by (blast dest!: set_update_subset_insert [THEN subsetD])
   820 
   821 
   822 subsection {* @{text last} and @{text butlast} *}
   823 
   824 lemma last_snoc [simp]: "last (xs @ [x]) = x"
   825 by (induct xs) auto
   826 
   827 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
   828 by (induct xs) auto
   829 
   830 lemma last_ConsL: "xs = [] \<Longrightarrow> last(x#xs) = x"
   831 by(simp add:last.simps)
   832 
   833 lemma last_ConsR: "xs \<noteq> [] \<Longrightarrow> last(x#xs) = last xs"
   834 by(simp add:last.simps)
   835 
   836 lemma last_append: "last(xs @ ys) = (if ys = [] then last xs else last ys)"
   837 by (induct xs) (auto)
   838 
   839 lemma last_appendL[simp]: "ys = [] \<Longrightarrow> last(xs @ ys) = last xs"
   840 by(simp add:last_append)
   841 
   842 lemma last_appendR[simp]: "ys \<noteq> [] \<Longrightarrow> last(xs @ ys) = last ys"
   843 by(simp add:last_append)
   844 
   845 
   846 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
   847 by (induct xs rule: rev_induct) auto
   848 
   849 lemma butlast_append:
   850 "!!ys. butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
   851 by (induct xs) auto
   852 
   853 lemma append_butlast_last_id [simp]:
   854 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
   855 by (induct xs) auto
   856 
   857 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
   858 by (induct xs) (auto split: split_if_asm)
   859 
   860 lemma in_set_butlast_appendI:
   861 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
   862 by (auto dest: in_set_butlastD simp add: butlast_append)
   863 
   864 
   865 subsection {* @{text take} and @{text drop} *}
   866 
   867 lemma take_0 [simp]: "take 0 xs = []"
   868 by (induct xs) auto
   869 
   870 lemma drop_0 [simp]: "drop 0 xs = xs"
   871 by (induct xs) auto
   872 
   873 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
   874 by simp
   875 
   876 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
   877 by simp
   878 
   879 declare take_Cons [simp del] and drop_Cons [simp del]
   880 
   881 lemma take_Suc: "xs ~= [] ==> take (Suc n) xs = hd xs # take n (tl xs)"
   882 by(clarsimp simp add:neq_Nil_conv)
   883 
   884 lemma drop_Suc: "drop (Suc n) xs = drop n (tl xs)"
   885 by(cases xs, simp_all)
   886 
   887 lemma drop_tl: "!!n. drop n (tl xs) = tl(drop n xs)"
   888 by(induct xs, simp_all add:drop_Cons drop_Suc split:nat.split)
   889 
   890 lemma nth_via_drop: "!!n. drop n xs = y#ys \<Longrightarrow> xs!n = y"
   891 apply (induct xs, simp)
   892 apply(simp add:drop_Cons nth_Cons split:nat.splits)
   893 done
   894 
   895 lemma take_Suc_conv_app_nth:
   896  "!!i. i < length xs \<Longrightarrow> take (Suc i) xs = take i xs @ [xs!i]"
   897 apply (induct xs, simp)
   898 apply (case_tac i, auto)
   899 done
   900 
   901 lemma drop_Suc_conv_tl:
   902   "!!i. i < length xs \<Longrightarrow> (xs!i) # (drop (Suc i) xs) = drop i xs"
   903 apply (induct xs, simp)
   904 apply (case_tac i, auto)
   905 done
   906 
   907 lemma length_take [simp]: "!!xs. length (take n xs) = min (length xs) n"
   908 by (induct n) (auto, case_tac xs, auto)
   909 
   910 lemma length_drop [simp]: "!!xs. length (drop n xs) = (length xs - n)"
   911 by (induct n) (auto, case_tac xs, auto)
   912 
   913 lemma take_all [simp]: "!!xs. length xs <= n ==> take n xs = xs"
   914 by (induct n) (auto, case_tac xs, auto)
   915 
   916 lemma drop_all [simp]: "!!xs. length xs <= n ==> drop n xs = []"
   917 by (induct n) (auto, case_tac xs, auto)
   918 
   919 lemma take_append [simp]:
   920 "!!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
   921 by (induct n) (auto, case_tac xs, auto)
   922 
   923 lemma drop_append [simp]:
   924 "!!xs. drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
   925 by (induct n) (auto, case_tac xs, auto)
   926 
   927 lemma take_take [simp]: "!!xs n. take n (take m xs) = take (min n m) xs"
   928 apply (induct m, auto)
   929 apply (case_tac xs, auto)
   930 apply (case_tac na, auto)
   931 done
   932 
   933 lemma drop_drop [simp]: "!!xs. drop n (drop m xs) = drop (n + m) xs"
   934 apply (induct m, auto)
   935 apply (case_tac xs, auto)
   936 done
   937 
   938 lemma take_drop: "!!xs n. take n (drop m xs) = drop m (take (n + m) xs)"
   939 apply (induct m, auto)
   940 apply (case_tac xs, auto)
   941 done
   942 
   943 lemma drop_take: "!!m n. drop n (take m xs) = take (m-n) (drop n xs)"
   944 apply(induct xs)
   945  apply simp
   946 apply(simp add: take_Cons drop_Cons split:nat.split)
   947 done
   948 
   949 lemma append_take_drop_id [simp]: "!!xs. take n xs @ drop n xs = xs"
   950 apply (induct n, auto)
   951 apply (case_tac xs, auto)
   952 done
   953 
   954 lemma take_eq_Nil[simp]: "!!n. (take n xs = []) = (n = 0 \<or> xs = [])"
   955 apply(induct xs)
   956  apply simp
   957 apply(simp add:take_Cons split:nat.split)
   958 done
   959 
   960 lemma drop_eq_Nil[simp]: "!!n. (drop n xs = []) = (length xs <= n)"
   961 apply(induct xs)
   962 apply simp
   963 apply(simp add:drop_Cons split:nat.split)
   964 done
   965 
   966 lemma take_map: "!!xs. take n (map f xs) = map f (take n xs)"
   967 apply (induct n, auto)
   968 apply (case_tac xs, auto)
   969 done
   970 
   971 lemma drop_map: "!!xs. drop n (map f xs) = map f (drop n xs)"
   972 apply (induct n, auto)
   973 apply (case_tac xs, auto)
   974 done
   975 
   976 lemma rev_take: "!!i. rev (take i xs) = drop (length xs - i) (rev xs)"
   977 apply (induct xs, auto)
   978 apply (case_tac i, auto)
   979 done
   980 
   981 lemma rev_drop: "!!i. rev (drop i xs) = take (length xs - i) (rev xs)"
   982 apply (induct xs, auto)
   983 apply (case_tac i, auto)
   984 done
   985 
   986 lemma nth_take [simp]: "!!n i. i < n ==> (take n xs)!i = xs!i"
   987 apply (induct xs, auto)
   988 apply (case_tac n, blast)
   989 apply (case_tac i, auto)
   990 done
   991 
   992 lemma nth_drop [simp]:
   993 "!!xs i. n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
   994 apply (induct n, auto)
   995 apply (case_tac xs, auto)
   996 done
   997 
   998 lemma set_take_subset: "\<And>n. set(take n xs) \<subseteq> set xs"
   999 by(induct xs)(auto simp:take_Cons split:nat.split)
  1000 
  1001 lemma set_drop_subset: "\<And>n. set(drop n xs) \<subseteq> set xs"
  1002 by(induct xs)(auto simp:drop_Cons split:nat.split)
  1003 
  1004 lemma in_set_takeD: "x : set(take n xs) \<Longrightarrow> x : set xs"
  1005 using set_take_subset by fast
  1006 
  1007 lemma in_set_dropD: "x : set(drop n xs) \<Longrightarrow> x : set xs"
  1008 using set_drop_subset by fast
  1009 
  1010 lemma append_eq_conv_conj:
  1011 "!!zs. (xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
  1012 apply (induct xs, simp, clarsimp)
  1013 apply (case_tac zs, auto)
  1014 done
  1015 
  1016 lemma take_add [rule_format]: 
  1017     "\<forall>i. i+j \<le> length(xs) --> take (i+j) xs = take i xs @ take j (drop i xs)"
  1018 apply (induct xs, auto) 
  1019 apply (case_tac i, simp_all) 
  1020 done
  1021 
  1022 lemma append_eq_append_conv_if:
  1023  "!! ys\<^isub>1. (xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>1 @ ys\<^isub>2) =
  1024   (if size xs\<^isub>1 \<le> size ys\<^isub>1
  1025    then xs\<^isub>1 = take (size xs\<^isub>1) ys\<^isub>1 \<and> xs\<^isub>2 = drop (size xs\<^isub>1) ys\<^isub>1 @ ys\<^isub>2
  1026    else take (size ys\<^isub>1) xs\<^isub>1 = ys\<^isub>1 \<and> drop (size ys\<^isub>1) xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>2)"
  1027 apply(induct xs\<^isub>1)
  1028  apply simp
  1029 apply(case_tac ys\<^isub>1)
  1030 apply simp_all
  1031 done
  1032 
  1033 lemma take_hd_drop:
  1034   "!!n. n < length xs \<Longrightarrow> take n xs @ [hd (drop n xs)] = take (n+1) xs"
  1035 apply(induct xs)
  1036 apply simp
  1037 apply(simp add:drop_Cons split:nat.split)
  1038 done
  1039 
  1040 
  1041 subsection {* @{text takeWhile} and @{text dropWhile} *}
  1042 
  1043 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
  1044 by (induct xs) auto
  1045 
  1046 lemma takeWhile_append1 [simp]:
  1047 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
  1048 by (induct xs) auto
  1049 
  1050 lemma takeWhile_append2 [simp]:
  1051 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
  1052 by (induct xs) auto
  1053 
  1054 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
  1055 by (induct xs) auto
  1056 
  1057 lemma dropWhile_append1 [simp]:
  1058 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
  1059 by (induct xs) auto
  1060 
  1061 lemma dropWhile_append2 [simp]:
  1062 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
  1063 by (induct xs) auto
  1064 
  1065 lemma set_take_whileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
  1066 by (induct xs) (auto split: split_if_asm)
  1067 
  1068 lemma takeWhile_eq_all_conv[simp]:
  1069  "(takeWhile P xs = xs) = (\<forall>x \<in> set xs. P x)"
  1070 by(induct xs, auto)
  1071 
  1072 lemma dropWhile_eq_Nil_conv[simp]:
  1073  "(dropWhile P xs = []) = (\<forall>x \<in> set xs. P x)"
  1074 by(induct xs, auto)
  1075 
  1076 lemma dropWhile_eq_Cons_conv:
  1077  "(dropWhile P xs = y#ys) = (xs = takeWhile P xs @ y # ys & \<not> P y)"
  1078 by(induct xs, auto)
  1079 
  1080 
  1081 subsection {* @{text zip} *}
  1082 
  1083 lemma zip_Nil [simp]: "zip [] ys = []"
  1084 by (induct ys) auto
  1085 
  1086 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
  1087 by simp
  1088 
  1089 declare zip_Cons [simp del]
  1090 
  1091 lemma length_zip [simp]:
  1092 "!!xs. length (zip xs ys) = min (length xs) (length ys)"
  1093 apply (induct ys, simp)
  1094 apply (case_tac xs, auto)
  1095 done
  1096 
  1097 lemma zip_append1:
  1098 "!!xs. zip (xs @ ys) zs =
  1099 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
  1100 apply (induct zs, simp)
  1101 apply (case_tac xs, simp_all)
  1102 done
  1103 
  1104 lemma zip_append2:
  1105 "!!ys. zip xs (ys @ zs) =
  1106 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
  1107 apply (induct xs, simp)
  1108 apply (case_tac ys, simp_all)
  1109 done
  1110 
  1111 lemma zip_append [simp]:
  1112  "[| length xs = length us; length ys = length vs |] ==>
  1113 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
  1114 by (simp add: zip_append1)
  1115 
  1116 lemma zip_rev:
  1117 "length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
  1118 by (induct rule:list_induct2, simp_all)
  1119 
  1120 lemma nth_zip [simp]:
  1121 "!!i xs. [| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
  1122 apply (induct ys, simp)
  1123 apply (case_tac xs)
  1124  apply (simp_all add: nth.simps split: nat.split)
  1125 done
  1126 
  1127 lemma set_zip:
  1128 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
  1129 by (simp add: set_conv_nth cong: rev_conj_cong)
  1130 
  1131 lemma zip_update:
  1132 "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
  1133 by (rule sym, simp add: update_zip)
  1134 
  1135 lemma zip_replicate [simp]:
  1136 "!!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
  1137 apply (induct i, auto)
  1138 apply (case_tac j, auto)
  1139 done
  1140 
  1141 
  1142 subsection {* @{text list_all2} *}
  1143 
  1144 lemma list_all2_lengthD [intro?]: 
  1145   "list_all2 P xs ys ==> length xs = length ys"
  1146 by (simp add: list_all2_def)
  1147 
  1148 lemma list_all2_Nil [iff]: "list_all2 P [] ys = (ys = [])"
  1149 by (simp add: list_all2_def)
  1150 
  1151 lemma list_all2_Nil2[iff]: "list_all2 P xs [] = (xs = [])"
  1152 by (simp add: list_all2_def)
  1153 
  1154 lemma list_all2_Cons [iff]:
  1155 "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
  1156 by (auto simp add: list_all2_def)
  1157 
  1158 lemma list_all2_Cons1:
  1159 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
  1160 by (cases ys) auto
  1161 
  1162 lemma list_all2_Cons2:
  1163 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
  1164 by (cases xs) auto
  1165 
  1166 lemma list_all2_rev [iff]:
  1167 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
  1168 by (simp add: list_all2_def zip_rev cong: conj_cong)
  1169 
  1170 lemma list_all2_rev1:
  1171 "list_all2 P (rev xs) ys = list_all2 P xs (rev ys)"
  1172 by (subst list_all2_rev [symmetric]) simp
  1173 
  1174 lemma list_all2_append1:
  1175 "list_all2 P (xs @ ys) zs =
  1176 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
  1177 list_all2 P xs us \<and> list_all2 P ys vs)"
  1178 apply (simp add: list_all2_def zip_append1)
  1179 apply (rule iffI)
  1180  apply (rule_tac x = "take (length xs) zs" in exI)
  1181  apply (rule_tac x = "drop (length xs) zs" in exI)
  1182  apply (force split: nat_diff_split simp add: min_def, clarify)
  1183 apply (simp add: ball_Un)
  1184 done
  1185 
  1186 lemma list_all2_append2:
  1187 "list_all2 P xs (ys @ zs) =
  1188 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  1189 list_all2 P us ys \<and> list_all2 P vs zs)"
  1190 apply (simp add: list_all2_def zip_append2)
  1191 apply (rule iffI)
  1192  apply (rule_tac x = "take (length ys) xs" in exI)
  1193  apply (rule_tac x = "drop (length ys) xs" in exI)
  1194  apply (force split: nat_diff_split simp add: min_def, clarify)
  1195 apply (simp add: ball_Un)
  1196 done
  1197 
  1198 lemma list_all2_append:
  1199   "length xs = length ys \<Longrightarrow>
  1200   list_all2 P (xs@us) (ys@vs) = (list_all2 P xs ys \<and> list_all2 P us vs)"
  1201 by (induct rule:list_induct2, simp_all)
  1202 
  1203 lemma list_all2_appendI [intro?, trans]:
  1204   "\<lbrakk> list_all2 P a b; list_all2 P c d \<rbrakk> \<Longrightarrow> list_all2 P (a@c) (b@d)"
  1205   by (simp add: list_all2_append list_all2_lengthD)
  1206 
  1207 lemma list_all2_conv_all_nth:
  1208 "list_all2 P xs ys =
  1209 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  1210 by (force simp add: list_all2_def set_zip)
  1211 
  1212 lemma list_all2_trans:
  1213   assumes tr: "!!a b c. P1 a b ==> P2 b c ==> P3 a c"
  1214   shows "!!bs cs. list_all2 P1 as bs ==> list_all2 P2 bs cs ==> list_all2 P3 as cs"
  1215         (is "!!bs cs. PROP ?Q as bs cs")
  1216 proof (induct as)
  1217   fix x xs bs assume I1: "!!bs cs. PROP ?Q xs bs cs"
  1218   show "!!cs. PROP ?Q (x # xs) bs cs"
  1219   proof (induct bs)
  1220     fix y ys cs assume I2: "!!cs. PROP ?Q (x # xs) ys cs"
  1221     show "PROP ?Q (x # xs) (y # ys) cs"
  1222       by (induct cs) (auto intro: tr I1 I2)
  1223   qed simp
  1224 qed simp
  1225 
  1226 lemma list_all2_all_nthI [intro?]:
  1227   "length a = length b \<Longrightarrow> (\<And>n. n < length a \<Longrightarrow> P (a!n) (b!n)) \<Longrightarrow> list_all2 P a b"
  1228   by (simp add: list_all2_conv_all_nth)
  1229 
  1230 lemma list_all2I:
  1231   "\<forall>x \<in> set (zip a b). split P x \<Longrightarrow> length a = length b \<Longrightarrow> list_all2 P a b"
  1232   by (simp add: list_all2_def)
  1233 
  1234 lemma list_all2_nthD:
  1235   "\<lbrakk> list_all2 P xs ys; p < size xs \<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  1236   by (simp add: list_all2_conv_all_nth)
  1237 
  1238 lemma list_all2_nthD2:
  1239   "\<lbrakk>list_all2 P xs ys; p < size ys\<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  1240   by (frule list_all2_lengthD) (auto intro: list_all2_nthD)
  1241 
  1242 lemma list_all2_map1: 
  1243   "list_all2 P (map f as) bs = list_all2 (\<lambda>x y. P (f x) y) as bs"
  1244   by (simp add: list_all2_conv_all_nth)
  1245 
  1246 lemma list_all2_map2: 
  1247   "list_all2 P as (map f bs) = list_all2 (\<lambda>x y. P x (f y)) as bs"
  1248   by (auto simp add: list_all2_conv_all_nth)
  1249 
  1250 lemma list_all2_refl [intro?]:
  1251   "(\<And>x. P x x) \<Longrightarrow> list_all2 P xs xs"
  1252   by (simp add: list_all2_conv_all_nth)
  1253 
  1254 lemma list_all2_update_cong:
  1255   "\<lbrakk> i<size xs; list_all2 P xs ys; P x y \<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1256   by (simp add: list_all2_conv_all_nth nth_list_update)
  1257 
  1258 lemma list_all2_update_cong2:
  1259   "\<lbrakk>list_all2 P xs ys; P x y; i < length ys\<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1260   by (simp add: list_all2_lengthD list_all2_update_cong)
  1261 
  1262 lemma list_all2_takeI [simp,intro?]:
  1263   "\<And>n ys. list_all2 P xs ys \<Longrightarrow> list_all2 P (take n xs) (take n ys)"
  1264   apply (induct xs)
  1265    apply simp
  1266   apply (clarsimp simp add: list_all2_Cons1)
  1267   apply (case_tac n)
  1268   apply auto
  1269   done
  1270 
  1271 lemma list_all2_dropI [simp,intro?]:
  1272   "\<And>n bs. list_all2 P as bs \<Longrightarrow> list_all2 P (drop n as) (drop n bs)"
  1273   apply (induct as, simp)
  1274   apply (clarsimp simp add: list_all2_Cons1)
  1275   apply (case_tac n, simp, simp)
  1276   done
  1277 
  1278 lemma list_all2_mono [intro?]:
  1279   "\<And>y. list_all2 P x y \<Longrightarrow> (\<And>x y. P x y \<Longrightarrow> Q x y) \<Longrightarrow> list_all2 Q x y"
  1280   apply (induct x, simp)
  1281   apply (case_tac y, auto)
  1282   done
  1283 
  1284 
  1285 subsection {* @{text foldl} and @{text foldr} *}
  1286 
  1287 lemma foldl_append [simp]:
  1288 "!!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  1289 by (induct xs) auto
  1290 
  1291 lemma foldr_append[simp]: "foldr f (xs @ ys) a = foldr f xs (foldr f ys a)"
  1292 by (induct xs) auto
  1293 
  1294 lemma foldr_foldl: "foldr f xs a = foldl (%x y. f y x) a (rev xs)"
  1295 by (induct xs) auto
  1296 
  1297 lemma foldl_foldr: "foldl f a xs = foldr (%x y. f y x) (rev xs) a"
  1298 by (simp add: foldr_foldl [of "%x y. f y x" "rev xs"])
  1299 
  1300 text {*
  1301 Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  1302 difficult to use because it requires an additional transitivity step.
  1303 *}
  1304 
  1305 lemma start_le_sum: "!!n::nat. m <= n ==> m <= foldl (op +) n ns"
  1306 by (induct ns) auto
  1307 
  1308 lemma elem_le_sum: "!!n::nat. n : set ns ==> n <= foldl (op +) 0 ns"
  1309 by (force intro: start_le_sum simp add: in_set_conv_decomp)
  1310 
  1311 lemma sum_eq_0_conv [iff]:
  1312 "!!m::nat. (foldl (op +) m ns = 0) = (m = 0 \<and> (\<forall>n \<in> set ns. n = 0))"
  1313 by (induct ns) auto
  1314 
  1315 
  1316 subsection {* @{text upto} *}
  1317 
  1318 lemma upt_rec: "[i..j(] = (if i<j then i#[Suc i..j(] else [])"
  1319 -- {* Does not terminate! *}
  1320 by (induct j) auto
  1321 
  1322 lemma upt_conv_Nil [simp]: "j <= i ==> [i..j(] = []"
  1323 by (subst upt_rec) simp
  1324 
  1325 lemma upt_Suc_append: "i <= j ==> [i..(Suc j)(] = [i..j(]@[j]"
  1326 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  1327 by simp
  1328 
  1329 lemma upt_conv_Cons: "i < j ==> [i..j(] = i # [Suc i..j(]"
  1330 apply(rule trans)
  1331 apply(subst upt_rec)
  1332  prefer 2 apply (rule refl, simp)
  1333 done
  1334 
  1335 lemma upt_add_eq_append: "i<=j ==> [i..j+k(] = [i..j(]@[j..j+k(]"
  1336 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  1337 by (induct k) auto
  1338 
  1339 lemma length_upt [simp]: "length [i..j(] = j - i"
  1340 by (induct j) (auto simp add: Suc_diff_le)
  1341 
  1342 lemma nth_upt [simp]: "i + k < j ==> [i..j(] ! k = i + k"
  1343 apply (induct j)
  1344 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  1345 done
  1346 
  1347 lemma take_upt [simp]: "!!i. i+m <= n ==> take m [i..n(] = [i..i+m(]"
  1348 apply (induct m, simp)
  1349 apply (subst upt_rec)
  1350 apply (rule sym)
  1351 apply (subst upt_rec)
  1352 apply (simp del: upt.simps)
  1353 done
  1354 
  1355 lemma map_Suc_upt: "map Suc [m..n(] = [Suc m..n]"
  1356 by (induct n) auto
  1357 
  1358 lemma nth_map_upt: "!!i. i < n-m ==> (map f [m..n(]) ! i = f(m+i)"
  1359 apply (induct n m rule: diff_induct)
  1360 prefer 3 apply (subst map_Suc_upt[symmetric])
  1361 apply (auto simp add: less_diff_conv nth_upt)
  1362 done
  1363 
  1364 lemma nth_take_lemma:
  1365   "!!xs ys. k <= length xs ==> k <= length ys ==>
  1366      (!!i. i < k --> xs!i = ys!i) ==> take k xs = take k ys"
  1367 apply (atomize, induct k)
  1368 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib, clarify)
  1369 txt {* Both lists must be non-empty *}
  1370 apply (case_tac xs, simp)
  1371 apply (case_tac ys, clarify)
  1372  apply (simp (no_asm_use))
  1373 apply clarify
  1374 txt {* prenexing's needed, not miniscoping *}
  1375 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  1376 apply blast
  1377 done
  1378 
  1379 lemma nth_equalityI:
  1380  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  1381 apply (frule nth_take_lemma [OF le_refl eq_imp_le])
  1382 apply (simp_all add: take_all)
  1383 done
  1384 
  1385 (* needs nth_equalityI *)
  1386 lemma list_all2_antisym:
  1387   "\<lbrakk> (\<And>x y. \<lbrakk>P x y; Q y x\<rbrakk> \<Longrightarrow> x = y); list_all2 P xs ys; list_all2 Q ys xs \<rbrakk> 
  1388   \<Longrightarrow> xs = ys"
  1389   apply (simp add: list_all2_conv_all_nth) 
  1390   apply (rule nth_equalityI, blast, simp)
  1391   done
  1392 
  1393 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  1394 -- {* The famous take-lemma. *}
  1395 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  1396 apply (simp add: le_max_iff_disj take_all)
  1397 done
  1398 
  1399 
  1400 subsection {* @{text "distinct"} and @{text remdups} *}
  1401 
  1402 lemma distinct_append [simp]:
  1403 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  1404 by (induct xs) auto
  1405 
  1406 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  1407 by (induct xs) (auto simp add: insert_absorb)
  1408 
  1409 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  1410 by (induct xs) auto
  1411 
  1412 lemma remdups_eq_nil_iff [simp]: "(remdups x = []) = (x = [])"
  1413   by (induct_tac x, auto) 
  1414 
  1415 lemma remdups_eq_nil_right_iff [simp]: "([] = remdups x) = (x = [])"
  1416   by (induct_tac x, auto)
  1417 
  1418 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  1419 by (induct xs) auto
  1420 
  1421 text {*
  1422 It is best to avoid this indexed version of distinct, but sometimes
  1423 it is useful. *}
  1424 lemma distinct_conv_nth:
  1425 "distinct xs = (\<forall>i j. i < size xs \<and> j < size xs \<and> i \<noteq> j --> xs!i \<noteq> xs!j)"
  1426 apply (induct_tac xs, simp, simp)
  1427 apply (rule iffI, clarsimp)
  1428  apply (case_tac i)
  1429 apply (case_tac j, simp)
  1430 apply (simp add: set_conv_nth)
  1431  apply (case_tac j)
  1432 apply (clarsimp simp add: set_conv_nth, simp)
  1433 apply (rule conjI)
  1434  apply (clarsimp simp add: set_conv_nth)
  1435  apply (erule_tac x = 0 in allE)
  1436  apply (erule_tac x = "Suc i" in allE, simp, clarsimp)
  1437 apply (erule_tac x = "Suc i" in allE)
  1438 apply (erule_tac x = "Suc j" in allE, simp)
  1439 done
  1440 
  1441 lemma distinct_card: "distinct xs ==> card (set xs) = size xs"
  1442   by (induct xs) auto
  1443 
  1444 lemma card_distinct: "card (set xs) = size xs ==> distinct xs"
  1445 proof (induct xs)
  1446   case Nil thus ?case by simp
  1447 next
  1448   case (Cons x xs)
  1449   show ?case
  1450   proof (cases "x \<in> set xs")
  1451     case False with Cons show ?thesis by simp
  1452   next
  1453     case True with Cons.prems
  1454     have "card (set xs) = Suc (length xs)" 
  1455       by (simp add: card_insert_if split: split_if_asm)
  1456     moreover have "card (set xs) \<le> length xs" by (rule card_length)
  1457     ultimately have False by simp
  1458     thus ?thesis ..
  1459   qed
  1460 qed
  1461 
  1462 lemma inj_on_setI: "distinct(map f xs) ==> inj_on f (set xs)"
  1463 apply(induct xs)
  1464  apply simp
  1465 apply fastsimp
  1466 done
  1467 
  1468 lemma inj_on_set_conv:
  1469  "distinct xs \<Longrightarrow> inj_on f (set xs) = distinct(map f xs)"
  1470 apply(induct xs)
  1471  apply simp
  1472 apply fastsimp
  1473 done
  1474 
  1475 
  1476 subsection {* @{text remove1} *}
  1477 
  1478 lemma set_remove1_subset: "set(remove1 x xs) <= set xs"
  1479 apply(induct xs)
  1480  apply simp
  1481 apply simp
  1482 apply blast
  1483 done
  1484 
  1485 lemma [simp]: "distinct xs ==> set(remove1 x xs) = set xs - {x}"
  1486 apply(induct xs)
  1487  apply simp
  1488 apply simp
  1489 apply blast
  1490 done
  1491 
  1492 lemma notin_set_remove1[simp]: "x ~: set xs ==> x ~: set(remove1 y xs)"
  1493 apply(insert set_remove1_subset)
  1494 apply fast
  1495 done
  1496 
  1497 lemma distinct_remove1[simp]: "distinct xs ==> distinct(remove1 x xs)"
  1498 by (induct xs) simp_all
  1499 
  1500 
  1501 subsection {* @{text replicate} *}
  1502 
  1503 lemma length_replicate [simp]: "length (replicate n x) = n"
  1504 by (induct n) auto
  1505 
  1506 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  1507 by (induct n) auto
  1508 
  1509 lemma replicate_app_Cons_same:
  1510 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  1511 by (induct n) auto
  1512 
  1513 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  1514 apply (induct n, simp)
  1515 apply (simp add: replicate_app_Cons_same)
  1516 done
  1517 
  1518 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  1519 by (induct n) auto
  1520 
  1521 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  1522 by (induct n) auto
  1523 
  1524 lemma tl_replicate [simp]: "n \<noteq> 0 ==> tl (replicate n x) = replicate (n - 1) x"
  1525 by (induct n) auto
  1526 
  1527 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  1528 by (atomize (full), induct n) auto
  1529 
  1530 lemma nth_replicate[simp]: "!!i. i < n ==> (replicate n x)!i = x"
  1531 apply (induct n, simp)
  1532 apply (simp add: nth_Cons split: nat.split)
  1533 done
  1534 
  1535 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  1536 by (induct n) auto
  1537 
  1538 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  1539 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  1540 
  1541 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  1542 by auto
  1543 
  1544 lemma in_set_replicateD: "x : set (replicate n y) ==> x = y"
  1545 by (simp add: set_replicate_conv_if split: split_if_asm)
  1546 
  1547 
  1548 subsection {* Lexicographic orderings on lists *}
  1549 
  1550 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  1551 apply (induct_tac n, simp, simp)
  1552 apply(rule wf_subset)
  1553  prefer 2 apply (rule Int_lower1)
  1554 apply(rule wf_prod_fun_image)
  1555  prefer 2 apply (rule inj_onI, auto)
  1556 done
  1557 
  1558 lemma lexn_length:
  1559 "!!xs ys. (xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  1560 by (induct n) auto
  1561 
  1562 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  1563 apply (unfold lex_def)
  1564 apply (rule wf_UN)
  1565 apply (blast intro: wf_lexn, clarify)
  1566 apply (rename_tac m n)
  1567 apply (subgoal_tac "m \<noteq> n")
  1568  prefer 2 apply blast
  1569 apply (blast dest: lexn_length not_sym)
  1570 done
  1571 
  1572 lemma lexn_conv:
  1573 "lexn r n =
  1574 {(xs,ys). length xs = n \<and> length ys = n \<and>
  1575 (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  1576 apply (induct_tac n, simp, blast)
  1577 apply (simp add: image_Collect lex_prod_def, safe, blast)
  1578  apply (rule_tac x = "ab # xys" in exI, simp)
  1579 apply (case_tac xys, simp_all, blast)
  1580 done
  1581 
  1582 lemma lex_conv:
  1583 "lex r =
  1584 {(xs,ys). length xs = length ys \<and>
  1585 (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  1586 by (force simp add: lex_def lexn_conv)
  1587 
  1588 lemma wf_lexico [intro!]: "wf r ==> wf (lexico r)"
  1589 by (unfold lexico_def) blast
  1590 
  1591 lemma lexico_conv:
  1592 "lexico r = {(xs,ys). length xs < length ys |
  1593 length xs = length ys \<and> (xs, ys) : lex r}"
  1594 by (simp add: lexico_def diag_def lex_prod_def measure_def inv_image_def)
  1595 
  1596 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  1597 by (simp add: lex_conv)
  1598 
  1599 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  1600 by (simp add:lex_conv)
  1601 
  1602 lemma Cons_in_lex [iff]:
  1603 "((x # xs, y # ys) : lex r) =
  1604 ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  1605 apply (simp add: lex_conv)
  1606 apply (rule iffI)
  1607  prefer 2 apply (blast intro: Cons_eq_appendI, clarify)
  1608 apply (case_tac xys, simp, simp)
  1609 apply blast
  1610 done
  1611 
  1612 
  1613 subsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  1614 
  1615 lemma sublist_empty [simp]: "sublist xs {} = []"
  1616 by (auto simp add: sublist_def)
  1617 
  1618 lemma sublist_nil [simp]: "sublist [] A = []"
  1619 by (auto simp add: sublist_def)
  1620 
  1621 lemma sublist_shift_lemma:
  1622 "map fst [p:zip xs [i..i + length xs(] . snd p : A] =
  1623 map fst [p:zip xs [0..length xs(] . snd p + i : A]"
  1624 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  1625 
  1626 lemma sublist_append:
  1627 "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  1628 apply (unfold sublist_def)
  1629 apply (induct l' rule: rev_induct, simp)
  1630 apply (simp add: upt_add_eq_append[of 0] zip_append sublist_shift_lemma)
  1631 apply (simp add: add_commute)
  1632 done
  1633 
  1634 lemma sublist_Cons:
  1635 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  1636 apply (induct l rule: rev_induct)
  1637  apply (simp add: sublist_def)
  1638 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  1639 done
  1640 
  1641 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  1642 by (simp add: sublist_Cons)
  1643 
  1644 lemma sublist_upt_eq_take [simp]: "sublist l {..<n} = take n l"
  1645 apply (induct l rule: rev_induct, simp)
  1646 apply (simp split: nat_diff_split add: sublist_append)
  1647 done
  1648 
  1649 
  1650 lemma take_Cons':
  1651 "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  1652 by (cases n) simp_all
  1653 
  1654 lemma drop_Cons':
  1655 "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  1656 by (cases n) simp_all
  1657 
  1658 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  1659 by (cases n) simp_all
  1660 
  1661 lemmas [simp] = take_Cons'[of "number_of v",standard]
  1662                 drop_Cons'[of "number_of v",standard]
  1663                 nth_Cons'[of _ _ "number_of v",standard]
  1664 
  1665 
  1666 lemma "card (set xs) = size xs \<Longrightarrow> distinct xs"
  1667 proof (induct xs)
  1668   case Nil thus ?case by simp
  1669 next
  1670   case (Cons x xs)
  1671   show ?case
  1672   proof (cases "x \<in> set xs")
  1673     case False with Cons show ?thesis by simp
  1674   next
  1675     case True with Cons.prems
  1676     have "card (set xs) = Suc (length xs)" 
  1677       by (simp add: card_insert_if split: split_if_asm)
  1678     moreover have "card (set xs) \<le> length xs" by (rule card_length)
  1679     ultimately have False by simp
  1680     thus ?thesis ..
  1681   qed
  1682 qed
  1683 
  1684 subsection {* Characters and strings *}
  1685 
  1686 datatype nibble =
  1687     Nibble0 | Nibble1 | Nibble2 | Nibble3 | Nibble4 | Nibble5 | Nibble6 | Nibble7
  1688   | Nibble8 | Nibble9 | NibbleA | NibbleB | NibbleC | NibbleD | NibbleE | NibbleF
  1689 
  1690 datatype char = Char nibble nibble
  1691   -- "Note: canonical order of character encoding coincides with standard term ordering"
  1692 
  1693 types string = "char list"
  1694 
  1695 syntax
  1696   "_Char" :: "xstr => char"    ("CHR _")
  1697   "_String" :: "xstr => string"    ("_")
  1698 
  1699 parse_ast_translation {*
  1700   let
  1701     val constants = Syntax.Appl o map Syntax.Constant;
  1702 
  1703     fun mk_nib n = "Nibble" ^ chr (n + (if n <= 9 then ord "0" else ord "A" - 10));
  1704     fun mk_char c =
  1705       if Symbol.is_ascii c andalso Symbol.is_printable c then
  1706         constants ["Char", mk_nib (ord c div 16), mk_nib (ord c mod 16)]
  1707       else error ("Printable ASCII character expected: " ^ quote c);
  1708 
  1709     fun mk_string [] = Syntax.Constant "Nil"
  1710       | mk_string (c :: cs) = Syntax.Appl [Syntax.Constant "Cons", mk_char c, mk_string cs];
  1711 
  1712     fun char_ast_tr [Syntax.Variable xstr] =
  1713         (case Syntax.explode_xstr xstr of
  1714           [c] => mk_char c
  1715         | _ => error ("Single character expected: " ^ xstr))
  1716       | char_ast_tr asts = raise AST ("char_ast_tr", asts);
  1717 
  1718     fun string_ast_tr [Syntax.Variable xstr] =
  1719         (case Syntax.explode_xstr xstr of
  1720           [] => constants [Syntax.constrainC, "Nil", "string"]
  1721         | cs => mk_string cs)
  1722       | string_ast_tr asts = raise AST ("string_tr", asts);
  1723   in [("_Char", char_ast_tr), ("_String", string_ast_tr)] end;
  1724 *}
  1725 
  1726 ML {*
  1727 fun int_of_nibble h =
  1728   if "0" <= h andalso h <= "9" then ord h - ord "0"
  1729   else if "A" <= h andalso h <= "F" then ord h - ord "A" + 10
  1730   else raise Match;
  1731 
  1732 fun nibble_of_int i =
  1733   if i <= 9 then chr (ord "0" + i) else chr (ord "A" + i - 10);
  1734 *}
  1735 
  1736 print_ast_translation {*
  1737   let
  1738     fun dest_nib (Syntax.Constant c) =
  1739         (case explode c of
  1740           ["N", "i", "b", "b", "l", "e", h] => int_of_nibble h
  1741         | _ => raise Match)
  1742       | dest_nib _ = raise Match;
  1743 
  1744     fun dest_chr c1 c2 =
  1745       let val c = chr (dest_nib c1 * 16 + dest_nib c2)
  1746       in if Symbol.is_printable c then c else raise Match end;
  1747 
  1748     fun dest_char (Syntax.Appl [Syntax.Constant "Char", c1, c2]) = dest_chr c1 c2
  1749       | dest_char _ = raise Match;
  1750 
  1751     fun xstr cs = Syntax.Appl [Syntax.Constant "_xstr", Syntax.Variable (Syntax.implode_xstr cs)];
  1752 
  1753     fun char_ast_tr' [c1, c2] = Syntax.Appl [Syntax.Constant "_Char", xstr [dest_chr c1 c2]]
  1754       | char_ast_tr' _ = raise Match;
  1755 
  1756     fun list_ast_tr' [args] = Syntax.Appl [Syntax.Constant "_String",
  1757             xstr (map dest_char (Syntax.unfold_ast "_args" args))]
  1758       | list_ast_tr' ts = raise Match;
  1759   in [("Char", char_ast_tr'), ("@list", list_ast_tr')] end;
  1760 *}
  1761 
  1762 subsection {* Code generator setup *}
  1763 
  1764 ML {*
  1765 local
  1766 
  1767 fun list_codegen thy gr dep b t =
  1768   let val (gr', ps) = foldl_map (Codegen.invoke_codegen thy dep false)
  1769     (gr, HOLogic.dest_list t)
  1770   in Some (gr', Pretty.list "[" "]" ps) end handle TERM _ => None;
  1771 
  1772 fun dest_nibble (Const (s, _)) = int_of_nibble (unprefix "List.nibble.Nibble" s)
  1773   | dest_nibble _ = raise Match;
  1774 
  1775 fun char_codegen thy gr dep b (Const ("List.char.Char", _) $ c1 $ c2) =
  1776     (let val c = chr (dest_nibble c1 * 16 + dest_nibble c2)
  1777      in if Symbol.is_printable c then Some (gr, Pretty.quote (Pretty.str c))
  1778        else None
  1779      end handle LIST _ => None | Match => None)
  1780   | char_codegen thy gr dep b _ = None;
  1781 
  1782 in
  1783 
  1784 val list_codegen_setup =
  1785   [Codegen.add_codegen "list_codegen" list_codegen,
  1786    Codegen.add_codegen "char_codegen" char_codegen];
  1787 
  1788 end;
  1789 
  1790 val term_of_list = HOLogic.mk_list;
  1791 
  1792 fun gen_list' aG i j = frequency
  1793   [(i, fn () => aG j :: gen_list' aG (i-1) j), (1, fn () => [])] ()
  1794 and gen_list aG i = gen_list' aG i i;
  1795 
  1796 val nibbleT = Type ("List.nibble", []);
  1797 
  1798 fun term_of_char c =
  1799   Const ("List.char.Char", nibbleT --> nibbleT --> Type ("List.char", [])) $
  1800     Const ("List.nibble.Nibble" ^ nibble_of_int (ord c div 16), nibbleT) $
  1801     Const ("List.nibble.Nibble" ^ nibble_of_int (ord c mod 16), nibbleT);
  1802 
  1803 fun gen_char i = chr (random_range (ord "a") (Int.min (ord "a" + i, ord "z")));
  1804 *}
  1805 
  1806 types_code
  1807   "list" ("_ list")
  1808   "char" ("string")
  1809 
  1810 consts_code "Cons" ("(_ ::/ _)")
  1811 
  1812 setup list_codegen_setup
  1813 
  1814 end