src/HOL/Transitive_Closure.thy
author kleing
Wed Apr 14 14:13:05 2004 +0200 (2004-04-14)
changeset 14565 c6dc17aab88a
parent 14404 4952c5a92e04
child 15076 4b3d280ef06a
permissions -rw-r--r--
use more symbols in HTML output
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header {* Reflexive and Transitive closure of a relation *}
     8 
     9 theory Transitive_Closure = Inductive:
    10 
    11 text {*
    12   @{text rtrancl} is reflexive/transitive closure,
    13   @{text trancl} is transitive closure,
    14   @{text reflcl} is reflexive closure.
    15 
    16   These postfix operators have \emph{maximum priority}, forcing their
    17   operands to be atomic.
    18 *}
    19 
    20 consts
    21   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^*)" [1000] 999)
    22 
    23 inductive "r^*"
    24   intros
    25     rtrancl_refl [intro!, CPure.intro!, simp]: "(a, a) : r^*"
    26     rtrancl_into_rtrancl [CPure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    27 
    28 consts
    29   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^+)" [1000] 999)
    30 
    31 inductive "r^+"
    32   intros
    33     r_into_trancl [intro, CPure.intro]: "(a, b) : r ==> (a, b) : r^+"
    34     trancl_into_trancl [CPure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a,c) : r^+"
    35 
    36 syntax
    37   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^=)" [1000] 999)
    38 translations
    39   "r^=" == "r \<union> Id"
    40 
    41 syntax (xsymbols)
    42   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)
    43   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)
    44   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)
    45 
    46 syntax (HTML output)
    47   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)
    48   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)
    49   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)
    50 
    51 
    52 subsection {* Reflexive-transitive closure *}
    53 
    54 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    55   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    56   apply (simp only: split_tupled_all)
    57   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    58   done
    59 
    60 lemma rtrancl_mono: "r \<subseteq> s ==> r^* \<subseteq> s^*"
    61   -- {* monotonicity of @{text rtrancl} *}
    62   apply (rule subsetI)
    63   apply (simp only: split_tupled_all)
    64   apply (erule rtrancl.induct)
    65    apply (rule_tac [2] rtrancl_into_rtrancl, blast+)
    66   done
    67 
    68 theorem rtrancl_induct [consumes 1, induct set: rtrancl]:
    69   assumes a: "(a, b) : r^*"
    70     and cases: "P a" "!!y z. [| (a, y) : r^*; (y, z) : r; P y |] ==> P z"
    71   shows "P b"
    72 proof -
    73   from a have "a = a --> P b"
    74     by (induct "%x y. x = a --> P y" a b) (rules intro: cases)+
    75   thus ?thesis by rules
    76 qed
    77 
    78 lemmas rtrancl_induct2 =
    79   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
    80                  consumes 1, case_names refl step]
    81  
    82 lemma trans_rtrancl: "trans(r^*)"
    83   -- {* transitivity of transitive closure!! -- by induction *}
    84 proof (rule transI)
    85   fix x y z
    86   assume "(x, y) \<in> r\<^sup>*"
    87   assume "(y, z) \<in> r\<^sup>*"
    88   thus "(x, z) \<in> r\<^sup>*" by induct (rules!)+
    89 qed
    90 
    91 lemmas rtrancl_trans = trans_rtrancl [THEN transD, standard]
    92 
    93 lemma rtranclE:
    94   "[| (a::'a,b) : r^*;  (a = b) ==> P;
    95       !!y.[| (a,y) : r^*; (y,b) : r |] ==> P
    96    |] ==> P"
    97   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}
    98 proof -
    99   assume major: "(a::'a,b) : r^*"
   100   case rule_context
   101   show ?thesis
   102     apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   103      apply (rule_tac [2] major [THEN rtrancl_induct])
   104       prefer 2 apply (blast!)
   105       prefer 2 apply (blast!)
   106     apply (erule asm_rl exE disjE conjE prems)+
   107     done
   108 qed
   109 
   110 lemma converse_rtrancl_into_rtrancl:
   111   "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> r\<^sup>* \<Longrightarrow> (a, c) \<in> r\<^sup>*"
   112   by (rule rtrancl_trans) rules+
   113 
   114 text {*
   115   \medskip More @{term "r^*"} equations and inclusions.
   116 *}
   117 
   118 lemma rtrancl_idemp [simp]: "(r^*)^* = r^*"
   119   apply auto
   120   apply (erule rtrancl_induct)
   121    apply (rule rtrancl_refl)
   122   apply (blast intro: rtrancl_trans)
   123   done
   124 
   125 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   126   apply (rule set_ext)
   127   apply (simp only: split_tupled_all)
   128   apply (blast intro: rtrancl_trans)
   129   done
   130 
   131 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   132 by (drule rtrancl_mono, simp)
   133 
   134 lemma rtrancl_subset: "R \<subseteq> S ==> S \<subseteq> R^* ==> S^* = R^*"
   135   apply (drule rtrancl_mono)
   136   apply (drule rtrancl_mono, simp)
   137   done
   138 
   139 lemma rtrancl_Un_rtrancl: "(R^* \<union> S^*)^* = (R \<union> S)^*"
   140   by (blast intro!: rtrancl_subset intro: r_into_rtrancl rtrancl_mono [THEN subsetD])
   141 
   142 lemma rtrancl_reflcl [simp]: "(R^=)^* = R^*"
   143   by (blast intro!: rtrancl_subset intro: r_into_rtrancl)
   144 
   145 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   146   apply (rule sym)
   147   apply (rule rtrancl_subset, blast, clarify)
   148   apply (rename_tac a b)
   149   apply (case_tac "a = b", blast)
   150   apply (blast intro!: r_into_rtrancl)
   151   done
   152 
   153 theorem rtrancl_converseD:
   154   assumes r: "(x, y) \<in> (r^-1)^*"
   155   shows "(y, x) \<in> r^*"
   156 proof -
   157   from r show ?thesis
   158     by induct (rules intro: rtrancl_trans dest!: converseD)+
   159 qed
   160 
   161 theorem rtrancl_converseI:
   162   assumes r: "(y, x) \<in> r^*"
   163   shows "(x, y) \<in> (r^-1)^*"
   164 proof -
   165   from r show ?thesis
   166     by induct (rules intro: rtrancl_trans converseI)+
   167 qed
   168 
   169 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   170   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   171 
   172 theorem converse_rtrancl_induct[consumes 1]:
   173   assumes major: "(a, b) : r^*"
   174     and cases: "P b" "!!y z. [| (y, z) : r; (z, b) : r^*; P z |] ==> P y"
   175   shows "P a"
   176 proof -
   177   from rtrancl_converseI [OF major]
   178   show ?thesis
   179     by induct (rules intro: cases dest!: converseD rtrancl_converseD)+
   180 qed
   181 
   182 lemmas converse_rtrancl_induct2 =
   183   converse_rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   184                  consumes 1, case_names refl step]
   185 
   186 lemma converse_rtranclE:
   187   "[| (x,z):r^*;
   188       x=z ==> P;
   189       !!y. [| (x,y):r; (y,z):r^* |] ==> P
   190    |] ==> P"
   191 proof -
   192   assume major: "(x,z):r^*"
   193   case rule_context
   194   show ?thesis
   195     apply (subgoal_tac "x = z | (EX y. (x,y) : r & (y,z) : r^*)")
   196      apply (rule_tac [2] major [THEN converse_rtrancl_induct])
   197       prefer 2 apply rules
   198      prefer 2 apply rules
   199     apply (erule asm_rl exE disjE conjE prems)+
   200     done
   201 qed
   202 
   203 ML_setup {*
   204   bind_thm ("converse_rtranclE2", split_rule
   205     (read_instantiate [("x","(xa,xb)"), ("z","(za,zb)")] (thm "converse_rtranclE")));
   206 *}
   207 
   208 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   209   by (blast elim: rtranclE converse_rtranclE
   210     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   211 
   212 
   213 subsection {* Transitive closure *}
   214 
   215 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   216   apply (simp only: split_tupled_all)
   217   apply (erule trancl.induct)
   218   apply (rules dest: subsetD)+
   219   done
   220 
   221 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   222   by (simp only: split_tupled_all) (erule r_into_trancl)
   223 
   224 text {*
   225   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   226 *}
   227 
   228 lemma trancl_into_rtrancl: "(a, b) \<in> r^+ ==> (a, b) \<in> r^*"
   229   by (erule trancl.induct) rules+
   230 
   231 lemma rtrancl_into_trancl1: assumes r: "(a, b) \<in> r^*"
   232   shows "!!c. (b, c) \<in> r ==> (a, c) \<in> r^+" using r
   233   by induct rules+
   234 
   235 lemma rtrancl_into_trancl2: "[| (a,b) : r;  (b,c) : r^* |]   ==>  (a,c) : r^+"
   236   -- {* intro rule from @{text r} and @{text rtrancl} *}
   237   apply (erule rtranclE, rules)
   238   apply (rule rtrancl_trans [THEN rtrancl_into_trancl1])
   239    apply (assumption | rule r_into_rtrancl)+
   240   done
   241 
   242 lemma trancl_induct [consumes 1, induct set: trancl]:
   243   assumes a: "(a,b) : r^+"
   244   and cases: "!!y. (a, y) : r ==> P y"
   245     "!!y z. (a,y) : r^+ ==> (y, z) : r ==> P y ==> P z"
   246   shows "P b"
   247   -- {* Nice induction rule for @{text trancl} *}
   248 proof -
   249   from a have "a = a --> P b"
   250     by (induct "%x y. x = a --> P y" a b) (rules intro: cases)+
   251   thus ?thesis by rules
   252 qed
   253 
   254 lemma trancl_trans_induct:
   255   "[| (x,y) : r^+;
   256       !!x y. (x,y) : r ==> P x y;
   257       !!x y z. [| (x,y) : r^+; P x y; (y,z) : r^+; P y z |] ==> P x z
   258    |] ==> P x y"
   259   -- {* Another induction rule for trancl, incorporating transitivity *}
   260 proof -
   261   assume major: "(x,y) : r^+"
   262   case rule_context
   263   show ?thesis
   264     by (rules intro: r_into_trancl major [THEN trancl_induct] prems)
   265 qed
   266 
   267 inductive_cases tranclE: "(a, b) : r^+"
   268 
   269 lemma trans_trancl: "trans(r^+)"
   270   -- {* Transitivity of @{term "r^+"} *}
   271 proof (rule transI)
   272   fix x y z
   273   assume "(x, y) \<in> r^+"
   274   assume "(y, z) \<in> r^+"
   275   thus "(x, z) \<in> r^+" by induct (rules!)+
   276 qed
   277 
   278 lemmas trancl_trans = trans_trancl [THEN transD, standard]
   279 
   280 lemma rtrancl_trancl_trancl: assumes r: "(x, y) \<in> r^*"
   281   shows "!!z. (y, z) \<in> r^+ ==> (x, z) \<in> r^+" using r
   282   by induct (rules intro: trancl_trans)+
   283 
   284 lemma trancl_into_trancl2: "(a, b) \<in> r ==> (b, c) \<in> r^+ ==> (a, c) \<in> r^+"
   285   by (erule transD [OF trans_trancl r_into_trancl])
   286 
   287 lemma trancl_insert:
   288   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   289   -- {* primitive recursion for @{text trancl} over finite relations *}
   290   apply (rule equalityI)
   291    apply (rule subsetI)
   292    apply (simp only: split_tupled_all)
   293    apply (erule trancl_induct, blast)
   294    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl r_into_trancl trancl_trans)
   295   apply (rule subsetI)
   296   apply (blast intro: trancl_mono rtrancl_mono
   297     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   298   done
   299 
   300 lemma trancl_converseI: "(x, y) \<in> (r^+)^-1 ==> (x, y) \<in> (r^-1)^+"
   301   apply (drule converseD)
   302   apply (erule trancl.induct)
   303   apply (rules intro: converseI trancl_trans)+
   304   done
   305 
   306 lemma trancl_converseD: "(x, y) \<in> (r^-1)^+ ==> (x, y) \<in> (r^+)^-1"
   307   apply (rule converseI)
   308   apply (erule trancl.induct)
   309   apply (rules dest: converseD intro: trancl_trans)+
   310   done
   311 
   312 lemma trancl_converse: "(r^-1)^+ = (r^+)^-1"
   313   by (fastsimp simp add: split_tupled_all
   314     intro!: trancl_converseI trancl_converseD)
   315 
   316 lemma converse_trancl_induct:
   317   "[| (a,b) : r^+; !!y. (y,b) : r ==> P(y);
   318       !!y z.[| (y,z) : r;  (z,b) : r^+;  P(z) |] ==> P(y) |]
   319     ==> P(a)"
   320 proof -
   321   assume major: "(a,b) : r^+"
   322   case rule_context
   323   show ?thesis
   324     apply (rule major [THEN converseI, THEN trancl_converseI [THEN trancl_induct]])
   325      apply (rule prems)
   326      apply (erule converseD)
   327     apply (blast intro: prems dest!: trancl_converseD)
   328     done
   329 qed
   330 
   331 lemma tranclD: "(x, y) \<in> R^+ ==> EX z. (x, z) \<in> R \<and> (z, y) \<in> R^*"
   332   apply (erule converse_trancl_induct, auto)
   333   apply (blast intro: rtrancl_trans)
   334   done
   335 
   336 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   337 by(blast elim: tranclE dest: trancl_into_rtrancl)
   338 
   339 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   340   by (blast dest: r_into_trancl)
   341 
   342 lemma trancl_subset_Sigma_aux:
   343     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   344   apply (erule rtrancl_induct, auto)
   345   done
   346 
   347 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   348   apply (rule subsetI)
   349   apply (simp only: split_tupled_all)
   350   apply (erule tranclE)
   351   apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   352   done
   353 
   354 lemma reflcl_trancl [simp]: "(r^+)^= = r^*"
   355   apply safe
   356    apply (erule trancl_into_rtrancl)
   357   apply (blast elim: rtranclE dest: rtrancl_into_trancl1)
   358   done
   359 
   360 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   361   apply safe
   362    apply (drule trancl_into_rtrancl, simp)
   363   apply (erule rtranclE, safe)
   364    apply (rule r_into_trancl, simp)
   365   apply (rule rtrancl_into_trancl1)
   366    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   367   done
   368 
   369 lemma trancl_empty [simp]: "{}^+ = {}"
   370   by (auto elim: trancl_induct)
   371 
   372 lemma rtrancl_empty [simp]: "{}^* = Id"
   373   by (rule subst [OF reflcl_trancl]) simp
   374 
   375 lemma rtranclD: "(a, b) \<in> R^* ==> a = b \<or> a \<noteq> b \<and> (a, b) \<in> R^+"
   376   by (force simp add: reflcl_trancl [symmetric] simp del: reflcl_trancl)
   377 
   378 
   379 text {* @{text Domain} and @{text Range} *}
   380 
   381 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   382   by blast
   383 
   384 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   385   by blast
   386 
   387 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   388   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   389 
   390 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   391   by (blast intro: subsetD [OF rtrancl_Un_subset])
   392 
   393 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   394   by (unfold Domain_def) (blast dest: tranclD)
   395 
   396 lemma trancl_range [simp]: "Range (r^+) = Range r"
   397   by (simp add: Range_def trancl_converse [symmetric])
   398 
   399 lemma Not_Domain_rtrancl:
   400     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   401   apply auto
   402   by (erule rev_mp, erule rtrancl_induct, auto)
   403 
   404 
   405 text {* More about converse @{text rtrancl} and @{text trancl}, should
   406   be merged with main body. *}
   407 
   408 lemma single_valued_confluent:
   409   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   410   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   411 apply(erule rtrancl_induct)
   412  apply simp
   413 apply(erule disjE)
   414  apply(blast elim:converse_rtranclE dest:single_valuedD)
   415 apply(blast intro:rtrancl_trans)
   416 done
   417 
   418 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   419   by (fast intro: trancl_trans)
   420 
   421 lemma trancl_into_trancl [rule_format]:
   422     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   423   apply (erule trancl_induct)
   424    apply (fast intro: r_r_into_trancl)
   425   apply (fast intro: r_r_into_trancl trancl_trans)
   426   done
   427 
   428 lemma trancl_rtrancl_trancl:
   429     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r\<^sup>* ==> (a, c) \<in> r\<^sup>+"
   430   apply (drule tranclD)
   431   apply (erule exE, erule conjE)
   432   apply (drule rtrancl_trans, assumption)
   433   apply (drule rtrancl_into_trancl2, assumption, assumption)
   434   done
   435 
   436 lemmas transitive_closure_trans [trans] =
   437   r_r_into_trancl trancl_trans rtrancl_trans
   438   trancl_into_trancl trancl_into_trancl2
   439   rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   440   rtrancl_trancl_trancl trancl_rtrancl_trancl
   441 
   442 declare trancl_into_rtrancl [elim]
   443 
   444 declare rtranclE [cases set: rtrancl]
   445 declare tranclE [cases set: trancl]
   446 
   447 end