src/HOL/Library/FuncSet.thy
author kleing
Wed Apr 14 14:13:05 2004 +0200 (2004-04-14)
changeset 14565 c6dc17aab88a
parent 13595 7e6cdcd113a2
child 14706 71590b7733b7
permissions -rw-r--r--
use more symbols in HTML output
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     ID:         $Id$
     3     Author:     Florian Kammueller and Lawrence C Paulson
     4 *)
     5 
     6 header {*
     7   \title{Pi and Function Sets}
     8   \author{Florian Kammueller and Lawrence C Paulson}
     9 *}
    10 
    11 theory FuncSet = Main:
    12 
    13 constdefs
    14   Pi      :: "['a set, 'a => 'b set] => ('a => 'b) set"
    15     "Pi A B == {f. \<forall>x. x \<in> A --> f(x) \<in> B(x)}"
    16 
    17   extensional :: "'a set => ('a => 'b) set"
    18     "extensional A == {f. \<forall>x. x~:A --> f(x) = arbitrary}"
    19 
    20   restrict :: "['a => 'b, 'a set] => ('a => 'b)"
    21     "restrict f A == (%x. if x \<in> A then f x else arbitrary)"
    22 
    23 syntax
    24   "@Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    25   funcset :: "['a set, 'b set] => ('a => 'b) set"      (infixr "->" 60)
    26   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    27 
    28 syntax (xsymbols)
    29   "@Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    30   funcset :: "['a set, 'b set] => ('a => 'b) set"  (infixr "\<rightarrow>" 60) 
    31   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    32 
    33 syntax (HTML output)
    34   "@Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    35   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    36 
    37 translations
    38   "PI x:A. B" => "Pi A (%x. B)"
    39   "A -> B"    => "Pi A (_K B)"
    40   "%x:A. f"  == "restrict (%x. f) A"
    41 
    42 constdefs
    43   compose :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)"
    44   "compose A g f == \<lambda>x\<in>A. g (f x)"
    45 
    46 print_translation {* [("Pi", dependent_tr' ("@Pi", "funcset"))] *}
    47 
    48 
    49 subsection{*Basic Properties of @{term Pi}*}
    50 
    51 lemma Pi_I: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    52 by (simp add: Pi_def)
    53 
    54 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    55 by (simp add: Pi_def)
    56 
    57 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    58 by (simp add: Pi_def)
    59 
    60 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    61 by (simp add: Pi_def)
    62 
    63 lemma Pi_eq_empty: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    64 apply (simp add: Pi_def, auto)
    65 txt{*Converse direction requires Axiom of Choice to exhibit a function
    66 picking an element from each non-empty @{term "B x"}*}
    67 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    68 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto) 
    69 done
    70 
    71 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    72 by (simp add: Pi_def)
    73 
    74 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    75 by (simp add: Pi_def)
    76 
    77 text{*Covariance of Pi-sets in their second argument*}
    78 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
    79 by (simp add: Pi_def, blast)
    80 
    81 text{*Contravariance of Pi-sets in their first argument*}
    82 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
    83 by (simp add: Pi_def, blast)
    84 
    85 
    86 subsection{*Composition With a Restricted Domain: @{term compose}*}
    87 
    88 lemma funcset_compose: 
    89      "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
    90 by (simp add: Pi_def compose_def restrict_def)
    91 
    92 lemma compose_assoc:
    93      "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |] 
    94       ==> compose A h (compose A g f) = compose A (compose B h g) f"
    95 by (simp add: expand_fun_eq Pi_def compose_def restrict_def) 
    96 
    97 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
    98 by (simp add: compose_def restrict_def)
    99 
   100 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   101 by (auto simp add: image_def compose_eq)
   102 
   103 lemma inj_on_compose:
   104      "[| f ` A = B; inj_on f A; inj_on g B |] ==> inj_on (compose A g f) A"
   105 by (auto simp add: inj_on_def compose_eq)
   106 
   107 
   108 subsection{*Bounded Abstraction: @{term restrict}*}
   109 
   110 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   111 by (simp add: Pi_def restrict_def)
   112 
   113 lemma restrictI: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   114 by (simp add: Pi_def restrict_def)
   115 
   116 lemma restrict_apply [simp]:
   117      "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else arbitrary)"
   118 by (simp add: restrict_def)
   119 
   120 lemma restrict_ext: 
   121     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   122 by (simp add: expand_fun_eq Pi_def Pi_def restrict_def)
   123 
   124 lemma inj_on_restrict_eq: "inj_on (restrict f A) A = inj_on f A"
   125 by (simp add: inj_on_def restrict_def)
   126 
   127 
   128 lemma Id_compose:
   129      "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   130 by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   131 
   132 lemma compose_Id:
   133      "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   134 by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   135 
   136 
   137 subsection{*Extensionality*}
   138 
   139 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = arbitrary"
   140 by (simp add: extensional_def)
   141 
   142 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   143 by (simp add: restrict_def extensional_def)
   144 
   145 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   146 by (simp add: compose_def)
   147 
   148 lemma extensionalityI:
   149      "[| f \<in> extensional A; g \<in> extensional A; 
   150          !!x. x\<in>A ==> f x = g x |] ==> f = g"
   151 by (force simp add: expand_fun_eq extensional_def)
   152 
   153 lemma Inv_funcset: "f ` A = B ==> (\<lambda>x\<in>B. Inv A f x) : B -> A"
   154 apply (unfold Inv_def)
   155 apply (fast intro: restrict_in_funcset someI2)
   156 done
   157 
   158 lemma compose_Inv_id:
   159      "[| inj_on f A;  f ` A = B |]  
   160       ==> compose A (\<lambda>y\<in>B. Inv A f y) f = (\<lambda>x\<in>A. x)"
   161 apply (simp add: compose_def)
   162 apply (rule restrict_ext, auto)
   163 apply (erule subst)
   164 apply (simp add: Inv_f_f)
   165 done
   166 
   167 lemma compose_id_Inv:
   168      "f ` A = B ==> compose B f (\<lambda>y\<in>B. Inv A f y) = (\<lambda>x\<in>B. x)"
   169 apply (simp add: compose_def)
   170 apply (rule restrict_ext)
   171 apply (simp add: f_Inv_f)
   172 done
   173 
   174 end