src/HOL/Transitive_Closure.thy
author nipkow
Mon Aug 16 14:22:27 2004 +0200 (2004-08-16)
changeset 15131 c69542757a4d
parent 15096 be1d3b8cfbd5
child 15140 322485b816ac
permissions -rw-r--r--
New theory header syntax.
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header {* Reflexive and Transitive closure of a relation *}
     8 
     9 theory Transitive_Closure
    10 import Inductive
    11 files ("../Provers/trancl.ML")
    12 begin
    13 
    14 text {*
    15   @{text rtrancl} is reflexive/transitive closure,
    16   @{text trancl} is transitive closure,
    17   @{text reflcl} is reflexive closure.
    18 
    19   These postfix operators have \emph{maximum priority}, forcing their
    20   operands to be atomic.
    21 *}
    22 
    23 consts
    24   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^*)" [1000] 999)
    25 
    26 inductive "r^*"
    27   intros
    28     rtrancl_refl [intro!, CPure.intro!, simp]: "(a, a) : r^*"
    29     rtrancl_into_rtrancl [CPure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    30 
    31 consts
    32   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^+)" [1000] 999)
    33 
    34 inductive "r^+"
    35   intros
    36     r_into_trancl [intro, CPure.intro]: "(a, b) : r ==> (a, b) : r^+"
    37     trancl_into_trancl [CPure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a,c) : r^+"
    38 
    39 syntax
    40   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^=)" [1000] 999)
    41 translations
    42   "r^=" == "r \<union> Id"
    43 
    44 syntax (xsymbols)
    45   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)
    46   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)
    47   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)
    48 
    49 syntax (HTML output)
    50   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)
    51   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)
    52   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)
    53 
    54 
    55 subsection {* Reflexive-transitive closure *}
    56 
    57 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    58   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    59   apply (simp only: split_tupled_all)
    60   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    61   done
    62 
    63 lemma rtrancl_mono: "r \<subseteq> s ==> r^* \<subseteq> s^*"
    64   -- {* monotonicity of @{text rtrancl} *}
    65   apply (rule subsetI)
    66   apply (simp only: split_tupled_all)
    67   apply (erule rtrancl.induct)
    68    apply (rule_tac [2] rtrancl_into_rtrancl, blast+)
    69   done
    70 
    71 theorem rtrancl_induct [consumes 1, induct set: rtrancl]:
    72   assumes a: "(a, b) : r^*"
    73     and cases: "P a" "!!y z. [| (a, y) : r^*; (y, z) : r; P y |] ==> P z"
    74   shows "P b"
    75 proof -
    76   from a have "a = a --> P b"
    77     by (induct "%x y. x = a --> P y" a b) (rules intro: cases)+
    78   thus ?thesis by rules
    79 qed
    80 
    81 lemmas rtrancl_induct2 =
    82   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
    83                  consumes 1, case_names refl step]
    84  
    85 lemma trans_rtrancl: "trans(r^*)"
    86   -- {* transitivity of transitive closure!! -- by induction *}
    87 proof (rule transI)
    88   fix x y z
    89   assume "(x, y) \<in> r\<^sup>*"
    90   assume "(y, z) \<in> r\<^sup>*"
    91   thus "(x, z) \<in> r\<^sup>*" by induct (rules!)+
    92 qed
    93 
    94 lemmas rtrancl_trans = trans_rtrancl [THEN transD, standard]
    95 
    96 lemma rtranclE:
    97   "[| (a::'a,b) : r^*;  (a = b) ==> P;
    98       !!y.[| (a,y) : r^*; (y,b) : r |] ==> P
    99    |] ==> P"
   100   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}
   101 proof -
   102   assume major: "(a::'a,b) : r^*"
   103   case rule_context
   104   show ?thesis
   105     apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   106      apply (rule_tac [2] major [THEN rtrancl_induct])
   107       prefer 2 apply (blast!)
   108       prefer 2 apply (blast!)
   109     apply (erule asm_rl exE disjE conjE prems)+
   110     done
   111 qed
   112 
   113 lemma converse_rtrancl_into_rtrancl:
   114   "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> r\<^sup>* \<Longrightarrow> (a, c) \<in> r\<^sup>*"
   115   by (rule rtrancl_trans) rules+
   116 
   117 text {*
   118   \medskip More @{term "r^*"} equations and inclusions.
   119 *}
   120 
   121 lemma rtrancl_idemp [simp]: "(r^*)^* = r^*"
   122   apply auto
   123   apply (erule rtrancl_induct)
   124    apply (rule rtrancl_refl)
   125   apply (blast intro: rtrancl_trans)
   126   done
   127 
   128 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   129   apply (rule set_ext)
   130   apply (simp only: split_tupled_all)
   131   apply (blast intro: rtrancl_trans)
   132   done
   133 
   134 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   135 by (drule rtrancl_mono, simp)
   136 
   137 lemma rtrancl_subset: "R \<subseteq> S ==> S \<subseteq> R^* ==> S^* = R^*"
   138   apply (drule rtrancl_mono)
   139   apply (drule rtrancl_mono, simp)
   140   done
   141 
   142 lemma rtrancl_Un_rtrancl: "(R^* \<union> S^*)^* = (R \<union> S)^*"
   143   by (blast intro!: rtrancl_subset intro: r_into_rtrancl rtrancl_mono [THEN subsetD])
   144 
   145 lemma rtrancl_reflcl [simp]: "(R^=)^* = R^*"
   146   by (blast intro!: rtrancl_subset intro: r_into_rtrancl)
   147 
   148 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   149   apply (rule sym)
   150   apply (rule rtrancl_subset, blast, clarify)
   151   apply (rename_tac a b)
   152   apply (case_tac "a = b", blast)
   153   apply (blast intro!: r_into_rtrancl)
   154   done
   155 
   156 theorem rtrancl_converseD:
   157   assumes r: "(x, y) \<in> (r^-1)^*"
   158   shows "(y, x) \<in> r^*"
   159 proof -
   160   from r show ?thesis
   161     by induct (rules intro: rtrancl_trans dest!: converseD)+
   162 qed
   163 
   164 theorem rtrancl_converseI:
   165   assumes r: "(y, x) \<in> r^*"
   166   shows "(x, y) \<in> (r^-1)^*"
   167 proof -
   168   from r show ?thesis
   169     by induct (rules intro: rtrancl_trans converseI)+
   170 qed
   171 
   172 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   173   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   174 
   175 theorem converse_rtrancl_induct[consumes 1]:
   176   assumes major: "(a, b) : r^*"
   177     and cases: "P b" "!!y z. [| (y, z) : r; (z, b) : r^*; P z |] ==> P y"
   178   shows "P a"
   179 proof -
   180   from rtrancl_converseI [OF major]
   181   show ?thesis
   182     by induct (rules intro: cases dest!: converseD rtrancl_converseD)+
   183 qed
   184 
   185 lemmas converse_rtrancl_induct2 =
   186   converse_rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   187                  consumes 1, case_names refl step]
   188 
   189 lemma converse_rtranclE:
   190   "[| (x,z):r^*;
   191       x=z ==> P;
   192       !!y. [| (x,y):r; (y,z):r^* |] ==> P
   193    |] ==> P"
   194 proof -
   195   assume major: "(x,z):r^*"
   196   case rule_context
   197   show ?thesis
   198     apply (subgoal_tac "x = z | (EX y. (x,y) : r & (y,z) : r^*)")
   199      apply (rule_tac [2] major [THEN converse_rtrancl_induct])
   200       prefer 2 apply rules
   201      prefer 2 apply rules
   202     apply (erule asm_rl exE disjE conjE prems)+
   203     done
   204 qed
   205 
   206 ML_setup {*
   207   bind_thm ("converse_rtranclE2", split_rule
   208     (read_instantiate [("x","(xa,xb)"), ("z","(za,zb)")] (thm "converse_rtranclE")));
   209 *}
   210 
   211 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   212   by (blast elim: rtranclE converse_rtranclE
   213     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   214 
   215 
   216 subsection {* Transitive closure *}
   217 
   218 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   219   apply (simp only: split_tupled_all)
   220   apply (erule trancl.induct)
   221   apply (rules dest: subsetD)+
   222   done
   223 
   224 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   225   by (simp only: split_tupled_all) (erule r_into_trancl)
   226 
   227 text {*
   228   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   229 *}
   230 
   231 lemma trancl_into_rtrancl: "(a, b) \<in> r^+ ==> (a, b) \<in> r^*"
   232   by (erule trancl.induct) rules+
   233 
   234 lemma rtrancl_into_trancl1: assumes r: "(a, b) \<in> r^*"
   235   shows "!!c. (b, c) \<in> r ==> (a, c) \<in> r^+" using r
   236   by induct rules+
   237 
   238 lemma rtrancl_into_trancl2: "[| (a,b) : r;  (b,c) : r^* |]   ==>  (a,c) : r^+"
   239   -- {* intro rule from @{text r} and @{text rtrancl} *}
   240   apply (erule rtranclE, rules)
   241   apply (rule rtrancl_trans [THEN rtrancl_into_trancl1])
   242    apply (assumption | rule r_into_rtrancl)+
   243   done
   244 
   245 lemma trancl_induct [consumes 1, induct set: trancl]:
   246   assumes a: "(a,b) : r^+"
   247   and cases: "!!y. (a, y) : r ==> P y"
   248     "!!y z. (a,y) : r^+ ==> (y, z) : r ==> P y ==> P z"
   249   shows "P b"
   250   -- {* Nice induction rule for @{text trancl} *}
   251 proof -
   252   from a have "a = a --> P b"
   253     by (induct "%x y. x = a --> P y" a b) (rules intro: cases)+
   254   thus ?thesis by rules
   255 qed
   256 
   257 lemma trancl_trans_induct:
   258   "[| (x,y) : r^+;
   259       !!x y. (x,y) : r ==> P x y;
   260       !!x y z. [| (x,y) : r^+; P x y; (y,z) : r^+; P y z |] ==> P x z
   261    |] ==> P x y"
   262   -- {* Another induction rule for trancl, incorporating transitivity *}
   263 proof -
   264   assume major: "(x,y) : r^+"
   265   case rule_context
   266   show ?thesis
   267     by (rules intro: r_into_trancl major [THEN trancl_induct] prems)
   268 qed
   269 
   270 inductive_cases tranclE: "(a, b) : r^+"
   271 
   272 lemma trans_trancl: "trans(r^+)"
   273   -- {* Transitivity of @{term "r^+"} *}
   274 proof (rule transI)
   275   fix x y z
   276   assume "(x, y) \<in> r^+"
   277   assume "(y, z) \<in> r^+"
   278   thus "(x, z) \<in> r^+" by induct (rules!)+
   279 qed
   280 
   281 lemmas trancl_trans = trans_trancl [THEN transD, standard]
   282 
   283 lemma rtrancl_trancl_trancl: assumes r: "(x, y) \<in> r^*"
   284   shows "!!z. (y, z) \<in> r^+ ==> (x, z) \<in> r^+" using r
   285   by induct (rules intro: trancl_trans)+
   286 
   287 lemma trancl_into_trancl2: "(a, b) \<in> r ==> (b, c) \<in> r^+ ==> (a, c) \<in> r^+"
   288   by (erule transD [OF trans_trancl r_into_trancl])
   289 
   290 lemma trancl_insert:
   291   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   292   -- {* primitive recursion for @{text trancl} over finite relations *}
   293   apply (rule equalityI)
   294    apply (rule subsetI)
   295    apply (simp only: split_tupled_all)
   296    apply (erule trancl_induct, blast)
   297    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl r_into_trancl trancl_trans)
   298   apply (rule subsetI)
   299   apply (blast intro: trancl_mono rtrancl_mono
   300     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   301   done
   302 
   303 lemma trancl_converseI: "(x, y) \<in> (r^+)^-1 ==> (x, y) \<in> (r^-1)^+"
   304   apply (drule converseD)
   305   apply (erule trancl.induct)
   306   apply (rules intro: converseI trancl_trans)+
   307   done
   308 
   309 lemma trancl_converseD: "(x, y) \<in> (r^-1)^+ ==> (x, y) \<in> (r^+)^-1"
   310   apply (rule converseI)
   311   apply (erule trancl.induct)
   312   apply (rules dest: converseD intro: trancl_trans)+
   313   done
   314 
   315 lemma trancl_converse: "(r^-1)^+ = (r^+)^-1"
   316   by (fastsimp simp add: split_tupled_all
   317     intro!: trancl_converseI trancl_converseD)
   318 
   319 lemma converse_trancl_induct:
   320   "[| (a,b) : r^+; !!y. (y,b) : r ==> P(y);
   321       !!y z.[| (y,z) : r;  (z,b) : r^+;  P(z) |] ==> P(y) |]
   322     ==> P(a)"
   323 proof -
   324   assume major: "(a,b) : r^+"
   325   case rule_context
   326   show ?thesis
   327     apply (rule major [THEN converseI, THEN trancl_converseI [THEN trancl_induct]])
   328      apply (rule prems)
   329      apply (erule converseD)
   330     apply (blast intro: prems dest!: trancl_converseD)
   331     done
   332 qed
   333 
   334 lemma tranclD: "(x, y) \<in> R^+ ==> EX z. (x, z) \<in> R \<and> (z, y) \<in> R^*"
   335   apply (erule converse_trancl_induct, auto)
   336   apply (blast intro: rtrancl_trans)
   337   done
   338 
   339 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   340 by(blast elim: tranclE dest: trancl_into_rtrancl)
   341 
   342 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   343   by (blast dest: r_into_trancl)
   344 
   345 lemma trancl_subset_Sigma_aux:
   346     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   347   apply (erule rtrancl_induct, auto)
   348   done
   349 
   350 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   351   apply (rule subsetI)
   352   apply (simp only: split_tupled_all)
   353   apply (erule tranclE)
   354   apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   355   done
   356 
   357 lemma reflcl_trancl [simp]: "(r^+)^= = r^*"
   358   apply safe
   359    apply (erule trancl_into_rtrancl)
   360   apply (blast elim: rtranclE dest: rtrancl_into_trancl1)
   361   done
   362 
   363 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   364   apply safe
   365    apply (drule trancl_into_rtrancl, simp)
   366   apply (erule rtranclE, safe)
   367    apply (rule r_into_trancl, simp)
   368   apply (rule rtrancl_into_trancl1)
   369    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   370   done
   371 
   372 lemma trancl_empty [simp]: "{}^+ = {}"
   373   by (auto elim: trancl_induct)
   374 
   375 lemma rtrancl_empty [simp]: "{}^* = Id"
   376   by (rule subst [OF reflcl_trancl]) simp
   377 
   378 lemma rtranclD: "(a, b) \<in> R^* ==> a = b \<or> a \<noteq> b \<and> (a, b) \<in> R^+"
   379   by (force simp add: reflcl_trancl [symmetric] simp del: reflcl_trancl)
   380 
   381 
   382 text {* @{text Domain} and @{text Range} *}
   383 
   384 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   385   by blast
   386 
   387 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   388   by blast
   389 
   390 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   391   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   392 
   393 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   394   by (blast intro: subsetD [OF rtrancl_Un_subset])
   395 
   396 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   397   by (unfold Domain_def) (blast dest: tranclD)
   398 
   399 lemma trancl_range [simp]: "Range (r^+) = Range r"
   400   by (simp add: Range_def trancl_converse [symmetric])
   401 
   402 lemma Not_Domain_rtrancl:
   403     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   404   apply auto
   405   by (erule rev_mp, erule rtrancl_induct, auto)
   406 
   407 
   408 text {* More about converse @{text rtrancl} and @{text trancl}, should
   409   be merged with main body. *}
   410 
   411 lemma single_valued_confluent:
   412   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   413   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   414 apply(erule rtrancl_induct)
   415  apply simp
   416 apply(erule disjE)
   417  apply(blast elim:converse_rtranclE dest:single_valuedD)
   418 apply(blast intro:rtrancl_trans)
   419 done
   420 
   421 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   422   by (fast intro: trancl_trans)
   423 
   424 lemma trancl_into_trancl [rule_format]:
   425     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   426   apply (erule trancl_induct)
   427    apply (fast intro: r_r_into_trancl)
   428   apply (fast intro: r_r_into_trancl trancl_trans)
   429   done
   430 
   431 lemma trancl_rtrancl_trancl:
   432     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r\<^sup>* ==> (a, c) \<in> r\<^sup>+"
   433   apply (drule tranclD)
   434   apply (erule exE, erule conjE)
   435   apply (drule rtrancl_trans, assumption)
   436   apply (drule rtrancl_into_trancl2, assumption, assumption)
   437   done
   438 
   439 lemmas transitive_closure_trans [trans] =
   440   r_r_into_trancl trancl_trans rtrancl_trans
   441   trancl_into_trancl trancl_into_trancl2
   442   rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   443   rtrancl_trancl_trancl trancl_rtrancl_trancl
   444 
   445 declare trancl_into_rtrancl [elim]
   446 
   447 declare rtranclE [cases set: rtrancl]
   448 declare tranclE [cases set: trancl]
   449 
   450 subsection {* Setup of transitivity reasoner *}
   451 
   452 use "../Provers/trancl.ML";
   453 
   454 ML_setup {*
   455 
   456 structure Trancl_Tac = Trancl_Tac_Fun (
   457   struct
   458     val r_into_trancl = thm "r_into_trancl";
   459     val trancl_trans  = thm "trancl_trans";
   460     val rtrancl_refl = thm "rtrancl_refl";
   461     val r_into_rtrancl = thm "r_into_rtrancl";
   462     val trancl_into_rtrancl = thm "trancl_into_rtrancl";
   463     val rtrancl_trancl_trancl = thm "rtrancl_trancl_trancl";
   464     val trancl_rtrancl_trancl = thm "trancl_rtrancl_trancl";
   465     val rtrancl_trans = thm "rtrancl_trans";
   466 
   467   fun decomp (Trueprop $ t) = 
   468     let fun dec (Const ("op :", _) $ (Const ("Pair", _) $ a $ b) $ rel ) = 
   469 	let fun decr (Const ("Transitive_Closure.rtrancl", _ ) $ r) = (r,"r*")
   470 	      | decr (Const ("Transitive_Closure.trancl", _ ) $ r)  = (r,"r+")
   471 	      | decr r = (r,"r");
   472 	    val (rel,r) = decr rel;
   473 	in Some (a,b,rel,r) end
   474       | dec _ =  None 
   475     in dec t end;
   476   
   477   end); (* struct *)
   478 
   479 simpset_ref() := simpset ()
   480     addSolver (mk_solver "Trancl" (fn _ => Trancl_Tac.trancl_tac))
   481     addSolver (mk_solver "Rtrancl" (fn _ => Trancl_Tac.rtrancl_tac));
   482 
   483 *}
   484 
   485 (* Optional methods
   486 
   487 method_setup trancl =
   488   {* Method.no_args (Method.SIMPLE_METHOD' HEADGOAL (trancl_tac)) *}
   489   {* simple transitivity reasoner *}	    
   490 method_setup rtrancl =
   491   {* Method.no_args (Method.SIMPLE_METHOD' HEADGOAL (rtrancl_tac)) *}
   492   {* simple transitivity reasoner *}
   493 
   494 *)
   495 
   496 end