src/HOL/SetInterval.thy
author wenzelm
Mon Mar 22 20:58:52 2010 +0100 (2010-03-22)
changeset 35898 c890a3835d15
parent 35828 46cfc4b8112e
child 36307 1732232f9b27
permissions -rw-r--r--
recovered header;
     1 (*  Title:      HOL/SetInterval.thy
     2     Author:     Tobias Nipkow
     3     Author:     Clemens Ballarin
     4     Author:     Jeremy Avigad
     5 
     6 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     7 *)
     8 
     9 header {* Set intervals *}
    10 
    11 theory SetInterval
    12 imports Int Nat_Transfer
    13 begin
    14 
    15 context ord
    16 begin
    17 definition
    18   lessThan    :: "'a => 'a set" ("(1{..<_})") where
    19   "{..<u} == {x. x < u}"
    20 
    21 definition
    22   atMost      :: "'a => 'a set" ("(1{.._})") where
    23   "{..u} == {x. x \<le> u}"
    24 
    25 definition
    26   greaterThan :: "'a => 'a set" ("(1{_<..})") where
    27   "{l<..} == {x. l<x}"
    28 
    29 definition
    30   atLeast     :: "'a => 'a set" ("(1{_..})") where
    31   "{l..} == {x. l\<le>x}"
    32 
    33 definition
    34   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    35   "{l<..<u} == {l<..} Int {..<u}"
    36 
    37 definition
    38   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    39   "{l..<u} == {l..} Int {..<u}"
    40 
    41 definition
    42   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    43   "{l<..u} == {l<..} Int {..u}"
    44 
    45 definition
    46   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    47   "{l..u} == {l..} Int {..u}"
    48 
    49 end
    50 
    51 
    52 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    53 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    54 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    55 
    56 syntax
    57   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3UN _<=_./ _)" 10)
    58   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3UN _<_./ _)" 10)
    59   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3INT _<=_./ _)" 10)
    60   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3INT _<_./ _)" 10)
    61 
    62 syntax (xsymbols)
    63   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" 10)
    64   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _<_./ _)" 10)
    65   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" 10)
    66   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" 10)
    67 
    68 syntax (latex output)
    69   "_UNION_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ \<le> _)/ _)" 10)
    70   "_UNION_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ < _)/ _)" 10)
    71   "_INTER_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ \<le> _)/ _)" 10)
    72   "_INTER_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ < _)/ _)" 10)
    73 
    74 translations
    75   "UN i<=n. A"  == "UN i:{..n}. A"
    76   "UN i<n. A"   == "UN i:{..<n}. A"
    77   "INT i<=n. A" == "INT i:{..n}. A"
    78   "INT i<n. A"  == "INT i:{..<n}. A"
    79 
    80 
    81 subsection {* Various equivalences *}
    82 
    83 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    84 by (simp add: lessThan_def)
    85 
    86 lemma Compl_lessThan [simp]:
    87     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    88 apply (auto simp add: lessThan_def atLeast_def)
    89 done
    90 
    91 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    92 by auto
    93 
    94 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
    95 by (simp add: greaterThan_def)
    96 
    97 lemma Compl_greaterThan [simp]:
    98     "!!k:: 'a::linorder. -greaterThan k = atMost k"
    99   by (auto simp add: greaterThan_def atMost_def)
   100 
   101 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   102 apply (subst Compl_greaterThan [symmetric])
   103 apply (rule double_complement)
   104 done
   105 
   106 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   107 by (simp add: atLeast_def)
   108 
   109 lemma Compl_atLeast [simp]:
   110     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   111   by (auto simp add: lessThan_def atLeast_def)
   112 
   113 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   114 by (simp add: atMost_def)
   115 
   116 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   117 by (blast intro: order_antisym)
   118 
   119 
   120 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   121 
   122 lemma atLeast_subset_iff [iff]:
   123      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   124 by (blast intro: order_trans)
   125 
   126 lemma atLeast_eq_iff [iff]:
   127      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   128 by (blast intro: order_antisym order_trans)
   129 
   130 lemma greaterThan_subset_iff [iff]:
   131      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   132 apply (auto simp add: greaterThan_def)
   133  apply (subst linorder_not_less [symmetric], blast)
   134 done
   135 
   136 lemma greaterThan_eq_iff [iff]:
   137      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   138 apply (rule iffI)
   139  apply (erule equalityE)
   140  apply simp_all
   141 done
   142 
   143 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   144 by (blast intro: order_trans)
   145 
   146 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   147 by (blast intro: order_antisym order_trans)
   148 
   149 lemma lessThan_subset_iff [iff]:
   150      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   151 apply (auto simp add: lessThan_def)
   152  apply (subst linorder_not_less [symmetric], blast)
   153 done
   154 
   155 lemma lessThan_eq_iff [iff]:
   156      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   157 apply (rule iffI)
   158  apply (erule equalityE)
   159  apply simp_all
   160 done
   161 
   162 
   163 subsection {*Two-sided intervals*}
   164 
   165 context ord
   166 begin
   167 
   168 lemma greaterThanLessThan_iff [simp,no_atp]:
   169   "(i : {l<..<u}) = (l < i & i < u)"
   170 by (simp add: greaterThanLessThan_def)
   171 
   172 lemma atLeastLessThan_iff [simp,no_atp]:
   173   "(i : {l..<u}) = (l <= i & i < u)"
   174 by (simp add: atLeastLessThan_def)
   175 
   176 lemma greaterThanAtMost_iff [simp,no_atp]:
   177   "(i : {l<..u}) = (l < i & i <= u)"
   178 by (simp add: greaterThanAtMost_def)
   179 
   180 lemma atLeastAtMost_iff [simp,no_atp]:
   181   "(i : {l..u}) = (l <= i & i <= u)"
   182 by (simp add: atLeastAtMost_def)
   183 
   184 text {* The above four lemmas could be declared as iffs. Unfortunately this
   185 breaks many proofs. Since it only helps blast, it is better to leave well
   186 alone *}
   187 
   188 end
   189 
   190 subsubsection{* Emptyness, singletons, subset *}
   191 
   192 context order
   193 begin
   194 
   195 lemma atLeastatMost_empty[simp]:
   196   "b < a \<Longrightarrow> {a..b} = {}"
   197 by(auto simp: atLeastAtMost_def atLeast_def atMost_def)
   198 
   199 lemma atLeastatMost_empty_iff[simp]:
   200   "{a..b} = {} \<longleftrightarrow> (~ a <= b)"
   201 by auto (blast intro: order_trans)
   202 
   203 lemma atLeastatMost_empty_iff2[simp]:
   204   "{} = {a..b} \<longleftrightarrow> (~ a <= b)"
   205 by auto (blast intro: order_trans)
   206 
   207 lemma atLeastLessThan_empty[simp]:
   208   "b <= a \<Longrightarrow> {a..<b} = {}"
   209 by(auto simp: atLeastLessThan_def)
   210 
   211 lemma atLeastLessThan_empty_iff[simp]:
   212   "{a..<b} = {} \<longleftrightarrow> (~ a < b)"
   213 by auto (blast intro: le_less_trans)
   214 
   215 lemma atLeastLessThan_empty_iff2[simp]:
   216   "{} = {a..<b} \<longleftrightarrow> (~ a < b)"
   217 by auto (blast intro: le_less_trans)
   218 
   219 lemma greaterThanAtMost_empty[simp]: "l \<le> k ==> {k<..l} = {}"
   220 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   221 
   222 lemma greaterThanAtMost_empty_iff[simp]: "{k<..l} = {} \<longleftrightarrow> ~ k < l"
   223 by auto (blast intro: less_le_trans)
   224 
   225 lemma greaterThanAtMost_empty_iff2[simp]: "{} = {k<..l} \<longleftrightarrow> ~ k < l"
   226 by auto (blast intro: less_le_trans)
   227 
   228 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..<l} = {}"
   229 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   230 
   231 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   232 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   233 
   234 lemma atLeastatMost_subset_iff[simp]:
   235   "{a..b} <= {c..d} \<longleftrightarrow> (~ a <= b) | c <= a & b <= d"
   236 unfolding atLeastAtMost_def atLeast_def atMost_def
   237 by (blast intro: order_trans)
   238 
   239 lemma atLeastatMost_psubset_iff:
   240   "{a..b} < {c..d} \<longleftrightarrow>
   241    ((~ a <= b) | c <= a & b <= d & (c < a | b < d))  &  c <= d"
   242 by(simp add: psubset_eq expand_set_eq less_le_not_le)(blast intro: order_trans)
   243 
   244 end
   245 
   246 lemma (in linorder) atLeastLessThan_subset_iff:
   247   "{a..<b} <= {c..<d} \<Longrightarrow> b <= a | c<=a & b<=d"
   248 apply (auto simp:subset_eq Ball_def)
   249 apply(frule_tac x=a in spec)
   250 apply(erule_tac x=d in allE)
   251 apply (simp add: less_imp_le)
   252 done
   253 
   254 subsubsection {* Intersection *}
   255 
   256 context linorder
   257 begin
   258 
   259 lemma Int_atLeastAtMost[simp]: "{a..b} Int {c..d} = {max a c .. min b d}"
   260 by auto
   261 
   262 lemma Int_atLeastAtMostR1[simp]: "{..b} Int {c..d} = {c .. min b d}"
   263 by auto
   264 
   265 lemma Int_atLeastAtMostR2[simp]: "{a..} Int {c..d} = {max a c .. d}"
   266 by auto
   267 
   268 lemma Int_atLeastAtMostL1[simp]: "{a..b} Int {..d} = {a .. min b d}"
   269 by auto
   270 
   271 lemma Int_atLeastAtMostL2[simp]: "{a..b} Int {c..} = {max a c .. b}"
   272 by auto
   273 
   274 lemma Int_atLeastLessThan[simp]: "{a..<b} Int {c..<d} = {max a c ..< min b d}"
   275 by auto
   276 
   277 lemma Int_greaterThanAtMost[simp]: "{a<..b} Int {c<..d} = {max a c <.. min b d}"
   278 by auto
   279 
   280 lemma Int_greaterThanLessThan[simp]: "{a<..<b} Int {c<..<d} = {max a c <..< min b d}"
   281 by auto
   282 
   283 end
   284 
   285 
   286 subsection {* Intervals of natural numbers *}
   287 
   288 subsubsection {* The Constant @{term lessThan} *}
   289 
   290 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   291 by (simp add: lessThan_def)
   292 
   293 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   294 by (simp add: lessThan_def less_Suc_eq, blast)
   295 
   296 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   297 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   298 
   299 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   300 by blast
   301 
   302 subsubsection {* The Constant @{term greaterThan} *}
   303 
   304 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   305 apply (simp add: greaterThan_def)
   306 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   307 done
   308 
   309 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   310 apply (simp add: greaterThan_def)
   311 apply (auto elim: linorder_neqE)
   312 done
   313 
   314 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   315 by blast
   316 
   317 subsubsection {* The Constant @{term atLeast} *}
   318 
   319 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   320 by (unfold atLeast_def UNIV_def, simp)
   321 
   322 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   323 apply (simp add: atLeast_def)
   324 apply (simp add: Suc_le_eq)
   325 apply (simp add: order_le_less, blast)
   326 done
   327 
   328 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   329   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   330 
   331 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   332 by blast
   333 
   334 subsubsection {* The Constant @{term atMost} *}
   335 
   336 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   337 by (simp add: atMost_def)
   338 
   339 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   340 apply (simp add: atMost_def)
   341 apply (simp add: less_Suc_eq order_le_less, blast)
   342 done
   343 
   344 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   345 by blast
   346 
   347 subsubsection {* The Constant @{term atLeastLessThan} *}
   348 
   349 text{*The orientation of the following 2 rules is tricky. The lhs is
   350 defined in terms of the rhs.  Hence the chosen orientation makes sense
   351 in this theory --- the reverse orientation complicates proofs (eg
   352 nontermination). But outside, when the definition of the lhs is rarely
   353 used, the opposite orientation seems preferable because it reduces a
   354 specific concept to a more general one. *}
   355 
   356 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   357 by(simp add:lessThan_def atLeastLessThan_def)
   358 
   359 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   360 by(simp add:atMost_def atLeastAtMost_def)
   361 
   362 declare atLeast0LessThan[symmetric, code_unfold]
   363         atLeast0AtMost[symmetric, code_unfold]
   364 
   365 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   366 by (simp add: atLeastLessThan_def)
   367 
   368 subsubsection {* Intervals of nats with @{term Suc} *}
   369 
   370 text{*Not a simprule because the RHS is too messy.*}
   371 lemma atLeastLessThanSuc:
   372     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   373 by (auto simp add: atLeastLessThan_def)
   374 
   375 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   376 by (auto simp add: atLeastLessThan_def)
   377 (*
   378 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   379 by (induct k, simp_all add: atLeastLessThanSuc)
   380 
   381 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   382 by (auto simp add: atLeastLessThan_def)
   383 *)
   384 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   385   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   386 
   387 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   388   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   389     greaterThanAtMost_def)
   390 
   391 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   392   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   393     greaterThanLessThan_def)
   394 
   395 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   396 by (auto simp add: atLeastAtMost_def)
   397 
   398 lemma atLeastLessThan_add_Un: "i \<le> j \<Longrightarrow> {i..<j+k} = {i..<j} \<union> {j..<j+k::nat}"
   399   apply (induct k) 
   400   apply (simp_all add: atLeastLessThanSuc)   
   401   done
   402 
   403 subsubsection {* Image *}
   404 
   405 lemma image_add_atLeastAtMost:
   406   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   407 proof
   408   show "?A \<subseteq> ?B" by auto
   409 next
   410   show "?B \<subseteq> ?A"
   411   proof
   412     fix n assume a: "n : ?B"
   413     hence "n - k : {i..j}" by auto
   414     moreover have "n = (n - k) + k" using a by auto
   415     ultimately show "n : ?A" by blast
   416   qed
   417 qed
   418 
   419 lemma image_add_atLeastLessThan:
   420   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   421 proof
   422   show "?A \<subseteq> ?B" by auto
   423 next
   424   show "?B \<subseteq> ?A"
   425   proof
   426     fix n assume a: "n : ?B"
   427     hence "n - k : {i..<j}" by auto
   428     moreover have "n = (n - k) + k" using a by auto
   429     ultimately show "n : ?A" by blast
   430   qed
   431 qed
   432 
   433 corollary image_Suc_atLeastAtMost[simp]:
   434   "Suc ` {i..j} = {Suc i..Suc j}"
   435 using image_add_atLeastAtMost[where k="Suc 0"] by simp
   436 
   437 corollary image_Suc_atLeastLessThan[simp]:
   438   "Suc ` {i..<j} = {Suc i..<Suc j}"
   439 using image_add_atLeastLessThan[where k="Suc 0"] by simp
   440 
   441 lemma image_add_int_atLeastLessThan:
   442     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   443   apply (auto simp add: image_def)
   444   apply (rule_tac x = "x - l" in bexI)
   445   apply auto
   446   done
   447 
   448 context ordered_ab_group_add
   449 begin
   450 
   451 lemma
   452   fixes x :: 'a
   453   shows image_uminus_greaterThan[simp]: "uminus ` {x<..} = {..<-x}"
   454   and image_uminus_atLeast[simp]: "uminus ` {x..} = {..-x}"
   455 proof safe
   456   fix y assume "y < -x"
   457   hence *:  "x < -y" using neg_less_iff_less[of "-y" x] by simp
   458   have "- (-y) \<in> uminus ` {x<..}"
   459     by (rule imageI) (simp add: *)
   460   thus "y \<in> uminus ` {x<..}" by simp
   461 next
   462   fix y assume "y \<le> -x"
   463   have "- (-y) \<in> uminus ` {x..}"
   464     by (rule imageI) (insert `y \<le> -x`[THEN le_imp_neg_le], simp)
   465   thus "y \<in> uminus ` {x..}" by simp
   466 qed simp_all
   467 
   468 lemma
   469   fixes x :: 'a
   470   shows image_uminus_lessThan[simp]: "uminus ` {..<x} = {-x<..}"
   471   and image_uminus_atMost[simp]: "uminus ` {..x} = {-x..}"
   472 proof -
   473   have "uminus ` {..<x} = uminus ` uminus ` {-x<..}"
   474     and "uminus ` {..x} = uminus ` uminus ` {-x..}" by simp_all
   475   thus "uminus ` {..<x} = {-x<..}" and "uminus ` {..x} = {-x..}"
   476     by (simp_all add: image_image
   477         del: image_uminus_greaterThan image_uminus_atLeast)
   478 qed
   479 
   480 lemma
   481   fixes x :: 'a
   482   shows image_uminus_atLeastAtMost[simp]: "uminus ` {x..y} = {-y..-x}"
   483   and image_uminus_greaterThanAtMost[simp]: "uminus ` {x<..y} = {-y..<-x}"
   484   and image_uminus_atLeastLessThan[simp]: "uminus ` {x..<y} = {-y<..-x}"
   485   and image_uminus_greaterThanLessThan[simp]: "uminus ` {x<..<y} = {-y<..<-x}"
   486   by (simp_all add: atLeastAtMost_def greaterThanAtMost_def atLeastLessThan_def
   487       greaterThanLessThan_def image_Int[OF inj_uminus] Int_commute)
   488 end
   489 
   490 subsubsection {* Finiteness *}
   491 
   492 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   493   by (induct k) (simp_all add: lessThan_Suc)
   494 
   495 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   496   by (induct k) (simp_all add: atMost_Suc)
   497 
   498 lemma finite_greaterThanLessThan [iff]:
   499   fixes l :: nat shows "finite {l<..<u}"
   500 by (simp add: greaterThanLessThan_def)
   501 
   502 lemma finite_atLeastLessThan [iff]:
   503   fixes l :: nat shows "finite {l..<u}"
   504 by (simp add: atLeastLessThan_def)
   505 
   506 lemma finite_greaterThanAtMost [iff]:
   507   fixes l :: nat shows "finite {l<..u}"
   508 by (simp add: greaterThanAtMost_def)
   509 
   510 lemma finite_atLeastAtMost [iff]:
   511   fixes l :: nat shows "finite {l..u}"
   512 by (simp add: atLeastAtMost_def)
   513 
   514 text {* A bounded set of natural numbers is finite. *}
   515 lemma bounded_nat_set_is_finite:
   516   "(ALL i:N. i < (n::nat)) ==> finite N"
   517 apply (rule finite_subset)
   518  apply (rule_tac [2] finite_lessThan, auto)
   519 done
   520 
   521 text {* A set of natural numbers is finite iff it is bounded. *}
   522 lemma finite_nat_set_iff_bounded:
   523   "finite(N::nat set) = (EX m. ALL n:N. n<m)" (is "?F = ?B")
   524 proof
   525   assume f:?F  show ?B
   526     using Max_ge[OF `?F`, simplified less_Suc_eq_le[symmetric]] by blast
   527 next
   528   assume ?B show ?F using `?B` by(blast intro:bounded_nat_set_is_finite)
   529 qed
   530 
   531 lemma finite_nat_set_iff_bounded_le:
   532   "finite(N::nat set) = (EX m. ALL n:N. n<=m)"
   533 apply(simp add:finite_nat_set_iff_bounded)
   534 apply(blast dest:less_imp_le_nat le_imp_less_Suc)
   535 done
   536 
   537 lemma finite_less_ub:
   538      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
   539 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
   540 
   541 text{* Any subset of an interval of natural numbers the size of the
   542 subset is exactly that interval. *}
   543 
   544 lemma subset_card_intvl_is_intvl:
   545   "A <= {k..<k+card A} \<Longrightarrow> A = {k..<k+card A}" (is "PROP ?P")
   546 proof cases
   547   assume "finite A"
   548   thus "PROP ?P"
   549   proof(induct A rule:finite_linorder_max_induct)
   550     case empty thus ?case by auto
   551   next
   552     case (insert b A)
   553     moreover hence "b ~: A" by auto
   554     moreover have "A <= {k..<k+card A}" and "b = k+card A"
   555       using `b ~: A` insert by fastsimp+
   556     ultimately show ?case by auto
   557   qed
   558 next
   559   assume "~finite A" thus "PROP ?P" by simp
   560 qed
   561 
   562 
   563 subsubsection {* Proving Inclusions and Equalities between Unions *}
   564 
   565 lemma UN_UN_finite_eq: "(\<Union>n::nat. \<Union>i\<in>{0..<n}. A i) = (\<Union>n. A n)"
   566   by (auto simp add: atLeast0LessThan) 
   567 
   568 lemma UN_finite_subset: "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> C) \<Longrightarrow> (\<Union>n. A n) \<subseteq> C"
   569   by (subst UN_UN_finite_eq [symmetric]) blast
   570 
   571 lemma UN_finite2_subset: 
   572      "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) \<subseteq> (\<Union>n. B n)"
   573   apply (rule UN_finite_subset)
   574   apply (subst UN_UN_finite_eq [symmetric, of B]) 
   575   apply blast
   576   done
   577 
   578 lemma UN_finite2_eq:
   579   "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) = (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) = (\<Union>n. B n)"
   580   apply (rule subset_antisym)
   581    apply (rule UN_finite2_subset, blast)
   582  apply (rule UN_finite2_subset [where k=k])
   583  apply (force simp add: atLeastLessThan_add_Un [of 0])
   584  done
   585 
   586 
   587 subsubsection {* Cardinality *}
   588 
   589 lemma card_lessThan [simp]: "card {..<u} = u"
   590   by (induct u, simp_all add: lessThan_Suc)
   591 
   592 lemma card_atMost [simp]: "card {..u} = Suc u"
   593   by (simp add: lessThan_Suc_atMost [THEN sym])
   594 
   595 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   596   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   597   apply (erule ssubst, rule card_lessThan)
   598   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   599   apply (erule subst)
   600   apply (rule card_image)
   601   apply (simp add: inj_on_def)
   602   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   603   apply (rule_tac x = "x - l" in exI)
   604   apply arith
   605   done
   606 
   607 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   608   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   609 
   610 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   611   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   612 
   613 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   614   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   615 
   616 lemma ex_bij_betw_nat_finite:
   617   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
   618 apply(drule finite_imp_nat_seg_image_inj_on)
   619 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
   620 done
   621 
   622 lemma ex_bij_betw_finite_nat:
   623   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
   624 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
   625 
   626 lemma finite_same_card_bij:
   627   "finite A \<Longrightarrow> finite B \<Longrightarrow> card A = card B \<Longrightarrow> EX h. bij_betw h A B"
   628 apply(drule ex_bij_betw_finite_nat)
   629 apply(drule ex_bij_betw_nat_finite)
   630 apply(auto intro!:bij_betw_trans)
   631 done
   632 
   633 lemma ex_bij_betw_nat_finite_1:
   634   "finite M \<Longrightarrow> \<exists>h. bij_betw h {1 .. card M} M"
   635 by (rule finite_same_card_bij) auto
   636 
   637 
   638 subsection {* Intervals of integers *}
   639 
   640 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   641   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   642 
   643 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   644   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   645 
   646 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   647     "{l+1..<u} = {l<..<u::int}"
   648   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   649 
   650 subsubsection {* Finiteness *}
   651 
   652 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   653     {(0::int)..<u} = int ` {..<nat u}"
   654   apply (unfold image_def lessThan_def)
   655   apply auto
   656   apply (rule_tac x = "nat x" in exI)
   657   apply (auto simp add: zless_nat_eq_int_zless [THEN sym])
   658   done
   659 
   660 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   661   apply (case_tac "0 \<le> u")
   662   apply (subst image_atLeastZeroLessThan_int, assumption)
   663   apply (rule finite_imageI)
   664   apply auto
   665   done
   666 
   667 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   668   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   669   apply (erule subst)
   670   apply (rule finite_imageI)
   671   apply (rule finite_atLeastZeroLessThan_int)
   672   apply (rule image_add_int_atLeastLessThan)
   673   done
   674 
   675 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   676   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   677 
   678 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   679   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   680 
   681 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   682   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   683 
   684 
   685 subsubsection {* Cardinality *}
   686 
   687 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   688   apply (case_tac "0 \<le> u")
   689   apply (subst image_atLeastZeroLessThan_int, assumption)
   690   apply (subst card_image)
   691   apply (auto simp add: inj_on_def)
   692   done
   693 
   694 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   695   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   696   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   697   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   698   apply (erule subst)
   699   apply (rule card_image)
   700   apply (simp add: inj_on_def)
   701   apply (rule image_add_int_atLeastLessThan)
   702   done
   703 
   704 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   705 apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   706 apply (auto simp add: algebra_simps)
   707 done
   708 
   709 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   710 by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   711 
   712 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   713 by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   714 
   715 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
   716 proof -
   717   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
   718   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
   719 qed
   720 
   721 lemma card_less:
   722 assumes zero_in_M: "0 \<in> M"
   723 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
   724 proof -
   725   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
   726   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
   727 qed
   728 
   729 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
   730 apply (rule card_bij_eq [of "Suc" _ _ "\<lambda>x. x - Suc 0"])
   731 apply simp
   732 apply fastsimp
   733 apply auto
   734 apply (rule inj_on_diff_nat)
   735 apply auto
   736 apply (case_tac x)
   737 apply auto
   738 apply (case_tac xa)
   739 apply auto
   740 apply (case_tac xa)
   741 apply auto
   742 done
   743 
   744 lemma card_less_Suc:
   745   assumes zero_in_M: "0 \<in> M"
   746     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
   747 proof -
   748   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
   749   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
   750     by (auto simp only: insert_Diff)
   751   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
   752   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
   753     apply (subst card_insert)
   754     apply simp_all
   755     apply (subst b)
   756     apply (subst card_less_Suc2[symmetric])
   757     apply simp_all
   758     done
   759   with c show ?thesis by simp
   760 qed
   761 
   762 
   763 subsection {*Lemmas useful with the summation operator setsum*}
   764 
   765 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   766 
   767 subsubsection {* Disjoint Unions *}
   768 
   769 text {* Singletons and open intervals *}
   770 
   771 lemma ivl_disj_un_singleton:
   772   "{l::'a::linorder} Un {l<..} = {l..}"
   773   "{..<u} Un {u::'a::linorder} = {..u}"
   774   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   775   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   776   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   777   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   778 by auto
   779 
   780 text {* One- and two-sided intervals *}
   781 
   782 lemma ivl_disj_un_one:
   783   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   784   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   785   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   786   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   787   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   788   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   789   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   790   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   791 by auto
   792 
   793 text {* Two- and two-sided intervals *}
   794 
   795 lemma ivl_disj_un_two:
   796   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   797   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   798   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   799   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   800   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   801   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   802   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   803   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   804 by auto
   805 
   806 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   807 
   808 subsubsection {* Disjoint Intersections *}
   809 
   810 text {* One- and two-sided intervals *}
   811 
   812 lemma ivl_disj_int_one:
   813   "{..l::'a::order} Int {l<..<u} = {}"
   814   "{..<l} Int {l..<u} = {}"
   815   "{..l} Int {l<..u} = {}"
   816   "{..<l} Int {l..u} = {}"
   817   "{l<..u} Int {u<..} = {}"
   818   "{l<..<u} Int {u..} = {}"
   819   "{l..u} Int {u<..} = {}"
   820   "{l..<u} Int {u..} = {}"
   821   by auto
   822 
   823 text {* Two- and two-sided intervals *}
   824 
   825 lemma ivl_disj_int_two:
   826   "{l::'a::order<..<m} Int {m..<u} = {}"
   827   "{l<..m} Int {m<..<u} = {}"
   828   "{l..<m} Int {m..<u} = {}"
   829   "{l..m} Int {m<..<u} = {}"
   830   "{l<..<m} Int {m..u} = {}"
   831   "{l<..m} Int {m<..u} = {}"
   832   "{l..<m} Int {m..u} = {}"
   833   "{l..m} Int {m<..u} = {}"
   834   by auto
   835 
   836 lemmas ivl_disj_int = ivl_disj_int_one ivl_disj_int_two
   837 
   838 subsubsection {* Some Differences *}
   839 
   840 lemma ivl_diff[simp]:
   841  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
   842 by(auto)
   843 
   844 
   845 subsubsection {* Some Subset Conditions *}
   846 
   847 lemma ivl_subset [simp,no_atp]:
   848  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
   849 apply(auto simp:linorder_not_le)
   850 apply(rule ccontr)
   851 apply(insert linorder_le_less_linear[of i n])
   852 apply(clarsimp simp:linorder_not_le)
   853 apply(fastsimp)
   854 done
   855 
   856 
   857 subsection {* Summation indexed over intervals *}
   858 
   859 syntax
   860   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
   861   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
   862   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
   863   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
   864 syntax (xsymbols)
   865   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   866   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   867   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   868   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   869 syntax (HTML output)
   870   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   871   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   872   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   873   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   874 syntax (latex_sum output)
   875   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   876  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
   877   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   878  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
   879   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   880  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
   881   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   882  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
   883 
   884 translations
   885   "\<Sum>x=a..b. t" == "CONST setsum (%x. t) {a..b}"
   886   "\<Sum>x=a..<b. t" == "CONST setsum (%x. t) {a..<b}"
   887   "\<Sum>i\<le>n. t" == "CONST setsum (\<lambda>i. t) {..n}"
   888   "\<Sum>i<n. t" == "CONST setsum (\<lambda>i. t) {..<n}"
   889 
   890 text{* The above introduces some pretty alternative syntaxes for
   891 summation over intervals:
   892 \begin{center}
   893 \begin{tabular}{lll}
   894 Old & New & \LaTeX\\
   895 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
   896 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
   897 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
   898 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
   899 \end{tabular}
   900 \end{center}
   901 The left column shows the term before introduction of the new syntax,
   902 the middle column shows the new (default) syntax, and the right column
   903 shows a special syntax. The latter is only meaningful for latex output
   904 and has to be activated explicitly by setting the print mode to
   905 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
   906 antiquotations). It is not the default \LaTeX\ output because it only
   907 works well with italic-style formulae, not tt-style.
   908 
   909 Note that for uniformity on @{typ nat} it is better to use
   910 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
   911 not provide all lemmas available for @{term"{m..<n}"} also in the
   912 special form for @{term"{..<n}"}. *}
   913 
   914 text{* This congruence rule should be used for sums over intervals as
   915 the standard theorem @{text[source]setsum_cong} does not work well
   916 with the simplifier who adds the unsimplified premise @{term"x:B"} to
   917 the context. *}
   918 
   919 lemma setsum_ivl_cong:
   920  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
   921  setsum f {a..<b} = setsum g {c..<d}"
   922 by(rule setsum_cong, simp_all)
   923 
   924 (* FIXME why are the following simp rules but the corresponding eqns
   925 on intervals are not? *)
   926 
   927 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
   928 by (simp add:atMost_Suc add_ac)
   929 
   930 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
   931 by (simp add:lessThan_Suc add_ac)
   932 
   933 lemma setsum_cl_ivl_Suc[simp]:
   934   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
   935 by (auto simp:add_ac atLeastAtMostSuc_conv)
   936 
   937 lemma setsum_op_ivl_Suc[simp]:
   938   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
   939 by (auto simp:add_ac atLeastLessThanSuc)
   940 (*
   941 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
   942     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
   943 by (auto simp:add_ac atLeastAtMostSuc_conv)
   944 *)
   945 
   946 lemma setsum_head:
   947   fixes n :: nat
   948   assumes mn: "m <= n" 
   949   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
   950 proof -
   951   from mn
   952   have "{m..n} = {m} \<union> {m<..n}"
   953     by (auto intro: ivl_disj_un_singleton)
   954   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
   955     by (simp add: atLeast0LessThan)
   956   also have "\<dots> = ?rhs" by simp
   957   finally show ?thesis .
   958 qed
   959 
   960 lemma setsum_head_Suc:
   961   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
   962 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
   963 
   964 lemma setsum_head_upt_Suc:
   965   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
   966 apply(insert setsum_head_Suc[of m "n - Suc 0" f])
   967 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] algebra_simps)
   968 done
   969 
   970 lemma setsum_ub_add_nat: assumes "(m::nat) \<le> n + 1"
   971   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
   972 proof-
   973   have "{m .. n+p} = {m..n} \<union> {n+1..n+p}" using `m \<le> n+1` by auto
   974   thus ?thesis by (auto simp: ivl_disj_int setsum_Un_disjoint
   975     atLeastSucAtMost_greaterThanAtMost)
   976 qed
   977 
   978 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   979   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
   980 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
   981 
   982 lemma setsum_diff_nat_ivl:
   983 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   984 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   985   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
   986 using setsum_add_nat_ivl [of m n p f,symmetric]
   987 apply (simp add: add_ac)
   988 done
   989 
   990 lemma setsum_natinterval_difff:
   991   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
   992   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
   993           (if m <= n then f m - f(n + 1) else 0)"
   994 by (induct n, auto simp add: algebra_simps not_le le_Suc_eq)
   995 
   996 lemmas setsum_restrict_set' = setsum_restrict_set[unfolded Int_def]
   997 
   998 lemma setsum_setsum_restrict:
   999   "finite S \<Longrightarrow> finite T \<Longrightarrow> setsum (\<lambda>x. setsum (\<lambda>y. f x y) {y. y\<in> T \<and> R x y}) S = setsum (\<lambda>y. setsum (\<lambda>x. f x y) {x. x \<in> S \<and> R x y}) T"
  1000   by (simp add: setsum_restrict_set'[unfolded mem_def] mem_def)
  1001      (rule setsum_commute)
  1002 
  1003 lemma setsum_image_gen: assumes fS: "finite S"
  1004   shows "setsum g S = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
  1005 proof-
  1006   { fix x assume "x \<in> S" then have "{y. y\<in> f`S \<and> f x = y} = {f x}" by auto }
  1007   hence "setsum g S = setsum (\<lambda>x. setsum (\<lambda>y. g x) {y. y\<in> f`S \<and> f x = y}) S"
  1008     by simp
  1009   also have "\<dots> = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
  1010     by (rule setsum_setsum_restrict[OF fS finite_imageI[OF fS]])
  1011   finally show ?thesis .
  1012 qed
  1013 
  1014 lemma setsum_le_included:
  1015   fixes f :: "'a \<Rightarrow> 'b::{comm_monoid_add,ordered_ab_semigroup_add_imp_le}"
  1016   assumes "finite s" "finite t"
  1017   and "\<forall>y\<in>t. 0 \<le> g y" "(\<forall>x\<in>s. \<exists>y\<in>t. i y = x \<and> f x \<le> g y)"
  1018   shows "setsum f s \<le> setsum g t"
  1019 proof -
  1020   have "setsum f s \<le> setsum (\<lambda>y. setsum g {x. x\<in>t \<and> i x = y}) s"
  1021   proof (rule setsum_mono)
  1022     fix y assume "y \<in> s"
  1023     with assms obtain z where z: "z \<in> t" "y = i z" "f y \<le> g z" by auto
  1024     with assms show "f y \<le> setsum g {x \<in> t. i x = y}" (is "?A y \<le> ?B y")
  1025       using order_trans[of "?A (i z)" "setsum g {z}" "?B (i z)", intro]
  1026       by (auto intro!: setsum_mono2)
  1027   qed
  1028   also have "... \<le> setsum (\<lambda>y. setsum g {x. x\<in>t \<and> i x = y}) (i ` t)"
  1029     using assms(2-4) by (auto intro!: setsum_mono2 setsum_nonneg)
  1030   also have "... \<le> setsum g t"
  1031     using assms by (auto simp: setsum_image_gen[symmetric])
  1032   finally show ?thesis .
  1033 qed
  1034 
  1035 lemma setsum_multicount_gen:
  1036   assumes "finite s" "finite t" "\<forall>j\<in>t. (card {i\<in>s. R i j} = k j)"
  1037   shows "setsum (\<lambda>i. (card {j\<in>t. R i j})) s = setsum k t" (is "?l = ?r")
  1038 proof-
  1039   have "?l = setsum (\<lambda>i. setsum (\<lambda>x.1) {j\<in>t. R i j}) s" by auto
  1040   also have "\<dots> = ?r" unfolding setsum_setsum_restrict[OF assms(1-2)]
  1041     using assms(3) by auto
  1042   finally show ?thesis .
  1043 qed
  1044 
  1045 lemma setsum_multicount:
  1046   assumes "finite S" "finite T" "\<forall>j\<in>T. (card {i\<in>S. R i j} = k)"
  1047   shows "setsum (\<lambda>i. card {j\<in>T. R i j}) S = k * card T" (is "?l = ?r")
  1048 proof-
  1049   have "?l = setsum (\<lambda>i. k) T" by(rule setsum_multicount_gen)(auto simp:assms)
  1050   also have "\<dots> = ?r" by(simp add: mult_commute)
  1051   finally show ?thesis by auto
  1052 qed
  1053 
  1054 
  1055 subsection{* Shifting bounds *}
  1056 
  1057 lemma setsum_shift_bounds_nat_ivl:
  1058   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
  1059 by (induct "n", auto simp:atLeastLessThanSuc)
  1060 
  1061 lemma setsum_shift_bounds_cl_nat_ivl:
  1062   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
  1063 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
  1064 apply (simp add:image_add_atLeastAtMost o_def)
  1065 done
  1066 
  1067 corollary setsum_shift_bounds_cl_Suc_ivl:
  1068   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
  1069 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k="Suc 0", simplified])
  1070 
  1071 corollary setsum_shift_bounds_Suc_ivl:
  1072   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
  1073 by (simp add:setsum_shift_bounds_nat_ivl[where k="Suc 0", simplified])
  1074 
  1075 lemma setsum_shift_lb_Suc0_0:
  1076   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
  1077 by(simp add:setsum_head_Suc)
  1078 
  1079 lemma setsum_shift_lb_Suc0_0_upt:
  1080   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
  1081 apply(cases k)apply simp
  1082 apply(simp add:setsum_head_upt_Suc)
  1083 done
  1084 
  1085 subsection {* The formula for geometric sums *}
  1086 
  1087 lemma geometric_sum:
  1088   "x ~= 1 ==> (\<Sum>i=0..<n. x ^ i) =
  1089   (x ^ n - 1) / (x - 1::'a::{field})"
  1090 by (induct "n") (simp_all add: field_simps)
  1091 
  1092 subsection {* The formula for arithmetic sums *}
  1093 
  1094 lemma gauss_sum:
  1095   "((1::'a::comm_semiring_1) + 1)*(\<Sum>i\<in>{1..n}. of_nat i) =
  1096    of_nat n*((of_nat n)+1)"
  1097 proof (induct n)
  1098   case 0
  1099   show ?case by simp
  1100 next
  1101   case (Suc n)
  1102   then show ?case by (simp add: algebra_simps)
  1103 qed
  1104 
  1105 theorem arith_series_general:
  1106   "((1::'a::comm_semiring_1) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1107   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1108 proof cases
  1109   assume ngt1: "n > 1"
  1110   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
  1111   have
  1112     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
  1113      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
  1114     by (rule setsum_addf)
  1115   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
  1116   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
  1117     unfolding One_nat_def
  1118     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt mult_ac)
  1119   also have "(1+1)*\<dots> = (1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..<n}. ?I i)"
  1120     by (simp add: left_distrib right_distrib)
  1121   also from ngt1 have "{1..<n} = {1..n - 1}"
  1122     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
  1123   also from ngt1
  1124   have "(1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..n - 1}. ?I i) = ((1+1)*?n*a + d*?I (n - 1)*?I n)"
  1125     by (simp only: mult_ac gauss_sum [of "n - 1"], unfold One_nat_def)
  1126        (simp add:  mult_ac trans [OF add_commute of_nat_Suc [symmetric]])
  1127   finally show ?thesis by (simp add: algebra_simps)
  1128 next
  1129   assume "\<not>(n > 1)"
  1130   hence "n = 1 \<or> n = 0" by auto
  1131   thus ?thesis by (auto simp: algebra_simps)
  1132 qed
  1133 
  1134 lemma arith_series_nat:
  1135   "Suc (Suc 0) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
  1136 proof -
  1137   have
  1138     "((1::nat) + 1) * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
  1139     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1140     by (rule arith_series_general)
  1141   thus ?thesis
  1142     unfolding One_nat_def by auto
  1143 qed
  1144 
  1145 lemma arith_series_int:
  1146   "(2::int) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1147   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1148 proof -
  1149   have
  1150     "((1::int) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1151     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1152     by (rule arith_series_general)
  1153   thus ?thesis by simp
  1154 qed
  1155 
  1156 lemma sum_diff_distrib:
  1157   fixes P::"nat\<Rightarrow>nat"
  1158   shows
  1159   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
  1160   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
  1161 proof (induct n)
  1162   case 0 show ?case by simp
  1163 next
  1164   case (Suc n)
  1165 
  1166   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
  1167   let ?rhs = "\<Sum>x<n. P x - Q x"
  1168 
  1169   from Suc have "?lhs = ?rhs" by simp
  1170   moreover
  1171   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
  1172   moreover
  1173   from Suc have
  1174     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
  1175     by (subst diff_diff_left[symmetric],
  1176         subst diff_add_assoc2)
  1177        (auto simp: diff_add_assoc2 intro: setsum_mono)
  1178   ultimately
  1179   show ?case by simp
  1180 qed
  1181 
  1182 subsection {* Products indexed over intervals *}
  1183 
  1184 syntax
  1185   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _.._./ _)" [0,0,0,10] 10)
  1186   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _..<_./ _)" [0,0,0,10] 10)
  1187   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<_./ _)" [0,0,10] 10)
  1188   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<=_./ _)" [0,0,10] 10)
  1189 syntax (xsymbols)
  1190   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1191   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1192   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1193   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1194 syntax (HTML output)
  1195   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1196   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1197   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1198   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1199 syntax (latex_prod output)
  1200   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1201  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1202   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1203  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1204   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1205  ("(3\<^raw:$\prod_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1206   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1207  ("(3\<^raw:$\prod_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1208 
  1209 translations
  1210   "\<Prod>x=a..b. t" == "CONST setprod (%x. t) {a..b}"
  1211   "\<Prod>x=a..<b. t" == "CONST setprod (%x. t) {a..<b}"
  1212   "\<Prod>i\<le>n. t" == "CONST setprod (\<lambda>i. t) {..n}"
  1213   "\<Prod>i<n. t" == "CONST setprod (\<lambda>i. t) {..<n}"
  1214 
  1215 subsection {* Transfer setup *}
  1216 
  1217 lemma transfer_nat_int_set_functions:
  1218     "{..n} = nat ` {0..int n}"
  1219     "{m..n} = nat ` {int m..int n}"  (* need all variants of these! *)
  1220   apply (auto simp add: image_def)
  1221   apply (rule_tac x = "int x" in bexI)
  1222   apply auto
  1223   apply (rule_tac x = "int x" in bexI)
  1224   apply auto
  1225   done
  1226 
  1227 lemma transfer_nat_int_set_function_closures:
  1228     "x >= 0 \<Longrightarrow> nat_set {x..y}"
  1229   by (simp add: nat_set_def)
  1230 
  1231 declare transfer_morphism_nat_int[transfer add
  1232   return: transfer_nat_int_set_functions
  1233     transfer_nat_int_set_function_closures
  1234 ]
  1235 
  1236 lemma transfer_int_nat_set_functions:
  1237     "is_nat m \<Longrightarrow> is_nat n \<Longrightarrow> {m..n} = int ` {nat m..nat n}"
  1238   by (simp only: is_nat_def transfer_nat_int_set_functions
  1239     transfer_nat_int_set_function_closures
  1240     transfer_nat_int_set_return_embed nat_0_le
  1241     cong: transfer_nat_int_set_cong)
  1242 
  1243 lemma transfer_int_nat_set_function_closures:
  1244     "is_nat x \<Longrightarrow> nat_set {x..y}"
  1245   by (simp only: transfer_nat_int_set_function_closures is_nat_def)
  1246 
  1247 declare transfer_morphism_int_nat[transfer add
  1248   return: transfer_int_nat_set_functions
  1249     transfer_int_nat_set_function_closures
  1250 ]
  1251 
  1252 end