src/HOL/Library/Commutative_Ring.thy
author haftmann
Mon Jul 07 08:47:17 2008 +0200 (2008-07-07)
changeset 27487 c8a6ce181805
parent 27368 9f90ac19e32b
child 28952 15a4b2cf8c34
permissions -rw-r--r--
absolute imports of HOL/*.thy theories
     1 (*  ID:         $Id$
     2     Author:     Bernhard Haeupler
     3 
     4 Proving equalities in commutative rings done "right" in Isabelle/HOL.
     5 *)
     6 
     7 header {* Proving equalities in commutative rings *}
     8 
     9 theory Commutative_Ring
    10 imports Plain "~~/src/HOL/List" Parity
    11 uses ("comm_ring.ML")
    12 begin
    13 
    14 text {* Syntax of multivariate polynomials (pol) and polynomial expressions. *}
    15 
    16 datatype 'a pol =
    17     Pc 'a
    18   | Pinj nat "'a pol"
    19   | PX "'a pol" nat "'a pol"
    20 
    21 datatype 'a polex =
    22     Pol "'a pol"
    23   | Add "'a polex" "'a polex"
    24   | Sub "'a polex" "'a polex"
    25   | Mul "'a polex" "'a polex"
    26   | Pow "'a polex" nat
    27   | Neg "'a polex"
    28 
    29 text {* Interpretation functions for the shadow syntax. *}
    30 
    31 fun
    32   Ipol :: "'a::{comm_ring,recpower} list \<Rightarrow> 'a pol \<Rightarrow> 'a"
    33 where
    34     "Ipol l (Pc c) = c"
    35   | "Ipol l (Pinj i P) = Ipol (drop i l) P"
    36   | "Ipol l (PX P x Q) = Ipol l P * (hd l)^x + Ipol (drop 1 l) Q"
    37 
    38 fun
    39   Ipolex :: "'a::{comm_ring,recpower} list \<Rightarrow> 'a polex \<Rightarrow> 'a"
    40 where
    41     "Ipolex l (Pol P) = Ipol l P"
    42   | "Ipolex l (Add P Q) = Ipolex l P + Ipolex l Q"
    43   | "Ipolex l (Sub P Q) = Ipolex l P - Ipolex l Q"
    44   | "Ipolex l (Mul P Q) = Ipolex l P * Ipolex l Q"
    45   | "Ipolex l (Pow p n) = Ipolex l p ^ n"
    46   | "Ipolex l (Neg P) = - Ipolex l P"
    47 
    48 text {* Create polynomial normalized polynomials given normalized inputs. *}
    49 
    50 definition
    51   mkPinj :: "nat \<Rightarrow> 'a pol \<Rightarrow> 'a pol" where
    52   "mkPinj x P = (case P of
    53     Pc c \<Rightarrow> Pc c |
    54     Pinj y P \<Rightarrow> Pinj (x + y) P |
    55     PX p1 y p2 \<Rightarrow> Pinj x P)"
    56 
    57 definition
    58   mkPX :: "'a::{comm_ring,recpower} pol \<Rightarrow> nat \<Rightarrow> 'a pol \<Rightarrow> 'a pol" where
    59   "mkPX P i Q = (case P of
    60     Pc c \<Rightarrow> (if (c = 0) then (mkPinj 1 Q) else (PX P i Q)) |
    61     Pinj j R \<Rightarrow> PX P i Q |
    62     PX P2 i2 Q2 \<Rightarrow> (if (Q2 = (Pc 0)) then (PX P2 (i+i2) Q) else (PX P i Q)) )"
    63 
    64 text {* Defining the basic ring operations on normalized polynomials *}
    65 
    66 function
    67   add :: "'a::{comm_ring,recpower} pol \<Rightarrow> 'a pol \<Rightarrow> 'a pol" (infixl "\<oplus>" 65)
    68 where
    69     "Pc a \<oplus> Pc b = Pc (a + b)"
    70   | "Pc c \<oplus> Pinj i P = Pinj i (P \<oplus> Pc c)"
    71   | "Pinj i P \<oplus> Pc c = Pinj i (P \<oplus> Pc c)"
    72   | "Pc c \<oplus> PX P i Q = PX P i (Q \<oplus> Pc c)"
    73   | "PX P i Q \<oplus> Pc c = PX P i (Q \<oplus> Pc c)"
    74   | "Pinj x P \<oplus> Pinj y Q =
    75       (if x = y then mkPinj x (P \<oplus> Q)
    76        else (if x > y then mkPinj y (Pinj (x - y) P \<oplus> Q)
    77          else mkPinj x (Pinj (y - x) Q \<oplus> P)))"
    78   | "Pinj x P \<oplus> PX Q y R =
    79       (if x = 0 then P \<oplus> PX Q y R
    80        else (if x = 1 then PX Q y (R \<oplus> P)
    81          else PX Q y (R \<oplus> Pinj (x - 1) P)))"
    82   | "PX P x R \<oplus> Pinj y Q =
    83       (if y = 0 then PX P x R \<oplus> Q
    84        else (if y = 1 then PX P x (R \<oplus> Q)
    85          else PX P x (R \<oplus> Pinj (y - 1) Q)))"
    86   | "PX P1 x P2 \<oplus> PX Q1 y Q2 =
    87       (if x = y then mkPX (P1 \<oplus> Q1) x (P2 \<oplus> Q2)
    88        else (if x > y then mkPX (PX P1 (x - y) (Pc 0) \<oplus> Q1) y (P2 \<oplus> Q2)
    89          else mkPX (PX Q1 (y-x) (Pc 0) \<oplus> P1) x (P2 \<oplus> Q2)))"
    90 by pat_completeness auto
    91 termination by (relation "measure (\<lambda>(x, y). size x + size y)") auto
    92 
    93 function
    94   mul :: "'a::{comm_ring,recpower} pol \<Rightarrow> 'a pol \<Rightarrow> 'a pol" (infixl "\<otimes>" 70)
    95 where
    96     "Pc a \<otimes> Pc b = Pc (a * b)"
    97   | "Pc c \<otimes> Pinj i P =
    98       (if c = 0 then Pc 0 else mkPinj i (P \<otimes> Pc c))"
    99   | "Pinj i P \<otimes> Pc c =
   100       (if c = 0 then Pc 0 else mkPinj i (P \<otimes> Pc c))"
   101   | "Pc c \<otimes> PX P i Q =
   102       (if c = 0 then Pc 0 else mkPX (P \<otimes> Pc c) i (Q \<otimes> Pc c))"
   103   | "PX P i Q \<otimes> Pc c =
   104       (if c = 0 then Pc 0 else mkPX (P \<otimes> Pc c) i (Q \<otimes> Pc c))"
   105   | "Pinj x P \<otimes> Pinj y Q =
   106       (if x = y then mkPinj x (P \<otimes> Q) else
   107          (if x > y then mkPinj y (Pinj (x-y) P \<otimes> Q)
   108            else mkPinj x (Pinj (y - x) Q \<otimes> P)))"
   109   | "Pinj x P \<otimes> PX Q y R =
   110       (if x = 0 then P \<otimes> PX Q y R else
   111          (if x = 1 then mkPX (Pinj x P \<otimes> Q) y (R \<otimes> P)
   112            else mkPX (Pinj x P \<otimes> Q) y (R \<otimes> Pinj (x - 1) P)))"
   113   | "PX P x R \<otimes> Pinj y Q =
   114       (if y = 0 then PX P x R \<otimes> Q else
   115          (if y = 1 then mkPX (Pinj y Q \<otimes> P) x (R \<otimes> Q)
   116            else mkPX (Pinj y Q \<otimes> P) x (R \<otimes> Pinj (y - 1) Q)))"
   117   | "PX P1 x P2 \<otimes> PX Q1 y Q2 =
   118       mkPX (P1 \<otimes> Q1) (x + y) (P2 \<otimes> Q2) \<oplus>
   119         (mkPX (P1 \<otimes> mkPinj 1 Q2) x (Pc 0) \<oplus>
   120           (mkPX (Q1 \<otimes> mkPinj 1 P2) y (Pc 0)))"
   121 by pat_completeness auto
   122 termination by (relation "measure (\<lambda>(x, y). size x + size y)")
   123   (auto simp add: mkPinj_def split: pol.split)
   124 
   125 text {* Negation*}
   126 fun
   127   neg :: "'a::{comm_ring,recpower} pol \<Rightarrow> 'a pol"
   128 where
   129     "neg (Pc c) = Pc (-c)"
   130   | "neg (Pinj i P) = Pinj i (neg P)"
   131   | "neg (PX P x Q) = PX (neg P) x (neg Q)"
   132 
   133 text {* Substraction *}
   134 definition
   135   sub :: "'a::{comm_ring,recpower} pol \<Rightarrow> 'a pol \<Rightarrow> 'a pol" (infixl "\<ominus>" 65)
   136 where
   137   "sub P Q = P \<oplus> neg Q"
   138 
   139 text {* Square for Fast Exponentation *}
   140 fun
   141   sqr :: "'a::{comm_ring,recpower} pol \<Rightarrow> 'a pol"
   142 where
   143     "sqr (Pc c) = Pc (c * c)"
   144   | "sqr (Pinj i P) = mkPinj i (sqr P)"
   145   | "sqr (PX A x B) = mkPX (sqr A) (x + x) (sqr B) \<oplus>
   146       mkPX (Pc (1 + 1) \<otimes> A \<otimes> mkPinj 1 B) x (Pc 0)"
   147 
   148 text {* Fast Exponentation *}
   149 fun
   150   pow :: "nat \<Rightarrow> 'a::{comm_ring,recpower} pol \<Rightarrow> 'a pol"
   151 where
   152     "pow 0 P = Pc 1"
   153   | "pow n P = (if even n then pow (n div 2) (sqr P)
   154        else P \<otimes> pow (n div 2) (sqr P))"
   155   
   156 lemma pow_if:
   157   "pow n P =
   158    (if n = 0 then Pc 1 else if even n then pow (n div 2) (sqr P)
   159     else P \<otimes> pow (n div 2) (sqr P))"
   160   by (cases n) simp_all
   161 
   162 
   163 text {* Normalization of polynomial expressions *}
   164 
   165 fun
   166   norm :: "'a::{comm_ring,recpower} polex \<Rightarrow> 'a pol"
   167 where
   168     "norm (Pol P) = P"
   169   | "norm (Add P Q) = norm P \<oplus> norm Q"
   170   | "norm (Sub P Q) = norm P \<ominus> norm Q"
   171   | "norm (Mul P Q) = norm P \<otimes> norm Q"
   172   | "norm (Pow P n) = pow n (norm P)"
   173   | "norm (Neg P) = neg (norm P)"
   174 
   175 text {* mkPinj preserve semantics *}
   176 lemma mkPinj_ci: "Ipol l (mkPinj a B) = Ipol l (Pinj a B)"
   177   by (induct B) (auto simp add: mkPinj_def ring_simps)
   178 
   179 text {* mkPX preserves semantics *}
   180 lemma mkPX_ci: "Ipol l (mkPX A b C) = Ipol l (PX A b C)"
   181   by (cases A) (auto simp add: mkPX_def mkPinj_ci power_add ring_simps)
   182 
   183 text {* Correctness theorems for the implemented operations *}
   184 
   185 text {* Negation *}
   186 lemma neg_ci: "Ipol l (neg P) = -(Ipol l P)"
   187   by (induct P arbitrary: l) auto
   188 
   189 text {* Addition *}
   190 lemma add_ci: "Ipol l (P \<oplus> Q) = Ipol l P + Ipol l Q"
   191 proof (induct P Q arbitrary: l rule: add.induct)
   192   case (6 x P y Q)
   193   show ?case
   194   proof (rule linorder_cases)
   195     assume "x < y"
   196     with 6 show ?case by (simp add: mkPinj_ci ring_simps)
   197   next
   198     assume "x = y"
   199     with 6 show ?case by (simp add: mkPinj_ci)
   200   next
   201     assume "x > y"
   202     with 6 show ?case by (simp add: mkPinj_ci ring_simps)
   203   qed
   204 next
   205   case (7 x P Q y R)
   206   have "x = 0 \<or> x = 1 \<or> x > 1" by arith
   207   moreover
   208   { assume "x = 0" with 7 have ?case by simp }
   209   moreover
   210   { assume "x = 1" with 7 have ?case by (simp add: ring_simps) }
   211   moreover
   212   { assume "x > 1" from 7 have ?case by (cases x) simp_all }
   213   ultimately show ?case by blast
   214 next
   215   case (8 P x R y Q)
   216   have "y = 0 \<or> y = 1 \<or> y > 1" by arith
   217   moreover
   218   { assume "y = 0" with 8 have ?case by simp }
   219   moreover
   220   { assume "y = 1" with 8 have ?case by simp }
   221   moreover
   222   { assume "y > 1" with 8 have ?case by simp }
   223   ultimately show ?case by blast
   224 next
   225   case (9 P1 x P2 Q1 y Q2)
   226   show ?case
   227   proof (rule linorder_cases)
   228     assume a: "x < y" hence "EX d. d + x = y" by arith
   229     with 9 a show ?case by (auto simp add: mkPX_ci power_add ring_simps)
   230   next
   231     assume a: "y < x" hence "EX d. d + y = x" by arith
   232     with 9 a show ?case by (auto simp add: power_add mkPX_ci ring_simps)
   233   next
   234     assume "x = y"
   235     with 9 show ?case by (simp add: mkPX_ci ring_simps)
   236   qed
   237 qed (auto simp add: ring_simps)
   238 
   239 text {* Multiplication *}
   240 lemma mul_ci: "Ipol l (P \<otimes> Q) = Ipol l P * Ipol l Q"
   241   by (induct P Q arbitrary: l rule: mul.induct)
   242     (simp_all add: mkPX_ci mkPinj_ci ring_simps add_ci power_add)
   243 
   244 text {* Substraction *}
   245 lemma sub_ci: "Ipol l (P \<ominus> Q) = Ipol l P - Ipol l Q"
   246   by (simp add: add_ci neg_ci sub_def)
   247 
   248 text {* Square *}
   249 lemma sqr_ci: "Ipol ls (sqr P) = Ipol ls P * Ipol ls P"
   250   by (induct P arbitrary: ls)
   251     (simp_all add: add_ci mkPinj_ci mkPX_ci mul_ci ring_simps power_add)
   252 
   253 text {* Power *}
   254 lemma even_pow:"even n \<Longrightarrow> pow n P = pow (n div 2) (sqr P)"
   255   by (induct n) simp_all
   256 
   257 lemma pow_ci: "Ipol ls (pow n P) = Ipol ls P ^ n"
   258 proof (induct n arbitrary: P rule: nat_less_induct)
   259   case (1 k)
   260   show ?case
   261   proof (cases k)
   262     case 0
   263     then show ?thesis by simp
   264   next
   265     case (Suc l)
   266     show ?thesis
   267     proof cases
   268       assume "even l"
   269       then have "Suc l div 2 = l div 2"
   270         by (simp add: nat_number even_nat_plus_one_div_two)
   271       moreover
   272       from Suc have "l < k" by simp
   273       with 1 have "\<And>P. Ipol ls (pow l P) = Ipol ls P ^ l" by simp
   274       moreover
   275       note Suc `even l` even_nat_plus_one_div_two
   276       ultimately show ?thesis by (auto simp add: mul_ci power_Suc even_pow)
   277     next
   278       assume "odd l"
   279       {
   280         fix p
   281         have "Ipol ls (sqr P) ^ (Suc l div 2) = Ipol ls P ^ Suc l"
   282         proof (cases l)
   283           case 0
   284           with `odd l` show ?thesis by simp
   285         next
   286           case (Suc w)
   287           with `odd l` have "even w" by simp
   288           have two_times: "2 * (w div 2) = w"
   289             by (simp only: numerals even_nat_div_two_times_two [OF `even w`])
   290           have "Ipol ls P * Ipol ls P = Ipol ls P ^ Suc (Suc 0)"
   291             by (simp add: power_Suc)
   292 	  then have "Ipol ls P * Ipol ls P = Ipol ls P ^ 2"
   293 	    by (simp add: numerals)
   294           with Suc show ?thesis
   295             by (auto simp add: power_mult [symmetric, of _ 2 _] two_times mul_ci sqr_ci)
   296         qed
   297       } with 1 Suc `odd l` show ?thesis by simp
   298     qed
   299   qed
   300 qed
   301 
   302 text {* Normalization preserves semantics  *}
   303 lemma norm_ci: "Ipolex l Pe = Ipol l (norm Pe)"
   304   by (induct Pe) (simp_all add: add_ci sub_ci mul_ci neg_ci pow_ci)
   305 
   306 text {* Reflection lemma: Key to the (incomplete) decision procedure *}
   307 lemma norm_eq:
   308   assumes "norm P1 = norm P2"
   309   shows "Ipolex l P1 = Ipolex l P2"
   310 proof -
   311   from prems have "Ipol l (norm P1) = Ipol l (norm P2)" by simp
   312   then show ?thesis by (simp only: norm_ci)
   313 qed
   314 
   315 
   316 use "comm_ring.ML"
   317 setup CommRing.setup
   318 
   319 end