src/HOL/Transcendental.thy
author wenzelm
Mon Mar 22 20:58:52 2010 +0100 (2010-03-22)
changeset 35898 c890a3835d15
parent 35216 7641e8d831d2
child 36776 c137ae7673d3
permissions -rw-r--r--
recovered header;
     1 (*  Title:      HOL/Transcendental.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge, University of Edinburgh
     3     Author:     Lawrence C Paulson
     4 *)
     5 
     6 header{*Power Series, Transcendental Functions etc.*}
     7 
     8 theory Transcendental
     9 imports Fact Series Deriv NthRoot
    10 begin
    11 
    12 subsection {* Properties of Power Series *}
    13 
    14 lemma lemma_realpow_diff:
    15   fixes y :: "'a::monoid_mult"
    16   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    17 proof -
    18   assume "p \<le> n"
    19   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    20   thus ?thesis by (simp add: power_commutes)
    21 qed
    22 
    23 lemma lemma_realpow_diff_sumr:
    24   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    25      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =  
    26       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    27 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    28          del: setsum_op_ivl_Suc)
    29 
    30 lemma lemma_realpow_diff_sumr2:
    31   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    32      "x ^ (Suc n) - y ^ (Suc n) =  
    33       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    34 apply (induct n, simp)
    35 apply (simp del: setsum_op_ivl_Suc)
    36 apply (subst setsum_op_ivl_Suc)
    37 apply (subst lemma_realpow_diff_sumr)
    38 apply (simp add: right_distrib del: setsum_op_ivl_Suc)
    39 apply (subst mult_left_commute [of "x - y"])
    40 apply (erule subst)
    41 apply (simp add: algebra_simps)
    42 done
    43 
    44 lemma lemma_realpow_rev_sumr:
    45      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =  
    46       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    47 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    48 apply (rule inj_onI, simp)
    49 apply auto
    50 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    51 done
    52 
    53 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    54 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    55 
    56 lemma powser_insidea:
    57   fixes x z :: "'a::{real_normed_field,banach}"
    58   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    59   assumes 2: "norm z < norm x"
    60   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    61 proof -
    62   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    63   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    64     by (rule summable_LIMSEQ_zero)
    65   hence "convergent (\<lambda>n. f n * x ^ n)"
    66     by (rule convergentI)
    67   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    68     by (simp add: Cauchy_convergent_iff)
    69   hence "Bseq (\<lambda>n. f n * x ^ n)"
    70     by (rule Cauchy_Bseq)
    71   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    72     by (simp add: Bseq_def, safe)
    73   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    74                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    75   proof (intro exI allI impI)
    76     fix n::nat assume "0 \<le> n"
    77     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    78           norm (f n * x ^ n) * norm (z ^ n)"
    79       by (simp add: norm_mult abs_mult)
    80     also have "\<dots> \<le> K * norm (z ^ n)"
    81       by (simp only: mult_right_mono 4 norm_ge_zero)
    82     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    83       by (simp add: x_neq_0)
    84     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    85       by (simp only: mult_assoc)
    86     finally show "norm (norm (f n * z ^ n)) \<le>
    87                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    88       by (simp add: mult_le_cancel_right x_neq_0)
    89   qed
    90   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    91   proof -
    92     from 2 have "norm (norm (z * inverse x)) < 1"
    93       using x_neq_0
    94       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    95     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    96       by (rule summable_geometric)
    97     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
    98       by (rule summable_mult)
    99     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   100       using x_neq_0
   101       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   102                     power_inverse norm_power mult_assoc)
   103   qed
   104   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   105     by (rule summable_comparison_test)
   106 qed
   107 
   108 lemma powser_inside:
   109   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   110      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]  
   111       ==> summable (%n. f(n) * (z ^ n))"
   112 by (rule powser_insidea [THEN summable_norm_cancel])
   113 
   114 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   115   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) = 
   116    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   117 proof (induct n)
   118   case (Suc n)
   119   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) = 
   120         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   121     using Suc.hyps unfolding One_nat_def by auto
   122   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   123   finally show ?case .
   124 qed auto
   125 
   126 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   127   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   128   unfolding sums_def
   129 proof (rule LIMSEQ_I)
   130   fix r :: real assume "0 < r"
   131   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   132   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   133 
   134   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   135   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   136     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }" 
   137       using sum_split_even_odd by auto
   138     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   139     moreover
   140     have "?SUM (2 * (m div 2)) = ?SUM m"
   141     proof (cases "even m")
   142       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   143     next
   144       case False hence "even (Suc m)" by auto
   145       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   146       have eq: "Suc (2 * (m div 2)) = m" by auto
   147       hence "even (2 * (m div 2))" using `odd m` by auto
   148       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   149       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   150       finally show ?thesis by auto
   151     qed
   152     ultimately have "(norm (?SUM m - x) < r)" by auto
   153   }
   154   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   155 qed
   156 
   157 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   158   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   159 proof -
   160   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   161   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   162       by (cases B) auto } note if_sum = this
   163   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   164   { 
   165     have "?s 0 = 0" by auto
   166     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   167     { fix B T E have "(if \<not> B then T else E) = (if B then E else T)" by auto } note if_eq = this
   168 
   169     have "?s sums y" using sums_if'[OF `f sums y`] .
   170     from this[unfolded sums_def, THEN LIMSEQ_Suc] 
   171     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   172       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   173                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   174                 even_Suc Suc_m1 if_eq .
   175   } from sums_add[OF g_sums this]
   176   show ?thesis unfolding if_sum .
   177 qed
   178 
   179 subsection {* Alternating series test / Leibniz formula *}
   180 
   181 lemma sums_alternating_upper_lower:
   182   fixes a :: "nat \<Rightarrow> real"
   183   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   184   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and> 
   185              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   186   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   187 proof -
   188   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   189 
   190   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   191   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   192   moreover
   193   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   194   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   195     unfolding One_nat_def by auto qed
   196   moreover
   197   have "\<forall> n. ?f n \<le> ?g n" 
   198   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   199     unfolding One_nat_def by auto qed
   200   moreover
   201   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   202   proof (rule LIMSEQ_I)
   203     fix r :: real assume "0 < r"
   204     with `a ----> 0`[THEN LIMSEQ_D] 
   205     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   206     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   207     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   208   qed
   209   ultimately
   210   show ?thesis by (rule lemma_nest_unique)
   211 qed 
   212 
   213 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   214   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   215   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   216   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   217   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   218   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   219   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221 proof -
   222   let "?S n" = "(-1)^n * a n"
   223   let "?P n" = "\<Sum>i=0..<n. ?S i"
   224   let "?f n" = "?P (2 * n)"
   225   let "?g n" = "?P (2 * n + 1)"
   226   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   227     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   228   
   229   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   230   have "?Sa ----> l"
   231   proof (rule LIMSEQ_I)
   232     fix r :: real assume "0 < r"
   233 
   234     with `?f ----> l`[THEN LIMSEQ_D] 
   235     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   236 
   237     from `0 < r` `?g ----> l`[THEN LIMSEQ_D] 
   238     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   239 
   240     { fix n :: nat
   241       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   242       have "norm (?Sa n - l) < r"
   243       proof (cases "even n")
   244         case True from even_nat_div_two_times_two[OF this]
   245         have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   246         with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   247         from f[OF this]
   248         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   249       next
   250         case False hence "even (n - 1)" by simp
   251         from even_nat_div_two_times_two[OF this]
   252         have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   253         hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   254 
   255         from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   256         from g[OF this]
   257         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   258       qed
   259     }
   260     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   261   qed
   262   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   263   thus "summable ?S" using summable_def by auto
   264 
   265   have "l = suminf ?S" using sums_unique[OF sums_l] .
   266 
   267   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   268   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   269   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   270   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   271 qed
   272 
   273 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   274   assumes a_zero: "a ----> 0" and "monoseq a"
   275   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   276   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   277   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   278   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   279   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   280 proof -
   281   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   282   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   283     case True
   284     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   285     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   286     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   287     from leibniz[OF mono]
   288     show ?thesis using `0 \<le> a 0` by auto
   289   next
   290     let ?a = "\<lambda> n. - a n"
   291     case False
   292     with monoseq_le[OF `monoseq a` `a ----> 0`]
   293     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   294     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   295     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   296     note monotone = this
   297     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF LIMSEQ_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   298     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   299     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   300     from this[THEN sums_minus]
   301     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   302     hence ?summable unfolding summable_def by auto
   303     moreover
   304     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   305     
   306     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   307     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   308 
   309     have ?pos using `0 \<le> ?a 0` by auto
   310     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   311     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN LIMSEQ_minus_cancel] by auto
   312     ultimately show ?thesis by auto
   313   qed
   314   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   315        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   316   show ?summable and ?pos and ?neg and ?f and ?g .
   317 qed
   318 
   319 subsection {* Term-by-Term Differentiability of Power Series *}
   320 
   321 definition
   322   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   323   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   324 
   325 text{*Lemma about distributing negation over it*}
   326 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   327 by (simp add: diffs_def)
   328 
   329 lemma sums_Suc_imp:
   330   assumes f: "f 0 = 0"
   331   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   332 unfolding sums_def
   333 apply (rule LIMSEQ_imp_Suc)
   334 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   335 apply (simp only: setsum_shift_bounds_Suc_ivl)
   336 done
   337 
   338 lemma diffs_equiv:
   339      "summable (%n. (diffs c)(n) * (x ^ n)) ==>  
   340       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums  
   341          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   342 unfolding diffs_def
   343 apply (drule summable_sums)
   344 apply (rule sums_Suc_imp, simp_all)
   345 done
   346 
   347 lemma lemma_termdiff1:
   348   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   349   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =  
   350    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   351 by(auto simp add: algebra_simps power_add [symmetric] cong: strong_setsum_cong)
   352 
   353 lemma sumr_diff_mult_const2:
   354   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   355 by (simp add: setsum_subtractf)
   356 
   357 lemma lemma_termdiff2:
   358   fixes h :: "'a :: {field}"
   359   assumes h: "h \<noteq> 0" shows
   360   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   361    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   362         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   363 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   364 apply (simp add: right_diff_distrib diff_divide_distrib h)
   365 apply (simp add: mult_assoc [symmetric])
   366 apply (cases "n", simp)
   367 apply (simp add: lemma_realpow_diff_sumr2 h
   368                  right_diff_distrib [symmetric] mult_assoc
   369             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   370 apply (subst lemma_realpow_rev_sumr)
   371 apply (subst sumr_diff_mult_const2)
   372 apply simp
   373 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   374 apply (rule setsum_cong [OF refl])
   375 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   376 apply (clarify)
   377 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   378             del: setsum_op_ivl_Suc power_Suc)
   379 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   380 apply (simp add: mult_ac)
   381 done
   382 
   383 lemma real_setsum_nat_ivl_bounded2:
   384   fixes K :: "'a::linordered_semidom"
   385   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   386   assumes K: "0 \<le> K"
   387   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   388 apply (rule order_trans [OF setsum_mono])
   389 apply (rule f, simp)
   390 apply (simp add: mult_right_mono K)
   391 done
   392 
   393 lemma lemma_termdiff3:
   394   fixes h z :: "'a::{real_normed_field}"
   395   assumes 1: "h \<noteq> 0"
   396   assumes 2: "norm z \<le> K"
   397   assumes 3: "norm (z + h) \<le> K"
   398   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   399           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   400 proof -
   401   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   402         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   403           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   404     apply (subst lemma_termdiff2 [OF 1])
   405     apply (subst norm_mult)
   406     apply (rule mult_commute)
   407     done
   408   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   409   proof (rule mult_right_mono [OF _ norm_ge_zero])
   410     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   411     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   412       apply (erule subst)
   413       apply (simp only: norm_mult norm_power power_add)
   414       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   415       done
   416     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   417               (z + h) ^ q * z ^ (n - 2 - q))
   418           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   419       apply (intro
   420          order_trans [OF norm_setsum]
   421          real_setsum_nat_ivl_bounded2
   422          mult_nonneg_nonneg
   423          zero_le_imp_of_nat
   424          zero_le_power K)
   425       apply (rule le_Kn, simp)
   426       done
   427   qed
   428   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   429     by (simp only: mult_assoc)
   430   finally show ?thesis .
   431 qed
   432 
   433 lemma lemma_termdiff4:
   434   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   435               'b::real_normed_vector"
   436   assumes k: "0 < (k::real)"
   437   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   438   shows "f -- 0 --> 0"
   439 unfolding LIM_eq diff_0_right
   440 proof (safe)
   441   let ?h = "of_real (k / 2)::'a"
   442   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   443   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   444   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   445   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   446 
   447   fix r::real assume r: "0 < r"
   448   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   449   proof (cases)
   450     assume "K = 0"
   451     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   452       by simp
   453     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   454   next
   455     assume K_neq_zero: "K \<noteq> 0"
   456     with zero_le_K have K: "0 < K" by simp
   457     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   458     proof (rule exI, safe)
   459       from k r K show "0 < min k (r * inverse K / 2)"
   460         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   461     next
   462       fix x::'a
   463       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   464       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   465         by simp_all
   466       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   467       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   468         by (rule mult_strict_left_mono)
   469       also have "\<dots> = r / 2"
   470         using K_neq_zero by simp
   471       also have "r / 2 < r"
   472         using r by simp
   473       finally show "norm (f x) < r" .
   474     qed
   475   qed
   476 qed
   477 
   478 lemma lemma_termdiff5:
   479   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   480               nat \<Rightarrow> 'b::banach"
   481   assumes k: "0 < (k::real)"
   482   assumes f: "summable f"
   483   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   484   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   485 proof (rule lemma_termdiff4 [OF k])
   486   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   487   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   488     by (simp add: le)
   489   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   490     by simp
   491   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   492     by (rule summable_mult2)
   493   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   494     by (rule summable_comparison_test)
   495   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   496     by (rule summable_norm)
   497   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   498     by (rule summable_le)
   499   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   500     by (rule suminf_mult2 [symmetric])
   501   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   502 qed
   503 
   504 
   505 text{* FIXME: Long proofs*}
   506 
   507 lemma termdiffs_aux:
   508   fixes x :: "'a::{real_normed_field,banach}"
   509   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   510   assumes 2: "norm x < norm K"
   511   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   512              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   513 proof -
   514   from dense [OF 2]
   515   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   516   from norm_ge_zero r1 have r: "0 < r"
   517     by (rule order_le_less_trans)
   518   hence r_neq_0: "r \<noteq> 0" by simp
   519   show ?thesis
   520   proof (rule lemma_termdiff5)
   521     show "0 < r - norm x" using r1 by simp
   522   next
   523     from r r2 have "norm (of_real r::'a) < norm K"
   524       by simp
   525     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   526       by (rule powser_insidea)
   527     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   528       using r
   529       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   530     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   531       by (rule diffs_equiv [THEN sums_summable])
   532     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   533       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   534       apply (rule ext)
   535       apply (simp add: diffs_def)
   536       apply (case_tac n, simp_all add: r_neq_0)
   537       done
   538     finally have "summable 
   539       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   540       by (rule diffs_equiv [THEN sums_summable])
   541     also have
   542       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   543            r ^ (n - Suc 0)) =
   544        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   545       apply (rule ext)
   546       apply (case_tac "n", simp)
   547       apply (case_tac "nat", simp)
   548       apply (simp add: r_neq_0)
   549       done
   550     finally show
   551       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   552   next
   553     fix h::'a and n::nat
   554     assume h: "h \<noteq> 0"
   555     assume "norm h < r - norm x"
   556     hence "norm x + norm h < r" by simp
   557     with norm_triangle_ineq have xh: "norm (x + h) < r"
   558       by (rule order_le_less_trans)
   559     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   560           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   561       apply (simp only: norm_mult mult_assoc)
   562       apply (rule mult_left_mono [OF _ norm_ge_zero])
   563       apply (simp (no_asm) add: mult_assoc [symmetric])
   564       apply (rule lemma_termdiff3)
   565       apply (rule h)
   566       apply (rule r1 [THEN order_less_imp_le])
   567       apply (rule xh [THEN order_less_imp_le])
   568       done
   569   qed
   570 qed
   571 
   572 lemma termdiffs:
   573   fixes K x :: "'a::{real_normed_field,banach}"
   574   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   575   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   576   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   577   assumes 4: "norm x < norm K"
   578   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   579 unfolding deriv_def
   580 proof (rule LIM_zero_cancel)
   581   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   582             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   583   proof (rule LIM_equal2)
   584     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   585   next
   586     fix h :: 'a
   587     assume "h \<noteq> 0"
   588     assume "norm (h - 0) < norm K - norm x"
   589     hence "norm x + norm h < norm K" by simp
   590     hence 5: "norm (x + h) < norm K"
   591       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   592     have A: "summable (\<lambda>n. c n * x ^ n)"
   593       by (rule powser_inside [OF 1 4])
   594     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   595       by (rule powser_inside [OF 1 5])
   596     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   597       by (rule powser_inside [OF 2 4])
   598     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   599              - (\<Sum>n. diffs c n * x ^ n) = 
   600           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   601       apply (subst sums_unique [OF diffs_equiv [OF C]])
   602       apply (subst suminf_diff [OF B A])
   603       apply (subst suminf_divide [symmetric])
   604       apply (rule summable_diff [OF B A])
   605       apply (subst suminf_diff)
   606       apply (rule summable_divide)
   607       apply (rule summable_diff [OF B A])
   608       apply (rule sums_summable [OF diffs_equiv [OF C]])
   609       apply (rule arg_cong [where f="suminf"], rule ext)
   610       apply (simp add: algebra_simps)
   611       done
   612   next
   613     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   614                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   615         by (rule termdiffs_aux [OF 3 4])
   616   qed
   617 qed
   618 
   619 
   620 subsection{* Some properties of factorials *}
   621 
   622 lemma real_of_nat_fact_not_zero [simp]: "real (fact (n::nat)) \<noteq> 0"
   623 by auto
   624 
   625 lemma real_of_nat_fact_gt_zero [simp]: "0 < real(fact (n::nat))"
   626 by auto
   627 
   628 lemma real_of_nat_fact_ge_zero [simp]: "0 \<le> real(fact (n::nat))"
   629 by simp
   630 
   631 lemma inv_real_of_nat_fact_gt_zero [simp]: "0 < inverse (real (fact (n::nat)))"
   632 by (auto simp add: positive_imp_inverse_positive)
   633 
   634 lemma inv_real_of_nat_fact_ge_zero [simp]: "0 \<le> inverse (real (fact (n::nat)))"
   635 by (auto intro: order_less_imp_le)
   636 
   637 subsection {* Derivability of power series *}
   638 
   639 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   640   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   641   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   642   and "summable (f' x0)"
   643   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   644   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   645   unfolding deriv_def
   646 proof (rule LIM_I)
   647   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   648 
   649   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3" 
   650     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   651 
   652   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3" 
   653     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   654 
   655   let ?N = "Suc (max N_L N_f')"
   656   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   657     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   658 
   659   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   660 
   661   let ?r = "r / (3 * real ?N)"
   662   have "0 < 3 * real ?N" by auto
   663   from divide_pos_pos[OF `0 < r` this]
   664   have "0 < ?r" .
   665 
   666   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   667   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   668 
   669   have "0 < S'" unfolding S'_def
   670   proof (rule iffD2[OF Min_gr_iff])
   671     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   672     proof (rule ballI)
   673       fix x assume "x \<in> ?s ` {0..<?N}"
   674       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   675       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def] 
   676       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   677       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   678       thus "0 < x" unfolding `x = ?s n` .
   679     qed
   680   qed auto
   681 
   682   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   683   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   684     by auto
   685 
   686   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   687     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   688     
   689     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   690     note div_smbl = summable_divide[OF diff_smbl]
   691     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   692     note ign = summable_ignore_initial_segment[where k="?N"]
   693     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   694     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   695     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   696 
   697     { fix n
   698       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>" 
   699         using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   700       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   701     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   702     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   703     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   704     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   705 
   706     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   707     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   708     proof (rule setsum_strict_mono)
   709       fix n assume "n \<in> { 0 ..< ?N}"
   710       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   711       also have "S \<le> S'" using `S \<le> S'` .
   712       also have "S' \<le> ?s n" unfolding S'_def 
   713       proof (rule Min_le_iff[THEN iffD2])
   714         have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   715         thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   716       qed auto
   717       finally have "\<bar> x \<bar> < ?s n" .
   718 
   719       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   720       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   721       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   722       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   723     qed auto
   724     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   725     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   726     also have "\<dots> = r/3" by auto
   727     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   728 
   729     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   730     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> = 
   731                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   732     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   733     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   734     also have "\<dots> < r /3 + r/3 + r/3" 
   735       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3` by auto
   736     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   737       by auto
   738   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow> 
   739       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   740     unfolding real_norm_def diff_0_right by blast
   741 qed
   742 
   743 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   744   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   745   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   746   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   747   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   748 proof -
   749   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   750     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   751     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   752     proof (rule DERIV_series')
   753       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   754       proof -
   755         have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   756         hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   757         have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   758         from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   759       qed
   760       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   761         show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   762         proof -
   763           have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>" 
   764             unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   765           also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)" 
   766           proof (rule mult_left_mono)
   767             have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   768             also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   769             proof (rule setsum_mono)
   770               fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   771               { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   772                 hence "\<bar>x\<bar> \<le> R'"  by auto
   773                 hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   774               } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   775               have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   776               thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   777             qed
   778             also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   779             finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   780             show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   781           qed
   782           also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult real_mult_assoc[symmetric] by algebra
   783           finally show ?thesis .
   784         qed }
   785       { fix n show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)"
   786           by (auto intro!: DERIV_intros simp del: power_Suc) }
   787       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   788         have "summable (\<lambda> n. f n * x^n)"
   789         proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   790           fix n
   791           have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   792           show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   793             by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   794         qed
   795         from this[THEN summable_mult2[where c=x], unfolded real_mult_assoc, unfolded real_mult_commute]
   796         show "summable (?f x)" by auto }
   797       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   798       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   799     qed
   800   } note for_subinterval = this
   801   let ?R = "(R + \<bar>x0\<bar>) / 2"
   802   have "\<bar>x0\<bar> < ?R" using assms by auto
   803   hence "- ?R < x0"
   804   proof (cases "x0 < 0")
   805     case True
   806     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   807     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   808   next
   809     case False
   810     have "- ?R < 0" using assms by auto
   811     also have "\<dots> \<le> x0" using False by auto 
   812     finally show ?thesis .
   813   qed
   814   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   815   from for_subinterval[OF this]
   816   show ?thesis .
   817 qed
   818 
   819 subsection {* Exponential Function *}
   820 
   821 definition
   822   exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   823   "exp x = (\<Sum>n. x ^ n /\<^sub>R real (fact n))"
   824 
   825 lemma summable_exp_generic:
   826   fixes x :: "'a::{real_normed_algebra_1,banach}"
   827   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   828   shows "summable S"
   829 proof -
   830   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   831     unfolding S_def by (simp del: mult_Suc)
   832   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   833     using dense [OF zero_less_one] by fast
   834   obtain N :: nat where N: "norm x < real N * r"
   835     using reals_Archimedean3 [OF r0] by fast
   836   from r1 show ?thesis
   837   proof (rule ratio_test [rule_format])
   838     fix n :: nat
   839     assume n: "N \<le> n"
   840     have "norm x \<le> real N * r"
   841       using N by (rule order_less_imp_le)
   842     also have "real N * r \<le> real (Suc n) * r"
   843       using r0 n by (simp add: mult_right_mono)
   844     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   845       using norm_ge_zero by (rule mult_right_mono)
   846     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   847       by (rule order_trans [OF norm_mult_ineq])
   848     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   849       by (simp add: pos_divide_le_eq mult_ac)
   850     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   851       by (simp add: S_Suc inverse_eq_divide)
   852   qed
   853 qed
   854 
   855 lemma summable_norm_exp:
   856   fixes x :: "'a::{real_normed_algebra_1,banach}"
   857   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   858 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   859   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   860     by (rule summable_exp_generic)
   861 next
   862   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   863     by (simp add: norm_power_ineq)
   864 qed
   865 
   866 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   867 by (insert summable_exp_generic [where x=x], simp)
   868 
   869 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   870 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   871 
   872 
   873 lemma exp_fdiffs: 
   874       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   875 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   876          del: mult_Suc of_nat_Suc)
   877 
   878 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   879 by (simp add: diffs_def)
   880 
   881 lemma lemma_exp_ext: "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   882 by (auto intro!: ext simp add: exp_def)
   883 
   884 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   885 apply (simp add: exp_def)
   886 apply (subst lemma_exp_ext)
   887 apply (subgoal_tac "DERIV (\<lambda>u. \<Sum>n. of_real (inverse (real (fact n))) * u ^ n) x :> (\<Sum>n. diffs (\<lambda>n. of_real (inverse (real (fact n)))) n * x ^ n)")
   888 apply (rule_tac [2] K = "of_real (1 + norm x)" in termdiffs)
   889 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   890 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   891 apply (simp del: of_real_add)
   892 done
   893 
   894 lemma isCont_exp [simp]: "isCont exp x"
   895 by (rule DERIV_exp [THEN DERIV_isCont])
   896 
   897 
   898 subsubsection {* Properties of the Exponential Function *}
   899 
   900 lemma powser_zero:
   901   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   902   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   903 proof -
   904   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   905     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   906   thus ?thesis unfolding One_nat_def by simp
   907 qed
   908 
   909 lemma exp_zero [simp]: "exp 0 = 1"
   910 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   911 
   912 lemma setsum_cl_ivl_Suc2:
   913   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   914 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   915          del: setsum_cl_ivl_Suc)
   916 
   917 lemma exp_series_add:
   918   fixes x y :: "'a::{real_field}"
   919   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   920   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   921 proof (induct n)
   922   case 0
   923   show ?case
   924     unfolding S_def by simp
   925 next
   926   case (Suc n)
   927   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   928     unfolding S_def by (simp del: mult_Suc)
   929   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   930     by simp
   931 
   932   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   933     by (simp only: times_S)
   934   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   935     by (simp only: Suc)
   936   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   937                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   938     by (rule left_distrib)
   939   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   940                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   941     by (simp only: setsum_right_distrib mult_ac)
   942   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   943                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   944     by (simp add: times_S Suc_diff_le)
   945   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   946              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   947     by (subst setsum_cl_ivl_Suc2, simp)
   948   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   949              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   950     by (subst setsum_cl_ivl_Suc, simp)
   951   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   952              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   953              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   954     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   955               real_of_nat_add [symmetric], simp)
   956   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   957     by (simp only: scaleR_right.setsum)
   958   finally show
   959     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   960     by (simp del: setsum_cl_ivl_Suc)
   961 qed
   962 
   963 lemma exp_add: "exp (x + y) = exp x * exp y"
   964 unfolding exp_def
   965 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   966 
   967 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   968 by (rule exp_add [symmetric])
   969 
   970 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   971 unfolding exp_def
   972 apply (subst of_real.suminf)
   973 apply (rule summable_exp_generic)
   974 apply (simp add: scaleR_conv_of_real)
   975 done
   976 
   977 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   978 proof
   979   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   980   also assume "exp x = 0"
   981   finally show "False" by simp
   982 qed
   983 
   984 lemma exp_minus: "exp (- x) = inverse (exp x)"
   985 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   986 
   987 lemma exp_diff: "exp (x - y) = exp x / exp y"
   988   unfolding diff_minus divide_inverse
   989   by (simp add: exp_add exp_minus)
   990 
   991 
   992 subsubsection {* Properties of the Exponential Function on Reals *}
   993 
   994 text {* Comparisons of @{term "exp x"} with zero. *}
   995 
   996 text{*Proof: because every exponential can be seen as a square.*}
   997 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
   998 proof -
   999   have "0 \<le> exp (x/2) * exp (x/2)" by simp
  1000   thus ?thesis by (simp add: exp_add [symmetric])
  1001 qed
  1002 
  1003 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
  1004 by (simp add: order_less_le)
  1005 
  1006 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
  1007 by (simp add: not_less)
  1008 
  1009 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
  1010 by (simp add: not_le)
  1011 
  1012 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
  1013 by simp
  1014 
  1015 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1016 apply (induct "n")
  1017 apply (auto simp add: real_of_nat_Suc right_distrib exp_add mult_commute)
  1018 done
  1019 
  1020 text {* Strict monotonicity of exponential. *}
  1021 
  1022 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1023 apply (drule order_le_imp_less_or_eq, auto)
  1024 apply (simp add: exp_def)
  1025 apply (rule real_le_trans)
  1026 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1027 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1028 done
  1029 
  1030 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1031 proof -
  1032   assume x: "0 < x"
  1033   hence "1 < 1 + x" by simp
  1034   also from x have "1 + x \<le> exp x"
  1035     by (simp add: exp_ge_add_one_self_aux)
  1036   finally show ?thesis .
  1037 qed
  1038 
  1039 lemma exp_less_mono:
  1040   fixes x y :: real
  1041   assumes "x < y" shows "exp x < exp y"
  1042 proof -
  1043   from `x < y` have "0 < y - x" by simp
  1044   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1045   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1046   thus "exp x < exp y" by simp
  1047 qed
  1048 
  1049 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1050 apply (simp add: linorder_not_le [symmetric])
  1051 apply (auto simp add: order_le_less exp_less_mono)
  1052 done
  1053 
  1054 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1055 by (auto intro: exp_less_mono exp_less_cancel)
  1056 
  1057 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1058 by (auto simp add: linorder_not_less [symmetric])
  1059 
  1060 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1061 by (simp add: order_eq_iff)
  1062 
  1063 text {* Comparisons of @{term "exp x"} with one. *}
  1064 
  1065 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1066   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1067 
  1068 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1069   using exp_less_cancel_iff [where x=x and y=0] by simp
  1070 
  1071 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1072   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1073 
  1074 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1075   using exp_le_cancel_iff [where x=x and y=0] by simp
  1076 
  1077 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1078   using exp_inj_iff [where x=x and y=0] by simp
  1079 
  1080 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1081 apply (rule IVT)
  1082 apply (auto intro: isCont_exp simp add: le_diff_eq)
  1083 apply (subgoal_tac "1 + (y - 1) \<le> exp (y - 1)") 
  1084 apply simp
  1085 apply (rule exp_ge_add_one_self_aux, simp)
  1086 done
  1087 
  1088 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1089 apply (rule_tac x = 1 and y = y in linorder_cases)
  1090 apply (drule order_less_imp_le [THEN lemma_exp_total])
  1091 apply (rule_tac [2] x = 0 in exI)
  1092 apply (frule_tac [3] real_inverse_gt_one)
  1093 apply (drule_tac [4] order_less_imp_le [THEN lemma_exp_total], auto)
  1094 apply (rule_tac x = "-x" in exI)
  1095 apply (simp add: exp_minus)
  1096 done
  1097 
  1098 
  1099 subsection {* Natural Logarithm *}
  1100 
  1101 definition
  1102   ln :: "real => real" where
  1103   "ln x = (THE u. exp u = x)"
  1104 
  1105 lemma ln_exp [simp]: "ln (exp x) = x"
  1106 by (simp add: ln_def)
  1107 
  1108 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1109 by (auto dest: exp_total)
  1110 
  1111 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1112 apply (rule iffI)
  1113 apply (erule subst, rule exp_gt_zero)
  1114 apply (erule exp_ln)
  1115 done
  1116 
  1117 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1118 by (erule subst, rule ln_exp)
  1119 
  1120 lemma ln_one [simp]: "ln 1 = 0"
  1121 by (rule ln_unique, simp)
  1122 
  1123 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1124 by (rule ln_unique, simp add: exp_add)
  1125 
  1126 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1127 by (rule ln_unique, simp add: exp_minus)
  1128 
  1129 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1130 by (rule ln_unique, simp add: exp_diff)
  1131 
  1132 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1133 by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1134 
  1135 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1136 by (subst exp_less_cancel_iff [symmetric], simp)
  1137 
  1138 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1139 by (simp add: linorder_not_less [symmetric])
  1140 
  1141 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1142 by (simp add: order_eq_iff)
  1143 
  1144 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1145 apply (rule exp_le_cancel_iff [THEN iffD1])
  1146 apply (simp add: exp_ge_add_one_self_aux)
  1147 done
  1148 
  1149 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1150 by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1151 
  1152 lemma ln_ge_zero [simp]:
  1153   assumes x: "1 \<le> x" shows "0 \<le> ln x"
  1154 proof -
  1155   have "0 < x" using x by arith
  1156   hence "exp 0 \<le> exp (ln x)"
  1157     by (simp add: x)
  1158   thus ?thesis by (simp only: exp_le_cancel_iff)
  1159 qed
  1160 
  1161 lemma ln_ge_zero_imp_ge_one:
  1162   assumes ln: "0 \<le> ln x" 
  1163       and x:  "0 < x"
  1164   shows "1 \<le> x"
  1165 proof -
  1166   from ln have "ln 1 \<le> ln x" by simp
  1167   thus ?thesis by (simp add: x del: ln_one) 
  1168 qed
  1169 
  1170 lemma ln_ge_zero_iff [simp]: "0 < x ==> (0 \<le> ln x) = (1 \<le> x)"
  1171 by (blast intro: ln_ge_zero ln_ge_zero_imp_ge_one)
  1172 
  1173 lemma ln_less_zero_iff [simp]: "0 < x ==> (ln x < 0) = (x < 1)"
  1174 by (insert ln_ge_zero_iff [of x], arith)
  1175 
  1176 lemma ln_gt_zero:
  1177   assumes x: "1 < x" shows "0 < ln x"
  1178 proof -
  1179   have "0 < x" using x by arith
  1180   hence "exp 0 < exp (ln x)" by (simp add: x)
  1181   thus ?thesis  by (simp only: exp_less_cancel_iff)
  1182 qed
  1183 
  1184 lemma ln_gt_zero_imp_gt_one:
  1185   assumes ln: "0 < ln x" 
  1186       and x:  "0 < x"
  1187   shows "1 < x"
  1188 proof -
  1189   from ln have "ln 1 < ln x" by simp
  1190   thus ?thesis by (simp add: x del: ln_one) 
  1191 qed
  1192 
  1193 lemma ln_gt_zero_iff [simp]: "0 < x ==> (0 < ln x) = (1 < x)"
  1194 by (blast intro: ln_gt_zero ln_gt_zero_imp_gt_one)
  1195 
  1196 lemma ln_eq_zero_iff [simp]: "0 < x ==> (ln x = 0) = (x = 1)"
  1197 by (insert ln_less_zero_iff [of x] ln_gt_zero_iff [of x], arith)
  1198 
  1199 lemma ln_less_zero: "[| 0 < x; x < 1 |] ==> ln x < 0"
  1200 by simp
  1201 
  1202 lemma exp_ln_eq: "exp u = x ==> ln x = u"
  1203 by auto
  1204 
  1205 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1206 apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1207 apply (rule isCont_inverse_function [where f=exp], simp_all)
  1208 done
  1209 
  1210 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1211 apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1212 apply (erule lemma_DERIV_subst [OF DERIV_exp exp_ln])
  1213 apply (simp_all add: abs_if isCont_ln)
  1214 done
  1215 
  1216 lemma DERIV_ln_divide: "0 < x ==> DERIV ln x :> 1 / x"
  1217   by (rule DERIV_ln[THEN DERIV_cong], simp, simp add: divide_inverse)
  1218 
  1219 lemma ln_series: assumes "0 < x" and "x < 2"
  1220   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1221 proof -
  1222   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1223 
  1224   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1225   proof (rule DERIV_isconst3[where x=x])
  1226     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1227     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1228     have "1 / x = 1 / (1 - (1 - x))" by auto
  1229     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1230     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1231     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding real_divide_def by auto
  1232     moreover
  1233     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1234     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1235     proof (rule DERIV_power_series')
  1236       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1237       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1238         show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1239           unfolding One_nat_def
  1240           by (auto simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1241       }
  1242     qed
  1243     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1244     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1245     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1246       by (rule DERIV_diff)
  1247     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1248   qed (auto simp add: assms)
  1249   thus ?thesis by (auto simp add: suminf_zero)
  1250 qed
  1251 
  1252 subsection {* Sine and Cosine *}
  1253 
  1254 definition
  1255   sin_coeff :: "nat \<Rightarrow> real" where
  1256   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  1257 
  1258 definition
  1259   cos_coeff :: "nat \<Rightarrow> real" where
  1260   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  1261 
  1262 definition
  1263   sin :: "real => real" where
  1264   "sin x = (\<Sum>n. sin_coeff n * x ^ n)"
  1265 
  1266 definition
  1267   cos :: "real => real" where
  1268   "cos x = (\<Sum>n. cos_coeff n * x ^ n)"
  1269 
  1270 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  1271 unfolding sin_coeff_def
  1272 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1273 apply (rule_tac [2] summable_exp)
  1274 apply (rule_tac x = 0 in exI)
  1275 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1276 done
  1277 
  1278 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  1279 unfolding cos_coeff_def
  1280 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1281 apply (rule_tac [2] summable_exp)
  1282 apply (rule_tac x = 0 in exI)
  1283 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1284 done
  1285 
  1286 lemma lemma_STAR_sin:
  1287      "(if even n then 0  
  1288        else -1 ^ ((n - Suc 0) div 2)/(real (fact n))) * 0 ^ n = 0"
  1289 by (induct "n", auto)
  1290 
  1291 lemma lemma_STAR_cos:
  1292      "0 < n -->  
  1293       -1 ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1294 by (induct "n", auto)
  1295 
  1296 lemma lemma_STAR_cos1:
  1297      "0 < n -->  
  1298       (-1) ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1299 by (induct "n", auto)
  1300 
  1301 lemma lemma_STAR_cos2:
  1302   "(\<Sum>n=1..<n. if even n then -1 ^ (n div 2)/(real (fact n)) *  0 ^ n 
  1303                          else 0) = 0"
  1304 apply (induct "n")
  1305 apply (case_tac [2] "n", auto)
  1306 done
  1307 
  1308 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  1309 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  1310 
  1311 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  1312 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  1313 
  1314 lemma sin_fdiffs: "diffs sin_coeff = cos_coeff"
  1315 unfolding sin_coeff_def cos_coeff_def
  1316 by (auto intro!: ext 
  1317          simp add: diffs_def divide_inverse real_of_nat_def of_nat_mult
  1318          simp del: mult_Suc of_nat_Suc)
  1319 
  1320 lemma sin_fdiffs2: "diffs sin_coeff n = cos_coeff n"
  1321 by (simp only: sin_fdiffs)
  1322 
  1323 lemma cos_fdiffs: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  1324 unfolding sin_coeff_def cos_coeff_def
  1325 by (auto intro!: ext 
  1326          simp add: diffs_def divide_inverse odd_Suc_mult_two_ex real_of_nat_def of_nat_mult
  1327          simp del: mult_Suc of_nat_Suc)
  1328 
  1329 lemma cos_fdiffs2: "diffs cos_coeff n = - sin_coeff n"
  1330 by (simp only: cos_fdiffs)
  1331 
  1332 text{*Now at last we can get the derivatives of exp, sin and cos*}
  1333 
  1334 lemma lemma_sin_minus: "- sin x = (\<Sum>n. - (sin_coeff n * x ^ n))"
  1335 by (auto intro!: sums_unique sums_minus sin_converges)
  1336 
  1337 lemma lemma_sin_ext: "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  1338 by (auto intro!: ext simp add: sin_def)
  1339 
  1340 lemma lemma_cos_ext: "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  1341 by (auto intro!: ext simp add: cos_def)
  1342 
  1343 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  1344 apply (simp add: cos_def)
  1345 apply (subst lemma_sin_ext)
  1346 apply (auto simp add: sin_fdiffs2 [symmetric])
  1347 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1348 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs)
  1349 done
  1350 
  1351 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  1352 apply (subst lemma_cos_ext)
  1353 apply (auto simp add: lemma_sin_minus cos_fdiffs2 [symmetric] minus_mult_left)
  1354 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1355 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs diffs_minus)
  1356 done
  1357 
  1358 lemma isCont_sin [simp]: "isCont sin x"
  1359 by (rule DERIV_sin [THEN DERIV_isCont])
  1360 
  1361 lemma isCont_cos [simp]: "isCont cos x"
  1362 by (rule DERIV_cos [THEN DERIV_isCont])
  1363 
  1364 
  1365 declare
  1366   DERIV_exp[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1367   DERIV_ln[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1368   DERIV_sin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1369   DERIV_cos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1370 
  1371 subsection {* Properties of Sine and Cosine *}
  1372 
  1373 lemma sin_zero [simp]: "sin 0 = 0"
  1374 unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  1375 
  1376 lemma cos_zero [simp]: "cos 0 = 1"
  1377 unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  1378 
  1379 lemma DERIV_sin_sin_mult [simp]:
  1380      "DERIV (%x. sin(x)*sin(x)) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1381 by (rule DERIV_mult, auto)
  1382 
  1383 lemma DERIV_sin_sin_mult2 [simp]:
  1384      "DERIV (%x. sin(x)*sin(x)) x :> 2 * cos(x) * sin(x)"
  1385 apply (cut_tac x = x in DERIV_sin_sin_mult)
  1386 apply (auto simp add: mult_assoc)
  1387 done
  1388 
  1389 lemma DERIV_sin_realpow2 [simp]:
  1390      "DERIV (%x. (sin x)\<twosuperior>) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1391 by (auto simp add: numeral_2_eq_2 real_mult_assoc [symmetric])
  1392 
  1393 lemma DERIV_sin_realpow2a [simp]:
  1394      "DERIV (%x. (sin x)\<twosuperior>) x :> 2 * cos(x) * sin(x)"
  1395 by (auto simp add: numeral_2_eq_2)
  1396 
  1397 lemma DERIV_cos_cos_mult [simp]:
  1398      "DERIV (%x. cos(x)*cos(x)) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1399 by (rule DERIV_mult, auto)
  1400 
  1401 lemma DERIV_cos_cos_mult2 [simp]:
  1402      "DERIV (%x. cos(x)*cos(x)) x :> -2 * cos(x) * sin(x)"
  1403 apply (cut_tac x = x in DERIV_cos_cos_mult)
  1404 apply (auto simp add: mult_ac)
  1405 done
  1406 
  1407 lemma DERIV_cos_realpow2 [simp]:
  1408      "DERIV (%x. (cos x)\<twosuperior>) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1409 by (auto simp add: numeral_2_eq_2 real_mult_assoc [symmetric])
  1410 
  1411 lemma DERIV_cos_realpow2a [simp]:
  1412      "DERIV (%x. (cos x)\<twosuperior>) x :> -2 * cos(x) * sin(x)"
  1413 by (auto simp add: numeral_2_eq_2)
  1414 
  1415 lemma lemma_DERIV_subst: "[| DERIV f x :> D; D = E |] ==> DERIV f x :> E"
  1416 by auto
  1417 
  1418 lemma DERIV_cos_realpow2b: "DERIV (%x. (cos x)\<twosuperior>) x :> -(2 * cos(x) * sin(x))"
  1419   by (auto intro!: DERIV_intros)
  1420 
  1421 (* most useful *)
  1422 lemma DERIV_cos_cos_mult3 [simp]:
  1423      "DERIV (%x. cos(x)*cos(x)) x :> -(2 * cos(x) * sin(x))"
  1424   by (auto intro!: DERIV_intros)
  1425 
  1426 lemma DERIV_sin_circle_all: 
  1427      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :>  
  1428              (2*cos(x)*sin(x) - 2*cos(x)*sin(x))"
  1429   by (auto intro!: DERIV_intros)
  1430 
  1431 lemma DERIV_sin_circle_all_zero [simp]:
  1432      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  1433 by (cut_tac DERIV_sin_circle_all, auto)
  1434 
  1435 lemma sin_cos_squared_add [simp]: "((sin x)\<twosuperior>) + ((cos x)\<twosuperior>) = 1"
  1436 apply (cut_tac x = x and y = 0 in DERIV_sin_circle_all_zero [THEN DERIV_isconst_all])
  1437 apply (auto simp add: numeral_2_eq_2)
  1438 done
  1439 
  1440 lemma sin_cos_squared_add2 [simp]: "((cos x)\<twosuperior>) + ((sin x)\<twosuperior>) = 1"
  1441 apply (subst add_commute)
  1442 apply (rule sin_cos_squared_add)
  1443 done
  1444 
  1445 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  1446 apply (cut_tac x = x in sin_cos_squared_add2)
  1447 apply (simp add: power2_eq_square)
  1448 done
  1449 
  1450 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  1451 apply (rule_tac a1 = "(cos x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1452 apply simp
  1453 done
  1454 
  1455 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  1456 apply (rule_tac a1 = "(sin x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1457 apply simp
  1458 done
  1459 
  1460 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  1461 by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  1462 
  1463 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  1464 apply (insert abs_sin_le_one [of x]) 
  1465 apply (simp add: abs_le_iff del: abs_sin_le_one) 
  1466 done
  1467 
  1468 lemma sin_le_one [simp]: "sin x \<le> 1"
  1469 apply (insert abs_sin_le_one [of x]) 
  1470 apply (simp add: abs_le_iff del: abs_sin_le_one) 
  1471 done
  1472 
  1473 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  1474 by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  1475 
  1476 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  1477 apply (insert abs_cos_le_one [of x]) 
  1478 apply (simp add: abs_le_iff del: abs_cos_le_one) 
  1479 done
  1480 
  1481 lemma cos_le_one [simp]: "cos x \<le> 1"
  1482 apply (insert abs_cos_le_one [of x]) 
  1483 apply (simp add: abs_le_iff del: abs_cos_le_one)
  1484 done
  1485 
  1486 lemma DERIV_fun_pow: "DERIV g x :> m ==>  
  1487       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  1488 unfolding One_nat_def
  1489 apply (rule lemma_DERIV_subst)
  1490 apply (rule_tac f = "(%x. x ^ n)" in DERIV_chain2)
  1491 apply (rule DERIV_pow, auto)
  1492 done
  1493 
  1494 lemma DERIV_fun_exp:
  1495      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  1496 apply (rule lemma_DERIV_subst)
  1497 apply (rule_tac f = exp in DERIV_chain2)
  1498 apply (rule DERIV_exp, auto)
  1499 done
  1500 
  1501 lemma DERIV_fun_sin:
  1502      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  1503 apply (rule lemma_DERIV_subst)
  1504 apply (rule_tac f = sin in DERIV_chain2)
  1505 apply (rule DERIV_sin, auto)
  1506 done
  1507 
  1508 lemma DERIV_fun_cos:
  1509      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  1510 apply (rule lemma_DERIV_subst)
  1511 apply (rule_tac f = cos in DERIV_chain2)
  1512 apply (rule DERIV_cos, auto)
  1513 done
  1514 
  1515 (* lemma *)
  1516 lemma lemma_DERIV_sin_cos_add:
  1517      "\<forall>x.  
  1518          DERIV (%x. (sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +  
  1519                (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2) x :> 0"
  1520   by (auto intro!: DERIV_intros simp add: algebra_simps)
  1521 
  1522 lemma sin_cos_add [simp]:
  1523      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +  
  1524       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  1525 apply (cut_tac y = 0 and x = x and y7 = y 
  1526        in lemma_DERIV_sin_cos_add [THEN DERIV_isconst_all])
  1527 apply (auto simp add: numeral_2_eq_2)
  1528 done
  1529 
  1530 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  1531 apply (cut_tac x = x and y = y in sin_cos_add)
  1532 apply (simp del: sin_cos_add)
  1533 done
  1534 
  1535 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  1536 apply (cut_tac x = x and y = y in sin_cos_add)
  1537 apply (simp del: sin_cos_add)
  1538 done
  1539 
  1540 lemma lemma_DERIV_sin_cos_minus:
  1541     "\<forall>x. DERIV (%x. (sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2) x :> 0"
  1542   by (auto intro!: DERIV_intros simp add: algebra_simps)
  1543 
  1544 
  1545 lemma sin_cos_minus: 
  1546     "(sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2 = 0"
  1547 apply (cut_tac y = 0 and x = x 
  1548        in lemma_DERIV_sin_cos_minus [THEN DERIV_isconst_all])
  1549 apply simp
  1550 done
  1551 
  1552 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  1553   using sin_cos_minus [where x=x] by simp
  1554 
  1555 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  1556   using sin_cos_minus [where x=x] by simp
  1557 
  1558 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  1559 by (simp add: diff_minus sin_add)
  1560 
  1561 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  1562 by (simp add: sin_diff mult_commute)
  1563 
  1564 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  1565 by (simp add: diff_minus cos_add)
  1566 
  1567 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  1568 by (simp add: cos_diff mult_commute)
  1569 
  1570 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  1571   using sin_add [where x=x and y=x] by simp
  1572 
  1573 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  1574   using cos_add [where x=x and y=x]
  1575   by (simp add: power2_eq_square)
  1576 
  1577 
  1578 subsection {* The Constant Pi *}
  1579 
  1580 definition
  1581   pi :: "real" where
  1582   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  1583 
  1584 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"}; 
  1585    hence define pi.*}
  1586 
  1587 lemma sin_paired:
  1588      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1)) 
  1589       sums  sin x"
  1590 proof -
  1591   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  1592     unfolding sin_def
  1593     by (rule sin_converges [THEN sums_summable, THEN sums_group], simp) 
  1594   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  1595 qed
  1596 
  1597 text {* FIXME: This is a long, ugly proof! *}
  1598 lemma sin_gt_zero: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1599 apply (subgoal_tac 
  1600        "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2.
  1601               -1 ^ k / real (fact (2 * k + 1)) * x ^ (2 * k + 1)) 
  1602      sums (\<Sum>n. -1 ^ n / real (fact (2 * n + 1)) * x ^ (2 * n + 1))")
  1603  prefer 2
  1604  apply (rule sin_paired [THEN sums_summable, THEN sums_group], simp) 
  1605 apply (rotate_tac 2)
  1606 apply (drule sin_paired [THEN sums_unique, THEN ssubst])
  1607 unfolding One_nat_def
  1608 apply (auto simp del: fact_Suc)
  1609 apply (frule sums_unique)
  1610 apply (auto simp del: fact_Suc)
  1611 apply (rule_tac n1 = 0 in series_pos_less [THEN [2] order_le_less_trans])
  1612 apply (auto simp del: fact_Suc)
  1613 apply (erule sums_summable)
  1614 apply (case_tac "m=0")
  1615 apply (simp (no_asm_simp))
  1616 apply (subgoal_tac "6 * (x * (x * x) / real (Suc (Suc (Suc (Suc (Suc (Suc 0))))))) < 6 * x") 
  1617 apply (simp only: mult_less_cancel_left, simp)  
  1618 apply (simp (no_asm_simp) add: numeral_2_eq_2 [symmetric] mult_assoc [symmetric])
  1619 apply (subgoal_tac "x*x < 2*3", simp) 
  1620 apply (rule mult_strict_mono)
  1621 apply (auto simp add: real_0_less_add_iff real_of_nat_Suc simp del: fact_Suc)
  1622 apply (subst fact_Suc)
  1623 apply (subst fact_Suc)
  1624 apply (subst fact_Suc)
  1625 apply (subst fact_Suc)
  1626 apply (subst real_of_nat_mult)
  1627 apply (subst real_of_nat_mult)
  1628 apply (subst real_of_nat_mult)
  1629 apply (subst real_of_nat_mult)
  1630 apply (simp (no_asm) add: divide_inverse del: fact_Suc)
  1631 apply (auto simp add: mult_assoc [symmetric] simp del: fact_Suc)
  1632 apply (rule_tac c="real (Suc (Suc (4*m)))" in mult_less_imp_less_right) 
  1633 apply (auto simp add: mult_assoc simp del: fact_Suc)
  1634 apply (rule_tac c="real (Suc (Suc (Suc (4*m))))" in mult_less_imp_less_right) 
  1635 apply (auto simp add: mult_assoc mult_less_cancel_left simp del: fact_Suc)
  1636 apply (subgoal_tac "x * (x * x ^ (4*m)) = (x ^ (4*m)) * (x * x)") 
  1637 apply (erule ssubst)+
  1638 apply (auto simp del: fact_Suc)
  1639 apply (subgoal_tac "0 < x ^ (4 * m) ")
  1640  prefer 2 apply (simp only: zero_less_power) 
  1641 apply (simp (no_asm_simp) add: mult_less_cancel_left)
  1642 apply (rule mult_strict_mono)
  1643 apply (simp_all (no_asm_simp))
  1644 done
  1645 
  1646 lemma sin_gt_zero1: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1647 by (auto intro: sin_gt_zero)
  1648 
  1649 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  1650 apply (cut_tac x = x in sin_gt_zero1)
  1651 apply (auto simp add: cos_squared_eq cos_double)
  1652 done
  1653 
  1654 lemma cos_paired:
  1655      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  1656 proof -
  1657   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  1658     unfolding cos_def
  1659     by (rule cos_converges [THEN sums_summable, THEN sums_group], simp) 
  1660   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  1661 qed
  1662 
  1663 lemma fact_lemma: "real (n::nat) * 4 = real (4 * n)"
  1664 by simp
  1665 
  1666 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  1667 apply (cut_tac x = 2 in cos_paired)
  1668 apply (drule sums_minus)
  1669 apply (rule neg_less_iff_less [THEN iffD1]) 
  1670 apply (frule sums_unique, auto)
  1671 apply (rule_tac y =
  1672  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  1673        in order_less_trans)
  1674 apply (simp (no_asm) add: fact_num_eq_if_nat realpow_num_eq_if del: fact_Suc)
  1675 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  1676 apply (rule sumr_pos_lt_pair)
  1677 apply (erule sums_summable, safe)
  1678 unfolding One_nat_def
  1679 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric] 
  1680             del: fact_Suc)
  1681 apply (rule real_mult_inverse_cancel2)
  1682 apply (rule real_of_nat_fact_gt_zero)+
  1683 apply (simp (no_asm) add: mult_assoc [symmetric] del: fact_Suc)
  1684 apply (subst fact_lemma) 
  1685 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  1686 apply (simp only: real_of_nat_mult)
  1687 apply (rule mult_strict_mono, force)
  1688   apply (rule_tac [3] real_of_nat_ge_zero)
  1689  prefer 2 apply force
  1690 apply (rule real_of_nat_less_iff [THEN iffD2])
  1691 apply (rule fact_less_mono_nat, auto)
  1692 done
  1693 
  1694 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  1695 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  1696 
  1697 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1698 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0")
  1699 apply (rule_tac [2] IVT2)
  1700 apply (auto intro: DERIV_isCont DERIV_cos)
  1701 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1702 apply (rule ccontr)
  1703 apply (subgoal_tac " (\<forall>x. cos differentiable x) & (\<forall>x. isCont cos x) ")
  1704 apply (auto intro: DERIV_cos DERIV_isCont simp add: differentiable_def)
  1705 apply (drule_tac f = cos in Rolle)
  1706 apply (drule_tac [5] f = cos in Rolle)
  1707 apply (auto dest!: DERIV_cos [THEN DERIV_unique] simp add: differentiable_def)
  1708 apply (metis order_less_le_trans real_less_def sin_gt_zero)
  1709 apply (metis order_less_le_trans real_less_def sin_gt_zero)
  1710 done
  1711 
  1712 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  1713 by (simp add: pi_def)
  1714 
  1715 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  1716 by (simp add: pi_half cos_is_zero [THEN theI'])
  1717 
  1718 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  1719 apply (rule order_le_neq_trans)
  1720 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1721 apply (rule notI, drule arg_cong [where f=cos], simp)
  1722 done
  1723 
  1724 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  1725 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  1726 
  1727 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  1728 apply (rule order_le_neq_trans)
  1729 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1730 apply (rule notI, drule arg_cong [where f=cos], simp)
  1731 done
  1732 
  1733 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  1734 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  1735 
  1736 lemma pi_gt_zero [simp]: "0 < pi"
  1737 by (insert pi_half_gt_zero, simp)
  1738 
  1739 lemma pi_ge_zero [simp]: "0 \<le> pi"
  1740 by (rule pi_gt_zero [THEN order_less_imp_le])
  1741 
  1742 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  1743 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  1744 
  1745 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  1746 by (simp add: linorder_not_less)
  1747 
  1748 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  1749 by simp
  1750 
  1751 lemma m2pi_less_pi: "- (2 * pi) < pi"
  1752 proof -
  1753   have "- (2 * pi) < 0" and "0 < pi" by auto
  1754   from order_less_trans[OF this] show ?thesis .
  1755 qed
  1756 
  1757 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  1758 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  1759 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  1760 apply (simp add: power2_eq_square)
  1761 done
  1762 
  1763 lemma cos_pi [simp]: "cos pi = -1"
  1764 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  1765 
  1766 lemma sin_pi [simp]: "sin pi = 0"
  1767 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  1768 
  1769 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  1770 by (simp add: diff_minus cos_add)
  1771 declare sin_cos_eq [symmetric, simp]
  1772 
  1773 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  1774 by (simp add: cos_add)
  1775 declare minus_sin_cos_eq [symmetric, simp]
  1776 
  1777 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  1778 by (simp add: diff_minus sin_add)
  1779 declare cos_sin_eq [symmetric, simp]
  1780 
  1781 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  1782 by (simp add: sin_add)
  1783 
  1784 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  1785 by (simp add: sin_add)
  1786 
  1787 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  1788 by (simp add: cos_add)
  1789 
  1790 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  1791 by (simp add: sin_add cos_double)
  1792 
  1793 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  1794 by (simp add: cos_add cos_double)
  1795 
  1796 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  1797 apply (induct "n")
  1798 apply (auto simp add: real_of_nat_Suc left_distrib)
  1799 done
  1800 
  1801 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  1802 proof -
  1803   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  1804   also have "... = -1 ^ n" by (rule cos_npi) 
  1805   finally show ?thesis .
  1806 qed
  1807 
  1808 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  1809 apply (induct "n")
  1810 apply (auto simp add: real_of_nat_Suc left_distrib)
  1811 done
  1812 
  1813 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  1814 by (simp add: mult_commute [of pi]) 
  1815 
  1816 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  1817 by (simp add: cos_double)
  1818 
  1819 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  1820 by simp
  1821 
  1822 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  1823 apply (rule sin_gt_zero, assumption)
  1824 apply (rule order_less_trans, assumption)
  1825 apply (rule pi_half_less_two)
  1826 done
  1827 
  1828 lemma sin_less_zero: 
  1829   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  1830 proof -
  1831   have "0 < sin (- x)" using prems by (simp only: sin_gt_zero2) 
  1832   thus ?thesis by simp
  1833 qed
  1834 
  1835 lemma pi_less_4: "pi < 4"
  1836 by (cut_tac pi_half_less_two, auto)
  1837 
  1838 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  1839 apply (cut_tac pi_less_4)
  1840 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  1841 apply (cut_tac cos_is_zero, safe)
  1842 apply (rename_tac y z)
  1843 apply (drule_tac x = y in spec)
  1844 apply (drule_tac x = "pi/2" in spec, simp) 
  1845 done
  1846 
  1847 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  1848 apply (rule_tac x = x and y = 0 in linorder_cases)
  1849 apply (rule cos_minus [THEN subst])
  1850 apply (rule cos_gt_zero)
  1851 apply (auto intro: cos_gt_zero)
  1852 done
  1853  
  1854 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  1855 apply (auto simp add: order_le_less cos_gt_zero_pi)
  1856 apply (subgoal_tac "x = pi/2", auto) 
  1857 done
  1858 
  1859 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  1860 apply (subst sin_cos_eq)
  1861 apply (rotate_tac 1)
  1862 apply (drule real_sum_of_halves [THEN ssubst])
  1863 apply (auto intro!: cos_gt_zero_pi simp del: sin_cos_eq [symmetric])
  1864 done
  1865 
  1866 
  1867 lemma pi_ge_two: "2 \<le> pi"
  1868 proof (rule ccontr)
  1869   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  1870   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  1871   proof (cases "2 < 2 * pi")
  1872     case True with dense[OF `pi < 2`] show ?thesis by auto
  1873   next
  1874     case False have "pi < 2 * pi" by auto
  1875     from dense[OF this] and False show ?thesis by auto
  1876   qed
  1877   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  1878   hence "0 < sin y" using sin_gt_zero by auto
  1879   moreover 
  1880   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  1881   ultimately show False by auto
  1882 qed
  1883 
  1884 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  1885 by (auto simp add: order_le_less sin_gt_zero_pi)
  1886 
  1887 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  1888 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y")
  1889 apply (rule_tac [2] IVT2)
  1890 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos)
  1891 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1892 apply (rule ccontr, auto)
  1893 apply (drule_tac f = cos in Rolle)
  1894 apply (drule_tac [5] f = cos in Rolle)
  1895 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos
  1896             dest!: DERIV_cos [THEN DERIV_unique] 
  1897             simp add: differentiable_def)
  1898 apply (auto dest: sin_gt_zero_pi [OF order_le_less_trans order_less_le_trans])
  1899 done
  1900 
  1901 lemma sin_total:
  1902      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  1903 apply (rule ccontr)
  1904 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  1905 apply (erule contrapos_np)
  1906 apply (simp del: minus_sin_cos_eq [symmetric])
  1907 apply (cut_tac y="-y" in cos_total, simp) apply simp 
  1908 apply (erule ex1E)
  1909 apply (rule_tac a = "x - (pi/2)" in ex1I)
  1910 apply (simp (no_asm) add: add_assoc)
  1911 apply (rotate_tac 3)
  1912 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all) 
  1913 done
  1914 
  1915 lemma reals_Archimedean4:
  1916      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  1917 apply (auto dest!: reals_Archimedean3)
  1918 apply (drule_tac x = x in spec, clarify) 
  1919 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  1920  prefer 2 apply (erule LeastI) 
  1921 apply (case_tac "LEAST m::nat. x < real m * y", simp) 
  1922 apply (subgoal_tac "~ x < real nat * y")
  1923  prefer 2 apply (rule not_less_Least, simp, force)  
  1924 done
  1925 
  1926 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic 
  1927    now causes some unwanted re-arrangements of literals!   *)
  1928 lemma cos_zero_lemma:
  1929      "[| 0 \<le> x; cos x = 0 |] ==>  
  1930       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  1931 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  1932 apply (subgoal_tac "0 \<le> x - real n * pi & 
  1933                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  1934 apply (auto simp add: algebra_simps real_of_nat_Suc)
  1935  prefer 2 apply (simp add: cos_diff)
  1936 apply (simp add: cos_diff)
  1937 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  1938 apply (rule_tac [2] cos_total, safe)
  1939 apply (drule_tac x = "x - real n * pi" in spec)
  1940 apply (drule_tac x = "pi/2" in spec)
  1941 apply (simp add: cos_diff)
  1942 apply (rule_tac x = "Suc (2 * n)" in exI)
  1943 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  1944 done
  1945 
  1946 lemma sin_zero_lemma:
  1947      "[| 0 \<le> x; sin x = 0 |] ==>  
  1948       \<exists>n::nat. even n & x = real n * (pi/2)"
  1949 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  1950  apply (clarify, rule_tac x = "n - 1" in exI)
  1951  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1952 apply (rule cos_zero_lemma)
  1953 apply (simp_all add: add_increasing)  
  1954 done
  1955 
  1956 
  1957 lemma cos_zero_iff:
  1958      "(cos x = 0) =  
  1959       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |    
  1960        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  1961 apply (rule iffI)
  1962 apply (cut_tac linorder_linear [of 0 x], safe)
  1963 apply (drule cos_zero_lemma, assumption+)
  1964 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp) 
  1965 apply (force simp add: minus_equation_iff [of x]) 
  1966 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib) 
  1967 apply (auto simp add: cos_add)
  1968 done
  1969 
  1970 (* ditto: but to a lesser extent *)
  1971 lemma sin_zero_iff:
  1972      "(sin x = 0) =  
  1973       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |    
  1974        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  1975 apply (rule iffI)
  1976 apply (cut_tac linorder_linear [of 0 x], safe)
  1977 apply (drule sin_zero_lemma, assumption+)
  1978 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  1979 apply (force simp add: minus_equation_iff [of x]) 
  1980 apply (auto simp add: even_mult_two_ex)
  1981 done
  1982 
  1983 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  1984   shows "cos x < cos y"
  1985 proof -
  1986   have "- (x - y) < 0" using assms by auto
  1987 
  1988   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  1989   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  1990   hence "0 < z" and "z < pi" using assms by auto
  1991   hence "0 < sin z" using sin_gt_zero_pi by auto
  1992   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  1993   thus ?thesis by auto
  1994 qed
  1995 
  1996 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  1997 proof (cases "y < x")
  1998   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  1999 next
  2000   case False hence "y = x" using `y \<le> x` by auto
  2001   thus ?thesis by auto
  2002 qed
  2003 
  2004 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  2005   shows "cos y < cos x"
  2006 proof -
  2007   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" using assms by auto
  2008   from cos_monotone_0_pi[OF this]
  2009   show ?thesis unfolding cos_minus .
  2010 qed
  2011 
  2012 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  2013 proof (cases "y < x")
  2014   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  2015 next
  2016   case False hence "y = x" using `y \<le> x` by auto
  2017   thus ?thesis by auto
  2018 qed
  2019 
  2020 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  2021 proof -
  2022   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi"
  2023     using pi_ge_two and assms by auto
  2024   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  2025 qed
  2026 
  2027 subsection {* Tangent *}
  2028 
  2029 definition
  2030   tan :: "real => real" where
  2031   "tan x = (sin x)/(cos x)"
  2032 
  2033 lemma tan_zero [simp]: "tan 0 = 0"
  2034 by (simp add: tan_def)
  2035 
  2036 lemma tan_pi [simp]: "tan pi = 0"
  2037 by (simp add: tan_def)
  2038 
  2039 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  2040 by (simp add: tan_def)
  2041 
  2042 lemma tan_minus [simp]: "tan (-x) = - tan x"
  2043 by (simp add: tan_def minus_mult_left)
  2044 
  2045 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  2046 by (simp add: tan_def)
  2047 
  2048 lemma lemma_tan_add1: 
  2049       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]  
  2050         ==> 1 - tan(x)*tan(y) = cos (x + y)/(cos x * cos y)"
  2051 apply (simp add: tan_def divide_inverse)
  2052 apply (auto simp del: inverse_mult_distrib 
  2053             simp add: inverse_mult_distrib [symmetric] mult_ac)
  2054 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2055 apply (auto simp del: inverse_mult_distrib 
  2056             simp add: mult_assoc left_diff_distrib cos_add)
  2057 done
  2058 
  2059 lemma add_tan_eq: 
  2060       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]  
  2061        ==> tan x + tan y = sin(x + y)/(cos x * cos y)"
  2062 apply (simp add: tan_def)
  2063 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2064 apply (auto simp add: mult_assoc left_distrib)
  2065 apply (simp add: sin_add)
  2066 done
  2067 
  2068 lemma tan_add:
  2069      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]  
  2070       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  2071 apply (simp (no_asm_simp) add: add_tan_eq lemma_tan_add1)
  2072 apply (simp add: tan_def)
  2073 done
  2074 
  2075 lemma tan_double:
  2076      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]  
  2077       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  2078 apply (insert tan_add [of x x]) 
  2079 apply (simp add: mult_2 [symmetric])  
  2080 apply (auto simp add: numeral_2_eq_2)
  2081 done
  2082 
  2083 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  2084 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi) 
  2085 
  2086 lemma tan_less_zero: 
  2087   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  2088 proof -
  2089   have "0 < tan (- x)" using prems by (simp only: tan_gt_zero) 
  2090   thus ?thesis by simp
  2091 qed
  2092 
  2093 lemma tan_half: fixes x :: real assumes "- (pi / 2) < x" and "x < pi / 2"
  2094   shows "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  2095 proof -
  2096   from cos_gt_zero_pi[OF `- (pi / 2) < x` `x < pi / 2`]
  2097   have "cos x \<noteq> 0" by auto
  2098 
  2099   have minus_cos_2x: "\<And>X. X - cos (2*x) = X - (cos x) ^ 2 + (sin x) ^ 2" unfolding cos_double by algebra
  2100 
  2101   have "tan x = (tan x + tan x) / 2" by auto
  2102   also have "\<dots> = sin (x + x) / (cos x * cos x) / 2" unfolding add_tan_eq[OF `cos x \<noteq> 0` `cos x \<noteq> 0`] ..
  2103   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + (cos x) ^ 2 + cos (2*x) - cos (2*x))" unfolding divide_divide_eq_left numeral_2_eq_2 by auto
  2104   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + cos (2*x) + (sin x)^2)" unfolding minus_cos_2x by auto
  2105   also have "\<dots> = sin (2 * x) / (cos (2*x) + 1)" by auto
  2106   finally show ?thesis .
  2107 qed
  2108 
  2109 lemma lemma_DERIV_tan:
  2110      "cos x \<noteq> 0 ==> DERIV (%x. sin(x)/cos(x)) x :> inverse((cos x)\<twosuperior>)"
  2111   by (auto intro!: DERIV_intros simp add: field_simps numeral_2_eq_2)
  2112 
  2113 lemma DERIV_tan [simp]: "cos x \<noteq> 0 ==> DERIV tan x :> inverse((cos x)\<twosuperior>)"
  2114 by (auto dest: lemma_DERIV_tan simp add: tan_def [symmetric])
  2115 
  2116 lemma isCont_tan [simp]: "cos x \<noteq> 0 ==> isCont tan x"
  2117 by (rule DERIV_tan [THEN DERIV_isCont])
  2118 
  2119 lemma LIM_cos_div_sin [simp]: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  2120 apply (subgoal_tac "(\<lambda>x. cos x * inverse (sin x)) -- pi * inverse 2 --> 0*1")
  2121 apply (simp add: divide_inverse [symmetric])
  2122 apply (rule LIM_mult)
  2123 apply (rule_tac [2] inverse_1 [THEN subst])
  2124 apply (rule_tac [2] LIM_inverse)
  2125 apply (simp_all add: divide_inverse [symmetric]) 
  2126 apply (simp_all only: isCont_def [symmetric] cos_pi_half [symmetric] sin_pi_half [symmetric]) 
  2127 apply (blast intro!: DERIV_isCont DERIV_sin DERIV_cos)+
  2128 done
  2129 
  2130 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  2131 apply (cut_tac LIM_cos_div_sin)
  2132 apply (simp only: LIM_eq)
  2133 apply (drule_tac x = "inverse y" in spec, safe, force)
  2134 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  2135 apply (rule_tac x = "(pi/2) - e" in exI)
  2136 apply (simp (no_asm_simp))
  2137 apply (drule_tac x = "(pi/2) - e" in spec)
  2138 apply (auto simp add: tan_def)
  2139 apply (rule inverse_less_iff_less [THEN iffD1])
  2140 apply (auto simp add: divide_inverse)
  2141 apply (rule real_mult_order) 
  2142 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  2143 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute) 
  2144 done
  2145 
  2146 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  2147 apply (frule order_le_imp_less_or_eq, safe)
  2148  prefer 2 apply force
  2149 apply (drule lemma_tan_total, safe)
  2150 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  2151 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  2152 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  2153 apply (auto dest: cos_gt_zero)
  2154 done
  2155 
  2156 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2157 apply (cut_tac linorder_linear [of 0 y], safe)
  2158 apply (drule tan_total_pos)
  2159 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  2160 apply (rule_tac [3] x = "-x" in exI)
  2161 apply (auto intro!: exI)
  2162 done
  2163 
  2164 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2165 apply (cut_tac y = y in lemma_tan_total1, auto)
  2166 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  2167 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  2168 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  2169 apply (rule_tac [4] Rolle)
  2170 apply (rule_tac [2] Rolle)
  2171 apply (auto intro!: DERIV_tan DERIV_isCont exI 
  2172             simp add: differentiable_def)
  2173 txt{*Now, simulate TRYALL*}
  2174 apply (rule_tac [!] DERIV_tan asm_rl)
  2175 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  2176             simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym]) 
  2177 done
  2178 
  2179 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  2180   shows "tan y < tan x"
  2181 proof -
  2182   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  2183   proof (rule allI, rule impI)
  2184     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  2185     hence "-(pi/2) < x'" and "x' < pi/2" using assms by auto
  2186     from cos_gt_zero_pi[OF this]
  2187     have "cos x' \<noteq> 0" by auto
  2188     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  2189   qed
  2190   from MVT2[OF `y < x` this] 
  2191   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  2192   hence "- (pi / 2) < z" and "z < pi / 2" using assms by auto
  2193   hence "0 < cos z" using cos_gt_zero_pi by auto
  2194   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  2195   have "0 < x - y" using `y < x` by auto
  2196   from real_mult_order[OF this inv_pos]
  2197   have "0 < tan x - tan y" unfolding tan_diff by auto
  2198   thus ?thesis by auto
  2199 qed
  2200 
  2201 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2202   shows "(y < x) = (tan y < tan x)"
  2203 proof
  2204   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2205 next
  2206   assume "tan y < tan x"
  2207   show "y < x"
  2208   proof (rule ccontr)
  2209     assume "\<not> y < x" hence "x \<le> y" by auto
  2210     hence "tan x \<le> tan y" 
  2211     proof (cases "x = y")
  2212       case True thus ?thesis by auto
  2213     next
  2214       case False hence "x < y" using `x \<le> y` by auto
  2215       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2216     qed
  2217     thus False using `tan y < tan x` by auto
  2218   qed
  2219 qed
  2220 
  2221 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2222 
  2223 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x" 
  2224   by (simp add: tan_def)
  2225 
  2226 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x" 
  2227 proof (induct n arbitrary: x)
  2228   case (Suc n)
  2229   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one real_add_mult_distrib by auto
  2230   show ?case unfolding split_pi_off using Suc by auto
  2231 qed auto
  2232 
  2233 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2234 proof (cases "0 \<le> i")
  2235   case True hence i_nat: "real i = real (nat i)" by auto
  2236   show ?thesis unfolding i_nat by auto
  2237 next
  2238   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2239   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2240   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2241   finally show ?thesis by auto
  2242 qed
  2243 
  2244 lemma tan_periodic_n[simp]: "tan (x + number_of n * pi) = tan x"
  2245   using tan_periodic_int[of _ "number_of n" ] unfolding real_number_of .
  2246 
  2247 subsection {* Inverse Trigonometric Functions *}
  2248 
  2249 definition
  2250   arcsin :: "real => real" where
  2251   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2252 
  2253 definition
  2254   arccos :: "real => real" where
  2255   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2256 
  2257 definition     
  2258   arctan :: "real => real" where
  2259   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2260 
  2261 lemma arcsin:
  2262      "[| -1 \<le> y; y \<le> 1 |]  
  2263       ==> -(pi/2) \<le> arcsin y &  
  2264            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2265 unfolding arcsin_def by (rule theI' [OF sin_total])
  2266 
  2267 lemma arcsin_pi:
  2268      "[| -1 \<le> y; y \<le> 1 |]  
  2269       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2270 apply (drule (1) arcsin)
  2271 apply (force intro: order_trans)
  2272 done
  2273 
  2274 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2275 by (blast dest: arcsin)
  2276       
  2277 lemma arcsin_bounded:
  2278      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2279 by (blast dest: arcsin)
  2280 
  2281 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2282 by (blast dest: arcsin)
  2283 
  2284 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2285 by (blast dest: arcsin)
  2286 
  2287 lemma arcsin_lt_bounded:
  2288      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2289 apply (frule order_less_imp_le)
  2290 apply (frule_tac y = y in order_less_imp_le)
  2291 apply (frule arcsin_bounded)
  2292 apply (safe, simp)
  2293 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2294 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2295 apply (drule_tac [!] f = sin in arg_cong, auto)
  2296 done
  2297 
  2298 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2299 apply (unfold arcsin_def)
  2300 apply (rule the1_equality)
  2301 apply (rule sin_total, auto)
  2302 done
  2303 
  2304 lemma arccos:
  2305      "[| -1 \<le> y; y \<le> 1 |]  
  2306       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2307 unfolding arccos_def by (rule theI' [OF cos_total])
  2308 
  2309 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2310 by (blast dest: arccos)
  2311       
  2312 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2313 by (blast dest: arccos)
  2314 
  2315 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2316 by (blast dest: arccos)
  2317 
  2318 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2319 by (blast dest: arccos)
  2320 
  2321 lemma arccos_lt_bounded:
  2322      "[| -1 < y; y < 1 |]  
  2323       ==> 0 < arccos y & arccos y < pi"
  2324 apply (frule order_less_imp_le)
  2325 apply (frule_tac y = y in order_less_imp_le)
  2326 apply (frule arccos_bounded, auto)
  2327 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2328 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2329 apply (drule_tac [!] f = cos in arg_cong, auto)
  2330 done
  2331 
  2332 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2333 apply (simp add: arccos_def)
  2334 apply (auto intro!: the1_equality cos_total)
  2335 done
  2336 
  2337 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2338 apply (simp add: arccos_def)
  2339 apply (auto intro!: the1_equality cos_total)
  2340 done
  2341 
  2342 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2343 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2344 apply (rule power2_eq_imp_eq)
  2345 apply (simp add: cos_squared_eq)
  2346 apply (rule cos_ge_zero)
  2347 apply (erule (1) arcsin_lbound)
  2348 apply (erule (1) arcsin_ubound)
  2349 apply simp
  2350 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2351 apply (rule power_mono, simp, simp)
  2352 done
  2353 
  2354 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2355 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2356 apply (rule power2_eq_imp_eq)
  2357 apply (simp add: sin_squared_eq)
  2358 apply (rule sin_ge_zero)
  2359 apply (erule (1) arccos_lbound)
  2360 apply (erule (1) arccos_ubound)
  2361 apply simp
  2362 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2363 apply (rule power_mono, simp, simp)
  2364 done
  2365 
  2366 lemma arctan [simp]:
  2367      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  2368 unfolding arctan_def by (rule theI' [OF tan_total])
  2369 
  2370 lemma tan_arctan: "tan(arctan y) = y"
  2371 by auto
  2372 
  2373 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  2374 by (auto simp only: arctan)
  2375 
  2376 lemma arctan_lbound: "- (pi/2) < arctan y"
  2377 by auto
  2378 
  2379 lemma arctan_ubound: "arctan y < pi/2"
  2380 by (auto simp only: arctan)
  2381 
  2382 lemma arctan_tan: 
  2383       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  2384 apply (unfold arctan_def)
  2385 apply (rule the1_equality)
  2386 apply (rule tan_total, auto)
  2387 done
  2388 
  2389 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  2390 by (insert arctan_tan [of 0], simp)
  2391 
  2392 lemma cos_arctan_not_zero [simp]: "cos(arctan x) \<noteq> 0"
  2393 apply (auto simp add: cos_zero_iff)
  2394 apply (case_tac "n")
  2395 apply (case_tac [3] "n")
  2396 apply (cut_tac [2] y = x in arctan_ubound)
  2397 apply (cut_tac [4] y = x in arctan_lbound) 
  2398 apply (auto simp add: real_of_nat_Suc left_distrib mult_less_0_iff)
  2399 done
  2400 
  2401 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  2402 apply (rule power_inverse [THEN subst])
  2403 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  2404 apply (auto dest: field_power_not_zero
  2405         simp add: power_mult_distrib left_distrib power_divide tan_def 
  2406                   mult_assoc power_inverse [symmetric])
  2407 done
  2408 
  2409 lemma isCont_inverse_function2:
  2410   fixes f g :: "real \<Rightarrow> real" shows
  2411   "\<lbrakk>a < x; x < b;
  2412     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2413     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2414    \<Longrightarrow> isCont g (f x)"
  2415 apply (rule isCont_inverse_function
  2416        [where f=f and d="min (x - a) (b - x)"])
  2417 apply (simp_all add: abs_le_iff)
  2418 done
  2419 
  2420 lemma isCont_arcsin: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arcsin x"
  2421 apply (subgoal_tac "isCont arcsin (sin (arcsin x))", simp)
  2422 apply (rule isCont_inverse_function2 [where f=sin])
  2423 apply (erule (1) arcsin_lt_bounded [THEN conjunct1])
  2424 apply (erule (1) arcsin_lt_bounded [THEN conjunct2])
  2425 apply (fast intro: arcsin_sin, simp)
  2426 done
  2427 
  2428 lemma isCont_arccos: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arccos x"
  2429 apply (subgoal_tac "isCont arccos (cos (arccos x))", simp)
  2430 apply (rule isCont_inverse_function2 [where f=cos])
  2431 apply (erule (1) arccos_lt_bounded [THEN conjunct1])
  2432 apply (erule (1) arccos_lt_bounded [THEN conjunct2])
  2433 apply (fast intro: arccos_cos, simp)
  2434 done
  2435 
  2436 lemma isCont_arctan: "isCont arctan x"
  2437 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  2438 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  2439 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  2440 apply (erule (1) isCont_inverse_function2 [where f=tan])
  2441 apply (metis arctan_tan order_le_less_trans order_less_le_trans)
  2442 apply (metis cos_gt_zero_pi isCont_tan order_less_le_trans real_less_def)
  2443 done
  2444 
  2445 lemma DERIV_arcsin:
  2446   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  2447 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  2448 apply (rule lemma_DERIV_subst [OF DERIV_sin])
  2449 apply (simp add: cos_arcsin)
  2450 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2451 apply (rule power_strict_mono, simp, simp, simp)
  2452 apply assumption
  2453 apply assumption
  2454 apply simp
  2455 apply (erule (1) isCont_arcsin)
  2456 done
  2457 
  2458 lemma DERIV_arccos:
  2459   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  2460 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  2461 apply (rule lemma_DERIV_subst [OF DERIV_cos])
  2462 apply (simp add: sin_arccos)
  2463 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2464 apply (rule power_strict_mono, simp, simp, simp)
  2465 apply assumption
  2466 apply assumption
  2467 apply simp
  2468 apply (erule (1) isCont_arccos)
  2469 done
  2470 
  2471 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  2472 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  2473 apply (rule lemma_DERIV_subst [OF DERIV_tan])
  2474 apply (rule cos_arctan_not_zero)
  2475 apply (simp add: power_inverse tan_sec [symmetric])
  2476 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  2477 apply (simp add: add_pos_nonneg)
  2478 apply (simp, simp, simp, rule isCont_arctan)
  2479 done
  2480 
  2481 declare
  2482   DERIV_arcsin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2483   DERIV_arccos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2484   DERIV_arctan[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2485 
  2486 subsection {* More Theorems about Sin and Cos *}
  2487 
  2488 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  2489 proof -
  2490   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  2491   have nonneg: "0 \<le> ?c"
  2492     by (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2493   have "0 = cos (pi / 4 + pi / 4)"
  2494     by simp
  2495   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  2496     by (simp only: cos_add power2_eq_square)
  2497   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  2498     by (simp add: sin_squared_eq)
  2499   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  2500     by (simp add: power_divide)
  2501   thus ?thesis
  2502     using nonneg by (rule power2_eq_imp_eq) simp
  2503 qed
  2504 
  2505 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  2506 proof -
  2507   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  2508   have pos_c: "0 < ?c"
  2509     by (rule cos_gt_zero, simp, simp)
  2510   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  2511     by simp
  2512   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  2513     by (simp only: cos_add sin_add)
  2514   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  2515     by (simp add: algebra_simps power2_eq_square)
  2516   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  2517     using pos_c by (simp add: sin_squared_eq power_divide)
  2518   thus ?thesis
  2519     using pos_c [THEN order_less_imp_le]
  2520     by (rule power2_eq_imp_eq) simp
  2521 qed
  2522 
  2523 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  2524 proof -
  2525   have "sin (pi / 4) = cos (pi / 2 - pi / 4)" by (rule sin_cos_eq)
  2526   also have "pi / 2 - pi / 4 = pi / 4" by simp
  2527   also have "cos (pi / 4) = sqrt 2 / 2" by (rule cos_45)
  2528   finally show ?thesis .
  2529 qed
  2530 
  2531 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  2532 proof -
  2533   have "sin (pi / 3) = cos (pi / 2 - pi / 3)" by (rule sin_cos_eq)
  2534   also have "pi / 2 - pi / 3 = pi / 6" by simp
  2535   also have "cos (pi / 6) = sqrt 3 / 2" by (rule cos_30)
  2536   finally show ?thesis .
  2537 qed
  2538 
  2539 lemma cos_60: "cos (pi / 3) = 1 / 2"
  2540 apply (rule power2_eq_imp_eq)
  2541 apply (simp add: cos_squared_eq sin_60 power_divide)
  2542 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2543 done
  2544 
  2545 lemma sin_30: "sin (pi / 6) = 1 / 2"
  2546 proof -
  2547   have "sin (pi / 6) = cos (pi / 2 - pi / 6)" by (rule sin_cos_eq)
  2548   also have "pi / 2 - pi / 6 = pi / 3" by simp
  2549   also have "cos (pi / 3) = 1 / 2" by (rule cos_60)
  2550   finally show ?thesis .
  2551 qed
  2552 
  2553 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  2554 unfolding tan_def by (simp add: sin_30 cos_30)
  2555 
  2556 lemma tan_45: "tan (pi / 4) = 1"
  2557 unfolding tan_def by (simp add: sin_45 cos_45)
  2558 
  2559 lemma tan_60: "tan (pi / 3) = sqrt 3"
  2560 unfolding tan_def by (simp add: sin_60 cos_60)
  2561 
  2562 text{*NEEDED??*}
  2563 lemma [simp]:
  2564      "sin (x + 1 / 2 * real (Suc m) * pi) =  
  2565       cos (x + 1 / 2 * real  (m) * pi)"
  2566 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib, auto)
  2567 
  2568 text{*NEEDED??*}
  2569 lemma [simp]:
  2570      "sin (x + real (Suc m) * pi / 2) =  
  2571       cos (x + real (m) * pi / 2)"
  2572 by (simp only: cos_add sin_add real_of_nat_Suc add_divide_distrib left_distrib, auto)
  2573 
  2574 lemma DERIV_sin_add [simp]: "DERIV (%x. sin (x + k)) xa :> cos (xa + k)"
  2575   by (auto intro!: DERIV_intros)
  2576 
  2577 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  2578 proof -
  2579   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  2580     by (auto simp add: algebra_simps sin_add)
  2581   thus ?thesis
  2582     by (simp add: real_of_nat_Suc left_distrib add_divide_distrib 
  2583                   mult_commute [of pi])
  2584 qed
  2585 
  2586 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  2587 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  2588 
  2589 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  2590 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  2591 apply (subst cos_add, simp)
  2592 done
  2593 
  2594 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  2595 by (auto simp add: mult_assoc)
  2596 
  2597 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  2598 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  2599 apply (subst sin_add, simp)
  2600 done
  2601 
  2602 (*NEEDED??*)
  2603 lemma [simp]:
  2604      "cos(x + 1 / 2 * real(Suc m) * pi) = -sin (x + 1 / 2 * real m * pi)"
  2605 apply (simp only: cos_add sin_add real_of_nat_Suc right_distrib left_distrib minus_mult_right, auto)
  2606 done
  2607 
  2608 (*NEEDED??*)
  2609 lemma [simp]: "cos (x + real(Suc m) * pi / 2) = -sin (x + real m * pi / 2)"
  2610 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib add_divide_distrib, auto)
  2611 
  2612 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  2613 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib add_divide_distrib, auto)
  2614 
  2615 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  2616   by (auto intro!: DERIV_intros)
  2617 
  2618 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  2619 by (auto simp add: sin_zero_iff even_mult_two_ex)
  2620 
  2621 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  2622 by (cut_tac x = x in sin_cos_squared_add3, auto)
  2623 
  2624 subsection {* Machins formula *}
  2625 
  2626 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  2627   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  2628 proof -
  2629   obtain z where "- (pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  2630   have "tan (pi / 4) = 1" and "tan (- (pi / 4)) = - 1" using tan_45 tan_minus by auto
  2631   have "z \<noteq> pi / 4" 
  2632   proof (rule ccontr)
  2633     assume "\<not> (z \<noteq> pi / 4)" hence "z = pi / 4" by auto
  2634     have "tan z = 1" unfolding `z = pi / 4` `tan (pi / 4) = 1` ..
  2635     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2636   qed
  2637   have "z \<noteq> - (pi / 4)"
  2638   proof (rule ccontr)
  2639     assume "\<not> (z \<noteq> - (pi / 4))" hence "z = - (pi / 4)" by auto
  2640     have "tan z = - 1" unfolding `z = - (pi / 4)` `tan (- (pi / 4)) = - 1` ..
  2641     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2642   qed
  2643 
  2644   have "z < pi / 4"
  2645   proof (rule ccontr)
  2646     assume "\<not> (z < pi / 4)" hence "pi / 4 < z" using `z \<noteq> pi / 4` by auto
  2647     have "- (pi / 2) < pi / 4" using m2pi_less_pi by auto
  2648     from tan_monotone[OF this `pi / 4 < z` `z < pi / 2`] 
  2649     have "1 < x" unfolding `tan z = x` `tan (pi / 4) = 1` .
  2650     thus False using `\<bar>x\<bar> < 1` by auto
  2651   qed
  2652   moreover 
  2653   have "-(pi / 4) < z"
  2654   proof (rule ccontr)
  2655     assume "\<not> (-(pi / 4) < z)" hence "z < - (pi / 4)" using `z \<noteq> - (pi / 4)` by auto
  2656     have "-(pi / 4) < pi / 2" using m2pi_less_pi by auto
  2657     from tan_monotone[OF `-(pi / 2) < z` `z < -(pi / 4)` this]
  2658     have "x < - 1" unfolding `tan z = x` `tan (-(pi / 4)) = - 1` .
  2659     thus False using `\<bar>x\<bar> < 1` by auto
  2660   qed
  2661   ultimately show ?thesis using `tan z = x` by auto
  2662 qed
  2663 
  2664 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  2665   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  2666 proof -
  2667   obtain y' where "-(pi/4) < y'" and "y' < pi/4" and "tan y' = y" using tan_total_pi4[OF `\<bar>y\<bar> < 1`] by blast
  2668 
  2669   have "pi / 4 < pi / 2" by auto
  2670 
  2671   have "\<exists> x'. -(pi/4) \<le> x' \<and> x' \<le> pi/4 \<and> tan x' = x"
  2672   proof (cases "\<bar>x\<bar> < 1")
  2673     case True from tan_total_pi4[OF this] obtain x' where "-(pi/4) < x'" and "x' < pi/4" and "tan x' = x" by blast
  2674     hence "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by auto
  2675     thus ?thesis by auto
  2676   next
  2677     case False
  2678     show ?thesis
  2679     proof (cases "x = 1")
  2680       case True hence "tan (pi/4) = x" using tan_45 by auto
  2681       moreover 
  2682       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2683       hence "-(pi/4) \<le> pi/4" and "pi/4 \<le> pi/4" by auto
  2684       ultimately show ?thesis by blast
  2685     next
  2686       case False hence "x = -1" using `\<not> \<bar>x\<bar> < 1` and `\<bar>x\<bar> \<le> 1` by auto
  2687       hence "tan (-(pi/4)) = x" using tan_45 tan_minus by auto
  2688       moreover 
  2689       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2690       hence "-(pi/4) \<le> pi/4" and "-(pi/4) \<le> -(pi/4)" by auto
  2691       ultimately show ?thesis by blast
  2692     qed
  2693   qed
  2694   then obtain x' where "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by blast
  2695   hence "-(pi/2) < x'" and "x' < pi/2" using order_le_less_trans[OF `x' \<le> pi/4` `pi / 4 < pi / 2`] by auto
  2696 
  2697   have "cos x' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/2) < x'` and `x' < pi/2` by auto
  2698   moreover have "cos y' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/4) < y'` and `y' < pi/4` by auto
  2699   ultimately have "cos x' * cos y' \<noteq> 0" by auto
  2700 
  2701   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> (A / C) / (B / C) = A / B" by auto
  2702   have divide_mult_commute: "\<And> A B C D :: real. A * B / (C * D) = (A / C) * (B / D)" by auto
  2703 
  2704   have "tan (x' + y') = sin (x' + y') / (cos x' * cos y' - sin x' * sin y')" unfolding tan_def cos_add ..
  2705   also have "\<dots> = (tan x' + tan y') / ((cos x' * cos y' - sin x' * sin y') / (cos x' * cos y'))" unfolding add_tan_eq[OF `cos x' \<noteq> 0` `cos y' \<noteq> 0`] divide_nonzero_divide[OF `cos x' * cos y' \<noteq> 0`] ..
  2706   also have "\<dots> = (tan x' + tan y') / (1 - tan x' * tan y')" unfolding tan_def diff_divide_distrib divide_self[OF `cos x' * cos y' \<noteq> 0`] unfolding divide_mult_commute ..
  2707   finally have tan_eq: "tan (x' + y') = (x + y) / (1 - x * y)" unfolding `tan y' = y` `tan x' = x` .
  2708 
  2709   have "arctan (tan (x' + y')) = x' + y'" using `-(pi/4) < y'` `-(pi/4) \<le> x'` `y' < pi/4` and `x' \<le> pi/4` by (auto intro!: arctan_tan)
  2710   moreover have "arctan (tan (x')) = x'" using `-(pi/2) < x'` and `x' < pi/2` by (auto intro!: arctan_tan)
  2711   moreover have "arctan (tan (y')) = y'" using `-(pi/4) < y'` and `y' < pi/4` by (auto intro!: arctan_tan)
  2712   ultimately have "arctan x + arctan y = arctan (tan (x' + y'))" unfolding `tan y' = y` [symmetric] `tan x' = x`[symmetric] by auto
  2713   thus "arctan x + arctan y = arctan ((x + y) / (1 - x * y))" unfolding tan_eq .
  2714 qed
  2715 
  2716 lemma arctan1_eq_pi4: "arctan 1 = pi / 4" unfolding tan_45[symmetric] by (rule arctan_tan, auto simp add: m2pi_less_pi)
  2717 
  2718 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  2719 proof -
  2720   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  2721   from arctan_add[OF less_imp_le[OF this] this]
  2722   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  2723   moreover
  2724   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  2725   from arctan_add[OF less_imp_le[OF this] this]
  2726   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  2727   moreover 
  2728   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  2729   from arctan_add[OF this]
  2730   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  2731   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  2732   thus ?thesis unfolding arctan1_eq_pi4 by algebra
  2733 qed
  2734 subsection {* Introducing the arcus tangens power series *}
  2735 
  2736 lemma monoseq_arctan_series: fixes x :: real
  2737   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  2738 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  2739 next
  2740   case False
  2741   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2742   show "monoseq ?a"
  2743   proof -
  2744     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  2745       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  2746       proof (rule mult_mono)
  2747         show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  2748         show "0 \<le> 1 / real (Suc (n * 2))" by auto
  2749         show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  2750         show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  2751       qed
  2752     } note mono = this
  2753     
  2754     show ?thesis
  2755     proof (cases "0 \<le> x")
  2756       case True from mono[OF this `x \<le> 1`, THEN allI]
  2757       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  2758     next
  2759       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  2760       from mono[OF this]
  2761       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  2762       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  2763     qed
  2764   qed
  2765 qed
  2766 
  2767 lemma zeroseq_arctan_series: fixes x :: real
  2768   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  2769 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: LIMSEQ_const)
  2770 next
  2771   case False
  2772   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2773   show "?a ----> 0"
  2774   proof (cases "\<bar>x\<bar> < 1")
  2775     case True hence "norm x < 1" by auto
  2776     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  2777     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  2778       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  2779     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  2780   next
  2781     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2782     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  2783     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] LIMSEQ_const[of x]]
  2784     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  2785   qed
  2786 qed
  2787 
  2788 lemma summable_arctan_series: fixes x :: real and n :: nat
  2789   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  2790   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  2791 
  2792 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  2793 proof -
  2794   from mult_mono1[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  2795   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  2796   thus ?thesis using zero_le_power2 by auto
  2797 qed 
  2798 
  2799 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  2800   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  2801 proof -
  2802   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  2803 
  2804   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  2805   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  2806 
  2807   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  2808     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  2809       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  2810     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  2811   } note summable_Integral = this
  2812 
  2813   { fix f :: "nat \<Rightarrow> real"
  2814     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2815     proof
  2816       fix x :: real assume "f sums x" 
  2817       from sums_if[OF sums_zero this]
  2818       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  2819     next
  2820       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2821       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  2822       show "f sums x" unfolding sums_def by auto
  2823     qed
  2824     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  2825   } note sums_even = this
  2826 
  2827   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  2828     by auto
  2829 
  2830   { fix x :: real
  2831     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n = 
  2832       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  2833       using n_even by auto
  2834     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto 
  2835     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  2836       by auto
  2837   } note arctan_eq = this
  2838 
  2839   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  2840   proof (rule DERIV_power_series')
  2841     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  2842     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  2843       hence "\<bar>x'\<bar> < 1" by auto
  2844 
  2845       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  2846       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  2847         by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  2848     }
  2849   qed auto
  2850   thus ?thesis unfolding Int_eq arctan_eq .
  2851 qed
  2852 
  2853 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  2854   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  2855 proof -
  2856   let "?c' x n" = "(-1)^n * x^(n*2)"
  2857 
  2858   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  2859     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  2860     from DERIV_arctan_series[OF this]
  2861     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  2862   } note DERIV_arctan_suminf = this
  2863 
  2864   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  2865   note arctan_series_borders = this
  2866 
  2867   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  2868   proof -
  2869     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  2870     hence "0 < r" and "-r < x" and "x < r" by auto
  2871 
  2872     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2873     proof -
  2874       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  2875       hence "\<bar>x\<bar> < r" by auto
  2876       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2877       proof (rule DERIV_isconst2[of "a" "b"])
  2878         show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  2879         have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  2880         proof (rule allI, rule impI)
  2881           fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  2882           hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  2883           have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  2884           hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  2885           hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  2886           hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  2887           have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  2888             by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  2889           from DERIV_add_minus[OF this DERIV_arctan]
  2890           show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  2891         qed
  2892         hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  2893         thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  2894         show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  2895       qed
  2896     qed
  2897     
  2898     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  2899       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  2900     
  2901     have "suminf (?c x) - arctan x = 0"
  2902     proof (cases "x = 0")
  2903       case True thus ?thesis using suminf_arctan_zero by auto
  2904     next
  2905       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  2906       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  2907         by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric])
  2908           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2909       moreover
  2910       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  2911         by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"])
  2912           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2913       ultimately 
  2914       show ?thesis using suminf_arctan_zero by auto
  2915     qed
  2916     thus ?thesis by auto
  2917   qed } note when_less_one = this
  2918 
  2919   show "arctan x = suminf (\<lambda> n. ?c x n)"
  2920   proof (cases "\<bar>x\<bar> < 1")
  2921     case True thus ?thesis by (rule when_less_one)
  2922   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2923     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  2924     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  2925     { fix n :: nat
  2926       have "0 < (1 :: real)" by auto
  2927       moreover
  2928       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  2929         from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  2930         note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  2931         have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  2932         hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  2933         have "?diff x n \<le> ?a x n"
  2934         proof (cases "even n")
  2935           case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  2936           from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  2937           from bounds[of m, unfolded this atLeastAtMost_iff]
  2938           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  2939           also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  2940           also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  2941           finally show ?thesis .
  2942         next
  2943           case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  2944           from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  2945           hence m_plus: "2 * (m + 1) = n + 1" by auto
  2946           from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  2947           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  2948           also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  2949           also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  2950           finally show ?thesis .
  2951         qed
  2952         hence "0 \<le> ?a x n - ?diff x n" by auto
  2953       }
  2954       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  2955       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  2956         unfolding real_diff_def divide_inverse
  2957         by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  2958       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  2959       hence "?diff 1 n \<le> ?a 1 n" by auto
  2960     }
  2961     have "?a 1 ----> 0"
  2962       unfolding LIMSEQ_rabs_zero power_one divide_inverse One_nat_def
  2963       by (auto intro!: LIMSEQ_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  2964     have "?diff 1 ----> 0"
  2965     proof (rule LIMSEQ_I)
  2966       fix r :: real assume "0 < r"
  2967       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  2968       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  2969         have "norm (?diff 1 n - 0) < r" by auto }
  2970       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  2971     qed
  2972     from this[unfolded LIMSEQ_rabs_zero real_diff_def add_commute[of "arctan 1"], THEN LIMSEQ_add_const, of "- arctan 1", THEN LIMSEQ_minus]
  2973     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  2974     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  2975     
  2976     show ?thesis
  2977     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  2978       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  2979       
  2980       have "- (pi / 2) < 0" using pi_gt_zero by auto
  2981       have "- (2 * pi) < 0" using pi_gt_zero by auto
  2982       
  2983       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  2984     
  2985       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  2986       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  2987       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  2988       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  2989       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  2990       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  2991       finally show ?thesis using `x = -1` by auto
  2992     qed
  2993   qed
  2994 qed
  2995 
  2996 lemma arctan_half: fixes x :: real
  2997   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  2998 proof -
  2999   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  3000   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  3001 
  3002   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  3003   
  3004   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  3005   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  3006 
  3007   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  3008   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  3009   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  3010   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  3011 
  3012   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  3013   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  3014   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  3015   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  3016   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  3017 
  3018   have "arctan x = y" using arctan_tan low high y_eq by auto
  3019   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  3020   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half[OF low2 high2] by auto
  3021   finally show ?thesis unfolding eq `tan y = x` .
  3022 qed
  3023 
  3024 lemma arctan_monotone: assumes "x < y"
  3025   shows "arctan x < arctan y"
  3026 proof -
  3027   obtain z where "-(pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  3028   obtain w where "-(pi / 2) < w" and "w < pi / 2" and "tan w = y" using tan_total by blast
  3029   have "z < w" unfolding tan_monotone'[OF `-(pi / 2) < z` `z < pi / 2` `-(pi / 2) < w` `w < pi / 2`] `tan z = x` `tan w = y` using `x < y` .
  3030   thus ?thesis
  3031     unfolding `tan z = x`[symmetric] arctan_tan[OF `-(pi / 2) < z` `z < pi / 2`]
  3032     unfolding `tan w = y`[symmetric] arctan_tan[OF `-(pi / 2) < w` `w < pi / 2`] .
  3033 qed
  3034 
  3035 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  3036 proof (cases "x = y") 
  3037   case False hence "x < y" using `x \<le> y` by auto from arctan_monotone[OF this] show ?thesis by auto
  3038 qed auto
  3039 
  3040 lemma arctan_minus: "arctan (- x) = - arctan x" 
  3041 proof -
  3042   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3043   thus ?thesis unfolding `tan y = x`[symmetric] tan_minus[symmetric] using arctan_tan[of y] arctan_tan[of "-y"] by auto 
  3044 qed
  3045 
  3046 lemma arctan_inverse: assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  3047 proof -
  3048   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3049   hence "y = arctan x" unfolding `tan y = x`[symmetric] using arctan_tan by auto
  3050 
  3051   { fix y x :: real assume "0 < y" and "y < pi /2" and "y = arctan x" and "tan y = x" hence "- (pi / 2) < y" by auto
  3052     have "tan y > 0" using tan_monotone'[OF _ _ `- (pi / 2) < y` `y < pi / 2`, of 0] tan_zero `0 < y` by auto
  3053     hence "x > 0" using `tan y = x` by auto
  3054 
  3055     have "- (pi / 2) < pi / 2 - y" using `y > 0` `y < pi / 2` by auto
  3056     moreover have "pi / 2 - y < pi / 2" using `y > 0` `y < pi / 2` by auto
  3057     ultimately have "arctan (1 / x) = pi / 2 - y" unfolding `tan y = x`[symmetric] tan_inverse using arctan_tan by auto
  3058     hence "arctan (1 / x) = sgn x * pi / 2 - arctan x" unfolding `y = arctan x` real_sgn_pos[OF `x > 0`] by auto
  3059   } note pos_y = this
  3060 
  3061   show ?thesis
  3062   proof (cases "y > 0")
  3063     case True from pos_y[OF this `y < pi / 2` `y = arctan x` `tan y = x`] show ?thesis .
  3064   next
  3065     case False hence "y \<le> 0" by auto
  3066     moreover have "y \<noteq> 0" 
  3067     proof (rule ccontr)
  3068       assume "\<not> y \<noteq> 0" hence "y = 0" by auto
  3069       have "x = 0" unfolding `tan y = x`[symmetric] `y = 0` tan_zero ..
  3070       thus False using `x \<noteq> 0` by auto
  3071     qed
  3072     ultimately have "y < 0" by auto
  3073     hence "0 < - y" and "-y < pi / 2" using `- (pi / 2) < y` by auto
  3074     moreover have "-y = arctan (-x)" unfolding arctan_minus `y = arctan x` ..
  3075     moreover have "tan (-y) = -x" unfolding tan_minus `tan y = x` ..
  3076     ultimately have "arctan (1 / -x) = sgn (-x) * pi / 2 - arctan (-x)" using pos_y by blast
  3077     hence "arctan (- (1 / x)) = - (sgn x * pi / 2 - arctan x)" unfolding arctan_minus[of x] divide_minus_right sgn_minus by auto
  3078     thus ?thesis unfolding arctan_minus neg_equal_iff_equal .
  3079   qed
  3080 qed
  3081 
  3082 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  3083 proof -
  3084   have "pi / 4 = arctan 1" using arctan1_eq_pi4 by auto
  3085   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  3086   finally show ?thesis by auto
  3087 qed
  3088 
  3089 subsection {* Existence of Polar Coordinates *}
  3090 
  3091 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  3092 apply (rule power2_le_imp_le [OF _ zero_le_one])
  3093 apply (simp add: power_divide divide_le_eq not_sum_power2_lt_zero)
  3094 done
  3095 
  3096 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  3097 by (simp add: abs_le_iff)
  3098 
  3099 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  3100 by (simp add: sin_arccos abs_le_iff)
  3101 
  3102 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  3103 
  3104 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  3105 
  3106 lemma polar_ex1:
  3107      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3108 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  3109 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  3110 apply (simp add: cos_arccos_lemma1)
  3111 apply (simp add: sin_arccos_lemma1)
  3112 apply (simp add: power_divide)
  3113 apply (simp add: real_sqrt_mult [symmetric])
  3114 apply (simp add: right_diff_distrib)
  3115 done
  3116 
  3117 lemma polar_ex2:
  3118      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3119 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  3120 apply (metis cos_minus minus_minus minus_mult_right sin_minus)
  3121 done
  3122 
  3123 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  3124 apply (rule_tac x=0 and y=y in linorder_cases)
  3125 apply (erule polar_ex1)
  3126 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  3127 apply (erule polar_ex2)
  3128 done
  3129 
  3130 end