src/HOL/Complex.thy
author wenzelm
Mon Mar 22 20:58:52 2010 +0100 (2010-03-22)
changeset 35898 c890a3835d15
parent 31492 5400beeddb55
child 36349 39be26d1bc28
permissions -rw-r--r--
recovered header;
     1 (*  Title:       Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec
    16   Re :: "complex \<Rightarrow> real"
    17 where
    18   Re: "Re (Complex x y) = x"
    19 
    20 primrec
    21   Im :: "complex \<Rightarrow> real"
    22 where
    23   Im: "Im (Complex x y) = y"
    24 
    25 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    26   by (induct z) simp
    27 
    28 lemma complex_equality [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    29   by (induct x, induct y) simp
    30 
    31 lemma expand_complex_eq: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    32   by (induct x, induct y) simp
    33 
    34 lemmas complex_Re_Im_cancel_iff = expand_complex_eq
    35 
    36 
    37 subsection {* Addition and Subtraction *}
    38 
    39 instantiation complex :: ab_group_add
    40 begin
    41 
    42 definition
    43   complex_zero_def: "0 = Complex 0 0"
    44 
    45 definition
    46   complex_add_def: "x + y = Complex (Re x + Re y) (Im x + Im y)"
    47 
    48 definition
    49   complex_minus_def: "- x = Complex (- Re x) (- Im x)"
    50 
    51 definition
    52   complex_diff_def: "x - (y\<Colon>complex) = x + - y"
    53 
    54 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    55   by (simp add: complex_zero_def)
    56 
    57 lemma complex_Re_zero [simp]: "Re 0 = 0"
    58   by (simp add: complex_zero_def)
    59 
    60 lemma complex_Im_zero [simp]: "Im 0 = 0"
    61   by (simp add: complex_zero_def)
    62 
    63 lemma complex_add [simp]:
    64   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    65   by (simp add: complex_add_def)
    66 
    67 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    68   by (simp add: complex_add_def)
    69 
    70 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    71   by (simp add: complex_add_def)
    72 
    73 lemma complex_minus [simp]:
    74   "- (Complex a b) = Complex (- a) (- b)"
    75   by (simp add: complex_minus_def)
    76 
    77 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    78   by (simp add: complex_minus_def)
    79 
    80 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    81   by (simp add: complex_minus_def)
    82 
    83 lemma complex_diff [simp]:
    84   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    85   by (simp add: complex_diff_def)
    86 
    87 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    88   by (simp add: complex_diff_def)
    89 
    90 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    91   by (simp add: complex_diff_def)
    92 
    93 instance
    94   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    95 
    96 end
    97 
    98 
    99 
   100 subsection {* Multiplication and Division *}
   101 
   102 instantiation complex :: "{field, division_by_zero}"
   103 begin
   104 
   105 definition
   106   complex_one_def: "1 = Complex 1 0"
   107 
   108 definition
   109   complex_mult_def: "x * y =
   110     Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   111 
   112 definition
   113   complex_inverse_def: "inverse x =
   114     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"
   115 
   116 definition
   117   complex_divide_def: "x / (y\<Colon>complex) = x * inverse y"
   118 
   119 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"
   120   by (simp add: complex_one_def)
   121 
   122 lemma complex_Re_one [simp]: "Re 1 = 1"
   123   by (simp add: complex_one_def)
   124 
   125 lemma complex_Im_one [simp]: "Im 1 = 0"
   126   by (simp add: complex_one_def)
   127 
   128 lemma complex_mult [simp]:
   129   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   130   by (simp add: complex_mult_def)
   131 
   132 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   133   by (simp add: complex_mult_def)
   134 
   135 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   136   by (simp add: complex_mult_def)
   137 
   138 lemma complex_inverse [simp]:
   139   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"
   140   by (simp add: complex_inverse_def)
   141 
   142 lemma complex_Re_inverse:
   143   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   144   by (simp add: complex_inverse_def)
   145 
   146 lemma complex_Im_inverse:
   147   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   148   by (simp add: complex_inverse_def)
   149 
   150 instance
   151   by intro_classes (simp_all add: complex_mult_def
   152   right_distrib left_distrib right_diff_distrib left_diff_distrib
   153   complex_inverse_def complex_divide_def
   154   power2_eq_square add_divide_distrib [symmetric]
   155   expand_complex_eq)
   156 
   157 end
   158 
   159 
   160 subsection {* Numerals and Arithmetic *}
   161 
   162 instantiation complex :: number_ring
   163 begin
   164 
   165 definition number_of_complex where
   166   complex_number_of_def: "number_of w = (of_int w \<Colon> complex)"
   167 
   168 instance
   169   by intro_classes (simp only: complex_number_of_def)
   170 
   171 end
   172 
   173 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   174 by (induct n) simp_all
   175 
   176 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   177 by (induct n) simp_all
   178 
   179 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   180 by (cases z rule: int_diff_cases) simp
   181 
   182 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   183 by (cases z rule: int_diff_cases) simp
   184 
   185 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"
   186 unfolding number_of_eq by (rule complex_Re_of_int)
   187 
   188 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"
   189 unfolding number_of_eq by (rule complex_Im_of_int)
   190 
   191 lemma Complex_eq_number_of [simp]:
   192   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"
   193 by (simp add: expand_complex_eq)
   194 
   195 
   196 subsection {* Scalar Multiplication *}
   197 
   198 instantiation complex :: real_field
   199 begin
   200 
   201 definition
   202   complex_scaleR_def: "scaleR r x = Complex (r * Re x) (r * Im x)"
   203 
   204 lemma complex_scaleR [simp]:
   205   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   206   unfolding complex_scaleR_def by simp
   207 
   208 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   209   unfolding complex_scaleR_def by simp
   210 
   211 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   212   unfolding complex_scaleR_def by simp
   213 
   214 instance
   215 proof
   216   fix a b :: real and x y :: complex
   217   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   218     by (simp add: expand_complex_eq right_distrib)
   219   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   220     by (simp add: expand_complex_eq left_distrib)
   221   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   222     by (simp add: expand_complex_eq mult_assoc)
   223   show "scaleR 1 x = x"
   224     by (simp add: expand_complex_eq)
   225   show "scaleR a x * y = scaleR a (x * y)"
   226     by (simp add: expand_complex_eq algebra_simps)
   227   show "x * scaleR a y = scaleR a (x * y)"
   228     by (simp add: expand_complex_eq algebra_simps)
   229 qed
   230 
   231 end
   232 
   233 
   234 subsection{* Properties of Embedding from Reals *}
   235 
   236 abbreviation
   237   complex_of_real :: "real \<Rightarrow> complex" where
   238     "complex_of_real \<equiv> of_real"
   239 
   240 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   241 by (simp add: of_real_def complex_scaleR_def)
   242 
   243 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   244 by (simp add: complex_of_real_def)
   245 
   246 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   247 by (simp add: complex_of_real_def)
   248 
   249 lemma Complex_add_complex_of_real [simp]:
   250      "Complex x y + complex_of_real r = Complex (x+r) y"
   251 by (simp add: complex_of_real_def)
   252 
   253 lemma complex_of_real_add_Complex [simp]:
   254      "complex_of_real r + Complex x y = Complex (r+x) y"
   255 by (simp add: complex_of_real_def)
   256 
   257 lemma Complex_mult_complex_of_real:
   258      "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   259 by (simp add: complex_of_real_def)
   260 
   261 lemma complex_of_real_mult_Complex:
   262      "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   263 by (simp add: complex_of_real_def)
   264 
   265 
   266 subsection {* Vector Norm *}
   267 
   268 instantiation complex :: real_normed_field
   269 begin
   270 
   271 definition complex_norm_def:
   272   "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   273 
   274 abbreviation
   275   cmod :: "complex \<Rightarrow> real" where
   276   "cmod \<equiv> norm"
   277 
   278 definition complex_sgn_def:
   279   "sgn x = x /\<^sub>R cmod x"
   280 
   281 definition dist_complex_def:
   282   "dist x y = cmod (x - y)"
   283 
   284 definition open_complex_def [code del]:
   285   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   286 
   287 lemmas cmod_def = complex_norm_def
   288 
   289 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"
   290   by (simp add: complex_norm_def)
   291 
   292 instance proof
   293   fix r :: real and x y :: complex and S :: "complex set"
   294   show "0 \<le> norm x"
   295     by (induct x) simp
   296   show "(norm x = 0) = (x = 0)"
   297     by (induct x) simp
   298   show "norm (x + y) \<le> norm x + norm y"
   299     by (induct x, induct y)
   300        (simp add: real_sqrt_sum_squares_triangle_ineq)
   301   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   302     by (induct x)
   303        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)
   304   show "norm (x * y) = norm x * norm y"
   305     by (induct x, induct y)
   306        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   307   show "sgn x = x /\<^sub>R cmod x"
   308     by (rule complex_sgn_def)
   309   show "dist x y = cmod (x - y)"
   310     by (rule dist_complex_def)
   311   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   312     by (rule open_complex_def)
   313 qed
   314 
   315 end
   316 
   317 lemma cmod_unit_one [simp]: "cmod (Complex (cos a) (sin a)) = 1"
   318 by simp
   319 
   320 lemma cmod_complex_polar [simp]:
   321      "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   322 by (simp add: norm_mult)
   323 
   324 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   325 unfolding complex_norm_def
   326 by (rule real_sqrt_sum_squares_ge1)
   327 
   328 lemma complex_mod_minus_le_complex_mod [simp]: "- cmod x \<le> cmod x"
   329 by (rule order_trans [OF _ norm_ge_zero], simp)
   330 
   331 lemma complex_mod_triangle_ineq2 [simp]: "cmod(b + a) - cmod b \<le> cmod a"
   332 by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   333 
   334 lemmas real_sum_squared_expand = power2_sum [where 'a=real]
   335 
   336 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   337 by (cases x) simp
   338 
   339 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   340 by (cases x) simp
   341 
   342 subsection {* Completeness of the Complexes *}
   343 
   344 interpretation Re: bounded_linear "Re"
   345 apply (unfold_locales, simp, simp)
   346 apply (rule_tac x=1 in exI)
   347 apply (simp add: complex_norm_def)
   348 done
   349 
   350 interpretation Im: bounded_linear "Im"
   351 apply (unfold_locales, simp, simp)
   352 apply (rule_tac x=1 in exI)
   353 apply (simp add: complex_norm_def)
   354 done
   355 
   356 lemma LIMSEQ_Complex:
   357   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. Complex (X n) (Y n)) ----> Complex a b"
   358 apply (rule LIMSEQ_I)
   359 apply (subgoal_tac "0 < r / sqrt 2")
   360 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   361 apply (drule_tac r="r / sqrt 2" in LIMSEQ_D, safe)
   362 apply (rename_tac M N, rule_tac x="max M N" in exI, safe)
   363 apply (simp add: real_sqrt_sum_squares_less)
   364 apply (simp add: divide_pos_pos)
   365 done
   366 
   367 instance complex :: banach
   368 proof
   369   fix X :: "nat \<Rightarrow> complex"
   370   assume X: "Cauchy X"
   371   from Re.Cauchy [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   372     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   373   from Im.Cauchy [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   374     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   375   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   376     using LIMSEQ_Complex [OF 1 2] by simp
   377   thus "convergent X"
   378     by (rule convergentI)
   379 qed
   380 
   381 
   382 subsection {* The Complex Number @{term "\<i>"} *}
   383 
   384 definition
   385   "ii" :: complex  ("\<i>") where
   386   i_def: "ii \<equiv> Complex 0 1"
   387 
   388 lemma complex_Re_i [simp]: "Re ii = 0"
   389 by (simp add: i_def)
   390 
   391 lemma complex_Im_i [simp]: "Im ii = 1"
   392 by (simp add: i_def)
   393 
   394 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   395 by (simp add: i_def)
   396 
   397 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   398 by (simp add: expand_complex_eq)
   399 
   400 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   401 by (simp add: expand_complex_eq)
   402 
   403 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"
   404 by (simp add: expand_complex_eq)
   405 
   406 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   407 by (simp add: expand_complex_eq)
   408 
   409 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   410 by (simp add: expand_complex_eq)
   411 
   412 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   413 by (simp add: i_def complex_of_real_def)
   414 
   415 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   416 by (simp add: i_def complex_of_real_def)
   417 
   418 lemma i_squared [simp]: "ii * ii = -1"
   419 by (simp add: i_def)
   420 
   421 lemma power2_i [simp]: "ii\<twosuperior> = -1"
   422 by (simp add: power2_eq_square)
   423 
   424 lemma inverse_i [simp]: "inverse ii = - ii"
   425 by (rule inverse_unique, simp)
   426 
   427 
   428 subsection {* Complex Conjugation *}
   429 
   430 definition
   431   cnj :: "complex \<Rightarrow> complex" where
   432   "cnj z = Complex (Re z) (- Im z)"
   433 
   434 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   435 by (simp add: cnj_def)
   436 
   437 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   438 by (simp add: cnj_def)
   439 
   440 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   441 by (simp add: cnj_def)
   442 
   443 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   444 by (simp add: expand_complex_eq)
   445 
   446 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   447 by (simp add: cnj_def)
   448 
   449 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   450 by (simp add: expand_complex_eq)
   451 
   452 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   453 by (simp add: expand_complex_eq)
   454 
   455 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   456 by (simp add: expand_complex_eq)
   457 
   458 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   459 by (simp add: expand_complex_eq)
   460 
   461 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   462 by (simp add: expand_complex_eq)
   463 
   464 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   465 by (simp add: expand_complex_eq)
   466 
   467 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   468 by (simp add: expand_complex_eq)
   469 
   470 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   471 by (simp add: complex_inverse_def)
   472 
   473 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   474 by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   475 
   476 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   477 by (induct n, simp_all add: complex_cnj_mult)
   478 
   479 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   480 by (simp add: expand_complex_eq)
   481 
   482 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   483 by (simp add: expand_complex_eq)
   484 
   485 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"
   486 by (simp add: expand_complex_eq)
   487 
   488 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   489 by (simp add: expand_complex_eq)
   490 
   491 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   492 by (simp add: complex_norm_def)
   493 
   494 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   495 by (simp add: expand_complex_eq)
   496 
   497 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   498 by (simp add: expand_complex_eq)
   499 
   500 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   501 by (simp add: expand_complex_eq)
   502 
   503 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   504 by (simp add: expand_complex_eq)
   505 
   506 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   507 by (simp add: expand_complex_eq power2_eq_square)
   508 
   509 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"
   510 by (simp add: norm_mult power2_eq_square)
   511 
   512 interpretation cnj: bounded_linear "cnj"
   513 apply (unfold_locales)
   514 apply (rule complex_cnj_add)
   515 apply (rule complex_cnj_scaleR)
   516 apply (rule_tac x=1 in exI, simp)
   517 done
   518 
   519 
   520 subsection{*The Functions @{term sgn} and @{term arg}*}
   521 
   522 text {*------------ Argand -------------*}
   523 
   524 definition
   525   arg :: "complex => real" where
   526   "arg z = (SOME a. Re(sgn z) = cos a & Im(sgn z) = sin a & -pi < a & a \<le> pi)"
   527 
   528 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   529 by (simp add: complex_sgn_def divide_inverse scaleR_conv_of_real mult_commute)
   530 
   531 lemma i_mult_eq: "ii * ii = complex_of_real (-1)"
   532 by (simp add: i_def complex_of_real_def)
   533 
   534 lemma i_mult_eq2 [simp]: "ii * ii = -(1::complex)"
   535 by (simp add: i_def complex_one_def)
   536 
   537 lemma complex_eq_cancel_iff2 [simp]:
   538      "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   539 by (simp add: complex_of_real_def)
   540 
   541 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   542 by (simp add: complex_sgn_def divide_inverse)
   543 
   544 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   545 by (simp add: complex_sgn_def divide_inverse)
   546 
   547 lemma complex_inverse_complex_split:
   548      "inverse(complex_of_real x + ii * complex_of_real y) =
   549       complex_of_real(x/(x ^ 2 + y ^ 2)) -
   550       ii * complex_of_real(y/(x ^ 2 + y ^ 2))"
   551 by (simp add: complex_of_real_def i_def diff_minus divide_inverse)
   552 
   553 (*----------------------------------------------------------------------------*)
   554 (* Many of the theorems below need to be moved elsewhere e.g. Transc. Also *)
   555 (* many of the theorems are not used - so should they be kept?                *)
   556 (*----------------------------------------------------------------------------*)
   557 
   558 lemma cos_arg_i_mult_zero_pos:
   559    "0 < y ==> cos (arg(Complex 0 y)) = 0"
   560 apply (simp add: arg_def abs_if)
   561 apply (rule_tac a = "pi/2" in someI2, auto)
   562 apply (rule order_less_trans [of _ 0], auto)
   563 done
   564 
   565 lemma cos_arg_i_mult_zero_neg:
   566    "y < 0 ==> cos (arg(Complex 0 y)) = 0"
   567 apply (simp add: arg_def abs_if)
   568 apply (rule_tac a = "- pi/2" in someI2, auto)
   569 apply (rule order_trans [of _ 0], auto)
   570 done
   571 
   572 lemma cos_arg_i_mult_zero [simp]:
   573      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   574 by (auto simp add: linorder_neq_iff cos_arg_i_mult_zero_pos cos_arg_i_mult_zero_neg)
   575 
   576 
   577 subsection{*Finally! Polar Form for Complex Numbers*}
   578 
   579 definition
   580 
   581   (* abbreviation for (cos a + i sin a) *)
   582   cis :: "real => complex" where
   583   "cis a = Complex (cos a) (sin a)"
   584 
   585 definition
   586   (* abbreviation for r*(cos a + i sin a) *)
   587   rcis :: "[real, real] => complex" where
   588   "rcis r a = complex_of_real r * cis a"
   589 
   590 definition
   591   (* e ^ (x + iy) *)
   592   expi :: "complex => complex" where
   593   "expi z = complex_of_real(exp (Re z)) * cis (Im z)"
   594 
   595 lemma complex_split_polar:
   596      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   597 apply (induct z)
   598 apply (auto simp add: polar_Ex complex_of_real_mult_Complex)
   599 done
   600 
   601 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   602 apply (induct z)
   603 apply (simp add: rcis_def cis_def polar_Ex complex_of_real_mult_Complex)
   604 done
   605 
   606 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   607 by (simp add: rcis_def cis_def)
   608 
   609 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   610 by (simp add: rcis_def cis_def)
   611 
   612 lemma sin_cos_squared_add2_mult: "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior>"
   613 proof -
   614   have "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior> * ((cos a)\<twosuperior> + (sin a)\<twosuperior>)"
   615     by (simp only: power_mult_distrib right_distrib)
   616   thus ?thesis by simp
   617 qed
   618 
   619 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   620 by (simp add: rcis_def cis_def sin_cos_squared_add2_mult)
   621 
   622 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   623 by (simp add: cmod_def power2_eq_square)
   624 
   625 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   626 by simp
   627 
   628 
   629 (*---------------------------------------------------------------------------*)
   630 (*  (r1 * cis a) * (r2 * cis b) = r1 * r2 * cis (a + b)                      *)
   631 (*---------------------------------------------------------------------------*)
   632 
   633 lemma cis_rcis_eq: "cis a = rcis 1 a"
   634 by (simp add: rcis_def)
   635 
   636 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   637 by (simp add: rcis_def cis_def cos_add sin_add right_distrib right_diff_distrib
   638               complex_of_real_def)
   639 
   640 lemma cis_mult: "cis a * cis b = cis (a + b)"
   641 by (simp add: cis_rcis_eq rcis_mult)
   642 
   643 lemma cis_zero [simp]: "cis 0 = 1"
   644 by (simp add: cis_def complex_one_def)
   645 
   646 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   647 by (simp add: rcis_def)
   648 
   649 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   650 by (simp add: rcis_def)
   651 
   652 lemma complex_of_real_minus_one:
   653    "complex_of_real (-(1::real)) = -(1::complex)"
   654 by (simp add: complex_of_real_def complex_one_def)
   655 
   656 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   657 by (simp add: mult_assoc [symmetric])
   658 
   659 
   660 lemma cis_real_of_nat_Suc_mult:
   661    "cis (real (Suc n) * a) = cis a * cis (real n * a)"
   662 by (simp add: cis_def real_of_nat_Suc left_distrib cos_add sin_add right_distrib)
   663 
   664 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   665 apply (induct_tac "n")
   666 apply (auto simp add: cis_real_of_nat_Suc_mult)
   667 done
   668 
   669 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   670 by (simp add: rcis_def power_mult_distrib DeMoivre)
   671 
   672 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   673 by (simp add: cis_def complex_inverse_complex_split diff_minus)
   674 
   675 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   676 by (simp add: divide_inverse rcis_def)
   677 
   678 lemma cis_divide: "cis a / cis b = cis (a - b)"
   679 by (simp add: complex_divide_def cis_mult real_diff_def)
   680 
   681 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   682 apply (simp add: complex_divide_def)
   683 apply (case_tac "r2=0", simp)
   684 apply (simp add: rcis_inverse rcis_mult real_diff_def)
   685 done
   686 
   687 lemma Re_cis [simp]: "Re(cis a) = cos a"
   688 by (simp add: cis_def)
   689 
   690 lemma Im_cis [simp]: "Im(cis a) = sin a"
   691 by (simp add: cis_def)
   692 
   693 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   694 by (auto simp add: DeMoivre)
   695 
   696 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   697 by (auto simp add: DeMoivre)
   698 
   699 lemma expi_add: "expi(a + b) = expi(a) * expi(b)"
   700 by (simp add: expi_def exp_add cis_mult [symmetric] mult_ac)
   701 
   702 lemma expi_zero [simp]: "expi (0::complex) = 1"
   703 by (simp add: expi_def)
   704 
   705 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   706 apply (insert rcis_Ex [of z])
   707 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   708 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   709 done
   710 
   711 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   712 by (simp add: expi_def cis_def)
   713 
   714 end