src/HOL/Divides.thy
author wenzelm
Mon Mar 22 20:58:52 2010 +0100 (2010-03-22)
changeset 35898 c890a3835d15
parent 35815 10e723e54076
child 36634 f9b43d197d16
permissions -rw-r--r--
recovered header;
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Numeral Nat_Transfer
    10 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    11 begin
    12 
    13 subsection {* Syntactic division operations *}
    14 
    15 class div = dvd +
    16   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    17     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    18 
    19 
    20 subsection {* Abstract division in commutative semirings. *}
    21 
    22 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    23   assumes mod_div_equality: "a div b * b + a mod b = a"
    24     and div_by_0 [simp]: "a div 0 = 0"
    25     and div_0 [simp]: "0 div a = 0"
    26     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    27     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    28 begin
    29 
    30 text {* @{const div} and @{const mod} *}
    31 
    32 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    33   unfolding mult_commute [of b]
    34   by (rule mod_div_equality)
    35 
    36 lemma mod_div_equality': "a mod b + a div b * b = a"
    37   using mod_div_equality [of a b]
    38   by (simp only: add_ac)
    39 
    40 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    41   by (simp add: mod_div_equality)
    42 
    43 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    44   by (simp add: mod_div_equality2)
    45 
    46 lemma mod_by_0 [simp]: "a mod 0 = a"
    47   using mod_div_equality [of a zero] by simp
    48 
    49 lemma mod_0 [simp]: "0 mod a = 0"
    50   using mod_div_equality [of zero a] div_0 by simp
    51 
    52 lemma div_mult_self2 [simp]:
    53   assumes "b \<noteq> 0"
    54   shows "(a + b * c) div b = c + a div b"
    55   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    56 
    57 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    58 proof (cases "b = 0")
    59   case True then show ?thesis by simp
    60 next
    61   case False
    62   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    63     by (simp add: mod_div_equality)
    64   also from False div_mult_self1 [of b a c] have
    65     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    66       by (simp add: algebra_simps)
    67   finally have "a = a div b * b + (a + c * b) mod b"
    68     by (simp add: add_commute [of a] add_assoc left_distrib)
    69   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    70     by (simp add: mod_div_equality)
    71   then show ?thesis by simp
    72 qed
    73 
    74 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    75   by (simp add: mult_commute [of b])
    76 
    77 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    78   using div_mult_self2 [of b 0 a] by simp
    79 
    80 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    81   using div_mult_self1 [of b 0 a] by simp
    82 
    83 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    84   using mod_mult_self2 [of 0 b a] by simp
    85 
    86 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    87   using mod_mult_self1 [of 0 a b] by simp
    88 
    89 lemma div_by_1 [simp]: "a div 1 = a"
    90   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    91 
    92 lemma mod_by_1 [simp]: "a mod 1 = 0"
    93 proof -
    94   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    95   then have "a + a mod 1 = a + 0" by simp
    96   then show ?thesis by (rule add_left_imp_eq)
    97 qed
    98 
    99 lemma mod_self [simp]: "a mod a = 0"
   100   using mod_mult_self2_is_0 [of 1] by simp
   101 
   102 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   103   using div_mult_self2_is_id [of _ 1] by simp
   104 
   105 lemma div_add_self1 [simp]:
   106   assumes "b \<noteq> 0"
   107   shows "(b + a) div b = a div b + 1"
   108   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   109 
   110 lemma div_add_self2 [simp]:
   111   assumes "b \<noteq> 0"
   112   shows "(a + b) div b = a div b + 1"
   113   using assms div_add_self1 [of b a] by (simp add: add_commute)
   114 
   115 lemma mod_add_self1 [simp]:
   116   "(b + a) mod b = a mod b"
   117   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   118 
   119 lemma mod_add_self2 [simp]:
   120   "(a + b) mod b = a mod b"
   121   using mod_mult_self1 [of a 1 b] by simp
   122 
   123 lemma mod_div_decomp:
   124   fixes a b
   125   obtains q r where "q = a div b" and "r = a mod b"
   126     and "a = q * b + r"
   127 proof -
   128   from mod_div_equality have "a = a div b * b + a mod b" by simp
   129   moreover have "a div b = a div b" ..
   130   moreover have "a mod b = a mod b" ..
   131   note that ultimately show thesis by blast
   132 qed
   133 
   134 lemma dvd_eq_mod_eq_0 [code, code_unfold, code_inline del]: "a dvd b \<longleftrightarrow> b mod a = 0"
   135 proof
   136   assume "b mod a = 0"
   137   with mod_div_equality [of b a] have "b div a * a = b" by simp
   138   then have "b = a * (b div a)" unfolding mult_commute ..
   139   then have "\<exists>c. b = a * c" ..
   140   then show "a dvd b" unfolding dvd_def .
   141 next
   142   assume "a dvd b"
   143   then have "\<exists>c. b = a * c" unfolding dvd_def .
   144   then obtain c where "b = a * c" ..
   145   then have "b mod a = a * c mod a" by simp
   146   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   147   then show "b mod a = 0" by simp
   148 qed
   149 
   150 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   151 proof (cases "b = 0")
   152   assume "b = 0"
   153   thus ?thesis by simp
   154 next
   155   assume "b \<noteq> 0"
   156   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   157     by (rule div_mult_self1 [symmetric])
   158   also have "\<dots> = a div b"
   159     by (simp only: mod_div_equality')
   160   also have "\<dots> = a div b + 0"
   161     by simp
   162   finally show ?thesis
   163     by (rule add_left_imp_eq)
   164 qed
   165 
   166 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   167 proof -
   168   have "a mod b mod b = (a mod b + a div b * b) mod b"
   169     by (simp only: mod_mult_self1)
   170   also have "\<dots> = a mod b"
   171     by (simp only: mod_div_equality')
   172   finally show ?thesis .
   173 qed
   174 
   175 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   176 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   177 
   178 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   179 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   180 
   181 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   182 by (drule dvd_div_mult_self) (simp add: mult_commute)
   183 
   184 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   185 apply (cases "a = 0")
   186  apply simp
   187 apply (auto simp: dvd_def mult_assoc)
   188 done
   189 
   190 lemma div_dvd_div[simp]:
   191   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   192 apply (cases "a = 0")
   193  apply simp
   194 apply (unfold dvd_def)
   195 apply auto
   196  apply(blast intro:mult_assoc[symmetric])
   197 apply(fastsimp simp add: mult_assoc)
   198 done
   199 
   200 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   201   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   202    apply (simp add: mod_div_equality)
   203   apply (simp only: dvd_add dvd_mult)
   204   done
   205 
   206 text {* Addition respects modular equivalence. *}
   207 
   208 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   209 proof -
   210   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   211     by (simp only: mod_div_equality)
   212   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   213     by (simp only: add_ac)
   214   also have "\<dots> = (a mod c + b) mod c"
   215     by (rule mod_mult_self1)
   216   finally show ?thesis .
   217 qed
   218 
   219 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   220 proof -
   221   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   222     by (simp only: mod_div_equality)
   223   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   224     by (simp only: add_ac)
   225   also have "\<dots> = (a + b mod c) mod c"
   226     by (rule mod_mult_self1)
   227   finally show ?thesis .
   228 qed
   229 
   230 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   231 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   232 
   233 lemma mod_add_cong:
   234   assumes "a mod c = a' mod c"
   235   assumes "b mod c = b' mod c"
   236   shows "(a + b) mod c = (a' + b') mod c"
   237 proof -
   238   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   239     unfolding assms ..
   240   thus ?thesis
   241     by (simp only: mod_add_eq [symmetric])
   242 qed
   243 
   244 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   245   \<Longrightarrow> (x + y) div z = x div z + y div z"
   246 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   247 
   248 text {* Multiplication respects modular equivalence. *}
   249 
   250 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   251 proof -
   252   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   253     by (simp only: mod_div_equality)
   254   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   255     by (simp only: algebra_simps)
   256   also have "\<dots> = (a mod c * b) mod c"
   257     by (rule mod_mult_self1)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   262 proof -
   263   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   264     by (simp only: mod_div_equality)
   265   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   266     by (simp only: algebra_simps)
   267   also have "\<dots> = (a * (b mod c)) mod c"
   268     by (rule mod_mult_self1)
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   273 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   274 
   275 lemma mod_mult_cong:
   276   assumes "a mod c = a' mod c"
   277   assumes "b mod c = b' mod c"
   278   shows "(a * b) mod c = (a' * b') mod c"
   279 proof -
   280   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   281     unfolding assms ..
   282   thus ?thesis
   283     by (simp only: mod_mult_eq [symmetric])
   284 qed
   285 
   286 lemma mod_mod_cancel:
   287   assumes "c dvd b"
   288   shows "a mod b mod c = a mod c"
   289 proof -
   290   from `c dvd b` obtain k where "b = c * k"
   291     by (rule dvdE)
   292   have "a mod b mod c = a mod (c * k) mod c"
   293     by (simp only: `b = c * k`)
   294   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   295     by (simp only: mod_mult_self1)
   296   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   297     by (simp only: add_ac mult_ac)
   298   also have "\<dots> = a mod c"
   299     by (simp only: mod_div_equality)
   300   finally show ?thesis .
   301 qed
   302 
   303 lemma div_mult_div_if_dvd:
   304   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   305   apply (cases "y = 0", simp)
   306   apply (cases "z = 0", simp)
   307   apply (auto elim!: dvdE simp add: algebra_simps)
   308   apply (subst mult_assoc [symmetric])
   309   apply (simp add: no_zero_divisors)
   310   done
   311 
   312 lemma div_mult_swap:
   313   assumes "c dvd b"
   314   shows "a * (b div c) = (a * b) div c"
   315 proof -
   316   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   317     by (simp only: div_mult_div_if_dvd one_dvd)
   318   then show ?thesis by (simp add: mult_commute)
   319 qed
   320    
   321 lemma div_mult_mult2 [simp]:
   322   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   323   by (drule div_mult_mult1) (simp add: mult_commute)
   324 
   325 lemma div_mult_mult1_if [simp]:
   326   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   327   by simp_all
   328 
   329 lemma mod_mult_mult1:
   330   "(c * a) mod (c * b) = c * (a mod b)"
   331 proof (cases "c = 0")
   332   case True then show ?thesis by simp
   333 next
   334   case False
   335   from mod_div_equality
   336   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   337   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   338     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   339   with mod_div_equality show ?thesis by simp 
   340 qed
   341   
   342 lemma mod_mult_mult2:
   343   "(a * c) mod (b * c) = (a mod b) * c"
   344   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   345 
   346 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   347   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   348 
   349 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   350 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   351 
   352 lemma div_power:
   353   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   354 apply (induct n)
   355  apply simp
   356 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   357 done
   358 
   359 lemma dvd_div_eq_mult:
   360   assumes "a \<noteq> 0" and "a dvd b"  
   361   shows "b div a = c \<longleftrightarrow> b = c * a"
   362 proof
   363   assume "b = c * a"
   364   then show "b div a = c" by (simp add: assms)
   365 next
   366   assume "b div a = c"
   367   then have "b div a * a = c * a" by simp
   368   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   369   ultimately show "b = c * a" by simp
   370 qed
   371    
   372 lemma dvd_div_div_eq_mult:
   373   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   374   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   375   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   376 
   377 end
   378 
   379 class ring_div = semiring_div + comm_ring_1
   380 begin
   381 
   382 text {* Negation respects modular equivalence. *}
   383 
   384 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   385 proof -
   386   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   387     by (simp only: mod_div_equality)
   388   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   389     by (simp only: minus_add_distrib minus_mult_left add_ac)
   390   also have "\<dots> = (- (a mod b)) mod b"
   391     by (rule mod_mult_self1)
   392   finally show ?thesis .
   393 qed
   394 
   395 lemma mod_minus_cong:
   396   assumes "a mod b = a' mod b"
   397   shows "(- a) mod b = (- a') mod b"
   398 proof -
   399   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   400     unfolding assms ..
   401   thus ?thesis
   402     by (simp only: mod_minus_eq [symmetric])
   403 qed
   404 
   405 text {* Subtraction respects modular equivalence. *}
   406 
   407 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   408   unfolding diff_minus
   409   by (intro mod_add_cong mod_minus_cong) simp_all
   410 
   411 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   412   unfolding diff_minus
   413   by (intro mod_add_cong mod_minus_cong) simp_all
   414 
   415 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   416   unfolding diff_minus
   417   by (intro mod_add_cong mod_minus_cong) simp_all
   418 
   419 lemma mod_diff_cong:
   420   assumes "a mod c = a' mod c"
   421   assumes "b mod c = b' mod c"
   422   shows "(a - b) mod c = (a' - b') mod c"
   423   unfolding diff_minus using assms
   424   by (intro mod_add_cong mod_minus_cong)
   425 
   426 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   427 apply (case_tac "y = 0") apply simp
   428 apply (auto simp add: dvd_def)
   429 apply (subgoal_tac "-(y * k) = y * - k")
   430  apply (erule ssubst)
   431  apply (erule div_mult_self1_is_id)
   432 apply simp
   433 done
   434 
   435 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   436 apply (case_tac "y = 0") apply simp
   437 apply (auto simp add: dvd_def)
   438 apply (subgoal_tac "y * k = -y * -k")
   439  apply (erule ssubst)
   440  apply (rule div_mult_self1_is_id)
   441  apply simp
   442 apply simp
   443 done
   444 
   445 end
   446 
   447 
   448 subsection {* Division on @{typ nat} *}
   449 
   450 text {*
   451   We define @{const div} and @{const mod} on @{typ nat} by means
   452   of a characteristic relation with two input arguments
   453   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   454   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   455 *}
   456 
   457 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   458   "divmod_nat_rel m n qr \<longleftrightarrow>
   459     m = fst qr * n + snd qr \<and>
   460       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   461 
   462 text {* @{const divmod_nat_rel} is total: *}
   463 
   464 lemma divmod_nat_rel_ex:
   465   obtains q r where "divmod_nat_rel m n (q, r)"
   466 proof (cases "n = 0")
   467   case True  with that show thesis
   468     by (auto simp add: divmod_nat_rel_def)
   469 next
   470   case False
   471   have "\<exists>q r. m = q * n + r \<and> r < n"
   472   proof (induct m)
   473     case 0 with `n \<noteq> 0`
   474     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   475     then show ?case by blast
   476   next
   477     case (Suc m) then obtain q' r'
   478       where m: "m = q' * n + r'" and n: "r' < n" by auto
   479     then show ?case proof (cases "Suc r' < n")
   480       case True
   481       from m n have "Suc m = q' * n + Suc r'" by simp
   482       with True show ?thesis by blast
   483     next
   484       case False then have "n \<le> Suc r'" by auto
   485       moreover from n have "Suc r' \<le> n" by auto
   486       ultimately have "n = Suc r'" by auto
   487       with m have "Suc m = Suc q' * n + 0" by simp
   488       with `n \<noteq> 0` show ?thesis by blast
   489     qed
   490   qed
   491   with that show thesis
   492     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   493 qed
   494 
   495 text {* @{const divmod_nat_rel} is injective: *}
   496 
   497 lemma divmod_nat_rel_unique:
   498   assumes "divmod_nat_rel m n qr"
   499     and "divmod_nat_rel m n qr'"
   500   shows "qr = qr'"
   501 proof (cases "n = 0")
   502   case True with assms show ?thesis
   503     by (cases qr, cases qr')
   504       (simp add: divmod_nat_rel_def)
   505 next
   506   case False
   507   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   508   apply (rule leI)
   509   apply (subst less_iff_Suc_add)
   510   apply (auto simp add: add_mult_distrib)
   511   done
   512   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   513     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   514   moreover from this assms have "snd qr = snd qr'"
   515     by (simp add: divmod_nat_rel_def)
   516   ultimately show ?thesis by (cases qr, cases qr') simp
   517 qed
   518 
   519 text {*
   520   We instantiate divisibility on the natural numbers by
   521   means of @{const divmod_nat_rel}:
   522 *}
   523 
   524 instantiation nat :: semiring_div
   525 begin
   526 
   527 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   528   [code del]: "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   529 
   530 lemma divmod_nat_rel_divmod_nat:
   531   "divmod_nat_rel m n (divmod_nat m n)"
   532 proof -
   533   from divmod_nat_rel_ex
   534     obtain qr where rel: "divmod_nat_rel m n qr" .
   535   then show ?thesis
   536   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   537 qed
   538 
   539 lemma divmod_nat_eq:
   540   assumes "divmod_nat_rel m n qr" 
   541   shows "divmod_nat m n = qr"
   542   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   543 
   544 definition div_nat where
   545   "m div n = fst (divmod_nat m n)"
   546 
   547 definition mod_nat where
   548   "m mod n = snd (divmod_nat m n)"
   549 
   550 lemma divmod_nat_div_mod:
   551   "divmod_nat m n = (m div n, m mod n)"
   552   unfolding div_nat_def mod_nat_def by simp
   553 
   554 lemma div_eq:
   555   assumes "divmod_nat_rel m n (q, r)" 
   556   shows "m div n = q"
   557   using assms by (auto dest: divmod_nat_eq simp add: divmod_nat_div_mod)
   558 
   559 lemma mod_eq:
   560   assumes "divmod_nat_rel m n (q, r)" 
   561   shows "m mod n = r"
   562   using assms by (auto dest: divmod_nat_eq simp add: divmod_nat_div_mod)
   563 
   564 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   565   by (simp add: div_nat_def mod_nat_def divmod_nat_rel_divmod_nat)
   566 
   567 lemma divmod_nat_zero:
   568   "divmod_nat m 0 = (0, m)"
   569 proof -
   570   from divmod_nat_rel [of m 0] show ?thesis
   571     unfolding divmod_nat_div_mod divmod_nat_rel_def by simp
   572 qed
   573 
   574 lemma divmod_nat_base:
   575   assumes "m < n"
   576   shows "divmod_nat m n = (0, m)"
   577 proof -
   578   from divmod_nat_rel [of m n] show ?thesis
   579     unfolding divmod_nat_div_mod divmod_nat_rel_def
   580     using assms by (cases "m div n = 0")
   581       (auto simp add: gr0_conv_Suc [of "m div n"])
   582 qed
   583 
   584 lemma divmod_nat_step:
   585   assumes "0 < n" and "n \<le> m"
   586   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   587 proof -
   588   from divmod_nat_rel have divmod_nat_m_n: "divmod_nat_rel m n (m div n, m mod n)" .
   589   with assms have m_div_n: "m div n \<ge> 1"
   590     by (cases "m div n") (auto simp add: divmod_nat_rel_def)
   591   have "divmod_nat_rel (m - n) n (m div n - Suc 0, m mod n)"
   592   proof -
   593     from assms have
   594       "n \<noteq> 0"
   595       "\<And>k. m = Suc k * n + m mod n ==> m - n = (Suc k - Suc 0) * n + m mod n"
   596       by simp_all
   597     then show ?thesis using assms divmod_nat_m_n 
   598       by (cases "m div n")
   599          (simp_all only: divmod_nat_rel_def fst_conv snd_conv, simp_all)
   600   qed
   601   with divmod_nat_eq have "divmod_nat (m - n) n = (m div n - Suc 0, m mod n)" by simp
   602   moreover from divmod_nat_div_mod have "divmod_nat (m - n) n = ((m - n) div n, (m - n) mod n)" .
   603   ultimately have "m div n = Suc ((m - n) div n)"
   604     and "m mod n = (m - n) mod n" using m_div_n by simp_all
   605   then show ?thesis using divmod_nat_div_mod by simp
   606 qed
   607 
   608 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   609 
   610 lemma div_less [simp]:
   611   fixes m n :: nat
   612   assumes "m < n"
   613   shows "m div n = 0"
   614   using assms divmod_nat_base divmod_nat_div_mod by simp
   615 
   616 lemma le_div_geq:
   617   fixes m n :: nat
   618   assumes "0 < n" and "n \<le> m"
   619   shows "m div n = Suc ((m - n) div n)"
   620   using assms divmod_nat_step divmod_nat_div_mod by simp
   621 
   622 lemma mod_less [simp]:
   623   fixes m n :: nat
   624   assumes "m < n"
   625   shows "m mod n = m"
   626   using assms divmod_nat_base divmod_nat_div_mod by simp
   627 
   628 lemma le_mod_geq:
   629   fixes m n :: nat
   630   assumes "n \<le> m"
   631   shows "m mod n = (m - n) mod n"
   632   using assms divmod_nat_step divmod_nat_div_mod by (cases "n = 0") simp_all
   633 
   634 instance proof -
   635   have [simp]: "\<And>n::nat. n div 0 = 0"
   636     by (simp add: div_nat_def divmod_nat_zero)
   637   have [simp]: "\<And>n::nat. 0 div n = 0"
   638   proof -
   639     fix n :: nat
   640     show "0 div n = 0"
   641       by (cases "n = 0") simp_all
   642   qed
   643   show "OFCLASS(nat, semiring_div_class)" proof
   644     fix m n :: nat
   645     show "m div n * n + m mod n = m"
   646       using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   647   next
   648     fix m n q :: nat
   649     assume "n \<noteq> 0"
   650     then show "(q + m * n) div n = m + q div n"
   651       by (induct m) (simp_all add: le_div_geq)
   652   next
   653     fix m n q :: nat
   654     assume "m \<noteq> 0"
   655     then show "(m * n) div (m * q) = n div q"
   656     proof (cases "n \<noteq> 0 \<and> q \<noteq> 0")
   657       case False then show ?thesis by auto
   658     next
   659       case True with `m \<noteq> 0`
   660         have "m > 0" and "n > 0" and "q > 0" by auto
   661       then have "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   662         by (auto simp add: divmod_nat_rel_def) (simp_all add: algebra_simps)
   663       moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   664       ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   665       then show ?thesis by (simp add: div_eq)
   666     qed
   667   qed simp_all
   668 qed
   669 
   670 end
   671 
   672 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   673   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   674 by (simp add: divmod_nat_zero divmod_nat_base divmod_nat_step)
   675     (simp add: divmod_nat_div_mod)
   676 
   677 text {* Simproc for cancelling @{const div} and @{const mod} *}
   678 
   679 ML {*
   680 local
   681 
   682 structure CancelDivMod = CancelDivModFun(struct
   683 
   684   val div_name = @{const_name div};
   685   val mod_name = @{const_name mod};
   686   val mk_binop = HOLogic.mk_binop;
   687   val mk_sum = Nat_Arith.mk_sum;
   688   val dest_sum = Nat_Arith.dest_sum;
   689 
   690   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   691 
   692   val trans = trans;
   693 
   694   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   695     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   696 
   697 end)
   698 
   699 in
   700 
   701 val cancel_div_mod_nat_proc = Simplifier.simproc @{theory}
   702   "cancel_div_mod" ["(m::nat) + n"] (K CancelDivMod.proc);
   703 
   704 val _ = Addsimprocs [cancel_div_mod_nat_proc];
   705 
   706 end
   707 *}
   708 
   709 
   710 subsubsection {* Quotient *}
   711 
   712 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   713 by (simp add: le_div_geq linorder_not_less)
   714 
   715 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   716 by (simp add: div_geq)
   717 
   718 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   719 by simp
   720 
   721 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   722 by simp
   723 
   724 
   725 subsubsection {* Remainder *}
   726 
   727 lemma mod_less_divisor [simp]:
   728   fixes m n :: nat
   729   assumes "n > 0"
   730   shows "m mod n < (n::nat)"
   731   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   732 
   733 lemma mod_less_eq_dividend [simp]:
   734   fixes m n :: nat
   735   shows "m mod n \<le> m"
   736 proof (rule add_leD2)
   737   from mod_div_equality have "m div n * n + m mod n = m" .
   738   then show "m div n * n + m mod n \<le> m" by auto
   739 qed
   740 
   741 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   742 by (simp add: le_mod_geq linorder_not_less)
   743 
   744 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   745 by (simp add: le_mod_geq)
   746 
   747 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   748 by (induct m) (simp_all add: mod_geq)
   749 
   750 lemma mod_mult_distrib: "(m mod n) * (k\<Colon>nat) = (m * k) mod (n * k)"
   751   apply (cases "n = 0", simp)
   752   apply (cases "k = 0", simp)
   753   apply (induct m rule: nat_less_induct)
   754   apply (subst mod_if, simp)
   755   apply (simp add: mod_geq diff_mult_distrib)
   756   done
   757 
   758 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   759 by (simp add: mult_commute [of k] mod_mult_distrib)
   760 
   761 (* a simple rearrangement of mod_div_equality: *)
   762 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   763 by (cut_tac a = m and b = n in mod_div_equality2, arith)
   764 
   765 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   766   apply (drule mod_less_divisor [where m = m])
   767   apply simp
   768   done
   769 
   770 subsubsection {* Quotient and Remainder *}
   771 
   772 lemma divmod_nat_rel_mult1_eq:
   773   "divmod_nat_rel b c (q, r) \<Longrightarrow> c > 0
   774    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   775 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   776 
   777 lemma div_mult1_eq:
   778   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   779 apply (cases "c = 0", simp)
   780 apply (blast intro: divmod_nat_rel [THEN divmod_nat_rel_mult1_eq, THEN div_eq])
   781 done
   782 
   783 lemma divmod_nat_rel_add1_eq:
   784   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br) \<Longrightarrow>  c > 0
   785    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   786 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   787 
   788 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   789 lemma div_add1_eq:
   790   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   791 apply (cases "c = 0", simp)
   792 apply (blast intro: divmod_nat_rel_add1_eq [THEN div_eq] divmod_nat_rel)
   793 done
   794 
   795 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   796   apply (cut_tac m = q and n = c in mod_less_divisor)
   797   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   798   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   799   apply (simp add: add_mult_distrib2)
   800   done
   801 
   802 lemma divmod_nat_rel_mult2_eq:
   803   "divmod_nat_rel a b (q, r) \<Longrightarrow> 0 < b \<Longrightarrow> 0 < c
   804    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   805 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   806 
   807 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   808   apply (cases "b = 0", simp)
   809   apply (cases "c = 0", simp)
   810   apply (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_eq])
   811   done
   812 
   813 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   814   apply (cases "b = 0", simp)
   815   apply (cases "c = 0", simp)
   816   apply (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_eq])
   817   done
   818 
   819 
   820 subsubsection{*Further Facts about Quotient and Remainder*}
   821 
   822 lemma div_1 [simp]: "m div Suc 0 = m"
   823 by (induct m) (simp_all add: div_geq)
   824 
   825 
   826 (* Monotonicity of div in first argument *)
   827 lemma div_le_mono [rule_format (no_asm)]:
   828     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   829 apply (case_tac "k=0", simp)
   830 apply (induct "n" rule: nat_less_induct, clarify)
   831 apply (case_tac "n<k")
   832 (* 1  case n<k *)
   833 apply simp
   834 (* 2  case n >= k *)
   835 apply (case_tac "m<k")
   836 (* 2.1  case m<k *)
   837 apply simp
   838 (* 2.2  case m>=k *)
   839 apply (simp add: div_geq diff_le_mono)
   840 done
   841 
   842 (* Antimonotonicity of div in second argument *)
   843 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   844 apply (subgoal_tac "0<n")
   845  prefer 2 apply simp
   846 apply (induct_tac k rule: nat_less_induct)
   847 apply (rename_tac "k")
   848 apply (case_tac "k<n", simp)
   849 apply (subgoal_tac "~ (k<m) ")
   850  prefer 2 apply simp
   851 apply (simp add: div_geq)
   852 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   853  prefer 2
   854  apply (blast intro: div_le_mono diff_le_mono2)
   855 apply (rule le_trans, simp)
   856 apply (simp)
   857 done
   858 
   859 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   860 apply (case_tac "n=0", simp)
   861 apply (subgoal_tac "m div n \<le> m div 1", simp)
   862 apply (rule div_le_mono2)
   863 apply (simp_all (no_asm_simp))
   864 done
   865 
   866 (* Similar for "less than" *)
   867 lemma div_less_dividend [rule_format]:
   868      "!!n::nat. 1<n ==> 0 < m --> m div n < m"
   869 apply (induct_tac m rule: nat_less_induct)
   870 apply (rename_tac "m")
   871 apply (case_tac "m<n", simp)
   872 apply (subgoal_tac "0<n")
   873  prefer 2 apply simp
   874 apply (simp add: div_geq)
   875 apply (case_tac "n<m")
   876  apply (subgoal_tac "(m-n) div n < (m-n) ")
   877   apply (rule impI less_trans_Suc)+
   878 apply assumption
   879   apply (simp_all)
   880 done
   881 
   882 declare div_less_dividend [simp]
   883 
   884 text{*A fact for the mutilated chess board*}
   885 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   886 apply (case_tac "n=0", simp)
   887 apply (induct "m" rule: nat_less_induct)
   888 apply (case_tac "Suc (na) <n")
   889 (* case Suc(na) < n *)
   890 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   891 (* case n \<le> Suc(na) *)
   892 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   893 apply (auto simp add: Suc_diff_le le_mod_geq)
   894 done
   895 
   896 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   897 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   898 
   899 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   900 
   901 (*Loses information, namely we also have r<d provided d is nonzero*)
   902 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   903   apply (cut_tac a = m in mod_div_equality)
   904   apply (simp only: add_ac)
   905   apply (blast intro: sym)
   906   done
   907 
   908 lemma split_div:
   909  "P(n div k :: nat) =
   910  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   911  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   912 proof
   913   assume P: ?P
   914   show ?Q
   915   proof (cases)
   916     assume "k = 0"
   917     with P show ?Q by simp
   918   next
   919     assume not0: "k \<noteq> 0"
   920     thus ?Q
   921     proof (simp, intro allI impI)
   922       fix i j
   923       assume n: "n = k*i + j" and j: "j < k"
   924       show "P i"
   925       proof (cases)
   926         assume "i = 0"
   927         with n j P show "P i" by simp
   928       next
   929         assume "i \<noteq> 0"
   930         with not0 n j P show "P i" by(simp add:add_ac)
   931       qed
   932     qed
   933   qed
   934 next
   935   assume Q: ?Q
   936   show ?P
   937   proof (cases)
   938     assume "k = 0"
   939     with Q show ?P by simp
   940   next
   941     assume not0: "k \<noteq> 0"
   942     with Q have R: ?R by simp
   943     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   944     show ?P by simp
   945   qed
   946 qed
   947 
   948 lemma split_div_lemma:
   949   assumes "0 < n"
   950   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   951 proof
   952   assume ?rhs
   953   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   954   then have A: "n * q \<le> m" by simp
   955   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   956   then have "m < m + (n - (m mod n))" by simp
   957   then have "m < n + (m - (m mod n))" by simp
   958   with nq have "m < n + n * q" by simp
   959   then have B: "m < n * Suc q" by simp
   960   from A B show ?lhs ..
   961 next
   962   assume P: ?lhs
   963   then have "divmod_nat_rel m n (q, m - n * q)"
   964     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   965   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   966   have "(q, m - n * q) = (m div n, m mod n)" by auto
   967   then show ?rhs by simp
   968 qed
   969 
   970 theorem split_div':
   971   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   972    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   973   apply (case_tac "0 < n")
   974   apply (simp only: add: split_div_lemma)
   975   apply simp_all
   976   done
   977 
   978 lemma split_mod:
   979  "P(n mod k :: nat) =
   980  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   981  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   982 proof
   983   assume P: ?P
   984   show ?Q
   985   proof (cases)
   986     assume "k = 0"
   987     with P show ?Q by simp
   988   next
   989     assume not0: "k \<noteq> 0"
   990     thus ?Q
   991     proof (simp, intro allI impI)
   992       fix i j
   993       assume "n = k*i + j" "j < k"
   994       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   995     qed
   996   qed
   997 next
   998   assume Q: ?Q
   999   show ?P
  1000   proof (cases)
  1001     assume "k = 0"
  1002     with Q show ?P by simp
  1003   next
  1004     assume not0: "k \<noteq> 0"
  1005     with Q have R: ?R by simp
  1006     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
  1007     show ?P by simp
  1008   qed
  1009 qed
  1010 
  1011 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
  1012   apply (rule_tac P="%x. m mod n = x - (m div n) * n" in
  1013     subst [OF mod_div_equality [of _ n]])
  1014   apply arith
  1015   done
  1016 
  1017 lemma div_mod_equality':
  1018   fixes m n :: nat
  1019   shows "m div n * n = m - m mod n"
  1020 proof -
  1021   have "m mod n \<le> m mod n" ..
  1022   from div_mod_equality have 
  1023     "m div n * n + m mod n - m mod n = m - m mod n" by simp
  1024   with diff_add_assoc [OF `m mod n \<le> m mod n`, of "m div n * n"] have
  1025     "m div n * n + (m mod n - m mod n) = m - m mod n"
  1026     by simp
  1027   then show ?thesis by simp
  1028 qed
  1029 
  1030 
  1031 subsubsection {*An ``induction'' law for modulus arithmetic.*}
  1032 
  1033 lemma mod_induct_0:
  1034   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1035   and base: "P i" and i: "i<p"
  1036   shows "P 0"
  1037 proof (rule ccontr)
  1038   assume contra: "\<not>(P 0)"
  1039   from i have p: "0<p" by simp
  1040   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1041   proof
  1042     fix k
  1043     show "?A k"
  1044     proof (induct k)
  1045       show "?A 0" by simp  -- "by contradiction"
  1046     next
  1047       fix n
  1048       assume ih: "?A n"
  1049       show "?A (Suc n)"
  1050       proof (clarsimp)
  1051         assume y: "P (p - Suc n)"
  1052         have n: "Suc n < p"
  1053         proof (rule ccontr)
  1054           assume "\<not>(Suc n < p)"
  1055           hence "p - Suc n = 0"
  1056             by simp
  1057           with y contra show "False"
  1058             by simp
  1059         qed
  1060         hence n2: "Suc (p - Suc n) = p-n" by arith
  1061         from p have "p - Suc n < p" by arith
  1062         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1063           by blast
  1064         show "False"
  1065         proof (cases "n=0")
  1066           case True
  1067           with z n2 contra show ?thesis by simp
  1068         next
  1069           case False
  1070           with p have "p-n < p" by arith
  1071           with z n2 False ih show ?thesis by simp
  1072         qed
  1073       qed
  1074     qed
  1075   qed
  1076   moreover
  1077   from i obtain k where "0<k \<and> i+k=p"
  1078     by (blast dest: less_imp_add_positive)
  1079   hence "0<k \<and> i=p-k" by auto
  1080   moreover
  1081   note base
  1082   ultimately
  1083   show "False" by blast
  1084 qed
  1085 
  1086 lemma mod_induct:
  1087   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1088   and base: "P i" and i: "i<p" and j: "j<p"
  1089   shows "P j"
  1090 proof -
  1091   have "\<forall>j<p. P j"
  1092   proof
  1093     fix j
  1094     show "j<p \<longrightarrow> P j" (is "?A j")
  1095     proof (induct j)
  1096       from step base i show "?A 0"
  1097         by (auto elim: mod_induct_0)
  1098     next
  1099       fix k
  1100       assume ih: "?A k"
  1101       show "?A (Suc k)"
  1102       proof
  1103         assume suc: "Suc k < p"
  1104         hence k: "k<p" by simp
  1105         with ih have "P k" ..
  1106         with step k have "P (Suc k mod p)"
  1107           by blast
  1108         moreover
  1109         from suc have "Suc k mod p = Suc k"
  1110           by simp
  1111         ultimately
  1112         show "P (Suc k)" by simp
  1113       qed
  1114     qed
  1115   qed
  1116   with j show ?thesis by blast
  1117 qed
  1118 
  1119 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1120 by (auto simp add: numeral_2_eq_2 le_div_geq)
  1121 
  1122 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1123 by (simp add: nat_mult_2 [symmetric])
  1124 
  1125 lemma mod2_Suc_Suc [simp]: "Suc(Suc(m)) mod 2 = m mod 2"
  1126 apply (subgoal_tac "m mod 2 < 2")
  1127 apply (erule less_2_cases [THEN disjE])
  1128 apply (simp_all (no_asm_simp) add: Let_def mod_Suc)
  1129 done
  1130 
  1131 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1132 proof -
  1133   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1134   moreover have "m mod 2 < 2" by simp
  1135   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1136   then show ?thesis by auto
  1137 qed
  1138 
  1139 text{*These lemmas collapse some needless occurrences of Suc:
  1140     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1141     We already have some rules to simplify operands smaller than 3.*}
  1142 
  1143 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1144 by (simp add: Suc3_eq_add_3)
  1145 
  1146 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1147 by (simp add: Suc3_eq_add_3)
  1148 
  1149 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1150 by (simp add: Suc3_eq_add_3)
  1151 
  1152 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1153 by (simp add: Suc3_eq_add_3)
  1154 
  1155 lemmas Suc_div_eq_add3_div_number_of =
  1156     Suc_div_eq_add3_div [of _ "number_of v", standard]
  1157 declare Suc_div_eq_add3_div_number_of [simp]
  1158 
  1159 lemmas Suc_mod_eq_add3_mod_number_of =
  1160     Suc_mod_eq_add3_mod [of _ "number_of v", standard]
  1161 declare Suc_mod_eq_add3_mod_number_of [simp]
  1162 
  1163 
  1164 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1165 apply (induct "m")
  1166 apply (simp_all add: mod_Suc)
  1167 done
  1168 
  1169 declare Suc_times_mod_eq [of "number_of w", standard, simp]
  1170 
  1171 lemma [simp]: "n div k \<le> (Suc n) div k"
  1172 by (simp add: div_le_mono) 
  1173 
  1174 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1175 by (cases n) simp_all
  1176 
  1177 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1178 proof -
  1179   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1180   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1181 qed
  1182 
  1183   (* Potential use of algebra : Equality modulo n*)
  1184 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1185 by (simp add: mult_ac add_ac)
  1186 
  1187 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1188 proof -
  1189   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1190   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1191   finally show ?thesis .
  1192 qed
  1193 
  1194 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1195 apply (subst mod_Suc [of m]) 
  1196 apply (subst mod_Suc [of "m mod n"], simp) 
  1197 done
  1198 
  1199 
  1200 subsection {* Division on @{typ int} *}
  1201 
  1202 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1203     --{*definition of quotient and remainder*}
  1204     [code]: "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1205                (if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0))"
  1206 
  1207 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1208     --{*for the division algorithm*}
  1209     [code]: "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1210                          else (2 * q, r))"
  1211 
  1212 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1213 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1214   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1215      else adjust b (posDivAlg a (2 * b)))"
  1216 by auto
  1217 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1218   (auto simp add: mult_2)
  1219 
  1220 text{*algorithm for the case @{text "a<0, b>0"}*}
  1221 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1222   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1223      else adjust b (negDivAlg a (2 * b)))"
  1224 by auto
  1225 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1226   (auto simp add: mult_2)
  1227 
  1228 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1229 definition negateSnd :: "int \<times> int \<Rightarrow> int \<times> int" where
  1230   [code_unfold]: "negateSnd = apsnd uminus"
  1231 
  1232 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1233     --{*The full division algorithm considers all possible signs for a, b
  1234        including the special case @{text "a=0, b<0"} because 
  1235        @{term negDivAlg} requires @{term "a<0"}.*}
  1236   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1237                   else if a = 0 then (0, 0)
  1238                        else negateSnd (negDivAlg (-a) (-b))
  1239                else 
  1240                   if 0 < b then negDivAlg a b
  1241                   else negateSnd (posDivAlg (-a) (-b)))"
  1242 
  1243 instantiation int :: Divides.div
  1244 begin
  1245 
  1246 definition
  1247   "a div b = fst (divmod_int a b)"
  1248 
  1249 definition
  1250  "a mod b = snd (divmod_int a b)"
  1251 
  1252 instance ..
  1253 
  1254 end
  1255 
  1256 lemma divmod_int_mod_div:
  1257   "divmod_int p q = (p div q, p mod q)"
  1258   by (auto simp add: div_int_def mod_int_def)
  1259 
  1260 text{*
  1261 Here is the division algorithm in ML:
  1262 
  1263 \begin{verbatim}
  1264     fun posDivAlg (a,b) =
  1265       if a<b then (0,a)
  1266       else let val (q,r) = posDivAlg(a, 2*b)
  1267                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1268            end
  1269 
  1270     fun negDivAlg (a,b) =
  1271       if 0\<le>a+b then (~1,a+b)
  1272       else let val (q,r) = negDivAlg(a, 2*b)
  1273                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1274            end;
  1275 
  1276     fun negateSnd (q,r:int) = (q,~r);
  1277 
  1278     fun divmod (a,b) = if 0\<le>a then 
  1279                           if b>0 then posDivAlg (a,b) 
  1280                            else if a=0 then (0,0)
  1281                                 else negateSnd (negDivAlg (~a,~b))
  1282                        else 
  1283                           if 0<b then negDivAlg (a,b)
  1284                           else        negateSnd (posDivAlg (~a,~b));
  1285 \end{verbatim}
  1286 *}
  1287 
  1288 
  1289 
  1290 subsubsection{*Uniqueness and Monotonicity of Quotients and Remainders*}
  1291 
  1292 lemma unique_quotient_lemma:
  1293      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1294       ==> q' \<le> (q::int)"
  1295 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1296  prefer 2 apply (simp add: right_diff_distrib)
  1297 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1298 apply (erule_tac [2] order_le_less_trans)
  1299  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1300 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1301  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1302 apply (simp add: mult_less_cancel_left)
  1303 done
  1304 
  1305 lemma unique_quotient_lemma_neg:
  1306      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1307       ==> q \<le> (q'::int)"
  1308 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1309     auto)
  1310 
  1311 lemma unique_quotient:
  1312      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r');  b \<noteq> 0 |]  
  1313       ==> q = q'"
  1314 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1315 apply (blast intro: order_antisym
  1316              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1317              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1318 done
  1319 
  1320 
  1321 lemma unique_remainder:
  1322      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r');  b \<noteq> 0 |]  
  1323       ==> r = r'"
  1324 apply (subgoal_tac "q = q'")
  1325  apply (simp add: divmod_int_rel_def)
  1326 apply (blast intro: unique_quotient)
  1327 done
  1328 
  1329 
  1330 subsubsection{*Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends*}
  1331 
  1332 text{*And positive divisors*}
  1333 
  1334 lemma adjust_eq [simp]:
  1335      "adjust b (q,r) = 
  1336       (let diff = r-b in  
  1337         if 0 \<le> diff then (2*q + 1, diff)   
  1338                      else (2*q, r))"
  1339 by (simp add: Let_def adjust_def)
  1340 
  1341 declare posDivAlg.simps [simp del]
  1342 
  1343 text{*use with a simproc to avoid repeatedly proving the premise*}
  1344 lemma posDivAlg_eqn:
  1345      "0 < b ==>  
  1346       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1347 by (rule posDivAlg.simps [THEN trans], simp)
  1348 
  1349 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1350 theorem posDivAlg_correct:
  1351   assumes "0 \<le> a" and "0 < b"
  1352   shows "divmod_int_rel a b (posDivAlg a b)"
  1353 using prems apply (induct a b rule: posDivAlg.induct)
  1354 apply auto
  1355 apply (simp add: divmod_int_rel_def)
  1356 apply (subst posDivAlg_eqn, simp add: right_distrib)
  1357 apply (case_tac "a < b")
  1358 apply simp_all
  1359 apply (erule splitE)
  1360 apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1361 done
  1362 
  1363 
  1364 subsubsection{*Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends*}
  1365 
  1366 text{*And positive divisors*}
  1367 
  1368 declare negDivAlg.simps [simp del]
  1369 
  1370 text{*use with a simproc to avoid repeatedly proving the premise*}
  1371 lemma negDivAlg_eqn:
  1372      "0 < b ==>  
  1373       negDivAlg a b =       
  1374        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1375 by (rule negDivAlg.simps [THEN trans], simp)
  1376 
  1377 (*Correctness of negDivAlg: it computes quotients correctly
  1378   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1379 lemma negDivAlg_correct:
  1380   assumes "a < 0" and "b > 0"
  1381   shows "divmod_int_rel a b (negDivAlg a b)"
  1382 using prems apply (induct a b rule: negDivAlg.induct)
  1383 apply (auto simp add: linorder_not_le)
  1384 apply (simp add: divmod_int_rel_def)
  1385 apply (subst negDivAlg_eqn, assumption)
  1386 apply (case_tac "a + b < (0\<Colon>int)")
  1387 apply simp_all
  1388 apply (erule splitE)
  1389 apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1390 done
  1391 
  1392 
  1393 subsubsection{*Existence Shown by Proving the Division Algorithm to be Correct*}
  1394 
  1395 (*the case a=0*)
  1396 lemma divmod_int_rel_0: "b \<noteq> 0 ==> divmod_int_rel 0 b (0, 0)"
  1397 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1398 
  1399 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1400 by (subst posDivAlg.simps, auto)
  1401 
  1402 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1403 by (subst negDivAlg.simps, auto)
  1404 
  1405 lemma negateSnd_eq [simp]: "negateSnd(q,r) = (q,-r)"
  1406 by (simp add: negateSnd_def)
  1407 
  1408 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (negateSnd qr)"
  1409 by (auto simp add: split_ifs divmod_int_rel_def)
  1410 
  1411 lemma divmod_int_correct: "b \<noteq> 0 ==> divmod_int_rel a b (divmod_int a b)"
  1412 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1413                     posDivAlg_correct negDivAlg_correct)
  1414 
  1415 text{*Arbitrary definitions for division by zero.  Useful to simplify 
  1416     certain equations.*}
  1417 
  1418 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"
  1419 by (simp add: div_int_def mod_int_def divmod_int_def posDivAlg.simps)  
  1420 
  1421 
  1422 text{*Basic laws about division and remainder*}
  1423 
  1424 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1425 apply (case_tac "b = 0", simp)
  1426 apply (cut_tac a = a and b = b in divmod_int_correct)
  1427 apply (auto simp add: divmod_int_rel_def div_int_def mod_int_def)
  1428 done
  1429 
  1430 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
  1431 by(simp add: zmod_zdiv_equality[symmetric])
  1432 
  1433 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
  1434 by(simp add: mult_commute zmod_zdiv_equality[symmetric])
  1435 
  1436 text {* Tool setup *}
  1437 
  1438 ML {*
  1439 local
  1440 
  1441 structure CancelDivMod = CancelDivModFun(struct
  1442 
  1443   val div_name = @{const_name div};
  1444   val mod_name = @{const_name mod};
  1445   val mk_binop = HOLogic.mk_binop;
  1446   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1447   val dest_sum = Arith_Data.dest_sum;
  1448 
  1449   val div_mod_eqs = map mk_meta_eq [@{thm zdiv_zmod_equality}, @{thm zdiv_zmod_equality2}];
  1450 
  1451   val trans = trans;
  1452 
  1453   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1454     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1455 
  1456 end)
  1457 
  1458 in
  1459 
  1460 val cancel_div_mod_int_proc = Simplifier.simproc @{theory}
  1461   "cancel_zdiv_zmod" ["(k::int) + l"] (K CancelDivMod.proc);
  1462 
  1463 val _ = Addsimprocs [cancel_div_mod_int_proc];
  1464 
  1465 end
  1466 *}
  1467 
  1468 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"
  1469 apply (cut_tac a = a and b = b in divmod_int_correct)
  1470 apply (auto simp add: divmod_int_rel_def mod_int_def)
  1471 done
  1472 
  1473 lemmas pos_mod_sign  [simp] = pos_mod_conj [THEN conjunct1, standard]
  1474    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2, standard]
  1475 
  1476 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"
  1477 apply (cut_tac a = a and b = b in divmod_int_correct)
  1478 apply (auto simp add: divmod_int_rel_def div_int_def mod_int_def)
  1479 done
  1480 
  1481 lemmas neg_mod_sign  [simp] = neg_mod_conj [THEN conjunct1, standard]
  1482    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2, standard]
  1483 
  1484 
  1485 
  1486 subsubsection{*General Properties of div and mod*}
  1487 
  1488 lemma divmod_int_rel_div_mod: "b \<noteq> 0 ==> divmod_int_rel a b (a div b, a mod b)"
  1489 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1490 apply (force simp add: divmod_int_rel_def linorder_neq_iff)
  1491 done
  1492 
  1493 lemma divmod_int_rel_div: "[| divmod_int_rel a b (q, r);  b \<noteq> 0 |] ==> a div b = q"
  1494 by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1495 
  1496 lemma divmod_int_rel_mod: "[| divmod_int_rel a b (q, r);  b \<noteq> 0 |] ==> a mod b = r"
  1497 by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1498 
  1499 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1500 apply (rule divmod_int_rel_div)
  1501 apply (auto simp add: divmod_int_rel_def)
  1502 done
  1503 
  1504 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1505 apply (rule divmod_int_rel_div)
  1506 apply (auto simp add: divmod_int_rel_def)
  1507 done
  1508 
  1509 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1510 apply (rule divmod_int_rel_div)
  1511 apply (auto simp add: divmod_int_rel_def)
  1512 done
  1513 
  1514 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1515 
  1516 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1517 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1518 apply (auto simp add: divmod_int_rel_def)
  1519 done
  1520 
  1521 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1522 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1523 apply (auto simp add: divmod_int_rel_def)
  1524 done
  1525 
  1526 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1527 apply (rule_tac q = "-1" in divmod_int_rel_mod)
  1528 apply (auto simp add: divmod_int_rel_def)
  1529 done
  1530 
  1531 text{*There is no @{text mod_neg_pos_trivial}.*}
  1532 
  1533 
  1534 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
  1535 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
  1536 apply (case_tac "b = 0", simp)
  1537 apply (simp add: divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, 
  1538                                  THEN divmod_int_rel_div, THEN sym])
  1539 
  1540 done
  1541 
  1542 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
  1543 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
  1544 apply (case_tac "b = 0", simp)
  1545 apply (subst divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, THEN divmod_int_rel_mod],
  1546        auto)
  1547 done
  1548 
  1549 
  1550 subsubsection{*Laws for div and mod with Unary Minus*}
  1551 
  1552 lemma zminus1_lemma:
  1553      "divmod_int_rel a b (q, r)
  1554       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1555                           if r=0 then 0 else b-r)"
  1556 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1557 
  1558 
  1559 lemma zdiv_zminus1_eq_if:
  1560      "b \<noteq> (0::int)  
  1561       ==> (-a) div b =  
  1562           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1563 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_div])
  1564 
  1565 lemma zmod_zminus1_eq_if:
  1566      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1567 apply (case_tac "b = 0", simp)
  1568 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_mod])
  1569 done
  1570 
  1571 lemma zmod_zminus1_not_zero:
  1572   fixes k l :: int
  1573   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1574   unfolding zmod_zminus1_eq_if by auto
  1575 
  1576 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
  1577 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)
  1578 
  1579 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
  1580 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)
  1581 
  1582 lemma zdiv_zminus2_eq_if:
  1583      "b \<noteq> (0::int)  
  1584       ==> a div (-b) =  
  1585           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1586 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
  1587 
  1588 lemma zmod_zminus2_eq_if:
  1589      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1590 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
  1591 
  1592 lemma zmod_zminus2_not_zero:
  1593   fixes k l :: int
  1594   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1595   unfolding zmod_zminus2_eq_if by auto 
  1596 
  1597 
  1598 subsubsection{*Division of a Number by Itself*}
  1599 
  1600 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"
  1601 apply (subgoal_tac "0 < a*q")
  1602  apply (simp add: zero_less_mult_iff, arith)
  1603 done
  1604 
  1605 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"
  1606 apply (subgoal_tac "0 \<le> a* (1-q) ")
  1607  apply (simp add: zero_le_mult_iff)
  1608 apply (simp add: right_diff_distrib)
  1609 done
  1610 
  1611 lemma self_quotient: "[| divmod_int_rel a a (q, r);  a \<noteq> (0::int) |] ==> q = 1"
  1612 apply (simp add: split_ifs divmod_int_rel_def linorder_neq_iff)
  1613 apply (rule order_antisym, safe, simp_all)
  1614 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)
  1615 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)
  1616 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+
  1617 done
  1618 
  1619 lemma self_remainder: "[| divmod_int_rel a a (q, r);  a \<noteq> (0::int) |] ==> r = 0"
  1620 apply (frule self_quotient, assumption)
  1621 apply (simp add: divmod_int_rel_def)
  1622 done
  1623 
  1624 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"
  1625 by (simp add: divmod_int_rel_div_mod [THEN self_quotient])
  1626 
  1627 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)
  1628 lemma zmod_self [simp]: "a mod a = (0::int)"
  1629 apply (case_tac "a = 0", simp)
  1630 apply (simp add: divmod_int_rel_div_mod [THEN self_remainder])
  1631 done
  1632 
  1633 
  1634 subsubsection{*Computation of Division and Remainder*}
  1635 
  1636 lemma zdiv_zero [simp]: "(0::int) div b = 0"
  1637 by (simp add: div_int_def divmod_int_def)
  1638 
  1639 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1640 by (simp add: div_int_def divmod_int_def)
  1641 
  1642 lemma zmod_zero [simp]: "(0::int) mod b = 0"
  1643 by (simp add: mod_int_def divmod_int_def)
  1644 
  1645 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1646 by (simp add: mod_int_def divmod_int_def)
  1647 
  1648 text{*a positive, b positive *}
  1649 
  1650 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1651 by (simp add: div_int_def divmod_int_def)
  1652 
  1653 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1654 by (simp add: mod_int_def divmod_int_def)
  1655 
  1656 text{*a negative, b positive *}
  1657 
  1658 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1659 by (simp add: div_int_def divmod_int_def)
  1660 
  1661 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1662 by (simp add: mod_int_def divmod_int_def)
  1663 
  1664 text{*a positive, b negative *}
  1665 
  1666 lemma div_pos_neg:
  1667      "[| 0 < a;  b < 0 |] ==> a div b = fst (negateSnd (negDivAlg (-a) (-b)))"
  1668 by (simp add: div_int_def divmod_int_def)
  1669 
  1670 lemma mod_pos_neg:
  1671      "[| 0 < a;  b < 0 |] ==> a mod b = snd (negateSnd (negDivAlg (-a) (-b)))"
  1672 by (simp add: mod_int_def divmod_int_def)
  1673 
  1674 text{*a negative, b negative *}
  1675 
  1676 lemma div_neg_neg:
  1677      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (negateSnd (posDivAlg (-a) (-b)))"
  1678 by (simp add: div_int_def divmod_int_def)
  1679 
  1680 lemma mod_neg_neg:
  1681      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (negateSnd (posDivAlg (-a) (-b)))"
  1682 by (simp add: mod_int_def divmod_int_def)
  1683 
  1684 text {*Simplify expresions in which div and mod combine numerical constants*}
  1685 
  1686 lemma divmod_int_relI:
  1687   "\<lbrakk>a == b * q + r; if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0\<rbrakk>
  1688     \<Longrightarrow> divmod_int_rel a b (q, r)"
  1689   unfolding divmod_int_rel_def by simp
  1690 
  1691 lemmas divmod_int_rel_div_eq = divmod_int_relI [THEN divmod_int_rel_div, THEN eq_reflection]
  1692 lemmas divmod_int_rel_mod_eq = divmod_int_relI [THEN divmod_int_rel_mod, THEN eq_reflection]
  1693 lemmas arithmetic_simps =
  1694   arith_simps
  1695   add_special
  1696   add_0_left
  1697   add_0_right
  1698   mult_zero_left
  1699   mult_zero_right
  1700   mult_1_left
  1701   mult_1_right
  1702 
  1703 (* simprocs adapted from HOL/ex/Binary.thy *)
  1704 ML {*
  1705 local
  1706   val mk_number = HOLogic.mk_number HOLogic.intT;
  1707   fun mk_cert u k l = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"} $
  1708     (@{term "times :: int \<Rightarrow> int \<Rightarrow> int"} $ u $ mk_number k) $
  1709       mk_number l;
  1710   fun prove ctxt prop = Goal.prove ctxt [] [] prop
  1711     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps @{thms arithmetic_simps}))));
  1712   fun binary_proc proc ss ct =
  1713     (case Thm.term_of ct of
  1714       _ $ t $ u =>
  1715       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1716         SOME args => proc (Simplifier.the_context ss) args
  1717       | NONE => NONE)
  1718     | _ => NONE);
  1719 in
  1720   fun divmod_proc rule = binary_proc (fn ctxt => fn ((m, t), (n, u)) =>
  1721     if n = 0 then NONE
  1722     else let val (k, l) = Integer.div_mod m n;
  1723     in SOME (rule OF [prove ctxt (Logic.mk_equals (t, mk_cert u k l))]) end);
  1724 end
  1725 *}
  1726 
  1727 simproc_setup binary_int_div ("number_of m div number_of n :: int") =
  1728   {* K (divmod_proc (@{thm divmod_int_rel_div_eq})) *}
  1729 
  1730 simproc_setup binary_int_mod ("number_of m mod number_of n :: int") =
  1731   {* K (divmod_proc (@{thm divmod_int_rel_mod_eq})) *}
  1732 
  1733 lemmas posDivAlg_eqn_number_of [simp] =
  1734     posDivAlg_eqn [of "number_of v" "number_of w", standard]
  1735 
  1736 lemmas negDivAlg_eqn_number_of [simp] =
  1737     negDivAlg_eqn [of "number_of v" "number_of w", standard]
  1738 
  1739 
  1740 text{*Special-case simplification *}
  1741 
  1742 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
  1743 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
  1744 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
  1745 apply (auto simp del: neg_mod_sign neg_mod_bound)
  1746 done
  1747 
  1748 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
  1749 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
  1750 
  1751 (** The last remaining special cases for constant arithmetic:
  1752     1 div z and 1 mod z **)
  1753 
  1754 lemmas div_pos_pos_1_number_of [simp] =
  1755     div_pos_pos [OF int_0_less_1, of "number_of w", standard]
  1756 
  1757 lemmas div_pos_neg_1_number_of [simp] =
  1758     div_pos_neg [OF int_0_less_1, of "number_of w", standard]
  1759 
  1760 lemmas mod_pos_pos_1_number_of [simp] =
  1761     mod_pos_pos [OF int_0_less_1, of "number_of w", standard]
  1762 
  1763 lemmas mod_pos_neg_1_number_of [simp] =
  1764     mod_pos_neg [OF int_0_less_1, of "number_of w", standard]
  1765 
  1766 
  1767 lemmas posDivAlg_eqn_1_number_of [simp] =
  1768     posDivAlg_eqn [of concl: 1 "number_of w", standard]
  1769 
  1770 lemmas negDivAlg_eqn_1_number_of [simp] =
  1771     negDivAlg_eqn [of concl: 1 "number_of w", standard]
  1772 
  1773 
  1774 
  1775 subsubsection{*Monotonicity in the First Argument (Dividend)*}
  1776 
  1777 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1778 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1779 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1780 apply (rule unique_quotient_lemma)
  1781 apply (erule subst)
  1782 apply (erule subst, simp_all)
  1783 done
  1784 
  1785 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1786 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1787 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1788 apply (rule unique_quotient_lemma_neg)
  1789 apply (erule subst)
  1790 apply (erule subst, simp_all)
  1791 done
  1792 
  1793 
  1794 subsubsection{*Monotonicity in the Second Argument (Divisor)*}
  1795 
  1796 lemma q_pos_lemma:
  1797      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1798 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1799  apply (simp add: zero_less_mult_iff)
  1800 apply (simp add: right_distrib)
  1801 done
  1802 
  1803 lemma zdiv_mono2_lemma:
  1804      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1805          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1806       ==> q \<le> (q'::int)"
  1807 apply (frule q_pos_lemma, assumption+) 
  1808 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1809  apply (simp add: mult_less_cancel_left)
  1810 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1811  prefer 2 apply simp
  1812 apply (simp (no_asm_simp) add: right_distrib)
  1813 apply (subst add_commute, rule zadd_zless_mono, arith)
  1814 apply (rule mult_right_mono, auto)
  1815 done
  1816 
  1817 lemma zdiv_mono2:
  1818      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1819 apply (subgoal_tac "b \<noteq> 0")
  1820  prefer 2 apply arith
  1821 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1822 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1823 apply (rule zdiv_mono2_lemma)
  1824 apply (erule subst)
  1825 apply (erule subst, simp_all)
  1826 done
  1827 
  1828 lemma q_neg_lemma:
  1829      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1830 apply (subgoal_tac "b'*q' < 0")
  1831  apply (simp add: mult_less_0_iff, arith)
  1832 done
  1833 
  1834 lemma zdiv_mono2_neg_lemma:
  1835      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1836          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1837       ==> q' \<le> (q::int)"
  1838 apply (frule q_neg_lemma, assumption+) 
  1839 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1840  apply (simp add: mult_less_cancel_left)
  1841 apply (simp add: right_distrib)
  1842 apply (subgoal_tac "b*q' \<le> b'*q'")
  1843  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1844 done
  1845 
  1846 lemma zdiv_mono2_neg:
  1847      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1848 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1849 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1850 apply (rule zdiv_mono2_neg_lemma)
  1851 apply (erule subst)
  1852 apply (erule subst, simp_all)
  1853 done
  1854 
  1855 
  1856 subsubsection{*More Algebraic Laws for div and mod*}
  1857 
  1858 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1859 
  1860 lemma zmult1_lemma:
  1861      "[| divmod_int_rel b c (q, r);  c \<noteq> 0 |]  
  1862       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1863 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1864 
  1865 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1866 apply (case_tac "c = 0", simp)
  1867 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_div])
  1868 done
  1869 
  1870 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
  1871 apply (case_tac "c = 0", simp)
  1872 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_mod])
  1873 done
  1874 
  1875 lemma zmod_zdiv_trivial: "(a mod b) div b = (0::int)"
  1876 apply (case_tac "b = 0", simp)
  1877 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)
  1878 done
  1879 
  1880 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1881 
  1882 lemma zadd1_lemma:
  1883      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br);  c \<noteq> 0 |]  
  1884       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1885 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1886 
  1887 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1888 lemma zdiv_zadd1_eq:
  1889      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1890 apply (case_tac "c = 0", simp)
  1891 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] divmod_int_rel_div)
  1892 done
  1893 
  1894 instance int :: ring_div
  1895 proof
  1896   fix a b c :: int
  1897   assume not0: "b \<noteq> 0"
  1898   show "(a + c * b) div b = c + a div b"
  1899     unfolding zdiv_zadd1_eq [of a "c * b"] using not0 
  1900       by (simp add: zmod_zmult1_eq zmod_zdiv_trivial zdiv_zmult1_eq)
  1901 next
  1902   fix a b c :: int
  1903   assume "a \<noteq> 0"
  1904   then show "(a * b) div (a * c) = b div c"
  1905   proof (cases "b \<noteq> 0 \<and> c \<noteq> 0")
  1906     case False then show ?thesis by auto
  1907   next
  1908     case True then have "b \<noteq> 0" and "c \<noteq> 0" by auto
  1909     with `a \<noteq> 0`
  1910     have "\<And>q r. divmod_int_rel b c (q, r) \<Longrightarrow> divmod_int_rel (a * b) (a * c) (q, a * r)"
  1911       apply (auto simp add: divmod_int_rel_def) 
  1912       apply (auto simp add: algebra_simps)
  1913       apply (auto simp add: zero_less_mult_iff zero_le_mult_iff mult_le_0_iff mult_commute [of a] mult_less_cancel_right)
  1914       done
  1915     moreover with `c \<noteq> 0` divmod_int_rel_div_mod have "divmod_int_rel b c (b div c, b mod c)" by auto
  1916     ultimately have "divmod_int_rel (a * b) (a * c) (b div c, a * (b mod c))" .
  1917     moreover from  `a \<noteq> 0` `c \<noteq> 0` have "a * c \<noteq> 0" by simp
  1918     ultimately show ?thesis by (rule divmod_int_rel_div)
  1919   qed
  1920 qed auto
  1921 
  1922 lemma posDivAlg_div_mod:
  1923   assumes "k \<ge> 0"
  1924   and "l \<ge> 0"
  1925   shows "posDivAlg k l = (k div l, k mod l)"
  1926 proof (cases "l = 0")
  1927   case True then show ?thesis by (simp add: posDivAlg.simps)
  1928 next
  1929   case False with assms posDivAlg_correct
  1930     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1931     by simp
  1932   from divmod_int_rel_div [OF this `l \<noteq> 0`] divmod_int_rel_mod [OF this `l \<noteq> 0`]
  1933   show ?thesis by simp
  1934 qed
  1935 
  1936 lemma negDivAlg_div_mod:
  1937   assumes "k < 0"
  1938   and "l > 0"
  1939   shows "negDivAlg k l = (k div l, k mod l)"
  1940 proof -
  1941   from assms have "l \<noteq> 0" by simp
  1942   from assms negDivAlg_correct
  1943     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1944     by simp
  1945   from divmod_int_rel_div [OF this `l \<noteq> 0`] divmod_int_rel_mod [OF this `l \<noteq> 0`]
  1946   show ?thesis by simp
  1947 qed
  1948 
  1949 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1950 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1951 
  1952 (* REVISIT: should this be generalized to all semiring_div types? *)
  1953 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1954 
  1955 
  1956 subsubsection{*Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1957 
  1958 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1959   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1960   to cause particular problems.*)
  1961 
  1962 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1963 
  1964 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1965 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1966  apply (simp add: algebra_simps)
  1967 apply (rule order_le_less_trans)
  1968  apply (erule_tac [2] mult_strict_right_mono)
  1969  apply (rule mult_left_mono_neg)
  1970   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1971  apply (simp)
  1972 apply (simp)
  1973 done
  1974 
  1975 lemma zmult2_lemma_aux2:
  1976      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1977 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1978  apply arith
  1979 apply (simp add: mult_le_0_iff)
  1980 done
  1981 
  1982 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1983 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1984 apply arith
  1985 apply (simp add: zero_le_mult_iff)
  1986 done
  1987 
  1988 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1989 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1990  apply (simp add: right_diff_distrib)
  1991 apply (rule order_less_le_trans)
  1992  apply (erule mult_strict_right_mono)
  1993  apply (rule_tac [2] mult_left_mono)
  1994   apply simp
  1995  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1996 apply simp
  1997 done
  1998 
  1999 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r);  b \<noteq> 0;  0 < c |]  
  2000       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  2001 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  2002                    zero_less_mult_iff right_distrib [symmetric] 
  2003                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)
  2004 
  2005 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  2006 apply (case_tac "b = 0", simp)
  2007 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_div])
  2008 done
  2009 
  2010 lemma zmod_zmult2_eq:
  2011      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  2012 apply (case_tac "b = 0", simp)
  2013 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_mod])
  2014 done
  2015 
  2016 
  2017 subsubsection {*Splitting Rules for div and mod*}
  2018 
  2019 text{*The proofs of the two lemmas below are essentially identical*}
  2020 
  2021 lemma split_pos_lemma:
  2022  "0<k ==> 
  2023     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  2024 apply (rule iffI, clarify)
  2025  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2026  apply (subst mod_add_eq) 
  2027  apply (subst zdiv_zadd1_eq) 
  2028  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  2029 txt{*converse direction*}
  2030 apply (drule_tac x = "n div k" in spec) 
  2031 apply (drule_tac x = "n mod k" in spec, simp)
  2032 done
  2033 
  2034 lemma split_neg_lemma:
  2035  "k<0 ==>
  2036     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  2037 apply (rule iffI, clarify)
  2038  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2039  apply (subst mod_add_eq) 
  2040  apply (subst zdiv_zadd1_eq) 
  2041  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  2042 txt{*converse direction*}
  2043 apply (drule_tac x = "n div k" in spec) 
  2044 apply (drule_tac x = "n mod k" in spec, simp)
  2045 done
  2046 
  2047 lemma split_zdiv:
  2048  "P(n div k :: int) =
  2049   ((k = 0 --> P 0) & 
  2050    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  2051    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  2052 apply (case_tac "k=0", simp)
  2053 apply (simp only: linorder_neq_iff)
  2054 apply (erule disjE) 
  2055  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  2056                       split_neg_lemma [of concl: "%x y. P x"])
  2057 done
  2058 
  2059 lemma split_zmod:
  2060  "P(n mod k :: int) =
  2061   ((k = 0 --> P n) & 
  2062    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  2063    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  2064 apply (case_tac "k=0", simp)
  2065 apply (simp only: linorder_neq_iff)
  2066 apply (erule disjE) 
  2067  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  2068                       split_neg_lemma [of concl: "%x y. P y"])
  2069 done
  2070 
  2071 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  2072   when these are applied to some constant that is of the form
  2073   @{term "number_of k"}: *}
  2074 declare split_zdiv [of _ _ "number_of k", standard, arith_split]
  2075 declare split_zmod [of _ _ "number_of k", standard, arith_split]
  2076 
  2077 
  2078 subsubsection{*Speeding up the Division Algorithm with Shifting*}
  2079 
  2080 text{*computing div by shifting *}
  2081 
  2082 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2083 proof cases
  2084   assume "a=0"
  2085     thus ?thesis by simp
  2086 next
  2087   assume "a\<noteq>0" and le_a: "0\<le>a"   
  2088   hence a_pos: "1 \<le> a" by arith
  2089   hence one_less_a2: "1 < 2 * a" by arith
  2090   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  2091     unfolding mult_le_cancel_left
  2092     by (simp add: add1_zle_eq add_commute [of 1])
  2093   with a_pos have "0 \<le> b mod a" by simp
  2094   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  2095     by (simp add: mod_pos_pos_trivial one_less_a2)
  2096   with  le_2a
  2097   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  2098     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  2099                   right_distrib) 
  2100   thus ?thesis
  2101     by (subst zdiv_zadd1_eq,
  2102         simp add: mod_mult_mult1 one_less_a2
  2103                   div_pos_pos_trivial)
  2104 qed
  2105 
  2106 lemma neg_zdiv_mult_2: 
  2107   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2108 proof -
  2109   have R: "1 + - (2 * (b + 1)) = - (1 + 2 * b)" by simp
  2110   have "(1 + 2 * (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a)"
  2111     by (rule pos_zdiv_mult_2, simp add: A)
  2112   thus ?thesis
  2113     by (simp only: R zdiv_zminus_zminus diff_minus
  2114       minus_add_distrib [symmetric] mult_minus_right)
  2115 qed
  2116 
  2117 lemma zdiv_number_of_Bit0 [simp]:
  2118      "number_of (Int.Bit0 v) div number_of (Int.Bit0 w) =  
  2119           number_of v div (number_of w :: int)"
  2120 by (simp only: number_of_eq numeral_simps) (simp add: mult_2 [symmetric])
  2121 
  2122 lemma zdiv_number_of_Bit1 [simp]:
  2123      "number_of (Int.Bit1 v) div number_of (Int.Bit0 w) =  
  2124           (if (0::int) \<le> number_of w                    
  2125            then number_of v div (number_of w)     
  2126            else (number_of v + (1::int)) div (number_of w))"
  2127 apply (simp only: number_of_eq numeral_simps UNIV_I split: split_if) 
  2128 apply (simp add: pos_zdiv_mult_2 neg_zdiv_mult_2 add_ac mult_2 [symmetric])
  2129 done
  2130 
  2131 
  2132 subsubsection{*Computing mod by Shifting (proofs resemble those for div)*}
  2133 
  2134 lemma pos_zmod_mult_2:
  2135   fixes a b :: int
  2136   assumes "0 \<le> a"
  2137   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2138 proof (cases "0 < a")
  2139   case False with assms show ?thesis by simp
  2140 next
  2141   case True
  2142   then have "b mod a < a" by (rule pos_mod_bound)
  2143   then have "1 + b mod a \<le> a" by simp
  2144   then have A: "2 * (1 + b mod a) \<le> 2 * a" by simp
  2145   from `0 < a` have "0 \<le> b mod a" by (rule pos_mod_sign)
  2146   then have B: "0 \<le> 1 + 2 * (b mod a)" by simp
  2147   have "((1\<Colon>int) mod ((2\<Colon>int) * a) + (2\<Colon>int) * b mod ((2\<Colon>int) * a)) mod ((2\<Colon>int) * a) = (1\<Colon>int) + (2\<Colon>int) * (b mod a)"
  2148     using `0 < a` and A
  2149     by (auto simp add: mod_mult_mult1 mod_pos_pos_trivial ring_distribs intro!: mod_pos_pos_trivial B)
  2150   then show ?thesis by (subst mod_add_eq)
  2151 qed
  2152 
  2153 lemma neg_zmod_mult_2:
  2154   fixes a b :: int
  2155   assumes "a \<le> 0"
  2156   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2157 proof -
  2158   from assms have "0 \<le> - a" by auto
  2159   then have "(1 + 2 * (- b - 1)) mod (2 * (- a)) = 1 + 2 * ((- b - 1) mod (- a))"
  2160     by (rule pos_zmod_mult_2)
  2161   then show ?thesis by (simp add: zmod_zminus2 algebra_simps)
  2162      (simp add: diff_minus add_ac)
  2163 qed
  2164 
  2165 lemma zmod_number_of_Bit0 [simp]:
  2166      "number_of (Int.Bit0 v) mod number_of (Int.Bit0 w) =  
  2167       (2::int) * (number_of v mod number_of w)"
  2168 apply (simp only: number_of_eq numeral_simps) 
  2169 apply (simp add: mod_mult_mult1 pos_zmod_mult_2 
  2170                  neg_zmod_mult_2 add_ac mult_2 [symmetric])
  2171 done
  2172 
  2173 lemma zmod_number_of_Bit1 [simp]:
  2174      "number_of (Int.Bit1 v) mod number_of (Int.Bit0 w) =  
  2175       (if (0::int) \<le> number_of w  
  2176                 then 2 * (number_of v mod number_of w) + 1     
  2177                 else 2 * ((number_of v + (1::int)) mod number_of w) - 1)"
  2178 apply (simp only: number_of_eq numeral_simps) 
  2179 apply (simp add: mod_mult_mult1 pos_zmod_mult_2 
  2180                  neg_zmod_mult_2 add_ac mult_2 [symmetric])
  2181 done
  2182 
  2183 
  2184 subsubsection{*Quotients of Signs*}
  2185 
  2186 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2187 apply (subgoal_tac "a div b \<le> -1", force)
  2188 apply (rule order_trans)
  2189 apply (rule_tac a' = "-1" in zdiv_mono1)
  2190 apply (auto simp add: div_eq_minus1)
  2191 done
  2192 
  2193 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2194 by (drule zdiv_mono1_neg, auto)
  2195 
  2196 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2197 by (drule zdiv_mono1, auto)
  2198 
  2199 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2200 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2201 They should all be simp rules unless that causes too much search. *}
  2202 
  2203 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2204 apply auto
  2205 apply (drule_tac [2] zdiv_mono1)
  2206 apply (auto simp add: linorder_neq_iff)
  2207 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2208 apply (blast intro: div_neg_pos_less0)
  2209 done
  2210 
  2211 lemma neg_imp_zdiv_nonneg_iff:
  2212   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2213 apply (subst zdiv_zminus_zminus [symmetric])
  2214 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2215 done
  2216 
  2217 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2218 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2219 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2220 
  2221 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2222 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2223 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2224 
  2225 lemma nonneg1_imp_zdiv_pos_iff:
  2226   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2227 apply rule
  2228  apply rule
  2229   using div_pos_pos_trivial[of a b]apply arith
  2230  apply(cases "b=0")apply simp
  2231  using div_nonneg_neg_le0[of a b]apply arith
  2232 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2233 done
  2234 
  2235 
  2236 subsubsection {* The Divides Relation *}
  2237 
  2238 lemmas zdvd_iff_zmod_eq_0_number_of [simp] =
  2239   dvd_eq_mod_eq_0 [of "number_of x::int" "number_of y::int", standard]
  2240 
  2241 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  2242   by (rule dvd_mod) (* TODO: remove *)
  2243 
  2244 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  2245   by (rule dvd_mod_imp_dvd) (* TODO: remove *)
  2246 
  2247 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2248   using zmod_zdiv_equality[where a="m" and b="n"]
  2249   by (simp add: algebra_simps)
  2250 
  2251 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  2252 apply (induct "y", auto)
  2253 apply (rule zmod_zmult1_eq [THEN trans])
  2254 apply (simp (no_asm_simp))
  2255 apply (rule mod_mult_eq [symmetric])
  2256 done
  2257 
  2258 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2259 apply (subst split_div, auto)
  2260 apply (subst split_zdiv, auto)
  2261 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2262 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2263 done
  2264 
  2265 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2266 apply (subst split_mod, auto)
  2267 apply (subst split_zmod, auto)
  2268 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2269        in unique_remainder)
  2270 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2271 done
  2272 
  2273 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2274 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2275 
  2276 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  2277 apply (subgoal_tac "m mod n = 0")
  2278  apply (simp add: zmult_div_cancel)
  2279 apply (simp only: dvd_eq_mod_eq_0)
  2280 done
  2281 
  2282 text{*Suggested by Matthias Daum*}
  2283 lemma int_power_div_base:
  2284      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2285 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2286  apply (erule ssubst)
  2287  apply (simp only: power_add)
  2288  apply simp_all
  2289 done
  2290 
  2291 text {* by Brian Huffman *}
  2292 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2293 by (rule mod_minus_eq [symmetric])
  2294 
  2295 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2296 by (rule mod_diff_left_eq [symmetric])
  2297 
  2298 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2299 by (rule mod_diff_right_eq [symmetric])
  2300 
  2301 lemmas zmod_simps =
  2302   mod_add_left_eq  [symmetric]
  2303   mod_add_right_eq [symmetric]
  2304   zmod_zmult1_eq   [symmetric]
  2305   mod_mult_left_eq [symmetric]
  2306   zpower_zmod
  2307   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2308 
  2309 text {* Distributive laws for function @{text nat}. *}
  2310 
  2311 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2312 apply (rule linorder_cases [of y 0])
  2313 apply (simp add: div_nonneg_neg_le0)
  2314 apply simp
  2315 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2316 done
  2317 
  2318 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2319 lemma nat_mod_distrib:
  2320   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2321 apply (case_tac "y = 0", simp)
  2322 apply (simp add: nat_eq_iff zmod_int)
  2323 done
  2324 
  2325 text  {* transfer setup *}
  2326 
  2327 lemma transfer_nat_int_functions:
  2328     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2329     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2330   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2331 
  2332 lemma transfer_nat_int_function_closures:
  2333     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2334     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2335   apply (cases "y = 0")
  2336   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2337   apply (cases "y = 0")
  2338   apply auto
  2339 done
  2340 
  2341 declare transfer_morphism_nat_int [transfer add return:
  2342   transfer_nat_int_functions
  2343   transfer_nat_int_function_closures
  2344 ]
  2345 
  2346 lemma transfer_int_nat_functions:
  2347     "(int x) div (int y) = int (x div y)"
  2348     "(int x) mod (int y) = int (x mod y)"
  2349   by (auto simp add: zdiv_int zmod_int)
  2350 
  2351 lemma transfer_int_nat_function_closures:
  2352     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2353     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2354   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2355 
  2356 declare transfer_morphism_int_nat [transfer add return:
  2357   transfer_int_nat_functions
  2358   transfer_int_nat_function_closures
  2359 ]
  2360 
  2361 text{*Suggested by Matthias Daum*}
  2362 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2363 apply (subgoal_tac "nat x div nat k < nat x")
  2364  apply (simp add: nat_div_distrib [symmetric])
  2365 apply (rule Divides.div_less_dividend, simp_all)
  2366 done
  2367 
  2368 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2369 proof
  2370   assume H: "x mod n = y mod n"
  2371   hence "x mod n - y mod n = 0" by simp
  2372   hence "(x mod n - y mod n) mod n = 0" by simp 
  2373   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2374   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2375 next
  2376   assume H: "n dvd x - y"
  2377   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2378   hence "x = n*k + y" by simp
  2379   hence "x mod n = (n*k + y) mod n" by simp
  2380   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2381 qed
  2382 
  2383 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2384   shows "\<exists>q. x = y + n * q"
  2385 proof-
  2386   from xy have th: "int x - int y = int (x - y)" by simp 
  2387   from xyn have "int x mod int n = int y mod int n" 
  2388     by (simp add: zmod_int[symmetric])
  2389   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2390   hence "n dvd x - y" by (simp add: th zdvd_int)
  2391   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2392 qed
  2393 
  2394 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2395   (is "?lhs = ?rhs")
  2396 proof
  2397   assume H: "x mod n = y mod n"
  2398   {assume xy: "x \<le> y"
  2399     from H have th: "y mod n = x mod n" by simp
  2400     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2401       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2402   moreover
  2403   {assume xy: "y \<le> x"
  2404     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2405       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2406   ultimately  show ?rhs using linear[of x y] by blast  
  2407 next
  2408   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2409   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2410   thus  ?lhs by simp
  2411 qed
  2412 
  2413 lemma div_nat_number_of [simp]:
  2414      "(number_of v :: nat)  div  number_of v' =  
  2415           (if neg (number_of v :: int) then 0  
  2416            else nat (number_of v div number_of v'))"
  2417   unfolding nat_number_of_def number_of_is_id neg_def
  2418   by (simp add: nat_div_distrib)
  2419 
  2420 lemma one_div_nat_number_of [simp]:
  2421      "Suc 0 div number_of v' = nat (1 div number_of v')" 
  2422 by (simp del: nat_numeral_1_eq_1 add: numeral_1_eq_Suc_0 [symmetric]) 
  2423 
  2424 lemma mod_nat_number_of [simp]:
  2425      "(number_of v :: nat)  mod  number_of v' =  
  2426         (if neg (number_of v :: int) then 0  
  2427          else if neg (number_of v' :: int) then number_of v  
  2428          else nat (number_of v mod number_of v'))"
  2429   unfolding nat_number_of_def number_of_is_id neg_def
  2430   by (simp add: nat_mod_distrib)
  2431 
  2432 lemma one_mod_nat_number_of [simp]:
  2433      "Suc 0 mod number_of v' =  
  2434         (if neg (number_of v' :: int) then Suc 0
  2435          else nat (1 mod number_of v'))"
  2436 by (simp del: nat_numeral_1_eq_1 add: numeral_1_eq_Suc_0 [symmetric]) 
  2437 
  2438 lemmas dvd_eq_mod_eq_0_number_of =
  2439   dvd_eq_mod_eq_0 [of "number_of x" "number_of y", standard]
  2440 
  2441 declare dvd_eq_mod_eq_0_number_of [simp]
  2442 
  2443 
  2444 subsubsection {* Nitpick *}
  2445 
  2446 lemma zmod_zdiv_equality':
  2447 "(m\<Colon>int) mod n = m - (m div n) * n"
  2448 by (rule_tac P="%x. m mod n = x - (m div n) * n"
  2449     in subst [OF mod_div_equality [of _ n]])
  2450    arith
  2451 
  2452 lemmas [nitpick_def] = dvd_eq_mod_eq_0 [THEN eq_reflection]
  2453                        mod_div_equality' [THEN eq_reflection]
  2454                        zmod_zdiv_equality' [THEN eq_reflection]
  2455 
  2456 
  2457 subsubsection {* Code generation *}
  2458 
  2459 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2460   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2461 
  2462 lemma pdivmod_posDivAlg [code]:
  2463   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2464 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2465 
  2466 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2467   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2468     then pdivmod k l
  2469     else (let (r, s) = pdivmod k l in
  2470       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2471 proof -
  2472   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2473   show ?thesis
  2474     by (simp add: divmod_int_mod_div pdivmod_def)
  2475       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2476       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2477 qed
  2478 
  2479 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2480   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2481     then pdivmod k l
  2482     else (let (r, s) = pdivmod k l in
  2483       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2484 proof -
  2485   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2486     by (auto simp add: not_less sgn_if)
  2487   then show ?thesis by (simp add: divmod_int_pdivmod)
  2488 qed
  2489 
  2490 context ring_1
  2491 begin
  2492 
  2493 lemma of_int_num [code]:
  2494   "of_int k = (if k = 0 then 0 else if k < 0 then
  2495      - of_int (- k) else let
  2496        (l, m) = divmod_int k 2;
  2497        l' = of_int l
  2498      in if m = 0 then l' + l' else l' + l' + 1)"
  2499 proof -
  2500   have aux1: "k mod (2\<Colon>int) \<noteq> (0\<Colon>int) \<Longrightarrow> 
  2501     of_int k = of_int (k div 2 * 2 + 1)"
  2502   proof -
  2503     have "k mod 2 < 2" by (auto intro: pos_mod_bound)
  2504     moreover have "0 \<le> k mod 2" by (auto intro: pos_mod_sign)
  2505     moreover assume "k mod 2 \<noteq> 0"
  2506     ultimately have "k mod 2 = 1" by arith
  2507     moreover have "of_int k = of_int (k div 2 * 2 + k mod 2)" by simp
  2508     ultimately show ?thesis by auto
  2509   qed
  2510   have aux2: "\<And>x. of_int 2 * x = x + x"
  2511   proof -
  2512     fix x
  2513     have int2: "(2::int) = 1 + 1" by arith
  2514     show "of_int 2 * x = x + x"
  2515     unfolding int2 of_int_add left_distrib by simp
  2516   qed
  2517   have aux3: "\<And>x. x * of_int 2 = x + x"
  2518   proof -
  2519     fix x
  2520     have int2: "(2::int) = 1 + 1" by arith
  2521     show "x * of_int 2 = x + x" 
  2522     unfolding int2 of_int_add right_distrib by simp
  2523   qed
  2524   from aux1 show ?thesis by (auto simp add: divmod_int_mod_div Let_def aux2 aux3)
  2525 qed
  2526 
  2527 end
  2528 
  2529 code_modulename SML
  2530   Divides Arith
  2531 
  2532 code_modulename OCaml
  2533   Divides Arith
  2534 
  2535 code_modulename Haskell
  2536   Divides Arith
  2537 
  2538 end