src/HOL/Ring_and_Field.thy
author nipkow
Mon Aug 16 14:22:27 2004 +0200 (2004-08-16)
changeset 15131 c69542757a4d
parent 15077 89840837108e
child 15140 322485b816ac
permissions -rw-r--r--
New theory header syntax.
     1 (*  Title:   HOL/Ring_and_Field.thy
     2     ID:      $Id$
     3     Author:  Gertrud Bauer, Steven Obua, Lawrence C Paulson and Markus Wenzel
     4 *)
     5 
     6 header {* (Ordered) Rings and Fields *}
     7 
     8 theory Ring_and_Field 
     9 import OrderedGroup
    10 begin
    11 
    12 text {*
    13   The theory of partially ordered rings is taken from the books:
    14   \begin{itemize}
    15   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
    16   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
    17   \end{itemize}
    18   Most of the used notions can also be looked up in 
    19   \begin{itemize}
    20   \item \url{http://www.mathworld.com} by Eric Weisstein et. al.
    21   \item \emph{Algebra I} by van der Waerden, Springer.
    22   \end{itemize}
    23 *}
    24 
    25 axclass semiring \<subseteq> ab_semigroup_add, semigroup_mult
    26   left_distrib: "(a + b) * c = a * c + b * c"
    27   right_distrib: "a * (b + c) = a * b + a * c"
    28 
    29 axclass semiring_0 \<subseteq> semiring, comm_monoid_add
    30 
    31 axclass semiring_0_cancel \<subseteq> semiring_0, cancel_ab_semigroup_add
    32 
    33 axclass comm_semiring \<subseteq> ab_semigroup_add, ab_semigroup_mult  
    34   mult_commute: "a * b = b * a"
    35   distrib: "(a + b) * c = a * c + b * c"
    36 
    37 instance comm_semiring \<subseteq> semiring
    38 proof
    39   fix a b c :: 'a
    40   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    41   have "a * (b + c) = (b + c) * a" by (simp add: mult_ac)
    42   also have "... = b * a + c * a" by (simp only: distrib)
    43   also have "... = a * b + a * c" by (simp add: mult_ac)
    44   finally show "a * (b + c) = a * b + a * c" by blast
    45 qed
    46 
    47 axclass comm_semiring_0 \<subseteq> comm_semiring, comm_monoid_add
    48 
    49 instance comm_semiring_0 \<subseteq> semiring_0 ..
    50 
    51 axclass comm_semiring_0_cancel \<subseteq> comm_semiring_0, cancel_ab_semigroup_add
    52 
    53 instance comm_semiring_0_cancel \<subseteq> semiring_0_cancel ..
    54 
    55 axclass axclass_0_neq_1 \<subseteq> zero, one
    56   zero_neq_one [simp]: "0 \<noteq> 1"
    57 
    58 axclass semiring_1 \<subseteq> axclass_0_neq_1, semiring_0, monoid_mult
    59 
    60 axclass comm_semiring_1 \<subseteq> axclass_0_neq_1, comm_semiring_0, comm_monoid_mult (* previously almost_semiring *)
    61 
    62 instance comm_semiring_1 \<subseteq> semiring_1 ..
    63 
    64 axclass axclass_no_zero_divisors \<subseteq> zero, times
    65   no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
    66 
    67 axclass semiring_1_cancel \<subseteq> semiring_1, cancel_ab_semigroup_add
    68 
    69 instance semiring_1_cancel \<subseteq> semiring_0_cancel ..
    70 
    71 axclass comm_semiring_1_cancel \<subseteq> comm_semiring_1, cancel_ab_semigroup_add (* previously semiring *)
    72 
    73 instance comm_semiring_1_cancel \<subseteq> semiring_1_cancel ..
    74 
    75 instance comm_semiring_1_cancel \<subseteq> comm_semiring_0_cancel ..
    76 
    77 axclass ring \<subseteq> semiring, ab_group_add
    78 
    79 instance ring \<subseteq> semiring_0_cancel ..
    80 
    81 axclass comm_ring \<subseteq> comm_semiring_0, ab_group_add
    82 
    83 instance comm_ring \<subseteq> ring ..
    84 
    85 instance comm_ring \<subseteq> comm_semiring_0_cancel ..
    86 
    87 axclass ring_1 \<subseteq> ring, semiring_1
    88 
    89 instance ring_1 \<subseteq> semiring_1_cancel ..
    90 
    91 axclass comm_ring_1 \<subseteq> comm_ring, comm_semiring_1 (* previously ring *)
    92 
    93 instance comm_ring_1 \<subseteq> ring_1 ..
    94 
    95 instance comm_ring_1 \<subseteq> comm_semiring_1_cancel ..
    96 
    97 axclass idom \<subseteq> comm_ring_1, axclass_no_zero_divisors
    98 
    99 axclass field \<subseteq> comm_ring_1, inverse
   100   left_inverse [simp]: "a \<noteq> 0 ==> inverse a * a = 1"
   101   divide_inverse:      "a / b = a * inverse b"
   102 
   103 lemma mult_zero_left [simp]: "0 * a = (0::'a::semiring_0_cancel)"
   104 proof -
   105   have "0*a + 0*a = 0*a + 0"
   106     by (simp add: left_distrib [symmetric])
   107   thus ?thesis 
   108     by (simp only: add_left_cancel)
   109 qed
   110 
   111 lemma mult_zero_right [simp]: "a * 0 = (0::'a::semiring_0_cancel)"
   112 proof -
   113   have "a*0 + a*0 = a*0 + 0"
   114     by (simp add: right_distrib [symmetric])
   115   thus ?thesis 
   116     by (simp only: add_left_cancel)
   117 qed
   118 
   119 lemma field_mult_eq_0_iff [simp]: "(a*b = (0::'a::field)) = (a = 0 | b = 0)"
   120 proof cases
   121   assume "a=0" thus ?thesis by simp
   122 next
   123   assume anz [simp]: "a\<noteq>0"
   124   { assume "a * b = 0"
   125     hence "inverse a * (a * b) = 0" by simp
   126     hence "b = 0"  by (simp (no_asm_use) add: mult_assoc [symmetric])}
   127   thus ?thesis by force
   128 qed
   129 
   130 instance field \<subseteq> idom
   131 by (intro_classes, simp)
   132   
   133 axclass division_by_zero \<subseteq> zero, inverse
   134   inverse_zero [simp]: "inverse 0 = 0"
   135 
   136 subsection {* Distribution rules *}
   137 
   138 theorems ring_distrib = right_distrib left_distrib
   139 
   140 text{*For the @{text combine_numerals} simproc*}
   141 lemma combine_common_factor:
   142      "a*e + (b*e + c) = (a+b)*e + (c::'a::semiring)"
   143 by (simp add: left_distrib add_ac)
   144 
   145 lemma minus_mult_left: "- (a * b) = (-a) * (b::'a::ring)"
   146 apply (rule equals_zero_I)
   147 apply (simp add: left_distrib [symmetric]) 
   148 done
   149 
   150 lemma minus_mult_right: "- (a * b) = a * -(b::'a::ring)"
   151 apply (rule equals_zero_I)
   152 apply (simp add: right_distrib [symmetric]) 
   153 done
   154 
   155 lemma minus_mult_minus [simp]: "(- a) * (- b) = a * (b::'a::ring)"
   156   by (simp add: minus_mult_left [symmetric] minus_mult_right [symmetric])
   157 
   158 lemma minus_mult_commute: "(- a) * b = a * (- b::'a::ring)"
   159   by (simp add: minus_mult_left [symmetric] minus_mult_right [symmetric])
   160 
   161 lemma right_diff_distrib: "a * (b - c) = a * b - a * (c::'a::ring)"
   162 by (simp add: right_distrib diff_minus 
   163               minus_mult_left [symmetric] minus_mult_right [symmetric]) 
   164 
   165 lemma left_diff_distrib: "(a - b) * c = a * c - b * (c::'a::ring)"
   166 by (simp add: left_distrib diff_minus 
   167               minus_mult_left [symmetric] minus_mult_right [symmetric]) 
   168 
   169 axclass pordered_semiring \<subseteq> semiring_0, pordered_ab_semigroup_add 
   170   mult_left_mono: "a <= b \<Longrightarrow> 0 <= c \<Longrightarrow> c * a <= c * b"
   171   mult_right_mono: "a <= b \<Longrightarrow> 0 <= c \<Longrightarrow> a * c <= b * c"
   172 
   173 axclass pordered_cancel_semiring \<subseteq> pordered_semiring, cancel_ab_semigroup_add
   174 
   175 instance pordered_cancel_semiring \<subseteq> semiring_0_cancel ..
   176 
   177 axclass ordered_semiring_strict \<subseteq> semiring_0, ordered_cancel_ab_semigroup_add
   178   mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   179   mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   180 
   181 instance ordered_semiring_strict \<subseteq> semiring_0_cancel ..
   182 
   183 instance ordered_semiring_strict \<subseteq> pordered_cancel_semiring
   184 apply intro_classes
   185 apply (case_tac "a < b & 0 < c")
   186 apply (auto simp add: mult_strict_left_mono order_less_le)
   187 apply (auto simp add: mult_strict_left_mono order_le_less)
   188 apply (simp add: mult_strict_right_mono)
   189 done
   190 
   191 axclass pordered_comm_semiring \<subseteq> comm_semiring_0, pordered_ab_semigroup_add
   192   mult_mono: "a <= b \<Longrightarrow> 0 <= c \<Longrightarrow> c * a <= c * b"
   193 
   194 axclass pordered_cancel_comm_semiring \<subseteq> pordered_comm_semiring, cancel_ab_semigroup_add
   195 
   196 instance pordered_cancel_comm_semiring \<subseteq> pordered_comm_semiring ..
   197 
   198 axclass ordered_comm_semiring_strict \<subseteq> comm_semiring_0, ordered_cancel_ab_semigroup_add
   199   mult_strict_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   200 
   201 instance pordered_comm_semiring \<subseteq> pordered_semiring
   202 by (intro_classes, insert mult_mono, simp_all add: mult_commute, blast+)
   203 
   204 instance pordered_cancel_comm_semiring \<subseteq> pordered_cancel_semiring ..
   205 
   206 instance ordered_comm_semiring_strict \<subseteq> ordered_semiring_strict
   207 by (intro_classes, insert mult_strict_mono, simp_all add: mult_commute, blast+)
   208 
   209 instance ordered_comm_semiring_strict \<subseteq> pordered_cancel_comm_semiring
   210 apply (intro_classes)
   211 apply (case_tac "a < b & 0 < c")
   212 apply (auto simp add: mult_strict_left_mono order_less_le)
   213 apply (auto simp add: mult_strict_left_mono order_le_less)
   214 done
   215 
   216 axclass pordered_ring \<subseteq> ring, pordered_semiring 
   217 
   218 instance pordered_ring \<subseteq> pordered_ab_group_add ..
   219 
   220 instance pordered_ring \<subseteq> pordered_cancel_semiring ..
   221 
   222 axclass lordered_ring \<subseteq> pordered_ring, lordered_ab_group_abs
   223 
   224 instance lordered_ring \<subseteq> lordered_ab_group_meet ..
   225 
   226 instance lordered_ring \<subseteq> lordered_ab_group_join ..
   227 
   228 axclass axclass_abs_if \<subseteq> minus, ord, zero
   229   abs_if: "abs a = (if (a < 0) then (-a) else a)"
   230 
   231 axclass ordered_ring_strict \<subseteq> ring, ordered_semiring_strict, axclass_abs_if
   232 
   233 instance ordered_ring_strict \<subseteq> lordered_ab_group ..
   234 
   235 instance ordered_ring_strict \<subseteq> lordered_ring
   236 by (intro_classes, simp add: abs_if join_eq_if)
   237 
   238 axclass pordered_comm_ring \<subseteq> comm_ring, pordered_comm_semiring
   239 
   240 axclass ordered_semidom \<subseteq> comm_semiring_1_cancel, ordered_comm_semiring_strict (* previously ordered_semiring *)
   241   zero_less_one [simp]: "0 < 1"
   242 
   243 axclass ordered_idom \<subseteq> comm_ring_1, ordered_comm_semiring_strict, axclass_abs_if (* previously ordered_ring *)
   244 
   245 instance ordered_idom \<subseteq> ordered_ring_strict ..
   246 
   247 axclass ordered_field \<subseteq> field, ordered_idom
   248 
   249 lemma eq_add_iff1:
   250      "(a*e + c = b*e + d) = ((a-b)*e + c = (d::'a::ring))"
   251 apply (simp add: diff_minus left_distrib)
   252 apply (simp add: diff_minus left_distrib add_ac)
   253 apply (simp add: compare_rls minus_mult_left [symmetric])
   254 done
   255 
   256 lemma eq_add_iff2:
   257      "(a*e + c = b*e + d) = (c = (b-a)*e + (d::'a::ring))"
   258 apply (simp add: diff_minus left_distrib add_ac)
   259 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   260 done
   261 
   262 lemma less_add_iff1:
   263      "(a*e + c < b*e + d) = ((a-b)*e + c < (d::'a::pordered_ring))"
   264 apply (simp add: diff_minus left_distrib add_ac)
   265 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   266 done
   267 
   268 lemma less_add_iff2:
   269      "(a*e + c < b*e + d) = (c < (b-a)*e + (d::'a::pordered_ring))"
   270 apply (simp add: diff_minus left_distrib add_ac)
   271 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   272 done
   273 
   274 lemma le_add_iff1:
   275      "(a*e + c \<le> b*e + d) = ((a-b)*e + c \<le> (d::'a::pordered_ring))"
   276 apply (simp add: diff_minus left_distrib add_ac)
   277 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   278 done
   279 
   280 lemma le_add_iff2:
   281      "(a*e + c \<le> b*e + d) = (c \<le> (b-a)*e + (d::'a::pordered_ring))"
   282 apply (simp add: diff_minus left_distrib add_ac)
   283 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   284 done
   285 
   286 subsection {* Ordering Rules for Multiplication *}
   287 
   288 lemma mult_left_le_imp_le:
   289      "[|c*a \<le> c*b; 0 < c|] ==> a \<le> (b::'a::ordered_semiring_strict)"
   290   by (force simp add: mult_strict_left_mono linorder_not_less [symmetric])
   291  
   292 lemma mult_right_le_imp_le:
   293      "[|a*c \<le> b*c; 0 < c|] ==> a \<le> (b::'a::ordered_semiring_strict)"
   294   by (force simp add: mult_strict_right_mono linorder_not_less [symmetric])
   295 
   296 lemma mult_left_less_imp_less:
   297      "[|c*a < c*b; 0 \<le> c|] ==> a < (b::'a::ordered_semiring_strict)"
   298   by (force simp add: mult_left_mono linorder_not_le [symmetric])
   299  
   300 lemma mult_right_less_imp_less:
   301      "[|a*c < b*c; 0 \<le> c|] ==> a < (b::'a::ordered_semiring_strict)"
   302   by (force simp add: mult_right_mono linorder_not_le [symmetric])
   303 
   304 lemma mult_strict_left_mono_neg:
   305      "[|b < a; c < 0|] ==> c * a < c * (b::'a::ordered_ring_strict)"
   306 apply (drule mult_strict_left_mono [of _ _ "-c"])
   307 apply (simp_all add: minus_mult_left [symmetric]) 
   308 done
   309 
   310 lemma mult_left_mono_neg:
   311      "[|b \<le> a; c \<le> 0|] ==> c * a \<le>  c * (b::'a::pordered_ring)"
   312 apply (drule mult_left_mono [of _ _ "-c"])
   313 apply (simp_all add: minus_mult_left [symmetric]) 
   314 done
   315 
   316 lemma mult_strict_right_mono_neg:
   317      "[|b < a; c < 0|] ==> a * c < b * (c::'a::ordered_ring_strict)"
   318 apply (drule mult_strict_right_mono [of _ _ "-c"])
   319 apply (simp_all add: minus_mult_right [symmetric]) 
   320 done
   321 
   322 lemma mult_right_mono_neg:
   323      "[|b \<le> a; c \<le> 0|] ==> a * c \<le>  (b::'a::pordered_ring) * c"
   324 apply (drule mult_right_mono [of _ _ "-c"])
   325 apply (simp)
   326 apply (simp_all add: minus_mult_right [symmetric]) 
   327 done
   328 
   329 subsection{* Products of Signs *}
   330 
   331 lemma mult_pos: "[| (0::'a::ordered_semiring_strict) < a; 0 < b |] ==> 0 < a*b"
   332 by (drule mult_strict_left_mono [of 0 b], auto)
   333 
   334 lemma mult_pos_le: "[| (0::'a::pordered_cancel_semiring) \<le> a; 0 \<le> b |] ==> 0 \<le> a*b"
   335 by (drule mult_left_mono [of 0 b], auto)
   336 
   337 lemma mult_pos_neg: "[| (0::'a::ordered_semiring_strict) < a; b < 0 |] ==> a*b < 0"
   338 by (drule mult_strict_left_mono [of b 0], auto)
   339 
   340 lemma mult_pos_neg_le: "[| (0::'a::pordered_cancel_semiring) \<le> a; b \<le> 0 |] ==> a*b \<le> 0"
   341 by (drule mult_left_mono [of b 0], auto)
   342 
   343 lemma mult_pos_neg2: "[| (0::'a::ordered_semiring_strict) < a; b < 0 |] ==> b*a < 0" 
   344 by (drule mult_strict_right_mono[of b 0], auto)
   345 
   346 lemma mult_pos_neg2_le: "[| (0::'a::pordered_cancel_semiring) \<le> a; b \<le> 0 |] ==> b*a \<le> 0" 
   347 by (drule mult_right_mono[of b 0], auto)
   348 
   349 lemma mult_neg: "[| a < (0::'a::ordered_ring_strict); b < 0 |] ==> 0 < a*b"
   350 by (drule mult_strict_right_mono_neg, auto)
   351 
   352 lemma mult_neg_le: "[| a \<le> (0::'a::pordered_ring); b \<le> 0 |] ==> 0 \<le> a*b"
   353 by (drule mult_right_mono_neg[of a 0 b ], auto)
   354 
   355 lemma zero_less_mult_pos:
   356      "[| 0 < a*b; 0 < a|] ==> 0 < (b::'a::ordered_semiring_strict)"
   357 apply (case_tac "b\<le>0") 
   358  apply (auto simp add: order_le_less linorder_not_less)
   359 apply (drule_tac mult_pos_neg [of a b]) 
   360  apply (auto dest: order_less_not_sym)
   361 done
   362 
   363 lemma zero_less_mult_pos2:
   364      "[| 0 < b*a; 0 < a|] ==> 0 < (b::'a::ordered_semiring_strict)"
   365 apply (case_tac "b\<le>0") 
   366  apply (auto simp add: order_le_less linorder_not_less)
   367 apply (drule_tac mult_pos_neg2 [of a b]) 
   368  apply (auto dest: order_less_not_sym)
   369 done
   370 
   371 lemma zero_less_mult_iff:
   372      "((0::'a::ordered_ring_strict) < a*b) = (0 < a & 0 < b | a < 0 & b < 0)"
   373 apply (auto simp add: order_le_less linorder_not_less mult_pos mult_neg)
   374 apply (blast dest: zero_less_mult_pos) 
   375 apply (blast dest: zero_less_mult_pos2)
   376 done
   377 
   378 text{*A field has no "zero divisors", and this theorem holds without the
   379       assumption of an ordering.  See @{text field_mult_eq_0_iff} below.*}
   380 lemma mult_eq_0_iff [simp]: "(a*b = (0::'a::ordered_ring_strict)) = (a = 0 | b = 0)"
   381 apply (case_tac "a < 0")
   382 apply (auto simp add: linorder_not_less order_le_less linorder_neq_iff)
   383 apply (force dest: mult_strict_right_mono_neg mult_strict_right_mono)+
   384 done
   385 
   386 lemma zero_le_mult_iff:
   387      "((0::'a::ordered_ring_strict) \<le> a*b) = (0 \<le> a & 0 \<le> b | a \<le> 0 & b \<le> 0)"
   388 by (auto simp add: eq_commute [of 0] order_le_less linorder_not_less
   389                    zero_less_mult_iff)
   390 
   391 lemma mult_less_0_iff:
   392      "(a*b < (0::'a::ordered_ring_strict)) = (0 < a & b < 0 | a < 0 & 0 < b)"
   393 apply (insert zero_less_mult_iff [of "-a" b]) 
   394 apply (force simp add: minus_mult_left[symmetric]) 
   395 done
   396 
   397 lemma mult_le_0_iff:
   398      "(a*b \<le> (0::'a::ordered_ring_strict)) = (0 \<le> a & b \<le> 0 | a \<le> 0 & 0 \<le> b)"
   399 apply (insert zero_le_mult_iff [of "-a" b]) 
   400 apply (force simp add: minus_mult_left[symmetric]) 
   401 done
   402 
   403 lemma split_mult_pos_le: "(0 \<le> a & 0 \<le> b) | (a \<le> 0 & b \<le> 0) \<Longrightarrow> 0 \<le> a * (b::_::pordered_ring)"
   404 by (auto simp add: mult_pos_le mult_neg_le)
   405 
   406 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> (0::_::pordered_cancel_semiring)" 
   407 by (auto simp add: mult_pos_neg_le mult_pos_neg2_le)
   408 
   409 lemma zero_le_square: "(0::'a::ordered_ring_strict) \<le> a*a"
   410 by (simp add: zero_le_mult_iff linorder_linear) 
   411 
   412 text{*Proving axiom @{text zero_less_one} makes all @{text ordered_semidom}
   413       theorems available to members of @{term ordered_idom} *}
   414 
   415 instance ordered_idom \<subseteq> ordered_semidom
   416 proof
   417   have "(0::'a) \<le> 1*1" by (rule zero_le_square)
   418   thus "(0::'a) < 1" by (simp add: order_le_less) 
   419 qed
   420 
   421 instance ordered_ring_strict \<subseteq> axclass_no_zero_divisors 
   422 by (intro_classes, simp)
   423 
   424 instance ordered_idom \<subseteq> idom ..
   425 
   426 text{*All three types of comparision involving 0 and 1 are covered.*}
   427 
   428 declare zero_neq_one [THEN not_sym, simp]
   429 
   430 lemma zero_le_one [simp]: "(0::'a::ordered_semidom) \<le> 1"
   431   by (rule zero_less_one [THEN order_less_imp_le]) 
   432 
   433 lemma not_one_le_zero [simp]: "~ (1::'a::ordered_semidom) \<le> 0"
   434 by (simp add: linorder_not_le) 
   435 
   436 lemma not_one_less_zero [simp]: "~ (1::'a::ordered_semidom) < 0"
   437 by (simp add: linorder_not_less) 
   438 
   439 subsection{*More Monotonicity*}
   440 
   441 text{*Strict monotonicity in both arguments*}
   442 lemma mult_strict_mono:
   443      "[|a<b; c<d; 0<b; 0\<le>c|] ==> a * c < b * (d::'a::ordered_semiring_strict)"
   444 apply (case_tac "c=0")
   445  apply (simp add: mult_pos) 
   446 apply (erule mult_strict_right_mono [THEN order_less_trans])
   447  apply (force simp add: order_le_less) 
   448 apply (erule mult_strict_left_mono, assumption)
   449 done
   450 
   451 text{*This weaker variant has more natural premises*}
   452 lemma mult_strict_mono':
   453      "[| a<b; c<d; 0 \<le> a; 0 \<le> c|] ==> a * c < b * (d::'a::ordered_semiring_strict)"
   454 apply (rule mult_strict_mono)
   455 apply (blast intro: order_le_less_trans)+
   456 done
   457 
   458 lemma mult_mono:
   459      "[|a \<le> b; c \<le> d; 0 \<le> b; 0 \<le> c|] 
   460       ==> a * c  \<le>  b * (d::'a::pordered_semiring)"
   461 apply (erule mult_right_mono [THEN order_trans], assumption)
   462 apply (erule mult_left_mono, assumption)
   463 done
   464 
   465 lemma less_1_mult: "[| 1 < m; 1 < n |] ==> 1 < m*(n::'a::ordered_semidom)"
   466 apply (insert mult_strict_mono [of 1 m 1 n]) 
   467 apply (simp add:  order_less_trans [OF zero_less_one]) 
   468 done
   469 
   470 subsection{*Cancellation Laws for Relationships With a Common Factor*}
   471 
   472 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
   473    also with the relations @{text "\<le>"} and equality.*}
   474 
   475 lemma mult_less_cancel_right:
   476     "(a*c < b*c) = ((0 < c & a < b) | (c < 0 & b < (a::'a::ordered_ring_strict)))"
   477 apply (case_tac "c = 0")
   478 apply (auto simp add: linorder_neq_iff mult_strict_right_mono 
   479                       mult_strict_right_mono_neg)
   480 apply (auto simp add: linorder_not_less 
   481                       linorder_not_le [symmetric, of "a*c"]
   482                       linorder_not_le [symmetric, of a])
   483 apply (erule_tac [!] notE)
   484 apply (auto simp add: order_less_imp_le mult_right_mono 
   485                       mult_right_mono_neg)
   486 done
   487 
   488 lemma mult_less_cancel_left:
   489     "(c*a < c*b) = ((0 < c & a < b) | (c < 0 & b < (a::'a::ordered_ring_strict)))"
   490 apply (case_tac "c = 0")
   491 apply (auto simp add: linorder_neq_iff mult_strict_left_mono 
   492                       mult_strict_left_mono_neg)
   493 apply (auto simp add: linorder_not_less 
   494                       linorder_not_le [symmetric, of "c*a"]
   495                       linorder_not_le [symmetric, of a])
   496 apply (erule_tac [!] notE)
   497 apply (auto simp add: order_less_imp_le mult_left_mono 
   498                       mult_left_mono_neg)
   499 done
   500 
   501 lemma mult_le_cancel_right:
   502      "(a*c \<le> b*c) = ((0<c --> a\<le>b) & (c<0 --> b \<le> (a::'a::ordered_ring_strict)))"
   503 by (simp add: linorder_not_less [symmetric] mult_less_cancel_right)
   504 
   505 lemma mult_le_cancel_left:
   506      "(c*a \<le> c*b) = ((0<c --> a\<le>b) & (c<0 --> b \<le> (a::'a::ordered_ring_strict)))"
   507 by (simp add: linorder_not_less [symmetric] mult_less_cancel_left)
   508 
   509 lemma mult_less_imp_less_left:
   510       assumes less: "c*a < c*b" and nonneg: "0 \<le> c"
   511       shows "a < (b::'a::ordered_semiring_strict)"
   512 proof (rule ccontr)
   513   assume "~ a < b"
   514   hence "b \<le> a" by (simp add: linorder_not_less)
   515   hence "c*b \<le> c*a" by (rule mult_left_mono)
   516   with this and less show False 
   517     by (simp add: linorder_not_less [symmetric])
   518 qed
   519 
   520 lemma mult_less_imp_less_right:
   521   assumes less: "a*c < b*c" and nonneg: "0 <= c"
   522   shows "a < (b::'a::ordered_semiring_strict)"
   523 proof (rule ccontr)
   524   assume "~ a < b"
   525   hence "b \<le> a" by (simp add: linorder_not_less)
   526   hence "b*c \<le> a*c" by (rule mult_right_mono)
   527   with this and less show False 
   528     by (simp add: linorder_not_less [symmetric])
   529 qed  
   530 
   531 text{*Cancellation of equalities with a common factor*}
   532 lemma mult_cancel_right [simp]:
   533      "(a*c = b*c) = (c = (0::'a::ordered_ring_strict) | a=b)"
   534 apply (cut_tac linorder_less_linear [of 0 c])
   535 apply (force dest: mult_strict_right_mono_neg mult_strict_right_mono
   536              simp add: linorder_neq_iff)
   537 done
   538 
   539 text{*These cancellation theorems require an ordering. Versions are proved
   540       below that work for fields without an ordering.*}
   541 lemma mult_cancel_left [simp]:
   542      "(c*a = c*b) = (c = (0::'a::ordered_ring_strict) | a=b)"
   543 apply (cut_tac linorder_less_linear [of 0 c])
   544 apply (force dest: mult_strict_left_mono_neg mult_strict_left_mono
   545              simp add: linorder_neq_iff)
   546 done
   547 
   548 text{*This list of rewrites decides ring equalities by ordered rewriting.*}
   549 lemmas ring_eq_simps =
   550   mult_ac
   551   left_distrib right_distrib left_diff_distrib right_diff_distrib
   552   add_ac
   553   add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   554   diff_eq_eq eq_diff_eq
   555     
   556 
   557 subsection {* Fields *}
   558 
   559 lemma right_inverse [simp]:
   560       assumes not0: "a \<noteq> 0" shows "a * inverse (a::'a::field) = 1"
   561 proof -
   562   have "a * inverse a = inverse a * a" by (simp add: mult_ac)
   563   also have "... = 1" using not0 by simp
   564   finally show ?thesis .
   565 qed
   566 
   567 lemma right_inverse_eq: "b \<noteq> 0 ==> (a / b = 1) = (a = (b::'a::field))"
   568 proof
   569   assume neq: "b \<noteq> 0"
   570   {
   571     hence "a = (a / b) * b" by (simp add: divide_inverse mult_ac)
   572     also assume "a / b = 1"
   573     finally show "a = b" by simp
   574   next
   575     assume "a = b"
   576     with neq show "a / b = 1" by (simp add: divide_inverse)
   577   }
   578 qed
   579 
   580 lemma nonzero_inverse_eq_divide: "a \<noteq> 0 ==> inverse (a::'a::field) = 1/a"
   581 by (simp add: divide_inverse)
   582 
   583 lemma divide_self [simp]: "a \<noteq> 0 ==> a / (a::'a::field) = 1"
   584   by (simp add: divide_inverse)
   585 
   586 lemma divide_zero [simp]: "a / 0 = (0::'a::{field,division_by_zero})"
   587 by (simp add: divide_inverse)
   588 
   589 lemma divide_zero_left [simp]: "0/a = (0::'a::field)"
   590 by (simp add: divide_inverse)
   591 
   592 lemma inverse_eq_divide: "inverse (a::'a::field) = 1/a"
   593 by (simp add: divide_inverse)
   594 
   595 lemma add_divide_distrib: "(a+b)/(c::'a::field) = a/c + b/c"
   596 by (simp add: divide_inverse left_distrib) 
   597 
   598 
   599 text{*Compared with @{text mult_eq_0_iff}, this version removes the requirement
   600       of an ordering.*}
   601 lemma field_mult_eq_0_iff [simp]: "(a*b = (0::'a::field)) = (a = 0 | b = 0)"
   602 proof cases
   603   assume "a=0" thus ?thesis by simp
   604 next
   605   assume anz [simp]: "a\<noteq>0"
   606   { assume "a * b = 0"
   607     hence "inverse a * (a * b) = 0" by simp
   608     hence "b = 0"  by (simp (no_asm_use) add: mult_assoc [symmetric])}
   609   thus ?thesis by force
   610 qed
   611 
   612 text{*Cancellation of equalities with a common factor*}
   613 lemma field_mult_cancel_right_lemma:
   614       assumes cnz: "c \<noteq> (0::'a::field)"
   615 	  and eq:  "a*c = b*c"
   616 	 shows "a=b"
   617 proof -
   618   have "(a * c) * inverse c = (b * c) * inverse c"
   619     by (simp add: eq)
   620   thus "a=b"
   621     by (simp add: mult_assoc cnz)
   622 qed
   623 
   624 lemma field_mult_cancel_right [simp]:
   625      "(a*c = b*c) = (c = (0::'a::field) | a=b)"
   626 proof cases
   627   assume "c=0" thus ?thesis by simp
   628 next
   629   assume "c\<noteq>0" 
   630   thus ?thesis by (force dest: field_mult_cancel_right_lemma)
   631 qed
   632 
   633 lemma field_mult_cancel_left [simp]:
   634      "(c*a = c*b) = (c = (0::'a::field) | a=b)"
   635   by (simp add: mult_commute [of c] field_mult_cancel_right) 
   636 
   637 lemma nonzero_imp_inverse_nonzero: "a \<noteq> 0 ==> inverse a \<noteq> (0::'a::field)"
   638 proof
   639   assume ianz: "inverse a = 0"
   640   assume "a \<noteq> 0"
   641   hence "1 = a * inverse a" by simp
   642   also have "... = 0" by (simp add: ianz)
   643   finally have "1 = (0::'a::field)" .
   644   thus False by (simp add: eq_commute)
   645 qed
   646 
   647 
   648 subsection{*Basic Properties of @{term inverse}*}
   649 
   650 lemma inverse_zero_imp_zero: "inverse a = 0 ==> a = (0::'a::field)"
   651 apply (rule ccontr) 
   652 apply (blast dest: nonzero_imp_inverse_nonzero) 
   653 done
   654 
   655 lemma inverse_nonzero_imp_nonzero:
   656    "inverse a = 0 ==> a = (0::'a::field)"
   657 apply (rule ccontr) 
   658 apply (blast dest: nonzero_imp_inverse_nonzero) 
   659 done
   660 
   661 lemma inverse_nonzero_iff_nonzero [simp]:
   662    "(inverse a = 0) = (a = (0::'a::{field,division_by_zero}))"
   663 by (force dest: inverse_nonzero_imp_nonzero) 
   664 
   665 lemma nonzero_inverse_minus_eq:
   666       assumes [simp]: "a\<noteq>0"  shows "inverse(-a) = -inverse(a::'a::field)"
   667 proof -
   668   have "-a * inverse (- a) = -a * - inverse a"
   669     by simp
   670   thus ?thesis 
   671     by (simp only: field_mult_cancel_left, simp)
   672 qed
   673 
   674 lemma inverse_minus_eq [simp]:
   675    "inverse(-a) = -inverse(a::'a::{field,division_by_zero})";
   676 proof cases
   677   assume "a=0" thus ?thesis by (simp add: inverse_zero)
   678 next
   679   assume "a\<noteq>0" 
   680   thus ?thesis by (simp add: nonzero_inverse_minus_eq)
   681 qed
   682 
   683 lemma nonzero_inverse_eq_imp_eq:
   684       assumes inveq: "inverse a = inverse b"
   685 	  and anz:  "a \<noteq> 0"
   686 	  and bnz:  "b \<noteq> 0"
   687 	 shows "a = (b::'a::field)"
   688 proof -
   689   have "a * inverse b = a * inverse a"
   690     by (simp add: inveq)
   691   hence "(a * inverse b) * b = (a * inverse a) * b"
   692     by simp
   693   thus "a = b"
   694     by (simp add: mult_assoc anz bnz)
   695 qed
   696 
   697 lemma inverse_eq_imp_eq:
   698      "inverse a = inverse b ==> a = (b::'a::{field,division_by_zero})"
   699 apply (case_tac "a=0 | b=0") 
   700  apply (force dest!: inverse_zero_imp_zero
   701               simp add: eq_commute [of "0::'a"])
   702 apply (force dest!: nonzero_inverse_eq_imp_eq) 
   703 done
   704 
   705 lemma inverse_eq_iff_eq [simp]:
   706      "(inverse a = inverse b) = (a = (b::'a::{field,division_by_zero}))"
   707 by (force dest!: inverse_eq_imp_eq) 
   708 
   709 lemma nonzero_inverse_inverse_eq:
   710       assumes [simp]: "a \<noteq> 0"  shows "inverse(inverse (a::'a::field)) = a"
   711   proof -
   712   have "(inverse (inverse a) * inverse a) * a = a" 
   713     by (simp add: nonzero_imp_inverse_nonzero)
   714   thus ?thesis
   715     by (simp add: mult_assoc)
   716   qed
   717 
   718 lemma inverse_inverse_eq [simp]:
   719      "inverse(inverse (a::'a::{field,division_by_zero})) = a"
   720   proof cases
   721     assume "a=0" thus ?thesis by simp
   722   next
   723     assume "a\<noteq>0" 
   724     thus ?thesis by (simp add: nonzero_inverse_inverse_eq)
   725   qed
   726 
   727 lemma inverse_1 [simp]: "inverse 1 = (1::'a::field)"
   728   proof -
   729   have "inverse 1 * 1 = (1::'a::field)" 
   730     by (rule left_inverse [OF zero_neq_one [symmetric]])
   731   thus ?thesis  by simp
   732   qed
   733 
   734 lemma inverse_unique: 
   735   assumes ab: "a*b = 1"
   736   shows "inverse a = (b::'a::field)"
   737 proof -
   738   have "a \<noteq> 0" using ab by auto
   739   moreover have "inverse a * (a * b) = inverse a" by (simp add: ab) 
   740   ultimately show ?thesis by (simp add: mult_assoc [symmetric]) 
   741 qed
   742 
   743 lemma nonzero_inverse_mult_distrib: 
   744       assumes anz: "a \<noteq> 0"
   745           and bnz: "b \<noteq> 0"
   746       shows "inverse(a*b) = inverse(b) * inverse(a::'a::field)"
   747   proof -
   748   have "inverse(a*b) * (a * b) * inverse(b) = inverse(b)" 
   749     by (simp add: field_mult_eq_0_iff anz bnz)
   750   hence "inverse(a*b) * a = inverse(b)" 
   751     by (simp add: mult_assoc bnz)
   752   hence "inverse(a*b) * a * inverse(a) = inverse(b) * inverse(a)" 
   753     by simp
   754   thus ?thesis
   755     by (simp add: mult_assoc anz)
   756   qed
   757 
   758 text{*This version builds in division by zero while also re-orienting
   759       the right-hand side.*}
   760 lemma inverse_mult_distrib [simp]:
   761      "inverse(a*b) = inverse(a) * inverse(b::'a::{field,division_by_zero})"
   762   proof cases
   763     assume "a \<noteq> 0 & b \<noteq> 0" 
   764     thus ?thesis  by (simp add: nonzero_inverse_mult_distrib mult_commute)
   765   next
   766     assume "~ (a \<noteq> 0 & b \<noteq> 0)" 
   767     thus ?thesis  by force
   768   qed
   769 
   770 text{*There is no slick version using division by zero.*}
   771 lemma inverse_add:
   772      "[|a \<noteq> 0;  b \<noteq> 0|]
   773       ==> inverse a + inverse b = (a+b) * inverse a * inverse (b::'a::field)"
   774 apply (simp add: left_distrib mult_assoc)
   775 apply (simp add: mult_commute [of "inverse a"]) 
   776 apply (simp add: mult_assoc [symmetric] add_commute)
   777 done
   778 
   779 lemma inverse_divide [simp]:
   780       "inverse (a/b) = b / (a::'a::{field,division_by_zero})"
   781   by (simp add: divide_inverse mult_commute)
   782 
   783 lemma nonzero_mult_divide_cancel_left:
   784   assumes [simp]: "b\<noteq>0" and [simp]: "c\<noteq>0" 
   785     shows "(c*a)/(c*b) = a/(b::'a::field)"
   786 proof -
   787   have "(c*a)/(c*b) = c * a * (inverse b * inverse c)"
   788     by (simp add: field_mult_eq_0_iff divide_inverse 
   789                   nonzero_inverse_mult_distrib)
   790   also have "... =  a * inverse b * (inverse c * c)"
   791     by (simp only: mult_ac)
   792   also have "... =  a * inverse b"
   793     by simp
   794     finally show ?thesis 
   795     by (simp add: divide_inverse)
   796 qed
   797 
   798 lemma mult_divide_cancel_left:
   799      "c\<noteq>0 ==> (c*a) / (c*b) = a / (b::'a::{field,division_by_zero})"
   800 apply (case_tac "b = 0")
   801 apply (simp_all add: nonzero_mult_divide_cancel_left)
   802 done
   803 
   804 lemma nonzero_mult_divide_cancel_right:
   805      "[|b\<noteq>0; c\<noteq>0|] ==> (a*c) / (b*c) = a/(b::'a::field)"
   806 by (simp add: mult_commute [of _ c] nonzero_mult_divide_cancel_left) 
   807 
   808 lemma mult_divide_cancel_right:
   809      "c\<noteq>0 ==> (a*c) / (b*c) = a / (b::'a::{field,division_by_zero})"
   810 apply (case_tac "b = 0")
   811 apply (simp_all add: nonzero_mult_divide_cancel_right)
   812 done
   813 
   814 (*For ExtractCommonTerm*)
   815 lemma mult_divide_cancel_eq_if:
   816      "(c*a) / (c*b) = 
   817       (if c=0 then 0 else a / (b::'a::{field,division_by_zero}))"
   818   by (simp add: mult_divide_cancel_left)
   819 
   820 lemma divide_1 [simp]: "a/1 = (a::'a::field)"
   821   by (simp add: divide_inverse)
   822 
   823 lemma times_divide_eq_right [simp]: "a * (b/c) = (a*b) / (c::'a::field)"
   824 by (simp add: divide_inverse mult_assoc)
   825 
   826 lemma times_divide_eq_left: "(b/c) * a = (b*a) / (c::'a::field)"
   827 by (simp add: divide_inverse mult_ac)
   828 
   829 lemma divide_divide_eq_right [simp]:
   830      "a / (b/c) = (a*c) / (b::'a::{field,division_by_zero})"
   831 by (simp add: divide_inverse mult_ac)
   832 
   833 lemma divide_divide_eq_left [simp]:
   834      "(a / b) / (c::'a::{field,division_by_zero}) = a / (b*c)"
   835 by (simp add: divide_inverse mult_assoc)
   836 
   837 
   838 subsection {* Division and Unary Minus *}
   839 
   840 lemma nonzero_minus_divide_left: "b \<noteq> 0 ==> - (a/b) = (-a) / (b::'a::field)"
   841 by (simp add: divide_inverse minus_mult_left)
   842 
   843 lemma nonzero_minus_divide_right: "b \<noteq> 0 ==> - (a/b) = a / -(b::'a::field)"
   844 by (simp add: divide_inverse nonzero_inverse_minus_eq minus_mult_right)
   845 
   846 lemma nonzero_minus_divide_divide: "b \<noteq> 0 ==> (-a)/(-b) = a / (b::'a::field)"
   847 by (simp add: divide_inverse nonzero_inverse_minus_eq)
   848 
   849 lemma minus_divide_left: "- (a/b) = (-a) / (b::'a::field)"
   850 by (simp add: divide_inverse minus_mult_left [symmetric])
   851 
   852 lemma minus_divide_right: "- (a/b) = a / -(b::'a::{field,division_by_zero})"
   853 by (simp add: divide_inverse minus_mult_right [symmetric])
   854 
   855 
   856 text{*The effect is to extract signs from divisions*}
   857 declare minus_divide_left  [symmetric, simp]
   858 declare minus_divide_right [symmetric, simp]
   859 
   860 text{*Also, extract signs from products*}
   861 declare minus_mult_left [symmetric, simp]
   862 declare minus_mult_right [symmetric, simp]
   863 
   864 lemma minus_divide_divide [simp]:
   865      "(-a)/(-b) = a / (b::'a::{field,division_by_zero})"
   866 apply (case_tac "b=0", simp) 
   867 apply (simp add: nonzero_minus_divide_divide) 
   868 done
   869 
   870 lemma diff_divide_distrib: "(a-b)/(c::'a::field) = a/c - b/c"
   871 by (simp add: diff_minus add_divide_distrib) 
   872 
   873 
   874 subsection {* Ordered Fields *}
   875 
   876 lemma positive_imp_inverse_positive: 
   877       assumes a_gt_0: "0 < a"  shows "0 < inverse (a::'a::ordered_field)"
   878   proof -
   879   have "0 < a * inverse a" 
   880     by (simp add: a_gt_0 [THEN order_less_imp_not_eq2] zero_less_one)
   881   thus "0 < inverse a" 
   882     by (simp add: a_gt_0 [THEN order_less_not_sym] zero_less_mult_iff)
   883   qed
   884 
   885 lemma negative_imp_inverse_negative:
   886      "a < 0 ==> inverse a < (0::'a::ordered_field)"
   887   by (insert positive_imp_inverse_positive [of "-a"], 
   888       simp add: nonzero_inverse_minus_eq order_less_imp_not_eq) 
   889 
   890 lemma inverse_le_imp_le:
   891       assumes invle: "inverse a \<le> inverse b"
   892 	  and apos:  "0 < a"
   893 	 shows "b \<le> (a::'a::ordered_field)"
   894   proof (rule classical)
   895   assume "~ b \<le> a"
   896   hence "a < b"
   897     by (simp add: linorder_not_le)
   898   hence bpos: "0 < b"
   899     by (blast intro: apos order_less_trans)
   900   hence "a * inverse a \<le> a * inverse b"
   901     by (simp add: apos invle order_less_imp_le mult_left_mono)
   902   hence "(a * inverse a) * b \<le> (a * inverse b) * b"
   903     by (simp add: bpos order_less_imp_le mult_right_mono)
   904   thus "b \<le> a"
   905     by (simp add: mult_assoc apos bpos order_less_imp_not_eq2)
   906   qed
   907 
   908 lemma inverse_positive_imp_positive:
   909       assumes inv_gt_0: "0 < inverse a"
   910           and [simp]:   "a \<noteq> 0"
   911         shows "0 < (a::'a::ordered_field)"
   912   proof -
   913   have "0 < inverse (inverse a)"
   914     by (rule positive_imp_inverse_positive)
   915   thus "0 < a"
   916     by (simp add: nonzero_inverse_inverse_eq)
   917   qed
   918 
   919 lemma inverse_positive_iff_positive [simp]:
   920       "(0 < inverse a) = (0 < (a::'a::{ordered_field,division_by_zero}))"
   921 apply (case_tac "a = 0", simp)
   922 apply (blast intro: inverse_positive_imp_positive positive_imp_inverse_positive)
   923 done
   924 
   925 lemma inverse_negative_imp_negative:
   926       assumes inv_less_0: "inverse a < 0"
   927           and [simp]:   "a \<noteq> 0"
   928         shows "a < (0::'a::ordered_field)"
   929   proof -
   930   have "inverse (inverse a) < 0"
   931     by (rule negative_imp_inverse_negative)
   932   thus "a < 0"
   933     by (simp add: nonzero_inverse_inverse_eq)
   934   qed
   935 
   936 lemma inverse_negative_iff_negative [simp]:
   937       "(inverse a < 0) = (a < (0::'a::{ordered_field,division_by_zero}))"
   938 apply (case_tac "a = 0", simp)
   939 apply (blast intro: inverse_negative_imp_negative negative_imp_inverse_negative)
   940 done
   941 
   942 lemma inverse_nonnegative_iff_nonnegative [simp]:
   943       "(0 \<le> inverse a) = (0 \<le> (a::'a::{ordered_field,division_by_zero}))"
   944 by (simp add: linorder_not_less [symmetric])
   945 
   946 lemma inverse_nonpositive_iff_nonpositive [simp]:
   947       "(inverse a \<le> 0) = (a \<le> (0::'a::{ordered_field,division_by_zero}))"
   948 by (simp add: linorder_not_less [symmetric])
   949 
   950 
   951 subsection{*Anti-Monotonicity of @{term inverse}*}
   952 
   953 lemma less_imp_inverse_less:
   954       assumes less: "a < b"
   955 	  and apos:  "0 < a"
   956 	shows "inverse b < inverse (a::'a::ordered_field)"
   957   proof (rule ccontr)
   958   assume "~ inverse b < inverse a"
   959   hence "inverse a \<le> inverse b"
   960     by (simp add: linorder_not_less)
   961   hence "~ (a < b)"
   962     by (simp add: linorder_not_less inverse_le_imp_le [OF _ apos])
   963   thus False
   964     by (rule notE [OF _ less])
   965   qed
   966 
   967 lemma inverse_less_imp_less:
   968    "[|inverse a < inverse b; 0 < a|] ==> b < (a::'a::ordered_field)"
   969 apply (simp add: order_less_le [of "inverse a"] order_less_le [of "b"])
   970 apply (force dest!: inverse_le_imp_le nonzero_inverse_eq_imp_eq) 
   971 done
   972 
   973 text{*Both premises are essential. Consider -1 and 1.*}
   974 lemma inverse_less_iff_less [simp]:
   975      "[|0 < a; 0 < b|] 
   976       ==> (inverse a < inverse b) = (b < (a::'a::ordered_field))"
   977 by (blast intro: less_imp_inverse_less dest: inverse_less_imp_less) 
   978 
   979 lemma le_imp_inverse_le:
   980    "[|a \<le> b; 0 < a|] ==> inverse b \<le> inverse (a::'a::ordered_field)"
   981   by (force simp add: order_le_less less_imp_inverse_less)
   982 
   983 lemma inverse_le_iff_le [simp]:
   984      "[|0 < a; 0 < b|] 
   985       ==> (inverse a \<le> inverse b) = (b \<le> (a::'a::ordered_field))"
   986 by (blast intro: le_imp_inverse_le dest: inverse_le_imp_le) 
   987 
   988 
   989 text{*These results refer to both operands being negative.  The opposite-sign
   990 case is trivial, since inverse preserves signs.*}
   991 lemma inverse_le_imp_le_neg:
   992    "[|inverse a \<le> inverse b; b < 0|] ==> b \<le> (a::'a::ordered_field)"
   993   apply (rule classical) 
   994   apply (subgoal_tac "a < 0") 
   995    prefer 2 apply (force simp add: linorder_not_le intro: order_less_trans) 
   996   apply (insert inverse_le_imp_le [of "-b" "-a"])
   997   apply (simp add: order_less_imp_not_eq nonzero_inverse_minus_eq) 
   998   done
   999 
  1000 lemma less_imp_inverse_less_neg:
  1001    "[|a < b; b < 0|] ==> inverse b < inverse (a::'a::ordered_field)"
  1002   apply (subgoal_tac "a < 0") 
  1003    prefer 2 apply (blast intro: order_less_trans) 
  1004   apply (insert less_imp_inverse_less [of "-b" "-a"])
  1005   apply (simp add: order_less_imp_not_eq nonzero_inverse_minus_eq) 
  1006   done
  1007 
  1008 lemma inverse_less_imp_less_neg:
  1009    "[|inverse a < inverse b; b < 0|] ==> b < (a::'a::ordered_field)"
  1010   apply (rule classical) 
  1011   apply (subgoal_tac "a < 0") 
  1012    prefer 2
  1013    apply (force simp add: linorder_not_less intro: order_le_less_trans) 
  1014   apply (insert inverse_less_imp_less [of "-b" "-a"])
  1015   apply (simp add: order_less_imp_not_eq nonzero_inverse_minus_eq) 
  1016   done
  1017 
  1018 lemma inverse_less_iff_less_neg [simp]:
  1019      "[|a < 0; b < 0|] 
  1020       ==> (inverse a < inverse b) = (b < (a::'a::ordered_field))"
  1021   apply (insert inverse_less_iff_less [of "-b" "-a"])
  1022   apply (simp del: inverse_less_iff_less 
  1023 	      add: order_less_imp_not_eq nonzero_inverse_minus_eq) 
  1024   done
  1025 
  1026 lemma le_imp_inverse_le_neg:
  1027    "[|a \<le> b; b < 0|] ==> inverse b \<le> inverse (a::'a::ordered_field)"
  1028   by (force simp add: order_le_less less_imp_inverse_less_neg)
  1029 
  1030 lemma inverse_le_iff_le_neg [simp]:
  1031      "[|a < 0; b < 0|] 
  1032       ==> (inverse a \<le> inverse b) = (b \<le> (a::'a::ordered_field))"
  1033 by (blast intro: le_imp_inverse_le_neg dest: inverse_le_imp_le_neg) 
  1034 
  1035 
  1036 subsection{*Inverses and the Number One*}
  1037 
  1038 lemma one_less_inverse_iff:
  1039     "(1 < inverse x) = (0 < x & x < (1::'a::{ordered_field,division_by_zero}))"proof cases
  1040   assume "0 < x"
  1041     with inverse_less_iff_less [OF zero_less_one, of x]
  1042     show ?thesis by simp
  1043 next
  1044   assume notless: "~ (0 < x)"
  1045   have "~ (1 < inverse x)"
  1046   proof
  1047     assume "1 < inverse x"
  1048     also with notless have "... \<le> 0" by (simp add: linorder_not_less)
  1049     also have "... < 1" by (rule zero_less_one) 
  1050     finally show False by auto
  1051   qed
  1052   with notless show ?thesis by simp
  1053 qed
  1054 
  1055 lemma inverse_eq_1_iff [simp]:
  1056     "(inverse x = 1) = (x = (1::'a::{field,division_by_zero}))"
  1057 by (insert inverse_eq_iff_eq [of x 1], simp) 
  1058 
  1059 lemma one_le_inverse_iff:
  1060    "(1 \<le> inverse x) = (0 < x & x \<le> (1::'a::{ordered_field,division_by_zero}))"
  1061 by (force simp add: order_le_less one_less_inverse_iff zero_less_one 
  1062                     eq_commute [of 1]) 
  1063 
  1064 lemma inverse_less_1_iff:
  1065    "(inverse x < 1) = (x \<le> 0 | 1 < (x::'a::{ordered_field,division_by_zero}))"
  1066 by (simp add: linorder_not_le [symmetric] one_le_inverse_iff) 
  1067 
  1068 lemma inverse_le_1_iff:
  1069    "(inverse x \<le> 1) = (x \<le> 0 | 1 \<le> (x::'a::{ordered_field,division_by_zero}))"
  1070 by (simp add: linorder_not_less [symmetric] one_less_inverse_iff) 
  1071 
  1072 
  1073 subsection{*Division and Signs*}
  1074 
  1075 lemma zero_less_divide_iff:
  1076      "((0::'a::{ordered_field,division_by_zero}) < a/b) = (0 < a & 0 < b | a < 0 & b < 0)"
  1077 by (simp add: divide_inverse zero_less_mult_iff)
  1078 
  1079 lemma divide_less_0_iff:
  1080      "(a/b < (0::'a::{ordered_field,division_by_zero})) = 
  1081       (0 < a & b < 0 | a < 0 & 0 < b)"
  1082 by (simp add: divide_inverse mult_less_0_iff)
  1083 
  1084 lemma zero_le_divide_iff:
  1085      "((0::'a::{ordered_field,division_by_zero}) \<le> a/b) =
  1086       (0 \<le> a & 0 \<le> b | a \<le> 0 & b \<le> 0)"
  1087 by (simp add: divide_inverse zero_le_mult_iff)
  1088 
  1089 lemma divide_le_0_iff:
  1090      "(a/b \<le> (0::'a::{ordered_field,division_by_zero})) =
  1091       (0 \<le> a & b \<le> 0 | a \<le> 0 & 0 \<le> b)"
  1092 by (simp add: divide_inverse mult_le_0_iff)
  1093 
  1094 lemma divide_eq_0_iff [simp]:
  1095      "(a/b = 0) = (a=0 | b=(0::'a::{field,division_by_zero}))"
  1096 by (simp add: divide_inverse field_mult_eq_0_iff)
  1097 
  1098 
  1099 subsection{*Simplification of Inequalities Involving Literal Divisors*}
  1100 
  1101 lemma pos_le_divide_eq: "0 < (c::'a::ordered_field) ==> (a \<le> b/c) = (a*c \<le> b)"
  1102 proof -
  1103   assume less: "0<c"
  1104   hence "(a \<le> b/c) = (a*c \<le> (b/c)*c)"
  1105     by (simp add: mult_le_cancel_right order_less_not_sym [OF less])
  1106   also have "... = (a*c \<le> b)"
  1107     by (simp add: order_less_imp_not_eq2 [OF less] divide_inverse mult_assoc) 
  1108   finally show ?thesis .
  1109 qed
  1110 
  1111 
  1112 lemma neg_le_divide_eq: "c < (0::'a::ordered_field) ==> (a \<le> b/c) = (b \<le> a*c)"
  1113 proof -
  1114   assume less: "c<0"
  1115   hence "(a \<le> b/c) = ((b/c)*c \<le> a*c)"
  1116     by (simp add: mult_le_cancel_right order_less_not_sym [OF less])
  1117   also have "... = (b \<le> a*c)"
  1118     by (simp add: order_less_imp_not_eq [OF less] divide_inverse mult_assoc) 
  1119   finally show ?thesis .
  1120 qed
  1121 
  1122 lemma le_divide_eq:
  1123   "(a \<le> b/c) = 
  1124    (if 0 < c then a*c \<le> b
  1125              else if c < 0 then b \<le> a*c
  1126              else  a \<le> (0::'a::{ordered_field,division_by_zero}))"
  1127 apply (case_tac "c=0", simp) 
  1128 apply (force simp add: pos_le_divide_eq neg_le_divide_eq linorder_neq_iff) 
  1129 done
  1130 
  1131 lemma pos_divide_le_eq: "0 < (c::'a::ordered_field) ==> (b/c \<le> a) = (b \<le> a*c)"
  1132 proof -
  1133   assume less: "0<c"
  1134   hence "(b/c \<le> a) = ((b/c)*c \<le> a*c)"
  1135     by (simp add: mult_le_cancel_right order_less_not_sym [OF less])
  1136   also have "... = (b \<le> a*c)"
  1137     by (simp add: order_less_imp_not_eq2 [OF less] divide_inverse mult_assoc) 
  1138   finally show ?thesis .
  1139 qed
  1140 
  1141 lemma neg_divide_le_eq: "c < (0::'a::ordered_field) ==> (b/c \<le> a) = (a*c \<le> b)"
  1142 proof -
  1143   assume less: "c<0"
  1144   hence "(b/c \<le> a) = (a*c \<le> (b/c)*c)"
  1145     by (simp add: mult_le_cancel_right order_less_not_sym [OF less])
  1146   also have "... = (a*c \<le> b)"
  1147     by (simp add: order_less_imp_not_eq [OF less] divide_inverse mult_assoc) 
  1148   finally show ?thesis .
  1149 qed
  1150 
  1151 lemma divide_le_eq:
  1152   "(b/c \<le> a) = 
  1153    (if 0 < c then b \<le> a*c
  1154              else if c < 0 then a*c \<le> b
  1155              else 0 \<le> (a::'a::{ordered_field,division_by_zero}))"
  1156 apply (case_tac "c=0", simp) 
  1157 apply (force simp add: pos_divide_le_eq neg_divide_le_eq linorder_neq_iff) 
  1158 done
  1159 
  1160 
  1161 lemma pos_less_divide_eq:
  1162      "0 < (c::'a::ordered_field) ==> (a < b/c) = (a*c < b)"
  1163 proof -
  1164   assume less: "0<c"
  1165   hence "(a < b/c) = (a*c < (b/c)*c)"
  1166     by (simp add: mult_less_cancel_right order_less_not_sym [OF less])
  1167   also have "... = (a*c < b)"
  1168     by (simp add: order_less_imp_not_eq2 [OF less] divide_inverse mult_assoc) 
  1169   finally show ?thesis .
  1170 qed
  1171 
  1172 lemma neg_less_divide_eq:
  1173  "c < (0::'a::ordered_field) ==> (a < b/c) = (b < a*c)"
  1174 proof -
  1175   assume less: "c<0"
  1176   hence "(a < b/c) = ((b/c)*c < a*c)"
  1177     by (simp add: mult_less_cancel_right order_less_not_sym [OF less])
  1178   also have "... = (b < a*c)"
  1179     by (simp add: order_less_imp_not_eq [OF less] divide_inverse mult_assoc) 
  1180   finally show ?thesis .
  1181 qed
  1182 
  1183 lemma less_divide_eq:
  1184   "(a < b/c) = 
  1185    (if 0 < c then a*c < b
  1186              else if c < 0 then b < a*c
  1187              else  a < (0::'a::{ordered_field,division_by_zero}))"
  1188 apply (case_tac "c=0", simp) 
  1189 apply (force simp add: pos_less_divide_eq neg_less_divide_eq linorder_neq_iff) 
  1190 done
  1191 
  1192 lemma pos_divide_less_eq:
  1193      "0 < (c::'a::ordered_field) ==> (b/c < a) = (b < a*c)"
  1194 proof -
  1195   assume less: "0<c"
  1196   hence "(b/c < a) = ((b/c)*c < a*c)"
  1197     by (simp add: mult_less_cancel_right order_less_not_sym [OF less])
  1198   also have "... = (b < a*c)"
  1199     by (simp add: order_less_imp_not_eq2 [OF less] divide_inverse mult_assoc) 
  1200   finally show ?thesis .
  1201 qed
  1202 
  1203 lemma neg_divide_less_eq:
  1204  "c < (0::'a::ordered_field) ==> (b/c < a) = (a*c < b)"
  1205 proof -
  1206   assume less: "c<0"
  1207   hence "(b/c < a) = (a*c < (b/c)*c)"
  1208     by (simp add: mult_less_cancel_right order_less_not_sym [OF less])
  1209   also have "... = (a*c < b)"
  1210     by (simp add: order_less_imp_not_eq [OF less] divide_inverse mult_assoc) 
  1211   finally show ?thesis .
  1212 qed
  1213 
  1214 lemma divide_less_eq:
  1215   "(b/c < a) = 
  1216    (if 0 < c then b < a*c
  1217              else if c < 0 then a*c < b
  1218              else 0 < (a::'a::{ordered_field,division_by_zero}))"
  1219 apply (case_tac "c=0", simp) 
  1220 apply (force simp add: pos_divide_less_eq neg_divide_less_eq linorder_neq_iff) 
  1221 done
  1222 
  1223 lemma nonzero_eq_divide_eq: "c\<noteq>0 ==> ((a::'a::field) = b/c) = (a*c = b)"
  1224 proof -
  1225   assume [simp]: "c\<noteq>0"
  1226   have "(a = b/c) = (a*c = (b/c)*c)"
  1227     by (simp add: field_mult_cancel_right)
  1228   also have "... = (a*c = b)"
  1229     by (simp add: divide_inverse mult_assoc) 
  1230   finally show ?thesis .
  1231 qed
  1232 
  1233 lemma eq_divide_eq:
  1234   "((a::'a::{field,division_by_zero}) = b/c) = (if c\<noteq>0 then a*c = b else a=0)"
  1235 by (simp add: nonzero_eq_divide_eq) 
  1236 
  1237 lemma nonzero_divide_eq_eq: "c\<noteq>0 ==> (b/c = (a::'a::field)) = (b = a*c)"
  1238 proof -
  1239   assume [simp]: "c\<noteq>0"
  1240   have "(b/c = a) = ((b/c)*c = a*c)"
  1241     by (simp add: field_mult_cancel_right)
  1242   also have "... = (b = a*c)"
  1243     by (simp add: divide_inverse mult_assoc) 
  1244   finally show ?thesis .
  1245 qed
  1246 
  1247 lemma divide_eq_eq:
  1248   "(b/c = (a::'a::{field,division_by_zero})) = (if c\<noteq>0 then b = a*c else a=0)"
  1249 by (force simp add: nonzero_divide_eq_eq) 
  1250 
  1251 subsection{*Cancellation Laws for Division*}
  1252 
  1253 lemma divide_cancel_right [simp]:
  1254      "(a/c = b/c) = (c = 0 | a = (b::'a::{field,division_by_zero}))"
  1255 apply (case_tac "c=0", simp) 
  1256 apply (simp add: divide_inverse field_mult_cancel_right) 
  1257 done
  1258 
  1259 lemma divide_cancel_left [simp]:
  1260      "(c/a = c/b) = (c = 0 | a = (b::'a::{field,division_by_zero}))" 
  1261 apply (case_tac "c=0", simp) 
  1262 apply (simp add: divide_inverse field_mult_cancel_left) 
  1263 done
  1264 
  1265 subsection {* Division and the Number One *}
  1266 
  1267 text{*Simplify expressions equated with 1*}
  1268 lemma divide_eq_1_iff [simp]:
  1269      "(a/b = 1) = (b \<noteq> 0 & a = (b::'a::{field,division_by_zero}))"
  1270 apply (case_tac "b=0", simp) 
  1271 apply (simp add: right_inverse_eq) 
  1272 done
  1273 
  1274 
  1275 lemma one_eq_divide_iff [simp]:
  1276      "(1 = a/b) = (b \<noteq> 0 & a = (b::'a::{field,division_by_zero}))"
  1277 by (simp add: eq_commute [of 1])  
  1278 
  1279 lemma zero_eq_1_divide_iff [simp]:
  1280      "((0::'a::{ordered_field,division_by_zero}) = 1/a) = (a = 0)"
  1281 apply (case_tac "a=0", simp) 
  1282 apply (auto simp add: nonzero_eq_divide_eq) 
  1283 done
  1284 
  1285 lemma one_divide_eq_0_iff [simp]:
  1286      "(1/a = (0::'a::{ordered_field,division_by_zero})) = (a = 0)"
  1287 apply (case_tac "a=0", simp) 
  1288 apply (insert zero_neq_one [THEN not_sym]) 
  1289 apply (auto simp add: nonzero_divide_eq_eq) 
  1290 done
  1291 
  1292 text{*Simplify expressions such as @{text "0 < 1/x"} to @{text "0 < x"}*}
  1293 declare zero_less_divide_iff [of "1", simp]
  1294 declare divide_less_0_iff [of "1", simp]
  1295 declare zero_le_divide_iff [of "1", simp]
  1296 declare divide_le_0_iff [of "1", simp]
  1297 
  1298 
  1299 subsection {* Ordering Rules for Division *}
  1300 
  1301 lemma divide_strict_right_mono:
  1302      "[|a < b; 0 < c|] ==> a / c < b / (c::'a::ordered_field)"
  1303 by (simp add: order_less_imp_not_eq2 divide_inverse mult_strict_right_mono 
  1304               positive_imp_inverse_positive) 
  1305 
  1306 lemma divide_right_mono:
  1307      "[|a \<le> b; 0 \<le> c|] ==> a/c \<le> b/(c::'a::{ordered_field,division_by_zero})"
  1308   by (force simp add: divide_strict_right_mono order_le_less) 
  1309 
  1310 
  1311 text{*The last premise ensures that @{term a} and @{term b} 
  1312       have the same sign*}
  1313 lemma divide_strict_left_mono:
  1314        "[|b < a; 0 < c; 0 < a*b|] ==> c / a < c / (b::'a::ordered_field)"
  1315 by (force simp add: zero_less_mult_iff divide_inverse mult_strict_left_mono 
  1316       order_less_imp_not_eq order_less_imp_not_eq2  
  1317       less_imp_inverse_less less_imp_inverse_less_neg) 
  1318 
  1319 lemma divide_left_mono:
  1320      "[|b \<le> a; 0 \<le> c; 0 < a*b|] ==> c / a \<le> c / (b::'a::ordered_field)"
  1321   apply (subgoal_tac "a \<noteq> 0 & b \<noteq> 0") 
  1322    prefer 2 
  1323    apply (force simp add: zero_less_mult_iff order_less_imp_not_eq) 
  1324   apply (case_tac "c=0", simp add: divide_inverse)
  1325   apply (force simp add: divide_strict_left_mono order_le_less) 
  1326   done
  1327 
  1328 lemma divide_strict_left_mono_neg:
  1329      "[|a < b; c < 0; 0 < a*b|] ==> c / a < c / (b::'a::ordered_field)"
  1330   apply (subgoal_tac "a \<noteq> 0 & b \<noteq> 0") 
  1331    prefer 2 
  1332    apply (force simp add: zero_less_mult_iff order_less_imp_not_eq) 
  1333   apply (drule divide_strict_left_mono [of _ _ "-c"]) 
  1334    apply (simp_all add: mult_commute nonzero_minus_divide_left [symmetric]) 
  1335   done
  1336 
  1337 lemma divide_strict_right_mono_neg:
  1338      "[|b < a; c < 0|] ==> a / c < b / (c::'a::ordered_field)"
  1339 apply (drule divide_strict_right_mono [of _ _ "-c"], simp) 
  1340 apply (simp add: order_less_imp_not_eq nonzero_minus_divide_right [symmetric]) 
  1341 done
  1342 
  1343 
  1344 subsection {* Ordered Fields are Dense *}
  1345 
  1346 lemma less_add_one: "a < (a+1::'a::ordered_semidom)"
  1347 proof -
  1348   have "a+0 < (a+1::'a::ordered_semidom)"
  1349     by (blast intro: zero_less_one add_strict_left_mono) 
  1350   thus ?thesis by simp
  1351 qed
  1352 
  1353 lemma zero_less_two: "0 < (1+1::'a::ordered_semidom)"
  1354   by (blast intro: order_less_trans zero_less_one less_add_one) 
  1355 
  1356 lemma less_half_sum: "a < b ==> a < (a+b) / (1+1::'a::ordered_field)"
  1357 by (simp add: zero_less_two pos_less_divide_eq right_distrib) 
  1358 
  1359 lemma gt_half_sum: "a < b ==> (a+b)/(1+1::'a::ordered_field) < b"
  1360 by (simp add: zero_less_two pos_divide_less_eq right_distrib) 
  1361 
  1362 lemma dense: "a < b ==> \<exists>r::'a::ordered_field. a < r & r < b"
  1363 by (blast intro!: less_half_sum gt_half_sum)
  1364 
  1365 subsection {* Absolute Value *}
  1366 
  1367 lemma abs_one [simp]: "abs 1 = (1::'a::ordered_idom)"
  1368   by (simp add: abs_if zero_less_one [THEN order_less_not_sym]) 
  1369 
  1370 lemma abs_le_mult: "abs (a * b) \<le> (abs a) * (abs (b::'a::lordered_ring))" 
  1371 proof -
  1372   let ?x = "pprt a * pprt b - pprt a * nprt b - nprt a * pprt b + nprt a * nprt b"
  1373   let ?y = "pprt a * pprt b + pprt a * nprt b + nprt a * pprt b + nprt a * nprt b"
  1374   have a: "(abs a) * (abs b) = ?x"
  1375     by (simp only: abs_prts[of a] abs_prts[of b] ring_eq_simps)
  1376   {
  1377     fix u v :: 'a
  1378     have bh: "\<lbrakk>u = a; v = b\<rbrakk> \<Longrightarrow> u * v = ?y"
  1379       apply (subst prts[of u], subst prts[of v])
  1380       apply (simp add: left_distrib right_distrib add_ac) 
  1381       done
  1382   }
  1383   note b = this[OF refl[of a] refl[of b]]
  1384   note addm = add_mono[of "0::'a" _ "0::'a", simplified]
  1385   note addm2 = add_mono[of _ "0::'a" _ "0::'a", simplified]
  1386   have xy: "- ?x <= ?y"
  1387     apply (simp)
  1388     apply (rule_tac y="0::'a" in order_trans)
  1389     apply (rule addm2)+
  1390     apply (simp_all add: mult_pos_le mult_neg_le)
  1391     apply (rule addm)+
  1392     apply (simp_all add: mult_pos_le mult_neg_le)
  1393     done
  1394   have yx: "?y <= ?x"
  1395     apply (simp add: add_ac)
  1396     apply (rule_tac y=0 in order_trans)
  1397     apply (rule addm2, (simp add: mult_pos_neg_le mult_pos_neg2_le)+)
  1398     apply (rule addm, (simp add: mult_pos_neg_le mult_pos_neg2_le)+)
  1399     done
  1400   have i1: "a*b <= abs a * abs b" by (simp only: a b yx)
  1401   have i2: "- (abs a * abs b) <= a*b" by (simp only: a b xy)
  1402   show ?thesis
  1403     apply (rule abs_leI)
  1404     apply (simp add: i1)
  1405     apply (simp add: i2[simplified minus_le_iff])
  1406     done
  1407 qed
  1408 
  1409 lemma abs_eq_mult: 
  1410   assumes "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0)"
  1411   shows "abs (a*b) = abs a * abs (b::'a::lordered_ring)"
  1412 proof -
  1413   have s: "(0 <= a*b) | (a*b <= 0)"
  1414     apply (auto)    
  1415     apply (rule_tac split_mult_pos_le)
  1416     apply (rule_tac contrapos_np[of "a*b <= 0"])
  1417     apply (simp)
  1418     apply (rule_tac split_mult_neg_le)
  1419     apply (insert prems)
  1420     apply (blast)
  1421     done
  1422   have mulprts: "a * b = (pprt a + nprt a) * (pprt b + nprt b)"
  1423     by (simp add: prts[symmetric])
  1424   show ?thesis
  1425   proof cases
  1426     assume "0 <= a * b"
  1427     then show ?thesis
  1428       apply (simp_all add: mulprts abs_prts)
  1429       apply (simp add: 
  1430 	iff2imp[OF zero_le_iff_zero_nprt]
  1431 	iff2imp[OF le_zero_iff_pprt_id]
  1432       )
  1433       apply (insert prems)
  1434       apply (auto simp add: 
  1435 	ring_eq_simps 
  1436 	iff2imp[OF zero_le_iff_zero_nprt] iff2imp[OF le_zero_iff_zero_pprt]
  1437 	iff2imp[OF le_zero_iff_pprt_id] iff2imp[OF zero_le_iff_nprt_id] 
  1438 	order_antisym mult_pos_neg_le[of a b] mult_pos_neg2_le[of b a])
  1439       done
  1440   next
  1441     assume "~(0 <= a*b)"
  1442     with s have "a*b <= 0" by simp
  1443     then show ?thesis
  1444       apply (simp_all add: mulprts abs_prts)
  1445       apply (insert prems)
  1446       apply (auto simp add: ring_eq_simps iff2imp[OF zero_le_iff_zero_nprt] iff2imp[OF le_zero_iff_zero_pprt]
  1447 	iff2imp[OF le_zero_iff_pprt_id] iff2imp[OF zero_le_iff_nprt_id] order_antisym mult_pos_le[of a b] mult_neg_le[of a b])
  1448       done
  1449   qed
  1450 qed
  1451 
  1452 lemma abs_mult: "abs (a * b) = abs a * abs (b::'a::ordered_idom)" 
  1453 by (simp add: abs_eq_mult linorder_linear)
  1454 
  1455 lemma abs_mult_self: "abs a * abs a = a * (a::'a::ordered_idom)"
  1456 by (simp add: abs_if) 
  1457 
  1458 lemma nonzero_abs_inverse:
  1459      "a \<noteq> 0 ==> abs (inverse (a::'a::ordered_field)) = inverse (abs a)"
  1460 apply (auto simp add: linorder_neq_iff abs_if nonzero_inverse_minus_eq 
  1461                       negative_imp_inverse_negative)
  1462 apply (blast intro: positive_imp_inverse_positive elim: order_less_asym) 
  1463 done
  1464 
  1465 lemma abs_inverse [simp]:
  1466      "abs (inverse (a::'a::{ordered_field,division_by_zero})) = 
  1467       inverse (abs a)"
  1468 apply (case_tac "a=0", simp) 
  1469 apply (simp add: nonzero_abs_inverse) 
  1470 done
  1471 
  1472 lemma nonzero_abs_divide:
  1473      "b \<noteq> 0 ==> abs (a / (b::'a::ordered_field)) = abs a / abs b"
  1474 by (simp add: divide_inverse abs_mult nonzero_abs_inverse) 
  1475 
  1476 lemma abs_divide:
  1477      "abs (a / (b::'a::{ordered_field,division_by_zero})) = abs a / abs b"
  1478 apply (case_tac "b=0", simp) 
  1479 apply (simp add: nonzero_abs_divide) 
  1480 done
  1481 
  1482 lemma abs_mult_less:
  1483      "[| abs a < c; abs b < d |] ==> abs a * abs b < c*(d::'a::ordered_idom)"
  1484 proof -
  1485   assume ac: "abs a < c"
  1486   hence cpos: "0<c" by (blast intro: order_le_less_trans abs_ge_zero)
  1487   assume "abs b < d"
  1488   thus ?thesis by (simp add: ac cpos mult_strict_mono) 
  1489 qed
  1490 
  1491 lemma eq_minus_self_iff: "(a = -a) = (a = (0::'a::ordered_idom))"
  1492 by (force simp add: order_eq_iff le_minus_self_iff minus_le_self_iff)
  1493 
  1494 lemma less_minus_self_iff: "(a < -a) = (a < (0::'a::ordered_idom))"
  1495 by (simp add: order_less_le le_minus_self_iff eq_minus_self_iff)
  1496 
  1497 lemma abs_less_iff: "(abs a < b) = (a < b & -a < (b::'a::ordered_idom))" 
  1498 apply (simp add: order_less_le abs_le_iff)  
  1499 apply (auto simp add: abs_if minus_le_self_iff eq_minus_self_iff)
  1500 apply (simp add: le_minus_self_iff linorder_neq_iff) 
  1501 done
  1502 
  1503 text{*Moving this up spoils many proofs using @{text mult_le_cancel_right}*}
  1504 declare times_divide_eq_left [simp]
  1505 
  1506 ML {*
  1507 val left_distrib = thm "left_distrib";
  1508 val right_distrib = thm "right_distrib";
  1509 val mult_commute = thm "mult_commute";
  1510 val distrib = thm "distrib";
  1511 val zero_neq_one = thm "zero_neq_one";
  1512 val no_zero_divisors = thm "no_zero_divisors";
  1513 val left_inverse = thm "left_inverse";
  1514 val divide_inverse = thm "divide_inverse";
  1515 val mult_zero_left = thm "mult_zero_left";
  1516 val mult_zero_right = thm "mult_zero_right";
  1517 val field_mult_eq_0_iff = thm "field_mult_eq_0_iff";
  1518 val inverse_zero = thm "inverse_zero";
  1519 val ring_distrib = thms "ring_distrib";
  1520 val combine_common_factor = thm "combine_common_factor";
  1521 val minus_mult_left = thm "minus_mult_left";
  1522 val minus_mult_right = thm "minus_mult_right";
  1523 val minus_mult_minus = thm "minus_mult_minus";
  1524 val minus_mult_commute = thm "minus_mult_commute";
  1525 val right_diff_distrib = thm "right_diff_distrib";
  1526 val left_diff_distrib = thm "left_diff_distrib";
  1527 val mult_left_mono = thm "mult_left_mono";
  1528 val mult_right_mono = thm "mult_right_mono";
  1529 val mult_strict_left_mono = thm "mult_strict_left_mono";
  1530 val mult_strict_right_mono = thm "mult_strict_right_mono";
  1531 val mult_mono = thm "mult_mono";
  1532 val mult_strict_mono = thm "mult_strict_mono";
  1533 val abs_if = thm "abs_if";
  1534 val zero_less_one = thm "zero_less_one";
  1535 val eq_add_iff1 = thm "eq_add_iff1";
  1536 val eq_add_iff2 = thm "eq_add_iff2";
  1537 val less_add_iff1 = thm "less_add_iff1";
  1538 val less_add_iff2 = thm "less_add_iff2";
  1539 val le_add_iff1 = thm "le_add_iff1";
  1540 val le_add_iff2 = thm "le_add_iff2";
  1541 val mult_left_le_imp_le = thm "mult_left_le_imp_le";
  1542 val mult_right_le_imp_le = thm "mult_right_le_imp_le";
  1543 val mult_left_less_imp_less = thm "mult_left_less_imp_less";
  1544 val mult_right_less_imp_less = thm "mult_right_less_imp_less";
  1545 val mult_strict_left_mono_neg = thm "mult_strict_left_mono_neg";
  1546 val mult_left_mono_neg = thm "mult_left_mono_neg";
  1547 val mult_strict_right_mono_neg = thm "mult_strict_right_mono_neg";
  1548 val mult_right_mono_neg = thm "mult_right_mono_neg";
  1549 val mult_pos = thm "mult_pos";
  1550 val mult_pos_le = thm "mult_pos_le";
  1551 val mult_pos_neg = thm "mult_pos_neg";
  1552 val mult_pos_neg_le = thm "mult_pos_neg_le";
  1553 val mult_pos_neg2 = thm "mult_pos_neg2";
  1554 val mult_pos_neg2_le = thm "mult_pos_neg2_le";
  1555 val mult_neg = thm "mult_neg";
  1556 val mult_neg_le = thm "mult_neg_le";
  1557 val zero_less_mult_pos = thm "zero_less_mult_pos";
  1558 val zero_less_mult_pos2 = thm "zero_less_mult_pos2";
  1559 val zero_less_mult_iff = thm "zero_less_mult_iff";
  1560 val mult_eq_0_iff = thm "mult_eq_0_iff";
  1561 val zero_le_mult_iff = thm "zero_le_mult_iff";
  1562 val mult_less_0_iff = thm "mult_less_0_iff";
  1563 val mult_le_0_iff = thm "mult_le_0_iff";
  1564 val split_mult_pos_le = thm "split_mult_pos_le";
  1565 val split_mult_neg_le = thm "split_mult_neg_le";
  1566 val zero_le_square = thm "zero_le_square";
  1567 val zero_le_one = thm "zero_le_one";
  1568 val not_one_le_zero = thm "not_one_le_zero";
  1569 val not_one_less_zero = thm "not_one_less_zero";
  1570 val mult_left_mono_neg = thm "mult_left_mono_neg";
  1571 val mult_right_mono_neg = thm "mult_right_mono_neg";
  1572 val mult_strict_mono = thm "mult_strict_mono";
  1573 val mult_strict_mono' = thm "mult_strict_mono'";
  1574 val mult_mono = thm "mult_mono";
  1575 val less_1_mult = thm "less_1_mult";
  1576 val mult_less_cancel_right = thm "mult_less_cancel_right";
  1577 val mult_less_cancel_left = thm "mult_less_cancel_left";
  1578 val mult_le_cancel_right = thm "mult_le_cancel_right";
  1579 val mult_le_cancel_left = thm "mult_le_cancel_left";
  1580 val mult_less_imp_less_left = thm "mult_less_imp_less_left";
  1581 val mult_less_imp_less_right = thm "mult_less_imp_less_right";
  1582 val mult_cancel_right = thm "mult_cancel_right";
  1583 val mult_cancel_left = thm "mult_cancel_left";
  1584 val ring_eq_simps = thms "ring_eq_simps";
  1585 val right_inverse = thm "right_inverse";
  1586 val right_inverse_eq = thm "right_inverse_eq";
  1587 val nonzero_inverse_eq_divide = thm "nonzero_inverse_eq_divide";
  1588 val divide_self = thm "divide_self";
  1589 val divide_zero = thm "divide_zero";
  1590 val divide_zero_left = thm "divide_zero_left";
  1591 val inverse_eq_divide = thm "inverse_eq_divide";
  1592 val add_divide_distrib = thm "add_divide_distrib";
  1593 val field_mult_eq_0_iff = thm "field_mult_eq_0_iff";
  1594 val field_mult_cancel_right_lemma = thm "field_mult_cancel_right_lemma";
  1595 val field_mult_cancel_right = thm "field_mult_cancel_right";
  1596 val field_mult_cancel_left = thm "field_mult_cancel_left";
  1597 val nonzero_imp_inverse_nonzero = thm "nonzero_imp_inverse_nonzero";
  1598 val inverse_zero_imp_zero = thm "inverse_zero_imp_zero";
  1599 val inverse_nonzero_imp_nonzero = thm "inverse_nonzero_imp_nonzero";
  1600 val inverse_nonzero_iff_nonzero = thm "inverse_nonzero_iff_nonzero";
  1601 val nonzero_inverse_minus_eq = thm "nonzero_inverse_minus_eq";
  1602 val inverse_minus_eq = thm "inverse_minus_eq";
  1603 val nonzero_inverse_eq_imp_eq = thm "nonzero_inverse_eq_imp_eq";
  1604 val inverse_eq_imp_eq = thm "inverse_eq_imp_eq";
  1605 val inverse_eq_iff_eq = thm "inverse_eq_iff_eq";
  1606 val nonzero_inverse_inverse_eq = thm "nonzero_inverse_inverse_eq";
  1607 val inverse_inverse_eq = thm "inverse_inverse_eq";
  1608 val inverse_1 = thm "inverse_1";
  1609 val nonzero_inverse_mult_distrib = thm "nonzero_inverse_mult_distrib";
  1610 val inverse_mult_distrib = thm "inverse_mult_distrib";
  1611 val inverse_add = thm "inverse_add";
  1612 val inverse_divide = thm "inverse_divide";
  1613 val nonzero_mult_divide_cancel_left = thm "nonzero_mult_divide_cancel_left";
  1614 val mult_divide_cancel_left = thm "mult_divide_cancel_left";
  1615 val nonzero_mult_divide_cancel_right = thm "nonzero_mult_divide_cancel_right";
  1616 val mult_divide_cancel_right = thm "mult_divide_cancel_right";
  1617 val mult_divide_cancel_eq_if = thm "mult_divide_cancel_eq_if";
  1618 val divide_1 = thm "divide_1";
  1619 val times_divide_eq_right = thm "times_divide_eq_right";
  1620 val times_divide_eq_left = thm "times_divide_eq_left";
  1621 val divide_divide_eq_right = thm "divide_divide_eq_right";
  1622 val divide_divide_eq_left = thm "divide_divide_eq_left";
  1623 val nonzero_minus_divide_left = thm "nonzero_minus_divide_left";
  1624 val nonzero_minus_divide_right = thm "nonzero_minus_divide_right";
  1625 val nonzero_minus_divide_divide = thm "nonzero_minus_divide_divide";
  1626 val minus_divide_left = thm "minus_divide_left";
  1627 val minus_divide_right = thm "minus_divide_right";
  1628 val minus_divide_divide = thm "minus_divide_divide";
  1629 val diff_divide_distrib = thm "diff_divide_distrib";
  1630 val positive_imp_inverse_positive = thm "positive_imp_inverse_positive";
  1631 val negative_imp_inverse_negative = thm "negative_imp_inverse_negative";
  1632 val inverse_le_imp_le = thm "inverse_le_imp_le";
  1633 val inverse_positive_imp_positive = thm "inverse_positive_imp_positive";
  1634 val inverse_positive_iff_positive = thm "inverse_positive_iff_positive";
  1635 val inverse_negative_imp_negative = thm "inverse_negative_imp_negative";
  1636 val inverse_negative_iff_negative = thm "inverse_negative_iff_negative";
  1637 val inverse_nonnegative_iff_nonnegative = thm "inverse_nonnegative_iff_nonnegative";
  1638 val inverse_nonpositive_iff_nonpositive = thm "inverse_nonpositive_iff_nonpositive";
  1639 val less_imp_inverse_less = thm "less_imp_inverse_less";
  1640 val inverse_less_imp_less = thm "inverse_less_imp_less";
  1641 val inverse_less_iff_less = thm "inverse_less_iff_less";
  1642 val le_imp_inverse_le = thm "le_imp_inverse_le";
  1643 val inverse_le_iff_le = thm "inverse_le_iff_le";
  1644 val inverse_le_imp_le_neg = thm "inverse_le_imp_le_neg";
  1645 val less_imp_inverse_less_neg = thm "less_imp_inverse_less_neg";
  1646 val inverse_less_imp_less_neg = thm "inverse_less_imp_less_neg";
  1647 val inverse_less_iff_less_neg = thm "inverse_less_iff_less_neg";
  1648 val le_imp_inverse_le_neg = thm "le_imp_inverse_le_neg";
  1649 val inverse_le_iff_le_neg = thm "inverse_le_iff_le_neg";
  1650 val one_less_inverse_iff = thm "one_less_inverse_iff";
  1651 val inverse_eq_1_iff = thm "inverse_eq_1_iff";
  1652 val one_le_inverse_iff = thm "one_le_inverse_iff";
  1653 val inverse_less_1_iff = thm "inverse_less_1_iff";
  1654 val inverse_le_1_iff = thm "inverse_le_1_iff";
  1655 val zero_less_divide_iff = thm "zero_less_divide_iff";
  1656 val divide_less_0_iff = thm "divide_less_0_iff";
  1657 val zero_le_divide_iff = thm "zero_le_divide_iff";
  1658 val divide_le_0_iff = thm "divide_le_0_iff";
  1659 val divide_eq_0_iff = thm "divide_eq_0_iff";
  1660 val pos_le_divide_eq = thm "pos_le_divide_eq";
  1661 val neg_le_divide_eq = thm "neg_le_divide_eq";
  1662 val le_divide_eq = thm "le_divide_eq";
  1663 val pos_divide_le_eq = thm "pos_divide_le_eq";
  1664 val neg_divide_le_eq = thm "neg_divide_le_eq";
  1665 val divide_le_eq = thm "divide_le_eq";
  1666 val pos_less_divide_eq = thm "pos_less_divide_eq";
  1667 val neg_less_divide_eq = thm "neg_less_divide_eq";
  1668 val less_divide_eq = thm "less_divide_eq";
  1669 val pos_divide_less_eq = thm "pos_divide_less_eq";
  1670 val neg_divide_less_eq = thm "neg_divide_less_eq";
  1671 val divide_less_eq = thm "divide_less_eq";
  1672 val nonzero_eq_divide_eq = thm "nonzero_eq_divide_eq";
  1673 val eq_divide_eq = thm "eq_divide_eq";
  1674 val nonzero_divide_eq_eq = thm "nonzero_divide_eq_eq";
  1675 val divide_eq_eq = thm "divide_eq_eq";
  1676 val divide_cancel_right = thm "divide_cancel_right";
  1677 val divide_cancel_left = thm "divide_cancel_left";
  1678 val divide_eq_1_iff = thm "divide_eq_1_iff";
  1679 val one_eq_divide_iff = thm "one_eq_divide_iff";
  1680 val zero_eq_1_divide_iff = thm "zero_eq_1_divide_iff";
  1681 val one_divide_eq_0_iff = thm "one_divide_eq_0_iff";
  1682 val divide_strict_right_mono = thm "divide_strict_right_mono";
  1683 val divide_right_mono = thm "divide_right_mono";
  1684 val divide_strict_left_mono = thm "divide_strict_left_mono";
  1685 val divide_left_mono = thm "divide_left_mono";
  1686 val divide_strict_left_mono_neg = thm "divide_strict_left_mono_neg";
  1687 val divide_strict_right_mono_neg = thm "divide_strict_right_mono_neg";
  1688 val less_add_one = thm "less_add_one";
  1689 val zero_less_two = thm "zero_less_two";
  1690 val less_half_sum = thm "less_half_sum";
  1691 val gt_half_sum = thm "gt_half_sum";
  1692 val dense = thm "dense";
  1693 val abs_one = thm "abs_one";
  1694 val abs_le_mult = thm "abs_le_mult";
  1695 val abs_eq_mult = thm "abs_eq_mult";
  1696 val abs_mult = thm "abs_mult";
  1697 val abs_mult_self = thm "abs_mult_self";
  1698 val nonzero_abs_inverse = thm "nonzero_abs_inverse";
  1699 val abs_inverse = thm "abs_inverse";
  1700 val nonzero_abs_divide = thm "nonzero_abs_divide";
  1701 val abs_divide = thm "abs_divide";
  1702 val abs_mult_less = thm "abs_mult_less";
  1703 val eq_minus_self_iff = thm "eq_minus_self_iff";
  1704 val less_minus_self_iff = thm "less_minus_self_iff";
  1705 val abs_less_iff = thm "abs_less_iff";
  1706 *}
  1707 
  1708 end