src/Pure/library.ML
author wenzelm
Mon Mar 19 21:16:19 2012 +0100 (2012-03-19)
changeset 47023 c7a89ecbc71e
parent 47022 8eac39af4ec0
child 47060 e2741ec9ae36
permissions -rw-r--r--
discontinued remains of duplicate exception UnequalLengths (cf. 441260986b63);
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*user errors*)
    32   exception ERROR of string
    33   val error: string -> 'a
    34   val cat_error: string -> string -> 'a
    35   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    36 
    37   (*pairs*)
    38   val pair: 'a -> 'b -> 'a * 'b
    39   val rpair: 'a -> 'b -> 'b * 'a
    40   val fst: 'a * 'b -> 'a
    41   val snd: 'a * 'b -> 'b
    42   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    43   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    44   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val swap: 'a * 'b -> 'b * 'a
    46   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    47   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    48   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    49 
    50   (*booleans*)
    51   val equal: ''a -> ''a -> bool
    52   val not_equal: ''a -> ''a -> bool
    53   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    54   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    55   val exists: ('a -> bool) -> 'a list -> bool
    56   val forall: ('a -> bool) -> 'a list -> bool
    57   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    58   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    59 
    60   (*lists*)
    61   val single: 'a -> 'a list
    62   val the_single: 'a list -> 'a
    63   val singleton: ('a list -> 'b list) -> 'a -> 'b
    64   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    65   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    66   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    67   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    68   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    69   val eq_list: ('a * 'a -> bool) -> 'a list * 'a list -> bool
    70   val maps: ('a -> 'b list) -> 'a list -> 'b list
    71   val filter: ('a -> bool) -> 'a list -> 'a list
    72   val filter_out: ('a -> bool) -> 'a list -> 'a list
    73   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    74   val take: int -> 'a list -> 'a list
    75   val drop: int -> 'a list -> 'a list
    76   val chop: int -> 'a list -> 'a list * 'a list
    77   val chop_while: ('a -> bool) -> 'a list -> 'a list * 'a list
    78   val chop_groups: int -> 'a list -> 'a list list
    79   val nth: 'a list -> int -> 'a
    80   val nth_list: 'a list list -> int -> 'a list
    81   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    82   val nth_drop: int -> 'a list -> 'a list
    83   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    84   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    85   val map_range: (int -> 'a) -> int -> 'a list
    86   val split_last: 'a list -> 'a list * 'a
    87   val find_first: ('a -> bool) -> 'a list -> 'a option
    88   val find_index: ('a -> bool) -> 'a list -> int
    89   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    90   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    91   val flat: 'a list list -> 'a list
    92   val unflat: 'a list list -> 'b list -> 'b list list
    93   val grouped: int -> (('a list -> 'b list) -> 'c list list -> 'd list list) ->
    94     ('a -> 'b) -> 'c list -> 'd list
    95   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    96   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    97   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    98   val separate: 'a -> 'a list -> 'a list
    99   val surround: 'a -> 'a list -> 'a list
   100   val replicate: int -> 'a -> 'a list
   101   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   102   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   103   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   104   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   105   val fold_rev2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   106   val forall2: ('a -> 'b -> bool) -> 'a list -> 'b list -> bool
   107   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   108   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   109   val ~~ : 'a list * 'b list -> ('a * 'b) list
   110   val split_list: ('a * 'b) list -> 'a list * 'b list
   111   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
   112   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   113   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   114   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val prefixes: 'a list -> 'a list list
   118   val suffixes1: 'a list -> 'a list list
   119   val suffixes: 'a list -> 'a list list
   120 
   121   (*integers*)
   122   val upto: int * int -> int list
   123   val downto: int * int -> int list
   124   val radixpand: int * int -> int list
   125   val radixstring: int * string * int -> string
   126   val string_of_int: int -> string
   127   val signed_string_of_int: int -> string
   128   val string_of_indexname: string * int -> string
   129   val read_radix_int: int -> string list -> int * string list
   130   val read_int: string list -> int * string list
   131   val oct_char: string -> string
   132 
   133   (*strings*)
   134   val nth_string: string -> int -> string
   135   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   136   val exists_string: (string -> bool) -> string -> bool
   137   val forall_string: (string -> bool) -> string -> bool
   138   val first_field: string -> string -> (string * string) option
   139   val enclose: string -> string -> string -> string
   140   val unenclose: string -> string
   141   val quote: string -> string
   142   val space_implode: string -> string list -> string
   143   val commas: string list -> string
   144   val commas_quote: string list -> string
   145   val cat_lines: string list -> string
   146   val space_explode: string -> string -> string list
   147   val split_lines: string -> string list
   148   val prefix_lines: string -> string -> string
   149   val prefix: string -> string -> string
   150   val suffix: string -> string -> string
   151   val unprefix: string -> string -> string
   152   val unsuffix: string -> string -> string
   153   val replicate_string: int -> string -> string
   154   val translate_string: (string -> string) -> string -> string
   155   val match_string: string -> string -> bool
   156 
   157   (*reals*)
   158   val string_of_real: real -> string
   159   val signed_string_of_real: real -> string
   160   val smart_string_of_real: real -> string
   161 
   162   (*lists as sets -- see also Pure/General/ord_list.ML*)
   163   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   164   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   165   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   166   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   167   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   168   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   169   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   170   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   171   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   172   val eq_set: ('a * 'a -> bool) -> 'a list * 'a list -> bool
   173   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   174   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   175   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   176   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   177 
   178   (*lists as multisets*)
   179   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   180   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   181   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   182 
   183   (*orders*)
   184   val is_equal: order -> bool
   185   val rev_order: order -> order
   186   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   187   val bool_ord: bool * bool -> order
   188   val int_ord: int * int -> order
   189   val string_ord: string * string -> order
   190   val fast_string_ord: string * string -> order
   191   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   192   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   193   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   194   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   195   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   196   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   197   val sort_strings: string list -> string list
   198   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   199   val tag_list: int -> 'a list -> (int * 'a) list
   200   val untag_list: (int * 'a) list -> 'a list
   201   val order_list: (int * 'a) list -> 'a list
   202 
   203   (*random numbers*)
   204   exception RANDOM
   205   val random: unit -> real
   206   val random_range: int -> int -> int
   207   val one_of: 'a list -> 'a
   208   val frequency: (int * 'a) list -> 'a
   209 
   210   (*misc*)
   211   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   212   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   213     'a -> 'b -> 'c * 'b
   214   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   215   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   216   type serial = int
   217   val serial: unit -> serial
   218   val serial_string: unit -> string
   219   eqtype stamp
   220   val stamp: unit -> stamp
   221   structure Object: sig type T = exn end
   222   val cd: string -> unit
   223   val pwd: unit -> string
   224   val getenv: string -> string
   225   val getenv_strict: string -> string
   226 end;
   227 
   228 signature LIBRARY =
   229 sig
   230   include BASIC_LIBRARY
   231   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   232   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   233 end;
   234 
   235 structure Library: LIBRARY =
   236 struct
   237 
   238 (* functions *)
   239 
   240 fun undefined _ = raise Match;
   241 
   242 fun I x = x;
   243 fun K x = fn _ => x;
   244 fun curry f x y = f (x, y);
   245 fun uncurry f (x, y) = f x y;
   246 
   247 (*conditional application*)
   248 fun b ? f = fn x => if b then f x else x;
   249 
   250 (*composition with multiple args*)
   251 fun (f oo g) x y = f (g x y);
   252 fun (f ooo g) x y z = f (g x y z);
   253 fun (f oooo g) x y z w = f (g x y z w);
   254 
   255 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   256 fun funpow (0 : int) _ = I
   257   | funpow n f = f #> funpow (n - 1) f;
   258 
   259 fun funpow_yield (0 : int) _ x = ([], x)
   260   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   261 
   262 
   263 (* user errors *)
   264 
   265 exception ERROR of string;
   266 fun error msg = raise ERROR msg;
   267 
   268 fun cat_error "" msg = error msg
   269   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   270 
   271 fun assert_all pred list msg =
   272   let
   273     fun ass [] = ()
   274       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   275   in ass list end;
   276 
   277 
   278 (* pairs *)
   279 
   280 fun pair x y = (x, y);
   281 fun rpair x y = (y, x);
   282 
   283 fun fst (x, y) = x;
   284 fun snd (x, y) = y;
   285 
   286 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   287 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   288 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   289 
   290 fun swap (x, y) = (y, x);
   291 
   292 fun apfst f (x, y) = (f x, y);
   293 fun apsnd f (x, y) = (x, f y);
   294 fun pairself f (x, y) = (f x, f y);
   295 
   296 
   297 (* booleans *)
   298 
   299 (*polymorphic equality*)
   300 fun equal x y = x = y;
   301 fun not_equal x y = x <> y;
   302 
   303 (*combining predicates*)
   304 fun p orf q = fn x => p x orelse q x;
   305 fun p andf q = fn x => p x andalso q x;
   306 
   307 val exists = List.exists;
   308 val forall = List.all;
   309 
   310 
   311 (* flags *)
   312 
   313 fun setmp_CRITICAL flag value f x =
   314   NAMED_CRITICAL "setmp" (fn () => Unsynchronized.setmp flag value f x);
   315 
   316 fun setmp_thread_data tag orig_data data f x =
   317   uninterruptible (fn restore_attributes => fn () =>
   318     let
   319       val _ = Thread.setLocal (tag, data);
   320       val result = Exn.capture (restore_attributes f) x;
   321       val _ = Thread.setLocal (tag, orig_data);
   322     in Exn.release result end) ();
   323 
   324 
   325 
   326 (** lists **)
   327 
   328 fun single x = [x];
   329 
   330 fun the_single [x] = x
   331   | the_single _ = raise Empty;
   332 
   333 fun singleton f x = the_single (f [x]);
   334 
   335 fun yield_singleton f x = f [x] #>> the_single;
   336 
   337 fun perhaps_apply funs arg =
   338   let
   339     fun app [] res = res
   340       | app (f :: fs) (changed, x) =
   341           (case f x of
   342             NONE => app fs (changed, x)
   343           | SOME x' => app fs (true, x'));
   344   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   345 
   346 fun perhaps_loop f arg =
   347   let
   348     fun loop (changed, x) =
   349       (case f x of
   350         NONE => (changed, x)
   351       | SOME x' => loop (true, x'));
   352   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   353 
   354 
   355 (* fold -- old versions *)
   356 
   357 (*the following versions of fold are designed to fit nicely with infixes*)
   358 
   359 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   360     for operators that associate to the left (TAIL RECURSIVE)*)
   361 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   362   let fun itl (e, [])  = e
   363         | itl (e, a::l) = itl (f(e, a), l)
   364   in  itl end;
   365 
   366 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   367     for operators that associate to the right (not tail recursive)*)
   368 fun foldr f (l, e) =
   369   let fun itr [] = e
   370         | itr (a::l) = f(a, itr l)
   371   in  itr l  end;
   372 
   373 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   374     for operators that associate to the left (TAIL RECURSIVE)*)
   375 fun foldl1 f [] = raise Empty
   376   | foldl1 f (x :: xs) = foldl f (x, xs);
   377 
   378 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   379     for n > 0, operators that associate to the right (not tail recursive)*)
   380 fun foldr1 f [] = raise Empty
   381   | foldr1 f l =
   382       let fun itr [x] = x
   383             | itr (x::l) = f(x, itr l)
   384       in  itr l  end;
   385 
   386 
   387 (* basic list functions *)
   388 
   389 fun eq_list eq (list1, list2) =
   390   pointer_eq (list1, list2) orelse
   391     let
   392       fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   393         | eq_lst _ = true;
   394     in length list1 = length list2 andalso eq_lst (list1, list2) end;
   395 
   396 fun maps f [] = []
   397   | maps f (x :: xs) = f x @ maps f xs;
   398 
   399 val filter = List.filter;
   400 fun filter_out f = filter (not o f);
   401 val map_filter = List.mapPartial;
   402 
   403 fun take (0: int) xs = []
   404   | take _ [] = []
   405   | take n (x :: xs) = x :: take (n - 1) xs;
   406 
   407 fun drop (0: int) xs = xs
   408   | drop _ [] = []
   409   | drop n (x :: xs) = drop (n - 1) xs;
   410 
   411 fun chop (0: int) xs = ([], xs)
   412   | chop _ [] = ([], [])
   413   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   414 
   415 fun chop_while P [] = ([], [])
   416   | chop_while P (ys as x :: xs) =
   417       if P x then chop_while P xs |>> cons x else ([], ys);
   418 
   419 fun chop_groups n list =
   420   (case chop (Int.max (n, 1)) list of
   421     ([], _) => []
   422   | (g, rest) => g :: chop_groups n rest);
   423 
   424 
   425 (*return nth element of a list, where 0 designates the first element;
   426   raise Subscript if list too short*)
   427 fun nth xs i = List.nth (xs, i);
   428 
   429 fun nth_list xss i = nth xss i handle General.Subscript => [];
   430 
   431 fun nth_map 0 f (x :: xs) = f x :: xs
   432   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   433   | nth_map (_: int) _ [] = raise Subscript;
   434 
   435 fun nth_drop n xs =
   436   List.take (xs, n) @ List.drop (xs, n + 1);
   437 
   438 fun map_index f =
   439   let
   440     fun mapp (_: int) [] = []
   441       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   442   in mapp 0 end;
   443 
   444 fun fold_index f =
   445   let
   446     fun fold_aux (_: int) [] y = y
   447       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   448   in fold_aux 0 end;
   449 
   450 fun map_range f i =
   451   let
   452     fun mapp (k: int) =
   453       if k < i then f k :: mapp (k + 1) else [];
   454   in mapp 0 end;
   455 
   456 (*rear decomposition*)
   457 fun split_last [] = raise Empty
   458   | split_last [x] = ([], x)
   459   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   460 
   461 (*find first element satisfying predicate*)
   462 val find_first = List.find;
   463 
   464 (*find position of first element satisfying a predicate*)
   465 fun find_index pred =
   466   let fun find (_: int) [] = ~1
   467         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   468   in find 0 end;
   469 
   470 (*get first element by lookup function*)
   471 fun get_first _ [] = NONE
   472   | get_first f (x :: xs) =
   473       (case f x of
   474         NONE => get_first f xs
   475       | some => some);
   476 
   477 fun get_index f =
   478   let
   479     fun get (_: int) [] = NONE
   480       | get i (x :: xs) =
   481           (case f x of
   482             NONE => get (i + 1) xs
   483           | SOME y => SOME (i, y))
   484   in get 0 end;
   485 
   486 val flat = List.concat;
   487 
   488 fun unflat (xs :: xss) ys =
   489       let val (ps, qs) = chop (length xs) ys
   490       in ps :: unflat xss qs end
   491   | unflat [] [] = []
   492   | unflat _ _ = raise ListPair.UnequalLengths;
   493 
   494 fun grouped n comb f = chop_groups n #> comb (map f) #> flat;
   495 
   496 fun burrow f xss = unflat xss (f (flat xss));
   497 
   498 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   499 
   500 fun fold_burrow f xss s =
   501   apfst (unflat xss) (f (flat xss) s);
   502 
   503 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   504 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   505   | separate _ xs = xs;
   506 
   507 fun surround s (x :: xs) = s :: x :: surround s xs
   508   | surround s [] = [s];
   509 
   510 (*make the list [x, x, ..., x] of length n*)
   511 fun replicate (n: int) x =
   512   let fun rep (0, xs) = xs
   513         | rep (n, xs) = rep (n - 1, x :: xs)
   514   in
   515     if n < 0 then raise Subscript
   516     else rep (n, [])
   517   end;
   518 
   519 
   520 (* direct product *)
   521 
   522 fun map_product f _ [] = []
   523   | map_product f [] _ = []
   524   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   525 
   526 fun fold_product f _ [] z = z
   527   | fold_product f [] _ z = z
   528   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   529 
   530 
   531 (* lists of pairs *)
   532 
   533 fun map2 _ [] [] = []
   534   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   535   | map2 _ _ _ = raise ListPair.UnequalLengths;
   536 
   537 fun fold2 f [] [] z = z
   538   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   539   | fold2 f _ _ _ = raise ListPair.UnequalLengths;
   540 
   541 fun fold_rev2 f [] [] z = z
   542   | fold_rev2 f (x :: xs) (y :: ys) z = f x y (fold_rev2 f xs ys z)
   543   | fold_rev2 f _ _ _ = raise ListPair.UnequalLengths;
   544 
   545 fun forall2 P [] [] = true
   546   | forall2 P (x :: xs) (y :: ys) = P x y andalso forall2 P xs ys
   547   | forall2 P _ _ = raise ListPair.UnequalLengths;
   548 
   549 fun map_split f [] = ([], [])
   550   | map_split f (x :: xs) =
   551       let
   552         val (y, w) = f x;
   553         val (ys, ws) = map_split f xs;
   554       in (y :: ys, w :: ws) end;
   555 
   556 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   557   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   558   | zip_options _ [] = []
   559   | zip_options [] _ = raise ListPair.UnequalLengths;
   560 
   561 (*combine two lists forming a list of pairs:
   562   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   563 fun [] ~~ [] = []
   564   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   565   | _ ~~ _ = raise ListPair.UnequalLengths;
   566 
   567 (*inverse of ~~; the old 'split':
   568   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   569 val split_list = ListPair.unzip;
   570 
   571 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   572 
   573 
   574 (* prefixes, suffixes *)
   575 
   576 fun is_prefix _ [] _ = true
   577   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   578   | is_prefix eq _ _ = false;
   579 
   580 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   581    where xi is the first element that does not satisfy the predicate*)
   582 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   583   let fun take (rxs, []) = (rev rxs, [])
   584         | take (rxs, x :: xs) =
   585             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   586   in  take([], xs)  end;
   587 
   588 fun chop_prefix eq ([], ys) = ([], ([], ys))
   589   | chop_prefix eq (xs, []) = ([], (xs, []))
   590   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   591       if eq (x, y) then
   592         let val (ps', xys'') = chop_prefix eq (xs', ys')
   593         in (x :: ps', xys'') end
   594       else ([], (xs, ys));
   595 
   596 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   597    where xi is the last element that does not satisfy the predicate*)
   598 fun take_suffix _ [] = ([], [])
   599   | take_suffix pred (x :: xs) =
   600       (case take_suffix pred xs of
   601         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   602       | (prfx, sffx) => (x :: prfx, sffx));
   603 
   604 fun prefixes1 [] = []
   605   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   606 
   607 fun prefixes xs = [] :: prefixes1 xs;
   608 
   609 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   610 fun suffixes xs = [] :: suffixes1 xs;
   611 
   612 
   613 
   614 (** integers **)
   615 
   616 (* lists of integers *)
   617 
   618 (*make the list [from, from + 1, ..., to]*)
   619 fun ((i: int) upto j) =
   620   if i > j then [] else i :: (i + 1 upto j);
   621 
   622 (*make the list [from, from - 1, ..., to]*)
   623 fun ((i: int) downto j) =
   624   if i < j then [] else i :: (i - 1 downto j);
   625 
   626 
   627 (* convert integers to strings *)
   628 
   629 (*expand the number in the given base;
   630   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   631 fun radixpand (base, num) : int list =
   632   let
   633     fun radix (n, tail) =
   634       if n < base then n :: tail
   635       else radix (n div base, (n mod base) :: tail)
   636   in radix (num, []) end;
   637 
   638 (*expands a number into a string of characters starting from "zerochar";
   639   example: radixstring (2, "0", 8) gives "1000"*)
   640 fun radixstring (base, zerochar, num) =
   641   let val offset = ord zerochar;
   642       fun chrof n = chr (offset + n)
   643   in implode (map chrof (radixpand (base, num))) end;
   644 
   645 
   646 local
   647   val zero = ord "0";
   648   val small = 10000: int;
   649   val small_table = Vector.tabulate (small, Int.toString);
   650 in
   651 
   652 fun string_of_int i =
   653   if i < 0 then Int.toString i
   654   else if i < 10 then chr (zero + i)
   655   else if i < small then Vector.sub (small_table, i)
   656   else Int.toString i;
   657 
   658 end;
   659 
   660 fun signed_string_of_int i =
   661   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   662 
   663 fun string_of_indexname (a, 0) = a
   664   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   665 
   666 
   667 (* read integers *)
   668 
   669 fun read_radix_int radix cs =
   670   let
   671     val zero = ord "0";
   672     val limit = zero + radix;
   673     fun scan (num, []) = (num, [])
   674       | scan (num, c :: cs) =
   675         if zero <= ord c andalso ord c < limit then
   676           scan (radix * num + (ord c - zero), cs)
   677         else (num, c :: cs);
   678   in scan (0, cs) end;
   679 
   680 val read_int = read_radix_int 10;
   681 
   682 fun oct_char s = chr (#1 (read_radix_int 8 (raw_explode s)));
   683 
   684 
   685 
   686 (** strings **)
   687 
   688 (* functions tuned for strings, avoiding explode *)
   689 
   690 fun nth_string str i =
   691   (case try String.substring (str, i, 1) of
   692     SOME s => s
   693   | NONE => raise Subscript);
   694 
   695 fun fold_string f str x0 =
   696   let
   697     val n = size str;
   698     fun iter (x, i) =
   699       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   700   in iter (x0, 0) end;
   701 
   702 fun exists_string pred str =
   703   let
   704     val n = size str;
   705     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   706   in ex 0 end;
   707 
   708 fun forall_string pred = not o exists_string (not o pred);
   709 
   710 fun first_field sep str =
   711   let
   712     val n = size sep;
   713     val len = size str;
   714     fun find i =
   715       if i + n > len then NONE
   716       else if String.substring (str, i, n) = sep then SOME i
   717       else find (i + 1);
   718   in
   719     (case find 0 of
   720       NONE => NONE
   721     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   722   end;
   723 
   724 (*enclose in brackets*)
   725 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   726 fun unenclose str = String.substring (str, 1, size str - 2);
   727 
   728 (*simple quoting (does not escape special chars)*)
   729 val quote = enclose "\"" "\"";
   730 
   731 fun space_implode a bs = implode (separate a bs);
   732 
   733 val commas = space_implode ", ";
   734 val commas_quote = commas o map quote;
   735 
   736 val cat_lines = space_implode "\n";
   737 
   738 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   739 fun space_explode _ "" = []
   740   | space_explode sep s = String.fields (fn c => str c = sep) s;
   741 
   742 val split_lines = space_explode "\n";
   743 
   744 fun prefix_lines "" txt = txt
   745   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   746 
   747 fun prefix prfx s = prfx ^ s;
   748 fun suffix sffx s = s ^ sffx;
   749 
   750 fun unprefix prfx s =
   751   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   752   else raise Fail "unprefix";
   753 
   754 fun unsuffix sffx s =
   755   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   756   else raise Fail "unsuffix";
   757 
   758 fun replicate_string (0: int) _ = ""
   759   | replicate_string 1 a = a
   760   | replicate_string k a =
   761       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   762       else replicate_string (k div 2) (a ^ a) ^ a;
   763 
   764 fun translate_string f = String.translate (f o String.str);
   765 
   766 (*crude matching of str against simple glob pat*)
   767 fun match_string pat str =
   768   let
   769     fun match [] _ = true
   770       | match (p :: ps) s =
   771           size p <= size s andalso
   772             (case try (unprefix p) s of
   773               SOME s' => match ps s'
   774             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   775   in match (space_explode "*" pat) str end;
   776 
   777 
   778 (** reals **)
   779 
   780 val string_of_real = Real.fmt (StringCvt.GEN NONE);
   781 
   782 fun signed_string_of_real x =
   783   if x < 0.0 then "-" ^ string_of_real (~ x) else string_of_real x;
   784 
   785 fun smart_string_of_real x =
   786   let
   787     val s = signed_string_of_real x;
   788   in
   789     (case space_explode "." s of
   790       [a, b] => if forall_string (fn c => c = "0") b then a else s
   791     | _ => s)
   792   end;
   793 
   794 
   795 
   796 (** lists as sets -- see also Pure/General/ord_list.ML **)
   797 
   798 (* canonical operations *)
   799 
   800 fun member eq list x =
   801   let
   802     fun memb [] = false
   803       | memb (y :: ys) = eq (x, y) orelse memb ys;
   804   in memb list end;
   805 
   806 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   807 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   808 fun update eq x xs = cons x (remove eq x xs);
   809 
   810 fun inter eq xs = filter (member eq xs);
   811 
   812 fun union eq = fold (insert eq);
   813 fun subtract eq = fold (remove eq);
   814 
   815 fun merge eq (xs, ys) =
   816   if pointer_eq (xs, ys) then xs
   817   else if null xs then ys
   818   else fold_rev (insert eq) ys xs;
   819 
   820 
   821 (* subset and set equality *)
   822 
   823 fun subset eq (xs, ys) = forall (member eq ys) xs;
   824 
   825 fun eq_set eq (xs, ys) =
   826   eq_list eq (xs, ys) orelse
   827     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   828 
   829 
   830 (*makes a list of the distinct members of the input; preserves order, takes
   831   first of equal elements*)
   832 fun distinct eq lst =
   833   let
   834     fun dist (rev_seen, []) = rev rev_seen
   835       | dist (rev_seen, x :: xs) =
   836           if member eq rev_seen x then dist (rev_seen, xs)
   837           else dist (x :: rev_seen, xs);
   838   in dist ([], lst) end;
   839 
   840 (*returns a list containing all repeated elements exactly once; preserves
   841   order, takes first of equal elements*)
   842 fun duplicates eq lst =
   843   let
   844     fun dups (rev_dups, []) = rev rev_dups
   845       | dups (rev_dups, x :: xs) =
   846           if member eq rev_dups x orelse not (member eq xs x) then
   847             dups (rev_dups, xs)
   848           else dups (x :: rev_dups, xs);
   849   in dups ([], lst) end;
   850 
   851 fun has_duplicates eq =
   852   let
   853     fun dups [] = false
   854       | dups (x :: xs) = member eq xs x orelse dups xs;
   855   in dups end;
   856 
   857 
   858 (* matrices *)
   859 
   860 fun map_transpose f xss =
   861   let
   862     val n =
   863       (case distinct (op =) (map length xss) of
   864         [] => 0
   865       | [n] => n
   866       | _ => raise ListPair.UnequalLengths);
   867   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   868 
   869 
   870 
   871 (** lists as multisets **)
   872 
   873 fun remove1 eq x [] = []
   874   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   875 
   876 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   877 
   878 fun submultiset _ ([], _)  = true
   879   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   880 
   881 
   882 
   883 (** orders **)
   884 
   885 fun is_equal EQUAL = true
   886   | is_equal _ = false;
   887 
   888 fun rev_order LESS = GREATER
   889   | rev_order EQUAL = EQUAL
   890   | rev_order GREATER = LESS;
   891 
   892 (*assume rel is a linear strict order*)
   893 fun make_ord rel (x, y) =
   894   if rel (x, y) then LESS
   895   else if rel (y, x) then GREATER
   896   else EQUAL;
   897 
   898 fun bool_ord (false, true) = LESS
   899   | bool_ord (true, false) = GREATER
   900   | bool_ord _ = EQUAL;
   901 
   902 val int_ord = Int.compare;
   903 val string_ord = String.compare;
   904 
   905 fun fast_string_ord (s1, s2) =
   906   if pointer_eq (s1, s2) then EQUAL
   907   else (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   908 
   909 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   910   | option_ord _ (NONE, NONE) = EQUAL
   911   | option_ord _ (NONE, SOME _) = LESS
   912   | option_ord _ (SOME _, NONE) = GREATER;
   913 
   914 (*lexicographic product*)
   915 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   916   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   917 
   918 (*dictionary order -- in general NOT well-founded!*)
   919 fun dict_ord elem_ord (x :: xs, y :: ys) =
   920       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   921   | dict_ord _ ([], []) = EQUAL
   922   | dict_ord _ ([], _ :: _) = LESS
   923   | dict_ord _ (_ :: _, []) = GREATER;
   924 
   925 (*lexicographic product of lists*)
   926 fun list_ord elem_ord (xs, ys) =
   927   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   928 
   929 
   930 (* sorting *)
   931 
   932 (*quicksort -- stable, i.e. does not reorder equal elements*)
   933 fun quicksort unique ord =
   934   let
   935     fun qsort [] = []
   936       | qsort (xs as [_]) = xs
   937       | qsort (xs as [x, y]) =
   938           (case ord (x, y) of
   939             LESS => xs
   940           | EQUAL => if unique then [x] else xs
   941           | GREATER => [y, x])
   942       | qsort xs =
   943           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   944           in qsort lts @ eqs @ qsort gts end
   945     and part _ [] = ([], [], [])
   946       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   947     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   948       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   949       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   950       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   951   in qsort end;
   952 
   953 fun sort ord = quicksort false ord;
   954 fun sort_distinct ord = quicksort true ord;
   955 
   956 val sort_strings = sort string_ord;
   957 fun sort_wrt key xs = sort (string_ord o pairself key) xs;
   958 
   959 
   960 (* items tagged by integer index *)
   961 
   962 (*insert tags*)
   963 fun tag_list k [] = []
   964   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   965 
   966 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   967 fun untag_list [] = []
   968   | untag_list [(k: int, x)] = [x]
   969   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   970       if k = k' then untag_list rest
   971       else x :: untag_list rest;
   972 
   973 (*return list elements in original order*)
   974 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   975 
   976 
   977 
   978 (** random numbers **)
   979 
   980 exception RANDOM;
   981 
   982 fun rmod x y = x - y * Real.realFloor (x / y);
   983 
   984 local
   985   val a = 16807.0;
   986   val m = 2147483647.0;
   987   val random_seed = Unsynchronized.ref 1.0;
   988 in
   989 
   990 fun random () = CRITICAL (fn () =>
   991   let val r = rmod (a * ! random_seed) m
   992   in (random_seed := r; r) end);
   993 
   994 end;
   995 
   996 fun random_range l h =
   997   if h < l orelse l < 0 then raise RANDOM
   998   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   999 
  1000 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1001 
  1002 fun frequency xs =
  1003   let
  1004     val sum = foldl op + (0, map fst xs);
  1005     fun pick n ((k: int, x) :: xs) =
  1006       if n <= k then x else pick (n - k) xs
  1007   in pick (random_range 1 sum) xs end;
  1008 
  1009 
  1010 
  1011 (** misc **)
  1012 
  1013 fun divide_and_conquer decomp x =
  1014   let val (ys, recomb) = decomp x
  1015   in recomb (map (divide_and_conquer decomp) ys) end;
  1016 
  1017 fun divide_and_conquer' decomp x s =
  1018   let val ((ys, recomb), s') = decomp x s
  1019   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1020 
  1021 
  1022 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1023    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1024 fun partition_list p i j =
  1025   let
  1026     fun part (k: int) xs =
  1027       if k > j then
  1028         (case xs of
  1029           [] => []
  1030         | _ => raise Fail "partition_list")
  1031       else
  1032         let val (ns, rest) = List.partition (p k) xs
  1033         in ns :: part (k + 1) rest end;
  1034   in part (i: int) end;
  1035 
  1036 fun partition_eq (eq: 'a * 'a -> bool) =
  1037   let
  1038     fun part [] = []
  1039       | part (x :: ys) =
  1040           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1041           in (x :: xs) :: part xs' end;
  1042   in part end;
  1043 
  1044 
  1045 (* serial numbers and abstract stamps *)
  1046 
  1047 type serial = int;
  1048 val serial = Multithreading.serial;
  1049 val serial_string = string_of_int o serial;
  1050 
  1051 datatype stamp = Stamp of serial;
  1052 fun stamp () = Stamp (serial ());
  1053 
  1054 
  1055 (* generic objects *)
  1056 
  1057 (*note that the builtin exception datatype may be extended by new
  1058   constructors at any time*)
  1059 structure Object = struct type T = exn end;
  1060 
  1061 
  1062 (* current directory *)
  1063 
  1064 val cd = OS.FileSys.chDir;
  1065 val pwd = OS.FileSys.getDir;
  1066 
  1067 
  1068 (* getenv *)
  1069 
  1070 fun getenv x =
  1071   (case OS.Process.getEnv x of
  1072     NONE => ""
  1073   | SOME y => y);
  1074 
  1075 fun getenv_strict x =
  1076   (case getenv x of
  1077     "" => error ("Undefined Isabelle environment variable: " ^ quote x)
  1078   | y => y);
  1079 
  1080 end;
  1081 
  1082 structure Basic_Library: BASIC_LIBRARY = Library;
  1083 open Basic_Library;
  1084