src/HOL/RealDef.thy
author wenzelm
Mon Mar 22 20:58:52 2010 +0100 (2010-03-22)
changeset 35898 c890a3835d15
parent 35635 90fffd5ff996
child 36349 39be26d1bc28
permissions -rw-r--r--
recovered header;
     1 (*  Title       : HOL/RealDef.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5     Additional contributions by Jeremy Avigad
     6 *)
     7 
     8 header{*Defining the Reals from the Positive Reals*}
     9 
    10 theory RealDef
    11 imports PReal
    12 begin
    13 
    14 definition
    15   realrel   ::  "((preal * preal) * (preal * preal)) set" where
    16   [code del]: "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    17 
    18 typedef (Real)  real = "UNIV//realrel"
    19   by (auto simp add: quotient_def)
    20 
    21 definition
    22   (** these don't use the overloaded "real" function: users don't see them **)
    23   real_of_preal :: "preal => real" where
    24   [code del]: "real_of_preal m = Abs_Real (realrel `` {(m + 1, 1)})"
    25 
    26 instantiation real :: "{zero, one, plus, minus, uminus, times, inverse, ord, abs, sgn}"
    27 begin
    28 
    29 definition
    30   real_zero_def [code del]: "0 = Abs_Real(realrel``{(1, 1)})"
    31 
    32 definition
    33   real_one_def [code del]: "1 = Abs_Real(realrel``{(1 + 1, 1)})"
    34 
    35 definition
    36   real_add_def [code del]: "z + w =
    37        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    38                  { Abs_Real(realrel``{(x+u, y+v)}) })"
    39 
    40 definition
    41   real_minus_def [code del]: "- r =  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    42 
    43 definition
    44   real_diff_def [code del]: "r - (s::real) = r + - s"
    45 
    46 definition
    47   real_mult_def [code del]:
    48     "z * w =
    49        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    50                  { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
    51 
    52 definition
    53   real_inverse_def [code del]: "inverse (R::real) = (THE S. (R = 0 & S = 0) | S * R = 1)"
    54 
    55 definition
    56   real_divide_def [code del]: "R / (S::real) = R * inverse S"
    57 
    58 definition
    59   real_le_def [code del]: "z \<le> (w::real) \<longleftrightarrow>
    60     (\<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w)"
    61 
    62 definition
    63   real_less_def [code del]: "x < (y\<Colon>real) \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
    64 
    65 definition
    66   real_abs_def:  "abs (r::real) = (if r < 0 then - r else r)"
    67 
    68 definition
    69   real_sgn_def: "sgn (x::real) = (if x=0 then 0 else if 0<x then 1 else - 1)"
    70 
    71 instance ..
    72 
    73 end
    74 
    75 subsection {* Equivalence relation over positive reals *}
    76 
    77 lemma preal_trans_lemma:
    78   assumes "x + y1 = x1 + y"
    79       and "x + y2 = x2 + y"
    80   shows "x1 + y2 = x2 + (y1::preal)"
    81 proof -
    82   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: add_ac)
    83   also have "... = (x2 + y) + x1"  by (simp add: prems)
    84   also have "... = x2 + (x1 + y)"  by (simp add: add_ac)
    85   also have "... = x2 + (x + y1)"  by (simp add: prems)
    86   also have "... = (x2 + y1) + x"  by (simp add: add_ac)
    87   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    88   thus ?thesis by (rule add_right_imp_eq)
    89 qed
    90 
    91 
    92 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
    93 by (simp add: realrel_def)
    94 
    95 lemma equiv_realrel: "equiv UNIV realrel"
    96 apply (auto simp add: equiv_def refl_on_def sym_def trans_def realrel_def)
    97 apply (blast dest: preal_trans_lemma) 
    98 done
    99 
   100 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
   101   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
   102 lemmas equiv_realrel_iff = 
   103        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   104 
   105 declare equiv_realrel_iff [simp]
   106 
   107 
   108 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   109 by (simp add: Real_def realrel_def quotient_def, blast)
   110 
   111 declare Abs_Real_inject [simp]
   112 declare Abs_Real_inverse [simp]
   113 
   114 
   115 text{*Case analysis on the representation of a real number as an equivalence
   116       class of pairs of positive reals.*}
   117 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   118      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   119 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   120 apply (drule arg_cong [where f=Abs_Real])
   121 apply (auto simp add: Rep_Real_inverse)
   122 done
   123 
   124 
   125 subsection {* Addition and Subtraction *}
   126 
   127 lemma real_add_congruent2_lemma:
   128      "[|a + ba = aa + b; ab + bc = ac + bb|]
   129       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   130 apply (simp add: add_assoc)
   131 apply (rule add_left_commute [of ab, THEN ssubst])
   132 apply (simp add: add_assoc [symmetric])
   133 apply (simp add: add_ac)
   134 done
   135 
   136 lemma real_add:
   137      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   138       Abs_Real (realrel``{(x+u, y+v)})"
   139 proof -
   140   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   141         respects2 realrel"
   142     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   143   thus ?thesis
   144     by (simp add: real_add_def UN_UN_split_split_eq
   145                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   146 qed
   147 
   148 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   149 proof -
   150   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   151     by (simp add: congruent_def add_commute) 
   152   thus ?thesis
   153     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   154 qed
   155 
   156 instance real :: ab_group_add
   157 proof
   158   fix x y z :: real
   159   show "(x + y) + z = x + (y + z)"
   160     by (cases x, cases y, cases z, simp add: real_add add_assoc)
   161   show "x + y = y + x"
   162     by (cases x, cases y, simp add: real_add add_commute)
   163   show "0 + x = x"
   164     by (cases x, simp add: real_add real_zero_def add_ac)
   165   show "- x + x = 0"
   166     by (cases x, simp add: real_minus real_add real_zero_def add_commute)
   167   show "x - y = x + - y"
   168     by (simp add: real_diff_def)
   169 qed
   170 
   171 
   172 subsection {* Multiplication *}
   173 
   174 lemma real_mult_congruent2_lemma:
   175      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   176           x * x1 + y * y1 + (x * y2 + y * x2) =
   177           x * x2 + y * y2 + (x * y1 + y * x1)"
   178 apply (simp add: add_left_commute add_assoc [symmetric])
   179 apply (simp add: add_assoc right_distrib [symmetric])
   180 apply (simp add: add_commute)
   181 done
   182 
   183 lemma real_mult_congruent2:
   184     "(%p1 p2.
   185         (%(x1,y1). (%(x2,y2). 
   186           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   187      respects2 realrel"
   188 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   189 apply (simp add: mult_commute add_commute)
   190 apply (auto simp add: real_mult_congruent2_lemma)
   191 done
   192 
   193 lemma real_mult:
   194       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   195        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   196 by (simp add: real_mult_def UN_UN_split_split_eq
   197          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   198 
   199 lemma real_mult_commute: "(z::real) * w = w * z"
   200 by (cases z, cases w, simp add: real_mult add_ac mult_ac)
   201 
   202 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   203 apply (cases z1, cases z2, cases z3)
   204 apply (simp add: real_mult algebra_simps)
   205 done
   206 
   207 lemma real_mult_1: "(1::real) * z = z"
   208 apply (cases z)
   209 apply (simp add: real_mult real_one_def algebra_simps)
   210 done
   211 
   212 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   213 apply (cases z1, cases z2, cases w)
   214 apply (simp add: real_add real_mult algebra_simps)
   215 done
   216 
   217 text{*one and zero are distinct*}
   218 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   219 proof -
   220   have "(1::preal) < 1 + 1"
   221     by (simp add: preal_self_less_add_left)
   222   thus ?thesis
   223     by (simp add: real_zero_def real_one_def)
   224 qed
   225 
   226 instance real :: comm_ring_1
   227 proof
   228   fix x y z :: real
   229   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   230   show "x * y = y * x" by (rule real_mult_commute)
   231   show "1 * x = x" by (rule real_mult_1)
   232   show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
   233   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   234 qed
   235 
   236 subsection {* Inverse and Division *}
   237 
   238 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   239 by (simp add: real_zero_def add_commute)
   240 
   241 text{*Instead of using an existential quantifier and constructing the inverse
   242 within the proof, we could define the inverse explicitly.*}
   243 
   244 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   245 apply (simp add: real_zero_def real_one_def, cases x)
   246 apply (cut_tac x = xa and y = y in linorder_less_linear)
   247 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   248 apply (rule_tac
   249         x = "Abs_Real (realrel``{(1, inverse (D) + 1)})"
   250        in exI)
   251 apply (rule_tac [2]
   252         x = "Abs_Real (realrel``{(inverse (D) + 1, 1)})" 
   253        in exI)
   254 apply (auto simp add: real_mult preal_mult_inverse_right algebra_simps)
   255 done
   256 
   257 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   258 apply (simp add: real_inverse_def)
   259 apply (drule real_mult_inverse_left_ex, safe)
   260 apply (rule theI, assumption, rename_tac z)
   261 apply (subgoal_tac "(z * x) * y = z * (x * y)")
   262 apply (simp add: mult_commute)
   263 apply (rule mult_assoc)
   264 done
   265 
   266 
   267 subsection{*The Real Numbers form a Field*}
   268 
   269 instance real :: field
   270 proof
   271   fix x y z :: real
   272   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   273   show "x / y = x * inverse y" by (simp add: real_divide_def)
   274 qed
   275 
   276 
   277 text{*Inverse of zero!  Useful to simplify certain equations*}
   278 
   279 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   280 by (simp add: real_inverse_def)
   281 
   282 instance real :: division_by_zero
   283 proof
   284   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   285 qed
   286 
   287 
   288 subsection{*The @{text "\<le>"} Ordering*}
   289 
   290 lemma real_le_refl: "w \<le> (w::real)"
   291 by (cases w, force simp add: real_le_def)
   292 
   293 text{*The arithmetic decision procedure is not set up for type preal.
   294   This lemma is currently unused, but it could simplify the proofs of the
   295   following two lemmas.*}
   296 lemma preal_eq_le_imp_le:
   297   assumes eq: "a+b = c+d" and le: "c \<le> a"
   298   shows "b \<le> (d::preal)"
   299 proof -
   300   have "c+d \<le> a+d" by (simp add: prems)
   301   hence "a+b \<le> a+d" by (simp add: prems)
   302   thus "b \<le> d" by simp
   303 qed
   304 
   305 lemma real_le_lemma:
   306   assumes l: "u1 + v2 \<le> u2 + v1"
   307       and "x1 + v1 = u1 + y1"
   308       and "x2 + v2 = u2 + y2"
   309   shows "x1 + y2 \<le> x2 + (y1::preal)"
   310 proof -
   311   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   312   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: add_ac)
   313   also have "... \<le> (x2+y1) + (u2+v1)" by (simp add: prems)
   314   finally show ?thesis by simp
   315 qed
   316 
   317 lemma real_le: 
   318      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   319       (x1 + y2 \<le> x2 + y1)"
   320 apply (simp add: real_le_def)
   321 apply (auto intro: real_le_lemma)
   322 done
   323 
   324 lemma real_le_antisym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   325 by (cases z, cases w, simp add: real_le)
   326 
   327 lemma real_trans_lemma:
   328   assumes "x + v \<le> u + y"
   329       and "u + v' \<le> u' + v"
   330       and "x2 + v2 = u2 + y2"
   331   shows "x + v' \<le> u' + (y::preal)"
   332 proof -
   333   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: add_ac)
   334   also have "... \<le> (u+y) + (u+v')" by (simp add: prems)
   335   also have "... \<le> (u+y) + (u'+v)" by (simp add: prems)
   336   also have "... = (u'+y) + (u+v)"  by (simp add: add_ac)
   337   finally show ?thesis by simp
   338 qed
   339 
   340 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   341 apply (cases i, cases j, cases k)
   342 apply (simp add: real_le)
   343 apply (blast intro: real_trans_lemma)
   344 done
   345 
   346 instance real :: order
   347 proof
   348   fix u v :: real
   349   show "u < v \<longleftrightarrow> u \<le> v \<and> \<not> v \<le> u" 
   350     by (auto simp add: real_less_def intro: real_le_antisym)
   351 qed (assumption | rule real_le_refl real_le_trans real_le_antisym)+
   352 
   353 (* Axiom 'linorder_linear' of class 'linorder': *)
   354 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   355 apply (cases z, cases w)
   356 apply (auto simp add: real_le real_zero_def add_ac)
   357 done
   358 
   359 instance real :: linorder
   360   by (intro_classes, rule real_le_linear)
   361 
   362 
   363 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   364 apply (cases x, cases y) 
   365 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   366                       add_ac)
   367 apply (simp_all add: add_assoc [symmetric])
   368 done
   369 
   370 lemma real_add_left_mono: 
   371   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   372 proof -
   373   have "z + x - (z + y) = (z + -z) + (x - y)" 
   374     by (simp add: algebra_simps) 
   375   with le show ?thesis 
   376     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   377 qed
   378 
   379 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   380 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   381 
   382 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   383 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   384 
   385 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   386 apply (cases x, cases y)
   387 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   388                  linorder_not_le [where 'a = preal] 
   389                   real_zero_def real_le real_mult)
   390   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   391 apply (auto dest!: less_add_left_Ex
   392      simp add: algebra_simps preal_self_less_add_left)
   393 done
   394 
   395 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   396 apply (rule real_sum_gt_zero_less)
   397 apply (drule real_less_sum_gt_zero [of x y])
   398 apply (drule real_mult_order, assumption)
   399 apply (simp add: right_distrib)
   400 done
   401 
   402 instantiation real :: distrib_lattice
   403 begin
   404 
   405 definition
   406   "(inf \<Colon> real \<Rightarrow> real \<Rightarrow> real) = min"
   407 
   408 definition
   409   "(sup \<Colon> real \<Rightarrow> real \<Rightarrow> real) = max"
   410 
   411 instance
   412   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
   413 
   414 end
   415 
   416 
   417 subsection{*The Reals Form an Ordered Field*}
   418 
   419 instance real :: linordered_field
   420 proof
   421   fix x y z :: real
   422   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   423   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
   424   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
   425   show "sgn x = (if x=0 then 0 else if 0<x then 1 else - 1)"
   426     by (simp only: real_sgn_def)
   427 qed
   428 
   429 text{*The function @{term real_of_preal} requires many proofs, but it seems
   430 to be essential for proving completeness of the reals from that of the
   431 positive reals.*}
   432 
   433 lemma real_of_preal_add:
   434      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   435 by (simp add: real_of_preal_def real_add algebra_simps)
   436 
   437 lemma real_of_preal_mult:
   438      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   439 by (simp add: real_of_preal_def real_mult algebra_simps)
   440 
   441 
   442 text{*Gleason prop 9-4.4 p 127*}
   443 lemma real_of_preal_trichotomy:
   444       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   445 apply (simp add: real_of_preal_def real_zero_def, cases x)
   446 apply (auto simp add: real_minus add_ac)
   447 apply (cut_tac x = x and y = y in linorder_less_linear)
   448 apply (auto dest!: less_add_left_Ex simp add: add_assoc [symmetric])
   449 done
   450 
   451 lemma real_of_preal_leD:
   452       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   453 by (simp add: real_of_preal_def real_le)
   454 
   455 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   456 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   457 
   458 lemma real_of_preal_lessD:
   459       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   460 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric])
   461 
   462 lemma real_of_preal_less_iff [simp]:
   463      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   464 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   465 
   466 lemma real_of_preal_le_iff:
   467      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   468 by (simp add: linorder_not_less [symmetric])
   469 
   470 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   471 apply (insert preal_self_less_add_left [of 1 m])
   472 apply (auto simp add: real_zero_def real_of_preal_def
   473                       real_less_def real_le_def add_ac)
   474 apply (rule_tac x="m + 1" in exI, rule_tac x="1" in exI)
   475 apply (simp add: add_ac)
   476 done
   477 
   478 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   479 by (simp add: real_of_preal_zero_less)
   480 
   481 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   482 proof -
   483   from real_of_preal_minus_less_zero
   484   show ?thesis by (blast dest: order_less_trans)
   485 qed
   486 
   487 
   488 subsection{*Theorems About the Ordering*}
   489 
   490 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   491 apply (auto simp add: real_of_preal_zero_less)
   492 apply (cut_tac x = x in real_of_preal_trichotomy)
   493 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   494 done
   495 
   496 lemma real_gt_preal_preal_Ex:
   497      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   498 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   499              intro: real_gt_zero_preal_Ex [THEN iffD1])
   500 
   501 lemma real_ge_preal_preal_Ex:
   502      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   503 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   504 
   505 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   506 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   507             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   508             simp add: real_of_preal_zero_less)
   509 
   510 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   511 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   512 
   513 
   514 subsection{*More Lemmas*}
   515 
   516 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   517 by auto
   518 
   519 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   520 by auto
   521 
   522 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   523   by (force elim: order_less_asym
   524             simp add: mult_less_cancel_right)
   525 
   526 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   527 apply (simp add: mult_le_cancel_right)
   528 apply (blast intro: elim: order_less_asym)
   529 done
   530 
   531 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   532 by(simp add:mult_commute)
   533 
   534 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   535 by (simp add: one_less_inverse_iff) (* TODO: generalize/move *)
   536 
   537 
   538 subsection {* Embedding numbers into the Reals *}
   539 
   540 abbreviation
   541   real_of_nat :: "nat \<Rightarrow> real"
   542 where
   543   "real_of_nat \<equiv> of_nat"
   544 
   545 abbreviation
   546   real_of_int :: "int \<Rightarrow> real"
   547 where
   548   "real_of_int \<equiv> of_int"
   549 
   550 abbreviation
   551   real_of_rat :: "rat \<Rightarrow> real"
   552 where
   553   "real_of_rat \<equiv> of_rat"
   554 
   555 consts
   556   (*overloaded constant for injecting other types into "real"*)
   557   real :: "'a => real"
   558 
   559 defs (overloaded)
   560   real_of_nat_def [code_unfold]: "real == real_of_nat"
   561   real_of_int_def [code_unfold]: "real == real_of_int"
   562 
   563 lemma real_eq_of_nat: "real = of_nat"
   564   unfolding real_of_nat_def ..
   565 
   566 lemma real_eq_of_int: "real = of_int"
   567   unfolding real_of_int_def ..
   568 
   569 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   570 by (simp add: real_of_int_def) 
   571 
   572 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   573 by (simp add: real_of_int_def) 
   574 
   575 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   576 by (simp add: real_of_int_def) 
   577 
   578 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   579 by (simp add: real_of_int_def) 
   580 
   581 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   582 by (simp add: real_of_int_def) 
   583 
   584 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   585 by (simp add: real_of_int_def) 
   586 
   587 lemma real_of_int_power [simp]: "real (x ^ n) = real (x::int) ^ n"
   588 by (simp add: real_of_int_def of_int_power)
   589 
   590 lemmas power_real_of_int = real_of_int_power [symmetric]
   591 
   592 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   593   apply (subst real_eq_of_int)+
   594   apply (rule of_int_setsum)
   595 done
   596 
   597 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   598     (PROD x:A. real(f x))"
   599   apply (subst real_eq_of_int)+
   600   apply (rule of_int_setprod)
   601 done
   602 
   603 lemma real_of_int_zero_cancel [simp, algebra, presburger]: "(real x = 0) = (x = (0::int))"
   604 by (simp add: real_of_int_def) 
   605 
   606 lemma real_of_int_inject [iff, algebra, presburger]: "(real (x::int) = real y) = (x = y)"
   607 by (simp add: real_of_int_def) 
   608 
   609 lemma real_of_int_less_iff [iff, presburger]: "(real (x::int) < real y) = (x < y)"
   610 by (simp add: real_of_int_def) 
   611 
   612 lemma real_of_int_le_iff [simp, presburger]: "(real (x::int) \<le> real y) = (x \<le> y)"
   613 by (simp add: real_of_int_def) 
   614 
   615 lemma real_of_int_gt_zero_cancel_iff [simp, presburger]: "(0 < real (n::int)) = (0 < n)"
   616 by (simp add: real_of_int_def) 
   617 
   618 lemma real_of_int_ge_zero_cancel_iff [simp, presburger]: "(0 <= real (n::int)) = (0 <= n)"
   619 by (simp add: real_of_int_def) 
   620 
   621 lemma real_of_int_lt_zero_cancel_iff [simp, presburger]: "(real (n::int) < 0) = (n < 0)" 
   622 by (simp add: real_of_int_def)
   623 
   624 lemma real_of_int_le_zero_cancel_iff [simp, presburger]: "(real (n::int) <= 0) = (n <= 0)"
   625 by (simp add: real_of_int_def)
   626 
   627 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   628 by (auto simp add: abs_if)
   629 
   630 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   631   apply (subgoal_tac "real n + 1 = real (n + 1)")
   632   apply (simp del: real_of_int_add)
   633   apply auto
   634 done
   635 
   636 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   637   apply (subgoal_tac "real m + 1 = real (m + 1)")
   638   apply (simp del: real_of_int_add)
   639   apply simp
   640 done
   641 
   642 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   643     real (x div d) + (real (x mod d)) / (real d)"
   644 proof -
   645   assume "d ~= 0"
   646   have "x = (x div d) * d + x mod d"
   647     by auto
   648   then have "real x = real (x div d) * real d + real(x mod d)"
   649     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   650   then have "real x / real d = ... / real d"
   651     by simp
   652   then show ?thesis
   653     by (auto simp add: add_divide_distrib algebra_simps prems)
   654 qed
   655 
   656 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   657     real(n div d) = real n / real d"
   658   apply (frule real_of_int_div_aux [of d n])
   659   apply simp
   660   apply (simp add: dvd_eq_mod_eq_0)
   661 done
   662 
   663 lemma real_of_int_div2:
   664   "0 <= real (n::int) / real (x) - real (n div x)"
   665   apply (case_tac "x = 0")
   666   apply simp
   667   apply (case_tac "0 < x")
   668   apply (simp add: algebra_simps)
   669   apply (subst real_of_int_div_aux)
   670   apply simp
   671   apply simp
   672   apply (subst zero_le_divide_iff)
   673   apply auto
   674   apply (simp add: algebra_simps)
   675   apply (subst real_of_int_div_aux)
   676   apply simp
   677   apply simp
   678   apply (subst zero_le_divide_iff)
   679   apply auto
   680 done
   681 
   682 lemma real_of_int_div3:
   683   "real (n::int) / real (x) - real (n div x) <= 1"
   684   apply(case_tac "x = 0")
   685   apply simp
   686   apply (simp add: algebra_simps)
   687   apply (subst real_of_int_div_aux)
   688   apply assumption
   689   apply simp
   690   apply (subst divide_le_eq)
   691   apply clarsimp
   692   apply (rule conjI)
   693   apply (rule impI)
   694   apply (rule order_less_imp_le)
   695   apply simp
   696   apply (rule impI)
   697   apply (rule order_less_imp_le)
   698   apply simp
   699 done
   700 
   701 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   702 by (insert real_of_int_div2 [of n x], simp)
   703 
   704 lemma Ints_real_of_int [simp]: "real (x::int) \<in> Ints"
   705 unfolding real_of_int_def by (rule Ints_of_int)
   706 
   707 
   708 subsection{*Embedding the Naturals into the Reals*}
   709 
   710 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   711 by (simp add: real_of_nat_def)
   712 
   713 lemma real_of_nat_1 [simp]: "real (1::nat) = 1"
   714 by (simp add: real_of_nat_def)
   715 
   716 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   717 by (simp add: real_of_nat_def)
   718 
   719 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   720 by (simp add: real_of_nat_def)
   721 
   722 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   723 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   724 by (simp add: real_of_nat_def)
   725 
   726 lemma real_of_nat_less_iff [iff]: 
   727      "(real (n::nat) < real m) = (n < m)"
   728 by (simp add: real_of_nat_def)
   729 
   730 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   731 by (simp add: real_of_nat_def)
   732 
   733 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   734 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   735 
   736 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   737 by (simp add: real_of_nat_def del: of_nat_Suc)
   738 
   739 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   740 by (simp add: real_of_nat_def of_nat_mult)
   741 
   742 lemma real_of_nat_power [simp]: "real (m ^ n) = real (m::nat) ^ n"
   743 by (simp add: real_of_nat_def of_nat_power)
   744 
   745 lemmas power_real_of_nat = real_of_nat_power [symmetric]
   746 
   747 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   748     (SUM x:A. real(f x))"
   749   apply (subst real_eq_of_nat)+
   750   apply (rule of_nat_setsum)
   751 done
   752 
   753 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   754     (PROD x:A. real(f x))"
   755   apply (subst real_eq_of_nat)+
   756   apply (rule of_nat_setprod)
   757 done
   758 
   759 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   760   apply (subst card_eq_setsum)
   761   apply (subst real_of_nat_setsum)
   762   apply simp
   763 done
   764 
   765 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   766 by (simp add: real_of_nat_def)
   767 
   768 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   769 by (simp add: real_of_nat_def)
   770 
   771 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   772 by (simp add: add: real_of_nat_def of_nat_diff)
   773 
   774 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   775 by (auto simp: real_of_nat_def)
   776 
   777 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   778 by (simp add: add: real_of_nat_def)
   779 
   780 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   781 by (simp add: add: real_of_nat_def)
   782 
   783 (* FIXME: duplicates real_of_nat_ge_zero *)
   784 lemma real_of_nat_ge_zero_cancel_iff: "(0 \<le> real (n::nat))"
   785 by (simp add: add: real_of_nat_def)
   786 
   787 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   788   apply (subgoal_tac "real n + 1 = real (Suc n)")
   789   apply simp
   790   apply (auto simp add: real_of_nat_Suc)
   791 done
   792 
   793 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   794   apply (subgoal_tac "real m + 1 = real (Suc m)")
   795   apply (simp add: less_Suc_eq_le)
   796   apply (simp add: real_of_nat_Suc)
   797 done
   798 
   799 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   800     real (x div d) + (real (x mod d)) / (real d)"
   801 proof -
   802   assume "0 < d"
   803   have "x = (x div d) * d + x mod d"
   804     by auto
   805   then have "real x = real (x div d) * real d + real(x mod d)"
   806     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   807   then have "real x / real d = \<dots> / real d"
   808     by simp
   809   then show ?thesis
   810     by (auto simp add: add_divide_distrib algebra_simps prems)
   811 qed
   812 
   813 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   814     real(n div d) = real n / real d"
   815   apply (frule real_of_nat_div_aux [of d n])
   816   apply simp
   817   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   818   apply assumption
   819 done
   820 
   821 lemma real_of_nat_div2:
   822   "0 <= real (n::nat) / real (x) - real (n div x)"
   823 apply(case_tac "x = 0")
   824  apply (simp)
   825 apply (simp add: algebra_simps)
   826 apply (subst real_of_nat_div_aux)
   827  apply simp
   828 apply simp
   829 apply (subst zero_le_divide_iff)
   830 apply simp
   831 done
   832 
   833 lemma real_of_nat_div3:
   834   "real (n::nat) / real (x) - real (n div x) <= 1"
   835 apply(case_tac "x = 0")
   836 apply (simp)
   837 apply (simp add: algebra_simps)
   838 apply (subst real_of_nat_div_aux)
   839  apply simp
   840 apply simp
   841 done
   842 
   843 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   844 by (insert real_of_nat_div2 [of n x], simp)
   845 
   846 lemma real_of_int_real_of_nat: "real (int n) = real n"
   847 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   848 
   849 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   850 by (simp add: real_of_int_def real_of_nat_def)
   851 
   852 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   853   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   854   apply force
   855   apply (simp only: real_of_int_real_of_nat)
   856 done
   857 
   858 lemma Nats_real_of_nat [simp]: "real (n::nat) \<in> Nats"
   859 unfolding real_of_nat_def by (rule of_nat_in_Nats)
   860 
   861 lemma Ints_real_of_nat [simp]: "real (n::nat) \<in> Ints"
   862 unfolding real_of_nat_def by (rule Ints_of_nat)
   863 
   864 
   865 subsection{* Rationals *}
   866 
   867 lemma Rats_real_nat[simp]: "real(n::nat) \<in> \<rat>"
   868 by (simp add: real_eq_of_nat)
   869 
   870 
   871 lemma Rats_eq_int_div_int:
   872   "\<rat> = { real(i::int)/real(j::int) |i j. j \<noteq> 0}" (is "_ = ?S")
   873 proof
   874   show "\<rat> \<subseteq> ?S"
   875   proof
   876     fix x::real assume "x : \<rat>"
   877     then obtain r where "x = of_rat r" unfolding Rats_def ..
   878     have "of_rat r : ?S"
   879       by (cases r)(auto simp add:of_rat_rat real_eq_of_int)
   880     thus "x : ?S" using `x = of_rat r` by simp
   881   qed
   882 next
   883   show "?S \<subseteq> \<rat>"
   884   proof(auto simp:Rats_def)
   885     fix i j :: int assume "j \<noteq> 0"
   886     hence "real i / real j = of_rat(Fract i j)"
   887       by (simp add:of_rat_rat real_eq_of_int)
   888     thus "real i / real j \<in> range of_rat" by blast
   889   qed
   890 qed
   891 
   892 lemma Rats_eq_int_div_nat:
   893   "\<rat> = { real(i::int)/real(n::nat) |i n. n \<noteq> 0}"
   894 proof(auto simp:Rats_eq_int_div_int)
   895   fix i j::int assume "j \<noteq> 0"
   896   show "EX (i'::int) (n::nat). real i/real j = real i'/real n \<and> 0<n"
   897   proof cases
   898     assume "j>0"
   899     hence "real i/real j = real i/real(nat j) \<and> 0<nat j"
   900       by (simp add: real_eq_of_int real_eq_of_nat of_nat_nat)
   901     thus ?thesis by blast
   902   next
   903     assume "~ j>0"
   904     hence "real i/real j = real(-i)/real(nat(-j)) \<and> 0<nat(-j)" using `j\<noteq>0`
   905       by (simp add: real_eq_of_int real_eq_of_nat of_nat_nat)
   906     thus ?thesis by blast
   907   qed
   908 next
   909   fix i::int and n::nat assume "0 < n"
   910   hence "real i/real n = real i/real(int n) \<and> int n \<noteq> 0" by simp
   911   thus "\<exists>(i'::int) j::int. real i/real n = real i'/real j \<and> j \<noteq> 0" by blast
   912 qed
   913 
   914 lemma Rats_abs_nat_div_natE:
   915   assumes "x \<in> \<rat>"
   916   obtains m n :: nat
   917   where "n \<noteq> 0" and "\<bar>x\<bar> = real m / real n" and "gcd m n = 1"
   918 proof -
   919   from `x \<in> \<rat>` obtain i::int and n::nat where "n \<noteq> 0" and "x = real i / real n"
   920     by(auto simp add: Rats_eq_int_div_nat)
   921   hence "\<bar>x\<bar> = real(nat(abs i)) / real n" by simp
   922   then obtain m :: nat where x_rat: "\<bar>x\<bar> = real m / real n" by blast
   923   let ?gcd = "gcd m n"
   924   from `n\<noteq>0` have gcd: "?gcd \<noteq> 0" by simp
   925   let ?k = "m div ?gcd"
   926   let ?l = "n div ?gcd"
   927   let ?gcd' = "gcd ?k ?l"
   928   have "?gcd dvd m" .. then have gcd_k: "?gcd * ?k = m"
   929     by (rule dvd_mult_div_cancel)
   930   have "?gcd dvd n" .. then have gcd_l: "?gcd * ?l = n"
   931     by (rule dvd_mult_div_cancel)
   932   from `n\<noteq>0` and gcd_l have "?l \<noteq> 0" by (auto iff del: neq0_conv)
   933   moreover
   934   have "\<bar>x\<bar> = real ?k / real ?l"
   935   proof -
   936     from gcd have "real ?k / real ?l =
   937         real (?gcd * ?k) / real (?gcd * ?l)" by simp
   938     also from gcd_k and gcd_l have "\<dots> = real m / real n" by simp
   939     also from x_rat have "\<dots> = \<bar>x\<bar>" ..
   940     finally show ?thesis ..
   941   qed
   942   moreover
   943   have "?gcd' = 1"
   944   proof -
   945     have "?gcd * ?gcd' = gcd (?gcd * ?k) (?gcd * ?l)"
   946       by (rule gcd_mult_distrib_nat)
   947     with gcd_k gcd_l have "?gcd * ?gcd' = ?gcd" by simp
   948     with gcd show ?thesis by auto
   949   qed
   950   ultimately show ?thesis ..
   951 qed
   952 
   953 
   954 subsection{*Numerals and Arithmetic*}
   955 
   956 instantiation real :: number_ring
   957 begin
   958 
   959 definition
   960   real_number_of_def [code del]: "number_of w = real_of_int w"
   961 
   962 instance
   963   by intro_classes (simp add: real_number_of_def)
   964 
   965 end
   966 
   967 lemma [code_unfold_post]:
   968   "number_of k = real_of_int (number_of k)"
   969   unfolding number_of_is_id real_number_of_def ..
   970 
   971 
   972 text{*Collapse applications of @{term real} to @{term number_of}*}
   973 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   974 by (simp add: real_of_int_def)
   975 
   976 lemma real_of_nat_number_of [simp]:
   977      "real (number_of v :: nat) =  
   978         (if neg (number_of v :: int) then 0  
   979          else (number_of v :: real))"
   980 by (simp add: real_of_int_real_of_nat [symmetric])
   981 
   982 declaration {*
   983   K (Lin_Arith.add_inj_thms [@{thm real_of_nat_le_iff} RS iffD2, @{thm real_of_nat_inject} RS iffD2]
   984     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: real_of_nat_less_iff RS iffD2 *)
   985   #> Lin_Arith.add_inj_thms [@{thm real_of_int_le_iff} RS iffD2, @{thm real_of_int_inject} RS iffD2]
   986     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: real_of_int_less_iff RS iffD2 *)
   987   #> Lin_Arith.add_simps [@{thm real_of_nat_zero}, @{thm real_of_nat_Suc}, @{thm real_of_nat_add},
   988       @{thm real_of_nat_mult}, @{thm real_of_int_zero}, @{thm real_of_one},
   989       @{thm real_of_int_add}, @{thm real_of_int_minus}, @{thm real_of_int_diff},
   990       @{thm real_of_int_mult}, @{thm real_of_int_of_nat_eq},
   991       @{thm real_of_nat_number_of}, @{thm real_number_of}]
   992   #> Lin_Arith.add_inj_const (@{const_name real}, HOLogic.natT --> HOLogic.realT)
   993   #> Lin_Arith.add_inj_const (@{const_name real}, HOLogic.intT --> HOLogic.realT))
   994 *}
   995 
   996 
   997 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   998 
   999 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
  1000 lemma real_0_le_divide_iff:
  1001      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
  1002 by (simp add: real_divide_def zero_le_mult_iff, auto)
  1003 
  1004 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
  1005 by arith
  1006 
  1007 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
  1008 by auto
  1009 
  1010 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
  1011 by auto
  1012 
  1013 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
  1014 by auto
  1015 
  1016 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
  1017 by auto
  1018 
  1019 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
  1020 by auto
  1021 
  1022 
  1023 (*
  1024 FIXME: we should have this, as for type int, but many proofs would break.
  1025 It replaces x+-y by x-y.
  1026 declare real_diff_def [symmetric, simp]
  1027 *)
  1028 
  1029 subsubsection{*Density of the Reals*}
  1030 
  1031 lemma real_lbound_gt_zero:
  1032      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
  1033 apply (rule_tac x = " (min d1 d2) /2" in exI)
  1034 apply (simp add: min_def)
  1035 done
  1036 
  1037 
  1038 text{*Similar results are proved in @{text Fields}*}
  1039 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
  1040   by auto
  1041 
  1042 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
  1043   by auto
  1044 
  1045 
  1046 subsection{*Absolute Value Function for the Reals*}
  1047 
  1048 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
  1049 by (simp add: abs_if)
  1050 
  1051 (* FIXME: redundant, but used by Integration/RealRandVar.thy in AFP *)
  1052 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
  1053 by (force simp add: abs_le_iff)
  1054 
  1055 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
  1056 by (simp add: abs_if)
  1057 
  1058 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
  1059 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
  1060 
  1061 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
  1062 by simp
  1063  
  1064 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
  1065 by simp
  1066 
  1067 
  1068 subsection {* Implementation of rational real numbers *}
  1069 
  1070 definition Ratreal :: "rat \<Rightarrow> real" where
  1071   [simp]: "Ratreal = of_rat"
  1072 
  1073 code_datatype Ratreal
  1074 
  1075 lemma Ratreal_number_collapse [code_post]:
  1076   "Ratreal 0 = 0"
  1077   "Ratreal 1 = 1"
  1078   "Ratreal (number_of k) = number_of k"
  1079 by simp_all
  1080 
  1081 lemma zero_real_code [code, code_unfold]:
  1082   "0 = Ratreal 0"
  1083 by simp
  1084 
  1085 lemma one_real_code [code, code_unfold]:
  1086   "1 = Ratreal 1"
  1087 by simp
  1088 
  1089 lemma number_of_real_code [code_unfold]:
  1090   "number_of k = Ratreal (number_of k)"
  1091 by simp
  1092 
  1093 lemma Ratreal_number_of_quotient [code_post]:
  1094   "Ratreal (number_of r) / Ratreal (number_of s) = number_of r / number_of s"
  1095 by simp
  1096 
  1097 lemma Ratreal_number_of_quotient2 [code_post]:
  1098   "Ratreal (number_of r / number_of s) = number_of r / number_of s"
  1099 unfolding Ratreal_number_of_quotient [symmetric] Ratreal_def of_rat_divide ..
  1100 
  1101 instantiation real :: eq
  1102 begin
  1103 
  1104 definition "eq_class.eq (x\<Colon>real) y \<longleftrightarrow> x - y = 0"
  1105 
  1106 instance by default (simp add: eq_real_def)
  1107 
  1108 lemma real_eq_code [code]: "eq_class.eq (Ratreal x) (Ratreal y) \<longleftrightarrow> eq_class.eq x y"
  1109   by (simp add: eq_real_def eq)
  1110 
  1111 lemma real_eq_refl [code nbe]:
  1112   "eq_class.eq (x::real) x \<longleftrightarrow> True"
  1113   by (rule HOL.eq_refl)
  1114 
  1115 end
  1116 
  1117 lemma real_less_eq_code [code]: "Ratreal x \<le> Ratreal y \<longleftrightarrow> x \<le> y"
  1118   by (simp add: of_rat_less_eq)
  1119 
  1120 lemma real_less_code [code]: "Ratreal x < Ratreal y \<longleftrightarrow> x < y"
  1121   by (simp add: of_rat_less)
  1122 
  1123 lemma real_plus_code [code]: "Ratreal x + Ratreal y = Ratreal (x + y)"
  1124   by (simp add: of_rat_add)
  1125 
  1126 lemma real_times_code [code]: "Ratreal x * Ratreal y = Ratreal (x * y)"
  1127   by (simp add: of_rat_mult)
  1128 
  1129 lemma real_uminus_code [code]: "- Ratreal x = Ratreal (- x)"
  1130   by (simp add: of_rat_minus)
  1131 
  1132 lemma real_minus_code [code]: "Ratreal x - Ratreal y = Ratreal (x - y)"
  1133   by (simp add: of_rat_diff)
  1134 
  1135 lemma real_inverse_code [code]: "inverse (Ratreal x) = Ratreal (inverse x)"
  1136   by (simp add: of_rat_inverse)
  1137  
  1138 lemma real_divide_code [code]: "Ratreal x / Ratreal y = Ratreal (x / y)"
  1139   by (simp add: of_rat_divide)
  1140 
  1141 definition (in term_syntax)
  1142   valterm_ratreal :: "rat \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> real \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  1143   [code_unfold]: "valterm_ratreal k = Code_Evaluation.valtermify Ratreal {\<cdot>} k"
  1144 
  1145 notation fcomp (infixl "o>" 60)
  1146 notation scomp (infixl "o\<rightarrow>" 60)
  1147 
  1148 instantiation real :: random
  1149 begin
  1150 
  1151 definition
  1152   "Quickcheck.random i = Quickcheck.random i o\<rightarrow> (\<lambda>r. Pair (valterm_ratreal r))"
  1153 
  1154 instance ..
  1155 
  1156 end
  1157 
  1158 no_notation fcomp (infixl "o>" 60)
  1159 no_notation scomp (infixl "o\<rightarrow>" 60)
  1160 
  1161 text {* Setup for SML code generator *}
  1162 
  1163 types_code
  1164   real ("(int */ int)")
  1165 attach (term_of) {*
  1166 fun term_of_real (p, q) =
  1167   let
  1168     val rT = HOLogic.realT
  1169   in
  1170     if q = 1 orelse p = 0 then HOLogic.mk_number rT p
  1171     else @{term "op / \<Colon> real \<Rightarrow> real \<Rightarrow> real"} $
  1172       HOLogic.mk_number rT p $ HOLogic.mk_number rT q
  1173   end;
  1174 *}
  1175 attach (test) {*
  1176 fun gen_real i =
  1177   let
  1178     val p = random_range 0 i;
  1179     val q = random_range 1 (i + 1);
  1180     val g = Integer.gcd p q;
  1181     val p' = p div g;
  1182     val q' = q div g;
  1183     val r = (if one_of [true, false] then p' else ~ p',
  1184       if p' = 0 then 1 else q')
  1185   in
  1186     (r, fn () => term_of_real r)
  1187   end;
  1188 *}
  1189 
  1190 consts_code
  1191   Ratreal ("(_)")
  1192 
  1193 consts_code
  1194   "of_int :: int \<Rightarrow> real" ("\<module>real'_of'_int")
  1195 attach {*
  1196 fun real_of_int i = (i, 1);
  1197 *}
  1198 
  1199 setup {*
  1200   Nitpick.register_frac_type @{type_name real}
  1201    [(@{const_name zero_real_inst.zero_real}, @{const_name Nitpick.zero_frac}),
  1202     (@{const_name one_real_inst.one_real}, @{const_name Nitpick.one_frac}),
  1203     (@{const_name plus_real_inst.plus_real}, @{const_name Nitpick.plus_frac}),
  1204     (@{const_name times_real_inst.times_real}, @{const_name Nitpick.times_frac}),
  1205     (@{const_name uminus_real_inst.uminus_real}, @{const_name Nitpick.uminus_frac}),
  1206     (@{const_name number_real_inst.number_of_real}, @{const_name Nitpick.number_of_frac}),
  1207     (@{const_name inverse_real_inst.inverse_real}, @{const_name Nitpick.inverse_frac}),
  1208     (@{const_name ord_real_inst.less_eq_real}, @{const_name Nitpick.less_eq_frac})]
  1209 *}
  1210 
  1211 lemmas [nitpick_def] = inverse_real_inst.inverse_real
  1212     number_real_inst.number_of_real one_real_inst.one_real
  1213     ord_real_inst.less_eq_real plus_real_inst.plus_real
  1214     times_real_inst.times_real uminus_real_inst.uminus_real
  1215     zero_real_inst.zero_real
  1216 
  1217 end